src/cocoa/combobox.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/combobox.mm
   3 // Purpose:     wxComboBox
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2005/02/16
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) 2003 David Elliott
   9 // Licence:     wxWidgets licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 //
  13 // Impl notes:
  14 // There is no custom data source because doing so unnecessarily sacrifices
  15 // some native autocompletion behavior (we would have to make our own -
  16 // the SimpleComboBox sample does so in the developer folder that
  17 // comes with OSX).  One reason you might want this would be to have
  18 // only one array or be able to display numbers returned by an NSNumber
  19 // from the methods.
  20 //
  21 // One problem though is that wxCB_SORT isn't implemented...
  22 //
  23 // Also, not sure if it is correctly getting text field events since
  24 // I'm using SetNSComboBox instead of SetNSTextField
  25 //
  26 // doWxEvent is really hackish... but since there's only one event...
  27 //
  28 // Ideas for future improvement - other notes:
  29 // Combox w/o wxCB_DROPDOWN doesn't seem to be implementable
  30 //wxCB_READONLY  Same as wxCB_DROPDOWN but only the strings specified as the combobox choices can be selected, it is impossible to select (even from a program) a string which is not in the choices list.
  31 //wxCB_SORT      is possible with data source
  32 //
  33 // setIntercellSpacing:/setItemHeight: to autoadjust to number of inserted items?
  34 //
  35 /*
  36     //example of autocompletion from SimpleComboBox Example
  37     // ==========================================================
  38 // Combo box data source methods
  39 // ==========================================================
  40
  41 - (int)numberOfItemsInComboBox:(NSComboBox *)aComboBox {
  42     return [genres count];
  43 }
  44 - (id)comboBox:(NSComboBox *)aComboBox objectValueForItemAtIndex:(int)index {
  45     return [genres objectAtIndex:index];
  46 }
  47 - (unsigned int)comboBox:(NSComboBox *)aComboBox indexOfItemWithStringValue:(NSString *)string {
  48     return [genres indexOfObject: string];
  49 }
  50
  51 - (NSString *) firstGenreMatchingPrefix:(NSString *)prefix {
  52     NSString *string = nil;
  53     NSString *lowercasePrefix = [prefix lowercaseString];
  54     NSEnumerator *stringEnum = [genres objectEnumerator];
  55     while ((string = [stringEnum nextObject])) {
  56         if ([[string lowercaseString] hasPrefix: lowercasePrefix]) return string;
  57     }
  58     return nil;
  59 }
  60
  61 - (NSString *)comboBox:(NSComboBox *)aComboBox completedString:(NSString *)inputString {
  62     // This method is received after each character typed by the user, because we have checked the "completes" flag for genreComboBox in IB.
  63     // Given the inputString the user has typed, see if we can find a genre with the prefix, and return it as the suggested complete string.
  64     NSString *candidate = [self firstGenreMatchingPrefix: inputString];
  65     return (candidate ? candidate : inputString);
  66 }
  67 */
  68
  69 // ============================================================================
  70 // declarations
  71 // ============================================================================
  72
  73 // ----------------------------------------------------------------------------
  74 // headers
  75 // ----------------------------------------------------------------------------
  76
  77 #include "wx/wxprec.h"
  78
  79 #if wxUSE_COMBOBOX
  80
  81 #include "wx/combobox.h"
  82
  83 #ifndef WX_PRECOMP
  84     #include "wx/window.h"
  85     #include "wx/log.h"
  86     #include "wx/app.h"
  87 #endif // WX_PRECOMP
  88
  89 #import <AppKit/NSComboBox.h>
  90 #import <Foundation/NSNotification.h>
  91 #import <Foundation/NSString.h>
  92
  93 // ----------------------------------------------------------------------------
  94 // globals
  95 // ----------------------------------------------------------------------------
  96 WX_IMPLEMENT_OBJC_INTERFACE_HASHMAP(NSComboBox)
  97
  98 void wxCocoaNSComboBox::AssociateNSComboBox(WX_NSComboBox cocoaNSComboBox)
  99 {
 100     if(cocoaNSComboBox)
 101     {
 102         sm_cocoaHash.insert(wxCocoaNSComboBoxHash::value_type(cocoaNSComboBox,this));
 103
 104         [[NSNotificationCenter defaultCenter] addObserver:(id)cocoaNSComboBox selector:@selector(comboBoxSelectionDidChange:) name:@"NSComboBoxSelectionDidChangeNotification" object:cocoaNSComboBox];
 105         [[NSNotificationCenter defaultCenter] addObserver:(id)cocoaNSComboBox selector:@selector(comboBoxSelectionDidChange:) name:@"NSComboBoxSelectionIsChangingNotification" object:cocoaNSComboBox];
 106         [[NSNotificationCenter defaultCenter] addObserver:(id)cocoaNSComboBox selector:@selector(comboBoxSelectionDidChange:) name:@"NSComboBoxWillDismissNotification" object:cocoaNSComboBox];
 107         [[NSNotificationCenter defaultCenter] addObserver:(id)cocoaNSComboBox selector:@selector(comboBoxSelectionDidChange:) name:@"NSComboBoxWillPopUpNotification" object:cocoaNSComboBox];
 108     }
 109 }
 110
 111 void wxCocoaNSComboBox::DisassociateNSComboBox(WX_NSComboBox cocoaNSComboBox)
 112 {
 113     if(cocoaNSComboBox)
 114     {
 115         sm_cocoaHash.erase(cocoaNSComboBox);
 116         [[NSNotificationCenter defaultCenter] removeObserver:(id)cocoaNSComboBox name:@"NSComboBoxSelectionDidChangeNotification" object:cocoaNSComboBox];
 117         [[NSNotificationCenter defaultCenter] removeObserver:(id)cocoaNSComboBox name:@"NSComboBoxSelectionIsChangingNotification" object:cocoaNSComboBox];
 118         [[NSNotificationCenter defaultCenter] removeObserver:(id)cocoaNSComboBox name:@"NSComboBoxWillDismissNotification" object:cocoaNSComboBox];
 119         [[NSNotificationCenter defaultCenter] removeObserver:(id)cocoaNSComboBox name:@"NSComboBoxWillPopUpNotification" object:cocoaNSComboBox];
 120     }
 121 }
 122
 123 // ============================================================================
 124 // @class wxPoserNSComboBox
 125 // ============================================================================
 126 @interface wxPoserNSComboBox : NSComboBox
 127 {
 128 }
 129
 130 - (void)comboBoxSelectionDidChange:(NSNotification *)notification;
 131 - (void)comboBoxSelectionIsChanging:(NSNotification *)notification;
 132 - (void)comboBoxWillDismiss:(NSNotification *)notification;
 133 - (void)comboBoxWillPopUp:(NSNotification *)notification;
 134 @end // wxPoserNSComboBox
 135
 136 //WX_IMPLEMENT_POSER(wxPoserNSComboBox);
 137 @implementation wxPoserNSComboBox : NSComboBox
 138
 139 - (void)comboBoxSelectionDidChange:(NSNotification *)notification
 140 {
 141     wxCocoaNSComboBox *win = wxCocoaNSComboBox::GetFromCocoa(self);
 142     win->doWxEvent(wxEVT_COMMAND_COMBOBOX_SELECTED);
 143 }
 144
 145 - (void)comboBoxSelectionIsChanging:(NSNotification *)notification
 146 {
 147     //...
 148 }
 149
 150 - (void)comboBoxWillDismiss:(NSNotification *)notification
 151 {
 152     //...
 153 }
 154
 155 - (void)comboBoxWillPopUp:(NSNotification *)notification
 156 {
 157     //...
 158 }
 159
 160 @end // implementation wxPoserNSComboBox
 161
 162 #include "wx/cocoa/autorelease.h"
 163 #include "wx/cocoa/string.h"
 164
 165 #import <AppKit/NSComboBox.h>
 166
 167 IMPLEMENT_DYNAMIC_CLASS(wxComboBox, wxTextCtrl)
 168 BEGIN_EVENT_TABLE(wxComboBox, wxTextCtrl)
 169 END_EVENT_TABLE()
 170 WX_IMPLEMENT_COCOA_OWNER(wxComboBox,NSComboBox,NSTextField,NSView)
 171
 172 bool wxComboBox::Create(wxWindow *parent, wxWindowID winid,
 173             const wxString& value,
 174             const wxPoint& pos,
 175             const wxSize& size,
 176             const wxArrayString& choices,
 177             long style,
 178             const wxValidator& validator,
 179             const wxString& name)
 180 {
 181     wxCArrayString chs(choices);
 182
 183     return Create(parent, winid, value, pos, size, chs.GetCount(),
 184                   chs.GetStrings(), style, validator, name);
 185 }
 186
 187 bool wxComboBox::Create(wxWindow *parent, wxWindowID winid,
 188             const wxString& value,
 189             const wxPoint& pos,
 190             const wxSize& size,
 191             int n, const wxString choices[],
 192             long style,
 193             const wxValidator& validator,
 194             const wxString& name)
 195 {
 196     wxAutoNSAutoreleasePool pool;
 197     if(!CreateControl(parent,winid,pos,size,style,validator,name))
 198         return false;
 199
 200     m_cocoaNSView = NULL;
 201     SetNSComboBox([[wxPoserNSComboBox alloc] initWithFrame:MakeDefaultNSRect(size)]);
 202     [m_cocoaNSView release];
 203     [GetNSTextField() setStringValue:wxNSStringWithWxString(value.c_str())];
 204     [GetNSControl() sizeToFit];
 205     if(m_parent)
 206         m_parent->CocoaAddChild(this);
 207     SetInitialFrameRect(pos,size);
 208
 209     wxComboBox::Append(n, choices);
 210
 211     [GetNSComboBox() setCompletes:true]; //autocomplete :)
 212
 213     return true;
 214 }
 215
 216 wxComboBox::~wxComboBox()
 217 {
 218     DisassociateNSComboBox(GetNSComboBox());
 219 }
 220
 221 void wxComboBox::doWxEvent(int nEvent)
 222 {
 223     wxCommandEvent event2(wxEVT_COMMAND_COMBOBOX_SELECTED, GetId() );
 224     event2.SetInt(GetSelection());
 225     event2.SetEventObject(this);
 226     event2.SetString(GetStringSelection());
 227     GetEventHandler()->ProcessEvent(event2);
 228
 229     // For consistency with MSW and GTK, also send a text updated event
 230     // After all, the text is updated when a selection is made
 231     wxCommandEvent TextEvent( wxEVT_COMMAND_TEXT_UPDATED, GetId() );
 232     TextEvent.SetString( GetStringSelection() );
 233     TextEvent.SetEventObject( this );
 234     GetEventHandler()->ProcessEvent( TextEvent );
 235 }
 236
 237
 238 void wxComboBox::SetSelection(int nSelection)
 239 {
 240     [GetNSComboBox() selectItemAtIndex:nSelection];
 241 }
 242
 243 wxString wxComboBox::GetStringSelection()
 244 {
 245     return wxStringWithNSString([GetNSComboBox() objectValueOfSelectedItem]);
 246 }
 247
 248 void wxComboBox::DoClear()
 249 {
 250     [GetNSComboBox() removeAllItems];
 251     m_Datas.Clear();
 252 }
 253
 254 void wxComboBox::DoDeleteOneItem(unsigned int n)
 255 {
 256     [GetNSComboBox() removeItemAtIndex:n];
 257     m_Datas.RemoveAt(n);
 258 }
 259
 260 unsigned int wxComboBox::GetCount() const
 261 {
 262     return (unsigned int)[GetNSComboBox() numberOfItems];
 263 }
 264
 265 wxString wxComboBox::GetString(unsigned int nIndex) const
 266 {
 267     return wxStringWithNSString([GetNSComboBox() itemObjectValueAtIndex:nIndex]);
 268 }
 269
 270 void wxComboBox::SetString(unsigned int nIndex, const wxString& szString)
 271 {
 272     wxAutoNSAutoreleasePool pool;
 273     //FIXME:  There appears to be no "set item data" method - maybe
 274     //an assignment would work?
 275     [GetNSComboBox() removeItemAtIndex:nIndex];
 276     [GetNSComboBox() insertItemWithObjectValue:wxNSStringWithWxString(szString) atIndex:nIndex];
 277 }
 278
 279 int wxComboBox::FindString(const wxString& szItem, bool bCase) const
 280 {
 281     // FIXME: use wxItemContainerImmutable::FindString for bCase parameter
 282     return [GetNSComboBox() indexOfItemWithObjectValue:wxNSStringWithWxString(szItem)];
 283 }
 284
 285 int wxComboBox::GetSelection() const
 286 {
 287     return [GetNSComboBox() indexOfSelectedItem];
 288 }
 289
 290 int wxComboBox::DoInsertItems(const wxArrayStringsAdapter& items,
 291                               unsigned int pos,
 292                               void **clientData,
 293                               wxClientDataType type)
 294 {
 295     wxAutoNSAutoreleasePool pool;
 296     const unsigned int numITems = items.GetCount();
 297     for ( unsigned int i = 0; i < numITems; ++i, ++pos )
 298     {
 299         [GetNSComboBox() insertItemWithObjectValue:wxNSStringWithWxString(items[i]) atIndex:(pos)];
 300         m_Datas.Insert(NULL, pos);
 301         AssignNewItemClientData(pos, clientData, i, type);
 302     }
 303     return pos - 1;
 304 }
 305
 306 void wxComboBox::DoSetItemClientData(unsigned int nIndex, void* pData)
 307 {
 308     m_Datas[nIndex] = pData;
 309 }
 310
 311 void* wxComboBox::DoGetItemClientData(unsigned int nIndex) const
 312 {
 313     return m_Datas[nIndex];
 314 }
 315
 316 #endif // wxUSE_COMBOBOX