src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16     #include "wx/app.h"
  17     #include "wx/dialog.h"
  18     #include "wx/menuitem.h"
  19     #include "wx/menu.h"
  20 #endif
  21
  22 #include "wx/osx/private.h"
  23
  24 NSScreen* wxOSXGetMenuScreen()
  25 {
  26     if ( [NSScreen screens] == nil )
  27         return [NSScreen mainScreen];
  28     else
  29     {
  30         return [[NSScreen screens] objectAtIndex:0];
  31     }
  32 }
  33
  34 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  35 {
  36     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  37     int y = r.y;
  38     int x = r.x ;
  39     if ( parent == NULL || ![ parent isFlipped ] )
  40         y = (int)(frame.size.height - ( r.y + r.height ));
  41     return NSMakeRect(x, y, r.width , r.height);
  42 }
  43
  44 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  45 {
  46     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  47     int y = (int)rect.origin.y;
  48     int x = (int)rect.origin.x;
  49     if ( parent == NULL || ![ parent isFlipped ] )
  50         y = (int)(frame.size.height - (rect.origin.y + rect.size.height));
  51     return wxRect( x, y, (int)rect.size.width, (int)rect.size.height );
  52 }
  53
  54 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  55 {
  56     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  57     int x = p.x ;
  58     int y = p.y;
  59     if ( parent == NULL || ![ parent isFlipped ] )
  60         y = (int)(frame.size.height - ( p.y ));
  61     return NSMakePoint(x, y);
  62 }
  63
  64 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  65 {
  66     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  67     int x = (int)p.x;
  68     int y = (int)p.y;
  69     if ( parent == NULL || ![ parent isFlipped ] )
  70         y = (int)(frame.size.height - ( p.y ));
  71     return wxPoint( x, y);
  72 }
  73
  74 bool shouldHandleSelector(SEL selector)
  75 {
  76     if (selector == @selector(noop:)
  77             || selector == @selector(complete:)
  78             || selector == @selector(deleteBackward:)
  79             || selector == @selector(deleteForward:)
  80             || selector == @selector(insertNewline:)
  81             || selector == @selector(insertTab:)
  82             || selector == @selector(insertBacktab:)
  83             || selector == @selector(keyDown:)
  84             || selector == @selector(keyUp:)
  85             || selector == @selector(scrollPageUp:)
  86             || selector == @selector(scrollPageDown:)
  87             || selector == @selector(scrollToBeginningOfDocument:)
  88             || selector == @selector(scrollToEndOfDocument:))
  89         return false;
  90
  91     return true;
  92
  93 }
  94
  95 //
  96 // wx category for NSWindow (our own and wrapped instances)
  97 //
  98
  99 @interface NSWindow (wxNSWindowSupport)
 100
 101 - (wxNonOwnedWindowCocoaImpl*) WX_implementation;
 102
 103 - (bool) WX_filterSendEvent:(NSEvent *) event;
 104
 105 @end
 106
 107 @implementation NSWindow (wxNSWindowSupport)
 108
 109 - (wxNonOwnedWindowCocoaImpl*) WX_implementation
 110 {
 111     return (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 112 }
 113
 114 // TODO in cocoa everything during a drag is sent to the NSWindow the mouse down occured,
 115 // this does not conform to the wx behaviour if the window is not captured, so try to resend
 116 // or capture all wx mouse event handling at the tlw as we did for carbon
 117
 118 - (bool) WX_filterSendEvent:(NSEvent *) event
 119 {
 120     bool handled = false;
 121     if ( ([event type] >= NSLeftMouseDown) && ([event type] <= NSMouseExited) )
 122     {
 123         wxWindow* cw = wxWindow::GetCapture();
 124         if ( cw != NULL )
 125         {
 126             ((wxWidgetCocoaImpl*)cw->GetPeer())->DoHandleMouseEvent( event);
 127             handled = true;
 128         }
 129     }
 130     return handled;
 131 }
 132 @end
 133
 134 //
 135 // wx native implementation
 136 //
 137
 138 @interface wxNSWindow : NSWindow
 139 {
 140 }
 141
 142 - (void) sendEvent:(NSEvent *)event;
 143 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 144 - (void)noResponderFor: (SEL) selector;
 145 @end
 146
 147 @implementation wxNSWindow
 148
 149 - (void)sendEvent:(NSEvent *) event
 150 {
 151     if ( ![self WX_filterSendEvent: event] )
 152     {
 153         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 154         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 155
 156         if (wxTheApp)
 157             wxTheApp->MacSetCurrentEvent(event, NULL);
 158
 159         [super sendEvent: event];
 160
 161         if (wxTheApp)
 162             wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 163     }
 164 }
 165
 166 // The default implementation always moves the window back onto the screen,
 167 // even when the programmer explicitly wants to hide it.
 168 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 169 {
 170     wxUnusedVar(screen);
 171     return frameRect;
 172 }
 173
 174 - (void)doCommandBySelector:(SEL)selector
 175 {
 176     if (shouldHandleSelector(selector) &&
 177         !(selector == @selector(cancel:) || selector == @selector(cancelOperation:)) )
 178         [super doCommandBySelector:selector];
 179 }
 180
 181
 182 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 183 - (void)noResponderFor: (SEL) selector
 184 {
 185     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 186     {
 187         [super noResponderFor:selector];
 188     }
 189 }
 190
 191 // We need this for borderless windows, i.e. shaped windows or windows without
 192 // a title bar. For more info, see:
 193 // http://lists.apple.com/archives/cocoa-dev/2008/May/msg02091.html
 194 - (BOOL)canBecomeKeyWindow
 195 {
 196     return YES;
 197 }
 198
 199 @end
 200
 201 @interface wxNSPanel : NSPanel
 202 {
 203 }
 204
 205 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 206 - (void)noResponderFor: (SEL) selector;
 207 - (void)sendEvent:(NSEvent *)event;
 208 @end
 209
 210 @implementation wxNSPanel
 211
 212 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 213 {
 214     wxNonOwnedWindowCocoaImpl* impl = (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 215     if (impl && impl->IsFullScreen())
 216         return frameRect;
 217     else
 218         return [super constrainFrameRect:frameRect toScreen:screen];
 219 }
 220
 221 - (BOOL)canBecomeKeyWindow
 222 {
 223     return YES;
 224 }
 225
 226 - (void)doCommandBySelector:(SEL)selector
 227 {
 228     if (shouldHandleSelector(selector))
 229         [super doCommandBySelector:selector];
 230 }
 231
 232 // NB: if we don't do this, it seems that all events that end here lead to a NSBeep
 233 - (void)noResponderFor: (SEL) selector
 234 {
 235     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 236     {
 237         [super noResponderFor:selector];
 238     }
 239 }
 240
 241 - (void)sendEvent:(NSEvent *) event
 242 {
 243     if ( ![self WX_filterSendEvent: event] )
 244         [super sendEvent: event];
 245 }
 246
 247 @end
 248
 249
 250 //
 251 // controller
 252 //
 253
 254 @interface wxNonOwnedWindowController : NSObject wxOSX_10_6_AND_LATER(<NSWindowDelegate>)
 255 {
 256 }
 257
 258 - (void)windowDidResize:(NSNotification *)notification;
 259 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 260 - (void)windowDidResignKey:(NSNotification *)notification;
 261 - (void)windowDidBecomeKey:(NSNotification *)notification;
 262 - (void)windowDidMove:(NSNotification *)notification;
 263 - (BOOL)windowShouldClose:(id)window;
 264 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame;
 265
 266 @end
 267
 268 extern int wxOSXGetIdFromSelector(SEL action );
 269
 270 @implementation wxNonOwnedWindowController
 271
 272 - (id) init
 273 {
 274     self = [super init];
 275     return self;
 276 }
 277
 278 - (BOOL) triggerMenu:(SEL) action
 279 {
 280     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 281     if ( mbar )
 282     {
 283         wxMenu* menu = NULL;
 284         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 285         if ( menu != NULL && menuitem != NULL)
 286             return menu->HandleCommandProcess(menuitem);
 287     }
 288     return NO;
 289 }
 290
 291 - (BOOL)validateMenuItem:(NSMenuItem *)menuItem
 292 {
 293     SEL action = [menuItem action];
 294
 295     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 296     if ( mbar )
 297     {
 298         wxMenu* menu = NULL;
 299         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 300         if ( menu != NULL && menuitem != NULL)
 301         {
 302             menu->HandleCommandUpdateStatus(menuitem);
 303             return menuitem->IsEnabled();
 304         }
 305     }
 306     return YES;
 307 }
 308
 309 - (void)undo:(id)sender
 310 {
 311     wxUnusedVar(sender);
 312     [self triggerMenu:_cmd];
 313 }
 314
 315 - (void)redo:(id)sender
 316 {
 317     wxUnusedVar(sender);
 318     [self triggerMenu:_cmd];
 319 }
 320
 321 - (void)cut:(id)sender
 322 {
 323     wxUnusedVar(sender);
 324     [self triggerMenu:_cmd];
 325 }
 326
 327 - (void)copy:(id)sender
 328 {
 329     wxUnusedVar(sender);
 330     [self triggerMenu:_cmd];
 331 }
 332
 333 - (void)paste:(id)sender
 334 {
 335     wxUnusedVar(sender);
 336     [self triggerMenu:_cmd];
 337 }
 338
 339 - (void)delete:(id)sender
 340 {
 341     wxUnusedVar(sender);
 342     [self triggerMenu:_cmd];
 343 }
 344
 345 - (void)selectAll:(id)sender
 346 {
 347     wxUnusedVar(sender);
 348     [self triggerMenu:_cmd];
 349 }
 350
 351 - (BOOL)windowShouldClose:(id)nwindow
 352 {
 353     wxNonOwnedWindowCocoaImpl* windowimpl = [(NSWindow*) nwindow WX_implementation];
 354     if ( windowimpl )
 355     {
 356         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 357         if ( wxpeer )
 358             wxpeer->Close();
 359     }
 360     return NO;
 361 }
 362
 363 - (NSSize)windowWillResize:(NSWindow *)window
 364                     toSize:(NSSize)proposedFrameSize
 365 {
 366     NSRect frame = [window frame];
 367     wxRect wxframe = wxFromNSRect( NULL, frame );
 368     wxframe.SetWidth( (int)proposedFrameSize.width );
 369     wxframe.SetHeight( (int)proposedFrameSize.height );
 370
 371     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 372     if ( windowimpl )
 373     {
 374         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 375         if ( wxpeer )
 376         {
 377             wxpeer->HandleResizing( 0, &wxframe );
 378             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 379             return newSize;
 380         }
 381     }
 382
 383     return proposedFrameSize;
 384 }
 385
 386 - (void)windowDidResize:(NSNotification *)notification
 387 {
 388     NSWindow* window = (NSWindow*) [notification object];
 389     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 390     if ( windowimpl )
 391     {
 392         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 393         if ( wxpeer )
 394             wxpeer->HandleResized(0);
 395     }
 396 }
 397
 398 - (void)windowDidMove:(NSNotification *)notification
 399 {
 400     wxNSWindow* window = (wxNSWindow*) [notification object];
 401     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 402     if ( windowimpl )
 403     {
 404         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 405         if ( wxpeer )
 406             wxpeer->HandleMoved(0);
 407     }
 408 }
 409
 410 - (void)windowDidBecomeKey:(NSNotification *)notification
 411 {
 412     NSWindow* window = (NSWindow*) [notification object];
 413     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 414     if ( windowimpl )
 415     {
 416         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 417         if ( wxpeer )
 418             wxpeer->HandleActivated(0, true);
 419     }
 420 }
 421
 422 - (void)windowDidResignKey:(NSNotification *)notification
 423 {
 424     NSWindow* window = (NSWindow*) [notification object];
 425     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 426     if ( windowimpl )
 427     {
 428         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 429         if ( wxpeer )
 430         {
 431             wxpeer->HandleActivated(0, false);
 432             // Needed for popup window since the firstResponder
 433             // (focus in wx) doesn't change when this
 434             // TLW becomes inactive.
 435             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 436             event.SetEventObject(wxpeer);
 437             wxpeer->HandleWindowEvent(event);
 438         }
 439     }
 440 }
 441
 442 - (id)windowWillReturnFieldEditor:(NSWindow *)sender toObject:(id)anObject
 443 {
 444     wxUnusedVar(sender);
 445
 446     if ([anObject isKindOfClass:[wxNSTextField class]])
 447     {
 448         wxNSTextField* tf = (wxNSTextField*) anObject;
 449         wxNSTextFieldEditor* editor = [tf fieldEditor];
 450         if ( editor == nil )
 451         {
 452             editor = [[wxNSTextFieldEditor alloc] init];
 453             [editor setFieldEditor:YES];
 454             [tf setFieldEditor:editor];
 455         }
 456         return editor;
 457     }
 458
 459     return nil;
 460 }
 461
 462 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame
 463 {
 464     wxUnusedVar(newFrame);
 465     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 466     if ( windowimpl )
 467     {
 468         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 469         wxMaximizeEvent event(wxpeer->GetId());
 470         event.SetEventObject(wxpeer);
 471         return !wxpeer->HandleWindowEvent(event);
 472     }
 473     return true;
 474 }
 475
 476 @end
 477
 478 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 479
 480 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 481     wxNonOwnedWindowImpl(nonownedwnd)
 482 {
 483     m_macWindow = NULL;
 484     m_macFullScreenData = NULL;
 485 }
 486
 487 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 488 {
 489     m_macWindow = NULL;
 490     m_macFullScreenData = NULL;
 491 }
 492
 493 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 494 {
 495     if ( !m_wxPeer->IsNativeWindowWrapper() )
 496     {
 497         [m_macWindow setDelegate:nil];
 498         [m_macWindow release];
 499     }
 500 }
 501
 502 void wxNonOwnedWindowCocoaImpl::WillBeDestroyed()
 503 {
 504     if ( !m_wxPeer->IsNativeWindowWrapper() )
 505     {
 506         [m_macWindow setDelegate:nil];
 507     }
 508 }
 509
 510 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* parent, const wxPoint& pos, const wxSize& size,
 511 long style, long extraStyle, const wxString& WXUNUSED(name) )
 512 {
 513     static wxNonOwnedWindowController* controller = NULL;
 514
 515     if ( !controller )
 516         controller =[[wxNonOwnedWindowController alloc] init];
 517
 518
 519     int windowstyle = NSBorderlessWindowMask;
 520
 521     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 522             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 523     {
 524         m_macWindow = [wxNSPanel alloc];
 525     }
 526     else
 527         m_macWindow = [wxNSWindow alloc];
 528
 529     CGWindowLevel level = kCGNormalWindowLevel;
 530
 531     if ( style & wxFRAME_TOOL_WINDOW )
 532     {
 533         windowstyle |= NSUtilityWindowMask;
 534         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 535             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 536         {
 537             windowstyle |= NSTitledWindowMask ;
 538         }
 539     }
 540     else if ( ( style & wxPOPUP_WINDOW ) )
 541     {
 542         level = kCGPopUpMenuWindowLevel;
 543         /*
 544         if ( ( style & wxBORDER_NONE ) )
 545         {
 546             wclass = kHelpWindowClass ;   // has no border
 547             attr |= kWindowNoShadowAttribute;
 548         }
 549         else
 550         {
 551             wclass = kPlainWindowClass ;  // has a single line border, it will have to do for now
 552         }
 553         */
 554     }
 555     else if ( ( style & wxCAPTION ) )
 556     {
 557         windowstyle |= NSTitledWindowMask ;
 558     }
 559     else if ( ( style & wxFRAME_DRAWER ) )
 560     {
 561         /*
 562         wclass = kDrawerWindowClass;
 563         */
 564     }
 565     else
 566     {
 567         // set these even if we have no title, otherwise the controls won't be visible
 568         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 569             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 570         {
 571             windowstyle |= NSTitledWindowMask ;
 572         }
 573         /*
 574         else if ( ( style & wxNO_BORDER ) )
 575         {
 576             wclass = kSimpleWindowClass ;
 577         }
 578         else
 579         {
 580             wclass = kPlainWindowClass ;
 581         }
 582         */
 583     }
 584
 585     if ( windowstyle & NSTitledWindowMask )
 586     {
 587         if ( ( style & wxMINIMIZE_BOX ) )
 588             windowstyle |= NSMiniaturizableWindowMask ;
 589
 590         if ( ( style & wxMAXIMIZE_BOX ) )
 591             windowstyle |= NSResizableWindowMask ; // TODO showing ZOOM ?
 592
 593         if ( ( style & wxRESIZE_BORDER ) )
 594             windowstyle |= NSResizableWindowMask ;
 595
 596         if ( ( style & wxCLOSE_BOX) )
 597             windowstyle |= NSClosableWindowMask ;
 598     }
 599     if ( extraStyle & wxFRAME_EX_METAL)
 600         windowstyle |= NSTexturedBackgroundWindowMask;
 601
 602     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 603         level = kCGFloatingWindowLevel;
 604
 605     if ( ( style & wxSTAY_ON_TOP ) )
 606         level = kCGUtilityWindowLevel;
 607
 608     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 609
 610     r = [NSWindow contentRectForFrameRect:r styleMask:windowstyle];
 611
 612     [m_macWindow initWithContentRect:r
 613         styleMask:windowstyle
 614         backing:NSBackingStoreBuffered
 615         defer:NO
 616         ];
 617
 618     // If the parent is modal, windows with wxFRAME_FLOAT_ON_PARENT style need
 619     // to be in kCGUtilityWindowLevel and not kCGFloatingWindowLevel to stay
 620     // above the parent.
 621     wxDialog * const parentDialog = wxDynamicCast(parent, wxDialog);
 622     if (parentDialog && parentDialog->IsModal())
 623     {
 624         if (level == kCGFloatingWindowLevel)
 625         {
 626             level = kCGUtilityWindowLevel;
 627         }
 628
 629         // Cocoa's modal loop does not process other windows by default, but
 630         // don't call this on normal window levels so nested modal dialogs will
 631         // still behave modally.
 632         if (level != kCGNormalWindowLevel)
 633         {
 634             if ([m_macWindow isKindOfClass:[NSPanel class]])
 635             {
 636                 [(NSPanel*)m_macWindow setWorksWhenModal:YES];
 637             }
 638         }
 639     }
 640
 641     [m_macWindow setLevel:level];
 642     m_macWindowLevel = level;
 643
 644     [m_macWindow setDelegate:controller];
 645
 646     [m_macWindow setAcceptsMouseMovedEvents: YES];
 647
 648     if ( ( style & wxFRAME_SHAPED) )
 649     {
 650         [m_macWindow setOpaque:NO];
 651         [m_macWindow setAlphaValue:1.0];
 652     }
 653
 654     if ( !(style & wxFRAME_TOOL_WINDOW) )
 655         [m_macWindow setHidesOnDeactivate:NO];
 656 }
 657
 658 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), WXWindow nativeWindow )
 659 {
 660     m_macWindow = nativeWindow;
 661 }
 662
 663 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 664 {
 665     return m_macWindow;
 666 }
 667
 668 void wxNonOwnedWindowCocoaImpl::Raise()
 669 {
 670     [m_macWindow makeKeyAndOrderFront:nil];
 671 }
 672
 673 void wxNonOwnedWindowCocoaImpl::Lower()
 674 {
 675     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 676 }
 677
 678 void wxNonOwnedWindowCocoaImpl::ShowWithoutActivating()
 679 {
 680     [m_macWindow orderFront:nil];
 681     [[m_macWindow contentView] setNeedsDisplay: YES];
 682 }
 683
 684 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 685 {
 686     if ( show )
 687     {
 688         wxNonOwnedWindow* wxpeer = GetWXPeer();
 689         if (wxpeer && !(wxpeer->GetWindowStyle() & wxFRAME_TOOL_WINDOW))
 690             [m_macWindow makeKeyAndOrderFront:nil];
 691         else
 692             [m_macWindow orderFront:nil];
 693         [[m_macWindow contentView] setNeedsDisplay: YES];
 694     }
 695     else
 696         [m_macWindow orderOut:nil];
 697     return true;
 698 }
 699
 700 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show,
 701                                                wxShowEffect effect,
 702                                                unsigned timeout)
 703 {
 704     return wxWidgetCocoaImpl::
 705             ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
 706 }
 707
 708 void wxNonOwnedWindowCocoaImpl::Update()
 709 {
 710     [m_macWindow displayIfNeeded];
 711 }
 712
 713 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 714 {
 715     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 716     return true;
 717 }
 718
 719 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& col )
 720 {
 721     [m_macWindow setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
 722                                                              green:(CGFloat) (col.Green() / 255.0)
 723                                                               blue:(CGFloat) (col.Blue() / 255.0)
 724                                                              alpha:(CGFloat) (col.Alpha() / 255.0)]];
 725     return true;
 726 }
 727
 728 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 729 {
 730     if ( m_macWindow )
 731     {
 732         bool metal = exStyle & wxFRAME_EX_METAL ;
 733         int windowStyle = [ m_macWindow styleMask];
 734         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 735         {
 736             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 737         }
 738         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 739         {
 740             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 741         }
 742     }
 743 }
 744
 745 void wxNonOwnedWindowCocoaImpl::SetWindowStyleFlag( long style )
 746 {
 747     if (m_macWindow)
 748     {
 749         CGWindowLevel level = kCGNormalWindowLevel;
 750
 751         if (style & wxSTAY_ON_TOP)
 752             level = kCGUtilityWindowLevel;
 753         else if (( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ))
 754             level = kCGFloatingWindowLevel;
 755
 756         [m_macWindow setLevel: level];
 757         m_macWindowLevel = level;
 758     }
 759 }
 760
 761 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle style)
 762 {
 763     if ( style == wxBG_STYLE_TRANSPARENT )
 764     {
 765         [m_macWindow setOpaque:NO];
 766         [m_macWindow setBackgroundColor:[NSColor clearColor]];
 767     }
 768
 769     return true;
 770 }
 771
 772 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 773 {
 774     return true;
 775 }
 776
 777 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 778 {
 779     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 780     // do not trigger refreshes upon invisible and possible partly created objects
 781     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 782 }
 783
 784 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 785 {
 786     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 787     x = r.GetLeft();
 788     y = r.GetTop();
 789 }
 790
 791 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 792 {
 793     NSRect rect = [m_macWindow frame];
 794     width = (int)rect.size.width;
 795     height = (int)rect.size.height;
 796 }
 797
 798 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 799 {
 800     NSRect rect = [[m_macWindow contentView] frame];
 801     left = (int)rect.origin.x;
 802     top = (int)rect.origin.y;
 803     width = (int)rect.size.width;
 804     height = (int)rect.size.height;
 805 }
 806
 807 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& WXUNUSED(region))
 808 {
 809     [m_macWindow setOpaque:NO];
 810     [m_macWindow setBackgroundColor:[NSColor clearColor]];
 811
 812     return true;
 813 }
 814
 815 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 816 {
 817     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 818 }
 819
 820 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 821 {
 822     if (([m_macWindow styleMask] & NSResizableWindowMask) != 0)
 823     {
 824         return [m_macWindow isZoomed];
 825     }
 826     else
 827     {
 828         NSRect rectScreen = [[NSScreen mainScreen] visibleFrame];
 829         NSRect rectWindow = [m_macWindow frame];
 830         return (rectScreen.origin.x == rectWindow.origin.x &&
 831                 rectScreen.origin.y == rectWindow.origin.y &&
 832                 rectScreen.size.width == rectWindow.size.width &&
 833                 rectScreen.size.height == rectWindow.size.height);
 834     }
 835 }
 836
 837 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 838 {
 839     return [m_macWindow isMiniaturized];
 840 }
 841
 842 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 843 {
 844     if ( iconize )
 845         [m_macWindow miniaturize:nil];
 846     else
 847         [m_macWindow deminiaturize:nil];
 848 }
 849
 850 void wxNonOwnedWindowCocoaImpl::Maximize(bool WXUNUSED(maximize))
 851 {
 852     [m_macWindow zoom:nil];
 853 }
 854
 855
 856 // http://cocoadevcentral.com/articles/000028.php
 857
 858 typedef struct
 859 {
 860     int m_formerLevel;
 861     NSRect m_formerFrame;
 862 } FullScreenData ;
 863
 864 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 865 {
 866     return m_macFullScreenData != NULL ;
 867 }
 868
 869 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long WXUNUSED(style))
 870 {
 871     if ( show )
 872     {
 873         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 874         delete data ;
 875         data = new FullScreenData();
 876
 877         m_macFullScreenData = data ;
 878         data->m_formerLevel = [m_macWindow level];
 879         data->m_formerFrame = [m_macWindow frame];
 880 #if 0
 881         // CGDisplayCapture( kCGDirectMainDisplay );
 882         //[m_macWindow setLevel:NSMainMenuWindowLevel+1/*CGShieldingWindowLevel()*/];
 883 #endif
 884         NSRect screenframe = [[NSScreen mainScreen] frame];
 885         NSRect frame = NSMakeRect (0, 0, 100, 100);
 886         NSRect contentRect;
 887         contentRect = [NSWindow contentRectForFrameRect: frame
 888                                 styleMask: [m_macWindow styleMask]];
 889         screenframe.origin.y += (frame.origin.y - contentRect.origin.y);
 890         screenframe.size.height += (frame.size.height - contentRect.size.height);
 891         [m_macWindow setFrame:screenframe display:YES];
 892
 893         SetSystemUIMode(kUIModeAllHidden,
 894                                 kUIOptionDisableAppleMenu
 895                         /*
 896                                 | kUIOptionDisableProcessSwitch
 897                                 | kUIOptionDisableForceQuit
 898                          */);
 899     }
 900     else if ( m_macFullScreenData != NULL )
 901     {
 902         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 903 #if 0
 904         // CGDisplayRelease( kCGDirectMainDisplay );
 905         // [m_macWindow setLevel:data->m_formerLevel];
 906 #endif
 907
 908         [m_macWindow setFrame:data->m_formerFrame display:YES];
 909         delete data ;
 910         m_macFullScreenData = NULL ;
 911
 912         SetSystemUIMode(kUIModeNormal, 0);
 913     }
 914
 915     return true;
 916 }
 917
 918 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int flagsWX)
 919 {
 920     NSRequestUserAttentionType flagsOSX;
 921     switch ( flagsWX )
 922     {
 923         case wxUSER_ATTENTION_INFO:
 924             flagsOSX = NSInformationalRequest;
 925             break;
 926
 927         case wxUSER_ATTENTION_ERROR:
 928             flagsOSX = NSCriticalRequest;
 929             break;
 930
 931         default:
 932             wxFAIL_MSG( "invalid RequestUserAttention() flags" );
 933             return;
 934     }
 935
 936     [NSApp requestUserAttention:flagsOSX];
 937 }
 938
 939 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 940 {
 941     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 942     NSPoint nspt = wxToNSPoint( NULL, p );
 943     nspt = [m_macWindow convertScreenToBase:nspt];
 944     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 945     p = wxFromNSPoint([m_macWindow contentView], nspt);
 946     if ( x )
 947         *x = p.x;
 948     if ( y )
 949         *y = p.y;
 950 }
 951
 952 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 953 {
 954     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 955     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 956     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 957     nspt = [m_macWindow convertBaseToScreen:nspt];
 958     p = wxFromNSPoint( NULL, nspt);
 959     if ( x )
 960         *x = p.x;
 961     if ( y )
 962         *y = p.y;
 963 }
 964
 965 bool wxNonOwnedWindowCocoaImpl::IsActive()
 966 {
 967     return [m_macWindow isKeyWindow];
 968 }
 969
 970 void wxNonOwnedWindowCocoaImpl::SetModified(bool modified)
 971 {
 972     [m_macWindow setDocumentEdited:modified];
 973 }
 974
 975 bool wxNonOwnedWindowCocoaImpl::IsModified() const
 976 {
 977     return [m_macWindow isDocumentEdited];
 978 }
 979
 980 void wxNonOwnedWindowCocoaImpl::RestoreWindowLevel()
 981 {
 982     if ( [m_macWindow level] != m_macWindowLevel )
 983         [m_macWindow setLevel:m_macWindowLevel];
 984 }
 985
 986 //
 987 //
 988 //
 989
 990 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, WXWindow nativeWindow)
 991 {
 992     wxNonOwnedWindowCocoaImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
 993     now->Create( parent, nativeWindow );
 994     return now;
 995 }
 996
 997 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
 998     long style, long extraStyle, const wxString& name )
 999 {
1000     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1001     now->Create( parent, pos, size, style , extraStyle, name );
1002     return now;
1003 }
1004