src/osx/cocoa/button.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/button.mm
   3 // Purpose:     wxButton
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: button.cpp 54845 2008-07-30 14:52:41Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #include "wx/button.h"
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/panel.h"
  18     #include "wx/toplevel.h"
  19     #include "wx/dcclient.h"
  20 #endif
  21
  22 #include "wx/stockitem.h"
  23
  24 #include "wx/osx/private.h"
  25
  26 wxSize wxButton::DoGetBestSize() const
  27 {
  28     if ( GetId() == wxID_HELP )
  29         return wxSize( 23 , 23 ) ;
  30
  31     wxSize sz = GetDefaultSize() ;
  32
  33     switch (GetWindowVariant())
  34     {
  35         case wxWINDOW_VARIANT_NORMAL:
  36         case wxWINDOW_VARIANT_LARGE:
  37             sz.y = 23 ;
  38             break;
  39
  40         case wxWINDOW_VARIANT_SMALL:
  41             sz.y = 17 ;
  42             break;
  43
  44         case wxWINDOW_VARIANT_MINI:
  45             sz.y = 15 ;
  46             break;
  47
  48         default:
  49             break;
  50     }
  51
  52     wxRect r ;
  53
  54     m_peer->GetBestRect(&r);
  55
  56     if ( r.GetWidth() == 0 && r.GetHeight() == 0 )
  57     {
  58     }
  59     sz.x = r.GetWidth();
  60     sz.y = r.GetHeight();
  61
  62     int wBtn = 96;
  63
  64     if ((wBtn > sz.x) || ( GetWindowStyle() & wxBU_EXACTFIT))
  65         sz.x = wBtn;
  66
  67 #if wxOSX_USE_CARBON
  68     Rect    bestsize = { 0 , 0 , 0 , 0 } ;
  69     m_peer->GetBestRect( &bestsize ) ;
  70
  71     int wBtn;
  72     if ( EmptyRect( &bestsize ) || ( GetWindowStyle() & wxBU_EXACTFIT) )
  73     {
  74         Point bounds;
  75
  76         ControlFontStyleRec controlFont;
  77         OSStatus err = m_peer->GetData<ControlFontStyleRec>( kControlEntireControl, kControlFontStyleTag, &controlFont );
  78         verify_noerr( err );
  79
  80         wxCFStringRef str( m_label,  GetFont().GetEncoding() );
  81
  82 #if wxOSX_USE_ATSU_TEXT
  83         SInt16 baseline;
  84         if ( m_font.MacGetThemeFontID() != kThemeCurrentPortFont )
  85         {
  86             err = GetThemeTextDimensions(
  87                 (!m_label.empty() ? (CFStringRef)str : CFSTR(" ")),
  88                 m_font.MacGetThemeFontID(), kThemeStateActive, false, &bounds, &baseline );
  89             verify_noerr( err );
  90         }
  91         else
  92 #endif
  93         {
  94             wxClientDC dc(const_cast<wxButton*>(this));
  95             wxCoord width, height ;
  96             dc.GetTextExtent( m_label , &width, &height);
  97             bounds.h = width;
  98             bounds.v = height;
  99         }
 100
 101         wBtn = bounds.h + sz.y;
 102     }
 103     else
 104     {
 105         wBtn = bestsize.right - bestsize.left ;
 106         // non 'normal' window variants don't return the correct height
 107         // sz.y = bestsize.bottom - bestsize.top ;
 108     }
 109     if ((wBtn > sz.x) || ( GetWindowStyle() & wxBU_EXACTFIT))
 110         sz.x = wBtn;
 111 #endif
 112
 113     return sz ;
 114 }
 115
 116 wxSize wxButton::GetDefaultSize()
 117 {
 118     int wBtn = 70 ;
 119     int hBtn = 20 ;
 120
 121     return wxSize(wBtn, hBtn);
 122 }
 123
 124 @implementation wxNSButton
 125
 126 + (void)initialize
 127 {
 128     static BOOL initialized = NO;
 129     if (!initialized)
 130     {
 131         initialized = YES;
 132         wxOSXCocoaClassAddWXMethods( self );
 133     }
 134 }
 135
 136 - (int) intValue
 137 {
 138     switch ( [self state] )
 139     {
 140         case NSOnState:
 141             return 1;
 142         case NSMixedState:
 143             return 2;
 144         default:
 145             return 0;
 146     }
 147 }
 148
 149 - (void) setIntValue: (int) v
 150 {
 151     switch( v )
 152     {
 153         case 2:
 154             [self setState:NSMixedState];
 155             break;
 156         case 1:
 157             [self setState:NSOnState];
 158             break;
 159         default :
 160             [self setState:NSOffState];
 161             break;
 162     }
 163 }
 164
 165 @end
 166
 167
 168 wxWidgetImplType* wxWidgetImpl::CreateButton( wxWindowMac* wxpeer,
 169                                     wxWindowMac* WXUNUSED(parent),
 170                                     wxWindowID id,
 171                                     const wxString& WXUNUSED(label),
 172                                     const wxPoint& pos,
 173                                     const wxSize& size,
 174                                     long WXUNUSED(style),
 175                                     long WXUNUSED(extraStyle))
 176 {
 177     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 178     wxNSButton* v = [[wxNSButton alloc] initWithFrame:r];
 179
 180     if ( id == wxID_HELP )
 181     {
 182         [v setBezelStyle:NSHelpButtonBezelStyle];
 183     }
 184     else
 185     {
 186         [v setBezelStyle:NSRoundedBezelStyle];
 187     }
 188
 189     [v setButtonType:NSMomentaryPushInButton];
 190     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v );
 191     return c;
 192 }
 193
 194 void wxWidgetCocoaImpl::SetDefaultButton( bool isDefault )
 195 {
 196     if ( isDefault && [m_osxView isKindOfClass:[NSButton class]] )
 197         // NOTE: setKeyEquivalent: nil will trigger an assert
 198         // instead do not call in that case.
 199         [(NSButton*)m_osxView setKeyEquivalent: @"\r" ];
 200 }
 201
 202 void wxWidgetCocoaImpl::PerformClick()
 203 {
 204 }
 205
 206 //
 207 // wxDisclosureButton implementation
 208 //
 209
 210 @interface wxDisclosureNSButton : NSButton
 211 {
 212
 213     BOOL isOpen;
 214 }
 215
 216 - (void) updateImage;
 217
 218 - (void) toggle;
 219
 220 + (NSImage *)rotateImage: (NSImage *)image;
 221
 222 @end
 223
 224 static const char * disc_triangle_xpm[] = {
 225 "10 9 4 1",
 226 "   c None",
 227 ".  c #737373",
 228 "+  c #989898",
 229 "-  c #c6c6c6",
 230 " .-       ",
 231 " ..+-     ",
 232 " ....+    ",
 233 " ......-  ",
 234 " .......- ",
 235 " ......-  ",
 236 " ....+    ",
 237 " ..+-     ",
 238 " .-       ",
 239 };
 240
 241 @implementation wxDisclosureNSButton
 242
 243 + (void)initialize
 244 {
 245     static BOOL initialized = NO;
 246     if (!initialized)
 247     {
 248         initialized = YES;
 249         wxOSXCocoaClassAddWXMethods( self );
 250     }
 251 }
 252
 253 - (id) initWithFrame:(NSRect) frame
 254 {
 255     self = [super initWithFrame:frame];
 256     [self setBezelStyle:NSSmallSquareBezelStyle];
 257     isOpen = NO;
 258     [self setImagePosition:NSImageLeft];
 259     [self updateImage];
 260     return self;
 261 }
 262
 263 - (int) intValue
 264 {
 265     return isOpen ? 1 : 0;
 266 }
 267
 268 - (void) setIntValue: (int) v
 269 {
 270     isOpen = ( v != 0 );
 271     [self updateImage];
 272 }
 273
 274 - (void) toggle
 275 {
 276     isOpen = !isOpen;
 277     [self updateImage];
 278 }
 279
 280 wxCFRef<NSImage*> downArray ;
 281
 282 - (void) updateImage
 283 {
 284     static wxBitmap trianglebm(disc_triangle_xpm);
 285     if ( downArray.get() == NULL )
 286     {
 287         downArray.reset( [wxDisclosureNSButton rotateImage:trianglebm.GetNSImage()] );
 288     }
 289
 290     if ( isOpen )
 291         [self setImage:(NSImage*)downArray.get()];
 292     else
 293         [self setImage:trianglebm.GetNSImage()];
 294 }
 295
 296 + (NSImage *)rotateImage: (NSImage *)image
 297 {
 298     NSSize imageSize = [image size];
 299     NSSize newImageSize = NSMakeSize(imageSize.height, imageSize.width);
 300     NSImage* newImage = [[NSImage alloc] initWithSize: newImageSize];
 301
 302     [newImage lockFocus];
 303
 304     NSAffineTransform* tm = [NSAffineTransform transform];
 305     [tm translateXBy:newImageSize.width/2 yBy:newImageSize.height/2];
 306     [tm rotateByDegrees:-90];
 307     [tm translateXBy:-newImageSize.width/2 yBy:-newImageSize.height/2];
 308     [tm concat];
 309
 310
 311     [image drawInRect:NSMakeRect(0,0,newImageSize.width, newImageSize.height)
 312         fromRect:NSZeroRect operation:NSCompositeCopy fraction:1.0];
 313
 314     [newImage unlockFocus];
 315     return newImage;
 316 }
 317
 318 @end
 319
 320 class wxDisclosureTriangleCocoaImpl : public wxWidgetCocoaImpl
 321 {
 322 public :
 323     wxDisclosureTriangleCocoaImpl(wxWindowMac* peer , WXWidget w) :
 324         wxWidgetCocoaImpl(peer, w)
 325     {
 326     }
 327
 328     ~wxDisclosureTriangleCocoaImpl()
 329     {
 330     }
 331
 332     virtual void controlAction(WXWidget slf, void* _cmd, void *sender)
 333     {
 334         wxDisclosureNSButton* db = (wxDisclosureNSButton*)m_osxView;
 335         [db toggle];
 336         wxWidgetCocoaImpl::controlAction(slf, _cmd, sender );
 337     }
 338 };
 339
 340 wxWidgetImplType* wxWidgetImpl::CreateDisclosureTriangle( wxWindowMac* wxpeer,
 341                                     wxWindowMac* WXUNUSED(parent),
 342                                     wxWindowID WXUNUSED(id),
 343                                     const wxString& label,
 344                                     const wxPoint& pos,
 345                                     const wxSize& size,
 346                                     long WXUNUSED(style),
 347                                     long WXUNUSED(extraStyle))
 348 {
 349     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 350     wxDisclosureNSButton* v = [[wxDisclosureNSButton alloc] initWithFrame:r];
 351     [v setTitle:wxCFStringRef( label).AsNSString()];
 352     wxDisclosureTriangleCocoaImpl* c = new wxDisclosureTriangleCocoaImpl( wxpeer, v );
 353     return c;
 354 }