src/osx/cocoa/textctrl.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/textctrl.mm
   3 // Purpose:     wxTextCtrl
   4 // Author:      Stefan Csomor
   5 // Modified by: Ryan Norton (MLTE GetLineLength and GetLineText)
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: textctrl.cpp 54820 2008-07-29 20:04:11Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_TEXTCTRL
  15
  16 #include "wx/textctrl.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/intl.h"
  20     #include "wx/app.h"
  21     #include "wx/utils.h"
  22     #include "wx/dc.h"
  23     #include "wx/button.h"
  24     #include "wx/menu.h"
  25     #include "wx/settings.h"
  26     #include "wx/msgdlg.h"
  27     #include "wx/toplevel.h"
  28 #endif
  29
  30 #ifdef __DARWIN__
  31     #include <sys/types.h>
  32     #include <sys/stat.h>
  33 #else
  34     #include <stat.h>
  35 #endif
  36
  37 #if wxUSE_STD_IOSTREAM
  38     #if wxUSE_IOSTREAMH
  39         #include <fstream.h>
  40     #else
  41         #include <fstream>
  42     #endif
  43 #endif
  44
  45 #include "wx/filefn.h"
  46 #include "wx/sysopt.h"
  47 #include "wx/thread.h"
  48
  49 #include "wx/osx/private.h"
  50 #include "wx/osx/cocoa/private/textimpl.h"
  51
  52 @interface NSView(EditableView)
  53 - (BOOL)isEditable;
  54 - (void)setEditable:(BOOL)flag;
  55 - (BOOL)isSelectable;
  56 - (void)setSelectable:(BOOL)flag;
  57 @end
  58
  59 class wxMacEditHelper
  60 {
  61 public :
  62     wxMacEditHelper( NSView* textView )
  63     {
  64         m_textView = textView;
  65         m_formerEditable = YES;
  66         if ( textView )
  67         {
  68             m_formerEditable = [textView isEditable];
  69             m_formerSelectable = [textView isSelectable];
  70             [textView setEditable:YES];
  71         }
  72     }
  73
  74     ~wxMacEditHelper()
  75     {
  76         if ( m_textView )
  77         {
  78             [m_textView setEditable:m_formerEditable];
  79             [m_textView setSelectable:m_formerSelectable];
  80         }
  81     }
  82
  83 protected :
  84     BOOL m_formerEditable ;
  85     BOOL m_formerSelectable;
  86     NSView* m_textView;
  87 } ;
  88
  89 @implementation wxNSSecureTextField
  90
  91 + (void)initialize
  92 {
  93     static BOOL initialized = NO;
  94     if (!initialized)
  95     {
  96         initialized = YES;
  97         wxOSXCocoaClassAddWXMethods( self );
  98     }
  99 }
 100
 101 - (void)controlTextDidChange:(NSNotification *)aNotification
 102 {
 103     wxUnusedVar(aNotification);
 104     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 105     if ( impl )
 106         impl->controlTextDidChange();
 107 }
 108
 109 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 110 {
 111     wxUnusedVar(aNotification);
 112     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 113     if ( impl )
 114     {
 115         impl->DoNotifyFocusEvent( false, NULL );
 116     }
 117 }
 118
 119 @end
 120
 121 @interface wxNSTextScrollView : NSScrollView
 122 {
 123 }
 124 @end
 125
 126 @implementation wxNSTextScrollView
 127
 128 + (void)initialize
 129 {
 130     static BOOL initialized = NO;
 131     if (!initialized)
 132     {
 133         initialized = YES;
 134         wxOSXCocoaClassAddWXMethods( self );
 135     }
 136 }
 137
 138 @end
 139
 140 @implementation wxNSTextFieldEditor
 141
 142 - (void) keyDown:(NSEvent*) event
 143 {
 144     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 145     lastKeyDownEvent = event;
 146     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 147         [super keyDown:event];
 148     lastKeyDownEvent = nil;
 149 }
 150
 151 - (void) keyUp:(NSEvent*) event
 152 {
 153     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 154     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 155         [super keyUp:event];
 156 }
 157
 158 - (void) flagsChanged:(NSEvent*) event
 159 {
 160     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 161     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 162         [super flagsChanged:event];
 163 }
 164
 165 - (BOOL) performKeyEquivalent:(NSEvent*) event
 166 {
 167     BOOL retval = [super performKeyEquivalent:event];
 168     return retval;
 169 }
 170
 171 - (void) insertText:(id) str
 172 {
 173     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 174     if ( impl == NULL || lastKeyDownEvent==nil || !impl->DoHandleCharEvent(lastKeyDownEvent, str) )
 175     {
 176         [super insertText:str];
 177     }
 178 }
 179
 180 @end
 181
 182 @implementation wxNSTextView
 183
 184 + (void)initialize
 185 {
 186     static BOOL initialized = NO;
 187     if (!initialized)
 188     {
 189         initialized = YES;
 190         wxOSXCocoaClassAddWXMethods( self );
 191     }
 192 }
 193
 194 - (void)textDidChange:(NSNotification *)aNotification
 195 {
 196     wxUnusedVar(aNotification);
 197     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 198     if ( impl )
 199         impl->controlTextDidChange();
 200 }
 201
 202 - (void) setEnabled:(BOOL) flag
 203 {
 204     // from Technical Q&A QA1461
 205     if (flag) {
 206         [self setTextColor: [NSColor controlTextColor]];
 207
 208     } else {
 209         [self setTextColor: [NSColor disabledControlTextColor]];
 210     }
 211
 212     [self setSelectable: flag];
 213     [self setEditable: flag];
 214 }
 215
 216 - (BOOL) isEnabled
 217 {
 218     return [self isEditable];
 219 }
 220
 221 - (void)textDidEndEditing:(NSNotification *)aNotification
 222 {
 223     wxUnusedVar(aNotification);
 224     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 225     if ( impl )
 226     {
 227         impl->DoNotifyFocusEvent( false, NULL );
 228     }
 229 }
 230
 231 @end
 232
 233 @implementation wxNSTextField
 234
 235 + (void)initialize
 236 {
 237     static BOOL initialized = NO;
 238     if (!initialized)
 239     {
 240         initialized = YES;
 241         wxOSXCocoaClassAddWXMethods( self );
 242     }
 243 }
 244
 245 - (id) initWithFrame:(NSRect) frame
 246 {
 247     self = [super initWithFrame:frame];
 248     fieldEditor = nil;
 249     return self;
 250 }
 251
 252 - (void) dealloc
 253 {
 254     [fieldEditor release];
 255     [super dealloc];
 256 }
 257
 258 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
 259 {
 260     fieldEditor = editor;
 261 }
 262
 263 - (wxNSTextFieldEditor*) fieldEditor
 264 {
 265     return fieldEditor;
 266 }
 267
 268 - (void) setEnabled:(BOOL) flag
 269 {
 270     [super setEnabled: flag];
 271
 272     if (![self drawsBackground]) {
 273         // Static text is drawn incorrectly when disabled.
 274         // For an explanation, see
 275         // http://www.cocoabuilder.com/archive/message/cocoa/2006/7/21/168028
 276         if (flag) {
 277             [self setTextColor: [NSColor controlTextColor]];
 278         } else {
 279             [self setTextColor: [NSColor secondarySelectedControlColor]];
 280         }
 281     }
 282 }
 283
 284 - (void)controlTextDidChange:(NSNotification *)aNotification
 285 {
 286     wxUnusedVar(aNotification);
 287     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 288     if ( impl )
 289         impl->controlTextDidChange();
 290 }
 291
 292 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 293 {
 294     wxUnusedVar(textView);
 295     wxUnusedVar(control);
 296
 297     BOOL handled = NO;
 298
 299     // send back key events wx' common code knows how to handle
 300
 301     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 302     if ( impl  )
 303     {
 304         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 305         if ( wxpeer )
 306         {
 307             if (commandSelector == @selector(insertNewline:))
 308             {
 309                 [textView insertNewlineIgnoringFieldEditor:self];
 310                 handled = YES;
 311             }
 312             else if ( commandSelector == @selector(insertTab:))
 313             {
 314                 [textView insertTabIgnoringFieldEditor:self];
 315                 handled = YES;
 316             }
 317             else if ( commandSelector == @selector(insertBacktab:))
 318             {
 319                 [textView insertTabIgnoringFieldEditor:self];
 320                 handled = YES;
 321             }
 322         }
 323     }
 324
 325     return handled;
 326 }
 327
 328 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 329 {
 330     wxUnusedVar(aNotification);
 331     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 332     if ( impl )
 333     {
 334         impl->DoNotifyFocusEvent( false, NULL );
 335     }
 336 }
 337 @end
 338
 339 // wxNSTextViewControl
 340
 341 wxNSTextViewControl::wxNSTextViewControl( wxTextCtrl *wxPeer, WXWidget w )
 342     : wxWidgetCocoaImpl(wxPeer, w),
 343       wxTextWidgetImpl(wxPeer)
 344 {
 345     wxNSTextScrollView* sv = (wxNSTextScrollView*) w;
 346     m_scrollView = sv;
 347
 348     [m_scrollView setHasVerticalScroller:YES];
 349     [m_scrollView setHasHorizontalScroller:NO];
 350     [m_scrollView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
 351     NSSize contentSize = [m_scrollView contentSize];
 352
 353     wxNSTextView* tv = [[wxNSTextView alloc] initWithFrame: NSMakeRect(0, 0,
 354             contentSize.width, contentSize.height)];
 355     m_textView = tv;
 356     [tv setVerticallyResizable:YES];
 357     [tv setHorizontallyResizable:NO];
 358     [tv setAutoresizingMask:NSViewWidthSizable];
 359
 360     [m_scrollView setDocumentView: tv];
 361
 362     [tv setDelegate: tv];
 363
 364     InstallEventHandler(tv);
 365 }
 366
 367 wxNSTextViewControl::~wxNSTextViewControl()
 368 {
 369     if (m_textView)
 370         [m_textView setDelegate: nil];
 371 }
 372
 373 bool wxNSTextViewControl::CanFocus() const
 374 {
 375     // since this doesn't work (return false), we hardcode
 376     // if (m_textView)
 377     //    return [m_textView canBecomeKeyView];
 378     return true;
 379 }
 380
 381 wxString wxNSTextViewControl::GetStringValue() const
 382 {
 383     if (m_textView)
 384     {
 385         wxString result = wxCFStringRef::AsString([m_textView string], m_wxPeer->GetFont().GetEncoding());
 386         wxMacConvertNewlines13To10( &result ) ;
 387         return result;
 388     }
 389     return wxEmptyString;
 390 }
 391 void wxNSTextViewControl::SetStringValue( const wxString &str)
 392 {
 393     wxString st = str;
 394     wxMacConvertNewlines10To13( &st );
 395     wxMacEditHelper helper(m_textView);
 396
 397     if (m_textView)
 398         [m_textView setString: wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 399 }
 400
 401 void wxNSTextViewControl::Copy()
 402 {
 403     if (m_textView)
 404         [m_textView copy:nil];
 405
 406 }
 407
 408 void wxNSTextViewControl::Cut()
 409 {
 410     if (m_textView)
 411         [m_textView cut:nil];
 412 }
 413
 414 void wxNSTextViewControl::Paste()
 415 {
 416     if (m_textView)
 417         [m_textView paste:nil];
 418 }
 419
 420 bool wxNSTextViewControl::CanPaste() const
 421 {
 422     return true;
 423 }
 424
 425 void wxNSTextViewControl::SetEditable(bool editable)
 426 {
 427     if (m_textView)
 428         [m_textView setEditable: editable];
 429 }
 430
 431 void wxNSTextViewControl::GetSelection( long* from, long* to) const
 432 {
 433     if (m_textView)
 434     {
 435         NSRange range = [m_textView selectedRange];
 436         *from = range.location;
 437         *to = range.location + range.length;
 438     }
 439 }
 440
 441 void wxNSTextViewControl::SetSelection( long from , long to )
 442 {
 443     long textLength = [[m_textView string] length];
 444     if ((from == -1) && (to == -1))
 445     {
 446         from = 0 ;
 447         to = textLength ;
 448     }
 449     else
 450     {
 451         from = wxMin(textLength,wxMax(from,0)) ;
 452         if ( to == -1 )
 453             to = textLength;
 454         else
 455             to = wxMax(0,wxMin(textLength,to)) ;
 456     }
 457
 458     NSRange selrange = NSMakeRange(from, to-from);
 459     [m_textView setSelectedRange:selrange];
 460     [m_textView scrollRangeToVisible:selrange];
 461 }
 462
 463 void wxNSTextViewControl::WriteText(const wxString& str)
 464 {
 465     wxString st = str;
 466     wxMacConvertNewlines10To13( &st );
 467     wxMacEditHelper helper(m_textView);
 468     NSEvent* formerEvent = m_lastKeyDownEvent;
 469     m_lastKeyDownEvent = nil;
 470     [m_textView insertText:wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 471     m_lastKeyDownEvent = formerEvent;
 472 }
 473
 474 void wxNSTextViewControl::SetFont( const wxFont & font , const wxColour& WXUNUSED(foreground) , long WXUNUSED(windowStyle), bool WXUNUSED(ignoreBlack) )
 475 {
 476     if ([m_textView respondsToSelector:@selector(setFont:)])
 477         [m_textView setFont: font.OSXGetNSFont()];
 478 }
 479
 480 bool wxNSTextViewControl::GetStyle(long position, wxTextAttr& style)
 481 {
 482     if (m_textView && position >=0)
 483     {
 484         NSFont* font = NULL;
 485         NSColor* bgcolor = NULL;
 486         NSColor* fgcolor = NULL;
 487         // NOTE: It appears that other platforms accept GetStyle with the position == length
 488         // but that NSTextStorage does not accept length as a valid position.
 489         // Therefore we return the default control style in that case.
 490         if (position < (long) [[m_textView string] length])
 491         {
 492             NSTextStorage* storage = [m_textView textStorage];
 493             font = [[storage attribute:NSFontAttributeName atIndex:position effectiveRange:NULL] autorelease];
 494             bgcolor = [[storage attribute:NSBackgroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 495             fgcolor = [[storage attribute:NSForegroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 496         }
 497         else
 498         {
 499             NSDictionary* attrs = [m_textView typingAttributes];
 500             font = [[attrs objectForKey:NSFontAttributeName] autorelease];
 501             bgcolor = [[attrs objectForKey:NSBackgroundColorAttributeName] autorelease];
 502             fgcolor = [[attrs objectForKey:NSForegroundColorAttributeName] autorelease];
 503         }
 504
 505         if (font)
 506             style.SetFont(wxFont(font));
 507
 508         if (bgcolor)
 509             style.SetBackgroundColour(wxColour(bgcolor));
 510
 511         if (fgcolor)
 512             style.SetTextColour(wxColour(fgcolor));
 513         return true;
 514     }
 515
 516     return false;
 517 }
 518
 519 void wxNSTextViewControl::SetStyle(long start,
 520                                 long end,
 521                                 const wxTextAttr& style)
 522 {
 523     if (m_textView) {
 524         NSRange range = NSMakeRange(start, end-start);
 525         if (start == -1 && end == -1)
 526             range = [m_textView selectedRange];
 527
 528         NSTextStorage* storage = [m_textView textStorage];
 529
 530         wxFont font = style.GetFont();
 531         if (style.HasFont() && font.IsOk())
 532             [storage addAttribute:NSFontAttributeName value:font.OSXGetNSFont() range:range];
 533
 534         wxColour bgcolor = style.GetBackgroundColour();
 535         if (style.HasBackgroundColour() && bgcolor.IsOk())
 536             [storage addAttribute:NSBackgroundColorAttributeName value:bgcolor.OSXGetNSColor() range:range];
 537
 538         wxColour fgcolor = style.GetTextColour();
 539         if (style.HasTextColour() && fgcolor.IsOk())
 540             [storage addAttribute:NSForegroundColorAttributeName value:fgcolor.OSXGetNSColor() range:range];
 541     }
 542 }
 543
 544 void wxNSTextViewControl::CheckSpelling(bool check)
 545 {
 546     if (m_textView)
 547         [m_textView setContinuousSpellCheckingEnabled: check];
 548 }
 549
 550 wxSize wxNSTextViewControl::GetBestSize() const
 551 {
 552     if (m_textView && [m_textView layoutManager])
 553     {
 554         NSRect rect = [[m_textView layoutManager] usedRectForTextContainer: [m_textView textContainer]];
 555         return wxSize((int)(rect.size.width + [m_textView textContainerInset].width),
 556                       (int)(rect.size.height + [m_textView textContainerInset].height));
 557     }
 558     return wxSize(0,0);
 559 }
 560
 561 // wxNSTextFieldControl
 562
 563 wxNSTextFieldControl::wxNSTextFieldControl( wxTextCtrl *text, WXWidget w )
 564     : wxWidgetCocoaImpl(text, w),
 565       wxTextWidgetImpl(text)
 566 {
 567     Init(w);
 568 }
 569
 570 wxNSTextFieldControl::wxNSTextFieldControl(wxWindow *wxPeer,
 571                                            wxTextEntry *entry,
 572                                            WXWidget w)
 573     : wxWidgetCocoaImpl(wxPeer, w),
 574       wxTextWidgetImpl(entry)
 575 {
 576     Init(w);
 577 }
 578
 579 void wxNSTextFieldControl::Init(WXWidget w)
 580 {
 581     NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>) *tf = (NSTextField*) w;
 582     m_textField = tf;
 583     [m_textField setDelegate: tf];
 584     m_selStart = m_selEnd = 0;
 585     m_hasEditor = [w isKindOfClass:[NSTextField class]];
 586 }
 587
 588 wxNSTextFieldControl::~wxNSTextFieldControl()
 589 {
 590     if (m_textField)
 591         [m_textField setDelegate: nil];
 592 }
 593
 594 wxString wxNSTextFieldControl::GetStringValue() const
 595 {
 596     return wxCFStringRef::AsString([m_textField stringValue], m_wxPeer->GetFont().GetEncoding());
 597 }
 598
 599 void wxNSTextFieldControl::SetStringValue( const wxString &str)
 600 {
 601     wxMacEditHelper helper(m_textField);
 602     [m_textField setStringValue: wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 603 }
 604
 605 void wxNSTextFieldControl::Copy()
 606 {
 607     NSText* editor = [m_textField currentEditor];
 608     if ( editor )
 609     {
 610         [editor copy:nil];
 611     }
 612 }
 613
 614 void wxNSTextFieldControl::Cut()
 615 {
 616     NSText* editor = [m_textField currentEditor];
 617     if ( editor )
 618     {
 619         [editor cut:nil];
 620     }
 621 }
 622
 623 void wxNSTextFieldControl::Paste()
 624 {
 625     NSText* editor = [m_textField currentEditor];
 626     if ( editor )
 627     {
 628         [editor paste:nil];
 629     }
 630 }
 631
 632 bool wxNSTextFieldControl::CanPaste() const
 633 {
 634     return true;
 635 }
 636
 637 void wxNSTextFieldControl::SetEditable(bool editable)
 638 {
 639     [m_textField setEditable:editable];
 640 }
 641
 642 void wxNSTextFieldControl::GetSelection( long* from, long* to) const
 643 {
 644     NSText* editor = [m_textField currentEditor];
 645     if ( editor )
 646     {
 647         NSRange range = [editor selectedRange];
 648         *from = range.location;
 649         *to = range.location + range.length;
 650     }
 651     else
 652     {
 653         *from = m_selStart;
 654         *to = m_selEnd;
 655     }
 656 }
 657
 658 void wxNSTextFieldControl::SetSelection( long from , long to )
 659 {
 660     long textLength = [[m_textField stringValue] length];
 661     if ((from == -1) && (to == -1))
 662     {
 663         from = 0 ;
 664         to = textLength ;
 665     }
 666     else
 667     {
 668         from = wxMin(textLength,wxMax(from,0)) ;
 669         if ( to == -1 )
 670             to = textLength;
 671         else
 672             to = wxMax(0,wxMin(textLength,to)) ;
 673     }
 674
 675     NSText* editor = [m_textField currentEditor];
 676     if ( editor )
 677     {
 678         [editor setSelectedRange:NSMakeRange(from, to-from)];
 679     }
 680     else
 681     {
 682         m_selStart = from;
 683         m_selEnd = to;
 684     }
 685 }
 686
 687 void wxNSTextFieldControl::WriteText(const wxString& str)
 688 {
 689     NSEvent* formerEvent = m_lastKeyDownEvent;
 690     m_lastKeyDownEvent = nil;
 691     NSText* editor = [m_textField currentEditor];
 692     if ( editor )
 693     {
 694         wxMacEditHelper helper(m_textField);
 695         [editor insertText:wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 696     }
 697     else
 698     {
 699         wxString val = GetStringValue() ;
 700         long start , end ;
 701         GetSelection( &start , &end ) ;
 702         val.Remove( start , end - start ) ;
 703         val.insert( start , str ) ;
 704         SetStringValue( val ) ;
 705         SetSelection( start + str.length() , start + str.length() ) ;
 706     }
 707     m_lastKeyDownEvent = formerEvent;
 708 }
 709
 710 void wxNSTextFieldControl::controlAction(WXWidget WXUNUSED(slf),
 711     void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 712 {
 713     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
 714     if ( wxpeer && (wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER) )
 715     {
 716         wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 717         event.SetEventObject( wxpeer );
 718         event.SetString( GetTextEntry()->GetValue() );
 719         wxpeer->HandleWindowEvent( event );
 720     }
 721 }
 722
 723 bool wxNSTextFieldControl::SetHint(const wxString& hint)
 724 {
 725     wxCFStringRef hintstring(hint);
 726     [[m_textField cell] setPlaceholderString:hintstring.AsNSString()];
 727     return true;
 728 }
 729
 730 //
 731 //
 732 //
 733
 734 wxWidgetImplType* wxWidgetImpl::CreateTextControl( wxTextCtrl* wxpeer,
 735                                     wxWindowMac* WXUNUSED(parent),
 736                                     wxWindowID WXUNUSED(id),
 737                                     const wxString& WXUNUSED(str),
 738                                     const wxPoint& pos,
 739                                     const wxSize& size,
 740                                     long style,
 741                                     long WXUNUSED(extraStyle))
 742 {
 743     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 744     wxWidgetCocoaImpl* c = NULL;
 745
 746     if ( style & wxTE_MULTILINE || style & wxTE_RICH || style & wxTE_RICH2 )
 747     {
 748         wxNSTextScrollView* v = nil;
 749         v = [[wxNSTextScrollView alloc] initWithFrame:r];
 750         c = new wxNSTextViewControl( wxpeer, v );
 751     }
 752     else
 753     {
 754         NSTextField* v = nil;
 755         if ( style & wxTE_PASSWORD )
 756             v = [[wxNSSecureTextField alloc] initWithFrame:r];
 757         else
 758             v = [[wxNSTextField alloc] initWithFrame:r];
 759
 760         if ( style & wxNO_BORDER )
 761         {
 762             // FIXME: How can we remove the native control's border?
 763             // setBordered is separate from the text ctrl's border.
 764         }
 765
 766         NSTextFieldCell* cell = [v cell];
 767         [cell setScrollable:YES];
 768         // TODO: Remove if we definitely are sure, it's not needed
 769         // as setting scrolling to yes, should turn off any wrapping
 770         // [cell setLineBreakMode:NSLineBreakByClipping];
 771
 772         [v setBezeled:NO];
 773         [v setBordered:NO];
 774
 775         c = new wxNSTextFieldControl( wxpeer, wxpeer, v );
 776     }
 777     c->SetNeedsFocusRect( true );
 778
 779     return c;
 780 }
 781
 782
 783 #endif // wxUSE_TEXTCTRL