src/cocoa/frame.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        cocoa/frame.mm
   3 // Purpose:     wxFrame
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2003/03/16
   7 // RCS-ID:      $Id:
   8 // Copyright:   (c) 2003 David Elliott
   9 // Licence:     wxWindows license
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/log.h"
  15     #include "wx/app.h"
  16     #include "wx/frame.h"
  17     #include "wx/menu.h"
  18     #include "wx/toolbar.h"
  19     #include "wx/statusbr.h"
  20 #endif // WX_PRECOMP
  21
  22 #include "wx/cocoa/autorelease.h"
  23 #include "wx/cocoa/mbarman.h"
  24
  25 #import <AppKit/NSWindow.h>
  26 #import <AppKit/NSApplication.h>
  27 #import <AppKit/NSView.h>
  28
  29 // wxFrame
  30
  31 BEGIN_EVENT_TABLE(wxFrame, wxFrameBase)
  32 END_EVENT_TABLE()
  33
  34 IMPLEMENT_DYNAMIC_CLASS(wxFrame, wxTopLevelWindow)
  35
  36 void wxFrame::Init()
  37 {
  38     m_frameNSView = nil;
  39 }
  40
  41 bool wxFrame::Create(wxWindow *parent,
  42            wxWindowID winid,
  43            const wxString& title,
  44            const wxPoint& pos,
  45            const wxSize& size,
  46            long style,
  47            const wxString& name)
  48 {
  49     bool rt = wxTopLevelWindow::Create(parent,winid,title,pos,size,style,name);
  50
  51     return rt;
  52 }
  53
  54 wxFrame::~wxFrame()
  55 {
  56     [m_frameNSView release];
  57 }
  58
  59 void wxFrame::AttachMenuBar(wxMenuBar *mbar)
  60 {
  61     wxFrameBase::AttachMenuBar(mbar);
  62     wxMenuBarManager::GetInstance()->UpdateMenuBar();
  63 }
  64
  65 void wxFrame::DetachMenuBar()
  66 {
  67     wxFrameBase::DetachMenuBar();
  68     wxMenuBarManager::GetInstance()->UpdateMenuBar();
  69 }
  70
  71 void wxFrame::SetMenuBar(wxMenuBar *menubar)
  72 {
  73     if ( menubar == GetMenuBar() )
  74     {
  75         // nothing to do
  76         return;
  77     }
  78
  79     wxFrameBase::DetachMenuBar();
  80     wxFrameBase::AttachMenuBar(menubar);
  81     wxMenuBarManager::GetInstance()->UpdateMenuBar();
  82 }
  83
  84 wxMenuBar* wxFrame::GetAppMenuBar(wxCocoaNSWindow *win)
  85 {
  86     if(GetMenuBar())
  87         return GetMenuBar();
  88     return wxFrameBase::GetAppMenuBar(win);
  89 }
  90
  91 wxPoint wxFrame::GetClientAreaOrigin() const
  92 {
  93     return wxPoint(0,0);
  94 }
  95
  96 void wxFrame::CocoaSetWxWindowSize(int width, int height)
  97 {
  98     if(m_frameStatusBar)
  99         height += m_frameStatusBar->GetSize().y;
 100 #if wxUSE_TOOLBAR
 101     if(m_frameToolBar)
 102         height += m_frameToolBar->GetSize().y;
 103 #endif //wxUSE_TOOLBAR
 104     wxTopLevelWindow::CocoaSetWxWindowSize(width,height);
 105 }
 106
 107 WX_NSView wxFrame::GetNonClientNSView()
 108 {
 109     if(m_frameNSView)
 110         return m_frameNSView;
 111     return GetNSViewForSuperview();
 112 }
 113
 114 void wxFrame::CocoaReplaceView(WX_NSView oldView, WX_NSView newView)
 115 {
 116     // If we have the additional toolbar/statbar view, then the
 117     // default replaceSubview will work. Otherwise, the old view
 118     // should be the content view and should be replaced that way
 119     if(m_frameNSView)
 120         wxWindow::CocoaReplaceView(oldView, newView);
 121     else
 122         wxTopLevelWindow::CocoaReplaceView(oldView, newView);
 123 }
 124
 125 void wxFrame::UpdateFrameNSView()
 126 {
 127     if(!m_frameNSView)
 128     {
 129         m_frameNSView = [[NSView alloc] initWithFrame:[[m_cocoaNSWindow contentView] frame]];
 130         [m_cocoaNSWindow setContentView: m_frameNSView];
 131         [m_frameNSView addSubview:m_cocoaNSView];
 132     }
 133     NSRect frameRect = [m_frameNSView frame];
 134     float tbarheight = 0.0;
 135 #if wxUSE_TOOLBAR
 136     if(m_frameToolBar)
 137     {
 138         NSView *tbarNSView = m_frameToolBar->GetNSViewForSuperview();
 139         if(![tbarNSView superview])
 140             [m_frameNSView addSubview: tbarNSView];
 141         // Do this after addSubView so that SetSize can work
 142         m_frameToolBar->SetSize(m_frameToolBar->DoGetBestSize());
 143         NSRect tbarRect = [tbarNSView frame];
 144         tbarRect.size.width = frameRect.size.width;
 145         tbarRect.origin.x = 0.0;
 146         tbarRect.origin.y = frameRect.size.height - tbarRect.size.height;
 147         [tbarNSView setFrame:tbarRect];
 148         // width expands, bottom margin expands
 149         [tbarNSView setAutoresizingMask: NSViewWidthSizable|NSViewMinYMargin];
 150         tbarheight = tbarRect.size.height;
 151     }
 152 #endif //wxUSE_TOOLBAR
 153     float sbarheight = 0.0;
 154     if(m_frameStatusBar)
 155     {
 156         NSView *sbarNSView = m_frameStatusBar->GetNSViewForSuperview();
 157         if(![sbarNSView superview])
 158             [m_frameNSView addSubview: sbarNSView];
 159         NSRect sbarRect = [sbarNSView frame];
 160         sbarRect.size.width = frameRect.size.width;
 161         sbarRect.origin.x = 0.0;
 162         sbarRect.origin.y = 0.0;
 163         [sbarNSView setFrame:sbarRect];
 164         // width expands, top margin expands
 165         [sbarNSView setAutoresizingMask: NSViewWidthSizable|NSViewMaxYMargin];
 166         sbarheight = sbarRect.size.height;
 167     }
 168     wxLogDebug(wxT("frame height=%f, tbar=%f, sbar=%f"),frameRect.size.height,tbarheight,sbarheight);
 169     NSRect innerRect = [m_cocoaNSView frame];
 170     innerRect.size.height = frameRect.size.height - tbarheight - sbarheight;
 171     innerRect.origin.y = sbarheight;
 172     [m_cocoaNSView setFrame:innerRect];
 173     [m_cocoaNSView setAutoresizingMask: NSViewWidthSizable|NSViewHeightSizable];
 174     // Don't let the frame get smaller than the toolbar+statusbar height
 175     NSRect frameMinRect = [NSWindow frameRectForContentRect:
 176             NSMakeRect(0.0,0.0,0.0,tbarheight+sbarheight)
 177         styleMask: [m_cocoaNSWindow styleMask]];
 178     [m_cocoaNSWindow setMinSize:frameMinRect.size];
 179 }
 180
 181 void wxFrame::SetStatusBar(wxStatusBar *statusbar)
 182 {
 183     if(m_frameStatusBar)
 184     {
 185         [m_frameStatusBar->GetNSViewForSuperview() removeFromSuperview];
 186         [m_frameStatusBar->GetNSViewForSuperview() setAutoresizingMask: NSViewMinYMargin];
 187         if(m_frameStatusBar->GetParent())
 188             m_frameStatusBar->GetParent()->CocoaAddChild(m_frameStatusBar);
 189     }
 190     m_frameStatusBar = statusbar;
 191     if(m_frameStatusBar)
 192     {
 193         m_frameStatusBar->CocoaRemoveFromParent();
 194     }
 195     UpdateFrameNSView();
 196 }
 197
 198 wxStatusBar* wxFrame::CreateStatusBar(int number,
 199                                           long style,
 200                                           wxWindowID winid,
 201                                           const wxString& name)
 202 {
 203     wxAutoNSAutoreleasePool pool;
 204     wxFrameBase::CreateStatusBar(number,style,winid,name);
 205     if(m_frameStatusBar)
 206     {
 207         m_frameStatusBar->CocoaRemoveFromParent();
 208     }
 209     UpdateFrameNSView();
 210     return m_frameStatusBar;
 211 }
 212
 213 #if wxUSE_TOOLBAR
 214 void wxFrame::SetToolBar(wxToolBar *toolbar)
 215 {
 216     if(m_frameToolBar)
 217     {
 218         m_frameToolBar->SetOwningFrame(NULL);
 219         [m_frameToolBar->GetNSViewForSuperview() removeFromSuperview];
 220         [m_frameToolBar->GetNSViewForSuperview() setAutoresizingMask: NSViewMinYMargin];
 221         if(m_frameToolBar->GetParent())
 222             m_frameToolBar->GetParent()->CocoaAddChild(m_frameToolBar);
 223     }
 224     m_frameToolBar = toolbar;
 225     if(m_frameToolBar)
 226     {
 227         m_frameToolBar->CocoaRemoveFromParent();
 228         m_frameToolBar->SetOwningFrame(this);
 229     }
 230     UpdateFrameNSView();
 231 }
 232
 233 wxToolBar* wxFrame::CreateToolBar(long style,
 234                                       wxWindowID winid,
 235                                       const wxString& name)
 236 {
 237     wxAutoNSAutoreleasePool pool;
 238     wxFrameBase::CreateToolBar(style,winid,name);
 239     if(m_frameToolBar)
 240     {
 241         m_frameToolBar->CocoaRemoveFromParent();
 242         m_frameToolBar->SetOwningFrame(this);
 243     }
 244     UpdateFrameNSView();
 245     return m_frameToolBar;
 246 }
 247 #endif // wxUSE_TOOLBAR
 248
 249 void wxFrame::PositionStatusBar()
 250 {
 251 }
 252