src/osx/cocoa/textctrl.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/textctrl.mm
   3 // Purpose:     wxTextCtrl
   4 // Author:      Stefan Csomor
   5 // Modified by: Ryan Norton (MLTE GetLineLength and GetLineText)
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: textctrl.cpp 54820 2008-07-29 20:04:11Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_TEXTCTRL
  15
  16 #include "wx/textctrl.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/intl.h"
  20     #include "wx/app.h"
  21     #include "wx/utils.h"
  22     #include "wx/dc.h"
  23     #include "wx/button.h"
  24     #include "wx/menu.h"
  25     #include "wx/settings.h"
  26     #include "wx/msgdlg.h"
  27     #include "wx/toplevel.h"
  28 #endif
  29
  30 #ifdef __DARWIN__
  31     #include <sys/types.h>
  32     #include <sys/stat.h>
  33 #else
  34     #include <stat.h>
  35 #endif
  36
  37 #if wxUSE_STD_IOSTREAM
  38     #if wxUSE_IOSTREAMH
  39         #include <fstream.h>
  40     #else
  41         #include <fstream>
  42     #endif
  43 #endif
  44
  45 #include "wx/filefn.h"
  46 #include "wx/sysopt.h"
  47 #include "wx/thread.h"
  48
  49 #include "wx/osx/private.h"
  50 #include "wx/osx/cocoa/private/textimpl.h"
  51
  52 @interface NSView(EditableView)
  53 - (BOOL)isEditable;
  54 - (void)setEditable:(BOOL)flag;
  55 @end
  56
  57 class wxMacEditHelper
  58 {
  59 public :
  60     wxMacEditHelper( NSView* textView )
  61     {
  62         m_textView = textView;
  63         m_formerState = YES;
  64         if ( textView )
  65         {
  66             m_formerState = [textView isEditable];
  67             [textView setEditable:YES];
  68         }
  69     }
  70
  71     ~wxMacEditHelper()
  72     {
  73         if ( m_textView )
  74             [m_textView setEditable:m_formerState];
  75     }
  76
  77 protected :
  78     BOOL m_formerState ;
  79     NSView* m_textView;
  80 } ;
  81
  82 @implementation wxNSSecureTextField
  83
  84 + (void)initialize
  85 {
  86     static BOOL initialized = NO;
  87     if (!initialized)
  88     {
  89         initialized = YES;
  90         wxOSXCocoaClassAddWXMethods( self );
  91     }
  92 }
  93
  94 - (void)controlTextDidChange:(NSNotification *)aNotification
  95 {
  96     wxUnusedVar(aNotification);
  97     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  98     if ( impl )
  99         impl->controlTextDidChange();
 100 }
 101
 102 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 103 {
 104     wxUnusedVar(aNotification);
 105     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 106     if ( impl )
 107     {
 108         impl->DoNotifyFocusEvent( false, NULL );
 109     }
 110 }
 111
 112 @end
 113
 114 @interface wxNSTextScrollView : NSScrollView
 115 {
 116 }
 117 @end
 118
 119 @implementation wxNSTextScrollView
 120
 121 + (void)initialize
 122 {
 123     static BOOL initialized = NO;
 124     if (!initialized)
 125     {
 126         initialized = YES;
 127         wxOSXCocoaClassAddWXMethods( self );
 128     }
 129 }
 130
 131 @end
 132
 133 @implementation wxNSTextFieldEditor
 134
 135 - (void) keyDown:(NSEvent*) event
 136 {
 137     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 138     lastKeyDownEvent = event;
 139     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 140         [super keyDown:event];
 141     lastKeyDownEvent = nil;
 142 }
 143
 144 - (void) keyUp:(NSEvent*) event
 145 {
 146     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 147     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 148         [super keyUp:event];
 149 }
 150
 151 - (void) flagsChanged:(NSEvent*) event
 152 {
 153     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 154     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 155         [super flagsChanged:event];
 156 }
 157
 158 - (BOOL) performKeyEquivalent:(NSEvent*) event
 159 {
 160     BOOL retval = [super performKeyEquivalent:event];
 161     return retval;
 162 }
 163
 164 - (void) insertText:(id) str
 165 {
 166     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 167     if ( impl == NULL || lastKeyDownEvent==nil || !impl->DoHandleCharEvent(lastKeyDownEvent, str) )
 168     {
 169         [super insertText:str];
 170     }
 171 }
 172
 173 @end
 174
 175 @implementation wxNSTextView
 176
 177 + (void)initialize
 178 {
 179     static BOOL initialized = NO;
 180     if (!initialized)
 181     {
 182         initialized = YES;
 183         wxOSXCocoaClassAddWXMethods( self );
 184     }
 185 }
 186
 187 - (void)textDidChange:(NSNotification *)aNotification
 188 {
 189     wxUnusedVar(aNotification);
 190     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 191     if ( impl )
 192         impl->controlTextDidChange();
 193 }
 194
 195 @end
 196
 197 @implementation wxNSTextField
 198
 199 + (void)initialize
 200 {
 201     static BOOL initialized = NO;
 202     if (!initialized)
 203     {
 204         initialized = YES;
 205         wxOSXCocoaClassAddWXMethods( self );
 206     }
 207 }
 208
 209 - (id) initWithFrame:(NSRect) frame
 210 {
 211     self = [super initWithFrame:frame];
 212     fieldEditor = nil;
 213     return self;
 214 }
 215
 216 - (void) dealloc
 217 {
 218     [fieldEditor release];
 219     [super dealloc];
 220 }
 221
 222 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
 223 {
 224     fieldEditor = editor;
 225 }
 226
 227 - (wxNSTextFieldEditor*) fieldEditor
 228 {
 229     return fieldEditor;
 230 }
 231
 232 - (void) setEnabled:(BOOL) flag
 233 {
 234     [super setEnabled: flag];
 235
 236     if (![self drawsBackground]) {
 237         // Static text is drawn incorrectly when disabled.
 238         // For an explanation, see
 239         // http://www.cocoabuilder.com/archive/message/cocoa/2006/7/21/168028
 240         if (flag) {
 241             [self setTextColor: [NSColor controlTextColor]];
 242         } else {
 243             [self setTextColor: [NSColor secondarySelectedControlColor]];
 244         }
 245     }
 246 }
 247
 248 - (void)controlTextDidChange:(NSNotification *)aNotification
 249 {
 250     wxUnusedVar(aNotification);
 251     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 252     if ( impl )
 253         impl->controlTextDidChange();
 254 }
 255
 256 typedef BOOL (*wxOSX_insertNewlineHandlerPtr)(NSView* self, SEL _cmd, NSControl *control, NSTextView* textView, SEL commandSelector);
 257
 258 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 259 {
 260     wxUnusedVar(textView);
 261     wxUnusedVar(control);
 262     if (commandSelector == @selector(insertNewline:))
 263     {
 264         wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 265         if ( impl  )
 266         {
 267             wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 268             if ( wxpeer && wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER )
 269             {
 270                 wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 271                 event.SetEventObject( wxpeer );
 272                 event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
 273                 wxpeer->HandleWindowEvent( event );
 274             }
 275         }
 276     }
 277
 278     return NO;
 279 }
 280
 281 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 282 {
 283     wxUnusedVar(aNotification);
 284     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 285     if ( impl )
 286     {
 287         impl->DoNotifyFocusEvent( false, NULL );
 288     }
 289 }
 290 @end
 291
 292 // wxNSTextViewControl
 293
 294 wxNSTextViewControl::wxNSTextViewControl( wxTextCtrl *wxPeer, WXWidget w ) : wxWidgetCocoaImpl(wxPeer, w)
 295 {
 296     wxNSTextScrollView* sv = (wxNSTextScrollView*) w;
 297     m_scrollView = sv;
 298
 299     [m_scrollView setHasVerticalScroller:YES];
 300     [m_scrollView setHasHorizontalScroller:NO];
 301     [m_scrollView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
 302     NSSize contentSize = [m_scrollView contentSize];
 303
 304     wxNSTextView* tv = [[wxNSTextView alloc] initWithFrame: NSMakeRect(0, 0,
 305             contentSize.width, contentSize.height)];
 306     m_textView = tv;
 307     [tv setVerticallyResizable:YES];
 308     [tv setHorizontallyResizable:NO];
 309     [tv setAutoresizingMask:NSViewWidthSizable];
 310
 311     [m_scrollView setDocumentView: tv];
 312
 313     [tv setDelegate: tv];
 314
 315     InstallEventHandler(tv);
 316 }
 317
 318 wxNSTextViewControl::~wxNSTextViewControl()
 319 {
 320     if (m_textView)
 321         [m_textView setDelegate: nil];
 322 }
 323
 324 bool wxNSTextViewControl::CanFocus() const
 325 {
 326     // we need to override so that we don't return the CanFocus value of
 327     // the text view's overriding scroll view.
 328     if (m_textView)
 329         return [m_textView canBecomeKeyView];
 330     return false;
 331 }
 332
 333 wxString wxNSTextViewControl::GetStringValue() const
 334 {
 335     if (m_textView)
 336     {
 337         wxString result = wxCFStringRef::AsString([m_textView string], m_wxPeer->GetFont().GetEncoding());
 338         wxMacConvertNewlines13To10( &result ) ;
 339         return result;
 340     }
 341     return wxEmptyString;
 342 }
 343 void wxNSTextViewControl::SetStringValue( const wxString &str)
 344 {
 345     wxString st = str;
 346     wxMacConvertNewlines10To13( &st );
 347     wxMacEditHelper helper(m_textView);
 348
 349     if (m_textView)
 350         [m_textView setString: wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 351 }
 352
 353 void wxNSTextViewControl::Copy()
 354 {
 355     if (m_textView)
 356         [m_textView copy:nil];
 357
 358 }
 359
 360 void wxNSTextViewControl::Cut()
 361 {
 362     if (m_textView)
 363         [m_textView cut:nil];
 364 }
 365
 366 void wxNSTextViewControl::Paste()
 367 {
 368     if (m_textView)
 369         [m_textView paste:nil];
 370 }
 371
 372 bool wxNSTextViewControl::CanPaste() const
 373 {
 374     return true;
 375 }
 376
 377 void wxNSTextViewControl::SetEditable(bool editable)
 378 {
 379     if (m_textView)
 380         [m_textView setEditable: editable];
 381 }
 382
 383 void wxNSTextViewControl::GetSelection( long* from, long* to) const
 384 {
 385     if (m_textView)
 386     {
 387         NSRange range = [m_textView selectedRange];
 388         *from = range.location;
 389         *to = range.location + range.length;
 390     }
 391 }
 392
 393 void wxNSTextViewControl::SetSelection( long from , long to )
 394 {
 395     long textLength = [[m_textView string] length];
 396     if ((from == -1) && (to == -1))
 397     {
 398         from = 0 ;
 399         to = textLength ;
 400     }
 401     else
 402     {
 403         from = wxMin(textLength,wxMax(from,0)) ;
 404         if ( to == -1 )
 405             to = textLength;
 406         else
 407             to = wxMax(0,wxMin(textLength,to)) ;
 408     }
 409
 410     NSRange selrange = NSMakeRange(from, to-from);
 411     [m_textView setSelectedRange:selrange];
 412     [m_textView scrollRangeToVisible:selrange];
 413 }
 414
 415 void wxNSTextViewControl::WriteText(const wxString& str)
 416 {
 417     wxString st = str;
 418     wxMacConvertNewlines10To13( &st );
 419     wxMacEditHelper helper(m_textView);
 420     NSEvent* formerEvent = m_lastKeyDownEvent;
 421     m_lastKeyDownEvent = nil;
 422     [m_textView insertText:wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 423     m_lastKeyDownEvent = formerEvent;
 424 }
 425
 426 void wxNSTextViewControl::SetFont( const wxFont & font , const wxColour& WXUNUSED(foreground) , long WXUNUSED(windowStyle), bool WXUNUSED(ignoreBlack) )
 427 {
 428     if ([m_textView respondsToSelector:@selector(setFont:)])
 429         [m_textView setFont: font.OSXGetNSFont()];
 430 }
 431
 432 bool wxNSTextViewControl::GetStyle(long position, wxTextAttr& style)
 433 {
 434     if (m_textView && position >=0)
 435     {
 436         NSFont* font = NULL;
 437         NSColor* bgcolor = NULL;
 438         NSColor* fgcolor = NULL;
 439         // NOTE: It appears that other platforms accept GetStyle with the position == length
 440         // but that NSTextStorage does not accept length as a valid position.
 441         // Therefore we return the default control style in that case.
 442         if (position < [[m_textView string] length])
 443         {
 444             NSTextStorage* storage = [m_textView textStorage];
 445             font = [[storage attribute:NSFontAttributeName atIndex:position effectiveRange:NULL] autorelease];
 446             bgcolor = [[storage attribute:NSBackgroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 447             fgcolor = [[storage attribute:NSForegroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 448         }
 449         else
 450         {
 451             NSDictionary* attrs = [m_textView typingAttributes];
 452             font = [[attrs objectForKey:NSFontAttributeName] autorelease];
 453             bgcolor = [[attrs objectForKey:NSBackgroundColorAttributeName] autorelease];
 454             fgcolor = [[attrs objectForKey:NSForegroundColorAttributeName] autorelease];
 455         }
 456
 457         if (font)
 458             style.SetFont(wxFont(font));
 459
 460         if (bgcolor)
 461             style.SetBackgroundColour(wxColour(bgcolor));
 462
 463         if (fgcolor)
 464             style.SetTextColour(wxColour(fgcolor));
 465         return true;
 466     }
 467
 468     return false;
 469 }
 470
 471 void wxNSTextViewControl::SetStyle(long start,
 472                                 long end,
 473                                 const wxTextAttr& style)
 474 {
 475     if (m_textView) {
 476         NSRange range = NSMakeRange(start, end-start);
 477         if (start == -1 && end == -1)
 478             range = [m_textView selectedRange];
 479
 480         NSTextStorage* storage = [m_textView textStorage];
 481
 482         wxFont font = style.GetFont();
 483         if (style.HasFont() && font.IsOk())
 484             [storage addAttribute:NSFontAttributeName value:font.OSXGetNSFont() range:range];
 485
 486         wxColour bgcolor = style.GetBackgroundColour();
 487         if (style.HasBackgroundColour() && bgcolor.IsOk())
 488             [storage addAttribute:NSBackgroundColorAttributeName value:bgcolor.OSXGetNSColor() range:range];
 489
 490         wxColour fgcolor = style.GetTextColour();
 491         if (style.HasTextColour() && fgcolor.IsOk())
 492             [storage addAttribute:NSForegroundColorAttributeName value:fgcolor.OSXGetNSColor() range:range];
 493     }
 494 }
 495
 496 void wxNSTextViewControl::CheckSpelling(bool check)
 497 {
 498     if (m_textView)
 499         [m_textView setContinuousSpellCheckingEnabled: check];
 500 }
 501
 502 wxSize wxNSTextViewControl::GetBestSize() const
 503 {
 504     if (m_textView && [m_textView layoutManager])
 505     {
 506         NSRect rect = [[m_textView layoutManager] usedRectForTextContainer: [m_textView textContainer]];
 507         wxSize size = wxSize(rect.size.width, rect.size.height);
 508         size.x += [m_textView textContainerInset].width;
 509         size.y += [m_textView textContainerInset].height;
 510         return size;
 511     }
 512     return wxSize(0,0);
 513 }
 514
 515 // wxNSTextFieldControl
 516
 517 wxNSTextFieldControl::wxNSTextFieldControl( wxWindow *wxPeer, WXWidget w ) : wxWidgetCocoaImpl(wxPeer, w)
 518 {
 519     NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>) *tf = (NSTextField*) w;
 520     m_textField = tf;
 521     [m_textField setDelegate: tf];
 522     m_selStart = m_selEnd = 0;
 523     m_hasEditor = [w isKindOfClass:[NSTextField class]];
 524 }
 525
 526 wxNSTextFieldControl::~wxNSTextFieldControl()
 527 {
 528     if (m_textField)
 529         [m_textField setDelegate: nil];
 530 }
 531
 532 wxString wxNSTextFieldControl::GetStringValue() const
 533 {
 534     return wxCFStringRef::AsString([m_textField stringValue], m_wxPeer->GetFont().GetEncoding());
 535 }
 536
 537 void wxNSTextFieldControl::SetStringValue( const wxString &str)
 538 {
 539     wxMacEditHelper helper(m_textField);
 540     [m_textField setStringValue: wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 541 }
 542
 543 void wxNSTextFieldControl::Copy()
 544 {
 545     NSText* editor = [m_textField currentEditor];
 546     if ( editor )
 547     {
 548         [editor copy:nil];
 549     }
 550 }
 551
 552 void wxNSTextFieldControl::Cut()
 553 {
 554     NSText* editor = [m_textField currentEditor];
 555     if ( editor )
 556     {
 557         [editor cut:nil];
 558     }
 559 }
 560
 561 void wxNSTextFieldControl::Paste()
 562 {
 563     NSText* editor = [m_textField currentEditor];
 564     if ( editor )
 565     {
 566         [editor paste:nil];
 567     }
 568 }
 569
 570 bool wxNSTextFieldControl::CanPaste() const
 571 {
 572     return true;
 573 }
 574
 575 void wxNSTextFieldControl::SetEditable(bool editable)
 576 {
 577     [m_textField setEditable:editable];
 578 }
 579
 580 void wxNSTextFieldControl::GetSelection( long* from, long* to) const
 581 {
 582     NSText* editor = [m_textField currentEditor];
 583     if ( editor )
 584     {
 585         NSRange range = [editor selectedRange];
 586         *from = range.location;
 587         *to = range.location + range.length;
 588     }
 589     else
 590     {
 591         *from = m_selStart;
 592         *to = m_selEnd;
 593     }
 594 }
 595
 596 void wxNSTextFieldControl::SetSelection( long from , long to )
 597 {
 598     long textLength = [[m_textField stringValue] length];
 599     if ((from == -1) && (to == -1))
 600     {
 601         from = 0 ;
 602         to = textLength ;
 603     }
 604     else
 605     {
 606         from = wxMin(textLength,wxMax(from,0)) ;
 607         if ( to == -1 )
 608             to = textLength;
 609         else
 610             to = wxMax(0,wxMin(textLength,to)) ;
 611     }
 612
 613     NSText* editor = [m_textField currentEditor];
 614     if ( editor )
 615     {
 616         [editor setSelectedRange:NSMakeRange(from, to-from)];
 617     }
 618     else
 619     {
 620         m_selStart = from;
 621         m_selEnd = to;
 622     }
 623 }
 624
 625 void wxNSTextFieldControl::WriteText(const wxString& str)
 626 {
 627     NSEvent* formerEvent = m_lastKeyDownEvent;
 628     m_lastKeyDownEvent = nil;
 629     NSText* editor = [m_textField currentEditor];
 630     if ( editor )
 631     {
 632         wxMacEditHelper helper(m_textField);
 633         [editor insertText:wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 634     }
 635     else
 636     {
 637         wxString val = GetStringValue() ;
 638         long start , end ;
 639         GetSelection( &start , &end ) ;
 640         val.Remove( start , end - start ) ;
 641         val.insert( start , str ) ;
 642         SetStringValue( val ) ;
 643         SetSelection( start + str.length() , start + str.length() ) ;
 644     }
 645     m_lastKeyDownEvent = formerEvent;
 646 }
 647
 648 void wxNSTextFieldControl::controlAction(WXWidget WXUNUSED(slf),
 649     void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 650 {
 651     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
 652     if ( wxpeer && (wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER) )
 653     {
 654         wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 655         event.SetEventObject( wxpeer );
 656         event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
 657         wxpeer->HandleWindowEvent( event );
 658     }
 659 }
 660
 661 //
 662 //
 663 //
 664
 665 wxWidgetImplType* wxWidgetImpl::CreateTextControl( wxTextCtrl* wxpeer,
 666                                     wxWindowMac* WXUNUSED(parent),
 667                                     wxWindowID WXUNUSED(id),
 668                                     const wxString& WXUNUSED(str),
 669                                     const wxPoint& pos,
 670                                     const wxSize& size,
 671                                     long style,
 672                                     long WXUNUSED(extraStyle))
 673 {
 674     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 675     wxWidgetCocoaImpl* c = NULL;
 676
 677     if ( style & wxTE_MULTILINE || style & wxTE_RICH || style & wxTE_RICH2 )
 678     {
 679         wxNSTextScrollView* v = nil;
 680         v = [[wxNSTextScrollView alloc] initWithFrame:r];
 681         c = new wxNSTextViewControl( wxpeer, v );
 682     }
 683     else
 684     {
 685         NSTextField* v = nil;
 686         if ( style & wxTE_PASSWORD )
 687             v = [[wxNSSecureTextField alloc] initWithFrame:r];
 688         else
 689             v = [[wxNSTextField alloc] initWithFrame:r];
 690
 691         if ( style & wxNO_BORDER )
 692         {
 693             // FIXME: How can we remove the native control's border?
 694             // setBordered is separate from the text ctrl's border.
 695         }
 696
 697         [v setBezeled:NO];
 698         [v setBordered:NO];
 699
 700         c = new wxNSTextFieldControl( wxpeer, v );
 701     }
 702
 703     return c;
 704 }
 705
 706
 707 #endif // wxUSE_TEXTCTRL