src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     BOOL _hasToolTip;
  91     NSTrackingRectTag   _lastToolTipTrackTag;
  92     id              _lastToolTipOwner;
  93     void*           _lastUserData;
  94
  95 }
  96
  97 @end // wxNSView
  98
  99 @interface NSView(PossibleMethods)
 100 - (void)setTitle:(NSString *)aString;
 101 - (void)setStringValue:(NSString *)aString;
 102 - (void)setIntValue:(int)anInt;
 103 - (void)setFloatValue:(float)aFloat;
 104 - (void)setDoubleValue:(double)aDouble;
 105
 106 - (double)minValue;
 107 - (double)maxValue;
 108 - (void)setMinValue:(double)aDouble;
 109 - (void)setMaxValue:(double)aDouble;
 110
 111 - (void)sizeToFit;
 112
 113 - (BOOL)isEnabled;
 114 - (void)setEnabled:(BOOL)flag;
 115
 116 - (void)setImage:(NSImage *)image;
 117 - (void)setControlSize:(NSControlSize)size;
 118
 119 - (void)setFont:(NSFont *)fontObject;
 120
 121 - (id)contentView;
 122
 123 - (void)setTarget:(id)anObject;
 124 - (void)setAction:(SEL)aSelector;
 125 - (void)setDoubleAction:(SEL)aSelector;
 126 - (void)setBackgroundColor:(NSColor*)aColor;
 127 - (void)setOpaque:(BOOL)opaque;
 128 - (void)setTextColor:(NSColor *)color;
 129 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 130 @end
 131
 132 // The following code is a combination of the code listed here:
 133 // http://lists.apple.com/archives/cocoa-dev/2008/Apr/msg01582.html
 134 // (which can't be used because KLGetCurrentKeyboardLayout etc aren't 64-bit)
 135 // and the code here:
 136 // http://inquisitivecocoa.com/category/objective-c/
 137 @interface NSEvent (OsGuiUtilsAdditions)
 138 - (NSString*) charactersIgnoringModifiersIncludingShift;
 139 @end
 140
 141 @implementation NSEvent (OsGuiUtilsAdditions)
 142 - (NSString*) charactersIgnoringModifiersIncludingShift {
 143     // First try -charactersIgnoringModifiers and look for keys which UCKeyTranslate translates
 144     // differently than AppKit.
 145     NSString* c = [self charactersIgnoringModifiers];
 146     if ([c length] == 1) {
 147         unichar codepoint = [c characterAtIndex:0];
 148         if ((codepoint >= 0xF700 && codepoint <= 0xF8FF) || codepoint == 0x7F) {
 149             return c;
 150         }
 151     }
 152     // This is not a "special" key, so ask UCKeyTranslate to give us the character with no
 153     // modifiers attached.  Actually, that's not quite accurate; we attach the Command modifier
 154     // which hints the OS to use Latin characters where possible, which is generally what we want.
 155     NSString* result = @"";
 156     TISInputSourceRef currentKeyboard = TISCopyCurrentKeyboardInputSource();
 157     CFDataRef uchr = (CFDataRef)TISGetInputSourceProperty(currentKeyboard, kTISPropertyUnicodeKeyLayoutData);
 158     CFRelease(currentKeyboard);
 159     if (uchr == NULL) {
 160         // this can happen for some non-U.S. input methods (eg. Romaji or Hiragana)
 161         return c;
 162     }
 163     const UCKeyboardLayout *keyboardLayout = (const UCKeyboardLayout*)CFDataGetBytePtr(uchr);
 164     if (keyboardLayout) {
 165         UInt32 deadKeyState = 0;
 166         UniCharCount maxStringLength = 255;
 167         UniCharCount actualStringLength = 0;
 168         UniChar unicodeString[maxStringLength];
 169
 170         OSStatus status = UCKeyTranslate(keyboardLayout,
 171                                          [self keyCode],
 172                                          kUCKeyActionDown,
 173                                          cmdKey >> 8,         // force the Command key to "on"
 174                                          LMGetKbdType(),
 175                                          kUCKeyTranslateNoDeadKeysMask,
 176                                          &deadKeyState,
 177                                          maxStringLength,
 178                                          &actualStringLength,
 179                                          unicodeString);
 180
 181         if(status == noErr)
 182             result = [NSString stringWithCharacters:unicodeString length:(NSInteger)actualStringLength];
 183     }
 184     return result;
 185 }
 186 @end
 187
 188 long wxOSXTranslateCocoaKey( NSEvent* event, int eventType )
 189 {
 190     long retval = 0;
 191
 192     if ([event type] != NSFlagsChanged)
 193     {
 194         NSString* s = [event charactersIgnoringModifiersIncludingShift];
 195         // backspace char reports as delete w/modifiers for some reason
 196         if ([s length] == 1)
 197         {
 198             if ( eventType == wxEVT_CHAR && ([event modifierFlags] & NSControlKeyMask) && ( [s characterAtIndex:0] >= 'a' && [s characterAtIndex:0] <= 'z' ) )
 199             {
 200                 retval = WXK_CONTROL_A + ([s characterAtIndex:0] - 'a');
 201             }
 202             else
 203             {
 204                 switch ( [s characterAtIndex:0] )
 205                 {
 206                     // backspace key
 207                     case 0x7F :
 208                     case 8 :
 209                         retval = WXK_BACK;
 210                         break;
 211                     case NSUpArrowFunctionKey :
 212                         retval = WXK_UP;
 213                         break;
 214                     case NSDownArrowFunctionKey :
 215                         retval = WXK_DOWN;
 216                         break;
 217                     case NSLeftArrowFunctionKey :
 218                         retval = WXK_LEFT;
 219                         break;
 220                     case NSRightArrowFunctionKey :
 221                         retval = WXK_RIGHT;
 222                         break;
 223                     case NSInsertFunctionKey  :
 224                         retval = WXK_INSERT;
 225                         break;
 226                     case NSDeleteFunctionKey  :
 227                         retval = WXK_DELETE;
 228                         break;
 229                     case NSHomeFunctionKey  :
 230                         retval = WXK_HOME;
 231                         break;
 232             //        case NSBeginFunctionKey  :
 233             //            retval = WXK_BEGIN;
 234             //            break;
 235                     case NSEndFunctionKey  :
 236                         retval = WXK_END;
 237                         break;
 238                     case NSPageUpFunctionKey  :
 239                         retval = WXK_PAGEUP;
 240                         break;
 241                    case NSPageDownFunctionKey  :
 242                         retval = WXK_PAGEDOWN;
 243                         break;
 244                    case NSHelpFunctionKey  :
 245                         retval = WXK_HELP;
 246                         break;
 247                     default:
 248                         int intchar = [s characterAtIndex: 0];
 249                         if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 250                             retval = WXK_F1 + (intchar - NSF1FunctionKey );
 251                         else if ( intchar > 0 && intchar < 32 )
 252                             retval = intchar;
 253                         break;
 254                 }
 255             }
 256         }
 257     }
 258
 259     // Some keys don't seem to have constants. The code mimics the approach
 260     // taken by WebKit. See:
 261     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 262     switch( [event keyCode] )
 263     {
 264         // command key
 265         case 54:
 266         case 55:
 267             retval = WXK_CONTROL;
 268             break;
 269         // caps locks key
 270         case 57: // Capslock
 271             retval = WXK_CAPITAL;
 272             break;
 273         // shift key
 274         case 56: // Left Shift
 275         case 60: // Right Shift
 276             retval = WXK_SHIFT;
 277             break;
 278         // alt key
 279         case 58: // Left Alt
 280         case 61: // Right Alt
 281             retval = WXK_ALT;
 282             break;
 283         // ctrl key
 284         case 59: // Left Ctrl
 285         case 62: // Right Ctrl
 286             retval = WXK_RAW_CONTROL;
 287             break;
 288         // clear key
 289         case 71:
 290             retval = WXK_CLEAR;
 291             break;
 292         // tab key
 293         case 48:
 294             retval = WXK_TAB;
 295             break;
 296
 297         case 75: // /
 298             retval = WXK_NUMPAD_DIVIDE;
 299             break;
 300         case 67: // *
 301             retval = WXK_NUMPAD_MULTIPLY;
 302             break;
 303         case 78: // -
 304             retval = WXK_NUMPAD_SUBTRACT;
 305             break;
 306         case 69: // +
 307             retval = WXK_NUMPAD_ADD;
 308             break;
 309         case 76: // Enter
 310             retval = WXK_NUMPAD_ENTER;
 311             break;
 312         case 65: // .
 313             retval = WXK_NUMPAD_DECIMAL;
 314             break;
 315         case 82: // 0
 316             retval = WXK_NUMPAD0;
 317             break;
 318         case 83: // 1
 319             retval = WXK_NUMPAD1;
 320             break;
 321         case 84: // 2
 322             retval = WXK_NUMPAD2;
 323             break;
 324         case 85: // 3
 325             retval = WXK_NUMPAD3;
 326             break;
 327         case 86: // 4
 328             retval = WXK_NUMPAD4;
 329             break;
 330         case 87: // 5
 331             retval = WXK_NUMPAD5;
 332             break;
 333         case 88: // 6
 334             retval = WXK_NUMPAD6;
 335             break;
 336         case 89: // 7
 337             retval = WXK_NUMPAD7;
 338             break;
 339         case 91: // 8
 340             retval = WXK_NUMPAD8;
 341             break;
 342         case 92: // 9
 343             retval = WXK_NUMPAD9;
 344             break;
 345         default:
 346             //retval = [event keyCode];
 347             break;
 348     }
 349     return retval;
 350 }
 351
 352 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 353 {
 354     UInt32 modifiers = [nsEvent modifierFlags] ;
 355     int eventType = [nsEvent type];
 356
 357     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 358     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 359     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 360     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 361
 362     wxevent.m_rawCode = [nsEvent keyCode];
 363     wxevent.m_rawFlags = modifiers;
 364
 365     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 366
 367     wxString chars;
 368     if ( eventType != NSFlagsChanged )
 369     {
 370         NSString* nschars = [[nsEvent charactersIgnoringModifiersIncludingShift] uppercaseString];
 371         if ( charString )
 372         {
 373             // if charString is set, it did not come from key up / key down
 374             wxevent.SetEventType( wxEVT_CHAR );
 375             chars = wxCFStringRef::AsString(charString);
 376         }
 377         else if ( nschars )
 378         {
 379             chars = wxCFStringRef::AsString(nschars);
 380         }
 381     }
 382
 383     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 384     long keyval = 0;
 385
 386     if (wxevent.GetEventType() != wxEVT_CHAR)
 387     {
 388         keyval = wxOSXTranslateCocoaKey(nsEvent, wxevent.GetEventType()) ;
 389         switch (eventType)
 390         {
 391             case NSKeyDown :
 392                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 393                 break;
 394             case NSKeyUp :
 395                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 396                 break;
 397             case NSFlagsChanged :
 398                 switch (keyval)
 399                 {
 400                     case WXK_CONTROL:
 401                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 402                         break;
 403                     case WXK_SHIFT:
 404                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 405                         break;
 406                     case WXK_ALT:
 407                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 408                         break;
 409                     case WXK_RAW_CONTROL:
 410                         wxevent.SetEventType( wxevent.m_rawControlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 411                         break;
 412                 }
 413                 break;
 414             default :
 415                 break ;
 416         }
 417     }
 418
 419     if ( !keyval )
 420     {
 421         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 422             keyval = wxToupper( aunichar ) ;
 423         else
 424             keyval = aunichar;
 425     }
 426
 427 #if wxUSE_UNICODE
 428     // OS X generates events with key codes in Unicode private use area for
 429     // unprintable symbols such as cursor arrows (WXK_UP is mapped to U+F700)
 430     // and function keys (WXK_F2 is U+F705). We don't want to use them as the
 431     // result of wxKeyEvent::GetUnicodeKey() however as it's supposed to return
 432     // WXK_NONE for "non characters" so explicitly exclude them.
 433     //
 434     // We only exclude the private use area inside the Basic Multilingual Plane
 435     // as key codes beyond it don't seem to be currently used.
 436     if ( !(aunichar >= 0xe000 && aunichar < 0xf900) )
 437         wxevent.m_uniChar = aunichar;
 438 #endif
 439     wxevent.m_keyCode = keyval;
 440
 441     wxWindowMac* peer = GetWXPeer();
 442     if ( peer )
 443     {
 444         wxevent.SetEventObject(peer);
 445         wxevent.SetId(peer->GetId()) ;
 446     }
 447 }
 448
 449 UInt32 g_lastButton = 0 ;
 450 bool g_lastButtonWasFakeRight = false ;
 451
 452 // better scroll wheel support
 453 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 454
 455 @interface NSEvent (DeviceDelta)
 456 - (CGFloat)deviceDeltaX;
 457 - (CGFloat)deviceDeltaY;
 458
 459 // 10.7+
 460 - (BOOL)hasPreciseScrollingDeltas;
 461 - (CGFloat)scrollingDeltaX;
 462 - (CGFloat)scrollingDeltaY;
 463 @end
 464
 465 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 466 {
 467     int eventType = [nsEvent type];
 468     UInt32 modifiers = [nsEvent modifierFlags] ;
 469
 470     NSPoint locationInWindow = [nsEvent locationInWindow];
 471
 472     // adjust coordinates for the window of the target view
 473     if ( [nsEvent window] != [m_osxView window] )
 474     {
 475         if ( [nsEvent window] != nil )
 476             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 477
 478         if ( [m_osxView window] != nil )
 479             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 480     }
 481
 482     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 483     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 484
 485     // these parameters are not given for all events
 486     UInt32 button = [nsEvent buttonNumber];
 487     UInt32 clickCount = 0;
 488
 489     wxevent.m_x = locationInViewWX.x;
 490     wxevent.m_y = locationInViewWX.y;
 491     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 492     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 493     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 494     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 495     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 496
 497     UInt32 mouseChord = 0;
 498
 499     switch (eventType)
 500     {
 501         case NSLeftMouseDown :
 502         case NSLeftMouseDragged :
 503             mouseChord = 1U;
 504             break;
 505         case NSRightMouseDown :
 506         case NSRightMouseDragged :
 507             mouseChord = 2U;
 508             break;
 509         case NSOtherMouseDown :
 510         case NSOtherMouseDragged :
 511             mouseChord = 4U;
 512             break;
 513     }
 514
 515     // a control click is interpreted as a right click
 516     bool thisButtonIsFakeRight = false ;
 517     if ( button == 0 && (modifiers & NSControlKeyMask) )
 518     {
 519         button = 1 ;
 520         thisButtonIsFakeRight = true ;
 521     }
 522
 523     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 524     if ( clickCount > 1 && button != g_lastButton )
 525         clickCount = 1 ;
 526
 527     // we must make sure that our synthetic 'right' button corresponds in
 528     // mouse down, moved and mouse up, and does not deliver a right down and left up
 529     switch (eventType)
 530     {
 531         case NSLeftMouseDown :
 532         case NSRightMouseDown :
 533         case NSOtherMouseDown :
 534             g_lastButton = button ;
 535             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 536             break;
 537      }
 538
 539     if ( button == 0 )
 540     {
 541         g_lastButton = 0 ;
 542         g_lastButtonWasFakeRight = false ;
 543     }
 544     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 545         button = g_lastButton ;
 546
 547     // Adjust the chord mask to remove the primary button and add the
 548     // secondary button.  It is possible that the secondary button is
 549     // already pressed, e.g. on a mouse connected to a laptop, but this
 550     // possibility is ignored here:
 551     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 552         mouseChord = ((mouseChord & ~1U) | 2U);
 553
 554     if(mouseChord & 1U)
 555                 wxevent.m_leftDown = true ;
 556     if(mouseChord & 2U)
 557                 wxevent.m_rightDown = true ;
 558     if(mouseChord & 4U)
 559                 wxevent.m_middleDown = true ;
 560
 561     // translate into wx types
 562     switch (eventType)
 563     {
 564         case NSLeftMouseDown :
 565         case NSRightMouseDown :
 566         case NSOtherMouseDown :
 567             clickCount = [nsEvent clickCount];
 568             switch ( button )
 569             {
 570                 case 0 :
 571                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 572                     break ;
 573
 574                 case 1 :
 575                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 576                     break ;
 577
 578                 case 2 :
 579                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 580                     break ;
 581
 582                 default:
 583                     break ;
 584             }
 585             break ;
 586
 587         case NSLeftMouseUp :
 588         case NSRightMouseUp :
 589         case NSOtherMouseUp :
 590             clickCount = [nsEvent clickCount];
 591             switch ( button )
 592             {
 593                 case 0 :
 594                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 595                     break ;
 596
 597                 case 1 :
 598                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 599                     break ;
 600
 601                 case 2 :
 602                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 603                     break ;
 604
 605                 default:
 606                     break ;
 607             }
 608             break ;
 609
 610      case NSScrollWheel :
 611         {
 612             float deltaX = 0.0;
 613             float deltaY = 0.0;
 614
 615             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 616
 617             if ( UMAGetSystemVersion() >= 0x1070 )
 618             {
 619                 if ( [nsEvent hasPreciseScrollingDeltas] )
 620                 {
 621                     deltaX = [nsEvent scrollingDeltaX];
 622                     deltaY = [nsEvent scrollingDeltaY];
 623                 }
 624                 else
 625                 {
 626                     deltaX = [nsEvent scrollingDeltaX] * 10;
 627                     deltaY = [nsEvent scrollingDeltaY] * 10;
 628                 }
 629             }
 630             else
 631             {
 632                 const EventRef cEvent = (EventRef) [nsEvent eventRef];
 633                 // see http://developer.apple.com/qa/qa2005/qa1453.html
 634                 // for more details on why we have to look for the exact type
 635
 636                 bool isMouseScrollEvent = false;
 637                 if ( cEvent )
 638                     isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 639
 640                 if ( isMouseScrollEvent )
 641                 {
 642                     deltaX = [nsEvent deviceDeltaX];
 643                     deltaY = [nsEvent deviceDeltaY];
 644                 }
 645                 else
 646                 {
 647                     deltaX = ([nsEvent deltaX] * 10);
 648                     deltaY = ([nsEvent deltaY] * 10);
 649                 }
 650             }
 651
 652             wxevent.m_wheelDelta = 10;
 653             wxevent.m_linesPerAction = 1;
 654
 655             if ( fabs(deltaX) > fabs(deltaY) )
 656             {
 657                 wxevent.m_wheelAxis = wxMOUSE_WHEEL_HORIZONTAL;
 658                 wxevent.m_wheelRotation = (int)deltaX;
 659             }
 660             else
 661             {
 662                 wxevent.m_wheelRotation = (int)deltaY;
 663             }
 664
 665         }
 666         break ;
 667
 668         case NSMouseEntered :
 669             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 670             break;
 671         case NSMouseExited :
 672             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 673             break;
 674         case NSLeftMouseDragged :
 675         case NSRightMouseDragged :
 676         case NSOtherMouseDragged :
 677         case NSMouseMoved :
 678             wxevent.SetEventType( wxEVT_MOTION ) ;
 679             break;
 680         default :
 681             break ;
 682     }
 683
 684     wxevent.m_clickCount = clickCount;
 685     wxWindowMac* peer = GetWXPeer();
 686     if ( peer )
 687     {
 688         wxevent.SetEventObject(peer);
 689         wxevent.SetId(peer->GetId()) ;
 690     }
 691 }
 692
 693 @implementation wxNSView
 694
 695 + (void)initialize
 696 {
 697     static BOOL initialized = NO;
 698     if (!initialized)
 699     {
 700         initialized = YES;
 701         wxOSXCocoaClassAddWXMethods( self );
 702     }
 703 }
 704
 705 /* idea taken from webkit sources: overwrite the methods that (private) NSToolTipManager will use to attach its tracking rectangle
 706  * then when changing the tooltip send fake view-exit and view-enter methods which will lead to a tooltip refresh
 707  */
 708
 709
 710 - (void)_sendToolTipMouseExited
 711 {
 712     // Nothing matters except window, trackingNumber, and userData.
 713     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseExited
 714                                                 location:NSMakePoint(0, 0)
 715                                            modifierFlags:0
 716                                                timestamp:0
 717                                             windowNumber:[[self window] windowNumber]
 718                                                  context:NULL
 719                                              eventNumber:0
 720                                           trackingNumber:_lastToolTipTrackTag
 721                                                 userData:_lastUserData];
 722     [_lastToolTipOwner mouseExited:fakeEvent];
 723 }
 724
 725 - (void)_sendToolTipMouseEntered
 726 {
 727     // Nothing matters except window, trackingNumber, and userData.
 728     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseEntered
 729                                                 location:NSMakePoint(0, 0)
 730                                            modifierFlags:0
 731                                                timestamp:0
 732                                             windowNumber:[[self window] windowNumber]
 733                                                  context:NULL
 734                                              eventNumber:0
 735                                           trackingNumber:_lastToolTipTrackTag
 736                                                 userData:_lastUserData];
 737     [_lastToolTipOwner mouseEntered:fakeEvent];
 738 }
 739
 740 - (void)setToolTip:(NSString *)string;
 741 {
 742     if (string)
 743     {
 744         if ( _hasToolTip )
 745         {
 746             [self _sendToolTipMouseExited];
 747         }
 748
 749         [super setToolTip:string];
 750         _hasToolTip = YES;
 751         [self _sendToolTipMouseEntered];
 752     }
 753     else
 754     {
 755         if ( _hasToolTip )
 756         {
 757             [self _sendToolTipMouseExited];
 758             [super setToolTip:nil];
 759             _hasToolTip = NO;
 760         }
 761     }
 762 }
 763
 764 - (NSTrackingRectTag)addTrackingRect:(NSRect)rect owner:(id)owner userData:(void *)data assumeInside:(BOOL)assumeInside
 765 {
 766     NSTrackingRectTag tag = [super addTrackingRect:rect owner:owner userData:data assumeInside:assumeInside];
 767     if ( owner != self )
 768     {
 769         _lastUserData = data;
 770         _lastToolTipOwner = owner;
 771         _lastToolTipTrackTag = tag;
 772     }
 773     return tag;
 774 }
 775
 776 - (void)removeTrackingRect:(NSTrackingRectTag)tag
 777 {
 778     if (tag == _lastToolTipTrackTag)
 779     {
 780         _lastUserData = NULL;
 781         _lastToolTipOwner = nil;
 782         _lastToolTipTrackTag = 0;
 783     }
 784     [super removeTrackingRect:tag];
 785 }
 786 @end // wxNSView
 787
 788 //
 789 // event handlers
 790 //
 791
 792 #if wxUSE_DRAG_AND_DROP
 793
 794 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 795 // for details on the NSPasteboard -> PasteboardRef conversion
 796
 797 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 798 {
 799     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 800     if (impl == NULL)
 801         return NSDragOperationNone;
 802
 803     return impl->draggingEntered(sender, self, _cmd);
 804 }
 805
 806 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 807 {
 808     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 809     if (impl == NULL)
 810         return ;
 811
 812     return impl->draggingExited(sender, self, _cmd);
 813 }
 814
 815 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 816 {
 817     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 818     if (impl == NULL)
 819         return NSDragOperationNone;
 820
 821     return impl->draggingUpdated(sender, self, _cmd);
 822 }
 823
 824 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 825 {
 826     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 827     if (impl == NULL)
 828         return NSDragOperationNone;
 829
 830     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 831 }
 832
 833 #endif
 834
 835 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 836 {
 837     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 838     if (impl == NULL)
 839         return;
 840
 841     impl->mouseEvent(event, self, _cmd);
 842 }
 843
 844 void wxOSX_cursorUpdate(NSView* self, SEL _cmd, NSEvent *event)
 845 {
 846     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 847     if (impl == NULL)
 848         return;
 849
 850     impl->cursorUpdate(event, self, _cmd);
 851 }
 852
 853 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 854 {
 855     // This is needed to support click through, otherwise the first click on a window
 856     // will not do anything unless it is the active window already.
 857     return YES;
 858 }
 859
 860 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 861 {
 862     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 863     if (impl == NULL)
 864         return;
 865
 866     impl->keyEvent(event, self, _cmd);
 867 }
 868
 869 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 870 {
 871     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 872     if (impl == NULL)
 873         return;
 874
 875     impl->insertText(text, self, _cmd);
 876 }
 877
 878 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 879 {
 880     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 881     if (impl == NULL)
 882         return NO;
 883
 884     return impl->performKeyEquivalent(event, self, _cmd);
 885 }
 886
 887 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 888 {
 889     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 890     if (impl == NULL)
 891         return NO;
 892
 893     return impl->acceptsFirstResponder(self, _cmd);
 894 }
 895
 896 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 897 {
 898     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 899     if (impl == NULL)
 900         return NO;
 901
 902     return impl->becomeFirstResponder(self, _cmd);
 903 }
 904
 905 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 906 {
 907     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 908     if (impl == NULL)
 909         return NO;
 910
 911     return impl->resignFirstResponder(self, _cmd);
 912 }
 913
 914 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 915 {
 916     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 917     if (impl == NULL)
 918         return NO;
 919
 920     return impl->isFlipped(self, _cmd) ? YES:NO;
 921 }
 922
 923 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 924
 925 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 926 {
 927     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 928     if (impl == NULL)
 929         return;
 930
 931 #if wxUSE_THREADS
 932     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 933     // dialog. This causes a drawRect of the active dialog from outside the
 934     // main UI thread. This causes an occasional crash since the wx drawing
 935     // objects (like wxPen) are not thread safe.
 936     //
 937     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 938     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 939     if ( !wxThread::IsMain() )
 940     {
 941         if ( impl->IsUserPane() )
 942         {
 943             wxWindow* win = impl->GetWXPeer();
 944             if ( win->UseBgCol() )
 945             {
 946
 947                 CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 948                 CGContextSaveGState( context );
 949
 950                 CGContextSetFillColorWithColor( context, win->GetBackgroundColour().GetCGColor());
 951                 CGRect r = CGRectMake(rect.origin.x, rect.origin.y, rect.size.width, rect.size.height);
 952                 CGContextFillRect( context, r );
 953
 954                 CGContextRestoreGState( context );
 955             }
 956         }
 957         else
 958         {
 959             // just call the superclass handler, we don't need any custom wx drawing
 960             // here and it seems to work fine:
 961             wxOSX_DrawRectHandlerPtr
 962             superimpl = (wxOSX_DrawRectHandlerPtr)
 963             [[self superclass] instanceMethodForSelector:_cmd];
 964             superimpl(self, _cmd, rect);
 965         }
 966
 967       return;
 968     }
 969 #endif // wxUSE_THREADS
 970
 971     return impl->drawRect(&rect, self, _cmd);
 972 }
 973
 974 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 975 {
 976     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 977     if (impl == NULL)
 978         return;
 979
 980     impl->controlAction(self, _cmd, sender);
 981 }
 982
 983 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 984 {
 985     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 986     if (impl == NULL)
 987         return;
 988
 989     impl->controlDoubleAction(self, _cmd, sender);
 990 }
 991
 992 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 993 {
 994     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 995     NSPasteboard *pboard = [sender draggingPasteboard];
 996     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 997
 998     wxWindow* wxpeer = GetWXPeer();
 999     if ( wxpeer == NULL )
1000         return NSDragOperationNone;
1001
1002     wxDropTarget* target = wxpeer->GetDropTarget();
1003     if ( target == NULL )
1004         return NSDragOperationNone;
1005
1006     wxDragResult result = wxDragNone;
1007     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1008     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1009
1010     if ( sourceDragMask & NSDragOperationLink )
1011         result = wxDragLink;
1012     else if ( sourceDragMask & NSDragOperationCopy )
1013         result = wxDragCopy;
1014     else if ( sourceDragMask & NSDragOperationMove )
1015         result = wxDragMove;
1016
1017     PasteboardRef pboardRef;
1018     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1019     target->SetCurrentDragPasteboard(pboardRef);
1020     result = target->OnEnter(pt.x, pt.y, result);
1021     CFRelease(pboardRef);
1022
1023     NSDragOperation nsresult = NSDragOperationNone;
1024     switch (result )
1025     {
1026         case wxDragLink:
1027             nsresult = NSDragOperationLink;
1028         case wxDragMove:
1029             nsresult = NSDragOperationMove;
1030         case wxDragCopy:
1031             nsresult = NSDragOperationCopy;
1032         default :
1033             break;
1034     }
1035     return nsresult;
1036 }
1037
1038 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1039 {
1040     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1041     NSPasteboard *pboard = [sender draggingPasteboard];
1042
1043     wxWindow* wxpeer = GetWXPeer();
1044     if ( wxpeer == NULL )
1045         return;
1046
1047     wxDropTarget* target = wxpeer->GetDropTarget();
1048     if ( target == NULL )
1049         return;
1050
1051     PasteboardRef pboardRef;
1052     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1053     target->SetCurrentDragPasteboard(pboardRef);
1054     target->OnLeave();
1055     CFRelease(pboardRef);
1056  }
1057
1058 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1059 {
1060     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1061     NSPasteboard *pboard = [sender draggingPasteboard];
1062     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1063
1064     wxWindow* wxpeer = GetWXPeer();
1065     if ( wxpeer == NULL )
1066         return NSDragOperationNone;
1067
1068     wxDropTarget* target = wxpeer->GetDropTarget();
1069     if ( target == NULL )
1070         return NSDragOperationNone;
1071
1072     wxDragResult result = wxDragNone;
1073     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1074     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1075
1076     if ( sourceDragMask & NSDragOperationLink )
1077         result = wxDragLink;
1078     else if ( sourceDragMask & NSDragOperationCopy )
1079         result = wxDragCopy;
1080     else if ( sourceDragMask & NSDragOperationMove )
1081         result = wxDragMove;
1082
1083     PasteboardRef pboardRef;
1084     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1085     target->SetCurrentDragPasteboard(pboardRef);
1086     result = target->OnDragOver(pt.x, pt.y, result);
1087     CFRelease(pboardRef);
1088
1089     NSDragOperation nsresult = NSDragOperationNone;
1090     switch (result )
1091     {
1092         case wxDragLink:
1093             nsresult = NSDragOperationLink;
1094         case wxDragMove:
1095             nsresult = NSDragOperationMove;
1096         case wxDragCopy:
1097             nsresult = NSDragOperationCopy;
1098         default :
1099             break;
1100     }
1101     return nsresult;
1102 }
1103
1104 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1105 {
1106     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1107
1108     NSPasteboard *pboard = [sender draggingPasteboard];
1109     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1110
1111     wxWindow* wxpeer = GetWXPeer();
1112     wxDropTarget* target = wxpeer->GetDropTarget();
1113     wxDragResult result = wxDragNone;
1114     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1115     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1116
1117     if ( sourceDragMask & NSDragOperationLink )
1118         result = wxDragLink;
1119     else if ( sourceDragMask & NSDragOperationCopy )
1120         result = wxDragCopy;
1121     else if ( sourceDragMask & NSDragOperationMove )
1122         result = wxDragMove;
1123
1124     PasteboardRef pboardRef;
1125     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1126     target->SetCurrentDragPasteboard(pboardRef);
1127
1128     if (target->OnDrop(pt.x, pt.y))
1129         result = target->OnData(pt.x, pt.y, result);
1130
1131     CFRelease(pboardRef);
1132
1133     return result != wxDragNone;
1134 }
1135
1136 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
1137 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1138 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1139 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
1140
1141 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1142 {
1143     if ( !DoHandleMouseEvent(event) )
1144     {
1145         // for plain NSView mouse events would propagate to parents otherwise
1146         if (!IsUserPane())
1147         {
1148             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1149             superimpl(slf, (SEL)_cmd, event);
1150
1151             // super of built-ins keeps the mouse up, as wx expects this event, we have to synthesize it
1152
1153             if ( [ event type]  == NSLeftMouseDown )
1154             {
1155                 wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
1156                 SetupMouseEvent(wxevent , event) ;
1157                 wxevent.SetEventType(wxEVT_LEFT_UP);
1158
1159                 GetWXPeer()->HandleWindowEvent(wxevent);
1160             }
1161         }
1162     }
1163 }
1164
1165 void wxWidgetCocoaImpl::cursorUpdate(WX_NSEvent event, WXWidget slf, void *_cmd)
1166 {
1167     NSCursor *cursor = (NSCursor*)GetWXPeer()->GetCursor().GetHCURSOR();
1168     if (cursor == NULL)
1169     {
1170         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1171         superimpl(slf, (SEL)_cmd, event);
1172     }
1173     else
1174     {
1175         [cursor set];
1176     }
1177 }
1178
1179
1180
1181 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1182 {
1183     if ( [event type] == NSKeyDown )
1184     {
1185         // there are key equivalents that are not command-combos and therefore not handled by cocoa automatically,
1186         // therefore we call the menubar directly here, exit if the menu is handling the shortcut
1187         if ( [[[NSApplication sharedApplication] mainMenu] performKeyEquivalent:event] )
1188             return;
1189
1190         m_lastKeyDownEvent = event;
1191     }
1192
1193     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1194     {
1195         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1196         superimpl(slf, (SEL)_cmd, event);
1197     }
1198     m_lastKeyDownEvent = NULL;
1199 }
1200
1201 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1202 {
1203     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1204     {
1205         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1206         superimpl(slf, (SEL)_cmd, text);
1207     }
1208 }
1209
1210
1211 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1212 {
1213     bool handled = false;
1214
1215     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1216     SetupKeyEvent( wxevent, event );
1217
1218     // because performKeyEquivalent is going up the entire view hierarchy, we don't have to
1219     // walk up the ancestors ourselves but let cocoa do it
1220
1221     int command = m_wxPeer->GetAcceleratorTable()->GetCommand( wxevent );
1222     if (command != -1)
1223     {
1224         wxEvtHandler * const handler = m_wxPeer->GetEventHandler();
1225
1226         wxCommandEvent command_event( wxEVT_COMMAND_MENU_SELECTED, command );
1227         command_event.SetEventObject( wxevent.GetEventObject() );
1228         handled = handler->ProcessEvent( command_event );
1229
1230         if ( !handled )
1231         {
1232             // accelerators can also be used with buttons, try them too
1233             command_event.SetEventType(wxEVT_COMMAND_BUTTON_CLICKED);
1234             handled = handler->ProcessEvent( command_event );
1235         }
1236     }
1237
1238     if ( !handled )
1239     {
1240         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1241         return superimpl(slf, (SEL)_cmd, event);
1242     }
1243     return YES;
1244 }
1245
1246 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1247 {
1248     if ( IsUserPane() )
1249         return m_wxPeer->AcceptsFocus();
1250     else
1251     {
1252         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1253         return superimpl(slf, (SEL)_cmd);
1254     }
1255 }
1256
1257 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1258 {
1259     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1260     // get the current focus before running becomeFirstResponder
1261     NSView* otherView = FindFocus();
1262
1263     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1264     BOOL r = superimpl(slf, (SEL)_cmd);
1265     if ( r )
1266     {
1267         DoNotifyFocusEvent( true, otherWindow );
1268     }
1269
1270     return r;
1271 }
1272
1273 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1274 {
1275     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1276     BOOL r = superimpl(slf, (SEL)_cmd);
1277     // get the current focus after running resignFirstResponder
1278     // note that this value isn't reliable, it might return the same view that
1279     // is resigning
1280     NSView* otherView = FindFocus();
1281     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1282
1283     // It doesn't make sense to notify about the loss of focus if we're not
1284     // really losing it and the window which has just gained focus is the same
1285     // one as this window itself. Of course, this should never happen in the
1286     // first place but somehow it does in wxGrid code and without this check we
1287     // enter into an infinite recursion, see #12267.
1288     if ( otherWindow == this )
1289         return r;
1290
1291     // NSTextViews have an editor as true responder, therefore the might get the
1292     // resign notification if their editor takes over, don't trigger any event then
1293     if ( r && !m_hasEditor)
1294     {
1295         DoNotifyFocusEvent( false, otherWindow );
1296     }
1297     return r;
1298 }
1299
1300 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1301 {
1302     return m_isFlipped;
1303 }
1304
1305
1306 #define OSX_DEBUG_DRAWING 0
1307
1308 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1309 {
1310     // preparing the update region
1311
1312     wxRegion updateRgn;
1313     const NSRect *rects;
1314     NSInteger count;
1315
1316     [slf getRectsBeingDrawn:&rects count:&count];
1317     for ( int i = 0 ; i < count ; ++i )
1318     {
1319         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1320     }
1321
1322     wxWindow* wxpeer = GetWXPeer();
1323
1324     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1325     {
1326         // as this update region is in native window locals we must adapt it to wx window local
1327         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1328     }
1329
1330     // Restrict the update region to the shape of the window, if any, and also
1331     // remember the region that we need to clear later.
1332     wxNonOwnedWindow* const tlwParent = wxpeer->MacGetTopLevelWindow();
1333     const bool isTopLevel = tlwParent == wxpeer;
1334     wxRegion clearRgn;
1335     if ( tlwParent->GetWindowStyle() & wxFRAME_SHAPED )
1336     {
1337         if ( isTopLevel )
1338             clearRgn = updateRgn;
1339
1340         int xoffset = 0, yoffset = 0;
1341         wxRegion rgn = tlwParent->GetShape();
1342         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1343         rgn.Offset( xoffset, yoffset );
1344         updateRgn.Intersect(rgn);
1345
1346         if ( isTopLevel )
1347         {
1348             // Exclude the window shape from the region to be cleared below.
1349             rgn.Xor(wxpeer->GetSize());
1350             clearRgn.Intersect(rgn);
1351         }
1352     }
1353
1354     wxpeer->GetUpdateRegion() = updateRgn;
1355
1356     // setting up the drawing context
1357
1358     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1359     CGContextSaveGState( context );
1360
1361 #if OSX_DEBUG_DRAWING
1362     CGContextBeginPath( context );
1363     CGContextMoveToPoint(context, 0, 0);
1364     NSRect bounds = [slf bounds];
1365     CGContextAddLineToPoint(context, 10, 0);
1366     CGContextMoveToPoint(context, 0, 0);
1367     CGContextAddLineToPoint(context, 0, 10);
1368     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1369     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1370     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1371     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1372     CGContextClosePath( context );
1373     CGContextStrokePath(context);
1374 #endif
1375
1376     if ( !m_isFlipped )
1377     {
1378         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1379         CGContextScaleCTM( context, 1, -1 );
1380     }
1381
1382     wxpeer->MacSetCGContextRef( context );
1383
1384     bool handled = wxpeer->MacDoRedraw( 0 );
1385     CGContextRestoreGState( context );
1386
1387     CGContextSaveGState( context );
1388     if ( !handled )
1389     {
1390         // call super
1391         SEL _cmd = @selector(drawRect:);
1392         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1393         superimpl(slf, _cmd, *(NSRect*)rect);
1394         CGContextRestoreGState( context );
1395         CGContextSaveGState( context );
1396     }
1397     // as we called restore above, we have to flip again if necessary
1398     if ( !m_isFlipped )
1399     {
1400         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1401         CGContextScaleCTM( context, 1, -1 );
1402     }
1403
1404     if ( isTopLevel )
1405     {
1406         // We also need to explicitly draw the part of the top level window
1407         // outside of its region with transparent colour to ensure that it is
1408         // really transparent.
1409         if ( clearRgn.IsOk() )
1410         {
1411             wxMacCGContextStateSaver saveState(context);
1412             wxWindowDC dc(wxpeer);
1413             dc.SetBackground(wxBrush(wxTransparentColour));
1414             dc.SetDeviceClippingRegion(clearRgn);
1415             dc.Clear();
1416         }
1417
1418 #if wxUSE_GRAPHICS_CONTEXT
1419         // If the window shape is defined by a path, stroke the path to show
1420         // the window border.
1421         const wxGraphicsPath& path = tlwParent->GetShapePath();
1422         if ( !path.IsNull() )
1423         {
1424             CGContextSetLineWidth(context, 1);
1425             CGContextSetStrokeColorWithColor(context, wxLIGHT_GREY->GetCGColor());
1426             CGContextAddPath(context, (CGPathRef) path.GetNativePath());
1427             CGContextStrokePath(context);
1428         }
1429 #endif // wxUSE_GRAPHICS_CONTEXT
1430     }
1431
1432     wxpeer->MacPaintChildrenBorders();
1433     wxpeer->MacSetCGContextRef( NULL );
1434     CGContextRestoreGState( context );
1435 }
1436
1437 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1438 {
1439     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1440     if ( wxpeer )
1441         wxpeer->OSXHandleClicked(0);
1442 }
1443
1444 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1445 {
1446 }
1447
1448 void wxWidgetCocoaImpl::controlTextDidChange()
1449 {
1450     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1451     if ( wxpeer )
1452     {
1453         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1454         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1455         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1456         if ( tc )
1457             tc->SendTextUpdatedEventIfAllowed();
1458         else if ( cb )
1459             cb->SendTextUpdatedEventIfAllowed();
1460         else
1461         {
1462             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1463         }
1464     }
1465 }
1466
1467 //
1468
1469 #if OBJC_API_VERSION >= 2
1470
1471 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1472     class_addMethod(c, s, i, t );
1473
1474 #else
1475
1476 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1477     { s, (char*) t, i },
1478
1479 #endif
1480
1481 void wxOSXCocoaClassAddWXMethods(Class c)
1482 {
1483
1484 #if OBJC_API_VERSION < 2
1485     static objc_method wxmethods[] =
1486     {
1487 #endif
1488
1489     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1490     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1491     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1492
1493     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1494     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1495     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1496
1497     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1498
1499     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1500     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1501     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1502
1503     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1504
1505     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1506     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1507     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1508
1509     wxOSX_CLASS_ADD_METHOD(c, @selector(cursorUpdate:), (IMP) wxOSX_cursorUpdate, "v@:@" )
1510
1511     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1512     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1513     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1514
1515     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1516
1517     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1518
1519     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1520     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1521     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1522
1523     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1524     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1525
1526     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1527     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1528
1529 #if wxUSE_DRAG_AND_DROP
1530     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1531     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1532     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1533     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1534 #endif
1535
1536 #if OBJC_API_VERSION < 2
1537     } ;
1538     static int method_count = WXSIZEOF( wxmethods );
1539     static objc_method_list *wxmethodlist = NULL;
1540     if ( wxmethodlist == NULL )
1541     {
1542         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1543         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1544         wxmethodlist->method_count = method_count;
1545         wxmethodlist->obsolete = 0;
1546     }
1547     class_addMethods( c, wxmethodlist );
1548 #endif
1549 }
1550
1551 //
1552 // C++ implementation class
1553 //
1554
1555 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1556
1557 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl, bool isUserPane ) :
1558     wxWidgetImpl( peer, isRootControl, isUserPane )
1559 {
1560     Init();
1561     m_osxView = w;
1562
1563     // check if the user wants to create the control initially hidden
1564     if ( !peer->IsShown() )
1565         SetVisibility(false);
1566
1567     // gc aware handling
1568     if ( m_osxView )
1569         CFRetain(m_osxView);
1570     [m_osxView release];
1571 }
1572
1573 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1574 {
1575     Init();
1576 }
1577
1578 void wxWidgetCocoaImpl::Init()
1579 {
1580     m_osxView = NULL;
1581     m_isFlipped = true;
1582     m_lastKeyDownEvent = NULL;
1583     m_hasEditor = false;
1584 }
1585
1586 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1587 {
1588     RemoveAssociations( this );
1589
1590     if ( !IsRootControl() )
1591     {
1592         NSView *sv = [m_osxView superview];
1593         if ( sv != nil )
1594             [m_osxView removeFromSuperview];
1595     }
1596     // gc aware handling
1597     if ( m_osxView )
1598         CFRelease(m_osxView);
1599 }
1600
1601 bool wxWidgetCocoaImpl::IsVisible() const
1602 {
1603     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1604 }
1605
1606 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1607 {
1608     [m_osxView setHidden:(visible ? NO:YES)];
1609 }
1610
1611 // ----------------------------------------------------------------------------
1612 // window animation stuff
1613 // ----------------------------------------------------------------------------
1614
1615 // define a delegate used to refresh the window during animation
1616 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1617 {
1618     wxWindow *m_win;
1619     bool m_isDone;
1620 }
1621
1622 - (id)init:(wxWindow *)win;
1623
1624 - (bool)isDone;
1625
1626 // NSAnimationDelegate methods
1627 - (void)animationDidEnd:(NSAnimation*)animation;
1628 - (void)animation:(NSAnimation*)animation
1629         didReachProgressMark:(NSAnimationProgress)progress;
1630 @end
1631
1632 @implementation wxNSAnimationDelegate
1633
1634 - (id)init:(wxWindow *)win
1635 {
1636     self = [super init];
1637
1638     m_win = win;
1639     m_isDone = false;
1640
1641     return self;
1642 }
1643
1644 - (bool)isDone
1645 {
1646     return m_isDone;
1647 }
1648
1649 - (void)animation:(NSAnimation*)animation
1650         didReachProgressMark:(NSAnimationProgress)progress
1651 {
1652     wxUnusedVar(animation);
1653     wxUnusedVar(progress);
1654
1655     m_win->SendSizeEvent();
1656     m_win->MacOnInternalSize();
1657 }
1658
1659 - (void)animationDidEnd:(NSAnimation*)animation
1660 {
1661     wxUnusedVar(animation);
1662     m_isDone = true;
1663 }
1664
1665 @end
1666
1667 /* static */
1668 bool
1669 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1670                                               bool show,
1671                                               wxShowEffect effect,
1672                                               unsigned timeout)
1673 {
1674     // create the dictionary describing the animation to perform on this view
1675     NSObject * const
1676         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1677     NSMutableDictionary * const
1678         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1679     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1680
1681     // determine the start and end rectangles assuming we're hiding the window
1682     const wxRect rectOrig = win->GetRect();
1683     wxRect rectStart,
1684            rectEnd;
1685     rectStart =
1686     rectEnd = rectOrig;
1687
1688     if ( show )
1689     {
1690         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1691                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1692             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1693         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1694                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1695             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1696         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1697                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1698             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1699         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1700                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1701             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1702     }
1703
1704     switch ( effect )
1705     {
1706         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1707         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1708             rectEnd.width = 0;
1709             break;
1710
1711         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1712         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1713             rectEnd.x = rectStart.GetRight();
1714             rectEnd.width = 0;
1715             break;
1716
1717         case wxSHOW_EFFECT_ROLL_TO_TOP:
1718         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1719             rectEnd.height = 0;
1720             break;
1721
1722         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1723         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1724             rectEnd.y = rectStart.GetBottom();
1725             rectEnd.height = 0;
1726             break;
1727
1728         case wxSHOW_EFFECT_EXPAND:
1729             rectEnd.x = rectStart.x + rectStart.width / 2;
1730             rectEnd.y = rectStart.y + rectStart.height / 2;
1731             rectEnd.width =
1732             rectEnd.height = 0;
1733             break;
1734
1735         case wxSHOW_EFFECT_BLEND:
1736             [dict setObject:(show ? NSViewAnimationFadeInEffect
1737                                   : NSViewAnimationFadeOutEffect)
1738                   forKey:NSViewAnimationEffectKey];
1739             break;
1740
1741         case wxSHOW_EFFECT_NONE:
1742         case wxSHOW_EFFECT_MAX:
1743             wxFAIL_MSG( "unexpected animation effect" );
1744             return false;
1745
1746         default:
1747             wxFAIL_MSG( "unknown animation effect" );
1748             return false;
1749     };
1750
1751     if ( show )
1752     {
1753         // we need to restore it to the original rectangle instead of making it
1754         // disappear
1755         wxSwap(rectStart, rectEnd);
1756
1757         // and as the window is currently hidden, we need to show it for the
1758         // animation to be visible at all (but don't restore it at its full
1759         // rectangle as it shouldn't appear immediately)
1760         win->SetSize(rectStart);
1761         win->Show();
1762     }
1763
1764     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1765                                     ? [(NSView *)viewOrWin superview]
1766                                     : nil;
1767     const NSRect rStart = wxToNSRect(parentView, rectStart);
1768     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1769
1770     [dict setObject:[NSValue valueWithRect:rStart]
1771           forKey:NSViewAnimationStartFrameKey];
1772     [dict setObject:[NSValue valueWithRect:rEnd]
1773           forKey:NSViewAnimationEndFrameKey];
1774
1775     // create an animation using the values in the above dictionary
1776     NSViewAnimation * const
1777         anim = [[NSViewAnimation alloc]
1778                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1779
1780     if ( !timeout )
1781     {
1782         // what is a good default duration? Windows uses 200ms, Web frameworks
1783         // use anything from 250ms to 1s... choose something in the middle
1784         timeout = 500;
1785     }
1786
1787     [anim setDuration:timeout/1000.];   // duration is in seconds here
1788
1789     // if the window being animated changes its layout depending on its size
1790     // (which is almost always the case) we need to redo it during animation
1791     //
1792     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1793     // controls in wxInfoBar visibly jump around)
1794     const int NUM_LAYOUTS = 20;
1795     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1796         [anim addProgressMark:f];
1797
1798     wxNSAnimationDelegate * const
1799         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1800     [anim setDelegate:animDelegate];
1801     [anim startAnimation];
1802
1803     // Cocoa is capable of doing animation asynchronously or even from separate
1804     // thread but wx API doesn't provide any way to be notified about the
1805     // animation end and without this we really must ensure that the window has
1806     // the expected (i.e. the same as if a simple Show() had been used) size
1807     // when we return, so block here until the animation finishes
1808     //
1809     // notice that because the default animation mode is NSAnimationBlocking,
1810     // no user input events ought to be processed from here
1811     {
1812         wxEventLoopGuarantor ensureEventLoopExistence;
1813         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1814         while ( ![animDelegate isDone] )
1815             loop->Dispatch();
1816     }
1817
1818     if ( !show )
1819     {
1820         // NSViewAnimation is smart enough to hide the NSView being animated at
1821         // the end but we also must ensure that it's hidden for wx too
1822         win->Hide();
1823
1824         // and we must also restore its size because it isn't expected to
1825         // change just because the window was hidden
1826         win->SetSize(rectOrig);
1827     }
1828     else
1829     {
1830         // refresh it once again after the end to ensure that everything is in
1831         // place
1832         win->SendSizeEvent();
1833         win->MacOnInternalSize();
1834     }
1835
1836     [anim setDelegate:nil];
1837     [animDelegate release];
1838     [anim release];
1839
1840     return true;
1841 }
1842
1843 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1844                                        wxShowEffect effect,
1845                                        unsigned timeout)
1846 {
1847     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1848 }
1849
1850 /* note that the drawing order between siblings is not defined under 10.4 */
1851 /* only starting from 10.5 the subview order is respected */
1852
1853 /* NSComparisonResult is typedef'd as an enum pre-Leopard but typedef'd as
1854  * NSInteger post-Leopard.  Pre-Leopard the Cocoa toolkit expects a function
1855  * returning int and not NSComparisonResult.  Post-Leopard the Cocoa toolkit
1856  * expects a function returning the new non-enum NSComparsionResult.
1857  * Hence we create a typedef named CocoaWindowCompareFunctionResult.
1858  */
1859 #if defined(NSINTEGER_DEFINED)
1860 typedef NSComparisonResult CocoaWindowCompareFunctionResult;
1861 #else
1862 typedef int CocoaWindowCompareFunctionResult;
1863 #endif
1864
1865 class CocoaWindowCompareContext
1866 {
1867     wxDECLARE_NO_COPY_CLASS(CocoaWindowCompareContext);
1868 public:
1869     CocoaWindowCompareContext(); // Not implemented
1870     CocoaWindowCompareContext(NSView *target, NSArray *subviews)
1871     {
1872         m_target = target;
1873         // Cocoa sorts subviews in-place.. make a copy
1874         m_subviews = [subviews copy];
1875     }
1876
1877     ~CocoaWindowCompareContext()
1878     {   // release the copy
1879         [m_subviews release];
1880     }
1881     NSView* target()
1882     {   return m_target; }
1883
1884     NSArray* subviews()
1885     {   return m_subviews; }
1886
1887     /* Helper function that returns the comparison based off of the original ordering */
1888     CocoaWindowCompareFunctionResult CompareUsingOriginalOrdering(id first, id second)
1889     {
1890         NSUInteger firstI = [m_subviews indexOfObjectIdenticalTo:first];
1891         NSUInteger secondI = [m_subviews indexOfObjectIdenticalTo:second];
1892         // NOTE: If either firstI or secondI is NSNotFound then it will be NSIntegerMax and thus will
1893         // likely compare higher than the other view which is reasonable considering the only way that
1894         // can happen is if the subview was added after our call to subviews but before the call to
1895         // sortSubviewsUsingFunction:context:.  Thus we don't bother checking.  Particularly because
1896         // that case should never occur anyway because that would imply a multi-threaded GUI call
1897         // which is a big no-no with Cocoa.
1898
1899         // Subviews are ordered from back to front meaning one that is already lower will have an lower index.
1900         NSComparisonResult result = (firstI < secondI)
1901                 ?   NSOrderedAscending /* -1 */
1902                 :   (firstI > secondI)
1903                 ?   NSOrderedDescending /* 1 */
1904                 :   NSOrderedSame /* 0 */;
1905
1906         return result;
1907     }
1908 private:
1909     /* The subview we are trying to Raise or Lower */
1910     NSView *m_target;
1911     /* A copy of the original array of subviews */
1912     NSArray *m_subviews;
1913 };
1914
1915 /* Causes Cocoa to raise the target view to the top of the Z-Order by telling the sort function that
1916  * the target view is always higher than every other view.  When comparing two views neither of
1917  * which is the target, it returns the correct response based on the original ordering
1918  */
1919 static CocoaWindowCompareFunctionResult CocoaRaiseWindowCompareFunction(id first, id second, void *ctx)
1920 {
1921     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
1922     // first should be ordered higher
1923     if(first==compareContext->target())
1924         return NSOrderedDescending;
1925     // second should be ordered higher
1926     if(second==compareContext->target())
1927         return NSOrderedAscending;
1928     return compareContext->CompareUsingOriginalOrdering(first,second);
1929 }
1930
1931 void wxWidgetCocoaImpl::Raise()
1932 {
1933         NSView* nsview = m_osxView;
1934
1935     NSView *superview = [nsview superview];
1936     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
1937
1938     [superview sortSubviewsUsingFunction:
1939          CocoaRaiseWindowCompareFunction
1940                                                                  context: &compareContext];
1941
1942 }
1943
1944 /* Causes Cocoa to lower the target view to the bottom of the Z-Order by telling the sort function that
1945  * the target view is always lower than every other view.  When comparing two views neither of
1946  * which is the target, it returns the correct response based on the original ordering
1947  */
1948 static CocoaWindowCompareFunctionResult CocoaLowerWindowCompareFunction(id first, id second, void *ctx)
1949 {
1950     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
1951     // first should be ordered lower
1952     if(first==compareContext->target())
1953         return NSOrderedAscending;
1954     // second should be ordered lower
1955     if(second==compareContext->target())
1956         return NSOrderedDescending;
1957     return compareContext->CompareUsingOriginalOrdering(first,second);
1958 }
1959
1960 void wxWidgetCocoaImpl::Lower()
1961 {
1962         NSView* nsview = m_osxView;
1963
1964     NSView *superview = [nsview superview];
1965     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
1966
1967     [superview sortSubviewsUsingFunction:
1968          CocoaLowerWindowCompareFunction
1969                                                                  context: &compareContext];
1970 }
1971
1972 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1973 {
1974 #if 1
1975     SetNeedsDisplay() ;
1976 #else
1977     // We should do something like this, but it wasn't working in 10.4.
1978     if (GetNeedsDisplay() )
1979     {
1980         SetNeedsDisplay() ;
1981     }
1982     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1983     NSSize offset = NSMakeSize((float)dx, (float)dy);
1984     [m_osxView scrollRect:r by:offset];
1985 #endif
1986 }
1987
1988 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1989 {
1990     wxWindowMac* parent = GetWXPeer()->GetParent();
1991     // under Cocoa we might have a contentView in the wxParent to which we have to
1992     // adjust the coordinates
1993     if (parent && [m_osxView superview] != parent->GetHandle() )
1994     {
1995         int cx = 0,cy = 0,cw = 0,ch = 0;
1996         if ( parent->GetPeer() )
1997         {
1998             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1999             x -= cx;
2000             y -= cy;
2001         }
2002     }
2003     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
2004     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
2005     [m_osxView setFrame:r];
2006     [[m_osxView superview] setNeedsDisplayInRect:r];
2007 }
2008
2009 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
2010 {
2011     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
2012     x = r.GetLeft();
2013     y = r.GetTop();
2014
2015     // under Cocoa we might have a contentView in the wxParent to which we have to
2016     // adjust the coordinates
2017     wxWindowMac* parent = GetWXPeer()->GetParent();
2018     if (parent && [m_osxView superview] != parent->GetHandle() )
2019     {
2020         int cx = 0,cy = 0,cw = 0,ch = 0;
2021         if ( parent->GetPeer() )
2022         {
2023             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2024             x += cx;
2025             y += cy;
2026         }
2027     }
2028 }
2029
2030 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
2031 {
2032     NSRect rect = [m_osxView frame];
2033     width = (int)rect.size.width;
2034     height = (int)rect.size.height;
2035 }
2036
2037 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
2038 {
2039     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
2040     {
2041         NSView* cv = [m_osxView contentView];
2042
2043         NSRect bounds = [m_osxView bounds];
2044         NSRect rect = [cv frame];
2045
2046         int y = (int)rect.origin.y;
2047         int x = (int)rect.origin.x;
2048         if ( ![ m_osxView isFlipped ] )
2049             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
2050         left = x;
2051         top = y;
2052         width = (int)rect.size.width;
2053         height = (int)rect.size.height;
2054     }
2055     else
2056     {
2057         left = top = 0;
2058         GetSize( width, height );
2059     }
2060 }
2061
2062 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
2063 {
2064     if ( where )
2065         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
2066     else
2067         [m_osxView setNeedsDisplay:YES];
2068 }
2069
2070 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
2071 {
2072     return [m_osxView needsDisplay];
2073 }
2074
2075 bool wxWidgetCocoaImpl::CanFocus() const
2076 {
2077     return [m_osxView canBecomeKeyView] == YES;
2078 }
2079
2080 bool wxWidgetCocoaImpl::HasFocus() const
2081 {
2082     return ( FindFocus() == m_osxView );
2083 }
2084
2085 bool wxWidgetCocoaImpl::SetFocus()
2086 {
2087     if ( !CanFocus() )
2088         return false;
2089
2090     // TODO remove if no issues arise: should not raise the window, only assign focus
2091     //[[m_osxView window] makeKeyAndOrderFront:nil] ;
2092     [[m_osxView window] makeFirstResponder: m_osxView] ;
2093     return true;
2094 }
2095
2096 void wxWidgetCocoaImpl::SetDropTarget(wxDropTarget* target)
2097 {
2098     [m_osxView unregisterDraggedTypes];
2099
2100     if ( target == NULL )
2101         return;
2102
2103     wxDataObject* dobj = target->GetDataObject();
2104
2105     if( dobj )
2106     {
2107         CFMutableArrayRef typesarray = CFArrayCreateMutable(kCFAllocatorDefault,0,&kCFTypeArrayCallBacks);
2108         dobj->AddSupportedTypes(typesarray);
2109         NSView* targetView = m_osxView;
2110         if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2111             targetView = [(NSScrollView*) m_osxView documentView];
2112
2113         [targetView registerForDraggedTypes:(NSArray*)typesarray];
2114         CFRelease(typesarray);
2115     }
2116 }
2117
2118 void wxWidgetCocoaImpl::RemoveFromParent()
2119 {
2120     [m_osxView removeFromSuperview];
2121 }
2122
2123 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
2124 {
2125     NSView* container = parent->GetWXWidget() ;
2126     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
2127     [container addSubview:m_osxView];
2128
2129     if( m_wxPeer->IsFrozen() )
2130         [[m_osxView window] disableFlushWindow];
2131 }
2132
2133 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
2134 {
2135     NSView* targetView = m_osxView;
2136     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2137         targetView = [(NSScrollView*) m_osxView documentView];
2138
2139     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
2140     {
2141         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2142                                                                 green:(CGFloat) (col.Green() / 255.0)
2143                                                                  blue:(CGFloat) (col.Blue() / 255.0)
2144                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
2145     }
2146 }
2147
2148 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
2149 {
2150     BOOL opaque = ( style == wxBG_STYLE_PAINT );
2151
2152     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
2153     {
2154         [m_osxView setOpaque: opaque];
2155     }
2156
2157     return true ;
2158 }
2159
2160 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
2161 {
2162     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
2163     {
2164         wxCFStringRef cf( title , encoding );
2165         [m_osxView setTitle:cf.AsNSString()];
2166     }
2167     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
2168     {
2169         wxCFStringRef cf( title , encoding );
2170         [m_osxView setStringValue:cf.AsNSString()];
2171     }
2172 }
2173
2174
2175 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
2176 {
2177     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
2178     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
2179     *pt = wxFromNSPoint( to->GetWXWidget(), p );
2180 }
2181
2182 wxInt32 wxWidgetCocoaImpl::GetValue() const
2183 {
2184     return [(NSControl*)m_osxView intValue];
2185 }
2186
2187 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
2188 {
2189     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
2190     {
2191         [m_osxView setIntValue:v];
2192     }
2193     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
2194     {
2195         [m_osxView setFloatValue:(double)v];
2196     }
2197     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
2198     {
2199         [m_osxView setDoubleValue:(double)v];
2200     }
2201 }
2202
2203 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
2204 {
2205     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
2206     {
2207         [m_osxView setMinValue:(double)v];
2208     }
2209 }
2210
2211 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
2212 {
2213     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
2214     {
2215         [m_osxView setMaxValue:(double)v];
2216     }
2217 }
2218
2219 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
2220 {
2221     if (  [m_osxView respondsToSelector:@selector(minValue)] )
2222     {
2223         return (int)[m_osxView minValue];
2224     }
2225     return 0;
2226 }
2227
2228 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
2229 {
2230     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
2231     {
2232         return (int)[m_osxView maxValue];
2233     }
2234     return 0;
2235 }
2236
2237 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
2238 {
2239     wxBitmap bmp;
2240
2241     // TODO: how to create a wxBitmap from NSImage?
2242 #if 0
2243     if ( [m_osxView respondsToSelector:@selector(image:)] )
2244         bmp = [m_osxView image];
2245 #endif
2246
2247     return bmp;
2248 }
2249
2250 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
2251 {
2252     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
2253     {
2254         if (bitmap.IsOk())
2255             [m_osxView setImage:bitmap.GetNSImage()];
2256         else
2257             [m_osxView setImage:nil];
2258
2259         [m_osxView setNeedsDisplay:YES];
2260     }
2261 }
2262
2263 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
2264 {
2265     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
2266     {
2267         NSCellImagePosition pos;
2268         switch ( dir )
2269         {
2270             case wxLEFT:
2271                 pos = NSImageLeft;
2272                 break;
2273
2274             case wxRIGHT:
2275                 pos = NSImageRight;
2276                 break;
2277
2278             case wxTOP:
2279                 pos = NSImageAbove;
2280                 break;
2281
2282             case wxBOTTOM:
2283                 pos = NSImageBelow;
2284                 break;
2285
2286             default:
2287                 wxFAIL_MSG( "invalid image position" );
2288                 pos = NSNoImage;
2289         }
2290
2291         [m_osxView setImagePosition:pos];
2292     }
2293 }
2294
2295 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
2296 {
2297     // implementation in subclass
2298 }
2299
2300 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
2301 {
2302     r->x = r->y = r->width = r->height = 0;
2303
2304     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
2305     {
2306         NSRect former = [m_osxView frame];
2307         [m_osxView sizeToFit];
2308         NSRect best = [m_osxView frame];
2309         [m_osxView setFrame:former];
2310         r->width = (int)best.size.width;
2311         r->height = (int)best.size.height;
2312     }
2313 }
2314
2315 bool wxWidgetCocoaImpl::IsEnabled() const
2316 {
2317     NSView* targetView = m_osxView;
2318     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2319         targetView = [(NSScrollView*) m_osxView documentView];
2320
2321     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
2322         return [targetView isEnabled];
2323     return true;
2324 }
2325
2326 void wxWidgetCocoaImpl::Enable( bool enable )
2327 {
2328     NSView* targetView = m_osxView;
2329     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2330         targetView = [(NSScrollView*) m_osxView documentView];
2331
2332     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
2333         [targetView setEnabled:enable];
2334 }
2335
2336 void wxWidgetCocoaImpl::PulseGauge()
2337 {
2338 }
2339
2340 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
2341 {
2342 }
2343
2344 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
2345 {
2346     NSControlSize size = NSRegularControlSize;
2347
2348     switch ( variant )
2349     {
2350         case wxWINDOW_VARIANT_NORMAL :
2351             size = NSRegularControlSize;
2352             break ;
2353
2354         case wxWINDOW_VARIANT_SMALL :
2355             size = NSSmallControlSize;
2356             break ;
2357
2358         case wxWINDOW_VARIANT_MINI :
2359             size = NSMiniControlSize;
2360             break ;
2361
2362         case wxWINDOW_VARIANT_LARGE :
2363             size = NSRegularControlSize;
2364             break ;
2365
2366         default:
2367             wxFAIL_MSG(wxT("unexpected window variant"));
2368             break ;
2369     }
2370     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2371         [m_osxView setControlSize:size];
2372     else if ([m_osxView respondsToSelector:@selector(cell)])
2373     {
2374         id cell = [(id)m_osxView cell];
2375         if ([cell respondsToSelector:@selector(setControlSize:)])
2376             [cell setControlSize:size];
2377     }
2378
2379     // we need to propagate this to inner views as well
2380     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2381     {
2382         NSView* targetView = [(NSScrollView*) m_osxView documentView];
2383
2384         if ( [targetView respondsToSelector:@selector(setControlSize:)] )
2385             [targetView setControlSize:size];
2386         else if ([targetView respondsToSelector:@selector(cell)])
2387         {
2388             id cell = [(id)targetView cell];
2389             if ([cell respondsToSelector:@selector(setControlSize:)])
2390                 [cell setControlSize:size];
2391         }
2392     }
2393 }
2394
2395 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2396 {
2397     NSView* targetView = m_osxView;
2398     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2399         targetView = [(NSScrollView*) m_osxView documentView];
2400
2401     if ([targetView respondsToSelector:@selector(setFont:)])
2402         [targetView setFont: font.OSXGetNSFont()];
2403     if ([targetView respondsToSelector:@selector(setTextColor:)])
2404         [targetView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2405                                                                  green:(CGFloat) (col.Green() / 255.0)
2406                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2407                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2408 }
2409
2410 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2411 {
2412     if ( tooltip )
2413     {
2414         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2415         [m_osxView setToolTip: cf.AsNSString()];
2416     }
2417     else
2418     {
2419         [m_osxView setToolTip:nil];
2420     }
2421 }
2422
2423 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2424 {
2425     WXWidget c =  control ? control : (WXWidget) m_osxView;
2426     wxWidgetImpl::Associate( c, this ) ;
2427     if ([c respondsToSelector:@selector(setAction:)])
2428     {
2429         [c setTarget: c];
2430         [c setAction: @selector(controlAction:)];
2431         if ([c respondsToSelector:@selector(setDoubleAction:)])
2432         {
2433             [c setDoubleAction: @selector(controlDoubleAction:)];
2434         }
2435
2436     }
2437     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingCursorUpdate|NSTrackingMouseMoved|NSTrackingActiveAlways|NSTrackingInVisibleRect;
2438         NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: NSZeroRect options: options owner: m_osxView userInfo: nil];
2439     [m_osxView addTrackingArea: area];
2440     [area release];
2441  }
2442
2443 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2444 {
2445     wxKeyEvent wxevent(wxEVT_CHAR);
2446     SetupKeyEvent( wxevent, event, text );
2447
2448     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2449 }
2450
2451 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2452 {
2453     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2454     SetupKeyEvent( wxevent, event );
2455
2456     // Generate wxEVT_CHAR_HOOK before sending any other events but only when
2457     // the key is pressed, not when it's released (the type of wxevent is
2458     // changed by SetupKeyEvent() so it can be wxEVT_KEY_UP too by now).
2459     if ( wxevent.GetEventType() == wxEVT_KEY_DOWN )
2460     {
2461         wxKeyEvent eventHook(wxEVT_CHAR_HOOK, wxevent);
2462         if ( GetWXPeer()->OSXHandleKeyEvent(eventHook)
2463                 && !eventHook.IsNextEventAllowed() )
2464             return true;
2465     }
2466
2467     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2468
2469     // this will fire higher level events, like insertText, to help
2470     // us handle EVT_CHAR, etc.
2471
2472     if ( !result )
2473     {
2474         if ( [event type] == NSKeyDown)
2475         {
2476             long keycode = wxOSXTranslateCocoaKey( event, wxEVT_CHAR );
2477
2478             if ( (keycode > 0 && keycode < WXK_SPACE) || keycode == WXK_DELETE || keycode >= WXK_START )
2479             {
2480                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2481                 wxKeyEvent wxevent2(wxevent) ;
2482                 wxevent2.SetEventType(wxEVT_CHAR);
2483                 SetupKeyEvent( wxevent2, event );
2484                 wxevent2.m_keyCode = keycode;
2485                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2486             }
2487             else if (wxevent.CmdDown())
2488             {
2489                 wxKeyEvent wxevent2(wxevent) ;
2490                 wxevent2.SetEventType(wxEVT_CHAR);
2491                 SetupKeyEvent( wxevent2, event );
2492                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2493             }
2494             else
2495             {
2496                 if ( IsUserPane() && !wxevent.CmdDown() )
2497                 {
2498                     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2499                         [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2500                     else
2501                         [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2502                     result = true;
2503                 }
2504             }
2505         }
2506     }
2507
2508     return result;
2509 }
2510
2511 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2512 {
2513     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2514     SetupMouseEvent(wxevent , event) ;
2515     return GetWXPeer()->HandleWindowEvent(wxevent);
2516 }
2517
2518 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2519 {
2520     wxWindow* thisWindow = GetWXPeer();
2521     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2522     {
2523         thisWindow->MacInvalidateBorders();
2524     }
2525
2526     if ( receivedFocus )
2527     {
2528         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2529         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2530         thisWindow->HandleWindowEvent(eventFocus);
2531
2532 #if wxUSE_CARET
2533         if ( thisWindow->GetCaret() )
2534             thisWindow->GetCaret()->OnSetFocus();
2535 #endif
2536
2537         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2538         event.SetEventObject(thisWindow);
2539         if (otherWindow)
2540             event.SetWindow(otherWindow->GetWXPeer());
2541         thisWindow->HandleWindowEvent(event) ;
2542     }
2543     else // !receivedFocuss
2544     {
2545 #if wxUSE_CARET
2546         if ( thisWindow->GetCaret() )
2547             thisWindow->GetCaret()->OnKillFocus();
2548 #endif
2549
2550         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2551
2552         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2553         event.SetEventObject(thisWindow);
2554         if (otherWindow)
2555             event.SetWindow(otherWindow->GetWXPeer());
2556         thisWindow->HandleWindowEvent(event) ;
2557     }
2558 }
2559
2560 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2561 {
2562     if ( !wxIsBusy() )
2563     {
2564         NSPoint location = [NSEvent mouseLocation];
2565         location = [[m_osxView window] convertScreenToBase:location];
2566         NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2567
2568         if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2569         {
2570             [(NSCursor*)cursor.GetHCURSOR() set];
2571         }
2572     }
2573 }
2574
2575 void wxWidgetCocoaImpl::CaptureMouse()
2576 {
2577     // TODO remove if we don't get into problems with cursor settings
2578     //    [[m_osxView window] disableCursorRects];
2579 }
2580
2581 void wxWidgetCocoaImpl::ReleaseMouse()
2582 {
2583     // TODO remove if we don't get into problems with cursor settings
2584     //    [[m_osxView window] enableCursorRects];
2585 }
2586
2587 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2588 {
2589     m_isFlipped = flipped;
2590 }
2591
2592 void wxWidgetCocoaImpl::SetDrawingEnabled(bool enabled)
2593 {
2594     if ( enabled )
2595     {
2596         [[m_osxView window] enableFlushWindow];
2597         [m_osxView setNeedsDisplay:YES];
2598     }
2599     else
2600     {
2601         [[m_osxView window] disableFlushWindow];
2602     }
2603 }
2604 //
2605 // Factory methods
2606 //
2607
2608 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2609     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2610     long WXUNUSED(style), long WXUNUSED(extraStyle))
2611 {
2612     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2613     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2614
2615     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v, false, true );
2616     return c;
2617 }
2618
2619 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2620 {
2621     NSWindow* tlw = now->GetWXWindow();
2622
2623     wxWidgetCocoaImpl* c = NULL;
2624     if ( now->IsNativeWindowWrapper() )
2625     {
2626         NSView* cv = [tlw contentView];
2627         c = new wxWidgetCocoaImpl( now, cv, true );
2628         // increase ref count, because the impl destructor will decrement it again
2629         CFRetain(cv);
2630         if ( !now->IsShown() )
2631             [cv setHidden:NO];
2632
2633     }
2634     else
2635     {
2636         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2637         c = new wxWidgetCocoaImpl( now, v, true );
2638         c->InstallEventHandler();
2639         [tlw setContentView:v];
2640     }
2641     return c;
2642 }