src/osx/cocoa/textctrl.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/textctrl.mm
   3 // Purpose:     wxTextCtrl
   4 // Author:      Stefan Csomor
   5 // Modified by: Ryan Norton (MLTE GetLineLength and GetLineText)
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: textctrl.cpp 54820 2008-07-29 20:04:11Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_TEXTCTRL
  15
  16 #include "wx/textctrl.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/intl.h"
  20     #include "wx/app.h"
  21     #include "wx/utils.h"
  22     #include "wx/dc.h"
  23     #include "wx/button.h"
  24     #include "wx/menu.h"
  25     #include "wx/settings.h"
  26     #include "wx/msgdlg.h"
  27     #include "wx/toplevel.h"
  28 #endif
  29
  30 #ifdef __DARWIN__
  31     #include <sys/types.h>
  32     #include <sys/stat.h>
  33 #else
  34     #include <stat.h>
  35 #endif
  36
  37 #if wxUSE_STD_IOSTREAM
  38     #if wxUSE_IOSTREAMH
  39         #include <fstream.h>
  40     #else
  41         #include <fstream>
  42     #endif
  43 #endif
  44
  45 #include "wx/filefn.h"
  46 #include "wx/sysopt.h"
  47 #include "wx/thread.h"
  48
  49 #include "wx/osx/private.h"
  50 #include "wx/osx/cocoa/private/textimpl.h"
  51
  52 @interface NSView(EditableView)
  53 - (BOOL)isEditable;
  54 - (void)setEditable:(BOOL)flag;
  55 @end
  56
  57 class wxMacEditHelper
  58 {
  59 public :
  60     wxMacEditHelper( NSView* textView )
  61     {
  62         m_textView = textView;
  63         m_formerState = YES;
  64         if ( textView )
  65         {
  66             m_formerState = [textView isEditable];
  67             [textView setEditable:YES];
  68         }
  69     }
  70
  71     ~wxMacEditHelper()
  72     {
  73         if ( m_textView )
  74             [m_textView setEditable:m_formerState];
  75     }
  76
  77 protected :
  78     BOOL m_formerState ;
  79     NSView* m_textView;
  80 } ;
  81
  82 @implementation wxNSSecureTextField
  83
  84 + (void)initialize
  85 {
  86     static BOOL initialized = NO;
  87     if (!initialized)
  88     {
  89         initialized = YES;
  90         wxOSXCocoaClassAddWXMethods( self );
  91     }
  92 }
  93
  94 - (void)controlTextDidChange:(NSNotification *)aNotification
  95 {
  96     wxUnusedVar(aNotification);
  97     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  98     if ( impl )
  99         impl->controlTextDidChange();
 100 }
 101
 102 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 103 {
 104     wxUnusedVar(aNotification);
 105     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 106     if ( impl )
 107     {
 108         impl->DoNotifyFocusEvent( false, NULL );
 109     }
 110 }
 111
 112 @end
 113
 114 @interface wxNSTextScrollView : NSScrollView
 115 {
 116 }
 117 @end
 118
 119 @implementation wxNSTextScrollView
 120
 121 + (void)initialize
 122 {
 123     static BOOL initialized = NO;
 124     if (!initialized)
 125     {
 126         initialized = YES;
 127         wxOSXCocoaClassAddWXMethods( self );
 128     }
 129 }
 130
 131 @end
 132
 133 @implementation wxNSTextFieldEditor
 134
 135 - (void) keyDown:(NSEvent*) event
 136 {
 137     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 138     lastKeyDownEvent = event;
 139     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 140         [super keyDown:event];
 141     lastKeyDownEvent = nil;
 142 }
 143
 144 - (void) keyUp:(NSEvent*) event
 145 {
 146     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 147     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 148         [super keyUp:event];
 149 }
 150
 151 - (void) flagsChanged:(NSEvent*) event
 152 {
 153     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 154     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 155         [super flagsChanged:event];
 156 }
 157
 158 - (BOOL) performKeyEquivalent:(NSEvent*) event
 159 {
 160     BOOL retval = [super performKeyEquivalent:event];
 161     return retval;
 162 }
 163
 164 - (void) insertText:(id) str
 165 {
 166     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 167     if ( impl == NULL || lastKeyDownEvent==nil || !impl->DoHandleCharEvent(lastKeyDownEvent, str) )
 168     {
 169         [super insertText:str];
 170     }
 171 }
 172
 173 @end
 174
 175 @implementation wxNSTextView
 176
 177 + (void)initialize
 178 {
 179     static BOOL initialized = NO;
 180     if (!initialized)
 181     {
 182         initialized = YES;
 183         wxOSXCocoaClassAddWXMethods( self );
 184     }
 185 }
 186
 187 - (void)textDidChange:(NSNotification *)aNotification
 188 {
 189     wxUnusedVar(aNotification);
 190     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 191     if ( impl )
 192         impl->controlTextDidChange();
 193 }
 194
 195 @end
 196
 197 @implementation wxNSTextField
 198
 199 + (void)initialize
 200 {
 201     static BOOL initialized = NO;
 202     if (!initialized)
 203     {
 204         initialized = YES;
 205         wxOSXCocoaClassAddWXMethods( self );
 206     }
 207 }
 208
 209 - (id) initWithFrame:(NSRect) frame
 210 {
 211     self = [super initWithFrame:frame];
 212     fieldEditor = nil;
 213     return self;
 214 }
 215
 216 - (void) dealloc
 217 {
 218     [fieldEditor release];
 219     [super dealloc];
 220 }
 221
 222 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
 223 {
 224     fieldEditor = editor;
 225 }
 226
 227 - (wxNSTextFieldEditor*) fieldEditor
 228 {
 229     return fieldEditor;
 230 }
 231
 232 - (void) setEnabled:(BOOL) flag
 233 {
 234     [super setEnabled: flag];
 235
 236     if (![self drawsBackground]) {
 237         // Static text is drawn incorrectly when disabled.
 238         // For an explanation, see
 239         // http://www.cocoabuilder.com/archive/message/cocoa/2006/7/21/168028
 240         if (flag) {
 241             [self setTextColor: [NSColor controlTextColor]];
 242         } else {
 243             [self setTextColor: [NSColor secondarySelectedControlColor]];
 244         }
 245     }
 246 }
 247
 248 - (void)controlTextDidChange:(NSNotification *)aNotification
 249 {
 250     wxUnusedVar(aNotification);
 251     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 252     if ( impl )
 253         impl->controlTextDidChange();
 254 }
 255
 256 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 257 {
 258     wxUnusedVar(textView);
 259     wxUnusedVar(control);
 260
 261     BOOL handled = NO;
 262
 263     // send back key events wx' common code knows how to handle
 264
 265     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 266     if ( impl  )
 267     {
 268         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 269         if ( wxpeer )
 270         {
 271             if (commandSelector == @selector(insertNewline:))
 272             {
 273                 [textView insertNewlineIgnoringFieldEditor:self];
 274                 handled = YES;
 275             }
 276             else if ( commandSelector == @selector(insertTab:))
 277             {
 278                 [textView insertTabIgnoringFieldEditor:self];
 279                 handled = YES;
 280             }
 281             else if ( commandSelector == @selector(insertBacktab:))
 282             {
 283                 [textView insertTabIgnoringFieldEditor:self];
 284                 handled = YES;
 285             }
 286         }
 287     }
 288
 289     return handled;
 290 }
 291
 292 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 293 {
 294     wxUnusedVar(aNotification);
 295     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 296     if ( impl )
 297     {
 298         impl->DoNotifyFocusEvent( false, NULL );
 299     }
 300 }
 301 @end
 302
 303 // wxNSTextViewControl
 304
 305 wxNSTextViewControl::wxNSTextViewControl( wxTextCtrl *wxPeer, WXWidget w )
 306     : wxWidgetCocoaImpl(wxPeer, w),
 307       wxTextWidgetImpl(wxPeer)
 308 {
 309     wxNSTextScrollView* sv = (wxNSTextScrollView*) w;
 310     m_scrollView = sv;
 311
 312     [m_scrollView setHasVerticalScroller:YES];
 313     [m_scrollView setHasHorizontalScroller:NO];
 314     [m_scrollView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
 315     NSSize contentSize = [m_scrollView contentSize];
 316
 317     wxNSTextView* tv = [[wxNSTextView alloc] initWithFrame: NSMakeRect(0, 0,
 318             contentSize.width, contentSize.height)];
 319     m_textView = tv;
 320     [tv setVerticallyResizable:YES];
 321     [tv setHorizontallyResizable:NO];
 322     [tv setAutoresizingMask:NSViewWidthSizable];
 323
 324     [m_scrollView setDocumentView: tv];
 325
 326     [tv setDelegate: tv];
 327
 328     InstallEventHandler(tv);
 329 }
 330
 331 wxNSTextViewControl::~wxNSTextViewControl()
 332 {
 333     if (m_textView)
 334         [m_textView setDelegate: nil];
 335 }
 336
 337 bool wxNSTextViewControl::CanFocus() const
 338 {
 339     // since this doesn't work (return false), we hardcode
 340     // if (m_textView)
 341     //    return [m_textView canBecomeKeyView];
 342     return true;
 343 }
 344
 345 wxString wxNSTextViewControl::GetStringValue() const
 346 {
 347     if (m_textView)
 348     {
 349         wxString result = wxCFStringRef::AsString([m_textView string], m_wxPeer->GetFont().GetEncoding());
 350         wxMacConvertNewlines13To10( &result ) ;
 351         return result;
 352     }
 353     return wxEmptyString;
 354 }
 355 void wxNSTextViewControl::SetStringValue( const wxString &str)
 356 {
 357     wxString st = str;
 358     wxMacConvertNewlines10To13( &st );
 359     wxMacEditHelper helper(m_textView);
 360
 361     if (m_textView)
 362         [m_textView setString: wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 363 }
 364
 365 void wxNSTextViewControl::Copy()
 366 {
 367     if (m_textView)
 368         [m_textView copy:nil];
 369
 370 }
 371
 372 void wxNSTextViewControl::Cut()
 373 {
 374     if (m_textView)
 375         [m_textView cut:nil];
 376 }
 377
 378 void wxNSTextViewControl::Paste()
 379 {
 380     if (m_textView)
 381         [m_textView paste:nil];
 382 }
 383
 384 bool wxNSTextViewControl::CanPaste() const
 385 {
 386     return true;
 387 }
 388
 389 void wxNSTextViewControl::SetEditable(bool editable)
 390 {
 391     if (m_textView)
 392         [m_textView setEditable: editable];
 393 }
 394
 395 void wxNSTextViewControl::GetSelection( long* from, long* to) const
 396 {
 397     if (m_textView)
 398     {
 399         NSRange range = [m_textView selectedRange];
 400         *from = range.location;
 401         *to = range.location + range.length;
 402     }
 403 }
 404
 405 void wxNSTextViewControl::SetSelection( long from , long to )
 406 {
 407     long textLength = [[m_textView string] length];
 408     if ((from == -1) && (to == -1))
 409     {
 410         from = 0 ;
 411         to = textLength ;
 412     }
 413     else
 414     {
 415         from = wxMin(textLength,wxMax(from,0)) ;
 416         if ( to == -1 )
 417             to = textLength;
 418         else
 419             to = wxMax(0,wxMin(textLength,to)) ;
 420     }
 421
 422     NSRange selrange = NSMakeRange(from, to-from);
 423     [m_textView setSelectedRange:selrange];
 424     [m_textView scrollRangeToVisible:selrange];
 425 }
 426
 427 void wxNSTextViewControl::WriteText(const wxString& str)
 428 {
 429     wxString st = str;
 430     wxMacConvertNewlines10To13( &st );
 431     wxMacEditHelper helper(m_textView);
 432     NSEvent* formerEvent = m_lastKeyDownEvent;
 433     m_lastKeyDownEvent = nil;
 434     [m_textView insertText:wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 435     m_lastKeyDownEvent = formerEvent;
 436 }
 437
 438 void wxNSTextViewControl::SetFont( const wxFont & font , const wxColour& WXUNUSED(foreground) , long WXUNUSED(windowStyle), bool WXUNUSED(ignoreBlack) )
 439 {
 440     if ([m_textView respondsToSelector:@selector(setFont:)])
 441         [m_textView setFont: font.OSXGetNSFont()];
 442 }
 443
 444 bool wxNSTextViewControl::GetStyle(long position, wxTextAttr& style)
 445 {
 446     if (m_textView && position >=0)
 447     {
 448         NSFont* font = NULL;
 449         NSColor* bgcolor = NULL;
 450         NSColor* fgcolor = NULL;
 451         // NOTE: It appears that other platforms accept GetStyle with the position == length
 452         // but that NSTextStorage does not accept length as a valid position.
 453         // Therefore we return the default control style in that case.
 454         if (position < [[m_textView string] length])
 455         {
 456             NSTextStorage* storage = [m_textView textStorage];
 457             font = [[storage attribute:NSFontAttributeName atIndex:position effectiveRange:NULL] autorelease];
 458             bgcolor = [[storage attribute:NSBackgroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 459             fgcolor = [[storage attribute:NSForegroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 460         }
 461         else
 462         {
 463             NSDictionary* attrs = [m_textView typingAttributes];
 464             font = [[attrs objectForKey:NSFontAttributeName] autorelease];
 465             bgcolor = [[attrs objectForKey:NSBackgroundColorAttributeName] autorelease];
 466             fgcolor = [[attrs objectForKey:NSForegroundColorAttributeName] autorelease];
 467         }
 468
 469         if (font)
 470             style.SetFont(wxFont(font));
 471
 472         if (bgcolor)
 473             style.SetBackgroundColour(wxColour(bgcolor));
 474
 475         if (fgcolor)
 476             style.SetTextColour(wxColour(fgcolor));
 477         return true;
 478     }
 479
 480     return false;
 481 }
 482
 483 void wxNSTextViewControl::SetStyle(long start,
 484                                 long end,
 485                                 const wxTextAttr& style)
 486 {
 487     if (m_textView) {
 488         NSRange range = NSMakeRange(start, end-start);
 489         if (start == -1 && end == -1)
 490             range = [m_textView selectedRange];
 491
 492         NSTextStorage* storage = [m_textView textStorage];
 493
 494         wxFont font = style.GetFont();
 495         if (style.HasFont() && font.IsOk())
 496             [storage addAttribute:NSFontAttributeName value:font.OSXGetNSFont() range:range];
 497
 498         wxColour bgcolor = style.GetBackgroundColour();
 499         if (style.HasBackgroundColour() && bgcolor.IsOk())
 500             [storage addAttribute:NSBackgroundColorAttributeName value:bgcolor.OSXGetNSColor() range:range];
 501
 502         wxColour fgcolor = style.GetTextColour();
 503         if (style.HasTextColour() && fgcolor.IsOk())
 504             [storage addAttribute:NSForegroundColorAttributeName value:fgcolor.OSXGetNSColor() range:range];
 505     }
 506 }
 507
 508 void wxNSTextViewControl::CheckSpelling(bool check)
 509 {
 510     if (m_textView)
 511         [m_textView setContinuousSpellCheckingEnabled: check];
 512 }
 513
 514 wxSize wxNSTextViewControl::GetBestSize() const
 515 {
 516     if (m_textView && [m_textView layoutManager])
 517     {
 518         NSRect rect = [[m_textView layoutManager] usedRectForTextContainer: [m_textView textContainer]];
 519         return wxSize((int)(rect.size.width + [m_textView textContainerInset].width),
 520                       (int)(rect.size.height + [m_textView textContainerInset].height));
 521     }
 522     return wxSize(0,0);
 523 }
 524
 525 // wxNSTextFieldControl
 526
 527 wxNSTextFieldControl::wxNSTextFieldControl( wxTextCtrl *text, WXWidget w )
 528     : wxWidgetCocoaImpl(text, w),
 529       wxTextWidgetImpl(text)
 530 {
 531     Init(w);
 532 }
 533
 534 wxNSTextFieldControl::wxNSTextFieldControl(wxWindow *wxPeer,
 535                                            wxTextEntry *entry,
 536                                            WXWidget w)
 537     : wxWidgetCocoaImpl(wxPeer, w),
 538       wxTextWidgetImpl(entry)
 539 {
 540     Init(w);
 541 }
 542
 543 void wxNSTextFieldControl::Init(WXWidget w)
 544 {
 545     NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>) *tf = (NSTextField*) w;
 546     m_textField = tf;
 547     [m_textField setDelegate: tf];
 548     m_selStart = m_selEnd = 0;
 549     m_hasEditor = [w isKindOfClass:[NSTextField class]];
 550 }
 551
 552 wxNSTextFieldControl::~wxNSTextFieldControl()
 553 {
 554     if (m_textField)
 555         [m_textField setDelegate: nil];
 556 }
 557
 558 wxString wxNSTextFieldControl::GetStringValue() const
 559 {
 560     return wxCFStringRef::AsString([m_textField stringValue], m_wxPeer->GetFont().GetEncoding());
 561 }
 562
 563 void wxNSTextFieldControl::SetStringValue( const wxString &str)
 564 {
 565     wxMacEditHelper helper(m_textField);
 566     [m_textField setStringValue: wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 567 }
 568
 569 void wxNSTextFieldControl::Copy()
 570 {
 571     NSText* editor = [m_textField currentEditor];
 572     if ( editor )
 573     {
 574         [editor copy:nil];
 575     }
 576 }
 577
 578 void wxNSTextFieldControl::Cut()
 579 {
 580     NSText* editor = [m_textField currentEditor];
 581     if ( editor )
 582     {
 583         [editor cut:nil];
 584     }
 585 }
 586
 587 void wxNSTextFieldControl::Paste()
 588 {
 589     NSText* editor = [m_textField currentEditor];
 590     if ( editor )
 591     {
 592         [editor paste:nil];
 593     }
 594 }
 595
 596 bool wxNSTextFieldControl::CanPaste() const
 597 {
 598     return true;
 599 }
 600
 601 void wxNSTextFieldControl::SetEditable(bool editable)
 602 {
 603     [m_textField setEditable:editable];
 604 }
 605
 606 void wxNSTextFieldControl::GetSelection( long* from, long* to) const
 607 {
 608     NSText* editor = [m_textField currentEditor];
 609     if ( editor )
 610     {
 611         NSRange range = [editor selectedRange];
 612         *from = range.location;
 613         *to = range.location + range.length;
 614     }
 615     else
 616     {
 617         *from = m_selStart;
 618         *to = m_selEnd;
 619     }
 620 }
 621
 622 void wxNSTextFieldControl::SetSelection( long from , long to )
 623 {
 624     long textLength = [[m_textField stringValue] length];
 625     if ((from == -1) && (to == -1))
 626     {
 627         from = 0 ;
 628         to = textLength ;
 629     }
 630     else
 631     {
 632         from = wxMin(textLength,wxMax(from,0)) ;
 633         if ( to == -1 )
 634             to = textLength;
 635         else
 636             to = wxMax(0,wxMin(textLength,to)) ;
 637     }
 638
 639     NSText* editor = [m_textField currentEditor];
 640     if ( editor )
 641     {
 642         [editor setSelectedRange:NSMakeRange(from, to-from)];
 643     }
 644     else
 645     {
 646         m_selStart = from;
 647         m_selEnd = to;
 648     }
 649 }
 650
 651 void wxNSTextFieldControl::WriteText(const wxString& str)
 652 {
 653     NSEvent* formerEvent = m_lastKeyDownEvent;
 654     m_lastKeyDownEvent = nil;
 655     NSText* editor = [m_textField currentEditor];
 656     if ( editor )
 657     {
 658         wxMacEditHelper helper(m_textField);
 659         [editor insertText:wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 660     }
 661     else
 662     {
 663         wxString val = GetStringValue() ;
 664         long start , end ;
 665         GetSelection( &start , &end ) ;
 666         val.Remove( start , end - start ) ;
 667         val.insert( start , str ) ;
 668         SetStringValue( val ) ;
 669         SetSelection( start + str.length() , start + str.length() ) ;
 670     }
 671     m_lastKeyDownEvent = formerEvent;
 672 }
 673
 674 void wxNSTextFieldControl::controlAction(WXWidget WXUNUSED(slf),
 675     void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 676 {
 677     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
 678     if ( wxpeer && (wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER) )
 679     {
 680         wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 681         event.SetEventObject( wxpeer );
 682         event.SetString( GetTextEntry()->GetValue() );
 683         wxpeer->HandleWindowEvent( event );
 684     }
 685 }
 686
 687 bool wxNSTextFieldControl::SetHint(const wxString& hint)
 688 {
 689     wxCFStringRef hintstring(hint);
 690     [[m_textField cell] setPlaceholderString:hintstring.AsNSString()];
 691     return true;
 692 }
 693
 694 //
 695 //
 696 //
 697
 698 wxWidgetImplType* wxWidgetImpl::CreateTextControl( wxTextCtrl* wxpeer,
 699                                     wxWindowMac* WXUNUSED(parent),
 700                                     wxWindowID WXUNUSED(id),
 701                                     const wxString& WXUNUSED(str),
 702                                     const wxPoint& pos,
 703                                     const wxSize& size,
 704                                     long style,
 705                                     long WXUNUSED(extraStyle))
 706 {
 707     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 708     wxWidgetCocoaImpl* c = NULL;
 709
 710     if ( style & wxTE_MULTILINE || style & wxTE_RICH || style & wxTE_RICH2 )
 711     {
 712         wxNSTextScrollView* v = nil;
 713         v = [[wxNSTextScrollView alloc] initWithFrame:r];
 714         c = new wxNSTextViewControl( wxpeer, v );
 715     }
 716     else
 717     {
 718         NSTextField* v = nil;
 719         if ( style & wxTE_PASSWORD )
 720             v = [[wxNSSecureTextField alloc] initWithFrame:r];
 721         else
 722             v = [[wxNSTextField alloc] initWithFrame:r];
 723
 724         if ( style & wxNO_BORDER )
 725         {
 726             // FIXME: How can we remove the native control's border?
 727             // setBordered is separate from the text ctrl's border.
 728         }
 729
 730         NSTextFieldCell* cell = [v cell];
 731         [cell setScrollable:YES];
 732         // TODO: Remove if we definitely are sure, it's not needed
 733         // as setting scrolling to yes, should turn off any wrapping
 734         // [cell setLineBreakMode:NSLineBreakByClipping];
 735
 736         [v setBezeled:NO];
 737         [v setBordered:NO];
 738
 739         c = new wxNSTextFieldControl( wxpeer, wxpeer, v );
 740     }
 741
 742     return c;
 743 }
 744
 745
 746 #endif // wxUSE_TEXTCTRL