build/autoconf_prepend-include/autoconf/general.m4

   1 # This file is part of Autoconf.                       -*- Autoconf -*-
   2 # Parameterized macros.
   3 # Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 # As a special exception, the Free Software Foundation gives unlimited
  22 # permission to copy, distribute and modify the configure scripts that
  23 # are the output of Autoconf.  You need not follow the terms of the GNU
  24 # General Public License when using or distributing such scripts, even
  25 # though portions of the text of Autoconf appear in them.  The GNU
  26 # General Public License (GPL) does govern all other use of the material
  27 # that constitutes the Autoconf program.
  28 #
  29 # Certain portions of the Autoconf source text are designed to be copied
  30 # (in certain cases, depending on the input) into the output of
  31 # Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  32 # source text consists of comments plus executable code that decides which
  33 # of the data portions to output in any given case.  We call these
  34 # comments and executable code the "non-data" portions.  Autoconf never
  35 # copies any of the non-data portions into its output.
  36 #
  37 # This special exception to the GPL applies to versions of Autoconf
  38 # released by the Free Software Foundation.  When you make and
  39 # distribute a modified version of Autoconf, you may extend this special
  40 # exception to the GPL to apply to your modified version as well, *unless*
  41 # your modified version has the potential to copy into its output some
  42 # of the text that was the non-data portion of the version that you started
  43 # with.  (In other words, unless your change moves or copies text from
  44 # the non-data portions to the data portions.)  If your modification has
  45 # such potential, you must delete any notice of this special exception
  46 # to the GPL from your modified version.
  47 #
  48 # Written by David MacKenzie, with help from
  49 # Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  50 # Roland McGrath, Noah Friedman, david d zuhn, and many others.
  51
  52
  53 ## ---------------- ##
  54 ## The diversions.  ##
  55 ## ---------------- ##
  56
  57
  58 # We heavily use m4's diversions both for the initializations and for
  59 # required macros (see AC_REQUIRE), because in both cases we have to
  60 # issue high in `configure' something which is discovered late.
  61 #
  62 # KILL is only used to suppress output.
  63 #
  64 # The layers of `configure'.  We let m4 undivert them by itself, when
  65 # it reaches the end of `configure.ac'.
  66 #
  67 # - BINSH
  68 #   #! /bin/sh
  69 # - HEADER-REVISION
  70 #   Sent by AC_REVISION
  71 # - HEADER-COMMENT
  72 #   Purpose of the script.
  73 # - HEADER-COPYRIGHT
  74 #   Copyright notice(s)
  75 # - M4SH-INIT
  76 #   Initialization of bottom layers.
  77 #
  78 # - DEFAULTS
  79 #   early initializations (defaults)
  80 # - PARSE_ARGS
  81 #   initialization code, option handling loop.
  82 #
  83 # - HELP_BEGIN
  84 #   Handling `configure --help'.
  85 # - HELP_CANON
  86 #   Help msg for AC_CANONICAL_*
  87 # - HELP_ENABLE
  88 #   Help msg from AC_ARG_ENABLE.
  89 # - HELP_WITH
  90 #   Help msg from AC_ARG_WITH.
  91 # - HELP_VAR
  92 #   Help msg from AC_ARG_VAR.
  93 # - HELP_VAR_END
  94 #   A small paragraph on the use of the variables.
  95 # - HELP_END
  96 #   Tail of the handling of --help.
  97 #
  98 # - VERSION_BEGIN
  99 #   Head of the handling of --version.
 100 # - VERSION_FSF
 101 #   FSF copyright notice for --version.
 102 # - VERSION_USER
 103 #   User copyright notice for --version.
 104 # - VERSION_END
 105 #   Tail of the handling of --version.
 106 #
 107 # - INIT_PREPARE
 108 #   Tail of initialization code.
 109 #
 110 # - BODY
 111 #   the tests and output code
 112 #
 113
 114
 115 # _m4_divert(DIVERSION-NAME)
 116 # --------------------------
 117 # Convert a diversion name into its number.  Otherwise, return
 118 # DIVERSION-NAME which is supposed to be an actual diversion number.
 119 # Of course it would be nicer to use m4_case here, instead of zillions
 120 # of little macros, but it then takes twice longer to run `autoconf'!
 121 #
 122 # From M4sugar:
 123 #    -1. KILL
 124 # 10000. GROW
 125 #
 126 # From M4sh:
 127 #    0. BINSH
 128 #    1. HEADER-REVISION
 129 #    2. HEADER-COMMENT
 130 #    3. HEADER-COPYRIGHT
 131 #    4. M4SH-INIT
 132 # 1000. BODY
 133 m4_define([_m4_divert(DEFAULTS)],        10)
 134 m4_define([_m4_divert(PARSE_ARGS)],      20)
 135
 136 m4_define([_m4_divert(HELP_BEGIN)],     100)
 137 m4_define([_m4_divert(HELP_CANON)],     101)
 138 m4_define([_m4_divert(HELP_ENABLE)],    102)
 139 m4_define([_m4_divert(HELP_WITH)],      103)
 140 m4_define([_m4_divert(HELP_VAR)],       104)
 141 m4_define([_m4_divert(HELP_VAR_END)],   105)
 142 m4_define([_m4_divert(HELP_END)],       106)
 143
 144 m4_define([_m4_divert(VERSION_BEGIN)],  200)
 145 m4_define([_m4_divert(VERSION_FSF)],    201)
 146 m4_define([_m4_divert(VERSION_USER)],   202)
 147 m4_define([_m4_divert(VERSION_END)],    203)
 148
 149 m4_define([_m4_divert(INIT_PREPARE)],   300)
 150
 151
 152
 153 # AC_DIVERT_PUSH(DIVERSION-NAME)
 154 # AC_DIVERT_POP
 155 # ------------------------------
 156 m4_copy([m4_divert_push],[AC_DIVERT_PUSH])
 157 m4_copy([m4_divert_pop], [AC_DIVERT_POP])
 158
 159
 160
 161 ## ------------------------------------ ##
 162 ## Defining/requiring Autoconf macros.  ##
 163 ## ------------------------------------ ##
 164
 165
 166 # AC_DEFUN(NAME, EXPANSION)
 167 # AC_DEFUN_ONCE(NAME, EXPANSION)
 168 # AC_BEFORE(THIS-MACRO-NAME, CALLED-MACRO-NAME)
 169 # AC_REQUIRE(STRING)
 170 # AC_PROVIDE(MACRO-NAME)
 171 # AC_PROVIDE_IFELSE(MACRO-NAME, IF-PROVIDED, IF-NOT-PROVIDED)
 172 # -----------------------------------------------------------
 173 m4_copy([m4_defun],       [AC_DEFUN])
 174 m4_copy([m4_defun_once],  [AC_DEFUN_ONCE])
 175 m4_copy([m4_before],      [AC_BEFORE])
 176 m4_copy([m4_require],     [AC_REQUIRE])
 177 m4_copy([m4_provide],     [AC_PROVIDE])
 178 m4_copy([m4_provide_if],  [AC_PROVIDE_IFELSE])
 179
 180
 181 # AC_OBSOLETE(THIS-MACRO-NAME, [SUGGESTION])
 182 # ------------------------------------------
 183 m4_define([AC_OBSOLETE],
 184 [AC_DIAGNOSE([obsolete], [$1 is obsolete$2])])
 185
 186
 187
 188 ## ----------------------------- ##
 189 ## Implementing Autoconf loops.  ##
 190 ## ----------------------------- ##
 191
 192
 193 # AU::AC_FOREACH(VARIABLE, LIST, EXPRESSION)
 194 # ------------------------------------------
 195 AU_DEFUN([AC_FOREACH], [[m4_foreach_w($@)]])
 196 AC_DEFUN([AC_FOREACH], [m4_foreach_w($@)dnl
 197 AC_DIAGNOSE([obsolete], [The macro `AC_FOREACH' is obsolete.
 198 You should run autoupdate.])])
 199
 200
 201
 202 ## ----------------------------------- ##
 203 ## Helping macros to display strings.  ##
 204 ## ----------------------------------- ##
 205
 206
 207 # AU::AC_HELP_STRING(LHS, RHS, [COLUMN])
 208 # --------------------------------------
 209 AU_ALIAS([AC_HELP_STRING], [AS_HELP_STRING])
 210
 211
 212
 213 ## ---------------------------------------------- ##
 214 ## Information on the package being Autoconf'ed.  ##
 215 ## ---------------------------------------------- ##
 216
 217
 218 # It is suggested that the macros in this section appear before
 219 # AC_INIT in `configure.ac'.  Nevertheless, this is just stylistic,
 220 # and from the implementation point of view, AC_INIT *must* be expanded
 221 # beforehand: it puts data in diversions which must appear before the
 222 # data provided by the macros of this section.
 223
 224 # The solution is to require AC_INIT in each of these macros.  AC_INIT
 225 # has the needed magic so that it can't be expanded twice.
 226
 227
 228
 229 # _AC_INIT_PACKAGE(PACKAGE-NAME, VERSION, BUG-REPORT, [TARNAME])
 230 # --------------------------------------------------------------
 231 m4_define([_AC_INIT_PACKAGE],
 232 [AS_LITERAL_IF([$1], [], [m4_warn([syntax], [AC_INIT: not a literal: $1])])
 233 AS_LITERAL_IF([$2], [],  [m4_warn([syntax], [AC_INIT: not a literal: $2])])
 234 AS_LITERAL_IF([$3], [],  [m4_warn([syntax], [AC_INIT: not a literal: $3])])
 235 m4_ifndef([AC_PACKAGE_NAME],
 236           [m4_define([AC_PACKAGE_NAME],     [$1])])
 237 m4_ifndef([AC_PACKAGE_TARNAME],
 238           [m4_define([AC_PACKAGE_TARNAME],
 239                      m4_default([$4],
 240                                 [m4_bpatsubst(m4_tolower(m4_bpatsubst([[[$1]]],
 241                                                                      [GNU ])),
 242                                  [[^_abcdefghijklmnopqrstuvwxyz0123456789]],
 243                                  [-])]))])
 244 m4_ifndef([AC_PACKAGE_VERSION],
 245           [m4_define([AC_PACKAGE_VERSION],   [$2])])
 246 m4_ifndef([AC_PACKAGE_STRING],
 247           [m4_define([AC_PACKAGE_STRING],    [$1 $2])])
 248 m4_ifndef([AC_PACKAGE_BUGREPORT],
 249           [m4_define([AC_PACKAGE_BUGREPORT], [$3])])
 250 ])
 251
 252
 253 # AC_COPYRIGHT(TEXT, [VERSION-DIVERSION = VERSION_USER])
 254 # ------------------------------------------------------
 255 # Emit TEXT, a copyright notice, in the top of `configure' and in
 256 # --version output.  Macros in TEXT are evaluated once.
 257 m4_define([AC_COPYRIGHT],
 258 [AS_COPYRIGHT([$1])[]dnl
 259 m4_divert_text(m4_default([$2], [VERSION_USER]),
 260 [
 261 $1])dnl
 262 ])# AC_COPYRIGHT
 263
 264
 265 # AC_REVISION(REVISION-INFO)
 266 # --------------------------
 267 # The second quote in the translit is just to cope with font-lock-mode
 268 # which sees the opening of a string.
 269 m4_define([AC_REVISION],
 270 [m4_divert_text([HEADER-REVISION],
 271                 [@%:@ From __file__ m4_translit([$1], [$""]).])dnl
 272 ])
 273
 274
 275
 276
 277 ## ---------------------------------------- ##
 278 ## Requirements over the Autoconf version.  ##
 279 ## ---------------------------------------- ##
 280
 281
 282 # AU::AC_PREREQ(VERSION)
 283 # ----------------------
 284 # Update this `AC_PREREQ' statement to require the current version of
 285 # Autoconf.  But fail if ever this autoupdate is too old.
 286 #
 287 # Note that `m4_defn([m4_PACKAGE_VERSION])' below are expanded before
 288 # calling `AU_DEFUN', i.e., it is hard coded.  Otherwise it would be
 289 # quite complex for autoupdate to import the value of
 290 # `m4_PACKAGE_VERSION'.  We could `AU_DEFUN' `m4_PACKAGE_VERSION', but
 291 # this would replace all its occurrences with the current version of
 292 # Autoconf, which is certainly not what the user intended.
 293 AU_DEFUN([AC_PREREQ],
 294 [m4_version_prereq([$1])[]dnl
 295 [AC_PREREQ(]]m4_defn([m4_PACKAGE_VERSION])[[)]])
 296
 297
 298 # AC_PREREQ(VERSION)
 299 # ------------------
 300 # Complain and exit if the Autoconf version is less than VERSION.
 301 m4_copy([m4_version_prereq], [AC_PREREQ])
 302
 303
 304
 305
 306
 307
 308 ## ---------------- ##
 309 ## Initialization.  ##
 310 ## ---------------- ##
 311
 312
 313 # All the following macros are used by AC_INIT.  Ideally, they should
 314 # be presented in the order in which they are output.  Please, help us
 315 # sorting it, or at least, don't augment the entropy.
 316
 317
 318 # _AC_INIT_NOTICE
 319 # ---------------
 320 m4_define([_AC_INIT_NOTICE],
 321 [m4_divert_text([HEADER-COMMENT],
 322 [@%:@ Guess values for system-dependent variables and create Makefiles.
 323 @%:@ Generated by m4_PACKAGE_STRING[]dnl
 324 m4_ifset([AC_PACKAGE_STRING], [ for AC_PACKAGE_STRING]).])
 325
 326 m4_ifset([AC_PACKAGE_BUGREPORT],
 327          [m4_divert_text([HEADER-COMMENT],
 328                          [@%:@
 329 @%:@ Report bugs to <AC_PACKAGE_BUGREPORT>.])])
 330 ])
 331
 332
 333 # _AC_INIT_COPYRIGHT
 334 # ------------------
 335 # We dump to VERSION_FSF to make sure we are inserted before the
 336 # user copyrights, and after the setup of the --version handling.
 337 m4_define([_AC_INIT_COPYRIGHT],
 338 [AC_COPYRIGHT(
 339 [Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001,
 340 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
 341 This configure script is free software; the Free Software Foundation
 342 gives unlimited permission to copy, distribute and modify it.],
 343               [VERSION_FSF])dnl
 344 ])
 345
 346
 347 # File Descriptors
 348 # ----------------
 349 # Set up the file descriptors used by `configure'.
 350 # File descriptor usage:
 351 # 0 standard input (/dev/null)
 352 # 1 file creation
 353 # 2 errors and warnings
 354 # AS_MESSAGE_LOG_FD compiler messages saved in config.log
 355 # AS_MESSAGE_FD checking for... messages and results
 356 # AS_ORIGINAL_STDIN_FD original standard input (still open)
 357 #
 358 # stdin is /dev/null because checks that run programs may
 359 # inadvertently run interactive ones, which would stop configuration
 360 # until someone typed an EOF.
 361 m4_define([AS_MESSAGE_FD], 6)
 362 m4_define([AS_ORIGINAL_STDIN_FD], 7)
 363 # That's how they used to be named.
 364 AU_ALIAS([AC_FD_CC],  [AS_MESSAGE_LOG_FD])
 365 AU_ALIAS([AC_FD_MSG], [AS_MESSAGE_FD])
 366
 367
 368 # _AC_INIT_DEFAULTS
 369 # -----------------
 370 # Values which defaults can be set from `configure.ac'.
 371 # `/bin/machine' is used in `glibcbug'.  The others are used in config.*
 372 m4_define([_AC_INIT_DEFAULTS],
 373 [m4_divert_push([DEFAULTS])dnl
 374
 375 exec AS_ORIGINAL_STDIN_FD<&0 </dev/null AS_MESSAGE_FD>&1
 376
 377 # Name of the host.
 378 # hostname on some systems (SVR3.2, Linux) returns a bogus exit status,
 379 # so uname gets run too.
 380 ac_hostname=`(hostname || uname -n) 2>/dev/null | sed 1q`
 381
 382 #
 383 # Initializations.
 384 #
 385 ac_default_prefix=/usr/local
 386 ac_clean_files=
 387 ac_config_libobj_dir=.
 388 LIB@&t@OBJS=
 389 cross_compiling=no
 390 subdirs=
 391 MFLAGS=
 392 MAKEFLAGS=
 393 AC_SUBST([SHELL], [${CONFIG_SHELL-/bin/sh}])dnl
 394 AC_SUBST([PATH_SEPARATOR])dnl
 395
 396 # Identity of this package.
 397 AC_SUBST([PACKAGE_NAME],
 398          [m4_ifdef([AC_PACKAGE_NAME],      ['AC_PACKAGE_NAME'])])dnl
 399 AC_SUBST([PACKAGE_TARNAME],
 400          [m4_ifdef([AC_PACKAGE_TARNAME],   ['AC_PACKAGE_TARNAME'])])dnl
 401 AC_SUBST([PACKAGE_VERSION],
 402          [m4_ifdef([AC_PACKAGE_VERSION],   ['AC_PACKAGE_VERSION'])])dnl
 403 AC_SUBST([PACKAGE_STRING],
 404          [m4_ifdef([AC_PACKAGE_STRING],    ['AC_PACKAGE_STRING'])])dnl
 405 AC_SUBST([PACKAGE_BUGREPORT],
 406          [m4_ifdef([AC_PACKAGE_BUGREPORT], ['AC_PACKAGE_BUGREPORT'])])dnl
 407
 408 m4_divert_pop([DEFAULTS])dnl
 409 m4_wrap([m4_divert_text([DEFAULTS],
 410 [ac_subst_vars='m4_ifdef([_AC_SUBST_VARS],  [m4_defn([_AC_SUBST_VARS])])'
 411 ac_subst_files='m4_ifdef([_AC_SUBST_FILES], [m4_defn([_AC_SUBST_FILES])])'
 412 m4_ifdef([_AC_PRECIOUS_VARS],
 413   [_AC_ARG_VAR_STORE[]dnl
 414    _AC_ARG_VAR_VALIDATE[]dnl
 415    ac_precious_vars='m4_defn([_AC_PRECIOUS_VARS])'])
 416 m4_ifdef([_AC_LIST_SUBDIRS],
 417   [ac_subdirs_all='m4_defn([_AC_LIST_SUBDIRS])'])dnl
 418 ])])dnl
 419 ])# _AC_INIT_DEFAULTS
 420
 421
 422 # AC_PREFIX_DEFAULT(PREFIX)
 423 # -------------------------
 424 AC_DEFUN([AC_PREFIX_DEFAULT],
 425 [m4_divert_text([DEFAULTS], [ac_default_prefix=$1])])
 426
 427
 428 # AC_PREFIX_PROGRAM(PROGRAM)
 429 # --------------------------
 430 # Guess the value for the `prefix' variable by looking for
 431 # the argument program along PATH and taking its parent.
 432 # Example: if the argument is `gcc' and we find /usr/local/gnu/bin/gcc,
 433 # set `prefix' to /usr/local/gnu.
 434 # This comes too late to find a site file based on the prefix,
 435 # and it might use a cached value for the path.
 436 # No big loss, I think, since most configures don't use this macro anyway.
 437 AC_DEFUN([AC_PREFIX_PROGRAM],
 438 [if test "x$prefix" = xNONE; then
 439 dnl We reimplement AC_MSG_CHECKING (mostly) to avoid the ... in the middle.
 440   _AS_ECHO_N([checking for prefix by ])
 441   AC_PATH_PROG(ac_prefix_program, [$1])
 442   if test -n "$ac_prefix_program"; then
 443     prefix=`AS_DIRNAME(["$ac_prefix_program"])`
 444     prefix=`AS_DIRNAME(["$prefix"])`
 445   fi
 446 fi
 447 ])# AC_PREFIX_PROGRAM
 448
 449
 450 # AC_CONFIG_SRCDIR([UNIQUE-FILE-IN-SOURCE-DIR])
 451 # ---------------------------------------------
 452 # UNIQUE-FILE-IN-SOURCE-DIR is a file name unique to this package,
 453 # relative to the directory that configure is in, which we can look
 454 # for to find out if srcdir is correct.
 455 AC_DEFUN([AC_CONFIG_SRCDIR],
 456 [m4_divert_text([DEFAULTS], [ac_unique_file="$1"])])
 457
 458
 459 # _AC_INIT_DIRCHECK
 460 # -----------------
 461 # Set ac_pwd, and sanity-check it and the source and installation directories.
 462 #
 463 # (This macro is AC_REQUIREd by _AC_INIT_SRCDIR, so it has to be AC_DEFUNed.)
 464 #
 465 AC_DEFUN([_AC_INIT_DIRCHECK],
 466 [m4_divert_push([PARSE_ARGS])dnl
 467
 468 ac_pwd=`pwd` && test -n "$ac_pwd" &&
 469 ac_ls_di=`ls -di .` &&
 470 ac_pwd_ls_di=`cd "$ac_pwd" && ls -di .` ||
 471   AC_MSG_ERROR([Working directory cannot be determined])
 472 test "X$ac_ls_di" = "X$ac_pwd_ls_di" ||
 473   AC_MSG_ERROR([pwd does not report name of working directory])
 474
 475 m4_divert_pop([PARSE_ARGS])dnl
 476 ])# _AC_INIT_DIRCHECK
 477
 478 # _AC_INIT_SRCDIR
 479 # ---------------
 480 # Compute `srcdir' based on `$ac_unique_file'.
 481 #
 482 # (We have to AC_DEFUN it, since we use AC_REQUIRE.)
 483 #
 484 AC_DEFUN([_AC_INIT_SRCDIR],
 485 [AC_REQUIRE([_AC_INIT_DIRCHECK])dnl
 486 m4_divert_push([PARSE_ARGS])dnl
 487
 488 # Find the source files, if location was not specified.
 489 if test -z "$srcdir"; then
 490   ac_srcdir_defaulted=yes
 491   # Try the directory containing this script, then the parent directory.
 492   ac_confdir=`AS_DIRNAME(["$[0]"])`
 493   srcdir=$ac_confdir
 494   if test ! -r "$srcdir/$ac_unique_file"; then
 495     srcdir=..
 496   fi
 497 else
 498   ac_srcdir_defaulted=no
 499 fi
 500 if test ! -r "$srcdir/$ac_unique_file"; then
 501   test "$ac_srcdir_defaulted" = yes && srcdir="$ac_confdir or .."
 502   AC_MSG_ERROR([cannot find sources ($ac_unique_file) in $srcdir])
 503 fi
 504 ac_msg="sources are in $srcdir, but \`cd $srcdir' does not work"
 505 ac_abs_confdir=`(
 506         cd "$srcdir" && test -r "./$ac_unique_file" || AC_MSG_ERROR([$ac_msg])
 507         pwd)`
 508 # When building in place, set srcdir=.
 509 if test "$ac_abs_confdir" = "$ac_pwd"; then
 510   srcdir=.
 511 fi
 512 # Remove unnecessary trailing slashes from srcdir.
 513 # Double slashes in file names in object file debugging info
 514 # mess up M-x gdb in Emacs.
 515 case $srcdir in
 516 */) srcdir=`expr "X$srcdir" : 'X\(.*[[^/]]\)' \| "X$srcdir" : 'X\(.*\)'`;;
 517 esac
 518 m4_divert_pop([PARSE_ARGS])dnl
 519 ])# _AC_INIT_SRCDIR
 520
 521
 522 # _AC_INIT_PARSE_ARGS
 523 # -------------------
 524 m4_define([_AC_INIT_PARSE_ARGS],
 525 [m4_divert_push([PARSE_ARGS])dnl
 526
 527 # Initialize some variables set by options.
 528 ac_init_help=
 529 ac_init_version=false
 530 # The variables have the same names as the options, with
 531 # dashes changed to underlines.
 532 cache_file=/dev/null
 533 AC_SUBST(exec_prefix, NONE)dnl
 534 no_create=
 535 no_recursion=
 536 AC_SUBST(prefix, NONE)dnl
 537 program_prefix=NONE
 538 program_suffix=NONE
 539 AC_SUBST(program_transform_name, [s,x,x,])dnl
 540 silent=
 541 site=
 542 srcdir=
 543 verbose=
 544 x_includes=NONE
 545 x_libraries=NONE
 546
 547 # Installation directory options.
 548 # These are left unexpanded so users can "make install exec_prefix=/foo"
 549 # and all the variables that are supposed to be based on exec_prefix
 550 # by default will actually change.
 551 # Use braces instead of parens because sh, perl, etc. also accept them.
 552 # (The list follows the same order as the GNU Coding Standards.)
 553 AC_SUBST([bindir],         ['${exec_prefix}/bin'])dnl
 554 AC_SUBST([sbindir],        ['${exec_prefix}/sbin'])dnl
 555 AC_SUBST([libexecdir],     ['${exec_prefix}/libexec'])dnl
 556 AC_SUBST([datarootdir],    ['${prefix}/share'])dnl
 557 AC_SUBST([datadir],        ['${datarootdir}'])dnl
 558 AC_SUBST([sysconfdir],     ['${prefix}/etc'])dnl
 559 AC_SUBST([sharedstatedir], ['${prefix}/com'])dnl
 560 AC_SUBST([localstatedir],  ['${prefix}/var'])dnl
 561 AC_SUBST([includedir],     ['${prefix}/include'])dnl
 562 AC_SUBST([oldincludedir],  ['/usr/include'])dnl
 563 AC_SUBST([docdir],         [m4_ifset([AC_PACKAGE_TARNAME],
 564                                      ['${datarootdir}/doc/${PACKAGE_TARNAME}'],
 565                                      ['${datarootdir}/doc/${PACKAGE}'])])dnl
 566 AC_SUBST([infodir],        ['${datarootdir}/info'])dnl
 567 AC_SUBST([htmldir],        ['${docdir}'])dnl
 568 AC_SUBST([dvidir],         ['${docdir}'])dnl
 569 AC_SUBST([pdfdir],         ['${docdir}'])dnl
 570 AC_SUBST([psdir],          ['${docdir}'])dnl
 571 AC_SUBST([libdir],         ['${exec_prefix}/lib'])dnl
 572 AC_SUBST([localedir],      ['${datarootdir}/locale'])dnl
 573 AC_SUBST([mandir],         ['${datarootdir}/man'])dnl
 574
 575 ac_prev=
 576 ac_dashdash=
 577 for ac_option
 578 do
 579   # If the previous option needs an argument, assign it.
 580   if test -n "$ac_prev"; then
 581     eval $ac_prev=\$ac_option
 582     ac_prev=
 583     continue
 584   fi
 585
 586   case $ac_option in
 587   *=*)  ac_optarg=`expr "X$ac_option" : '[[^=]]*=\(.*\)'` ;;
 588   *)    ac_optarg=yes ;;
 589   esac
 590
 591   # Accept the important Cygnus configure options, so we can diagnose typos.
 592
 593   case $ac_dashdash$ac_option in
 594   --)
 595     ac_dashdash=yes ;;
 596
 597   -bindir | --bindir | --bindi | --bind | --bin | --bi)
 598     ac_prev=bindir ;;
 599   -bindir=* | --bindir=* | --bindi=* | --bind=* | --bin=* | --bi=*)
 600     bindir=$ac_optarg ;;
 601
 602   -build | --build | --buil | --bui | --bu)
 603     ac_prev=build_alias ;;
 604   -build=* | --build=* | --buil=* | --bui=* | --bu=*)
 605     build_alias=$ac_optarg ;;
 606
 607   -cache-file | --cache-file | --cache-fil | --cache-fi \
 608   | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
 609     ac_prev=cache_file ;;
 610   -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
 611   | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* | --c=*)
 612     cache_file=$ac_optarg ;;
 613
 614   --config-cache | -C)
 615     cache_file=config.cache ;;
 616
 617   -datadir | --datadir | --datadi | --datad)
 618     ac_prev=datadir ;;
 619   -datadir=* | --datadir=* | --datadi=* | --datad=*)
 620     datadir=$ac_optarg ;;
 621
 622   -datarootdir | --datarootdir | --datarootdi | --datarootd | --dataroot \
 623   | --dataroo | --dataro | --datar)
 624     ac_prev=datarootdir ;;
 625   -datarootdir=* | --datarootdir=* | --datarootdi=* | --datarootd=* \
 626   | --dataroot=* | --dataroo=* | --dataro=* | --datar=*)
 627     datarootdir=$ac_optarg ;;
 628
 629   _AC_INIT_PARSE_ENABLE([disable], [feature], [no])
 630
 631   -docdir | --docdir | --docdi | --doc | --do)
 632     ac_prev=docdir ;;
 633   -docdir=* | --docdir=* | --docdi=* | --doc=* | --do=*)
 634     docdir=$ac_optarg ;;
 635
 636   -dvidir | --dvidir | --dvidi | --dvid | --dvi | --dv)
 637     ac_prev=dvidir ;;
 638   -dvidir=* | --dvidir=* | --dvidi=* | --dvid=* | --dvi=* | --dv=*)
 639     dvidir=$ac_optarg ;;
 640
 641   _AC_INIT_PARSE_ENABLE([enable], [feature], [\$ac_optarg])
 642
 643   -exec-prefix | --exec_prefix | --exec-prefix | --exec-prefi \
 644   | --exec-pref | --exec-pre | --exec-pr | --exec-p | --exec- \
 645   | --exec | --exe | --ex)
 646     ac_prev=exec_prefix ;;
 647   -exec-prefix=* | --exec_prefix=* | --exec-prefix=* | --exec-prefi=* \
 648   | --exec-pref=* | --exec-pre=* | --exec-pr=* | --exec-p=* | --exec-=* \
 649   | --exec=* | --exe=* | --ex=*)
 650     exec_prefix=$ac_optarg ;;
 651
 652   -gas | --gas | --ga | --g)
 653     # Obsolete; use --with-gas.
 654     with_gas=yes ;;
 655
 656   -help | --help | --hel | --he | -h)
 657     ac_init_help=long ;;
 658   -help=r* | --help=r* | --hel=r* | --he=r* | -hr*)
 659     ac_init_help=recursive ;;
 660   -help=s* | --help=s* | --hel=s* | --he=s* | -hs*)
 661     ac_init_help=short ;;
 662
 663   -host | --host | --hos | --ho)
 664     ac_prev=host_alias ;;
 665   -host=* | --host=* | --hos=* | --ho=*)
 666     host_alias=$ac_optarg ;;
 667
 668   -htmldir | --htmldir | --htmldi | --htmld | --html | --htm | --ht)
 669     ac_prev=htmldir ;;
 670   -htmldir=* | --htmldir=* | --htmldi=* | --htmld=* | --html=* | --htm=* \
 671   | --ht=*)
 672     htmldir=$ac_optarg ;;
 673
 674   -includedir | --includedir | --includedi | --included | --include \
 675   | --includ | --inclu | --incl | --inc)
 676     ac_prev=includedir ;;
 677   -includedir=* | --includedir=* | --includedi=* | --included=* | --include=* \
 678   | --includ=* | --inclu=* | --incl=* | --inc=*)
 679     includedir=$ac_optarg ;;
 680
 681   -infodir | --infodir | --infodi | --infod | --info | --inf)
 682     ac_prev=infodir ;;
 683   -infodir=* | --infodir=* | --infodi=* | --infod=* | --info=* | --inf=*)
 684     infodir=$ac_optarg ;;
 685
 686   -libdir | --libdir | --libdi | --libd)
 687     ac_prev=libdir ;;
 688   -libdir=* | --libdir=* | --libdi=* | --libd=*)
 689     libdir=$ac_optarg ;;
 690
 691   -libexecdir | --libexecdir | --libexecdi | --libexecd | --libexec \
 692   | --libexe | --libex | --libe)
 693     ac_prev=libexecdir ;;
 694   -libexecdir=* | --libexecdir=* | --libexecdi=* | --libexecd=* | --libexec=* \
 695   | --libexe=* | --libex=* | --libe=*)
 696     libexecdir=$ac_optarg ;;
 697
 698   -localedir | --localedir | --localedi | --localed | --locale)
 699     ac_prev=localedir ;;
 700   -localedir=* | --localedir=* | --localedi=* | --localed=* | --locale=*)
 701     localedir=$ac_optarg ;;
 702
 703   -localstatedir | --localstatedir | --localstatedi | --localstated \
 704   | --localstate | --localstat | --localsta | --localst | --locals)
 705     ac_prev=localstatedir ;;
 706   -localstatedir=* | --localstatedir=* | --localstatedi=* | --localstated=* \
 707   | --localstate=* | --localstat=* | --localsta=* | --localst=* | --locals=*)
 708     localstatedir=$ac_optarg ;;
 709
 710   -mandir | --mandir | --mandi | --mand | --man | --ma | --m)
 711     ac_prev=mandir ;;
 712   -mandir=* | --mandir=* | --mandi=* | --mand=* | --man=* | --ma=* | --m=*)
 713     mandir=$ac_optarg ;;
 714
 715   -nfp | --nfp | --nf)
 716     # Obsolete; use --without-fp.
 717     with_fp=no ;;
 718
 719   -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 720   | --no-cr | --no-c | -n)
 721     no_create=yes ;;
 722
 723   -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 724   | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r)
 725     no_recursion=yes ;;
 726
 727   -oldincludedir | --oldincludedir | --oldincludedi | --oldincluded \
 728   | --oldinclude | --oldinclud | --oldinclu | --oldincl | --oldinc \
 729   | --oldin | --oldi | --old | --ol | --o)
 730     ac_prev=oldincludedir ;;
 731   -oldincludedir=* | --oldincludedir=* | --oldincludedi=* | --oldincluded=* \
 732   | --oldinclude=* | --oldinclud=* | --oldinclu=* | --oldincl=* | --oldinc=* \
 733   | --oldin=* | --oldi=* | --old=* | --ol=* | --o=*)
 734     oldincludedir=$ac_optarg ;;
 735
 736   -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
 737     ac_prev=prefix ;;
 738   -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
 739     prefix=$ac_optarg ;;
 740
 741   -program-prefix | --program-prefix | --program-prefi | --program-pref \
 742   | --program-pre | --program-pr | --program-p)
 743     ac_prev=program_prefix ;;
 744   -program-prefix=* | --program-prefix=* | --program-prefi=* \
 745   | --program-pref=* | --program-pre=* | --program-pr=* | --program-p=*)
 746     program_prefix=$ac_optarg ;;
 747
 748   -program-suffix | --program-suffix | --program-suffi | --program-suff \
 749   | --program-suf | --program-su | --program-s)
 750     ac_prev=program_suffix ;;
 751   -program-suffix=* | --program-suffix=* | --program-suffi=* \
 752   | --program-suff=* | --program-suf=* | --program-su=* | --program-s=*)
 753     program_suffix=$ac_optarg ;;
 754
 755   -program-transform-name | --program-transform-name \
 756   | --program-transform-nam | --program-transform-na \
 757   | --program-transform-n | --program-transform- \
 758   | --program-transform | --program-transfor \
 759   | --program-transfo | --program-transf \
 760   | --program-trans | --program-tran \
 761   | --progr-tra | --program-tr | --program-t)
 762     ac_prev=program_transform_name ;;
 763   -program-transform-name=* | --program-transform-name=* \
 764   | --program-transform-nam=* | --program-transform-na=* \
 765   | --program-transform-n=* | --program-transform-=* \
 766   | --program-transform=* | --program-transfor=* \
 767   | --program-transfo=* | --program-transf=* \
 768   | --program-trans=* | --program-tran=* \
 769   | --progr-tra=* | --program-tr=* | --program-t=*)
 770     program_transform_name=$ac_optarg ;;
 771
 772   -pdfdir | --pdfdir | --pdfdi | --pdfd | --pdf | --pd)
 773     ac_prev=pdfdir ;;
 774   -pdfdir=* | --pdfdir=* | --pdfdi=* | --pdfd=* | --pdf=* | --pd=*)
 775     pdfdir=$ac_optarg ;;
 776
 777   -psdir | --psdir | --psdi | --psd | --ps)
 778     ac_prev=psdir ;;
 779   -psdir=* | --psdir=* | --psdi=* | --psd=* | --ps=*)
 780     psdir=$ac_optarg ;;
 781
 782   -q | -quiet | --quiet | --quie | --qui | --qu | --q \
 783   | -silent | --silent | --silen | --sile | --sil)
 784     silent=yes ;;
 785
 786   -sbindir | --sbindir | --sbindi | --sbind | --sbin | --sbi | --sb)
 787     ac_prev=sbindir ;;
 788   -sbindir=* | --sbindir=* | --sbindi=* | --sbind=* | --sbin=* \
 789   | --sbi=* | --sb=*)
 790     sbindir=$ac_optarg ;;
 791
 792   -sharedstatedir | --sharedstatedir | --sharedstatedi \
 793   | --sharedstated | --sharedstate | --sharedstat | --sharedsta \
 794   | --sharedst | --shareds | --shared | --share | --shar \
 795   | --sha | --sh)
 796     ac_prev=sharedstatedir ;;
 797   -sharedstatedir=* | --sharedstatedir=* | --sharedstatedi=* \
 798   | --sharedstated=* | --sharedstate=* | --sharedstat=* | --sharedsta=* \
 799   | --sharedst=* | --shareds=* | --shared=* | --share=* | --shar=* \
 800   | --sha=* | --sh=*)
 801     sharedstatedir=$ac_optarg ;;
 802
 803   -site | --site | --sit)
 804     ac_prev=site ;;
 805   -site=* | --site=* | --sit=*)
 806     site=$ac_optarg ;;
 807
 808   -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
 809     ac_prev=srcdir ;;
 810   -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
 811     srcdir=$ac_optarg ;;
 812
 813   -sysconfdir | --sysconfdir | --sysconfdi | --sysconfd | --sysconf \
 814   | --syscon | --sysco | --sysc | --sys | --sy)
 815     ac_prev=sysconfdir ;;
 816   -sysconfdir=* | --sysconfdir=* | --sysconfdi=* | --sysconfd=* | --sysconf=* \
 817   | --syscon=* | --sysco=* | --sysc=* | --sys=* | --sy=*)
 818     sysconfdir=$ac_optarg ;;
 819
 820   -target | --target | --targe | --targ | --tar | --ta | --t)
 821     ac_prev=target_alias ;;
 822   -target=* | --target=* | --targe=* | --targ=* | --tar=* | --ta=* | --t=*)
 823     target_alias=$ac_optarg ;;
 824
 825   -v | -verbose | --verbose | --verbos | --verbo | --verb)
 826     verbose=yes ;;
 827
 828   -version | --version | --versio | --versi | --vers | -V)
 829     ac_init_version=: ;;
 830
 831   _AC_INIT_PARSE_ENABLE([with],    [package], [\$ac_optarg])
 832
 833   _AC_INIT_PARSE_ENABLE([without], [package], [no])
 834
 835   --x)
 836     # Obsolete; use --with-x.
 837     with_x=yes ;;
 838
 839   -x-includes | --x-includes | --x-include | --x-includ | --x-inclu \
 840   | --x-incl | --x-inc | --x-in | --x-i)
 841     ac_prev=x_includes ;;
 842   -x-includes=* | --x-includes=* | --x-include=* | --x-includ=* | --x-inclu=* \
 843   | --x-incl=* | --x-inc=* | --x-in=* | --x-i=*)
 844     x_includes=$ac_optarg ;;
 845
 846   -x-libraries | --x-libraries | --x-librarie | --x-librari \
 847   | --x-librar | --x-libra | --x-libr | --x-lib | --x-li | --x-l)
 848     ac_prev=x_libraries ;;
 849   -x-libraries=* | --x-libraries=* | --x-librarie=* | --x-librari=* \
 850   | --x-librar=* | --x-libra=* | --x-libr=* | --x-lib=* | --x-li=* | --x-l=*)
 851     x_libraries=$ac_optarg ;;
 852
 853   -*) AC_MSG_ERROR([unrecognized option: $ac_option
 854 Try `$[0] --help' for more information.])
 855     ;;
 856
 857   *=*)
 858     ac_envvar=`expr "x$ac_option" : 'x\([[^=]]*\)='`
 859     # Reject names that are not valid shell variable names.
 860     expr "x$ac_envvar" : "[.*[^_$as_cr_alnum]]" >/dev/null &&
 861       AC_MSG_ERROR([invalid variable name: $ac_envvar])
 862     eval $ac_envvar=\$ac_optarg
 863     export $ac_envvar ;;
 864
 865   *)
 866     # FIXME: should be removed in autoconf 3.0.
 867     AC_MSG_WARN([you should use --build, --host, --target])
 868     expr "x$ac_option" : "[.*[^-._$as_cr_alnum]]" >/dev/null &&
 869       AC_MSG_WARN([invalid host type: $ac_option])
 870     : ${build_alias=$ac_option} ${host_alias=$ac_option} ${target_alias=$ac_option}
 871     ;;
 872
 873   esac
 874 done
 875
 876 if test -n "$ac_prev"; then
 877   ac_option=--`echo $ac_prev | sed 's/_/-/g'`
 878   AC_MSG_ERROR([missing argument to $ac_option])
 879 fi
 880
 881 # Be sure to have absolute directory names.
 882 for ac_var in   exec_prefix prefix bindir sbindir libexecdir datarootdir \
 883                 datadir sysconfdir sharedstatedir localstatedir includedir \
 884                 oldincludedir docdir infodir htmldir dvidir pdfdir psdir \
 885                 libdir localedir mandir
 886 do
 887   eval ac_val=\$$ac_var
 888   case $ac_val in
 889     [[\\/$]]* | ?:[[\\/]]* )  continue;;
 890     NONE | '' ) case $ac_var in *prefix ) continue;; esac;;
 891   esac
 892   AC_MSG_ERROR([expected an absolute directory name for --$ac_var: $ac_val])
 893 done
 894
 895 # There might be people who depend on the old broken behavior: `$host'
 896 # used to hold the argument of --host etc.
 897 # FIXME: To remove some day.
 898 build=$build_alias
 899 host=$host_alias
 900 target=$target_alias
 901
 902 # FIXME: To remove some day.
 903 if test "x$host_alias" != x; then
 904   if test "x$build_alias" = x; then
 905     cross_compiling=maybe
 906     AC_MSG_WARN([If you wanted to set the --build type, don't use --host.
 907     If a cross compiler is detected then cross compile mode will be used.])
 908   elif test "x$build_alias" != "x$host_alias"; then
 909     cross_compiling=yes
 910   fi
 911 fi
 912
 913 ac_tool_prefix=
 914 test -n "$host_alias" && ac_tool_prefix=$host_alias-
 915
 916 test "$silent" = yes && exec AS_MESSAGE_FD>/dev/null
 917
 918 m4_divert_pop([PARSE_ARGS])dnl
 919 ])# _AC_INIT_PARSE_ARGS
 920
 921
 922 # _AC_INIT_PARSE_ENABLE(OPTION-NAME, FEATURE, VALUE)
 923 # --------------------------------------------------
 924 # Handle an `--enable' or a `--with' option.
 925 #
 926 m4_define([_AC_INIT_PARSE_ENABLE],
 927 [-$1-* | --$1-*)
 928     ac_$2=`expr "x$ac_option" : 'x-*$1-\(m4_bmatch([$1], [^\(enable\|with\)$], [[[^=]]], [.])*\)'`
 929     # Reject names that are not valid shell variable names.
 930     expr "x$ac_$2" : "[.*[^-._$as_cr_alnum]]" >/dev/null &&
 931       AC_MSG_ERROR([invalid $2 name: $ac_$2])
 932     [ac_$2=`echo $ac_$2 | sed 's/[-.]/_/g'`]
 933     eval m4_bmatch([$1], [^\(enable\|disable\)$], [enable], [with])_$ac_$2=$3 ;;dnl
 934 ])
 935
 936
 937 # _AC_INIT_HELP
 938 # -------------
 939 # Handle the `configure --help' message.
 940 m4_define([_AC_INIT_HELP],
 941 [m4_divert_push([HELP_BEGIN])dnl
 942
 943 #
 944 # Report the --help message.
 945 #
 946 if test "$ac_init_help" = "long"; then
 947   # Omit some internal or obsolete options to make the list less imposing.
 948   # This message is too long to be a string in the A/UX 3.1 sh.
 949   cat <<_ACEOF
 950 \`configure' configures m4_ifset([AC_PACKAGE_STRING],
 951                         [AC_PACKAGE_STRING],
 952                         [this package]) to adapt to many kinds of systems.
 953
 954 Usage: $[0] [[OPTION]]... [[VAR=VALUE]]...
 955
 956 [To assign environment variables (e.g., CC, CFLAGS...), specify them as
 957 VAR=VALUE.  See below for descriptions of some of the useful variables.
 958
 959 Defaults for the options are specified in brackets.
 960
 961 Configuration:
 962   -h, --help              display this help and exit
 963       --help=short        display options specific to this package
 964       --help=recursive    display the short help of all the included packages
 965   -V, --version           display version information and exit
 966   -q, --quiet, --silent   do not print \`checking...' messages
 967       --cache-file=FILE   cache test results in FILE [disabled]
 968   -C, --config-cache      alias for \`--cache-file=config.cache'
 969   -n, --no-create         do not create output files
 970       --srcdir=DIR        find the sources in DIR [configure dir or \`..']
 971
 972 Installation directories:
 973   --prefix=PREFIX         install architecture-independent files in PREFIX
 974                           [$ac_default_prefix]
 975   --exec-prefix=EPREFIX   install architecture-dependent files in EPREFIX
 976                           [PREFIX]
 977
 978 By default, \`make install' will install all the files in
 979 \`$ac_default_prefix/bin', \`$ac_default_prefix/lib' etc.  You can specify
 980 an installation prefix other than \`$ac_default_prefix' using \`--prefix',
 981 for instance \`--prefix=\$HOME'.
 982
 983 For better control, use the options below.
 984
 985 Fine tuning of the installation directories:
 986   --bindir=DIR           user executables [EPREFIX/bin]
 987   --sbindir=DIR          system admin executables [EPREFIX/sbin]
 988   --libexecdir=DIR       program executables [EPREFIX/libexec]
 989   --sysconfdir=DIR       read-only single-machine data [PREFIX/etc]
 990   --sharedstatedir=DIR   modifiable architecture-independent data [PREFIX/com]
 991   --localstatedir=DIR    modifiable single-machine data [PREFIX/var]
 992   --libdir=DIR           object code libraries [EPREFIX/lib]
 993   --includedir=DIR       C header files [PREFIX/include]
 994   --oldincludedir=DIR    C header files for non-gcc [/usr/include]
 995   --datarootdir=DIR      read-only arch.-independent data root [PREFIX/share]
 996   --datadir=DIR          read-only architecture-independent data [DATAROOTDIR]
 997   --infodir=DIR          info documentation [DATAROOTDIR/info]
 998   --localedir=DIR        locale-dependent data [DATAROOTDIR/locale]
 999   --mandir=DIR           man documentation [DATAROOTDIR/man]
1000   --docdir=DIR           documentation root ]@<:@DATAROOTDIR/doc/m4_ifset([AC_PACKAGE_TARNAME], [AC_PACKAGE_TARNAME], [PACKAGE])@:>@[
1001   --htmldir=DIR          html documentation [DOCDIR]
1002   --dvidir=DIR           dvi documentation [DOCDIR]
1003   --pdfdir=DIR           pdf documentation [DOCDIR]
1004   --psdir=DIR            ps documentation [DOCDIR]
1005 _ACEOF
1006
1007   cat <<\_ACEOF]
1008 m4_divert_pop([HELP_BEGIN])dnl
1009 dnl The order of the diversions here is
1010 dnl - HELP_BEGIN
1011 dnl   which may be extended by extra generic options such as with X or
1012 dnl   AC_ARG_PROGRAM.  Displayed only in long --help.
1013 dnl
1014 dnl - HELP_CANON
1015 dnl   Support for cross compilation (--build, --host and --target).
1016 dnl   Display only in long --help.
1017 dnl
1018 dnl - HELP_ENABLE
1019 dnl   which starts with the trailer of the HELP_BEGIN, HELP_CANON section,
1020 dnl   then implements the header of the non generic options.
1021 dnl
1022 dnl - HELP_WITH
1023 dnl
1024 dnl - HELP_VAR
1025 dnl
1026 dnl - HELP_VAR_END
1027 dnl
1028 dnl - HELP_END
1029 dnl   initialized below, in which we dump the trailer (handling of the
1030 dnl   recursion for instance).
1031 m4_divert_push([HELP_ENABLE])dnl
1032 _ACEOF
1033 fi
1034
1035 if test -n "$ac_init_help"; then
1036 m4_ifset([AC_PACKAGE_STRING],
1037 [  case $ac_init_help in
1038      short | recursive ) echo "Configuration of AC_PACKAGE_STRING:";;
1039    esac])
1040   cat <<\_ACEOF
1041 m4_divert_pop([HELP_ENABLE])dnl
1042 m4_divert_push([HELP_END])dnl
1043 m4_ifset([AC_PACKAGE_BUGREPORT], [
1044 Report bugs to <AC_PACKAGE_BUGREPORT>.])
1045 _ACEOF
1046 ac_status=$?
1047 fi
1048
1049 if test "$ac_init_help" = "recursive"; then
1050   # If there are subdirs, report their specific --help.
1051   for ac_dir in : $ac_subdirs_all; do test "x$ac_dir" = x: && continue
1052     test -d "$ac_dir" || continue
1053     _AC_SRCDIRS(["$ac_dir"])
1054     cd "$ac_dir" || { ac_status=$?; continue; }
1055     # Check for guested configure.
1056     if test -f "$ac_srcdir/configure.gnu"; then
1057       echo &&
1058       $SHELL "$ac_srcdir/configure.gnu" --help=recursive
1059     elif test -f "$ac_srcdir/configure"; then
1060       echo &&
1061       $SHELL "$ac_srcdir/configure" --help=recursive
1062     else
1063       AC_MSG_WARN([no configuration information is in $ac_dir])
1064     fi || ac_status=$?
1065     cd "$ac_pwd" || { ac_status=$?; break; }
1066   done
1067 fi
1068
1069 test -n "$ac_init_help" && exit $ac_status
1070 m4_divert_pop([HELP_END])dnl
1071 ])# _AC_INIT_HELP
1072
1073
1074 # _AC_INIT_VERSION
1075 # ----------------
1076 # Handle the `configure --version' message.
1077 m4_define([_AC_INIT_VERSION],
1078 [m4_divert_text([VERSION_BEGIN],
1079 [if $ac_init_version; then
1080   cat <<\_ACEOF
1081 m4_ifset([AC_PACKAGE_NAME], [AC_PACKAGE_NAME ])configure[]dnl
1082 m4_ifset([AC_PACKAGE_VERSION], [ AC_PACKAGE_VERSION])
1083 generated by m4_PACKAGE_STRING])
1084 m4_divert_text([VERSION_END],
1085 [_ACEOF
1086   exit
1087 fi])dnl
1088 ])# _AC_INIT_VERSION
1089
1090
1091 # _AC_INIT_CONFIG_LOG
1092 # -------------------
1093 # Initialize the config.log file descriptor and write header to it.
1094 m4_define([_AC_INIT_CONFIG_LOG],
1095 [m4_divert_text([INIT_PREPARE],
1096 [m4_define([AS_MESSAGE_LOG_FD], 5)dnl
1097 cat >config.log <<_ACEOF
1098 This file contains any messages produced by compilers while
1099 running configure, to aid debugging if configure makes a mistake.
1100
1101 It was created by m4_ifset([AC_PACKAGE_NAME], [AC_PACKAGE_NAME ])dnl
1102 $as_me[]m4_ifset([AC_PACKAGE_VERSION], [ AC_PACKAGE_VERSION]), which was
1103 generated by m4_PACKAGE_STRING.  Invocation command line was
1104
1105   $ $[0] $[@]
1106
1107 _ACEOF
1108 exec AS_MESSAGE_LOG_FD>>config.log
1109 AS_UNAME >&AS_MESSAGE_LOG_FD
1110
1111 cat >&AS_MESSAGE_LOG_FD <<_ACEOF
1112
1113
1114 m4_text_box([Core tests.])
1115
1116 _ACEOF
1117 ])])# _AC_INIT_CONFIG_LOG
1118
1119
1120 # _AC_INIT_PREPARE
1121 # ----------------
1122 # Called by AC_INIT to build the preamble of the `configure' scripts.
1123 # 1. Trap and clean up various tmp files.
1124 # 2. Set up the fd and output files
1125 # 3. Remember the options given to `configure' for `config.status --recheck'.
1126 # 4. Initiates confdefs.h
1127 # 5. Loads site and cache files
1128 m4_define([_AC_INIT_PREPARE],
1129 [m4_divert_push([INIT_PREPARE])dnl
1130
1131 # Keep a trace of the command line.
1132 # Strip out --no-create and --no-recursion so they do not pile up.
1133 # Strip out --silent because we don't want to record it for future runs.
1134 # Also quote any args containing shell meta-characters.
1135 # Make two passes to allow for proper duplicate-argument suppression.
1136 ac_configure_args=
1137 ac_configure_args0=
1138 ac_configure_args1=
1139 ac_must_keep_next=false
1140 for ac_pass in 1 2
1141 do
1142   for ac_arg
1143   do
1144     case $ac_arg in
1145     -no-create | --no-c* | -n | -no-recursion | --no-r*) continue ;;
1146     -q | -quiet | --quiet | --quie | --qui | --qu | --q \
1147     | -silent | --silent | --silen | --sile | --sil)
1148       continue ;;
1149     *\'*)
1150       ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
1151     esac
1152     case $ac_pass in
1153     1) ac_configure_args0="$ac_configure_args0 '$ac_arg'" ;;
1154     2)
1155       ac_configure_args1="$ac_configure_args1 '$ac_arg'"
1156 dnl If trying to remove duplicates, be sure to (i) keep the *last*
1157 dnl value (e.g. --prefix=1 --prefix=2 --prefix=1 might keep 2 only),
1158 dnl and (ii) not to strip long options (--prefix foo --prefix bar might
1159 dnl give --prefix foo bar).
1160       if test $ac_must_keep_next = true; then
1161         ac_must_keep_next=false # Got value, back to normal.
1162       else
1163         case $ac_arg in
1164 dnl Use broad patterns, as arguments that would have already made configure
1165 dnl exit don't matter.
1166           *=* | --config-cache | -C | -disable-* | --disable-* \
1167           | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
1168           | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
1169           | -with-* | --with-* | -without-* | --without-* | --x)
1170             case "$ac_configure_args0 " in
1171               "$ac_configure_args1"*" '$ac_arg' "* ) continue ;;
1172             esac
1173             ;;
1174           -* ) ac_must_keep_next=true ;;
1175         esac
1176       fi
1177       ac_configure_args="$ac_configure_args '$ac_arg'"
1178       ;;
1179     esac
1180   done
1181 done
1182 AS_UNSET(ac_configure_args0)
1183 AS_UNSET(ac_configure_args1)
1184
1185 # When interrupted or exit'd, cleanup temporary files, and complete
1186 # config.log.  We remove comments because anyway the quotes in there
1187 # would cause problems or look ugly.
1188 # WARNING: Use '\'' to represent an apostrophe within the trap.
1189 # WARNING: Do not start the trap code with a newline, due to a FreeBSD 4.0 bug.
1190 trap 'exit_status=$?
1191   # Save into config.log some information that might help in debugging.
1192   {
1193     echo
1194
1195     AS_BOX([Cache variables.])
1196     echo
1197     m4_bpatsubsts(m4_defn([_AC_CACHE_DUMP]),
1198                   [^ *\(#.*\)?
1199 ],                [],
1200                   ['], ['\\''])
1201     echo
1202
1203     AS_BOX([Output variables.])
1204     echo
1205     for ac_var in $ac_subst_vars
1206     do
1207       eval ac_val=\$$ac_var
1208       case $ac_val in
1209       *\'\''*) ac_val=`echo "$ac_val" | sed "s/'\''/'\''\\\\\\\\'\'''\''/g"`;;
1210       esac
1211       echo "$ac_var='\''$ac_val'\''"
1212     done | sort
1213     echo
1214
1215     if test -n "$ac_subst_files"; then
1216       AS_BOX([File substitutions.])
1217       echo
1218       for ac_var in $ac_subst_files
1219       do
1220         eval ac_val=\$$ac_var
1221         case $ac_val in
1222         *\'\''*) ac_val=`echo "$ac_val" | sed "s/'\''/'\''\\\\\\\\'\'''\''/g"`;;
1223         esac
1224         echo "$ac_var='\''$ac_val'\''"
1225       done | sort
1226       echo
1227     fi
1228
1229     if test -s confdefs.h; then
1230       AS_BOX([confdefs.h.])
1231       echo
1232       cat confdefs.h
1233       echo
1234     fi
1235     test "$ac_signal" != 0 &&
1236       echo "$as_me: caught signal $ac_signal"
1237     echo "$as_me: exit $exit_status"
1238   } >&AS_MESSAGE_LOG_FD
1239   rm -f core *.core core.conftest.* &&
1240     rm -f -r conftest* confdefs* conf$[$]* $ac_clean_files &&
1241     exit $exit_status
1242 ' 0
1243 for ac_signal in 1 2 13 15; do
1244   trap 'ac_signal='$ac_signal'; AS_EXIT([1])' $ac_signal
1245 done
1246 ac_signal=0
1247
1248 # confdefs.h avoids OS command line length limits that DEFS can exceed.
1249 rm -f -r conftest* confdefs.h
1250 dnl AIX cpp loses on an empty file, NextStep 3.3 (patch 3) loses on a file
1251 dnl containing less than 14 bytes (including the newline).
1252 dnl But the defines below solve this problem.
1253
1254 # Predefined preprocessor variables.
1255 AC_DEFINE_UNQUOTED([PACKAGE_NAME], ["$PACKAGE_NAME"],
1256                    [Define to the full name of this package.])
1257 AC_DEFINE_UNQUOTED([PACKAGE_TARNAME], ["$PACKAGE_TARNAME"],
1258                    [Define to the one symbol short name of this package.])
1259 AC_DEFINE_UNQUOTED([PACKAGE_VERSION], ["$PACKAGE_VERSION"],
1260                    [Define to the version of this package.])
1261 AC_DEFINE_UNQUOTED([PACKAGE_STRING], ["$PACKAGE_STRING"],
1262                    [Define to the full name and version of this package.])
1263 AC_DEFINE_UNQUOTED([PACKAGE_BUGREPORT], ["$PACKAGE_BUGREPORT"],
1264                    [Define to the address where bug reports for this package
1265                     should be sent.])
1266
1267 # Let the site file select an alternate cache file if it wants to.
1268 AC_SITE_LOAD
1269 AC_CACHE_LOAD
1270 m4_divert_pop([INIT_PREPARE])dnl
1271 ])# _AC_INIT_PREPARE
1272
1273
1274 # AU::AC_INIT([UNIQUE-FILE-IN-SOURCE-DIR])
1275 # ----------------------------------------
1276 # This macro is used only for Autoupdate.
1277 AU_DEFUN([AC_INIT],
1278 [m4_ifval([$2], [[AC_INIT($@)]],
1279           [m4_ifval([$1],
1280 [[AC_INIT]
1281 AC_CONFIG_SRCDIR([$1])], [[AC_INIT]])])[]dnl
1282 ])
1283
1284
1285 # AC_INIT([PACKAGE, VERSION, [BUG-REPORT])
1286 # ----------------------------------------
1287 # Include the user macro files, prepare the diversions, and output the
1288 # preamble of the `configure' script.
1289 # Note that the order is important: first initialize, then set the
1290 # AC_CONFIG_SRCDIR.
1291 m4_define([AC_INIT],
1292 [# Forbidden tokens and exceptions.
1293 m4_pattern_forbid([^_?A[CHUM]_])
1294 m4_pattern_forbid([_AC_])
1295 m4_pattern_forbid([^LIBOBJS$],
1296                   [do not use LIBOBJS directly, use AC_LIBOBJ (see section `AC_LIBOBJ vs LIBOBJS'])
1297 # Actually reserved by M4sh.
1298 m4_pattern_allow([^AS_FLAGS$])
1299 AS_INIT
1300 AS_PREPARE
1301 m4_ifval([$2], [_AC_INIT_PACKAGE($@)])
1302 _AC_INIT_DEFAULTS
1303 _AC_INIT_PARSE_ARGS
1304 _AC_INIT_DIRCHECK
1305 _AC_INIT_SRCDIR
1306 _AC_INIT_HELP
1307 _AC_INIT_VERSION
1308 _AC_INIT_CONFIG_LOG
1309 _AC_INIT_PREPARE
1310 _AC_INIT_NOTICE
1311 _AC_INIT_COPYRIGHT
1312 m4_ifval([$2], , [m4_ifval([$1], [AC_CONFIG_SRCDIR([$1])])])dnl
1313 dnl
1314 dnl Substitute for predefined variables.
1315 AC_SUBST([DEFS])dnl
1316 AC_SUBST([ECHO_C])dnl
1317 AC_SUBST([ECHO_N])dnl
1318 AC_SUBST([ECHO_T])dnl
1319 AC_SUBST([LIBS])dnl
1320 _AC_ARG_VAR_PRECIOUS([build_alias])AC_SUBST([build_alias])dnl
1321 _AC_ARG_VAR_PRECIOUS([host_alias])AC_SUBST([host_alias])dnl
1322 _AC_ARG_VAR_PRECIOUS([target_alias])AC_SUBST([target_alias])dnl
1323 dnl
1324 AC_LANG_PUSH(C)
1325 ])
1326
1327
1328
1329
1330 ## ------------------------------------------------------------- ##
1331 ## Selecting optional features, working with optional software.  ##
1332 ## ------------------------------------------------------------- ##
1333
1334 # AC_PRESERVE_HELP_ORDER
1335 # ----------------------
1336 # Emit help strings in the order given, rather than grouping all --enable-FOO
1337 # and all --with-BAR.
1338 AC_DEFUN([AC_PRESERVE_HELP_ORDER],
1339 [m4_divert_once([HELP_ENABLE], [[
1340 Optional Features and Packages:
1341   --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
1342   --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
1343   --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]
1344   --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)]])
1345 m4_define([_m4_divert(HELP_ENABLE)],    _m4_divert(HELP_WITH))
1346 ])# AC_PRESERVE_HELP_ORDER
1347
1348 # _AC_ENABLE_IF(OPTION, FEATURE, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
1349 # -------------------------------------------------------------------
1350 # Common code for AC_ARG_ENABLE and AC_ARG_WITH.
1351 # OPTION is either "enable" or "with".
1352 #
1353 m4_define([_AC_ENABLE_IF],
1354 [# Check whether --$1-$2 was given.
1355 _AC_ENABLE_IF_ACTION([$1], m4_translit([$2], [-.], [__]), [$3], [$4])[]dnl
1356 ])
1357
1358 m4_define([_AC_ENABLE_IF_ACTION],
1359 [AS_IF([test "${$1_$2+set}" = set], [$1val=$$1_$2; $3], [$4])dnl
1360 ])
1361
1362 # AC_ARG_ENABLE(FEATURE, HELP-STRING, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
1363 # ------------------------------------------------------------------------
1364 AC_DEFUN([AC_ARG_ENABLE],
1365 [AC_PROVIDE_IFELSE([AC_PRESERVE_HELP_ORDER],
1366 [],
1367 [m4_divert_once([HELP_ENABLE], [[
1368 Optional Features:
1369   --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
1370   --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]]])])dnl
1371 m4_divert_once([HELP_ENABLE], [$2])dnl
1372 _AC_ENABLE_IF([enable], [$1], [$3], [$4])dnl
1373 ])# AC_ARG_ENABLE
1374
1375
1376 AU_DEFUN([AC_ENABLE],
1377 [AC_ARG_ENABLE([$1], [  --enable-$1], [$2], [$3])])
1378
1379
1380 # AC_ARG_WITH(PACKAGE, HELP-STRING, ACTION-IF-TRUE, [ACTION-IF-FALSE])
1381 # --------------------------------------------------------------------
1382 AC_DEFUN([AC_ARG_WITH],
1383 [AC_PROVIDE_IFELSE([AC_PRESERVE_HELP_ORDER],
1384 [],
1385 [m4_divert_once([HELP_WITH], [[
1386 Optional Packages:
1387   --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]
1388   --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)]])])
1389 m4_divert_once([HELP_WITH], [$2])dnl
1390 _AC_ENABLE_IF([with], [$1], [$3], [$4])dnl
1391 ])# AC_ARG_WITH
1392
1393 AU_DEFUN([AC_WITH],
1394 [AC_ARG_WITH([$1], [  --with-$1], [$2], [$3])])
1395
1396
1397
1398 ## ----------------------------------------- ##
1399 ## Remembering variables for reconfiguring.  ##
1400 ## ----------------------------------------- ##
1401
1402
1403 # AC_ARG_VAR(VARNAME, DOCUMENTATION)
1404 # ----------------------------------
1405 # Register VARNAME as a precious variable, and document it in
1406 # `configure --help' (but only once).
1407 AC_DEFUN([AC_ARG_VAR],
1408 [m4_divert_once([HELP_VAR], [[
1409 Some influential environment variables:]])dnl
1410 m4_divert_once([HELP_VAR_END], [[
1411 Use these variables to override the choices made by `configure' or to help
1412 it to find libraries and programs with nonstandard names/locations.]])dnl
1413 m4_expand_once([m4_divert_text([HELP_VAR],
1414                                [AS_HELP_STRING([$1], [$2], [              ])])],
1415                [$0($1)])dnl
1416 AC_SUBST([$1])dnl
1417 _AC_ARG_VAR_PRECIOUS([$1])dnl
1418 ])# AC_ARG_VAR
1419
1420
1421 # _AC_ARG_VAR_PRECIOUS(VARNAME)
1422 # -----------------------------
1423 # Declare VARNAME is precious.
1424 m4_define([_AC_ARG_VAR_PRECIOUS],
1425 [m4_append_uniq([_AC_PRECIOUS_VARS], [$1], [
1426 ])dnl
1427 ])
1428
1429
1430 # _AC_ARG_VAR_STORE
1431 # -----------------
1432 # We try to diagnose when precious variables have changed.  To do this,
1433 # make two early snapshots (after the option processing to take
1434 # explicit variables into account) of those variables: one (ac_env_)
1435 # which represents the current run, and a second (ac_cv_env_) which,
1436 # at the first run, will be saved in the cache.  As an exception to
1437 # the cache mechanism, its loading will override these variables (non
1438 # `ac_cv_env_' cache value are only set when unset).
1439 #
1440 # In subsequent runs, after having loaded the cache, compare
1441 # ac_cv_env_foo against ac_env_foo.  See _AC_ARG_VAR_VALIDATE.
1442 m4_define([_AC_ARG_VAR_STORE],
1443 [m4_divert_text([PARSE_ARGS],
1444 [for ac_var in $ac_precious_vars; do
1445   eval ac_env_${ac_var}_set=\${${ac_var}+set}
1446   eval ac_env_${ac_var}_value=\$${ac_var}
1447   eval ac_cv_env_${ac_var}_set=\${${ac_var}+set}
1448   eval ac_cv_env_${ac_var}_value=\$${ac_var}
1449 done])dnl
1450 ])
1451
1452
1453 # _AC_ARG_VAR_VALIDATE
1454 # --------------------
1455 # The precious variables are saved twice at the beginning of
1456 # configure.  E.g., PRECIOUS is saved as `ac_env_PRECIOUS_set' and
1457 # `ac_env_PRECIOUS_value' on the one hand and `ac_cv_env_PRECIOUS_set'
1458 # and `ac_cv_env_PRECIOUS_value' on the other hand.
1459 #
1460 # Now the cache has just been loaded, so `ac_cv_env_' represents the
1461 # content of the cached values, while `ac_env_' represents that of the
1462 # current values.
1463 #
1464 # So we check that `ac_env_' and `ac_cv_env_' are consistent.  If
1465 # they aren't, die.
1466 m4_define([_AC_ARG_VAR_VALIDATE],
1467 [m4_divert_text([INIT_PREPARE],
1468 [# Check that the precious variables saved in the cache have kept the same
1469 # value.
1470 ac_cache_corrupted=false
1471 for ac_var in $ac_precious_vars; do
1472   eval ac_old_set=\$ac_cv_env_${ac_var}_set
1473   eval ac_new_set=\$ac_env_${ac_var}_set
1474   eval ac_old_val=\$ac_cv_env_${ac_var}_value
1475   eval ac_new_val=\$ac_env_${ac_var}_value
1476   case $ac_old_set,$ac_new_set in
1477     set,)
1478       AS_MESSAGE([error: `$ac_var' was set to `$ac_old_val' in the previous run], 2)
1479       ac_cache_corrupted=: ;;
1480     ,set)
1481       AS_MESSAGE([error: `$ac_var' was not set in the previous run], 2)
1482       ac_cache_corrupted=: ;;
1483     ,);;
1484     *)
1485       if test "x$ac_old_val" != "x$ac_new_val"; then
1486         AS_MESSAGE([error: `$ac_var' has changed since the previous run:], 2)
1487         AS_MESSAGE([  former value:  $ac_old_val], 2)
1488         AS_MESSAGE([  current value: $ac_new_val], 2)
1489         ac_cache_corrupted=:
1490       fi;;
1491   esac
1492   # Pass precious variables to config.status.
1493   if test "$ac_new_set" = set; then
1494     case $ac_new_val in
1495     *\'*) ac_arg=$ac_var=`echo "$ac_new_val" | sed "s/'/'\\\\\\\\''/g"` ;;
1496     *) ac_arg=$ac_var=$ac_new_val ;;
1497     esac
1498     case " $ac_configure_args " in
1499       *" '$ac_arg' "*) ;; # Avoid dups.  Use of quotes ensures accuracy.
1500       *) ac_configure_args="$ac_configure_args '$ac_arg'" ;;
1501     esac
1502   fi
1503 done
1504 if $ac_cache_corrupted; then
1505   AS_MESSAGE([error: changes in the environment can compromise the build], 2)
1506   AS_ERROR([run `make distclean' and/or `rm $cache_file' and start over])
1507 fi])dnl
1508 ])# _AC_ARG_VAR_VALIDATE
1509
1510
1511
1512
1513
1514 ## ---------------------------- ##
1515 ## Transforming program names.  ##
1516 ## ---------------------------- ##
1517
1518
1519 # AC_ARG_PROGRAM
1520 # --------------
1521 # This macro is expanded only once, to avoid that `foo' ends up being
1522 # installed as `ggfoo'.
1523 AC_DEFUN_ONCE([AC_ARG_PROGRAM],
1524 [dnl Document the options.
1525 m4_divert_push([HELP_BEGIN])dnl
1526
1527 Program names:
1528   --program-prefix=PREFIX            prepend PREFIX to installed program names
1529   --program-suffix=SUFFIX            append SUFFIX to installed program names
1530   --program-transform-name=PROGRAM   run sed PROGRAM on installed program names
1531 m4_divert_pop([HELP_BEGIN])dnl
1532 test "$program_prefix" != NONE &&
1533   program_transform_name="s&^&$program_prefix&;$program_transform_name"
1534 # Use a double $ so make ignores it.
1535 test "$program_suffix" != NONE &&
1536   program_transform_name="s&\$&$program_suffix&;$program_transform_name"
1537 # Double any \ or $.  echo might interpret backslashes.
1538 # By default was `s,x,x', remove it if useless.
1539 cat <<\_ACEOF >conftest.sed
1540 [s/[\\$]/&&/g;s/;s,x,x,$//]
1541 _ACEOF
1542 program_transform_name=`echo $program_transform_name | sed -f conftest.sed`
1543 rm -f conftest.sed
1544 ])# AC_ARG_PROGRAM
1545
1546
1547
1548
1549
1550 ## ------------------------- ##
1551 ## Finding auxiliary files.  ##
1552 ## ------------------------- ##
1553
1554
1555 # AC_CONFIG_AUX_DIR(DIR)
1556 # ----------------------
1557 # Find install-sh, config.sub, config.guess, and Cygnus configure
1558 # in directory DIR.  These are auxiliary files used in configuration.
1559 # DIR can be either absolute or relative to $srcdir.
1560 AC_DEFUN([AC_CONFIG_AUX_DIR],
1561 [AC_CONFIG_AUX_DIRS($1 "$srcdir"/$1)])
1562
1563
1564 # AC_CONFIG_AUX_DIR_DEFAULT
1565 # -------------------------
1566 # The default is `$srcdir' or `$srcdir/..' or `$srcdir/../..'.
1567 # There's no need to call this macro explicitly; just AC_REQUIRE it.
1568 AC_DEFUN([AC_CONFIG_AUX_DIR_DEFAULT],
1569 [AC_CONFIG_AUX_DIRS("$srcdir" "$srcdir/.." "$srcdir/../..")])
1570
1571
1572 # AC_CONFIG_AUX_DIRS(DIR ...)
1573 # ---------------------------
1574 # Internal subroutine.
1575 # Search for the configuration auxiliary files in directory list $1.
1576 # We look only for install-sh, so users of AC_PROG_INSTALL
1577 # do not automatically need to distribute the other auxiliary files.
1578 AC_DEFUN([AC_CONFIG_AUX_DIRS],
1579 [ac_aux_dir=
1580 for ac_dir in $1; do
1581   if test -f "$ac_dir/install-sh"; then
1582     ac_aux_dir=$ac_dir
1583     ac_install_sh="$ac_aux_dir/install-sh -c"
1584     break
1585   elif test -f "$ac_dir/install.sh"; then
1586     ac_aux_dir=$ac_dir
1587     ac_install_sh="$ac_aux_dir/install.sh -c"
1588     break
1589   elif test -f "$ac_dir/shtool"; then
1590     ac_aux_dir=$ac_dir
1591     ac_install_sh="$ac_aux_dir/shtool install -c"
1592     break
1593   fi
1594 done
1595 if test -z "$ac_aux_dir"; then
1596   AC_MSG_ERROR([cannot find install-sh or install.sh in $1])
1597 fi
1598
1599 # These three variables are undocumented and unsupported,
1600 # and are intended to be withdrawn in a future Autoconf release.
1601 # They can cause serious problems if a builder's source tree is in a directory
1602 # whose full name contains unusual characters.
1603 ac_config_guess="$SHELL $ac_aux_dir/config.guess"  # Please don't use this var.
1604 ac_config_sub="$SHELL $ac_aux_dir/config.sub"  # Please don't use this var.
1605 ac_configure="$SHELL $ac_aux_dir/configure"  # Please don't use this var.
1606
1607 AC_PROVIDE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
1608 ])# AC_CONFIG_AUX_DIRS
1609
1610
1611
1612
1613 ## ------------------------ ##
1614 ## Finding aclocal macros.  ##
1615 ## ------------------------ ##
1616
1617
1618 # AC_CONFIG_MACRO_DIR(DIR)
1619 # ------------------------
1620 # Declare directory containing additional macros for aclocal.
1621 AC_DEFUN([AC_CONFIG_MACRO_DIR], [])
1622
1623
1624
1625 ## --------------------- ##
1626 ## Requiring aux files.  ##
1627 ## --------------------- ##
1628
1629 # AC_REQUIRE_AUX_FILE(FILE)
1630 # -------------------------
1631 # This macro does nothing, it's a hook to be read with `autoconf --trace'.
1632 # It announces FILE is required in the auxdir.
1633 m4_define([AC_REQUIRE_AUX_FILE],
1634 [AS_LITERAL_IF([$1], [],
1635                [AC_FATAL([$0: requires a literal argument])])])
1636
1637
1638
1639 ## ----------------------------------- ##
1640 ## Getting the canonical system type.  ##
1641 ## ----------------------------------- ##
1642
1643 # The inputs are:
1644 #    configure --host=HOST --target=TARGET --build=BUILD
1645 #
1646 # The rules are:
1647 # 1. Build defaults to the current platform, as determined by config.guess.
1648 # 2. Host defaults to build.
1649 # 3. Target defaults to host.
1650
1651
1652 # _AC_CANONICAL_SPLIT(THING)
1653 # --------------------------
1654 # Generate the variables THING, THING_{alias cpu vendor os}.
1655 m4_define([_AC_CANONICAL_SPLIT],
1656 [case $ac_cv_$1 in
1657 *-*-*) ;;
1658 *) AC_MSG_ERROR([invalid value of canonical $1]);;
1659 esac
1660 AC_SUBST([$1], [$ac_cv_$1])dnl
1661 ac_save_IFS=$IFS; IFS='-'
1662 set x $ac_cv_$1
1663 shift
1664 AC_SUBST([$1_cpu], [$[1]])dnl
1665 AC_SUBST([$1_vendor], [$[2]])dnl
1666 shift; shift
1667 [# Remember, the first character of IFS is used to create $]*,
1668 # except with old shells:
1669 $1_os=$[*]
1670 IFS=$ac_save_IFS
1671 case $$1_os in *\ *) $1_os=`echo "$$1_os" | sed 's/ /-/g'`;; esac
1672 AC_SUBST([$1_os])dnl
1673 ])# _AC_CANONICAL_SPLIT
1674
1675
1676 # AC_CANONICAL_BUILD
1677 # ------------------
1678 AC_DEFUN([AC_CANONICAL_BUILD],
1679 [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
1680 AC_REQUIRE_AUX_FILE([config.sub])dnl
1681 AC_REQUIRE_AUX_FILE([config.guess])dnl
1682 m4_divert_once([HELP_CANON],
1683 [[
1684 System types:
1685   --build=BUILD     configure for building on BUILD [guessed]]])dnl
1686 # Make sure we can run config.sub.
1687 $SHELL "$ac_aux_dir/config.sub" sun4 >/dev/null 2>&1 ||
1688   AC_MSG_ERROR([cannot run $SHELL $ac_aux_dir/config.sub])
1689
1690 AC_CACHE_CHECK([build system type], [ac_cv_build],
1691 [ac_build_alias=$build_alias
1692 test "x$ac_build_alias" = x &&
1693   ac_build_alias=`$SHELL "$ac_aux_dir/config.guess"`
1694 test "x$ac_build_alias" = x &&
1695   AC_MSG_ERROR([cannot guess build type; you must specify one])
1696 ac_cv_build=`$SHELL "$ac_aux_dir/config.sub" $ac_build_alias` ||
1697   AC_MSG_ERROR([$SHELL $ac_aux_dir/config.sub $ac_build_alias failed])
1698 ])
1699 _AC_CANONICAL_SPLIT(build)
1700 ])# AC_CANONICAL_BUILD
1701
1702
1703 # AC_CANONICAL_HOST
1704 # -----------------
1705 AC_DEFUN([AC_CANONICAL_HOST],
1706 [AC_REQUIRE([AC_CANONICAL_BUILD])dnl
1707 m4_divert_once([HELP_CANON],
1708 [[  --host=HOST       cross-compile to build programs to run on HOST [BUILD]]])dnl
1709 AC_CACHE_CHECK([host system type], [ac_cv_host],
1710 [if test "x$host_alias" = x; then
1711   ac_cv_host=$ac_cv_build
1712 else
1713   ac_cv_host=`$SHELL "$ac_aux_dir/config.sub" $host_alias` ||
1714     AC_MSG_ERROR([$SHELL $ac_aux_dir/config.sub $host_alias failed])
1715 fi
1716 ])
1717 _AC_CANONICAL_SPLIT([host])
1718 ])# AC_CANONICAL_HOST
1719
1720
1721 # AC_CANONICAL_TARGET
1722 # -------------------
1723 AC_DEFUN([AC_CANONICAL_TARGET],
1724 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
1725 AC_BEFORE([$0], [AC_ARG_PROGRAM])dnl
1726 m4_divert_once([HELP_CANON],
1727 [[  --target=TARGET   configure for building compilers for TARGET [HOST]]])dnl
1728 AC_CACHE_CHECK([target system type], [ac_cv_target],
1729 [if test "x$target_alias" = x; then
1730   ac_cv_target=$ac_cv_host
1731 else
1732   ac_cv_target=`$SHELL "$ac_aux_dir/config.sub" $target_alias` ||
1733     AC_MSG_ERROR([$SHELL $ac_aux_dir/config.sub $target_alias failed])
1734 fi
1735 ])
1736 _AC_CANONICAL_SPLIT([target])
1737
1738 # The aliases save the names the user supplied, while $host etc.
1739 # will get canonicalized.
1740 test -n "$target_alias" &&
1741   test "$program_prefix$program_suffix$program_transform_name" = \
1742     NONENONEs,x,x, &&
1743   program_prefix=${target_alias}-[]dnl
1744 ])# AC_CANONICAL_TARGET
1745
1746
1747 AU_ALIAS([AC_CANONICAL_SYSTEM], [AC_CANONICAL_TARGET])
1748
1749
1750 # AU::AC_VALIDATE_CACHED_SYSTEM_TUPLE([CMD])
1751 # ------------------------------------------
1752 # If the cache file is inconsistent with the current host,
1753 # target and build system types, execute CMD or print a default
1754 # error message.  Now handled via _AC_ARG_VAR_PRECIOUS.
1755 AU_DEFUN([AC_VALIDATE_CACHED_SYSTEM_TUPLE], [])
1756
1757
1758 ## ---------------------- ##
1759 ## Caching test results.  ##
1760 ## ---------------------- ##
1761
1762
1763 # AC_SITE_LOAD
1764 # ------------
1765 # Look for site or system specific initialization scripts.
1766 m4_define([AC_SITE_LOAD],
1767 [# Prefer explicitly selected file to automatically selected ones.
1768 if test -n "$CONFIG_SITE"; then
1769   set x "$CONFIG_SITE"
1770 elif test "x$prefix" != xNONE; then
1771   set x "$prefix/share/config.site" "$prefix/etc/config.site"
1772 else
1773   set x "$ac_default_prefix/share/config.site" \
1774         "$ac_default_prefix/etc/config.site"
1775 fi
1776 shift
1777 for ac_site_file
1778 do
1779   if test -r "$ac_site_file"; then
1780     AC_MSG_NOTICE([loading site script $ac_site_file])
1781     sed 's/^/| /' "$ac_site_file" >&AS_MESSAGE_LOG_FD
1782     . "$ac_site_file"
1783   fi
1784 done
1785 ])
1786
1787
1788 # AC_CACHE_LOAD
1789 # -------------
1790 m4_define([AC_CACHE_LOAD],
1791 [if test -r "$cache_file"; then
1792   # Some versions of bash will fail to source /dev/null (special
1793   # files actually), so we avoid doing that.
1794   if test -f "$cache_file"; then
1795     AC_MSG_NOTICE([loading cache $cache_file])
1796     case $cache_file in
1797       [[\\/]]* | ?:[[\\/]]* ) . "$cache_file";;
1798       *)                      . "./$cache_file";;
1799     esac
1800   fi
1801 else
1802   AC_MSG_NOTICE([creating cache $cache_file])
1803   >$cache_file
1804 fi
1805 ])# AC_CACHE_LOAD
1806
1807
1808 # _AC_CACHE_DUMP
1809 # --------------
1810 # Dump the cache to stdout.  It can be in a pipe (this is a requirement).
1811 m4_define([_AC_CACHE_DUMP],
1812 [# The following way of writing the cache mishandles newlines in values,
1813 # but we know of no workaround that is simple, portable, and efficient.
1814 # So, we kill variables containing newlines.
1815 # Ultrix sh set writes to stderr and can't be redirected directly,
1816 # and sets the high bit in the cache file unless we assign to the vars.
1817 (
1818   for ac_var in `(set) 2>&1 | sed -n ['s/^\([a-zA-Z_][a-zA-Z0-9_]*\)=.*/\1/p']`; do
1819     eval ac_val=\$$ac_var
1820     case $ac_val in #(
1821     *${as_nl}*)
1822       case $ac_var in #(
1823       *_cv_*) AC_MSG_WARN([Cache variable $ac_var contains a newline.]) ;;
1824       esac
1825       case $ac_var in #(
1826       _ | IFS | as_nl) ;; #(
1827       *) $as_unset $ac_var ;;
1828       esac ;;
1829     esac
1830   done
1831
1832   (set) 2>&1 |
1833     case $as_nl`(ac_space=' '; set) 2>&1` in #(
1834     *${as_nl}ac_space=\ *)
1835       # `set' does not quote correctly, so add quotes (double-quote
1836       # substitution turns \\\\ into \\, and sed turns \\ into \).
1837       sed -n \
1838         ["s/'/'\\\\''/g;
1839           s/^\\([_$as_cr_alnum]*_cv_[_$as_cr_alnum]*\\)=\\(.*\\)/\\1='\\2'/p"]
1840       ;; #(
1841     *)
1842       # `set' quotes correctly as required by POSIX, so do not add quotes.
1843       sed -n ["/^[_$as_cr_alnum]*_cv_[_$as_cr_alnum]*=/p"]
1844       ;;
1845     esac |
1846     sort
1847 )dnl
1848 ])# _AC_CACHE_DUMP
1849
1850
1851 # AC_CACHE_SAVE
1852 # -------------
1853 # Save the cache.
1854 # Allow a site initialization script to override cache values.
1855 m4_define([AC_CACHE_SAVE],
1856 [cat >confcache <<\_ACEOF
1857 # This file is a shell script that caches the results of configure
1858 # tests run on this system so they can be shared between configure
1859 # scripts and configure runs, see configure's option --config-cache.
1860 # It is not useful on other systems.  If it contains results you don't
1861 # want to keep, you may remove or edit it.
1862 #
1863 # config.status only pays attention to the cache file if you give it
1864 # the --recheck option to rerun configure.
1865 #
1866 # `ac_cv_env_foo' variables (set or unset) will be overridden when
1867 # loading this file, other *unset* `ac_cv_foo' will be assigned the
1868 # following values.
1869
1870 _ACEOF
1871
1872 _AC_CACHE_DUMP() |
1873   sed ['
1874      /^ac_cv_env_/b end
1875      t clear
1876      :clear
1877      s/^\([^=]*\)=\(.*[{}].*\)$/test "${\1+set}" = set || &/
1878      t end
1879      s/^\([^=]*\)=\(.*\)$/\1=${\1=\2}/
1880      :end'] >>confcache
1881 if diff "$cache_file" confcache >/dev/null 2>&1; then :; else
1882   if test -w "$cache_file"; then
1883     test "x$cache_file" != "x/dev/null" &&
1884       AC_MSG_NOTICE([updating cache $cache_file])
1885     cat confcache >$cache_file
1886   else
1887     AC_MSG_NOTICE([not updating unwritable cache $cache_file])
1888   fi
1889 fi
1890 rm -f confcache[]dnl
1891 ])# AC_CACHE_SAVE
1892
1893
1894 # AC_CACHE_VAL(CACHE-ID, COMMANDS-TO-SET-IT)
1895 # ------------------------------------------
1896 # The name of shell var CACHE-ID must contain `_cv_' in order to get saved.
1897 # Should be dnl'ed.  Try to catch common mistakes.
1898 m4_defun([AC_CACHE_VAL],
1899 [m4_bmatch([$2], [AC_DEFINE],
1900            [AC_DIAGNOSE([syntax],
1901 [$0($1, ...): suspicious presence of an AC_DEFINE in the second argument, ]dnl
1902 [where no actions should be taken])])dnl
1903 AS_VAR_SET_IF([$1],
1904               [_AS_ECHO_N([(cached) ])],
1905               [$2])])
1906
1907
1908 # AC_CACHE_CHECK(MESSAGE, CACHE-ID, COMMANDS)
1909 # -------------------------------------------
1910 # Do not call this macro with a dnl right behind.
1911 m4_defun([AC_CACHE_CHECK],
1912 [AC_MSG_CHECKING([$1])
1913 AC_CACHE_VAL([$2], [$3])dnl
1914 AS_LITERAL_IF([$2],
1915               [AC_MSG_RESULT([$$2])],
1916               [ac_res=AS_VAR_GET([$2])
1917                AC_MSG_RESULT([$ac_res])])dnl
1918 ])
1919
1920 # _AC_CACHE_CHECK_INT(MESSAGE, CACHE-ID, EXPRESSION,
1921 #                     [PROLOGUE = DEFAULT-INCLUDES], [IF-FAILS])
1922 # -------------------------------------------------------------
1923 AC_DEFUN([_AC_CACHE_CHECK_INT],
1924 [AC_CACHE_CHECK([$1], [$2],
1925    [AC_COMPUTE_INT([$2], [$3], [$4], [$5])])
1926 ])# _AC_CACHE_CHECK_INT
1927
1928
1929
1930 ## ---------------------- ##
1931 ## Defining CPP symbols.  ##
1932 ## ---------------------- ##
1933
1934
1935 # AC_DEFINE_TRACE_LITERAL(LITERAL-CPP-SYMBOL)
1936 # -------------------------------------------
1937 # Used by --trace to collect the list of AC_DEFINEd macros.
1938 m4_define([AC_DEFINE_TRACE_LITERAL],
1939 [m4_pattern_allow([^$1$])])
1940
1941
1942 # AC_DEFINE_TRACE(CPP-SYMBOL)
1943 # ---------------------------
1944 # This macro is a wrapper around AC_DEFINE_TRACE_LITERAL which filters
1945 # out non literal symbols.
1946 m4_define([AC_DEFINE_TRACE],
1947 [AS_LITERAL_IF([$1], [AC_DEFINE_TRACE_LITERAL([$1])])])
1948
1949
1950 # AC_DEFINE(VARIABLE, [VALUE], [DESCRIPTION])
1951 # -------------------------------------------
1952 # Set VARIABLE to VALUE, verbatim, or 1.  Remember the value
1953 # and if VARIABLE is affected the same VALUE, do nothing, else
1954 # die.  The third argument is used by autoheader.
1955 m4_define([AC_DEFINE], [_AC_DEFINE_Q([\], $@)])
1956
1957
1958 # AC_DEFINE_UNQUOTED(VARIABLE, [VALUE], [DESCRIPTION])
1959 # ----------------------------------------------------
1960 # Similar, but perform shell substitutions $ ` \ once on VALUE.
1961 m4_define([AC_DEFINE_UNQUOTED], [_AC_DEFINE_Q([], $@)])
1962
1963
1964 # _AC_DEFINE_Q(QUOTE, VARIABLE, [VALUE], [DESCRIPTION])
1965 # -----------------------------------------------------
1966 m4_define([_AC_DEFINE_Q],
1967 [AC_DEFINE_TRACE([$2])dnl
1968 m4_ifval([$4], [AH_TEMPLATE(m4_bpatsubst([[$2]], [(.*)]), [$4])])dnl
1969 cat >>confdefs.h <<$1_ACEOF
1970 [@%:@define] $2 m4_if($#, 2, 1, [$3])
1971 _ACEOF
1972 ])
1973
1974
1975
1976 ## -------------------------- ##
1977 ## Setting output variables.  ##
1978 ## -------------------------- ##
1979
1980
1981 # AC_SUBST_TRACE(VARIABLE)
1982 # ------------------------
1983 # This macro is used with --trace to collect the list of substituted variables.
1984 m4_define([AC_SUBST_TRACE])
1985
1986
1987 # AC_SUBST(VARIABLE, [VALUE])
1988 # ---------------------------
1989 # Create an output variable from a shell VARIABLE.  If VALUE is given
1990 # assign it to VARIABLE.  Use `""' is you want to set VARIABLE to an
1991 # empty value, not an empty second argument.
1992 #
1993 m4_define([AC_SUBST],
1994 [AC_SUBST_TRACE([$1])dnl
1995 m4_pattern_allow([^$1$])dnl
1996 m4_ifvaln([$2], [$1=$2])[]dnl
1997 m4_append_uniq([_AC_SUBST_VARS], [$1], [
1998 ])dnl
1999 ])# AC_SUBST
2000
2001
2002 # AC_SUBST_FILE(VARIABLE)
2003 # -----------------------
2004 # Read the comments of the preceding macro.
2005 m4_define([AC_SUBST_FILE],
2006 [m4_pattern_allow([^$1$])dnl
2007 m4_append_uniq([_AC_SUBST_FILES], [$1], [
2008 ])])
2009
2010
2011
2012 ## --------------------------------------- ##
2013 ## Printing messages at autoconf runtime.  ##
2014 ## --------------------------------------- ##
2015
2016 # In fact, I think we should promote the use of m4_warn and m4_fatal
2017 # directly.  This will also avoid to some people to get it wrong
2018 # between AC_FATAL and AC_MSG_ERROR.
2019
2020
2021 # AC_DIAGNOSE(CATEGORY, MESSAGE)
2022 # AC_FATAL(MESSAGE, [EXIT-STATUS])
2023 # --------------------------------
2024 m4_define([AC_DIAGNOSE], [m4_warn($@)])
2025 m4_define([AC_FATAL],    [m4_fatal($@)])
2026
2027
2028 # AC_WARNING(MESSAGE)
2029 # -------------------
2030 # Report a MESSAGE to the user of autoconf if `-W' or `-W all' was
2031 # specified.
2032 m4_define([AC_WARNING],
2033 [AC_DIAGNOSE([syntax], [$1])])
2034
2035
2036
2037
2038 ## ---------------------------------------- ##
2039 ## Printing messages at configure runtime.  ##
2040 ## ---------------------------------------- ##
2041
2042
2043 # AC_MSG_CHECKING(FEATURE)
2044 # ------------------------
2045 m4_define([AC_MSG_CHECKING],
2046 [{ _AS_ECHO_LOG([checking $1])
2047 _AS_ECHO_N([checking $1... ]); }dnl
2048 ])
2049
2050
2051 # AC_MSG_RESULT(RESULT)
2052 # ---------------------
2053 m4_define([AC_MSG_RESULT],
2054 [{ _AS_ECHO_LOG([result: $1])
2055 _AS_ECHO([${ECHO_T}$1]); }dnl
2056 ])
2057
2058
2059 # AC_MSG_WARN(PROBLEM)
2060 # AC_MSG_NOTICE(STRING)
2061 # AC_MSG_ERROR(ERROR, [EXIT-STATUS = 1])
2062 # AC_MSG_FAILURE(ERROR, [EXIT-STATUS = 1])
2063 # ----------------------------------------
2064 m4_copy([AS_WARN],    [AC_MSG_WARN])
2065 m4_copy([AS_MESSAGE], [AC_MSG_NOTICE])
2066 m4_copy([AS_ERROR],   [AC_MSG_ERROR])
2067 m4_define([AC_MSG_FAILURE],
2068 [AC_MSG_ERROR([$1
2069 See `config.log' for more details.], [$2])])
2070
2071
2072 # _AC_MSG_LOG_CONFTEST
2073 # --------------------
2074 m4_define([_AC_MSG_LOG_CONFTEST],
2075 [echo "$as_me: failed program was:" >&AS_MESSAGE_LOG_FD
2076 sed 's/^/| /' conftest.$ac_ext >&AS_MESSAGE_LOG_FD
2077 ])
2078
2079
2080 # AU::AC_CHECKING(FEATURE)
2081 # ------------------------
2082 AU_DEFUN([AC_CHECKING],
2083 [AS_MESSAGE([checking $1...])])
2084
2085
2086 # AU::AC_MSG_RESULT_UNQUOTED(RESULT)
2087 # ----------------------------------
2088 # No escaping, so it performed also backtick substitution.
2089 AU_DEFUN([AC_MSG_RESULT_UNQUOTED],
2090 [_AS_ECHO_UNQUOTED([$as_me:$LINENO: result: $1], AS_MESSAGE_LOG_FD)
2091 _AS_ECHO_UNQUOTED([${ECHO_T}$1])[]dnl
2092 ])
2093
2094
2095 # AU::AC_VERBOSE(STRING)
2096 # ----------------------
2097 AU_ALIAS([AC_VERBOSE], [AC_MSG_RESULT])
2098
2099
2100
2101
2102
2103
2104 ## ---------------------------- ##
2105 ## Compiler-running mechanics.  ##
2106 ## ---------------------------- ##
2107
2108
2109 # _AC_RUN_LOG(COMMAND, LOG-COMMANDS)
2110 # ----------------------------------
2111 # Eval COMMAND, save the exit status in ac_status, and log it.
2112 AC_DEFUN([_AC_RUN_LOG],
2113 [{ ($2) >&AS_MESSAGE_LOG_FD
2114   ($1) 2>&AS_MESSAGE_LOG_FD
2115   ac_status=$?
2116   _AS_ECHO_LOG([\$? = $ac_status])
2117   (exit $ac_status); }])
2118
2119
2120 # _AC_RUN_LOG_STDERR(COMMAND, LOG-COMMANDS)
2121 # -----------------------------------------
2122 # Run COMMAND, save its stderr into conftest.err, save the exit status
2123 # in ac_status, and log it.  Don't forget to clean up conftest.err after
2124 # use.
2125 # Note that when tracing, most shells will leave the traces in stderr
2126 # starting with "+": that's what this macro tries to address.
2127 AC_DEFUN([_AC_RUN_LOG_STDERR],
2128 [{ ($2) >&AS_MESSAGE_LOG_FD
2129   ($1) 2>conftest.er1
2130   ac_status=$?
2131   grep -v '^ *+' conftest.er1 >conftest.err
2132   rm -f conftest.er1
2133   cat conftest.err >&AS_MESSAGE_LOG_FD
2134   _AS_ECHO_LOG([\$? = $ac_status])
2135   (exit $ac_status); }])
2136
2137 # _AC_DO_ECHO(COMMAND)
2138 # --------------------
2139 # Echo COMMAND.  This is designed to be used just before evaluating COMMAND.
2140 AC_DEFUN([_AC_DO_ECHO],
2141 [m4_if([$1], [$ac_try], [], [ac_try="$1"
2142 ])dnl
2143 dnl If the string contains '"', '`', or '\', then just echo it rather
2144 dnl than expanding it.  This is a hack, but it is safer, while also
2145 dnl typically expanding simple substrings like '$CC', which is what we want.
2146 dnl
2147 dnl The rest of this macro body is quoted, to work around misuses like
2148 dnl `AC_CHECK_FUNC(sigblock, , AC_CHECK_LIB(bsd, sigblock))',
2149 dnl which underquotes the 3rd arg and would misbehave if we didn't quote here.
2150 dnl The "(($ac_try" instead of $ac_try avoids problems with even-worse
2151 dnl underquoting misuses, such as
2152 dnl `AC_CHECK_FUNC(foo, , AC_CHECK_LIB(a, foo, , AC_CHECK_LIB(b, foo)))'.
2153 dnl We normally wouldn't bother with this kind of workaround for invalid code
2154 dnl but this change was put in just before Autoconf 2.60 and we wanted to
2155 dnl minimize the integration hassle.
2156 [case "(($ac_try" in
2157   *\"* | *\`* | *\\*) ac_try_echo=\$ac_try;;
2158   *) ac_try_echo=$ac_try;;
2159 esac
2160 eval "echo \"\$as_me:$LINENO: $ac_try_echo\""]])
2161
2162 # _AC_DO(COMMAND)
2163 # ---------------
2164 # Eval COMMAND, save the exit status in ac_status, and log it.
2165 # For internal use only.
2166 AC_DEFUN([_AC_DO],
2167 [_AC_RUN_LOG([eval "$1"],
2168              [_AC_DO_ECHO([$1])])])
2169
2170
2171 # _AC_DO_STDERR(COMMAND)
2172 # ----------------------
2173 # Like _AC_RUN_LOG_STDERR, but eval (instead of running) COMMAND.
2174 AC_DEFUN([_AC_DO_STDERR],
2175 [_AC_RUN_LOG_STDERR([eval "$1"],
2176                     [_AC_DO_ECHO([$1])])])
2177
2178
2179 # _AC_DO_VAR(VARIABLE)
2180 # --------------------
2181 # Evaluate "$VARIABLE", which should be a valid shell command.
2182 # The purpose of this macro is to write "configure:123: command line"
2183 # into config.log for every test run.
2184 AC_DEFUN([_AC_DO_VAR],
2185 [_AC_DO([$$1])])
2186
2187
2188 # _AC_DO_TOKENS(COMMAND)
2189 # ----------------------
2190 # Like _AC_DO_VAR, but execute COMMAND instead, where COMMAND is a series of
2191 # tokens of the shell command language.
2192 AC_DEFUN([_AC_DO_TOKENS],
2193 [{ ac_try='$1'
2194   _AC_DO([$ac_try]); }])
2195
2196
2197 # _AC_EVAL(COMMAND)
2198 # -----------------
2199 # Eval COMMAND, save the exit status in ac_status, and log it.
2200 # Unlike _AC_DO, this macro mishandles quoted arguments in some cases.
2201 # It is present only for backward compatibility with previous Autoconf versions.
2202 AC_DEFUN([_AC_EVAL],
2203 [_AC_RUN_LOG([eval $1],
2204              [eval echo "$as_me:$LINENO: \"$1\""])])
2205
2206
2207 # _AC_EVAL_STDERR(COMMAND)
2208 # ------------------------
2209 # Like _AC_RUN_LOG_STDERR, but eval (instead of running) COMMAND.
2210 # Unlike _AC_DO_STDERR, this macro mishandles quoted arguments in some cases.
2211 # It is present only for backward compatibility with previous Autoconf versions.
2212 AC_DEFUN([_AC_EVAL_STDERR],
2213 [_AC_RUN_LOG_STDERR([eval $1],
2214                     [eval echo "$as_me:$LINENO: \"$1\""])])
2215
2216
2217 # AC_TRY_EVAL(VARIABLE)
2218 # ---------------------
2219 # Evaluate $VARIABLE, which should be a valid shell command.
2220 # The purpose of this macro is to write "configure:123: command line"
2221 # into config.log for every test run.
2222 #
2223 # The AC_TRY_EVAL and AC_TRY_COMMAND macros are dangerous and
2224 # undocumented, and should not be used.
2225 # They may be removed or their API changed in a future release.
2226 # Autoconf itself no longer uses these two macros; they are present
2227 # only for backward compatibility with previous versions of Autoconf.
2228 # Not every shell command will work due to problems with eval
2229 # and quoting, and the rules for exactly what does work are tricky.
2230 # Worse, due to double-expansion during evaluation, arbitrary unintended
2231 # shell commands could be executed in some situations.
2232 AC_DEFUN([AC_TRY_EVAL],
2233 [_AC_EVAL([$$1])])
2234
2235
2236 # AC_TRY_COMMAND(COMMAND)
2237 # -----------------------
2238 # Like AC_TRY_EVAL, but execute COMMAND instead, where COMMAND is a series of
2239 # tokens of the shell command language.
2240 # This macro should not be used; see the comments under AC_TRY_EVAL for why.
2241 AC_DEFUN([AC_TRY_COMMAND],
2242 [{ ac_try='$1'
2243   _AC_EVAL([$ac_try]); }])
2244
2245
2246 # AC_RUN_LOG(COMMAND)
2247 # -------------------
2248 AC_DEFUN([AC_RUN_LOG],
2249 [_AC_RUN_LOG([$1],
2250              [echo "$as_me:$LINENO: AS_ESCAPE([$1])"])])
2251
2252
2253
2254
2255 ## ------------------------ ##
2256 ## Examining declarations.  ##
2257 ## ------------------------ ##
2258
2259
2260
2261 # _AC_PREPROC_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2262 # ----------------------------------------------------------------
2263 # Try to preprocess PROGRAM.
2264 #
2265 # This macro can be used during the selection of a preprocessor.
2266 # eval is necessary to expand ac_cpp.
2267 AC_DEFUN([_AC_PREPROC_IFELSE],
2268 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
2269 AS_IF([_AC_DO_STDERR([$ac_cpp conftest.$ac_ext]) >/dev/null && {
2270          test -z "$ac_[]_AC_LANG_ABBREV[]_preproc_warn_flag$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
2271          test ! -s conftest.err
2272        }],
2273   [$2],
2274   [_AC_MSG_LOG_CONFTEST
2275   $3])
2276 rm -f conftest.err m4_ifval([$1], [conftest.$ac_ext])[]dnl
2277 ])# _AC_PREPROC_IFELSE
2278
2279
2280 # AC_PREPROC_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2281 # ---------------------------------------------------------------
2282 # Try to preprocess PROGRAM.  Requires that the preprocessor for the
2283 # current language was checked for, hence do not use this macro in macros
2284 # looking for a preprocessor.
2285 AC_DEFUN([AC_PREPROC_IFELSE],
2286 [AC_LANG_PREPROC_REQUIRE()dnl
2287 _AC_PREPROC_IFELSE($@)])
2288
2289
2290 # AC_TRY_CPP(INCLUDES, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2291 # ---------------------------------------------------------
2292 # AC_TRY_CPP is used to check whether particular header files exist.
2293 # (But it actually tests whether INCLUDES produces no CPP errors.)
2294 #
2295 # INCLUDES are not defaulted and are double quoted.
2296 AU_DEFUN([AC_TRY_CPP],
2297 [AC_PREPROC_IFELSE([AC_LANG_SOURCE([[$1]])], [$2], [$3])])
2298
2299
2300 # AC_EGREP_CPP(PATTERN, PROGRAM,
2301 #              [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
2302 # ------------------------------------------------------
2303 # Because this macro is used by AC_PROG_GCC_TRADITIONAL, which must
2304 # come early, it is not included in AC_BEFORE checks.
2305 AC_DEFUN([AC_EGREP_CPP],
2306 [AC_LANG_PREPROC_REQUIRE()dnl
2307 AC_REQUIRE([AC_PROG_EGREP])dnl
2308 AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
2309 AS_IF([dnl eval is necessary to expand ac_cpp.
2310 dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
2311 (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
2312 dnl Quote $1 to prevent m4 from eating character classes
2313   $EGREP "[$1]" >/dev/null 2>&1],
2314   [$3],
2315   [$4])dnl
2316 rm -f conftest*
2317 ])# AC_EGREP_CPP
2318
2319
2320 # AC_EGREP_HEADER(PATTERN, HEADER-FILE,
2321 #                 [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
2322 # ---------------------------------------------------------
2323 AC_DEFUN([AC_EGREP_HEADER],
2324 [AC_EGREP_CPP([$1],
2325 [#include <$2>
2326 ], [$3], [$4])])
2327
2328
2329
2330
2331 ## ------------------ ##
2332 ## Examining syntax.  ##
2333 ## ------------------ ##
2334
2335
2336 # _AC_COMPILE_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2337 # ----------------------------------------------------------------
2338 # Try to compile PROGRAM.
2339 # This macro can be used during the selection of a compiler.
2340 m4_define([_AC_COMPILE_IFELSE],
2341 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
2342 rm -f conftest.$ac_objext
2343 AS_IF([_AC_DO_STDERR($ac_compile) && {
2344          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
2345          test ! -s conftest.err
2346        } && test -s conftest.$ac_objext],
2347       [$2],
2348       [_AC_MSG_LOG_CONFTEST
2349         $3])
2350 rm -f core conftest.err conftest.$ac_objext m4_ifval([$1], [conftest.$ac_ext])[]dnl
2351 ])# _AC_COMPILE_IFELSE
2352
2353
2354 # AC_COMPILE_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2355 # ---------------------------------------------------------------
2356 # Try to compile PROGRAM.  Requires that the compiler for the current
2357 # language was checked for, hence do not use this macro in macros looking
2358 # for a compiler.
2359 AC_DEFUN([AC_COMPILE_IFELSE],
2360 [AC_LANG_COMPILER_REQUIRE()dnl
2361 _AC_COMPILE_IFELSE($@)])
2362
2363
2364 # AC_TRY_COMPILE(INCLUDES, FUNCTION-BODY,
2365 #                [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2366 # ---------------------------------------------------
2367 AU_DEFUN([AC_TRY_COMPILE],
2368 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[$1]], [[$2]])], [$3], [$4])])
2369
2370
2371
2372 ## --------------------- ##
2373 ## Examining libraries.  ##
2374 ## --------------------- ##
2375
2376
2377 # _AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2378 # -------------------------------------------------------------
2379 # Try to link PROGRAM.
2380 # This macro can be used during the selection of a compiler.
2381 m4_define([_AC_LINK_IFELSE],
2382 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
2383 rm -f conftest.$ac_objext conftest$ac_exeext
2384 AS_IF([_AC_DO_STDERR($ac_link) && {
2385          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
2386          test ! -s conftest.err
2387        } && test -s conftest$ac_exeext &&
2388        AS_TEST_X([conftest$ac_exeext])],
2389       [$2],
2390       [_AC_MSG_LOG_CONFTEST
2391         $3])
2392 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
2393 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
2394 dnl as it would interfere with the next link command.
2395 rm -f core conftest.err conftest.$ac_objext conftest_ipa8_conftest.oo \
2396       conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
2397 ])# _AC_LINK_IFELSE
2398
2399
2400 # AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2401 # ------------------------------------------------------------
2402 # Try to link PROGRAM.  Requires that the compiler for the current
2403 # language was checked for, hence do not use this macro in macros looking
2404 # for a compiler.
2405 AC_DEFUN([AC_LINK_IFELSE],
2406 [AC_LANG_COMPILER_REQUIRE()dnl
2407 _AC_LINK_IFELSE($@)])
2408
2409
2410 # AC_TRY_LINK(INCLUDES, FUNCTION-BODY,
2411 #             [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2412 # ------------------------------------------------
2413 # Contrarily to AC_LINK_IFELSE, this macro double quote its first two args.
2414 AU_DEFUN([AC_TRY_LINK],
2415 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$1]], [[$2]])], [$3], [$4])])
2416
2417
2418 # AC_COMPILE_CHECK(ECHO-TEXT, INCLUDES, FUNCTION-BODY,
2419 #                  ACTION-IF-TRUE, [ACTION-IF-FALSE])
2420 # ---------------------------------------------------
2421 AU_DEFUN([AC_COMPILE_CHECK],
2422 [m4_ifvaln([$1], [AC_MSG_CHECKING([for $1])])dnl
2423 AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]], [[$3]])], [$4], [$5])])
2424
2425
2426
2427
2428 ## ------------------------------- ##
2429 ## Checking for runtime features.  ##
2430 ## ------------------------------- ##
2431
2432
2433 # _AC_RUN_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
2434 # ------------------------------------------------------------
2435 # Compile, link, and run.
2436 # This macro can be used during the selection of a compiler.
2437 # We also remove conftest.o as if the compilation fails, some compilers
2438 # don't remove it.  We remove gmon.out and bb.out, which may be
2439 # created during the run if the program is built with profiling support.
2440 m4_define([_AC_RUN_IFELSE],
2441 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
2442 rm -f conftest$ac_exeext
2443 AS_IF([_AC_DO_VAR(ac_link) && _AC_DO_TOKENS(./conftest$ac_exeext)],
2444       [$2],
2445       [echo "$as_me: program exited with status $ac_status" >&AS_MESSAGE_LOG_FD
2446 _AC_MSG_LOG_CONFTEST
2447 m4_ifvaln([$3],
2448           [( exit $ac_status )
2449 $3])dnl])[]dnl
2450 rm -f core *.core core.conftest.* gmon.out bb.out conftest$ac_exeext conftest.$ac_objext m4_ifval([$1],
2451                                                      [conftest.$ac_ext])[]dnl
2452 ])# _AC_RUN_IFELSE
2453
2454
2455 # AC_RUN_IFELSE(PROGRAM,
2456 #               [ACTION-IF-TRUE], [ACTION-IF-FALSE],
2457 #               [ACTION-IF-CROSS-COMPILING = RUNTIME-ERROR])
2458 # ----------------------------------------------------------
2459 # Compile, link, and run. Requires that the compiler for the current
2460 # language was checked for, hence do not use this macro in macros looking
2461 # for a compiler.
2462 AC_DEFUN([AC_RUN_IFELSE],
2463 [AC_LANG_COMPILER_REQUIRE()dnl
2464 m4_ifval([$4], [],
2465          [AC_DIAGNOSE([cross],
2466                      [$0 called without default to allow cross compiling])])dnl
2467 AS_IF([test "$cross_compiling" = yes],
2468   [m4_default([$4],
2469            [AC_MSG_FAILURE([cannot run test program while cross compiling])])],
2470   [_AC_RUN_IFELSE($@)])
2471 ])
2472
2473
2474 # AC_TRY_RUN(PROGRAM,
2475 #            [ACTION-IF-TRUE], [ACTION-IF-FALSE],
2476 #            [ACTION-IF-CROSS-COMPILING = RUNTIME-ERROR])
2477 # --------------------------------------------------------
2478 AU_DEFUN([AC_TRY_RUN],
2479 [AC_RUN_IFELSE([AC_LANG_SOURCE([[$1]])], [$2], [$3], [$4])])
2480
2481
2482
2483 ## ------------------------------------- ##
2484 ## Checking for the existence of files.  ##
2485 ## ------------------------------------- ##
2486
2487 # AC_CHECK_FILE(FILE, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
2488 # -------------------------------------------------------------
2489 #
2490 # Check for the existence of FILE.
2491 AC_DEFUN([AC_CHECK_FILE],
2492 [AC_DIAGNOSE([cross],
2493              [cannot check for file existence when cross compiling])dnl
2494 AS_VAR_PUSHDEF([ac_File], [ac_cv_file_$1])dnl
2495 AC_CACHE_CHECK([for $1], [ac_File],
2496 [test "$cross_compiling" = yes &&
2497   AC_MSG_ERROR([cannot check for file existence when cross compiling])
2498 if test -r "$1"; then
2499   AS_VAR_SET([ac_File], [yes])
2500 else
2501   AS_VAR_SET([ac_File], [no])
2502 fi])
2503 AS_IF([test AS_VAR_GET([ac_File]) = yes], [$2], [$3])[]dnl
2504 AS_VAR_POPDEF([ac_File])dnl
2505 ])# AC_CHECK_FILE
2506
2507
2508 # AC_CHECK_FILES(FILE..., [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
2509 # -----------------------------------------------------------------
2510 AC_DEFUN([AC_CHECK_FILES],
2511 [m4_foreach_w([AC_FILE_NAME], [$1],
2512   [AC_CHECK_FILE(AC_FILE_NAME,
2513                  [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]AC_FILE_NAME), 1,
2514                                     [Define to 1 if you have the
2515                                      file `]AC_File['.])
2516 $2],
2517                  [$3])])])
2518
2519
2520 ## ------------------------------- ##
2521 ## Checking for declared symbols.  ##
2522 ## ------------------------------- ##
2523
2524
2525 # AC_CHECK_DECL(SYMBOL,
2526 #               [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
2527 #               [INCLUDES = DEFAULT-INCLUDES])
2528 # -------------------------------------------------------
2529 # Check whether SYMBOL (a function, variable, or constant) is declared.
2530 AC_DEFUN([AC_CHECK_DECL],
2531 [AS_VAR_PUSHDEF([ac_Symbol], [ac_cv_have_decl_$1])dnl
2532 AC_CACHE_CHECK([whether $1 is declared], [ac_Symbol],
2533 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT([$4])],
2534 [#ifndef $1
2535   (void) $1;
2536 #endif
2537 ])],
2538                    [AS_VAR_SET([ac_Symbol], [yes])],
2539                    [AS_VAR_SET([ac_Symbol], [no])])])
2540 AS_IF([test AS_VAR_GET([ac_Symbol]) = yes], [$2], [$3])[]dnl
2541 AS_VAR_POPDEF([ac_Symbol])dnl
2542 ])# AC_CHECK_DECL
2543
2544
2545 # AC_CHECK_DECLS(SYMBOLS,
2546 #                [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
2547 #                [INCLUDES = DEFAULT-INCLUDES])
2548 # --------------------------------------------------------
2549 # Defines HAVE_DECL_SYMBOL to 1 if declared, 0 otherwise.  See the
2550 # documentation for a detailed explanation of this difference with
2551 # other AC_CHECK_*S macros.  SYMBOLS is an m4 list.
2552 AC_DEFUN([AC_CHECK_DECLS],
2553 [m4_foreach([AC_Symbol], [$1],
2554   [AC_CHECK_DECL(AC_Symbol,
2555                  [AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_DECL_]AC_Symbol), 1,
2556                                      [Define to 1 if you have the declaration
2557                                      of `]AC_Symbol[', and to 0 if you don't.])
2558 $2],
2559                  [AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_DECL_]AC_Symbol), 0)
2560 $3],
2561                  [$4])])
2562 ])# AC_CHECK_DECLS
2563
2564
2565 # AC_CHECK_DECLS_ONCE(SYMBOLS)
2566 # ----------------------------
2567 # Like AC_CHECK_DECLS(SYMBOLS), but do it at most once.
2568 AC_DEFUN([AC_CHECK_DECLS_ONCE],
2569 [
2570   m4_foreach([AC_Symbol], [$1],
2571     [AC_DEFUN([_AC_Check_Decl_]m4_defn([AC_Symbol]),
2572        [AC_CHECK_DECLS(m4_defn([AC_Symbol]))])
2573      AC_REQUIRE([_AC_Check_Decl_]m4_defn([AC_Symbol]))])
2574 ])
2575
2576
2577
2578 ## ---------------------------------- ##
2579 ## Replacement of library functions.  ##
2580 ## ---------------------------------- ##
2581
2582
2583 # AC_CONFIG_LIBOBJ_DIR(DIRNAME)
2584 # -----------------------------
2585 # Announce LIBOBJ replacement files are in $top_srcdir/DIRNAME.
2586 AC_DEFUN_ONCE([AC_CONFIG_LIBOBJ_DIR],
2587 [m4_divert_text([DEFAULTS], [ac_config_libobj_dir=$1])])
2588
2589
2590 # AC_LIBSOURCE(FILE-NAME)
2591 # -----------------------
2592 # Announce we might need the file `FILE-NAME'.
2593 m4_define([AC_LIBSOURCE], [])
2594
2595
2596 # AC_LIBSOURCES([FILE-NAME1, ...])
2597 # -------------------------------
2598 # Announce we might need these files.
2599 m4_define([AC_LIBSOURCES],
2600 [m4_foreach([_AC_FILE_NAME], [$1],
2601             [AC_LIBSOURCE(_AC_FILE_NAME)])])
2602
2603
2604 # _AC_LIBOBJ(FILE-NAME-NOEXT, ACTION-IF-INDIR)
2605 # --------------------------------------------
2606 # We need `FILE-NAME-NOEXT.o', save this into `LIBOBJS'.
2607 m4_define([_AC_LIBOBJ],
2608 [AS_LITERAL_IF([$1],
2609                [AC_LIBSOURCE([$1.c])],
2610                [$2])dnl
2611 case " $LIB@&t@OBJS " in
2612   *" $1.$ac_objext "* ) ;;
2613   *) AC_SUBST([LIB@&t@OBJS], ["$LIB@&t@OBJS $1.$ac_objext"]) ;;
2614 esac
2615 ])
2616
2617
2618 # AC_LIBOBJ(FILE-NAME-NOEXT)
2619 # -------------------------
2620 # We need `FILE-NAME-NOEXT.o', save this into `LIBOBJS'.
2621 m4_define([AC_LIBOBJ],
2622 [_AC_LIBOBJ([$1],
2623             [AC_DIAGNOSE(syntax,
2624                          [$0($1): you should use literals])])dnl
2625 ])
2626
2627
2628 # _AC_LIBOBJS_NORMALIZE
2629 # ---------------------
2630 # Clean up LIBOBJS and LTLIBOBJS so that they work with 1. ac_objext,
2631 # 2. Automake's ANSI2KNR, 3. Libtool, 4. combination of the three.
2632 # Used with AC_CONFIG_COMMANDS_PRE.
2633 AC_DEFUN([_AC_LIBOBJS_NORMALIZE],
2634 [ac_libobjs=
2635 ac_ltlibobjs=
2636 for ac_i in : $LIB@&t@OBJS; do test "x$ac_i" = x: && continue
2637   # 1. Remove the extension, and $U if already installed.
2638   ac_script='s/\$U\././;s/\.o$//;s/\.obj$//'
2639   ac_i=`echo "$ac_i" | sed "$ac_script"`
2640   # 2. Prepend LIBOBJDIR.  When used with automake>=1.10 LIBOBJDIR
2641   #    will be set to the directory where LIBOBJS objects are built.
2642   ac_libobjs="$ac_libobjs \${LIBOBJDIR}$ac_i\$U.$ac_objext"
2643   ac_ltlibobjs="$ac_ltlibobjs \${LIBOBJDIR}$ac_i"'$U.lo'
2644 done
2645 AC_SUBST([LIB@&t@OBJS], [$ac_libobjs])
2646 AC_SUBST([LTLIBOBJS], [$ac_ltlibobjs])
2647 ])
2648
2649
2650 ## ----------------------------------- ##
2651 ## Checking compiler characteristics.  ##
2652 ## ----------------------------------- ##
2653
2654
2655 # _AC_COMPUTE_INT_COMPILE(EXPRESSION, VARIABLE, PROLOGUE, [IF-FAILS])
2656 # -------------------------------------------------------------------
2657 # Compute the integer EXPRESSION and store the result in the VARIABLE.
2658 # Works OK if cross compiling, but assumes twos-complement arithmetic.
2659 m4_define([_AC_COMPUTE_INT_COMPILE],
2660 [# Depending upon the size, compute the lo and hi bounds.
2661 _AC_COMPILE_IFELSE([AC_LANG_BOOL_COMPILE_TRY([$3], [($1) >= 0])],
2662  [ac_lo=0 ac_mid=0
2663   while :; do
2664     _AC_COMPILE_IFELSE([AC_LANG_BOOL_COMPILE_TRY([$3], [($1) <= $ac_mid])],
2665                        [ac_hi=$ac_mid; break],
2666                        [ac_lo=`expr $ac_mid + 1`
2667                         if test $ac_lo -le $ac_mid; then
2668                           ac_lo= ac_hi=
2669                           break
2670                         fi
2671                         ac_mid=`expr 2 '*' $ac_mid + 1`])
2672   done],
2673 [AC_COMPILE_IFELSE([AC_LANG_BOOL_COMPILE_TRY([$3], [($1) < 0])],
2674  [ac_hi=-1 ac_mid=-1
2675   while :; do
2676     _AC_COMPILE_IFELSE([AC_LANG_BOOL_COMPILE_TRY([$3], [($1) >= $ac_mid])],
2677                        [ac_lo=$ac_mid; break],
2678                        [ac_hi=`expr '(' $ac_mid ')' - 1`
2679                         if test $ac_mid -le $ac_hi; then
2680                           ac_lo= ac_hi=
2681                           break
2682                         fi
2683                         ac_mid=`expr 2 '*' $ac_mid`])
2684   done],
2685  [ac_lo= ac_hi=])])
2686 # Binary search between lo and hi bounds.
2687 while test "x$ac_lo" != "x$ac_hi"; do
2688   ac_mid=`expr '(' $ac_hi - $ac_lo ')' / 2 + $ac_lo`
2689   _AC_COMPILE_IFELSE([AC_LANG_BOOL_COMPILE_TRY([$3], [($1) <= $ac_mid])],
2690                      [ac_hi=$ac_mid], [ac_lo=`expr '(' $ac_mid ')' + 1`])
2691 done
2692 case $ac_lo in
2693 ?*) $2=$ac_lo;;
2694 '') $4 ;;
2695 esac[]dnl
2696 ])# _AC_COMPUTE_INT_COMPILE
2697
2698
2699 # _AC_COMPUTE_INT_RUN(EXPRESSION, VARIABLE, PROLOGUE, [IF-FAILS])
2700 # ---------------------------------------------------------------
2701 # Store the evaluation of the integer EXPRESSION in VARIABLE.
2702 m4_define([_AC_COMPUTE_INT_RUN],
2703 [_AC_RUN_IFELSE([AC_LANG_INT_SAVE([$3], [$1])],
2704                 [$2=`cat conftest.val`], [$4])])
2705
2706
2707 # AC_COMPUTE_INT(VARIABLE, EXPRESSION, PROLOGUE, [IF-FAILS])
2708 # ----------------------------------------------------------
2709 AC_DEFUN([AC_COMPUTE_INT],
2710 [AC_LANG_COMPILER_REQUIRE()dnl
2711 if test "$cross_compiling" = yes; then
2712   _AC_COMPUTE_INT_COMPILE([$2], [$1], [$3], [$4])
2713 else
2714   _AC_COMPUTE_INT_RUN([$2], [$1], [$3], [$4])
2715 fi
2716 rm -f conftest.val[]dnl
2717 ])# _AC_COMPUTE_INT
2718
2719 # _AC_COMPUTE_INT(EXPRESSION, VARIABLE, PROLOGUE, [IF-FAILS])
2720 # -----------------------------------------------------------
2721 # FIXME: this private interface was used by several packages.
2722 # Give them time to transition to AC_COMPUTE_INT and then delete this one.
2723 AC_DEFUN([_AC_COMPUTE_INT],
2724 [AC_COMPUTE_INT([$2], [$1], [$3], [$4])
2725 AC_DIAGNOSE([obsolete],
2726 [The macro `_AC_COMPUTE_INT' is obsolete and will be deleted in a
2727 future version or Autoconf.  Hence, it is suggested that you use
2728 instead the public AC_COMPUTE_INT macro.  Note that the arguments are
2729 slightly different between the two.])dnl
2730 ])# _AC_COMPUTE_INT