src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: window.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19 #endif
  20
  21 #ifdef __WXMAC__
  22     #include "wx/osx/private.h"
  23 #endif
  24
  25 #include "wx/evtloop.h"
  26
  27 #if wxUSE_CARET
  28     #include "wx/caret.h"
  29 #endif
  30
  31 #if wxUSE_DRAG_AND_DROP
  32     #include "wx/dnd.h"
  33 #endif
  34
  35 #if wxUSE_TOOLTIPS
  36     #include "wx/tooltip.h"
  37 #endif
  38
  39 #include <objc/objc-runtime.h>
  40
  41 // Get the window with the focus
  42
  43 NSView* GetViewFromResponder( NSResponder* responder )
  44 {
  45     NSView* view = nil;
  46     if ( [responder isKindOfClass:[NSTextView class]] )
  47     {
  48         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  49         if ( [delegate isKindOfClass:[NSTextField class] ] )
  50             view = delegate;
  51         else
  52             view =  (NSView*) responder;
  53     }
  54     else
  55     {
  56         if ( [responder isKindOfClass:[NSView class]] )
  57             view = (NSView*) responder;
  58     }
  59     return view;
  60 }
  61
  62 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  63 {
  64     NSView* focusedView = nil;
  65     if ( keyWindow != nil )
  66         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  67
  68     return focusedView;
  69 }
  70
  71 WXWidget wxWidgetImpl::FindFocus()
  72 {
  73     return GetFocusedViewInWindow( [[NSApplication sharedApplication] keyWindow] );
  74 }
  75
  76 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  77 {
  78     int x, y, w, h ;
  79
  80     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  81     wxRect bounds(x,y,w,h);
  82     NSView* sv = (window->GetParent()->GetHandle() );
  83
  84     return wxToNSRect( sv, bounds );
  85 }
  86
  87 @interface wxNSView : NSView
  88 {
  89     NSTrackingRectTag rectTag;
  90 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  91     NSTrackingArea* _trackingArea;
  92 #endif
  93 }
  94
  95 // the tracking tag is needed to track mouse enter / exit events
  96 - (void) setTrackingTag: (NSTrackingRectTag)tag;
  97 - (NSTrackingRectTag) trackingTag;
  98 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  99 // under 10.5 we can also track mouse moved events on non-focused windows if
 100 // we use the new NSTrackingArea APIs.
 101 - (void) updateTrackingArea;
 102 - (NSTrackingArea*) trackingArea;
 103 #endif
 104 @end // wxNSView
 105
 106 @interface NSView(PossibleMethods)
 107 - (void)setTitle:(NSString *)aString;
 108 - (void)setStringValue:(NSString *)aString;
 109 - (void)setIntValue:(int)anInt;
 110 - (void)setFloatValue:(float)aFloat;
 111 - (void)setDoubleValue:(double)aDouble;
 112
 113 - (double)minValue;
 114 - (double)maxValue;
 115 - (void)setMinValue:(double)aDouble;
 116 - (void)setMaxValue:(double)aDouble;
 117
 118 - (void)sizeToFit;
 119
 120 - (BOOL)isEnabled;
 121 - (void)setEnabled:(BOOL)flag;
 122
 123 - (void)setImage:(NSImage *)image;
 124 - (void)setControlSize:(NSControlSize)size;
 125
 126 - (void)setFont:(NSFont *)fontObject;
 127
 128 - (id)contentView;
 129
 130 - (void)setTarget:(id)anObject;
 131 - (void)setAction:(SEL)aSelector;
 132 - (void)setDoubleAction:(SEL)aSelector;
 133 - (void)setBackgroundColor:(NSColor*)aColor;
 134 - (void)setOpaque:(BOOL)opaque;
 135 - (void)setTextColor:(NSColor *)color;
 136 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 137 @end
 138
 139 long wxOSXTranslateCocoaKey( NSEvent* event )
 140 {
 141     long retval = 0;
 142
 143     if ([event type] != NSFlagsChanged)
 144     {
 145         NSString* s = [event charactersIgnoringModifiers];
 146         // backspace char reports as delete w/modifiers for some reason
 147         if ([s length] == 1)
 148         {
 149             switch ( [s characterAtIndex:0] )
 150             {
 151                 // backspace key
 152                 case 0x7F :
 153                 case 8 :
 154                     retval = WXK_BACK;
 155                     break;
 156                 case NSUpArrowFunctionKey :
 157                     retval = WXK_UP;
 158                     break;
 159                 case NSDownArrowFunctionKey :
 160                     retval = WXK_DOWN;
 161                     break;
 162                 case NSLeftArrowFunctionKey :
 163                     retval = WXK_LEFT;
 164                     break;
 165                 case NSRightArrowFunctionKey :
 166                     retval = WXK_RIGHT;
 167                     break;
 168                 case NSInsertFunctionKey  :
 169                     retval = WXK_INSERT;
 170                     break;
 171                 case NSDeleteFunctionKey  :
 172                     retval = WXK_DELETE;
 173                     break;
 174                 case NSHomeFunctionKey  :
 175                     retval = WXK_HOME;
 176                     break;
 177         //        case NSBeginFunctionKey  :
 178         //            retval = WXK_BEGIN;
 179         //            break;
 180                 case NSEndFunctionKey  :
 181                     retval = WXK_END;
 182                     break;
 183                 case NSPageUpFunctionKey  :
 184                     retval = WXK_PAGEUP;
 185                     break;
 186                case NSPageDownFunctionKey  :
 187                     retval = WXK_PAGEDOWN;
 188                     break;
 189                case NSHelpFunctionKey  :
 190                     retval = WXK_HELP;
 191                     break;
 192                 default:
 193                     int intchar = [s characterAtIndex: 0];
 194                     if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 195                         retval = WXK_F1 + (intchar - NSF1FunctionKey );
 196                     break;
 197             }
 198         }
 199     }
 200
 201     // Some keys don't seem to have constants. The code mimics the approach
 202     // taken by WebKit. See:
 203     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 204     switch( [event keyCode] )
 205     {
 206         // command key
 207         case 54:
 208         case 55:
 209             retval = WXK_COMMAND;
 210             break;
 211         // caps locks key
 212         case 57: // Capslock
 213             retval = WXK_CAPITAL;
 214             break;
 215         // shift key
 216         case 56: // Left Shift
 217         case 60: // Right Shift
 218             retval = WXK_SHIFT;
 219             break;
 220         // alt key
 221         case 58: // Left Alt
 222         case 61: // Right Alt
 223             retval = WXK_ALT;
 224             break;
 225         // ctrl key
 226         case 59: // Left Ctrl
 227         case 62: // Right Ctrl
 228             retval = WXK_CONTROL;
 229             break;
 230         // clear key
 231         case 71:
 232             retval = WXK_CLEAR;
 233             break;
 234         // tab key
 235         case 48:
 236             retval = WXK_TAB;
 237             break;
 238
 239         case 75: // /
 240             retval = WXK_NUMPAD_DIVIDE;
 241             break;
 242         case 67: // *
 243             retval = WXK_NUMPAD_MULTIPLY;
 244             break;
 245         case 78: // -
 246             retval = WXK_NUMPAD_SUBTRACT;
 247             break;
 248         case 69: // +
 249             retval = WXK_NUMPAD_ADD;
 250             break;
 251         case 76: // Enter
 252             retval = WXK_NUMPAD_ENTER;
 253             break;
 254         case 65: // .
 255             retval = WXK_NUMPAD_DECIMAL;
 256             break;
 257         case 82: // 0
 258             retval = WXK_NUMPAD0;
 259             break;
 260         case 83: // 1
 261             retval = WXK_NUMPAD1;
 262             break;
 263         case 84: // 2
 264             retval = WXK_NUMPAD2;
 265             break;
 266         case 85: // 3
 267             retval = WXK_NUMPAD3;
 268             break;
 269         case 86: // 4
 270             retval = WXK_NUMPAD4;
 271             break;
 272         case 87: // 5
 273             retval = WXK_NUMPAD5;
 274             break;
 275         case 88: // 6
 276             retval = WXK_NUMPAD6;
 277             break;
 278         case 89: // 7
 279             retval = WXK_NUMPAD7;
 280             break;
 281         case 91: // 8
 282             retval = WXK_NUMPAD8;
 283             break;
 284         case 92: // 9
 285             retval = WXK_NUMPAD9;
 286             break;
 287         default:
 288             //retval = [event keyCode];
 289             break;
 290     }
 291     return retval;
 292 }
 293
 294 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 295 {
 296     UInt32 modifiers = [nsEvent modifierFlags] ;
 297     int eventType = [nsEvent type];
 298
 299     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 300     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 301     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 302     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 303
 304     wxevent.m_rawCode = [nsEvent keyCode];
 305     wxevent.m_rawFlags = modifiers;
 306
 307     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 308
 309     wxString chars;
 310     if ( eventType != NSFlagsChanged )
 311     {
 312         NSString* nschars = [nsEvent charactersIgnoringModifiers];
 313         if ( charString )
 314         {
 315             // if charString is set, it did not come from key up / key down
 316             wxevent.SetEventType( wxEVT_CHAR );
 317             chars = wxCFStringRef::AsString(charString);
 318         }
 319         else if ( nschars )
 320         {
 321             chars = wxCFStringRef::AsString(nschars);
 322         }
 323     }
 324
 325     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 326     long keyval = 0;
 327
 328     if (wxevent.GetEventType() != wxEVT_CHAR)
 329     {
 330         keyval = wxOSXTranslateCocoaKey(nsEvent) ;
 331         switch (eventType)
 332         {
 333             case NSKeyDown :
 334                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 335                 break;
 336             case NSKeyUp :
 337                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 338                 break;
 339             case NSFlagsChanged :
 340                 switch (keyval)
 341                 {
 342                     case WXK_CONTROL:
 343                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 344                         break;
 345                     case WXK_SHIFT:
 346                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 347                         break;
 348                     case WXK_ALT:
 349                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 350                         break;
 351                     case WXK_COMMAND:
 352                         wxevent.SetEventType( wxevent.m_metaDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 353                         break;
 354                 }
 355                 break;
 356             default :
 357                 break ;
 358         }
 359     }
 360
 361     if ( !keyval )
 362     {
 363         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 364             keyval = wxToupper( aunichar ) ;
 365         else
 366             keyval = aunichar;
 367     }
 368
 369 #if wxUSE_UNICODE
 370     wxevent.m_uniChar = aunichar;
 371 #endif
 372     wxevent.m_keyCode = keyval;
 373
 374     wxWindowMac* peer = GetWXPeer();
 375     if ( peer )
 376     {
 377         wxevent.SetEventObject(peer);
 378         wxevent.SetId(peer->GetId()) ;
 379     }
 380 }
 381
 382 UInt32 g_lastButton = 0 ;
 383 bool g_lastButtonWasFakeRight = false ;
 384
 385 // better scroll wheel support
 386 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 387
 388 @interface NSEvent (DeviceDelta)
 389 - (float)deviceDeltaX;
 390 - (float)deviceDeltaY;
 391 @end
 392
 393 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 394 {
 395     int eventType = [nsEvent type];
 396     UInt32 modifiers = [nsEvent modifierFlags] ;
 397     wxPoint screenMouseLocation = wxFromNSPoint( NULL, [nsEvent locationInWindow]);
 398
 399     // these parameters are not given for all events
 400     UInt32 button = [nsEvent buttonNumber];
 401     UInt32 clickCount = 0;
 402
 403     wxevent.m_x = screenMouseLocation.x;
 404     wxevent.m_y = screenMouseLocation.y;
 405     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 406     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 407     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 408     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 409     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 410
 411     UInt32 mouseChord = 0;
 412
 413     switch (eventType)
 414     {
 415         case NSLeftMouseDown :
 416         case NSLeftMouseDragged :
 417             mouseChord = 1U;
 418             break;
 419         case NSRightMouseDown :
 420         case NSRightMouseDragged :
 421             mouseChord = 2U;
 422             break;
 423         case NSOtherMouseDown :
 424         case NSOtherMouseDragged :
 425             mouseChord = 4U;
 426             break;
 427     }
 428
 429     // a control click is interpreted as a right click
 430     bool thisButtonIsFakeRight = false ;
 431     if ( button == 0 && (modifiers & NSControlKeyMask) )
 432     {
 433         button = 1 ;
 434         thisButtonIsFakeRight = true ;
 435     }
 436
 437     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 438     if ( clickCount > 1 && button != g_lastButton )
 439         clickCount = 1 ;
 440
 441     // we must make sure that our synthetic 'right' button corresponds in
 442     // mouse down, moved and mouse up, and does not deliver a right down and left up
 443     switch (eventType)
 444     {
 445         case NSLeftMouseDown :
 446         case NSRightMouseDown :
 447         case NSOtherMouseDown :
 448             g_lastButton = button ;
 449             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 450             break;
 451      }
 452
 453     if ( button == 0 )
 454     {
 455         g_lastButton = 0 ;
 456         g_lastButtonWasFakeRight = false ;
 457     }
 458     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 459         button = g_lastButton ;
 460
 461     // Adjust the chord mask to remove the primary button and add the
 462     // secondary button.  It is possible that the secondary button is
 463     // already pressed, e.g. on a mouse connected to a laptop, but this
 464     // possibility is ignored here:
 465     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 466         mouseChord = ((mouseChord & ~1U) | 2U);
 467
 468     if(mouseChord & 1U)
 469                 wxevent.m_leftDown = true ;
 470     if(mouseChord & 2U)
 471                 wxevent.m_rightDown = true ;
 472     if(mouseChord & 4U)
 473                 wxevent.m_middleDown = true ;
 474
 475     // translate into wx types
 476     switch (eventType)
 477     {
 478         case NSLeftMouseDown :
 479         case NSRightMouseDown :
 480         case NSOtherMouseDown :
 481             clickCount = [nsEvent clickCount];
 482             switch ( button )
 483             {
 484                 case 0 :
 485                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 486                     break ;
 487
 488                 case 1 :
 489                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 490                     break ;
 491
 492                 case 2 :
 493                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 494                     break ;
 495
 496                 default:
 497                     break ;
 498             }
 499             break ;
 500
 501         case NSLeftMouseUp :
 502         case NSRightMouseUp :
 503         case NSOtherMouseUp :
 504             clickCount = [nsEvent clickCount];
 505             switch ( button )
 506             {
 507                 case 0 :
 508                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 509                     break ;
 510
 511                 case 1 :
 512                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 513                     break ;
 514
 515                 case 2 :
 516                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 517                     break ;
 518
 519                 default:
 520                     break ;
 521             }
 522             break ;
 523
 524      case NSScrollWheel :
 525         {
 526             float deltaX = 0.0;
 527             float deltaY = 0.0;
 528
 529             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 530
 531             // see http://developer.apple.com/qa/qa2005/qa1453.html
 532             // for more details on why we have to look for the exact type
 533
 534             const EventRef cEvent = (EventRef) [nsEvent eventRef];
 535             bool isMouseScrollEvent = false;
 536             if ( cEvent )
 537                 isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 538
 539             if ( isMouseScrollEvent )
 540             {
 541                 deltaX = [nsEvent deviceDeltaX];
 542                 deltaY = [nsEvent deviceDeltaY];
 543             }
 544             else
 545             {
 546                 deltaX = ([nsEvent deltaX] * 10);
 547                 deltaY = ([nsEvent deltaY] * 10);
 548             }
 549
 550             wxevent.m_wheelDelta = 10;
 551             wxevent.m_linesPerAction = 1;
 552
 553             if ( fabs(deltaX) > fabs(deltaY) )
 554             {
 555                 wxevent.m_wheelAxis = 1;
 556                 wxevent.m_wheelRotation = (int)deltaX;
 557             }
 558             else
 559             {
 560                 wxevent.m_wheelRotation = (int)deltaY;
 561             }
 562
 563         }
 564         break ;
 565
 566         case NSMouseEntered :
 567             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 568             break;
 569         case NSMouseExited :
 570             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 571             break;
 572         case NSLeftMouseDragged :
 573         case NSRightMouseDragged :
 574         case NSOtherMouseDragged :
 575         case NSMouseMoved :
 576             wxevent.SetEventType( wxEVT_MOTION ) ;
 577             break;
 578         default :
 579             break ;
 580     }
 581
 582     wxevent.m_clickCount = clickCount;
 583     wxWindowMac* peer = GetWXPeer();
 584     if ( peer )
 585     {
 586         wxevent.SetEventObject(peer);
 587         wxevent.SetId(peer->GetId()) ;
 588     }
 589 }
 590
 591 @implementation wxNSView
 592
 593 + (void)initialize
 594 {
 595     static BOOL initialized = NO;
 596     if (!initialized)
 597     {
 598         initialized = YES;
 599         wxOSXCocoaClassAddWXMethods( self );
 600     }
 601 }
 602
 603 - (void) setTrackingTag: (NSTrackingRectTag)tag
 604 {
 605     rectTag = tag;
 606 }
 607
 608 - (NSTrackingRectTag) trackingTag
 609 {
 610     return rectTag;
 611 }
 612
 613 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 614 - (void) updateTrackingArea
 615 {
 616     if (_trackingArea)
 617     {
 618         [self removeTrackingArea: _trackingArea];
 619         [_trackingArea release];
 620     }
 621
 622     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingMouseMoved|NSTrackingActiveAlways;
 623
 624     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: [self bounds] options: options owner: self userInfo: nil];
 625     [self addTrackingArea: area];
 626
 627     _trackingArea = area;
 628 }
 629
 630 - (NSTrackingArea*) trackingArea
 631 {
 632     return _trackingArea;
 633 }
 634 #endif
 635 @end // wxNSView
 636
 637 //
 638 // event handlers
 639 //
 640
 641 #if wxUSE_DRAG_AND_DROP
 642
 643 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 644 // for details on the NSPasteboard -> PasteboardRef conversion
 645
 646 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 647 {
 648     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 649     if (impl == NULL)
 650         return NSDragOperationNone;
 651
 652     return impl->draggingEntered(sender, self, _cmd);
 653 }
 654
 655 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 656 {
 657     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 658     if (impl == NULL)
 659         return ;
 660
 661     return impl->draggingExited(sender, self, _cmd);
 662 }
 663
 664 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 665 {
 666     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 667     if (impl == NULL)
 668         return NSDragOperationNone;
 669
 670     return impl->draggingUpdated(sender, self, _cmd);
 671 }
 672
 673 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 674 {
 675     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 676     if (impl == NULL)
 677         return NSDragOperationNone;
 678
 679     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 680 }
 681
 682 #endif
 683
 684 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 685 {
 686     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 687     if (impl == NULL)
 688         return;
 689
 690     impl->mouseEvent(event, self, _cmd);
 691 }
 692
 693 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 694 {
 695     // This is needed to support click through, otherwise the first click on a window
 696     // will not do anything unless it is the active window already.
 697     return YES;
 698 }
 699
 700 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 701 {
 702     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 703     if (impl == NULL)
 704         return;
 705
 706     impl->keyEvent(event, self, _cmd);
 707 }
 708
 709 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 710 {
 711     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 712     if (impl == NULL)
 713         return;
 714
 715     impl->insertText(text, self, _cmd);
 716 }
 717
 718 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 719 {
 720     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 721     if (impl == NULL)
 722         return NO;
 723
 724     return impl->performKeyEquivalent(event, self, _cmd);
 725 }
 726
 727 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 728 {
 729     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 730     if (impl == NULL)
 731         return NO;
 732
 733     return impl->acceptsFirstResponder(self, _cmd);
 734 }
 735
 736 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 737 {
 738     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 739     if (impl == NULL)
 740         return NO;
 741
 742     return impl->becomeFirstResponder(self, _cmd);
 743 }
 744
 745 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 746 {
 747     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 748     if (impl == NULL)
 749         return NO;
 750
 751     return impl->resignFirstResponder(self, _cmd);
 752 }
 753
 754 void wxOSX_resetCursorRects(NSView* self, SEL _cmd)
 755 {
 756     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 757     if (impl == NULL)
 758         return;
 759
 760     impl->resetCursorRects(self, _cmd);
 761 }
 762
 763 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 764 {
 765     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 766     if (impl == NULL)
 767         return NO;
 768
 769     return impl->isFlipped(self, _cmd) ? YES:NO;
 770 }
 771
 772 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 773 {
 774     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 775     if (impl == NULL)
 776         return;
 777
 778     return impl->drawRect(&rect, self, _cmd);
 779 }
 780
 781 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 782 {
 783     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 784     if (impl == NULL)
 785         return;
 786
 787     impl->controlAction(self, _cmd, sender);
 788 }
 789
 790 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 791 {
 792     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 793     if (impl == NULL)
 794         return;
 795
 796     impl->controlDoubleAction(self, _cmd, sender);
 797 }
 798
 799 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 800 {
 801     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 802     NSPasteboard *pboard = [sender draggingPasteboard];
 803     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 804
 805     wxWindow* wxpeer = GetWXPeer();
 806     if ( wxpeer == NULL )
 807         return NSDragOperationNone;
 808
 809     wxDropTarget* target = wxpeer->GetDropTarget();
 810     if ( target == NULL )
 811         return NSDragOperationNone;
 812
 813     wxDragResult result = wxDragNone;
 814     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 815     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 816
 817     if ( sourceDragMask & NSDragOperationLink )
 818         result = wxDragLink;
 819     else if ( sourceDragMask & NSDragOperationCopy )
 820         result = wxDragCopy;
 821     else if ( sourceDragMask & NSDragOperationMove )
 822         result = wxDragMove;
 823
 824     PasteboardRef pboardRef;
 825     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 826     target->SetCurrentDragPasteboard(pboardRef);
 827     result = target->OnEnter(pt.x, pt.y, result);
 828     CFRelease(pboardRef);
 829
 830     NSDragOperation nsresult = NSDragOperationNone;
 831     switch (result )
 832     {
 833         case wxDragLink:
 834             nsresult = NSDragOperationLink;
 835         case wxDragMove:
 836             nsresult = NSDragOperationMove;
 837         case wxDragCopy:
 838             nsresult = NSDragOperationCopy;
 839         default :
 840             break;
 841     }
 842     return nsresult;
 843 }
 844
 845 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 846 {
 847     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 848     NSPasteboard *pboard = [sender draggingPasteboard];
 849
 850     wxWindow* wxpeer = GetWXPeer();
 851     if ( wxpeer == NULL )
 852         return;
 853
 854     wxDropTarget* target = wxpeer->GetDropTarget();
 855     if ( target == NULL )
 856         return;
 857
 858     PasteboardRef pboardRef;
 859     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 860     target->SetCurrentDragPasteboard(pboardRef);
 861     target->OnLeave();
 862     CFRelease(pboardRef);
 863  }
 864
 865 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 866 {
 867     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 868     NSPasteboard *pboard = [sender draggingPasteboard];
 869     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 870
 871     wxWindow* wxpeer = GetWXPeer();
 872     if ( wxpeer == NULL )
 873         return NSDragOperationNone;
 874
 875     wxDropTarget* target = wxpeer->GetDropTarget();
 876     if ( target == NULL )
 877         return NSDragOperationNone;
 878
 879     wxDragResult result = wxDragNone;
 880     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 881     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 882
 883     if ( sourceDragMask & NSDragOperationLink )
 884         result = wxDragLink;
 885     else if ( sourceDragMask & NSDragOperationCopy )
 886         result = wxDragCopy;
 887     else if ( sourceDragMask & NSDragOperationMove )
 888         result = wxDragMove;
 889
 890     PasteboardRef pboardRef;
 891     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 892     target->SetCurrentDragPasteboard(pboardRef);
 893     result = target->OnDragOver(pt.x, pt.y, result);
 894     CFRelease(pboardRef);
 895
 896     NSDragOperation nsresult = NSDragOperationNone;
 897     switch (result )
 898     {
 899         case wxDragLink:
 900             nsresult = NSDragOperationLink;
 901         case wxDragMove:
 902             nsresult = NSDragOperationMove;
 903         case wxDragCopy:
 904             nsresult = NSDragOperationCopy;
 905         default :
 906             break;
 907     }
 908     return nsresult;
 909 }
 910
 911 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 912 {
 913     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 914
 915     NSPasteboard *pboard = [sender draggingPasteboard];
 916     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 917
 918     wxWindow* wxpeer = GetWXPeer();
 919     wxDropTarget* target = wxpeer->GetDropTarget();
 920     wxDragResult result = wxDragNone;
 921     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 922     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 923
 924     if ( sourceDragMask & NSDragOperationLink )
 925         result = wxDragLink;
 926     else if ( sourceDragMask & NSDragOperationCopy )
 927         result = wxDragCopy;
 928     else if ( sourceDragMask & NSDragOperationMove )
 929         result = wxDragMove;
 930
 931     PasteboardRef pboardRef;
 932     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 933     target->SetCurrentDragPasteboard(pboardRef);
 934
 935     if (target->OnDrop(pt.x, pt.y))
 936         result = target->OnData(pt.x, pt.y, result);
 937
 938     CFRelease(pboardRef);
 939
 940     return result != wxDragNone;
 941 }
 942
 943 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
 944 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 945 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 946 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
 947 typedef BOOL (*wxOSX_ResetCursorRectsHandlerPtr)(NSView* self, SEL _cmd);
 948 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 949
 950 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 951 {
 952     if ( !DoHandleMouseEvent(event) )
 953     {
 954         // for plain NSView mouse events would propagate to parents otherwise
 955         if (!m_wxPeer->MacIsUserPane())
 956         {
 957             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 958             superimpl(slf, (SEL)_cmd, event);
 959         }
 960     }
 961 }
 962
 963 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 964 {
 965     if ( [event type] == NSKeyDown )
 966         m_lastKeyDownEvent = event;
 967     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
 968     {
 969         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 970         superimpl(slf, (SEL)_cmd, event);
 971     }
 972     m_lastKeyDownEvent = NULL;
 973 }
 974
 975 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
 976 {
 977     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
 978     {
 979         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 980         superimpl(slf, (SEL)_cmd, text);
 981     }
 982 }
 983
 984
 985 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
 986 {
 987     wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 988     return superimpl(slf, (SEL)_cmd, event);
 989 }
 990
 991 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
 992 {
 993     if ( m_wxPeer->MacIsUserPane() )
 994         return m_wxPeer->AcceptsFocus();
 995     else
 996     {
 997         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 998         return superimpl(slf, (SEL)_cmd);
 999     }
1000 }
1001
1002 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1003 {
1004     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1005     // get the current focus before running becomeFirstResponder
1006     NSView* otherView = FindFocus();
1007
1008     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1009     BOOL r = superimpl(slf, (SEL)_cmd);
1010     if ( r )
1011     {
1012         DoNotifyFocusEvent( true, otherWindow );
1013     }
1014
1015     return r;
1016 }
1017
1018 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1019 {
1020     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1021     BOOL r = superimpl(slf, (SEL)_cmd);
1022     // get the current focus after running resignFirstResponder
1023     // note that this value isn't reliable, it might return the same view that
1024     // is resigning
1025     NSView* otherView = FindFocus();
1026     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1027     // NSTextViews have an editor as true responder, therefore the might get the
1028     // resign notification if their editor takes over, don't trigger any event then
1029     if ( r && !m_hasEditor)
1030     {
1031         DoNotifyFocusEvent( false, otherWindow );
1032     }
1033     return r;
1034 }
1035
1036 void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
1037 {
1038     wxWindow* wxpeer = GetWXPeer();
1039     if ( wxpeer )
1040     {
1041         NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
1042         if (cursor == NULL)
1043         {
1044             wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1045             superimpl(slf, (SEL)_cmd);
1046         }
1047         else
1048         {
1049             [slf addCursorRect: [slf bounds]
1050                 cursor: cursor];
1051         }
1052     }
1053 }
1054
1055 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1056 {
1057     return m_isFlipped;
1058 }
1059
1060
1061 #define OSX_DEBUG_DRAWING 0
1062
1063 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1064 {
1065     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1066     CGContextSaveGState( context );
1067
1068 #if OSX_DEBUG_DRAWING
1069     CGContextBeginPath( context );
1070     CGContextMoveToPoint(context, 0, 0);
1071     NSRect bounds = [self bounds];
1072     CGContextAddLineToPoint(context, 10, 0);
1073     CGContextMoveToPoint(context, 0, 0);
1074     CGContextAddLineToPoint(context, 0, 10);
1075     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1076     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1077     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1078     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1079     CGContextClosePath( context );
1080     CGContextStrokePath(context);
1081 #endif
1082
1083     if ( !m_isFlipped )
1084     {
1085         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1086         CGContextScaleCTM( context, 1, -1 );
1087     }
1088
1089     wxRegion updateRgn;
1090     const NSRect *rects;
1091     NSInteger count;
1092
1093     [slf getRectsBeingDrawn:&rects count:&count];
1094     for ( int i = 0 ; i < count ; ++i )
1095     {
1096         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1097     }
1098
1099     wxWindow* wxpeer = GetWXPeer();
1100     if ( wxpeer->MacGetTopLevelWindow()->GetWindowStyle() & wxFRAME_SHAPED )
1101     {
1102         int xoffset = 0, yoffset = 0;
1103         wxRegion rgn = wxpeer->MacGetTopLevelWindow()->GetShape();
1104         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1105         rgn.Offset( xoffset, yoffset );
1106         updateRgn.Intersect(rgn);
1107     }
1108
1109     wxpeer->GetUpdateRegion() = updateRgn;
1110     wxpeer->MacSetCGContextRef( context );
1111
1112     bool handled = wxpeer->MacDoRedraw( 0 );
1113     CGContextRestoreGState( context );
1114
1115     CGContextSaveGState( context );
1116     if ( !handled )
1117     {
1118         // call super
1119         SEL _cmd = @selector(drawRect:);
1120         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1121         superimpl(slf, _cmd, *(NSRect*)rect);
1122         CGContextRestoreGState( context );
1123         CGContextSaveGState( context );
1124     }
1125     wxpeer->MacPaintChildrenBorders();
1126     wxpeer->MacSetCGContextRef( NULL );
1127     CGContextRestoreGState( context );
1128 }
1129
1130 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1131 {
1132     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1133     if ( wxpeer )
1134         wxpeer->OSXHandleClicked(0);
1135 }
1136
1137 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1138 {
1139 }
1140
1141 void wxWidgetCocoaImpl::controlTextDidChange()
1142 {
1143     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1144     if ( wxpeer )
1145     {
1146         wxCommandEvent event(wxEVT_COMMAND_TEXT_UPDATED, wxpeer->GetId());
1147         event.SetEventObject( wxpeer );
1148         event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
1149         wxpeer->HandleWindowEvent( event );
1150     }
1151 }
1152
1153 //
1154
1155 #if OBJC_API_VERSION >= 2
1156
1157 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1158     class_addMethod(c, s, i, t );
1159
1160 #else
1161
1162 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1163     { s, t, i },
1164
1165 #endif
1166
1167 void wxOSXCocoaClassAddWXMethods(Class c)
1168 {
1169
1170 #if OBJC_API_VERSION < 2
1171     static objc_method wxmethods[] =
1172     {
1173 #endif
1174
1175     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1176     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1177     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1178
1179     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1180     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1181     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1182
1183     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1184
1185     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1186     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1187     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1188
1189     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1190
1191     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1192     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1193     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1194
1195     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1196     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1197     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1198
1199     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1200
1201     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1202
1203     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1204     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1205     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1206     wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
1207
1208     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1209     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1210
1211     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1212     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1213
1214 #if wxUSE_DRAG_AND_DROP
1215     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1216     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1217     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1218     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1219 #endif
1220
1221 #if OBJC_API_VERSION < 2
1222     } ;
1223     static int method_count = WXSIZEOF( wxmethods );
1224     static objc_method_list *wxmethodlist = NULL;
1225     if ( wxmethodlist == NULL )
1226     {
1227         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1228         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1229         wxmethodlist->method_count = method_count;
1230         wxmethodlist->obsolete = 0;
1231     }
1232     class_addMethods( c, wxmethodlist );
1233 #endif
1234 }
1235
1236 //
1237 // C++ implementation class
1238 //
1239
1240 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1241
1242 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl ) :
1243     wxWidgetImpl( peer, isRootControl )
1244 {
1245     Init();
1246     m_osxView = w;
1247
1248     // check if the user wants to create the control initially hidden
1249     if ( !peer->IsShown() )
1250         SetVisibility(false);
1251
1252     // gc aware handling
1253     if ( m_osxView )
1254         CFRetain(m_osxView);
1255     [m_osxView release];
1256 }
1257
1258 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1259 {
1260     Init();
1261 }
1262
1263 void wxWidgetCocoaImpl::Init()
1264 {
1265     m_osxView = NULL;
1266     m_isFlipped = true;
1267     m_lastKeyDownEvent = NULL;
1268     m_hasEditor = false;
1269 }
1270
1271 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1272 {
1273     RemoveAssociations( this );
1274
1275     if ( !IsRootControl() )
1276     {
1277         NSView *sv = [m_osxView superview];
1278         if ( sv != nil )
1279             [m_osxView removeFromSuperview];
1280     }
1281     // gc aware handling
1282     if ( m_osxView )
1283         CFRelease(m_osxView);
1284 }
1285
1286 bool wxWidgetCocoaImpl::IsVisible() const
1287 {
1288     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1289 }
1290
1291 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1292 {
1293     [m_osxView setHidden:(visible ? NO:YES)];
1294 }
1295
1296 // ----------------------------------------------------------------------------
1297 // window animation stuff
1298 // ----------------------------------------------------------------------------
1299
1300 // define a delegate used to refresh the window during animation
1301 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1302 {
1303     wxWindow *m_win;
1304     bool m_isDone;
1305 }
1306
1307 - (id)init:(wxWindow *)win;
1308
1309 - (bool)isDone;
1310
1311 // NSAnimationDelegate methods
1312 - (void)animationDidEnd:(NSAnimation*)animation;
1313 - (void)animation:(NSAnimation*)animation
1314         didReachProgressMark:(NSAnimationProgress)progress;
1315 @end
1316
1317 @implementation wxNSAnimationDelegate
1318
1319 - (id)init:(wxWindow *)win
1320 {
1321     [super init];
1322
1323     m_win = win;
1324     m_isDone = false;
1325
1326     return self;
1327 }
1328
1329 - (bool)isDone
1330 {
1331     return m_isDone;
1332 }
1333
1334 - (void)animation:(NSAnimation*)animation
1335         didReachProgressMark:(NSAnimationProgress)progress
1336 {
1337     wxUnusedVar(animation);
1338     wxUnusedVar(progress);
1339
1340     m_win->SendSizeEvent();
1341 }
1342
1343 - (void)animationDidEnd:(NSAnimation*)animation
1344 {
1345     wxUnusedVar(animation);
1346     m_isDone = true;
1347 }
1348
1349 @end
1350
1351 /* static */
1352 bool
1353 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1354                                               bool show,
1355                                               wxShowEffect effect,
1356                                               unsigned timeout)
1357 {
1358     // create the dictionary describing the animation to perform on this view
1359     NSObject * const
1360         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1361     NSMutableDictionary * const
1362         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1363     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1364
1365     // determine the start and end rectangles assuming we're hiding the window
1366     const wxRect rectOrig = win->GetRect();
1367     wxRect rectStart,
1368            rectEnd;
1369     rectStart =
1370     rectEnd = rectOrig;
1371
1372     if ( show )
1373     {
1374         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1375                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1376             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1377         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1378                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1379             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1380         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1381                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1382             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1383         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1384                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1385             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1386     }
1387
1388     switch ( effect )
1389     {
1390         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1391         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1392             rectEnd.width = 0;
1393             break;
1394
1395         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1396         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1397             rectEnd.x = rectStart.GetRight();
1398             rectEnd.width = 0;
1399             break;
1400
1401         case wxSHOW_EFFECT_ROLL_TO_TOP:
1402         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1403             rectEnd.height = 0;
1404             break;
1405
1406         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1407         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1408             rectEnd.y = rectStart.GetBottom();
1409             rectEnd.height = 0;
1410             break;
1411
1412         case wxSHOW_EFFECT_EXPAND:
1413             rectEnd.x = rectStart.x + rectStart.width / 2;
1414             rectEnd.y = rectStart.y + rectStart.height / 2;
1415             rectEnd.width =
1416             rectEnd.height = 0;
1417             break;
1418
1419         case wxSHOW_EFFECT_BLEND:
1420             [dict setObject:(show ? NSViewAnimationFadeInEffect
1421                                   : NSViewAnimationFadeOutEffect)
1422                   forKey:NSViewAnimationEffectKey];
1423             break;
1424
1425         case wxSHOW_EFFECT_NONE:
1426         case wxSHOW_EFFECT_MAX:
1427             wxFAIL_MSG( "unexpected animation effect" );
1428             return false;
1429
1430         default:
1431             wxFAIL_MSG( "unknown animation effect" );
1432             return false;
1433     };
1434
1435     if ( show )
1436     {
1437         // we need to restore it to the original rectangle instead of making it
1438         // disappear
1439         wxSwap(rectStart, rectEnd);
1440
1441         // and as the window is currently hidden, we need to show it for the
1442         // animation to be visible at all (but don't restore it at its full
1443         // rectangle as it shouldn't appear immediately)
1444         win->SetSize(rectStart);
1445         win->Show();
1446     }
1447
1448     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1449                                     ? [(NSView *)viewOrWin superview]
1450                                     : nil;
1451     const NSRect rStart = wxToNSRect(parentView, rectStart);
1452     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1453
1454     [dict setObject:[NSValue valueWithRect:rStart]
1455           forKey:NSViewAnimationStartFrameKey];
1456     [dict setObject:[NSValue valueWithRect:rEnd]
1457           forKey:NSViewAnimationEndFrameKey];
1458
1459     // create an animation using the values in the above dictionary
1460     NSViewAnimation * const
1461         anim = [[NSViewAnimation alloc]
1462                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1463
1464     if ( !timeout )
1465     {
1466         // what is a good default duration? Windows uses 200ms, Web frameworks
1467         // use anything from 250ms to 1s... choose something in the middle
1468         timeout = 500;
1469     }
1470
1471     [anim setDuration:timeout/1000.];   // duration is in seconds here
1472
1473     // if the window being animated changes its layout depending on its size
1474     // (which is almost always the case) we need to redo it during animation
1475     //
1476     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1477     // controls in wxInfoBar visibly jump around)
1478     const int NUM_LAYOUTS = 20;
1479     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1480         [anim addProgressMark:f];
1481
1482     wxNSAnimationDelegate * const
1483         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1484     [anim setDelegate:animDelegate];
1485     [anim startAnimation];
1486
1487     // Cocoa is capable of doing animation asynchronously or even from separate
1488     // thread but wx API doesn't provide any way to be notified about the
1489     // animation end and without this we really must ensure that the window has
1490     // the expected (i.e. the same as if a simple Show() had been used) size
1491     // when we return, so block here until the animation finishes
1492     //
1493     // notice that because the default animation mode is NSAnimationBlocking,
1494     // no user input events ought to be processed from here
1495     {
1496         wxEventLoopGuarantor ensureEventLoopExistence;
1497         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1498         while ( ![animDelegate isDone] )
1499             loop->Dispatch();
1500     }
1501
1502     if ( !show )
1503     {
1504         // NSViewAnimation is smart enough to hide the NSView being animated at
1505         // the end but we also must ensure that it's hidden for wx too
1506         win->Hide();
1507
1508         // and we must also restore its size because it isn't expected to
1509         // change just because the window was hidden
1510         win->SetSize(rectOrig);
1511     }
1512     else
1513     {
1514         // refresh it once again after the end to ensure that everything is in
1515         // place
1516         win->SendSizeEvent();
1517     }
1518
1519     [anim setDelegate:nil];
1520     [animDelegate release];
1521     [anim release];
1522
1523     return true;
1524 }
1525
1526 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1527                                        wxShowEffect effect,
1528                                        unsigned timeout)
1529 {
1530     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1531 }
1532
1533 void wxWidgetCocoaImpl::Raise()
1534 {
1535     // Not implemented
1536 }
1537
1538 void wxWidgetCocoaImpl::Lower()
1539 {
1540     // Not implemented
1541 }
1542
1543 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1544 {
1545 #if 1
1546     SetNeedsDisplay() ;
1547 #else
1548     // We should do something like this, but it wasn't working in 10.4.
1549     if (GetNeedsDisplay() )
1550     {
1551         SetNeedsDisplay() ;
1552     }
1553     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1554     NSSize offset = NSMakeSize((float)dx, (float)dy);
1555     [m_osxView scrollRect:r by:offset];
1556 #endif
1557 }
1558
1559 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1560 {
1561     wxWindowMac* parent = GetWXPeer()->GetParent();
1562     // under Cocoa we might have a contentView in the wxParent to which we have to
1563     // adjust the coordinates
1564     if (parent && [m_osxView superview] != parent->GetHandle() )
1565     {
1566         int cx = 0,cy = 0,cw = 0,ch = 0;
1567         if ( parent->GetPeer() )
1568         {
1569             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1570             x -= cx;
1571             y -= cy;
1572         }
1573     }
1574     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
1575     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
1576     [m_osxView setFrame:r];
1577     [[m_osxView superview] setNeedsDisplayInRect:r];
1578
1579     wxNSView* wxview = (wxNSView*)m_osxView;
1580 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
1581     if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
1582         [wxview updateTrackingArea];
1583 #else
1584     if ([m_osxView respondsToSelector:@selector(trackingTag)] )
1585     {
1586         if ( [wxview trackingTag] )
1587             [wxview removeTrackingRect: [wxview trackingTag]];
1588
1589         [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
1590     }
1591 #endif
1592 }
1593
1594 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
1595 {
1596     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
1597     x = r.GetLeft();
1598     y = r.GetTop();
1599 }
1600
1601 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
1602 {
1603     NSRect rect = [m_osxView frame];
1604     width = (int)rect.size.width;
1605     height = (int)rect.size.height;
1606 }
1607
1608 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
1609 {
1610     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
1611     {
1612         NSView* cv = [m_osxView contentView];
1613
1614         NSRect bounds = [m_osxView bounds];
1615         NSRect rect = [cv frame];
1616
1617         int y = (int)rect.origin.y;
1618         int x = (int)rect.origin.x;
1619         if ( ![ m_osxView isFlipped ] )
1620             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
1621         left = x;
1622         top = y;
1623         width = (int)rect.size.width;
1624         height = (int)rect.size.height;
1625     }
1626     else
1627     {
1628         left = top = 0;
1629         GetSize( width, height );
1630     }
1631 }
1632
1633 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
1634 {
1635     if ( where )
1636         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
1637     else
1638         [m_osxView setNeedsDisplay:YES];
1639 }
1640
1641 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
1642 {
1643     return [m_osxView needsDisplay];
1644 }
1645
1646 bool wxWidgetCocoaImpl::CanFocus() const
1647 {
1648     return [m_osxView canBecomeKeyView] == YES;
1649 }
1650
1651 bool wxWidgetCocoaImpl::HasFocus() const
1652 {
1653     return ( FindFocus() == m_osxView );
1654 }
1655
1656 bool wxWidgetCocoaImpl::SetFocus()
1657 {
1658     if ( !CanFocus() )
1659         return false;
1660
1661     [[m_osxView window] makeKeyAndOrderFront:nil] ;
1662     [[m_osxView window] makeFirstResponder: m_osxView] ;
1663     return true;
1664 }
1665
1666
1667 void wxWidgetCocoaImpl::RemoveFromParent()
1668 {
1669     [m_osxView removeFromSuperview];
1670 }
1671
1672 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
1673 {
1674     NSView* container = parent->GetWXWidget() ;
1675     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
1676     [container addSubview:m_osxView];
1677 }
1678
1679 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
1680 {
1681     NSView* targetView = m_osxView;
1682     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1683         targetView = [(NSScrollView*) m_osxView documentView];
1684
1685     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
1686     {
1687         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1688                                                                 green:(CGFloat) (col.Green() / 255.0)
1689                                                                  blue:(CGFloat) (col.Blue() / 255.0)
1690                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
1691     }
1692 }
1693
1694 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
1695 {
1696     BOOL opaque = ( style == wxBG_STYLE_PAINT );
1697
1698     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
1699     {
1700         [m_osxView setOpaque: opaque];
1701     }
1702
1703     return true ;
1704 }
1705
1706 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
1707 {
1708     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
1709     {
1710         wxCFStringRef cf( title , encoding );
1711         [m_osxView setTitle:cf.AsNSString()];
1712     }
1713     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
1714     {
1715         wxCFStringRef cf( title , encoding );
1716         [m_osxView setStringValue:cf.AsNSString()];
1717     }
1718 }
1719
1720
1721 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
1722 {
1723     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
1724     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
1725     *pt = wxFromNSPoint( to->GetWXWidget(), p );
1726 }
1727
1728 wxInt32 wxWidgetCocoaImpl::GetValue() const
1729 {
1730     return [(NSControl*)m_osxView intValue];
1731 }
1732
1733 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
1734 {
1735     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
1736     {
1737         [m_osxView setIntValue:v];
1738     }
1739     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
1740     {
1741         [m_osxView setFloatValue:(double)v];
1742     }
1743     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
1744     {
1745         [m_osxView setDoubleValue:(double)v];
1746     }
1747 }
1748
1749 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
1750 {
1751     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
1752     {
1753         [m_osxView setMinValue:(double)v];
1754     }
1755 }
1756
1757 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
1758 {
1759     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
1760     {
1761         [m_osxView setMaxValue:(double)v];
1762     }
1763 }
1764
1765 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
1766 {
1767     if (  [m_osxView respondsToSelector:@selector(getMinValue:)] )
1768     {
1769         return (int)[m_osxView minValue];
1770     }
1771     return 0;
1772 }
1773
1774 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
1775 {
1776     if (  [m_osxView respondsToSelector:@selector(getMaxValue:)] )
1777     {
1778         return (int)[m_osxView maxValue];
1779     }
1780     return 0;
1781 }
1782
1783 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
1784 {
1785     wxBitmap bmp;
1786
1787     // TODO: how to create a wxBitmap from NSImage?
1788 #if 0
1789     if ( [m_osxView respondsToSelector:@selector(image:)] )
1790         bmp = [m_osxView image];
1791 #endif
1792
1793     return bmp;
1794 }
1795
1796 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
1797 {
1798     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
1799     {
1800         [m_osxView setImage:bitmap.GetNSImage()];
1801         [m_osxView setNeedsDisplay:YES];
1802     }
1803 }
1804
1805 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
1806 {
1807     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
1808     {
1809         NSCellImagePosition pos;
1810         switch ( dir )
1811         {
1812             case wxLEFT:
1813                 pos = NSImageLeft;
1814                 break;
1815
1816             case wxRIGHT:
1817                 pos = NSImageRight;
1818                 break;
1819
1820             case wxTOP:
1821                 pos = NSImageAbove;
1822                 break;
1823
1824             case wxBOTTOM:
1825                 pos = NSImageBelow;
1826                 break;
1827
1828             default:
1829                 wxFAIL_MSG( "invalid image position" );
1830                 pos = NSNoImage;
1831         }
1832
1833         [m_osxView setImagePosition:pos];
1834     }
1835 }
1836
1837 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
1838 {
1839     // implementation in subclass
1840 }
1841
1842 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
1843 {
1844     r->x = r->y = r->width = r->height = 0;
1845
1846     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
1847     {
1848         NSRect former = [m_osxView frame];
1849         [m_osxView sizeToFit];
1850         NSRect best = [m_osxView frame];
1851         [m_osxView setFrame:former];
1852         r->width = (int)best.size.width;
1853         r->height = (int)best.size.height;
1854     }
1855 }
1856
1857 bool wxWidgetCocoaImpl::IsEnabled() const
1858 {
1859     if ( [m_osxView respondsToSelector:@selector(isEnabled) ] )
1860         return [m_osxView isEnabled];
1861     return true;
1862 }
1863
1864 void wxWidgetCocoaImpl::Enable( bool enable )
1865 {
1866     if ( [m_osxView respondsToSelector:@selector(setEnabled:) ] )
1867         [m_osxView setEnabled:enable];
1868 }
1869
1870 void wxWidgetCocoaImpl::PulseGauge()
1871 {
1872 }
1873
1874 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
1875 {
1876 }
1877
1878 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
1879 {
1880     NSControlSize size = NSRegularControlSize;
1881
1882     switch ( variant )
1883     {
1884         case wxWINDOW_VARIANT_NORMAL :
1885             size = NSRegularControlSize;
1886             break ;
1887
1888         case wxWINDOW_VARIANT_SMALL :
1889             size = NSSmallControlSize;
1890             break ;
1891
1892         case wxWINDOW_VARIANT_MINI :
1893             size = NSMiniControlSize;
1894             break ;
1895
1896         case wxWINDOW_VARIANT_LARGE :
1897             size = NSRegularControlSize;
1898             break ;
1899
1900         default:
1901             wxFAIL_MSG(wxT("unexpected window variant"));
1902             break ;
1903     }
1904     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
1905         [m_osxView setControlSize:size];
1906     else if ([m_osxView respondsToSelector:@selector(cell)])
1907     {
1908         id cell = [(id)m_osxView cell];
1909         if ([cell respondsToSelector:@selector(setControlSize:)])
1910             [cell setControlSize:size];
1911     }
1912 }
1913
1914 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
1915 {
1916     if ([m_osxView respondsToSelector:@selector(setFont:)])
1917         [m_osxView setFont: font.OSXGetNSFont()];
1918     if ([m_osxView respondsToSelector:@selector(setTextColor:)])
1919         [m_osxView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1920                                                                  green:(CGFloat) (col.Green() / 255.0)
1921                                                                   blue:(CGFloat) (col.Blue() / 255.0)
1922                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
1923 }
1924
1925 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
1926 {
1927     if (tooltip)
1928     {
1929         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
1930         [m_osxView setToolTip: cf.AsNSString()];
1931     }
1932     else
1933         [m_osxView setToolTip: nil];
1934
1935 }
1936
1937 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
1938 {
1939     WXWidget c =  control ? control : (WXWidget) m_osxView;
1940     wxWidgetImpl::Associate( c, this ) ;
1941     if ([c respondsToSelector:@selector(setAction:)])
1942     {
1943         [c setTarget: c];
1944         [c setAction: @selector(controlAction:)];
1945         if ([c respondsToSelector:@selector(setDoubleAction:)])
1946         {
1947             [c setDoubleAction: @selector(controlDoubleAction:)];
1948         }
1949
1950     }
1951 }
1952
1953 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
1954 {
1955     wxKeyEvent wxevent(wxEVT_CHAR);
1956     SetupKeyEvent( wxevent, event, text );
1957
1958     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
1959 }
1960
1961 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
1962 {
1963     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1964     SetupKeyEvent( wxevent, event );
1965     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
1966
1967     // this will fire higher level events, like insertText, to help
1968     // us handle EVT_CHAR, etc.
1969
1970     if ( m_wxPeer->MacIsUserPane() && [event type] == NSKeyDown)
1971     {
1972         if ( !result )
1973         {
1974             if ( wxevent.GetKeyCode() < WXK_SPACE || wxevent.GetKeyCode() == WXK_DELETE || wxevent.GetKeyCode() >= WXK_START )
1975             {
1976                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
1977                 wxKeyEvent wxevent2(wxevent) ;
1978                 wxevent2.SetEventType(wxEVT_CHAR);
1979                 GetWXPeer()->OSXHandleKeyEvent(wxevent2);
1980             }
1981             else
1982             {
1983                 if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1984                     [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
1985                 else
1986                     [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
1987             }
1988             result = true;
1989         }
1990     }
1991
1992     return result;
1993 }
1994
1995 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
1996 {
1997     NSPoint clickLocation;
1998     clickLocation = [m_osxView convertPoint:[event locationInWindow] fromView:nil];
1999     wxPoint pt = wxFromNSPoint( m_osxView, clickLocation );
2000     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2001     SetupMouseEvent(wxevent , event) ;
2002     wxevent.m_x = pt.x;
2003     wxevent.m_y = pt.y;
2004
2005     return GetWXPeer()->HandleWindowEvent(wxevent);
2006 }
2007
2008 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2009 {
2010     wxWindow* thisWindow = GetWXPeer();
2011     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2012     {
2013         thisWindow->MacInvalidateBorders();
2014     }
2015
2016     if ( receivedFocus )
2017     {
2018         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2019         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2020         thisWindow->HandleWindowEvent(eventFocus);
2021
2022 #if wxUSE_CARET
2023         if ( thisWindow->GetCaret() )
2024             thisWindow->GetCaret()->OnSetFocus();
2025 #endif
2026
2027         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2028         event.SetEventObject(thisWindow);
2029         if (otherWindow)
2030             event.SetWindow(otherWindow->GetWXPeer());
2031         thisWindow->HandleWindowEvent(event) ;
2032     }
2033     else // !receivedFocuss
2034     {
2035 #if wxUSE_CARET
2036         if ( thisWindow->GetCaret() )
2037             thisWindow->GetCaret()->OnKillFocus();
2038 #endif
2039
2040         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2041
2042         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2043         event.SetEventObject(thisWindow);
2044         if (otherWindow)
2045             event.SetWindow(otherWindow->GetWXPeer());
2046         thisWindow->HandleWindowEvent(event) ;
2047     }
2048 }
2049
2050 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2051 {
2052     NSPoint location = [NSEvent mouseLocation];
2053     location = [[m_osxView window] convertScreenToBase:location];
2054     NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2055
2056     if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2057     {
2058         [(NSCursor*)cursor.GetHCURSOR() set];
2059     }
2060     [[m_osxView window] invalidateCursorRectsForView:m_osxView];
2061 }
2062
2063 void wxWidgetCocoaImpl::CaptureMouse()
2064 {
2065     [[m_osxView window] disableCursorRects];
2066 }
2067
2068 void wxWidgetCocoaImpl::ReleaseMouse()
2069 {
2070     [[m_osxView window] enableCursorRects];
2071 }
2072
2073 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2074 {
2075     m_isFlipped = flipped;
2076 }
2077
2078 //
2079 // Factory methods
2080 //
2081
2082 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2083     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2084     long WXUNUSED(style), long WXUNUSED(extraStyle))
2085 {
2086     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2087     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2088
2089     // temporary hook for dnd
2090     [v registerForDraggedTypes:[NSArray arrayWithObjects:
2091         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
2092
2093     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v );
2094     return c;
2095 }
2096
2097 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2098 {
2099     NSWindow* tlw = now->GetWXWindow();
2100
2101     wxWidgetCocoaImpl* c = NULL;
2102     if ( now->IsNativeWindowWrapper() )
2103     {
2104         NSView* cv = [tlw contentView];
2105         c = new wxWidgetCocoaImpl( now, cv, true );
2106         // increase ref count, because the impl destructor will decrement it again
2107         CFRetain(cv);
2108         if ( !now->IsShown() )
2109             [cv setHidden:NO];
2110
2111     }
2112     else
2113     {
2114         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2115         c = new wxWidgetCocoaImpl( now, v, true );
2116         c->InstallEventHandler();
2117         [tlw setContentView:v];
2118     }
2119     return c;
2120 }