configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Id$)dnl
   3
   4 AC_PREREQ(2.58)
   5
   6 dnl ---------------------------------------------------------------------------
   7 dnl
   8 dnl Top-level configure.in for wxWidgets by Robert Roebling, Phil Blecker,
   9 dnl Vadim Zeitlin and Ron Lee
  10 dnl
  11 dnl This script is under the wxWidgets licence.
  12 dnl
  13 dnl Version: $Id$
  14 dnl ---------------------------------------------------------------------------
  15
  16 dnl ---------------------------------------------------------------------------
  17 dnl initialization
  18 dnl ---------------------------------------------------------------------------
  19
  20 AC_INIT([wxWidgets], [2.9.1], [wx-dev@lists.wxwidgets.org])
  21
  22 dnl the file passed to AC_CONFIG_SRCDIR should be specific to our package
  23 AC_CONFIG_SRCDIR([wx-config.in])
  24
  25 dnl sets build, host variables and the same with _alias
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28
  29 dnl notice that if --host was given but --build was not, cross_compiling is
  30 dnl only set to "maybe" and not "yes" and will be either set to "yes" later or
  31 dnl configure will exit with error in AC_PROG_CC so don't test for = "yes" here
  32 if test "$cross_compiling" != "no"; then
  33     HOST_PREFIX="${host_alias}-"
  34     HOST_SUFFIX="-$host_alias"
  35 else
  36     HOST_PREFIX=
  37     HOST_SUFFIX=
  38 fi
  39
  40 dnl When making releases do:
  41 dnl
  42 dnl wx_release_number += 1
  43
  44 wx_major_version_number=2
  45 wx_minor_version_number=9
  46 wx_release_number=1
  47 wx_subrelease_number=0
  48
  49 WX_RELEASE=$wx_major_version_number.$wx_minor_version_number
  50 WX_VERSION=$WX_RELEASE.$wx_release_number
  51 WX_SUBVERSION=$WX_VERSION.$wx_subrelease_number
  52
  53 WX_MSW_VERSION=$wx_major_version_number$wx_minor_version_number$wx_release_number
  54
  55
  56 dnl Autoconf-2.60 changed the meaning of top_builddir variable, so we have
  57 dnl to use our own replacement that will work with both 2.5x and 2.60+:
  58 wx_top_builddir="`pwd`"
  59 AC_SUBST(wx_top_builddir)
  60
  61
  62 dnl ------------------------------------------------------------------------
  63 dnl Check platform (host system)
  64 dnl ------------------------------------------------------------------------
  65
  66 dnl OS (assume Unix)
  67 USE_UNIX=1
  68 USE_OS2=0
  69 USE_WIN32=0
  70 USE_DOS=0
  71 USE_BEOS=0
  72 USE_MAC=0
  73
  74 dnl Unix kind
  75 USE_AIX=
  76 USE_BSD=                            dnl any BSD
  77 USE_DARWIN=                         dnl a.k.a. Mac OS X
  78 USE_FREEBSD=
  79 USE_GNU=                            dnl GNU/Hurd
  80 USE_HPUX=
  81 USE_LINUX=
  82 USE_NETBSD=
  83 USE_OPENBSD=
  84 USE_OSF=                            dnl OSF/1 (obsolete?)
  85 USE_SGI=
  86 USE_SOLARIS=                        dnl Solaris ("SunOS" >= 5)
  87 USE_SUN=                            dnl SunOS or Solaris
  88 USE_SUNOS=                          dnl old/real SunOS (obsolete)
  89 USE_SVR4=                           dnl SysV R4
  90 USE_SYSV=                           dnl any System V
  91 USE_VMS=
  92 USE_ULTRIX=
  93 USE_UNIXWARE=
  94
  95 dnl hardware platform
  96 USE_ALPHA=
  97
  98 dnl on some platforms xxx_r() functions are declared inside "#ifdef
  99 dnl _REENTRANT" and it's easier to just define this symbol for these platforms
 100 dnl than checking it during run-time
 101 NEEDS_D_REENTRANT_FOR_R_FUNCS=0
 102
 103 dnl the list of all available toolkits
 104 dnl
 105 dnl update NUM_TOOLKITS calculation below when adding a new toolkit here!
 106 ALL_TOOLKITS="COCOA GTK OSX_CARBON OSX_COCOA MGL MICROWIN MOTIF MSW PM X11 DFB"
 107
 108 dnl NB: these wxUSE_XXX constants have value of 0 or 1 unlike all the other ones
 109 dnl     which are either yes or no
 110 DEFAULT_wxUSE_COCOA=0
 111 DEFAULT_wxUSE_GTK=0
 112 DEFAULT_wxUSE_OSX_CARBON=0
 113 DEFAULT_wxUSE_OSX_COCOA=0
 114 DEFAULT_wxUSE_MGL=0
 115 DEFAULT_wxUSE_MICROWIN=0
 116 DEFAULT_wxUSE_MOTIF=0
 117 DEFAULT_wxUSE_MSW=0
 118 DEFAULT_wxUSE_PM=0
 119 DEFAULT_wxUSE_X11=0
 120 DEFAULT_wxUSE_DFB=0
 121
 122 dnl these are the values which are really default for the given platform:
 123 dnl they're used if no --with-<toolkit> options were given to detect the
 124 dnl toolkit to use by default for the target platform
 125 DEFAULT_DEFAULT_wxUSE_COCOA=0
 126 DEFAULT_DEFAULT_wxUSE_GTK=0
 127 DEFAULT_DEFAULT_wxUSE_OSX_CARBON=0
 128 DEFAULT_DEFAULT_wxUSE_OSX_COCOA=0
 129 DEFAULT_DEFAULT_wxUSE_MGL=0
 130 DEFAULT_DEFAULT_wxUSE_MICROWIN=0
 131 DEFAULT_DEFAULT_wxUSE_MOTIF=0
 132 DEFAULT_DEFAULT_wxUSE_MSW=0
 133 DEFAULT_DEFAULT_wxUSE_PM=0
 134 DEFAULT_DEFAULT_wxUSE_X11=0
 135 DEFAULT_DEFAULT_wxUSE_DFB=0
 136
 137 PROGRAM_EXT=
 138 SAMPLES_RPATH_FLAG=
 139 DYLIB_RPATH_INSTALL=
 140 DYLIB_RPATH_POSTLINK=
 141
 142 DEFAULT_STD_FLAG=yes
 143
 144 dnl to support a new system, you need to add its canonical name (as determined
 145 dnl by config.sub or specified by the configure command line) to this "case"
 146 dnl and also define the shared library flags below - search for
 147 dnl SHARED_LIB_SETUP to find the exact place
 148 case "${host}" in
 149   *-hp-hpux* )
 150     USE_HPUX=1
 151     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 152     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 153     AC_DEFINE(__HPUX__)
 154
 155     dnl many standard declarations in HP-UX headers are only included if either
 156     dnl _HPUX_SOURCE is defined, see stdsyms(5)
 157     CPPFLAGS="-D_HPUX_SOURCE $CPPFLAGS"
 158   ;;
 159   *-*-linux* )
 160     USE_LINUX=1
 161     AC_DEFINE(__LINUX__)
 162     TMP=`uname -m`
 163     if test "x$TMP" = "xalpha"; then
 164       USE_ALPHA=1
 165       AC_DEFINE(__ALPHA__)
 166     fi
 167     DEFAULT_DEFAULT_wxUSE_GTK=1
 168   ;;
 169   *-*-gnu* | *-*-k*bsd*-gnu )
 170     USE_GNU=1
 171     TMP=`uname -m`
 172     if test "x$TMP" = "xalpha"; then
 173       USE_ALPHA=1
 174       AC_DEFINE(__ALPHA__)
 175     fi
 176     DEFAULT_DEFAULT_wxUSE_GTK=1
 177   ;;
 178   *-*-irix5* | *-*-irix6* )
 179     USE_SGI=1
 180     USE_SVR4=1
 181     AC_DEFINE(__SGI__)
 182     AC_DEFINE(__SVR4__)
 183     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 184   ;;
 185   *-*-solaris2* )
 186     USE_SUN=1
 187     USE_SOLARIS=1
 188     USE_SVR4=1
 189     AC_DEFINE(__SUN__)
 190     AC_DEFINE(__SOLARIS__)
 191     AC_DEFINE(__SVR4__)
 192     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 193     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 194   ;;
 195   *-*-sunos4* )
 196     USE_SUN=1
 197     USE_SUNOS=1
 198     USE_BSD=1
 199     AC_DEFINE(__SUN__)
 200     AC_DEFINE(__SUNOS__)
 201     AC_DEFINE(__BSD__)
 202     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 203   ;;
 204   *-*-freebsd*)
 205     USE_BSD=1
 206     USE_FREEBSD=1
 207     AC_DEFINE(__FREEBSD__)
 208     AC_DEFINE(__BSD__)
 209     DEFAULT_DEFAULT_wxUSE_GTK=1
 210   ;;
 211   *-*-openbsd*|*-*-mirbsd*)
 212     USE_BSD=1
 213     USE_OPENBSD=1
 214     AC_DEFINE(__OPENBSD__)
 215     AC_DEFINE(__BSD__)
 216     DEFAULT_DEFAULT_wxUSE_GTK=1
 217   ;;
 218   *-*-netbsd*)
 219     USE_BSD=1
 220     USE_NETBSD=1
 221     AC_DEFINE(__NETBSD__)
 222     AC_DEFINE(__BSD__)
 223     DEFAULT_DEFAULT_wxUSE_GTK=1
 224     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 225
 226     dnl some standard declarations in NetBSD headers are only included if
 227     dnl _NETBSD_SOURCE and _LIBC are defined, e.g. getservbyname_r in netdb.h
 228     CPPFLAGS="-D_NETBSD_SOURCE -D_LIBC $CPPFLAGS"
 229   ;;
 230   *-*-osf* )
 231     USE_ALPHA=1
 232     USE_OSF=1
 233     AC_DEFINE(__ALPHA__)
 234     AC_DEFINE(__OSF__)
 235     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 236     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 237   ;;
 238   *-*-dgux5* )
 239     USE_ALPHA=1
 240     USE_SVR4=1
 241     AC_DEFINE(__ALPHA__)
 242     AC_DEFINE(__SVR4__)
 243     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 244   ;;
 245   *-*-sysv5* )
 246     USE_SYSV=1
 247     USE_SVR4=1
 248     AC_DEFINE(__SYSV__)
 249     AC_DEFINE(__SVR4__)
 250     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 251   ;;
 252   *-*-aix* )
 253     USE_AIX=1
 254     USE_SYSV=1
 255     USE_SVR4=1
 256     AC_DEFINE(__AIX__)
 257     AC_DEFINE(__SYSV__)
 258     AC_DEFINE(__SVR4__)
 259     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 260   ;;
 261
 262   *-*-*UnixWare*)
 263     USE_SYSV=1
 264     USE_SVR4=1
 265     USE_UNIXWARE=1
 266     AC_DEFINE(__UNIXWARE__)
 267   ;;
 268
 269   *-*-cygwin* | *-*-mingw32* )
 270     dnl MBN: some of the defines have been moved after toolkit detection
 271     dnl      because for wxMotif/wxGTK/wxX11 to build on Cygwin
 272     dnl      USE_UNIX  must be set and not USE_WIN32
 273     PROGRAM_EXT=".exe"
 274     DEFAULT_DEFAULT_wxUSE_MSW=1
 275   ;;
 276
 277   *-pc-msdosdjgpp )
 278     USE_UNIX=0
 279     USE_DOS=1
 280     AC_DEFINE(__DOS__)
 281     PROGRAM_EXT=".exe"
 282     DEFAULT_DEFAULT_wxUSE_MGL=1
 283   ;;
 284
 285   *-pc-os2_emx | *-pc-os2-emx )
 286     AC_DEFINE(__EMX__)
 287     USE_OS2=1
 288     AC_DEFINE(__OS2__)
 289     PROGRAM_EXT=".exe"
 290     DEFAULT_DEFAULT_wxUSE_PM=1
 291     dnl "c++" wrapper is not always available, so always use plain gcc.
 292     CXX=gcc
 293     LDFLAGS="$LDFLAGS -Zcrtdll"
 294     dnl
 295     dnl Some special code that's automatically added by autoconf-2.57 for OS/2
 296     dnl and hopefully also by autoconf-2.58 and newer on all other platforms.
 297     dnl For now however, we still need it to make sure the configure script
 298     dnl works on OS/2 no matter what platform it is generated on.
 299     ac_executable_extensions=".exe"
 300     export ac_executable_extensions
 301     dnl This strange code is necessary to deal with handling of
 302     dnl backslashes by ksh and pdksh's sh variant.
 303     ac_save_IFS="$IFS"
 304     IFS='\\'
 305     ac_TEMP_PATH=
 306     for ac_dir in $PATH; do
 307       IFS=$ac_save_IFS
 308       if test -z "$ac_TEMP_PATH"; then
 309         ac_TEMP_PATH="$ac_dir"
 310       else
 311         ac_TEMP_PATH="$ac_TEMP_PATH/$ac_dir"
 312       fi
 313     done
 314     export PATH="$ac_TEMP_PATH"
 315     unset ac_TEMP_PATH
 316     DEFAULT_STD_FLAG=no
 317   ;;
 318
 319   *-*-darwin* )
 320     dnl Darwin based distributions (including Mac OS X)
 321     USE_BSD=1
 322     USE_DARWIN=1
 323     AC_DEFINE(__BSD__)
 324     AC_DEFINE(__DARWIN__)
 325     AC_DEFINE(TARGET_CARBON)
 326     DEFAULT_DEFAULT_wxUSE_OSX_CARBON=1
 327   ;;
 328
 329   *-*-beos* )
 330     dnl leave USE_UNIX on - BeOS is sufficiently Unix-like for this
 331     USE_BEOS=1
 332     AC_DEFINE(__BEOS__)
 333   ;;
 334
 335   *)
 336     AC_MSG_WARN([*** System type ${host} is unknown, assuming generic Unix and continuing nevertheless.])
 337     AC_MSG_WARN([*** Please report the build results to wx-dev@lists.wxwidgets.org.])
 338
 339     DEFAULT_DEFAULT_wxUSE_X11=1
 340     DEFAULT_wxUSE_SHARED=no
 341 esac
 342
 343 dnl ---------------------------------------------------------------------------
 344 dnl command line options for configure
 345 dnl ---------------------------------------------------------------------------
 346
 347 dnl the default values for all options - we collect them all here to simplify
 348 dnl modification of the default values (for example, if the defaults for some
 349 dnl platform should be changed, it can be done here too)
 350 dnl
 351 dnl NB: see also DEFAULT_wxUSE<toolkit> variables defined above
 352
 353 dnl it's only necessary to list the options which should be disabled by
 354 dnl default, all the rest have default value of "yes" (or, rather, of
 355 dnl wxUSE_ALL_FEATURES which is the only which has to be set to "yes" by
 356 dnl default)
 357 DEFAULT_wxUSE_ALL_FEATURES=yes
 358
 359 DEFAULT_wxUSE_STD_IOSTREAM=$DEFAULT_STD_FLAG
 360 DEFAULT_wxUSE_STD_STRING=$DEFAULT_STD_FLAG
 361
 362 dnl libraries disabled by default
 363 DEFAULT_wxUSE_DMALLOC=no
 364 DEFAULT_wxUSE_LIBGNOMEVFS=no
 365 DEFAULT_wxUSE_LIBHILDON=no
 366 DEFAULT_wxUSE_LIBHILDON2=no
 367 DEFAULT_wxUSE_LIBMSPACK=no
 368 DEFAULT_wxUSE_LIBSDL=no
 369
 370 dnl features disabled by default
 371 DEFAULT_wxUSE_ACCESSIBILITY=no
 372 DEFAULT_wxUSE_GRAPHICS_CONTEXT=no
 373 DEFAULT_wxUSE_IPV6=no
 374 DEFAULT_wxUSE_GSTREAMER8=no
 375
 376 dnl automatic features
 377 DEFAULT_wxUSE_UNICODE_UTF8=auto
 378 DEFAULT_wxUSE_OPENGL=auto
 379 DEFAULT_wxUSE_MEDIACTRL=auto
 380 DEFAULT_wxUSE_COMPILER_TLS=auto
 381
 382 DEFAULT_wxUSE_UNICODE_UTF8_LOCALE=no
 383
 384 dnl Mac/Cocoa users need to enable building universal binaries explicitly
 385 DEFAULT_wxUSE_UNIVERSAL_BINARY=no
 386
 387 DEFAULT_wxUSE_OFFICIAL_BUILD=no
 388
 389 dnl Applicable only when --with-gtk was used:
 390 DEFAULT_wxUSE_GTK2=yes
 391
 392 dnl Always default to no. Only special cases require this.
 393 DEFAULT_wxUSE_OBJC_UNIQUIFYING=no
 394
 395 dnl ===========================
 396 dnl deal with configure options
 397 dnl ===========================
 398
 399 dnl we use several macros here:
 400 dnl     - AC_ARG_WITH/AC_ARG_ENABLE are the standard autoconf macros, see
 401 dnl       autoconf manual for details about them
 402 dnl     - WX_ARG_WITH/WX_ARG_ENABLE are their wx counterparts which perform
 403 dnl       the caching of the command line options and also use DEFAULT_foo
 404 dnl       variable as the default value for "foo" if neither --enable-foo nor
 405 dnl       --disable-foo is specified
 406 dnl     - WX_ARG_SYS_WITH is a special version of WX_ARG_WITH which allows
 407 dnl       to choose not only whether an external library is used but also if we
 408 dnl       use the copy of it included with wxWidgets or an already installed
 409 dnl       system version
 410 dnl     - WX_ARG_WITHOUT/WX_ARG_DISABLE mirror WX_ARG_WITH/WX_ARG_ENABLE but
 411 dnl       should be used for the options which are enabled by default
 412 dnl     - WX_ARG_FEATURE is a version of WX_ARG_ENABLE which should be used for
 413 dnl       optional features, i.e. options which should be disabled if
 414 dnl       --disable-all-features is specified (WX_ARG_WITH/WX_ARG_SYS_WITH are
 415 dnl       also affected by this)
 416
 417 dnl ---------------------------------------------------------------------------
 418 dnl global build options
 419 dnl ---------------------------------------------------------------------------
 420
 421 WX_ARG_DISABLE(gui,        [  --disable-gui           don't build GUI parts of the library], wxUSE_GUI)
 422 WX_ARG_ENABLE(monolithic,  [  --enable-monolithic     build wxWidgets as single library], wxUSE_MONOLITHIC)
 423 WX_ARG_ENABLE(plugins,     [  --enable-plugins        build parts of wxWidgets as loadable components], wxUSE_PLUGINS)
 424 WX_ARG_WITHOUT(subdirs,    [  --without-subdirs       don't generate makefiles for samples/demos/...], wxWITH_SUBDIRS)
 425 AC_ARG_WITH(flavour,       [  --with-flavour=NAME     specify a name to identify this build], [WX_FLAVOUR="$withval"])
 426 WX_ARG_ENABLE(official_build,  [  --enable-official_build official build of wxWidgets (win32 DLL only)], wxUSE_OFFICIAL_BUILD)
 427 AC_ARG_ENABLE(vendor,  [  --enable-vendor=VENDOR  vendor name (win32 DLL only)], [VENDOR="$enableval"])
 428 if test "x$VENDOR" = "x"; then
 429     VENDOR="custom"
 430 fi
 431
 432 WX_ARG_DISABLE(all-features,[  --disable-all-features  disable all optional features to build minimal library], wxUSE_ALL_FEATURES)
 433
 434 if test "$wxUSE_ALL_FEATURES" = "no"; then
 435     dnl this is a bit ugly but currently we have no choice but to manually
 436     dnl reset all the options with default value of auto if all features are to
 437     dnl be disabled because we can't have an option with default value of
 438     dnl "auto-or-no-if-wxUSE_ALL_FEATURES-is-disabled"
 439     DEFAULT_wxUSE_MEDIACTRL=no
 440 fi
 441
 442 dnl ---------------------------------------------------------------------------
 443 dnl port selection
 444 dnl ---------------------------------------------------------------------------
 445
 446 if test "$wxUSE_GUI" = "yes"; then
 447
 448 WX_ARG_ENABLE(universal,   [  --enable-universal      use wxWidgets GUI controls instead of native ones], wxUSE_UNIVERSAL)
 449 if test "$wxUSE_UNIVERSAL" = "yes"; then
 450     AC_ARG_WITH(themes,    [  --with-themes=all|list  use only the specified comma-separated list of wxUniversal themes], [wxUNIV_THEMES="$withval"])
 451 fi
 452
 453 dnl we use AC_ARG_WITH and not WX_ARG_WITH for the toolkit options as they
 454 dnl shouldn't default to wxUSE_ALL_FEATURES
 455 AC_ARG_WITH(gtk,          [[  --with-gtk[=VERSION]    use GTK+, VERSION can be 2 (default), 1 or "any"]], [wxUSE_GTK="$withval" CACHE_GTK=1 TOOLKIT_GIVEN=1])
 456 AC_ARG_WITH(motif,         [  --with-motif            use Motif/Lesstif], [wxUSE_MOTIF="$withval" CACHE_MOTIF=1 TOOLKIT_GIVEN=1])
 457 AC_ARG_WITH(osx_carbon,    [  --with-osx_carbon       use Mac OS X (Carbon) ], [wxUSE_OSX_CARBON="$withval" CACHE_OSX_CARBON=1 TOOLKIT_GIVEN=1])
 458 AC_ARG_WITH(osx_cocoa,     [  --with-osx_cocoa        use Mac OS X (Cocoa) ], [wxUSE_OSX_COCOA="$withval" CACHE_OSX_COCOA=1 TOOLKIT_GIVEN=1])
 459 AC_ARG_WITH(mac,           [  --with-mac              use Mac OS X (Default) ], [wxUSE_OSX_CARBON="$withval" CACHE_OSX_CARBON=1 TOOLKIT_GIVEN=1])
 460 AC_ARG_WITH(cocoa,         [  --with-cocoa            use Cocoa], [wxUSE_COCOA="$withval" CACHE_COCOA=1 TOOLKIT_GIVEN=1])
 461 AC_ARG_WITH(wine,          [  --with-wine             use Wine], [wxUSE_WINE="$withval" CACHE_WINE=1])
 462 AC_ARG_WITH(msw,           [  --with-msw              use MS-Windows], [wxUSE_MSW="$withval" CACHE_MSW=1 TOOLKIT_GIVEN=1])
 463 AC_ARG_WITH(pm,            [  --with-pm               use OS/2 Presentation Manager], [wxUSE_PM="$withval" CACHE_PM=1 TOOLKIT_GIVEN=1])
 464 AC_ARG_WITH(mgl,           [  --with-mgl              use SciTech MGL], [wxUSE_MGL="$withval" wxUSE_UNIVERSAL="yes" CACHE_MGL=1 TOOLKIT_GIVEN=1])
 465 AC_ARG_WITH(directfb,      [  --with-directfb         use DirectFB], [wxUSE_DFB="$withval" wxUSE_UNIVERSAL="yes" CACHE_DFB=1 TOOLKIT_GIVEN=1])
 466 AC_ARG_WITH(microwin,      [  --with-microwin         use MicroWindows], [wxUSE_MICROWIN="$withval" CACHE_MICROWIN=1 TOOLKIT_GIVEN=1])
 467 AC_ARG_WITH(x11,           [  --with-x11              use X11], [wxUSE_X11="$withval" wxUSE_UNIVERSAL="yes" CACHE_X11=1 TOOLKIT_GIVEN=1])
 468 WX_ARG_ENABLE(nanox,       [  --enable-nanox          use NanoX], wxUSE_NANOX)
 469
 470 AC_ARG_ENABLE(gtk2,        [  --disable-gtk2          use GTK+ 1.2 instead of 2.0], [wxUSE_GTK2="$enableval"])
 471 WX_ARG_ENABLE(gpe,         [  --enable-gpe            use GNOME PDA Environment features if possible], wxUSE_GPE)
 472
 473 dnl check that no more than one toolkit is given and that if none are given that
 474 dnl we have a default one
 475
 476 AC_MSG_CHECKING(for toolkit)
 477
 478
 479
 480 # In Wine, we need to default to MSW, not GTK or MOTIF
 481 if test "$wxUSE_WINE" = "yes"; then
 482     DEFAULT_DEFAULT_wxUSE_GTK=0
 483     DEFAULT_DEFAULT_wxUSE_MOTIF=0
 484     DEFAULT_DEFAULT_wxUSE_MSW=1
 485     wxUSE_SHARED=no
 486     CC=${CC:-winegcc}
 487     CXX=${CXX:-wineg++}
 488 fi
 489
 490
 491 if test "$wxUSE_GUI" = "yes"; then
 492
 493     if test "$USE_BEOS" = 1; then
 494         AC_MSG_ERROR([BeOS GUI is not supported yet, use --disable-gui])
 495     fi
 496
 497     if test "$TOOLKIT_GIVEN" = 1; then
 498       dnl convert "yes", "any" or a number to 1 and "no" to 0
 499       for toolkit in $ALL_TOOLKITS; do
 500         var=wxUSE_$toolkit
 501         eval "value=\$${var}"
 502         if test "x$value" = "xno"; then
 503           eval "$var=0"
 504         elif test "x$value" != "x"; then
 505           eval "$var=1"
 506         fi
 507
 508         if test "x$value" != "x" -a "x$value" != "xyes" -a "x$value" != "xno"; then
 509           eval "wx${toolkit}_VERSION=$value"
 510         fi
 511       done
 512     else
 513       dnl try to guess the most apropriate toolkit for this platform
 514       for toolkit in $ALL_TOOLKITS; do
 515         var=DEFAULT_DEFAULT_wxUSE_$toolkit
 516         eval "wxUSE_$toolkit=\$${var}"
 517       done
 518     fi
 519
 520     dnl we suppose that expr is available (maybe there is a better way to do
 521     dnl this? what about using ALL_TOOLKITS? TODO)
 522     NUM_TOOLKITS=`expr ${wxUSE_COCOA:-0} + ${wxUSE_GTK:-0} + ${wxUSE_OSX_CARBON:-0} \
 523                   + ${wxUSE_OSX_COCOA:-0} + ${wxUSE_MGL:-0} + ${wxUSE_DFB:-0} \
 524                   + ${wxUSE_MICROWIN:-0} + ${wxUSE_MOTIF:-0} + ${wxUSE_MSW:-0} + ${wxUSE_X11:-0}`
 525
 526     dnl Allow wxUSE_PM only for OS/2 with EMX.
 527     case "${host}" in
 528       *-pc-os2_emx | *-pc-os2-emx )
 529         NUM_TOOLKITS=`expr ${NUM_TOOLKITS} + ${wxUSE_PM:-0}`
 530     esac
 531
 532     case "$NUM_TOOLKITS" in
 533       1)
 534       ;;
 535       0)
 536         AC_MSG_ERROR(Please specify a toolkit -- cannot determine the default for ${host})
 537       ;;
 538       *)
 539         AC_MSG_ERROR(Please specify at most one toolkit)
 540     esac
 541
 542     # to be removed when --disable-gtk2 isn't needed
 543     if test "x$wxUSE_GTK2" = "xyes"; then
 544         wxGTK_VERSION=2
 545     elif test "x$wxUSE_GTK2" = "xno"; then
 546         wxGTK_VERSION=1
 547     fi
 548
 549     for toolkit in $ALL_TOOLKITS; do
 550         var=wxUSE_$toolkit
 551         eval "value=\$${var}"
 552         if test "$value" = 1; then
 553           toolkit_echo=`echo $toolkit | tr '[[A-Z]]' '[[a-z]]'`
 554           AC_MSG_RESULT($toolkit_echo)
 555         fi
 556     done
 557 else
 558     if test "x$host_alias" != "x"; then
 559         AC_MSG_RESULT(base ($host_alias hosted) only)
 560     else
 561         AC_MSG_RESULT(base only)
 562     fi
 563 fi
 564
 565 wxUSE_MAC=0
 566 if test "$wxUSE_OSX_CARBON" = 1 -o "$wxUSE_OSX_COCOA" = 1; then
 567     wxUSE_MAC=1
 568 fi
 569
 570 dnl ---------------------------------------------------------------------------
 571 dnl external libraries
 572 dnl ---------------------------------------------------------------------------
 573
 574 WX_ARG_SYS_WITH(libpng,    [  --with-libpng           use libpng (PNG image format)], wxUSE_LIBPNG)
 575 WX_ARG_SYS_WITH(libjpeg,   [  --with-libjpeg          use libjpeg (JPEG file format)], wxUSE_LIBJPEG)
 576 WX_ARG_SYS_WITH(libtiff,   [  --with-libtiff          use libtiff (TIFF file format)], wxUSE_LIBTIFF)
 577 WX_ARG_SYS_WITH(libxpm,    [  --with-libxpm           use libxpm (XPM file format)], wxUSE_LIBXPM)
 578 WX_ARG_WITH(libiconv,      [  --with-libiconv         use libiconv (character conversion)], wxUSE_LIBICONV)
 579 WX_ARG_WITH(libmspack,     [  --with-libmspack        use libmspack (CHM help files loading)], wxUSE_LIBMSPACK)
 580 WX_ARG_WITHOUT(gtkprint,   [  --without-gtkprint      don't use GTK printing support], wxUSE_GTKPRINT)
 581 WX_ARG_WITHOUT(gnomeprint, [  --without-gnomeprint    don't use GNOME printing libraries], wxUSE_LIBGNOMEPRINT)
 582 WX_ARG_WITH(gnomevfs,      [  --with-gnomevfs         use GNOME VFS for associating MIME types], wxUSE_LIBGNOMEVFS)
 583 WX_ARG_WITH(hildon,        [  --with-hildon           use Hildon framework for Nokia 770/800/810], wxUSE_LIBHILDON)
 584 WX_ARG_WITH(opengl,        [  --with-opengl           use OpenGL (or Mesa)], wxUSE_OPENGL)
 585
 586 fi
 587 dnl for GUI only
 588
 589 WX_ARG_WITH(dmalloc,       [  --with-dmalloc          use dmalloc library (http://dmalloc.com/)], wxUSE_DMALLOC)
 590 WX_ARG_WITH(sdl,           [  --with-sdl              use SDL for audio on Unix], wxUSE_LIBSDL)
 591 WX_ARG_SYS_WITH(regex,     [  --with-regex            enable support for wxRegEx class], wxUSE_REGEX)
 592 WX_ARG_SYS_WITH(zlib,      [  --with-zlib             use zlib for LZW compression], wxUSE_ZLIB)
 593 WX_ARG_SYS_WITH(expat,     [  --with-expat            enable XML support using expat parser], wxUSE_EXPAT)
 594
 595 AC_MSG_CHECKING([for --with-macosx-sdk])
 596 AC_ARG_WITH(macosx-sdk,    [  --with-macosx-sdk=PATH  use an OS X SDK at PATH], [
 597         wxUSE_MACOSX_SDK=$withval
 598         wx_cv_use_macosx_sdk="wxUSE_MACOSX_SDK=$withval"
 599     ])
 600 AC_MSG_RESULT([$wxUSE_MACOSX_SDK])
 601
 602 AC_MSG_CHECKING([for --with-macosx-version-min])
 603 AC_ARG_WITH(macosx-version-min,    [  --with-macosx-version-min=VER   build binaries which require at least this OS X version], [
 604         wxUSE_MACOSX_VERSION_MIN=$withval
 605         wx_cv_use_macosx_version_min="wxUSE_MACOSX_VERSION_MIN=$withval"
 606     ])
 607 AC_MSG_RESULT([$wxUSE_MACOSX_VERSION_MIN])
 608
 609 dnl ---------------------------------------------------------------------------
 610 dnl debugging options
 611 dnl ---------------------------------------------------------------------------
 612
 613 dnl don't use WX_ARG_ENABLE as it just gets in the way instead of helping with
 614 dnl this rather unusual option
 615 AC_MSG_CHECKING([for --enable-debug])
 616 AC_ARG_ENABLE(debug,       [  --enable-debug          build library for debugging],
 617     [
 618         if test "$enableval" = yes; then
 619             wxUSE_DEBUG=yes
 620         elif test "$enableval" = no; then
 621             wxUSE_DEBUG=no
 622         elif test "$enableval" = max; then
 623             wxUSE_DEBUG=yes
 624             WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -DwxDEBUG_LEVEL=2"
 625         else
 626             AC_MSG_ERROR([Invalid --enable-debug value, must be yes, no or max])
 627         fi
 628     ],
 629     wxUSE_DEBUG=default
 630 )
 631
 632 case "$wxUSE_DEBUG" in
 633     yes)
 634         dnl build the library for debugging: enable debugging code and generate
 635         dnl the debug information for the library itself
 636         DEFAULT_wxUSE_DEBUG_FLAG=yes
 637         DEFAULT_wxUSE_DEBUG_INFO=yes
 638
 639         dnl also disable optimizations by default if --enable-debug was used
 640         dnl (this can still be overridden by an explicit --enable-optimise)
 641         DEFAULT_wxUSE_OPTIMISE=no
 642         ;;
 643
 644     no)
 645         dnl --disable-debug is equivalent to both --disable-debug_flag and
 646         dnl --disable-debug_info
 647         DEFAULT_wxUSE_DEBUG_FLAG=no
 648         DEFAULT_wxUSE_DEBUG_INFO=no
 649         ;;
 650
 651     default)
 652         dnl the library is built with debugging support by default but without
 653         dnl debug information as this requires much, much more disk space
 654         DEFAULT_wxUSE_DEBUG_FLAG=yes
 655         DEFAULT_wxUSE_DEBUG_INFO=no
 656         ;;
 657 esac
 658
 659 WX_ARG_DISABLE(debug_flag,   [  --disable-debug_flag    disable all debugging support], wxUSE_DEBUG_FLAG)
 660 WX_ARG_ENABLE(debug_info,    [  --enable-debug_info     generate debug information], wxUSE_DEBUG_INFO)
 661
 662 dnl enabled if just --enable-debug_{flag,info} was
 663 dnl
 664 dnl in any case, only set the default value and allow overriding it with an
 665
 666 WX_ARG_ENABLE(debug_gdb,     [  --enable-debug_gdb      create code with extra GDB debugging information], wxUSE_DEBUG_GDB)
 667 WX_ARG_ENABLE(debug_cntxt,   [  --enable-debug_cntxt    obsolete, don't use: use wxDebugContext], wxUSE_DEBUG_CONTEXT)
 668 WX_ARG_ENABLE(mem_tracing,   [  --enable-mem_tracing    obsolete, don't use: create code with memory tracing], wxUSE_MEM_TRACING)
 669
 670 dnl ---------------------------------------------------------------------------
 671 dnl global compile options
 672 dnl ---------------------------------------------------------------------------
 673
 674 WX_ARG_DISABLE(shared,     [  --disable-shared        create static library instead of shared], wxUSE_SHARED)
 675 WX_ARG_ENABLE(stl,         [  --enable-stl            use STL for containers], wxUSE_STL)
 676 WX_ARG_ENABLE(std_iostreams, [  --enable-std_iostreams  use standard C++ stream classes], wxUSE_STD_IOSTREAM)
 677 WX_ARG_ENABLE(std_string,    [  --enable-std_string     use standard C++ string classes], wxUSE_STD_STRING)
 678 WX_ARG_DISABLE(unicode,      [  --disable-unicode       compile without Unicode support], wxUSE_UNICODE)
 679 WX_ARG_ENABLE(mslu,          [  --enable-mslu           use MS Layer for Unicode on Windows 9x (Win32 only)], wxUSE_UNICODE_MSLU)
 680 WX_ARG_ENABLE_PARAM(utf8,    [  --enable-utf8           use UTF-8 representation for strings (Unix only)], wxUSE_UNICODE_UTF8)
 681 WX_ARG_ENABLE(utf8only,      [  --enable-utf8only       only support UTF-8 locales in UTF-8 build (Unix only)], wxUSE_UNICODE_UTF8_LOCALE)
 682 WX_ARG_ENABLE(extended_rtti, [  --enable-extended_rtti  use extended RTTI (XTI)], wxUSE_EXTENDED_RTTI)
 683 if test "$USE_OS2" = 1; then
 684     DEFAULT_wxUSE_OMF=no
 685     WX_ARG_ENABLE(omf,     [  --enable-omf            use OMF object format], wxUSE_OMF)
 686 fi
 687
 688 WX_ARG_DISABLE(optimise,   [  --disable-optimise      compile without optimisations], wxUSE_OPTIMISE)
 689
 690 WX_ARG_ENABLE(profile,       [  --enable-profile        create code with profiling information], wxUSE_PROFILE)
 691 WX_ARG_ENABLE(no_rtti,       [  --enable-no_rtti        create code without RTTI information], wxUSE_NO_RTTI)
 692 WX_ARG_ENABLE(no_exceptions, [  --enable-no_exceptions  create code without C++ exceptions handling], wxUSE_NO_EXCEPTIONS)
 693 WX_ARG_ENABLE(permissive,    [  --enable-permissive     compile code disregarding strict ANSI], wxUSE_PERMISSIVE)
 694 WX_ARG_ENABLE(no_deps,       [  --enable-no_deps        create code without dependency information], wxUSE_NO_DEPS)
 695 WX_ARG_DISABLE(vararg_macros,[  --disable-vararg_macros don't use vararg macros, even if they are supported], wxUSE_VARARG_MACROS)
 696 WX_ARG_ENABLE_PARAM(universal_binary, [[  --enable-universal_binary  create Mac PowerPC and Intel Universal binary]], wxUSE_UNIVERSAL_BINARY)
 697
 698 WX_ARG_ENABLE(compat26,      [  --enable-compat26       enable wxWidgets 2.6 compatibility], WXWIN_COMPATIBILITY_2_6)
 699 WX_ARG_DISABLE(compat28,     [  --disable-compat28      disable wxWidgets 2.8 compatibility], WXWIN_COMPATIBILITY_2_8)
 700
 701 WX_ARG_DISABLE(rpath,        [  --disable-rpath         disable use of rpath for uninstalled builds], wxUSE_RPATH)
 702
 703 WX_ARG_ENABLE(objc_uniquifying,[  --enable-objc_uniquifying enable Objective-C class name uniquifying], wxUSE_OBJC_UNIQUIFYING)
 704
 705 WX_ARG_DISABLE(visibility,   [  --disable-visibility    disable use of ELF symbols visibility even if supported], wxUSE_VISIBILITY)
 706 WX_ARG_DISABLE(tls,          [  --disable-tls           disable use of compiler TLS support], wxUSE_COMPILER_TLS)
 707
 708 dnl ---------------------------------------------------------------------------
 709 dnl optional non GUI features
 710 dnl ---------------------------------------------------------------------------
 711
 712 WX_ARG_FEATURE(intl,          [  --enable-intl           use internationalization system], wxUSE_INTL)
 713 WX_ARG_FEATURE(xlocale,       [  --enable-xlocale        use x-locale support (requires wxLocale)], wxUSE_XLOCALE)
 714 WX_ARG_FEATURE(config,        [  --enable-config         use wxConfig (and derived) classes], wxUSE_CONFIG)
 715
 716 WX_ARG_FEATURE(protocols,     [  --enable-protocols      use wxProtocol and derived classes], wxUSE_PROTOCOL)
 717 WX_ARG_FEATURE(ftp,           [  --enable-ftp            use wxFTP (requires wxProtocol], wxUSE_PROTOCOL_FTP)
 718 WX_ARG_FEATURE(http,          [  --enable-http           use wxHTTP (requires wxProtocol], wxUSE_PROTOCOL_HTTP)
 719 WX_ARG_FEATURE(fileproto,     [  --enable-fileproto      use wxFileProto class (requires wxProtocol], wxUSE_PROTOCOL_FILE)
 720 WX_ARG_FEATURE(sockets,       [  --enable-sockets        use socket/network classes], wxUSE_SOCKETS)
 721 WX_ARG_FEATURE(ipv6,          [  --enable-ipv6           enable IPv6 support in wxSocket], wxUSE_IPV6)
 722 WX_ARG_FEATURE(ole,           [  --enable-ole            use OLE classes (Win32 only)], wxUSE_OLE)
 723 WX_ARG_FEATURE(dataobj,       [  --enable-dataobj        use data object classes], wxUSE_DATAOBJ)
 724
 725 WX_ARG_FEATURE(ipc,           [  --enable-ipc            use interprocess communication (wxSocket etc.)], wxUSE_IPC)
 726
 727 WX_ARG_FEATURE(baseevtloop,   [  --enable-baseevtloop    use event loop in console programs too], wxUSE_CONSOLE_EVENTLOOP)
 728 WX_ARG_FEATURE(epollloop,     [  --enable-epollloop      use wxEpollDispatcher class (Linux only)], wxUSE_EPOLL_DISPATCHER)
 729 WX_ARG_FEATURE(selectloop,    [  --enable-selectloop     use wxSelectDispatcher class], wxUSE_SELECT_DISPATCHER)
 730
 731 dnl please keep the settings below in alphabetical order
 732 WX_ARG_FEATURE(any,           [  --enable-any            use wxAny class], wxUSE_ANY)
 733 WX_ARG_FEATURE(apple_ieee,    [  --enable-apple_ieee     use the Apple IEEE codec], wxUSE_APPLE_IEEE)
 734 WX_ARG_FEATURE(arcstream,     [  --enable-arcstream      use wxArchive streams], wxUSE_ARCHIVE_STREAMS)
 735 WX_ARG_FEATURE(base64,        [  --enable-base64         use base64 encoding/decoding functions], wxUSE_BASE64)
 736 WX_ARG_FEATURE(backtrace,     [  --enable-backtrace      use wxStackWalker class for getting backtraces], wxUSE_STACKWALKER)
 737 WX_ARG_FEATURE(catch_segvs,   [  --enable-catch_segvs    catch signals in wxApp::OnFatalException (Unix only)], wxUSE_ON_FATAL_EXCEPTION)
 738 WX_ARG_FEATURE(cmdline,       [  --enable-cmdline        use wxCmdLineParser class], wxUSE_CMDLINE_PARSER)
 739 WX_ARG_FEATURE(datetime,      [  --enable-datetime       use wxDateTime class], wxUSE_DATETIME)
 740 WX_ARG_FEATURE(debugreport,   [  --enable-debugreport    use wxDebugReport class], wxUSE_DEBUGREPORT)
 741 WX_ARG_FEATURE(dialupman,     [  --enable-dialupman      use dialup network classes], wxUSE_DIALUP_MANAGER)
 742 WX_ARG_FEATURE(dynlib,        [  --enable-dynlib         use wxLibrary class for DLL loading], wxUSE_DYNLIB_CLASS)
 743 WX_ARG_FEATURE(dynamicloader, [  --enable-dynamicloader  use (new) wxDynamicLibrary class], wxUSE_DYNAMIC_LOADER)
 744 WX_ARG_FEATURE(exceptions,    [  --enable-exceptions     build exception-safe library], wxUSE_EXCEPTIONS)
 745 WX_ARG_FEATURE(ffile,         [  --enable-ffile          use wxFFile class], wxUSE_FFILE)
 746 WX_ARG_FEATURE(file,          [  --enable-file           use wxFile class], wxUSE_FILE)
 747 WX_ARG_FEATURE(filesystem,    [  --enable-filesystem     use virtual file systems classes], wxUSE_FILESYSTEM)
 748 WX_ARG_FEATURE(fontenum,      [  --enable-fontenum       use wxFontEnumerator class], wxUSE_FONTENUM)
 749 WX_ARG_FEATURE(fontmap,       [  --enable-fontmap        use font encodings conversion classes], wxUSE_FONTMAP)
 750 WX_ARG_FEATURE(fs_archive,    [  --enable-fs_archive     use virtual archive filesystems], wxUSE_FS_ARCHIVE)
 751 WX_ARG_FEATURE(fs_inet,       [  --enable-fs_inet        use virtual HTTP/FTP filesystems], wxUSE_FS_INET)
 752 WX_ARG_FEATURE(fs_zip,        [  --enable-fs_zip         now replaced by fs_archive], wxUSE_FS_ZIP)
 753 WX_ARG_FEATURE(geometry,      [  --enable-geometry       use geometry class], wxUSE_GEOMETRY)
 754 WX_ARG_FEATURE(log,           [  --enable-log            use logging system], wxUSE_LOG)
 755 WX_ARG_FEATURE(longlong,      [  --enable-longlong       use wxLongLong class], wxUSE_LONGLONG)
 756 WX_ARG_FEATURE(mimetype,      [  --enable-mimetype       use wxMimeTypesManager], wxUSE_MIMETYPE)
 757 WX_ARG_FEATURE(printfposparam,[  --enable-printfposparam use wxVsnprintf() which supports positional parameters], wxUSE_PRINTF_POS_PARAMS)
 758 WX_ARG_FEATURE(snglinst,      [  --enable-snglinst       use wxSingleInstanceChecker class], wxUSE_SNGLINST_CHECKER)
 759 WX_ARG_FEATURE(sound,         [  --enable-sound          use wxSound class], wxUSE_SOUND)
 760 WX_ARG_FEATURE(stdpaths,      [  --enable-stdpaths       use wxStandardPaths class], wxUSE_STDPATHS)
 761 WX_ARG_FEATURE(stopwatch,     [  --enable-stopwatch      use wxStopWatch class], wxUSE_STOPWATCH)
 762 WX_ARG_FEATURE(streams,       [  --enable-streams        use wxStream etc classes], wxUSE_STREAMS)
 763 WX_ARG_FEATURE(system_options,[  --enable-sysoptions     use wxSystemOptions], wxUSE_SYSTEM_OPTIONS)
 764 WX_ARG_FEATURE(tarstream,     [  --enable-tarstream      use wxTar streams], wxUSE_TARSTREAM)
 765 WX_ARG_FEATURE(textbuf,       [  --enable-textbuf        use wxTextBuffer class], wxUSE_TEXTBUFFER)
 766 WX_ARG_FEATURE(textfile,      [  --enable-textfile       use wxTextFile class], wxUSE_TEXTFILE)
 767 WX_ARG_FEATURE(timer,         [  --enable-timer          use wxTimer class], wxUSE_TIMER)
 768 WX_ARG_FEATURE(variant,       [  --enable-variant        use wxVariant class], wxUSE_VARIANT)
 769 WX_ARG_FEATURE(zipstream,     [  --enable-zipstream      use wxZip streams], wxUSE_ZIPSTREAM)
 770
 771 dnl URL-related classes
 772 WX_ARG_FEATURE(url,           [  --enable-url            use wxURL class], wxUSE_URL)
 773 WX_ARG_FEATURE(protocol,      [  --enable-protocol       use wxProtocol class], wxUSE_PROTOCOL)
 774 WX_ARG_FEATURE(protocol_http, [  --enable-protocol-http  HTTP support in wxProtocol], wxUSE_PROTOCOL_HTTP)
 775 WX_ARG_FEATURE(protocol_ftp,  [  --enable-protocol-ftp   FTP support in wxProtocol], wxUSE_PROTOCOL_FTP)
 776 WX_ARG_FEATURE(protocol_file, [  --enable-protocol-file  FILE support in wxProtocol], wxUSE_PROTOCOL_FILE)
 777
 778 WX_ARG_FEATURE(threads,     [  --enable-threads        use threads], wxUSE_THREADS)
 779
 780 WX_ARG_ENABLE(iniconf,      [  --enable-iniconf        use wxIniConfig (Win32 only)], wxUSE_INICONF)
 781 WX_ARG_FEATURE(regkey,      [  --enable-regkey         use wxRegKey class (Win32 only)], wxUSE_REGKEY)
 782
 783 if test "$wxUSE_GUI" = "yes"; then
 784
 785 dnl ---------------------------------------------------------------------------
 786 dnl optional "big" GUI features
 787 dnl ---------------------------------------------------------------------------
 788
 789 WX_ARG_FEATURE(docview,     [  --enable-docview        use document view architecture], wxUSE_DOC_VIEW_ARCHITECTURE)
 790 WX_ARG_FEATURE(help,        [  --enable-help           use help subsystem], wxUSE_HELP)
 791 WX_ARG_FEATURE(mshtmlhelp,  [  --enable-mshtmlhelp     use MS HTML Help (win32)], wxUSE_MS_HTML_HELP)
 792 WX_ARG_FEATURE(html,        [  --enable-html           use wxHTML sub-library], wxUSE_HTML)
 793 WX_ARG_FEATURE(htmlhelp,    [  --enable-htmlhelp       use wxHTML-based help], wxUSE_WXHTML_HELP)
 794 WX_ARG_FEATURE(xrc,         [  --enable-xrc            use XRC resources sub-library], wxUSE_XRC)
 795 WX_ARG_FEATURE(aui,         [  --enable-aui            use AUI docking library], wxUSE_AUI)
 796 WX_ARG_FEATURE(propgrid,    [  --enable-propgrid       use wxPropertyGrid library], wxUSE_PROPGRID)
 797 WX_ARG_FEATURE(ribbon,      [  --enable-ribbon         use wxRibbon library], wxUSE_RIBBON)
 798 WX_ARG_FEATURE(stc,         [  --enable-stc            use wxStyledTextCtrl library], wxUSE_STC)
 799 WX_ARG_FEATURE(constraints, [  --enable-constraints    use layout-constraints system], wxUSE_CONSTRAINTS)
 800 WX_ARG_FEATURE(loggui,      [  --enable-loggui         use standard GUI logger], wxUSE_LOGGUI)
 801 WX_ARG_FEATURE(logwin,      [  --enable-logwin         use wxLogWindow], wxUSE_LOGWINDOW)
 802 WX_ARG_FEATURE(logdialog,   [  --enable-logdialog      use wxLogDialog], wxUSE_LOGDIALOG)
 803 WX_ARG_FEATURE(mdi,         [  --enable-mdi            use multiple document interface architecture], wxUSE_MDI)
 804 WX_ARG_FEATURE(mdidoc,      [  --enable-mdidoc         use docview architecture with MDI], wxUSE_MDI_ARCHITECTURE)
 805 WX_ARG_FEATURE(mediactrl,   [  --enable-mediactrl      use wxMediaCtrl class], wxUSE_MEDIACTRL)
 806 WX_ARG_FEATURE(gstreamer8,  [  --enable-gstreamer8     force GStreamer 0.8 instead of 0.10 with the wxMediaCtrl class on unix], wxUSE_GSTREAMER8)
 807 WX_ARG_FEATURE(webkit,      [  --enable-webkit         use wxWebKitCtrl (Mac)], wxUSE_WEBKIT)
 808 WX_ARG_FEATURE(richtext,    [  --enable-richtext       use wxRichTextCtrl], wxUSE_RICHTEXT)
 809 WX_ARG_FEATURE(graphics_ctx,[  --enable-graphics_ctx   use graphics context 2D drawing API], wxUSE_GRAPHICS_CONTEXT)
 810 WX_ARG_FEATURE(postscript,  [  --enable-postscript     use wxPostscriptDC device context (default for gtk+)], wxUSE_POSTSCRIPT)
 811 WX_ARG_FEATURE(printarch,   [  --enable-printarch      use printing architecture], wxUSE_PRINTING_ARCHITECTURE)
 812 WX_ARG_FEATURE(svg,         [  --enable-svg            use wxSVGFileDC device context], wxUSE_SVG)
 813
 814 dnl ---------------------------------------------------------------------------
 815 dnl IPC &c
 816 dnl ---------------------------------------------------------------------------
 817
 818 WX_ARG_FEATURE(clipboard,   [  --enable-clipboard      use wxClipboard class], wxUSE_CLIPBOARD)
 819 WX_ARG_FEATURE(dnd,         [  --enable-dnd            use Drag'n'Drop classes], wxUSE_DRAG_AND_DROP)
 820 WX_ARG_FEATURE(metafile,    [  --enable-metafile       use win32 metafiles], wxUSE_METAFILE)
 821
 822 dnl ---------------------------------------------------------------------------
 823 dnl optional GUI controls (in alphabetical order except the first one)
 824 dnl ---------------------------------------------------------------------------
 825
 826 dnl don't set DEFAULT_wxUSE_XXX below if the option is not specified
 827 DEFAULT_wxUSE_CONTROLS=none
 828 WX_ARG_DISABLE(controls,    [  --disable-controls      disable compilation of all standard controls], wxUSE_CONTROLS)
 829
 830 dnl even with --disable-controls, some may be enabled by an explicit
 831 dnl --enable-<control> later on the command line -- but by default all will be
 832 dnl disabled
 833 if test "$wxUSE_CONTROLS" = "no"; then
 834     DEFAULT_wxUSE_ACCEL=no
 835     DEFAULT_wxUSE_ANIMATIONCTRL=no
 836     DEFAULT_wxUSE_BMPBUTTON=no
 837     DEFAULT_wxUSE_BUTTON=no
 838     DEFAULT_wxUSE_CALCTRL=no
 839     DEFAULT_wxUSE_CARET=no
 840     DEFAULT_wxUSE_CHECKBOX=no
 841     DEFAULT_wxUSE_CHECKLISTBOX=no
 842     DEFAULT_wxUSE_CHOICE=no
 843     DEFAULT_wxUSE_CHOICEBOOK=no
 844     DEFAULT_wxUSE_COLLPANE=no
 845     DEFAULT_wxUSE_COLOURPICKERCTRL=no
 846     DEFAULT_wxUSE_COMBOBOX=no
 847     DEFAULT_wxUSE_COMBOBOX=no
 848     DEFAULT_wxUSE_DATAVIEWCTRL=no
 849     DEFAULT_wxUSE_DATEPICKCTRL=no
 850     DEFAULT_wxUSE_DETECT_SM=no
 851     DEFAULT_wxUSE_DIRPICKERCTRL=no
 852     DEFAULT_wxUSE_DISPLAY=no
 853     DEFAULT_wxUSE_FILECTRL=no
 854     DEFAULT_wxUSE_FILEPICKERCTRL=no
 855     DEFAULT_wxUSE_FONTPICKERCTRL=no
 856     DEFAULT_wxUSE_GAUGE=no
 857     DEFAULT_wxUSE_GRID=no
 858     DEFAULT_wxUSE_HEADERCTRL=no
 859     DEFAULT_wxUSE_HYPERLINKCTRL=no
 860     DEFAULT_wxUSE_IMAGLIST=no
 861     DEFAULT_wxUSE_LISTBOOK=no
 862     DEFAULT_wxUSE_LISTBOX=no
 863     DEFAULT_wxUSE_LISTCTRL=no
 864     DEFAULT_wxUSE_NOTEBOOK=no
 865     DEFAULT_wxUSE_POPUPWIN=no
 866     DEFAULT_wxUSE_RADIOBOX=no
 867     DEFAULT_wxUSE_RADIOBTN=no
 868     DEFAULT_wxUSE_REARRANGECTRL=no
 869     DEFAULT_wxUSE_SASH=no
 870     DEFAULT_wxUSE_SCROLLBAR=no
 871     DEFAULT_wxUSE_SEARCHCTRL=no
 872     DEFAULT_wxUSE_SLIDER=no
 873     DEFAULT_wxUSE_SPINBTN=no
 874     DEFAULT_wxUSE_SPINCTRL=no
 875     DEFAULT_wxUSE_SPLITTER=no
 876     DEFAULT_wxUSE_STATBMP=no
 877     DEFAULT_wxUSE_STATBOX=no
 878     DEFAULT_wxUSE_STATLINE=no
 879     DEFAULT_wxUSE_STATUSBAR=no
 880     DEFAULT_wxUSE_TIPWINDOW=no
 881     DEFAULT_wxUSE_TOGGLEBTN=no
 882     DEFAULT_wxUSE_TOOLBAR=no
 883     DEFAULT_wxUSE_TOOLBAR_NATIVE=no
 884     DEFAULT_wxUSE_TOOLBOOK=no
 885     DEFAULT_wxUSE_TOOLTIPS=no
 886     DEFAULT_wxUSE_TREEBOOK=no
 887     DEFAULT_wxUSE_TREECTRL=no
 888 fi
 889
 890 dnl please keep the settings below in alphabetical order
 891 WX_ARG_FEATURE(accel,       [  --enable-accel          use accelerators], wxUSE_ACCEL)
 892 WX_ARG_FEATURE(animatectrl, [  --enable-animatectrl    use wxAnimationCtrl class], wxUSE_ANIMATIONCTRL)
 893 WX_ARG_FEATURE(bmpbutton,   [  --enable-bmpbutton      use wxBitmapButton class], wxUSE_BMPBUTTON)
 894 WX_ARG_FEATURE(bmpcombobox, [  --enable-bmpcombobox    use wxBitmapComboBox class], wxUSE_BITMAPCOMBOBOX)
 895 WX_ARG_FEATURE(button,      [  --enable-button         use wxButton class], wxUSE_BUTTON)
 896 WX_ARG_FEATURE(calendar,    [  --enable-calendar       use wxCalendarCtrl class], wxUSE_CALCTRL)
 897 WX_ARG_FEATURE(caret,       [  --enable-caret          use wxCaret class], wxUSE_CARET)
 898 WX_ARG_FEATURE(checkbox,    [  --enable-checkbox       use wxCheckBox class], wxUSE_CHECKBOX)
 899 WX_ARG_FEATURE(checklst,    [  --enable-checklst       use wxCheckListBox (listbox with checkboxes) class], wxUSE_CHECKLST)
 900 WX_ARG_FEATURE(choice,      [  --enable-choice         use wxChoice class], wxUSE_CHOICE)
 901 WX_ARG_FEATURE(choicebook,  [  --enable-choicebook     use wxChoicebook class], wxUSE_CHOICEBOOK)
 902 WX_ARG_FEATURE(collpane,    [  --enable-collpane       use wxCollapsiblePane class], wxUSE_COLLPANE)
 903 WX_ARG_FEATURE(colourpicker,[  --enable-colourpicker   use wxColourPickerCtrl class], wxUSE_COLOURPICKERCTRL)
 904 WX_ARG_FEATURE(combobox,    [  --enable-combobox       use wxComboBox class], wxUSE_COMBOBOX)
 905 WX_ARG_FEATURE(comboctrl,   [  --enable-comboctrl      use wxComboCtrl class], wxUSE_COMBOCTRL)
 906 WX_ARG_FEATURE(dataviewctrl,[  --enable-dataviewctrl   use wxDataViewCtrl class], wxUSE_DATAVIEWCTRL)
 907 WX_ARG_FEATURE(datepick,    [  --enable-datepick       use wxDatePickerCtrl class], wxUSE_DATEPICKCTRL)
 908 WX_ARG_FEATURE(detect_sm,   [  --enable-detect_sm      use code to detect X11 session manager], wxUSE_DETECT_SM)
 909 WX_ARG_FEATURE(dirpicker,   [  --enable-dirpicker      use wxDirPickerCtrl class], wxUSE_DIRPICKERCTRL)
 910 WX_ARG_FEATURE(display,     [  --enable-display        use wxDisplay class], wxUSE_DISPLAY)
 911 WX_ARG_FEATURE(editablebox, [  --enable-editablebox    use wxEditableListBox class], wxUSE_EDITABLELISTBOX)
 912 WX_ARG_FEATURE(filectrl,    [  --enable-filectrl       use wxFileCtrl class], wxUSE_FILECTRL)
 913 WX_ARG_FEATURE(filepicker,  [  --enable-filepicker     use wxFilePickerCtrl class], wxUSE_FILEPICKERCTRL)
 914 WX_ARG_FEATURE(fontpicker,  [  --enable-fontpicker     use wxFontPickerCtrl class], wxUSE_FONTPICKERCTRL)
 915 WX_ARG_FEATURE(gauge,       [  --enable-gauge          use wxGauge class], wxUSE_GAUGE)
 916 WX_ARG_FEATURE(grid,        [  --enable-grid           use wxGrid class], wxUSE_GRID)
 917 WX_ARG_FEATURE(headerctrl,  [  --enable-headerctrl     use wxHeaderCtrl class], wxUSE_HEADERCTRL)
 918 WX_ARG_FEATURE(hyperlink,   [  --enable-hyperlink      use wxHyperlinkCtrl class], wxUSE_HYPERLINKCTRL)
 919 WX_ARG_FEATURE(imaglist,    [  --enable-imaglist       use wxImageList class], wxUSE_IMAGLIST)
 920 WX_ARG_FEATURE(infobar,     [  --enable-infobar        use wxInfoBar class], wxUSE_INFOBAR)
 921 WX_ARG_FEATURE(listbook,    [  --enable-listbook       use wxListbook class], wxUSE_LISTBOOK)
 922 WX_ARG_FEATURE(listbox,     [  --enable-listbox        use wxListBox class], wxUSE_LISTBOX)
 923 WX_ARG_FEATURE(listctrl,    [  --enable-listctrl       use wxListCtrl class], wxUSE_LISTCTRL)
 924 WX_ARG_FEATURE(notebook,    [  --enable-notebook       use wxNotebook class], wxUSE_NOTEBOOK)
 925 WX_ARG_FEATURE(notifmsg,    [  --enable-notifmsg       use wxNotificationMessage class], wxUSE_NOTIFICATION_MESSAGE)
 926 WX_ARG_FEATURE(odcombobox,  [  --enable-odcombobox     use wxOwnerDrawnComboBox class], wxUSE_ODCOMBOBOX)
 927 WX_ARG_FEATURE(popupwin,    [  --enable-popupwin       use wxPopUpWindow class], wxUSE_POPUPWIN)
 928 WX_ARG_FEATURE(radiobox,    [  --enable-radiobox       use wxRadioBox class], wxUSE_RADIOBOX)
 929 WX_ARG_FEATURE(radiobtn,    [  --enable-radiobtn       use wxRadioButton class], wxUSE_RADIOBTN)
 930 WX_ARG_FEATURE(rearrangectrl,[  --enable-rearrangectrl  use wxRearrangeList/Ctrl/Dialog], wxUSE_REARRANGECTRL)
 931 WX_ARG_FEATURE(sash,        [  --enable-sash           use wxSashWindow class], wxUSE_SASH)
 932 WX_ARG_FEATURE(scrollbar,   [  --enable-scrollbar      use wxScrollBar class and scrollable windows], wxUSE_SCROLLBAR)
 933 WX_ARG_FEATURE(searchctrl,  [  --enable-searchctrl     use wxSearchCtrl class], wxUSE_SEARCHCTRL)
 934 WX_ARG_FEATURE(slider,      [  --enable-slider         use wxSlider class], wxUSE_SLIDER)
 935 WX_ARG_FEATURE(spinbtn,     [  --enable-spinbtn        use wxSpinButton class], wxUSE_SPINBTN)
 936 WX_ARG_FEATURE(spinctrl,    [  --enable-spinctrl       use wxSpinCtrl class], wxUSE_SPINCTRL)
 937 WX_ARG_FEATURE(splitter,    [  --enable-splitter       use wxSplitterWindow class], wxUSE_SPLITTER)
 938 WX_ARG_FEATURE(statbmp,     [  --enable-statbmp        use wxStaticBitmap class], wxUSE_STATBMP)
 939 WX_ARG_FEATURE(statbox,     [  --enable-statbox        use wxStaticBox class], wxUSE_STATBOX)
 940 WX_ARG_FEATURE(statline,    [  --enable-statline       use wxStaticLine class], wxUSE_STATLINE)
 941 WX_ARG_FEATURE(stattext,    [  --enable-stattext       use wxStaticText class], wxUSE_STATTEXT)
 942 WX_ARG_FEATURE(statusbar,   [  --enable-statusbar      use wxStatusBar class], wxUSE_STATUSBAR)
 943 WX_ARG_FEATURE(taskbaricon, [  --enable-taskbaricon    use wxTaskBarIcon class], wxUSE_TASKBARICON)
 944 WX_ARG_FEATURE(tbarnative,  [  --enable-tbarnative     use native wxToolBar class], wxUSE_TOOLBAR_NATIVE)
 945 WX_ARG_FEATURE(textctrl,    [  --enable-textctrl       use wxTextCtrl class], wxUSE_TEXTCTRL)
 946 WX_ARG_FEATURE(tipwindow,   [  --enable-tipwindow      use wxTipWindow class], wxUSE_TIPWINDOW)
 947 WX_ARG_FEATURE(togglebtn,   [  --enable-togglebtn      use wxToggleButton class], wxUSE_TOGGLEBTN)
 948 WX_ARG_FEATURE(toolbar,     [  --enable-toolbar        use wxToolBar class], wxUSE_TOOLBAR)
 949 WX_ARG_FEATURE(toolbook,    [  --enable-toolbook       use wxToolbook class], wxUSE_TOOLBOOK)
 950 WX_ARG_FEATURE(treebook,    [  --enable-treebook       use wxTreebook class], wxUSE_TREEBOOK)
 951 WX_ARG_FEATURE(treectrl,    [  --enable-treectrl       use wxTreeCtrl class], wxUSE_TREECTRL)
 952
 953 dnl ---------------------------------------------------------------------------
 954 dnl common dialogs
 955 dnl ---------------------------------------------------------------------------
 956
 957 WX_ARG_FEATURE(commondlg,   [  --enable-commondlg      use all common dialogs], wxUSE_COMMONDLGS)
 958 WX_ARG_FEATURE(aboutdlg,    [  --enable-aboutdlg       use wxAboutBox], wxUSE_ABOUTDLG)
 959 WX_ARG_FEATURE(choicedlg,   [  --enable-choicedlg      use wxChoiceDialog], wxUSE_CHOICEDLG)
 960 WX_ARG_FEATURE(coldlg,      [  --enable-coldlg         use wxColourDialog], wxUSE_COLOURDLG)
 961 WX_ARG_FEATURE(filedlg,     [  --enable-filedlg        use wxFileDialog], wxUSE_FILEDLG)
 962 WX_ARG_FEATURE(finddlg,     [  --enable-finddlg        use wxFindReplaceDialog], wxUSE_FINDREPLDLG)
 963 WX_ARG_FEATURE(fontdlg,     [  --enable-fontdlg        use wxFontDialog], wxUSE_FONTDLG)
 964 WX_ARG_FEATURE(dirdlg,      [  --enable-dirdlg         use wxDirDialog], wxUSE_DIRDLG)
 965 WX_ARG_FEATURE(msgdlg,      [  --enable-msgdlg         use wxMessageDialog], wxUSE_MSGDLG)
 966 WX_ARG_FEATURE(numberdlg,   [  --enable-numberdlg      use wxNumberEntryDialog], wxUSE_NUMBERDLG)
 967 WX_ARG_FEATURE(splash,      [  --enable-splash         use wxSplashScreen], wxUSE_SPLASH)
 968 WX_ARG_FEATURE(textdlg,     [  --enable-textdlg        use wxTextDialog], wxUSE_TEXTDLG)
 969 WX_ARG_FEATURE(tipdlg,      [  --enable-tipdlg         use startup tips], wxUSE_STARTUP_TIPS)
 970 WX_ARG_FEATURE(progressdlg, [  --enable-progressdlg    use wxProgressDialog], wxUSE_PROGRESSDLG)
 971 WX_ARG_FEATURE(wizarddlg,   [  --enable-wizarddlg      use wxWizard], wxUSE_WIZARDDLG)
 972
 973 dnl ---------------------------------------------------------------------------
 974 dnl misc GUI options
 975 dnl ---------------------------------------------------------------------------
 976
 977 WX_ARG_FEATURE(menus,       [  --enable-menus          use wxMenu/wxMenuBar/wxMenuItem classes], wxUSE_MENUS)
 978 WX_ARG_FEATURE(miniframe,   [  --enable-miniframe      use wxMiniFrame class], wxUSE_MINIFRAME)
 979 WX_ARG_FEATURE(tooltips,    [  --enable-tooltips       use wxToolTip class], wxUSE_TOOLTIPS)
 980 WX_ARG_FEATURE(splines,     [  --enable-splines        use spline drawing code], wxUSE_SPLINES)
 981 WX_ARG_FEATURE(mousewheel,  [  --enable-mousewheel     use mousewheel], wxUSE_MOUSEWHEEL)
 982 WX_ARG_FEATURE(validators,  [  --enable-validators     use wxValidator and derived classes], wxUSE_VALIDATORS)
 983 WX_ARG_FEATURE(busyinfo,    [  --enable-busyinfo       use wxBusyInfo], wxUSE_BUSYINFO)
 984 WX_ARG_FEATURE(joystick,    [  --enable-joystick       use wxJoystick], wxUSE_JOYSTICK)
 985 WX_ARG_FEATURE(metafile,    [  --enable-metafiles      use wxMetaFile (Win32 only)], wxUSE_METAFILE)
 986 WX_ARG_FEATURE(dragimage,   [  --enable-dragimage      use wxDragImage], wxUSE_DRAGIMAGE)
 987 WX_ARG_FEATURE(accessibility,[  --enable-accessibility  enable accessibility support], wxUSE_ACCESSIBILITY)
 988
 989 dnl ---------------------------------------------------------------------------
 990 dnl support for image formats that do not rely on external library
 991 dnl ---------------------------------------------------------------------------
 992
 993 WX_ARG_FEATURE(palette,     [  --enable-palette        use wxPalette class], wxUSE_PALETTE)
 994 WX_ARG_FEATURE(image,       [  --enable-image          use wxImage class], wxUSE_IMAGE)
 995 WX_ARG_FEATURE(gif,         [  --enable-gif            use gif images (GIF file format)], wxUSE_GIF)
 996 WX_ARG_FEATURE(pcx,         [  --enable-pcx            use pcx images (PCX file format)], wxUSE_PCX)
 997 WX_ARG_FEATURE(tga,         [  --enable-tga            use tga images (TGA file format)], wxUSE_TGA)
 998 WX_ARG_FEATURE(iff,         [  --enable-iff            use iff images (IFF file format)], wxUSE_IFF)
 999 WX_ARG_FEATURE(pnm,         [  --enable-pnm            use pnm images (PNM file format)], wxUSE_PNM)
1000 WX_ARG_FEATURE(xpm,         [  --enable-xpm            use xpm images (XPM file format)], wxUSE_XPM)
1001 WX_ARG_FEATURE(ico_cur,     [  --enable-ico_cur        use Windows ICO and CUR formats], wxUSE_ICO_CUR)
1002
1003 dnl ---------------------------------------------------------------------------
1004 dnl wxMSW-only options
1005 dnl ---------------------------------------------------------------------------
1006
1007 WX_ARG_FEATURE(dccache,     [  --enable-dccache        cache temporary wxDC objects (Win32 only)], wxUSE_DC_CACHEING)
1008 WX_ARG_FEATURE(ps-in-msw,   [  --enable-ps-in-msw      use PS printing in wxMSW (Win32 only)], wxUSE_POSTSCRIPT_ARCHITECTURE_IN_MSW)
1009 WX_ARG_FEATURE(ownerdrawn,  [  --enable-ownerdrawn     use owner drawn controls (Win32 and OS/2 only)], wxUSE_OWNER_DRAWN)
1010 WX_ARG_FEATURE(uxtheme,     [  --enable-uxtheme        enable support for Windows XP themed look (Win32 only)], wxUSE_UXTHEME)
1011 WX_ARG_FEATURE(wxdib,       [  --enable-wxdib          use wxDIB class (Win32 only)], wxUSE_DIB)
1012
1013 dnl this one is not really MSW-specific but it exists mainly to be turned off
1014 dnl under MSW, it should be off by default on the other platforms
1015 if test "$wxUSE_MSW" != 1; then
1016     DEFAULT_wxUSE_AUTOID_MANAGEMENT=no
1017 fi
1018
1019 WX_ARG_FEATURE(autoidman,   [  --enable-autoidman      use automatic ids management], wxUSE_AUTOID_MANAGEMENT)
1020
1021 fi
1022 dnl for GUI only
1023
1024 dnl ---------------------------------------------------------------------------
1025 dnl Checks for programs
1026 dnl ---------------------------------------------------------------------------
1027
1028 dnl flush the cache because checking for programs might abort
1029 AC_CACHE_SAVE
1030
1031 dnl C-compiler checks
1032 dnl   defines CC with the compiler to use
1033 dnl   defines GCC with yes if using gcc
1034 dnl   defines GCC empty if not using gcc
1035 dnl   defines CFLAGS
1036 dnl
1037 dnl this magic incantation is needed to prevent AC_PROG_CC from setting the
1038 dnl default CFLAGS (something like "-g -O2") -- we don't need this as we add
1039 dnl (if not already present in C*FLAGS) the -g and -O flags ourselves below
1040 CFLAGS=${CFLAGS:=}
1041 AC_BAKEFILE_PROG_CC
1042
1043 dnl is -traditional needed for correct compilations
1044 dnl   adds -traditional for gcc if needed
1045 AC_PROG_GCC_TRADITIONAL
1046
1047 dnl C++-compiler checks
1048 dnl   defines CXX with the compiler to use
1049 dnl   defines GXX with yes if using gxx
1050 dnl   defines GXX empty if not using gxx
1051 dnl   defines CXXFLAGS
1052 dnl
1053 dnl see CFLAGS line above
1054 CXXFLAGS=${CXXFLAGS:=}
1055 AC_BAKEFILE_PROG_CXX
1056
1057 dnl configure always sets CXX to something as it falls back to g++ even if no
1058 dnl C++ compiler was found, but we prefer to abort now with a clear error
1059 dnl message rather than give errors about all tests failures below
1060 if test "$CXX" = "g++" -a "$GXX" != "yes"; then
1061     AC_MSG_ERROR([C++ compiler is needed to build wxWidgets])
1062 fi
1063
1064 dnl ar command
1065 dnl   defines AR with the appropriate command
1066 dnl
1067 dnl For Sun CC AC_BAKEFILE below sets AR to the compiler itself.
1068 if test "x$SUNCXX" != xyes; then
1069     AC_CHECK_TOOL(AR, ar)
1070     if test "x$AR" = "x" ; then
1071         AC_MSG_ERROR([ar is needed to build wxWidgets])
1072     fi
1073 fi
1074
1075 dnl ---------------------------------------------------------------------------
1076 dnl Mac-specific SDK/architectures checks
1077 dnl ---------------------------------------------------------------------------
1078
1079 if test "$wxUSE_MAC" = 1; then
1080
1081 retest_macosx_linking=no
1082
1083 dnl Support the old --enable-universal_binary in case anyone was using it.
1084     if test "x$wxUSE_UNIVERSAL_BINARY" != xno ; then
1085         dnl --enable-universal_binary uses a default SDK (currently 10.4u)
1086         dnl --enable-universal_binary=SDK names a path to an SDK
1087         if test "x$wxUSE_UNIVERSAL_BINARY" == xyes; then
1088             # Implicitly turn on the new --with-macosx-sdk using the default
1089             # SDK which provides the behavior this option has always had.
1090             if test "x$wxUSE_MACOSX_SDK" = "x"; then
1091                 AC_MSG_WARN([Enabling default SDK due to --enable-universal_binary.])
1092                 AC_MSG_WARN([If you don't want this, specify --without-macosx-sdk])
1093                 wxUSE_MACOSX_SDK=yes
1094             fi
1095         else
1096             # Complain to user if he specified an argument to --enable-universal_binary
1097             # and also 1) specified --with-macosx-sdk using the default (yes) or
1098             # 2) specified --with-macosx-sdk using a path or 3) specified
1099             # --without-macosx-sdk (no).
1100             if test "x$wxUSE_MACOSX_SDK" != "x" ; then
1101                 AC_MSG_FAILURE([Please specify the new --with-macosx-sdk=PATH and do not specify an arg to --enable-universal_binary])
1102             else
1103                 # Put the SDK path into the wxUSE_MACOSX_SDK.  We don't have to
1104                 # special-case the empty string because the below test simply
1105                 # converts "no" to the empty string anyway.
1106                 wxUSE_MACOSX_SDK="$wxUSE_UNIVERSAL_BINARY"
1107                 dnl Warn about deprecated usage.
1108                 AC_MSG_WARN([Please use --with-macosx-sdk=PATH and --enable-universal_binary without an argument])
1109             fi
1110         fi
1111         dnl FIXME: I think it would be better to put this into CC, CXX, and LD rather than the flags.
1112         OSX_UNIV_OPTS="-arch ppc -arch i386"
1113         CXXFLAGS="$OSX_UNIV_OPTS $CXXFLAGS"
1114         CFLAGS="$OSX_UNIV_OPTS $CFLAGS"
1115         OBJCXXFLAGS="$OSX_UNIV_OPTS $OBJCXXFLAGS"
1116         OBJCFLAGS="$OSX_UNIV_OPTS $OBJCFLAGS"
1117         LDFLAGS="$OSX_UNIV_OPTS $LDFLAGS"
1118         dnl NOTE: Only the compiler driver needs arch flags.  The link editor
1119         dnl is incapable of using them but the compiler driver (which we use
1120         dnl as LD when building dynamic libraries) uses them to invoke the
1121         dnl real ld multiple times.  If we moved to libtool -dynamic we would
1122         dnl need no arch flags because libtool automatically invokes ld for
1123         dnl every architecture found in the fat input files.
1124         dnl
1125         dnl For static library builds, AR/RANLIB automatically create proper
1126         dnl fat archives although AR is unable to update them once RANLIB has
1127         dnl made them into proper fat archives.  Fortunately, our link process
1128         dnl simply removes the .a file before using ar to create a new one.
1129         dnl If we did move to libtool -static we still wouldn't need arch flags
1130         dnl because libtool automatically figures it out based on input.
1131         retest_macosx_linking=yes
1132
1133         dnl HACK: PCH could be made to work by precompiling for each architecture into separate directories
1134         dnl and including all architecture directories with each compiler invocation.
1135         dnl That would require a major rework of Bakefile and at the same time it would be nice to have
1136         dnl Objective-C++ precompiled headers.
1137         AC_MSG_WARN([Disabling precompiled headers due to universal binary build.])
1138         bk_use_pch=no
1139     fi
1140
1141 dnl Set up the Mac OS X SDK.  We do this early so configure tests will occur
1142 dnl with the SDK in place.
1143 dnl NOTE: We clobber wxUSE_MACOSX_SDK with the SDK path
1144 if test "x$wxUSE_MACOSX_SDK" = "xno"; then
1145     wxUSE_MACOSX_SDK=
1146 elif test "x$wxUSE_MACOSX_SDK" = "xyes"; then
1147     # TODO: Search for most recent SDK and use it.
1148     wxUSE_MACOSX_SDK="/Developer/SDKs/MacOSX10.4u.sdk"
1149 fi
1150
1151
1152 if test "x$wxUSE_MACOSX_SDK" != "x"; then
1153     AC_MSG_CHECKING([for SDK directory $wxUSE_MACOSX_SDK])
1154     if ! test -d "$wxUSE_MACOSX_SDK"; then
1155         AC_MSG_FAILURE([not found])
1156     else
1157         AC_MSG_RESULT([exists])
1158     fi
1159     MACOSX_SDK_OPTS="-isysroot $wxUSE_MACOSX_SDK"
1160     eval "CC=\"$CC $MACOSX_SDK_OPTS\""
1161     eval "CXX=\"$CXX $MACOSX_SDK_OPTS\""
1162     eval "LD=\"$LD $MACOSX_SDK_OPTS\""
1163     retest_macosx_linking=yes
1164     dnl NOTE: When libtool is used in lieu of AR/RANLIB (i.e. in static mode)
1165     dnl the syslibroot makes no difference.  We aren't using libtool now but
1166     dnl if we ever did, be aware that you don't need to worry about it.
1167 fi
1168
1169 dnl Set up the deployment target
1170 dnl No   : Don't specify a min version even if using an SDK
1171 dnl Yes  : Use the version from the SDK if used, otherwise same as no
1172 dnl Param: Use the specified version
1173 if test "x$wxUSE_MACOSX_VERSION_MIN" = "xno"; then
1174     wxUSE_MACOSX_VERSION_MIN=
1175 elif test "x$wxUSE_MACOSX_VERSION_MIN" = "xyes"; then
1176     if test "x$wxUSE_MACOSX_SDK" != "x"; then
1177         AC_MSG_CHECKING([SDK deployment version])
1178 dnl We need to quote the next line where we don't need macros and do need [] in the regex
1179 [
1180         MACOSX_SDK_PLIST_VERSION_MIN=`defaults read "$wxUSE_MACOSX_SDK/SDKSettings" buildSettings | grep '^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}[^"]*"\{0,1\}; *$' | sed 's/^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}\([^"]*\)"\{0,1\} *; *$/\1/'`
1181 ]
1182         # If that failed, try again with the new key
1183         if test "x$MACOSX_SDK_PLIST_VERSION_MIN" == "x"; then
1184 [
1185             MACOSX_SDK_PLIST_VERSION_MIN=`defaults read "$wxUSE_MACOSX_SDK/SDKSettings" DefaultProperties | grep '^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}[^"]*"\{0,1\}; *$' | sed 's/^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}\([^"]*\)"\{0,1\} *; *$/\1/'`
1186 ]
1187         fi
1188
1189         if test "x$MACOSX_SDK_PLIST_VERSION_MIN" != "x"; then
1190             wxUSE_MACOSX_VERSION_MIN=$MACOSX_SDK_PLIST_VERSION_MIN
1191             AC_MSG_RESULT([$wxUSE_MACOSX_VERSION_MIN])
1192         else
1193             AC_MSG_WARN([Could not determine deployment target from SDKSettings.plist])
1194             wxUSE_MACOSX_VERSION_MIN=
1195         fi
1196     else
1197         wxUSE_MACOSX_VERSION_MIN=
1198     fi
1199 elif test "x$wxUSE_MACOSX_VERSION_MIN" = "x"; then
1200     OSX_VERSION=`sw_vers -productVersion | grep 10.[[0-9]]`
1201     if test "$wxUSE_OSX_CARBON" = 1 -o "x$OSX_VERSION" = "x10.4"; then
1202         # otherwise configure stops on leopard for universal_binary
1203         wxUSE_MACOSX_VERSION_MIN=10.4
1204     else
1205         # for OS X Cocoa, use 10.5 so we can get 64-bit compile on Snow Leopard
1206         wxUSE_MACOSX_VERSION_MIN=10.5
1207     fi
1208 fi
1209
1210 NEEDS_GCC40="no"
1211 if test "x$wxUSE_MACOSX_VERSION_MIN" == "x10.4"; then
1212     NEEDS_GCC40="yes"
1213 fi
1214
1215 if test "$wxUSE_OSX_CARBON" = 1; then
1216     NEEDS_GCC40="yes"
1217 fi
1218
1219 if test "x$NEEDS_GCC40" == "xyes"; then
1220     # gcc 4.2 cannot compile 10.4 compatible code, so if the user is using it
1221     # and wants 10.4 compatible code, then 'downgrade' to 4.0
1222     # This is also the simplest way to get 32-bit binaries on Snow Leopard.
1223     if test "x$CC" = "xgcc"; then
1224         CCVERSION=`$CC --version | grep 4.[[2-9]].`
1225         if test "x$CCVERSION" != "x"; then
1226             echo "$as_me:$LINENO: WARNING: gcc >= 4.2 cannot compile 10.4 compatible code. Using gcc 4.0 instead."
1227             CC="/usr/bin/gcc-4.0"
1228         fi
1229     fi
1230
1231     if test "x$CXX" = "xg++"; then
1232         CCVERSION=`$CXX --version | grep 4.[[2-9]].`
1233         if test "x$CCVERSION" != "x"; then
1234             CXX="/usr/bin/g++-4.0"
1235         fi
1236     fi
1237 fi
1238
1239 if test "x$wxUSE_MACOSX_VERSION_MIN" != "x"; then
1240     MACOSX_VERSION_MIN_OPTS="-mmacosx-version-min=$wxUSE_MACOSX_VERSION_MIN"
1241     eval "CC=\"$CC $MACOSX_VERSION_MIN_OPTS\""
1242     eval "CXX=\"$CXX $MACOSX_VERSION_MIN_OPTS\""
1243     eval "LD=\"$LD $MACOSX_VERSION_MIN_OPTS\""
1244     retest_macosx_linking=yes
1245 fi
1246
1247 dnl If either an SDK or a version option was added, make sure that we can
1248 dnl still compile and link both C and C++.  If we didn't do this, then most
1249 dnl of the remaining tests would fail.
1250 if test "x$retest_macosx_linking" = "xyes"; then
1251     AC_LANG_PUSH(C)
1252     AC_MSG_CHECKING([if C compiler works with SDK/version options])
1253     AC_TRY_LINK([],[],[AC_MSG_RESULT([yes])],[AC_MSG_FAILURE([no.  Try a different SDK]); exit 1])
1254     AC_LANG_POP()
1255
1256     AC_LANG_PUSH(C++)
1257     AC_MSG_CHECKING([if C++ compiler works with SDK/version options])
1258     AC_TRY_LINK([],[],[AC_MSG_RESULT([yes])],[AC_MSG_FAILURE([no.  Try a different SDK]); exit 1])
1259     AC_LANG_POP()
1260 fi
1261
1262 fi dnl wxUSE_MAC
1263
1264 case "${host}" in
1265
1266     dnl The other BSD's should probably go in here too, since this is
1267     dnl to workaround a strange static lib BSDism.
1268     dnl Mac OS X install seems to ignore -p option...
1269     *-*-darwin* )
1270         INSTALL_PROGRAM="cp -fp"
1271         INSTALL_DATA="cp -fp"
1272         ;;
1273     *)
1274         ;;
1275 esac
1276
1277 dnl ------------------------------------------------------------------------
1278 dnl Platform specific tests
1279 dnl ------------------------------------------------------------------------
1280
1281 dnl xlC needs -qunique under AIX so that one source file can be
1282 dnl compiled to multiple object files and safely linked together.
1283 if test "x$XLCXX" = "xyes" -a "x$USE_AIX" = "x1"; then
1284     CXXFLAGS="-qunique $CXXFLAGS"
1285 fi
1286
1287 dnl This case is for PowerPC OS X vs. everything else
1288 case "${host}" in
1289   powerpc-*-darwin* )
1290     AC_MSG_CHECKING([if __POWERPC__ is already defined])
1291     AC_TRY_COMPILE([],[#ifndef __POWERPC__
1292         choke me for lack of PowerPC
1293 #endif
1294 ],
1295         [AC_MSG_RESULT([yes])],
1296         [AC_MSG_RESULT([no])
1297         AC_DEFINE(__POWERPC__)
1298     ])
1299   ;;
1300 esac
1301
1302 dnl This case is for OS X vs. everything else
1303 case "${host}" in
1304   *-*-darwin* )
1305     AC_MSG_CHECKING([if CoreFoundation/CFBase.h is usable])
1306     AC_TRY_COMPILE([#include <CoreFoundation/CFBase.h>
1307 ],[],
1308         [AC_MSG_RESULT([yes])],
1309         [AC_MSG_RESULT([no])
1310         AC_MSG_CHECKING([if __CF_USE_FRAMEWORK_INCLUDES__ is required])
1311         AC_TRY_COMPILE([#define __CF_USE_FRAMEWORK_INCLUDES__
1312 #include <CoreFoundation/CFBase.h>
1313         ],[],
1314         [AC_MSG_RESULT([yes])
1315         dnl We must use -D so source files that don't include wx/setup.h
1316         dnl but do include CFBase will work.
1317         CPPFLAGS="-D__CF_USE_FRAMEWORK_INCLUDES__ $CPPFLAGS"],
1318         [AC_MSG_FAILURE([no.  CoreFoundation not available.])]
1319         )
1320         ]
1321     )
1322   ;;
1323 esac
1324
1325 dnl Determine whether we want to use Cygwin as Windows or POSIX platform: the
1326 dnl latter makes more sense for wxGTK/Motif/X11 ports
1327 wants_win32=0
1328 doesnt_want_win32=0
1329 case "${host}" in
1330   *-*-cygwin*)
1331       if test "$wxUSE_MSW" = 1 ; then
1332         wants_win32=1
1333       else
1334         dnl when we use cygwin compiler with -mno-cygwin option it uses mingw32
1335         dnl headers and libraries, so it's Windows-like in this case
1336         AC_CACHE_CHECK([if -mno-cygwin is in effect], wx_cv_nocygwin,
1337             [
1338                 AC_TRY_COMPILE(
1339                     [],
1340                     [
1341                         #ifdef __MINGW32__
1342                             choke me
1343                         #endif
1344                     ],
1345                     wx_cv_nocygwin=no,
1346                     wx_cv_nocygwin=yes
1347                 )
1348             ]
1349         )
1350
1351         if test "$wx_cv_nocygwin" = "yes"; then
1352             wants_win32=1
1353         else
1354             doesnt_want_win32=1
1355         fi
1356       fi
1357       if test "$wants_win32" = 1 ; then
1358         BAKEFILE_FORCE_PLATFORM=win32
1359       fi
1360   ;;
1361   *-*-mingw*)
1362       wants_win32=1
1363   ;;
1364 esac
1365
1366 if test "$wxUSE_WINE" = "yes"; then
1367     wants_win32=1
1368     LDFLAGS_GUI="-mwindows"
1369 fi
1370
1371 dnl NB: The two tests bellow are *NOT* mutually exclusive! They should only
1372 dnl     take effect on Cygwin/Mingw and not other platforms.
1373 if test "$wants_win32" = 1 ; then
1374     USE_UNIX=0
1375     USE_WIN32=1
1376     AC_DEFINE(__WIN32__)
1377     AC_DEFINE(__WIN95__)
1378     AC_DEFINE(__WINDOWS__)
1379     AC_DEFINE(__GNUWIN32__)
1380     AC_DEFINE(STRICT)
1381 fi
1382 if test "$doesnt_want_win32" = 1 ; then
1383     USE_UNIX=1
1384     USE_WIN32=0
1385 fi
1386 dnl (end of Windows-only piece)
1387
1388 if test "$USE_UNIX" = 1 ; then
1389     wxUSE_UNIX=yes
1390     AC_DEFINE(__UNIX__)
1391 fi
1392
1393 dnl This case is for OS/2 vs. everything else
1394 case "${host}" in
1395   *-pc-os2_emx | *-pc-os2-emx )
1396       dnl ---------------------------------------------------------------------
1397       dnl When we are using gcc on OS/2, we want to be either using resources
1398       dnl (PM) or a more complete POSIX emulation for Motif/GTK+/X11.
1399       dnl Moreover we need to link explicitly against either stdcpp.a or
1400       dnl stdcxx.a (depending on compiler version), since we are using "gcc",
1401       dnl not "g++/c++".
1402       dnl ---------------------------------------------------------------------
1403       dnl (OS/2-only piece)
1404       if test "$wxUSE_MOTIF" = 1 -o "$wxUSE_GTK" = 1 -o "$wxUSE_X11" = 1; then
1405           dnl More complete Unix emulation for unix-like ports
1406           dnl by linking in POSIX/2's cExt (if available).
1407           AC_CHECK_LIB(cExt, drand48, LIBS="$LIBS -lcExt")
1408       else
1409           dnl Include resources for the "native" port (wxPM).
1410           RESPROGRAMOBJ="\${top_srcdir}/include/wx/os2/wx.res"
1411       fi
1412       dnl Check for the gcc version (and thereby for the C runtime library).
1413       dnl wx_cv_gccversion = EMX2 -> Standard EMX environment
1414       dnl wx_cv_gccversion = EMX3 -> EMX with gcc-3.0.3 or gcc-3.2.1
1415       dnl wx_cv_gccversion = Innotek5 -> gcc-3.2.2 with Innotek libc5
1416       dnl wx_cv_gccversion = Innotek6 -> gcc-3.3.5 with Innotek libc6.
1417       AC_CACHE_CHECK([for gcc/libc version], wx_cv_gccversion,[
1418           AC_TRY_RUN(
1419               dnl Check the gcc version macro.
1420               [
1421                   #include <stdio.h>
1422
1423                   int main()
1424                   {
1425                       FILE *f=fopen("conftestval", "w");
1426                       if (!f) exit(1);
1427                       fprintf(f,
1428                   #if (__GNUC__ < 3)
1429                               "EMX2"
1430                   #elif (__GNUC__==3) && ((__GNUC_MINOR__ < 2) || ((__GNUC_MINOR__==2) && (__GNUC_PATCHLEVEL__<2)))
1431                               "EMX3"
1432                   #elif (__GNUC__==3) && (__GNUC_MINOR__==2) && (__GNUC_PATCHLEVEL__==2)
1433                               "Innotek5"
1434                   #else
1435                               "Innotek6"
1436                   #endif
1437                       );
1438                       exit(0);
1439                   }
1440               ],
1441               wx_cv_gccversion=`cat conftestval`,
1442               wx_cv_gccversion="EMX2",
1443               dnl Compilation error: Assuming standard EMX environment
1444               wx_cv_gccversion="EMX2"
1445           )
1446       ])
1447       if test "$wx_cv_gccversion" = "EMX2"; then
1448           LIBS="$LIBS -lstdcpp"
1449           LDFLAGS="$LDFLAGS -Zsysv-signals"
1450       else
1451           if test "$wx_cv_gccversion" = "EMX3"; then
1452               LIBS="$LIBS -lstdcxx -lgcc"
1453               LDFLAGS="$LDFLAGS -Zsysv-signals"
1454           else
1455               LIBS="$LIBS -lstdc++"
1456           fi
1457       fi
1458       if test "$wxUSE_SHARED" = "yes" -a "$wxUSE_OMF" = "no"; then
1459         AC_MSG_WARN([Building DLLs requires OMF mode, enabled])
1460         wxUSE_OMF=yes
1461         enable_omf=yes
1462       fi
1463       dnl (end of OS/2-only piece)
1464   ;;
1465   *)
1466       dnl ---------------------------------------------------------------------
1467       dnl look for strcasecmp() in string.h and then strings.h if it's not
1468       dnl there. Don't do this on OS/2, where "stricmp" is the function to be
1469       dnl used.
1470       dnl ---------------------------------------------------------------------
1471       dnl (non-OS/2-only piece)
1472
1473       AC_CACHE_CHECK([for strcasecmp() in string.h], ac_cv_string_strcasecmp, [
1474           AC_TRY_LINK([
1475               #include <string.h>
1476               ],
1477               [
1478                   strcasecmp("foo", "bar");
1479               ],
1480               ac_cv_string_strcasecmp=yes,
1481               ac_cv_string_strcasecmp=no
1482           )
1483       ])
1484
1485       if test x"$ac_cv_string_strcasecmp" = "xyes"; then
1486           AC_DEFINE(HAVE_STRCASECMP_IN_STRING_H)
1487       else
1488           AC_CACHE_CHECK([for strcasecmp() in strings.h], ac_cv_strings_strcasecmp, [
1489               AC_TRY_LINK([
1490                   #include <strings.h>
1491                   ],
1492                   [
1493                       strcasecmp("foo", "bar");
1494                   ],
1495                   ac_cv_strings_strcasecmp=yes,
1496                   ac_cv_strings_strcasecmp=no
1497               )
1498           ])
1499
1500           if test x"$ac_cv_strings_strcasecmp" = "xyes"; then
1501               AC_DEFINE(HAVE_STRCASECMP_IN_STRINGS_H)
1502           else
1503               AC_MSG_ERROR([No case-insensitive string comparison function found.])
1504           fi
1505       fi
1506
1507       dnl (end of non-OS/2-only piece)
1508   ;;
1509 esac
1510
1511 dnl ------------------------------------------------------------------------
1512 dnl Check for headers
1513 dnl ------------------------------------------------------------------------
1514
1515 dnl Note: non-empty last parameter makes check compile-only,
1516 dnl   skipping worthless preprocessing check
1517 AC_CHECK_HEADERS(langinfo.h wchar.h,,, [AC_INCLUDES_DEFAULT])
1518
1519 dnl maybe wchar_t is in wcstr.h if we don't have wchar.h?
1520 if test "$ac_cv_header_wchar_h" != "yes"; then
1521     AC_CHECK_HEADERS([wcstr.h],,, [AC_INCLUDES_DEFAULT()])
1522 fi
1523
1524 case "${host}" in
1525   *-pc-os2_emx | *-pc-os2-emx )
1526       dnl Explicitly link -lintl if langinfo.h is available
1527       dnl and intl not yet included in libc
1528       if test $ac_cv_header_langinfo_h = "yes" \
1529                 -a \(   "$wx_cv_gccversion" = "EMX2" \
1530                      -o "$wx_cv_gccversion" = "EMX3" \
1531                      -o "$wx_cv_gccversion" = "Innotek5" \); then
1532           LIBS="$LIBS -lintl"
1533       fi
1534   ;;
1535 esac
1536
1537 dnl POSIX needs this for select(), but old systems don't have it
1538 if test "$USE_UNIX" = 1 ; then
1539     AC_CHECK_HEADERS([sys/select.h],,, [AC_INCLUDES_DEFAULT()])
1540 fi
1541
1542 dnl ---------------------------------------------------------------------------
1543 dnl Checks for compiler characteristics
1544 dnl ---------------------------------------------------------------------------
1545
1546 dnl defines const to be empty if c-compiler does not support const fully
1547 AC_C_CONST
1548 dnl defines inline to a sensible value for the c-compiler
1549 AC_C_INLINE
1550
1551 dnl check the sizes of integral types (give some reasonable default values for
1552 dnl cross-compiling)
1553 dnl   defines the size of certain types of variables in SIZEOF_<TYPE>
1554 AC_CHECK_SIZEOF(short, 2)
1555 AC_CHECK_SIZEOF(void *, 4)
1556 AC_CHECK_SIZEOF(int, 4)
1557 AC_CHECK_SIZEOF(long, 4)
1558 AC_CHECK_SIZEOF(size_t, 4)
1559
1560 case "${host}" in
1561     arm-*-linux* )
1562         AC_CHECK_SIZEOF(long long, 8)
1563     ;;
1564     *-hp-hpux* )
1565         AC_CHECK_SIZEOF(long long, 0)
1566         if test "$ac_cv_sizeof_long_long" != 0; then
1567             dnl HPUX 10.20 headers need this define in order to use long long definitions
1568             CPPFLAGS="-D_INCLUDE_LONGLONG $CPPFLAGS"
1569         fi
1570     ;;
1571     * )
1572         AC_CHECK_SIZEOF(long long, 0)
1573 esac
1574
1575 dnl SGI/Irix's stdio.h does not include wchar_t. Mac OS X does not provide
1576 dnl wchar.h and wchar_t is defined by stdlib.h (GD)
1577 AC_CHECK_SIZEOF(wchar_t, 0,
1578     [
1579         /* DJGPP's wchar_t is now a keyword in C++ (still not C though) */
1580         #if defined(__DJGPP__) && !( (__GNUC_MINOR__ >= 8 && __GNUC__ == 2 ) || __GNUC__ >= 3 )
1581         #  error "fake wchar_t"
1582         #endif
1583         #ifdef HAVE_WCHAR_H
1584         #  ifdef __CYGWIN__
1585         #    include <stddef.h>
1586         #  endif
1587         #  include <wchar.h>
1588         #endif
1589         #ifdef HAVE_STDLIB_H
1590         #  include <stdlib.h>
1591         #endif
1592         #include <stdio.h>
1593     ]
1594 )
1595 if test "$ac_cv_sizeof_wchar_t" != 0; then
1596     wxUSE_WCHAR_T=yes
1597 else
1598     wxUSE_WCHAR_T=no
1599 fi
1600
1601 dnl checks needed to define wxVaCopy
1602 AC_CACHE_CHECK([for va_copy],
1603     wx_cv_func_va_copy,
1604     [
1605         AC_LANG_PUSH(C++)
1606         AC_LINK_IFELSE([
1607             #include <stdarg.h>
1608             void foo(char *f, ...)
1609             {
1610                 va_list ap1, ap2;
1611                 va_start(ap1, f);
1612                 va_copy(ap2, ap1);
1613                 va_end(ap2);
1614                 va_end(ap1);
1615             }
1616             int main()
1617             {
1618                 foo("hi", 17);
1619                 return 0;
1620             }],
1621             wx_cv_func_va_copy=yes,
1622             wx_cv_func_va_copy=no
1623         )
1624         AC_LANG_POP()
1625     ]
1626 )
1627
1628 if test $wx_cv_func_va_copy = "yes"; then
1629     AC_DEFINE(HAVE_VA_COPY)
1630 else
1631     dnl try to understand how can we copy va_lists
1632     AC_CACHE_CHECK([if va_list can be copied by value],
1633         wx_cv_type_va_list_lvalue,
1634         [
1635             AC_RUN_IFELSE([
1636                 #include <stdarg.h>
1637                 int foo(char *f, ...)
1638                 {
1639                     va_list ap1, ap2;
1640                     va_start(ap1, f);
1641                     ap2 = ap1;
1642                     if ( va_arg(ap1, int) != 17 || va_arg(ap2, int) != 17 )
1643                         return 1;
1644                     va_end(ap2);
1645                     va_end(ap1);
1646                     return 0;
1647                 }
1648                 int main()
1649                 {
1650                     return foo("hi", 17);
1651                 }],
1652                 wx_cv_type_va_list_lvalue=yes,
1653                 wx_cv_type_va_list_lvalue=no,
1654                 dnl assume most common case for cross-compiling...
1655                 wx_cv_type_va_list_lvalue=yes
1656             )
1657         ]
1658     )
1659
1660     if test $wx_cv_type_va_list_lvalue != "yes"; then
1661         dnl we suppose that the only thing which can't be copied like this
1662         dnl are arrays... only experience will show whether this is really true
1663         AC_DEFINE(VA_LIST_IS_ARRAY)
1664     fi
1665 fi
1666
1667 dnl don't check for vararg macros if they're explicitly disabled: this is
1668 dnl useful if the user code using the library wants to limit itself to standard
1669 dnl C++ only (e.g. is compiled with g++ -std=c++98)
1670 if test "$wxUSE_VARARG_MACROS" = "yes"; then
1671
1672 dnl Check if variadic macros (C99 feature) are supported:
1673 AC_CACHE_CHECK(
1674     [whether the compiler supports variadic macros],
1675     [wx_cv_have_variadic_macros],
1676     [
1677         dnl C compiler might support variadic macros when C++ one doesn't
1678         dnl (happens with gcc/g++ 2.95.4), so must use C++ one explicitly
1679         AC_LANG_PUSH(C++)
1680         AC_COMPILE_IFELSE(
1681             AC_LANG_PROGRAM(
1682                 [
1683                     #include <stdio.h>
1684                     #define test(fmt, ...) printf(fmt, __VA_ARGS__)
1685                 ],
1686                 [
1687                     test("%s %d %p", "test", 1, 0);
1688                 ]
1689             ),
1690             [wx_cv_have_variadic_macros=yes],
1691             [wx_cv_have_variadic_macros=no]
1692             )
1693         AC_LANG_POP()
1694     ]
1695 )
1696
1697 if test $wx_cv_have_variadic_macros = "yes"; then
1698     AC_DEFINE(HAVE_VARIADIC_MACROS)
1699 fi
1700
1701 fi dnl wxUSE_VARARG_MACROS == yes
1702
1703
1704 dnl check for large file support
1705 LARGEFILE_CPPFLAGS=
1706 AC_SYS_LARGEFILE
1707 if test "$ac_cv_sys_file_offset_bits" = "64"; then
1708     LARGEFILE_CPPFLAGS="-D_FILE_OFFSET_BITS=64"
1709 elif test "$ac_cv_sys_large_files" = 1; then
1710     LARGEFILE_CPPFLAGS="-D_LARGE_FILES"
1711 fi
1712
1713 dnl we need to define _FILE_OFFSET_BITS or _LARGE_FILES on the compiler command
1714 dnl line because otherwise the system headers risk being included before
1715 dnl wx/defs.h which defines these constants leading to inconsistent
1716 dnl sizeof(off_t) in different source files of the same program and linking
1717 dnl problems
1718 if test -n "$LARGEFILE_CPPFLAGS"; then
1719     WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS $LARGEFILE_CPPFLAGS"
1720
1721     dnl We get "Large Files (ILP32) not supported in strict ANSI mode."
1722     dnl #error from HP standard headers unless __STDC_EXT__ is defined.
1723     dnl The compiler should define it automatically, but some old g++
1724     dnl versions don't define it, so test and add it if necessary. AFAIK
1725     dnl the problem only affects the C++ compiler so it is added to
1726     dnl CXXFLAGS only.
1727     if test "$USE_HPUX" = 1 -a "$GXX" = "yes"; then
1728         AC_CACHE_CHECK(
1729             [if -D__STDC_EXT__ is required],
1730             wx_cv_STDC_EXT_required,
1731             [
1732                 AC_LANG_PUSH(C++)
1733                 AC_TRY_COMPILE(
1734                     [],
1735                     [
1736                         #ifndef __STDC_EXT__
1737                             choke me
1738                         #endif
1739                     ],
1740                     wx_cv_STDC_EXT_required=no,
1741                     wx_cv_STDC_EXT_required=yes
1742                 )
1743                 AC_LANG_POP()
1744             ]
1745         )
1746         if test "x$wx_cv_STDC_EXT_required" = "xyes"; then
1747             WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -D__STDC_EXT__"
1748         fi
1749     fi
1750 fi
1751
1752 dnl AC_FUNC_FSEEKO sets HAVE_FSEEKO and $ac_cv_sys_largefile_source
1753 dnl
1754 dnl it may be affected by large file flags (this happens under HP-UX 11 for
1755 dnl example) so set them before using it and also use C++ to ensure that we get
1756 dnl errors, not warnings, about the missing functions
1757 AC_LANG_PUSH(C++)
1758 old_CPPFLAGS="$CPPFLAGS"
1759 CPPFLAGS="$CPPFLAGS $LARGEFILE_CPPFLAGS"
1760 AC_FUNC_FSEEKO
1761 CPPFLAGS="$old_CPPFLAGS"
1762 AC_LANG_POP()
1763 if test "$ac_cv_sys_largefile_source" != no; then
1764     WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_LARGEFILE_SOURCE=$ac_cv_sys_largefile_source"
1765 fi
1766
1767 dnl check for bytesex stuff (don't use AC_C_BIGENDIAN to allow cross-compiling)
1768 WX_C_BIGENDIAN
1769
1770 dnl check for iostream (as opposed to iostream.h) standard header
1771 WX_CPP_NEW_HEADERS(, AC_DEFINE(wxUSE_IOSTREAMH))
1772
1773 dnl check whether C++ compiler supports explicit keyword
1774 WX_CPP_EXPLICIT
1775
1776 dnl With Sun CC, temporaries have block scope by default. This flag is needed
1777 dnl to get the expression scope behaviour that conforms to the standard.
1778 if test "x$SUNCXX" = xyes; then
1779     CXXFLAGS="-features=tmplife $CXXFLAGS"
1780 fi
1781
1782 dnl Sun X11 headers are (still, in 2005!) non-ANSI and the best they could do
1783 dnl was to hack their C++ compiler to accept them silently -- but C compiler
1784 dnl still spits out dozens of warnings for each X include file, so suppress
1785 dnl them
1786 if test "x$SUNCC" = xyes; then
1787     CFLAGS="-erroff=E_NO_EXPLICIT_TYPE_GIVEN $CFLAGS"
1788 fi
1789
1790 dnl SGI mipsPro compiler gives this warning for "conversion from pointer to
1791 dnl same-sized integral type" even when there is an explicit cast and as there
1792 dnl is no way to turn it off and there are hundreds of these warnings in wx
1793 dnl sources, just turn it off for now
1794 dnl
1795 dnl a better long term solution would be to use #pragma set/reset woff in
1796 dnl wxPtrToUInt() and use it instead of casts elsewhere
1797 if test "x$SGICC" = "xyes"; then
1798     CFLAGS="-woff 3970 $CFLAGS"
1799 fi
1800 if test "x$SGICXX" = "xyes"; then
1801     CXXFLAGS="-woff 3970 $CXXFLAGS"
1802 fi
1803
1804 dnl HP-UX c89/aCC compiler warnings
1805 if test "x$HPCC" = "xyes"; then
1806     dnl 2011: "unrecognized preprocessor directive": nice warning but it's given
1807     dnl       even for directives inside #if which is not true (i.e. which are
1808     dnl       used for other compilers/OS) and so we have no way to get rid of it
1809     dnl 2450: "long long is non standard" -- yes, we know
1810     CFLAGS="+W 2011,2450 $CFLAGS"
1811 fi
1812 if test "x$HPCXX" = "xyes"; then
1813     dnl 2340: "value copied to temporary, reference to temporary used": very
1814     dnl       painful as triggered by any occurrence of user-defined conversion
1815     dnl 4232: "conversion from 'Foo *' to a more strictly aligned type 'Bar *'
1816     dnl       may cause misaligned access": this might indicate a real problem
1817     dnl       but any use of GTK+ cast macros results in it so it's unusable
1818     dnl       for wxGTK code
1819     CXXFLAGS="+W 2340,4232 $CXXFLAGS"
1820 fi
1821
1822 dnl DEC/Compaq/HP cxx warnings
1823 if test "x$COMPAQCXX" = "xyes"; then
1824     dnl -w0 enables all warnings, then we disable some of them:
1825     dnl basclsnondto: base class dtor non virtual (sometimes we do want this)
1826     dnl unrimpret:  "end of routine block may be unreachable" is given for
1827     dnl             every "if ( ) return ...; else return ...;"
1828     dnl intconlosbit: "conversion to integral type of smaller size could lose
1829     dnl               data" this is a useful warning but there are too many of
1830     dnl               them for now
1831     CXXFLAGS="-w0 -msg_disable basclsnondto,unrimpret,intconlosbit"
1832 fi
1833
1834 dnl the next few tests are all for C++ features and so need to be done using
1835 dnl C++ compiler
1836 AC_LANG_PUSH(C++)
1837
1838 dnl check for std::string or std::wstring
1839 if test "$wxUSE_STD_STRING" = "yes" -o "$wxUSE_STL" = "yes"; then
1840     if test "$wxUSE_UNICODE" = "yes"; then
1841         std_string="std::wstring"
1842         char_type="wchar_t"
1843     else
1844         std_string="std::string"
1845         char_type="char"
1846     fi
1847
1848     dnl check if <string> declares std::[w]string
1849     AC_CACHE_CHECK([for $std_string in <string>],
1850         wx_cv_class_stdstring,
1851         [
1852             AC_TRY_COMPILE([#include <string>],
1853                 [$std_string foo;],
1854                 wx_cv_class_stdstring=yes,
1855                 wx_cv_class_stdstring=no
1856             )
1857         ]
1858     )
1859
1860     if test "$wx_cv_class_stdstring" = yes; then
1861         if test "$wxUSE_UNICODE" = "yes"; then
1862             AC_DEFINE(HAVE_STD_WSTRING)
1863         fi
1864         dnl we don't need HAVE_STD_STRING, we just suppose it's available if
1865         dnl wxUSE_STD_STRING==yes
1866     else
1867         AC_CACHE_CHECK([if std::basic_string<$char_type> works],
1868             wx_cv_class_stdbasicstring,
1869             [
1870                 AC_TRY_COMPILE([
1871                     #ifdef HAVE_WCHAR_H
1872                     #  ifdef __CYGWIN__
1873                     #    include <stddef.h>
1874                     #  endif
1875                     #  include <wchar.h>
1876                     #endif
1877                     #ifdef HAVE_STDLIB_H
1878                     #  include <stdlib.h>
1879                     #endif
1880                     #include <stdio.h>
1881                     #include <string>
1882                     ],
1883                     [std::basic_string<$char_type> foo;
1884                      const $char_type* dummy = foo.c_str();],
1885                     wx_cv_class_stdbasicstring=yes,
1886                     wx_cv_class_stdbasicstring=no
1887                 )
1888             ]
1889         )
1890
1891         if test "$wx_cv_class_stdbasicstring" != yes; then
1892             if test "$wxUSE_STL" = "yes"; then
1893                 AC_MSG_ERROR([Can't use --enable-stl without $std_string or std::basic_string<$char_type>])
1894             elif test "$wxUSE_STD_STRING" = "yes"; then
1895                 AC_MSG_ERROR([Can't use --enable-std_string without $std_string or std::basic_string<$char_type>])
1896             else
1897                 AC_MSG_WARN([No $std_string or std::basic_string<$char_type>, switching to --disable-std_string])
1898                 wxUSE_STD_STRING=no
1899             fi
1900         fi
1901     fi
1902 fi
1903
1904 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
1905     AC_CHECK_TYPES([std::istream, std::ostream],,
1906                    [wxUSE_STD_IOSTREAM=no],
1907                    [#include <iostream>])
1908
1909     if test "$wxUSE_STD_IOSTREAM" != "yes"; then
1910         if test "$wxUSE_STD_IOSTREAM" = "yes"; then
1911             AC_MSG_ERROR([Can't use --enable-std_iostreams without std::istream and std::ostream])
1912         else
1913             AC_MSG_WARN([No std::iostreams, switching to --disable-std_iostreams])
1914         fi
1915     fi
1916 fi
1917
1918 if test "$wxUSE_STL" = "yes"; then
1919     dnl check for basic STL functionality
1920     AC_CACHE_CHECK([for basic STL functionality],
1921         wx_cv_lib_stl,
1922         [AC_TRY_COMPILE([#include <string>
1923             #include <functional>
1924             #include <algorithm>
1925             #include <vector>
1926             #include <list>],
1927             [std::vector<int> moo;
1928              std::list<int> foo;
1929              std::vector<int>::iterator it =
1930                  std::find_if(moo.begin(), moo.end(),
1931                               std::bind2nd(std::less<int>(), 3));],
1932             wx_cv_lib_stl=yes,
1933             wx_cv_lib_stl=no
1934         )]
1935     )
1936
1937     if test "$wx_cv_lib_stl" != yes; then
1938          AC_MSG_ERROR([Can't use --enable-stl as basic STL functionality is missing])
1939     fi
1940
1941     dnl check for compliant std::string::compare
1942     AC_CACHE_CHECK([for compliant std::string::compare],
1943         wx_cv_func_stdstring_compare,
1944         [AC_TRY_COMPILE([#include <string>],
1945             [std::string foo, bar;
1946             foo.compare(bar);
1947             foo.compare(1, 1, bar);
1948             foo.compare(1, 1, bar, 1, 1);
1949             foo.compare("");
1950             foo.compare(1, 1, "");
1951             foo.compare(1, 1, "", 2);],
1952             wx_cv_func_stdstring_compare=yes,
1953             wx_cv_func_stdstring_compare=no
1954         )]
1955     )
1956
1957     if test "$wx_cv_func_stdstring_compare" = yes; then
1958         AC_DEFINE(HAVE_STD_STRING_COMPARE)
1959     fi
1960
1961     if test "$wx_cv_class_gnuhashmapset" = yes; then
1962          AC_DEFINE(HAVE_EXT_HASH_MAP)
1963          AC_DEFINE(HAVE_GNU_CXX_HASH_MAP)
1964     fi
1965
1966     AC_CHECK_HEADER([unordered_map],
1967         [AC_CACHE_CHECK([for unordered_map and unordered_set in std],
1968             wx_cv_class_stdunorderedmapset,
1969             [AC_TRY_COMPILE([#include <unordered_map>
1970                 #include <unordered_set>],
1971                 [std::unordered_map<double*, char*> test1;
1972                  std::unordered_set<char*> test2;],
1973                 wx_cv_class_stdunorderedmapset=yes,
1974                 wx_cv_class_stdunorderedmapset=no)
1975             ]
1976         )],
1977         [],
1978         [ ]
1979     )
1980
1981     if test "$wx_cv_class_stdunorderedmapset" = yes; then
1982          AC_DEFINE(HAVE_STD_UNORDERED_MAP)
1983          AC_DEFINE(HAVE_STD_UNORDERED_SET)
1984     else
1985         AC_CHECK_HEADER([tr1/unordered_map],
1986             [AC_CACHE_CHECK([for unordered_map and unordered_set in std::tr1],
1987                 wx_cv_class_tr1unorderedmapset,
1988                 [AC_TRY_COMPILE([#include <tr1/unordered_map>
1989                     #include <tr1/unordered_set>],
1990                     [std::tr1::unordered_map<double*, char*> test1;
1991                      std::tr1::unordered_set<char*> test2;
1992             #if defined(__GNUC__) && (__GNUC__==4) && (__GNUC_MINOR__<2)
1993             #error can't use unordered_{map,set} with gcc-4.[01]: http://gcc.gnu.org/PR24389
1994             #endif],
1995                     wx_cv_class_tr1unorderedmapset=yes,
1996                     wx_cv_class_tr1unorderedmapset=no)
1997                 ]
1998             )],
1999             [],
2000             [ ]
2001         )
2002
2003         if test "$wx_cv_class_tr1unorderedmapset" = yes; then
2004             AC_DEFINE(HAVE_TR1_UNORDERED_MAP)
2005             AC_DEFINE(HAVE_TR1_UNORDERED_SET)
2006         else
2007             dnl check for hash_map and hash_set headers
2008             AC_CHECK_HEADER([hash_map],
2009                 [AC_CACHE_CHECK([for std::hash_map and hash_set],
2010                     wx_cv_class_stdhashmapset,
2011                     [AC_TRY_COMPILE([#include <hash_map>
2012                         #include <hash_set>],
2013                         [std::hash_map<double*, char*, std::hash<double*>, std::equal_to<double*> > test1;
2014                          std::hash_set<char*, std::hash<char*>, std::equal_to<char*> > test2;],
2015                         wx_cv_class_stdhashmapset=yes,
2016                         wx_cv_class_stdhashmapset=no)
2017                     ]
2018                 )],
2019                 [],
2020                 [ ]
2021             )
2022
2023             if test "$wx_cv_class_stdhashmapset" = yes; then
2024                 AC_DEFINE(HAVE_HASH_MAP)
2025                 AC_DEFINE(HAVE_STD_HASH_MAP)
2026             fi
2027
2028             AC_CHECK_HEADER([ext/hash_map],
2029                 [AC_CACHE_CHECK([for GNU hash_map and hash_set],
2030                     wx_cv_class_gnuhashmapset,
2031                     [AC_TRY_COMPILE([#include <ext/hash_map>
2032                         #include <ext/hash_set>],
2033                         [__gnu_cxx::hash_map<double*, char*, __gnu_cxx::hash<double*>, std::equal_to<double*> > test1;
2034                          __gnu_cxx::hash_set<char*, __gnu_cxx::hash<char*>, std::equal_to<char*> > test2;],
2035                         wx_cv_class_gnuhashmapset=yes,
2036                         wx_cv_class_gnuhashmapset=no)
2037                     ]
2038                 )],
2039                 [],
2040                 [ ]
2041             )
2042
2043         fi
2044     fi
2045 fi
2046
2047 dnl check for atomic operations builtins for wx/atomic.h:
2048 WX_ATOMIC_BUILTINS
2049
2050 dnl pop C++
2051 AC_LANG_POP()
2052
2053 dnl ---------------------------------------------------------------------------
2054 dnl Define search path for includes and libraries: all headers and libs will be
2055 dnl looked for in all directories of this path
2056 dnl ---------------------------------------------------------------------------
2057
2058 dnl Notice that /usr/include should *not* be in this list, otherwise it breaks
2059 dnl compilation on Solaris/AIX/... with gcc because standard (non ANSI C)
2060 dnl headers are included instead of the "fixed" (ANSI-fied) gcc ones.
2061 dnl
2062 dnl Also try to put all directories which may contain X11R6 before those which
2063 dnl may contain X11R5/4 - we want to use R6 on machines which have both!
2064 dnl
2065 dnl In the same vein. Motif 2.1 should be tried before Motif 1.2 for the
2066 dnl systems which have both (AIX 4.x does)
2067 SEARCH_INCLUDE="\
2068     /usr/local/include        \
2069     /usr/local/X11/include    \
2070     /usr/local/include/X11    \
2071     /usr/local/X11R7/include  \
2072     /usr/local/X11R6/include  \
2073     /usr/local/include/X11R7  \
2074     /usr/local/include/X11R6  \
2075                               \
2076     /usr/Motif-2.1/include    \
2077     /usr/Motif-1.2/include    \
2078     /usr/include/Motif1.2     \
2079                               \
2080     /usr/dt/include           \
2081     /usr/openwin/include      \
2082                               \
2083     /usr/include/Xm           \
2084                               \
2085     /usr/X11R7/include        \
2086     /usr/X11R6/include        \
2087     /usr/X11R6.4/include      \
2088                               \
2089     /usr/include/X11R7        \
2090     /usr/include/X11R6        \
2091                               \
2092     /usr/X11/include          \
2093     /usr/include/X11          \
2094                               \
2095     /usr/XFree86/include/X11  \
2096     /usr/pkg/include          \
2097                               \
2098     /usr/local/X1R5/include  \
2099     /usr/local/include/X11R5  \
2100     /usr/X11R5/include        \
2101     /usr/include/X11R5        \
2102                               \
2103     /usr/local/X11R4/include  \
2104     /usr/local/include/X11R4  \
2105     /usr/X11R4/include        \
2106     /usr/include/X11R4        \
2107                               \
2108     /usr/openwin/share/include"
2109
2110 dnl try to find out the standard lib locations for the systems with multiple
2111 dnl ABIs
2112 AC_MSG_CHECKING([for libraries directory])
2113
2114 case "${host}" in
2115     *-*-irix6* )
2116         AC_CACHE_VAL(
2117             wx_cv_std_libpath,
2118             [
2119                 for d in WX_STD_LIBPATH(); do
2120                     for e in a so sl dylib dll.a; do
2121                         libc="$d/libc.$e"
2122                         if test -f $libc; then
2123                             save_LIBS="$LIBS"
2124                             LIBS="$libc"
2125                             AC_LINK_IFELSE([int main() { return 0; }],
2126                                 wx_cv_std_libpath=`echo $d | sed s@/usr/@@`)
2127                             LIBS="$save_LIBS"
2128                             if test "x$wx_cv_std_libpath" != "x"; then
2129                                 break 2
2130                             fi
2131                         fi
2132                     done
2133                 done
2134                 if test "x$wx_cv_std_libpath" = "x"; then
2135                     wx_cv_std_libpath="lib"
2136                 fi
2137             ]
2138         )
2139         ;;
2140
2141     *-*-solaris2* )
2142         dnl use ../lib or ../lib/64 depending on the size of void*
2143         if test "$ac_cv_sizeof_void_p" = 8 -a -d "/usr/lib/64"; then
2144             wx_cv_std_libpath="lib/64"
2145         else
2146             wx_cv_std_libpath="lib"
2147         fi
2148         ;;
2149
2150     *-*-linux* )
2151         dnl use ../lib or ../lib64 depending on the size of void*
2152         if test "$ac_cv_sizeof_void_p" = 8 -a \
2153                 -d "/usr/lib64" -a ! -h "/usr/lib64"; then
2154             wx_cv_std_libpath="lib64"
2155         else
2156             wx_cv_std_libpath="lib"
2157         fi
2158         ;;
2159
2160     *)
2161         wx_cv_std_libpath="lib";
2162         ;;
2163 esac
2164
2165 AC_MSG_RESULT($wx_cv_std_libpath)
2166
2167 SEARCH_LIB="`echo "$SEARCH_INCLUDE" | sed s@include@$wx_cv_std_libpath@g` /usr/$wx_cv_std_libpath"
2168
2169 dnl Cross compiling with gcc?
2170 if test "$build" != "$host" -a "$GCC" = yes; then
2171     dnl for gcc cross-compilers "$CC -print-prog-name=ld" prints the path to
2172     dnl the linker. Stripping off the trailing '/bin/ld' gives us a candiate
2173     dnl for a 'root' below which libraries and headers for the target system
2174     dnl might be installed.
2175     if cross_root=`$CC -print-prog-name=ld 2>/dev/null`; then
2176         cross_root=`dirname $cross_root`
2177         cross_root=`dirname $cross_root`
2178
2179         dnl substitute this candiate root for '^/usr' in the search lists,
2180         dnl strip out any that don't start '^/usr'.
2181         SEARCH_LIB=`for x in $SEARCH_LIB; do echo $x; done | sed -ne "s|^/usr|$cross_root|p"`
2182         SEARCH_INCLUDE=`for x in $SEARCH_INCLUDE; do echo $x; done | sed -ne "s|^/usr|$cross_root|p"`
2183         SEARCH_INCLUDE="$SEARCH_INCLUDE $cross_root/include"
2184
2185         dnl also have pkg-config search for *.pc files under this 'root'
2186         if test -z "$PKG_CONFIG_PATH"; then
2187             PKG_CONFIG_PATH="$cross_root/local/lib/pkgconfig:$cross_root/lib/pkgconfig"
2188             export PKG_CONFIG_PATH
2189         fi
2190
2191         dnl AC_PATH_XTRA doesn't work currently unless -x-includes and
2192         dnl -x-libraries are given on the command line. So if they are not
2193         dnl set then set them here to plausible defaults.
2194         if test -z "$x_includes" -o "$x_includes" = NONE; then
2195             WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, X11/Intrinsic.h)
2196             x_includes=$ac_find_includes
2197         fi
2198         if test -z "$x_libraries" -o "$x_libraries" = NONE; then
2199             WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xt)
2200             x_libraries=$ac_find_libraries
2201         fi
2202     fi
2203 fi
2204
2205 dnl ------------------------------------------------------------------------
2206 dnl Check for libraries
2207 dnl ------------------------------------------------------------------------
2208
2209 dnl flush the cache because checking for libraries below might abort
2210 AC_CACHE_SAVE
2211
2212 dnl check for glibc version
2213 dnl
2214 dnl VZ: I have no idea why had this check been there originally, but now
2215 dnl     we could probably do without it by just always adding _GNU_SOURCE
2216 if test "$USE_LINUX" = 1 -o "$USE_GNU" = 1; then
2217     AC_CACHE_CHECK([for glibc 2.1 or later], wx_cv_lib_glibc21,[
2218         AC_TRY_COMPILE([#include <features.h>],
2219             [
2220                 #if (__GLIBC__ < 2) || (__GLIBC_MINOR__ < 1)
2221                 not glibc 2.1
2222                 #endif
2223             ],
2224             [
2225                 wx_cv_lib_glibc21=yes
2226             ],
2227             [
2228                 wx_cv_lib_glibc21=no
2229             ]
2230         )
2231     ])
2232     if test "$wx_cv_lib_glibc21" = "yes"; then
2233         AC_DEFINE(wxHAVE_GLIBC2)
2234     fi
2235 fi
2236
2237 dnl we may need _GNU_SOURCE for 2 things:
2238 dnl
2239 dnl  1. to get PTHREAD_MUTEX_RECURSIVE with glibc 2.1+ (strictly speaking we
2240 dnl  only need _XOPEN_SOURCE=500 but just defining this disables _BSD_SOURCE
2241 dnl  which breaks libtiff compilation, so it is simpler to just define
2242 dnl  _GNU_SOURCE to get everything)
2243 dnl
2244 dnl  2. for Unicode functions
2245 if test "x$wx_cv_lib_glibc21" = "xyes"; then
2246     if test "$wxUSE_UNICODE" = "yes" -o "$wxUSE_THREADS" = "yes"; then
2247         AC_DEFINE(_GNU_SOURCE)
2248     fi
2249 fi
2250
2251 dnl Only add the -lm library if floating point functions cannot be used
2252 dnl without it.  This check is important on cygwin because of the bizarre
2253 dnl way that they have organized functions into libraries.  On cygwin, both
2254 dnl libc.a and libm.a are symbolic links to a single lib libcygwin.a.  This
2255 dnl means that
2256 dnl   1) linking with -lm is not necessary, and
2257 dnl   2) linking with -lm is dangerous if the order of libraries is wrong
2258 dnl In particular, if you compile any program with -mno-cygwin and link with
2259 dnl -lm, it will crash instantly when it is run.  This happens because the
2260 dnl linker incorrectly links the Cygwin libm.a (==libcygwin.a), which replaces
2261 dnl the ___main function instead of allowing it to be defined by
2262 dnl /usr/lib/mingw/libmingw32.a as it should be.
2263 dnl
2264 dnl On MacOS X, this test will find that -lm is unnecessary and leave it out.
2265 dnl
2266 dnl Just check a few floating point functions. If they are all found without
2267 dnl -lm, then we must not need -lm.
2268 have_cos=0
2269 have_floor=0
2270 AC_CHECK_FUNCS(cos, have_cos=1)
2271 AC_CHECK_FUNCS(floor, have_floor=1)
2272 AC_MSG_CHECKING(if floating point functions link without -lm)
2273 if test "$have_cos" = 1 -a "$have_floor" = 1; then
2274     AC_MSG_RESULT(yes)
2275 else
2276     AC_MSG_RESULT(no)
2277     LIBS="$LIBS -lm"
2278     # use different functions to avoid configure caching
2279     have_sin=0
2280     have_ceil=0
2281     AC_CHECK_FUNCS(sin, have_sin=1)
2282     AC_CHECK_FUNCS(ceil, have_ceil=1)
2283     AC_MSG_CHECKING(if floating point functions link with -lm)
2284     if test "$have_sin" = 1 -a "$have_ceil" = 1; then
2285         AC_MSG_RESULT(yes)
2286     else
2287         AC_MSG_RESULT(no)
2288         # not sure we should warn the user, crash, etc.
2289     fi
2290 fi
2291
2292 dnl check for C99 string to long long conversion functions, assume that if we
2293 dnl have the unsigned variants, then we have the signed ones as well
2294 dnl
2295 dnl at least under SGI these functions are only available in C99 code and not
2296 dnl in C++ so do these tests using C++ compiler
2297 AC_LANG_PUSH(C++)
2298 if test "wxUSE_UNICODE" = "yes"; then
2299     WX_CHECK_FUNCS(wcstoull)
2300 else
2301     WX_CHECK_FUNCS(strtoull)
2302 fi
2303 AC_LANG_POP()
2304
2305 dnl ---------------------------------------------------------------------------
2306 dnl Optional libraries
2307 dnl
2308 dnl   --with-<lib>=sys
2309 dnl       looks for system library and fails if not found
2310 dnl
2311 dnl   --with-<lib>
2312 dnl   --with-<lib>=yes
2313 dnl       looks for system library and, if not found, prints a warning,
2314 dnl       falls back to the builtin wx version, and continues configuration
2315 dnl
2316 dnl   --with-<lib>=builtin
2317 dnl       uses builtin wx version without searching for system library
2318 dnl
2319 dnl   --with-<lib>=no
2320 dnl   --without-<lib>
2321 dnl       do not use library (neither system nor builtin wx version)
2322 dnl
2323 dnl ---------------------------------------------------------------------------
2324
2325 dnl ------------------------------------------------------------------------
2326 dnl Check for regex libraries
2327 dnl ------------------------------------------------------------------------
2328
2329 if test "$wxUSE_REGEX" != "no"; then
2330     AC_DEFINE(wxUSE_REGEX)
2331
2332     if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_REGEX" = "yes"; then
2333         AC_MSG_WARN([Defaulting to the builtin regex library for Unicode build.])
2334         wxUSE_REGEX=builtin
2335     fi
2336
2337     if test "$wxUSE_REGEX" = "sys" -o "$wxUSE_REGEX" = "yes" ; then
2338         dnl according to Unix 98 specs, regcomp() is in libc but I believe that
2339         dnl on some old systems it may be in libregex - check for it too?
2340         AC_CHECK_HEADER(regex.h, [AC_CHECK_FUNCS(regcomp re_search)],, [ ])
2341
2342         if test "x$ac_cv_func_regcomp" != "xyes"; then
2343             if test "$wxUSE_REGEX" = "sys" ; then
2344                 AC_MSG_ERROR([system regex library not found! Use --with-regex to use built-in version])
2345             else
2346                 AC_MSG_WARN([system regex library not found, will use built-in instead])
2347                 wxUSE_REGEX=builtin
2348             fi
2349         else
2350             dnl we are using the system library
2351             wxUSE_REGEX=sys
2352             dnl only the built-in supports advanced REs
2353             AC_DEFINE(WX_NO_REGEX_ADVANCED)
2354         fi
2355     fi
2356 fi
2357
2358 dnl ------------------------------------------------------------------------
2359 dnl Check for zlib compression library
2360 dnl ------------------------------------------------------------------------
2361
2362 ZLIB_LINK=
2363 if test "$wxUSE_ZLIB" != "no" ; then
2364     AC_DEFINE(wxUSE_ZLIB)
2365
2366     if test "$wxUSE_ZLIB" = "sys" -o "$wxUSE_ZLIB" = "yes" ; then
2367         dnl don't test for zlib under Mac -- its verson there is 1.1.3 but we
2368         dnl should still use it because hopefully (can someone confirm this?)
2369         dnl Apple did fix the security problem in it and not using the system
2370         dnl library results in a whole bunch of warnings when linking with
2371         dnl Carbon framework
2372         if test "$USE_DARWIN" = 1; then
2373             system_zlib_h_ok="yes"
2374         else
2375             dnl we have troubles with ancient zlib versions (e.g. 1.0.4 is
2376             dnl known to not work) and although I don't know which is
2377             dnl the minimal required version it's safer to test for 1.1.4 as
2378             dnl it fixes a security problem in 1.1.3 -- and hopefully nobody
2379             dnl has anything more ancient (1.1.3 was released in July 1998)
2380             dnl anyhow
2381             AC_CACHE_CHECK([for zlib.h >= 1.1.4], ac_cv_header_zlib_h,
2382                 [AC_TRY_RUN(
2383                     dnl zlib.h defines ZLIB_VERSION="x.y.z"
2384                     [
2385                         #include <zlib.h>
2386                         #include <stdio.h>
2387
2388                         int main()
2389                         {
2390                             FILE *f=fopen("conftestval", "w");
2391                             if (!f) exit(1);
2392                             fprintf(f, "%s",
2393                                     ZLIB_VERSION[0] == '1' &&
2394                                     (ZLIB_VERSION[2] > '1' ||
2395                                     (ZLIB_VERSION[2] == '1' &&
2396                                      ZLIB_VERSION[4] >= '4')) ? "yes" : "no");
2397                             exit(0);
2398                         }
2399                     ],
2400                     ac_cv_header_zlib_h=`cat conftestval`,
2401                     ac_cv_header_zlib_h=no,
2402                     dnl cross-compiling: don't have an answer, try later
2403                     unset ac_cv_header_zlib_h
2404                 )]
2405             )
2406             dnl If the test above did not come up with a value (e.g. cross
2407             dnl compiling) then this should give a definitive answer
2408             AC_CHECK_HEADER(zlib.h,,, [ ])
2409
2410             system_zlib_h_ok=$ac_cv_header_zlib_h
2411         fi
2412
2413         if test "$system_zlib_h_ok" = "yes"; then
2414             AC_CHECK_LIB(z, deflate, ZLIB_LINK=" -lz")
2415         fi
2416
2417         if test "x$ZLIB_LINK" = "x" ; then
2418             if test "$wxUSE_ZLIB" = "sys" ; then
2419                 AC_MSG_ERROR([zlib library not found or too old! Use --with-zlib=builtin to use built-in version])
2420             else
2421                 AC_MSG_WARN([zlib library not found or too old, will use built-in instead])
2422                 wxUSE_ZLIB=builtin
2423             fi
2424         else
2425             dnl we are using the system library
2426             wxUSE_ZLIB=sys
2427         fi
2428     fi
2429 fi
2430
2431 dnl ------------------------------------------------------------------------
2432 dnl Check for png library
2433 dnl ------------------------------------------------------------------------
2434
2435 PNG_LINK=
2436 if test "$wxUSE_LIBPNG" != "no" ; then
2437     AC_DEFINE(wxUSE_LIBPNG)
2438
2439     if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBPNG" = "builtin" ; then
2440         AC_MSG_WARN([wxMGL doesn't work with builtin png library, will use MGL one instead])
2441         wxUSE_LIBPNG=sys
2442     fi
2443
2444     dnl for the check below to have a chance to succeed, we must already have
2445     dnl libz somewhere (don't do this when bulding wxMGL since its libpng
2446     dnl doesn't depend on zlib)
2447     if test "$wxUSE_MGL" != 1 -a "$wxUSE_LIBPNG" = "sys" -a "$wxUSE_ZLIB" != "sys" ; then
2448         AC_MSG_WARN([system png library doesn't work without system zlib, will use built-in instead])
2449         wxUSE_LIBPNG=builtin
2450     fi
2451
2452     if test "$wxUSE_MGL" != 1 ; then
2453         dnl Don't check for libpng when building wxMGL, libmgl contains it
2454         if test "$wxUSE_LIBPNG" = "sys" -o "$wxUSE_LIBPNG" = "yes" ; then
2455             dnl libpng version 0.9 is known to not work, if an even newer
2456             dnl version is required, just bump it up in the test below
2457             AC_CACHE_CHECK([for png.h > 0.90], ac_cv_header_png_h,
2458                 [AC_TRY_RUN(
2459                     dnl png.h defines PNG_LIBPNG_VER=number
2460                     [
2461                         #include <png.h>
2462                         #include <stdio.h>
2463
2464                         int main()
2465                         {
2466                             FILE *f=fopen("conftestval", "w");
2467                             if (!f) exit(1);
2468                             fprintf(f, "%s",
2469                                      PNG_LIBPNG_VER > 90 ? "yes" : "no");
2470                             exit(0);
2471                         }
2472                     ],
2473                     ac_cv_header_png_h=`cat conftestval`,
2474                     ac_cv_header_png_h=no,
2475                     dnl cross-compiling: test (later) if we have any png.h
2476                     unset ac_cv_header_png_h
2477                 )]
2478             )
2479             AC_CHECK_HEADER(png.h,,, [ ])
2480
2481             if test "$ac_cv_header_png_h" = "yes"; then
2482                 AC_CHECK_LIB(png, png_check_sig, PNG_LINK=" -lpng -lz", , [-lz -lm])
2483             fi
2484
2485             if test "x$PNG_LINK" = "x" ; then
2486                 if test "$wxUSE_LIBPNG" = "sys" ; then
2487                     AC_MSG_ERROR([system png library not found or too old! Use --with-libpng=builtin to use built-in version])
2488                 else
2489                     AC_MSG_WARN([system png library not found or too old, will use built-in instead])
2490                     wxUSE_LIBPNG=builtin
2491                 fi
2492             else
2493                 dnl we are using the system library
2494                 wxUSE_LIBPNG=sys
2495             fi
2496         fi
2497     fi
2498 fi
2499
2500 dnl ------------------------------------------------------------------------
2501 dnl Check for jpeg library
2502 dnl ------------------------------------------------------------------------
2503
2504 dnl this check must be done before the check for libtiff as libtiff uses
2505 dnl libjpeg itself
2506 JPEG_LINK=
2507 if test "$wxUSE_LIBJPEG" != "no" ; then
2508     AC_DEFINE(wxUSE_LIBJPEG)
2509
2510     if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBJPEG" = "builtin" ; then
2511         AC_MSG_WARN([wxMGL doesn't work with builtin jpeg library, will use MGL one instead])
2512         wxUSE_LIBJPEG=sys
2513     fi
2514
2515     if test "$wxUSE_MGL" != 1 ; then
2516         dnl Don't check for libjpeg when building wxMGL, libmgl contains it
2517         if test "$wxUSE_LIBJPEG" = "sys" -o "$wxUSE_LIBJPEG" = "yes" ; then
2518             dnl can't use AC_CHECK_HEADER as jconfig.h defines things like
2519             dnl HAVE_STDLIB_H which are already defined and this provokes
2520             dnl a compiler warning which configure considers as an error...
2521             AC_MSG_CHECKING(for jpeglib.h)
2522             AC_CACHE_VAL(ac_cv_header_jpeglib_h,
2523                 AC_TRY_COMPILE(
2524                     [
2525                         #undef HAVE_STDLIB_H
2526                         #include <stdio.h>
2527                         #include <jpeglib.h>
2528                     ],
2529                     [
2530                     ],
2531                     ac_cv_header_jpeglib_h=yes,
2532                     ac_cv_header_jpeglib_h=no
2533                 )
2534             )
2535             AC_MSG_RESULT($ac_cv_header_jpeglib_h)
2536
2537             if test "$ac_cv_header_jpeglib_h" = "yes"; then
2538                 AC_CHECK_LIB(jpeg, jpeg_read_header, JPEG_LINK=" -ljpeg")
2539             fi
2540
2541             if test "x$JPEG_LINK" = "x" ; then
2542                 if test "$wxUSE_LIBJPEG" = "sys" ; then
2543                     AC_MSG_ERROR([system jpeg library not found! Use --with-libjpeg=builtin to use built-in version])
2544                 else
2545                     AC_MSG_WARN([system jpeg library not found, will use built-in instead])
2546                     wxUSE_LIBJPEG=builtin
2547                 fi
2548             else
2549                 dnl we are using the system library
2550                 wxUSE_LIBJPEG=sys
2551
2552                 if test "$wxUSE_MSW" = 1; then
2553                     dnl boolean is defined by the jpeg headers and also by the
2554                     dnl Windows headers of some compilers. This type has been
2555                     dnl renamed in the builtin, so it is only an issue when
2556                     dnl using an external jpeg lib on Windows.
2557                     AC_CHECK_TYPES(
2558                         [boolean],
2559                         [
2560                             AC_CHECK_SIZEOF(
2561                                 [boolean],
2562                                 [],
2563                                 [
2564                                     #undef HAVE_BOOLEAN
2565                                     #include <stdio.h>
2566                                     #include <jpeglib.h>
2567                                 ])
2568                             AC_DEFINE_UNQUOTED(
2569                                 [wxHACK_BOOLEAN],
2570                                 [wxInt`expr 8 \* $ac_cv_sizeof_boolean`])
2571                         ],
2572                         [],
2573                         [#include <windows.h>])
2574                 fi
2575             fi
2576         fi
2577     fi
2578 fi
2579
2580 dnl ------------------------------------------------------------------------
2581 dnl Check for tiff library
2582 dnl ------------------------------------------------------------------------
2583
2584 TIFF_LINK=
2585 TIFF_PREREQ_LINKS=-lm
2586 if test "$wxUSE_LIBTIFF" != "no" ; then
2587     AC_DEFINE(wxUSE_LIBTIFF)
2588
2589     if test "$wxUSE_LIBTIFF" = "sys" -o "$wxUSE_LIBTIFF" = "yes" ; then
2590         dnl libtiff may depend on libjpeg and libz so use them in the test
2591         dnl below or it would fail
2592         if test "$wxUSE_LIBJPEG" = "sys"; then
2593             TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $JPEG_LINK"
2594         fi
2595         if test "$wxUSE_ZLIB" = "sys"; then
2596             TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $ZLIB_LINK"
2597         fi
2598         AC_CHECK_HEADER(tiffio.h,
2599                         [
2600                             AC_CHECK_LIB(tiff, TIFFError,
2601                                          TIFF_LINK=" -ltiff",
2602                                          ,
2603                                          $TIFF_PREREQ_LINKS)
2604                         ],
2605                         [],
2606                         [ ]
2607                        )
2608
2609         if test "x$TIFF_LINK" = "x" ; then
2610             if test "$wxUSE_LIBTIFF" = "sys" ; then
2611                 AC_MSG_ERROR([system tiff library not found! Use --with-libtiff=builtin to use built-in version])
2612             else
2613                 AC_MSG_WARN([system tiff library not found, will use built-in instead])
2614                 wxUSE_LIBTIFF=builtin
2615             fi
2616         else
2617             dnl we are using the system library
2618             wxUSE_LIBTIFF=sys
2619         fi
2620     fi
2621     if test "$wxUSE_LIBTIFF" = "builtin" ; then
2622         if test "$wxUSE_LIBJPEG" = "no"; then
2623             dnl we have to prevent the builtin libtiff configure from building the
2624             dnl library with JPEG support as this was explicitly disabled by user,
2625             dnl but unfortunately it needs --disable-jpeg and not --without-libjpeg
2626             dnl (which will be passed to it anyhow as configure passes arguments to
2627             dnl the top-level script to all the other ones called recursively), so
2628             dnl we need to hack around this
2629             ac_configure_args="$ac_configure_args --disable-jpeg"
2630         fi
2631         AC_CONFIG_SUBDIRS([src/tiff])
2632     fi
2633 fi
2634
2635 dnl ------------------------------------------------------------------------
2636 dnl Check for expat libraries
2637 dnl ------------------------------------------------------------------------
2638
2639 if test "$wxUSE_WCHAR_T" != "yes"; then
2640     if test "$wxUSE_EXPAT" != "no"; then
2641         AC_MSG_WARN([wxWidgets requires wchar_t to use expat, disabling])
2642         wxUSE_EXPAT=no
2643     fi
2644     if test "$wxUSE_XML" != "no"; then
2645         AC_MSG_WARN([wxWidgets requires wchar_t to use xml, disabling])
2646         wxUSE_XML=no
2647     fi
2648 fi
2649
2650 if test "$wxUSE_EXPAT" != "no"; then
2651     wxUSE_XML=yes
2652     AC_DEFINE(wxUSE_EXPAT)
2653     AC_DEFINE(wxUSE_XML)
2654
2655     if test "$wxUSE_EXPAT" = "sys" -o "$wxUSE_EXPAT" = "yes" ; then
2656         AC_CHECK_HEADER([expat.h], [found_expat_h=1],, [ ])
2657         if test "x$found_expat_h" = "x1"; then
2658             dnl Expat 1.95.6 comes with broken expat.h:
2659             AC_CACHE_CHECK([if expat.h is valid C++ header],
2660                 wx_cv_expat_is_not_broken,
2661                 [
2662                 AC_LANG_PUSH(C++)
2663                 AC_TRY_COMPILE([#include <expat.h>],[],
2664                     wx_cv_expat_is_not_broken=yes,
2665                     wx_cv_expat_is_not_broken=no
2666                 )
2667                 AC_LANG_POP()
2668                 ]
2669             )
2670             if test "$wx_cv_expat_is_not_broken" = "yes" ; then
2671                 AC_CHECK_LIB(expat, XML_ParserCreate, EXPAT_LINK=" -lexpat")
2672             fi
2673         fi
2674         if test "x$EXPAT_LINK" = "x" ; then
2675             if test "$wxUSE_EXPAT" = "sys" ; then
2676                 AC_MSG_ERROR([system expat library not found! Use --with-expat=builtin to use built-in version])
2677             else
2678                 AC_MSG_WARN([system expat library not found, will use built-in instead])
2679                 wxUSE_EXPAT=builtin
2680             fi
2681         else
2682             dnl we are using the system library
2683             wxUSE_EXPAT=sys
2684         fi
2685     fi
2686     if test "$wxUSE_EXPAT" = "builtin" ; then
2687         dnl Expat needs this:
2688         AC_CONFIG_SUBDIRS([src/expat])
2689     fi
2690 fi
2691
2692
2693 dnl ------------------------------------------------------------------------
2694 dnl Check for libmspack
2695 dnl ------------------------------------------------------------------------
2696
2697 if test "$wxUSE_LIBMSPACK" != "no"; then
2698     AC_CHECK_HEADER([mspack.h], [found_mspack_h=1],, [ ])
2699     if test "x$found_mspack_h" = "x1"; then
2700         AC_CHECK_LIB(mspack, mspack_create_chm_decompressor,
2701                      MSPACK_LINK=" -lmspack")
2702     fi
2703     if test "x$MSPACK_LINK" = "x" ; then
2704         wxUSE_LIBMSPACK=no
2705     fi
2706 fi
2707
2708 if test "$wxUSE_LIBMSPACK" != "no"; then
2709     AC_DEFINE(wxUSE_LIBMSPACK)
2710 fi
2711
2712
2713 dnl ----------------------------------------------------------------
2714 dnl search for toolkit (widget sets)
2715 dnl ----------------------------------------------------------------
2716
2717 AFMINSTALL=
2718 WIN32INSTALL=
2719
2720 TOOLKIT=
2721 TOOLKIT_INCLUDE=
2722 WIDGET_SET=
2723
2724 dnl are we building for a win32 target environment?
2725 dnl If so, setup common stuff needed for both GUI and Base libs.
2726 if test "$USE_WIN32" = 1 ; then
2727     AC_CHECK_HEADERS(w32api.h,,, [ ])
2728     AC_CHECK_HEADER(windows.h,,
2729     [
2730         AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
2731     ],
2732     [ ])
2733
2734     dnl --- FIXME: This is still a somewhat random list of libs,
2735     dnl ---        some of them should probably be included conditionally.
2736     case "${host}" in
2737         x86_64-*-mingw32* )
2738             dnl --- For mingw-w64 lctl3d32's name has changed
2739             LIBS="$LIBS -lwinspool -lwinmm -lshell32 -lcomctl32 -lcomdlg32 -lwctl3d32 -ladvapi32 -lwsock32 -lgdi32"
2740         ;;
2741         * )
2742             LIBS="$LIBS -lwinspool -lwinmm -lshell32 -lcomctl32 -lcomdlg32 -lctl3d32 -ladvapi32 -lwsock32 -lgdi32"
2743         ;;
2744     esac
2745     if test "$wxUSE_ACCESSIBILITY" = "yes" ; then
2746         LIBS="$LIBS -loleacc"
2747     fi
2748
2749     case "${host}" in
2750         *-*-cygwin* )
2751             dnl Cygwin doesn't include these by default
2752             LIBS="$LIBS -lkernel32 -luser32"
2753     esac
2754
2755     dnl This one is still used by some sample makefiles.
2756     RESFLAGS="--include-dir \$(top_srcdir)/include --include-dir \$(top_srcdir)/\$(program_dir) --define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
2757     RESPROGRAMOBJ="\$(PROGRAM)_resources.o"
2758
2759     dnl This lot we export to wx-config.  It must add the relevant
2760     dnl include directories at the point when they can be known.
2761     dnl (but are these (still) required anyway?)
2762     WXCONFIG_RESFLAGS="--define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
2763
2764     dnl install Win32-specific files in "make install"
2765     WIN32INSTALL=win32install
2766
2767     dnl pbt.h is missing on Wine at least
2768     AC_CHECK_HEADER([pbt.h],, [AC_DEFINE(NEED_PBT_H)], [ ])
2769 fi
2770
2771 if test "$wxUSE_GUI" = "yes"; then
2772     USE_GUI=1
2773
2774     GUI_TK_LIBRARY=
2775
2776     WXGTK12=
2777     WXGTK127=
2778     WXGTK2=
2779     WXGPE=
2780
2781     if test "$wxUSE_COCOA" = 1 ; then
2782         if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes"; then
2783             AC_MSG_WARN([Printing not supported under wxCocoa yet, disabled])
2784             wxUSE_PRINTING_ARCHITECTURE=no
2785         fi
2786         if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
2787             AC_MSG_WARN([Drag and Drop not supported under wxCocoa yet, disabled])
2788             wxUSE_DRAG_AND_DROP=no
2789         fi
2790         if test "$wxUSE_DRAGIMAGE" = "yes"; then
2791             AC_MSG_WARN([wxDragImage not supported under wxCocoa yet, disabled])
2792             wxUSE_DRAGIMAGE=no
2793         fi
2794     fi
2795
2796     if test "$wxUSE_MSW" = 1 ; then
2797         TOOLKIT=MSW
2798         GUIDIST=MSW_DIST
2799
2800         dnl -mwindows causes a heap of other default gui libs to be linked in.
2801         case "${host}" in
2802             *-*-mingw32* )
2803                 WXCONFIG_LDFLAGS_GUI="$LDFLAGS -Wl,--subsystem,windows -mwindows"
2804         esac
2805     fi
2806
2807     if test "$wxUSE_GTK" = 1; then
2808         dnl GTK+ test program must be compiled with C compiler
2809         AC_MSG_CHECKING([for GTK+ version])
2810
2811         gtk_version_cached=1
2812         AC_CACHE_VAL(wx_cv_lib_gtk,
2813             [
2814                 dnl stupid GTK+ AM macros produce their own messages, so we
2815                 dnl have to pass to the next line
2816                 gtk_version_cached=0
2817                 AC_MSG_RESULT()
2818
2819                 dnl we must link against lgthread unless the user
2820                 dnl used --disable-threads
2821                 GTK_MODULES=
2822                 if test "$wxUSE_THREADS" = "yes"; then
2823                     GTK_MODULES=gthread
2824                 fi
2825
2826                 dnl detect GTK2
2827                 wx_cv_lib_gtk=
2828                 if test "x$wxGTK_VERSION" != "x1"
2829                 then
2830                     dnl The gthread.pc that ships with Solaris returns '-mt',
2831                     dnl it's correct for Sun CC, but gcc requires '-pthreads'.
2832                     dnl So disable the compile check and remove the -mt below.
2833                     case "${host}" in
2834                         *-*-solaris2* )
2835                             if test "$wxUSE_THREADS" = "yes" -a "$GCC" = yes; then
2836                                 enable_gtktest=no
2837                             fi
2838                     esac
2839
2840                     AM_PATH_GTK_2_0(2.4.0, wx_cv_lib_gtk=2.0, , $GTK_MODULES)
2841
2842                     dnl Solaris also requires -lX11 for static lib
2843                     case "${host}" in
2844                         *-*-solaris2* )
2845                             if test "$wxUSE_SHARED" != "yes"; then
2846                                 GTK_LIBS="$GTK_LIBS -lX11"
2847                             fi
2848                     esac
2849                 fi
2850
2851                 dnl detect GTK1.x
2852                 if test -z "$wx_cv_lib_gtk"; then
2853                     if test "x$wxGTK_VERSION" = "x1" -o "x$wxGTK_VERSION" = "xany" ; then
2854                         AM_PATH_GTK(1.2.7, wx_cv_lib_gtk=1.2.7, , $GTK_MODULES)
2855
2856                         if test -z "$wx_cv_lib_gtk"; then
2857                             AM_PATH_GTK(1.2.3, wx_cv_lib_gtk=1.2.3, , $GTK_MODULES)
2858                         fi
2859                     fi
2860                 fi
2861
2862                 if test -z "$wx_cv_lib_gtk"; then
2863                     dnl looks better in AC_MSG_RESULT
2864                     wx_cv_lib_gtk=none
2865                 else
2866                     dnl we need to cache GTK_CFLAGS and GTK_LIBS for the
2867                     dnl subsequent runs
2868                     wx_cv_cflags_gtk=$GTK_CFLAGS
2869                     wx_cv_libs_gtk=`echo $GTK_LIBS | sed -e 's/ -l[[^ ]]*cairo[[^ ]]*//g'`
2870                 fi
2871             ]
2872         )
2873
2874         dnl if it wasn't cached, the messages from AM_PATH_GTK() above are
2875         dnl enough
2876         if test "$gtk_version_cached" = 1; then
2877             AC_MSG_RESULT($wx_cv_lib_gtk)
2878         fi
2879
2880         case "$wx_cv_lib_gtk" in
2881             2.0)    WXGTK2=1
2882                     TOOLKIT_VERSION=2
2883                     ;;
2884             1.2.7)  WXGTK127=1
2885                     WXGTK12=1
2886                     ;;
2887             1.2.3)  WXGTK12=1
2888                     ;;
2889             *)      AC_MSG_ERROR([
2890 The development files for GTK+ were not found. For GTK+ 2, please
2891 ensure that pkg-config is in the path and that gtk+-2.0.pc is
2892 installed. For GTK+ 1.2 please check that gtk-config is in the path,
2893 and that the version is 1.2.3 or above. Also check that the
2894 libraries returned by 'pkg-config gtk+-2.0 --libs' or 'gtk-config
2895 --libs' are in the LD_LIBRARY_PATH or equivalent.
2896                             ])
2897                     ;;
2898         esac
2899
2900         if test "$WXGTK2" = 1; then
2901             save_CFLAGS="$CFLAGS"
2902             save_LIBS="$LIBS"
2903             CFLAGS="$wx_cv_cflags_gtk $CFLAGS"
2904             LIBS="$LIBS $wx_cv_libs_gtk"
2905
2906             dnl test if we have at least GTK+ 2.10:
2907             AC_MSG_CHECKING([if GTK+ is version >= 2.10])
2908             AC_TRY_COMPILE([
2909                             #include <gtk/gtk.h>
2910                            ],
2911                            [
2912                             #if !GTK_CHECK_VERSION(2,10,0)
2913                             Not GTK+ 2.10
2914                             #endif
2915                            ],
2916                            [
2917                             AC_DEFINE(__WXGTK210__)
2918                             AC_DEFINE(__WXGTK26__)
2919                             AC_MSG_RESULT([yes])
2920                             ac_wxgtk210=1
2921                            ],
2922                            [
2923                             AC_MSG_RESULT([no])
2924                             ac_wxgtk210=0
2925                            ])
2926
2927             if test "$ac_wxgtk210" = 0; then
2928                 dnl test if we have at least GTK+ 2.6:
2929                 AC_MSG_CHECKING([if GTK+ is version >= 2.6])
2930                 AC_TRY_COMPILE([
2931                                 #include <gtk/gtk.h>
2932                             ],
2933                             [
2934                                 #if !GTK_CHECK_VERSION(2,6,0)
2935                                 Not GTK+ 2.6
2936                                 #endif
2937                             ],
2938                             [
2939                                 AC_DEFINE(__WXGTK26__)
2940                                 AC_MSG_RESULT([yes])
2941                                 ac_wxgtk26=1
2942                             ],
2943                             [
2944                                 AC_MSG_RESULT([no])
2945                                 ac_wxgtk26=0
2946                             ])
2947             fi
2948
2949             CFLAGS="$save_CFLAGS"
2950             LIBS="$save_LIBS"
2951         else
2952             if test "$wxUSE_UNICODE" = "yes"; then
2953                 AC_MSG_WARN([Unicode configuration not supported with GTK+ 1.x])
2954                 wxUSE_UNICODE=no
2955             fi
2956
2957             dnl test for XIM support in libgdk
2958             AC_CHECK_LIB(gdk, gdk_im_open, AC_DEFINE(HAVE_XIM))
2959
2960             dnl we need poll() in src/gtk1/app.cpp (we know that Darwin doesn't
2961             dnl have it but we do the check for the others)
2962             if test "$USE_DARWIN" != 1; then
2963                 AC_CHECK_FUNCS(poll)
2964             fi
2965         fi
2966
2967         TOOLKIT_INCLUDE="$wx_cv_cflags_gtk"
2968         GUI_TK_LIBRARY="$wx_cv_libs_gtk $GUI_TK_LIBRARY"
2969
2970         AFMINSTALL=afminstall
2971         TOOLKIT=GTK
2972         GUIDIST=GTK_DIST
2973
2974         dnl test for external libxpm if we're configured to use it
2975         if test "$wxUSE_GPE" = "yes"; then
2976             AC_MSG_CHECKING(for gpewidget library)
2977             WX_PATH_FIND_LIBRARIES($SEARCH_LIB,gpewidget)
2978             if test "$ac_find_libraries" != "" ; then
2979                 WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
2980                 dnl -lgpewidget must be before all GTK libs and
2981                 dnl we guess its path from the prefix
2982                 GUI_TK_LIBRARY="-L${prefix}/lib -lgpewidget $GUI_TK_LIBRARY"
2983                 WXGPE=1
2984                 AC_MSG_RESULT([found in $ac_find_libraries])
2985             else
2986                 AC_MSG_RESULT(not found)
2987             fi
2988
2989             dnl AC_MSG_CHECKING(for gpe library)
2990             dnl WX_PATH_FIND_LIBRARIES($SEARCH_LIB,gpe)
2991             dnl if test "$ac_find_libraries" != "" ; then
2992             dnl     WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
2993             dnl     GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lgpe"
2994             dnl     AC_MSG_RESULT(found in $ac_find_libraries)
2995             dnl else
2996             dnl     AC_MSG_RESULT(not found)
2997             dnl fi
2998         fi
2999     fi
3000
3001     if test "$wxUSE_MGL" = 1; then
3002        AC_MSG_CHECKING(for SciTech MGL library)
3003         if test "x$MGL_ROOT" = x ; then
3004             AC_MSG_RESULT(not found)
3005             AC_MSG_ERROR([Cannot find MGL library. Make sure MGL_ROOT is set.])
3006         else
3007             AC_MSG_RESULT($MGL_ROOT)
3008         fi
3009
3010         AC_MSG_CHECKING(for libmgl location)
3011         dnl Find MGL library that we want
3012         dnl FIXME_MGL - test for MGL variants for freebsd etc.;
3013         dnl             and for non-x86 versions
3014         case "${host}" in
3015             *-*-linux* )
3016               dnl glibc.so, glibc are for older versions of MGL,
3017               dnl x86/a, x86/so are used by >= 5.0 R11
3018               if test "x$wxUSE_SHARED" = xyes ; then
3019                   mgl_os_candidates="linux/gcc/x86/so linux/gcc/x86/a linux/gcc/glibc.so linux/gcc/glibc"
3020               else
3021                   mgl_os_candidates="linux/gcc/x86/a linux/gcc/x86/so linux/gcc/glibc linux/gcc/glibc.so"
3022               fi
3023               ;;
3024             *-pc-msdosdjgpp )
3025               mgl_os_candidates="dos32/dj2"
3026               ;;
3027             *)
3028               AC_MSG_ERROR(This system type ${host} is not yet supported by wxMGL.)
3029         esac
3030
3031         mgl_lib_type=""
3032         mgl_os=""
3033
3034         for mgl_os_i in $mgl_os_candidates ; do
3035             if test "x$mgl_os" = x ; then
3036                 if test "$wxUSE_DEBUG_FLAG" = yes ; then
3037                     if test -f $MGL_ROOT/lib/debug/$mgl_os_i/libmgl.a -o \
3038                             -f $MGL_ROOT/lib/debug/$mgl_os_i/libmgl.so; then
3039                         mgl_lib_type=debug
3040                         mgl_os=$mgl_os_i
3041                     fi
3042                 fi
3043                 if test "x$mgl_lib_type" = x ; then
3044                     if test -f $MGL_ROOT/lib/release/$mgl_os_i/libmgl.a -o \
3045                             -f $MGL_ROOT/lib/release/$mgl_os_i/libmgl.so; then
3046                         mgl_lib_type=release
3047                         mgl_os=$mgl_os_i
3048                     fi
3049                 fi
3050             fi
3051         done
3052
3053         if test "x$mgl_os" = x ; then
3054             AC_MSG_RESULT(not found)
3055             AC_MSG_ERROR([Cannot find MGL libraries, make sure they are compiled.])
3056         fi
3057         AC_MSG_RESULT("$MGL_ROOT/lib/$mgl_lib_type/$mgl_os")
3058
3059         wxUSE_UNIVERSAL="yes"
3060
3061         TOOLKIT_INCLUDE="-I$MGL_ROOT/include"
3062         GUI_TK_LIBRARY="-L$MGL_ROOT/lib/$mgl_lib_type/$mgl_os -lmgl -lmglcpp -lpm"
3063
3064         AFMINSTALL=afminstall
3065         TOOLKIT=MGL
3066         GUIDIST=MGL_DIST
3067     fi
3068
3069     if test "$wxUSE_DFB" = 1; then
3070        PKG_PROG_PKG_CONFIG()
3071
3072        PKG_CHECK_MODULES(DIRECTFB,
3073                          [directfb >= 0.9.23],
3074                          [
3075                            wxUSE_UNIVERSAL="yes"
3076                            TOOLKIT_INCLUDE="$DIRECTFB_CFLAGS"
3077                            GUI_TK_LIBRARY="$DIRECTFB_LIBS"
3078                            TOOLKIT=DFB
3079                            GUIDIST=DFB_DIST
3080                          ],
3081                          [
3082                            AC_MSG_ERROR([DirectFB not found.])
3083                          ]
3084                          )
3085     fi
3086
3087     if test "$wxUSE_MICROWIN" = 1; then
3088         AC_MSG_CHECKING(for MicroWindows)
3089         if test "x$MICROWINDOWS" = x ; then
3090             AC_MSG_RESULT(not found)
3091             AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWINDOWS is set.])
3092         else
3093             AC_MSG_RESULT($MICROWINDOWS)
3094         fi
3095
3096         if test -f $MICROWINDOWS/lib/libmwin.a; then
3097             AC_MSG_RESULT(MicroWindows' libraries found.)
3098         else
3099             AC_MSG_ERROR([Cannot find MicroWindows libraries, make sure they are compiled.])
3100         fi
3101
3102         TOOLKIT_INCLUDE="-I$MICROWINDOWS/include"
3103         GUI_TK_LIBRARY="-L$MICROWINDOWS/lib -lmwin -lmwengine -mwfonts -mwdrivers -mwinlib"
3104
3105         wxUSE_UNIVERSAL="yes"
3106
3107         AFMINSTALL=afminstall
3108         TOOLKIT=MICROWIN
3109         GUIDIST=MICROWIN_DIST
3110
3111         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXMSW__ -D__WIN95__ -D__WIN32__ -DMWIN -DMICROWIN_NOCONTROLS -DMICROWIN_TODO=1"
3112     fi
3113
3114     dnl common part of X11 and Motif port checks
3115     if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
3116         dnl use standard macros to check for X headers/libs, this brings
3117         dnl support for the standard configure options --x-includes,
3118         dnl --x-libraries and --no-x
3119         AC_PATH_XTRA
3120
3121         if test "$no_x" = "yes"; then
3122           AC_MSG_ERROR([X11 not found, please use --x-includes and/or --x-libraries options (see config.log for details)])
3123         fi
3124
3125         dnl for some reason AC_PATH_XTRA seems to add -INONE and -LNONE (and
3126         dnl also sometimes -RNONE) to X_CFLAGS and X_LIBS respectively, filter
3127         dnl this junk out
3128         GUI_TK_LIBRARY=`echo $X_LIBS | sed 's/ -LNONE//' | sed 's/ -RNONE//'`
3129         TOOLKIT_INCLUDE=`echo $X_CFLAGS | sed 's/ -INONE//'`
3130         AFMINSTALL=afminstall
3131         COMPILED_X_PROGRAM=0
3132
3133     fi
3134
3135     if test "$wxUSE_X11" = 1; then
3136         if test "$wxUSE_NANOX" = "yes"; then
3137             AC_MSG_CHECKING(for MicroWindows/NanoX distribution)
3138             if test "x$MICROWIN" = x ; then
3139                 AC_MSG_RESULT(not found)
3140                 AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWIN is set.])
3141             else
3142                 AC_MSG_RESULT($MICROWIN)
3143                 AC_DEFINE(wxUSE_NANOX)
3144             fi
3145         fi
3146
3147         if test "$wxUSE_UNICODE" = "yes"; then
3148             PKG_PROG_PKG_CONFIG()
3149
3150             PKG_CHECK_MODULES(PANGOX, pangox,
3151                 [
3152                     CFLAGS="$PANGOX_CFLAGS $CFLAGS"
3153                     CXXFLAGS="$PANGOX_CFLAGS $CXXFLAGS"
3154                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOX_LIBS"
3155                 ],
3156                 [
3157                     AC_MSG_ERROR([pangox library not found, library cannot be compiled in Unicode mode])
3158                 ]
3159             )
3160             PKG_CHECK_MODULES(PANGOFT2, pangoft2,
3161                 [
3162                     CFLAGS="$PANGOFT2_CFLAGS $CFLAGS"
3163                     CXXFLAGS="$PANGOFT2_CFLAGS $CXXFLAGS"
3164                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOFT2_LIBS"
3165                 ],
3166                 [
3167                     AC_MSG_WARN([pangoft2 library not found, library will be compiled without printing support])
3168                     wxUSE_PRINTING_ARCHITECTURE="no"
3169                 ]
3170             )
3171             PKG_CHECK_MODULES(PANGOXFT, pangoxft,
3172                 [
3173                     AC_DEFINE(HAVE_PANGO_XFT)
3174                     CFLAGS="$PANGOXFT_CFLAGS $CFLAGS"
3175                     CXXFLAGS="$PANGOXFT_CFLAGS $CXXFLAGS"
3176                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOXFT_LIBS"
3177                 ],
3178                 [
3179                     AC_MSG_WARN([pangoxft library not found, library will be compiled without anti-aliasing support])
3180                 ]
3181             )
3182             save_LIBS="$LIBS"
3183             LIBS="$LIBS $PANGOX_LIBS"
3184             AC_CHECK_FUNCS([pango_font_family_is_monospace])
3185             LIBS="$save_LIBS"
3186         fi
3187
3188         wxUSE_UNIVERSAL="yes"
3189
3190         if test "$wxUSE_NANOX" = "yes"; then
3191             TOOLKIT_INCLUDE="-I\$(top_srcdir)/include/wx/x11/nanox -I\$(MICROWIN)/src/include $TOOLKIT_INCLUDE"
3192             TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__NANOX__ -DMWPIXEL_FORMAT=MWPF_TRUECOLOR0888 -DHAVE_FILEIO -DHAVE_BMP_SUPPORT=1 -DHAVE_GIF_SUPPORT=1 -DHAVE_PNM_SUPPORT=1 -DHAVE_XPM_SUPPORT=1 -DUNIX=1 -DUSE_EXPOSURE -DSCREEN_HEIGHT=480 -DSCREEN_WIDTH=640 -DSCREEN_DEPTH=4 -DX11=1"
3193             GUI_TK_LIBRARY="$GUI_TK_LIBRARY \$(MICROWIN)/src/lib/libnano-X.a"
3194         else
3195             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lX11"
3196         fi
3197
3198         TOOLKIT=X11
3199         GUIDIST=X11_DIST
3200     fi
3201
3202     if test "$wxUSE_MOTIF" = 1; then
3203         AC_MSG_CHECKING(for Motif/Lesstif headers)
3204         WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, Xm/Xm.h)
3205         if test "$ac_find_includes" != "" ; then
3206             AC_MSG_RESULT(found in $ac_find_includes)
3207             WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
3208             TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE$ac_path_to_include"
3209         else
3210             save_CFLAGS=$CFLAGS
3211             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3212
3213             AC_TRY_COMPILE(
3214                 [
3215                     #include <Xm/Xm.h>
3216                 ],
3217                 [
3218                     int version;
3219                     version = xmUseVersion;
3220                 ],
3221                 [
3222                     AC_MSG_RESULT(found in default search path)
3223                     COMPILED_X_PROGRAM=1
3224                 ],
3225                 [
3226                     AC_MSG_RESULT(no)
3227                     AC_MSG_ERROR(please set CPPFLAGS to contain the location of Xm/Xm.h)
3228                 ]
3229             )
3230
3231             CFLAGS=$save_CFLAGS
3232         fi
3233
3234
3235         AC_MSG_CHECKING(for Motif/Lesstif library)
3236         WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xm)
3237
3238         if test "x$ac_find_libraries" != "x" ; then
3239             AC_MSG_RESULT(found in $ac_find_libraries)
3240
3241             WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
3242             GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
3243         else
3244             dnl it might happen that we found headers in one of the standard
3245             dnl paths but the libs are elsewhere but still in default (linker)
3246             dnl path -- try to compile a test program to check for this
3247             save_CFLAGS=$CFLAGS
3248             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3249             save_LIBS="$LIBS"
3250             LIBS="$GUI_TK_LIBRARY -lXm -lXmu -lXext -lX11"
3251
3252             AC_TRY_LINK(
3253                 [
3254                     #include <Xm/Xm.h>
3255                 ],
3256                 [
3257                     int version;
3258                     version = xmUseVersion;
3259                 ],
3260                 [
3261                     AC_MSG_RESULT(found in default search path)
3262                     COMPILED_X_PROGRAM=1
3263                 ],
3264                 [
3265                     AC_MSG_RESULT(no)
3266                     AC_MSG_ERROR(please set LDFLAGS to contain the location of libXm)
3267                 ]
3268             )
3269
3270             CFLAGS=$save_CFLAGS
3271             LIBS="$save_LIBS"
3272         fi
3273
3274         AC_MSG_CHECKING([if we need -lXp and/or -lSM -lICE])
3275         libp_link=""
3276         libsm_ice_link=""
3277         libs_found=0
3278         for libp in "" " -lXp"; do
3279             if test "$libs_found" = 0; then
3280                 for libsm_ice in "" " -lSM -lICE"; do
3281                     if test "$libs_found" = 0; then
3282                         save_LIBS="$LIBS"
3283                         LIBS="$GUI_TK_LIBRARY -lXm ${libp} -lXmu -lXext -lXt${libsm_ice} -lX11"
3284                         save_CFLAGS=$CFLAGS
3285                         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3286
3287                         AC_TRY_LINK(
3288                             [
3289                                 #include <Xm/Xm.h>
3290                                 #include <Xm/List.h>
3291                             ],
3292                             [
3293                                 XmString string = NULL;
3294                                 Widget w = NULL;
3295                                 int position = 0;
3296                                 XmListAddItem(w, string, position);
3297                             ],
3298                             [
3299                                 libp_link="$libp"
3300                                 libsm_ice_link="$libsm_ice"
3301                                 AC_MSG_RESULT(
3302                                     [need${libp_link}${libsm_ice_link}])
3303                                 libs_found=1
3304                             ], []
3305                         )
3306
3307                         LIBS="$save_LIBS"
3308                         CFLAGS=$save_CFLAGS
3309                     fi
3310                 done
3311             fi
3312         done
3313
3314         if test "$libs_found" = 0; then
3315             AC_MSG_RESULT([can't find the right libraries])
3316             AC_MSG_ERROR([can't link a simple motif program])
3317         fi
3318
3319         dnl this seems to be needed under IRIX and shouldn't do any harm
3320         dnl elsewhere
3321         AC_CHECK_LIB(Sgm, [SgCreateList], [libsgm_link=" -lSgm"])
3322
3323         save_CFLAGS=$CFLAGS
3324         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3325
3326         AC_CACHE_CHECK([for Motif 2],
3327             wx_cv_lib_motif2,
3328             AC_TRY_COMPILE([
3329                             #include <Xm/Xm.h>
3330                            ],
3331                            [
3332                             #if XmVersion < 2000
3333                             Not Motif 2
3334                             #endif
3335                            ],
3336                            wx_cv_lib_motif2="yes",
3337                            wx_cv_lib_motif2="no"))
3338         if test "$wx_cv_lib_motif2" = "yes"; then
3339             AC_DEFINE(__WXMOTIF20__,1)
3340         else
3341             AC_DEFINE(__WXMOTIF20__,0)
3342         fi
3343
3344         AC_CACHE_CHECK([whether Motif is Lesstif],
3345             wx_cv_lib_lesstif,
3346             AC_TRY_COMPILE([
3347                             #include <Xm/Xm.h>
3348                            ],
3349                            [
3350                             #if !defined(LesstifVersion) || LesstifVersion <= 0
3351                             Not Lesstif
3352                             #endif
3353                            ],
3354                            wx_cv_lib_lesstif="yes",
3355                            wx_cv_lib_lesstif="no")
3356         )
3357         if test "$wx_cv_lib_lesstif" = "yes"; then
3358             AC_DEFINE(__WXLESSTIF__,1)
3359         else
3360             AC_DEFINE(__WXLESSTIF__,0)
3361         fi
3362
3363         CFLAGS=$save_CFLAGS
3364
3365         GUI_TK_LIBRARY="$GUI_TK_LIBRARY${libsgm_link} -lXm${libp_link} -lXmu -lXext -lXt${libsm_ice_link} -lX11"
3366         TOOLKIT=MOTIF
3367         GUIDIST=MOTIF_DIST
3368     fi
3369
3370     dnl more tests common to X11 and Motif:
3371     if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
3372         dnl test for external libxpm if we're configured to use it
3373         if test "$wxUSE_LIBXPM" = "sys"; then
3374             AC_MSG_CHECKING(for Xpm library)
3375             WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
3376             if test "$ac_find_libraries" != "" ; then
3377                 WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
3378                 GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
3379                 AC_MSG_RESULT(found in $ac_find_libraries)
3380
3381                 AC_CACHE_CHECK([for X11/xpm.h],
3382                     wx_cv_x11_xpm_h,
3383                     [
3384                         save_CFLAGS=$CFLAGS
3385                         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3386
3387                         AC_TRY_COMPILE(
3388                             [
3389                                 #include <X11/xpm.h>
3390                             ],
3391                             [
3392                                 int version;
3393                                 version = XpmLibraryVersion();
3394                             ],
3395                             wx_cv_x11_xpm_h=yes,
3396                             wx_cv_x11_xpm_h=no
3397                         )
3398
3399                         CFLAGS=$save_CFLAGS
3400                     ]
3401                 )
3402
3403                 if test $wx_cv_x11_xpm_h = "yes"; then
3404                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXpm"
3405                     AC_DEFINE(wxHAVE_LIB_XPM)
3406                 else
3407                     AC_MSG_WARN([built-in less efficient XPM decoder will be used])
3408                 fi
3409             fi
3410
3411         fi
3412
3413         dnl XShapeQueryExtension checks: first the library, then prototype
3414         AC_CHECK_LIB([Xext], [XShapeQueryExtension],
3415                      [
3416                       GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXext"
3417                       wxHAVE_XEXT_LIB=1
3418                      ],
3419                      [], [$GUI_TK_LIBRARY -lX11])
3420
3421         if test "$wxHAVE_XEXT_LIB" = 1; then
3422             save_CFLAGS="$CFLAGS"
3423             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3424
3425             AC_MSG_CHECKING([for X11/extensions/shape.h])
3426             AC_TRY_COMPILE([
3427                             #include <X11/Xlib.h>
3428                             #include <X11/extensions/shape.h>
3429                            ],
3430                            [
3431                             int dummy1, dummy2;
3432                             XShapeQueryExtension((Display*)NULL,
3433                                                  (int*)NULL, (int*)NULL);
3434                            ],
3435                            [
3436                             AC_DEFINE(HAVE_XSHAPE)
3437                             AC_MSG_RESULT([found])
3438                            ],
3439                            [
3440                             AC_MSG_RESULT([not found])
3441                            ])
3442             CFLAGS="$save_CFLAGS"
3443
3444         fi
3445     fi
3446
3447     if test "$wxUSE_OSX_CARBON" = 1; then
3448         AC_MSG_CHECKING([for compiler syntax to enable Pascal strings])
3449         if test "$GCC" = yes; then
3450             AC_MSG_RESULT([gcc])
3451             CPPFLAGS_PASCAL="-fpascal-strings"
3452         elif test "`echo $CXX | sed -e 's@.*/@@'`" = "xlC"; then
3453             AC_MSG_RESULT([xlc])
3454             CPPFLAGS_PASCAL="-qmacpstr"
3455         else
3456             AC_MSG_RESULT([none])
3457         fi
3458
3459         if test "x$wxUSE_UNIX" = "xyes"; then
3460             CPPFLAGS="$CPPFLAGS_PASCAL -I\${top_srcdir}/src/mac/carbon/morefilex -I/Developer/Headers/FlatCarbon $CPPFLAGS"
3461         else
3462             dnl platform.h needs TARGET_CARBON before setup.h
3463             CPPFLAGS="$CPPFLAGS_PASCAL -I\${top_srcdir}/src/mac/carbon/morefilex -DTARGET_CARBON $CPPFLAGS"
3464         fi
3465
3466         TOOLKIT=OSX_CARBON
3467         dnl we can't call this MAC_DIST or autoconf thinks its a macro
3468         GUIDIST=OSX_CARBON_DIST
3469         dnl wxMac version of wxBase and wxCocoa or wxBase-only built on Darwin
3470         dnl are different, so they need different names:
3471         WXBASEPORT="_carbon"
3472
3473         dnl in addition to defining __WXOSX_CARBON__ for this toolkit we want
3474         dnl to also define these extra symbols to make it possible to test for
3475         dnl any Mac port (__WXMAC__ is for backwards compatibility, __WXOSX__
3476         dnl is a new name)
3477         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXMAC__ -D__WXOSX__"
3478     fi
3479
3480     if test "$wxUSE_OSX_COCOA" = 1; then
3481         TOOLKIT=OSX_COCOA
3482         GUIDIST=OSX_COCOA_DIST
3483
3484         dnl see the comment above in wxUSE_OSX_CARBON branch
3485         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXMAC__ -D__WXOSX__"
3486     fi
3487
3488     if test "$wxUSE_COCOA" = 1; then
3489         TOOLKIT=COCOA
3490         GUIDIST=COCOA_DIST
3491     fi
3492
3493     if test "$wxUSE_PM" = 1; then
3494         TOOLKIT=PM
3495         GUIDIST=PM_DIST
3496         AC_CACHE_CHECK([for type SPBCDATA],
3497             wx_cv_spbcdata,
3498             [
3499                 AC_TRY_COMPILE(
3500                     [
3501                         #define INCL_PM
3502                         #include <os2.h>
3503                     ],
3504                     [
3505                         SPBCDATA test;
3506                     ],
3507                     wx_cv_spbcdata=yes,
3508                     wx_cv_spbcdata=no
3509                 )
3510             ]
3511         )
3512
3513         if test $wx_cv_spbcdata = "yes"; then
3514             AC_DEFINE(HAVE_SPBCDATA)
3515         fi
3516     fi
3517
3518     dnl the name of the directory where the files for this toolkit live
3519     if test "$TOOLKIT" = "PM" ; then
3520         TOOLKIT_DIR="os2"
3521     else
3522         TOOLKIT_DIR=`echo ${TOOLKIT} | tr '[[A-Z]]' '[[a-z]]'`
3523     fi
3524
3525     if test "$wxUSE_UNIVERSAL" = "yes"; then
3526         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXUNIVERSAL__"
3527         WIDGET_SET=univ
3528     fi
3529
3530     dnl distribute samples/demos/utils with GUI versions
3531     GUIDIST="${GUIDIST} SAMPLES_DIST DEMOS_DIST UTILS_DIST MISC_DIST"
3532     DISTDIR="wx\$(TOOLKIT)"
3533 else
3534     USE_GUI=0
3535
3536     dnl this doesn't quite work right for wxBase, but the places
3537     dnl where it is wrong aren't fatal (yet) though.
3538     TOOLKIT_DIR="base"
3539
3540     dnl the sources, their dependenices and the headers
3541     if test "$USE_WIN32" = 1 ; then
3542         dnl yes, the toolkit for wxBase on win32 is actually MSW
3543         dnl wxBase on unix does not need a 'TOOLKIT' defined.
3544         TOOLKIT="MSW"
3545     fi
3546
3547     dnl distribute only wxBase sources/headers
3548     GUIDIST="BASE_DIST"
3549     DISTDIR="wxBase"
3550 fi
3551
3552
3553 dnl ---------------------------------------------------------------------------
3554 dnl UTF-8 support
3555 dnl ---------------------------------------------------------------------------
3556
3557 dnl If UTF-8 support wasn't explicitly enabled or disabled, enable it only
3558 dnl for ports where it makes sense by default (GTK+, DirectFB):
3559 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_UTF8" = "auto" ; then
3560     if test "$USE_UNIX" = 1 -a "$wxUSE_DARWIN" != 1 ; then
3561         wxUSE_UNICODE_UTF8=yes
3562     elif test "$USE_OS2" = 1 ; then
3563         dnl wide char support is quite incomplete in libc;
3564         dnl UTF-8 might actually work when evaluating/setting
3565         dnl code pages correctly, even for ports other than GTK20.
3566         wxUSE_UNICODE_UTF8=yes
3567     else
3568         wxUSE_UNICODE_UTF8=no
3569     fi
3570 fi
3571
3572 dnl ---------------------------------------------------------------------------
3573 dnl Optional libraries included when system library is not used
3574 dnl ---------------------------------------------------------------------------
3575
3576 dnl do this after test for X11 above so that we have a chance of finding Xlib.h
3577 if test "$wxUSE_GUI" = "yes"; then
3578     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_PM" != 1; then
3579         dnl defines HAVE_X11_XKBLIB_H
3580         AC_CHECK_HEADERS([X11/Xlib.h],,, [ ])
3581         AC_CHECK_HEADERS([X11/XKBlib.h],,,
3582                          [
3583                           #if HAVE_X11_XLIB_H
3584                             #include <X11/Xlib.h>
3585                           #endif
3586                          ])
3587     fi
3588 fi
3589
3590
3591 dnl ---------------------------------------------------------------------------
3592 dnl wxDisplay Sanity checks
3593 dnl ---------------------------------------------------------------------------
3594
3595 if test "$wxUSE_DISPLAY" = "yes"; then
3596 dnl ---------------------------------------------------------------------------
3597 dnl Xinerama (for unix ) - Brian Victor
3598 dnl ---------------------------------------------------------------------------
3599     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1; then
3600         AC_MSG_CHECKING([for Xinerama])
3601         WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],Xinerama)
3602         if test "$ac_find_libraries" != "" ; then
3603             WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3604             if test "$ac_path_to_link" != " -L/usr/lib" ; then
3605                 LDFLAGS="$LDFLAGS $ac_path_to_link"
3606             fi
3607             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXinerama"
3608             AC_MSG_RESULT([yes])
3609
3610             AC_MSG_CHECKING([for Xxf86vm extension])
3611             WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],Xxf86vm)
3612             if test "$ac_find_libraries" != "" ; then
3613                 AC_MSG_RESULT([yes])
3614                 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h],
3615                                  [
3616                                   GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXxf86vm"
3617                                  ],
3618                                  [],
3619                                  [
3620                                       #if HAVE_X11_XLIB_H
3621                                         #include <X11/Xlib.h>
3622                                       #endif
3623                                  ])
3624             else
3625                 AC_MSG_RESULT([no])
3626             fi
3627
3628         else
3629             AC_MSG_RESULT([no])
3630             AC_MSG_WARN([Xinerama not found; disabling wxDisplay])
3631             wxUSE_DISPLAY="no"
3632         fi
3633     elif test "$wxUSE_MSW" = 1; then
3634 dnl ---------------------------------------------------------------------------
3635 dnl DirectDraw for MSW - optionally used by WxDisplay.
3636 dnl ---------------------------------------------------------------------------
3637         AC_CHECK_HEADER([ddraw.h], [], [], [#include <windows.h>])
3638     fi
3639 fi
3640
3641 dnl ---------------------------------------------------------------------------
3642 dnl X11 session management
3643 dnl ---------------------------------------------------------------------------
3644 if test "$wxUSE_DETECT_SM" = "yes"; then
3645     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1; then
3646         AC_MSG_CHECKING([for -lSM - X11 session management])
3647         WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],SM)
3648         if test "$ac_find_libraries" != "" ; then
3649             WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3650             if test "$ac_path_to_link" != " -L/usr/lib" ; then
3651                 LDFLAGS="$LDFLAGS $ac_path_to_link"
3652             fi
3653             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lSM"
3654             AC_MSG_RESULT([yes])
3655         else
3656             AC_MSG_RESULT([no])
3657             AC_MSG_WARN([libSM not found; disabling session management detection])
3658             wxUSE_DETECT_SM="no"
3659         fi
3660     else
3661         wxUSE_DETECT_SM="no"
3662     fi
3663 fi
3664
3665
3666 dnl ---------------------------------------------------------------------------
3667 dnl OpenGL libraries
3668 dnl ---------------------------------------------------------------------------
3669
3670 USE_OPENGL=0
3671 if test "$wxUSE_OPENGL" = "yes" -o "$wxUSE_OPENGL" = "auto"; then
3672
3673     dnl look in glcanvas.h for the list of platforms supported by wxGlCanvas:
3674
3675     if test "$wxUSE_OSX_CARBON" = 1 -o "$wxUSE_OSX_COCOA" = 1 -o "$wxUSE_COCOA" = 1; then
3676         OPENGL_LIBS="-framework OpenGL -framework AGL"
3677     elif test "$wxUSE_MSW" = 1; then
3678         OPENGL_LIBS="-lopengl32 -lglu32"
3679     elif test "$wxUSE_MOTIF" = 1 -o "$wxUSE_X11" = 1 -o "$wxUSE_GTK2" = 1 -o "$wxUSE_GTK" = 1; then
3680
3681         dnl adjust CPPFLAGS to include GL/gl.h location if necessary
3682         dnl (/opt/graphics/OpenGL is for HP-UX systems, bug 925307)
3683         AC_MSG_CHECKING([for OpenGL headers])
3684         WX_PATH_FIND_INCLUDES([$SEARCH_INCLUDE /opt/graphics/OpenGL/include], GL/gl.h)
3685         if test "$ac_find_includes" != "" ; then
3686             AC_MSG_RESULT(found in $ac_find_includes)
3687             WX_INCLUDE_PATH_EXIST($ac_find_includes, $CPPFLAGS)
3688             CPPFLAGS="$ac_path_to_include $CPPFLAGS"
3689         else
3690             AC_MSG_RESULT([not found])
3691         fi
3692
3693         AC_CHECK_HEADER(GL/gl.h, [
3694             AC_CHECK_HEADER(GL/glu.h, [
3695                 found_gl=0
3696
3697                 AC_MSG_CHECKING([for -lGL])
3698                 WX_PATH_FIND_LIBRARIES([$SEARCH_LIB /opt/graphics/OpenGL/lib],GL)
3699                 if test "$ac_find_libraries" != "" ; then
3700                     AC_MSG_RESULT([found in $ac_find_libraries])
3701
3702                     WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3703                     if test "$ac_path_to_link" != " -L/usr/lib" ; then
3704                         LDFLAGS_GL="$ac_path_to_link"
3705                     fi
3706
3707                     dnl don't suppose that libGL and libGLU are always in the
3708                     dnl same directory -- this is not true for some common
3709                     dnl distributions
3710                     AC_MSG_CHECKING([for -lGLU])
3711                     WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],GLU)
3712                     if test "$ac_find_libraries" != "" ; then
3713                         WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3714                         if test "$ac_path_to_link" != " -L/usr/lib" -a \
3715                                     "$ac_path_to_link" != "$LDFLAGS_GL"; then
3716                             LDFLAGS_GL="$LDFLAGS_GL$ac_path_to_link"
3717                         fi
3718
3719                         found_gl=1
3720                         OPENGL_LIBS="-lGL -lGLU"
3721                         AC_MSG_RESULT([yes])
3722                     else
3723                         AC_MSG_RESULT([no])
3724                     fi
3725                 else
3726                     AC_MSG_RESULT([no])
3727                 fi
3728
3729                 if test "$found_gl" != 1; then
3730                     AC_MSG_CHECKING([for -lMesaGL])
3731                     WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],MesaGL)
3732                     if test "$ac_find_libraries" != "" ; then
3733                         WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3734                         LDFLAGS_GL="$LDFLAGS$ac_path_to_link"
3735                         OPENGL_LIBS="-lMesaGL -lMesaGLU"
3736                         AC_MSG_RESULT([yes])
3737                     else
3738                         AC_MSG_RESULT([no])
3739                     fi
3740                 fi
3741             ],, [ ])
3742         ],
3743         [],
3744         [ ])
3745
3746         if test "x$OPENGL_LIBS" = "x"; then
3747             if test "$wxUSE_OPENGL" = "yes"; then
3748                 AC_MSG_ERROR([OpenGL libraries not available])
3749             else
3750                 dnl case wxUSE_OPENGL=auto
3751                 AC_MSG_WARN([OpenGL libraries not available, disabling support for OpenGL])
3752                 wxUSE_OPENGL=no
3753                 USE_OPENGL=0
3754             fi
3755         fi
3756     else
3757         AC_MSG_WARN([wxGLCanvas not implemented for this port, library will be compiled without it.])
3758         wxUSE_OPENGL="no"
3759     fi
3760
3761     if test "$wxUSE_OPENGL" = "auto"; then
3762         dnl if the OpenGL libraries were unavailable, this would have been
3763         dnl changed to "no" above, if it wasn't, change it to "yes" as we've
3764         dnl verified that we can indeed use OpenGL
3765         wxUSE_OPENGL=yes
3766     fi
3767
3768     if test "$wxUSE_OPENGL" = "yes"; then
3769         USE_OPENGL=1
3770         AC_DEFINE(wxUSE_OPENGL)
3771         AC_DEFINE(wxUSE_GLCANVAS)
3772         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS opengl opengl/cube opengl/penguin opengl/isosurf"
3773     fi
3774 fi
3775
3776
3777 dnl the symbol which allows conditional compilation for the given toolkit
3778 if test -n "$TOOLKIT" ; then
3779     TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WX${TOOLKIT}__"
3780 fi
3781
3782
3783 dnl --- the marker for quick search, leave it here: SHARED_LIB_SETUP ---
3784
3785 if test "$wxUSE_SHARED" = "yes"; then
3786     case "${host}" in
3787       *-pc-msdosdjgpp )
3788         dnl only static for now
3789         wxUSE_SHARED=no
3790         AC_MSG_WARN([Host system doesn't support shared libraries, disabling])
3791       ;;
3792     esac
3793 fi
3794
3795 if test "$wxUSE_SHARED" = "yes"; then
3796
3797     dnl use versioned symbols if available on the platform
3798     WX_VERSIONED_SYMBOLS([\$(wx_top_builddir)/version-script])
3799
3800     dnl test for GCC's visibility support (sets CFLAGS_VISIBILITY, which is
3801     dnl assigned to CFLAGS and CXXFLAGS below)
3802     if test "$wxUSE_VISIBILITY" != "no"; then
3803         WX_VISIBILITY
3804     fi
3805
3806     dnl test for Sun CC which can be used under both Solaris and Linux
3807     if test "x$SUNCXX" = xyes; then
3808         SAMPLES_RPATH_FLAG="-R\$(wx_top_builddir)/lib"
3809         WXCONFIG_RPATH="-R\$libdir"
3810     else
3811     case "${host}" in
3812       *-*-linux* | *-*-gnu* )
3813         SAMPLES_RPATH_FLAG="-Wl,-rpath,\$(wx_top_builddir)/lib"
3814         WXCONFIG_RPATH="-Wl,-rpath,\$libdir"
3815         ;;
3816
3817       *-*-solaris2* )
3818         dnl here we know that Sun CC is not used as we tested for it above,
3819         dnl hence we must be using gcc
3820
3821         dnl newer versions of gcc need -isystem to compile X headers on
3822         dnl Solaris (which use old style C syntax)
3823         CPPFLAGS="-isystem /usr/openwin/include $CPPFLAGS"
3824
3825         dnl gcc may use Sun's ld, in which case -rpath gives a confusing
3826         dnl error message. We have to try both -Wl,-rpath and -Wl,-R:
3827         saveLdflags="$LDFLAGS"
3828         LDFLAGS="$saveLdflags -Wl,-rpath,/"
3829         AC_MSG_CHECKING([if the linker accepts -rpath])
3830         AC_TRY_LINK(
3831             [],[],
3832             [
3833                 AC_MSG_RESULT([yes])
3834                 SAMPLES_RPATH_FLAG="-Wl,-rpath,\$(wx_top_builddir)/lib"
3835                 WXCONFIG_RPATH="-Wl,-rpath,\$libdir"
3836             ],[
3837                 AC_MSG_RESULT([no])
3838                 AC_MSG_CHECKING([if the linker accepts -R])
3839                 LDFLAGS="$saveLdflags -Wl,-R,/"
3840                 AC_TRY_LINK(
3841                     [],[],
3842                     [
3843                         AC_MSG_RESULT([yes])
3844                         SAMPLES_RPATH_FLAG="-Wl,-R,\$(wx_top_builddir)/lib"
3845                         WXCONFIG_RPATH="-Wl,-R,\$libdir"
3846                     ],[
3847                         AC_MSG_RESULT([no])
3848                     ])
3849             ])
3850         LDFLAGS="$saveLdflags"
3851       ;;
3852
3853       *-*-darwin* )
3854         install_name_tool=`which ${HOST_PREFIX}install_name_tool`
3855         if test "$install_name_tool" -a -x "$install_name_tool"; then
3856             DYLIB_RPATH_POSTLINK="${HOST_PREFIX}install_name_tool -id \$@ \$@"
3857             cat <<EOF >change-install-names
3858 #!/bin/sh
3859 libnames=\`cd \${1} ; ls -1 | grep '\.[[0-9]][[0-9]]*\.dylib\$'\`
3860 for i in \${libnames} ; do
3861     ${HOST_PREFIX}install_name_tool -id \${1}/\${i} \${1}/\${i}
3862     for dep in \${libnames} ; do
3863         ${HOST_PREFIX}install_name_tool -change \${2}/\${dep} \${1}/\${dep} \${1}/\${i}
3864     done
3865 done
3866 EOF
3867             chmod +x change-install-names
3868             DYLIB_RPATH_INSTALL="\$(wx_top_builddir)/change-install-names \${libdir} \$(wx_top_builddir)/lib"
3869         fi
3870
3871         dnl the HEADER_PAD_OPTION is required by some wx samples to avoid the error:
3872         dnl "install_name_tool: changing install names can't be redone for: the_exe_name
3873         dnl (for architecture ppc) because larger updated load commands do not fit
3874         dnl (the program must be relinked)"
3875         HEADER_PAD_OPTION="-headerpad_max_install_names"
3876       ;;
3877
3878       *-*-cygwin* | *-*-mingw32* )
3879         ;;
3880
3881       *-*-hpux* )
3882         SAMPLES_RPATH_FLAG="-Wl,+b,\$(wx_top_builddir)/lib"
3883         WXCONFIG_RPATH="-Wl,+b,\$libdir"
3884         ;;
3885
3886     esac
3887     fi
3888
3889     dnl this one shouldn't be used for the library build so put it in a
3890     dnl separate variable from WXCONFIG_CPPFLAGS
3891     WXCONFIG_ONLY_CPPFLAGS="$WXCONFIG_ONLY_CPPFLAGS -DWXUSINGDLL"
3892
3893     if test $wxUSE_RPATH = "no"; then
3894         SAMPLES_RPATH_FLAG=''
3895         DYLIB_PATH_POSTLINK=''
3896         WXCONFIG_RPATH=''
3897     fi
3898
3899     SHARED=1
3900
3901 else
3902
3903     config_linkage_component="-static"
3904     SHARED=0
3905
3906 fi
3907
3908
3909 UNICODE=0
3910 lib_unicode_suffix=
3911 WX_CHARTYPE="ansi"
3912 if test "$wxUSE_UNICODE" = "yes"; then
3913     lib_unicode_suffix=u
3914     WX_CHARTYPE="unicode"
3915     UNICODE=1
3916 fi
3917
3918 WX_FLAVOUR=${WX_FLAVOUR:+-$WX_FLAVOUR}
3919 WX_LIB_FLAVOUR=`echo $WX_FLAVOUR | tr '-' '_'`
3920
3921 DEBUG_INFO=0
3922 if test "$wxUSE_DEBUG_INFO" = "yes"; then
3923     DEBUG_INFO=1
3924 fi
3925
3926 WX_VERSION_TAG=`echo WX${lib_unicode_suffix}${WX_LIB_FLAVOUR}_${WX_RELEASE} | tr '[[a-z]]' '[[A-Z]]'`
3927
3928 TOOLCHAIN_NAME="${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}${lib_unicode_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX}"
3929
3930 TOOLCHAIN_FULLNAME="${HOST_PREFIX}${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}-${WX_CHARTYPE}${config_linkage_component}-${WX_RELEASE}${WX_FLAVOUR}"
3931
3932 dnl library link name
3933 dnl These just save us from exporting lib_{unicode,flavour}_suffix.
3934 dnl If we ever need to do that, we won't need to keep these.
3935
3936 if test "$wxUSE_OSX_CARBON" = 1 -o "$wxUSE_OSX_COCOA" = 1 -o "$wxUSE_COCOA" = 1; then
3937     WX_LIBRARY_BASENAME_NOGUI="wx_base${lib_unicode_suffix}${WX_LIB_FLAVOUR}"
3938 else
3939     WX_LIBRARY_BASENAME_NOGUI="wx_base${WXBASEPORT}${lib_unicode_suffix}${WX_LIB_FLAVOUR}"
3940 fi
3941 if test "${TOOLKIT_DIR}" = "os2"; then
3942     WX_LIBRARY_BASENAME_GUI="wx_pm${WIDGET_SET}${lib_unicode_suffix}${WX_LIB_FLAVOUR}"
3943 else
3944     WX_LIBRARY_BASENAME_GUI="wx_${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}${lib_unicode_suffix}${WX_LIB_FLAVOUR}"
3945 fi
3946
3947
3948
3949 if test "$wxUSE_COCOA" = 1; then
3950     AC_LANG_SAVE
3951     AC_WX_LANG_OBJECTIVEC
3952 dnl Recent AppKit/NSEvent.h include parts of IOKit which eventually
3953 dnl gets IOKit/graphics/IOGraphicsTypes.h included which typedefs
3954 dnl Point but only if MacTypes.h was not included first.  Of course,
3955 dnl if MacTypes.h is included later then you're screwed when it
3956 dnl tries to typedef Point.  Defining __Point__ will cause IOGraphicsTypes.h
3957 dnl to not typedef Point and thus fix the problem.
3958     AC_MSG_CHECKING([if AppKit/NSEvent.h conflicts with CoreFoundation])
3959     AC_TRY_COMPILE([#include <AppKit/NSEvent.h>
3960 #include <CoreFoundation/CoreFoundation.h>
3961         ],[],
3962         [AC_MSG_RESULT([no])],
3963         [AC_MSG_RESULT([yes])
3964         AC_MSG_CHECKING([if defining __Point__ will fix it])
3965         AC_TRY_COMPILE([#define __Point__ 1
3966 #include <AppKit/NSEvent.h>
3967 #include <CoreFoundation/CoreFoundation.h>
3968             ],[],
3969             [AC_MSG_RESULT([yes])
3970             AC_DEFINE(__Point__)
3971             ],
3972             [AC_MSG_FAILURE([no])]
3973         )]
3974     )
3975     AC_LANG_RESTORE
3976 fi
3977
3978 dnl ---------------------------------------------------------------------------
3979 dnl Checks for typedefs
3980 dnl ---------------------------------------------------------------------------
3981
3982 dnl   defines mode_t if not already defined
3983 AC_TYPE_MODE_T
3984 dnl   defines off_t if not already defined
3985 AC_TYPE_OFF_T
3986 dnl   defines pid_t if not already defined
3987 AC_TYPE_PID_T
3988 dnl   defines size_t if not already defined
3989 AC_TYPE_SIZE_T
3990
3991 dnl sets HAVE_SSIZE_T if ssize_t is defined
3992 AC_CHECK_TYPES(ssize_t)
3993
3994 dnl check what exactly size_t is on this machine - this is necessary to avoid
3995 dnl ambiguous overloads in several places, notably wx/string.h and wx/array.h
3996 AC_LANG_PUSH(C++) dnl tests below use overloaded functions and so need C++
3997 AC_CACHE_CHECK([if size_t is unsigned int],
3998     wx_cv_size_t_is_uint,
3999     [
4000     dnl an obvious check like AC_TRY_COMPILE[struct Foo { ... };] doesn't work
4001     dnl with egcs (at least) up to 1.1.1 as it allows you to compile duplicate
4002     dnl methods in a local class (i.e. class inside a function) declaration
4003     dnl without any objections!!
4004     dnl
4005     dnl hence the hack below: we must have Foo at global scope!
4006     AC_TRY_COMPILE([#include <stddef.h>],
4007         [
4008             return 0; }
4009
4010             struct Foo { void foo(size_t); void foo(unsigned int); };
4011
4012             int bar() {
4013         ],
4014         wx_cv_size_t_is_uint=no,
4015         wx_cv_size_t_is_uint=yes
4016     )
4017     ]
4018 )
4019
4020 if test "$wx_cv_size_t_is_uint" = "yes"; then
4021     AC_DEFINE(wxSIZE_T_IS_UINT)
4022 else
4023     AC_CACHE_CHECK([if size_t is unsigned long],
4024         wx_cv_size_t_is_ulong,
4025         AC_TRY_COMPILE([#include <stddef.h>],
4026             [
4027                 return 0; }
4028
4029                 struct Foo { void foo(size_t); void foo(unsigned long); };
4030
4031                 int bar() {
4032             ],
4033             wx_cv_size_t_is_ulong=no,
4034             wx_cv_size_t_is_ulong=yes
4035         )
4036     )
4037
4038     if test "$wx_cv_size_t_is_ulong" = "yes"; then
4039         AC_DEFINE(wxSIZE_T_IS_ULONG)
4040     fi
4041 fi
4042
4043 AC_CACHE_CHECK([if wchar_t is separate type],
4044     wx_cv_wchar_t_is_separate_type,
4045     AC_TRY_COMPILE([#include <wchar.h>],
4046         [
4047             return 0; }
4048
4049             struct Foo { void foo(wchar_t);
4050                          void foo(unsigned short);
4051                          void foo(unsigned int);
4052                          void foo(unsigned long); };
4053
4054             int bar() {
4055         ],
4056         wx_cv_wchar_t_is_separate_type=yes,
4057         wx_cv_wchar_t_is_separate_type=no
4058     )
4059 )
4060
4061 if test "$wx_cv_wchar_t_is_separate_type" = "yes"; then
4062     AC_DEFINE(wxWCHAR_T_IS_REAL_TYPE, 1)
4063 else
4064     AC_DEFINE(wxWCHAR_T_IS_REAL_TYPE, 0)
4065 fi
4066
4067 AC_LANG_POP() dnl C++
4068
4069 dnl ---------------------------------------------------------------------------
4070 dnl Checks for structures
4071 dnl ---------------------------------------------------------------------------
4072
4073 dnl does passwd struct has the pw_gecos field?
4074 AC_CACHE_CHECK([for pw_gecos in struct passwd], wx_cv_struct_pw_gecos,
4075     [
4076         AC_TRY_COMPILE([#include <pwd.h>],
4077              [
4078                 char *p;
4079                 struct passwd *pw;
4080                 p = pw->pw_gecos;
4081              ],
4082              [
4083                 wx_cv_struct_pw_gecos=yes
4084              ],
4085              [
4086                 wx_cv_struct_pw_gecos=no
4087              ]
4088         )
4089     ]
4090 )
4091
4092 if test "$wx_cv_struct_pw_gecos" = "yes"; then
4093     AC_DEFINE(HAVE_PW_GECOS)
4094 fi
4095
4096 dnl ---------------------------------------------------------------------------
4097 dnl Check for functions
4098 dnl ---------------------------------------------------------------------------
4099
4100 dnl don't check for wchar_t functions if we haven't got wchar_t itself
4101 if test "$wxUSE_WCHAR_T" = "yes"; then
4102     AC_DEFINE(wxUSE_WCHAR_T)
4103
4104     dnl check for wcslen in all possible places
4105     WCSLEN_FOUND=0
4106     WCHAR_LINK=
4107     AC_CHECK_FUNCS(wcslen, WCSLEN_FOUND=1)
4108
4109     if test "$WCSLEN_FOUND" = 0; then
4110         if test "$TOOLKIT" = "MSW"; then
4111             AC_CHECK_LIB(msvcrt, wcslen, WCHAR_OK=1)
4112         else
4113             AC_CHECK_LIB(w, wcslen, [
4114                             WCHAR_LINK=" -lw"
4115                             WCSLEN_FOUND=1
4116                         ])
4117         fi
4118     fi
4119
4120     if test "$WCSLEN_FOUND" = 1; then
4121         AC_DEFINE(HAVE_WCSLEN)
4122     fi
4123
4124     AC_CHECK_FUNCS([wcsdup strnlen wcsnlen wcscasecmp wcsncasecmp])
4125
4126     dnl On HP-UX aCC need this define to find mbstrtowcs() &c
4127     dnl Can't be used for g++ since the mbstate_t in wchar.h can conflict
4128     dnl with g++'s in <cwchar> (unless -D_INCLUDE__STDC_A1_SOURCE is in the
4129     dnl flags when g++ is configured, it will declare it's own).
4130     if test "$USE_HPUX" = 1 -a "$GCC" != "yes"; then
4131         CPPFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CPPFLAGS"
4132     fi
4133
4134     dnl Try to use wcsrtombs instead of wcstombs which is buggy in old GNU
4135     dnl libc versions if possible. AC_CHECK_FUNCS only checks it's in the
4136     dnl library, not the header, so do a header check for mbstate_t first.
4137     AC_CHECK_TYPES([mbstate_t],
4138                    [AC_CHECK_FUNCS(wcsrtombs)],
4139                    [],
4140                    [#include <wchar.h>])
4141 else
4142     AC_MSG_WARN([Wide character support is unavailable])
4143 fi
4144
4145 dnl check for vsnprintf() -- a safe version of vsprintf())
4146 dnl
4147 dnl the trouble here is that on some systems (e.g HP-UX 10) this function is
4148 dnl present in libc but not in the system headers and so AC_CHECK_FUNCS (which,
4149 dnl stupidly, provides a dummy function declaration inside its extension)
4150 dnl succeeds, even with C++ compiler, but the compilation of wxWidgets fails
4151 dnl
4152 dnl so we first check if the function is in the library
4153 dnl
4154 dnl FIXME: replace this mess with WX_CHECK_FUNCS()
4155 AC_CHECK_FUNCS(snprintf vsnprintf vsscanf)
4156
4157 AC_LANG_PUSH(C++)
4158 if test "$ac_cv_func_vsnprintf" = "yes"; then
4159     dnl yes it is -- now check if it is in the headers
4160     AC_CACHE_CHECK([for vsnprintf declaration], wx_cv_func_vsnprintf_decl,
4161         [
4162             dnl our troubles are not over: HP-UX 11 prototypes vsnprintf() as
4163             dnl taking "char *" and not "const char *" while Metrowerks does
4164             dnl provide a correct vsnprintf declaration but in C++ mode it's
4165             dnl always in std namespace and so we have to bring it in scope
4166             AC_TRY_COMPILE(
4167                 [
4168                     #include <stdio.h>
4169                     #include <stdarg.h>
4170                     #ifdef __MSL__
4171                     #if __MSL__ >= 0x6000
4172                     namespace std {}
4173                     using namespace std;
4174                     #endif
4175                     #endif
4176                 ],
4177                 [
4178                     char *buf;
4179                     va_list ap;
4180                     vsnprintf(buf, 10u, "%s", ap);
4181                 ],
4182                 wx_cv_func_vsnprintf_decl=yes,
4183                 wx_cv_func_vsnprintf_decl=no
4184             )
4185         ]
4186     )
4187
4188     if test "$wx_cv_func_vsnprintf_decl" = "yes"; then
4189         AC_DEFINE(HAVE_VSNPRINTF_DECL)
4190
4191         dnl we know there is a vsnprintf declaration, but some old headers
4192         dnl may have one taking a "char *" format instead of "const char *"
4193         AC_CACHE_CHECK([if vsnprintf declaration is broken], wx_cv_func_broken_vsnprintf_decl,
4194             [
4195                 AC_TRY_COMPILE(
4196                     [
4197                         #include <stdio.h>
4198                         #include <stdarg.h>
4199                         #ifdef __MSL__
4200                         #if __MSL__ >= 0x6000
4201                         namespace std {}
4202                         using namespace std;
4203                         #endif
4204                         #endif
4205                     ],
4206                     [
4207                         char *buf;
4208                         va_list ap;
4209                         const char *fmt = "%s";
4210                         vsnprintf(buf, 10u, fmt, ap);
4211                     ],
4212                     wx_cv_func_broken_vsnprintf_decl=no,
4213                     wx_cv_func_broken_vsnprintf_decl=yes
4214                 )
4215             ]
4216         )
4217
4218         if test "$wx_cv_func_broken_vsnprintf_decl" = "yes"; then
4219             AC_DEFINE(HAVE_BROKEN_VSNPRINTF_DECL)
4220         fi
4221     fi
4222 fi
4223
4224 dnl the same as above but for snprintf() now: it's not present in at least AIX
4225 dnl 4.2 headers
4226 if test "$ac_cv_func_snprintf" = "yes"; then
4227     AC_CACHE_CHECK([for snprintf declaration], wx_cv_func_snprintf_decl,
4228         [
4229             AC_TRY_COMPILE(
4230                 [
4231                     #include <stdio.h>
4232                     #include <stdarg.h>
4233                     #ifdef __MSL__
4234                     #if __MSL__ >= 0x6000
4235                     namespace std {}
4236                     using namespace std;
4237                     #endif
4238                     #endif
4239                 ],
4240                 [
4241                     char *buf;
4242                     snprintf(buf, 10u, "%s", "wx");
4243                 ],
4244                 wx_cv_func_snprintf_decl=yes,
4245                 wx_cv_func_snprintf_decl=no
4246             )
4247         ]
4248     )
4249
4250     if test "$wx_cv_func_snprintf_decl" = "yes"; then
4251         AC_DEFINE(HAVE_SNPRINTF_DECL)
4252     fi
4253
4254     if test "$wxUSE_PRINTF_POS_PARAMS" = "yes"; then
4255
4256         dnl check if snprintf() has support for positional arguments
4257         dnl NB: if snprintf() has positional support we can safely suppose that also
4258         dnl     other *printf() functions support them as they all belong to the same
4259         dnl     family and they all fallback to the same implementation
4260         AC_CACHE_CHECK([if snprintf supports positional arguments], wx_cv_func_snprintf_pos_params,
4261             [
4262                 AC_TRY_RUN(
4263                     [
4264                         #include <stdio.h>
4265
4266                         int main (void)
4267                         {
4268                             char buffer[128];
4269                             snprintf (buffer, 128, "%2$d %3$d %1$d", 1, 2, 3);
4270                             if (strcmp ("2 3 1", buffer) == 0)
4271                                 exit (0);
4272                             exit (1);
4273                         }
4274                     ],
4275                     wx_cv_func_snprintf_pos_params=no,
4276                     wx_cv_func_snprintf_pos_params=yes,
4277                     dnl be pessimistic when cross-compiling
4278                     [
4279                         AC_MSG_WARN([Assuming Unix98 printf() is not available,
4280 define HAVE_UNIX98_PRINTF as 1 in setup.h if it is available.])
4281                         wx_cv_func_snprintf_pos_params=no
4282                     ]
4283                 )
4284             ]
4285         )
4286
4287         if test "$wx_cv_func_snprintf_pos_params" = "yes"; then
4288             AC_DEFINE(HAVE_UNIX98_PRINTF)
4289         fi
4290     fi
4291 fi
4292
4293 dnl the same as above but for vsscanf() now: it's not present in at least
4294 dnl Solaris 9 headers for gcc-3.4 (due to fixinclude's processing of stdio.h)
4295 if test "$ac_cv_func_vsscanf" = "yes"; then
4296     AC_CACHE_CHECK([for vsscanf declaration], wx_cv_func_vsscanf_decl,
4297         [
4298             AC_TRY_COMPILE(
4299                 [
4300                     #include <stdio.h>
4301                     #include <stdarg.h>
4302                     #ifdef __MSL__
4303                     #if __MSL__ >= 0x6000
4304                     namespace std {}
4305                     using namespace std;
4306                     #endif
4307                     #endif
4308                 ],
4309                 [
4310                     char *buf;
4311                     va_list args;
4312                     vsscanf(buf, "%s", args);
4313                 ],
4314                 wx_cv_func_vsscanf_decl=yes,
4315                 wx_cv_func_vsscanf_decl=no
4316             )
4317         ]
4318     )
4319
4320     if test "$wx_cv_func_vsscanf_decl" = "yes"; then
4321         AC_DEFINE(HAVE_VSSCANF_DECL)
4322     fi
4323 fi
4324 AC_LANG_POP()
4325
4326 if test "$wxUSE_UNICODE" = yes; then
4327
4328     dnl also look if we have wide char IO functions, notice that [f]putws are
4329     dnl declared in special widec.h under Solaris
4330     wchar_headers="#include <stdio.h>
4331 #include <wchar.h>"
4332     case "${host}" in
4333         *-*-solaris2* )
4334             AC_CHECK_HEADERS(widec.h,,, [AC_INCLUDES_DEFAULT()])
4335             if test "$ac_cv_header_widec_h" = "yes"; then
4336                 wchar_headers="$wchar_headers
4337 #include <widec.h>"
4338             fi
4339     esac
4340
4341     WX_CHECK_FUNCS(putws fputws wprintf vswprintf vswscanf,,,
4342                    [$wchar_headers])
4343
4344     dnl MinGW has a vswprintf with a different prototype, and
4345     dnl a _vsnwprintf with the correct prototype, but AC_CHECK_FUNCS
4346     dnl finds it even if it is not declared in some versions...
4347     AC_MSG_CHECKING([for _vsnwprintf])
4348     AC_TRY_COMPILE([#include <wchar.h>],
4349                    [&_vsnwprintf;],
4350                    [AC_MSG_RESULT([yes])
4351                     AC_DEFINE(HAVE__VSNWPRINTF)],
4352                    [AC_MSG_RESULT([no])]);
4353 fi
4354
4355 if test "$wxUSE_FILE" = "yes"; then
4356     WX_CHECK_FUNCS(fsync)
4357 fi
4358
4359 dnl at least under IRIX with mipsPro the C99 round() function is available when
4360 dnl building using the C compiler but not when using C++ one
4361 AC_LANG_PUSH(C++)
4362 WX_CHECK_FUNCS(round,,,[#include <math.h>])
4363 AC_LANG_POP()
4364
4365 dnl the following tests are for Unix(like) systems only
4366 if test "$TOOLKIT" != "MSW"; then
4367
4368 dnl check for available version of iconv()
4369 if test "$wxUSE_LIBICONV" != "no" ; then
4370     AM_ICONV
4371     LIBS="$LIBICONV $LIBS"
4372 fi
4373
4374 dnl check for POSIX signals if we need them
4375 if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes" -a "$wxUSE_UNIX" = "yes"; then
4376     AC_CHECK_FUNCS(sigaction)
4377
4378     if test "$ac_cv_func_sigaction" = "no"; then
4379         AC_MSG_WARN([No POSIX signal functions on this system, wxApp::OnFatalException will not be called])
4380         wxUSE_ON_FATAL_EXCEPTION=no
4381     fi
4382
4383     if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
4384       AC_CACHE_CHECK([for sa_handler type], wx_cv_type_sa_handler,
4385       [
4386         dnl C compiler happily compiles the code even if there is type mismatch
4387         AC_LANG_PUSH(C++)
4388         AC_TRY_COMPILE([#include <signal.h>],
4389                      [
4390                         extern void testSigHandler(int);
4391
4392                         struct sigaction sa;
4393                         sa.sa_handler = testSigHandler;
4394                      ], [
4395                         wx_cv_type_sa_handler=int
4396                      ], [
4397                         wx_cv_type_sa_handler=void
4398                      ])
4399         AC_LANG_POP()
4400       ])
4401
4402       AC_DEFINE_UNQUOTED(wxTYPE_SA_HANDLER, $wx_cv_type_sa_handler)
4403     fi
4404 fi
4405
4406 dnl backtrace() and backtrace_symbols() for wxStackWalker
4407 if test "$wxUSE_STACKWALKER" = "yes" -a "$wxUSE_UNIX" = "yes"; then
4408     AC_CACHE_CHECK([for backtrace() in <execinfo.h>], wx_cv_func_backtrace,
4409         [
4410             AC_LANG_PUSH(C++)
4411             AC_TRY_COMPILE([#include <execinfo.h>],
4412                 [
4413                     void *trace[1];
4414                     char **messages;
4415
4416                     backtrace(trace, 1);
4417                     messages = backtrace_symbols(trace, 1);
4418                 ],
4419                 wx_cv_func_backtrace=yes,
4420                 wx_cv_func_backtrace=no
4421             )
4422             AC_LANG_POP()
4423         ]
4424     )
4425
4426
4427     if test "$wx_cv_func_backtrace" = "no"; then
4428         AC_MSG_WARN([backtrace() is not available, wxStackWalker will not be available])
4429         wxUSE_STACKWALKER=no
4430     else
4431         AC_CACHE_CHECK([for __cxa_demangle() in <cxxabi.h>], wx_cv_func_cxa_demangle,
4432             [
4433                 AC_LANG_PUSH(C++)
4434                 AC_TRY_LINK([#include <cxxabi.h>],
4435                     [
4436                         int rc;
4437                         __cxxabiv1::__cxa_demangle("foo", 0, 0, &rc);
4438                     ],
4439                     wx_cv_func_cxa_demangle=yes,
4440                     wx_cv_func_cxa_demangle=no
4441                 )
4442                 AC_LANG_POP()
4443             ]
4444         )
4445
4446         if test "$wx_cv_func_cxa_demangle" = "yes"; then
4447             AC_DEFINE(HAVE_CXA_DEMANGLE)
4448         fi
4449     fi
4450 fi
4451
4452 if test "$wxUSE_STACKWALKER" = "yes" -a "$USE_WIN32" != 1 -a "$USE_UNIX" != 1; then
4453     AC_MSG_WARN([wxStackWalker is only available on Win32 and UNIX... disabled])
4454     wxUSE_STACKWALKER=no
4455 fi
4456
4457
4458 dnl check for the function for temp files creation
4459 AC_CHECK_FUNCS(mkstemp mktemp, break)
4460
4461 dnl get the library function to use for wxGetDiskSpace(): it is statfs() under
4462 dnl Linux and *BSD and statvfs() under Solaris
4463 AC_CACHE_CHECK(for statfs, wx_cv_func_statfs,
4464     AC_TRY_COMPILE(
4465         [
4466              #if defined(__BSD__)
4467              #include <sys/param.h>
4468              #include <sys/mount.h>
4469              #else
4470              #include <sys/vfs.h>
4471              #endif
4472         ],
4473         [
4474              long l;
4475              struct statfs fs;
4476              statfs("/", &fs);
4477              l = fs.f_bsize;
4478              l += fs.f_blocks;
4479              l += fs.f_bavail;
4480         ],
4481          wx_cv_func_statfs=yes,
4482          wx_cv_func_statfs=no
4483     )
4484 )
4485
4486 if test "$wx_cv_func_statfs" = "yes"; then
4487     dnl check whether we have its dcelaration too: some systems (AIX 4) lack it
4488     AC_CACHE_CHECK(for statfs declaration, wx_cv_func_statfs_decl,
4489         AC_LANG_PUSH(C++)
4490         AC_TRY_COMPILE(
4491             [
4492                  #if defined(__BSD__)
4493                  #include <sys/param.h>
4494                  #include <sys/mount.h>
4495                  #else
4496                  #include <sys/vfs.h>
4497                  #endif
4498             ],
4499             [
4500                 struct statfs fs;
4501                 statfs("", &fs);
4502             ],
4503             wx_cv_func_statfs_decl=yes,
4504             wx_cv_func_statfs_decl=no
4505         )
4506         AC_LANG_POP()
4507     )
4508
4509     if test "$wx_cv_func_statfs_decl" = "yes"; then
4510         AC_DEFINE(HAVE_STATFS_DECL)
4511     fi
4512
4513     wx_cv_type_statvfs_t="struct statfs"
4514     AC_DEFINE(HAVE_STATFS)
4515 else
4516     AC_CACHE_CHECK(for statvfs, wx_cv_func_statvfs,
4517         AC_TRY_COMPILE(
4518             [
4519                 #include <stddef.h>
4520                 #include <sys/statvfs.h>
4521             ],
4522             [
4523                 statvfs("/", NULL);
4524             ],
4525             wx_cv_func_statvfs=yes,
4526             wx_cv_func_statvfs=no
4527         )
4528     )
4529
4530     if test "$wx_cv_func_statvfs" = "yes"; then
4531         dnl we also have to check whether we should use statvfs_t (works under
4532         dnl Solaris 8, doesn't work under Solaris 7) or "struct statvfs" (vice
4533         dnl versa) as the argument for statvfs in 64 bit off_t mode (in 32 bit
4534         dnl mode both work fine)
4535         dnl
4536         dnl for this check C++ compiler has to be used as passing incompatible
4537         dnl pointers is just a warning and not an error in C
4538         AC_CACHE_CHECK(for statvfs argument type, wx_cv_type_statvfs_t,
4539             AC_LANG_PUSH(C++)
4540             AC_TRY_COMPILE(
4541                 [
4542                     #include <sys/statvfs.h>
4543                 ],
4544                 [
4545                     long l;
4546                     statvfs_t fs;
4547                     statvfs("/", &fs);
4548                     l = fs.f_bsize;
4549                     l += fs.f_blocks;
4550                     l += fs.f_bavail;
4551                 ],
4552                 wx_cv_type_statvfs_t=statvfs_t,
4553                 [
4554                     AC_TRY_COMPILE(
4555                         [
4556                             #include <sys/statvfs.h>
4557                         ],
4558                         [
4559                             long l;
4560                             struct statvfs fs;
4561                             statvfs("/", &fs);
4562                             l = fs.f_bsize;
4563                             l += fs.f_blocks;
4564                             l += fs.f_bavail;
4565                         ],
4566                         wx_cv_type_statvfs_t="struct statvfs",
4567                         wx_cv_type_statvfs_t="unknown"
4568                     )
4569                 ]
4570             )
4571             AC_LANG_POP()
4572         )
4573
4574         if test "$wx_cv_type_statvfs_t" != "unknown"; then
4575             AC_DEFINE(HAVE_STATVFS)
4576         fi
4577     else
4578         dnl set it for the test below
4579         wx_cv_type_statvfs_t="unknown"
4580     fi
4581 fi
4582
4583 if test "$wx_cv_type_statvfs_t" != "unknown"; then
4584     AC_DEFINE_UNQUOTED(WX_STATFS_T, $wx_cv_type_statvfs_t)
4585 else
4586     AC_MSG_WARN([wxGetDiskSpace() function won't work without statfs()])
4587 fi
4588
4589 dnl check for fcntl() or at least flock() needed by Unix implementation of
4590 dnl wxSingleInstanceChecker
4591 if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
4592     AC_CHECK_FUNCS(fcntl flock, break)
4593
4594     if test "$ac_cv_func_fcntl" != "yes" -a "$ac_cv_func_flock" != "yes"; then
4595         AC_MSG_WARN(wxSingleInstanceChecker not available)
4596         wxUSE_SNGLINST_CHECKER=no
4597     fi
4598 fi
4599
4600 dnl look for a function to modify the environment
4601 AC_CHECK_FUNCS(setenv putenv, break)
4602 if test "$ac_cv_func_setenv" = "yes"; then
4603     AC_CHECK_FUNCS(unsetenv)
4604 fi
4605
4606 HAVE_SOME_SLEEP_FUNC=0
4607 if test "$USE_BEOS" = 1; then
4608     dnl BeOS has its own (wonder where did they get it from) sleep() function
4609     dnl in unistd.h
4610     AC_DEFINE(HAVE_SLEEP)
4611     HAVE_SOME_SLEEP_FUNC=1
4612 fi
4613
4614 if test "$USE_DARWIN" = 1; then
4615     dnl Mac OS X/Darwin has both nanosleep and usleep
4616     dnl but only usleep is defined in unistd.h
4617     AC_DEFINE(HAVE_USLEEP)
4618     HAVE_SOME_SLEEP_FUNC=1
4619 fi
4620
4621 if test "$HAVE_SOME_SLEEP_FUNC" != 1; then
4622     dnl try nanosleep() in libc and libposix4, if this fails - usleep()
4623     POSIX4_LINK=
4624     AC_CHECK_FUNCS(nanosleep,
4625         AC_DEFINE(HAVE_NANOSLEEP),
4626         [
4627             AC_CHECK_LIB(posix4, nanosleep,
4628                 [
4629                     AC_DEFINE(HAVE_NANOSLEEP)
4630                     POSIX4_LINK=" -lposix4"
4631                 ],
4632                 [
4633                     WX_CHECK_FUNCS(usleep,,
4634                                     AC_MSG_WARN([wxSleep() function will not work])
4635                     )
4636                 ]
4637             )
4638         ]
4639     )
4640 fi
4641
4642 dnl check for uname (POSIX) and gethostname (BSD)
4643 WX_CHECK_FUNCS(uname,,,[#include <sys/utsname.h>])
4644 if test "$wx_cv_func_uname" != yes; then
4645     WX_CHECK_FUNCS(gethostname)
4646 fi
4647
4648 WX_CHECK_FUNCS(strtok_r, [], [], [#define _REENTRANT])
4649
4650 dnl check for inet_addr and inet_aton (these may live either in libc, or in
4651 dnl libnsl or libresolv or libsocket)
4652 INET_LINK=
4653 AC_CHECK_FUNCS(inet_addr,
4654     AC_DEFINE(HAVE_INET_ADDR),
4655     [
4656         AC_CHECK_LIB(nsl, inet_addr,
4657             INET_LINK="nsl",
4658             [
4659                 AC_CHECK_LIB(resolv, inet_addr,
4660                     INET_LINK="resolv",
4661                     [
4662                         AC_CHECK_LIB(socket, inet_addr,
4663                             INET_LINK="socket"
4664                         )
4665                     ]
4666                 )
4667             ]
4668         )
4669     ]
4670 )
4671
4672 AC_CHECK_FUNCS(inet_aton,
4673         AC_DEFINE(HAVE_INET_ATON),
4674         [
4675             dnl only check it in the same lib
4676             AC_CHECK_LIB($INET_LINK, inet_aton, AC_DEFINE(HAVE_INET_ATON))
4677         ])
4678
4679 if test "x$INET_LINK" != "x"; then
4680     AC_DEFINE(HAVE_INET_ADDR)
4681     INET_LINK=" -l$INET_LINK"
4682 fi
4683
4684 WX_CHECK_FUNCS(fdopen)
4685
4686 if test "$wxUSE_TARSTREAM" = "yes"; then
4687     WX_CHECK_FUNCS(sysconf)
4688
4689     WX_CHECK_FUNCS(getpwuid_r, [], [],
4690                    [
4691                     #define _REENTRANT
4692                     #include <pwd.h>
4693                    ],
4694                    [[
4695                     struct passwd pw, *ppw;
4696                     char buf[1024];
4697                     getpwuid_r(0, &pw, buf, sizeof(buf), &ppw)
4698                    ]])
4699
4700     WX_CHECK_FUNCS(getgrgid_r, [], [],
4701                    [
4702                     #define _REENTRANT
4703                     #include <grp.h>
4704                    ],
4705                    [[
4706                     struct group grp, *pgrp;
4707                     char buf[1024];
4708                     getgrgid_r(0, &grp, buf, sizeof(buf), &pgrp)
4709                    ]])
4710 fi
4711
4712 fi
4713
4714
4715 dnl ===========================================================================
4716 dnl Now we have all the info we need - use it!
4717 dnl ===========================================================================
4718
4719 dnl flush the cache
4720 AC_CACHE_SAVE
4721
4722 dnl ---------------------------------------------------------------------------
4723 dnl thread support for Unix (for Win32 and OS/2 see past
4724 dnl                          the next matching "else")
4725 dnl ---------------------------------------------------------------------------
4726
4727 dnl under MSW (except mingw32) we always have thread support
4728 if test "$TOOLKIT" != "MSW" -a "$USE_OS2" != 1; then
4729
4730     dnl the code below:
4731     dnl
4732     dnl   defines THREADS_LINK and THREADS_CFLAGS which are the options
4733     dnl   necessary to build the MT programs for the linker and compiler
4734     dnl   respectively
4735     dnl
4736     dnl   sets wxUSE_THREADS=1 if thread support is activated
4737
4738     THREADS_LINK=
4739     THREADS_CFLAGS=
4740
4741     if test "$wxUSE_THREADS" = "yes" ; then
4742         if test "$USE_BEOS" = 1; then
4743             AC_MSG_WARN([BeOS threads are not yet supported... disabled])
4744             wxUSE_THREADS="no"
4745         fi
4746     fi
4747
4748     if test "$wxUSE_THREADS" = "yes" ; then
4749         dnl find if POSIX threads are available
4750         dnl
4751         dnl the tests here are based on ACX_PTHREAD macro from autoconf macro
4752         dnl archive from http://ac-archive.sourceforge.net/
4753         dnl
4754         dnl thanks to Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro
4755         dnl Forero Cuervo <bachue@bachue.com> for the original code
4756
4757         dnl TODO: cache the result
4758
4759         dnl define the list of the thread options to try in the loop below
4760         dnl with the convention that anything starting with '-' is a cpp flag
4761         dnl while anything else is a library (i.e. there is an implicit "-l")
4762         THREAD_OPTS="-pthread"
4763         if test "x$SUNCXX" = xyes; then
4764             THREAD_OPTS="-mt lthread $THREAD_OPTS"
4765         fi
4766
4767         case "${host}" in
4768           *-*-solaris2* | *-*-sunos4* )
4769                 if test "x$GCC" = "xyes"; then
4770                     dnl Solaris/gcc combination use this one for some reason
4771                     THREAD_OPTS="-pthreads $THREAD_OPTS"
4772                 fi
4773                 ;;
4774           *-*-freebsd*)
4775                 dnl look, in order, for the kernel threads, then Linux threads
4776                 dnl and finally the userland threads
4777                 THREAD_OPTS="-kthread lthread $THREAD_OPTS c_r"
4778                 ;;
4779           *-*-darwin* | *-*-cygwin* )
4780                 dnl Darwin / Mac OS X just uses -lpthread tested below
4781                 dnl and so does Cygwin
4782                 THREAD_OPTS=""
4783                 ;;
4784           *-*-aix*)
4785                 dnl AIX calls the library libpthreads - thanks IBM!
4786                 THREAD_OPTS="pthreads"
4787                 ;;
4788           *-hp-hpux* )
4789                 if test "x$GCC" = "xyes"; then
4790                     dnl g++ versions before 3.3.2 don't support -pthread.
4791                     $CXX -dumpspecs | grep 'pthread:' >/dev/null ||
4792                         THREAD_OPTS=""
4793                 else
4794                     dnl HP-UX aCC (tested with version B3910B A.06.05 [Jul 25
4795                     dnl 2005]) supports -mt
4796                     THREAD_OPTS="-mt"
4797                 fi
4798                 ;;
4799
4800           *-*-irix* )
4801                 dnl gcc under IRIX doesn't seem to like -pthread, but it
4802                 dnl doesn't give an error for it neither, just a warning
4803                 dnl message -- but this is still very annoying
4804                 if test "x$GCC" = "xyes"; then
4805                     THREAD_OPTS=""
4806                 fi
4807                 ;;
4808
4809           *-*-*UnixWare*)
4810                 dnl flying by man pages here: Caldera online docs use this
4811                 if test "x$GCC" != "xyes"; then
4812                     THREAD_OPTS="-Ethread"
4813                 fi
4814                 ;;
4815         esac
4816
4817         dnl simply linking with libpthread should make the test below work but
4818         dnl it's far from certain that the threaded programs compiled without
4819         dnl any special switches actually work, so try it after all the others
4820         THREAD_OPTS="$THREAD_OPTS pthread none"
4821
4822         dnl now test for all possibilities
4823         THREADS_OK=no
4824         for flag in $THREAD_OPTS; do
4825             case $flag in
4826                 none)
4827                     AC_MSG_CHECKING([whether pthreads work without any flags])
4828                     ;;
4829
4830                 -*)
4831                     AC_MSG_CHECKING([whether pthreads work with $flag])
4832                     THREADS_CFLAGS="$flag"
4833                     ;;
4834
4835                 *)
4836                     AC_MSG_CHECKING([for the pthreads library -l$flag])
4837                     THREADS_LINK="-l$flag"
4838                     ;;
4839               esac
4840
4841               save_LIBS="$LIBS"
4842               save_CFLAGS="$CFLAGS"
4843               LIBS="$THREADS_LINK $LIBS"
4844               CFLAGS="$THREADS_CFLAGS $CFLAGS"
4845
4846               AC_TRY_LINK([#include <pthread.h>],
4847                           [pthread_create(0,0,0,0);],
4848                           THREADS_OK=yes)
4849
4850               LIBS="$save_LIBS"
4851               CFLAGS="$save_CFLAGS"
4852
4853               AC_MSG_RESULT($THREADS_OK)
4854               if test "x$THREADS_OK" = "xyes"; then
4855                       break;
4856               fi
4857
4858               THREADS_LINK=""
4859               THREADS_CFLAGS=""
4860       done
4861
4862       if test "x$THREADS_OK" != "xyes"; then
4863           wxUSE_THREADS=no
4864           AC_MSG_WARN([No thread support on this system... disabled])
4865       else
4866           dnl yes, these special compiler flags should be used with the
4867           dnl linker as well
4868           LDFLAGS="$THREADS_CFLAGS $LDFLAGS"
4869           LIBS="$THREADS_LINK $LIBS"
4870
4871           AC_MSG_CHECKING([if more special flags are required for pthreads])
4872           flag=no
4873           case "${host}" in
4874             *-aix*)
4875                 dnl again quoting from
4876                 dnl http://www-1.ibm.com/servers/esdd/articles/gnu.html:
4877                 dnl
4878                 dnl     When compiling and linking with -pthread, the library
4879                 dnl     search path should include -L/usr/lib/threads at the
4880                 dnl     beginning of the path.
4881                 LDFLAGS="-L/usr/lib/threads $LDFLAGS"
4882                 flag="-D_THREAD_SAFE"
4883                 ;;
4884             *-freebsd*)
4885                 flag="-D_THREAD_SAFE"
4886                 ;;
4887             *-hp-hpux* )
4888                 flag="-D_REENTRANT"
4889                 if test "x$GCC" != "xyes"; then
4890                     dnl see http://docs.hp.com/hpux/onlinedocs/2213/threads.htm
4891                     flag="$flag -D_RWSTD_MULTI_THREAD"
4892                 fi
4893                 ;;
4894             *solaris* | alpha*-osf*)
4895                 flag="-D_REENTRANT"
4896                 ;;
4897           esac
4898           AC_MSG_RESULT(${flag})
4899           if test "x$flag" != xno; then
4900               THREADS_CFLAGS="$THREADS_CFLAGS $flag"
4901           fi
4902
4903           dnl don't add these options to CPPFLAGS as cpp might not know them
4904           WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS $THREADS_CFLAGS"
4905       fi
4906     fi
4907
4908     dnl do other tests only if we are using threads
4909     if test "$wxUSE_THREADS" = "yes" ; then
4910       AC_CHECK_FUNCS(thr_setconcurrency)
4911
4912       dnl can't use AC_CHECK_FUNCS for this one as it's usually a macro and so
4913       dnl wouldn't be found by it
4914       AC_CACHE_CHECK([for pthread_cleanup_push/pop], wx_cv_func_pthread_cleanup,
4915       [
4916         dnl C compiler may treat pthread_cleanup_push() as an undeclared
4917         dnl function and not give a warning even if it's unavailable, so use
4918         dnl the C++ one for this test
4919         AC_LANG_PUSH(C++)
4920         AC_TRY_COMPILE([#include <pthread.h>
4921                void ThreadCleanupFunc(void *p);
4922             ],
4923             [
4924                 void *p;
4925                 pthread_cleanup_push(ThreadCleanupFunc, p);
4926                 pthread_cleanup_pop(0);
4927             ], [
4928                wx_cv_func_pthread_cleanup=yes
4929             ], [
4930                wx_cv_func_pthread_cleanup=no
4931             ]
4932         )
4933         AC_LANG_POP()
4934       ])
4935       if test "x$wx_cv_func_pthread_cleanup" = "xyes"; then
4936         AC_DEFINE(wxHAVE_PTHREAD_CLEANUP)
4937       fi
4938
4939       AC_CHECK_HEADERS(sched.h,,, [AC_INCLUDES_DEFAULT()])
4940       if test "$ac_cv_header_sched_h" = "yes"; then
4941           AC_CHECK_FUNC(sched_yield,
4942             AC_DEFINE(HAVE_SCHED_YIELD),
4943             [
4944                 AC_CHECK_LIB(posix4,
4945                     sched_yield,
4946                     [AC_DEFINE(HAVE_SCHED_YIELD) POSIX4_LINK=" -lposix4"],
4947                     AC_MSG_WARN(wxThread::Yield will not work properly)
4948                 )
4949             ]
4950           )
4951       fi
4952
4953       dnl to be able to set the thread priority, we need to have all of the
4954       dnl following functions:
4955       dnl   1. pthread_attr_getschedpolicy
4956       dnl   2. sched_get_priority_min and sched_get_priority_max
4957       dnl      (this one can be in either libpthread or libposix4 (under Solaris))
4958       dnl   3. pthread_attr_getschedparam and pthread_attr_setschedparam
4959       HAVE_PRIOR_FUNCS=0
4960       AC_CHECK_FUNC(pthread_attr_getschedpolicy,
4961                      [AC_CHECK_FUNC(pthread_attr_setschedparam,
4962                        [AC_CHECK_FUNC(sched_get_priority_max,
4963                            HAVE_PRIOR_FUNCS=1,
4964                            [AC_CHECK_LIB([posix4], sched_get_priority_max,
4965                              [
4966                                 HAVE_PRIOR_FUNCS=1
4967                                 POSIX4_LINK=" -lposix4"
4968                              ],
4969                            )]
4970                        )]
4971                      )]
4972                    )
4973
4974       if test "$HAVE_PRIOR_FUNCS" = 1; then
4975         AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS)
4976       else
4977         AC_MSG_WARN(Setting thread priority will not work)
4978       fi
4979
4980       AC_CHECK_FUNC(pthread_cancel,
4981                     AC_DEFINE(HAVE_PTHREAD_CANCEL),
4982                     AC_MSG_WARN([wxThread::Kill() will not work properly]))
4983
4984       AC_CHECK_FUNC(pthread_mutex_timedlock,
4985                     AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK),
4986                     AC_MSG_WARN([wxMutex::LockTimeout() will not work]))
4987
4988       AC_CHECK_FUNC(pthread_attr_setstacksize,
4989                     AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE))
4990
4991       dnl mutexattr_t initialization is done in quite different ways on different
4992       dnl platforms, so check for a few things:
4993       dnl
4994       dnl HAVE_MUTEX_RECURSIVE means that we can create recursive mutexes
4995       dnl HAVE_MUTEXATTR_SETTYPE means that we do it using
4996       dnl pthread_mutexattr_settype(PTHREAD_MUTEX_RECURSIVE) and if it is not
4997       dnl defined, we do it by directly assigned
4998       dnl PTHREAD_MUTEX_RECURSIVE_MUTEX_INITIALIZER_NP to attr
4999
5000       AC_CACHE_CHECK([for pthread_mutexattr_t], wx_cv_type_pthread_mutexattr_t,
5001       [
5002         AC_TRY_COMPILE([#include <pthread.h>],
5003             [
5004                pthread_mutexattr_t attr;
5005                pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
5006             ],
5007             wx_cv_type_pthread_mutexattr_t=yes,
5008             wx_cv_type_pthread_mutexattr_t=no
5009         )
5010       ])
5011
5012       if test "$wx_cv_type_pthread_mutexattr_t" = "yes"; then
5013         AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_T)
5014
5015         dnl check if we already have the declaration we need, it is not
5016         dnl present in some systems' headers
5017         AC_CACHE_CHECK([for pthread_mutexattr_settype declaration],
5018                        wx_cv_func_pthread_mutexattr_settype_decl, [
5019                        AC_TRY_COMPILE([#include <pthread.h>],
5020                            [
5021                                pthread_mutexattr_t attr;
5022                                pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
5023                            ],
5024                            wx_cv_func_pthread_mutexattr_settype_decl=yes,
5025                            wx_cv_func_pthread_mutexattr_settype_decl=no
5026                        )
5027         ])
5028         if test "$wx_cv_func_pthread_mutexattr_settype_decl" = "yes"; then
5029             AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_SETTYPE_DECL)
5030         fi
5031       else
5032         dnl don't despair, there may be another way to do it
5033         AC_CACHE_CHECK([for PTHREAD_RECURSIVE_MUTEX_INITIALIZER],
5034                        wx_cv_type_pthread_rec_mutex_init,
5035         [
5036             AC_TRY_COMPILE([#include <pthread.h>],
5037                 [
5038                     pthread_mutex_t attr = PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP;
5039                 ], [
5040                     wx_cv_type_pthread_rec_mutex_init=yes
5041                 ], [
5042                     wx_cv_type_pthread_rec_mutex_init=no
5043                 ]
5044             )
5045         ])
5046         if test "$wx_cv_type_pthread_rec_mutex_init" = "yes"; then
5047           AC_DEFINE(HAVE_PTHREAD_RECURSIVE_MUTEX_INITIALIZER)
5048         else
5049           dnl this may break code working elsewhere, so at least warn about it
5050           AC_MSG_WARN([wxMutex won't be recursive on this platform])
5051         fi
5052       fi
5053
5054       if test "$wxUSE_COMPILER_TLS" = "auto"; then
5055           if test "$USE_NETBSD" = 1; then
5056               AC_MSG_WARN([Disabling TLS under NetBSD, please contact wx-dev if it works now])
5057               wxUSE_COMPILER_TLS=no
5058           else
5059               wxUSE_COMPILER_TLS=yes
5060           fi
5061       fi
5062
5063       if test "$wxUSE_COMPILER_TLS" = "yes"; then
5064           dnl test for compiler thread-specific variables support
5065           AC_CACHE_CHECK([for __thread keyword],
5066                          wx_cv_cc___thread,
5067               [
5068                   AC_TRY_COMPILE([#include <pthread.h>],
5069                       [
5070                           static __thread int n = 0;
5071                           static __thread int *p = 0;
5072                       ],
5073                       wx_cv_cc___thread=yes,
5074                       wx_cv_cc___thread=no
5075                   )
5076               ]
5077           )
5078
5079           if test "$wx_cv_cc___thread" = "yes"; then
5080               AX_GXX_VERSION
5081               if test -n "$ax_cv_gxx_version"; then
5082                   dnl g++ supports __thread since at least version 3.3 but its support
5083                   dnl seems to be broken until 4.1, see
5084                   dnl   http://thread.gmane.org/gmane.comp.lib.wxwidgets.devel/108388
5085                   dnl
5086                   dnl NB: we still need to test __thread support with
5087                   dnl     AC_TRY_COMPILE above even for g++ 4 as it doesn't
5088                   dnl     support it for all architectures (e.g. it doesn't
5089                   dnl     work under OS X)
5090                   AC_MSG_CHECKING([whether __thread support in g++ is usable])
5091                   case "$ax_cv_gxx_version" in
5092                     1.* | 2.* | 3.* )
5093                         AC_MSG_RESULT([no, it's broken])
5094                         wx_cv_cc___thread=no
5095                         ;;
5096                     *)
5097                         AC_MSG_RESULT([yes, it works])
5098                         ;;
5099                   esac
5100               fi
5101           fi
5102
5103           if test "$wx_cv_cc___thread" = "yes"; then
5104             AC_DEFINE(HAVE___THREAD_KEYWORD)
5105           fi
5106         fi
5107     fi
5108
5109 dnl from if !MSW
5110 else
5111     if test "$wxUSE_THREADS" = "yes" ; then
5112       case "${host}" in
5113         x86_64-*-mingw32* )
5114         ;;
5115         *-*-mingw32* )
5116             dnl check if the compiler accepts -mthreads
5117             AC_CACHE_CHECK([if compiler supports -mthreads],
5118                 wx_cv_cflags_mthread,
5119                 [
5120                     CFLAGS_OLD="$CFLAGS"
5121                     CFLAGS="-mthreads $CFLAGS"
5122                     AC_TRY_COMPILE([], [],
5123                         wx_cv_cflags_mthread=yes,
5124                         wx_cv_cflags_mthread=no
5125                     )
5126                 ]
5127             )
5128
5129             if test "$wx_cv_cflags_mthread" = "yes"; then
5130                 dnl it does, use it
5131                 WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -mthreads"
5132                 LDFLAGS="$LDFLAGS -mthreads"
5133             else
5134                 dnl it doesn't
5135                 CFLAGS="$CFLAGS_OLD"
5136             fi
5137         ;;
5138         *-pc-os2*emx )
5139             WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -Zmt -D__ST_MT_ERRNO__"
5140             LDFLAGS="$LDFLAGS -Zmt"
5141         ;;
5142       esac
5143     fi
5144 fi
5145
5146 AC_CHECK_FUNC(localtime_r, [ AC_DEFINE(HAVE_LOCALTIME_R) ])
5147 AC_CHECK_FUNC(gmtime_r, [ AC_DEFINE(HAVE_GMTIME_R) ])
5148 dnl By preference, we probably should use getaddrinfo which avoids thread
5149 dnl safety issues and supports IPv6, however there currently is no code
5150 dnl for it, so testing for it is temporarily disabled and we are restricted
5151 dnl to gethostbyname_r/gethostbyaddr_r  and getservbyname_r
5152
5153 dnl AC_CHECK_FUNC(getaddrinfo, AC_DEFINE(HAVE_GETADDRINFO), [
5154     dnl no getaddrinfo, so check for gethostbyname_r and
5155     dnl related functions (taken from python's configure.in)
5156     dnl sigh -- gethostbyname_r is a mess; it can have 3, 5 or 6 arguments
5157       AX_FUNC_WHICH_GETHOSTBYNAME_R
5158       if test "x$ac_cv_func_which_gethostbyname_r" = "xno" -o \
5159               "x$ac_cv_func_which_gethostbyname_r" = "xunknown" ; then
5160           AC_CHECK_FUNC(gethostbyname, [ AC_DEFINE(HAVE_GETHOSTBYNAME) ])
5161       fi
5162       dnl A similar test for getservbyname_r
5163       dnl I'm tempted to just not do this test which is taking much time and
5164       dnl do something similar as for gethostbyaddr_r, but OTOH the macro
5165       dnl doing the test already exists, so using it is easy enough.     - SN
5166       AC_raf_FUNC_WHICH_GETSERVBYNAME_R
5167       if test "x$ac_cv_func_which_getservbyname_r" = "xno" -o \
5168               "x$ac_cv_func_which_getservbyname_r" = "xunknown" ; then
5169           AC_CHECK_FUNCS(getservbyname,[ AC_DEFINE(HAVE_GETSERVBYNAME) ])
5170       fi
5171       dnl For gethostbyaddr_r, we currently do no separate test, instead, we
5172       dnl silently assume it's available exactly if gethostbyname_r is
5173       dnl available and always requires two more arguments than
5174       dnl gethostbyname_r.
5175       dnl (also, I'm lazy and there no m4 file that's ready for use for this
5176       dnl  function, although it should be easy to rewrite the gethostbyname_r
5177       dnl  check to fit this case, if it's really needed.                - SN )
5178 dnl    ]
5179 dnl )
5180
5181 if test "$wxUSE_THREADS" = "yes"; then
5182   AC_DEFINE(wxUSE_THREADS)
5183
5184   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS thread"
5185 else
5186   dnl on some systems, _REENTRANT should be defined if we want to use any _r()
5187   dnl functions - add tests for other functions here as well
5188   if test "$wx_cv_func_strtok_r" = "yes"; then
5189     AC_MSG_CHECKING(if -D_REENTRANT is needed)
5190     if test "$NEEDS_D_REENTRANT_FOR_R_FUNCS" = 1; then
5191         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_REENTRANT"
5192         AC_MSG_RESULT(yes)
5193     else
5194         AC_MSG_RESULT(no)
5195     fi
5196   fi
5197 fi
5198
5199 if test "$WXGTK2" = 1 ; then
5200   AC_DEFINE_UNQUOTED(__WXGTK20__,$WXGTK2)
5201   WXGTK12=1
5202 fi
5203
5204 if test "$WXGTK12" = 1 ; then
5205   AC_DEFINE_UNQUOTED(__WXGTK12__,$WXGTK12)
5206 fi
5207
5208 if test "$WXGTK127" = 1 ; then
5209   AC_DEFINE_UNQUOTED(__WXGTK127__,$WXGTK127)
5210 fi
5211
5212 if test "$WXGPE" = 1 ; then
5213   AC_DEFINE_UNQUOTED(__WXGPE__,$WXGPE)
5214 fi
5215
5216 dnl DEBUG_CFLAGS contains debugging options (supposed to be the same for C and C++
5217 dnl compilers: we'd need a separate DEBUG_CXXFLAGS if this is ever not the case)
5218 DEBUG_CFLAGS=
5219 if `echo $CXXFLAGS $CFLAGS | grep " -g" >/dev/null`; then
5220     dnl the CXXFLAGS or the CFLAGS variable already contains the -g flag
5221     dnl (e.g. it was specified by the user before running configure); since
5222     dnl later they will be merged with DEBUG_CFLAGS, don't set the -g option
5223     dnl in DEBUG_CFLAGS to avoid (possibly different) flag duplicates
5224     AC_MSG_WARN([CXXFLAGS/CFLAGS already contains -g flag; ignoring the --enable-debug_info option])
5225 elif test "$wxUSE_DEBUG_INFO" = "yes" ; then
5226     DEBUG_CFLAGS="-g"
5227 fi
5228
5229 if test "$wxUSE_DEBUG_GDB" = "yes" ; then
5230     wxUSE_DEBUG_INFO=yes
5231     if test "$GCC" = yes; then
5232         DEBUG_CFLAGS="-ggdb"
5233     fi
5234 fi
5235
5236 if test "$wxUSE_DEBUG_FLAG" = "no" ; then
5237     if test "$wxUSE_GTK" = 1 ; then
5238         if test "x$wxGTK_VERSION" = "x1" ; then
5239             CPPFLAGS="-DGTK_NO_CHECK_CASTS $CPPFLAGS"
5240         fi
5241     fi
5242 fi
5243
5244 if test "$wxUSE_MEM_TRACING" = "yes" ; then
5245     AC_DEFINE(wxUSE_MEMORY_TRACING)
5246     AC_DEFINE(wxUSE_GLOBAL_MEMORY_OPERATORS)
5247     AC_DEFINE(wxUSE_DEBUG_NEW_ALWAYS)
5248     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS memcheck"
5249 fi
5250
5251 if test "$wxUSE_DMALLOC" = "yes" ; then
5252     DMALLOC_LIBS="-ldmallocthcxx"
5253 fi
5254
5255 dnl cc/cxx/ld option for profiling
5256 PROFILE_FLAGS=
5257 if test "$wxUSE_PROFILE" = "yes" ; then
5258     PROFILE_FLAGS=" -pg"
5259 fi
5260
5261 if test "$GCC" = "yes" ; then
5262     if test "$wxUSE_NO_RTTI" = "yes" ; then
5263         WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fno-rtti"
5264     fi
5265     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
5266         WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fno-exceptions"
5267     fi
5268     if test "$wxUSE_PERMISSIVE" = "yes" ; then
5269         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -fpermissive"
5270     fi
5271
5272     dnl Ian Brown <ian.brown@printsoft.de> reports that versions of gcc before
5273     dnl 3.0 overflow the table of contents on rs6000 as they create an entry
5274     dnl for each subroutine by default -- using the switch below only creates
5275     dnl one entry per file instead at the price of minor performance penalty
5276     dnl
5277     dnl As of wx2.4 a bug in the hppa gcc compiler causes a similar problem
5278     dnl without -ffunction-sections.  No idea how long we'll need to maintain
5279     dnl this, or even the extent of gcc/wx version combinations affected, but
5280     dnl also as above, this 'fix' does not come without side effects.
5281     dnl
5282     dnl TODO: test for the gcc version here (how?)
5283     case "${host}" in
5284       powerpc*-*-aix* )
5285         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -mminimal-toc"
5286         ;;
5287       *-hppa* )
5288         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -ffunction-sections"
5289         ;;
5290     esac
5291 fi
5292
5293 dnl C/C++ compiler option for optimization (supposed to be the same for both)
5294 OPTIMISE_CFLAGS=
5295 if `echo $CXXFLAGS $CFLAGS | grep " -O" >/dev/null`; then
5296     dnl the CXXFLAGS or the CFLAGS variable already contains -O optimization flag
5297     dnl (e.g. it was specified by the user before running configure); since
5298     dnl later they will be merged with OPTIMISE_CFLAGS, don't set the -O option
5299     dnl in OPTIMISE_CFLAGS to avoid (possibly different) flag duplicates
5300     AC_MSG_WARN([CXXFLAGS/CFLAGS already contains -O flag; ignoring the --disable-optimise option])
5301 else
5302     if test "$wxUSE_OPTIMISE" = "no" ; then
5303         if test "$GCC" = yes ; then
5304             dnl use -O0 because compiling with it is faster than compiling with no
5305             dnl optimization options at all (at least with g++ 3.2)
5306             OPTIMISE_CFLAGS="-O0"
5307         fi
5308     else
5309         if test "$GCC" = yes ; then
5310             case "${host}" in
5311                 *-pc-os2_emx | *-pc-os2-emx )
5312                     dnl Not all of the supported gcc versions understand
5313                     dnl -fstrict-aliasing and none actually needs it (yet).
5314                     OPTIMISE_CFLAGS="-O2"
5315                 ;;
5316                 *)
5317                     dnl Switch on optimisation but keep strict-aliasing off for
5318                     dnl now (see -fstrict-aliasing in the gcc manual). When it is
5319                     dnl switched back on consider using -Wstrict-aliasing=2.
5320                     OPTIMISE_CFLAGS="-O2 -fno-strict-aliasing"
5321                 ;;
5322             esac
5323         else
5324             OPTIMISE_CFLAGS="-O"
5325         fi
5326     fi
5327 fi
5328
5329 dnl ---------------------------------------------------------------------------
5330 dnl compatibility level
5331 dnl ---------------------------------------------------------------------------
5332
5333 if test "x$WXWIN_COMPATIBILITY_2_6" = "xyes"; then
5334     AC_DEFINE(WXWIN_COMPATIBILITY_2_6)
5335
5336     WXWIN_COMPATIBILITY_2_8="yes"
5337 fi
5338
5339 if test "x$WXWIN_COMPATIBILITY_2_8" != "xno"; then
5340     AC_DEFINE(WXWIN_COMPATIBILITY_2_8)
5341 fi
5342
5343 dnl ---------------------------------------------------------------------------
5344 dnl the library may be built without GUI classes at all
5345 dnl ---------------------------------------------------------------------------
5346
5347 if test "$wxUSE_GUI" = "yes"; then
5348     AC_DEFINE(wxUSE_GUI)
5349
5350     dnl the things we always pull in the GUI version of the library:
5351     dnl 1. basic things like wxApp, wxWindow, wxControl, wxFrame, wxDialog (the
5352     dnl    library really can't be built without those)
5353     dnl 2. basic controls: wxButton, wxStaticText, wxTextCtrl (these are used in
5354     dnl    almost any program and the first 2 are needed to show a message box
5355     dnl    which want to be always able to do)
5356     dnl 3. GDI stuff: icon, cursors and all that. Although it would be very nice
5357     dnl    to compile without them (if the app doesn't do any drawing, it doesn't
5358     dnl    need the dcs, pens, brushes, ...), this just can't be done now
5359     dnl 4. menu stuff: wxMenu, wxMenuBar, wxMenuItem
5360     dnl 5. misc stuff: timers, settings, message box
5361 fi
5362
5363 dnl ---------------------------------------------------------------------------
5364 dnl Unix/Windows
5365 dnl ---------------------------------------------------------------------------
5366
5367 if test "$wxUSE_UNIX" = "yes"; then
5368   AC_DEFINE(wxUSE_UNIX)
5369 fi
5370
5371 dnl ------------------------------------------------------------------------
5372 dnl DLL support
5373 dnl ------------------------------------------------------------------------
5374
5375 dnl under MSW we always have LoadLibrary/GetProcAddress
5376 if test "$TOOLKIT" != "MSW" -a "$USE_OS2" != 1; then
5377
5378     HAVE_DL_FUNCS=0
5379     HAVE_SHL_FUNCS=0
5380     if test "$wxUSE_DYNAMIC_LOADER" = "yes" -o "$wxUSE_DYNLIB_CLASS" = "yes" ; then
5381         if test "$USE_DOS" = 1; then
5382             HAVE_DL_FUNCS=0
5383         else
5384             dnl the test is a bit complicated because we check for dlopen() both with
5385             dnl and without -ldl and we also try to find shl_load() if there is no
5386             dnl dlopen() on this system
5387             AC_CHECK_FUNCS(dlopen,
5388             [
5389                 AC_DEFINE(HAVE_DLOPEN)
5390                 HAVE_DL_FUNCS=1
5391             ],
5392             [
5393                 AC_CHECK_LIB(dl, dlopen,
5394                             [
5395                                 AC_DEFINE(HAVE_DLOPEN)
5396                                 HAVE_DL_FUNCS=1
5397                                 DL_LINK=" -ldl$DL_LINK"
5398                             ],
5399                             [
5400                                 AC_CHECK_FUNCS(shl_load,
5401                                               [
5402                                                 AC_DEFINE(HAVE_SHL_LOAD)
5403                                                 HAVE_SHL_FUNCS=1
5404                                               ],
5405                                               [
5406                                                 AC_CHECK_LIB(shl_load, dld,
5407                                                              [
5408                                                                 HAVE_SHL_FUNCS=1
5409                                                                 DL_LINK=" -ldld$DL_LINK"
5410                                                              ])
5411                                               ])
5412                             ])
5413             ])
5414
5415             dnl check also for dlerror()
5416             if test "$HAVE_DL_FUNCS" = 1; then
5417                 AC_CHECK_FUNCS(dlerror,
5418                     AC_DEFINE(HAVE_DLERROR),
5419                     [
5420                         AC_CHECK_LIB(dl, dlerror, AC_DEFINE(HAVE_DLERROR))
5421                     ]
5422                 )
5423             fi
5424         fi
5425
5426         dnl Force HAVE_DL_FUNCS on for Darwin, even if the tests failed (e.g. pre-10.3)
5427         if test "$USE_DARWIN" = 1; then
5428             dnl dlopen/dlerror is implemented in dynlib.cpp for Darwin/Mac OS X
5429             HAVE_DL_FUNCS=1
5430         fi
5431
5432         if test "$HAVE_DL_FUNCS" = 0; then
5433             if test "$HAVE_SHL_FUNCS" = 0; then
5434               if test "$USE_UNIX" = 1 -o "$USE_DOS" = 1; then
5435                   AC_MSG_WARN([Missing dynamic loading support, several features will be disabled])
5436                   wxUSE_DYNAMIC_LOADER=no
5437                   wxUSE_DYNLIB_CLASS=no
5438               else
5439                   AC_MSG_WARN([Assuming wxLibrary class works on this platform])
5440               fi
5441             fi
5442         fi
5443     fi
5444 fi
5445
5446 if test "$wxUSE_DYNAMIC_LOADER" = "yes" ; then
5447     AC_DEFINE(wxUSE_DYNAMIC_LOADER)
5448 fi
5449 if test "$wxUSE_DYNLIB_CLASS" = "yes" ; then
5450     AC_DEFINE(wxUSE_DYNLIB_CLASS)
5451 fi
5452
5453
5454 dnl ---------------------------------------------------------------------------
5455 dnl Verify consistency of plugins/monolithic/shared settings:
5456 dnl ---------------------------------------------------------------------------
5457
5458 if test "$wxUSE_PLUGINS" = "yes" ; then
5459     if test "$wxUSE_SHARED" = "no" ; then
5460         AC_MSG_WARN([plugins supported only in shared build, disabling])
5461         wxUSE_PLUGINS=no
5462     fi
5463     if test "$wxUSE_MONOLITHIC" = "yes" ; then
5464         AC_MSG_WARN([plugins not supported monolithic build, disabling])
5465         wxUSE_PLUGINS=no
5466     fi
5467     if test "$wxUSE_DYNLIB_CLASS" = "no" ; then
5468         AC_MSG_WARN([plugins require wxDynamicLibrary, disabling])
5469         wxUSE_PLUGINS=no
5470     fi
5471     if test "$wxUSE_PLUGINS" = "yes" ; then
5472         AC_DEFINE(wxUSE_PLUGINS)
5473     fi
5474 fi
5475
5476 dnl ---------------------------------------------------------------------------
5477 dnl Register non-GUI class options for makefiles and setup.h
5478 dnl ---------------------------------------------------------------------------
5479
5480 if test "$wxUSE_STL" = "yes"; then
5481   AC_DEFINE(wxUSE_STL)
5482 fi
5483
5484 if test "$wxUSE_EXTENDED_RTTI" = "yes"; then
5485   AC_DEFINE(wxUSE_EXTENDED_RTTI)
5486 fi
5487
5488 if test "$wxUSE_ANY" = "yes"; then
5489     AC_DEFINE(wxUSE_ANY)
5490 fi
5491
5492 if test "$wxUSE_APPLE_IEEE" = "yes"; then
5493   AC_DEFINE(wxUSE_APPLE_IEEE)
5494 fi
5495
5496 if test "$wxUSE_TIMER" = "yes"; then
5497   AC_DEFINE(wxUSE_TIMER)
5498 fi
5499
5500 dnl Unix implementation needs additional checks because audio support
5501 dnl comes in many favours:
5502 if test "$USE_UNIX" = 1 ; then
5503     dnl mmedia doesn't compile with wxMGL, remove this if this is ever fixed
5504     if test "$wxUSE_MGL" != 1; then
5505         dnl it's not enough to check for just the header because OSS under NetBSD
5506         dnl redefines ioctl as oss_ioctrl inside it and so we also need to test
5507         dnl whether we need -lossaudio at link-time
5508         AC_CACHE_CHECK([for SNDCTL_DSP_SPEED in sys/soundcard.h], ac_cv_header_sys_soundcard, [
5509             AC_TRY_LINK([
5510                     #include <sys/ioctl.h>
5511                     #include <sys/soundcard.h>
5512                 ],
5513                 [
5514                     ioctl(0, SNDCTL_DSP_SPEED, 0);
5515                 ],
5516                 ac_cv_header_sys_soundcard=yes,
5517                 [
5518                     saveLibs="$LIBS"
5519                     LIBS="$saveLibs -lossaudio"
5520                     AC_TRY_LINK([
5521                             #include <sys/ioctl.h>
5522                             #include <sys/soundcard.h>
5523                         ],
5524                         [
5525                             ioctl(0, SNDCTL_DSP_SPEED, 0);
5526                         ],
5527                         ac_cv_header_sys_soundcard=yes,
5528                         [
5529                             LIBS="$saveLibs"
5530                             ac_cv_header_sys_soundcard=no
5531                         ]
5532                     )
5533                 ]
5534             )
5535         ])
5536     fi
5537
5538     if test "$ac_cv_header_sys_soundcard" = "yes"; then
5539         AC_DEFINE(HAVE_SYS_SOUNDCARD_H)
5540     fi
5541 fi
5542
5543 WITH_PLUGIN_SDL=0
5544 if test "$wxUSE_SOUND" = "yes"; then
5545   if test "$USE_UNIX" = 1 ; then
5546     if test "$wxUSE_LIBSDL" != "no"; then
5547       AM_PATH_SDL([1.2.0],
5548                   [
5549                     EXTRALIBS_SDL="$SDL_LIBS"
5550                     CFLAGS="$SDL_CFLAGS $CFLAGS"
5551                     CXXFLAGS="$SDL_CFLAGS $CXXFLAGS"
5552                     AC_DEFINE(wxUSE_LIBSDL)
5553                   ],
5554                   [wxUSE_LIBSDL="no"])
5555       if test "$wxUSE_LIBSDL" = "yes" -a "$wxUSE_PLUGINS" = "yes" ; then
5556         WITH_PLUGIN_SDL=1
5557       fi
5558     fi
5559   else
5560     dnl wxMGL doesn't support sound under DOS, only under Unix
5561     if test "$wxUSE_MGL" = 1; then
5562         AC_MSG_WARN([wxSound not supported in MGL under DOS... disabled])
5563         wxUSE_SOUND="no"
5564     fi
5565   fi
5566 fi
5567
5568 if test "$wxUSE_SOUND" = "yes"; then
5569   AC_DEFINE(wxUSE_SOUND)
5570   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sound"
5571 fi
5572
5573 if test "$WXGTK2" = 1; then
5574     PKG_PROG_PKG_CONFIG()
5575
5576     if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
5577
5578         if test "$wxUSE_GTKPRINT" = "yes" ; then
5579
5580                 PKG_CHECK_MODULES(GTKPRINT,
5581                                   [gtk+-unix-print-2.0 >= 2.10],
5582                     [
5583                         CFLAGS="$GTKPRINT_CFLAGS $CFLAGS"
5584                         CXXFLAGS="$GTKPRINT_CFLAGS $CXXFLAGS"
5585                         AC_DEFINE(wxUSE_GTKPRINT)
5586                     ],
5587                     [
5588                         AC_MSG_WARN([GTK printing support not found (GTK+ >= 2.10), library will use GNOME printing support or standard PostScript printing])
5589                         wxUSE_GTKPRINT="no"
5590                     ]
5591                 )
5592         fi
5593
5594         if test "$wxUSE_LIBGNOMEPRINT" = "yes" ; then
5595
5596                 PKG_CHECK_MODULES(LIBGNOMEPRINTUI,
5597                                   [libgnomeprintui-2.2 >= 2.8],
5598                     [
5599                         CFLAGS="$LIBGNOMEPRINTUI_CFLAGS $CFLAGS"
5600                         CXXFLAGS="$LIBGNOMEPRINTUI_CFLAGS $CXXFLAGS"
5601                         AC_DEFINE(wxUSE_LIBGNOMEPRINT)
5602                     ],
5603                     [
5604                         AC_MSG_WARN([libgnomeprintui not found, library will use standard PostScript printing])
5605                         wxUSE_LIBGNOMEPRINT="no"
5606                     ]
5607                 )
5608         fi
5609     fi
5610
5611     if test "$wxUSE_MIMETYPE" = "yes" ; then
5612         if test "$wxUSE_LIBGNOMEVFS" = "yes" ; then
5613
5614                 PKG_CHECK_MODULES(GNOMEVFS,
5615                                   [gnome-vfs-2.0 >= 2.0],
5616                     [
5617                         CFLAGS="$GNOMEVFS_CFLAGS $CFLAGS"
5618                         CXXFLAGS="$GNOMEVFS_CFLAGS $CXXFLAGS"
5619                         AC_DEFINE(wxUSE_LIBGNOMEVFS)
5620                     ],
5621                     [
5622                         AC_MSG_WARN([libgnomevfs not found, library won't be able to associate MIME type])
5623                         wxUSE_LIBGNOMEVFS="no"
5624                     ]
5625                 )
5626         fi
5627     fi
5628
5629     if test "$wxUSE_LIBHILDON" = "yes" ; then
5630         PKG_CHECK_MODULES(HILDON,
5631                           [hildon-lgpl >= 0.9],
5632             [
5633                 EXTRALIBS_HILDON="$HILDON_LIBS"
5634                 CFLAGS="$CFLAGS $HILDON_CFLAGS"
5635                 CXXFLAGS="$CXXFLAGS $HILDON_CFLAGS"
5636                 AC_DEFINE(wxUSE_LIBHILDON)
5637                 ac_hildon_lgpl=1
5638             ],
5639             [
5640                 AC_MSG_WARN([libhildon_lgpl not found])
5641                         wxUSE_LIBHILDON="no"
5642                         ac_hildon_lgpl=0
5643             ]
5644         )
5645
5646         if test "$ac_hildon_lgpl" = 0 ; then
5647             PKG_CHECK_MODULES(HILDON2,
5648                               [hildon-1 >= 1.99],
5649                 [
5650                     EXTRALIBS_HILDON="$HILDON2_LIBS"
5651                     CFLAGS="$CFLAGS $HILDON2_CFLAGS"
5652                     CXXFLAGS="$CXXFLAGS $HILDON2_CFLAGS"
5653                     AC_DEFINE(wxUSE_LIBHILDON2)
5654                 ],
5655                 [
5656                     AC_MSG_WARN([libhildon_1 not found])
5657                             wxUSE_LIBHILDON2="no"
5658                 ]
5659             )
5660         fi
5661     fi
5662 fi
5663
5664 if test "$wxUSE_CMDLINE_PARSER" = "yes"; then
5665   AC_DEFINE(wxUSE_CMDLINE_PARSER)
5666 fi
5667
5668 if test "$wxUSE_STOPWATCH" = "yes"; then
5669   AC_DEFINE(wxUSE_STOPWATCH)
5670 fi
5671
5672 if test "$wxUSE_DATETIME" = "yes"; then
5673   AC_DEFINE(wxUSE_DATETIME)
5674 fi
5675
5676 if test "$wxUSE_FILE" = "yes"; then
5677   AC_DEFINE(wxUSE_FILE)
5678 fi
5679
5680 if test "$wxUSE_FFILE" = "yes"; then
5681   AC_DEFINE(wxUSE_FFILE)
5682 fi
5683
5684 if test "$wxUSE_ARCHIVE_STREAMS" = "yes"; then
5685   if test "$wxUSE_STREAMS" != yes; then
5686     AC_MSG_WARN(wxArchive requires wxStreams... disabled)
5687     wxUSE_ARCHIVE_STREAMS=no
5688   else
5689     AC_DEFINE(wxUSE_ARCHIVE_STREAMS)
5690   fi
5691 fi
5692
5693 if test "$wxUSE_ZIPSTREAM" = "yes"; then
5694   if test "$wxUSE_ARCHIVE_STREAMS" != "yes"; then
5695     AC_MSG_WARN(wxZip requires wxArchive... disabled)
5696   elif test "$wxUSE_ZLIB" = "no"; then
5697     AC_MSG_WARN(wxZip requires wxZlib... disabled)
5698   else
5699     AC_DEFINE(wxUSE_ZIPSTREAM)
5700   fi
5701 fi
5702
5703 if test "$wxUSE_TARSTREAM" = "yes"; then
5704   if test "$wxUSE_ARCHIVE_STREAMS" != "yes"; then
5705     AC_MSG_WARN(wxTar requires wxArchive... disabled)
5706   else
5707     AC_DEFINE(wxUSE_TARSTREAM)
5708   fi
5709 fi
5710
5711 if test "$wxUSE_FILESYSTEM" = "yes"; then
5712   if test "$wxUSE_STREAMS" != yes -o \( "$wxUSE_FILE" != yes -a "$wxUSE_FFILE" != yes \); then
5713     AC_MSG_WARN(wxFileSystem requires wxStreams and wxFile or wxFFile... disabled)
5714     wxUSE_FILESYSTEM=no
5715   else
5716     AC_DEFINE(wxUSE_FILESYSTEM)
5717   fi
5718 fi
5719
5720 if test "$wxUSE_FS_ARCHIVE" = "yes"; then
5721   if test "$wxUSE_FILESYSTEM" != yes -o "$wxUSE_ARCHIVE_STREAMS" != yes; then
5722     AC_MSG_WARN(wxArchiveFSHandler requires wxArchive and wxFileSystem... disabled)
5723   else
5724     AC_DEFINE(wxUSE_FS_ARCHIVE)
5725   fi
5726 fi
5727
5728 if test "$wxUSE_FS_ZIP" = "yes"; then
5729   if test "$wxUSE_FS_ARCHIVE" != yes; then
5730     AC_MSG_WARN(wxZipFSHandler requires wxArchiveFSHandler... disabled)
5731   else
5732     AC_DEFINE(wxUSE_FS_ZIP)
5733   fi
5734 fi
5735
5736 if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
5737   if test "$USE_UNIX" != 1; then
5738     AC_MSG_WARN([Catching fatal exceptions not currently supported on this system, wxApp::OnFatalException will not be called])
5739     wxUSE_ON_FATAL_EXCEPTION=no
5740   else
5741     AC_DEFINE(wxUSE_ON_FATAL_EXCEPTION)
5742   fi
5743 fi
5744
5745 if test "$wxUSE_STACKWALKER" = "yes"; then
5746     AC_DEFINE(wxUSE_STACKWALKER)
5747 fi
5748
5749 if test "$wxUSE_DEBUGREPORT" = "yes"; then
5750     if test "$USE_UNIX" != 1 -a "$USE_WIN32" != 1; then
5751         AC_MSG_WARN([Creating debug reports not currently supported on this system, disabled])
5752         wxUSE_DEBUGREPORT=no
5753     else
5754         AC_DEFINE(wxUSE_DEBUGREPORT)
5755         if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
5756             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS debugrpt"
5757         fi
5758     fi
5759 fi
5760
5761 if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
5762   AC_DEFINE(wxUSE_SNGLINST_CHECKER)
5763 fi
5764
5765 if test "$wxUSE_BUSYINFO" = "yes"; then
5766   AC_DEFINE(wxUSE_BUSYINFO)
5767 fi
5768
5769 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
5770   AC_DEFINE(wxUSE_STD_IOSTREAM)
5771 fi
5772
5773 if test "$wxUSE_STD_STRING" = "yes"; then
5774   AC_DEFINE(wxUSE_STD_STRING)
5775 fi
5776
5777 if test "$wxUSE_STDPATHS" = "yes"; then
5778   AC_DEFINE(wxUSE_STDPATHS)
5779 fi
5780
5781 if test "$wxUSE_TEXTBUFFER" = "yes"; then
5782     AC_DEFINE(wxUSE_TEXTBUFFER)
5783 fi
5784
5785 if test "$wxUSE_TEXTFILE" = "yes"; then
5786   if test "$wxUSE_FILE" != "yes" -o "$wxUSE_TEXTBUFFER" != "yes" ; then
5787     AC_MSG_WARN(wxTextFile requires wxFile and wxTextBuffer... disabled)
5788   else
5789     AC_DEFINE(wxUSE_TEXTFILE)
5790   fi
5791 fi
5792
5793 if test "$wxUSE_CONFIG" = "yes" ; then
5794   if test "$wxUSE_TEXTFILE" != "yes"; then
5795     AC_MSG_WARN(wxConfig requires wxTextFile... disabled)
5796   else
5797     AC_DEFINE(wxUSE_CONFIG)
5798     AC_DEFINE(wxUSE_CONFIG_NATIVE)
5799     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS config"
5800   fi
5801 fi
5802
5803 if test "$wxUSE_INTL" = "yes" ; then
5804   if test "$wxUSE_FILE" != "yes"; then
5805     AC_MSG_WARN(I18n code requires wxFile... disabled)
5806   else
5807     AC_DEFINE(wxUSE_INTL)
5808     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS internat"
5809     GUIDIST="$GUIDIST INTL_DIST"
5810   fi
5811 fi
5812
5813 if test "$wxUSE_XLOCALE" = "yes" ; then
5814     AC_DEFINE(wxUSE_XLOCALE)
5815     AC_CHECK_TYPES(locale_t,,,
5816                    [#include <xlocale.h>
5817                     #include <locale.h>])
5818 fi
5819
5820 if test "$wxUSE_LOG" = "yes"; then
5821   AC_DEFINE(wxUSE_LOG)
5822
5823     if test "$wxUSE_LOGGUI" = "yes"; then
5824       AC_DEFINE(wxUSE_LOGGUI)
5825     fi
5826
5827     if test "$wxUSE_LOGWINDOW" = "yes"; then
5828       AC_DEFINE(wxUSE_LOGWINDOW)
5829     fi
5830
5831     if test "$wxUSE_LOGDIALOG" = "yes"; then
5832       AC_DEFINE(wxUSE_LOG_DIALOG)
5833     fi
5834
5835     dnl the keyboard sample requires wxUSE_LOG
5836     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS keyboard"
5837 fi
5838
5839 if test "$wxUSE_LONGLONG" = "yes"; then
5840   AC_DEFINE(wxUSE_LONGLONG)
5841 fi
5842
5843 if test "$wxUSE_GEOMETRY" = "yes"; then
5844   AC_DEFINE(wxUSE_GEOMETRY)
5845 fi
5846
5847 if test "$wxUSE_BASE64" = "yes"; then
5848   AC_DEFINE(wxUSE_BASE64)
5849 fi
5850
5851 if test "$wxUSE_STREAMS" = "yes" ; then
5852   AC_DEFINE(wxUSE_STREAMS)
5853 fi
5854
5855 if test "$wxUSE_PRINTF_POS_PARAMS" = "yes"; then
5856   AC_DEFINE(wxUSE_PRINTF_POS_PARAMS)
5857 fi
5858
5859 if test "$wxUSE_OBJC_UNIQUIFYING" = "yes"; then
5860   AC_DEFINE(wxUSE_OBJC_UNIQUIFYING)
5861 fi
5862
5863 dnl ---------------------------------------------------------------------------
5864 dnl console event loop stuff
5865 dnl ---------------------------------------------------------------------------
5866
5867 if test "$wxUSE_CONSOLE_EVENTLOOP" = "yes"; then
5868     AC_DEFINE(wxUSE_CONSOLE_EVENTLOOP)
5869
5870     if test "$wxUSE_UNIX" = "yes"; then
5871         if test "$wxUSE_SELECT_DISPATCHER" = "yes"; then
5872             AC_DEFINE(wxUSE_SELECT_DISPATCHER)
5873         fi
5874
5875         if test "$wxUSE_EPOLL_DISPATCHER" = "yes"; then
5876             AC_CHECK_HEADERS(sys/epoll.h,,, [AC_INCLUDES_DEFAULT()])
5877             if test "$ac_cv_header_sys_epoll_h" = "yes"; then
5878                 AC_DEFINE(wxUSE_EPOLL_DISPATCHER)
5879             else
5880                 AC_MSG_WARN([sys/epoll.h not available, wxEpollDispatcher disabled])
5881             fi
5882         fi
5883     fi
5884 fi
5885
5886 dnl ---------------------------------------------------------------------------
5887 dnl time/date functions
5888 dnl ---------------------------------------------------------------------------
5889
5890 dnl check for gettimeofday (SVr4, BSD 4.3) and ftime (V7, BSD 4.3) for the
5891 dnl function to be used for high resolution timers
5892 AC_CHECK_FUNCS(gettimeofday ftime, break)
5893
5894 if test "$ac_cv_func_gettimeofday" = "yes"; then
5895     AC_CACHE_CHECK([whether gettimeofday takes two arguments],
5896                    wx_cv_func_gettimeofday_has_2_args,
5897     [
5898         dnl on some _really_ old systems it takes only 1 argument
5899         AC_TRY_COMPILE(
5900             [
5901                 #include <sys/time.h>
5902                 #include <unistd.h>
5903             ],
5904             [
5905                 struct timeval tv;
5906                 gettimeofday(&tv, NULL);
5907             ],
5908             wx_cv_func_gettimeofday_has_2_args=yes,
5909             AC_TRY_COMPILE(
5910                 [
5911                     #include <sys/time.h>
5912                     #include <unistd.h>
5913                 ],
5914                 [
5915                     struct timeval tv;
5916                     gettimeofday(&tv);
5917                 ],
5918                 wx_cv_func_gettimeofday_has_2_args=no,
5919                 [
5920                     AC_MSG_WARN([failed to determine number of gettimeofday() arguments])
5921                     wx_cv_func_gettimeofday_has_2_args=unknown
5922                 ]
5923             )
5924         )
5925     ])
5926
5927     if test "$wx_cv_func_gettimeofday_has_2_args" != "yes"; then
5928         AC_DEFINE(WX_GETTIMEOFDAY_NO_TZ)
5929     fi
5930 fi
5931
5932 if test "$wxUSE_DATETIME" = "yes"; then
5933     dnl check for timezone variable
5934     dnl   doesn't exist under Darwin / Mac OS X which uses tm_gmtoff instead
5935     AC_CACHE_CHECK(for timezone variable in <time.h>,
5936                    wx_cv_var_timezone,
5937                    [
5938                         AC_LANG_PUSH(C++)
5939                         AC_TRY_COMPILE(
5940                             [
5941                                 #include <time.h>
5942                             ],
5943                             [
5944                                 int tz;
5945                                 tz = timezone;
5946                             ],
5947                             [
5948                                 wx_cv_var_timezone=timezone
5949                             ],
5950                             [
5951                                 AC_TRY_COMPILE(
5952                                     [
5953                                         #include <time.h>
5954                                     ],
5955                                     [
5956                                         int tz;
5957                                         tz = _timezone;
5958                                     ],
5959                                     [
5960                                         wx_cv_var_timezone=_timezone
5961                                     ],
5962                                     [
5963                                         AC_TRY_COMPILE(
5964                                             [
5965                                                 #include <time.h>
5966                                             ],
5967                                             [
5968                                                 int tz;
5969                                                 tz = __timezone;
5970                                             ],
5971                                             [
5972                                                 wx_cv_var_timezone=__timezone
5973                                             ],
5974                                             [
5975                                                 if test "$USE_DOS" = 0 ; then
5976                                                     AC_MSG_WARN(no timezone variable, will use tm_gmtoff instead)
5977                                                 fi
5978                                             ]
5979                                         )
5980                                     ]
5981                                 )
5982                             ]
5983                         )
5984                         AC_LANG_POP()
5985                    ]
5986     )
5987
5988     dnl as we want $wx_cv_var_timezone to be expanded, use AC_DEFINE_UNQUOTED
5989     if test "x$wx_cv_var_timezone" != x ; then
5990         AC_DEFINE_UNQUOTED(WX_TIMEZONE, $wx_cv_var_timezone)
5991     fi
5992
5993     dnl check for localtime (it's POSIX, but the check can do no harm...)
5994     AC_CHECK_FUNCS(localtime)
5995
5996     if test "$ac_cv_func_localtime" = "yes"; then
5997         AC_CACHE_CHECK(for tm_gmtoff in struct tm,
5998                        wx_cv_struct_tm_has_gmtoff,
5999         [
6000             AC_TRY_COMPILE(
6001                 [
6002                     #include <time.h>
6003                 ],
6004                 [
6005                     struct tm tm;
6006                     tm.tm_gmtoff++;
6007                 ],
6008                 [
6009                     wx_cv_struct_tm_has_gmtoff=yes
6010                 ],
6011                 wx_cv_struct_tm_has_gmtoff=no
6012             )
6013         ])
6014     fi
6015
6016     if test "$wx_cv_struct_tm_has_gmtoff" = "yes"; then
6017         AC_DEFINE(WX_GMTOFF_IN_TM)
6018     fi
6019
6020     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS typetest"
6021 fi
6022
6023 dnl ------------------------------------------------------------------------
6024 dnl wxSocket
6025 dnl ------------------------------------------------------------------------
6026
6027 dnl VZ: the GUI hooks wxSocket needs are not implemented yet in some toolkits
6028 if test "$wxUSE_SOCKETS" = "yes"; then
6029     if test "$wxUSE_MGL" = 1; then
6030         AC_MSG_WARN([wxSocket not yet supported under MGL... disabled])
6031         wxUSE_SOCKETS="no"
6032     fi
6033 fi
6034
6035 if test "$wxUSE_SOCKETS" = "yes"; then
6036     dnl under MSW we always have sockets
6037     if test "$TOOLKIT" != "MSW"; then
6038         dnl under Solaris and OS/2, socket functions live in -lsocket
6039         AC_CHECK_FUNC(socket,,
6040             [
6041                 AC_CHECK_LIB(socket, socket,
6042                     if test "$INET_LINK" != " -lsocket"; then
6043                         INET_LINK="$INET_LINK -lsocket"
6044                     fi,
6045                     [
6046                         AC_MSG_WARN([socket library not found - sockets will be disabled])
6047                         wxUSE_SOCKETS=no
6048                     ]
6049                 )
6050             ]
6051         )
6052     fi
6053 fi
6054
6055 if test "$wxUSE_SOCKETS" = "yes" ; then
6056     dnl this test may be appropriate if building under cygwin
6057     dnl right now I'm assuming it also uses the winsock stuff
6058     dnl like mingw does..  -- RL
6059     if test "$TOOLKIT" != "MSW"; then
6060         dnl determine the type of third argument for getsockname
6061         dnl This test needs to be done in C++ mode since gsocket.cpp now
6062         dnl is C++ code and pointer cast that are possible even without
6063         dnl warning in C still fail in C++.
6064         AC_CACHE_CHECK([what is the type of the third argument of getsockname],
6065                        wx_cv_type_getsockname3,
6066             [
6067                 AC_LANG_PUSH(C++)
6068                 AC_TRY_COMPILE(
6069                     [
6070                         #include <sys/types.h>
6071                         #include <sys/socket.h>
6072                     ],
6073                     [
6074                         socklen_t len;
6075                         getsockname(0, 0, &len);
6076                     ],
6077                     wx_cv_type_getsockname3=socklen_t,
6078                     [
6079                         dnl the compiler will compile the version with size_t
6080                         dnl even if the real type of the last parameter is int
6081                         dnl but it should give at least a warning about
6082                         dnl converting between incompatible pointer types, so
6083                         dnl try to use it to get the correct behaviour at
6084                         dnl least with gcc (otherwise we'd always use size_t)
6085                         CFLAGS_OLD="$CFLAGS"
6086                         if test "$GCC" = yes ; then
6087                             CFLAGS="-Werror $CFLAGS"
6088                         fi
6089
6090                         AC_TRY_COMPILE(
6091                             [
6092                                 #include <sys/types.h>
6093                                 #include <sys/socket.h>
6094                             ],
6095                             [
6096                                 size_t len;
6097                                 getsockname(0, 0, &len);
6098                             ],
6099                             wx_cv_type_getsockname3=size_t,
6100                             AC_TRY_COMPILE(
6101                                 [
6102                                     #include <sys/types.h>
6103                                     #include <sys/socket.h>
6104                                 ],
6105                                 [
6106                                     int len;
6107                                     getsockname(0, 0, &len);
6108                                 ],
6109                                 wx_cv_type_getsockname3=int,
6110                                 wx_cv_type_getsockname3=unknown
6111                             )
6112                         )
6113
6114                         CFLAGS="$CFLAGS_OLD"
6115                     ]
6116                 )
6117                 AC_LANG_POP()
6118             ])
6119
6120         if test "$wx_cv_type_getsockname3" = "unknown"; then
6121             wxUSE_SOCKETS=no
6122             AC_MSG_WARN([Couldn't find socklen_t synonym for this system])
6123         else
6124             AC_DEFINE_UNQUOTED(WX_SOCKLEN_T, $wx_cv_type_getsockname3)
6125         fi
6126         dnl Do this again for getsockopt as it may be different
6127         AC_CACHE_CHECK([what is the type of the fifth argument of getsockopt],
6128                        wx_cv_type_getsockopt5,
6129             [
6130                 dnl Note that the rules for compatibility of pointers
6131                 dnl are somewhat different between C and C++, so code
6132                 dnl that fails in C++ may not even give a warning about
6133                 dnl converting between incompatible pointer types in C.
6134                 dnl So this test needs to be done in C++ mode.
6135                 AC_LANG_PUSH(C++)
6136                 AC_TRY_COMPILE(
6137                     [
6138                         #include <sys/types.h>
6139                         #include <sys/socket.h>
6140                     ],
6141                     [
6142                         socklen_t len;
6143                         getsockopt(0, 0, 0, 0, &len);
6144                     ],
6145                     wx_cv_type_getsockopt5=socklen_t,
6146                     [
6147                         AC_TRY_COMPILE(
6148                             [
6149                                 #include <sys/types.h>
6150                                 #include <sys/socket.h>
6151                             ],
6152                             [
6153                                 size_t len;
6154                                 getsockopt(0, 0, 0, 0, &len);
6155                             ],
6156                             wx_cv_type_getsockopt5=size_t,
6157                             AC_TRY_COMPILE(
6158                                 [
6159                                     #include <sys/types.h>
6160                                     #include <sys/socket.h>
6161                                 ],
6162                                 [
6163                                     int len;
6164                                     getsockopt(0, 0, 0, 0, &len);
6165                                 ],
6166                                 wx_cv_type_getsockopt5=int,
6167                                 wx_cv_type_getsockopt5=unknown
6168                             )
6169                         )
6170                     ]
6171                 )
6172                 AC_LANG_POP()
6173             ])
6174
6175         if test "$wx_cv_type_getsockopt5" = "unknown"; then
6176             wxUSE_SOCKETS=no
6177             AC_MSG_WARN([Couldn't find socklen_t synonym for this system])
6178         else
6179             AC_DEFINE_UNQUOTED(SOCKOPTLEN_T, $wx_cv_type_getsockopt5)
6180         fi
6181     fi
6182 fi
6183
6184 if test "$wxUSE_SOCKETS" = "yes" ; then
6185     if test "$wxUSE_IPV6" = "yes"; then
6186         AC_CACHE_CHECK(
6187             [whether we have sockaddr_in6],
6188             [wx_cv_type_sockaddr_in6],
6189             [
6190                 AC_TRY_COMPILE(
6191                     [
6192                         #include <sys/types.h>
6193                         #include <sys/socket.h>
6194                         #include <netinet/in.h>
6195                     ],
6196                     [
6197                         struct sockaddr_in6 sa6;
6198                     ],
6199                     wx_cv_type_sockaddr_in6=yes,
6200                     wx_cv_type_sockaddr_in6=no
6201                 )
6202             ]
6203         )
6204
6205         if test "$wx_cv_type_sockaddr_in6"="yes"; then
6206             AC_DEFINE(wxUSE_IPV6)
6207         else
6208             AC_MSG_WARN([IPv6 support not available... disabled])
6209         fi
6210     fi
6211
6212     AC_DEFINE(wxUSE_SOCKETS)
6213     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sockets"
6214 fi
6215
6216 if test "$wxUSE_PROTOCOL" = "yes"; then
6217     if test "$wxUSE_SOCKETS" != "yes"; then
6218         AC_MSG_WARN(Protocol classes require sockets... disabled)
6219         wxUSE_PROTOCOL=no
6220     fi
6221 fi
6222
6223 if test "$wxUSE_PROTOCOL" = "yes"; then
6224     AC_DEFINE(wxUSE_PROTOCOL)
6225
6226     if test "$wxUSE_PROTOCOL_HTTP" = "yes"; then
6227         AC_DEFINE(wxUSE_PROTOCOL_HTTP)
6228     fi
6229     if test "$wxUSE_PROTOCOL_FTP" = "yes"; then
6230         AC_DEFINE(wxUSE_PROTOCOL_FTP)
6231     fi
6232     if test "$wxUSE_PROTOCOL_FILE" = "yes"; then
6233         AC_DEFINE(wxUSE_PROTOCOL_FILE)
6234     fi
6235 else
6236     if test "$wxUSE_FS_INET" = "yes"; then
6237         AC_MSG_WARN([HTTP filesystem require protocol classes... disabled])
6238         wxUSE_FS_INET="no"
6239     fi
6240 fi
6241
6242 if test "$wxUSE_URL" = "yes"; then
6243     if test "$wxUSE_PROTOCOL" != "yes"; then
6244         AC_MSG_WARN(wxURL class requires wxProtocol... disabled)
6245         wxUSE_URL=no
6246     fi
6247     if test "$wxUSE_URL" = "yes"; then
6248         AC_DEFINE(wxUSE_URL)
6249     fi
6250 fi
6251
6252 if test "$wxUSE_VARIANT" = "yes"; then
6253     AC_DEFINE(wxUSE_VARIANT)
6254 fi
6255
6256 if test "$wxUSE_FS_INET" = "yes"; then
6257   AC_DEFINE(wxUSE_FS_INET)
6258 fi
6259
6260 dnl ---------------------------------------------------------------------------
6261 dnl Joystick support
6262 dnl ---------------------------------------------------------------------------
6263
6264 if test "$wxUSE_GUI" = "yes" -a "$wxUSE_JOYSTICK" = "yes"; then
6265     wxUSE_JOYSTICK=no
6266
6267     dnl under MSW we always have joystick support
6268     if test "$TOOLKIT" = "MSW"; then
6269         wxUSE_JOYSTICK=yes
6270
6271     dnl mac only available on darwin
6272     elif test "$TOOLKIT" = "OSX" -o "$TOOLKIT" = "COCOA"; then
6273         if test "$USE_DARWIN" = 1; then
6274             dnl check for a bug in the headers, some have bad setEventCallout
6275             AC_MSG_CHECKING([headers have declarations needed for joystick support])
6276             AC_LANG_PUSH(C++)
6277             AC_TRY_COMPILE( [ #include <IOKit/hid/IOHIDLib.h> ],
6278                             [ IOHIDQueueInterface *qi = NULL;
6279                               IOHIDCallbackFunction cb = NULL;
6280                               qi->setEventCallout(NULL, cb, NULL, NULL); ],
6281                             [ wxUSE_JOYSTICK=yes ]
6282                           )
6283             AC_LANG_POP()
6284             AC_MSG_RESULT($wxUSE_JOYSTICK)
6285         fi
6286
6287     dnl joystick support is only for Linux 2.1.x or greater
6288     else
6289         dnl wxJoystick not supported by wxMGL at all
6290         if test "$wxUSE_MGL" != 1; then
6291             dnl notice the dummy includes argument: without it, AC_CHECK_HEADER
6292             dnl checks only whether the header can be preprocessed, not that it
6293             dnl can be compiled and in Linux 2.6.16 joystick.h is present but
6294             dnl can't be compiled because of an error and with the default
6295             dnl AC_CHECK_HEADER semantics we'd still detect it in this case and
6296             dnl build would fail later
6297             AC_CHECK_HEADERS([linux/joystick.h], [wxUSE_JOYSTICK=yes],, [AC_INCLUDES_DEFAULT()])
6298         fi
6299     fi
6300
6301     if test "$wxUSE_JOYSTICK" = "yes"; then
6302         AC_DEFINE(wxUSE_JOYSTICK)
6303         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS joytest"
6304     else
6305         AC_MSG_WARN(Joystick not supported by this system... disabled)
6306     fi
6307 fi
6308
6309
6310 dnl ---------------------------------------------------------------------------
6311 dnl String stuff
6312 dnl ---------------------------------------------------------------------------
6313
6314 if test "$wxUSE_FONTENUM" = "yes" ; then
6315   AC_DEFINE(wxUSE_FONTENUM)
6316 fi
6317
6318 if test "$wxUSE_FONTMAP" = "yes" ; then
6319   AC_DEFINE(wxUSE_FONTMAP)
6320 fi
6321
6322 if test "$wxUSE_UNICODE" = "yes" ; then
6323   AC_DEFINE(wxUSE_UNICODE)
6324
6325   if test "$USE_WIN32" != 1; then
6326       wxUSE_UNICODE_MSLU=no
6327   fi
6328
6329   if test "$USE_WIN32" = 1 -a "$wxUSE_UNICODE_MSLU" = "yes"; then
6330         AC_CHECK_LIB(unicows,main,
6331             [
6332                 AC_DEFINE(wxUSE_UNICODE_MSLU)
6333             ],
6334             [
6335                 AC_MSG_WARN([Compiler doesn't support MSLU (libunicows.a), disabled.
6336                              Applications will only run on Windows NT/2000/XP!])
6337                 wxUSE_UNICODE_MSLU=no
6338             ])
6339     fi
6340 fi
6341
6342 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_UTF8" = "yes"; then
6343     AC_DEFINE(wxUSE_UNICODE_UTF8)
6344
6345     if test "$wxUSE_UNICODE_UTF8_LOCALE" = "yes"; then
6346         AC_DEFINE(wxUSE_UTF8_LOCALE_ONLY)
6347     fi
6348 fi
6349
6350 dnl ---------------------------------------------------------------------------
6351 dnl big GUI components: MDI, doc/view, printing, help, ...
6352 dnl ---------------------------------------------------------------------------
6353
6354 if test "$wxUSE_CONSTRAINTS" = "yes"; then
6355     AC_DEFINE(wxUSE_CONSTRAINTS)
6356     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS layout"
6357 fi
6358
6359 if test "$wxUSE_MDI" = "yes"; then
6360     AC_DEFINE(wxUSE_MDI)
6361
6362     if test "$wxUSE_MDI_ARCHITECTURE" = "yes"; then
6363         AC_DEFINE(wxUSE_MDI_ARCHITECTURE)
6364         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mdi"
6365     fi
6366 fi
6367
6368 if test "$wxUSE_DOC_VIEW_ARCHITECTURE" = "yes" ; then
6369     AC_DEFINE(wxUSE_DOC_VIEW_ARCHITECTURE)
6370     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS docview"
6371 fi
6372
6373 if test "$wxUSE_HELP" = "yes"; then
6374     AC_DEFINE(wxUSE_HELP)
6375     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS help"
6376
6377     if test "$wxUSE_MSW" = 1; then
6378       if test "$wxUSE_MS_HTML_HELP" = "yes"; then
6379         AC_DEFINE(wxUSE_MS_HTML_HELP)
6380       fi
6381     fi
6382
6383     if test "$wxUSE_WXHTML_HELP" = "yes"; then
6384       if test "$wxUSE_HTML" = "yes"; then
6385         AC_DEFINE(wxUSE_WXHTML_HELP)
6386       else
6387         AC_MSG_WARN(Cannot use wxHTML-based help without wxHTML so it won't be compiled)
6388         wxUSE_WXHTML_HELP=no
6389       fi
6390     fi
6391 fi
6392
6393 if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
6394     AC_DEFINE(wxUSE_PRINTING_ARCHITECTURE)
6395     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS printing"
6396 fi
6397
6398 if test "$wxUSE_POSTSCRIPT" = "yes" ; then
6399   AC_DEFINE(wxUSE_POSTSCRIPT)
6400 fi
6401
6402 AC_DEFINE(wxUSE_AFM_FOR_POSTSCRIPT)
6403
6404 if test "$wxUSE_SVG" = "yes"; then
6405     AC_DEFINE(wxUSE_SVG)
6406 fi
6407
6408 dnl ---------------------------------------------------------------------------
6409 dnl wxMetafile availability
6410 dnl ---------------------------------------------------------------------------
6411
6412 if test "$wxUSE_METAFILE" = "yes"; then
6413     if test "$wxUSE_MSW" != 1 -a "$wxUSE_MAC" != 1 -a "$wxUSE_PM" != 1; then
6414         AC_MSG_WARN([wxMetafile is not available on this system... disabled])
6415         wxUSE_METAFILE=no
6416     fi
6417 fi
6418
6419 dnl ---------------------------------------------------------------------------
6420 dnl IPC: IPC, Drag'n'Drop, Clipboard, ...
6421 dnl ---------------------------------------------------------------------------
6422
6423 dnl check for ole headers and disable a few features requiring it if not
6424 dnl present (earlier versions of mingw32 don't have ole2.h)
6425 if test "$USE_WIN32" = 1 -a \( "$wxUSE_DATAOBJ"       = "yes" \
6426                           -o "$wxUSE_CLIPBOARD"     = "yes" \
6427                           -o "$wxUSE_OLE"     = "yes" \
6428                           -o "$wxUSE_DRAG_AND_DROP" = "yes" \) ; then
6429     AC_CHECK_HEADER(ole2.h,,, [ ])
6430
6431     if test "$ac_cv_header_ole2_h" = "yes" ; then
6432         if test "$GCC" = yes ; then
6433             AC_MSG_CHECKING([if g++ requires -fvtable-thunks])
6434             AC_TRY_COMPILE([#include <windows.h>
6435                             #include <ole2.h>],
6436                            [],
6437                            [AC_MSG_RESULT(no)],
6438                            [AC_MSG_RESULT(yes)
6439                             WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fvtable-thunks"])
6440             LIBS=" -lrpcrt4 -loleaut32 -lole32 -luuid$LIBS"
6441             if test "$wxUSE_OLE" = "yes" ; then
6442                 AC_DEFINE(wxUSE_OLE)
6443                 AC_DEFINE(wxUSE_OLE_AUTOMATION)
6444                 AC_DEFINE(wxUSE_ACTIVEX)
6445                 SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS oleauto"
6446             fi
6447         fi
6448
6449         dnl for OLE clipboard and dnd
6450         if test "$wxUSE_DATAOBJ" = "yes" ; then
6451             AC_DEFINE(wxUSE_DATAOBJ)
6452         fi
6453     else
6454         AC_MSG_WARN([Some features disabled because OLE headers not found])
6455
6456         wxUSE_CLIPBOARD=no
6457         wxUSE_DRAG_AND_DROP=no
6458         wxUSE_DATAOBJ=no
6459         wxUSE_OLE=no
6460     fi
6461
6462     if test "$wxUSE_METAFILE" = "yes"; then
6463         AC_DEFINE(wxUSE_METAFILE)
6464
6465         dnl this one should probably be made separately configurable
6466         AC_DEFINE(wxUSE_ENH_METAFILE)
6467     fi
6468 fi
6469
6470 if test "$wxUSE_IPC" = "yes"; then
6471     if test "$wxUSE_SOCKETS" != "yes" -a "$USE_WIN32" != 1; then
6472         AC_MSG_WARN(wxWidgets IPC classes require sockets... disabled)
6473         wxUSE_IPC=no
6474     fi
6475
6476     if test "$wxUSE_IPC" = "yes"; then
6477         AC_DEFINE(wxUSE_IPC)
6478         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ipc"
6479     fi
6480 fi
6481
6482 if test "$wxUSE_DATAOBJ" = "yes"; then
6483     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
6484         AC_MSG_WARN([wxDataObject not yet supported under $TOOLKIT... disabled])
6485         wxUSE_DATAOBJ=no
6486     else
6487         AC_DEFINE(wxUSE_DATAOBJ)
6488     fi
6489 else
6490     AC_MSG_WARN([Clipboard and drag-and-drop require wxDataObject -- disabled])
6491     wxUSE_CLIPBOARD=no
6492     wxUSE_DRAG_AND_DROP=no
6493 fi
6494
6495 if test "$wxUSE_CLIPBOARD" = "yes"; then
6496     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
6497         AC_MSG_WARN([Clipboard not yet supported under $TOOLKIT... disabled])
6498         wxUSE_CLIPBOARD=no
6499     fi
6500
6501     if test "$wxUSE_CLIPBOARD" = "yes"; then
6502         AC_DEFINE(wxUSE_CLIPBOARD)
6503     fi
6504 fi
6505
6506 if test "$wxUSE_DRAG_AND_DROP" = "yes" ; then
6507     if test "$wxUSE_GTK" = 1; then
6508         if test "$WXGTK12" != 1; then
6509             AC_MSG_WARN([Drag and drop is only supported under GTK+ 1.2... disabled])
6510             wxUSE_DRAG_AND_DROP=no
6511         fi
6512     fi
6513
6514     if test "$wxUSE_MOTIF" = 1 -o "$wxUSE_X11" = 1 -o "$wxUSE_MGL" = 1 -o \
6515             "$wxUSE_DFB" = 1; then
6516         AC_MSG_WARN([Drag and drop not yet supported under $TOOLKIT... disabled])
6517         wxUSE_DRAG_AND_DROP=no
6518     fi
6519
6520     if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
6521         AC_DEFINE(wxUSE_DRAG_AND_DROP)
6522     fi
6523
6524 fi
6525
6526 if test "$wxUSE_DRAG_AND_DROP" = "yes" -o "$wxUSE_CLIPBOARD" = "yes"; then
6527     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dnd"
6528 fi
6529
6530 if test "$wxUSE_CLIPBOARD" = "yes"; then
6531     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS clipboard"
6532 fi
6533
6534 if test "$wxUSE_SPLINES" = "yes" ; then
6535   AC_DEFINE(wxUSE_SPLINES)
6536 fi
6537
6538 if test "$wxUSE_MOUSEWHEEL" = "yes" ; then
6539   AC_DEFINE(wxUSE_MOUSEWHEEL)
6540 fi
6541
6542 dnl ---------------------------------------------------------------------------
6543 dnl GUI controls
6544 dnl ---------------------------------------------------------------------------
6545
6546 USES_CONTROLS=0
6547 if test "$wxUSE_CONTROLS" = "yes"; then
6548   USES_CONTROLS=1
6549 fi
6550
6551 if test "$wxUSE_ACCEL" = "yes"; then
6552   AC_DEFINE(wxUSE_ACCEL)
6553   USES_CONTROLS=1
6554 fi
6555
6556 if test "$wxUSE_ANIMATIONCTRL" = "yes"; then
6557   AC_DEFINE(wxUSE_ANIMATIONCTRL)
6558   USES_CONTROLS=1
6559   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS animate"
6560 fi
6561
6562 if test "$wxUSE_BUTTON" = "yes"; then
6563   AC_DEFINE(wxUSE_BUTTON)
6564   USES_CONTROLS=1
6565 fi
6566
6567 if test "$wxUSE_BMPBUTTON" = "yes"; then
6568   AC_DEFINE(wxUSE_BMPBUTTON)
6569   USES_CONTROLS=1
6570 fi
6571
6572 if test "$wxUSE_CALCTRL" = "yes"; then
6573   AC_DEFINE(wxUSE_CALENDARCTRL)
6574   USES_CONTROLS=1
6575   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS calendar"
6576 fi
6577
6578 if test "$wxUSE_CARET" = "yes"; then
6579   AC_DEFINE(wxUSE_CARET)
6580   USES_CONTROLS=1
6581   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS caret"
6582 fi
6583
6584 if test "$wxUSE_COLLPANE" = "yes"; then
6585     AC_DEFINE(wxUSE_COLLPANE)
6586     USES_CONTROLS=1
6587     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS collpane"
6588 fi
6589
6590 if test "$wxUSE_COMBOBOX" = "yes"; then
6591   AC_DEFINE(wxUSE_COMBOBOX)
6592   USES_CONTROLS=1
6593 fi
6594
6595 if test "$wxUSE_COMBOCTRL" = "yes"; then
6596   AC_DEFINE(wxUSE_COMBOCTRL)
6597   USES_CONTROLS=1
6598 fi
6599
6600 if test "$wxUSE_CHOICE" = "yes"; then
6601   AC_DEFINE(wxUSE_CHOICE)
6602   USES_CONTROLS=1
6603 fi
6604
6605 if test "$wxUSE_CHOICEBOOK" = "yes"; then
6606     AC_DEFINE(wxUSE_CHOICEBOOK)
6607     USES_CONTROLS=1
6608 fi
6609
6610 if test "$wxUSE_CHECKBOX" = "yes"; then
6611   AC_DEFINE(wxUSE_CHECKBOX)
6612   USES_CONTROLS=1
6613 fi
6614
6615 if test "$wxUSE_CHECKLST" = "yes"; then
6616   AC_DEFINE(wxUSE_CHECKLISTBOX)
6617   USES_CONTROLS=1
6618 fi
6619
6620 if test "$wxUSE_COLOURPICKERCTRL" = "yes"; then
6621   AC_DEFINE(wxUSE_COLOURPICKERCTRL)
6622   USES_CONTROLS=1
6623 fi
6624
6625 if test "$wxUSE_DATEPICKCTRL" = "yes"; then
6626   AC_DEFINE(wxUSE_DATEPICKCTRL)
6627   USES_CONTROLS=1
6628 fi
6629
6630 if test "$wxUSE_DIRPICKERCTRL" = "yes"; then
6631   AC_DEFINE(wxUSE_DIRPICKERCTRL)
6632   USES_CONTROLS=1
6633 fi
6634
6635 if test "$wxUSE_FILECTRL" = "yes"; then
6636   AC_DEFINE(wxUSE_FILECTRL)
6637   USES_CONTROLS=1
6638 fi
6639
6640 if test "$wxUSE_FILEPICKERCTRL" = "yes"; then
6641   AC_DEFINE(wxUSE_FILEPICKERCTRL)
6642   USES_CONTROLS=1
6643 fi
6644
6645 if test "$wxUSE_FONTPICKERCTRL" = "yes"; then
6646   AC_DEFINE(wxUSE_FONTPICKERCTRL)
6647   USES_CONTROLS=1
6648 fi
6649
6650 if test "$wxUSE_DISPLAY" = "yes"; then
6651     if test "$wxUSE_DFB" = 1 -o "$wxUSE_MGL" = 1; then
6652         AC_MSG_WARN([wxDisplay not yet supported under $TOOLKIT... disabled])
6653         wxUSE_DISPLAY=no
6654     else
6655         AC_DEFINE(wxUSE_DISPLAY)
6656         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS display"
6657     fi
6658 fi
6659
6660 if test "$wxUSE_DETECT_SM" = "yes"; then
6661     AC_DEFINE(wxUSE_DETECT_SM)
6662 fi
6663
6664 if test "$wxUSE_GAUGE" = "yes"; then
6665   AC_DEFINE(wxUSE_GAUGE)
6666   USES_CONTROLS=1
6667 fi
6668
6669 if test "$wxUSE_GRID" = "yes"; then
6670   AC_DEFINE(wxUSE_GRID)
6671   USES_CONTROLS=1
6672   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS grid"
6673 fi
6674
6675 if test "$wxUSE_HEADERCTRL" = "yes"; then
6676   AC_DEFINE(wxUSE_HEADERCTRL)
6677   USES_CONTROLS=1
6678 fi
6679
6680 if test "$wxUSE_HYPERLINKCTRL" = "yes"; then
6681   AC_DEFINE(wxUSE_HYPERLINKCTRL)
6682   USES_CONTROLS=1
6683 fi
6684
6685 if test "$wxUSE_BITMAPCOMBOBOX" = "yes"; then
6686   AC_DEFINE(wxUSE_BITMAPCOMBOBOX)
6687   USES_CONTROLS=1
6688 fi
6689
6690 if test "$wxUSE_DATAVIEWCTRL" = "yes"; then
6691   AC_DEFINE(wxUSE_DATAVIEWCTRL)
6692   USES_CONTROLS=1
6693   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dataview"
6694 fi
6695
6696 if test "$wxUSE_IMAGLIST" = "yes"; then
6697     AC_DEFINE(wxUSE_IMAGLIST)
6698 fi
6699
6700 if test "$wxUSE_INFOBAR" = "yes"; then
6701     AC_DEFINE(wxUSE_INFOBAR)
6702 fi
6703
6704 if test "$wxUSE_LISTBOOK" = "yes"; then
6705     AC_DEFINE(wxUSE_LISTBOOK)
6706     USES_CONTROLS=1
6707 fi
6708
6709 if test "$wxUSE_LISTBOX" = "yes"; then
6710     AC_DEFINE(wxUSE_LISTBOX)
6711     USES_CONTROLS=1
6712 fi
6713
6714 if test "$wxUSE_LISTCTRL" = "yes"; then
6715     if test "$wxUSE_IMAGLIST" = "yes"; then
6716         AC_DEFINE(wxUSE_LISTCTRL)
6717         USES_CONTROLS=1
6718         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS listctrl"
6719     else
6720         AC_MSG_WARN([wxListCtrl requires wxImageList and won't be compiled without it])
6721     fi
6722 fi
6723
6724 if test "$wxUSE_EDITABLELISTBOX" = "yes"; then
6725     AC_DEFINE(wxUSE_EDITABLELISTBOX)
6726     USES_CONTROLS=1
6727 fi
6728
6729 if test "$wxUSE_NOTEBOOK" = "yes"; then
6730     AC_DEFINE(wxUSE_NOTEBOOK)
6731     USES_CONTROLS=1
6732     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS notebook"
6733 fi
6734
6735 if test "$wxUSE_NOTIFICATION_MESSAGE" = "yes"; then
6736     AC_DEFINE(wxUSE_NOTIFICATION_MESSAGE)
6737 fi
6738
6739 if test "$wxUSE_ODCOMBOBOX" = "yes"; then
6740   AC_DEFINE(wxUSE_ODCOMBOBOX)
6741   USES_CONTROLS=1
6742   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS combo"
6743 fi
6744
6745 if test "$wxUSE_RADIOBOX" = "yes"; then
6746     AC_DEFINE(wxUSE_RADIOBOX)
6747     USES_CONTROLS=1
6748 fi
6749
6750 if test "$wxUSE_RADIOBTN" = "yes"; then
6751     AC_DEFINE(wxUSE_RADIOBTN)
6752     USES_CONTROLS=1
6753 fi
6754
6755 if test "$wxUSE_REARRANGECTRL" = "yes"; then
6756     AC_DEFINE(wxUSE_REARRANGECTRL)
6757 fi
6758
6759 if test "$wxUSE_SASH" = "yes"; then
6760     AC_DEFINE(wxUSE_SASH)
6761     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sashtest"
6762 fi
6763
6764 if test "$wxUSE_SCROLLBAR" = "yes"; then
6765     AC_DEFINE(wxUSE_SCROLLBAR)
6766     USES_CONTROLS=1
6767     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS scroll"
6768 fi
6769
6770 if test "$wxUSE_SEARCHCTRL" = "yes"; then
6771     AC_DEFINE(wxUSE_SEARCHCTRL)
6772     USES_CONTROLS=1
6773 fi
6774
6775 if test "$wxUSE_SLIDER" = "yes"; then
6776     AC_DEFINE(wxUSE_SLIDER)
6777     USES_CONTROLS=1
6778 fi
6779
6780 if test "$wxUSE_SPINBTN" = "yes"; then
6781     AC_DEFINE(wxUSE_SPINBTN)
6782     USES_CONTROLS=1
6783 fi
6784
6785 if test "$wxUSE_SPINCTRL" = "yes"; then
6786     AC_DEFINE(wxUSE_SPINCTRL)
6787     USES_CONTROLS=1
6788 fi
6789
6790 if test "$wxUSE_SPLITTER" = "yes"; then
6791     AC_DEFINE(wxUSE_SPLITTER)
6792     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splitter"
6793 fi
6794
6795 if test "$wxUSE_STATBMP" = "yes"; then
6796     AC_DEFINE(wxUSE_STATBMP)
6797     USES_CONTROLS=1
6798 fi
6799
6800 if test "$wxUSE_STATBOX" = "yes"; then
6801     AC_DEFINE(wxUSE_STATBOX)
6802     USES_CONTROLS=1
6803 fi
6804
6805 if test "$wxUSE_STATTEXT" = "yes"; then
6806     AC_DEFINE(wxUSE_STATTEXT)
6807     USES_CONTROLS=1
6808 fi
6809
6810 if test "$wxUSE_STATLINE" = "yes"; then
6811     AC_DEFINE(wxUSE_STATLINE)
6812     USES_CONTROLS=1
6813 fi
6814
6815 if test "$wxUSE_STATUSBAR" = "yes"; then
6816     dnl this will get undefined in wx/chkconf.h if it's not supported
6817     AC_DEFINE(wxUSE_NATIVE_STATUSBAR)
6818     AC_DEFINE(wxUSE_STATUSBAR)
6819     USES_CONTROLS=1
6820
6821     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS statbar"
6822 fi
6823
6824 if test "$wxUSE_TEXTCTRL" = "yes"; then
6825     AC_DEFINE(wxUSE_TEXTCTRL)
6826     USES_CONTROLS=1
6827     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS text"
6828
6829     dnl we don't have special switches to disable wxUSE_RICHEDIT[2], it doesn't
6830     dnl seem useful to allow disabling them
6831     AC_DEFINE(wxUSE_RICHEDIT)
6832     AC_DEFINE(wxUSE_RICHEDIT2)
6833 fi
6834
6835 if test "$wxUSE_TOGGLEBTN" = "yes"; then
6836     if test "$wxUSE_COCOA" = 1 ; then
6837         AC_MSG_WARN([Toggle button not yet supported under Mac OS X... disabled])
6838         wxUSE_TOGGLEBTN=no
6839     fi
6840
6841     if test "$wxUSE_TOGGLEBTN" = "yes"; then
6842         AC_DEFINE(wxUSE_TOGGLEBTN)
6843         USES_CONTROLS=1
6844     fi
6845 fi
6846
6847 if test "$wxUSE_TOOLBAR" = "yes"; then
6848     AC_DEFINE(wxUSE_TOOLBAR)
6849     USES_CONTROLS=1
6850
6851     if test "$wxUSE_UNIVERSAL" = "yes"; then
6852         wxUSE_TOOLBAR_NATIVE="no"
6853     else
6854         wxUSE_TOOLBAR_NATIVE="yes"
6855         AC_DEFINE(wxUSE_TOOLBAR_NATIVE)
6856     fi
6857
6858     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS toolbar"
6859 fi
6860
6861 if test "$wxUSE_TOOLTIPS" = "yes"; then
6862     if test "$wxUSE_MOTIF" = 1; then
6863         AC_MSG_WARN([wxTooltip not supported yet under Motif... disabled])
6864     else
6865         if test "$wxUSE_UNIVERSAL" = "yes"; then
6866             AC_MSG_WARN([wxTooltip not supported yet in wxUniversal... disabled])
6867         else
6868             AC_DEFINE(wxUSE_TOOLTIPS)
6869         fi
6870     fi
6871 fi
6872
6873 if test "$wxUSE_TREEBOOK" = "yes"; then
6874     AC_DEFINE(wxUSE_TREEBOOK)
6875     USES_CONTROLS=1
6876 fi
6877
6878 if test "$wxUSE_TOOLBOOK" = "yes"; then
6879     AC_DEFINE(wxUSE_TOOLBOOK)
6880     USES_CONTROLS=1
6881 fi
6882
6883 if test "$wxUSE_TREECTRL" = "yes"; then
6884     if test "$wxUSE_IMAGLIST" = "yes"; then
6885         AC_DEFINE(wxUSE_TREECTRL)
6886         USES_CONTROLS=1
6887         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS treectrl"
6888     else
6889         AC_MSG_WARN([wxTreeCtrl requires wxImageList and won't be compiled without it])
6890     fi
6891 fi
6892
6893 if test "$wxUSE_POPUPWIN" = "yes"; then
6894     if test "$wxUSE_COCOA" = 1 ; then
6895         AC_MSG_WARN([Popup window not yet supported under Mac OS X... disabled])
6896     else
6897         if test "$wxUSE_PM" = 1; then
6898             AC_MSG_WARN([wxPopupWindow not yet supported under PM... disabled])
6899         else
6900             AC_DEFINE(wxUSE_POPUPWIN)
6901             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS popup"
6902
6903             USES_CONTROLS=1
6904         fi
6905     fi
6906 fi
6907
6908 if test "$wxUSE_DIALUP_MANAGER" = "yes"; then
6909     if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1 -o "$wxUSE_MGL" = 1; then
6910         AC_MSG_WARN([Dialup manager not supported on this platform... disabled])
6911     else
6912         AC_DEFINE(wxUSE_DIALUP_MANAGER)
6913         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dialup"
6914     fi
6915 fi
6916
6917 if test "$wxUSE_TIPWINDOW" = "yes"; then
6918     if test "$wxUSE_PM" = 1; then
6919         AC_MSG_WARN([wxTipWindow not yet supported under PM... disabled])
6920     else
6921         AC_DEFINE(wxUSE_TIPWINDOW)
6922     fi
6923 fi
6924
6925 if test "$USES_CONTROLS" = 1; then
6926     AC_DEFINE(wxUSE_CONTROLS)
6927 fi
6928
6929 dnl ---------------------------------------------------------------------------
6930 dnl misc options
6931 dnl ---------------------------------------------------------------------------
6932
6933 dnl please keep the settings below in alphabetical order
6934 if test "$wxUSE_ACCESSIBILITY" = "yes"; then
6935     AC_DEFINE(wxUSE_ACCESSIBILITY)
6936     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS access"
6937 fi
6938
6939 if test "$wxUSE_DRAGIMAGE" = "yes"; then
6940     AC_DEFINE(wxUSE_DRAGIMAGE)
6941     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dragimag"
6942 fi
6943
6944 if test "$wxUSE_EXCEPTIONS" = "yes"; then
6945     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
6946         AC_MSG_WARN([--enable-exceptions can't be used with --enable-no_exceptions])
6947     else
6948         AC_DEFINE(wxUSE_EXCEPTIONS)
6949         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS except"
6950     fi
6951 fi
6952
6953 USE_HTML=0
6954 if test "$wxUSE_HTML" = "yes"; then
6955     AC_DEFINE(wxUSE_HTML)
6956     USE_HTML=1
6957     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html html/about html/help html/helpview html/printing html/test html/virtual html/widget html/zip htlbox"
6958 fi
6959 if test "$wxUSE_WEBKIT" = "yes"; then
6960     if test "$wxUSE_MAC" = 1 -a "$USE_DARWIN" = 1; then
6961         old_CPPFLAGS="$CPPFLAGS"
6962         CPPFLAGS="-x objective-c++ $CPPFLAGS"
6963         AC_CHECK_HEADER([WebKit/HIWebView.h],
6964                         [
6965                            AC_DEFINE(wxUSE_WEBKIT)
6966                            WEBKIT_LINK="-framework WebKit"
6967                         ],
6968                         [
6969                            AC_MSG_WARN([WebKit headers not found; disabling wxWebKit])
6970                            wxUSE_WEBKIT=no
6971                         ],
6972                         [
6973                            #include <Carbon/Carbon.h>
6974                            #include <WebKit/WebKit.h>
6975                         ])
6976         CPPFLAGS="$old_CPPFLAGS"
6977     elif test "$wxUSE_COCOA" = 1; then
6978         AC_DEFINE(wxUSE_WEBKIT)
6979     else
6980         wxUSE_WEBKIT=no
6981     fi
6982     if test "$wxUSE_WEBKIT" = "yes"; then
6983         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html/htmlctrl"
6984     fi
6985 fi
6986
6987 USE_XRC=0
6988 if test "$wxUSE_XRC" = "yes"; then
6989     if test "$wxUSE_XML" != "yes"; then
6990         AC_MSG_WARN([XML library not built, XRC resources disabled])
6991         wxUSE_XRC=no
6992     else
6993         AC_DEFINE(wxUSE_XRC)
6994         USE_XRC=1
6995         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS xrc"
6996     fi
6997 fi
6998
6999 USE_AUI=0
7000 if test "$wxUSE_AUI" = "yes"; then
7001    AC_DEFINE(wxUSE_AUI)
7002    USE_AUI=1
7003    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS aui"
7004 fi
7005
7006 USE_PROPGRID=0
7007 if test "$wxUSE_PROPGRID" = "yes"; then
7008    AC_DEFINE(wxUSE_PROPGRID)
7009    USE_PROPGRID=1
7010    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS propgrid"
7011 fi
7012
7013 USE_RIBBON=0
7014 if test "$wxUSE_RIBBON" = "yes"; then
7015    AC_DEFINE(wxUSE_RIBBON)
7016    USE_RIBBON=1
7017    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ribbon"
7018 fi
7019
7020 USE_STC=0
7021 if test "$wxUSE_STC" = "yes"; then
7022    AC_DEFINE(wxUSE_STC)
7023    USE_STC=1
7024    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS stc"
7025
7026    dnl python is used to update src/stc.h (see build/bakefiles/scintilla.bkl)
7027    AC_PATH_PROG(PYTHON, python)
7028    if test "x$PYTHON" = "x"; then
7029      COND_PYTHON="#"
7030    fi
7031    AC_SUBST(COND_PYTHON)
7032 fi
7033
7034 if test "$wxUSE_MENUS" = "yes"; then
7035     AC_DEFINE(wxUSE_MENUS)
7036     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS menu"
7037 fi
7038
7039 if test "$wxUSE_METAFILE" = "yes"; then
7040     AC_DEFINE(wxUSE_METAFILE)
7041 fi
7042
7043 if test "$wxUSE_MIMETYPE" = "yes"; then
7044     AC_DEFINE(wxUSE_MIMETYPE)
7045 fi
7046
7047 if test "$wxUSE_MINIFRAME" = "yes"; then
7048     AC_DEFINE(wxUSE_MINIFRAME)
7049 fi
7050
7051 if test "$wxUSE_SYSTEM_OPTIONS" = "yes"; then
7052     AC_DEFINE(wxUSE_SYSTEM_OPTIONS)
7053 fi
7054
7055 if test "$wxUSE_TASKBARICON" = "yes"; then
7056     AC_DEFINE(wxUSE_TASKBARICON)
7057     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS taskbar"
7058 fi
7059
7060
7061 if test "$wxUSE_VALIDATORS" = "yes"; then
7062     AC_DEFINE(wxUSE_VALIDATORS)
7063     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS validate"
7064 fi
7065
7066 if test "$wxUSE_PALETTE" = "yes" ; then
7067     if test "$wxUSE_DFB" = 1; then
7068         AC_MSG_WARN([wxPalette not yet supported under DFB... disabled])
7069         wxUSE_PALETTE=no
7070     else
7071         AC_DEFINE(wxUSE_PALETTE)
7072     fi
7073 fi
7074
7075 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_MSLU" = "yes" ; then
7076   dnl Must be done this late because -lunicows must be before all the other libs
7077   LIBS=" -lunicows $LIBS"
7078 fi
7079
7080 USE_RICHTEXT=0
7081 if test "$wxUSE_RICHTEXT" = "yes"; then
7082     AC_DEFINE(wxUSE_RICHTEXT)
7083     USE_RICHTEXT=1
7084     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS richtext"
7085 fi
7086
7087 dnl ---------------------------------------------------------------------------
7088 dnl wxImage options
7089 dnl ---------------------------------------------------------------------------
7090
7091 if test "$wxUSE_IMAGE" = "yes" ; then
7092     AC_DEFINE(wxUSE_IMAGE)
7093
7094     if test "$wxUSE_GIF" = "yes" ; then
7095       AC_DEFINE(wxUSE_GIF)
7096     fi
7097
7098     if test "$wxUSE_PCX" = "yes" ; then
7099       AC_DEFINE(wxUSE_PCX)
7100     fi
7101
7102     if test "$wxUSE_TGA" = "yes" ; then
7103       AC_DEFINE(wxUSE_TGA)
7104     fi
7105
7106     if test "$wxUSE_IFF" = "yes" ; then
7107       AC_DEFINE(wxUSE_IFF)
7108     fi
7109
7110     if test "$wxUSE_PNM" = "yes" ; then
7111       AC_DEFINE(wxUSE_PNM)
7112     fi
7113
7114     if test "$wxUSE_XPM" = "yes" ; then
7115       AC_DEFINE(wxUSE_XPM)
7116     fi
7117
7118     if test "$wxUSE_ICO_CUR" = "yes" ; then
7119       AC_DEFINE(wxUSE_ICO_CUR)
7120     fi
7121 fi
7122
7123 dnl ---------------------------------------------------------------------------
7124 dnl common dialogs
7125 dnl ---------------------------------------------------------------------------
7126
7127 if test "$wxUSE_ABOUTDLG" = "yes"; then
7128     AC_DEFINE(wxUSE_ABOUTDLG)
7129 fi
7130
7131 if test "$wxUSE_CHOICEDLG" = "yes"; then
7132     AC_DEFINE(wxUSE_CHOICEDLG)
7133 fi
7134
7135 if test "$wxUSE_COLOURDLG" = "yes"; then
7136     AC_DEFINE(wxUSE_COLOURDLG)
7137 fi
7138
7139 if test "$wxUSE_FILEDLG" = "yes"; then
7140     AC_DEFINE(wxUSE_FILEDLG)
7141 fi
7142
7143 if test "$wxUSE_FINDREPLDLG" = "yes"; then
7144     AC_DEFINE(wxUSE_FINDREPLDLG)
7145 fi
7146
7147 if test "$wxUSE_FONTDLG" = "yes"; then
7148     AC_DEFINE(wxUSE_FONTDLG)
7149 fi
7150
7151 if test "$wxUSE_DIRDLG" = "yes"; then
7152     if test "$wxUSE_TREECTRL" != "yes"; then
7153         AC_MSG_WARN(wxDirDialog requires wxTreeCtrl so it won't be compiled without it)
7154     else
7155         AC_DEFINE(wxUSE_DIRDLG)
7156     fi
7157 fi
7158
7159 if test "$wxUSE_MSGDLG" = "yes"; then
7160     AC_DEFINE(wxUSE_MSGDLG)
7161 fi
7162
7163 if test "$wxUSE_NUMBERDLG" = "yes"; then
7164     AC_DEFINE(wxUSE_NUMBERDLG)
7165 fi
7166
7167 if test "$wxUSE_PROGRESSDLG" = "yes"; then
7168     AC_DEFINE(wxUSE_PROGRESSDLG)
7169 fi
7170
7171 if test "$wxUSE_SPLASH" = "yes"; then
7172     AC_DEFINE(wxUSE_SPLASH)
7173     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splash"
7174 fi
7175
7176 if test "$wxUSE_STARTUP_TIPS" = "yes"; then
7177     AC_DEFINE(wxUSE_STARTUP_TIPS)
7178 fi
7179
7180 if test "$wxUSE_TEXTDLG" = "yes"; then
7181     AC_DEFINE(wxUSE_TEXTDLG)
7182 fi
7183
7184 if test "$wxUSE_WIZARDDLG" = "yes"; then
7185     AC_DEFINE(wxUSE_WIZARDDLG)
7186     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS wizard"
7187 fi
7188
7189 dnl ---------------------------------------------------------------------------
7190 dnl options used under wxMSW and wxPM
7191 dnl ---------------------------------------------------------------------------
7192
7193 if test "$wxUSE_MSW" = 1 -o "$wxUSE_PM" = 1; then
7194     if test "$wxUSE_OWNER_DRAWN" = "yes"; then
7195         AC_DEFINE(wxUSE_OWNER_DRAWN)
7196     fi
7197 fi
7198
7199 dnl ---------------------------------------------------------------------------
7200 dnl wxMSW-only options
7201 dnl ---------------------------------------------------------------------------
7202
7203 if test "$wxUSE_MSW" = 1 ; then
7204
7205     if test "$wxUSE_DC_CACHEING" = "yes"; then
7206         AC_DEFINE(wxUSE_DC_CACHEING)
7207     fi
7208
7209     if test "$wxUSE_DIB" = "yes"; then
7210         AC_DEFINE(wxUSE_WXDIB)
7211     fi
7212
7213     if test "$wxUSE_POSTSCRIPT_ARCHITECTURE_IN_MSW" = "yes"; then
7214         AC_DEFINE(wxUSE_POSTSCRIPT_ARCHITECTURE_IN_MSW)
7215     fi
7216
7217     if test "$wxUSE_UXTHEME" = "yes"; then
7218         AC_DEFINE(wxUSE_UXTHEME)
7219     fi
7220
7221 fi
7222 dnl wxUSE_MSW = 1
7223
7224 dnl not quite MSW-only although mostly useful to disable this under MSW
7225 if test "$wxUSE_AUTOID_MANAGEMENT" = "yes"; then
7226     AC_DEFINE(wxUSE_AUTOID_MANAGEMENT)
7227 fi
7228
7229 if test "$USE_WIN32" = 1 ; then
7230     if test "$wxUSE_INICONF" = "yes"; then
7231         AC_DEFINE(wxUSE_INICONF)
7232     fi
7233
7234     if test "$wxUSE_REGKEY" = "yes"; then
7235         AC_DEFINE(wxUSE_REGKEY)
7236     fi
7237 fi
7238 dnl USE_WIN32 = 1
7239
7240 dnl ---------------------------------------------------------------------------
7241 dnl wxGraphicsContext
7242 dnl ---------------------------------------------------------------------------
7243
7244 if test "$wxUSE_MAC" = 1; then
7245         wxUSE_GRAPHICS_CONTEXT="yes"
7246 fi
7247
7248 if test "$wxUSE_GRAPHICS_CONTEXT" = "yes"; then
7249    if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1; then
7250       AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)
7251    elif test "$wxUSE_GTK" != 1; then
7252       dnl for other builds we'll just wing it for now...
7253       AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)
7254    else
7255       dnl ...but let's check for cairo availability for wxGTK builds
7256       PKG_CHECK_MODULES(CAIRO, cairo,
7257           [AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)],
7258           [AC_MSG_WARN([Cairo library not found, unable to set wxUSE_GRAPHICS_CONTEXT])]
7259       )
7260    fi
7261 fi
7262
7263 dnl ---------------------------------------------------------------------------
7264 dnl wxMediaCtrl
7265 dnl ---------------------------------------------------------------------------
7266
7267 USE_MEDIA=0
7268
7269 if test "$wxUSE_MEDIACTRL" = "yes" -o "$wxUSE_MEDIACTRL" = "auto"; then
7270     USE_MEDIA=1
7271
7272     dnl -----------------------------------------------------------------------
7273     dnl GStreamer
7274     dnl -----------------------------------------------------------------------
7275     if test "$wxUSE_GTK" = 1; then
7276         wxUSE_GSTREAMER="no"
7277
7278         dnl -------------------------------------------------------------------
7279         dnl Test for at least 0.8 gstreamer module from pkg-config
7280         dnl Even totem doesn't accept 0.9 evidently.
7281         dnl
7282         dnl So, we first check to see if 0.10 if available - if not we
7283         dnl try the older 0.8 version
7284         dnl -------------------------------------------------------------------
7285         GST_VERSION_MAJOR=0
7286         GST_VERSION_MINOR=10
7287         GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
7288
7289         if test "$wxUSE_GSTREAMER8" = "no"; then
7290             PKG_CHECK_MODULES(GST,
7291                 [gstreamer-$GST_VERSION gstreamer-plugins-base-$GST_VERSION gconf-2.0],
7292                 [
7293                     wxUSE_GSTREAMER="yes"
7294                     GST_LIBS="$GST_LIBS -lgstinterfaces-$GST_VERSION"
7295                 ],
7296                 [
7297                     AC_MSG_WARN([GStreamer 0.10 not available, falling back to 0.8])
7298                     GST_VERSION_MINOR=8
7299                 ]
7300             )
7301         else
7302             dnl check only for 0.8
7303             GST_VERSION_MINOR=8
7304         fi
7305
7306         if test $GST_VERSION_MINOR = "8"; then
7307             GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
7308             PKG_CHECK_MODULES(GST,
7309                 [gstreamer-$GST_VERSION gstreamer-interfaces-$GST_VERSION gstreamer-gconf-$GST_VERSION],
7310                 wxUSE_GSTREAMER="yes",
7311                 [
7312                     AC_MSG_WARN([GStreamer 0.8/0.10 not available.])
7313                 ])
7314         fi
7315
7316
7317         if test "$wxUSE_GSTREAMER" = "yes"; then
7318             CPPFLAGS="$GST_CFLAGS $CPPFLAGS"
7319             EXTRALIBS_MEDIA="$GST_LIBS"
7320
7321             AC_DEFINE(wxUSE_GSTREAMER)
7322         else
7323             USE_MEDIA=0
7324         fi
7325     fi
7326
7327     if test $USE_MEDIA = 1; then
7328         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mediaplayer"
7329         AC_DEFINE(wxUSE_MEDIACTRL)
7330     else
7331         if test "$wxUSE_MEDIACTRL" = "yes"; then
7332             AC_MSG_ERROR([GStreamer not available])
7333         else
7334             dnl was set to 'auto'
7335             AC_MSG_WARN([GStreamer not available... disabling wxMediaCtrl])
7336         fi
7337     fi
7338 fi
7339
7340 dnl ---------------------------------------------------------------------------
7341 dnl get the string with OS info - used by wxGetOsDescription() on MacOS X
7342 dnl ---------------------------------------------------------------------------
7343
7344 if test "$cross_compiling" != "no"; then
7345     dnl Use best guess from host as we can't use uname when cross compiling
7346     OSINFO="\"$host\""
7347 else
7348     dnl attualy work out OS version
7349     OSINFO=`uname -s -r -m`
7350     OSINFO="\"$OSINFO\""
7351 fi
7352
7353 AC_DEFINE_UNQUOTED(WXWIN_OS_DESCRIPTION, $OSINFO)
7354
7355 dnl ---------------------------------------------------------------------------
7356 dnl define the variable containing the installation prefix (used in dcpsg.cpp)
7357 dnl ---------------------------------------------------------------------------
7358
7359 if test "x$prefix" != "xNONE"; then
7360     wxPREFIX=$prefix
7361 else
7362     wxPREFIX=$ac_default_prefix
7363 fi
7364
7365 AC_DEFINE_UNQUOTED(wxINSTALL_PREFIX, "$wxPREFIX")
7366
7367
7368 dnl ---------------------------------------------------------------------------
7369 dnl define variables with all built libraries for wx-config
7370 dnl ---------------------------------------------------------------------------
7371
7372 STD_BASE_LIBS="base"
7373 STD_GUI_LIBS=""
7374 BUILT_WX_LIBS="base"
7375 ALL_WX_LIBS="xrc stc gl media qa html adv core xml net base"
7376
7377 if test "$wxUSE_SOCKETS" = "yes" ; then
7378     STD_BASE_LIBS="net $STD_BASE_LIBS"
7379     BUILT_WX_LIBS="net $BUILT_WX_LIBS"
7380 fi
7381 if test "$wxUSE_XML" = "yes" ; then
7382     STD_BASE_LIBS="xml $STD_BASE_LIBS"
7383     BUILT_WX_LIBS="xml $BUILT_WX_LIBS"
7384 fi
7385
7386 if test "$wxUSE_GUI" = "yes"; then
7387     STD_GUI_LIBS="adv core"
7388     BUILT_WX_LIBS="$STD_GUI_LIBS $BUILT_WX_LIBS"
7389
7390     if test "$wxUSE_DEBUGREPORT" = "yes" ; then
7391         STD_GUI_LIBS="qa $STD_GUI_LIBS"
7392         BUILT_WX_LIBS="qa $BUILT_WX_LIBS"
7393     fi
7394     if test "$wxUSE_HTML" = "yes" ; then
7395         STD_GUI_LIBS="html $STD_GUI_LIBS"
7396         BUILT_WX_LIBS="html $BUILT_WX_LIBS"
7397     fi
7398     if test "$wxUSE_MEDIACTRL" = "yes" ; then
7399         BUILT_WX_LIBS="media $BUILT_WX_LIBS"
7400     fi
7401     if test "$wxUSE_OPENGL" = "yes" ; then
7402         BUILT_WX_LIBS="gl $BUILT_WX_LIBS"
7403     fi
7404     if test "$wxUSE_AUI" = "yes" ; then
7405         BUILT_WX_LIBS="aui $BUILT_WX_LIBS"
7406     fi
7407     if test "$wxUSE_PROPGRID" = "yes" ; then
7408         BUILT_WX_LIBS="propgrid $BUILT_WX_LIBS"
7409     fi
7410     if test "$wxUSE_RIBBON" = "yes" ; then
7411         BUILT_WX_LIBS="ribbon $BUILT_WX_LIBS"
7412     fi
7413     if test "$wxUSE_RICHTEXT" = "yes" ; then
7414         BUILT_WX_LIBS="richtext $BUILT_WX_LIBS"
7415     fi
7416     if test "$wxUSE_STC" = "yes" ; then
7417         BUILT_WX_LIBS="stc $BUILT_WX_LIBS"
7418     fi
7419     if test "$wxUSE_XRC" = "yes" ; then
7420         STD_GUI_LIBS="xrc $STD_GUI_LIBS"
7421         BUILT_WX_LIBS="xrc $BUILT_WX_LIBS"
7422     fi
7423 fi
7424
7425 AC_SUBST(ALL_WX_LIBS)
7426 AC_SUBST(BUILT_WX_LIBS)
7427 AC_SUBST(STD_BASE_LIBS)
7428 AC_SUBST(STD_GUI_LIBS)
7429
7430 dnl ---------------------------------------------------------------------------
7431 dnl Output the makefiles and such from the results found above
7432 dnl ---------------------------------------------------------------------------
7433
7434 dnl all additional libraries (except wxWidgets itself) we link with
7435
7436 if test "$wxUSE_MAC" = 1 ; then
7437     if test "$USE_DARWIN" = 1; then
7438         LDFLAGS="$LDFLAGS -framework IOKit -framework Carbon -framework Cocoa -framework AudioToolbox -framework System -framework OpenGL -framework QuickTime"
7439     fi
7440 fi
7441 if test "$wxUSE_COCOA" = 1 ; then
7442     LDFLAGS="$LDFLAGS -framework IOKit -framework Cocoa"
7443     if test "$wxUSE_MEDIACTRL" = "yes"; then
7444         LDFLAGS="$LDFLAGS -framework QuickTime"
7445     fi
7446 fi
7447 if test "$USE_DARWIN" = 1 -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1 ; then
7448     LDFLAGS="$LDFLAGS -framework IOKit -framework CoreServices -framework System -framework ApplicationServices"
7449 fi
7450
7451 LIBS="$ZLIB_LINK $POSIX4_LINK $INET_LINK $WCHAR_LINK $DL_LINK $LIBS"
7452
7453 if test "$wxUSE_GUI" = "yes"; then
7454
7455     dnl TODO add checks that these samples will really compile (i.e. all the
7456     dnl      library features they need are present)
7457
7458     dnl TODO some samples are never built so far: mfc (requires VC++)
7459     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS artprov controls dialogs drawing \
7460                      erase event exec font image minimal render \
7461                      shaped svg taborder vscroll widgets wrapsizer"
7462
7463     if test "$wxUSE_MONOLITHIC" != "yes"; then
7464         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS console"
7465     fi
7466     if test "$TOOLKIT" = "MSW"; then
7467         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS regtest"
7468         if test "$wxUSE_UNIVERSAL" != "yes"; then
7469             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ownerdrw nativdlg"
7470         fi
7471     fi
7472     if test "$TOOLKIT" = "PM" -a "$wxUSE_UNIVERSAL" != "yes"; then
7473         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ownerdrw"
7474     fi
7475 else
7476     SAMPLES_SUBDIRS="console"
7477     if test "$wxUSE_SOCKETS" = "yes" ; then
7478         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sockets"
7479     fi
7480     if test "$wxUSE_IPC" = "yes" ; then
7481         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ipc"
7482     fi
7483 fi
7484
7485
7486 dnl C/C++ compiler options used to compile wxWidgets
7487 dnl
7488 dnl check for icc before gcc as icc is also recognized as gcc
7489 if test "x$INTELCC" = "xyes" ; then
7490     dnl Warnings which can't be easily suppressed in C code are disabled:
7491     dnl
7492     dnl     #810: conversion from "x" to "y" may lose significant bits
7493     dnl     #869: parameter "foo" was never referenced
7494     dnl     #1572: floating-point equality and inequality comparisons
7495     dnl            are unreliable
7496     dnl     #1684: conversion from pointer to same-sized integral type
7497     dnl     #2259: non-pointer conversion from "x" to "y" may lose significant
7498     dnl            bits
7499     CWARNINGS="-Wall -wd810,869,981,1418,1572,1684,2259"
7500 elif test "$GCC" = yes ; then
7501     CWARNINGS="-Wall -Wundef"
7502 fi
7503
7504 if test "x$INTELCXX" = "xyes" ; then
7505     dnl Intel compiler gives some warnings which simply can't be worked
7506     dnl around or of which we have too many (810, 869) so it's impractical to
7507     dnl keep them enabled even if in theory it would be nice and some others
7508     dnl (279) are generated for standard macros and so there is nothing we can
7509     dnl do about them
7510     dnl
7511     dnl     #279: controlling expression is constant
7512     dnl     #383: value copied to temporary, reference to temporary used
7513     dnl     #444: destructor for base class "xxx" is not virtual
7514     dnl     #981: operands are evaluated in unspecified order
7515     dnl     #1418: external definition with no prior declaration
7516     dnl     #1419: external declaration in primary source file
7517     dnl     #1881: argument must be a constant null pointer value
7518     dnl
7519     dnl (for others see CWARNINGS above)
7520     CXXWARNINGS="-Wall -wd279,383,444,810,869,981,1418,1419,1881,2259"
7521 elif test "$GXX" = yes ; then
7522     CXXWARNINGS="-Wall -Wundef -Wunused-parameter -Wno-ctor-dtor-privacy"
7523     AX_CXXFLAGS_GCC_OPTION(-Woverloaded-virtual, CXXWARNINGS)
7524
7525     dnl when building under Mac we currently get hundreds of deprecation
7526     dnl warnings for Carbon symbols from the standard headers -- disable them
7527     dnl as we already know that they're deprecated and nothing else can be seen
7528     dnl with these warnings on
7529     if test "$wxUSE_MAC" = 1 ; then
7530         CXXWARNINGS="$CXXWARNINGS -Wno-deprecated-declarations"
7531     fi
7532 fi
7533
7534
7535 dnl combine everything together and remove the extra white space while doing it
7536 WXCONFIG_CFLAGS=`echo $WXCONFIG_CFLAGS`
7537 WXCONFIG_CXXFLAGS=`echo $WXCONFIG_CFLAGS $WXCONFIG_CXXFLAGS`
7538
7539
7540 dnl add -I options we use during library compilation
7541 dnl
7542 dnl note that the order is somewhat important: wxWidgets headers should
7543 dnl come first and the one with setup.h should be before $(top_srcdir)/include
7544 dnl in case the latter contains setup.h used by non-autoconf makefiles (e.g.
7545 dnl CodeWarrior):
7546 CPPFLAGS=`echo $WXCONFIG_CPPFLAGS \
7547  -I\\${wx_top_builddir}/lib/wx/include/${TOOLCHAIN_FULLNAME} \
7548  -I\\${top_srcdir}/include $TOOLKIT_INCLUDE \
7549  $CPPFLAGS `
7550
7551 C_AND_CXX_FLAGS="$DEBUG_CFLAGS $PROFILE_FLAGS $OPTIMISE_CFLAGS"
7552 CFLAGS=`echo $WXCONFIG_CFLAGS $CWARNINGS $C_AND_CXX_FLAGS $CFLAGS `
7553 CXXFLAGS=`echo $WXCONFIG_CXXFLAGS $C_AND_CXX_FLAGS $CXXFLAGS `
7554 OBJCFLAGS=`echo $WXCONFIG_CFLAGS $CWARNINGS $C_AND_CXX_FLAGS $OBJCFLAGS `
7555 OBJCXXFLAGS=`echo $WXCONFIG_CXXFLAGS $C_AND_CXX_FLAGS $OBJCXXFLAGS `
7556
7557 dnl now that we added WXCONFIG_CPPFLAGS to CPPFLAGS we can add the wx-config
7558 dnl only stuff to it
7559 WXCONFIG_CPPFLAGS=`echo $WXCONFIG_CPPFLAGS $WXCONFIG_ONLY_CPPFLAGS`
7560
7561
7562 if test "x$MWCC" = "xyes"; then
7563     dnl Correct MW 8.3 to be more similar to GCC.  In particular we
7564     dnl must use <regex.h> from system not our local copy on OS X,
7565     dnl but must use local not system on OS 9.
7566     dnl The following should make all -I paths usable for <> includes
7567     dnl while first checking in real system paths.  With 8.3 using
7568     dnl -gccincludes it will actually check local paths before system
7569     dnl even for <> which is totally wrong.
7570
7571     dnl Note that because this absolutely needs to be before any -I
7572     dnl that we have to tack it on to the end of the compiler commandline.
7573     CC="$CC -cwd source -I-"
7574     CXX="$CXX -cwd source -I-"
7575 fi
7576
7577
7578 LIBS=`echo $LIBS`
7579 EXTRALIBS="$LDFLAGS $LDFLAGS_VERSIONING $LIBS $DMALLOC_LIBS"
7580 EXTRALIBS_XML="$EXPAT_LINK"
7581 EXTRALIBS_HTML="$MSPACK_LINK"
7582 EXTRALIBS_MEDIA="$GST_LIBS"
7583 EXTRALIBS_STC="-lwxscintilla${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX}"
7584 if test "$wxUSE_GUI" = "yes"; then
7585     EXTRALIBS_GUI=`echo $GUI_TK_LIBRARY $PNG_LINK $JPEG_LINK $TIFF_LINK $WEBKIT_LINK $EXTRALIBS_HILDON $EXTRALIBS_GNOMEVFS $EXTRALIBS_GNOMEPRINT`
7586 fi
7587 if test "$wxUSE_OPENGL" = "yes"; then
7588     EXTRALIBS_OPENGL="$LDFLAGS_GL $OPENGL_LIBS"
7589 fi
7590
7591 LDFLAGS="$LDFLAGS $PROFILE_FLAGS"
7592
7593 WXCONFIG_LIBS="$LIBS"
7594
7595 dnl wx-config must output builtin 3rd party libs in --libs in static build:
7596 if test "$wxUSE_REGEX" = "builtin" ; then
7597     wxconfig_3rdparty="regex${lib_unicode_suffix} $wxconfig_3rdparty"
7598 fi
7599 if test "$wxUSE_EXPAT" = "builtin" ; then
7600     wxconfig_3rdparty="expat $wxconfig_3rdparty"
7601 fi
7602 if test "$wxUSE_LIBTIFF" = "builtin" ; then
7603     wxconfig_3rdparty="tiff $wxconfig_3rdparty"
7604 fi
7605 if test "$wxUSE_LIBJPEG" = "builtin" ; then
7606     wxconfig_3rdparty="jpeg $wxconfig_3rdparty"
7607 fi
7608 if test "$wxUSE_LIBPNG" = "builtin" ; then
7609     wxconfig_3rdparty="png $wxconfig_3rdparty"
7610 fi
7611 if test "$wxUSE_ZLIB" = "builtin" ; then
7612     wxconfig_3rdparty="zlib $wxconfig_3rdparty"
7613 fi
7614
7615 for i in $wxconfig_3rdparty ; do
7616     WXCONFIG_LIBS="-lwx${i}${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX} $WXCONFIG_LIBS"
7617 done
7618
7619
7620 if test "x$wxUSE_UNIVERSAL" = "xyes" ; then
7621     WXUNIV=1
7622
7623     case "$wxUNIV_THEMES" in
7624         ''|all)
7625             AC_DEFINE(wxUSE_ALL_THEMES)
7626             ;;
7627
7628         *)
7629             for t in `echo $wxUNIV_THEMES | tr , ' ' | tr '[[a-z]]' '[[A-Z]]'`; do
7630                 AC_DEFINE_UNQUOTED(wxUSE_THEME_$t)
7631             done
7632     esac
7633 else
7634     WXUNIV=0
7635 fi
7636
7637 AC_SUBST(wxUSE_ZLIB)
7638 AC_SUBST(wxUSE_REGEX)
7639 AC_SUBST(wxUSE_EXPAT)
7640 AC_SUBST(wxUSE_LIBJPEG)
7641 AC_SUBST(wxUSE_LIBPNG)
7642 AC_SUBST(wxUSE_LIBTIFF)
7643
7644 if test $wxUSE_MONOLITHIC = "yes" ; then
7645     MONOLITHIC=1
7646 else
7647     MONOLITHIC=0
7648 fi
7649
7650 if test $wxUSE_PLUGINS = "yes" ; then
7651     USE_PLUGINS=1
7652 else
7653     USE_PLUGINS=0
7654 fi
7655
7656 if test "$wxUSE_DEBUGREPORT" = "yes" ; then
7657     USE_QA=1
7658 else
7659     USE_QA=0
7660 fi
7661
7662 if test $wxUSE_OFFICIAL_BUILD = "yes" ; then
7663     OFFICIAL_BUILD=1
7664 else
7665     OFFICIAL_BUILD=0
7666 fi
7667
7668 AC_SUBST(VENDOR)
7669 AC_SUBST(OFFICIAL_BUILD)
7670 AC_SUBST(WX_FLAVOUR)
7671 AC_SUBST(WX_LIB_FLAVOUR)
7672
7673 AC_SUBST(WXUNIV)
7674 AC_SUBST(MONOLITHIC)
7675 AC_SUBST(USE_PLUGINS)
7676 AC_SUBST(LIBS)
7677 AC_SUBST(CXXWARNINGS)
7678 AC_SUBST(EXTRALIBS)
7679 AC_SUBST(EXTRALIBS_XML)
7680 AC_SUBST(EXTRALIBS_HTML)
7681 AC_SUBST(EXTRALIBS_MEDIA)
7682 AC_SUBST(EXTRALIBS_GUI)
7683 AC_SUBST(EXTRALIBS_OPENGL)
7684 AC_SUBST(EXTRALIBS_SDL)
7685 AC_SUBST(EXTRALIBS_STC)
7686 AC_SUBST(WITH_PLUGIN_SDL)
7687 AC_SUBST(EXTRALIBS_GTKPRINT)
7688 AC_SUBST(EXTRALIBS_GNOMEPRINT)
7689 AC_SUBST(EXTRALIBS_GNOMEVFS)
7690 AC_SUBST(EXTRALIBS_HILDON)
7691 AC_SUBST(UNICODE)
7692 AC_SUBST(DEBUG_INFO)
7693 AC_SUBST(DEBUG_FLAG)
7694 TOOLKIT_LOWERCASE=xxx
7695 if test "$TOOLKIT" = "MAC"; then
7696     TOOLKIT_LOWERCASE=osx_carbon
7697 fi
7698 if test "$TOOLKIT" = "OSX_CARBON"; then
7699     TOOLKIT_LOWERCASE=osx_carbon
7700 fi
7701 if test "$TOOLKIT" = "OSX_COCOA"; then
7702     TOOLKIT_LOWERCASE=osx_cocoa
7703 fi
7704 if test "$TOOLKIT_LOWERCASE" = "xxx"; then
7705     TOOLKIT_LOWERCASE=`echo $TOOLKIT | tr '[[A-Z]]' '[[a-z]]'`
7706 fi
7707 AC_SUBST(TOOLKIT_LOWERCASE)
7708 AC_SUBST(TOOLKIT_VERSION)
7709 AC_SUBST(DYLIB_RPATH_INSTALL)
7710 AC_SUBST(DYLIB_RPATH_POSTLINK)
7711 AC_SUBST(SAMPLES_RPATH_FLAG)
7712 AC_SUBST(HEADER_PAD_OPTION)
7713 AC_SUBST(HOST_SUFFIX)
7714 AC_SUBST(CPPUNIT_CFLAGS)
7715 AC_SUBST(CPPUNIT_LIBS)
7716
7717 case "$TOOLKIT" in
7718     GTK)
7719         TOOLKIT_DESC="GTK+"
7720         if test "$WXGTK2" = 1; then
7721             TOOLKIT_DESC="$TOOLKIT_DESC 2"
7722             if test "$wxUSE_GTKPRINT" = "yes" ; then
7723                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA GTK+ printing";
7724             fi
7725             if test "$wxUSE_LIBGNOMEPRINT" = "yes" ; then
7726                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA gnomeprint";
7727             fi
7728             if test "$wxUSE_LIBGNOMEVFS" = "yes" ; then
7729                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA gnomevfs"
7730             fi
7731             if test "$wxUSE_LIBHILDON" = "yes"; then
7732                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA hildon"
7733             fi
7734             if test "$wxUSE_LIBHILDON2" = "yes"; then
7735                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA hildon"
7736             fi
7737
7738             if test "$TOOLKIT_EXTRA" != ""; then
7739                 TOOLKIT_DESC="$TOOLKIT_DESC with support for `echo $TOOLKIT_EXTRA | tr -s ' '`"
7740             fi
7741         fi
7742         ;;
7743
7744     ?*)
7745         TOOLKIT_DESC=$TOOLKIT_LOWERCASE
7746         ;;
7747
7748     *)
7749         TOOLKIT_DESC="base only"
7750         ;;
7751 esac
7752
7753 if test "$wxUSE_WINE" = "yes"; then
7754     BAKEFILE_FORCE_PLATFORM=win32
7755 fi
7756
7757 dnl gcc 3.4 has a pch bug which truncates wide character constants in headers.
7758 dnl Hopefully for a non-unicode build there aren't any wide constants in
7759 dnl headers, but for a unicode build it's best to disable pch.
7760 if test "$wxUSE_UNICODE" = yes -a "$GCC" = yes -a "$bk_use_pch" != no
7761 then
7762     AC_CACHE_CHECK(
7763         [for gcc precompiled header bug],
7764         [wx_cv_gcc_pch_bug],
7765         [[
7766             echo '#include <stdio.h>
7767                   const wchar_t test_var[] = L"awidetest";' > conftest.h
7768
7769             echo '#include "conftest.h"
7770                   int main()
7771                   {
7772                      printf("%ls", test_var);
7773                      return 0;
7774                   }' > conftest.cpp
7775
7776             wx_cv_gcc_pch_bug="pch not supported"
7777
7778             if $CXX conftest.h >/dev/null 2>&1
7779             then
7780                 wx_cv_gcc_pch_bug=
7781
7782                 if $CXX -o conftest$PROGRAM_EXT conftest.cpp >/dev/null 2>&1
7783                 then
7784                     if tr -dc '[a-z]' < conftest$PROGRAM_EXT |
7785                         grep awidetest >/dev/null
7786                     then
7787                         wx_cv_gcc_pch_bug=no
7788                     else
7789                         wx_cv_gcc_pch_bug=yes
7790                     fi
7791                 fi
7792             fi
7793
7794             rm -f conftest.h conftest.gch conftest.cpp conftest$PROGRAM_EXT
7795         ]])
7796
7797     if test "$wx_cv_gcc_pch_bug" = yes; then
7798         dnl make the default for pch 'no'
7799         dnl further below check whether the user overrode and warn them
7800         bk_use_pch=no
7801     fi
7802 fi
7803
7804 AC_BAKEFILE([m4_include(autoconf_inc.m4)])
7805
7806 dnl make install path absolute (if not already);
7807 dnl will fail with (some) MSDOS paths
7808 case ${INSTALL} in
7809   /* ) # Absolute
7810      ;;
7811   ?:* ) # Drive letter, considered as absolute.
7812      ;;
7813   *)
7814      INSTALL=`pwd`/${INSTALL} ;;
7815 esac
7816
7817 if test "$wxUSE_GUI" = "yes"; then
7818
7819 if test "$wxUSE_MSW" = 1 ; then
7820     if test "x$WINDRES" = "x"; then
7821         AC_MSG_ERROR([Required windres program not found])
7822     fi
7823
7824     RESCOMP="$WINDRES"
7825 fi
7826
7827 if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1; then
7828     dnl base name of the resource file for wxMac must be the same
7829     dnl as library installation base name (-install_name)
7830     WX_RESOURCES_MACOSX_ASCII="libwx_${TOOLCHAIN_NAME}.${wx_release_number}.r"
7831     WX_RESOURCES_MACOSX_DATA="libwx_${TOOLCHAIN_NAME}.${wx_release_number}.rsrc"
7832
7833     dnl add the resources target for wxMac
7834     LIBWXMACRES="\$(wx_top_builddir)/lib/${WX_RESOURCES_MACOSX_ASCII}"
7835
7836     AC_CHECK_PROG(DEREZ, DeRez, DeRez, /Developer/Tools/DeRez)
7837
7838     MACSETFILE="\$(SETFILE)"
7839
7840     dnl resources are bundled both with shared library and applications
7841     dnl since the carb resource *must* be included in the application
7842     if test "$wxUSE_OSX_CARBON" = 1; then
7843         POSTLINK_COMMAND="\$(REZ) -d __DARWIN__ -t APPL Carbon.r -o"
7844         RESCOMP="$REZ"
7845         WXCONFIG_RESFLAGS="-d __DARWIN__ -t APPL Carbon.r -o"
7846     else
7847         POSTLINK_COMMAND="cat /dev/null | \$(REZ) -d __DARWIN__ -t APPL ${LIBWXMACRES}"
7848         RESCOMP="cat /dev/null \| $REZ"
7849         WXCONFIG_RESFLAGS="-d __DARWIN__ -t APPL \$libdir/$WX_RESOURCES_MACOSX_ASCII"
7850     fi
7851
7852 else
7853     dnl default value is to (silently) do nothing in the makefile
7854     MACSETFILE="@true"
7855
7856     if test "$wxUSE_PM" = 1; then
7857         RESCOMP="emxbind"
7858         WXCONFIG_RESFLAGS="-ep"
7859
7860         dnl Is this one really used anywhere for pm?
7861         POSTLINK_COMMAND="$RESCOMP $WXCONFIG_RESFLAGS"
7862     else
7863         POSTLINK_COMMAND="@true"
7864     fi
7865 fi
7866
7867 fi
7868 dnl wxUSE_GUI = 1
7869
7870
7871 dnl find out if the compiler supports PCH
7872 dnl
7873 dnl TODO: this should be in bakefile
7874 if test $GCC_PCH = 1
7875 then
7876     if test "$wx_cv_gcc_pch_bug" = yes; then
7877         AC_MSG_WARN([*** Precompiled header support is broken on this compiler])
7878         AC_MSG_WARN([*** --enable-precomp-headers is not recommended])
7879         AC_MSG_WARN([*** see http://gcc.gnu.org/bugzilla/show_bug.cgi?id=13361])
7880     fi
7881
7882     # Our WX_PRECOMP flag does not make sense for any language except C++ because
7883     # the headers that benefit from precompilation are mostly C++ headers.
7884     CXXFLAGS="-DWX_PRECOMP $CXXFLAGS"
7885     # When Bakefile can do multi-language PCH (e.g. C++ and Objective-C++) enable this:
7886     #OBJCXXFLAGS="-DWX_PRECOMP $CXXFLAGS"
7887 fi
7888
7889 dnl HACK ALERT!!
7890 dnl For now, we need to alter bk-deps not to generate deps
7891 dnl when we've configured a Universal binary build.
7892 dnl The next version of Bakefile will have the correct fix for this
7893 dnl at which time, this hack can be removed.
7894
7895 if test "$wxUSE_MAC" = 1 ; then
7896     if test "x$wxUSE_UNIVERSAL_BINARY" != "xno" ; then
7897         sed "s/DEPSMODE=gcc/DEPSMODE=none/" < bk-deps > temp
7898         mv temp bk-deps
7899         chmod +x bk-deps
7900     fi
7901 fi
7902
7903 if test "$wxUSE_SHARED" = "yes"; then
7904     dnl Need addtional flag on OS/2, so override bakefiles value
7905     dnl (there currently is no suitable variable to which the
7906     dnl  missing flags could be added, AFAICS. SN, 18.12.2004. )
7907     case "${host}" in
7908       *-pc-os2_emx | *-pc-os2-emx )
7909         SHARED_LD_CC="`pwd`/dllar.sh -name-mangler-script ./dllnames.sh -libf INITINSTANCE -libf TERMINSTANCE -o"
7910         SHARED_LD_CXX="`pwd`/dllar.sh -name-mangler-script ./dllnames.sh -libf INITINSTANCE -libf TERMINSTANCE -o"
7911         cp -p ${srcdir}/src/os2/dllnames.sh .
7912         cp -p ${srcdir}/src/os2/dllar.sh .
7913       ;;
7914     esac
7915 fi
7916 if test "$wxUSE_OMF" = "yes"; then
7917     case "${host}" in
7918       *-pc-os2_emx | *-pc-os2-emx )
7919         LDFLAGS="$LDFLAGS -Zlinker /EXEPACK"
7920         LDFLAGS_GUI="-Zlinker /PMTYPE:PM"
7921         WXCONFIG_LDFLAGS_GUI="-Zlinker /PMTYPE:PM"
7922       ;;
7923     esac
7924 fi
7925
7926 dnl TOOLCHAIN_DEFS should be used for both wx and client code
7927 WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS $TOOLCHAIN_DEFS"
7928
7929
7930 dnl Sun cc is compatible with gcc and so either of them can use the C
7931 dnl libraries built with the other, i.e. gcc can be used to build wxGTK under
7932 dnl Solaris where GTK+ is compiled using cc and cc can be used under Linux
7933 dnl where GTK+ is built with gcc
7934 dnl
7935 dnl However the compiler options are not compatible at all and in particular
7936 dnl gcc doesn't like cc -mt option and cc doesn't like -pthread. We simply
7937 dnl filter them out as we already have the correct options for multithreaded
7938 dnl programs if we're using threads (and if we don't, it shouldn't matter)
7939 case "${host}" in
7940     *-*-solaris2* )
7941         dnl system packages are compiled with Sun CC and so pkg-config outputs
7942         dnl CC-specific "-mt" flag, remove it when using gcc
7943         if test "$GCC" = yes; then
7944             CPPFLAGS=`echo $CPPFLAGS | sed 's/-mt//'`
7945             LIBS=`echo $LIBS | sed 's/-mt//'`
7946             EXTRALIBS_GUI=`echo $EXTRALIBS_GUI | sed 's/-mt//'`
7947         fi
7948         ;;
7949
7950     *-*-linux* )
7951         dnl OTOH when using Sun CC under Linux, the flags contain gcc-specific
7952         dnl -pthreads which Sun CC doesn't know about
7953         if test "x$SUNCXX" = xyes; then
7954             CPPFLAGS=`echo $CPPFLAGS | sed 's/-pthread//'`
7955             LIBS=`echo $LIBS | sed 's/-pthread//'`
7956             EXTRALIBS_GUI=`echo $EXTRALIBS_GUI | sed 's/-pthread//'`
7957         fi
7958         ;;
7959 esac
7960
7961 dnl Add visibility support flags to CFLAGS/CXXFLAGS - do it this late so that
7962 dnl it doesn't affect compilation checks above
7963 CFLAGS="$CFLAGS $CFLAGS_VISIBILITY"
7964 CXXFLAGS="$CXXFLAGS $CXXFLAGS_VISIBILITY"
7965 OBJCFLAGS="$OBJCFLAGS $CFLAGS_VISIBILITY"
7966 OBJCXXFLAGS="$OBJCXXFLAGS $CXXFLAGS_VISIBILITY"
7967
7968 dnl for convenience, sort the samples in alphabetical order
7969 dnl
7970 dnl FIXME For some mysterious reasons, sometimes the directories are duplicated
7971 dnl       in this list - hence uniq. But normally, this shouldn't be needed!
7972 dnl
7973 dnl       Unfortunately, there is a bug in OS/2's tr, such that
7974 dnl       tr ' ' '\n' introduces DOS-like line breaks, whereas tr '\n' ' '
7975 dnl       only removes the Unix-like part of the introduced line break.
7976 SAMPLES_SUBDIRS="`echo $SAMPLES_SUBDIRS | tr -s ' ' | tr ' ' '\n' | sort | uniq | tr '\n' ' '| tr -d '\r'`"
7977
7978 dnl subtle bakefile goop.
7979 dnl Used in wx-config now too, as its STATIC_FLAG with different makeup.
7980 dnl I wish we would have called it something less likely to clash with
7981 dnl things though.
7982 AC_SUBST(SHARED)
7983
7984 dnl global options
7985 AC_SUBST(WX_LIBRARY_BASENAME_NOGUI)
7986 AC_SUBST(WX_LIBRARY_BASENAME_GUI)
7987
7988 dnl toolkit options
7989 AC_SUBST(USE_GUI)
7990 AC_SUBST(AFMINSTALL)
7991 AC_SUBST(WIN32INSTALL)
7992 AC_SUBST(TOOLKIT)
7993 AC_SUBST(TOOLKIT_DIR)
7994 AC_SUBST(TOOLCHAIN_NAME)
7995 AC_SUBST(TOOLCHAIN_FULLNAME)
7996
7997 dnl wx-config options
7998 AC_SUBST(host_alias)
7999 AC_SUBST(cross_compiling)
8000 AC_SUBST(WIDGET_SET)
8001 AC_SUBST(WX_RELEASE)
8002 AC_SUBST(WX_VERSION)
8003 AC_SUBST(WX_SUBVERSION)
8004 AC_SUBST(WX_CHARTYPE)
8005
8006 dnl note that in addition to the usual CPP/C/CXXFLAGS which are used for
8007 dnl building the library itself, we also have WXCONFIG_-prefixed variants which
8008 dnl are used when building the libraries using the library
8009 dnl
8010 dnl so put anything which should be used only during the library build in, e.g.
8011 dnl CXXFLAGS, but put everything else (by default) into WXCONFIG_CXXFLAGS
8012 dnl
8013 dnl and, finally, for some things which should be only used by wx-config but
8014 dnl not during the library compilation, use WXCONFIG_ONLY_CPPFLAGS which is
8015 dnl added to WXCONFIG_CPPFLAGS after adding the latter to CPPFLAGS
8016 AC_SUBST(WXCONFIG_CPPFLAGS)
8017 AC_SUBST(WXCONFIG_CFLAGS)
8018 AC_SUBST(WXCONFIG_CXXFLAGS)
8019
8020 AC_SUBST(WXCONFIG_LIBS)
8021 AC_SUBST(WXCONFIG_RPATH)
8022 AC_SUBST(WXCONFIG_LDFLAGS_GUI)
8023 AC_SUBST(WXCONFIG_RESFLAGS)
8024
8025 dnl distribution vars
8026 AC_SUBST(GUIDIST)
8027 AC_SUBST(DISTDIR)
8028
8029 dnl additional subdirectories where we will build
8030 AC_SUBST(SAMPLES_SUBDIRS)
8031
8032 dnl additional libraries and linker settings
8033 AC_SUBST(LDFLAGS)
8034 AC_SUBST(LDFLAGS_GL)
8035 AC_SUBST(OPENGL_LIBS)
8036 AC_SUBST(DMALLOC_LIBS)
8037 AC_SUBST(WX_VERSION_TAG)
8038
8039 dnl additional resurces settings
8040 AC_SUBST(RESCOMP)
8041 AC_SUBST(WINDRES)
8042 AC_SUBST(REZ)
8043 AC_SUBST(RESFLAGS)
8044 AC_SUBST(RESPROGRAMOBJ)
8045 AC_SUBST(WX_RESOURCES_MACOSX_ASCII)
8046 AC_SUBST(WX_RESOURCES_MACOSX_DATA)
8047
8048 dnl additional for Mac OS X
8049 AC_SUBST(DEREZ)
8050 AC_SUBST(LIBWXMACRES)
8051 AC_SUBST(POSTLINK_COMMAND)
8052 AC_SUBST(MACSETFILE)
8053
8054 dnl other tools
8055 AC_SUBST(GCC)
8056 AC_SUBST(DLLTOOL)
8057
8058
8059 dnl MAKE_SET will be replaced with "MAKE=..." or nothing if make sets MAKE
8060 dnl itself (this macro is required if SUBDIRS variable is used in Makefile.am
8061 dnl - and we do use it)
8062 AC_PROG_MAKE_SET
8063
8064
8065 AC_CONFIG_HEADERS([lib/wx/include/${TOOLCHAIN_FULLNAME}/wx/setup.h:setup.h.in])
8066
8067 if test "$USE_WIN32" = 1; then
8068     AC_CONFIG_COMMANDS([rcdefs.h],
8069         [
8070             mkdir -p $outdir &&
8071             $CPP $infile | sed 's/^# *[1-9].*//;s/^ *//;/./,/^$/!d' > $outdir/rcdefs.h
8072         ],
8073         [
8074             CPP="$CPP"
8075             infile="$srcdir/include/wx/msw/genrcdefs.h"
8076             outdir="lib/wx/include/$TOOLCHAIN_FULLNAME/wx/msw"
8077         ]
8078     )
8079 fi
8080
8081 AC_CONFIG_FILES([ lib/wx/config/${TOOLCHAIN_FULLNAME}:wx-config.in ],
8082                 [ chmod +x lib/wx/config/${TOOLCHAIN_FULLNAME} ],
8083                 [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}" ])
8084
8085 AC_CONFIG_FILES([ lib/wx/config/inplace-${TOOLCHAIN_FULLNAME}:wx-config-inplace.in ],
8086                 [ chmod +x lib/wx/config/inplace-${TOOLCHAIN_FULLNAME} ],
8087                 [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}" ])
8088
8089 dnl this is used to run ifacecheck with the same flags used by the compiler
8090 dnl for the real compilation:
8091 AC_CONFIG_FILES([ utils/ifacecheck/rungccxml.sh ],
8092                 [ chmod +x utils/ifacecheck/rungccxml.sh ])
8093
8094 if test "$wx_cv_version_script" = "yes"; then
8095     AC_CONFIG_FILES(version-script)
8096 fi
8097 AC_CONFIG_FILES(Makefile)
8098
8099 AC_CONFIG_COMMANDS([wx-config],
8100                    [ rm -f wx-config
8101                      ${LN_S} lib/wx/config/inplace-${TOOLCHAIN_FULLNAME} wx-config
8102                    ],
8103                    [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}"
8104                      LN_S="${LN_S}"
8105                    ])
8106
8107 dnl This would give us us build dir that in every significant way
8108 dnl resembles an installed wx in prefix=$builddir.  It is troublesome
8109 dnl though in this form because AC_CONFIG_LINKS will fail for directories
8110 dnl on platforms that do not have symlinks.
8111 dnl AC_CONFIG_LINKS([ include/wx-$WX_RELEASE$WX_FLAVOUR:include ])
8112
8113 if test "$wxWITH_SUBDIRS" != "no"; then
8114 dnl Configure samples, demos etc. directories, but only if they are present:
8115 if test "$wxUSE_GUI" = "yes"; then
8116     SUBDIRS="samples demos utils"
8117 else
8118     dnl we build wxBase only
8119     dnl there are no wxBase programs in demos
8120     SUBDIRS="samples utils"
8121 fi
8122 dnl Add tests to the list of subdirs if cppunit 1.8.0+ is detected
8123 AM_PATH_CPPUNIT(1.8.0, [SUBDIRS="$SUBDIRS tests"])
8124
8125 for subdir in $SUBDIRS; do
8126     if test -d ${srcdir}/${subdir} ; then
8127         if test "$wxUSE_GUI" = "yes"; then
8128             if test ${subdir} = "samples"; then
8129                 dnl only take those samples which compile in the current
8130                 dnl configuration and which exist
8131                 makefiles="samples/Makefile.in $makefiles"
8132                 for sample in $SAMPLES_SUBDIRS; do
8133                     if test -d $srcdir/samples/$sample; then
8134                         makefiles="samples/$sample/Makefile.in $makefiles"
8135                     fi
8136                 done
8137             else
8138                 dnl assume that everything compiles for utils &c
8139                 dnl any that shouldn't be built can be added to
8140                 dnl DISABLED_UTILS, DISABLED_DEMOS
8141                 disabled_var=DISABLED_`echo $subdir | tr '[[a-z]]' '[[A-Z]]'`
8142                 eval "disabled=\$$disabled_var"
8143                 disabled=/`echo X $disabled | sed 's@ @/|/@g'`/
8144                 makefiles=`(cd $srcdir ; find $subdir -name Makefile.in) | $EGREP -v "$disabled"`
8145             fi
8146         else
8147             dnl we build wxBase only
8148             dnl don't take all samples/utils, just those which build with wxBase
8149             if test ${subdir} = "samples"; then
8150                 dnl only take those samples which compile in the current
8151                 dnl configuration and which exist
8152                 makefiles="samples/Makefile.in $makefiles"
8153                 for sample in `echo $SAMPLES_SUBDIRS`; do
8154                     if test -d $srcdir/samples/$sample; then
8155                         makefiles="samples/$sample/Makefile.in $makefiles"
8156                     fi
8157                 done
8158             elif test ${subdir} = "utils"; then
8159                 makefiles=""
8160                 for util in ifacecheck ; do
8161                     if test -d $srcdir/utils/$util ; then
8162                         makefiles="utils/$util/src/Makefile.in \
8163                                    $makefiles"
8164                     fi
8165                 done
8166             else
8167                 dnl assume that everything compiles for tests
8168                 makefiles=`(cd $srcdir ; find $subdir -name Makefile.in)`
8169             fi
8170         fi
8171
8172         for mkin in $makefiles ; do
8173             mk=`echo $mkin | sed 's/Makefile\.in/Makefile/g'`
8174             AC_CONFIG_FILES([$mk])
8175         done
8176     fi
8177 done
8178 fi dnl wxWITH_SUBDIRS
8179
8180 AC_OUTPUT
8181
8182 dnl report how we have been configured
8183 echo
8184 echo "Configured wxWidgets ${WX_VERSION} for \`${host}'"
8185 echo ""
8186 echo "  Which GUI toolkit should wxWidgets use?                 ${TOOLKIT_DESC}"
8187 echo "  Should wxWidgets be compiled into single library?       ${wxUSE_MONOLITHIC:-yes}"
8188 echo "  Should wxWidgets be linked as a shared library?         ${wxUSE_SHARED:-no}"
8189 echo $ECHO_N "  Should wxWidgets support Unicode?                       ${wxUSE_UNICODE:-no}$ECHO_C"
8190 if test "$wxUSE_UNICODE" = "yes"; then
8191     if test "$wxUSE_UNICODE_UTF8" = "yes"; then
8192         echo " (using UTF-8)"
8193     else
8194         echo " (using wchar_t)"
8195     fi
8196 else
8197     echo
8198 fi
8199
8200 echo "  What level of wxWidgets compatibility should be enabled?"
8201 echo "                                       wxWidgets 2.6      ${WXWIN_COMPATIBILITY_2_6:-no}"
8202 echo "                                       wxWidgets 2.8      ${WXWIN_COMPATIBILITY_2_8:-yes}"
8203
8204 echo "  Which libraries should wxWidgets use?"
8205 echo "                                       STL                ${wxUSE_STL}"
8206 echo "                                       jpeg               ${wxUSE_LIBJPEG-none}"
8207 echo "                                       png                ${wxUSE_LIBPNG-none}"
8208 echo "                                       regex              ${wxUSE_REGEX}"
8209 echo "                                       tiff               ${wxUSE_LIBTIFF-none}"
8210 if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
8211 echo "                                       xpm                ${wxUSE_LIBXPM-none}"
8212 fi
8213 echo "                                       zlib               ${wxUSE_ZLIB}"
8214 echo "                                       expat              ${wxUSE_EXPAT}"
8215 echo "                                       libmspack          ${wxUSE_LIBMSPACK}"
8216 echo "                                       sdl                ${wxUSE_LIBSDL}"
8217
8218 echo ""
8219
8220 dnl vi: set et sts=4 sw=4 com=\:dnl: