src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     NSTrackingRectTag rectTag;
  91 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  92     NSTrackingArea* _trackingArea;
  93 #endif
  94 }
  95
  96 // the tracking tag is needed to track mouse enter / exit events
  97 - (void) setTrackingTag: (NSTrackingRectTag)tag;
  98 - (NSTrackingRectTag) trackingTag;
  99 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 100 // under 10.5 we can also track mouse moved events on non-focused windows if
 101 // we use the new NSTrackingArea APIs.
 102 - (void) updateTrackingArea;
 103 - (NSTrackingArea*) trackingArea;
 104 #endif
 105 @end // wxNSView
 106
 107 @interface NSView(PossibleMethods)
 108 - (void)setTitle:(NSString *)aString;
 109 - (void)setStringValue:(NSString *)aString;
 110 - (void)setIntValue:(int)anInt;
 111 - (void)setFloatValue:(float)aFloat;
 112 - (void)setDoubleValue:(double)aDouble;
 113
 114 - (double)minValue;
 115 - (double)maxValue;
 116 - (void)setMinValue:(double)aDouble;
 117 - (void)setMaxValue:(double)aDouble;
 118
 119 - (void)sizeToFit;
 120
 121 - (BOOL)isEnabled;
 122 - (void)setEnabled:(BOOL)flag;
 123
 124 - (void)setImage:(NSImage *)image;
 125 - (void)setControlSize:(NSControlSize)size;
 126
 127 - (void)setFont:(NSFont *)fontObject;
 128
 129 - (id)contentView;
 130
 131 - (void)setTarget:(id)anObject;
 132 - (void)setAction:(SEL)aSelector;
 133 - (void)setDoubleAction:(SEL)aSelector;
 134 - (void)setBackgroundColor:(NSColor*)aColor;
 135 - (void)setOpaque:(BOOL)opaque;
 136 - (void)setTextColor:(NSColor *)color;
 137 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 138 @end
 139
 140 long wxOSXTranslateCocoaKey( NSEvent* event )
 141 {
 142     long retval = 0;
 143
 144     if ([event type] != NSFlagsChanged)
 145     {
 146         NSString* s = [event charactersIgnoringModifiers];
 147         // backspace char reports as delete w/modifiers for some reason
 148         if ([s length] == 1)
 149         {
 150             switch ( [s characterAtIndex:0] )
 151             {
 152                 // backspace key
 153                 case 0x7F :
 154                 case 8 :
 155                     retval = WXK_BACK;
 156                     break;
 157                 case NSUpArrowFunctionKey :
 158                     retval = WXK_UP;
 159                     break;
 160                 case NSDownArrowFunctionKey :
 161                     retval = WXK_DOWN;
 162                     break;
 163                 case NSLeftArrowFunctionKey :
 164                     retval = WXK_LEFT;
 165                     break;
 166                 case NSRightArrowFunctionKey :
 167                     retval = WXK_RIGHT;
 168                     break;
 169                 case NSInsertFunctionKey  :
 170                     retval = WXK_INSERT;
 171                     break;
 172                 case NSDeleteFunctionKey  :
 173                     retval = WXK_DELETE;
 174                     break;
 175                 case NSHomeFunctionKey  :
 176                     retval = WXK_HOME;
 177                     break;
 178         //        case NSBeginFunctionKey  :
 179         //            retval = WXK_BEGIN;
 180         //            break;
 181                 case NSEndFunctionKey  :
 182                     retval = WXK_END;
 183                     break;
 184                 case NSPageUpFunctionKey  :
 185                     retval = WXK_PAGEUP;
 186                     break;
 187                case NSPageDownFunctionKey  :
 188                     retval = WXK_PAGEDOWN;
 189                     break;
 190                case NSHelpFunctionKey  :
 191                     retval = WXK_HELP;
 192                     break;
 193                 default:
 194                     int intchar = [s characterAtIndex: 0];
 195                     if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 196                         retval = WXK_F1 + (intchar - NSF1FunctionKey );
 197                     break;
 198             }
 199         }
 200     }
 201
 202     // Some keys don't seem to have constants. The code mimics the approach
 203     // taken by WebKit. See:
 204     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 205     switch( [event keyCode] )
 206     {
 207         // command key
 208         case 54:
 209         case 55:
 210             retval = WXK_COMMAND;
 211             break;
 212         // caps locks key
 213         case 57: // Capslock
 214             retval = WXK_CAPITAL;
 215             break;
 216         // shift key
 217         case 56: // Left Shift
 218         case 60: // Right Shift
 219             retval = WXK_SHIFT;
 220             break;
 221         // alt key
 222         case 58: // Left Alt
 223         case 61: // Right Alt
 224             retval = WXK_ALT;
 225             break;
 226         // ctrl key
 227         case 59: // Left Ctrl
 228         case 62: // Right Ctrl
 229             retval = WXK_CONTROL;
 230             break;
 231         // clear key
 232         case 71:
 233             retval = WXK_CLEAR;
 234             break;
 235         // tab key
 236         case 48:
 237             retval = WXK_TAB;
 238             break;
 239
 240         case 75: // /
 241             retval = WXK_NUMPAD_DIVIDE;
 242             break;
 243         case 67: // *
 244             retval = WXK_NUMPAD_MULTIPLY;
 245             break;
 246         case 78: // -
 247             retval = WXK_NUMPAD_SUBTRACT;
 248             break;
 249         case 69: // +
 250             retval = WXK_NUMPAD_ADD;
 251             break;
 252         case 76: // Enter
 253             retval = WXK_NUMPAD_ENTER;
 254             break;
 255         case 65: // .
 256             retval = WXK_NUMPAD_DECIMAL;
 257             break;
 258         case 82: // 0
 259             retval = WXK_NUMPAD0;
 260             break;
 261         case 83: // 1
 262             retval = WXK_NUMPAD1;
 263             break;
 264         case 84: // 2
 265             retval = WXK_NUMPAD2;
 266             break;
 267         case 85: // 3
 268             retval = WXK_NUMPAD3;
 269             break;
 270         case 86: // 4
 271             retval = WXK_NUMPAD4;
 272             break;
 273         case 87: // 5
 274             retval = WXK_NUMPAD5;
 275             break;
 276         case 88: // 6
 277             retval = WXK_NUMPAD6;
 278             break;
 279         case 89: // 7
 280             retval = WXK_NUMPAD7;
 281             break;
 282         case 91: // 8
 283             retval = WXK_NUMPAD8;
 284             break;
 285         case 92: // 9
 286             retval = WXK_NUMPAD9;
 287             break;
 288         default:
 289             //retval = [event keyCode];
 290             break;
 291     }
 292     return retval;
 293 }
 294
 295 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 296 {
 297     UInt32 modifiers = [nsEvent modifierFlags] ;
 298     int eventType = [nsEvent type];
 299
 300     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 301     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 302     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 303     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 304
 305     wxevent.m_rawCode = [nsEvent keyCode];
 306     wxevent.m_rawFlags = modifiers;
 307
 308     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 309
 310     wxString chars;
 311     if ( eventType != NSFlagsChanged )
 312     {
 313         NSString* nschars = [nsEvent charactersIgnoringModifiers];
 314         if ( charString )
 315         {
 316             // if charString is set, it did not come from key up / key down
 317             wxevent.SetEventType( wxEVT_CHAR );
 318             chars = wxCFStringRef::AsString(charString);
 319         }
 320         else if ( nschars )
 321         {
 322             chars = wxCFStringRef::AsString(nschars);
 323         }
 324     }
 325
 326     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 327     long keyval = 0;
 328
 329     if (wxevent.GetEventType() != wxEVT_CHAR)
 330     {
 331         keyval = wxOSXTranslateCocoaKey(nsEvent) ;
 332         switch (eventType)
 333         {
 334             case NSKeyDown :
 335                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 336                 break;
 337             case NSKeyUp :
 338                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 339                 break;
 340             case NSFlagsChanged :
 341                 switch (keyval)
 342                 {
 343                     case WXK_CONTROL:
 344                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 345                         break;
 346                     case WXK_SHIFT:
 347                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 348                         break;
 349                     case WXK_ALT:
 350                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 351                         break;
 352                     case WXK_COMMAND:
 353                         wxevent.SetEventType( wxevent.m_metaDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 354                         break;
 355                 }
 356                 break;
 357             default :
 358                 break ;
 359         }
 360     }
 361
 362     if ( !keyval )
 363     {
 364         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 365             keyval = wxToupper( aunichar ) ;
 366         else
 367             keyval = aunichar;
 368     }
 369
 370 #if wxUSE_UNICODE
 371     wxevent.m_uniChar = aunichar;
 372 #endif
 373     wxevent.m_keyCode = keyval;
 374
 375     wxWindowMac* peer = GetWXPeer();
 376     if ( peer )
 377     {
 378         wxevent.SetEventObject(peer);
 379         wxevent.SetId(peer->GetId()) ;
 380     }
 381 }
 382
 383 UInt32 g_lastButton = 0 ;
 384 bool g_lastButtonWasFakeRight = false ;
 385
 386 // better scroll wheel support
 387 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 388
 389 @interface NSEvent (DeviceDelta)
 390 - (CGFloat)deviceDeltaX;
 391 - (CGFloat)deviceDeltaY;
 392 @end
 393
 394 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 395 {
 396     int eventType = [nsEvent type];
 397     UInt32 modifiers = [nsEvent modifierFlags] ;
 398
 399     NSPoint locationInWindow = [nsEvent locationInWindow];
 400
 401     // adjust coordinates for the window of the target view
 402     if ( [nsEvent window] != [m_osxView window] )
 403     {
 404         if ( [nsEvent window] != nil )
 405             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 406
 407         if ( [m_osxView window] != nil )
 408             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 409     }
 410
 411     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 412     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 413
 414     // these parameters are not given for all events
 415     UInt32 button = [nsEvent buttonNumber];
 416     UInt32 clickCount = 0;
 417
 418     wxevent.m_x = locationInViewWX.x;
 419     wxevent.m_y = locationInViewWX.y;
 420     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 421     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 422     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 423     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 424     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 425
 426     UInt32 mouseChord = 0;
 427
 428     switch (eventType)
 429     {
 430         case NSLeftMouseDown :
 431         case NSLeftMouseDragged :
 432             mouseChord = 1U;
 433             break;
 434         case NSRightMouseDown :
 435         case NSRightMouseDragged :
 436             mouseChord = 2U;
 437             break;
 438         case NSOtherMouseDown :
 439         case NSOtherMouseDragged :
 440             mouseChord = 4U;
 441             break;
 442     }
 443
 444     // a control click is interpreted as a right click
 445     bool thisButtonIsFakeRight = false ;
 446     if ( button == 0 && (modifiers & NSControlKeyMask) )
 447     {
 448         button = 1 ;
 449         thisButtonIsFakeRight = true ;
 450     }
 451
 452     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 453     if ( clickCount > 1 && button != g_lastButton )
 454         clickCount = 1 ;
 455
 456     // we must make sure that our synthetic 'right' button corresponds in
 457     // mouse down, moved and mouse up, and does not deliver a right down and left up
 458     switch (eventType)
 459     {
 460         case NSLeftMouseDown :
 461         case NSRightMouseDown :
 462         case NSOtherMouseDown :
 463             g_lastButton = button ;
 464             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 465             break;
 466      }
 467
 468     if ( button == 0 )
 469     {
 470         g_lastButton = 0 ;
 471         g_lastButtonWasFakeRight = false ;
 472     }
 473     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 474         button = g_lastButton ;
 475
 476     // Adjust the chord mask to remove the primary button and add the
 477     // secondary button.  It is possible that the secondary button is
 478     // already pressed, e.g. on a mouse connected to a laptop, but this
 479     // possibility is ignored here:
 480     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 481         mouseChord = ((mouseChord & ~1U) | 2U);
 482
 483     if(mouseChord & 1U)
 484                 wxevent.m_leftDown = true ;
 485     if(mouseChord & 2U)
 486                 wxevent.m_rightDown = true ;
 487     if(mouseChord & 4U)
 488                 wxevent.m_middleDown = true ;
 489
 490     // translate into wx types
 491     switch (eventType)
 492     {
 493         case NSLeftMouseDown :
 494         case NSRightMouseDown :
 495         case NSOtherMouseDown :
 496             clickCount = [nsEvent clickCount];
 497             switch ( button )
 498             {
 499                 case 0 :
 500                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 501                     break ;
 502
 503                 case 1 :
 504                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 505                     break ;
 506
 507                 case 2 :
 508                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 509                     break ;
 510
 511                 default:
 512                     break ;
 513             }
 514             break ;
 515
 516         case NSLeftMouseUp :
 517         case NSRightMouseUp :
 518         case NSOtherMouseUp :
 519             clickCount = [nsEvent clickCount];
 520             switch ( button )
 521             {
 522                 case 0 :
 523                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 524                     break ;
 525
 526                 case 1 :
 527                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 528                     break ;
 529
 530                 case 2 :
 531                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 532                     break ;
 533
 534                 default:
 535                     break ;
 536             }
 537             break ;
 538
 539      case NSScrollWheel :
 540         {
 541             float deltaX = 0.0;
 542             float deltaY = 0.0;
 543
 544             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 545
 546             // see http://developer.apple.com/qa/qa2005/qa1453.html
 547             // for more details on why we have to look for the exact type
 548
 549             const EventRef cEvent = (EventRef) [nsEvent eventRef];
 550             bool isMouseScrollEvent = false;
 551             if ( cEvent )
 552                 isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 553
 554             if ( isMouseScrollEvent )
 555             {
 556                 deltaX = [nsEvent deviceDeltaX];
 557                 deltaY = [nsEvent deviceDeltaY];
 558             }
 559             else
 560             {
 561                 deltaX = ([nsEvent deltaX] * 10);
 562                 deltaY = ([nsEvent deltaY] * 10);
 563             }
 564
 565             wxevent.m_wheelDelta = 10;
 566             wxevent.m_linesPerAction = 1;
 567
 568             if ( fabs(deltaX) > fabs(deltaY) )
 569             {
 570                 wxevent.m_wheelAxis = 1;
 571                 wxevent.m_wheelRotation = (int)deltaX;
 572             }
 573             else
 574             {
 575                 wxevent.m_wheelRotation = (int)deltaY;
 576             }
 577
 578         }
 579         break ;
 580
 581         case NSMouseEntered :
 582             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 583             break;
 584         case NSMouseExited :
 585             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 586             break;
 587         case NSLeftMouseDragged :
 588         case NSRightMouseDragged :
 589         case NSOtherMouseDragged :
 590         case NSMouseMoved :
 591             wxevent.SetEventType( wxEVT_MOTION ) ;
 592             break;
 593         default :
 594             break ;
 595     }
 596
 597     wxevent.m_clickCount = clickCount;
 598     wxWindowMac* peer = GetWXPeer();
 599     if ( peer )
 600     {
 601         wxevent.SetEventObject(peer);
 602         wxevent.SetId(peer->GetId()) ;
 603     }
 604 }
 605
 606 @implementation wxNSView
 607
 608 + (void)initialize
 609 {
 610     static BOOL initialized = NO;
 611     if (!initialized)
 612     {
 613         initialized = YES;
 614         wxOSXCocoaClassAddWXMethods( self );
 615     }
 616 }
 617
 618 - (void) setTrackingTag: (NSTrackingRectTag)tag
 619 {
 620     rectTag = tag;
 621 }
 622
 623 - (NSTrackingRectTag) trackingTag
 624 {
 625     return rectTag;
 626 }
 627
 628 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 629 - (void) updateTrackingArea
 630 {
 631     if (_trackingArea)
 632     {
 633         [self removeTrackingArea: _trackingArea];
 634         [_trackingArea release];
 635     }
 636
 637     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingMouseMoved|NSTrackingActiveAlways;
 638
 639     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: [self bounds] options: options owner: self userInfo: nil];
 640     [self addTrackingArea: area];
 641
 642     _trackingArea = area;
 643 }
 644
 645 - (NSTrackingArea*) trackingArea
 646 {
 647     return _trackingArea;
 648 }
 649 #endif
 650 @end // wxNSView
 651
 652 //
 653 // event handlers
 654 //
 655
 656 #if wxUSE_DRAG_AND_DROP
 657
 658 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 659 // for details on the NSPasteboard -> PasteboardRef conversion
 660
 661 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 662 {
 663     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 664     if (impl == NULL)
 665         return NSDragOperationNone;
 666
 667     return impl->draggingEntered(sender, self, _cmd);
 668 }
 669
 670 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 671 {
 672     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 673     if (impl == NULL)
 674         return ;
 675
 676     return impl->draggingExited(sender, self, _cmd);
 677 }
 678
 679 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 680 {
 681     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 682     if (impl == NULL)
 683         return NSDragOperationNone;
 684
 685     return impl->draggingUpdated(sender, self, _cmd);
 686 }
 687
 688 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 689 {
 690     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 691     if (impl == NULL)
 692         return NSDragOperationNone;
 693
 694     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 695 }
 696
 697 #endif
 698
 699 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 700 {
 701     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 702     if (impl == NULL)
 703         return;
 704
 705     impl->mouseEvent(event, self, _cmd);
 706 }
 707
 708 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 709 {
 710     // This is needed to support click through, otherwise the first click on a window
 711     // will not do anything unless it is the active window already.
 712     return YES;
 713 }
 714
 715 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 716 {
 717     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 718     if (impl == NULL)
 719         return;
 720
 721     impl->keyEvent(event, self, _cmd);
 722 }
 723
 724 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 725 {
 726     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 727     if (impl == NULL)
 728         return;
 729
 730     impl->insertText(text, self, _cmd);
 731 }
 732
 733 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 734 {
 735     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 736     if (impl == NULL)
 737         return NO;
 738
 739     return impl->performKeyEquivalent(event, self, _cmd);
 740 }
 741
 742 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 743 {
 744     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 745     if (impl == NULL)
 746         return NO;
 747
 748     return impl->acceptsFirstResponder(self, _cmd);
 749 }
 750
 751 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 752 {
 753     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 754     if (impl == NULL)
 755         return NO;
 756
 757     return impl->becomeFirstResponder(self, _cmd);
 758 }
 759
 760 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 761 {
 762     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 763     if (impl == NULL)
 764         return NO;
 765
 766     return impl->resignFirstResponder(self, _cmd);
 767 }
 768
 769 void wxOSX_resetCursorRects(NSView* self, SEL _cmd)
 770 {
 771     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 772     if (impl == NULL)
 773         return;
 774
 775     impl->resetCursorRects(self, _cmd);
 776 }
 777
 778 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 779 {
 780     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 781     if (impl == NULL)
 782         return NO;
 783
 784     return impl->isFlipped(self, _cmd) ? YES:NO;
 785 }
 786
 787 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 788
 789 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 790 {
 791     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 792     if (impl == NULL)
 793         return;
 794
 795 #ifdef wxUSE_THREADS
 796     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 797     // dialog. This causes a drawRect of the active dialog from outside the
 798     // main UI thread. This causes an occasional crash since the wx drawing
 799     // objects (like wxPen) are not thread safe.
 800     //
 801     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 802     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 803     if ( !wxThread::IsMain() )
 804     {
 805         if ( impl->IsUserPane() )
 806         {
 807             wxWindow* win = impl->GetWXPeer();
 808             if ( win->UseBgCol() )
 809             {
 810
 811                 CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 812                 CGContextSaveGState( context );
 813
 814                 CGContextSetFillColorWithColor( context, win->GetBackgroundColour().GetCGColor());
 815                 CGRect r = CGRectMake(rect.origin.x, rect.origin.y, rect.size.width, rect.size.height);
 816                 CGContextFillRect( context, r );
 817
 818                 CGContextRestoreGState( context );
 819             }
 820         }
 821         else
 822         {
 823             // just call the superclass handler, we don't need any custom wx drawing
 824             // here and it seems to work fine:
 825             wxOSX_DrawRectHandlerPtr
 826             superimpl = (wxOSX_DrawRectHandlerPtr)
 827             [[self superclass] instanceMethodForSelector:_cmd];
 828             superimpl(self, _cmd, rect);
 829         }
 830
 831       return;
 832     }
 833 #endif // wxUSE_THREADS
 834
 835     return impl->drawRect(&rect, self, _cmd);
 836 }
 837
 838 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 839 {
 840     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 841     if (impl == NULL)
 842         return;
 843
 844     impl->controlAction(self, _cmd, sender);
 845 }
 846
 847 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 848 {
 849     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 850     if (impl == NULL)
 851         return;
 852
 853     impl->controlDoubleAction(self, _cmd, sender);
 854 }
 855
 856 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 857 {
 858     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 859     NSPasteboard *pboard = [sender draggingPasteboard];
 860     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 861
 862     wxWindow* wxpeer = GetWXPeer();
 863     if ( wxpeer == NULL )
 864         return NSDragOperationNone;
 865
 866     wxDropTarget* target = wxpeer->GetDropTarget();
 867     if ( target == NULL )
 868         return NSDragOperationNone;
 869
 870     wxDragResult result = wxDragNone;
 871     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 872     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 873
 874     if ( sourceDragMask & NSDragOperationLink )
 875         result = wxDragLink;
 876     else if ( sourceDragMask & NSDragOperationCopy )
 877         result = wxDragCopy;
 878     else if ( sourceDragMask & NSDragOperationMove )
 879         result = wxDragMove;
 880
 881     PasteboardRef pboardRef;
 882     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 883     target->SetCurrentDragPasteboard(pboardRef);
 884     result = target->OnEnter(pt.x, pt.y, result);
 885     CFRelease(pboardRef);
 886
 887     NSDragOperation nsresult = NSDragOperationNone;
 888     switch (result )
 889     {
 890         case wxDragLink:
 891             nsresult = NSDragOperationLink;
 892         case wxDragMove:
 893             nsresult = NSDragOperationMove;
 894         case wxDragCopy:
 895             nsresult = NSDragOperationCopy;
 896         default :
 897             break;
 898     }
 899     return nsresult;
 900 }
 901
 902 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 903 {
 904     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 905     NSPasteboard *pboard = [sender draggingPasteboard];
 906
 907     wxWindow* wxpeer = GetWXPeer();
 908     if ( wxpeer == NULL )
 909         return;
 910
 911     wxDropTarget* target = wxpeer->GetDropTarget();
 912     if ( target == NULL )
 913         return;
 914
 915     PasteboardRef pboardRef;
 916     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 917     target->SetCurrentDragPasteboard(pboardRef);
 918     target->OnLeave();
 919     CFRelease(pboardRef);
 920  }
 921
 922 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 923 {
 924     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 925     NSPasteboard *pboard = [sender draggingPasteboard];
 926     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 927
 928     wxWindow* wxpeer = GetWXPeer();
 929     if ( wxpeer == NULL )
 930         return NSDragOperationNone;
 931
 932     wxDropTarget* target = wxpeer->GetDropTarget();
 933     if ( target == NULL )
 934         return NSDragOperationNone;
 935
 936     wxDragResult result = wxDragNone;
 937     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 938     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 939
 940     if ( sourceDragMask & NSDragOperationLink )
 941         result = wxDragLink;
 942     else if ( sourceDragMask & NSDragOperationCopy )
 943         result = wxDragCopy;
 944     else if ( sourceDragMask & NSDragOperationMove )
 945         result = wxDragMove;
 946
 947     PasteboardRef pboardRef;
 948     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 949     target->SetCurrentDragPasteboard(pboardRef);
 950     result = target->OnDragOver(pt.x, pt.y, result);
 951     CFRelease(pboardRef);
 952
 953     NSDragOperation nsresult = NSDragOperationNone;
 954     switch (result )
 955     {
 956         case wxDragLink:
 957             nsresult = NSDragOperationLink;
 958         case wxDragMove:
 959             nsresult = NSDragOperationMove;
 960         case wxDragCopy:
 961             nsresult = NSDragOperationCopy;
 962         default :
 963             break;
 964     }
 965     return nsresult;
 966 }
 967
 968 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 969 {
 970     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 971
 972     NSPasteboard *pboard = [sender draggingPasteboard];
 973     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 974
 975     wxWindow* wxpeer = GetWXPeer();
 976     wxDropTarget* target = wxpeer->GetDropTarget();
 977     wxDragResult result = wxDragNone;
 978     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 979     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 980
 981     if ( sourceDragMask & NSDragOperationLink )
 982         result = wxDragLink;
 983     else if ( sourceDragMask & NSDragOperationCopy )
 984         result = wxDragCopy;
 985     else if ( sourceDragMask & NSDragOperationMove )
 986         result = wxDragMove;
 987
 988     PasteboardRef pboardRef;
 989     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 990     target->SetCurrentDragPasteboard(pboardRef);
 991
 992     if (target->OnDrop(pt.x, pt.y))
 993         result = target->OnData(pt.x, pt.y, result);
 994
 995     CFRelease(pboardRef);
 996
 997     return result != wxDragNone;
 998 }
 999
1000 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
1001 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1002 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1003 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
1004 typedef BOOL (*wxOSX_ResetCursorRectsHandlerPtr)(NSView* self, SEL _cmd);
1005
1006 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1007 {
1008     if ( !DoHandleMouseEvent(event) )
1009     {
1010         // for plain NSView mouse events would propagate to parents otherwise
1011         if (!IsUserPane())
1012         {
1013             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1014             superimpl(slf, (SEL)_cmd, event);
1015         }
1016     }
1017 }
1018
1019 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1020 {
1021     if ( [event type] == NSKeyDown )
1022     {
1023         // there are key equivalents that are not command-combos and therefore not handled by cocoa automatically,
1024         // therefore we call the menubar directly here, exit if the menu is handling the shortcut
1025         if ( [[[NSApplication sharedApplication] mainMenu] performKeyEquivalent:event] )
1026             return;
1027
1028         m_lastKeyDownEvent = event;
1029     }
1030
1031     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1032     {
1033         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1034         superimpl(slf, (SEL)_cmd, event);
1035     }
1036     m_lastKeyDownEvent = NULL;
1037 }
1038
1039 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1040 {
1041     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1042     {
1043         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1044         superimpl(slf, (SEL)_cmd, text);
1045     }
1046 }
1047
1048
1049 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1050 {
1051     bool handled = false;
1052
1053     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1054     SetupKeyEvent( wxevent, event );
1055
1056     // because performKeyEquivalent is going up the entire view hierarchy, we don't have to
1057     // walk up the ancestors ourselves but let cocoa do it
1058
1059     int command = m_wxPeer->GetAcceleratorTable()->GetCommand( wxevent );
1060     if (command != -1)
1061     {
1062         wxEvtHandler * const handler = m_wxPeer->GetEventHandler();
1063
1064         wxCommandEvent command_event( wxEVT_COMMAND_MENU_SELECTED, command );
1065         handled = handler->ProcessEvent( command_event );
1066
1067         if ( !handled )
1068         {
1069             // accelerators can also be used with buttons, try them too
1070             command_event.SetEventType(wxEVT_COMMAND_BUTTON_CLICKED);
1071             handled = handler->ProcessEvent( command_event );
1072         }
1073     }
1074
1075     if ( !handled )
1076     {
1077         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1078         return superimpl(slf, (SEL)_cmd, event);
1079     }
1080     return YES;
1081 }
1082
1083 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1084 {
1085     if ( IsUserPane() )
1086         return m_wxPeer->AcceptsFocus();
1087     else
1088     {
1089         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1090         return superimpl(slf, (SEL)_cmd);
1091     }
1092 }
1093
1094 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1095 {
1096     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1097     // get the current focus before running becomeFirstResponder
1098     NSView* otherView = FindFocus();
1099
1100     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1101     BOOL r = superimpl(slf, (SEL)_cmd);
1102     if ( r )
1103     {
1104         DoNotifyFocusEvent( true, otherWindow );
1105     }
1106
1107     return r;
1108 }
1109
1110 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1111 {
1112     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1113     BOOL r = superimpl(slf, (SEL)_cmd);
1114     // get the current focus after running resignFirstResponder
1115     // note that this value isn't reliable, it might return the same view that
1116     // is resigning
1117     NSView* otherView = FindFocus();
1118     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1119
1120     // It doesn't make sense to notify about the loss of focus if we're not
1121     // really losing it and the window which has just gained focus is the same
1122     // one as this window itself. Of course, this should never happen in the
1123     // first place but somehow it does in wxGrid code and without this check we
1124     // enter into an infinite recursion, see #12267.
1125     if ( otherWindow == this )
1126         return r;
1127
1128     // NSTextViews have an editor as true responder, therefore the might get the
1129     // resign notification if their editor takes over, don't trigger any event then
1130     if ( r && !m_hasEditor)
1131     {
1132         DoNotifyFocusEvent( false, otherWindow );
1133     }
1134     return r;
1135 }
1136
1137 void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
1138 {
1139     wxWindow* wxpeer = GetWXPeer();
1140     if ( wxpeer )
1141     {
1142         NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
1143         if (cursor == NULL)
1144         {
1145             wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1146             superimpl(slf, (SEL)_cmd);
1147         }
1148         else
1149         {
1150             [slf addCursorRect: [slf bounds]
1151                 cursor: cursor];
1152         }
1153     }
1154 }
1155
1156 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1157 {
1158     return m_isFlipped;
1159 }
1160
1161
1162 #define OSX_DEBUG_DRAWING 0
1163
1164 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1165 {
1166     // preparing the update region
1167
1168     wxRegion updateRgn;
1169     const NSRect *rects;
1170     NSInteger count;
1171
1172     [slf getRectsBeingDrawn:&rects count:&count];
1173     for ( int i = 0 ; i < count ; ++i )
1174     {
1175         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1176     }
1177
1178     wxWindow* wxpeer = GetWXPeer();
1179
1180     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1181     {
1182         // as this update region is in native window locals we must adapt it to wx window local
1183         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1184     }
1185
1186     if ( wxpeer->MacGetTopLevelWindow()->GetWindowStyle() & wxFRAME_SHAPED )
1187     {
1188         int xoffset = 0, yoffset = 0;
1189         wxRegion rgn = wxpeer->MacGetTopLevelWindow()->GetShape();
1190         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1191         rgn.Offset( xoffset, yoffset );
1192         updateRgn.Intersect(rgn);
1193     }
1194
1195     wxpeer->GetUpdateRegion() = updateRgn;
1196
1197     // setting up the drawing context
1198
1199     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1200     CGContextSaveGState( context );
1201
1202 #if OSX_DEBUG_DRAWING
1203     CGContextBeginPath( context );
1204     CGContextMoveToPoint(context, 0, 0);
1205     NSRect bounds = [slf bounds];
1206     CGContextAddLineToPoint(context, 10, 0);
1207     CGContextMoveToPoint(context, 0, 0);
1208     CGContextAddLineToPoint(context, 0, 10);
1209     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1210     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1211     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1212     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1213     CGContextClosePath( context );
1214     CGContextStrokePath(context);
1215 #endif
1216
1217     if ( !m_isFlipped )
1218     {
1219         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1220         CGContextScaleCTM( context, 1, -1 );
1221     }
1222
1223     wxpeer->MacSetCGContextRef( context );
1224
1225     bool handled = wxpeer->MacDoRedraw( 0 );
1226     CGContextRestoreGState( context );
1227
1228     CGContextSaveGState( context );
1229     if ( !handled )
1230     {
1231         // call super
1232         SEL _cmd = @selector(drawRect:);
1233         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1234         superimpl(slf, _cmd, *(NSRect*)rect);
1235         CGContextRestoreGState( context );
1236         CGContextSaveGState( context );
1237     }
1238     // as we called restore above, we have to flip again if necessary
1239     if ( !m_isFlipped )
1240     {
1241         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1242         CGContextScaleCTM( context, 1, -1 );
1243     }
1244     wxpeer->MacPaintChildrenBorders();
1245     wxpeer->MacSetCGContextRef( NULL );
1246     CGContextRestoreGState( context );
1247 }
1248
1249 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1250 {
1251     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1252     if ( wxpeer )
1253         wxpeer->OSXHandleClicked(0);
1254 }
1255
1256 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1257 {
1258 }
1259
1260 void wxWidgetCocoaImpl::controlTextDidChange()
1261 {
1262     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1263     if ( wxpeer )
1264     {
1265         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1266         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1267         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1268         if ( tc )
1269             tc->SendTextUpdatedEventIfAllowed();
1270         else if ( cb )
1271             cb->SendTextUpdatedEventIfAllowed();
1272         else
1273         {
1274             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1275         }
1276     }
1277 }
1278
1279 //
1280
1281 #if OBJC_API_VERSION >= 2
1282
1283 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1284     class_addMethod(c, s, i, t );
1285
1286 #else
1287
1288 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1289     { s, (char*) t, i },
1290
1291 #endif
1292
1293 void wxOSXCocoaClassAddWXMethods(Class c)
1294 {
1295
1296 #if OBJC_API_VERSION < 2
1297     static objc_method wxmethods[] =
1298     {
1299 #endif
1300
1301     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1302     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1303     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1304
1305     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1306     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1307     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1308
1309     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1310
1311     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1312     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1313     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1314
1315     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1316
1317     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1318     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1319     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1320
1321     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1322     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1323     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1324
1325     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1326
1327     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1328
1329     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1330     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1331     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1332     wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
1333
1334     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1335     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1336
1337     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1338     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1339
1340 #if wxUSE_DRAG_AND_DROP
1341     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1342     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1343     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1344     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1345 #endif
1346
1347 #if OBJC_API_VERSION < 2
1348     } ;
1349     static int method_count = WXSIZEOF( wxmethods );
1350     static objc_method_list *wxmethodlist = NULL;
1351     if ( wxmethodlist == NULL )
1352     {
1353         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1354         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1355         wxmethodlist->method_count = method_count;
1356         wxmethodlist->obsolete = 0;
1357     }
1358     class_addMethods( c, wxmethodlist );
1359 #endif
1360 }
1361
1362 //
1363 // C++ implementation class
1364 //
1365
1366 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1367
1368 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl, bool isUserPane ) :
1369     wxWidgetImpl( peer, isRootControl, isUserPane )
1370 {
1371     Init();
1372     m_osxView = w;
1373
1374     // check if the user wants to create the control initially hidden
1375     if ( !peer->IsShown() )
1376         SetVisibility(false);
1377
1378     // gc aware handling
1379     if ( m_osxView )
1380         CFRetain(m_osxView);
1381     [m_osxView release];
1382 }
1383
1384 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1385 {
1386     Init();
1387 }
1388
1389 void wxWidgetCocoaImpl::Init()
1390 {
1391     m_osxView = NULL;
1392     m_isFlipped = true;
1393     m_lastKeyDownEvent = NULL;
1394     m_hasEditor = false;
1395 }
1396
1397 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1398 {
1399     RemoveAssociations( this );
1400
1401     if ( !IsRootControl() )
1402     {
1403         NSView *sv = [m_osxView superview];
1404         if ( sv != nil )
1405             [m_osxView removeFromSuperview];
1406     }
1407     // gc aware handling
1408     if ( m_osxView )
1409         CFRelease(m_osxView);
1410 }
1411
1412 bool wxWidgetCocoaImpl::IsVisible() const
1413 {
1414     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1415 }
1416
1417 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1418 {
1419     [m_osxView setHidden:(visible ? NO:YES)];
1420 }
1421
1422 // ----------------------------------------------------------------------------
1423 // window animation stuff
1424 // ----------------------------------------------------------------------------
1425
1426 // define a delegate used to refresh the window during animation
1427 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1428 {
1429     wxWindow *m_win;
1430     bool m_isDone;
1431 }
1432
1433 - (id)init:(wxWindow *)win;
1434
1435 - (bool)isDone;
1436
1437 // NSAnimationDelegate methods
1438 - (void)animationDidEnd:(NSAnimation*)animation;
1439 - (void)animation:(NSAnimation*)animation
1440         didReachProgressMark:(NSAnimationProgress)progress;
1441 @end
1442
1443 @implementation wxNSAnimationDelegate
1444
1445 - (id)init:(wxWindow *)win
1446 {
1447     [super init];
1448
1449     m_win = win;
1450     m_isDone = false;
1451
1452     return self;
1453 }
1454
1455 - (bool)isDone
1456 {
1457     return m_isDone;
1458 }
1459
1460 - (void)animation:(NSAnimation*)animation
1461         didReachProgressMark:(NSAnimationProgress)progress
1462 {
1463     wxUnusedVar(animation);
1464     wxUnusedVar(progress);
1465
1466     m_win->SendSizeEvent();
1467 }
1468
1469 - (void)animationDidEnd:(NSAnimation*)animation
1470 {
1471     wxUnusedVar(animation);
1472     m_isDone = true;
1473 }
1474
1475 @end
1476
1477 /* static */
1478 bool
1479 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1480                                               bool show,
1481                                               wxShowEffect effect,
1482                                               unsigned timeout)
1483 {
1484     // create the dictionary describing the animation to perform on this view
1485     NSObject * const
1486         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1487     NSMutableDictionary * const
1488         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1489     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1490
1491     // determine the start and end rectangles assuming we're hiding the window
1492     const wxRect rectOrig = win->GetRect();
1493     wxRect rectStart,
1494            rectEnd;
1495     rectStart =
1496     rectEnd = rectOrig;
1497
1498     if ( show )
1499     {
1500         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1501                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1502             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1503         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1504                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1505             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1506         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1507                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1508             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1509         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1510                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1511             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1512     }
1513
1514     switch ( effect )
1515     {
1516         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1517         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1518             rectEnd.width = 0;
1519             break;
1520
1521         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1522         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1523             rectEnd.x = rectStart.GetRight();
1524             rectEnd.width = 0;
1525             break;
1526
1527         case wxSHOW_EFFECT_ROLL_TO_TOP:
1528         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1529             rectEnd.height = 0;
1530             break;
1531
1532         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1533         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1534             rectEnd.y = rectStart.GetBottom();
1535             rectEnd.height = 0;
1536             break;
1537
1538         case wxSHOW_EFFECT_EXPAND:
1539             rectEnd.x = rectStart.x + rectStart.width / 2;
1540             rectEnd.y = rectStart.y + rectStart.height / 2;
1541             rectEnd.width =
1542             rectEnd.height = 0;
1543             break;
1544
1545         case wxSHOW_EFFECT_BLEND:
1546             [dict setObject:(show ? NSViewAnimationFadeInEffect
1547                                   : NSViewAnimationFadeOutEffect)
1548                   forKey:NSViewAnimationEffectKey];
1549             break;
1550
1551         case wxSHOW_EFFECT_NONE:
1552         case wxSHOW_EFFECT_MAX:
1553             wxFAIL_MSG( "unexpected animation effect" );
1554             return false;
1555
1556         default:
1557             wxFAIL_MSG( "unknown animation effect" );
1558             return false;
1559     };
1560
1561     if ( show )
1562     {
1563         // we need to restore it to the original rectangle instead of making it
1564         // disappear
1565         wxSwap(rectStart, rectEnd);
1566
1567         // and as the window is currently hidden, we need to show it for the
1568         // animation to be visible at all (but don't restore it at its full
1569         // rectangle as it shouldn't appear immediately)
1570         win->SetSize(rectStart);
1571         win->Show();
1572     }
1573
1574     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1575                                     ? [(NSView *)viewOrWin superview]
1576                                     : nil;
1577     const NSRect rStart = wxToNSRect(parentView, rectStart);
1578     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1579
1580     [dict setObject:[NSValue valueWithRect:rStart]
1581           forKey:NSViewAnimationStartFrameKey];
1582     [dict setObject:[NSValue valueWithRect:rEnd]
1583           forKey:NSViewAnimationEndFrameKey];
1584
1585     // create an animation using the values in the above dictionary
1586     NSViewAnimation * const
1587         anim = [[NSViewAnimation alloc]
1588                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1589
1590     if ( !timeout )
1591     {
1592         // what is a good default duration? Windows uses 200ms, Web frameworks
1593         // use anything from 250ms to 1s... choose something in the middle
1594         timeout = 500;
1595     }
1596
1597     [anim setDuration:timeout/1000.];   // duration is in seconds here
1598
1599     // if the window being animated changes its layout depending on its size
1600     // (which is almost always the case) we need to redo it during animation
1601     //
1602     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1603     // controls in wxInfoBar visibly jump around)
1604     const int NUM_LAYOUTS = 20;
1605     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1606         [anim addProgressMark:f];
1607
1608     wxNSAnimationDelegate * const
1609         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1610     [anim setDelegate:animDelegate];
1611     [anim startAnimation];
1612
1613     // Cocoa is capable of doing animation asynchronously or even from separate
1614     // thread but wx API doesn't provide any way to be notified about the
1615     // animation end and without this we really must ensure that the window has
1616     // the expected (i.e. the same as if a simple Show() had been used) size
1617     // when we return, so block here until the animation finishes
1618     //
1619     // notice that because the default animation mode is NSAnimationBlocking,
1620     // no user input events ought to be processed from here
1621     {
1622         wxEventLoopGuarantor ensureEventLoopExistence;
1623         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1624         while ( ![animDelegate isDone] )
1625             loop->Dispatch();
1626     }
1627
1628     if ( !show )
1629     {
1630         // NSViewAnimation is smart enough to hide the NSView being animated at
1631         // the end but we also must ensure that it's hidden for wx too
1632         win->Hide();
1633
1634         // and we must also restore its size because it isn't expected to
1635         // change just because the window was hidden
1636         win->SetSize(rectOrig);
1637     }
1638     else
1639     {
1640         // refresh it once again after the end to ensure that everything is in
1641         // place
1642         win->SendSizeEvent();
1643     }
1644
1645     [anim setDelegate:nil];
1646     [animDelegate release];
1647     [anim release];
1648
1649     return true;
1650 }
1651
1652 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1653                                        wxShowEffect effect,
1654                                        unsigned timeout)
1655 {
1656     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1657 }
1658
1659 void wxWidgetCocoaImpl::Raise()
1660 {
1661     // Not implemented
1662 }
1663
1664 void wxWidgetCocoaImpl::Lower()
1665 {
1666     // Not implemented
1667 }
1668
1669 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1670 {
1671 #if 1
1672     SetNeedsDisplay() ;
1673 #else
1674     // We should do something like this, but it wasn't working in 10.4.
1675     if (GetNeedsDisplay() )
1676     {
1677         SetNeedsDisplay() ;
1678     }
1679     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1680     NSSize offset = NSMakeSize((float)dx, (float)dy);
1681     [m_osxView scrollRect:r by:offset];
1682 #endif
1683 }
1684
1685 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1686 {
1687     wxWindowMac* parent = GetWXPeer()->GetParent();
1688     // under Cocoa we might have a contentView in the wxParent to which we have to
1689     // adjust the coordinates
1690     if (parent && [m_osxView superview] != parent->GetHandle() )
1691     {
1692         int cx = 0,cy = 0,cw = 0,ch = 0;
1693         if ( parent->GetPeer() )
1694         {
1695             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1696             x -= cx;
1697             y -= cy;
1698         }
1699     }
1700     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
1701     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
1702     [m_osxView setFrame:r];
1703     [[m_osxView superview] setNeedsDisplayInRect:r];
1704
1705     wxNSView* wxview = (wxNSView*)m_osxView;
1706 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
1707     if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
1708         [wxview updateTrackingArea];
1709 #else
1710     if ([m_osxView respondsToSelector:@selector(trackingTag)] )
1711     {
1712         if ( [wxview trackingTag] )
1713             [wxview removeTrackingRect: [wxview trackingTag]];
1714
1715         [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
1716     }
1717 #endif
1718 }
1719
1720 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
1721 {
1722     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
1723     x = r.GetLeft();
1724     y = r.GetTop();
1725
1726     // under Cocoa we might have a contentView in the wxParent to which we have to
1727     // adjust the coordinates
1728     wxWindowMac* parent = GetWXPeer()->GetParent();
1729     if (parent && [m_osxView superview] != parent->GetHandle() )
1730     {
1731         int cx = 0,cy = 0,cw = 0,ch = 0;
1732         if ( parent->GetPeer() )
1733         {
1734             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1735             x += cx;
1736             y += cy;
1737         }
1738     }
1739 }
1740
1741 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
1742 {
1743     NSRect rect = [m_osxView frame];
1744     width = (int)rect.size.width;
1745     height = (int)rect.size.height;
1746 }
1747
1748 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
1749 {
1750     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
1751     {
1752         NSView* cv = [m_osxView contentView];
1753
1754         NSRect bounds = [m_osxView bounds];
1755         NSRect rect = [cv frame];
1756
1757         int y = (int)rect.origin.y;
1758         int x = (int)rect.origin.x;
1759         if ( ![ m_osxView isFlipped ] )
1760             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
1761         left = x;
1762         top = y;
1763         width = (int)rect.size.width;
1764         height = (int)rect.size.height;
1765     }
1766     else
1767     {
1768         left = top = 0;
1769         GetSize( width, height );
1770     }
1771 }
1772
1773 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
1774 {
1775     if ( where )
1776         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
1777     else
1778         [m_osxView setNeedsDisplay:YES];
1779 }
1780
1781 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
1782 {
1783     return [m_osxView needsDisplay];
1784 }
1785
1786 bool wxWidgetCocoaImpl::CanFocus() const
1787 {
1788     return [m_osxView canBecomeKeyView] == YES;
1789 }
1790
1791 bool wxWidgetCocoaImpl::HasFocus() const
1792 {
1793     return ( FindFocus() == m_osxView );
1794 }
1795
1796 bool wxWidgetCocoaImpl::SetFocus()
1797 {
1798     if ( !CanFocus() )
1799         return false;
1800
1801     [[m_osxView window] makeKeyAndOrderFront:nil] ;
1802     [[m_osxView window] makeFirstResponder: m_osxView] ;
1803     return true;
1804 }
1805
1806
1807 void wxWidgetCocoaImpl::RemoveFromParent()
1808 {
1809     [m_osxView removeFromSuperview];
1810 }
1811
1812 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
1813 {
1814     NSView* container = parent->GetWXWidget() ;
1815     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
1816     [container addSubview:m_osxView];
1817 }
1818
1819 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
1820 {
1821     NSView* targetView = m_osxView;
1822     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1823         targetView = [(NSScrollView*) m_osxView documentView];
1824
1825     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
1826     {
1827         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1828                                                                 green:(CGFloat) (col.Green() / 255.0)
1829                                                                  blue:(CGFloat) (col.Blue() / 255.0)
1830                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
1831     }
1832 }
1833
1834 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
1835 {
1836     BOOL opaque = ( style == wxBG_STYLE_PAINT );
1837
1838     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
1839     {
1840         [m_osxView setOpaque: opaque];
1841     }
1842
1843     return true ;
1844 }
1845
1846 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
1847 {
1848     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
1849     {
1850         wxCFStringRef cf( title , encoding );
1851         [m_osxView setTitle:cf.AsNSString()];
1852     }
1853     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
1854     {
1855         wxCFStringRef cf( title , encoding );
1856         [m_osxView setStringValue:cf.AsNSString()];
1857     }
1858 }
1859
1860
1861 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
1862 {
1863     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
1864     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
1865     *pt = wxFromNSPoint( to->GetWXWidget(), p );
1866 }
1867
1868 wxInt32 wxWidgetCocoaImpl::GetValue() const
1869 {
1870     return [(NSControl*)m_osxView intValue];
1871 }
1872
1873 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
1874 {
1875     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
1876     {
1877         [m_osxView setIntValue:v];
1878     }
1879     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
1880     {
1881         [m_osxView setFloatValue:(double)v];
1882     }
1883     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
1884     {
1885         [m_osxView setDoubleValue:(double)v];
1886     }
1887 }
1888
1889 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
1890 {
1891     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
1892     {
1893         [m_osxView setMinValue:(double)v];
1894     }
1895 }
1896
1897 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
1898 {
1899     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
1900     {
1901         [m_osxView setMaxValue:(double)v];
1902     }
1903 }
1904
1905 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
1906 {
1907     if (  [m_osxView respondsToSelector:@selector(minValue)] )
1908     {
1909         return (int)[m_osxView minValue];
1910     }
1911     return 0;
1912 }
1913
1914 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
1915 {
1916     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
1917     {
1918         return (int)[m_osxView maxValue];
1919     }
1920     return 0;
1921 }
1922
1923 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
1924 {
1925     wxBitmap bmp;
1926
1927     // TODO: how to create a wxBitmap from NSImage?
1928 #if 0
1929     if ( [m_osxView respondsToSelector:@selector(image:)] )
1930         bmp = [m_osxView image];
1931 #endif
1932
1933     return bmp;
1934 }
1935
1936 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
1937 {
1938     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
1939     {
1940         [m_osxView setImage:bitmap.GetNSImage()];
1941         [m_osxView setNeedsDisplay:YES];
1942     }
1943 }
1944
1945 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
1946 {
1947     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
1948     {
1949         NSCellImagePosition pos;
1950         switch ( dir )
1951         {
1952             case wxLEFT:
1953                 pos = NSImageLeft;
1954                 break;
1955
1956             case wxRIGHT:
1957                 pos = NSImageRight;
1958                 break;
1959
1960             case wxTOP:
1961                 pos = NSImageAbove;
1962                 break;
1963
1964             case wxBOTTOM:
1965                 pos = NSImageBelow;
1966                 break;
1967
1968             default:
1969                 wxFAIL_MSG( "invalid image position" );
1970                 pos = NSNoImage;
1971         }
1972
1973         [m_osxView setImagePosition:pos];
1974     }
1975 }
1976
1977 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
1978 {
1979     // implementation in subclass
1980 }
1981
1982 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
1983 {
1984     r->x = r->y = r->width = r->height = 0;
1985
1986     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
1987     {
1988         NSRect former = [m_osxView frame];
1989         [m_osxView sizeToFit];
1990         NSRect best = [m_osxView frame];
1991         [m_osxView setFrame:former];
1992         r->width = (int)best.size.width;
1993         r->height = (int)best.size.height;
1994     }
1995 }
1996
1997 bool wxWidgetCocoaImpl::IsEnabled() const
1998 {
1999     NSView* targetView = m_osxView;
2000     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2001         targetView = [(NSScrollView*) m_osxView documentView];
2002
2003     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
2004         return [targetView isEnabled];
2005     return true;
2006 }
2007
2008 void wxWidgetCocoaImpl::Enable( bool enable )
2009 {
2010     NSView* targetView = m_osxView;
2011     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2012         targetView = [(NSScrollView*) m_osxView documentView];
2013
2014     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
2015         [targetView setEnabled:enable];
2016 }
2017
2018 void wxWidgetCocoaImpl::PulseGauge()
2019 {
2020 }
2021
2022 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
2023 {
2024 }
2025
2026 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
2027 {
2028     NSControlSize size = NSRegularControlSize;
2029
2030     switch ( variant )
2031     {
2032         case wxWINDOW_VARIANT_NORMAL :
2033             size = NSRegularControlSize;
2034             break ;
2035
2036         case wxWINDOW_VARIANT_SMALL :
2037             size = NSSmallControlSize;
2038             break ;
2039
2040         case wxWINDOW_VARIANT_MINI :
2041             size = NSMiniControlSize;
2042             break ;
2043
2044         case wxWINDOW_VARIANT_LARGE :
2045             size = NSRegularControlSize;
2046             break ;
2047
2048         default:
2049             wxFAIL_MSG(wxT("unexpected window variant"));
2050             break ;
2051     }
2052     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2053         [m_osxView setControlSize:size];
2054     else if ([m_osxView respondsToSelector:@selector(cell)])
2055     {
2056         id cell = [(id)m_osxView cell];
2057         if ([cell respondsToSelector:@selector(setControlSize:)])
2058             [cell setControlSize:size];
2059     }
2060 }
2061
2062 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2063 {
2064     if ([m_osxView respondsToSelector:@selector(setFont:)])
2065         [m_osxView setFont: font.OSXGetNSFont()];
2066     if ([m_osxView respondsToSelector:@selector(setTextColor:)])
2067         [m_osxView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2068                                                                  green:(CGFloat) (col.Green() / 255.0)
2069                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2070                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2071 }
2072
2073 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2074 {
2075     if (tooltip)
2076     {
2077         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2078         [m_osxView setToolTip: cf.AsNSString()];
2079     }
2080     else
2081         [m_osxView setToolTip: nil];
2082
2083 }
2084
2085 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2086 {
2087     WXWidget c =  control ? control : (WXWidget) m_osxView;
2088     wxWidgetImpl::Associate( c, this ) ;
2089     if ([c respondsToSelector:@selector(setAction:)])
2090     {
2091         [c setTarget: c];
2092         [c setAction: @selector(controlAction:)];
2093         if ([c respondsToSelector:@selector(setDoubleAction:)])
2094         {
2095             [c setDoubleAction: @selector(controlDoubleAction:)];
2096         }
2097
2098     }
2099 }
2100
2101 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2102 {
2103     wxKeyEvent wxevent(wxEVT_CHAR);
2104     SetupKeyEvent( wxevent, event, text );
2105
2106     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2107 }
2108
2109 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2110 {
2111     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2112     SetupKeyEvent( wxevent, event );
2113     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2114
2115     // this will fire higher level events, like insertText, to help
2116     // us handle EVT_CHAR, etc.
2117
2118     if ( !result )
2119     {
2120         if ( IsUserPane() && [event type] == NSKeyDown)
2121         {
2122             if ( wxevent.GetKeyCode() < WXK_SPACE || wxevent.GetKeyCode() == WXK_DELETE || wxevent.GetKeyCode() >= WXK_START )
2123             {
2124                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2125                 wxKeyEvent wxevent2(wxevent) ;
2126                 wxevent2.SetEventType(wxEVT_CHAR);
2127                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2128             }
2129             else
2130             {
2131                 if ( !wxevent.CmdDown() )
2132                 {
2133                     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2134                         [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2135                     else
2136                         [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2137                     result = true;
2138                 }
2139             }
2140         }
2141     }
2142
2143     return result;
2144 }
2145
2146 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2147 {
2148     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2149     SetupMouseEvent(wxevent , event) ;
2150
2151     return GetWXPeer()->HandleWindowEvent(wxevent);
2152 }
2153
2154 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2155 {
2156     wxWindow* thisWindow = GetWXPeer();
2157     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2158     {
2159         thisWindow->MacInvalidateBorders();
2160     }
2161
2162     if ( receivedFocus )
2163     {
2164         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2165         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2166         thisWindow->HandleWindowEvent(eventFocus);
2167
2168 #if wxUSE_CARET
2169         if ( thisWindow->GetCaret() )
2170             thisWindow->GetCaret()->OnSetFocus();
2171 #endif
2172
2173         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2174         event.SetEventObject(thisWindow);
2175         if (otherWindow)
2176             event.SetWindow(otherWindow->GetWXPeer());
2177         thisWindow->HandleWindowEvent(event) ;
2178     }
2179     else // !receivedFocuss
2180     {
2181 #if wxUSE_CARET
2182         if ( thisWindow->GetCaret() )
2183             thisWindow->GetCaret()->OnKillFocus();
2184 #endif
2185
2186         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2187
2188         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2189         event.SetEventObject(thisWindow);
2190         if (otherWindow)
2191             event.SetWindow(otherWindow->GetWXPeer());
2192         thisWindow->HandleWindowEvent(event) ;
2193     }
2194 }
2195
2196 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2197 {
2198     if ( !wxIsBusy() )
2199     {
2200         NSPoint location = [NSEvent mouseLocation];
2201         location = [[m_osxView window] convertScreenToBase:location];
2202         NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2203
2204         if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2205         {
2206             [(NSCursor*)cursor.GetHCURSOR() set];
2207         }
2208     }
2209     [[m_osxView window] invalidateCursorRectsForView:m_osxView];
2210 }
2211
2212 void wxWidgetCocoaImpl::CaptureMouse()
2213 {
2214     [[m_osxView window] disableCursorRects];
2215 }
2216
2217 void wxWidgetCocoaImpl::ReleaseMouse()
2218 {
2219     [[m_osxView window] enableCursorRects];
2220 }
2221
2222 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2223 {
2224     m_isFlipped = flipped;
2225 }
2226
2227 //
2228 // Factory methods
2229 //
2230
2231 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2232     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2233     long WXUNUSED(style), long WXUNUSED(extraStyle))
2234 {
2235     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2236     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2237
2238     // temporary hook for dnd
2239     [v registerForDraggedTypes:[NSArray arrayWithObjects:
2240         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
2241
2242     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v, false, true );
2243     return c;
2244 }
2245
2246 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2247 {
2248     NSWindow* tlw = now->GetWXWindow();
2249
2250     wxWidgetCocoaImpl* c = NULL;
2251     if ( now->IsNativeWindowWrapper() )
2252     {
2253         NSView* cv = [tlw contentView];
2254         c = new wxWidgetCocoaImpl( now, cv, true );
2255         // increase ref count, because the impl destructor will decrement it again
2256         CFRetain(cv);
2257         if ( !now->IsShown() )
2258             [cv setHidden:NO];
2259
2260     }
2261     else
2262     {
2263         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2264         c = new wxWidgetCocoaImpl( now, v, true );
2265         c->InstallEventHandler();
2266         [tlw setContentView:v];
2267     }
2268     return c;
2269 }