src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: nonownedwnd.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16 #endif
  17
  18 #include "wx/osx/private.h"
  19
  20 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  21 {
  22     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  23     int y = r.y;
  24     int x = r.x ;
  25     if ( parent == NULL || ![ parent isFlipped ] )
  26         y = frame.size.height - ( r.y + r.height );
  27     return NSMakeRect(x, y, r.width , r.height);
  28 }
  29
  30 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  31 {
  32     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  33     int y = rect.origin.y;
  34     int x = rect.origin.x;
  35     if ( parent == NULL || ![ parent isFlipped ] )
  36         y = frame.size.height - (rect.origin.y + rect.size.height);
  37     return wxRect( x, y, rect.size.width, rect.size.height );
  38 }
  39
  40 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  41 {
  42     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  43     int x = p.x ;
  44     int y = p.y;
  45     if ( parent == NULL || ![ parent isFlipped ] )
  46         y = frame.size.height - ( p.y );
  47     return NSMakePoint(x, y);
  48 }
  49
  50 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  51 {
  52     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  53     int x = p.x;
  54     int y = p.y;
  55     if ( parent == NULL || ![ parent isFlipped ] )
  56         y = frame.size.height - ( p.y );
  57     return wxPoint( x, y);
  58 }
  59
  60 //
  61 // wx native implementation classes
  62 //
  63
  64 typedef void (*wxOSX_NoResponderHandlerPtr)(NSView* self, SEL _cmd, SEL selector);
  65
  66 @interface wxNSWindow : NSWindow
  67
  68 {
  69     wxNonOwnedWindowCocoaImpl* impl;
  70 }
  71
  72 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation;
  73 - (wxNonOwnedWindowCocoaImpl*) implementation;
  74 - (void)noResponderFor: (SEL) selector;
  75 @end
  76
  77 @implementation wxNSWindow
  78
  79 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation
  80 {
  81     impl = theImplementation;
  82 }
  83
  84 - (wxNonOwnedWindowCocoaImpl*) implementation
  85 {
  86     return impl;
  87 }
  88
  89 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
  90 - (void)noResponderFor: (SEL) selector
  91 {
  92     if (selector != @selector(keyDown:))
  93     {
  94         wxOSX_NoResponderHandlerPtr superimpl = (wxOSX_NoResponderHandlerPtr) [[self superclass] instanceMethodForSelector:@selector(noResponderFor:)];
  95         superimpl(self, @selector(noResponderFor:), selector);
  96     }
  97 }
  98
  99 @end
 100
 101 @interface wxNSPanel : NSPanel
 102
 103 {
 104     wxNonOwnedWindowCocoaImpl* impl;
 105 }
 106
 107 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation;
 108 - (wxNonOwnedWindowCocoaImpl*) implementation;
 109 - (void)noResponderFor: (SEL) selector;
 110 @end
 111
 112 @implementation wxNSPanel
 113
 114 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation
 115 {
 116     impl = theImplementation;
 117 }
 118
 119 - (BOOL)canBecomeKeyWindow
 120 {
 121     return YES;
 122 }
 123
 124 - (wxNonOwnedWindowCocoaImpl*) implementation
 125 {
 126     return impl;
 127 }
 128
 129 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 130 - (void)noResponderFor: (SEL) selector
 131 {
 132     if (selector != @selector(keyDown:))
 133     {
 134         wxOSX_NoResponderHandlerPtr superimpl = (wxOSX_NoResponderHandlerPtr) [[self superclass] instanceMethodForSelector:@selector(noResponderFor:)];
 135         superimpl(self, @selector(noResponderFor:), selector);
 136     }
 137 }
 138
 139 @end
 140
 141
 142 //
 143 // controller
 144 //
 145
 146 @interface wxNonOwnedWindowController : NSObject
 147 {
 148 }
 149
 150 - (void)windowDidResize:(NSNotification *)notification;
 151 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 152 - (void)windowDidResignKey:(NSNotification *)notification;
 153 - (void)windowDidBecomeKey:(NSNotification *)notification;
 154 - (void)windowDidMove:(NSNotification *)notification;
 155 - (BOOL)windowShouldClose:(id)window;
 156
 157 @end
 158
 159 @implementation wxNonOwnedWindowController
 160
 161 - (id) init
 162 {
 163     [super init];
 164     return self;
 165 }
 166
 167 - (BOOL)windowShouldClose:(id)nwindow
 168 {
 169     wxNSWindow* window = (wxNSWindow*) nwindow;
 170     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 171     if ( windowimpl )
 172     {
 173         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 174         if ( wxpeer )
 175             wxpeer->Close();
 176     }
 177     return NO;
 178 }
 179
 180 - (NSSize)windowWillResize:(NSWindow *)win
 181                     toSize:(NSSize)proposedFrameSize
 182 {
 183     NSRect frame = [win frame];
 184     wxRect wxframe = wxFromNSRect( NULL, frame );
 185     wxframe.SetWidth( proposedFrameSize.width );
 186     wxframe.SetHeight( proposedFrameSize.height );
 187     wxNSWindow* window = (wxNSWindow*) win;
 188     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 189     if ( windowimpl )
 190     {
 191         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 192         if ( wxpeer )
 193         {
 194             wxpeer->HandleResizing( 0, &wxframe );
 195             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 196             return newSize;
 197         }
 198     }
 199
 200     return proposedFrameSize;
 201 }
 202
 203 - (void)windowDidResize:(NSNotification *)notification
 204 {
 205     wxNSWindow* window = (wxNSWindow*) [notification object];
 206     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 207     if ( windowimpl )
 208     {
 209         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 210         if ( wxpeer )
 211             wxpeer->HandleResized(0);
 212     }
 213 }
 214
 215 - (void)windowDidMove:(NSNotification *)notification
 216 {
 217     wxNSWindow* window = (wxNSWindow*) [notification object];
 218     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 219     if ( windowimpl )
 220     {
 221         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 222         if ( wxpeer )
 223             wxpeer->HandleMoved(0);
 224     }
 225 }
 226
 227 - (void)windowDidBecomeKey:(NSNotification *)notification
 228 {
 229     wxNSWindow* window = (wxNSWindow*) [notification object];
 230     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 231     if ( windowimpl )
 232     {
 233         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 234         if ( wxpeer )
 235             wxpeer->HandleActivated(0, true);
 236     }
 237 }
 238
 239 - (void)windowDidResignKey:(NSNotification *)notification
 240 {
 241     wxNSWindow* window = (wxNSWindow*) [notification object];
 242     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 243     if ( windowimpl )
 244     {
 245         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 246         if ( wxpeer )
 247         {
 248             wxpeer->HandleActivated(0, false);
 249             // Needed for popup window since the firstResponder
 250             // (focus in wx) doesn't change when this
 251             // TLW becomes inactive.
 252             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 253             event.SetEventObject(wxpeer);
 254             wxpeer->HandleWindowEvent(event);
 255         }
 256     }
 257 }
 258
 259 @end
 260
 261 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 262
 263 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 264     wxNonOwnedWindowImpl(nonownedwnd)
 265 {
 266     m_macWindow = NULL;
 267     m_macFullScreenData = NULL;
 268 }
 269
 270 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 271 {
 272     m_macWindow = NULL;
 273     m_macFullScreenData = NULL;
 274 }
 275
 276 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 277 {
 278     [m_macWindow setImplementation:nil];
 279     [m_macWindow setDelegate:nil];
 280     [m_macWindow release];
 281 }
 282
 283 void wxNonOwnedWindowCocoaImpl::Destroy()
 284 {
 285     wxPendingDelete.Append( new wxDeferredObjectDeleter( this ) );
 286 }
 287
 288 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* parent, const wxPoint& pos, const wxSize& size,
 289 long style, long extraStyle, const wxString& name )
 290 {
 291     static wxNonOwnedWindowController* controller = NULL;
 292
 293     if ( !controller )
 294         controller =[[wxNonOwnedWindowController alloc] init];
 295
 296
 297     int windowstyle = NSBorderlessWindowMask;
 298
 299     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 300             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 301     {
 302         m_macWindow = [wxNSPanel alloc];
 303     }
 304     else
 305         m_macWindow = [wxNSWindow alloc];
 306
 307     CGWindowLevel level = kCGNormalWindowLevel;
 308
 309     if ( style & wxFRAME_TOOL_WINDOW )
 310     {
 311         windowstyle |= NSUtilityWindowMask;
 312         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 313             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 314         {
 315             windowstyle |= NSTitledWindowMask ;
 316         }
 317     }
 318     else if ( ( style & wxPOPUP_WINDOW ) )
 319     {
 320         level = kCGPopUpMenuWindowLevel;
 321         /*
 322         if ( ( style & wxBORDER_NONE ) )
 323         {
 324             wclass = kHelpWindowClass ;   // has no border
 325             attr |= kWindowNoShadowAttribute;
 326         }
 327         else
 328         {
 329             wclass = kPlainWindowClass ;  // has a single line border, it will have to do for now
 330         }
 331         */
 332     }
 333     else if ( ( style & wxCAPTION ) )
 334     {
 335         windowstyle |= NSTitledWindowMask ;
 336     }
 337     else if ( ( style & wxFRAME_DRAWER ) )
 338     {
 339         /*
 340         wclass = kDrawerWindowClass;
 341         */
 342     }
 343     else
 344     {
 345         // set these even if we have no title, otherwise the controls won't be visible
 346         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 347             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 348         {
 349             windowstyle |= NSTitledWindowMask ;
 350         }
 351         /*
 352         else if ( ( style & wxNO_BORDER ) )
 353         {
 354             wclass = kSimpleWindowClass ;
 355         }
 356         else
 357         {
 358             wclass = kPlainWindowClass ;
 359         }
 360         */
 361     }
 362
 363     if ( windowstyle & NSTitledWindowMask )
 364     {
 365         if ( ( style & wxMINIMIZE_BOX ) )
 366             windowstyle |= NSMiniaturizableWindowMask ;
 367
 368         if ( ( style & wxMAXIMIZE_BOX ) )
 369             windowstyle |= NSResizableWindowMask ; // TODO showing ZOOM ?
 370
 371         if ( ( style & wxRESIZE_BORDER ) )
 372             windowstyle |= NSResizableWindowMask ;
 373
 374         if ( ( style & wxCLOSE_BOX) )
 375             windowstyle |= NSClosableWindowMask ;
 376     }
 377     if ( extraStyle & wxFRAME_EX_METAL)
 378         windowstyle |= NSTexturedBackgroundWindowMask;
 379
 380     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 381         level = kCGFloatingWindowLevel;
 382
 383     if ( ( style & wxSTAY_ON_TOP ) )
 384         level = kCGUtilityWindowLevel;
 385
 386     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 387
 388     [m_macWindow setImplementation:this];
 389
 390     [m_macWindow initWithContentRect:r
 391         styleMask:windowstyle
 392         backing:NSBackingStoreBuffered
 393         defer:NO
 394         ];
 395
 396     [m_macWindow setLevel:level];
 397
 398     [m_macWindow setDelegate:controller];
 399
 400     [m_macWindow setAcceptsMouseMovedEvents: YES];
 401 }
 402
 403
 404 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 405 {
 406     return m_macWindow;
 407 }
 408
 409 void wxNonOwnedWindowCocoaImpl::Raise()
 410 {
 411     [m_macWindow orderWindow:NSWindowAbove relativeTo:0];
 412 }
 413
 414 void wxNonOwnedWindowCocoaImpl::Lower()
 415 {
 416     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 417 }
 418
 419 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 420 {
 421     if ( show )
 422     {
 423         [m_macWindow makeKeyAndOrderFront:nil];
 424         [[m_macWindow contentView] setNeedsDisplay:YES];
 425     }
 426     else
 427         [m_macWindow orderOut:nil];
 428     return true;
 429 }
 430
 431 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show, wxShowEffect effect, unsigned timeout)
 432 {
 433     return Show(show);
 434 }
 435
 436 void wxNonOwnedWindowCocoaImpl::Update()
 437 {
 438     [m_macWindow displayIfNeeded];
 439 }
 440
 441 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 442 {
 443     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 444     return true;
 445 }
 446
 447 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& col )
 448 {
 449     return true;
 450 }
 451
 452 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 453 {
 454     if ( m_macWindow )
 455     {
 456         bool metal = exStyle & wxFRAME_EX_METAL ;
 457         int windowStyle = [ m_macWindow styleMask];
 458         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 459         {
 460             wxFAIL_MSG( _T("Metal Style cannot be changed after creation") );
 461         }
 462         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 463         {
 464             wxFAIL_MSG( _T("Metal Style cannot be changed after creation") );
 465         }
 466     }
 467 }
 468
 469 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle style)
 470 {
 471     return true;
 472 }
 473
 474 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 475 {
 476     return true;
 477 }
 478
 479 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 480 {
 481     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 482     // do not trigger refreshes upon invisible and possible partly created objects
 483     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 484 }
 485
 486 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 487 {
 488     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 489     x = r.GetLeft();
 490     y = r.GetTop();
 491 }
 492
 493 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 494 {
 495     NSRect rect = [m_macWindow frame];
 496     width = rect.size.width;
 497     height = rect.size.height;
 498 }
 499
 500 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 501 {
 502     NSRect outer = NSMakeRect(100,100,100,100);
 503     NSRect content = [NSWindow contentRectForFrameRect:outer styleMask:[m_macWindow styleMask] ];
 504     NSRect rect = [[m_macWindow contentView] frame];
 505     left = rect.origin.x;
 506     top = rect.origin.y;
 507     width = rect.size.width;
 508     height = rect.size.height;
 509 }
 510
 511 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& region)
 512 {
 513     return false;
 514 }
 515
 516 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 517 {
 518     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 519 }
 520
 521 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 522 {
 523     return [m_macWindow isZoomed];
 524 }
 525
 526 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 527 {
 528     return [m_macWindow isMiniaturized];
 529 }
 530
 531 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 532 {
 533     if ( iconize )
 534         [m_macWindow miniaturize:nil];
 535     else
 536         [m_macWindow deminiaturize:nil];
 537 }
 538
 539 void wxNonOwnedWindowCocoaImpl::Maximize(bool maximize)
 540 {
 541     [m_macWindow zoom:nil];
 542 }
 543
 544
 545 // http://cocoadevcentral.com/articles/000028.php
 546
 547 typedef struct
 548 {
 549     int m_formerLevel;
 550     NSRect m_formerFrame;
 551 } FullScreenData ;
 552
 553 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 554 {
 555     return m_macFullScreenData != NULL ;
 556 }
 557
 558 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long style)
 559 {
 560     if ( show )
 561     {
 562         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 563         delete data ;
 564         data = new FullScreenData();
 565
 566         m_macFullScreenData = data ;
 567         data->m_formerLevel = [m_macWindow level];
 568         data->m_formerFrame = [m_macWindow frame];
 569         CGDisplayCapture( kCGDirectMainDisplay );
 570         [m_macWindow setLevel:CGShieldingWindowLevel()];
 571         [m_macWindow setFrame:[[NSScreen mainScreen] frame] display:YES];
 572     }
 573     else if ( m_macFullScreenData != NULL )
 574     {
 575         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 576         CGDisplayRelease( kCGDirectMainDisplay );
 577         [m_macWindow setLevel:data->m_formerLevel];
 578         [m_macWindow setFrame:data->m_formerFrame display:YES];
 579         delete data ;
 580         m_macFullScreenData = NULL ;
 581     }
 582
 583     return true;
 584 }
 585
 586 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int WXUNUSED(flags))
 587 {
 588 }
 589
 590 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 591 {
 592     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 593     NSPoint nspt = wxToNSPoint( NULL, p );
 594     nspt = [m_macWindow convertScreenToBase:nspt];
 595     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 596     p = wxFromNSPoint([m_macWindow contentView], nspt);
 597     if ( x )
 598         *x = p.x;
 599     if ( y )
 600         *y = p.y;
 601 }
 602
 603 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 604 {
 605     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 606     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 607     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 608     nspt = [m_macWindow convertBaseToScreen:nspt];
 609     p = wxFromNSPoint( NULL, nspt);
 610     if ( x )
 611         *x = p.x;
 612     if ( y )
 613         *y = p.y;
 614 }
 615
 616 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
 617     long style, long extraStyle, const wxString& name )
 618 {
 619     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
 620     now->Create( parent, pos, size, style , extraStyle, name );
 621     return now;
 622 }