acinclude.m4

   1 dnl ---------------------------------------------------------------------------
   2 dnl
   3 dnl Macros for configure.in for wxWindows by Robert Roebling, Phil Blecker,
   4 dnl Vadim Zeitlin and Ron Lee
   5 dnl
   6 dnl This script is under the wxWindows licence.
   7 dnl
   8 dnl Version: $Id$
   9 dnl ---------------------------------------------------------------------------
  10
  11
  12 dnl ===========================================================================
  13 dnl Objective-C(++) related macros
  14 dnl ===========================================================================
  15 m4_define([AC_WX_LANG_OBJECTIVEC],
  16 [AC_LANG(C)
  17 ac_ext=m
  18 ])
  19
  20 m4_define([AC_WX_LANG_OBJECTIVECPLUSPLUS],
  21 [AC_LANG(C++)
  22 ac_ext=mm
  23 ])
  24
  25 dnl ===========================================================================
  26 dnl macros to find the a file in the list of include/lib paths
  27 dnl ===========================================================================
  28
  29 dnl ---------------------------------------------------------------------------
  30 dnl call WX_PATH_FIND_INCLUDES(search path, header name), sets ac_find_includes
  31 dnl to the full name of the file that was found or leaves it empty if not found
  32 dnl ---------------------------------------------------------------------------
  33 AC_DEFUN([WX_PATH_FIND_INCLUDES],
  34 [
  35 ac_find_includes=
  36 for ac_dir in $1 /usr/include;
  37   do
  38     if test -f "$ac_dir/$2"; then
  39       ac_find_includes=$ac_dir
  40       break
  41     fi
  42   done
  43 ])
  44
  45 dnl ---------------------------------------------------------------------------
  46 dnl call WX_PATH_FIND_LIBRARIES(search path, lib name), sets ac_find_libraries
  47 dnl to the full name of the file that was found or leaves it empty if not found
  48 dnl ---------------------------------------------------------------------------
  49 AC_DEFUN([WX_PATH_FIND_LIBRARIES],
  50 [
  51   ac_find_libraries=
  52   for ac_dir in $1;
  53   do
  54     for ac_extension in a so sl dylib dll.a; do
  55       if test -f "$ac_dir/lib$2.$ac_extension"; then
  56         ac_find_libraries=$ac_dir
  57         break 2
  58       fi
  59     done
  60   done
  61 ])
  62
  63 dnl ---------------------------------------------------------------------------
  64 dnl return list of standard library paths
  65 dnl ---------------------------------------------------------------------------
  66 dnl return all default locations:
  67 dnl   - /usr/lib: standard
  68 dnl   - /usr/lib32: n32 ABI on IRIX
  69 dnl   - /usr/lib64: n64 ABI on IRIX
  70 dnl   - /usr/lib/64: 64 bit ABI on Solaris and Linux x86-64
  71 dnl
  72 dnl NB: if any of directories in the list is not a subdir of /usr, code setting
  73 dnl     wx_cv_std_libpath needs to be updated
  74 AC_DEFUN([WX_STD_LIBPATH], [/usr/lib /usr/lib32 /usr/lib/64 /usr/lib64])
  75
  76 dnl ---------------------------------------------------------------------------
  77 dnl Path to include, already defined
  78 dnl ---------------------------------------------------------------------------
  79 AC_DEFUN([WX_INCLUDE_PATH_EXIST],
  80 [
  81   dnl never add -I/usr/include to the CPPFLAGS
  82   if test "x$1" = "x/usr/include"; then
  83     ac_path_to_include=""
  84   else
  85     echo "$2" | grep "\-I$1" > /dev/null
  86     result=$?
  87     if test $result = 0; then
  88       ac_path_to_include=""
  89     else
  90       ac_path_to_include=" -I$1"
  91     fi
  92   fi
  93 ])
  94
  95 dnl ---------------------------------------------------------------------------
  96 dnl Usage: WX_LINK_PATH_EXIST(path, libpath)
  97 dnl
  98 dnl Set ac_path_to_link to nothing if path is already in libpath of to -Lpath
  99 dnl if it is not, so that libpath can be set to "$libpath$ac_path_to_link"
 100 dnl after calling this function
 101 dnl ---------------------------------------------------------------------------
 102 AC_DEFUN([WX_LINK_PATH_EXIST],
 103 [
 104   dnl never add -L/usr/libXXX explicitely to libpath
 105   if test "$1" = "default location"; then
 106     ac_path_to_link=""
 107   else
 108     echo "$2" | grep "\-L$1" > /dev/null
 109     result=$?
 110     if test $result = 0; then
 111       ac_path_to_link=""
 112     else
 113       ac_path_to_link=" -L$1"
 114     fi
 115   fi
 116 ])
 117
 118 dnl ===========================================================================
 119 dnl C++ features test
 120 dnl ===========================================================================
 121
 122 dnl ---------------------------------------------------------------------------
 123 dnl WX_CPP_NEW_HEADERS checks whether the compiler has "new" <iostream> header
 124 dnl or only the old <iostream.h> one - it may be generally assumed that if
 125 dnl <iostream> exists, the other "new" headers (without .h) exist too.
 126 dnl
 127 dnl call WX_CPP_NEW_HEADERS(actiof-if-true, action-if-false)
 128 dnl ---------------------------------------------------------------------------
 129
 130 AC_DEFUN([WX_CPP_NEW_HEADERS],
 131 [
 132     AC_LANG_SAVE
 133     AC_LANG_CPLUSPLUS
 134
 135     AC_CHECK_HEADERS(iostream)
 136
 137     if test "$ac_cv_header_iostream" = "yes" ; then
 138       ifelse([$1], , :, [$1])
 139     else
 140       ifelse([$2], , :, [$2])
 141     fi
 142
 143     AC_LANG_RESTORE
 144 ])
 145
 146 dnl ---------------------------------------------------------------------------
 147 dnl WX_CPP_BOOL checks whether the C++ compiler has a built in bool type
 148 dnl
 149 dnl call WX_CPP_BOOL - will define HAVE_BOOL if the compiler supports bool
 150 dnl ---------------------------------------------------------------------------
 151
 152 AC_DEFUN([WX_CPP_BOOL],
 153 [
 154   AC_CACHE_CHECK([if C++ compiler supports bool], wx_cv_cpp_bool,
 155   [
 156     AC_LANG_SAVE
 157     AC_LANG_CPLUSPLUS
 158
 159     AC_TRY_COMPILE(
 160       [
 161       ],
 162       [
 163         bool b = true;
 164
 165         return 0;
 166       ],
 167       [
 168         wx_cv_cpp_bool=yes
 169       ],
 170       [
 171         wx_cv_cpp_bool=no
 172       ]
 173     )
 174
 175     AC_LANG_RESTORE
 176   ])
 177
 178   if test "$wx_cv_cpp_bool" = "yes"; then
 179     AC_DEFINE(HAVE_BOOL)
 180   fi
 181 ])
 182
 183 dnl ---------------------------------------------------------------------------
 184 dnl WX_CPP_EXPLICIT checks whether the C++ compiler support the explicit
 185 dnl keyword and defines HAVE_EXPLICIT if this is the case
 186 dnl ---------------------------------------------------------------------------
 187
 188 AC_DEFUN([WX_CPP_EXPLICIT],
 189 [
 190   AC_CACHE_CHECK([if C++ compiler supports the explicit keyword],
 191                  wx_cv_explicit,
 192   [
 193     AC_LANG_SAVE
 194     AC_LANG_CPLUSPLUS
 195
 196     dnl do the test in 2 steps: first check that the compiler knows about the
 197     dnl explicit keyword at all and then verify that it really honours it
 198     AC_TRY_COMPILE(
 199       [
 200         class Foo { public: explicit Foo(int) {} };
 201       ],
 202       [
 203         return 0;
 204       ],
 205       [
 206         AC_TRY_COMPILE(
 207             [
 208                 class Foo { public: explicit Foo(int) {} };
 209                 static void TakeFoo(const Foo& foo) { }
 210             ],
 211             [
 212                 TakeFoo(17);
 213                 return 0;
 214             ],
 215             wx_cv_explicit=no,
 216             wx_cv_explicit=yes
 217         )
 218       ],
 219       wx_cv_explicit=no
 220     )
 221
 222     AC_LANG_RESTORE
 223   ])
 224
 225   if test "$wx_cv_explicit" = "yes"; then
 226     AC_DEFINE(HAVE_EXPLICIT)
 227   fi
 228 ])
 229
 230 dnl ---------------------------------------------------------------------------
 231 dnl WX_CHECK_FUNCS(FUNCTIONS...,
 232 dnl                [ACTION-IF-FOUND],
 233 dnl                [ACTION-IF-NOT-FOUND],
 234 dnl                [EXTRA-DEFINES-AND-INCLUDES],
 235 dnl                [EXTRA-TEST-CODE])
 236 dnl
 237 dnl Checks that the functions listed in FUNCTIONS exist in the headers and the
 238 dnl libs. For each function, if it is found then defines 'HAVE_FUNCTION' and
 239 dnl executes ACTION-IF-FOUND, otherwise executes ACTION-IF-NOT-FOUND.
 240 dnl
 241 dnl The code from EXTRA-DEFINES-AND-INCLUDES is inserted into the test before
 242 dnl the default headers are included, and EXTRA-TEST-CODE is inserted into
 243 dnl the main() function after the default test for existence.
 244 dnl
 245 dnl Examples:
 246 dnl   # the simple case
 247 dnl   WX_CHECK_FUNCS(stat)
 248 dnl   # use break to finish the loop early
 249 dnl   WX_CHECK_FUNCS(mkstemp mktemp, break)
 250 dnl   # extra defines
 251 dnl   WX_CHECK_FUNCS(strtok_r, [], [], [#define _RREENTRANT])
 252 dnl   # extra includes
 253 dnl   WX_CHECK_FUNCS(swprintf, [], [], [#include <wchar.h>])
 254 dnl   # checking the signature with extra test code
 255 dnl   WX_CHECK_FUNCS(gettimeofday, [], [], [#include <sys/time.h>]
 256 dnl     [struct timeval tv; struct timezone tz; gettimeofday(&tv, &tz)])
 257 dnl ---------------------------------------------------------------------------
 258
 259 AC_DEFUN([WX_CHECK_FUNCS],
 260 [
 261   for wx_func in $1
 262   do
 263     AC_CACHE_CHECK(
 264       [for $wx_func],
 265       [wx_cv_func_$wx_func],
 266       [
 267         AC_LINK_IFELSE(
 268           [
 269             AC_LANG_PROGRAM(
 270               [
 271                 $4
 272                 AC_INCLUDES_DEFAULT
 273               ],
 274               [
 275                 #ifndef $wx_func
 276                   &$wx_func;
 277                 #endif
 278                 $5
 279               ])
 280           ],
 281           [eval wx_cv_func_$wx_func=yes],
 282           [eval wx_cv_func_$wx_func=no])
 283       ])
 284
 285     if eval test \$wx_cv_func_$wx_func = yes
 286     then
 287       AC_DEFINE_UNQUOTED([HAVE_`echo $wx_func | tr 'a-z' 'A-Z'`])
 288       $2
 289     else
 290       :
 291       $3
 292     fi
 293   done
 294 ])
 295
 296 dnl ---------------------------------------------------------------------------
 297 dnl a slightly better AC_C_BIGENDIAN macro which allows cross-compiling
 298 dnl ---------------------------------------------------------------------------
 299
 300 AC_DEFUN([WX_C_BIGENDIAN],
 301 [AC_CACHE_CHECK([whether byte ordering is bigendian], ac_cv_c_bigendian,
 302 [ac_cv_c_bigendian=unknown
 303 # See if sys/param.h defines the BYTE_ORDER macro.
 304 AC_TRY_COMPILE([#include <sys/types.h>
 305 #include <sys/param.h>], [
 306 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
 307  bogus endian macros
 308 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
 309 AC_TRY_COMPILE([#include <sys/types.h>
 310 #include <sys/param.h>], [
 311 #if BYTE_ORDER != BIG_ENDIAN
 312  not big endian
 313 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
 314 if test $ac_cv_c_bigendian = unknown; then
 315 AC_TRY_RUN([main () {
 316   /* Are we little or big endian?  From Harbison&Steele.  */
 317   union
 318   {
 319     long l;
 320     char c[sizeof (long)];
 321   } u;
 322   u.l = 1;
 323   exit (u.c[sizeof (long) - 1] == 1);
 324 }], [ac_cv_c_bigendian=no], [ac_cv_c_bigendian=yes], [ac_cv_c_bigendian=unknown])
 325 fi])
 326 if test $ac_cv_c_bigendian = unknown; then
 327   AC_MSG_WARN([Assuming little-endian target machine - this may be overriden by adding the line "ac_cv_c_bigendian=${ac_cv_c_bigendian='yes'}" to config.cache file])
 328 fi
 329 if test $ac_cv_c_bigendian = yes; then
 330   AC_DEFINE(WORDS_BIGENDIAN)
 331 fi
 332 ])
 333
 334 dnl ---------------------------------------------------------------------------
 335 dnl override AC_ARG_ENABLE/WITH to cache the results in .cache file
 336 dnl ---------------------------------------------------------------------------
 337
 338 AC_DEFUN([WX_ARG_CACHE_INIT],
 339         [
 340           wx_arg_cache_file="configarg.cache"
 341           echo "loading argument cache $wx_arg_cache_file"
 342           rm -f ${wx_arg_cache_file}.tmp
 343           touch ${wx_arg_cache_file}.tmp
 344           touch ${wx_arg_cache_file}
 345         ])
 346
 347 AC_DEFUN([WX_ARG_CACHE_FLUSH],
 348         [
 349           echo "saving argument cache $wx_arg_cache_file"
 350           mv ${wx_arg_cache_file}.tmp ${wx_arg_cache_file}
 351         ])
 352
 353 dnl this macro checks for a three-valued command line --with argument:
 354 dnl   possible arguments are 'yes', 'no', 'sys', or 'builtin'
 355 dnl usage: WX_ARG_SYS_WITH(option, helpmessage, variable-name)
 356 AC_DEFUN([WX_ARG_SYS_WITH],
 357         [
 358           AC_MSG_CHECKING([for --with-$1])
 359           no_cache=0
 360           AC_ARG_WITH($1, [$2],
 361                       [
 362                         if test "$withval" = yes; then
 363                           ac_cv_use_$1='$3=yes'
 364                         elif test "$withval" = no; then
 365                           ac_cv_use_$1='$3=no'
 366                         elif test "$withval" = sys; then
 367                           ac_cv_use_$1='$3=sys'
 368                         elif test "$withval" = builtin; then
 369                           ac_cv_use_$1='$3=builtin'
 370                         else
 371                           AC_MSG_ERROR([Invalid value for --with-$1: should be yes, no, sys, or builtin])
 372                         fi
 373                       ],
 374                       [
 375                         LINE=`grep "$3" ${wx_arg_cache_file}`
 376                         if test "x$LINE" != x ; then
 377                           eval "DEFAULT_$LINE"
 378                         else
 379                           no_cache=1
 380                         fi
 381
 382                         ac_cv_use_$1='$3='$DEFAULT_$3
 383                       ])
 384
 385           eval "$ac_cv_use_$1"
 386           if test "$no_cache" != 1; then
 387             echo $ac_cv_use_$1 >> ${wx_arg_cache_file}.tmp
 388           fi
 389
 390           if test "$$3" = yes; then
 391             AC_MSG_RESULT(yes)
 392           elif test "$$3" = no; then
 393             AC_MSG_RESULT(no)
 394           elif test "$$3" = sys; then
 395             AC_MSG_RESULT([system version])
 396           elif test "$$3" = builtin; then
 397             AC_MSG_RESULT([builtin version])
 398           else
 399             AC_MSG_ERROR([Invalid value for --with-$1: should be yes, no, sys, or builtin])
 400           fi
 401         ])
 402
 403 dnl this macro checks for a command line argument and caches the result
 404 dnl usage: WX_ARG_WITH(option, helpmessage, variable-name, [withstring])
 405 AC_DEFUN([WX_ARG_WITH],
 406         [
 407           withstring=$4
 408           AC_MSG_CHECKING([for --${withstring:-with}-$1])
 409           no_cache=0
 410           AC_ARG_WITH($1, [$2],
 411                       [
 412                         if test "$withval" = yes; then
 413                           ac_cv_use_$1='$3=yes'
 414                         else
 415                           ac_cv_use_$1='$3=no'
 416                         fi
 417                       ],
 418                       [
 419                         LINE=`grep "$3" ${wx_arg_cache_file}`
 420                         if test "x$LINE" != x ; then
 421                           eval "DEFAULT_$LINE"
 422                         else
 423                           no_cache=1
 424                         fi
 425
 426                         ac_cv_use_$1='$3='$DEFAULT_$3
 427                       ])
 428
 429           eval "$ac_cv_use_$1"
 430           if test "$no_cache" != 1; then
 431             echo $ac_cv_use_$1 >> ${wx_arg_cache_file}.tmp
 432           fi
 433
 434           if test "$$3" = yes; then
 435             AC_MSG_RESULT(yes)
 436           else
 437             AC_MSG_RESULT(no)
 438           fi
 439         ])
 440
 441 dnl like WX_ARG_WITH but uses AC_ARG_ENABLE instead of AC_ARG_WITH
 442 dnl usage: WX_ARG_ENABLE(option, helpmessage, variable-name, enablestring)
 443 dnl
 444 dnl enablestring is a hack and allows to show "checking for --disable-foo"
 445 dnl message when running configure instead of the default "checking for
 446 dnl --enable-foo" one whih is useful for the options enabled by default
 447 AC_DEFUN([WX_ARG_ENABLE],
 448         [
 449           enablestring=$4
 450           AC_MSG_CHECKING([for --${enablestring:-enable}-$1])
 451           no_cache=0
 452           AC_ARG_ENABLE($1, [$2],
 453                         [
 454                           if test "$enableval" = yes; then
 455                             ac_cv_use_$1='$3=yes'
 456                           else
 457                             ac_cv_use_$1='$3=no'
 458                           fi
 459                         ],
 460                         [
 461                           LINE=`grep "$3" ${wx_arg_cache_file}`
 462                           if test "x$LINE" != x ; then
 463                             eval "DEFAULT_$LINE"
 464                           else
 465                             no_cache=1
 466                           fi
 467
 468                           ac_cv_use_$1='$3='$DEFAULT_$3
 469                         ])
 470
 471           eval "$ac_cv_use_$1"
 472           if test "$no_cache" != 1; then
 473             echo $ac_cv_use_$1 >> ${wx_arg_cache_file}.tmp
 474           fi
 475
 476           if test "$$3" = yes; then
 477             AC_MSG_RESULT(yes)
 478           else
 479             AC_MSG_RESULT(no)
 480           fi
 481         ])
 482
 483
 484 dnl Like WX_ARG_ENABLE but accepts a parameter.
 485 dnl
 486 dnl Usage:
 487 dnl   WX_ARG_ENABLE_PARAM(option, helpmessage, variable-name, enablestring)
 488 dnl
 489 dnl Example:
 490 dnl   WX_ARG_ENABLE_PARAM(foo, [[  --enable-foo[=bar] use foo]], wxUSE_FOO)
 491 dnl
 492 dnl  --enable-foo       wxUSE_FOO=yes
 493 dnl  --disable-foo      wxUSE_FOO=no
 494 dnl  --enable-foo=bar   wxUSE_FOO=bar
 495 dnl  <not given>        value from configarg.cache or wxUSE_FOO=no
 496 dnl
 497 AC_DEFUN([WX_ARG_ENABLE_PARAM],
 498         [
 499           enablestring=$4
 500           AC_MSG_CHECKING([for --${enablestring:-enable}-$1])
 501           no_cache=0
 502           AC_ARG_ENABLE($1, [$2],
 503                         [
 504                           wx_cv_use_$1="$3='$enableval'"
 505                         ],
 506                         [
 507                           LINE=`grep "$3" ${wx_arg_cache_file}`
 508                           if test "x$LINE" != x ; then
 509                             eval "DEFAULT_$LINE"
 510                             wx_cv_use_$1='$3='$DEFAULT_$3
 511                           else
 512                             no_cache=1
 513                             wx_cv_use_$1="$3=no"
 514                           fi
 515                         ])
 516
 517           eval "$wx_cv_use_$1"
 518           if test "$no_cache" != 1; then
 519             echo $wx_cv_use_$1 >> ${wx_arg_cache_file}.tmp
 520           fi
 521
 522           AC_MSG_RESULT([$$3])
 523         ])
 524
 525 dnl ===========================================================================
 526 dnl Linker features test
 527 dnl ===========================================================================
 528
 529 dnl ---------------------------------------------------------------------------
 530 dnl WX_VERSIONED_SYMBOLS checks whether the linker can create versioned
 531 dnl symbols. If it can, sets LDFLAGS_VERSIONING to $CXX flags needed to use
 532 dnl version script file named versionfile
 533 dnl
 534 dnl call WX_VERSIONED_SYMBOLS(versionfile)
 535 dnl ---------------------------------------------------------------------------
 536 AC_DEFUN([WX_VERSIONED_SYMBOLS],
 537 [
 538   found_versioning=no
 539
 540   dnl FIXME - doesn't work, Solaris linker doesn't accept wildcards
 541   dnl         in the script.
 542   dnl dnl Check for known non-gcc cases:
 543   dnl case "${host}" in
 544   dnl   *-*-solaris2* )
 545   dnl     if test "x$GCC" != "xyes" ; then
 546   dnl         LDFLAGS_VERSIONING="-M $1"
 547   dnl         found_versioning=yes
 548   dnl     fi
 549   dnl   ;;
 550   dnl esac
 551
 552   dnl Generic check for GCC or GCC-like behaviour (Intel C++, GCC):
 553   if test $found_versioning = no ; then
 554       AC_CACHE_CHECK([if the linker accepts --version-script], wx_cv_version_script,
 555       [
 556         echo "VER_1 { *; };" >conftest.sym
 557         echo "int main() { return 0; }" >conftest.cpp
 558
 559         if AC_TRY_COMMAND([
 560                 $CXX -o conftest.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 561                 -Wl,--version-script,conftest.sym >/dev/null 2>conftest.stderr]) ; then
 562           if test -s conftest.stderr ; then
 563               wx_cv_version_script=no
 564           else
 565               wx_cv_version_script=yes
 566           fi
 567         else
 568           wx_cv_version_script=no
 569         fi
 570
 571         dnl There's a problem in some old linkers with --version-script that
 572         dnl can cause linking to fail when you have objects with vtables in
 573         dnl libs 3 deep.  This is known to happen in netbsd and openbsd with
 574         dnl ld 2.11.2.
 575         dnl
 576         dnl To test for this we need to make some shared libs and
 577         dnl unfortunately we can't be sure of the right way to do that. If the
 578         dnl first two compiles don't succeed then it looks like the test isn't
 579         dnl working and the result is ignored, but if OTOH the first two
 580         dnl succeed but the third does not then the bug has been detected and
 581         dnl the --version-script flag is dropped.
 582         if test $wx_cv_version_script = yes
 583         then
 584           echo "struct B { virtual ~B() { } }; \
 585                 struct D : public B { }; \
 586                 void F() { D d; }" > conftest.cpp
 587
 588           if AC_TRY_COMMAND([
 589                 $CXX -shared -fPIC -o conftest1.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 590                 -Wl,--version-script,conftest.sym >/dev/null 2>/dev/null]) &&
 591              AC_TRY_COMMAND([
 592                 $CXX -shared -fPIC -o conftest2.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 593                 -Wl,--version-script,conftest.sym conftest1.output >/dev/null 2>/dev/null])
 594           then
 595             if AC_TRY_COMMAND([
 596                   $CXX -shared -fPIC -o conftest3.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 597                   -Wl,--version-script,conftest.sym conftest2.output conftest1.output >/dev/null 2>/dev/null])
 598             then
 599               wx_cv_version_script=yes
 600             else
 601               wx_cv_version_script=no
 602             fi
 603           fi
 604         fi
 605
 606         rm -f conftest.output conftest.stderr conftest.sym conftest.cpp
 607         rm -f conftest1.output conftest2.output conftest3.output
 608       ])
 609       if test $wx_cv_version_script = yes ; then
 610         LDFLAGS_VERSIONING="-Wl,--version-script,$1"
 611       fi
 612   fi
 613 ])
 614
 615
 616 dnl ===========================================================================
 617 dnl "3rd party" macros included here because they are not widely available
 618 dnl ===========================================================================
 619
 620 dnl ---------------------------------------------------------------------------
 621 dnl test for availability of iconv()
 622 dnl ---------------------------------------------------------------------------
 623
 624 dnl From Bruno Haible.
 625
 626 AC_DEFUN([AM_ICONV],
 627 [
 628   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 629   dnl those with the standalone portable GNU libiconv installed).
 630
 631   AC_ARG_WITH([libiconv-prefix],
 632 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
 633     for dir in `echo "$withval" | tr : ' '`; do
 634       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
 635       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
 636     done
 637    ])
 638
 639   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 640     am_cv_func_iconv="no, consider installing GNU libiconv"
 641     am_cv_lib_iconv=no
 642     AC_TRY_LINK([#include <stdlib.h>
 643 #include <iconv.h>],
 644       [iconv_t cd = iconv_open("","");
 645        iconv(cd,NULL,NULL,NULL,NULL);
 646        iconv_close(cd);],
 647       am_cv_func_iconv=yes)
 648     if test "$am_cv_func_iconv" != yes; then
 649       am_save_LIBS="$LIBS"
 650       LIBS="$LIBS -liconv"
 651       AC_TRY_LINK([#include <stdlib.h>
 652 #include <iconv.h>],
 653         [iconv_t cd = iconv_open("","");
 654          iconv(cd,NULL,NULL,NULL,NULL);
 655          iconv_close(cd);],
 656         am_cv_lib_iconv=yes
 657         am_cv_func_iconv=yes)
 658       LIBS="$am_save_LIBS"
 659     fi
 660   ])
 661   if test "$am_cv_func_iconv" = yes; then
 662     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 663     AC_CACHE_CHECK([if iconv needs const], wx_cv_func_iconv_const,
 664       AC_TRY_COMPILE([
 665 #include <stdlib.h>
 666 #include <iconv.h>
 667 extern
 668 #ifdef __cplusplus
 669 "C"
 670 #endif
 671 #if defined(__STDC__) || defined(__cplusplus)
 672 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 673 #else
 674 size_t iconv();
 675 #endif
 676         ],
 677         [],
 678         wx_cv_func_iconv_const="no",
 679         wx_cv_func_iconv_const="yes"
 680       )
 681     )
 682
 683     iconv_const=
 684     if test "x$wx_cv_func_iconv_const" = "xyes"; then
 685         iconv_const="const"
 686     fi
 687
 688     AC_DEFINE_UNQUOTED(ICONV_CONST, $iconv_const,
 689       [Define as const if the declaration of iconv() needs const.])
 690   fi
 691   LIBICONV=
 692   if test "$am_cv_lib_iconv" = yes; then
 693     LIBICONV="-liconv"
 694   fi
 695   AC_SUBST(LIBICONV)
 696 ])
 697
 698 dnl ---------------------------------------------------------------------------
 699 dnl AC_SYS_LARGEFILE (partly based on the code from autoconf 2.5x)
 700 dnl ---------------------------------------------------------------------------
 701
 702 dnl WX_SYS_LARGEFILE_TEST
 703 dnl
 704 dnl NB: original autoconf test was checking if compiler supported 6 bit off_t
 705 dnl     arithmetic properly but this failed miserably with gcc under Linux
 706 dnl     whereas the system still supports 64 bit files, so now simply check
 707 dnl     that off_t is big enough
 708 define(WX_SYS_LARGEFILE_TEST,
 709 [typedef struct {
 710     unsigned int field: sizeof(off_t) == 8;
 711 } wxlf;
 712 ])
 713
 714
 715 dnl WX_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR)
 716 define(WX_SYS_LARGEFILE_MACRO_VALUE,
 717 [
 718     AC_CACHE_CHECK([for $1 value needed for large files], [$3],
 719         [
 720           AC_TRY_COMPILE([#define $1 $2
 721                           #include <sys/types.h>],
 722                          WX_SYS_LARGEFILE_TEST,
 723                          [$3=$2],
 724                          [$3=no])
 725         ]
 726     )
 727
 728     if test "$$3" != no; then
 729         wx_largefile=yes
 730         AC_DEFINE_UNQUOTED([$1], [$$3])
 731     fi
 732 ])
 733
 734
 735 dnl AC_SYS_LARGEFILE
 736 dnl ----------------
 737 dnl By default, many hosts won't let programs access large files;
 738 dnl one must use special compiler options to get large-file access to work.
 739 dnl For more details about this brain damage please see:
 740 dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
 741 AC_DEFUN([AC_SYS_LARGEFILE],
 742 [AC_ARG_ENABLE(largefile,
 743                [  --disable-largefile     omit support for large files])
 744 if test "$enable_largefile" != no; then
 745     dnl _FILE_OFFSET_BITS==64 is needed for Linux, Solaris, ...
 746     dnl _LARGE_FILES -- for AIX
 747     wx_largefile=no
 748     WX_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64, ac_cv_sys_file_offset_bits)
 749     if test "x$wx_largefile" != "xyes"; then
 750         WX_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1, ac_cv_sys_large_files)
 751     fi
 752
 753     AC_MSG_CHECKING(if large file support is available)
 754     if test "x$wx_largefile" = "xyes"; then
 755         AC_DEFINE(HAVE_LARGEFILE_SUPPORT)
 756     fi
 757     AC_MSG_RESULT($wx_largefile)
 758 fi
 759 ])
 760
 761
 762 dnl Available from the GNU Autoconf Macro Archive at:
 763 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_const_cast.html
 764 dnl
 765 AC_DEFUN([AC_CXX_CONST_CAST],
 766 [AC_CACHE_CHECK(whether the compiler supports const_cast<>,
 767 ac_cv_cxx_const_cast,
 768 [AC_LANG_SAVE
 769  AC_LANG_CPLUSPLUS
 770  AC_TRY_COMPILE(,[int x = 0;const int& y = x;int& z = const_cast<int&>(y);return z;],
 771  ac_cv_cxx_const_cast=yes, ac_cv_cxx_const_cast=no)
 772  AC_LANG_RESTORE
 773 ])
 774 if test "$ac_cv_cxx_const_cast" = yes; then
 775   AC_DEFINE(HAVE_CONST_CAST,,[define if the compiler supports const_cast<>])
 776 fi
 777 ])
 778
 779 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_reinterpret_cast.html
 780 AC_DEFUN([AC_CXX_REINTERPRET_CAST],
 781 [AC_CACHE_CHECK(whether the compiler supports reinterpret_cast<>,
 782 ac_cv_cxx_reinterpret_cast,
 783 [AC_LANG_SAVE
 784  AC_LANG_CPLUSPLUS
 785  AC_TRY_COMPILE([#include <typeinfo>
 786 class Base { public : Base () {} virtual void f () = 0;};
 787 class Derived : public Base { public : Derived () {} virtual void f () {} };
 788 class Unrelated { public : Unrelated () {} };
 789 int g (Unrelated&) { return 0; }],[
 790 Derived d;Base& b=d;Unrelated& e=reinterpret_cast<Unrelated&>(b);return g(e);],
 791  ac_cv_cxx_reinterpret_cast=yes, ac_cv_cxx_reinterpret_cast=no)
 792  AC_LANG_RESTORE
 793 ])
 794 if test "$ac_cv_cxx_reinterpret_cast" = yes; then
 795   AC_DEFINE(HAVE_REINTERPRET_CAST,,
 796             [define if the compiler supports reinterpret_cast<>])
 797 fi
 798 ])
 799
 800 dnl and http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_static_cast.html
 801 AC_DEFUN([AC_CXX_STATIC_CAST],
 802 [AC_CACHE_CHECK(whether the compiler supports static_cast<>,
 803 ac_cv_cxx_static_cast,
 804 [AC_LANG_SAVE
 805  AC_LANG_CPLUSPLUS
 806  AC_TRY_COMPILE([#include <typeinfo>
 807 class Base { public : Base () {} virtual void f () = 0; };
 808 class Derived : public Base { public : Derived () {} virtual void f () {} };
 809 int g (Derived&) { return 0; }],[
 810 Derived d; Base& b = d; Derived& s = static_cast<Derived&> (b); return g (s);],
 811  ac_cv_cxx_static_cast=yes, ac_cv_cxx_static_cast=no)
 812  AC_LANG_RESTORE
 813 ])
 814 if test "$ac_cv_cxx_static_cast" = yes; then
 815   AC_DEFINE(HAVE_STATIC_CAST,, [define if the compiler supports static_cast<>])
 816 fi
 817 ])
 818
 819 dnl http://autoconf-archive.cryp.to/ac_cxx_dynamic_cast.html
 820 AC_DEFUN([AC_CXX_DYNAMIC_CAST],
 821 [AC_CACHE_CHECK(whether the compiler supports dynamic_cast<>,
 822 ac_cv_cxx_dynamic_cast,
 823 [AC_LANG_SAVE
 824  AC_LANG_CPLUSPLUS
 825  AC_TRY_COMPILE([#include <typeinfo>
 826 class Base { public : Base () {} virtual void f () = 0;};
 827 class Derived : public Base { public : Derived () {} virtual void f () {} };],[
 828 Derived d; Base& b=d; return dynamic_cast<Derived*>(&b) ? 0 : 1;],
 829  ac_cv_cxx_dynamic_cast=yes, ac_cv_cxx_dynamic_cast=no)
 830  AC_LANG_RESTORE
 831 ])
 832 if test "$ac_cv_cxx_dynamic_cast" = yes; then
 833   AC_DEFINE(HAVE_DYNAMIC_CAST,,[define if the compiler supports dynamic_cast<>])
 834 fi
 835 ])
 836