src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     BOOL _hasToolTip;
  91     NSTrackingRectTag   _lastToolTipTrackTag;
  92     id              _lastToolTipOwner;
  93     void*           _lastUserData;
  94
  95 }
  96
  97 @end // wxNSView
  98
  99 @interface NSView(PossibleMethods)
 100 - (void)setTitle:(NSString *)aString;
 101 - (void)setStringValue:(NSString *)aString;
 102 - (void)setIntValue:(int)anInt;
 103 - (void)setFloatValue:(float)aFloat;
 104 - (void)setDoubleValue:(double)aDouble;
 105
 106 - (double)minValue;
 107 - (double)maxValue;
 108 - (void)setMinValue:(double)aDouble;
 109 - (void)setMaxValue:(double)aDouble;
 110
 111 - (void)sizeToFit;
 112
 113 - (BOOL)isEnabled;
 114 - (void)setEnabled:(BOOL)flag;
 115
 116 - (void)setImage:(NSImage *)image;
 117 - (void)setControlSize:(NSControlSize)size;
 118
 119 - (void)setFont:(NSFont *)fontObject;
 120
 121 - (id)contentView;
 122
 123 - (void)setTarget:(id)anObject;
 124 - (void)setAction:(SEL)aSelector;
 125 - (void)setDoubleAction:(SEL)aSelector;
 126 - (void)setBackgroundColor:(NSColor*)aColor;
 127 - (void)setOpaque:(BOOL)opaque;
 128 - (void)setTextColor:(NSColor *)color;
 129 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 130 @end
 131
 132 // The following code is a combination of the code listed here:
 133 // http://lists.apple.com/archives/cocoa-dev/2008/Apr/msg01582.html
 134 // (which can't be used because KLGetCurrentKeyboardLayout etc aren't 64-bit)
 135 // and the code here:
 136 // http://inquisitivecocoa.com/category/objective-c/
 137 @interface NSEvent (OsGuiUtilsAdditions)
 138 - (NSString*) charactersIgnoringModifiersIncludingShift;
 139 @end
 140
 141 @implementation NSEvent (OsGuiUtilsAdditions)
 142 - (NSString*) charactersIgnoringModifiersIncludingShift {
 143     // First try -charactersIgnoringModifiers and look for keys which UCKeyTranslate translates
 144     // differently than AppKit.
 145     NSString* c = [self charactersIgnoringModifiers];
 146     if ([c length] == 1) {
 147         unichar codepoint = [c characterAtIndex:0];
 148         if ((codepoint >= 0xF700 && codepoint <= 0xF8FF) || codepoint == 0x7F) {
 149             return c;
 150         }
 151     }
 152     // This is not a "special" key, so ask UCKeyTranslate to give us the character with no
 153     // modifiers attached.  Actually, that's not quite accurate; we attach the Command modifier
 154     // which hints the OS to use Latin characters where possible, which is generally what we want.
 155     NSString* result = @"";
 156     TISInputSourceRef currentKeyboard = TISCopyCurrentKeyboardInputSource();
 157     CFDataRef uchr = (CFDataRef)TISGetInputSourceProperty(currentKeyboard, kTISPropertyUnicodeKeyLayoutData);
 158     CFRelease(currentKeyboard);
 159     if (uchr == NULL) {
 160         // this can happen for some non-U.S. input methods (eg. Romaji or Hiragana)
 161         return c;
 162     }
 163     const UCKeyboardLayout *keyboardLayout = (const UCKeyboardLayout*)CFDataGetBytePtr(uchr);
 164     if (keyboardLayout) {
 165         UInt32 deadKeyState = 0;
 166         UniCharCount maxStringLength = 255;
 167         UniCharCount actualStringLength = 0;
 168         UniChar unicodeString[maxStringLength];
 169
 170         OSStatus status = UCKeyTranslate(keyboardLayout,
 171                                          [self keyCode],
 172                                          kUCKeyActionDown,
 173                                          cmdKey >> 8,         // force the Command key to "on"
 174                                          LMGetKbdType(),
 175                                          kUCKeyTranslateNoDeadKeysMask,
 176                                          &deadKeyState,
 177                                          maxStringLength,
 178                                          &actualStringLength,
 179                                          unicodeString);
 180
 181         if(status == noErr)
 182             result = [NSString stringWithCharacters:unicodeString length:(NSInteger)actualStringLength];
 183     }
 184     return result;
 185 }
 186 @end
 187
 188 long wxOSXTranslateCocoaKey( NSEvent* event, int eventType )
 189 {
 190     long retval = 0;
 191
 192     if ([event type] != NSFlagsChanged)
 193     {
 194         NSString* s = [event charactersIgnoringModifiersIncludingShift];
 195         // backspace char reports as delete w/modifiers for some reason
 196         if ([s length] == 1)
 197         {
 198             if ( eventType == wxEVT_CHAR && ([event modifierFlags] & NSControlKeyMask) && ( [s characterAtIndex:0] >= 'a' && [s characterAtIndex:0] <= 'z' ) )
 199             {
 200                 retval = WXK_CONTROL_A + ([s characterAtIndex:0] - 'a');
 201             }
 202             else
 203             {
 204                 switch ( [s characterAtIndex:0] )
 205                 {
 206                     // backspace key
 207                     case 0x7F :
 208                     case 8 :
 209                         retval = WXK_BACK;
 210                         break;
 211                     case NSUpArrowFunctionKey :
 212                         retval = WXK_UP;
 213                         break;
 214                     case NSDownArrowFunctionKey :
 215                         retval = WXK_DOWN;
 216                         break;
 217                     case NSLeftArrowFunctionKey :
 218                         retval = WXK_LEFT;
 219                         break;
 220                     case NSRightArrowFunctionKey :
 221                         retval = WXK_RIGHT;
 222                         break;
 223                     case NSInsertFunctionKey  :
 224                         retval = WXK_INSERT;
 225                         break;
 226                     case NSDeleteFunctionKey  :
 227                         retval = WXK_DELETE;
 228                         break;
 229                     case NSHomeFunctionKey  :
 230                         retval = WXK_HOME;
 231                         break;
 232             //        case NSBeginFunctionKey  :
 233             //            retval = WXK_BEGIN;
 234             //            break;
 235                     case NSEndFunctionKey  :
 236                         retval = WXK_END;
 237                         break;
 238                     case NSPageUpFunctionKey  :
 239                         retval = WXK_PAGEUP;
 240                         break;
 241                    case NSPageDownFunctionKey  :
 242                         retval = WXK_PAGEDOWN;
 243                         break;
 244                    case NSHelpFunctionKey  :
 245                         retval = WXK_HELP;
 246                         break;
 247                     default:
 248                         int intchar = [s characterAtIndex: 0];
 249                         if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 250                             retval = WXK_F1 + (intchar - NSF1FunctionKey );
 251                         else if ( intchar > 0 && intchar < 32 )
 252                             retval = intchar;
 253                         break;
 254                 }
 255             }
 256         }
 257     }
 258
 259     // Some keys don't seem to have constants. The code mimics the approach
 260     // taken by WebKit. See:
 261     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 262     switch( [event keyCode] )
 263     {
 264         // command key
 265         case 54:
 266         case 55:
 267             retval = WXK_CONTROL;
 268             break;
 269         // caps locks key
 270         case 57: // Capslock
 271             retval = WXK_CAPITAL;
 272             break;
 273         // shift key
 274         case 56: // Left Shift
 275         case 60: // Right Shift
 276             retval = WXK_SHIFT;
 277             break;
 278         // alt key
 279         case 58: // Left Alt
 280         case 61: // Right Alt
 281             retval = WXK_ALT;
 282             break;
 283         // ctrl key
 284         case 59: // Left Ctrl
 285         case 62: // Right Ctrl
 286             retval = WXK_RAW_CONTROL;
 287             break;
 288         // clear key
 289         case 71:
 290             retval = WXK_CLEAR;
 291             break;
 292         // tab key
 293         case 48:
 294             retval = WXK_TAB;
 295             break;
 296         default:
 297             break;
 298     }
 299
 300     // Check for NUMPAD keys.  For KEY_UP/DOWN events we need to use the
 301     // WXK_NUMPAD constants, but for the CHAR event we want to use the
 302     // standard ascii values
 303     if ( eventType != wxEVT_CHAR )
 304     {
 305         switch( [event keyCode] )
 306         {
 307             case 75: // /
 308                 retval = WXK_NUMPAD_DIVIDE;
 309                 break;
 310             case 67: // *
 311                 retval = WXK_NUMPAD_MULTIPLY;
 312                 break;
 313             case 78: // -
 314                 retval = WXK_NUMPAD_SUBTRACT;
 315                 break;
 316             case 69: // +
 317                 retval = WXK_NUMPAD_ADD;
 318                 break;
 319             case 76: // Enter
 320                 retval = WXK_NUMPAD_ENTER;
 321                 break;
 322             case 65: // .
 323                 retval = WXK_NUMPAD_DECIMAL;
 324                 break;
 325             case 82: // 0
 326                 retval = WXK_NUMPAD0;
 327                 break;
 328             case 83: // 1
 329                 retval = WXK_NUMPAD1;
 330                 break;
 331             case 84: // 2
 332                 retval = WXK_NUMPAD2;
 333                 break;
 334             case 85: // 3
 335                 retval = WXK_NUMPAD3;
 336                 break;
 337             case 86: // 4
 338                 retval = WXK_NUMPAD4;
 339                 break;
 340             case 87: // 5
 341                 retval = WXK_NUMPAD5;
 342                 break;
 343             case 88: // 6
 344                 retval = WXK_NUMPAD6;
 345                 break;
 346             case 89: // 7
 347                 retval = WXK_NUMPAD7;
 348                 break;
 349             case 91: // 8
 350                 retval = WXK_NUMPAD8;
 351                 break;
 352             case 92: // 9
 353                 retval = WXK_NUMPAD9;
 354                 break;
 355             default:
 356                 //retval = [event keyCode];
 357                 break;
 358         }
 359     }
 360     return retval;
 361 }
 362
 363 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 364 {
 365     UInt32 modifiers = [nsEvent modifierFlags] ;
 366     int eventType = [nsEvent type];
 367
 368     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 369     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 370     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 371     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 372
 373     wxevent.m_rawCode = [nsEvent keyCode];
 374     wxevent.m_rawFlags = modifiers;
 375
 376     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 377
 378     wxString chars;
 379     if ( eventType != NSFlagsChanged )
 380     {
 381         NSString* nschars = [[nsEvent charactersIgnoringModifiersIncludingShift] uppercaseString];
 382         if ( charString )
 383         {
 384             // if charString is set, it did not come from key up / key down
 385             wxevent.SetEventType( wxEVT_CHAR );
 386             chars = wxCFStringRef::AsString(charString);
 387         }
 388         else if ( nschars )
 389         {
 390             chars = wxCFStringRef::AsString(nschars);
 391         }
 392     }
 393
 394     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 395     long keyval = 0;
 396
 397     if (wxevent.GetEventType() != wxEVT_CHAR)
 398     {
 399         keyval = wxOSXTranslateCocoaKey(nsEvent, wxevent.GetEventType()) ;
 400         switch (eventType)
 401         {
 402             case NSKeyDown :
 403                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 404                 break;
 405             case NSKeyUp :
 406                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 407                 break;
 408             case NSFlagsChanged :
 409                 switch (keyval)
 410                 {
 411                     case WXK_CONTROL:
 412                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 413                         break;
 414                     case WXK_SHIFT:
 415                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 416                         break;
 417                     case WXK_ALT:
 418                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 419                         break;
 420                     case WXK_RAW_CONTROL:
 421                         wxevent.SetEventType( wxevent.m_rawControlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 422                         break;
 423                 }
 424                 break;
 425             default :
 426                 break ;
 427         }
 428     }
 429
 430     if ( !keyval )
 431     {
 432         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 433             keyval = wxToupper( aunichar ) ;
 434         else
 435             keyval = aunichar;
 436     }
 437
 438 #if wxUSE_UNICODE
 439     // OS X generates events with key codes in Unicode private use area for
 440     // unprintable symbols such as cursor arrows (WXK_UP is mapped to U+F700)
 441     // and function keys (WXK_F2 is U+F705). We don't want to use them as the
 442     // result of wxKeyEvent::GetUnicodeKey() however as it's supposed to return
 443     // WXK_NONE for "non characters" so explicitly exclude them.
 444     //
 445     // We only exclude the private use area inside the Basic Multilingual Plane
 446     // as key codes beyond it don't seem to be currently used.
 447     if ( !(aunichar >= 0xe000 && aunichar < 0xf900) )
 448         wxevent.m_uniChar = aunichar;
 449 #endif
 450     wxevent.m_keyCode = keyval;
 451
 452     wxWindowMac* peer = GetWXPeer();
 453     if ( peer )
 454     {
 455         wxevent.SetEventObject(peer);
 456         wxevent.SetId(peer->GetId()) ;
 457     }
 458 }
 459
 460 UInt32 g_lastButton = 0 ;
 461 bool g_lastButtonWasFakeRight = false ;
 462
 463 // better scroll wheel support
 464 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 465
 466 @interface NSEvent (DeviceDelta)
 467 - (CGFloat)deviceDeltaX;
 468 - (CGFloat)deviceDeltaY;
 469
 470 // 10.7+
 471 - (BOOL)hasPreciseScrollingDeltas;
 472 - (CGFloat)scrollingDeltaX;
 473 - (CGFloat)scrollingDeltaY;
 474 @end
 475
 476 void wxWidgetCocoaImpl::SetupCoordinates(wxCoord &x, wxCoord &y, NSEvent* nsEvent)
 477 {
 478     NSPoint locationInWindow = [nsEvent locationInWindow];
 479
 480     // adjust coordinates for the window of the target view
 481     if ( [nsEvent window] != [m_osxView window] )
 482     {
 483         if ( [nsEvent window] != nil )
 484             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 485
 486         if ( [m_osxView window] != nil )
 487             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 488     }
 489
 490     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 491     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 492
 493     x = locationInViewWX.x;
 494     y = locationInViewWX.y;
 495
 496 }
 497
 498 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 499 {
 500     int eventType = [nsEvent type];
 501     UInt32 modifiers = [nsEvent modifierFlags] ;
 502
 503     SetupCoordinates(wxevent.m_x, wxevent.m_y, nsEvent);
 504
 505     // these parameters are not given for all events
 506     UInt32 button = [nsEvent buttonNumber];
 507     UInt32 clickCount = 0;
 508
 509     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 510     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 511     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 512     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 513     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 514
 515     UInt32 mouseChord = 0;
 516
 517     switch (eventType)
 518     {
 519         case NSLeftMouseDown :
 520         case NSLeftMouseDragged :
 521             mouseChord = 1U;
 522             break;
 523         case NSRightMouseDown :
 524         case NSRightMouseDragged :
 525             mouseChord = 2U;
 526             break;
 527         case NSOtherMouseDown :
 528         case NSOtherMouseDragged :
 529             mouseChord = 4U;
 530             break;
 531     }
 532
 533     // a control click is interpreted as a right click
 534     bool thisButtonIsFakeRight = false ;
 535     if ( button == 0 && (modifiers & NSControlKeyMask) )
 536     {
 537         button = 1 ;
 538         thisButtonIsFakeRight = true ;
 539     }
 540
 541     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 542     if ( clickCount > 1 && button != g_lastButton )
 543         clickCount = 1 ;
 544
 545     // we must make sure that our synthetic 'right' button corresponds in
 546     // mouse down, moved and mouse up, and does not deliver a right down and left up
 547     switch (eventType)
 548     {
 549         case NSLeftMouseDown :
 550         case NSRightMouseDown :
 551         case NSOtherMouseDown :
 552             g_lastButton = button ;
 553             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 554             break;
 555      }
 556
 557     if ( button == 0 )
 558     {
 559         g_lastButton = 0 ;
 560         g_lastButtonWasFakeRight = false ;
 561     }
 562     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 563         button = g_lastButton ;
 564
 565     // Adjust the chord mask to remove the primary button and add the
 566     // secondary button.  It is possible that the secondary button is
 567     // already pressed, e.g. on a mouse connected to a laptop, but this
 568     // possibility is ignored here:
 569     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 570         mouseChord = ((mouseChord & ~1U) | 2U);
 571
 572     if(mouseChord & 1U)
 573                 wxevent.m_leftDown = true ;
 574     if(mouseChord & 2U)
 575                 wxevent.m_rightDown = true ;
 576     if(mouseChord & 4U)
 577                 wxevent.m_middleDown = true ;
 578
 579     // translate into wx types
 580     switch (eventType)
 581     {
 582         case NSLeftMouseDown :
 583         case NSRightMouseDown :
 584         case NSOtherMouseDown :
 585             clickCount = [nsEvent clickCount];
 586             switch ( button )
 587             {
 588                 case 0 :
 589                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 590                     break ;
 591
 592                 case 1 :
 593                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 594                     break ;
 595
 596                 case 2 :
 597                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 598                     break ;
 599
 600                 default:
 601                     break ;
 602             }
 603             break ;
 604
 605         case NSLeftMouseUp :
 606         case NSRightMouseUp :
 607         case NSOtherMouseUp :
 608             clickCount = [nsEvent clickCount];
 609             switch ( button )
 610             {
 611                 case 0 :
 612                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 613                     break ;
 614
 615                 case 1 :
 616                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 617                     break ;
 618
 619                 case 2 :
 620                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 621                     break ;
 622
 623                 default:
 624                     break ;
 625             }
 626             break ;
 627
 628      case NSScrollWheel :
 629         {
 630             float deltaX = 0.0;
 631             float deltaY = 0.0;
 632
 633             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 634
 635             if ( UMAGetSystemVersion() >= 0x1070 )
 636             {
 637                 if ( [nsEvent hasPreciseScrollingDeltas] )
 638                 {
 639                     deltaX = [nsEvent scrollingDeltaX];
 640                     deltaY = [nsEvent scrollingDeltaY];
 641                 }
 642                 else
 643                 {
 644                     deltaX = [nsEvent scrollingDeltaX] * 10;
 645                     deltaY = [nsEvent scrollingDeltaY] * 10;
 646                 }
 647             }
 648             else
 649             {
 650                 const EventRef cEvent = (EventRef) [nsEvent eventRef];
 651                 // see http://developer.apple.com/qa/qa2005/qa1453.html
 652                 // for more details on why we have to look for the exact type
 653
 654                 bool isMouseScrollEvent = false;
 655                 if ( cEvent )
 656                     isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 657
 658                 if ( isMouseScrollEvent )
 659                 {
 660                     deltaX = [nsEvent deviceDeltaX];
 661                     deltaY = [nsEvent deviceDeltaY];
 662                 }
 663                 else
 664                 {
 665                     deltaX = ([nsEvent deltaX] * 10);
 666                     deltaY = ([nsEvent deltaY] * 10);
 667                 }
 668             }
 669
 670             wxevent.m_wheelDelta = 10;
 671             wxevent.m_linesPerAction = 1;
 672
 673             if ( fabs(deltaX) > fabs(deltaY) )
 674             {
 675                 wxevent.m_wheelAxis = wxMOUSE_WHEEL_HORIZONTAL;
 676                 wxevent.m_wheelRotation = (int)deltaX;
 677             }
 678             else
 679             {
 680                 wxevent.m_wheelRotation = (int)deltaY;
 681             }
 682
 683         }
 684         break ;
 685
 686         case NSMouseEntered :
 687             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 688             break;
 689         case NSMouseExited :
 690             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 691             break;
 692         case NSLeftMouseDragged :
 693         case NSRightMouseDragged :
 694         case NSOtherMouseDragged :
 695         case NSMouseMoved :
 696             wxevent.SetEventType( wxEVT_MOTION ) ;
 697             break;
 698         default :
 699             break ;
 700     }
 701
 702     wxevent.m_clickCount = clickCount;
 703     wxWindowMac* peer = GetWXPeer();
 704     if ( peer )
 705     {
 706         wxevent.SetEventObject(peer);
 707         wxevent.SetId(peer->GetId()) ;
 708     }
 709 }
 710
 711 @implementation wxNSView
 712
 713 + (void)initialize
 714 {
 715     static BOOL initialized = NO;
 716     if (!initialized)
 717     {
 718         initialized = YES;
 719         wxOSXCocoaClassAddWXMethods( self );
 720     }
 721 }
 722
 723 /* idea taken from webkit sources: overwrite the methods that (private) NSToolTipManager will use to attach its tracking rectangle
 724  * then when changing the tooltip send fake view-exit and view-enter methods which will lead to a tooltip refresh
 725  */
 726
 727
 728 - (void)_sendToolTipMouseExited
 729 {
 730     // Nothing matters except window, trackingNumber, and userData.
 731     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseExited
 732                                                 location:NSMakePoint(0, 0)
 733                                            modifierFlags:0
 734                                                timestamp:0
 735                                             windowNumber:[[self window] windowNumber]
 736                                                  context:NULL
 737                                              eventNumber:0
 738                                           trackingNumber:_lastToolTipTrackTag
 739                                                 userData:_lastUserData];
 740     [_lastToolTipOwner mouseExited:fakeEvent];
 741 }
 742
 743 - (void)_sendToolTipMouseEntered
 744 {
 745     // Nothing matters except window, trackingNumber, and userData.
 746     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseEntered
 747                                                 location:NSMakePoint(0, 0)
 748                                            modifierFlags:0
 749                                                timestamp:0
 750                                             windowNumber:[[self window] windowNumber]
 751                                                  context:NULL
 752                                              eventNumber:0
 753                                           trackingNumber:_lastToolTipTrackTag
 754                                                 userData:_lastUserData];
 755     [_lastToolTipOwner mouseEntered:fakeEvent];
 756 }
 757
 758 - (void)setToolTip:(NSString *)string;
 759 {
 760     if (string)
 761     {
 762         if ( _hasToolTip )
 763         {
 764             [self _sendToolTipMouseExited];
 765         }
 766
 767         [super setToolTip:string];
 768         _hasToolTip = YES;
 769         [self _sendToolTipMouseEntered];
 770     }
 771     else
 772     {
 773         if ( _hasToolTip )
 774         {
 775             [self _sendToolTipMouseExited];
 776             [super setToolTip:nil];
 777             _hasToolTip = NO;
 778         }
 779     }
 780 }
 781
 782 - (NSTrackingRectTag)addTrackingRect:(NSRect)rect owner:(id)owner userData:(void *)data assumeInside:(BOOL)assumeInside
 783 {
 784     NSTrackingRectTag tag = [super addTrackingRect:rect owner:owner userData:data assumeInside:assumeInside];
 785     if ( owner != self )
 786     {
 787         _lastUserData = data;
 788         _lastToolTipOwner = owner;
 789         _lastToolTipTrackTag = tag;
 790     }
 791     return tag;
 792 }
 793
 794 - (void)removeTrackingRect:(NSTrackingRectTag)tag
 795 {
 796     if (tag == _lastToolTipTrackTag)
 797     {
 798         _lastUserData = NULL;
 799         _lastToolTipOwner = nil;
 800         _lastToolTipTrackTag = 0;
 801     }
 802     [super removeTrackingRect:tag];
 803 }
 804
 805 #if wxOSX_USE_NATIVE_FLIPPED
 806 - (BOOL)isFlipped
 807 {
 808     return YES;
 809 }
 810 #endif
 811
 812 - (BOOL) canBecomeKeyView
 813 {
 814     wxWidgetCocoaImpl* viewimpl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 815     if ( viewimpl && viewimpl->IsUserPane() && viewimpl->GetWXPeer() )
 816         return viewimpl->GetWXPeer()->AcceptsFocus();
 817     return NO;
 818 }
 819
 820 @end // wxNSView
 821
 822 //
 823 // event handlers
 824 //
 825
 826 #if wxUSE_DRAG_AND_DROP
 827
 828 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 829 // for details on the NSPasteboard -> PasteboardRef conversion
 830
 831 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 832 {
 833     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 834     if (impl == NULL)
 835         return NSDragOperationNone;
 836
 837     return impl->draggingEntered(sender, self, _cmd);
 838 }
 839
 840 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 841 {
 842     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 843     if (impl == NULL)
 844         return ;
 845
 846     return impl->draggingExited(sender, self, _cmd);
 847 }
 848
 849 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 850 {
 851     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 852     if (impl == NULL)
 853         return NSDragOperationNone;
 854
 855     return impl->draggingUpdated(sender, self, _cmd);
 856 }
 857
 858 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 859 {
 860     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 861     if (impl == NULL)
 862         return NSDragOperationNone;
 863
 864     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 865 }
 866
 867 #endif
 868
 869 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 870 {
 871     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 872     if (impl == NULL)
 873         return;
 874
 875     impl->mouseEvent(event, self, _cmd);
 876 }
 877
 878 void wxOSX_cursorUpdate(NSView* self, SEL _cmd, NSEvent *event)
 879 {
 880     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 881     if (impl == NULL)
 882         return;
 883
 884     impl->cursorUpdate(event, self, _cmd);
 885 }
 886
 887 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 888 {
 889     // This is needed to support click through, otherwise the first click on a window
 890     // will not do anything unless it is the active window already.
 891     return YES;
 892 }
 893
 894 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 895 {
 896     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 897     if (impl == NULL)
 898         return;
 899
 900     impl->keyEvent(event, self, _cmd);
 901 }
 902
 903 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 904 {
 905     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 906     if (impl == NULL)
 907         return;
 908
 909     impl->insertText(text, self, _cmd);
 910 }
 911
 912 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 913 {
 914     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 915     if (impl == NULL)
 916         return NO;
 917
 918     return impl->performKeyEquivalent(event, self, _cmd);
 919 }
 920
 921 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 922 {
 923     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 924     if (impl == NULL)
 925         return NO;
 926
 927     return impl->acceptsFirstResponder(self, _cmd);
 928 }
 929
 930 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 931 {
 932     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 933     if (impl == NULL)
 934         return NO;
 935
 936     return impl->becomeFirstResponder(self, _cmd);
 937 }
 938
 939 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 940 {
 941     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 942     if (impl == NULL)
 943         return NO;
 944
 945     return impl->resignFirstResponder(self, _cmd);
 946 }
 947
 948 #if !wxOSX_USE_NATIVE_FLIPPED
 949
 950 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 951 {
 952     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 953     if (impl == NULL)
 954         return NO;
 955
 956     return impl->isFlipped(self, _cmd) ? YES:NO;
 957 }
 958
 959 #endif
 960
 961 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 962
 963 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 964 {
 965     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 966     if (impl == NULL)
 967         return;
 968
 969 #if wxUSE_THREADS
 970     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 971     // dialog. This causes a drawRect of the active dialog from outside the
 972     // main UI thread. This causes an occasional crash since the wx drawing
 973     // objects (like wxPen) are not thread safe.
 974     //
 975     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 976     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 977     if ( !wxThread::IsMain() )
 978     {
 979         if ( impl->IsUserPane() )
 980         {
 981             wxWindow* win = impl->GetWXPeer();
 982             if ( win->UseBgCol() )
 983             {
 984
 985                 CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 986                 CGContextSaveGState( context );
 987
 988                 CGContextSetFillColorWithColor( context, win->GetBackgroundColour().GetCGColor());
 989                 CGRect r = CGRectMake(rect.origin.x, rect.origin.y, rect.size.width, rect.size.height);
 990                 CGContextFillRect( context, r );
 991
 992                 CGContextRestoreGState( context );
 993             }
 994         }
 995         else
 996         {
 997             // just call the superclass handler, we don't need any custom wx drawing
 998             // here and it seems to work fine:
 999             wxOSX_DrawRectHandlerPtr
1000             superimpl = (wxOSX_DrawRectHandlerPtr)
1001             [[self superclass] instanceMethodForSelector:_cmd];
1002             superimpl(self, _cmd, rect);
1003         }
1004
1005       return;
1006     }
1007 #endif // wxUSE_THREADS
1008
1009     return impl->drawRect(&rect, self, _cmd);
1010 }
1011
1012 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
1013 {
1014     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
1015     if (impl == NULL)
1016         return;
1017
1018     impl->controlAction(self, _cmd, sender);
1019 }
1020
1021 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
1022 {
1023     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
1024     if (impl == NULL)
1025         return;
1026
1027     impl->controlDoubleAction(self, _cmd, sender);
1028 }
1029
1030 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1031 {
1032     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1033     NSPasteboard *pboard = [sender draggingPasteboard];
1034     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1035
1036     wxWindow* wxpeer = GetWXPeer();
1037     if ( wxpeer == NULL )
1038         return NSDragOperationNone;
1039
1040     wxDropTarget* target = wxpeer->GetDropTarget();
1041     if ( target == NULL )
1042         return NSDragOperationNone;
1043
1044     wxDragResult result = wxDragNone;
1045     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1046     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1047
1048     if ( sourceDragMask & NSDragOperationLink )
1049         result = wxDragLink;
1050     else if ( sourceDragMask & NSDragOperationCopy )
1051         result = wxDragCopy;
1052     else if ( sourceDragMask & NSDragOperationMove )
1053         result = wxDragMove;
1054
1055     PasteboardRef pboardRef;
1056     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1057     target->SetCurrentDragPasteboard(pboardRef);
1058     result = target->OnEnter(pt.x, pt.y, result);
1059     CFRelease(pboardRef);
1060
1061     NSDragOperation nsresult = NSDragOperationNone;
1062     switch (result )
1063     {
1064         case wxDragLink:
1065             nsresult = NSDragOperationLink;
1066         case wxDragMove:
1067             nsresult = NSDragOperationMove;
1068         case wxDragCopy:
1069             nsresult = NSDragOperationCopy;
1070         default :
1071             break;
1072     }
1073     return nsresult;
1074 }
1075
1076 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1077 {
1078     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1079     NSPasteboard *pboard = [sender draggingPasteboard];
1080
1081     wxWindow* wxpeer = GetWXPeer();
1082     if ( wxpeer == NULL )
1083         return;
1084
1085     wxDropTarget* target = wxpeer->GetDropTarget();
1086     if ( target == NULL )
1087         return;
1088
1089     PasteboardRef pboardRef;
1090     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1091     target->SetCurrentDragPasteboard(pboardRef);
1092     target->OnLeave();
1093     CFRelease(pboardRef);
1094  }
1095
1096 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1097 {
1098     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1099     NSPasteboard *pboard = [sender draggingPasteboard];
1100     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1101
1102     wxWindow* wxpeer = GetWXPeer();
1103     if ( wxpeer == NULL )
1104         return NSDragOperationNone;
1105
1106     wxDropTarget* target = wxpeer->GetDropTarget();
1107     if ( target == NULL )
1108         return NSDragOperationNone;
1109
1110     wxDragResult result = wxDragNone;
1111     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1112     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1113
1114     if ( sourceDragMask & NSDragOperationLink )
1115         result = wxDragLink;
1116     else if ( sourceDragMask & NSDragOperationCopy )
1117         result = wxDragCopy;
1118     else if ( sourceDragMask & NSDragOperationMove )
1119         result = wxDragMove;
1120
1121     PasteboardRef pboardRef;
1122     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1123     target->SetCurrentDragPasteboard(pboardRef);
1124     result = target->OnDragOver(pt.x, pt.y, result);
1125     CFRelease(pboardRef);
1126
1127     NSDragOperation nsresult = NSDragOperationNone;
1128     switch (result )
1129     {
1130         case wxDragLink:
1131             nsresult = NSDragOperationLink;
1132         case wxDragMove:
1133             nsresult = NSDragOperationMove;
1134         case wxDragCopy:
1135             nsresult = NSDragOperationCopy;
1136         default :
1137             break;
1138     }
1139     return nsresult;
1140 }
1141
1142 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1143 {
1144     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1145
1146     NSPasteboard *pboard = [sender draggingPasteboard];
1147     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1148
1149     wxWindow* wxpeer = GetWXPeer();
1150     wxDropTarget* target = wxpeer->GetDropTarget();
1151     wxDragResult result = wxDragNone;
1152     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1153     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1154
1155     if ( sourceDragMask & NSDragOperationLink )
1156         result = wxDragLink;
1157     else if ( sourceDragMask & NSDragOperationCopy )
1158         result = wxDragCopy;
1159     else if ( sourceDragMask & NSDragOperationMove )
1160         result = wxDragMove;
1161
1162     PasteboardRef pboardRef;
1163     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1164     target->SetCurrentDragPasteboard(pboardRef);
1165
1166     if (target->OnDrop(pt.x, pt.y))
1167         result = target->OnData(pt.x, pt.y, result);
1168
1169     CFRelease(pboardRef);
1170
1171     return result != wxDragNone;
1172 }
1173
1174 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
1175 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1176 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1177 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
1178
1179 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1180 {
1181     // we are getting moved events for all windows in the hierarchy, not something wx expects
1182     // therefore we only handle it for the deepest child in the hierarchy
1183     if ( [event type] == NSMouseMoved )
1184     {
1185         NSView* hitview = [[[slf window] contentView] hitTest:[event locationInWindow]];
1186         if ( hitview == NULL || hitview != slf)
1187             return;
1188     }
1189
1190     if ( !DoHandleMouseEvent(event) )
1191     {
1192         // for plain NSView mouse events would propagate to parents otherwise
1193         // scrollwheel events have to be propagated if not handled in all cases
1194         if (!IsUserPane() || [event type] == NSScrollWheel )
1195         {
1196             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1197             superimpl(slf, (SEL)_cmd, event);
1198
1199             // super of built-ins keeps the mouse up, as wx expects this event, we have to synthesize it
1200             // only trigger if at this moment the mouse is already up
1201             if ( [ event type]  == NSLeftMouseDown && !wxGetMouseState().LeftIsDown() )
1202             {
1203                 wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
1204                 SetupMouseEvent(wxevent , event) ;
1205                 wxevent.SetEventType(wxEVT_LEFT_UP);
1206
1207                 GetWXPeer()->HandleWindowEvent(wxevent);
1208             }
1209         }
1210     }
1211 }
1212
1213 void wxWidgetCocoaImpl::cursorUpdate(WX_NSEvent event, WXWidget slf, void *_cmd)
1214 {
1215     if ( !SetupCursor(event) )
1216     {
1217         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1218             superimpl(slf, (SEL)_cmd, event);
1219     }
1220  }
1221
1222 bool wxWidgetCocoaImpl::SetupCursor(WX_NSEvent event)
1223 {
1224     extern wxCursor gGlobalCursor;
1225
1226     if ( gGlobalCursor.IsOk() )
1227     {
1228         gGlobalCursor.MacInstall();
1229         return true;
1230     }
1231     else
1232     {
1233         wxWindow* cursorTarget = GetWXPeer();
1234         wxCoord x,y;
1235         SetupCoordinates(x, y, event);
1236         wxPoint cursorPoint( x , y ) ;
1237
1238         while ( cursorTarget && !cursorTarget->MacSetupCursor( cursorPoint ) )
1239         {
1240             // at least in GTK cursor events are not propagated either ...
1241 #if 1
1242             cursorTarget = NULL;
1243 #else
1244             cursorTarget = cursorTarget->GetParent() ;
1245             if ( cursorTarget )
1246                 cursorPoint += cursorTarget->GetPosition();
1247 #endif
1248         }
1249
1250         return cursorTarget != NULL;
1251     }
1252 }
1253
1254 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1255 {
1256     if ( [event type] == NSKeyDown )
1257     {
1258         // there are key equivalents that are not command-combos and therefore not handled by cocoa automatically,
1259         // therefore we call the menubar directly here, exit if the menu is handling the shortcut
1260         if ( [[[NSApplication sharedApplication] mainMenu] performKeyEquivalent:event] )
1261             return;
1262
1263         m_lastKeyDownEvent = event;
1264     }
1265
1266     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1267     {
1268         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1269         superimpl(slf, (SEL)_cmd, event);
1270     }
1271     m_lastKeyDownEvent = NULL;
1272 }
1273
1274 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1275 {
1276     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1277     {
1278         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1279         superimpl(slf, (SEL)_cmd, text);
1280     }
1281 }
1282
1283
1284 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1285 {
1286     bool handled = false;
1287
1288     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1289     SetupKeyEvent( wxevent, event );
1290
1291     // because performKeyEquivalent is going up the entire view hierarchy, we don't have to
1292     // walk up the ancestors ourselves but let cocoa do it
1293
1294     int command = m_wxPeer->GetAcceleratorTable()->GetCommand( wxevent );
1295     if (command != -1)
1296     {
1297         wxEvtHandler * const handler = m_wxPeer->GetEventHandler();
1298
1299         wxCommandEvent command_event( wxEVT_MENU, command );
1300         command_event.SetEventObject( wxevent.GetEventObject() );
1301         handled = handler->ProcessEvent( command_event );
1302
1303         if ( !handled )
1304         {
1305             // accelerators can also be used with buttons, try them too
1306             command_event.SetEventType(wxEVT_BUTTON);
1307             handled = handler->ProcessEvent( command_event );
1308         }
1309     }
1310
1311     if ( !handled )
1312     {
1313         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1314         return superimpl(slf, (SEL)_cmd, event);
1315     }
1316     return YES;
1317 }
1318
1319 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1320 {
1321     if ( IsUserPane() )
1322         return m_wxPeer->AcceptsFocus();
1323     else
1324     {
1325         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1326         return superimpl(slf, (SEL)_cmd);
1327     }
1328 }
1329
1330 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1331 {
1332     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1333     // get the current focus before running becomeFirstResponder
1334     NSView* otherView = FindFocus();
1335
1336     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1337     BOOL r = superimpl(slf, (SEL)_cmd);
1338     if ( r )
1339     {
1340         DoNotifyFocusEvent( true, otherWindow );
1341     }
1342
1343     return r;
1344 }
1345
1346 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1347 {
1348     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1349     BOOL r = superimpl(slf, (SEL)_cmd);
1350
1351     NSResponder * responder = wxNonOwnedWindowCocoaImpl::GetNextFirstResponder();
1352     NSView* otherView = GetViewFromResponder(responder);
1353
1354     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1355
1356     // NSScrollViews can have their subviews like NSClipView getting focus
1357     // therefore check and use the NSScrollView peer in that case
1358     if ( otherWindow == NULL && [[otherView superview] isKindOfClass:[NSScrollView class]])
1359         otherWindow = FindFromWXWidget([otherView superview]);
1360
1361     // It doesn't make sense to notify about the loss of focus if it's the same
1362     // control in the end, and just a different subview
1363     if ( otherWindow == this )
1364         return r;
1365
1366     // NSTextViews have an editor as true responder, therefore the might get the
1367     // resign notification if their editor takes over, don't trigger any event then
1368     if ( r && !m_hasEditor)
1369     {
1370         DoNotifyFocusEvent( false, otherWindow );
1371     }
1372     return r;
1373 }
1374
1375 #if !wxOSX_USE_NATIVE_FLIPPED
1376
1377 bool wxWidgetCocoaImpl::isFlipped(WXWidget slf, void *WXUNUSED(_cmd))
1378 {
1379     return m_isFlipped;
1380 }
1381
1382 #endif
1383
1384 #define OSX_DEBUG_DRAWING 0
1385
1386 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1387 {
1388     // preparing the update region
1389
1390     wxRegion updateRgn;
1391
1392     // since adding many rects to a region is a costly process, by default use the bounding rect
1393 #if 0
1394     const NSRect *rects;
1395     NSInteger count;
1396     [slf getRectsBeingDrawn:&rects count:&count];
1397     for ( int i = 0 ; i < count ; ++i )
1398     {
1399         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1400     }
1401 #else
1402     updateRgn.Union(wxFromNSRect(slf,*(NSRect*)rect));
1403 #endif
1404
1405     wxWindow* wxpeer = GetWXPeer();
1406
1407     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1408     {
1409         // as this update region is in native window locals we must adapt it to wx window local
1410         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1411     }
1412
1413     // Restrict the update region to the shape of the window, if any, and also
1414     // remember the region that we need to clear later.
1415     wxNonOwnedWindow* const tlwParent = wxpeer->MacGetTopLevelWindow();
1416     const bool isTopLevel = tlwParent == wxpeer;
1417     wxRegion clearRgn;
1418     if ( tlwParent->GetWindowStyle() & wxFRAME_SHAPED )
1419     {
1420         if ( isTopLevel )
1421             clearRgn = updateRgn;
1422
1423         int xoffset = 0, yoffset = 0;
1424         wxRegion rgn = tlwParent->GetShape();
1425         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1426         rgn.Offset( xoffset, yoffset );
1427         updateRgn.Intersect(rgn);
1428
1429         if ( isTopLevel )
1430         {
1431             // Exclude the window shape from the region to be cleared below.
1432             rgn.Xor(wxpeer->GetSize());
1433             clearRgn.Intersect(rgn);
1434         }
1435     }
1436
1437     wxpeer->GetUpdateRegion() = updateRgn;
1438
1439     // setting up the drawing context
1440
1441     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1442     CGContextSaveGState( context );
1443
1444 #if OSX_DEBUG_DRAWING
1445     CGContextBeginPath( context );
1446     CGContextMoveToPoint(context, 0, 0);
1447     NSRect bounds = [slf bounds];
1448     CGContextAddLineToPoint(context, 10, 0);
1449     CGContextMoveToPoint(context, 0, 0);
1450     CGContextAddLineToPoint(context, 0, 10);
1451     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1452     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1453     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1454     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1455     CGContextClosePath( context );
1456     CGContextStrokePath(context);
1457 #endif
1458
1459     if ( ![slf isFlipped] )
1460     {
1461         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1462         CGContextScaleCTM( context, 1, -1 );
1463     }
1464
1465     wxpeer->MacSetCGContextRef( context );
1466
1467     bool handled = wxpeer->MacDoRedraw( 0 );
1468     CGContextRestoreGState( context );
1469
1470     CGContextSaveGState( context );
1471     if ( !handled )
1472     {
1473         // call super
1474         SEL _cmd = @selector(drawRect:);
1475         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1476         superimpl(slf, _cmd, *(NSRect*)rect);
1477         CGContextRestoreGState( context );
1478         CGContextSaveGState( context );
1479     }
1480     // as we called restore above, we have to flip again if necessary
1481     if ( ![slf isFlipped] )
1482     {
1483         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1484         CGContextScaleCTM( context, 1, -1 );
1485     }
1486
1487     if ( isTopLevel )
1488     {
1489         // We also need to explicitly draw the part of the top level window
1490         // outside of its region with transparent colour to ensure that it is
1491         // really transparent.
1492         if ( clearRgn.IsOk() )
1493         {
1494             wxMacCGContextStateSaver saveState(context);
1495             wxWindowDC dc(wxpeer);
1496             dc.SetBackground(wxBrush(wxTransparentColour));
1497             dc.SetDeviceClippingRegion(clearRgn);
1498             dc.Clear();
1499         }
1500
1501 #if wxUSE_GRAPHICS_CONTEXT
1502         // If the window shape is defined by a path, stroke the path to show
1503         // the window border.
1504         const wxGraphicsPath& path = tlwParent->GetShapePath();
1505         if ( !path.IsNull() )
1506         {
1507             CGContextSetLineWidth(context, 1);
1508             CGContextSetStrokeColorWithColor(context, wxLIGHT_GREY->GetCGColor());
1509             CGContextAddPath(context, (CGPathRef) path.GetNativePath());
1510             CGContextStrokePath(context);
1511         }
1512 #endif // wxUSE_GRAPHICS_CONTEXT
1513     }
1514
1515     wxpeer->MacPaintChildrenBorders();
1516     wxpeer->MacSetCGContextRef( NULL );
1517     CGContextRestoreGState( context );
1518 }
1519
1520 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1521 {
1522     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1523     if ( wxpeer )
1524     {
1525         wxpeer->OSXSimulateFocusEvents();
1526         wxpeer->OSXHandleClicked(0);
1527     }
1528 }
1529
1530 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1531 {
1532 }
1533
1534 void wxWidgetCocoaImpl::controlTextDidChange()
1535 {
1536     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1537     if ( wxpeer )
1538     {
1539         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1540         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1541         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1542         if ( tc )
1543             tc->SendTextUpdatedEventIfAllowed();
1544         else if ( cb )
1545             cb->SendTextUpdatedEventIfAllowed();
1546         else
1547         {
1548             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1549         }
1550     }
1551 }
1552
1553 //
1554
1555 #if OBJC_API_VERSION >= 2
1556
1557 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1558     class_addMethod(c, s, i, t );
1559
1560 #else
1561
1562 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1563     { s, (char*) t, i },
1564
1565 #endif
1566
1567 void wxOSXCocoaClassAddWXMethods(Class c)
1568 {
1569
1570 #if OBJC_API_VERSION < 2
1571     static objc_method wxmethods[] =
1572     {
1573 #endif
1574
1575     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1576     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1577     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1578
1579     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1580     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1581     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1582
1583     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1584
1585     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1586     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1587     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1588
1589     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1590
1591     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1592     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1593     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1594
1595     wxOSX_CLASS_ADD_METHOD(c, @selector(cursorUpdate:), (IMP) wxOSX_cursorUpdate, "v@:@" )
1596
1597     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1598     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1599     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1600
1601     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1602
1603     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1604
1605     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1606     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1607     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1608
1609 #if !wxOSX_USE_NATIVE_FLIPPED
1610     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1611 #endif
1612     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1613
1614     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1615     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1616
1617 #if wxUSE_DRAG_AND_DROP
1618     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1619     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1620     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1621     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1622 #endif
1623
1624 #if OBJC_API_VERSION < 2
1625     } ;
1626     static int method_count = WXSIZEOF( wxmethods );
1627     static objc_method_list *wxmethodlist = NULL;
1628     if ( wxmethodlist == NULL )
1629     {
1630         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1631         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1632         wxmethodlist->method_count = method_count;
1633         wxmethodlist->obsolete = 0;
1634     }
1635     class_addMethods( c, wxmethodlist );
1636 #endif
1637 }
1638
1639 //
1640 // C++ implementation class
1641 //
1642
1643 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1644
1645 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl, bool isUserPane ) :
1646     wxWidgetImpl( peer, isRootControl, isUserPane )
1647 {
1648     Init();
1649     m_osxView = w;
1650
1651     // check if the user wants to create the control initially hidden
1652     if ( !peer->IsShown() )
1653         SetVisibility(false);
1654
1655     // gc aware handling
1656     if ( m_osxView )
1657         CFRetain(m_osxView);
1658     [m_osxView release];
1659 }
1660
1661 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1662 {
1663     Init();
1664 }
1665
1666 void wxWidgetCocoaImpl::Init()
1667 {
1668     m_osxView = NULL;
1669 #if !wxOSX_USE_NATIVE_FLIPPED
1670     m_isFlipped = true;
1671 #endif
1672     m_lastKeyDownEvent = NULL;
1673     m_hasEditor = false;
1674 }
1675
1676 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1677 {
1678     RemoveAssociations( this );
1679
1680     if ( !IsRootControl() )
1681     {
1682         NSView *sv = [m_osxView superview];
1683         if ( sv != nil )
1684             [m_osxView removeFromSuperview];
1685     }
1686     // gc aware handling
1687     if ( m_osxView )
1688         CFRelease(m_osxView);
1689 }
1690
1691 bool wxWidgetCocoaImpl::IsVisible() const
1692 {
1693     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1694 }
1695
1696 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1697 {
1698     [m_osxView setHidden:(visible ? NO:YES)];
1699 }
1700
1701 // ----------------------------------------------------------------------------
1702 // window animation stuff
1703 // ----------------------------------------------------------------------------
1704
1705 // define a delegate used to refresh the window during animation
1706 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1707 {
1708     wxWindow *m_win;
1709     bool m_isDone;
1710 }
1711
1712 - (id)init:(wxWindow *)win;
1713
1714 - (bool)isDone;
1715
1716 // NSAnimationDelegate methods
1717 - (void)animationDidEnd:(NSAnimation*)animation;
1718 - (void)animation:(NSAnimation*)animation
1719         didReachProgressMark:(NSAnimationProgress)progress;
1720 @end
1721
1722 @implementation wxNSAnimationDelegate
1723
1724 - (id)init:(wxWindow *)win
1725 {
1726     self = [super init];
1727
1728     m_win = win;
1729     m_isDone = false;
1730
1731     return self;
1732 }
1733
1734 - (bool)isDone
1735 {
1736     return m_isDone;
1737 }
1738
1739 - (void)animation:(NSAnimation*)animation
1740         didReachProgressMark:(NSAnimationProgress)progress
1741 {
1742     wxUnusedVar(animation);
1743     wxUnusedVar(progress);
1744
1745     m_win->SendSizeEvent();
1746 }
1747
1748 - (void)animationDidEnd:(NSAnimation*)animation
1749 {
1750     wxUnusedVar(animation);
1751     m_isDone = true;
1752 }
1753
1754 @end
1755
1756 /* static */
1757 bool
1758 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1759                                               bool show,
1760                                               wxShowEffect effect,
1761                                               unsigned timeout)
1762 {
1763     // create the dictionary describing the animation to perform on this view
1764     NSObject * const
1765         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1766     NSMutableDictionary * const
1767         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1768     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1769
1770     // determine the start and end rectangles assuming we're hiding the window
1771     const wxRect rectOrig = win->GetRect();
1772     wxRect rectStart,
1773            rectEnd;
1774     rectStart =
1775     rectEnd = rectOrig;
1776
1777     if ( show )
1778     {
1779         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1780                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1781             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1782         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1783                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1784             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1785         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1786                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1787             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1788         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1789                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1790             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1791     }
1792
1793     switch ( effect )
1794     {
1795         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1796         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1797             rectEnd.width = 0;
1798             break;
1799
1800         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1801         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1802             rectEnd.x = rectStart.GetRight();
1803             rectEnd.width = 0;
1804             break;
1805
1806         case wxSHOW_EFFECT_ROLL_TO_TOP:
1807         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1808             rectEnd.height = 0;
1809             break;
1810
1811         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1812         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1813             rectEnd.y = rectStart.GetBottom();
1814             rectEnd.height = 0;
1815             break;
1816
1817         case wxSHOW_EFFECT_EXPAND:
1818             rectEnd.x = rectStart.x + rectStart.width / 2;
1819             rectEnd.y = rectStart.y + rectStart.height / 2;
1820             rectEnd.width =
1821             rectEnd.height = 0;
1822             break;
1823
1824         case wxSHOW_EFFECT_BLEND:
1825             [dict setObject:(show ? NSViewAnimationFadeInEffect
1826                                   : NSViewAnimationFadeOutEffect)
1827                   forKey:NSViewAnimationEffectKey];
1828             break;
1829
1830         case wxSHOW_EFFECT_NONE:
1831         case wxSHOW_EFFECT_MAX:
1832             wxFAIL_MSG( "unexpected animation effect" );
1833             return false;
1834
1835         default:
1836             wxFAIL_MSG( "unknown animation effect" );
1837             return false;
1838     };
1839
1840     if ( show )
1841     {
1842         // we need to restore it to the original rectangle instead of making it
1843         // disappear
1844         wxSwap(rectStart, rectEnd);
1845
1846         // and as the window is currently hidden, we need to show it for the
1847         // animation to be visible at all (but don't restore it at its full
1848         // rectangle as it shouldn't appear immediately)
1849         win->SetSize(rectStart);
1850         win->Show();
1851     }
1852
1853     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1854                                     ? [(NSView *)viewOrWin superview]
1855                                     : nil;
1856     const NSRect rStart = wxToNSRect(parentView, rectStart);
1857     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1858
1859     [dict setObject:[NSValue valueWithRect:rStart]
1860           forKey:NSViewAnimationStartFrameKey];
1861     [dict setObject:[NSValue valueWithRect:rEnd]
1862           forKey:NSViewAnimationEndFrameKey];
1863
1864     // create an animation using the values in the above dictionary
1865     NSViewAnimation * const
1866         anim = [[NSViewAnimation alloc]
1867                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1868
1869     if ( !timeout )
1870     {
1871         // what is a good default duration? Windows uses 200ms, Web frameworks
1872         // use anything from 250ms to 1s... choose something in the middle
1873         timeout = 500;
1874     }
1875
1876     [anim setDuration:timeout/1000.];   // duration is in seconds here
1877
1878     // if the window being animated changes its layout depending on its size
1879     // (which is almost always the case) we need to redo it during animation
1880     //
1881     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1882     // controls in wxInfoBar visibly jump around)
1883     const int NUM_LAYOUTS = 20;
1884     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1885         [anim addProgressMark:f];
1886
1887     wxNSAnimationDelegate * const
1888         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1889     [anim setDelegate:animDelegate];
1890     [anim startAnimation];
1891
1892     // Cocoa is capable of doing animation asynchronously or even from separate
1893     // thread but wx API doesn't provide any way to be notified about the
1894     // animation end and without this we really must ensure that the window has
1895     // the expected (i.e. the same as if a simple Show() had been used) size
1896     // when we return, so block here until the animation finishes
1897     //
1898     // notice that because the default animation mode is NSAnimationBlocking,
1899     // no user input events ought to be processed from here
1900     {
1901         wxEventLoopGuarantor ensureEventLoopExistence;
1902         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1903         while ( ![animDelegate isDone] )
1904             loop->Dispatch();
1905     }
1906
1907     if ( !show )
1908     {
1909         // NSViewAnimation is smart enough to hide the NSView being animated at
1910         // the end but we also must ensure that it's hidden for wx too
1911         win->Hide();
1912
1913         // and we must also restore its size because it isn't expected to
1914         // change just because the window was hidden
1915         win->SetSize(rectOrig);
1916     }
1917     else
1918     {
1919         // refresh it once again after the end to ensure that everything is in
1920         // place
1921         win->SendSizeEvent();
1922     }
1923
1924     [anim setDelegate:nil];
1925     [animDelegate release];
1926     [anim release];
1927
1928     return true;
1929 }
1930
1931 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1932                                        wxShowEffect effect,
1933                                        unsigned timeout)
1934 {
1935     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1936 }
1937
1938 /* note that the drawing order between siblings is not defined under 10.4 */
1939 /* only starting from 10.5 the subview order is respected */
1940
1941 /* NSComparisonResult is typedef'd as an enum pre-Leopard but typedef'd as
1942  * NSInteger post-Leopard.  Pre-Leopard the Cocoa toolkit expects a function
1943  * returning int and not NSComparisonResult.  Post-Leopard the Cocoa toolkit
1944  * expects a function returning the new non-enum NSComparsionResult.
1945  * Hence we create a typedef named CocoaWindowCompareFunctionResult.
1946  */
1947 #if defined(NSINTEGER_DEFINED)
1948 typedef NSComparisonResult CocoaWindowCompareFunctionResult;
1949 #else
1950 typedef int CocoaWindowCompareFunctionResult;
1951 #endif
1952
1953 class CocoaWindowCompareContext
1954 {
1955     wxDECLARE_NO_COPY_CLASS(CocoaWindowCompareContext);
1956 public:
1957     CocoaWindowCompareContext(); // Not implemented
1958     CocoaWindowCompareContext(NSView *target, NSArray *subviews)
1959     {
1960         m_target = target;
1961         // Cocoa sorts subviews in-place.. make a copy
1962         m_subviews = [subviews copy];
1963     }
1964
1965     ~CocoaWindowCompareContext()
1966     {   // release the copy
1967         [m_subviews release];
1968     }
1969     NSView* target()
1970     {   return m_target; }
1971
1972     NSArray* subviews()
1973     {   return m_subviews; }
1974
1975     /* Helper function that returns the comparison based off of the original ordering */
1976     CocoaWindowCompareFunctionResult CompareUsingOriginalOrdering(id first, id second)
1977     {
1978         NSUInteger firstI = [m_subviews indexOfObjectIdenticalTo:first];
1979         NSUInteger secondI = [m_subviews indexOfObjectIdenticalTo:second];
1980         // NOTE: If either firstI or secondI is NSNotFound then it will be NSIntegerMax and thus will
1981         // likely compare higher than the other view which is reasonable considering the only way that
1982         // can happen is if the subview was added after our call to subviews but before the call to
1983         // sortSubviewsUsingFunction:context:.  Thus we don't bother checking.  Particularly because
1984         // that case should never occur anyway because that would imply a multi-threaded GUI call
1985         // which is a big no-no with Cocoa.
1986
1987         // Subviews are ordered from back to front meaning one that is already lower will have an lower index.
1988         NSComparisonResult result = (firstI < secondI)
1989                 ?   NSOrderedAscending /* -1 */
1990                 :   (firstI > secondI)
1991                 ?   NSOrderedDescending /* 1 */
1992                 :   NSOrderedSame /* 0 */;
1993
1994         return result;
1995     }
1996 private:
1997     /* The subview we are trying to Raise or Lower */
1998     NSView *m_target;
1999     /* A copy of the original array of subviews */
2000     NSArray *m_subviews;
2001 };
2002
2003 /* Causes Cocoa to raise the target view to the top of the Z-Order by telling the sort function that
2004  * the target view is always higher than every other view.  When comparing two views neither of
2005  * which is the target, it returns the correct response based on the original ordering
2006  */
2007 static CocoaWindowCompareFunctionResult CocoaRaiseWindowCompareFunction(id first, id second, void *ctx)
2008 {
2009     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
2010     // first should be ordered higher
2011     if(first==compareContext->target())
2012         return NSOrderedDescending;
2013     // second should be ordered higher
2014     if(second==compareContext->target())
2015         return NSOrderedAscending;
2016     return compareContext->CompareUsingOriginalOrdering(first,second);
2017 }
2018
2019 void wxWidgetCocoaImpl::Raise()
2020 {
2021         NSView* nsview = m_osxView;
2022
2023     NSView *superview = [nsview superview];
2024     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
2025
2026     [superview sortSubviewsUsingFunction:
2027          CocoaRaiseWindowCompareFunction
2028                                                                  context: &compareContext];
2029
2030 }
2031
2032 /* Causes Cocoa to lower the target view to the bottom of the Z-Order by telling the sort function that
2033  * the target view is always lower than every other view.  When comparing two views neither of
2034  * which is the target, it returns the correct response based on the original ordering
2035  */
2036 static CocoaWindowCompareFunctionResult CocoaLowerWindowCompareFunction(id first, id second, void *ctx)
2037 {
2038     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
2039     // first should be ordered lower
2040     if(first==compareContext->target())
2041         return NSOrderedAscending;
2042     // second should be ordered lower
2043     if(second==compareContext->target())
2044         return NSOrderedDescending;
2045     return compareContext->CompareUsingOriginalOrdering(first,second);
2046 }
2047
2048 void wxWidgetCocoaImpl::Lower()
2049 {
2050         NSView* nsview = m_osxView;
2051
2052     NSView *superview = [nsview superview];
2053     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
2054
2055     [superview sortSubviewsUsingFunction:
2056          CocoaLowerWindowCompareFunction
2057                                                                  context: &compareContext];
2058 }
2059
2060 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
2061 {
2062 #if 1
2063     SetNeedsDisplay() ;
2064 #else
2065     // We should do something like this, but it wasn't working in 10.4.
2066     if (GetNeedsDisplay() )
2067     {
2068         SetNeedsDisplay() ;
2069     }
2070     NSRect r = wxToNSRect( [m_osxView superview], *rect );
2071     NSSize offset = NSMakeSize((float)dx, (float)dy);
2072     [m_osxView scrollRect:r by:offset];
2073 #endif
2074 }
2075
2076 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
2077 {
2078     wxWindowMac* parent = GetWXPeer()->GetParent();
2079     // under Cocoa we might have a contentView in the wxParent to which we have to
2080     // adjust the coordinates
2081     if (parent && [m_osxView superview] != parent->GetHandle() )
2082     {
2083         int cx = 0,cy = 0,cw = 0,ch = 0;
2084         if ( parent->GetPeer() )
2085         {
2086             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2087             x -= cx;
2088             y -= cy;
2089         }
2090     }
2091     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
2092     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
2093     [m_osxView setFrame:r];
2094     [[m_osxView superview] setNeedsDisplayInRect:r];
2095 }
2096
2097 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
2098 {
2099     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
2100     x = r.GetLeft();
2101     y = r.GetTop();
2102
2103     // under Cocoa we might have a contentView in the wxParent to which we have to
2104     // adjust the coordinates
2105     wxWindowMac* parent = GetWXPeer()->GetParent();
2106     if (parent && [m_osxView superview] != parent->GetHandle() )
2107     {
2108         int cx = 0,cy = 0,cw = 0,ch = 0;
2109         if ( parent->GetPeer() )
2110         {
2111             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2112             x += cx;
2113             y += cy;
2114         }
2115     }
2116 }
2117
2118 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
2119 {
2120     NSRect rect = [m_osxView frame];
2121     width = (int)rect.size.width;
2122     height = (int)rect.size.height;
2123 }
2124
2125 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
2126 {
2127     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
2128     {
2129         NSView* cv = [m_osxView contentView];
2130
2131         NSRect bounds = [m_osxView bounds];
2132         NSRect rect = [cv frame];
2133
2134         int y = (int)rect.origin.y;
2135         int x = (int)rect.origin.x;
2136         if ( ![ m_osxView isFlipped ] )
2137             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
2138         left = x;
2139         top = y;
2140         width = (int)rect.size.width;
2141         height = (int)rect.size.height;
2142     }
2143     else
2144     {
2145         left = top = 0;
2146         GetSize( width, height );
2147     }
2148 }
2149
2150 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
2151 {
2152     if ( where )
2153         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
2154     else
2155         [m_osxView setNeedsDisplay:YES];
2156 }
2157
2158 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
2159 {
2160     return [m_osxView needsDisplay];
2161 }
2162
2163 bool wxWidgetCocoaImpl::CanFocus() const
2164 {
2165     return [m_osxView canBecomeKeyView] == YES;
2166 }
2167
2168 bool wxWidgetCocoaImpl::HasFocus() const
2169 {
2170     return ( FindFocus() == m_osxView );
2171 }
2172
2173 bool wxWidgetCocoaImpl::SetFocus()
2174 {
2175     if ( !CanFocus() )
2176         return false;
2177
2178     // TODO remove if no issues arise: should not raise the window, only assign focus
2179     //[[m_osxView window] makeKeyAndOrderFront:nil] ;
2180     [[m_osxView window] makeFirstResponder: m_osxView] ;
2181     return true;
2182 }
2183
2184 void wxWidgetCocoaImpl::SetDropTarget(wxDropTarget* target)
2185 {
2186     [m_osxView unregisterDraggedTypes];
2187
2188     if ( target == NULL )
2189         return;
2190
2191     wxDataObject* dobj = target->GetDataObject();
2192
2193     if( dobj )
2194     {
2195         CFMutableArrayRef typesarray = CFArrayCreateMutable(kCFAllocatorDefault,0,&kCFTypeArrayCallBacks);
2196         dobj->AddSupportedTypes(typesarray);
2197         NSView* targetView = m_osxView;
2198         if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2199             targetView = [(NSScrollView*) m_osxView documentView];
2200
2201         [targetView registerForDraggedTypes:(NSArray*)typesarray];
2202         CFRelease(typesarray);
2203     }
2204 }
2205
2206 void wxWidgetCocoaImpl::RemoveFromParent()
2207 {
2208     [m_osxView removeFromSuperview];
2209 }
2210
2211 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
2212 {
2213     NSView* container = parent->GetWXWidget() ;
2214     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
2215     [container addSubview:m_osxView];
2216
2217     if( m_wxPeer->IsFrozen() )
2218         [[m_osxView window] disableFlushWindow];
2219 }
2220
2221 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
2222 {
2223     NSView* targetView = m_osxView;
2224     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2225         targetView = [(NSScrollView*) m_osxView documentView];
2226
2227     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
2228     {
2229         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2230                                                                 green:(CGFloat) (col.Green() / 255.0)
2231                                                                  blue:(CGFloat) (col.Blue() / 255.0)
2232                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
2233     }
2234 }
2235
2236 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
2237 {
2238     BOOL opaque = ( style == wxBG_STYLE_PAINT );
2239
2240     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
2241     {
2242         [m_osxView setOpaque: opaque];
2243     }
2244
2245     return true ;
2246 }
2247
2248 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
2249 {
2250     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
2251     {
2252         wxCFStringRef cf( title , encoding );
2253         [m_osxView setTitle:cf.AsNSString()];
2254     }
2255     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
2256     {
2257         wxCFStringRef cf( title , encoding );
2258         [m_osxView setStringValue:cf.AsNSString()];
2259     }
2260 }
2261
2262
2263 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
2264 {
2265     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
2266     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
2267     *pt = wxFromNSPoint( to->GetWXWidget(), p );
2268 }
2269
2270 wxInt32 wxWidgetCocoaImpl::GetValue() const
2271 {
2272     return [(NSControl*)m_osxView intValue];
2273 }
2274
2275 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
2276 {
2277     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
2278     {
2279         [m_osxView setIntValue:v];
2280     }
2281     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
2282     {
2283         [m_osxView setFloatValue:(double)v];
2284     }
2285     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
2286     {
2287         [m_osxView setDoubleValue:(double)v];
2288     }
2289 }
2290
2291 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
2292 {
2293     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
2294     {
2295         [m_osxView setMinValue:(double)v];
2296     }
2297 }
2298
2299 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
2300 {
2301     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
2302     {
2303         [m_osxView setMaxValue:(double)v];
2304     }
2305 }
2306
2307 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
2308 {
2309     if (  [m_osxView respondsToSelector:@selector(minValue)] )
2310     {
2311         return (int)[m_osxView minValue];
2312     }
2313     return 0;
2314 }
2315
2316 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
2317 {
2318     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
2319     {
2320         return (int)[m_osxView maxValue];
2321     }
2322     return 0;
2323 }
2324
2325 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
2326 {
2327     wxBitmap bmp;
2328
2329     // TODO: how to create a wxBitmap from NSImage?
2330 #if 0
2331     if ( [m_osxView respondsToSelector:@selector(image:)] )
2332         bmp = [m_osxView image];
2333 #endif
2334
2335     return bmp;
2336 }
2337
2338 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
2339 {
2340     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
2341     {
2342         if (bitmap.IsOk())
2343             [m_osxView setImage:bitmap.GetNSImage()];
2344         else
2345             [m_osxView setImage:nil];
2346
2347         [m_osxView setNeedsDisplay:YES];
2348     }
2349 }
2350
2351 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
2352 {
2353     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
2354     {
2355         NSCellImagePosition pos;
2356         switch ( dir )
2357         {
2358             case wxLEFT:
2359                 pos = NSImageLeft;
2360                 break;
2361
2362             case wxRIGHT:
2363                 pos = NSImageRight;
2364                 break;
2365
2366             case wxTOP:
2367                 pos = NSImageAbove;
2368                 break;
2369
2370             case wxBOTTOM:
2371                 pos = NSImageBelow;
2372                 break;
2373
2374             default:
2375                 wxFAIL_MSG( "invalid image position" );
2376                 pos = NSNoImage;
2377         }
2378
2379         [m_osxView setImagePosition:pos];
2380     }
2381 }
2382
2383 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
2384 {
2385     // implementation in subclass
2386 }
2387
2388 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
2389 {
2390     r->x = r->y = r->width = r->height = 0;
2391
2392     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
2393     {
2394         NSRect former = [m_osxView frame];
2395         [m_osxView sizeToFit];
2396         NSRect best = [m_osxView frame];
2397         [m_osxView setFrame:former];
2398         r->width = (int)best.size.width;
2399         r->height = (int)best.size.height;
2400     }
2401 }
2402
2403 bool wxWidgetCocoaImpl::IsEnabled() const
2404 {
2405     NSView* targetView = m_osxView;
2406     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2407         targetView = [(NSScrollView*) m_osxView documentView];
2408
2409     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
2410         return [targetView isEnabled];
2411     return true;
2412 }
2413
2414 void wxWidgetCocoaImpl::Enable( bool enable )
2415 {
2416     NSView* targetView = m_osxView;
2417     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2418         targetView = [(NSScrollView*) m_osxView documentView];
2419
2420     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
2421         [targetView setEnabled:enable];
2422 }
2423
2424 void wxWidgetCocoaImpl::PulseGauge()
2425 {
2426 }
2427
2428 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
2429 {
2430 }
2431
2432 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
2433 {
2434     NSControlSize size = NSRegularControlSize;
2435
2436     switch ( variant )
2437     {
2438         case wxWINDOW_VARIANT_NORMAL :
2439             size = NSRegularControlSize;
2440             break ;
2441
2442         case wxWINDOW_VARIANT_SMALL :
2443             size = NSSmallControlSize;
2444             break ;
2445
2446         case wxWINDOW_VARIANT_MINI :
2447             size = NSMiniControlSize;
2448             break ;
2449
2450         case wxWINDOW_VARIANT_LARGE :
2451             size = NSRegularControlSize;
2452             break ;
2453
2454         default:
2455             wxFAIL_MSG(wxT("unexpected window variant"));
2456             break ;
2457     }
2458     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2459         [m_osxView setControlSize:size];
2460     else if ([m_osxView respondsToSelector:@selector(cell)])
2461     {
2462         id cell = [(id)m_osxView cell];
2463         if ([cell respondsToSelector:@selector(setControlSize:)])
2464             [cell setControlSize:size];
2465     }
2466
2467     // we need to propagate this to inner views as well
2468     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2469     {
2470         NSView* targetView = [(NSScrollView*) m_osxView documentView];
2471
2472         if ( [targetView respondsToSelector:@selector(setControlSize:)] )
2473             [targetView setControlSize:size];
2474         else if ([targetView respondsToSelector:@selector(cell)])
2475         {
2476             id cell = [(id)targetView cell];
2477             if ([cell respondsToSelector:@selector(setControlSize:)])
2478                 [cell setControlSize:size];
2479         }
2480     }
2481 }
2482
2483 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2484 {
2485     NSView* targetView = m_osxView;
2486     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2487         targetView = [(NSScrollView*) m_osxView documentView];
2488
2489     if ([targetView respondsToSelector:@selector(setFont:)])
2490         [targetView setFont: font.OSXGetNSFont()];
2491     if ([targetView respondsToSelector:@selector(setTextColor:)])
2492         [targetView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2493                                                                  green:(CGFloat) (col.Green() / 255.0)
2494                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2495                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2496 }
2497
2498 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2499 {
2500     if ( tooltip )
2501     {
2502         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2503         [m_osxView setToolTip: cf.AsNSString()];
2504     }
2505     else
2506     {
2507         [m_osxView setToolTip:nil];
2508     }
2509 }
2510
2511 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2512 {
2513     WXWidget c =  control ? control : (WXWidget) m_osxView;
2514     wxWidgetImpl::Associate( c, this ) ;
2515     if ([c respondsToSelector:@selector(setAction:)])
2516     {
2517         [c setTarget: c];
2518         [c setAction: @selector(controlAction:)];
2519         if ([c respondsToSelector:@selector(setDoubleAction:)])
2520         {
2521             [c setDoubleAction: @selector(controlDoubleAction:)];
2522         }
2523
2524     }
2525     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingCursorUpdate|NSTrackingMouseMoved|NSTrackingActiveAlways|NSTrackingInVisibleRect;
2526     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: NSZeroRect options: options owner: m_osxView userInfo: nil];
2527     [m_osxView addTrackingArea: area];
2528     [area release];
2529  }
2530
2531 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2532 {
2533     wxKeyEvent wxevent(wxEVT_CHAR);
2534     SetupKeyEvent( wxevent, event, text );
2535
2536     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2537 }
2538
2539 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2540 {
2541     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2542     SetupKeyEvent( wxevent, event );
2543
2544     // Generate wxEVT_CHAR_HOOK before sending any other events but only when
2545     // the key is pressed, not when it's released (the type of wxevent is
2546     // changed by SetupKeyEvent() so it can be wxEVT_KEY_UP too by now).
2547     if ( wxevent.GetEventType() == wxEVT_KEY_DOWN )
2548     {
2549         wxKeyEvent eventHook(wxEVT_CHAR_HOOK, wxevent);
2550         if ( GetWXPeer()->OSXHandleKeyEvent(eventHook)
2551                 && !eventHook.IsNextEventAllowed() )
2552             return true;
2553     }
2554
2555     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2556
2557     // this will fire higher level events, like insertText, to help
2558     // us handle EVT_CHAR, etc.
2559
2560     if ( !result )
2561     {
2562         if ( [event type] == NSKeyDown)
2563         {
2564             long keycode = wxOSXTranslateCocoaKey( event, wxEVT_CHAR );
2565
2566             if ( (keycode > 0 && keycode < WXK_SPACE) || keycode == WXK_DELETE || keycode >= WXK_START )
2567             {
2568                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2569                 wxKeyEvent wxevent2(wxevent) ;
2570                 wxevent2.SetEventType(wxEVT_CHAR);
2571                 SetupKeyEvent( wxevent2, event );
2572                 wxevent2.m_keyCode = keycode;
2573                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2574             }
2575             else if (wxevent.CmdDown())
2576             {
2577                 wxKeyEvent wxevent2(wxevent) ;
2578                 wxevent2.SetEventType(wxEVT_CHAR);
2579                 SetupKeyEvent( wxevent2, event );
2580                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2581             }
2582             else
2583             {
2584                 if ( IsUserPane() && !wxevent.CmdDown() )
2585                 {
2586                     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2587                         [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2588                     else
2589                         [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2590                     result = true;
2591                 }
2592             }
2593         }
2594     }
2595
2596     return result;
2597 }
2598
2599 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2600 {
2601     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2602     SetupMouseEvent(wxevent , event) ;
2603     bool result = GetWXPeer()->HandleWindowEvent(wxevent);
2604
2605     (void)SetupCursor(event);
2606
2607     return result;
2608 }
2609
2610 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2611 {
2612     wxWindow* thisWindow = GetWXPeer();
2613     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2614     {
2615         thisWindow->MacInvalidateBorders();
2616     }
2617
2618     if ( receivedFocus )
2619     {
2620         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2621         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2622         thisWindow->HandleWindowEvent(eventFocus);
2623
2624 #if wxUSE_CARET
2625         if ( thisWindow->GetCaret() )
2626             thisWindow->GetCaret()->OnSetFocus();
2627 #endif
2628
2629         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2630         event.SetEventObject(thisWindow);
2631         if (otherWindow)
2632             event.SetWindow(otherWindow->GetWXPeer());
2633         thisWindow->HandleWindowEvent(event) ;
2634     }
2635     else // !receivedFocus
2636     {
2637 #if wxUSE_CARET
2638         if ( thisWindow->GetCaret() )
2639             thisWindow->GetCaret()->OnKillFocus();
2640 #endif
2641
2642         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2643
2644         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2645         event.SetEventObject(thisWindow);
2646         if (otherWindow)
2647             event.SetWindow(otherWindow->GetWXPeer());
2648         thisWindow->HandleWindowEvent(event) ;
2649     }
2650 }
2651
2652 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2653 {
2654     if ( !wxIsBusy() )
2655     {
2656         NSPoint location = [NSEvent mouseLocation];
2657         location = [[m_osxView window] convertScreenToBase:location];
2658         NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2659
2660         if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2661         {
2662             [(NSCursor*)cursor.GetHCURSOR() set];
2663         }
2664     }
2665 }
2666
2667 void wxWidgetCocoaImpl::CaptureMouse()
2668 {
2669     // TODO remove if we don't get into problems with cursor settings
2670     //    [[m_osxView window] disableCursorRects];
2671 }
2672
2673 void wxWidgetCocoaImpl::ReleaseMouse()
2674 {
2675     // TODO remove if we don't get into problems with cursor settings
2676     //    [[m_osxView window] enableCursorRects];
2677 }
2678
2679 #if !wxOSX_USE_NATIVE_FLIPPED
2680
2681 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2682 {
2683     m_isFlipped = flipped;
2684 }
2685
2686 #endif
2687
2688 void wxWidgetCocoaImpl::SetDrawingEnabled(bool enabled)
2689 {
2690     if ( enabled )
2691     {
2692         [[m_osxView window] enableFlushWindow];
2693         [m_osxView setNeedsDisplay:YES];
2694     }
2695     else
2696     {
2697         [[m_osxView window] disableFlushWindow];
2698     }
2699 }
2700 //
2701 // Factory methods
2702 //
2703
2704 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2705     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2706     long WXUNUSED(style), long WXUNUSED(extraStyle))
2707 {
2708     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2709     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2710
2711     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v, false, true );
2712     return c;
2713 }
2714
2715 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2716 {
2717     NSWindow* tlw = now->GetWXWindow();
2718
2719     wxWidgetCocoaImpl* c = NULL;
2720     if ( now->IsNativeWindowWrapper() )
2721     {
2722         NSView* cv = [tlw contentView];
2723         c = new wxWidgetCocoaImpl( now, cv, true );
2724         if ( cv != nil )
2725         {
2726             // increase ref count, because the impl destructor will decrement it again
2727             CFRetain(cv);
2728             if ( !now->IsShown() )
2729                 [cv setHidden:NO];
2730         }
2731     }
2732     else
2733     {
2734         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2735         c = new wxWidgetCocoaImpl( now, v, true );
2736         c->InstallEventHandler();
2737         [tlw setContentView:v];
2738     }
2739     return c;
2740 }