configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Id$)dnl
   3
   4 AC_PREREQ(2.58)
   5
   6 dnl ---------------------------------------------------------------------------
   7 dnl
   8 dnl Top-level configure.in for wxWidgets by Robert Roebling, Phil Blecker,
   9 dnl Vadim Zeitlin and Ron Lee
  10 dnl
  11 dnl This script is under the wxWidgets licence.
  12 dnl
  13 dnl Version: $Id$
  14 dnl ---------------------------------------------------------------------------
  15
  16 dnl ---------------------------------------------------------------------------
  17 dnl initialization
  18 dnl ---------------------------------------------------------------------------
  19
  20 AC_INIT([wxWidgets], [2.9.0], [wx-dev@lists.wxwidgets.org])
  21
  22 dnl the file passed to AC_CONFIG_SRCDIR should be specific to our package
  23 AC_CONFIG_SRCDIR([wx-config.in])
  24
  25 dnl sets build, host, target variables and the same with _alias
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28 AC_CANONICAL_TARGET
  29
  30
  31 dnl When making releases do:
  32 dnl
  33 dnl wx_release_number += 1
  34
  35 wx_major_version_number=2
  36 wx_minor_version_number=9
  37 wx_release_number=0
  38 wx_subrelease_number=0
  39
  40 WX_RELEASE=$wx_major_version_number.$wx_minor_version_number
  41 WX_VERSION=$WX_RELEASE.$wx_release_number
  42 WX_SUBVERSION=$WX_VERSION.$wx_subrelease_number
  43
  44 WX_MSW_VERSION=$wx_major_version_number$wx_minor_version_number$wx_release_number
  45
  46
  47 dnl Autoconf-2.60 changed the meaning of top_builddir variable, so we have
  48 dnl to use our own replacement that will work with both 2.5x and 2.60+:
  49 wx_top_builddir="`pwd`"
  50 AC_SUBST(wx_top_builddir)
  51
  52
  53 dnl ------------------------------------------------------------------------
  54 dnl Check platform (host system)
  55 dnl ------------------------------------------------------------------------
  56
  57 dnl OS (assume Unix)
  58 USE_UNIX=1
  59 USE_OS2=0
  60 USE_WIN32=0
  61 USE_DOS=0
  62 USE_BEOS=0
  63 USE_MAC=0
  64
  65 dnl Unix kind
  66 USE_AIX=
  67 USE_BSD=                            dnl any BSD
  68 USE_DARWIN=                         dnl a.k.a. Mac OS X
  69 USE_FREEBSD=
  70 USE_GNU=                            dnl GNU/Hurd
  71 USE_HPUX=
  72 USE_LINUX=
  73 USE_NETBSD=
  74 USE_OPENBSD=
  75 USE_OSF=                            dnl OSF/1 (obsolete?)
  76 USE_SGI=
  77 USE_SOLARIS=                        dnl Solaris ("SunOS" >= 5)
  78 USE_SUN=                            dnl SunOS or Solaris
  79 USE_SUNOS=                          dnl old/real SunOS (obsolete)
  80 USE_SVR4=                           dnl SysV R4
  81 USE_SYSV=                           dnl any System V
  82 USE_VMS=
  83 USE_ULTRIX=
  84 USE_UNIXWARE=
  85
  86 dnl hardware platform
  87 USE_ALPHA=
  88
  89 dnl on some platforms xxx_r() functions are declared inside "#ifdef
  90 dnl _REENTRANT" and it's easier to just define this symbol for these platforms
  91 dnl than checking it during run-time
  92 NEEDS_D_REENTRANT_FOR_R_FUNCS=0
  93
  94 dnl the list of all available toolkits
  95 dnl
  96 dnl update NUM_TOOLKITS calculation below when adding a new toolkit here!
  97 ALL_TOOLKITS="COCOA GTK MAC MGL MICROWIN MOTIF MSW PM X11 DFB"
  98
  99 dnl NB: these wxUSE_XXX constants have value of 0 or 1 unlike all the other ones
 100 dnl     which are either yes or no
 101 DEFAULT_wxUSE_COCOA=0
 102 DEFAULT_wxUSE_GTK=0
 103 DEFAULT_wxUSE_MAC=0
 104 DEFAULT_wxUSE_MGL=0
 105 DEFAULT_wxUSE_MICROWIN=0
 106 DEFAULT_wxUSE_MOTIF=0
 107 DEFAULT_wxUSE_MSW=0
 108 DEFAULT_wxUSE_PM=0
 109 DEFAULT_wxUSE_X11=0
 110 DEFAULT_wxUSE_DFB=0
 111
 112 dnl these are the values which are really default for the given platform -
 113 dnl they're not cached and are only used if no --with-toolkit was given *and*
 114 dnl nothing was found in the cache
 115 DEFAULT_DEFAULT_wxUSE_COCOA=0
 116 DEFAULT_DEFAULT_wxUSE_GTK=0
 117 DEFAULT_DEFAULT_wxUSE_MAC=0
 118 DEFAULT_DEFAULT_wxUSE_MGL=0
 119 DEFAULT_DEFAULT_wxUSE_MICROWIN=0
 120 DEFAULT_DEFAULT_wxUSE_MOTIF=0
 121 DEFAULT_DEFAULT_wxUSE_MSW=0
 122 DEFAULT_DEFAULT_wxUSE_PM=0
 123 DEFAULT_DEFAULT_wxUSE_X11=0
 124 DEFAULT_DEFAULT_wxUSE_DFB=0
 125
 126 PROGRAM_EXT=
 127 SO_SUFFIX=so
 128 SAMPLES_RPATH_FLAG=
 129 SAMPLES_RPATH_POSTLINK=
 130
 131 DEFAULT_STD_FLAG=yes
 132
 133 dnl to support a new system, you need to add its canonical name (as determined
 134 dnl by config.sub or specified by the configure command line) to this "case"
 135 dnl and also define the shared library flags below - search for
 136 dnl SHARED_LIB_SETUP to find the exact place
 137 case "${host}" in
 138   *-hp-hpux* )
 139     USE_HPUX=1
 140     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 141     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 142     SO_SUFFIX=sl
 143     AC_DEFINE(__HPUX__)
 144
 145     dnl many standard declarations in HP-UX headers are only included if either
 146     dnl _HPUX_SOURCE is defined, see stdsyms(5)
 147     CPPFLAGS="-D_HPUX_SOURCE $CPPFLAGS"
 148   ;;
 149   *-*-linux* )
 150     USE_LINUX=1
 151     AC_DEFINE(__LINUX__)
 152     TMP=`uname -m`
 153     if test "x$TMP" = "xalpha"; then
 154       USE_ALPHA=1
 155       AC_DEFINE(__ALPHA__)
 156     fi
 157     DEFAULT_DEFAULT_wxUSE_GTK=1
 158   ;;
 159   *-*-gnu* | *-*-k*bsd*-gnu )
 160     USE_GNU=1
 161     TMP=`uname -m`
 162     if test "x$TMP" = "xalpha"; then
 163       USE_ALPHA=1
 164       AC_DEFINE(__ALPHA__)
 165     fi
 166     DEFAULT_DEFAULT_wxUSE_GTK=1
 167   ;;
 168   *-*-irix5* | *-*-irix6* )
 169     USE_SGI=1
 170     USE_SVR4=1
 171     AC_DEFINE(__SGI__)
 172     AC_DEFINE(__SVR4__)
 173     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 174   ;;
 175   *-*-solaris2* )
 176     USE_SUN=1
 177     USE_SOLARIS=1
 178     USE_SVR4=1
 179     AC_DEFINE(__SUN__)
 180     AC_DEFINE(__SOLARIS__)
 181     AC_DEFINE(__SVR4__)
 182     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 183     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 184   ;;
 185   *-*-sunos4* )
 186     USE_SUN=1
 187     USE_SUNOS=1
 188     USE_BSD=1
 189     AC_DEFINE(__SUN__)
 190     AC_DEFINE(__SUNOS__)
 191     AC_DEFINE(__BSD__)
 192     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 193   ;;
 194   *-*-freebsd*)
 195     USE_BSD=1
 196     USE_FREEBSD=1
 197     AC_DEFINE(__FREEBSD__)
 198     AC_DEFINE(__BSD__)
 199     DEFAULT_DEFAULT_wxUSE_GTK=1
 200   ;;
 201   *-*-openbsd*|*-*-mirbsd*)
 202     USE_BSD=1
 203     USE_OPENBSD=1
 204     AC_DEFINE(__OPENBSD__)
 205     AC_DEFINE(__BSD__)
 206     DEFAULT_DEFAULT_wxUSE_GTK=1
 207   ;;
 208   *-*-netbsd*)
 209     USE_BSD=1
 210     USE_NETBSD=1
 211     AC_DEFINE(__NETBSD__)
 212     AC_DEFINE(__BSD__)
 213     DEFAULT_DEFAULT_wxUSE_GTK=1
 214     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 215
 216     dnl some standard declarations in NetBSD headers are only included if
 217     dnl _NETBSD_SOURCE and _LIBC are defined, e.g. getservbyname_r in netdb.h
 218     CPPFLAGS="-D_NETBSD_SOURCE -D_LIBC $CPPFLAGS"
 219   ;;
 220   *-*-osf* )
 221     USE_ALPHA=1
 222     USE_OSF=1
 223     AC_DEFINE(__ALPHA__)
 224     AC_DEFINE(__OSF__)
 225     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 226     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 227   ;;
 228   *-*-dgux5* )
 229     USE_ALPHA=1
 230     USE_SVR4=1
 231     AC_DEFINE(__ALPHA__)
 232     AC_DEFINE(__SVR4__)
 233     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 234   ;;
 235   *-*-sysv5* )
 236     USE_SYSV=1
 237     USE_SVR4=1
 238     AC_DEFINE(__SYSV__)
 239     AC_DEFINE(__SVR4__)
 240     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 241   ;;
 242   *-*-aix* )
 243     USE_AIX=1
 244     USE_SYSV=1
 245     USE_SVR4=1
 246     dnl quoting from http://www-1.ibm.com/servers/esdd/articles/gnu.html:
 247     dnl
 248     dnl     Both archive libraries and shared libraries on AIX have an .a
 249     dnl     extension. This will explain why you can't link with an .so and
 250     dnl     why it works with the name changed to .a.
 251     SO_SUFFIX=a
 252     AC_DEFINE(__AIX__)
 253     AC_DEFINE(__SYSV__)
 254     AC_DEFINE(__SVR4__)
 255     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 256   ;;
 257
 258   *-*-*UnixWare*)
 259     USE_SYSV=1
 260     USE_SVR4=1
 261     USE_UNIXWARE=1
 262     AC_DEFINE(__UNIXWARE__)
 263   ;;
 264
 265   *-*-cygwin* | *-*-mingw32* )
 266     dnl MBN: some of the defines have been moved after toolkit detection
 267     dnl      because for wxMotif/wxGTK/wxX11 to build on Cygwin
 268     dnl      USE_UNIX  must be set and not USE_WIN32
 269     SO_SUFFIX=dll
 270     PROGRAM_EXT=".exe"
 271     DEFAULT_DEFAULT_wxUSE_MSW=1
 272   ;;
 273
 274   *-pc-msdosdjgpp )
 275     USE_UNIX=0
 276     USE_DOS=1
 277     AC_DEFINE(__DOS__)
 278     PROGRAM_EXT=".exe"
 279     DEFAULT_DEFAULT_wxUSE_MGL=1
 280   ;;
 281
 282   *-pc-os2_emx | *-pc-os2-emx )
 283     AC_DEFINE(__EMX__)
 284     USE_OS2=1
 285     AC_DEFINE(__OS2__)
 286     PROGRAM_EXT=".exe"
 287     DEFAULT_DEFAULT_wxUSE_PM=1
 288     dnl "c++" wrapper is not always available, so always use plain gcc.
 289     CXX=gcc
 290     LDFLAGS="$LDFLAGS -Zcrtdll"
 291     dnl
 292     dnl Some special code that's automatically added by autoconf-2.57 for OS/2
 293     dnl and hopefully also by autoconf-2.58 and newer on all other platforms.
 294     dnl For now however, we still need it to make sure the configure script
 295     dnl works on OS/2 no matter what platform it is generated on.
 296     ac_executable_extensions=".exe"
 297     export ac_executable_extensions
 298     dnl This strange code is necessary to deal with handling of
 299     dnl backslashes by ksh and pdksh's sh variant.
 300     ac_save_IFS="$IFS"
 301     IFS='\\'
 302     ac_TEMP_PATH=
 303     for ac_dir in $PATH; do
 304       IFS=$ac_save_IFS
 305       if test -z "$ac_TEMP_PATH"; then
 306         ac_TEMP_PATH="$ac_dir"
 307       else
 308         ac_TEMP_PATH="$ac_TEMP_PATH/$ac_dir"
 309       fi
 310     done
 311     export PATH="$ac_TEMP_PATH"
 312     unset ac_TEMP_PATH
 313     DEFAULT_STD_FLAG=no
 314   ;;
 315
 316   *-*-darwin* )
 317     dnl Darwin based distributions (including Mac OS X)
 318     USE_BSD=1
 319     USE_DARWIN=1
 320     SO_SUFFIX=dylib
 321     AC_DEFINE(__BSD__)
 322     AC_DEFINE(__DARWIN__)
 323     AC_DEFINE(TARGET_CARBON)
 324     DEFAULT_DEFAULT_wxUSE_MAC=1
 325     DEFAULT_STD_FLAG=no
 326   ;;
 327   powerpc-apple-macos* )
 328     dnl Classic Mac OS (< X)
 329     USE_UNIX=0
 330     dnl For some reason the test that should be cross-compiler capable fails
 331     dnl However, there is no doubt that MacOS PowerPC is big endian.
 332     ac_cv_c_bigendian=yes
 333     SO_SUFFIX=shlib
 334     dnl AC_DEFINE(TARGET_CARBON)
 335     dnl platform.h needs TARGET_CARBON before setup.h, we'll add it to CPPFLAGS
 336     DEFAULT_DEFAULT_wxUSE_MAC=1
 337     DEFAULT_STD_FLAG=no
 338   ;;
 339
 340   *-*-beos* )
 341     dnl leave USE_UNIX on - BeOS is sufficiently Unix-like for this
 342     USE_BEOS=1
 343     AC_DEFINE(__BEOS__)
 344   ;;
 345
 346   *)
 347     AC_MSG_WARN([*** System type ${host} is unknown, assuming generic Unix and continuing nevertheless.])
 348     AC_MSG_WARN([*** Please report the build results to wx-dev@lists.wxwidgets.org.])
 349
 350     DEFAULT_DEFAULT_wxUSE_X11=1
 351     DEFAULT_wxUSE_SHARED=no
 352 esac
 353
 354 dnl ---------------------------------------------------------------------------
 355 dnl command line options for configure
 356 dnl ---------------------------------------------------------------------------
 357
 358 dnl the default values for all options - we collect them all here to simplify
 359 dnl modification of the default values (for example, if the defaults for some
 360 dnl platform should be changed, it can be done here too)
 361 dnl
 362 dnl NB: see also DEFAULT_wxUSE<toolkit> variables defined above
 363
 364 WX_ARG_CACHE_INIT
 365
 366 dnl it's only necessary to list the options which should be disabled by
 367 dnl default, all the rest have default value of "yes" (or, rather, of
 368 dnl wxUSE_ALL_FEATURES which is the only which has to be set to "yes" by
 369 dnl default)
 370 DEFAULT_wxUSE_ALL_FEATURES=yes
 371
 372 DEFAULT_wxUSE_STD_IOSTREAM=$DEFAULT_STD_FLAG
 373 DEFAULT_wxUSE_STD_STRING=$DEFAULT_STD_FLAG
 374
 375 dnl libraries disabled by default
 376 DEFAULT_wxUSE_DMALLOC=no
 377 DEFAULT_wxUSE_LIBGNOMEVFS=no
 378 DEFAULT_wxUSE_LIBHILDON=no
 379 DEFAULT_wxUSE_LIBMSPACK=no
 380 DEFAULT_wxUSE_LIBSDL=no
 381 DEFAULT_wxUSE_ODBC=no
 382 DEFAULT_wxUSE_OPENGL=no
 383
 384 dnl features disabled by default
 385 DEFAULT_wxUSE_ACCESSIBILITY=no
 386 DEFAULT_wxUSE_DATAVIEWCTRL=no
 387 DEFAULT_wxUSE_GRAPHICS_CONTEXT=no
 388 DEFAULT_wxUSE_MEDIACTRL=no
 389 DEFAULT_wxUSE_TAB_DIALOG=no
 390
 391 DEFAULT_wxUSE_UNICODE_UTF8=auto
 392 DEFAULT_wxUSE_UNICODE_UTF8_LOCALE=no
 393
 394 DEFAULT_wxUSE_OFFICIAL_BUILD=no
 395
 396 dnl Applicable only when --with-gtk was used:
 397 DEFAULT_wxUSE_GTK2=yes
 398
 399 dnl Always default to no. Only special cases require this.
 400 DEFAULT_wxUSE_OBJC_UNIQUIFYING=no
 401
 402
 403 for toolkit in `echo $ALL_TOOLKITS`; do
 404   LINE=`grep "wxUSE_$toolkit=" ${wx_arg_cache_file}`
 405   if test "x$LINE" != "x" ; then
 406     has_toolkit_in_cache=1
 407     eval "DEFAULT_$LINE"
 408     eval "CACHE_$toolkit=1"
 409
 410     LINE=`grep "wx${toolkit}_VERSION=" ${wx_arg_cache_file}`
 411     if test "x$LINE" != "x" ; then
 412         eval "DEFAULT_$LINE"
 413     fi
 414   fi
 415 done
 416
 417 dnl ===========================
 418 dnl deal with configure options
 419 dnl ===========================
 420
 421 dnl we use several macros here:
 422 dnl     - AC_ARG_WITH/AC_ARG_ENABLE are the standard autoconf macros, see
 423 dnl       autoconf manual for details about them
 424 dnl     - WX_ARG_WITH/WX_ARG_ENABLE are their wx counterparts which perform
 425 dnl       the caching of the command line options and also use DEFAULT_foo
 426 dnl       variable as the default value for "foo" if neither --enable-foo nor
 427 dnl       --disable-foo is specified
 428 dnl     - WX_ARG_SYS_WITH is a special version of WX_ARG_WITH which allows
 429 dnl       to choose not only whether an external library is used but also if we
 430 dnl       use the copy of it included with wxWidgets or an already installed
 431 dnl       system version
 432 dnl     - WX_ARG_WITHOUT/WX_ARG_DISABLE mirror WX_ARG_WITH/WX_ARG_ENABLE but
 433 dnl       should be used for the options which are enabled by default
 434 dnl     - WX_ARG_FEATURE is a version of WX_ARG_ENABLE which should be used for
 435 dnl       optional features, i.e. options which should be disabled if
 436 dnl       --disable-all_features is specified (WX_ARG_WITH/WX_ARG_SYS_WITH are
 437 dnl       also affected by this)
 438
 439 dnl ---------------------------------------------------------------------------
 440 dnl global build options
 441 dnl ---------------------------------------------------------------------------
 442
 443 WX_ARG_DISABLE(gui,        [  --disable-gui           don't build GUI parts of the library], wxUSE_GUI)
 444 WX_ARG_ENABLE(monolithic,  [  --enable-monolithic     build wxWidgets as single library], wxUSE_MONOLITHIC)
 445 WX_ARG_ENABLE(plugins,     [  --enable-plugins        build parts of wxWidgets as loadable components], wxUSE_PLUGINS)
 446 WX_ARG_WITHOUT(subdirs,    [  --without-subdirs       don't generate makefiles for samples/demos/...], wxWITH_SUBDIRS)
 447 AC_ARG_WITH(flavour,       [  --with-flavour=NAME     specify a name to identify this build], [WX_FLAVOUR="$withval"])
 448 WX_ARG_ENABLE(official_build,  [  --enable-official_build official build of wxWidgets (win32 DLL only)], wxUSE_OFFICIAL_BUILD)
 449 AC_ARG_ENABLE(vendor,  [  --enable-vendor=VENDOR  vendor name (win32 DLL only)], [VENDOR="$enableval"])
 450 if test "x$VENDOR" = "x"; then
 451     VENDOR="custom"
 452 fi
 453
 454 WX_ARG_DISABLE(all_features,[  --disable-all_features  disable all optional features to build minimal library], wxUSE_ALL_FEATURES)
 455
 456 dnl ---------------------------------------------------------------------------
 457 dnl port selection
 458 dnl ---------------------------------------------------------------------------
 459
 460 if test "$wxUSE_GUI" = "yes"; then
 461
 462 WX_ARG_ENABLE(universal,   [  --enable-universal      use wxWidgets GUI controls instead of native ones], wxUSE_UNIVERSAL)
 463 if test "$wxUSE_UNIVERSAL" = "yes"; then
 464     AC_ARG_WITH(themes,    [  --with-themes=all|list  use only the specified comma-separated list of wxUniversal themes], [wxUNIV_THEMES="$withval"])
 465 fi
 466
 467 dnl we use AC_ARG_WITH and not WX_ARG_WITH for the toolkit options as they
 468 dnl shouldn't default to wxUSE_ALL_FEATURES, and we don't need to cache them
 469 dnl automatically
 470 AC_ARG_WITH(gtk,          [[  --with-gtk[=VERSION]    use GTK+, VERSION can be 2 (default), 1 or "any"]], [wxUSE_GTK="$withval" CACHE_GTK=1 TOOLKIT_GIVEN=1])
 471 AC_ARG_WITH(motif,         [  --with-motif            use Motif/Lesstif], [wxUSE_MOTIF="$withval" CACHE_MOTIF=1 TOOLKIT_GIVEN=1])
 472 AC_ARG_WITH(mac,           [  --with-mac              use Mac OS X], [wxUSE_MAC="$withval" CACHE_MAC=1 TOOLKIT_GIVEN=1])
 473 AC_ARG_WITH(cocoa,         [  --with-cocoa            use Cocoa], [wxUSE_COCOA="$withval" CACHE_COCOA=1 TOOLKIT_GIVEN=1])
 474 AC_ARG_WITH(wine,          [  --with-wine             use Wine], [wxUSE_WINE="$withval" CACHE_WINE=1])
 475 AC_ARG_WITH(msw,           [  --with-msw              use MS-Windows], [wxUSE_MSW="$withval" CACHE_MSW=1 TOOLKIT_GIVEN=1])
 476 AC_ARG_WITH(pm,            [  --with-pm               use OS/2 Presentation Manager], [wxUSE_PM="$withval" CACHE_PM=1 TOOLKIT_GIVEN=1])
 477 AC_ARG_WITH(mgl,           [  --with-mgl              use SciTech MGL], [wxUSE_MGL="$withval" wxUSE_UNIVERSAL="yes" CACHE_MGL=1 TOOLKIT_GIVEN=1])
 478 AC_ARG_WITH(directfb,      [  --with-directfb         use DirectFB], [wxUSE_DFB="$withval" wxUSE_UNIVERSAL="yes" CACHE_DFB=1 TOOLKIT_GIVEN=1])
 479 AC_ARG_WITH(microwin,      [  --with-microwin         use MicroWindows], [wxUSE_MICROWIN="$withval" CACHE_MICROWIN=1 TOOLKIT_GIVEN=1])
 480 AC_ARG_WITH(x11,           [  --with-x11              use X11], [wxUSE_X11="$withval" wxUSE_UNIVERSAL="yes" CACHE_X11=1 TOOLKIT_GIVEN=1])
 481 WX_ARG_ENABLE(nanox,       [  --enable-nanox          use NanoX], wxUSE_NANOX)
 482
 483 AC_ARG_ENABLE(gtk2,        [  --disable-gtk2          use GTK+ 1.2 instead of 2.0], [wxUSE_GTK2="$enableval"])
 484 WX_ARG_ENABLE(gpe,         [  --enable-gpe            use GNOME PDA Environment features if possible], wxUSE_GPE)
 485
 486 dnl ---------------------------------------------------------------------------
 487 dnl external libraries
 488 dnl ---------------------------------------------------------------------------
 489
 490 WX_ARG_SYS_WITH(libpng,    [  --with-libpng           use libpng (PNG image format)], wxUSE_LIBPNG)
 491 WX_ARG_SYS_WITH(libjpeg,   [  --with-libjpeg          use libjpeg (JPEG file format)], wxUSE_LIBJPEG)
 492 WX_ARG_SYS_WITH(libtiff,   [  --with-libtiff          use libtiff (TIFF file format)], wxUSE_LIBTIFF)
 493 WX_ARG_SYS_WITH(libxpm,    [  --with-libxpm           use libxpm (XPM file format)], wxUSE_LIBXPM)
 494 WX_ARG_WITH(libmspack,     [  --with-libmspack        use libmspack (CHM help files loading)], wxUSE_LIBMSPACK)
 495 WX_ARG_WITHOUT(gnomeprint, [  --without-gnomeprint    don't use GNOME printing libraries], wxUSE_LIBGNOMEPRINT)
 496 WX_ARG_WITH(gnomevfs,      [  --with-gnomevfs         use GNOME VFS for associating MIME types], wxUSE_LIBGNOMEVFS)
 497 WX_ARG_WITH(hildon,        [  --with-hildon           use Hildon framework for Nokia 770], wxUSE_LIBHILDON)
 498 WX_ARG_WITH(opengl,        [  --with-opengl           use OpenGL (or Mesa)], wxUSE_OPENGL)
 499
 500 fi
 501 dnl for GUI only
 502
 503 WX_ARG_WITH(dmalloc,       [  --with-dmalloc          use dmalloc library (http://dmalloc.com/)], wxUSE_DMALLOC)
 504 WX_ARG_WITH(sdl,           [  --with-sdl              use SDL for audio on Unix], wxUSE_LIBSDL)
 505 WX_ARG_SYS_WITH(regex,     [  --with-regex            enable support for wxRegEx class], wxUSE_REGEX)
 506 WX_ARG_SYS_WITH(zlib,      [  --with-zlib             use zlib for LZW compression], wxUSE_ZLIB)
 507 WX_ARG_SYS_WITH(odbc,      [  --with-odbc             use the IODBC and wxODBC classes], wxUSE_ODBC)
 508 WX_ARG_SYS_WITH(expat,     [  --with-expat            enable XML support using expat parser], wxUSE_EXPAT)
 509
 510 dnl ---------------------------------------------------------------------------
 511 dnl global compile options
 512 dnl ---------------------------------------------------------------------------
 513
 514 WX_ARG_DISABLE(shared,     [  --disable-shared        create static library instead of shared], wxUSE_SHARED)
 515 WX_ARG_ENABLE(optimise,    [  --enable-optimise       create optimised code], wxUSE_OPTIMISE)
 516 WX_ARG_ENABLE(debug,       [  --enable-debug          same as debug_flag and debug_info], wxUSE_DEBUG)
 517 WX_ARG_ENABLE(stl,         [  --enable-stl            use STL for containers], wxUSE_STL)
 518 WX_ARG_ENABLE(std_iostreams, [  --enable-std_iostreams  use standard C++ stream classes], wxUSE_STD_IOSTREAM)
 519 WX_ARG_ENABLE(std_string,    [  --enable-std_string     use standard C++ string classes], wxUSE_STD_STRING)
 520 WX_ARG_DISABLE(unicode,      [  --disable-unicode       compile without Unicode support], wxUSE_UNICODE)
 521 WX_ARG_ENABLE(mslu,          [  --enable-mslu           use MS Layer for Unicode on Windows 9x (Win32 only)], wxUSE_UNICODE_MSLU)
 522 WX_ARG_ENABLE_PARAM(utf8,    [  --enable-utf8           use UTF-8 representation for strings (Unix only)], wxUSE_UNICODE_UTF8)
 523 WX_ARG_ENABLE(utf8only,      [  --enable-utf8only      only support UTF-8 locales in UTF-8 build (Unix only)], wxUSE_UNICODE_UTF8_LOCALE)
 524 WX_ARG_ENABLE(extended_rtti, [  --enable-extended_rtti  use extended RTTI (XTI)], wxUSE_EXTENDED_RTTI)
 525 if test "$USE_OS2" = "1"; then
 526     DEFAULT_wxUSE_OMF=no
 527     WX_ARG_ENABLE(omf,     [  --enable-omf            use OMF object format], wxUSE_OMF)
 528 fi
 529
 530 if test "$wxUSE_DEBUG" = "yes"; then
 531   DEFAULT_wxUSE_DEBUG_FLAG=yes
 532   DEFAULT_wxUSE_DEBUG_INFO=yes
 533   BUILD=debug
 534 elif test "$wxUSE_DEBUG" = "no"; then
 535   DEFAULT_wxUSE_DEBUG_FLAG=no
 536   DEFAULT_wxUSE_DEBUG_INFO=no
 537   BUILD=release
 538 fi
 539
 540 WX_ARG_ENABLE(debug_flag,    [  --enable-debug_flag     set __WXDEBUG__ flag (recommended for developers!)], wxUSE_DEBUG_FLAG)
 541 WX_ARG_ENABLE(debug_info,    [  --enable-debug_info     create code with debugging information], wxUSE_DEBUG_INFO)
 542 WX_ARG_ENABLE(debug_gdb,     [  --enable-debug_gdb      create code with extra GDB debugging information], wxUSE_DEBUG_GDB)
 543 WX_ARG_ENABLE(debug_cntxt,   [  --enable-debug_cntxt    use wxDebugContext], wxUSE_DEBUG_CONTEXT)
 544 WX_ARG_ENABLE(mem_tracing,   [  --enable-mem_tracing    create code with memory tracing], wxUSE_MEM_TRACING)
 545 WX_ARG_ENABLE(profile,       [  --enable-profile        create code with profiling information], wxUSE_PROFILE)
 546 WX_ARG_ENABLE(no_rtti,       [  --enable-no_rtti        create code without RTTI information], wxUSE_NO_RTTI)
 547 WX_ARG_ENABLE(no_exceptions, [  --enable-no_exceptions  create code without C++ exceptions handling], wxUSE_NO_EXCEPTIONS)
 548 WX_ARG_ENABLE(permissive,    [  --enable-permissive     compile code disregarding strict ANSI], wxUSE_PERMISSIVE)
 549 WX_ARG_ENABLE(no_deps,       [  --enable-no_deps        create code without dependency information], wxUSE_NO_DEPS)
 550 WX_ARG_DISABLE(vararg_macros,[  --disable-vararg_macros don't use vararg macros, even if they are supported], wxUSE_VARARG_MACROS)
 551 WX_ARG_ENABLE_PARAM(universal_binary, [[  --enable-universal_binary[=SDK] create Mac PowerPC and Intel Universal binary (not yet working)]], wxUSE_UNIVERSAL_BINARY)
 552
 553 WX_ARG_ENABLE(compat26,      [  --enable-compat26       enable wxWidgets 2.6 compatibility], WXWIN_COMPATIBILITY_2_6)
 554 WX_ARG_DISABLE(compat28,     [  --disable-compat28      disable wxWidgets 2.8 compatibility], WXWIN_COMPATIBILITY_2_8)
 555
 556 WX_ARG_DISABLE(rpath,        [  --disable-rpath         disable use of rpath for uninstalled builds], wxUSE_RPATH)
 557
 558 WX_ARG_ENABLE(objc_uniquifying,[  --enable-objc_uniquifying enable Objective-C class name uniquifying], wxUSE_OBJC_UNIQUIFYING)
 559
 560 dnl ---------------------------------------------------------------------------
 561 dnl optional non GUI features
 562 dnl ---------------------------------------------------------------------------
 563
 564 WX_ARG_FEATURE(intl,          [  --enable-intl           use internationalization system], wxUSE_INTL)
 565 WX_ARG_FEATURE(config,        [  --enable-config         use wxConfig (and derived) classes], wxUSE_CONFIG)
 566
 567 WX_ARG_FEATURE(protocols,     [  --enable-protocols      use wxProtocol and derived classes], wxUSE_PROTOCOL)
 568 WX_ARG_FEATURE(ftp,           [  --enable-ftp            use wxFTP (requires wxProtocol], wxUSE_PROTOCOL_FTP)
 569 WX_ARG_FEATURE(http,          [  --enable-http           use wxHTTP (requires wxProtocol], wxUSE_PROTOCOL_HTTP)
 570 WX_ARG_FEATURE(fileproto,     [  --enable-fileproto      use wxFileProto class (requires wxProtocol], wxUSE_PROTOCOL_FILE)
 571 WX_ARG_FEATURE(sockets,       [  --enable-sockets        use socket/network classes], wxUSE_SOCKETS)
 572 WX_ARG_FEATURE(ole,           [  --enable-ole            use OLE classes (Win32 only)], wxUSE_OLE)
 573 WX_ARG_FEATURE(dataobj,       [  --enable-dataobj        use data object classes], wxUSE_DATAOBJ)
 574
 575 WX_ARG_FEATURE(ipc,           [  --enable-ipc            use interprocess communication (wxSocket etc.)], wxUSE_IPC)
 576
 577 dnl please keep the settings below in alphabetical order
 578 WX_ARG_FEATURE(apple_ieee,    [  --enable-apple_ieee     use the Apple IEEE codec], wxUSE_APPLE_IEEE)
 579 WX_ARG_FEATURE(arcstream,     [  --enable-arcstream      use wxArchive streams], wxUSE_ARCHIVE_STREAMS)
 580 WX_ARG_FEATURE(base64,        [  --enable-base64         use base64 encoding/decoding functions], wxUSE_BASE64)
 581 WX_ARG_FEATURE(backtrace,     [  --enable-backtrace      use wxStackWalker class for getting backtraces], wxUSE_STACKWALKER)
 582 WX_ARG_FEATURE(catch_segvs,   [  --enable-catch_segvs    catch signals in wxApp::OnFatalException (Unix only)], wxUSE_ON_FATAL_EXCEPTION)
 583 WX_ARG_FEATURE(cmdline,       [  --enable-cmdline        use wxCmdLineParser class], wxUSE_CMDLINE_PARSER)
 584 WX_ARG_FEATURE(datetime,      [  --enable-datetime       use wxDateTime class], wxUSE_DATETIME)
 585 WX_ARG_FEATURE(debugreport,   [  --enable-debugreport    use wxDebugReport class], wxUSE_DEBUGREPORT)
 586 WX_ARG_FEATURE(dialupman,     [  --enable-dialupman      use dialup network classes], wxUSE_DIALUP_MANAGER)
 587 WX_ARG_FEATURE(dynlib,        [  --enable-dynlib         use wxLibrary class for DLL loading], wxUSE_DYNLIB_CLASS)
 588 WX_ARG_FEATURE(dynamicloader, [  --enable-dynamicloader  use (new) wxDynamicLibrary class], wxUSE_DYNAMIC_LOADER)
 589 WX_ARG_FEATURE(exceptions,    [  --enable-exceptions     build exception-safe library], wxUSE_EXCEPTIONS)
 590 WX_ARG_FEATURE(ffile,         [  --enable-ffile          use wxFFile class], wxUSE_FFILE)
 591 WX_ARG_FEATURE(file,          [  --enable-file           use wxFile class], wxUSE_FILE)
 592 WX_ARG_FEATURE(filesystem,    [  --enable-filesystem     use virtual file systems classes], wxUSE_FILESYSTEM)
 593 WX_ARG_FEATURE(fontmap,       [  --enable-fontmap        use font encodings conversion classes], wxUSE_FONTMAP)
 594 WX_ARG_FEATURE(fs_archive,    [  --enable-fs_archive     use virtual archive filesystems], wxUSE_FS_ARCHIVE)
 595 WX_ARG_FEATURE(fs_inet,       [  --enable-fs_inet        use virtual HTTP/FTP filesystems], wxUSE_FS_INET)
 596 WX_ARG_FEATURE(fs_zip,        [  --enable-fs_zip         now replaced by fs_archive], wxUSE_FS_ZIP)
 597 WX_ARG_FEATURE(geometry,      [  --enable-geometry       use geometry class], wxUSE_GEOMETRY)
 598 WX_ARG_FEATURE(log,           [  --enable-log            use logging system], wxUSE_LOG)
 599 WX_ARG_FEATURE(longlong,      [  --enable-longlong       use wxLongLong class], wxUSE_LONGLONG)
 600 WX_ARG_FEATURE(mimetype,      [  --enable-mimetype       use wxMimeTypesManager], wxUSE_MIMETYPE)
 601 WX_ARG_FEATURE(snglinst,      [  --enable-snglinst       use wxSingleInstanceChecker class], wxUSE_SNGLINST_CHECKER)
 602 WX_ARG_FEATURE(stdpaths,      [  --enable-stdpaths       use wxStandardPaths class], wxUSE_STDPATHS)
 603 WX_ARG_FEATURE(stopwatch,     [  --enable-stopwatch      use wxStopWatch class], wxUSE_STOPWATCH)
 604 WX_ARG_FEATURE(streams,       [  --enable-streams        use wxStream etc classes], wxUSE_STREAMS)
 605 WX_ARG_FEATURE(system_options,[  --enable-sysoptions     use wxSystemOptions], wxUSE_SYSTEM_OPTIONS)
 606 WX_ARG_FEATURE(tarstream,     [  --enable-tarstream      use wxTar streams], wxUSE_TARSTREAM)
 607 WX_ARG_FEATURE(textbuf,       [  --enable-textbuf        use wxTextBuffer class], wxUSE_TEXTBUFFER)
 608 WX_ARG_FEATURE(textfile,      [  --enable-textfile       use wxTextFile class], wxUSE_TEXTFILE)
 609 WX_ARG_FEATURE(timer,         [  --enable-timer          use wxTimer class], wxUSE_TIMER)
 610 WX_ARG_FEATURE(sound,         [  --enable-sound          use wxSound class], wxUSE_SOUND)
 611 WX_ARG_FEATURE(mediactrl,     [  --enable-mediactrl      use wxMediaCtrl class], wxUSE_MEDIACTRL)
 612 WX_ARG_FEATURE(gstreamer8,    [  --enable-gstreamer8     force GStreamer 0.8 instead of 0.10 with the wxMediaCtrl class on unix], wxUSE_GSTREAMER8)
 613 WX_ARG_FEATURE(printfposparam,[  --enable-printfposparam use wxVsnprintf() which supports positional parameters], wxUSE_PRINTF_POS_PARAMS)
 614 WX_ARG_FEATURE(zipstream,     [  --enable-zipstream      use wxZip streams], wxUSE_ZIPSTREAM)
 615
 616 WX_ARG_FEATURE(url,           [  --enable-url            use wxURL class], wxUSE_URL)
 617 WX_ARG_FEATURE(variant,       [  --enable-variant        use wxVariant class], wxUSE_VARIANT)
 618 WX_ARG_FEATURE(protocol,      [  --enable-protocol       use wxProtocol class], wxUSE_PROTOCOL)
 619 WX_ARG_FEATURE(protocol_http, [  --enable-protocol-http  HTTP support in wxProtocol], wxUSE_PROTOCOL_HTTP)
 620 WX_ARG_FEATURE(protocol_ftp,  [  --enable-protocol-ftp   FTP support in wxProtocol], wxUSE_PROTOCOL_FTP)
 621 WX_ARG_FEATURE(protocol_file, [  --enable-protocol-file  FILE support in wxProtocol], wxUSE_PROTOCOL_FILE)
 622
 623 WX_ARG_FEATURE(threads,     [  --enable-threads        use threads], wxUSE_THREADS)
 624
 625 if test "$wxUSE_GUI" = "yes"; then
 626
 627 dnl ---------------------------------------------------------------------------
 628 dnl optional "big" GUI features
 629 dnl ---------------------------------------------------------------------------
 630
 631 WX_ARG_FEATURE(docview,     [  --enable-docview        use document view architecture], wxUSE_DOC_VIEW_ARCHITECTURE)
 632 WX_ARG_FEATURE(help,        [  --enable-help           use help subsystem], wxUSE_HELP)
 633 WX_ARG_FEATURE(mshtmlhelp,  [  --enable-mshtmlhelp     use MS HTML Help (win32)], wxUSE_MS_HTML_HELP)
 634 WX_ARG_FEATURE(html,        [  --enable-html           use wxHTML sub-library], wxUSE_HTML)
 635 WX_ARG_FEATURE(htmlhelp,    [  --enable-htmlhelp       use wxHTML-based help], wxUSE_WXHTML_HELP)
 636 WX_ARG_FEATURE(xrc,         [  --enable-xrc            use XRC resources sub-library], wxUSE_XRC)
 637 WX_ARG_FEATURE(aui,         [  --enable-aui            use AUI docking library], wxUSE_AUI)
 638 WX_ARG_FEATURE(stc,         [  --enable-stc            use wxStyledTextCtrl library], wxUSE_STC)
 639 WX_ARG_FEATURE(constraints, [  --enable-constraints    use layout-constraints system], wxUSE_CONSTRAINTS)
 640 WX_ARG_FEATURE(printarch,   [  --enable-printarch      use printing architecture], wxUSE_PRINTING_ARCHITECTURE)
 641 WX_ARG_FEATURE(mdi,         [  --enable-mdi            use multiple document interface architecture], wxUSE_MDI)
 642 WX_ARG_FEATURE(mdidoc,      [  --enable-mdidoc         use docview architecture with MDI], wxUSE_MDI_ARCHITECTURE)
 643 WX_ARG_FEATURE(loggui,      [  --enable-loggui         use standard GUI logger], wxUSE_LOGGUI)
 644 WX_ARG_FEATURE(logwin,      [  --enable-logwin         use wxLogWindow], wxUSE_LOGWINDOW)
 645 WX_ARG_FEATURE(logdialog,   [  --enable-logdialog      use wxLogDialog], wxUSE_LOGDIALOG)
 646 WX_ARG_FEATURE(webkit,      [  --enable-webkit         use wxWebKitCtrl (Mac)], wxUSE_WEBKIT)
 647 WX_ARG_FEATURE(richtext,    [  --enable-richtext       use wxRichTextCtrl], wxUSE_RICHTEXT)
 648 WX_ARG_FEATURE(graphics_ctx,[  --enable-graphics_ctx   use graphics context 2D drawing API], wxUSE_GRAPHICS_CONTEXT)
 649 WX_ARG_FEATURE(postscript,  [  --enable-postscript     use wxPostscriptDC device context (default for gtk+)], wxUSE_POSTSCRIPT)
 650 WX_ARG_FEATURE(svg,         [  --enable-svg            use wxSVGFileDC device context], wxUSE_SVG)
 651
 652 dnl ---------------------------------------------------------------------------
 653 dnl IPC &c
 654 dnl ---------------------------------------------------------------------------
 655
 656 WX_ARG_FEATURE(clipboard,   [  --enable-clipboard      use wxClipboard class], wxUSE_CLIPBOARD)
 657 WX_ARG_FEATURE(dnd,         [  --enable-dnd            use Drag'n'Drop classes], wxUSE_DRAG_AND_DROP)
 658 WX_ARG_FEATURE(metafile,    [  --enable-metafile       use win32 metafiles], wxUSE_METAFILE)
 659
 660 dnl ---------------------------------------------------------------------------
 661 dnl optional GUI controls (in alphabetical order except the first one)
 662 dnl ---------------------------------------------------------------------------
 663
 664 WX_ARG_FEATURE(controls,    [  --enable-controls       use all usual controls], wxUSE_CONTROLS)
 665
 666 dnl even with --enable-controls, some may be disabled by giving
 667 dnl --disable-<control> later on the command line - but by default all will be
 668 dnl used (and vice versa)
 669 if test "$wxUSE_CONTROLS" = "yes"; then
 670   DEFAULT_wxUSE_ACCEL=yes
 671   DEFAULT_wxUSE_ANIMATIONCTRL=yes
 672   DEFAULT_wxUSE_BMPBUTTON=yes
 673   DEFAULT_wxUSE_BUTTON=yes
 674   DEFAULT_wxUSE_CALCTRL=yes
 675   DEFAULT_wxUSE_CARET=yes
 676   DEFAULT_wxUSE_COMBOBOX=yes
 677   DEFAULT_wxUSE_CHECKBOX=yes
 678   DEFAULT_wxUSE_CHECKLISTBOX=yes
 679   DEFAULT_wxUSE_CHOICE=yes
 680   DEFAULT_wxUSE_CHOICEBOOK=yes
 681   DEFAULT_wxUSE_COLLPANE=yes
 682   DEFAULT_wxUSE_COLOURPICKERCTRL=yes
 683   DEFAULT_wxUSE_COMBOBOX=yes
 684   DEFAULT_wxUSE_DATEPICKCTRL=yes
 685   DEFAULT_wxUSE_DISPLAY=yes
 686   DEFAULT_wxUSE_DETECT_SM=yes
 687   DEFAULT_wxUSE_DIRPICKERCTRL=yes
 688   DEFAULT_wxUSE_FILEPICKERCTRL=yes
 689   DEFAULT_wxUSE_FONTPICKERCTRL=yes
 690   DEFAULT_wxUSE_GAUGE=yes
 691   DEFAULT_wxUSE_GRID=yes
 692   DEFAULT_wxUSE_HYPERLINKCTRL=yes
 693   DEFAULT_wxUSE_DATAVIEWCTRL=no
 694   DEFAULT_wxUSE_IMAGLIST=yes
 695   DEFAULT_wxUSE_LISTBOOK=yes
 696   DEFAULT_wxUSE_LISTBOX=yes
 697   DEFAULT_wxUSE_LISTCTRL=yes
 698   DEFAULT_wxUSE_NOTEBOOK=yes
 699   DEFAULT_wxUSE_RADIOBOX=yes
 700   DEFAULT_wxUSE_RADIOBTN=yes
 701   DEFAULT_wxUSE_SASH=yes
 702   DEFAULT_wxUSE_SCROLLBAR=yes
 703   DEFAULT_wxUSE_SEARCHCTRL=yes
 704   DEFAULT_wxUSE_SLIDER=yes
 705   DEFAULT_wxUSE_SPINBTN=yes
 706   DEFAULT_wxUSE_SPINCTRL=yes
 707   DEFAULT_wxUSE_SPLITTER=yes
 708   DEFAULT_wxUSE_STATBMP=yes
 709   DEFAULT_wxUSE_STATBOX=yes
 710   DEFAULT_wxUSE_STATLINE=yes
 711   DEFAULT_wxUSE_STATUSBAR=yes
 712   DEFAULT_wxUSE_TAB_DIALOG=yes
 713   DEFAULT_wxUSE_TOGGLEBTN=yes
 714   DEFAULT_wxUSE_TOOLBAR=yes
 715   DEFAULT_wxUSE_TOOLBAR_NATIVE=yes
 716   DEFAULT_wxUSE_TOOLTIPS=yes
 717   DEFAULT_wxUSE_TREEBOOK=yes
 718   DEFAULT_wxUSE_TOOLBOOK=yes
 719   DEFAULT_wxUSE_TREECTRL=yes
 720   DEFAULT_wxUSE_POPUPWIN=yes
 721   DEFAULT_wxUSE_TIPWINDOW=yes
 722 elif test "$wxUSE_CONTROLS" = "no"; then
 723   DEFAULT_wxUSE_ACCEL=no
 724   DEFAULT_wxUSE_ANIMATIONCTRL=no
 725   DEFAULT_wxUSE_BMPBUTTON=no
 726   DEFAULT_wxUSE_BUTTON=no
 727   DEFAULT_wxUSE_CALCTRL=no
 728   DEFAULT_wxUSE_CARET=no
 729   DEFAULT_wxUSE_COLLPANE=no
 730   DEFAULT_wxUSE_COMBOBOX=no
 731   DEFAULT_wxUSE_CHECKBOX=no
 732   DEFAULT_wxUSE_CHECKLISTBOX=no
 733   DEFAULT_wxUSE_CHOICE=no
 734   DEFAULT_wxUSE_CHOICEBOOK=no
 735   DEFAULT_wxUSE_COLOURPICKERCTRL=no
 736   DEFAULT_wxUSE_COMBOBOX=no
 737   DEFAULT_wxUSE_DATEPICKCTRL=no
 738   DEFAULT_wxUSE_DISPLAY=no
 739   DEFAULT_wxUSE_DETECT_SM=no
 740   DEFAULT_wxUSE_DIRPICKERCTRL=no
 741   DEFAULT_wxUSE_FILEPICKERCTRL=no
 742   DEFAULT_wxUSE_FONTPICKERCTRL=no
 743   DEFAULT_wxUSE_GAUGE=no
 744   DEFAULT_wxUSE_GRID=no
 745   DEFAULT_wxUSE_HYPERLINKCTRL=no
 746   DEFAULT_wxUSE_DATAVIEWCTRL=no
 747   DEFAULT_wxUSE_IMAGLIST=no
 748   DEFAULT_wxUSE_LISTBOOK=no
 749   DEFAULT_wxUSE_LISTBOX=no
 750   DEFAULT_wxUSE_LISTCTRL=no
 751   DEFAULT_wxUSE_NOTEBOOK=no
 752   DEFAULT_wxUSE_RADIOBOX=no
 753   DEFAULT_wxUSE_RADIOBTN=no
 754   DEFAULT_wxUSE_SASH=no
 755   DEFAULT_wxUSE_SCROLLBAR=no
 756   DEFAULT_wxUSE_SEARCHCTRL=no
 757   DEFAULT_wxUSE_SLIDER=no
 758   DEFAULT_wxUSE_SPINBTN=no
 759   DEFAULT_wxUSE_SPINCTRL=no
 760   DEFAULT_wxUSE_SPLITTER=no
 761   DEFAULT_wxUSE_STATBMP=no
 762   DEFAULT_wxUSE_STATBOX=no
 763   DEFAULT_wxUSE_STATLINE=no
 764   DEFAULT_wxUSE_STATUSBAR=no
 765   DEFAULT_wxUSE_TAB_DIALOG=no
 766   DEFAULT_wxUSE_TOGGLEBTN=no
 767   DEFAULT_wxUSE_TOOLBAR=no
 768   DEFAULT_wxUSE_TOOLBAR_NATIVE=no
 769   DEFAULT_wxUSE_TOOLTIPS=no
 770   DEFAULT_wxUSE_TREEBOOK=no
 771   DEFAULT_wxUSE_TOOLBOOK=no
 772   DEFAULT_wxUSE_TREECTRL=no
 773   DEFAULT_wxUSE_POPUPWIN=no
 774   DEFAULT_wxUSE_TIPWINDOW=no
 775 fi
 776
 777 WX_ARG_FEATURE(accel,       [  --enable-accel          use accelerators], wxUSE_ACCEL)
 778 WX_ARG_FEATURE(animatectrl, [  --enable-animatectrl    use wxAnimationCtrl class], wxUSE_ANIMATIONCTRL)
 779 WX_ARG_FEATURE(button,      [  --enable-button         use wxButton class], wxUSE_BUTTON)
 780 WX_ARG_FEATURE(bmpbutton,   [  --enable-bmpbutton      use wxBitmapButton class], wxUSE_BMPBUTTON)
 781 WX_ARG_FEATURE(bmpcombobox, [  --enable-bmpcombobox    use wxBitmapComboBox class], wxUSE_BITMAPCOMBOBOX)
 782 WX_ARG_FEATURE(calendar,    [  --enable-calendar       use wxCalendarCtrl class], wxUSE_CALCTRL)
 783 WX_ARG_FEATURE(caret,       [  --enable-caret          use wxCaret class], wxUSE_CARET)
 784 WX_ARG_FEATURE(checkbox,    [  --enable-checkbox       use wxCheckBox class], wxUSE_CHECKBOX)
 785 WX_ARG_FEATURE(checklst,    [  --enable-checklst       use wxCheckListBox (listbox with checkboxes) class], wxUSE_CHECKLST)
 786 WX_ARG_FEATURE(choice,      [  --enable-choice         use wxChoice class], wxUSE_CHOICE)
 787 WX_ARG_FEATURE(choicebook,  [  --enable-choicebook     use wxChoicebook class], wxUSE_CHOICEBOOK)
 788 WX_ARG_FEATURE(collpane,    [  --enable-collpane       use wxCollapsiblePane class], wxUSE_COLLPANE)
 789 WX_ARG_FEATURE(colourpicker,[  --enable-colourpicker   use wxColourPickerCtrl class], wxUSE_COLOURPICKERCTRL)
 790 WX_ARG_FEATURE(combobox,    [  --enable-combobox       use wxComboBox class], wxUSE_COMBOBOX)
 791 WX_ARG_FEATURE(comboctrl,   [  --enable-comboctrl      use wxComboCtrl class], wxUSE_COMBOCTRL)
 792 WX_ARG_FEATURE(datepick,    [  --enable-datepick       use wxDatePickerCtrl class], wxUSE_DATEPICKCTRL)
 793 WX_ARG_FEATURE(dirpicker,   [  --enable-dirpicker      use wxDirPickerCtrl class], wxUSE_DIRPICKERCTRL)
 794 WX_ARG_FEATURE(display,     [  --enable-display        use wxDisplay class], wxUSE_DISPLAY)
 795 WX_ARG_FEATURE(detect_sm,   [  --enable-detect_sm      use code to detect X11 session manager], wxUSE_DETECT_SM)
 796 WX_ARG_FEATURE(editablebox, [  --enable-editablebox    use wxEditableListBox class], wxUSE_EDITABLELISTBOX)
 797 WX_ARG_FEATURE(filepicker,  [  --enable-filepicker     use wxFilePickerCtrl class], wxUSE_FILEPICKERCTRL)
 798 WX_ARG_FEATURE(fontpicker,  [  --enable-fontpicker     use wxFontPickerCtrl class], wxUSE_FONTPICKERCTRL)
 799 WX_ARG_FEATURE(gauge,       [  --enable-gauge          use wxGauge class], wxUSE_GAUGE)
 800 WX_ARG_FEATURE(grid,        [  --enable-grid           use wxGrid class], wxUSE_GRID)
 801 WX_ARG_FEATURE(dataviewctrl,[  --enable-dataviewctrl   use wxDataViewCtrl class], wxUSE_DATAVIEWCTRL)
 802 WX_ARG_FEATURE(hyperlink,   [  --enable-hyperlink      use wxHyperlinkCtrl class], wxUSE_HYPERLINKCTRL)
 803 WX_ARG_FEATURE(imaglist,    [  --enable-imaglist       use wxImageList class], wxUSE_IMAGLIST)
 804 WX_ARG_FEATURE(listbook,    [  --enable-listbook       use wxListbook class], wxUSE_LISTBOOK)
 805 WX_ARG_FEATURE(listbox,     [  --enable-listbox        use wxListBox class], wxUSE_LISTBOX)
 806 WX_ARG_FEATURE(listctrl,    [  --enable-listctrl       use wxListCtrl class], wxUSE_LISTCTRL)
 807 WX_ARG_FEATURE(notebook,    [  --enable-notebook       use wxNotebook class], wxUSE_NOTEBOOK)
 808 WX_ARG_FEATURE(odcombobox,  [  --enable-odcombobox     use wxOwnerDrawnComboBox class], wxUSE_ODCOMBOBOX)
 809 WX_ARG_FEATURE(radiobox,    [  --enable-radiobox       use wxRadioBox class], wxUSE_RADIOBOX)
 810 WX_ARG_FEATURE(radiobtn,    [  --enable-radiobtn       use wxRadioButton class], wxUSE_RADIOBTN)
 811 WX_ARG_FEATURE(sash,        [  --enable-sash           use wxSashWindow class], wxUSE_SASH)
 812 WX_ARG_FEATURE(scrollbar,   [  --enable-scrollbar      use wxScrollBar class and scrollable windows], wxUSE_SCROLLBAR)
 813 WX_ARG_FEATURE(searchctrl,  [  --enable-searchctrl     use wxSearchCtrl class], wxUSE_SEARCHCTRL)
 814 WX_ARG_FEATURE(slider,      [  --enable-slider         use wxSlider class], wxUSE_SLIDER)
 815 WX_ARG_FEATURE(spinbtn,     [  --enable-spinbtn        use wxSpinButton class], wxUSE_SPINBTN)
 816 WX_ARG_FEATURE(spinctrl,    [  --enable-spinctrl       use wxSpinCtrl class], wxUSE_SPINCTRL)
 817 WX_ARG_FEATURE(splitter,    [  --enable-splitter       use wxSplitterWindow class], wxUSE_SPLITTER)
 818 WX_ARG_FEATURE(statbmp,     [  --enable-statbmp        use wxStaticBitmap class], wxUSE_STATBMP)
 819 WX_ARG_FEATURE(statbox,     [  --enable-statbox        use wxStaticBox class], wxUSE_STATBOX)
 820 WX_ARG_FEATURE(statline,    [  --enable-statline       use wxStaticLine class], wxUSE_STATLINE)
 821 WX_ARG_FEATURE(stattext,    [  --enable-stattext       use wxStaticText class], wxUSE_STATTEXT)
 822 WX_ARG_FEATURE(statusbar,   [  --enable-statusbar      use wxStatusBar class], wxUSE_STATUSBAR)
 823 WX_ARG_FEATURE(tabdialog,   [  --enable-tabdialog      use wxTabControl class], wxUSE_TAB_DIALOG)
 824 WX_ARG_FEATURE(textctrl,    [  --enable-textctrl       use wxTextCtrl class], wxUSE_TEXTCTRL)
 825 WX_ARG_FEATURE(togglebtn,   [  --enable-togglebtn      use wxToggleButton class], wxUSE_TOGGLEBTN)
 826 WX_ARG_FEATURE(toolbar,     [  --enable-toolbar        use wxToolBar class], wxUSE_TOOLBAR)
 827 WX_ARG_FEATURE(tbarnative,  [  --enable-tbarnative     use native wxToolBar class], wxUSE_TOOLBAR_NATIVE)
 828 WX_ARG_FEATURE(treebook,    [  --enable-treebook       use wxTreebook class], wxUSE_TREEBOOK)
 829 WX_ARG_FEATURE(toolbook,    [  --enable-toolbook       use wxToolbook class], wxUSE_TOOLBOOK)
 830 WX_ARG_FEATURE(treectrl,    [  --enable-treectrl       use wxTreeCtrl class], wxUSE_TREECTRL)
 831 WX_ARG_FEATURE(tipwindow,   [  --enable-tipwindow      use wxTipWindow class], wxUSE_TIPWINDOW)
 832 WX_ARG_FEATURE(popupwin,    [  --enable-popupwin       use wxPopUpWindow class], wxUSE_POPUPWIN)
 833
 834 dnl ---------------------------------------------------------------------------
 835 dnl common dialogs
 836 dnl ---------------------------------------------------------------------------
 837
 838 WX_ARG_FEATURE(commondlg,   [  --enable-commondlg      use all common dialogs], wxUSE_COMMONDLGS)
 839 WX_ARG_FEATURE(aboutdlg,    [  --enable-aboutdlg       use wxAboutBox], wxUSE_ABOUTDLG)
 840 WX_ARG_FEATURE(choicedlg,   [  --enable-choicedlg      use wxChoiceDialog], wxUSE_CHOICEDLG)
 841 WX_ARG_FEATURE(coldlg,      [  --enable-coldlg         use wxColourDialog], wxUSE_COLOURDLG)
 842 WX_ARG_FEATURE(filedlg,     [  --enable-filedlg        use wxFileDialog], wxUSE_FILEDLG)
 843 WX_ARG_FEATURE(finddlg,     [  --enable-finddlg        use wxFindReplaceDialog], wxUSE_FINDREPLDLG)
 844 WX_ARG_FEATURE(fontdlg,     [  --enable-fontdlg        use wxFontDialog], wxUSE_FONTDLG)
 845 WX_ARG_FEATURE(dirdlg,      [  --enable-dirdlg         use wxDirDialog], wxUSE_DIRDLG)
 846 WX_ARG_FEATURE(msgdlg,      [  --enable-msgdlg         use wxMessageDialog], wxUSE_MSGDLG)
 847 WX_ARG_FEATURE(numberdlg,   [  --enable-numberdlg      use wxNumberEntryDialog], wxUSE_NUMBERDLG)
 848 WX_ARG_FEATURE(splash,      [  --enable-splash         use wxSplashScreen], wxUSE_SPLASH)
 849 WX_ARG_FEATURE(textdlg,     [  --enable-textdlg        use wxTextDialog], wxUSE_TEXTDLG)
 850 WX_ARG_FEATURE(tipdlg,      [  --enable-tipdlg         use startup tips], wxUSE_STARTUP_TIPS)
 851 WX_ARG_FEATURE(progressdlg, [  --enable-progressdlg    use wxProgressDialog], wxUSE_PROGRESSDLG)
 852 WX_ARG_FEATURE(wizarddlg,   [  --enable-wizarddlg      use wxWizard], wxUSE_WIZARDDLG)
 853
 854 dnl ---------------------------------------------------------------------------
 855 dnl misc GUI options
 856 dnl ---------------------------------------------------------------------------
 857
 858 WX_ARG_FEATURE(menus,       [  --enable-menus          use wxMenu/wxMenuBar/wxMenuItem classes], wxUSE_MENUS)
 859 WX_ARG_FEATURE(miniframe,   [  --enable-miniframe      use wxMiniFrame class], wxUSE_MINIFRAME)
 860 WX_ARG_FEATURE(tooltips,    [  --enable-tooltips       use wxToolTip class], wxUSE_TOOLTIPS)
 861 WX_ARG_FEATURE(splines,     [  --enable-splines        use spline drawing code], wxUSE_SPLINES)
 862 WX_ARG_FEATURE(mousewheel,  [  --enable-mousewheel     use mousewheel], wxUSE_MOUSEWHEEL)
 863 WX_ARG_FEATURE(validators,  [  --enable-validators     use wxValidator and derived classes], wxUSE_VALIDATORS)
 864 WX_ARG_FEATURE(busyinfo,    [  --enable-busyinfo       use wxBusyInfo], wxUSE_BUSYINFO)
 865 WX_ARG_FEATURE(joystick,    [  --enable-joystick       use wxJoystick], wxUSE_JOYSTICK)
 866 WX_ARG_FEATURE(metafile,    [  --enable-metafiles      use wxMetaFile (Win32 only)], wxUSE_METAFILE)
 867 WX_ARG_FEATURE(dragimage,   [  --enable-dragimage      use wxDragImage], wxUSE_DRAGIMAGE)
 868 WX_ARG_FEATURE(accessibility,[  --enable-accessibility  enable accessibility support], wxUSE_ACCESSIBILITY)
 869
 870 if test "$wxUSE_MSW" = "1"; then
 871     WX_ARG_FEATURE(dccache, [  --enable-dccache        cache temporary wxDC objects (Win32 only)], wxUSE_DC_CACHEING)
 872 fi
 873
 874 dnl ---------------------------------------------------------------------------
 875 dnl support for image formats that do not rely on external library
 876 dnl ---------------------------------------------------------------------------
 877
 878 WX_ARG_FEATURE(palette,     [  --enable-palette        use wxPalette class], wxUSE_PALETTE)
 879 WX_ARG_FEATURE(image,       [  --enable-image          use wxImage class], wxUSE_IMAGE)
 880 WX_ARG_FEATURE(gif,         [  --enable-gif            use gif images (GIF file format)], wxUSE_GIF)
 881 WX_ARG_FEATURE(pcx,         [  --enable-pcx            use pcx images (PCX file format)], wxUSE_PCX)
 882 WX_ARG_FEATURE(tga,         [  --enable-tga            use tga images (TGA file format)], wxUSE_TGA)
 883 WX_ARG_FEATURE(iff,         [  --enable-iff            use iff images (IFF file format)], wxUSE_IFF)
 884 WX_ARG_FEATURE(pnm,         [  --enable-pnm            use pnm images (PNM file format)], wxUSE_PNM)
 885 WX_ARG_FEATURE(xpm,         [  --enable-xpm            use xpm images (XPM file format)], wxUSE_XPM)
 886 WX_ARG_FEATURE(ico_cur,     [  --enable-icocur         use Windows ICO and CUR formats], wxUSE_ICO_CUR)
 887
 888 fi
 889 dnl for GUI only
 890
 891 dnl cache the options values before (may be) aborting below
 892 WX_ARG_CACHE_FLUSH
 893
 894 dnl check that no more than one toolkit is given and that if none are given that
 895 dnl we have a default one
 896
 897 AC_MSG_CHECKING(for toolkit)
 898
 899 # In Wine, we need to default to MSW, not GTK or MOTIF
 900 if test "$wxUSE_WINE" = "yes"; then
 901     DEFAULT_DEFAULT_wxUSE_GTK=0
 902     DEFAULT_DEFAULT_wxUSE_MOTIF=0
 903     DEFAULT_DEFAULT_wxUSE_MSW=1
 904     wxUSE_SHARED=no
 905     CC=${CC:-winegcc}
 906     CXX=${CXX:-wineg++}
 907 fi
 908
 909
 910 if test "$wxUSE_GUI" = "yes"; then
 911
 912     if test "$USE_BEOS" = 1; then
 913         AC_MSG_ERROR([BeOS GUI is not supported yet, use --disable-gui])
 914     fi
 915
 916     if test "$TOOLKIT_GIVEN" = 1; then
 917       dnl convert "yes", "any" or a number to 1 and "no" to 0
 918       for toolkit in `echo $ALL_TOOLKITS`; do
 919         var=wxUSE_$toolkit
 920         eval "value=\$${var}"
 921         if test "x$value" = "xno"; then
 922           eval "$var=0"
 923         elif test "x$value" != "x"; then
 924           eval "$var=1"
 925         fi
 926
 927         if test "x$value" != "x" -a "x$value" != "xyes" -a "x$value" != "xno"; then
 928           eval "wx${toolkit}_VERSION=$value"
 929         fi
 930       done
 931     else
 932       dnl try to guess the most apropriate toolkit for this platform
 933       for toolkit in `echo $ALL_TOOLKITS`; do
 934         if test "$has_toolkit_in_cache" != 1; then
 935           var=DEFAULT_DEFAULT_wxUSE_$toolkit
 936         else
 937           var=DEFAULT_wxUSE_$toolkit
 938
 939           eval "version=\$DEFAULT_wx${toolkit}_VERSION"
 940           if test "x$version" != "x"; then
 941             eval "wx${toolkit}_VERSION=$version"
 942           fi
 943         fi
 944         eval "wxUSE_$toolkit=\$${var}"
 945       done
 946     fi
 947
 948     dnl we suppose that expr is available (maybe there is a better way to do
 949     dnl this? what about using ALL_TOOLKITS? TODO)
 950     NUM_TOOLKITS=`expr ${wxUSE_COCOA:-0} + ${wxUSE_GTK:-0} + ${wxUSE_MAC:-0} \
 951                   + ${wxUSE_MGL:-0} + ${wxUSE_DFB:-0} + ${wxUSE_MICROWIN:-0} \
 952                   + ${wxUSE_MOTIF:-0} + ${wxUSE_MSW:-0} + ${wxUSE_X11:-0}`
 953
 954     dnl Allow wxUSE_PM only for OS/2 with EMX.
 955     case "${host}" in
 956       *-pc-os2_emx | *-pc-os2-emx )
 957         NUM_TOOLKITS=`expr ${NUM_TOOLKITS} + ${wxUSE_PM:-0}`
 958     esac
 959
 960     case "$NUM_TOOLKITS" in
 961       1)
 962       ;;
 963       0)
 964         AC_MSG_ERROR(Please specify a toolkit -- cannot determine the default for ${host})
 965       ;;
 966       *)
 967         AC_MSG_ERROR(Please specify at most one toolkit (maybe some are cached in configarg.cache?))
 968     esac
 969
 970     # to be removed when --disable-gtk2 isn't needed
 971     if test "x$wxUSE_GTK2" = "xyes"; then
 972         wxGTK_VERSION=2
 973     elif test "x$wxUSE_GTK2" = "xno"; then
 974         wxGTK_VERSION=1
 975     fi
 976
 977     dnl cache the wxUSE_<TOOLKIT> values too
 978     for toolkit in `echo $ALL_TOOLKITS`; do
 979       var=wxUSE_$toolkit
 980       eval "value=\$${var}"
 981       if test "x$value" != x; then
 982         cache_var=CACHE_$toolkit
 983         eval "cache=\$${cache_var}"
 984         if test "$cache" = 1; then
 985           echo "$var=$value" >> ${wx_arg_cache_file}
 986           eval "version=\$wx${toolkit}_VERSION"
 987           if test "x$version" != "x"; then
 988             echo "wx${toolkit}_VERSION=$version" >> ${wx_arg_cache_file}
 989           fi
 990         fi
 991         if test "$value" = 1; then
 992           toolkit_echo=`echo $toolkit | tr "[[A-Z]]" "[[a-z]]"`
 993           AC_MSG_RESULT($toolkit_echo)
 994         fi
 995       fi
 996     done
 997 else
 998     if test "x$host_alias" != "x"; then
 999         AC_MSG_RESULT(base ($host_alias hosted) only)
1000     else
1001         AC_MSG_RESULT(base only)
1002     fi
1003 fi
1004
1005 dnl ---------------------------------------------------------------------------
1006 dnl Checks for programs
1007 dnl ---------------------------------------------------------------------------
1008
1009 dnl flush the cache because checking for programs might abort
1010 AC_CACHE_SAVE
1011
1012 dnl C-compiler checks
1013 dnl   defines CC with the compiler to use
1014 dnl   defines GCC with yes if using gcc
1015 dnl   defines GCC empty if not using gcc
1016 dnl   defines CFLAGS
1017 dnl
1018 dnl this magic incantation is needed to prevent AC_PROG_CC from setting the
1019 dnl default CFLAGS (something like "-g -O2") -- we don't need this as we add
1020 dnl -g and -O flags ourselves below
1021 CFLAGS=${CFLAGS:=}
1022 AC_BAKEFILE_PROG_CC
1023
1024 dnl is -traditional needed for correct compilations
1025 dnl   adds -traditional for gcc if needed
1026 AC_PROG_GCC_TRADITIONAL
1027
1028 dnl C++-compiler checks
1029 dnl   defines CXX with the compiler to use
1030 dnl   defines GXX with yes if using gxx
1031 dnl   defines GXX empty if not using gxx
1032 dnl   defines CXXFLAGS
1033 dnl
1034 dnl see CFLAGS line above
1035 CXXFLAGS=${CXXFLAGS:=}
1036 AC_BAKEFILE_PROG_CXX
1037
1038 dnl configure always sets CXX to something as it falls back to g++ even if no
1039 dnl C++ compiler was found, but we prefer to abort now with a clear error
1040 dnl message rather than give errors about all tests failures below
1041 if test "$CXX" = "g++" -a "$GXX" != "yes"; then
1042     AC_MSG_ERROR([C++ compiler is needed to build wxWidgets])
1043 fi
1044
1045 dnl ranlib command
1046 dnl   defines RANLIB with the appropriate command
1047 AC_PROG_RANLIB
1048
1049 dnl ar command
1050 dnl   defines AR with the appropriate command
1051 dnl
1052 dnl For Sun CC AC_BAKEFILE below sets AR to the compiler itself.
1053 if test "x$SUNCXX" != xyes; then
1054     AC_CHECK_TOOL(AR, ar)
1055     if test "x$AR" = "x" ; then
1056         AC_MSG_ERROR([ar is needed to build wxWidgets])
1057     fi
1058 fi
1059
1060 dnl install checks
1061 dnl   defines INSTALL with the appropriate command
1062 AC_PROG_INSTALL
1063
1064 dnl   make install path absolute (if not already);
1065 dnl   will fail with (some) MSDOS paths
1066 case ${INSTALL} in
1067   /* ) # Absolute
1068      ;;
1069   ?:* ) # Drive letter, considered as absolute.
1070      ;;
1071   *)
1072      INSTALL=`pwd`/${INSTALL} ;;
1073 esac
1074
1075
1076 case "${host}" in
1077
1078     dnl The other BSD's should probably go in here too, since this is
1079     dnl to workaround a strange static lib BSDism.
1080     dnl Mac OS X install seems to ignore -p option...
1081     *-*-darwin* )
1082         INSTALL_PROGRAM="cp -fp"
1083         INSTALL_DATA="cp -fp"
1084         ;;
1085     *)
1086         ;;
1087 esac
1088
1089 dnl strip command
1090 dnl   defines STRIP as strip or nothing (true) if not found
1091 AC_CHECK_TOOL(STRIP, strip, true)
1092
1093 dnl Win32 tools
1094 if test "$wxUSE_WINE" = "yes"; then
1095     AC_CHECK_TOOL(WINDRES, wrc)
1096     RESCOMP="$WINDRES"
1097 else
1098     case "${host}" in
1099     *-*-cygwin* | *-*-mingw32* )
1100         dnl Bakefile CVS (as of 2005-11-24) now detects windres properly
1101         dnl ... maybe it does, but it does not make it available here
1102         dnl anymore, so do it ourselves still.
1103         AC_CHECK_TOOL(WINDRES, windres)
1104         RESCOMP="$WINDRES"
1105         AC_CHECK_TOOL(DLLTOOL, dlltool)
1106         ;;
1107     esac
1108 fi
1109
1110 dnl does make support "-include" (only GNU make does AFAIK)?
1111 AC_CACHE_CHECK([if make is GNU make], wx_cv_prog_makeisgnu,
1112 [
1113     if ( ${SHELL-sh} -c "${MAKE-make} --version" 2> /dev/null |
1114             $EGREP -s GNU > /dev/null); then
1115         wx_cv_prog_makeisgnu="yes"
1116     else
1117         wx_cv_prog_makeisgnu="no"
1118     fi
1119 ])
1120
1121 if test "x$wx_cv_prog_makeisgnu" = "xyes"; then
1122     IF_GNU_MAKE=""
1123 else
1124     IF_GNU_MAKE="#"
1125 fi
1126
1127 AC_SUBST(IF_GNU_MAKE)
1128
1129 dnl we don't need to check for VPATH support in GNU make - it does have it
1130 if test "x$wx_cv_prog_makeisgnu" != "xyes"; then
1131 dnl check if VPATH works
1132 AC_CACHE_CHECK([if make supports VPATH], wx_cv_prog_makevpath, [
1133 dnl create Makefile
1134 cat - << EOF > confMake
1135 check : file
1136         cp \$? \$@
1137         cp \$? final_file
1138 EOF
1139
1140 if test ! -d sub ; then
1141   mkdir sub
1142 fi
1143 echo dummy > sub/file
1144 ${MAKE-make} -f confMake VPATH=sub 2>&5 > /dev/null
1145 RESULT=$?
1146 rm -f sub/file check final_file confMake
1147 rmdir sub
1148 if test "$RESULT" = 0; then
1149   wx_cv_prog_makevpath="yes"
1150 else
1151   wx_cv_prog_makevpath="no"
1152 fi
1153 ])
1154
1155 if test "x$wx_cv_prog_makevpath" != "xyes"; then
1156 AC_MSG_ERROR([
1157 You need a make-utility that is able to use the variable
1158 VPATH correctly.
1159 If your version of make does not support VPATH correctly,
1160 please install GNU-make (possibly as gmake), and start
1161 configure with the following command:
1162 export MAKE=gmake; ./configure  for sh-type shells
1163 setenv MAKE gmake; ./configure  for csh-type shells
1164 Also please do remember to use gmake in this case every time
1165 you are trying to compile.
1166 ])
1167 fi dnl make without VPATH
1168 fi dnl not GNU make
1169
1170 dnl needed for making link to setup.h
1171 AC_PROG_LN_S
1172
1173
1174 dnl ------------------------------------------------------------------------
1175 dnl Platform specific tests
1176 dnl ------------------------------------------------------------------------
1177
1178 dnl xlC needs -qunique under AIX so that one source file can be
1179 dnl compiled to multiple object files and safely linked together.
1180 if test "x$XLCXX" = "xyes" -a "x$USE_AIX" = "x1"; then
1181     CXXFLAGS="-qunique $CXXFLAGS"
1182 fi
1183
1184 dnl This case is for PowerPC OS X vs. everything else
1185 case "${host}" in
1186   powerpc-*-darwin* )
1187     AC_MSG_CHECKING([if __POWERPC__ is already defined])
1188     AC_TRY_COMPILE([],[#ifndef __POWERPC__
1189         choke me for lack of PowerPC
1190 #endif
1191 ],
1192         [AC_MSG_RESULT([yes])],
1193         [AC_MSG_RESULT([no])
1194         AC_DEFINE(__POWERPC__)
1195     ])
1196   ;;
1197 esac
1198
1199 dnl This case is for OS X vs. everything else
1200 case "${host}" in
1201   *-*-darwin* )
1202     AC_MSG_CHECKING([if CoreFoundation/CFBase.h is usable])
1203     AC_TRY_COMPILE([#include <CoreFoundation/CFBase.h>
1204 ],[],
1205         [AC_MSG_RESULT([yes])],
1206         [AC_MSG_RESULT([no])
1207         AC_MSG_CHECKING([if __CF_USE_FRAMEWORK_INCLUDES__ is required])
1208         AC_TRY_COMPILE([#define __CF_USE_FRAMEWORK_INCLUDES__
1209 #include <CoreFoundation/CFBase.h>
1210         ],[],
1211         [AC_MSG_RESULT([yes])
1212         dnl We must use -D so source files that don't include wx/setup.h
1213         dnl but do include CFBase will work.
1214         CPPFLAGS="-D__CF_USE_FRAMEWORK_INCLUDES__ $CPPFLAGS"],
1215         [AC_MSG_FAILURE([no.  CoreFoundation not available.])]
1216         )
1217         ]
1218     )
1219   ;;
1220 esac
1221
1222 dnl Determine whether we want to use Cygwin as Windows or POSIX platform: the
1223 dnl latter makes more sense for wxGTK/Motif/X11 ports
1224 wants_win32=0
1225 doesnt_want_win32=0
1226 case "${host}" in
1227   *-*-cygwin*)
1228       if test "$wxUSE_MSW" = 1 ; then
1229         wants_win32=1
1230       else
1231         dnl when we use cygwin compiler with -mno-cygwin option it uses mingw32
1232         dnl headers and libraries, so it's Windows-like in this case
1233         AC_CACHE_CHECK([if -mno-cygwin is in effect], wx_cv_nocygwin,
1234             [
1235                 AC_TRY_COMPILE(
1236                     [],
1237                     [
1238                         #ifdef __MINGW32__
1239                             choke me
1240                         #endif
1241                     ],
1242                     wx_cv_nocygwin=no,
1243                     wx_cv_nocygwin=yes
1244                 )
1245             ]
1246         )
1247
1248         if test "$wx_cv_nocygwin" = "yes"; then
1249             wants_win32=1
1250         else
1251             doesnt_want_win32=1
1252         fi
1253       fi
1254       if test "$wants_win32" = 1 ; then
1255         BAKEFILE_FORCE_PLATFORM=win32
1256       fi
1257   ;;
1258   *-*-mingw*)
1259       wants_win32=1
1260   ;;
1261 esac
1262
1263 if test "$wxUSE_WINE" = "yes"; then
1264     wants_win32=1
1265     LDFLAGS_GUI="-mwindows"
1266 fi
1267
1268 dnl NB: The two tests bellow are *NOT* mutually exclusive! They should only
1269 dnl     take effect on Cygwin/Mingw and not other platforms.
1270 if test "$wants_win32" = 1 ; then
1271     USE_UNIX=0
1272     USE_WIN32=1
1273     AC_DEFINE(__WIN32__)
1274     AC_DEFINE(__WIN95__)
1275     AC_DEFINE(__WINDOWS__)
1276     AC_DEFINE(__GNUWIN32__)
1277     AC_DEFINE(STRICT)
1278 fi
1279 if test "$doesnt_want_win32" = 1 ; then
1280     USE_UNIX=1
1281     USE_WIN32=0
1282 fi
1283 dnl (end of Windows-only piece)
1284
1285 if test "$USE_UNIX" = 1 ; then
1286     wxUSE_UNIX=yes
1287     AC_DEFINE(__UNIX__)
1288 fi
1289
1290 dnl This case is for OS/2 vs. everything else
1291 case "${host}" in
1292   *-pc-os2_emx | *-pc-os2-emx )
1293       dnl ---------------------------------------------------------------------
1294       dnl When we are using gcc on OS/2, we want to be either using resources
1295       dnl (PM) or a more complete POSIX emulation for Motif/GTK+/X11.
1296       dnl Moreover we need to link explicitly against either stdcpp.a or
1297       dnl stdcxx.a (depending on compiler version), since we are using "gcc",
1298       dnl not "g++/c++".
1299       dnl ---------------------------------------------------------------------
1300       dnl (OS/2-only piece)
1301       if test "$wxUSE_MOTIF" = 1 -o "$wxUSE_GTK" = 1 -o "$wxUSE_X11" = 1; then
1302           dnl More complete Unix emulation for unix-like ports
1303           dnl by linking in POSIX/2's cExt (if available).
1304           AC_CHECK_LIB(cExt, drand48, LIBS="$LIBS -lcExt")
1305       else
1306           dnl Include resources for the "native" port (wxPM).
1307           RESPROGRAMOBJ="\${top_srcdir}/include/wx/os2/wx.res"
1308       fi
1309       dnl Check for the gcc version (and thereby for the C runtime library).
1310       dnl wx_cv_gccversion = EMX2 -> Standard EMX environment
1311       dnl wx_cv_gccversion = EMX3 -> EMX with gcc-3.0.3 or gcc-3.2.1
1312       dnl wx_cv_gccversion = Innotek5 -> gcc-3.2.2 with Innotek libc5
1313       dnl wx_cv_gccversion = Innotek6 -> gcc-3.3.5 with Innotek libc6.
1314       AC_CACHE_CHECK([for gcc/libc version], wx_cv_gccversion,[
1315           AC_TRY_RUN(
1316               dnl Check the gcc version macro.
1317               [
1318                   #include <stdio.h>
1319
1320                   int main()
1321                   {
1322                       FILE *f=fopen("conftestval", "w");
1323                       if (!f) exit(1);
1324                       fprintf(f,
1325                   #if (__GNUC__ < 3)
1326                               "EMX2"
1327                   #elif (__GNUC__==3) && ((__GNUC_MINOR__ < 2) || ((__GNUC_MINOR__==2) && (__GNUC_PATCHLEVEL__<2)))
1328                               "EMX3"
1329                   #elif (__GNUC__==3) && (__GNUC_MINOR__==2) && (__GNUC_PATCHLEVEL__==2)
1330                               "Innotek5"
1331                   #else
1332                               "Innotek6"
1333                   #endif
1334                       );
1335                       exit(0);
1336                   }
1337               ],
1338               wx_cv_gccversion=`cat conftestval`,
1339               wx_cv_gccversion="EMX2",
1340               dnl Compilation error: Assuming standard EMX environment
1341               wx_cv_gccversion="EMX2"
1342           )
1343       ])
1344       if test "$wx_cv_gccversion" = "EMX2"; then
1345           LIBS="$LIBS -lstdcpp"
1346           LDFLAGS="$LDFLAGS -Zsysv-signals"
1347       else
1348           if test "$wx_cv_gccversion" = "EMX3"; then
1349               LIBS="$LIBS -lstdcxx -lgcc"
1350               LDFLAGS="$LDFLAGS -Zsysv-signals"
1351           else
1352               LIBS="$LIBS -lstdc++"
1353           fi
1354       fi
1355       if test "$wxUSE_SHARED" = "yes" -a "$wxUSE_OMF" = "no"; then
1356         AC_MSG_WARN([Building DLLs requires OMF mode, enabled])
1357         wxUSE_OMF=yes
1358         enable_omf=yes
1359       fi
1360       dnl (end of OS/2-only piece)
1361   ;;
1362   *)
1363       dnl ---------------------------------------------------------------------
1364       dnl look for strcasecmp() in string.h and then strings.h if it's not
1365       dnl there. Don't do this on OS/2, where "stricmp" is the function to be
1366       dnl used.
1367       dnl ---------------------------------------------------------------------
1368       dnl (non-OS/2-only piece)
1369
1370       AC_CACHE_CHECK([for strcasecmp() in string.h], ac_cv_string_strcasecmp, [
1371           AC_TRY_LINK([
1372               #include <string.h>
1373               ],
1374               [
1375                   strcasecmp("foo", "bar");
1376               ],
1377               ac_cv_string_strcasecmp=yes,
1378               ac_cv_string_strcasecmp=no
1379           )
1380       ])
1381
1382       if test x"$ac_cv_string_strcasecmp" = "xyes"; then
1383           AC_DEFINE(HAVE_STRCASECMP_IN_STRING_H)
1384       else
1385           AC_CACHE_CHECK([for strcasecmp() in strings.h], ac_cv_strings_strcasecmp, [
1386               AC_TRY_LINK([
1387                   #include <strings.h>
1388                   ],
1389                   [
1390                       strcasecmp("foo", "bar");
1391                   ],
1392                   ac_cv_strings_strcasecmp=yes,
1393                   ac_cv_strings_strcasecmp=no
1394               )
1395           ])
1396
1397           if test x"$ac_cv_strings_strcasecmp" = "xyes"; then
1398               AC_DEFINE(HAVE_STRCASECMP_IN_STRINGS_H)
1399           else
1400               AC_MSG_ERROR([No case-insensitive string comparison function found.])
1401           fi
1402       fi
1403
1404       dnl (end of non-OS/2-only piece)
1405   ;;
1406 esac
1407
1408 dnl ------------------------------------------------------------------------
1409 dnl Check for headers
1410 dnl ------------------------------------------------------------------------
1411
1412 dnl Note: non-empty last parameter makes check compile-only,
1413 dnl   skipping worthless preprocessing check
1414 AC_CHECK_HEADERS(stdlib.h fnmatch.h langinfo.h malloc.h unistd.h wchar.h,,, [AC_INCLUDES_DEFAULT()])
1415
1416 dnl maybe wchar_t is in wcstr.h if we don't have wchar.h?
1417 if test "$ac_cv_header_wchar_h" != "yes"; then
1418     AC_CHECK_HEADER(wcstr.h,,, [AC_INCLUDES_DEFAULT()])
1419 fi
1420
1421 case "${host}" in
1422   *-pc-os2_emx | *-pc-os2-emx )
1423       dnl Explicitly link -lintl if langinfo.h is available
1424       dnl and intl not yet included in libc
1425       if test $ac_cv_header_langinfo_h = "yes" \
1426                 -a \(   "$wx_cv_gccversion" = "EMX2" \
1427                      -o "$wx_cv_gccversion" = "EMX3" \
1428                      -o "$wx_cv_gccversion" = "Innotek5" \); then
1429           LIBS="$LIBS -lintl"
1430       fi
1431   ;;
1432 esac
1433
1434 dnl POSIX needs this for select(), but old systems don't have it
1435 if test "$USE_UNIX" = 1 ; then
1436     AC_CHECK_HEADER([sys/select.h],,, [AC_INCLUDES_DEFAULT()])
1437 fi
1438
1439 dnl defines HAVE_SYS_EPOLL_H - for epoll mainloop implementation in wxbase
1440 AC_CHECK_HEADERS(sys/epoll.h)
1441
1442 dnl ---------------------------------------------------------------------------
1443 dnl Checks for compiler characteristics
1444 dnl ---------------------------------------------------------------------------
1445
1446 dnl defines const to be empty if c-compiler does not support const fully
1447 AC_C_CONST
1448 dnl defines inline to a sensible value for the c-compiler
1449 AC_C_INLINE
1450
1451 dnl check the sizes of integral types (give some reasonable default values for
1452 dnl cross-compiling)
1453 dnl   defines the size of certain types of variables in SIZEOF_<TYPE>
1454 AC_CHECK_SIZEOF(short, 2)
1455 AC_CHECK_SIZEOF(void *, 4)
1456 AC_CHECK_SIZEOF(int, 4)
1457 AC_CHECK_SIZEOF(long, 4)
1458 AC_CHECK_SIZEOF(size_t, 4)
1459
1460 case "${host}" in
1461     arm-*-linux* )
1462         AC_CHECK_SIZEOF(long long, 8)
1463     ;;
1464     *-hp-hpux* )
1465         AC_CHECK_SIZEOF(long long, 0)
1466         if test "$ac_cv_sizeof_long_long" != "0"; then
1467             dnl HPUX 10.20 headers need this define in order to use long long definitions
1468             CPPFLAGS="-D_INCLUDE_LONGLONG $CPPFLAGS"
1469         fi
1470     ;;
1471     * )
1472         AC_CHECK_SIZEOF(long long, 0)
1473 esac
1474
1475 dnl SGI/Irix's stdio.h does not include wchar_t. Mac OS X does not provide
1476 dnl wchar.h and wchar_t is defined by stdlib.h (GD)
1477 AC_CHECK_SIZEOF(wchar_t, 0,
1478     [
1479         /* DJGPP's wchar_t is now a keyword in C++ (still not C though) */
1480         #if defined(__DJGPP__) && !( (__GNUC_MINOR__ >= 8 && __GNUC__ == 2 ) || __GNUC__ >= 3 )
1481         #  error "fake wchar_t"
1482         #endif
1483         #ifdef HAVE_WCHAR_H
1484         #  ifdef __CYGWIN__
1485         #    include <stddef.h>
1486         #  endif
1487         #  include <wchar.h>
1488         #endif
1489         #ifdef HAVE_STDLIB_H
1490         #  include <stdlib.h>
1491         #endif
1492         #include <stdio.h>
1493     ]
1494 )
1495 if test "$ac_cv_sizeof_wchar_t" != "0"; then
1496     wxUSE_WCHAR_T=yes
1497 else
1498     wxUSE_WCHAR_T=no
1499 fi
1500
1501 dnl checks needed to define wxVaCopy
1502 AC_CACHE_CHECK([for va_copy],
1503     wx_cv_func_va_copy,
1504     [
1505         AC_LANG_PUSH(C++)
1506         AC_LINK_IFELSE([
1507             #include <stdarg.h>
1508             void foo(char *f, ...)
1509             {
1510                 va_list ap1, ap2;
1511                 va_start(ap1, f);
1512                 va_copy(ap2, ap1);
1513                 va_end(ap2);
1514                 va_end(ap1);
1515             }
1516             int main()
1517             {
1518                 foo("hi", 17);
1519                 return 0;
1520             }],
1521             wx_cv_func_va_copy=yes,
1522             wx_cv_func_va_copy=no
1523         )
1524         AC_LANG_POP()
1525     ]
1526 )
1527
1528 if test $wx_cv_func_va_copy = "yes"; then
1529     AC_DEFINE(HAVE_VA_COPY)
1530 else
1531     dnl try to understand how can we copy va_lists
1532     AC_CACHE_CHECK([if va_list can be copied by value],
1533         wx_cv_type_va_list_lvalue,
1534         [
1535             AC_RUN_IFELSE([
1536                 #include <stdarg.h>
1537                 int foo(char *f, ...)
1538                 {
1539                     va_list ap1, ap2;
1540                     va_start(ap1, f);
1541                     ap2 = ap1;
1542                     if ( va_arg(ap1, int) != 17 || va_arg(ap2, int) != 17 )
1543                         return 1;
1544                     va_end(ap2);
1545                     va_end(ap1);
1546                     return 0;
1547                 }
1548                 int main()
1549                 {
1550                     return foo("hi", 17);
1551                 }],
1552                 wx_cv_type_va_list_lvalue=yes,
1553                 wx_cv_type_va_list_lvalue=no,
1554                 dnl assume most common case for cross-compiling...
1555                 wx_cv_type_va_list_lvalue=yes
1556             )
1557         ]
1558     )
1559
1560     if test $wx_cv_type_va_list_lvalue != "yes"; then
1561         dnl we suppose that the only thing which can't be copied like this
1562         dnl are arrays... only experience will show whether this is really true
1563         AC_DEFINE(VA_LIST_IS_ARRAY)
1564     fi
1565 fi
1566
1567 dnl don't check for vararg macros if they're explicitly disabled: this is
1568 dnl useful if the user code using the library wants to limit itself to standard
1569 dnl C++ only (e.g. is compiled with g++ -std=c++98)
1570 if test "$wxUSE_VARARG_MACROS" = "yes"; then
1571
1572 dnl Check if variadic macros (C99 feature) are supported:
1573 AC_CACHE_CHECK(
1574     [whether the compiler supports variadic macros],
1575     [wx_cv_have_variadic_macros],
1576     [
1577         dnl C compiler might support variadic macros when C++ one doesn't
1578         dnl (happens with gcc/g++ 2.95.4), so must use C++ one explicitly
1579         AC_LANG_PUSH(C++)
1580         AC_COMPILE_IFELSE(
1581             AC_LANG_PROGRAM(
1582                 [
1583                     #include <stdio.h>
1584                     #define test(fmt, ...) printf(fmt, __VA_ARGS__)
1585                 ],
1586                 [
1587                     test("%s %d %p", "test", 1, 0);
1588                 ]
1589             ),
1590             [wx_cv_have_variadic_macros=yes],
1591             [wx_cv_have_variadic_macros=no]
1592             )
1593         AC_LANG_POP()
1594     ]
1595 )
1596
1597 if test $wx_cv_have_variadic_macros = "yes"; then
1598     AC_DEFINE(HAVE_VARIADIC_MACROS)
1599 fi
1600
1601 fi dnl wxUSE_VARARG_MACROS == yes
1602
1603 dnl check for large file support
1604 AC_SYS_LARGEFILE
1605
1606 dnl we need to define _FILE_OFFSET_BITS or _LARGE_FILES on the compiler command
1607 dnl line because otherwise the system headers risk being included before
1608 dnl wx/defs.h which defines these constants leading to inconsistent
1609 dnl sizeof(off_t) in different source files of the same program and linking
1610 dnl problems
1611 if test "x$wx_largefile" = "xyes"; then
1612     if test "x$ac_cv_sys_file_offset_bits" = "x64"; then
1613         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_FILE_OFFSET_BITS=64 -D_LARGE_FILES"
1614
1615         dnl We get "Large Files (ILP32) not supported in strict ANSI mode."
1616         dnl #error from HP standard headers unless __STDC_EXT__ is defined.
1617         dnl The compiler should define it automatically, but some old g++
1618         dnl versions don't define it, so test and add it if necessary. AFAIK
1619         dnl the problem only affects the C++ compiler so it is added to
1620         dnl CXXFLAGS only.
1621         if test "$USE_HPUX" = 1 -a "$GXX" = "yes"; then
1622             AC_CACHE_CHECK(
1623                 [if -D__STDC_EXT__ is required],
1624                 wx_cv_STDC_EXT_required,
1625                 [
1626                     AC_LANG_PUSH(C++)
1627                     AC_TRY_COMPILE(
1628                         [],
1629                         [
1630                             #ifndef __STDC_EXT__
1631                                 choke me
1632                             #endif
1633                         ],
1634                         wx_cv_STDC_EXT_required=no,
1635                         wx_cv_STDC_EXT_required=yes
1636                     )
1637                     AC_LANG_POP()
1638                 ]
1639             )
1640             if test "x$wx_cv_STDC_EXT_required" = "xyes"; then
1641                 WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -D__STDC_EXT__"
1642             fi
1643         fi
1644     else
1645         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_LARGE_FILES"
1646     fi
1647     dnl AC_FUNC_FSEEKO sets HAVE_FSEEKO and $ac_cv_sys_largefile_source
1648     AC_FUNC_FSEEKO
1649     if test "$ac_cv_sys_largefile_source" != no; then
1650         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_LARGEFILE_SOURCE=$ac_cv_sys_largefile_source"
1651     fi
1652 fi
1653
1654 dnl check for bytesex stuff (don't use AC_C_BIGENDIAN to allow cross-compiling)
1655 WX_C_BIGENDIAN
1656
1657 dnl check for iostream (as opposed to iostream.h) standard header
1658 WX_CPP_NEW_HEADERS(, AC_DEFINE(wxUSE_IOSTREAMH))
1659
1660 dnl check whether C++ compiler supports bool built-in type
1661 WX_CPP_BOOL
1662
1663 dnl check whether C++ compiler supports explicit keyword
1664 WX_CPP_EXPLICIT
1665
1666 dnl check whether C++ compiler supports C++ casts
1667 AC_CXX_CONST_CAST
1668 AC_CXX_REINTERPRET_CAST
1669 AC_CXX_STATIC_CAST
1670 dnl we don't use HAVE_DYNAMIC_CAST anywhere right now...
1671 dnl AC_CXX_DYNAMIC_CAST
1672
1673 dnl With Sun CC, temporaries have block scope by default. This flag is needed
1674 dnl to get the expression scope behaviour that conforms to the standard.
1675 if test "x$SUNCXX" = xyes; then
1676     CXXFLAGS="-features=tmplife $CXXFLAGS"
1677 fi
1678
1679 dnl Sun X11 headers are (still, in 2005!) non-ANSI and the best they could do
1680 dnl was to hack their C++ compiler to accept them silently -- but C compiler
1681 dnl still spits out dozens of warnings for each X include file, so suppress
1682 dnl them
1683 if test "x$SUNCC" = xyes; then
1684     CFLAGS="-erroff=E_NO_EXPLICIT_TYPE_GIVEN $CFLAGS"
1685 fi
1686
1687 dnl SGI mipsPro compiler gives this warning for "conversion from pointer to
1688 dnl same-sized integral type" even when there is an explicit cast and as there
1689 dnl is no way to turn it off and there are hundreds of these warnings in wx
1690 dnl sources, just turn it off for now
1691 dnl
1692 dnl a better long term solution would be to use #pragma set/reset woff in
1693 dnl wxPtrToUInt() and use it instead of casts elsewhere
1694 if test "x$SGICC" = "xyes"; then
1695     CFLAGS="-woff 3970 $CFLAGS"
1696 fi
1697 if test "x$SGICXX" = "xyes"; then
1698     CXXFLAGS="-woff 3970 $CXXFLAGS"
1699 fi
1700
1701 dnl HP-UX c89/aCC compiler warnings
1702 if test "x$HPCC" = "xyes"; then
1703     dnl 2011: "unrecognized preprocessor directive": nice warning but it's given
1704     dnl       even for directives inside #if which is not true (i.e. which are
1705     dnl       used for other compilers/OS) and so we have no way to get rid of it
1706     dnl 2450: "long long is non standard" -- yes, we know
1707     CFLAGS="+W 2011,2450 $CFLAGS"
1708 fi
1709 if test "x$HPCXX" = "xyes"; then
1710     dnl 2340: "value copied to temporary, reference to temporary used": very
1711     dnl       painful as triggered by any occurrence of user-defined conversion
1712     CXXFLAGS="+W 2340 $CXXFLAGS"
1713 fi
1714
1715 dnl DEC/Compaq/HP cxx warnings
1716 if test "x$COMPAQCXX" = "xyes"; then
1717     dnl -w0 enables all warnings, then we disable some of them:
1718     dnl basclsnondto: base class dtor non virtual (sometimes we do want this)
1719     dnl unrimpret:  "end of routine block may be unreachable" is given for
1720     dnl             every "if ( ) return ...; else return ...;"
1721     dnl intconlosbit: "conversion to integral type of smaller size could lose
1722     dnl               data" this is a useful warning but there are too many of
1723     dnl               them for now
1724     CXXFLAGS="-w0 -msg_disable basclsnondto,unrimpret,intconlosbit"
1725 fi
1726
1727 dnl the next few tests are all for C++ features and so need to be done using
1728 dnl C++ compiler
1729 AC_LANG_PUSH(C++)
1730
1731 dnl check for std::string or std::wstring
1732 if test "$wxUSE_STD_STRING" = "yes" -o "$wxUSE_STL" = "yes"; then
1733     if test "$wxUSE_UNICODE" = "yes"; then
1734         std_string="std::wstring"
1735         char_type="wchar_t"
1736     else
1737         std_string="std::string"
1738         char_type="char"
1739     fi
1740
1741     dnl check if <string> declares std::[w]string
1742     AC_CACHE_CHECK([for $std_string in <string>],
1743         wx_cv_class_stdstring,
1744         [
1745             AC_TRY_COMPILE([#include <string>],
1746                 [$std_string foo;],
1747                 wx_cv_class_stdstring=yes,
1748                 wx_cv_class_stdstring=no
1749             )
1750         ]
1751     )
1752
1753     if test "$wx_cv_class_stdstring" = yes; then
1754         if test "$wxUSE_UNICODE" = "yes"; then
1755             AC_DEFINE(HAVE_STD_WSTRING)
1756         fi
1757         dnl we don't need HAVE_STD_STRING, we just suppose it's available if
1758         dnl wxUSE_STD_STRING==yes
1759     else
1760         AC_CACHE_CHECK([if std::basic_string<$char_type> works],
1761             wx_cv_class_stdbasicstring,
1762             [
1763                 AC_TRY_COMPILE([
1764                     #ifdef HAVE_WCHAR_H
1765                     #  ifdef __CYGWIN__
1766                     #    include <stddef.h>
1767                     #  endif
1768                     #  include <wchar.h>
1769                     #endif
1770                     #ifdef HAVE_STDLIB_H
1771                     #  include <stdlib.h>
1772                     #endif
1773                     #include <stdio.h>
1774                     #include <string>
1775                     ],
1776                     [std::basic_string<$char_type> foo;
1777                      const $char_type* dummy = foo.c_str();],
1778                     wx_cv_class_stdbasicstring=yes,
1779                     wx_cv_class_stdbasicstring=no
1780                 )
1781             ]
1782         )
1783
1784         if test "$wx_cv_class_stdbasicstring" != yes; then
1785             if test "$wxUSE_STL" = "yes"; then
1786                 AC_MSG_ERROR([Can't use --enable-stl without $std_string or std::basic_string<$char_type>])
1787             elif grep wxUSE_STD_STRING $wx_arg_cache_file >/dev/null; then
1788                 AC_MSG_ERROR([Can't use --enable-std_string without $std_string or std::basic_string<$char_type>])
1789             else
1790                 AC_MSG_WARN([No $std_string or std::basic_string<$char_type>, switching to --disable-std_string])
1791                 wxUSE_STD_STRING=no
1792             fi
1793         fi
1794     fi
1795 fi
1796
1797 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
1798     AC_CHECK_TYPES([std::istream, std::ostream],,
1799                    [wxUSE_STD_IOSTREAM=no],
1800                    [#include <iostream>])
1801
1802     if test "$wxUSE_STD_IOSTREAM" != "yes"; then
1803         if grep wxUSE_STD_IOSTREAM $wx_arg_cache_file >/dev/null; then
1804             AC_MSG_ERROR([Can't use --enable-std_iostreams without std::istream and std::ostream])
1805         else
1806             AC_MSG_WARN([No std::iostreams, switching to --disable-std_iostreams])
1807         fi
1808     fi
1809 fi
1810
1811 if test "$wxUSE_STL" = "yes"; then
1812     dnl check for basic STL functionality
1813     AC_CACHE_CHECK([for basic STL functionality],
1814         wx_cv_lib_stl,
1815         [AC_TRY_COMPILE([#include <string>
1816             #include <functional>
1817             #include <algorithm>
1818             #include <vector>
1819             #include <list>],
1820             [std::vector<int> moo;
1821              std::list<int> foo;
1822              std::vector<int>::iterator it =
1823                  std::find_if(moo.begin(), moo.end(),
1824                               std::bind2nd(std::less<int>(), 3));],
1825             wx_cv_lib_stl=yes,
1826             wx_cv_lib_stl=no
1827         )]
1828     )
1829
1830     if test "$wx_cv_lib_stl" != yes; then
1831          AC_MSG_ERROR([Can't use --enable-stl as basic STL functionality is missing])
1832     fi
1833
1834     dnl check for compliant std::string::compare
1835     AC_CACHE_CHECK([for compliant std::string::compare],
1836         wx_cv_func_stdstring_compare,
1837         [AC_TRY_COMPILE([#include <string>],
1838             [std::string foo, bar;
1839             foo.compare(bar);
1840             foo.compare(1, 1, bar);
1841             foo.compare(1, 1, bar, 1, 1);
1842             foo.compare("");
1843             foo.compare(1, 1, "");
1844             foo.compare(1, 1, "", 2);],
1845             wx_cv_func_stdstring_compare=yes,
1846             wx_cv_func_stdstring_compare=no
1847         )]
1848     )
1849
1850     if test "$wx_cv_func_stdstring_compare" = yes; then
1851         AC_DEFINE(HAVE_STD_STRING_COMPARE)
1852     fi
1853
1854     dnl check for hash_map and hash_set headers
1855     AC_CHECK_HEADER([hash_map],
1856         [AC_CACHE_CHECK([for standard hash_map and hash_set],
1857             wx_cv_class_stdhashmapset,
1858             [AC_TRY_COMPILE([#include <hash_map>
1859                 #include <hash_set>],
1860                 [std::hash_map<double*, char*, std::hash<double*>, std::equal_to<double*> > test1;
1861                  std::hash_set<char*, std::hash<char*>, std::equal_to<char*> > test2;],
1862                 wx_cv_class_stdhashmapset=yes,
1863                 wx_cv_class_stdhashmapset=no)
1864             ]
1865         )],
1866         [],
1867         [ ]
1868     )
1869
1870     if test "$wx_cv_class_stdhashmapset" = yes; then
1871         AC_DEFINE(HAVE_HASH_MAP)
1872         AC_DEFINE(HAVE_STD_HASH_MAP)
1873     fi
1874
1875     AC_CHECK_HEADER([ext/hash_map],
1876         [AC_CACHE_CHECK([for GNU hash_map and hash_set],
1877             wx_cv_class_gnuhashmapset,
1878             [AC_TRY_COMPILE([#include <ext/hash_map>
1879                 #include <ext/hash_set>],
1880                 [__gnu_cxx::hash_map<double*, char*, __gnu_cxx::hash<double*>, std::equal_to<double*> > test1;
1881                  __gnu_cxx::hash_set<char*, __gnu_cxx::hash<char*>, std::equal_to<char*> > test2;],
1882                 wx_cv_class_gnuhashmapset=yes,
1883                 wx_cv_class_gnuhashmapset=no)
1884             ]
1885         )],
1886         [],
1887         [ ]
1888     )
1889
1890     if test "$wx_cv_class_gnuhashmapset" = yes; then
1891          AC_DEFINE(HAVE_EXT_HASH_MAP)
1892          AC_DEFINE(HAVE_GNU_CXX_HASH_MAP)
1893     fi
1894 fi
1895
1896 dnl pop C++
1897 AC_LANG_POP()
1898
1899 dnl ---------------------------------------------------------------------------
1900 dnl Define search path for includes and libraries: all headers and libs will be
1901 dnl looked for in all directories of this path
1902 dnl ---------------------------------------------------------------------------
1903
1904 dnl Notice that /usr/include should *not* be in this list, otherwise it breaks
1905 dnl compilation on Solaris/AIX/... with gcc because standard (non ANSI C)
1906 dnl headers are included instead of the "fixed" (ANSI-fied) gcc ones.
1907 dnl
1908 dnl Also try to put all directories which may contain X11R6 before those which
1909 dnl may contain X11R5/4 - we want to use R6 on machines which have both!
1910 dnl
1911 dnl In the same vein. Motif 2.1 should be tried before Motif 1.2 for the
1912 dnl systems which have both (AIX 4.x does)
1913 SEARCH_INCLUDE="\
1914     /usr/local/include        \
1915                               \
1916     /usr/Motif-2.1/include    \
1917     /usr/Motif-1.2/include    \
1918     /usr/include/Motif1.2     \
1919                               \
1920     /usr/dt/include           \
1921     /usr/openwin/include      \
1922                               \
1923     /usr/include/Xm           \
1924                               \
1925     /usr/X11R6/include        \
1926     /usr/X11R6.4/include      \
1927     /usr/X11R5/include        \
1928     /usr/X11R4/include        \
1929                               \
1930     /usr/include/X11R6        \
1931     /usr/include/X11R5        \
1932     /usr/include/X11R4        \
1933                               \
1934     /usr/local/X11R6/include  \
1935     /usr/local/X11R5/include  \
1936     /usr/local/X11R4/include  \
1937                               \
1938     /usr/local/include/X11R6  \
1939     /usr/local/include/X11R5  \
1940     /usr/local/include/X11R4  \
1941                               \
1942     /usr/X11/include          \
1943     /usr/include/X11          \
1944     /usr/local/X11/include    \
1945     /usr/local/include/X11    \
1946                               \
1947     /usr/XFree86/include/X11  \
1948     /usr/pkg/include          \
1949                               \
1950     /usr/openwin/share/include"
1951
1952 dnl try to find out the standard lib locations for the systems with multiple
1953 dnl ABIs
1954 AC_MSG_CHECKING([for libraries directory])
1955
1956 case "${host}" in
1957     *-*-irix6* )
1958         AC_CACHE_VAL(
1959             wx_cv_std_libpath,
1960             [
1961                 for d in WX_STD_LIBPATH(); do
1962                     for e in a so sl dylib dll.a; do
1963                         libc="$d/libc.$e"
1964                         if test -f $libc; then
1965                             save_LIBS="$LIBS"
1966                             LIBS="$libc"
1967                             AC_LINK_IFELSE([int main() { return 0; }],
1968                                 wx_cv_std_libpath=`echo $d | sed s@/usr/@@`)
1969                             LIBS="$save_LIBS"
1970                             if test "x$wx_cv_std_libpath" != "x"; then
1971                                 break 2
1972                             fi
1973                         fi
1974                     done
1975                 done
1976                 if test "x$wx_cv_std_libpath" = "x"; then
1977                     wx_cv_std_libpath="lib"
1978                 fi
1979             ]
1980         )
1981         ;;
1982
1983     *-*-solaris2* )
1984         dnl use ../lib or ../lib/64 depending on the size of void*
1985         if test "$ac_cv_sizeof_void_p" = 8 -a -d "/usr/lib/64"; then
1986             wx_cv_std_libpath="lib/64"
1987         else
1988             wx_cv_std_libpath="lib"
1989         fi
1990         ;;
1991
1992     *-*-linux* )
1993         dnl use ../lib or ../lib64 depending on the size of void*
1994         if test "$ac_cv_sizeof_void_p" = 8 -a \
1995                 -d "/usr/lib64" -a ! -h "/usr/lib64"; then
1996             wx_cv_std_libpath="lib64"
1997         else
1998             wx_cv_std_libpath="lib"
1999         fi
2000         ;;
2001
2002     *)
2003         wx_cv_std_libpath="lib";
2004         ;;
2005 esac
2006
2007 AC_MSG_RESULT($wx_cv_std_libpath)
2008
2009 SEARCH_LIB="`echo "$SEARCH_INCLUDE" | sed s@include@$wx_cv_std_libpath@g` /usr/$wx_cv_std_libpath"
2010
2011 dnl Cross compiling with gcc?
2012 if test "$build" != "$host" -a "$GCC" = yes; then
2013     dnl for gcc cross-compilers "$CC -print-prog-name=ld" prints the path to
2014     dnl the linker. Stripping off the trailing '/bin/ld' gives us a candiate
2015     dnl for a 'root' below which libraries and headers for the target system
2016     dnl might be installed.
2017     if cross_root=`$CC -print-prog-name=ld 2>/dev/null`; then
2018         cross_root=`dirname $cross_root`
2019         cross_root=`dirname $cross_root`
2020
2021         dnl substitute this candiate root for '^/usr' in the search lists,
2022         dnl strip out any that don't start '^/usr'.
2023         SEARCH_LIB=`for x in $SEARCH_LIB; do echo $x; done | sed -ne "s|^/usr|$cross_root|p"`
2024         SEARCH_INCLUDE=`for x in $SEARCH_INCLUDE; do echo $x; done | sed -ne "s|^/usr|$cross_root|p"`
2025         SEARCH_INCLUDE="$SEARCH_INCLUDE $cross_root/include"
2026
2027         dnl also have pkg-config search for *.pc files under this 'root'
2028         if test -z "$PKG_CONFIG_PATH"; then
2029             PKG_CONFIG_PATH="$cross_root/local/lib/pkgconfig:$cross_root/lib/pkgconfig"
2030             export PKG_CONFIG_PATH
2031         fi
2032
2033         dnl AC_PATH_XTRA doesn't work currently unless -x-includes and
2034         dnl -x-libraries are given on the command line. So if they are not
2035         dnl set then set them here to plausible defaults.
2036         if test -z "$x_includes" -o "$x_includes" = NONE; then
2037             WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, X11/Intrinsic.h)
2038             x_includes=$ac_find_includes
2039         fi
2040         if test -z "$x_libraries" -o "$x_libraries" = NONE; then
2041             WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xt)
2042             x_libraries=$ac_find_libraries
2043         fi
2044     fi
2045 fi
2046
2047 dnl ------------------------------------------------------------------------
2048 dnl Check for libraries
2049 dnl ------------------------------------------------------------------------
2050
2051 dnl flush the cache because checking for libraries below might abort
2052 AC_CACHE_SAVE
2053
2054 dnl check for glibc version
2055 dnl
2056 dnl VZ: I have no idea why had this check been there originally, but now
2057 dnl     we could probably do without it by just always adding _GNU_SOURCE
2058 if test "$USE_LINUX" = 1 -o "$USE_GNU" = 1; then
2059     AC_CACHE_CHECK([for glibc 2.1 or later], wx_cv_lib_glibc21,[
2060         AC_TRY_COMPILE([#include <features.h>],
2061             [
2062                 #if (__GLIBC__ < 2) || (__GLIBC_MINOR__ < 1)
2063                 not glibc 2.1
2064                 #endif
2065             ],
2066             [
2067                 wx_cv_lib_glibc21=yes
2068             ],
2069             [
2070                 wx_cv_lib_glibc21=no
2071             ]
2072         )
2073     ])
2074     if test "$wx_cv_lib_glibc21" = "yes"; then
2075         AC_DEFINE(wxHAVE_GLIBC2)
2076     fi
2077 fi
2078
2079 dnl we may need _GNU_SOURCE for 2 things:
2080 dnl
2081 dnl  1. to get PTHREAD_MUTEX_RECURSIVE with glibc 2.1+ (strictly speaking we
2082 dnl  only need _XOPEN_SOURCE=500 but just defining this disables _BSD_SOURCE
2083 dnl  which breaks libtiff compilation, so it is simpler to just define
2084 dnl  _GNU_SOURCE to get everything)
2085 dnl
2086 dnl  2. for Unicode functions
2087 if test "x$wx_cv_lib_glibc21" = "xyes"; then
2088     if test "$wxUSE_UNICODE" = "yes" -o "$wxUSE_THREADS" = "yes"; then
2089         AC_DEFINE(_GNU_SOURCE)
2090     fi
2091 fi
2092
2093 dnl Only add the -lm library if floating point functions cannot be used
2094 dnl without it.  This check is important on cygwin because of the bizarre
2095 dnl way that they have organized functions into libraries.  On cygwin, both
2096 dnl libc.a and libm.a are symbolic links to a single lib libcygwin.a.  This
2097 dnl means that
2098 dnl   1) linking with -lm is not necessary, and
2099 dnl   2) linking with -lm is dangerous if the order of libraries is wrong
2100 dnl In particular, if you compile any program with -mno-cygwin and link with
2101 dnl -lm, it will crash instantly when it is run.  This happens because the
2102 dnl linker incorrectly links the Cygwin libm.a (==libcygwin.a), which replaces
2103 dnl the ___main function instead of allowing it to be defined by
2104 dnl /usr/lib/mingw/libmingw32.a as it should be.
2105 dnl
2106 dnl On MacOS X, this test will find that -lm is unnecessary and leave it out.
2107 dnl
2108 dnl Just check a few floating point functions. If they are all found without
2109 dnl -lm, then we must not need -lm.
2110 have_cos=0
2111 have_floor=0
2112 AC_CHECK_FUNCS(cos, have_cos=1)
2113 AC_CHECK_FUNCS(floor, have_floor=1)
2114 AC_MSG_CHECKING(if floating point functions link without -lm)
2115 if test "$have_cos" = 1 -a "$have_floor" = 1; then
2116     AC_MSG_RESULT(yes)
2117 else
2118     AC_MSG_RESULT(no)
2119     LIBS="$LIBS -lm"
2120     # use different functions to avoid configure caching
2121     have_sin=0
2122     have_ceil=0
2123     AC_CHECK_FUNCS(sin, have_sin=1)
2124     AC_CHECK_FUNCS(ceil, have_ceil=1)
2125     AC_MSG_CHECKING(if floating point functions link with -lm)
2126     if test "$have_sin" = 1 -a "$have_ceil" = 1; then
2127         AC_MSG_RESULT(yes)
2128     else
2129         AC_MSG_RESULT(no)
2130         # not sure we should warn the user, crash, etc.
2131     fi
2132 fi
2133
2134 dnl check for C99 string to long long conversion functions, assume that if we
2135 dnl have the unsigned variants, then we have the signed ones as well
2136 dnl
2137 dnl at least under SGI these functions are only available in C99 code and not
2138 dnl in C++ so do these tests using C++ compiler
2139 AC_LANG_PUSH(C++)
2140 if test "wxUSE_UNICODE" = "yes"; then
2141     WX_CHECK_FUNCS(wcstoull)
2142 else
2143     WX_CHECK_FUNCS(strtoull)
2144 fi
2145 AC_LANG_POP()
2146
2147 dnl ---------------------------------------------------------------------------
2148 dnl Optional libraries
2149 dnl
2150 dnl   --with-<lib>=sys
2151 dnl       looks for system library and fails if not found
2152 dnl
2153 dnl   --with-<lib>
2154 dnl   --with-<lib>=yes
2155 dnl       looks for system library and, if not found, prints a warning,
2156 dnl       falls back to the builtin wx version, and continues configuration
2157 dnl
2158 dnl   --with-<lib>=builtin
2159 dnl       uses builtin wx version without searching for system library
2160 dnl
2161 dnl   --with-<lib>=no
2162 dnl   --without-<lib>
2163 dnl       do not use library (neither system nor builtin wx version)
2164 dnl
2165 dnl ---------------------------------------------------------------------------
2166
2167 dnl ------------------------------------------------------------------------
2168 dnl Check for regex libraries
2169 dnl ------------------------------------------------------------------------
2170
2171 if test "$wxUSE_REGEX" != "no"; then
2172     AC_DEFINE(wxUSE_REGEX)
2173
2174     if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_REGEX" = "yes"; then
2175         AC_MSG_WARN([Defaulting to the the builtin regex library for Unicode build.])
2176         wxUSE_REGEX=builtin
2177     fi
2178
2179     if test "$wxUSE_REGEX" = "sys" -o "$wxUSE_REGEX" = "yes" ; then
2180         dnl according to Unix 98 specs, regcomp() is in libc but I believe that
2181         dnl on some old systems it may be in libregex - check for it too?
2182         AC_CHECK_HEADER(regex.h, [AC_CHECK_FUNCS(regcomp re_search)],, [ ])
2183
2184         if test "x$ac_cv_func_regcomp" != "xyes"; then
2185             if test "$wxUSE_REGEX" = "sys" ; then
2186                 AC_MSG_ERROR([system regex library not found! Use --with-regex to use built-in version])
2187             else
2188                 AC_MSG_WARN([system regex library not found, will use built-in instead])
2189                 wxUSE_REGEX=builtin
2190             fi
2191         else
2192             dnl we are using the system library
2193             wxUSE_REGEX=sys
2194             dnl only the built-in supports advanced REs
2195             AC_DEFINE(WX_NO_REGEX_ADVANCED)
2196         fi
2197     fi
2198 fi
2199
2200 dnl ------------------------------------------------------------------------
2201 dnl Check for zlib compression library
2202 dnl ------------------------------------------------------------------------
2203
2204 ZLIB_LINK=
2205 if test "$wxUSE_ZLIB" != "no" ; then
2206     AC_DEFINE(wxUSE_ZLIB)
2207
2208     if test "$wxUSE_ZLIB" = "sys" -o "$wxUSE_ZLIB" = "yes" ; then
2209         dnl don't test for zlib under Mac -- its verson there is 1.1.3 but we
2210         dnl should still use it because hopefully (can someone confirm this?)
2211         dnl Apple did fix the security problem in it and not using the system
2212         dnl library results in a whole bunch of warnings when linking with
2213         dnl Carbon framework
2214         if test "$USE_DARWIN" = 1; then
2215             system_zlib_h_ok="yes"
2216         else
2217             dnl we have troubles with ancient zlib versions (e.g. 1.0.4 is
2218             dnl known to not work) and although I don't know which is
2219             dnl the minimal required version it's safer to test for 1.1.4 as
2220             dnl it fixes a security problem in 1.1.3 -- and hopefully nobody
2221             dnl has anything more ancient (1.1.3 was released in July 1998)
2222             dnl anyhow
2223             AC_CACHE_CHECK([for zlib.h >= 1.1.4], ac_cv_header_zlib_h,
2224                 [AC_TRY_RUN(
2225                     dnl zlib.h defines ZLIB_VERSION="x.y.z"
2226                     [
2227                         #include <zlib.h>
2228                         #include <stdio.h>
2229
2230                         int main()
2231                         {
2232                             FILE *f=fopen("conftestval", "w");
2233                             if (!f) exit(1);
2234                             fprintf(f, "%s",
2235                                     ZLIB_VERSION[0] == '1' &&
2236                                     (ZLIB_VERSION[2] > '1' ||
2237                                     (ZLIB_VERSION[2] == '1' &&
2238                                      ZLIB_VERSION[4] >= '4')) ? "yes" : "no");
2239                             exit(0);
2240                         }
2241                     ],
2242                     ac_cv_header_zlib_h=`cat conftestval`,
2243                     ac_cv_header_zlib_h=no,
2244                     dnl cross-compiling: don't have an answer, try later
2245                     unset ac_cv_header_zlib_h
2246                 )]
2247             )
2248             dnl If the test above did not come up with a value (e.g. cross
2249             dnl compiling) then this should give a definitive answer
2250             AC_CHECK_HEADER(zlib.h,,, [ ])
2251
2252             system_zlib_h_ok=$ac_cv_header_zlib_h
2253         fi
2254
2255         if test "$system_zlib_h_ok" = "yes"; then
2256             AC_CHECK_LIB(z, deflate, ZLIB_LINK=" -lz")
2257         fi
2258
2259         if test "x$ZLIB_LINK" = "x" ; then
2260             if test "$wxUSE_ZLIB" = "sys" ; then
2261                 AC_MSG_ERROR([zlib library not found or too old! Use --with-zlib=builtin to use built-in version])
2262             else
2263                 AC_MSG_WARN([zlib library not found or too old, will use built-in instead])
2264                 wxUSE_ZLIB=builtin
2265             fi
2266         else
2267             dnl we are using the system library
2268             wxUSE_ZLIB=sys
2269         fi
2270     fi
2271 fi
2272
2273 dnl ------------------------------------------------------------------------
2274 dnl Check for png library
2275 dnl ------------------------------------------------------------------------
2276
2277 PNG_LINK=
2278 if test "$wxUSE_LIBPNG" != "no" ; then
2279     AC_DEFINE(wxUSE_LIBPNG)
2280
2281     if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBPNG" = "builtin" ; then
2282         AC_MSG_WARN([wxMGL doesn't work with builtin png library, will use MGL one instead])
2283         wxUSE_LIBPNG=sys
2284     fi
2285
2286     dnl for the check below to have a chance to succeed, we must already have
2287     dnl libz somewhere (don't do this when bulding wxMGL since its libpng
2288     dnl doesn't depend on zlib)
2289     if test "$wxUSE_MGL" != 1 -a "$wxUSE_LIBPNG" = "sys" -a "$wxUSE_ZLIB" != "sys" ; then
2290         AC_MSG_WARN([system png library doesn't work without system zlib, will use built-in instead])
2291         wxUSE_LIBPNG=builtin
2292     fi
2293
2294     if test "$wxUSE_MGL" != 1 ; then
2295         dnl Don't check for libpng when building wxMGL, libmgl contains it
2296         if test "$wxUSE_LIBPNG" = "sys" -o "$wxUSE_LIBPNG" = "yes" ; then
2297             dnl libpng version 0.9 is known to not work, if an even newer
2298             dnl version is required, just bump it up in the test below
2299             AC_CACHE_CHECK([for png.h > 0.90], ac_cv_header_png_h,
2300                 [AC_TRY_RUN(
2301                     dnl png.h defines PNG_LIBPNG_VER=number
2302                     [
2303                         #include <png.h>
2304                         #include <stdio.h>
2305
2306                         int main()
2307                         {
2308                             FILE *f=fopen("conftestval", "w");
2309                             if (!f) exit(1);
2310                             fprintf(f, "%s",
2311                                      PNG_LIBPNG_VER > 90 ? "yes" : "no");
2312                             exit(0);
2313                         }
2314                     ],
2315                     ac_cv_header_png_h=`cat conftestval`,
2316                     ac_cv_header_png_h=no,
2317                     dnl cross-compiling: test (later) if we have any png.h
2318                     unset ac_cv_header_png_h
2319                 )]
2320             )
2321             AC_CHECK_HEADER(png.h,,, [ ])
2322
2323             if test "$ac_cv_header_png_h" = "yes"; then
2324                 AC_CHECK_LIB(png, png_check_sig, PNG_LINK=" -lpng -lz", , [-lz -lm])
2325             fi
2326
2327             if test "x$PNG_LINK" = "x" ; then
2328                 if test "$wxUSE_LIBPNG" = "sys" ; then
2329                     AC_MSG_ERROR([system png library not found or too old! Use --with-libpng=builtin to use built-in version])
2330                 else
2331                     AC_MSG_WARN([system png library not found or too old, will use built-in instead])
2332                     wxUSE_LIBPNG=builtin
2333                 fi
2334             else
2335                 dnl we are using the system library
2336                 wxUSE_LIBPNG=sys
2337             fi
2338         fi
2339     fi
2340
2341     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS png"
2342 fi
2343
2344 dnl ------------------------------------------------------------------------
2345 dnl Check for jpeg library
2346 dnl ------------------------------------------------------------------------
2347
2348 JPEG_LINK=
2349 if test "$wxUSE_LIBJPEG" != "no" ; then
2350     AC_DEFINE(wxUSE_LIBJPEG)
2351
2352     if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBJPEG" = "builtin" ; then
2353         AC_MSG_WARN([wxMGL doesn't work with builtin jpeg library, will use MGL one instead])
2354         wxUSE_LIBJPEG=sys
2355     fi
2356
2357     if test "$wxUSE_MGL" != 1 ; then
2358         dnl Don't check for libjpeg when building wxMGL, libmgl contains it
2359         if test "$wxUSE_LIBJPEG" = "sys" -o "$wxUSE_LIBJPEG" = "yes" ; then
2360             dnl can't use AC_CHECK_HEADER as jconfig.h defines things like
2361             dnl HAVE_STDLIB_H which are already defined and this provokes
2362             dnl a compiler warning which configure considers as an error...
2363             AC_MSG_CHECKING(for jpeglib.h)
2364             AC_CACHE_VAL(ac_cv_header_jpeglib_h,
2365                 AC_TRY_COMPILE(
2366                     [
2367                         #undef HAVE_STDLIB_H
2368                         #include <stdio.h>
2369                         #include <jpeglib.h>
2370                     ],
2371                     [
2372                     ],
2373                     ac_cv_header_jpeglib_h=yes,
2374                     ac_cv_header_jpeglib_h=no
2375                 )
2376             )
2377             AC_MSG_RESULT($ac_cv_header_jpeglib_h)
2378
2379             if test "$ac_cv_header_jpeglib_h" = "yes"; then
2380                 AC_CHECK_LIB(jpeg, jpeg_read_header, JPEG_LINK=" -ljpeg")
2381             fi
2382
2383             if test "x$JPEG_LINK" = "x" ; then
2384                 if test "$wxUSE_LIBJPEG" = "sys" ; then
2385                     AC_MSG_ERROR([system jpeg library not found! Use --with-libjpeg=builtin to use built-in version])
2386                 else
2387                     AC_MSG_WARN([system jpeg library not found, will use built-in instead])
2388                     wxUSE_LIBJPEG=builtin
2389                 fi
2390             else
2391                 dnl we are using the system library
2392                 wxUSE_LIBJPEG=sys
2393
2394                 if test "$wxUSE_MSW" = 1; then
2395                     dnl boolean is defined by the jpeg headers and also by the
2396                     dnl Windows headers of some compilers. This type has been
2397                     dnl renamed in the builtin, so it is only an issue when
2398                     dnl using an external jpeg lib on Windows.
2399                     AC_CHECK_TYPES(
2400                         [boolean],
2401                         [
2402                             AC_CHECK_SIZEOF(
2403                                 [boolean],
2404                                 [],
2405                                 [
2406                                     #undef HAVE_BOOLEAN
2407                                     #include <stdio.h>
2408                                     #include <jpeglib.h>
2409                                 ])
2410                             AC_DEFINE_UNQUOTED(
2411                                 [wxHACK_BOOLEAN],
2412                                 [wxInt`expr 8 \* $ac_cv_sizeof_boolean`])
2413                         ],
2414                         [],
2415                         [#include <windows.h>])
2416                 fi
2417             fi
2418         fi
2419     fi
2420 fi
2421
2422 dnl ------------------------------------------------------------------------
2423 dnl Check for tiff library
2424 dnl ------------------------------------------------------------------------
2425
2426 TIFF_LINK=
2427 TIFF_PREREQ_LINKS=-lm
2428 if test "$wxUSE_LIBTIFF" != "no" ; then
2429     AC_DEFINE(wxUSE_LIBTIFF)
2430
2431     if test "$wxUSE_LIBTIFF" = "sys" -o "$wxUSE_LIBTIFF" = "yes" ; then
2432         dnl libtiff may depend on libjpeg and libz so use them in the test
2433         dnl below or it would fail
2434         if test "$wxUSE_LIBJPEG" = "sys"; then
2435             TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $JPEG_LINK"
2436         fi
2437         if test "$wxUSE_ZLIB" = "sys"; then
2438             TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $ZLIB_LINK"
2439         fi
2440         AC_CHECK_HEADER(tiffio.h,
2441                         [
2442                             AC_CHECK_LIB(tiff, TIFFError,
2443                                          TIFF_LINK=" -ltiff",
2444                                          ,
2445                                          $TIFF_PREREQ_LINKS)
2446                         ],
2447                         [],
2448                         [ ]
2449                        )
2450
2451         if test "x$TIFF_LINK" = "x" ; then
2452             if test "$wxUSE_LIBTIFF" = "sys" ; then
2453                 AC_MSG_ERROR([system tiff library not found! Use --with-libtiff=builtin to use built-in version])
2454             else
2455                 AC_MSG_WARN([system tiff library not found, will use built-in instead])
2456                 wxUSE_LIBTIFF=builtin
2457             fi
2458         else
2459             dnl we are using the system library
2460             wxUSE_LIBTIFF=sys
2461         fi
2462     fi
2463 fi
2464
2465 dnl ------------------------------------------------------------------------
2466 dnl Check for expat libraries
2467 dnl ------------------------------------------------------------------------
2468
2469 if test "$wxUSE_WCHAR_T" != "yes"; then
2470     if test "$wxUSE_EXPAT" != "no"; then
2471         AC_MSG_WARN([wxWidgets requires wchar_t to use expat, disabling])
2472         wxUSE_EXPAT=no
2473     fi
2474     if test "$wxUSE_XML" != "no"; then
2475         AC_MSG_WARN([wxWidgets requires wchar_t to use xml, disabling])
2476         wxUSE_XML=no
2477     fi
2478 fi
2479
2480 if test "$wxUSE_EXPAT" != "no"; then
2481     wxUSE_XML=yes
2482     AC_DEFINE(wxUSE_EXPAT)
2483     AC_DEFINE(wxUSE_XML)
2484
2485     if test "$wxUSE_EXPAT" = "sys" -o "$wxUSE_EXPAT" = "yes" ; then
2486         AC_CHECK_HEADER([expat.h], [found_expat_h=1],, [ ])
2487         if test "x$found_expat_h" = "x1"; then
2488             dnl Expat 1.95.6 comes with broken expat.h:
2489             AC_CACHE_CHECK([if expat.h is valid C++ header],
2490                 wx_cv_expat_is_not_broken,
2491                 [
2492                 AC_LANG_PUSH(C++)
2493                 AC_TRY_COMPILE([#include <expat.h>],[],
2494                     wx_cv_expat_is_not_broken=yes,
2495                     wx_cv_expat_is_not_broken=no
2496                 )
2497                 AC_LANG_POP()
2498                 ]
2499             )
2500             if test "$wx_cv_expat_is_not_broken" = "yes" ; then
2501                 AC_CHECK_LIB(expat, XML_ParserCreate, EXPAT_LINK=" -lexpat")
2502             fi
2503         fi
2504         if test "x$EXPAT_LINK" = "x" ; then
2505             if test "$wxUSE_EXPAT" = "sys" ; then
2506                 AC_MSG_ERROR([system expat library not found! Use --with-expat=builtin to use built-in version])
2507             else
2508                 AC_MSG_WARN([system expat library not found, will use built-in instead])
2509                 wxUSE_EXPAT=builtin
2510             fi
2511         else
2512             dnl we are using the system library
2513             wxUSE_EXPAT=sys
2514         fi
2515     fi
2516     if test "$wxUSE_EXPAT" = "builtin" ; then
2517         dnl Expat needs this:
2518         AC_CONFIG_SUBDIRS([src/expat])
2519     fi
2520 fi
2521
2522
2523 dnl ------------------------------------------------------------------------
2524 dnl Check for libmspack
2525 dnl ------------------------------------------------------------------------
2526
2527 if test "$wxUSE_LIBMSPACK" != "no"; then
2528     AC_CHECK_HEADER([mspack.h], [found_mspack_h=1],, [ ])
2529     if test "x$found_mspack_h" = "x1"; then
2530         AC_CHECK_LIB(mspack, mspack_create_chm_decompressor,
2531                      MSPACK_LINK=" -lmspack")
2532     fi
2533     if test "x$MSPACK_LINK" = "x" ; then
2534         wxUSE_LIBMSPACK=no
2535     fi
2536 fi
2537
2538 if test "$wxUSE_LIBMSPACK" != "no"; then
2539     AC_DEFINE(wxUSE_LIBMSPACK)
2540 fi
2541
2542
2543 dnl ----------------------------------------------------------------
2544 dnl search for toolkit (widget sets)
2545 dnl ----------------------------------------------------------------
2546
2547 AFMINSTALL=
2548 WIN32INSTALL=
2549
2550 TOOLKIT=
2551 TOOLKIT_INCLUDE=
2552 WIDGET_SET=
2553
2554 dnl are we building for a win32 target environment?
2555 dnl If so, setup common stuff needed for both GUI and Base libs.
2556 if test "$USE_WIN32" = 1 ; then
2557     AC_CHECK_HEADER(w32api.h,,, [ ])
2558     AC_CHECK_HEADER(windows.h,,
2559     [
2560         AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
2561     ],
2562     [ ])
2563
2564     dnl --- FIXME: This is still a somewhat random list of libs,
2565     dnl ---        some of them should probably be included conditionally.
2566     LIBS="$LIBS -lwinspool -lwinmm -lshell32 -lcomctl32 -lcomdlg32 -lctl3d32 -ladvapi32 -lwsock32 -lgdi32"
2567
2568     if test "$wxUSE_ACCESSIBILITY" = "yes" ; then
2569         LIBS="$LIBS -loleacc"
2570     fi
2571
2572     case "${host}" in
2573         *-*-cygwin* )
2574             dnl Cygwin doesn't include these by default
2575             LIBS="$LIBS -lkernel32 -luser32"
2576     esac
2577
2578     dnl add extra odbc libs if we have compiled in odbc
2579     if test "$wxUSE_ODBC" = "sys" ; then
2580         wxUSE_ODBC = "yes"
2581     fi
2582     if test "$wxUSE_ODBC" = "yes" ; then
2583         LIBS=" -lodbc32 -lole32 -loleaut32 $LIBS"
2584         AC_DEFINE(wxUSE_ODBC)
2585     fi
2586     dnl We might want to abort here if wxUSE_ODBC="builtin" isn't supported on msw.
2587
2588     dnl This one is still used by some sample makefiles.
2589     RESFLAGS="--include-dir \$(top_srcdir)/include --include-dir \$(top_srcdir)/\$(program_dir) --define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
2590     RESPROGRAMOBJ="\$(PROGRAM)_resources.o"
2591
2592     dnl This lot we export to wx-config.  It must add the relevant
2593     dnl include directories at the point when they can be known.
2594     dnl (but are these (still) required anyway?)
2595     WXCONFIG_RESFLAGS="--define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
2596
2597     dnl install Win32-specific files in "make install"
2598     WIN32INSTALL=win32install
2599
2600     dnl pbt.h is missing on Wine at least
2601     AC_CHECK_HEADER(pbt.h,, [AC_DEFINE(NEED_PBT_H)], [ ])
2602 fi
2603
2604 if test "$wxUSE_GUI" = "yes"; then
2605     USE_GUI=1
2606
2607     GUI_TK_LIBRARY=
2608
2609     WXGTK12=
2610     WXGTK127=
2611     WXGTK20=
2612     WXGPE=
2613
2614     if test "$wxUSE_COCOA" = 1 ; then
2615         if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes"; then
2616             AC_MSG_WARN([Printing not supported under wxCocoa yet, disabled])
2617             wxUSE_PRINTING_ARCHITECTURE=no
2618         fi
2619         if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
2620             AC_MSG_WARN([Drag and Drop not supported under wxCocoa yet, disabled])
2621             wxUSE_DRAG_AND_DROP=no
2622         fi
2623         if test "$wxUSE_DRAGIMAGE" = "yes"; then
2624             AC_MSG_WARN([wxDragImage not supported under wxCocoa yet, disabled])
2625             wxUSE_DRAGIMAGE=no
2626         fi
2627     fi
2628
2629     if test "$wxUSE_MSW" = 1 ; then
2630         TOOLKIT=MSW
2631         GUIDIST=MSW_DIST
2632
2633         dnl -mwindows causes a heap of other default gui libs to be linked in.
2634         case "${host}" in
2635             *-*-mingw32* )
2636                 WXCONFIG_LDFLAGS_GUI="$LDFLAGS -Wl,--subsystem,windows -mwindows"
2637         esac
2638     fi
2639
2640     if test "$wxUSE_GTK" = 1; then
2641         dnl GTK+ test program must be compiled with C compiler
2642         AC_MSG_CHECKING([for GTK+ version])
2643
2644         gtk_version_cached=1
2645         AC_CACHE_VAL(wx_cv_lib_gtk,
2646             [
2647                 dnl stupid GTK+ AM macros produce their own messages, so we
2648                 dnl have to pass to the next line
2649                 gtk_version_cached=0
2650                 AC_MSG_RESULT()
2651
2652                 dnl we must link against lgthread unless the user
2653                 dnl used --disable-threads
2654                 GTK_MODULES=
2655                 if test "$wxUSE_THREADS" = "yes"; then
2656                     GTK_MODULES=gthread
2657                 fi
2658
2659                 dnl detect GTK2
2660                 wx_cv_lib_gtk=
2661                 if test "x$wxGTK_VERSION" != "x1"
2662                 then
2663                     dnl The gthread.pc that ships with Solaris returns '-mt',
2664                     dnl it's correct for Sun CC, but gcc requires '-pthreads'.
2665                     dnl So disable the compile check and remove the -mt below.
2666                     case "${host}" in
2667                         *-*-solaris2* )
2668                             if test "$wxUSE_THREADS" = "yes" -a "$GCC" = yes; then
2669                                 enable_gtktest=no
2670                             fi
2671                     esac
2672
2673                     AM_PATH_GTK_2_0(2.0.0, wx_cv_lib_gtk=2.0, , $GTK_MODULES)
2674
2675                     dnl Solaris also requires -lX11 for static lib
2676                     case "${host}" in
2677                         *-*-solaris2* )
2678                             if test "$wxUSE_SHARED" != "yes"; then
2679                                 GTK_LIBS="$GTK_LIBS -lX11"
2680                             fi
2681                     esac
2682                 fi
2683
2684                 dnl detect GTK1.x
2685                 if test -z "$wx_cv_lib_gtk"; then
2686                     if test "x$wxGTK_VERSION" = "x1" -o "x$wxGTK_VERSION" = "xany" ; then
2687                         AM_PATH_GTK(1.2.7, wx_cv_lib_gtk=1.2.7, , $GTK_MODULES)
2688
2689                         if test -z "$wx_cv_lib_gtk"; then
2690                             AM_PATH_GTK(1.2.3, wx_cv_lib_gtk=1.2.3, , $GTK_MODULES)
2691                         fi
2692                     fi
2693                 fi
2694
2695                 if test -z "$wx_cv_lib_gtk"; then
2696                     dnl looks better in AC_MSG_RESULT
2697                     wx_cv_lib_gtk=none
2698                 else
2699                     dnl we need to cache GTK_CFLAGS and GTK_LIBS for the
2700                     dnl subsequent runs
2701                     wx_cv_cflags_gtk=$GTK_CFLAGS
2702                     wx_cv_libs_gtk=`echo $GTK_LIBS | sed -e 's/ -l[[^ ]]*cairo[[^ ]]*//g'`
2703                 fi
2704             ]
2705         )
2706
2707         dnl if it wasn't cached, the messages from AM_PATH_GTK() above are
2708         dnl enough
2709         if test "$gtk_version_cached" = 1; then
2710             AC_MSG_RESULT($wx_cv_lib_gtk)
2711         fi
2712
2713         case "$wx_cv_lib_gtk" in
2714             2.0)    WXGTK20=1
2715                     TOOLKIT_VERSION=2
2716                     ;;
2717             1.2.7)  WXGTK127=1
2718                     WXGTK12=1
2719                     ;;
2720             1.2.3)  WXGTK12=1
2721                     ;;
2722             *)      AC_MSG_ERROR([
2723 The development files for GTK+ were not found. For GTK+ 2, please
2724 ensure that pkg-config is in the path and that gtk+-2.0.pc is
2725 installed. For GTK+ 1.2 please check that gtk-config is in the path,
2726 and that the version is 1.2.3 or above. Also check that the
2727 libraries returned by 'pkg-config gtk+-2.0 --libs' or 'gtk-config
2728 --libs' are in the LD_LIBRARY_PATH or equivalent.
2729                             ])
2730                     ;;
2731         esac
2732
2733         if test "$WXGTK20" = 1; then
2734             save_CFLAGS="$CFLAGS"
2735             save_LIBS="$LIBS"
2736             CFLAGS="$wx_cv_cflags_gtk $CFLAGS"
2737             LIBS="$LIBS $wx_cv_libs_gtk"
2738
2739             dnl gtk_icon_size_lookup is not available in the GTK+ headers
2740             dnl that have shipped with some versions of Sun's JDS. Not using
2741             dnl AC_CHECK_FUNCS here since it only checks the function exists
2742             dnl in the lib (not the header).
2743             AC_CHECK_DECLS([gtk_icon_size_lookup], [],
2744                            [AC_DEFINE(NEED_GTK_ICON_SIZE_LOOKUP)],
2745                            [#include <gtk/gtk.h>])
2746
2747
2748             dnl test if we have at least GTK+ 2.10:
2749             AC_MSG_CHECKING([if GTK+ is version >= 2.10])
2750             AC_TRY_COMPILE([
2751                             #include <gtk/gtk.h>
2752                            ],
2753                            [
2754                             #if !GTK_CHECK_VERSION(2,10,0)
2755                             Not GTK+ 2.10
2756                             #endif
2757                            ],
2758                            [
2759                             AC_DEFINE(__WXGTK210__)
2760                             AC_DEFINE(__WXGTK26__)
2761                             AC_DEFINE(__WXGTK24__)
2762                             AC_MSG_RESULT([yes])
2763                             ac_wxgtk210=1
2764                            ],
2765                            [
2766                             AC_MSG_RESULT([no])
2767                             ac_wxgtk210=0
2768                            ])
2769
2770             if test "$ac_wxgtk210" = 0; then
2771                 dnl test if we have at least GTK+ 2.6:
2772                 AC_MSG_CHECKING([if GTK+ is version >= 2.6])
2773                 AC_TRY_COMPILE([
2774                                 #include <gtk/gtk.h>
2775                             ],
2776                             [
2777                                 #if !GTK_CHECK_VERSION(2,6,0)
2778                                 Not GTK+ 2.6
2779                                 #endif
2780                             ],
2781                             [
2782                                 AC_DEFINE(__WXGTK26__)
2783                                 AC_DEFINE(__WXGTK24__)
2784                                 AC_MSG_RESULT([yes])
2785                                 ac_wxgtk26=1
2786                             ],
2787                             [
2788                                 AC_MSG_RESULT([no])
2789                                 ac_wxgtk26=0
2790                             ])
2791             fi
2792
2793             if test "$ac_wxgtk26" = 0; then
2794                 dnl test if we have at least GTK+ 2.4:
2795                 AC_MSG_CHECKING([if GTK+ is version >= 2.4])
2796                 AC_TRY_COMPILE([
2797                                 #include <gtk/gtk.h>
2798                             ],
2799                             [
2800                                 #if !GTK_CHECK_VERSION(2,4,0)
2801                                 Not GTK+ 2.4
2802                                 #endif
2803                             ],
2804                             [
2805                                 AC_DEFINE(__WXGTK24__)
2806                                 AC_MSG_RESULT([yes])
2807                             ],
2808                             [
2809                                 AC_MSG_RESULT([no])
2810                             ])
2811             fi
2812
2813             CFLAGS="$save_CFLAGS"
2814             LIBS="$save_LIBS"
2815         else
2816             if test "$wxUSE_UNICODE" = "yes"; then
2817                 AC_MSG_WARN([Unicode configuration not supported with GTK+ 1.x])
2818                 wxUSE_UNICODE=no
2819             fi
2820
2821             dnl test for XIM support in libgdk
2822             AC_CHECK_LIB(gdk, gdk_im_open, AC_DEFINE(HAVE_XIM))
2823
2824             dnl we need poll() in src/gtk1/app.cpp (we know that Darwin doesn't
2825             dnl have it but we do the check for the others)
2826             if test "$USE_DARWIN" != 1; then
2827                 AC_CHECK_FUNCS(poll)
2828             fi
2829         fi
2830
2831         TOOLKIT_INCLUDE="$wx_cv_cflags_gtk"
2832         GUI_TK_LIBRARY="$wx_cv_libs_gtk $GUI_TK_LIBRARY"
2833
2834         AFMINSTALL=afminstall
2835         TOOLKIT=GTK
2836         GUIDIST=GTK_DIST
2837
2838         dnl test for external libxpm if we're configured to use it
2839         if test "$wxUSE_GPE" = "yes"; then
2840             AC_MSG_CHECKING(for gpewidget library)
2841             WX_PATH_FIND_LIBRARIES($SEARCH_LIB,gpewidget)
2842             if test "$ac_find_libraries" != "" ; then
2843                 WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
2844                 dnl -lgpewidget must be before all GTK libs and
2845                 dnl we guess its path from the prefix
2846                 GUI_TK_LIBRARY="-L${prefix}/lib -lgpewidget $GUI_TK_LIBRARY"
2847                 WXGPE=1
2848                 AC_MSG_RESULT([found in $ac_find_libraries])
2849             else
2850                 AC_MSG_RESULT(not found)
2851             fi
2852
2853             dnl AC_MSG_CHECKING(for gpe library)
2854             dnl WX_PATH_FIND_LIBRARIES($SEARCH_LIB,gpe)
2855             dnl if test "$ac_find_libraries" != "" ; then
2856             dnl     WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
2857             dnl     GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lgpe"
2858             dnl     AC_MSG_RESULT(found in $ac_find_libraries)
2859             dnl else
2860             dnl     AC_MSG_RESULT(not found)
2861             dnl fi
2862         fi
2863     fi
2864
2865     if test "$wxUSE_MGL" = 1; then
2866        AC_MSG_CHECKING(for SciTech MGL library)
2867         if test "x$MGL_ROOT" = x ; then
2868             AC_MSG_RESULT(not found)
2869             AC_MSG_ERROR([Cannot find MGL library. Make sure MGL_ROOT is set.])
2870         else
2871             AC_MSG_RESULT($MGL_ROOT)
2872         fi
2873
2874         AC_MSG_CHECKING(for libmgl location)
2875         dnl Find MGL library that we want
2876         dnl FIXME_MGL - test for MGL variants for freebsd etc.;
2877         dnl             and for non-x86 versions
2878         case "${host}" in
2879             *-*-linux* )
2880               dnl glibc.so, glibc are for older versions of MGL,
2881               dnl x86/a, x86/so are used by >= 5.0 R11
2882               if test "x$wxUSE_SHARED" = xyes ; then
2883                   mgl_os_candidates="linux/gcc/x86/so linux/gcc/x86/a linux/gcc/glibc.so linux/gcc/glibc"
2884               else
2885                   mgl_os_candidates="linux/gcc/x86/a linux/gcc/x86/so linux/gcc/glibc linux/gcc/glibc.so"
2886               fi
2887               ;;
2888             *-pc-msdosdjgpp )
2889               mgl_os_candidates="dos32/dj2"
2890               ;;
2891             *)
2892               AC_MSG_ERROR(This system type ${host} is not yet supported by wxMGL.)
2893         esac
2894
2895         mgl_lib_type=""
2896         mgl_os=""
2897
2898         for mgl_os_i in $mgl_os_candidates ; do
2899             if test "x$mgl_os" = x ; then
2900                 if test "$wxUSE_DEBUG_FLAG" = yes ; then
2901                     if test -f $MGL_ROOT/lib/debug/$mgl_os_i/libmgl.a -o \
2902                             -f $MGL_ROOT/lib/debug/$mgl_os_i/libmgl.so; then
2903                         mgl_lib_type=debug
2904                         mgl_os=$mgl_os_i
2905                     fi
2906                 fi
2907                 if test "x$mgl_lib_type" = x ; then
2908                     if test -f $MGL_ROOT/lib/release/$mgl_os_i/libmgl.a -o \
2909                             -f $MGL_ROOT/lib/release/$mgl_os_i/libmgl.so; then
2910                         mgl_lib_type=release
2911                         mgl_os=$mgl_os_i
2912                     fi
2913                 fi
2914             fi
2915         done
2916
2917         if test "x$mgl_os" = x ; then
2918             AC_MSG_RESULT(not found)
2919             AC_MSG_ERROR([Cannot find MGL libraries, make sure they are compiled.])
2920         fi
2921         AC_MSG_RESULT("$MGL_ROOT/lib/$mgl_lib_type/$mgl_os")
2922
2923         wxUSE_UNIVERSAL="yes"
2924
2925         TOOLKIT_INCLUDE="-I$MGL_ROOT/include"
2926         GUI_TK_LIBRARY="-L$MGL_ROOT/lib/$mgl_lib_type/$mgl_os -lmgl -lmglcpp -lpm"
2927
2928         AFMINSTALL=afminstall
2929         TOOLKIT=MGL
2930         GUIDIST=MGL_DIST
2931     fi
2932
2933     if test "$wxUSE_DFB" = 1; then
2934        PKG_PROG_PKG_CONFIG()
2935
2936        PKG_CHECK_MODULES(DIRECTFB,
2937                          [directfb >= 0.9.23],
2938                          [
2939                            wxUSE_UNIVERSAL="yes"
2940                            TOOLKIT_INCLUDE="$DIRECTFB_CFLAGS"
2941                            GUI_TK_LIBRARY="$DIRECTFB_LIBS"
2942                            TOOLKIT=DFB
2943                            GUIDIST=DFB_DIST
2944                          ],
2945                          [
2946                            AC_MSG_ERROR([DirectFB not found.])
2947                          ]
2948                          )
2949     fi
2950
2951     if test "$wxUSE_MICROWIN" = 1; then
2952         AC_MSG_CHECKING(for MicroWindows)
2953         if test "x$MICROWINDOWS" = x ; then
2954             AC_MSG_RESULT(not found)
2955             AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWINDOWS is set.])
2956         else
2957             AC_MSG_RESULT($MICROWINDOWS)
2958         fi
2959
2960         if test -f $MICROWINDOWS/lib/libmwin.a; then
2961             AC_MSG_RESULT(MicroWindows' libraries found.)
2962         else
2963             AC_MSG_ERROR([Cannot find MicroWindows libraries, make sure they are compiled.])
2964         fi
2965
2966         TOOLKIT_INCLUDE="-I$MICROWINDOWS/include"
2967         GUI_TK_LIBRARY="-L$MICROWINDOWS/lib -lmwin -lmwengine -mwfonts -mwdrivers -mwinlib"
2968
2969         wxUSE_UNIVERSAL="yes"
2970
2971         AFMINSTALL=afminstall
2972         TOOLKIT=MICROWIN
2973         GUIDIST=MICROWIN_DIST
2974
2975         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXMSW__ -D__WIN95__ -D__WIN32__ -DMWIN -DMICROWIN_NOCONTROLS -DMICROWIN_TODO=1"
2976     fi
2977
2978     dnl common part of X11 and Motif port checks
2979     if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
2980         dnl use standard macros to check for X headers/libs, this brings
2981         dnl support for the standard configure options --x-includes,
2982         dnl --x-libraries and --no-x
2983         AC_PATH_XTRA
2984
2985         if test "$no_x" = "yes"; then
2986           AC_MSG_ERROR([X11 not found, please use --x-includes and/or --x-libraries options (see config.log for details)])
2987         fi
2988
2989         dnl for some reason AC_PATH_XTRA seems to add -INONE and -LNONE (and
2990         dnl also sometimes -RNONE) to X_CFLAGS and X_LIBS respectively, filter
2991         dnl this junk out
2992         GUI_TK_LIBRARY=`echo $X_LIBS | sed 's/ -LNONE//' | sed 's/ -RNONE//'`
2993         TOOLKIT_INCLUDE=`echo $X_CFLAGS | sed 's/ -INONE//'`
2994         AFMINSTALL=afminstall
2995         COMPILED_X_PROGRAM=0
2996
2997     fi
2998
2999     if test "$wxUSE_X11" = 1; then
3000         if test "$wxUSE_NANOX" = "yes"; then
3001             AC_MSG_CHECKING(for MicroWindows/NanoX distribution)
3002             if test "x$MICROWIN" = x ; then
3003                 AC_MSG_RESULT(not found)
3004                 AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWIN is set.])
3005             else
3006                 AC_MSG_RESULT($MICROWIN)
3007                 AC_DEFINE(wxUSE_NANOX)
3008             fi
3009         fi
3010
3011         if test "$wxUSE_UNICODE" = "yes"; then
3012             PKG_PROG_PKG_CONFIG()
3013
3014             PKG_CHECK_MODULES(PANGOX, pangox,
3015                 [
3016                     CFLAGS="$PANGOX_CFLAGS $CFLAGS"
3017                     CXXFLAGS="$PANGOX_CFLAGS $CXXFLAGS"
3018                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOX_LIBS"
3019                 ],
3020                 [
3021                     AC_MSG_ERROR([pangox library not found, library cannot be compiled in Unicode mode])
3022                 ]
3023             )
3024             PKG_CHECK_MODULES(PANGOFT2, pangoft2,
3025                 [
3026                     CFLAGS="$PANGOFT2_CFLAGS $CFLAGS"
3027                     CXXFLAGS="$PANGOFT2_CFLAGS $CXXFLAGS"
3028                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOFT2_LIBS"
3029                 ],
3030                 [
3031                     AC_MSG_WARN([pangoft2 library not found, library will be compiled without printing support])
3032                     wxUSE_PRINTING_ARCHITECTURE="no"
3033                 ]
3034             )
3035             PKG_CHECK_MODULES(PANGOXFT, pangoxft,
3036                 [
3037                     AC_DEFINE(HAVE_PANGO_XFT)
3038                     CFLAGS="$PANGOXFT_CFLAGS $CFLAGS"
3039                     CXXFLAGS="$PANGOXFT_CFLAGS $CXXFLAGS"
3040                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOXFT_LIBS"
3041                 ],
3042                 [
3043                     AC_MSG_WARN([pangoxft library not found, library will be compiled without anti-aliasing support])
3044                 ]
3045             )
3046             save_LIBS="$LIBS"
3047             LIBS="$LIBS $PANGOX_LIBS"
3048             AC_CHECK_FUNCS([pango_font_family_is_monospace])
3049             LIBS="$save_LIBS"
3050         fi
3051
3052         wxUSE_UNIVERSAL="yes"
3053
3054         if test "$wxUSE_NANOX" = "yes"; then
3055             TOOLKIT_INCLUDE="-I\$(top_srcdir)/include/wx/x11/nanox -I\$(MICROWIN)/src/include $TOOLKIT_INCLUDE"
3056             TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__NANOX__ -DMWPIXEL_FORMAT=MWPF_TRUECOLOR0888 -DHAVE_FILEIO -DHAVE_BMP_SUPPORT=1 -DHAVE_GIF_SUPPORT=1 -DHAVE_PNM_SUPPORT=1 -DHAVE_XPM_SUPPORT=1 -DUNIX=1 -DUSE_EXPOSURE -DSCREEN_HEIGHT=480 -DSCREEN_WIDTH=640 -DSCREEN_DEPTH=4 -DX11=1"
3057             GUI_TK_LIBRARY="$GUI_TK_LIBRARY \$(MICROWIN)/src/lib/libnano-X.a"
3058         else
3059             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lX11"
3060         fi
3061
3062         TOOLKIT=X11
3063         GUIDIST=X11_DIST
3064     fi
3065
3066     if test "$wxUSE_MOTIF" = 1; then
3067         if test "$wxUSE_UNICODE" = "yes"; then
3068             AC_MSG_ERROR([Unicode configuration not supported with Motif])
3069         fi
3070
3071         AC_MSG_CHECKING(for Motif/Lesstif headers)
3072         WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, Xm/Xm.h)
3073         if test "$ac_find_includes" != "" ; then
3074             AC_MSG_RESULT(found in $ac_find_includes)
3075             WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
3076             TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE$ac_path_to_include"
3077         else
3078             save_CFLAGS=$CFLAGS
3079             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3080
3081             AC_TRY_COMPILE(
3082                 [
3083                     #include <Xm/Xm.h>
3084                 ],
3085                 [
3086                     int version;
3087                     version = xmUseVersion;
3088                 ],
3089                 [
3090                     AC_MSG_RESULT(found in default search path)
3091                     COMPILED_X_PROGRAM=1
3092                 ],
3093                 [
3094                     AC_MSG_RESULT(no)
3095                     AC_MSG_ERROR(please set CPPFLAGS to contain the location of Xm/Xm.h)
3096                 ]
3097             )
3098
3099             CFLAGS=$save_CFLAGS
3100         fi
3101
3102
3103         AC_MSG_CHECKING(for Motif/Lesstif library)
3104         WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xm)
3105
3106         if test "x$ac_find_libraries" != "x" ; then
3107             AC_MSG_RESULT(found in $ac_find_libraries)
3108
3109             WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
3110             GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
3111         else
3112             dnl it might happen that we found headers in one of the standard
3113             dnl paths but the libs are elsewhere but still in default (linker)
3114             dnl path -- try to compile a test program to check for this
3115             save_CFLAGS=$CFLAGS
3116             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3117             save_LIBS="$LIBS"
3118             LIBS="$GUI_TK_LIBRARY -lXm -lXmu -lXext -lX11"
3119
3120             AC_TRY_LINK(
3121                 [
3122                     #include <Xm/Xm.h>
3123                 ],
3124                 [
3125                     int version;
3126                     version = xmUseVersion;
3127                 ],
3128                 [
3129                     AC_MSG_RESULT(found in default search path)
3130                     COMPILED_X_PROGRAM=1
3131                 ],
3132                 [
3133                     AC_MSG_RESULT(no)
3134                     AC_MSG_ERROR(please set LDFLAGS to contain the location of libXm)
3135                 ]
3136             )
3137
3138             CFLAGS=$save_CFLAGS
3139             LIBS="$save_LIBS"
3140         fi
3141
3142         AC_MSG_CHECKING([if we need -lXp and/or -lSM -lICE])
3143         libp_link=""
3144         libsm_ice_link=""
3145         libs_found=0
3146         for libp in "" " -lXp"; do
3147             if test "$libs_found" = "0"; then
3148                 for libsm_ice in "" " -lSM -lICE"; do
3149                     if test "$libs_found" = "0"; then
3150                         save_LIBS="$LIBS"
3151                         LIBS="$GUI_TK_LIBRARY -lXm ${libp} -lXmu -lXext -lXt${libsm_ice} -lX11"
3152                         save_CFLAGS=$CFLAGS
3153                         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3154
3155                         AC_TRY_LINK(
3156                             [
3157                                 #include <Xm/Xm.h>
3158                                 #include <Xm/List.h>
3159                             ],
3160                             [
3161                                 XmString string = NULL;
3162                                 Widget w = NULL;
3163                                 int position = 0;
3164                                 XmListAddItem(w, string, position);
3165                             ],
3166                             [
3167                                 libp_link="$libp"
3168                                 libsm_ice_link="$libsm_ice"
3169                                 AC_MSG_RESULT(
3170                                     [need${libp_link}${libsm_ice_link}])
3171                                 libs_found=1
3172                             ], []
3173                         )
3174
3175                         LIBS="$save_LIBS"
3176                         CFLAGS=$save_CFLAGS
3177                     fi
3178                 done
3179             fi
3180         done
3181
3182         if test "$libs_found" = "0"; then
3183             AC_MSG_RESULT([can't find the right libraries])
3184             AC_MSG_ERROR([can't link a simple motif program])
3185         fi
3186
3187         dnl this seems to be needed under IRIX and shouldn't do any harm
3188         dnl elsewhere
3189         AC_CHECK_LIB(Sgm, [SgCreateList], [libsgm_link=" -lSgm"])
3190
3191         save_CFLAGS=$CFLAGS
3192         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3193
3194         AC_CACHE_CHECK([for Motif 2],
3195             wx_cv_lib_motif2,
3196             AC_TRY_COMPILE([
3197                             #include <Xm/Xm.h>
3198                            ],
3199                            [
3200                             #if XmVersion < 2000
3201                             Not Motif 2
3202                             #endif
3203                            ],
3204                            wx_cv_lib_motif2="yes",
3205                            wx_cv_lib_motif2="no"))
3206         if test "$wx_cv_lib_motif2" = "yes"; then
3207             AC_DEFINE(__WXMOTIF20__,1)
3208         else
3209             AC_DEFINE(__WXMOTIF20__,0)
3210         fi
3211
3212         AC_CACHE_CHECK([whether Motif is Lesstif],
3213             wx_cv_lib_lesstif,
3214             AC_TRY_COMPILE([
3215                             #include <Xm/Xm.h>
3216                            ],
3217                            [
3218                             #if !defined(LesstifVersion) || LesstifVersion <= 0
3219                             Not Lesstif
3220                             #endif
3221                            ],
3222                            wx_cv_lib_lesstif="yes",
3223                            wx_cv_lib_lesstif="no")
3224         )
3225         if test "$wx_cv_lib_lesstif" = "yes"; then
3226             AC_DEFINE(__WXLESSTIF__,1)
3227         else
3228             AC_DEFINE(__WXLESSTIF__,0)
3229         fi
3230
3231         CFLAGS=$save_CFLAGS
3232
3233         GUI_TK_LIBRARY="$GUI_TK_LIBRARY${libsgm_link} -lXm${libp_link} -lXmu -lXext -lXt${libsm_ice_link} -lX11"
3234         TOOLKIT=MOTIF
3235         GUIDIST=MOTIF_DIST
3236     fi
3237
3238     dnl more tests common to X11 and Motif:
3239     if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
3240         dnl test for external libxpm if we're configured to use it
3241         if test "$wxUSE_LIBXPM" = "sys"; then
3242             AC_MSG_CHECKING(for Xpm library)
3243             WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
3244             if test "$ac_find_libraries" != "" ; then
3245                 WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
3246                 GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
3247                 AC_MSG_RESULT(found in $ac_find_libraries)
3248
3249                 AC_CACHE_CHECK([for X11/xpm.h],
3250                     wx_cv_x11_xpm_h,
3251                     [
3252                         save_CFLAGS=$CFLAGS
3253                         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3254
3255                         AC_TRY_COMPILE(
3256                             [
3257                                 #include <X11/xpm.h>
3258                             ],
3259                             [
3260                                 int version;
3261                                 version = XpmLibraryVersion();
3262                             ],
3263                             wx_cv_x11_xpm_h=yes,
3264                             wx_cv_x11_xpm_h=no
3265                         )
3266
3267                         CFLAGS=$save_CFLAGS
3268                     ]
3269                 )
3270
3271                 if test $wx_cv_x11_xpm_h = "yes"; then
3272                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXpm"
3273                     AC_DEFINE(wxHAVE_LIB_XPM)
3274                 else
3275                     AC_MSG_WARN([built-in less efficient XPM decoder will be used])
3276                 fi
3277             fi
3278
3279         fi
3280
3281         dnl XShapeQueryExtension checks: first the library, then prototype
3282         AC_CHECK_LIB([Xext], [XShapeQueryExtension],
3283                      [
3284                       GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXext"
3285                       wxHAVE_XEXT_LIB=1
3286                      ],
3287                      [], [$GUI_TK_LIBRARY -lX11])
3288
3289         if test "$wxHAVE_XEXT_LIB" = 1; then
3290             save_CFLAGS="$CFLAGS"
3291             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3292
3293             AC_MSG_CHECKING([for X11/extensions/shape.h])
3294             AC_TRY_COMPILE([
3295                             #include <X11/Xlib.h>
3296                             #include <X11/extensions/shape.h>
3297                            ],
3298                            [
3299                             int dummy1, dummy2;
3300                             XShapeQueryExtension((Display*)NULL,
3301                                                  (int*)NULL, (int*)NULL);
3302                            ],
3303                            [
3304                             AC_DEFINE(HAVE_XSHAPE)
3305                             AC_MSG_RESULT([found])
3306                            ],
3307                            [
3308                             AC_MSG_RESULT([not found])
3309                            ])
3310             CFLAGS="$save_CFLAGS"
3311
3312         fi
3313     fi
3314
3315     if test "$wxUSE_MAC" = 1; then
3316         AC_MSG_CHECKING([for compiler syntax to enable Pascal strings])
3317         if test "$GCC" = yes; then
3318             AC_MSG_RESULT([gcc])
3319             CPPFLAGS_PASCAL="-fpascal-strings"
3320         elif test "`echo $CXX | sed -e 's@.*/@@'`" = "xlC"; then
3321             AC_MSG_RESULT([xlc])
3322             CPPFLAGS_PASCAL="-qmacpstr"
3323         else
3324             AC_MSG_RESULT([none])
3325         fi
3326
3327         if test "x$wxUSE_UNIX" = "xyes"; then
3328             CPPFLAGS="$CPPFLAGS_PASCAL -I\${top_srcdir}/src/mac/carbon/morefilex -I/Developer/Headers/FlatCarbon $CPPFLAGS"
3329         else
3330             dnl platform.h needs TARGET_CARBON before setup.h
3331             CPPFLAGS="$CPPFLAGS_PASCAL -I\${top_srcdir}/src/mac/carbon/morefilex -DTARGET_CARBON $CPPFLAGS"
3332         fi
3333
3334         TOOLKIT=MAC
3335         dnl we can't call this MAC_DIST or autoconf thinks its a macro
3336         GUIDIST=MACX_DIST
3337         dnl wxMac version of wxBase and wxCocoa or wxBase-only built on Darwin
3338         dnl are different, so they need different names:
3339         WXBASEPORT="_carbon"
3340     fi
3341
3342     if test "$wxUSE_COCOA" = 1; then
3343         TOOLKIT=COCOA
3344         GUIDIST=COCOA_DIST
3345     fi
3346
3347     if test "$wxUSE_PM" = 1; then
3348         TOOLKIT=PM
3349         GUIDIST=PM_DIST
3350         AC_CACHE_CHECK([for type SPBCDATA],
3351             wx_cv_spbcdata,
3352             [
3353                 AC_TRY_COMPILE(
3354                     [
3355                         #define INCL_PM
3356                         #include <os2.h>
3357                     ],
3358                     [
3359                         SPBCDATA test;
3360                     ],
3361                     wx_cv_spbcdata=yes,
3362                     wx_cv_spbcdata=no
3363                 )
3364             ]
3365         )
3366
3367         if test $wx_cv_spbcdata = "yes"; then
3368             AC_DEFINE(HAVE_SPBCDATA)
3369         fi
3370     fi
3371
3372     dnl the name of the directory where the files for this toolkit live
3373     if test "$TOOLKIT" = "PM" ; then
3374         TOOLKIT_DIR="os2"
3375     else
3376         TOOLKIT_DIR=`echo ${TOOLKIT} | tr "[[A-Z]]" "[[a-z]]"`
3377     fi
3378
3379     if test "$wxUSE_UNIVERSAL" = "yes"; then
3380         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXUNIVERSAL__"
3381         WIDGET_SET=univ
3382     fi
3383
3384     dnl distribute samples/demos/utils with GUI versions
3385     GUIDIST="${GUIDIST} SAMPLES_DIST DEMOS_DIST UTILS_DIST MISC_DIST"
3386     DISTDIR="wx\$(TOOLKIT)"
3387 else
3388     USE_GUI=0
3389
3390     dnl this doesn't quite work right for wxBase, but the places
3391     dnl where it is wrong aren't fatal (yet) though.
3392     TOOLKIT_DIR="base"
3393
3394     dnl the sources, their dependenices and the headers
3395     if test "$USE_WIN32" = 1 ; then
3396         dnl yes, the toolkit for wxBase on win32 is actually MSW
3397         dnl wxBase on unix does not need a 'TOOLKIT' defined.
3398         TOOLKIT="MSW"
3399     fi
3400
3401     dnl distribute only wxBase sources/headers
3402     GUIDIST="BASE_DIST"
3403     DISTDIR="wxBase"
3404 fi
3405
3406
3407 dnl ---------------------------------------------------------------------------
3408 dnl UTF-8 support
3409 dnl ---------------------------------------------------------------------------
3410
3411 dnl If UTF-8 support wasn't explicitly enabled or disabled, enable it only
3412 dnl for ports where it makes sense by default (GTK+, DirectFB):
3413 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_UTF8" = "auto" ; then
3414     if test "$TOOLKIT" = "DFB" ; then
3415         wxUSE_UNICODE_UTF8=yes
3416     elif test "$TOOLKIT" = "GTK" -a "$WXGTK20" = "1" ; then
3417         wxUSE_UNICODE_UTF8=yes
3418     elif test "$USE_OS2" = "1" ; then
3419         dnl wide char support is quite incomplete in libc;
3420         dnl UTF-8 might actually work when evaluating/setting
3421         dnl code pages correctly, even for ports other than GTK20.
3422         wxUSE_UNICODE_UTF8=yes
3423     else
3424         wxUSE_UNICODE_UTF8=no
3425     fi
3426 fi
3427
3428 dnl ---------------------------------------------------------------------------
3429 dnl Optional libraries included when system library is not used
3430 dnl ---------------------------------------------------------------------------
3431
3432 dnl do this after test for X11 above so that we have a chance of finding Xlib.h
3433 if test "$wxUSE_GUI" = "yes"; then
3434     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_PM" != 1; then
3435         dnl defines HAVE_X11_XKBLIB_H
3436         AC_CHECK_HEADER(X11/Xlib.h,,, [ ])
3437         AC_CHECK_HEADER([X11/XKBlib.h],,,
3438                          [
3439                           #if HAVE_X11_XLIB_H
3440                             #include <X11/Xlib.h>
3441                           #endif
3442                          ])
3443     fi
3444 fi
3445
3446
3447 dnl ----------------------------------------------------------------
3448 dnl iODBC support
3449 dnl ----------------------------------------------------------------
3450
3451 IODBC_C_SRC=""
3452
3453
3454 dnl ODBC is handled separately for MSW
3455 if test "$TOOLKIT" != "MSW" ; then
3456
3457     if test "$wxUSE_ODBC" = "sys" -o "$wxUSE_ODBC" = "yes" ; then
3458         dnl This is not ideal we really ough to use the unixodbc-config
3459         dnl  or iodbc-config if they exist.
3460
3461         AC_CHECK_HEADER([sql.h], [found_sql_h=1],, [ ])
3462         if test "x$found_sql_h" = "x1" ; then
3463             AC_CHECK_LIB(iodbc, SQLAllocEnv, ODBC_LINK=" -liodbc",
3464             [
3465                 AC_CHECK_LIB(unixodbc, SQLAllocEnv, ODBC_LINK=" -lunixodbc",
3466                 [
3467                     AC_CHECK_LIB(odbc, SQLAllocEnv, ODBC_LINK=" -lodbc")
3468                 ])
3469             ])
3470         fi
3471         if test "x$ODBC_LINK" = "x" ; then
3472             if test "$wxUSE_ODBC" = "sys" ; then
3473                 AC_MSG_ERROR([system ODBC library not found! Use --with-odbc=builtin to use built-in version])
3474             else
3475                 AC_MSG_WARN([system ODBC library not found, will use built-in instead])
3476                 wxUSE_ODBC=builtin
3477             fi
3478         else
3479             dnl we are using the system library
3480             wxUSE_ODBC=sys
3481         fi
3482     fi
3483
3484     if test "$wxUSE_ODBC" = "builtin" ; then
3485         AC_DEFINE(wxUSE_BUILTIN_IODBC)
3486     fi
3487 fi
3488
3489 if test "$wxUSE_ODBC" != "no" ; then
3490     AC_DEFINE(wxUSE_ODBC)
3491     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS db"
3492
3493     dnl is this still necessary?
3494     WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_IODBC_"
3495 fi
3496
3497 dnl ---------------------------------------------------------------------------
3498 dnl wxDisplay Sanity checks
3499 dnl ---------------------------------------------------------------------------
3500
3501 if test "$wxUSE_DISPLAY" = "yes"; then
3502 dnl ---------------------------------------------------------------------------
3503 dnl Xinerama (for unix ) - Brian Victor
3504 dnl ---------------------------------------------------------------------------
3505     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1; then
3506         AC_MSG_CHECKING([for Xinerama])
3507         WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],Xinerama)
3508         if test "$ac_find_libraries" != "" ; then
3509             WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3510             if test "$ac_path_to_link" != " -L/usr/lib" ; then
3511                 LDFLAGS="$LDFLAGS $ac_path_to_link"
3512             fi
3513             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXinerama"
3514             AC_MSG_RESULT([yes])
3515
3516             AC_MSG_CHECKING([for Xxf86vm extension])
3517             WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],Xxf86vm)
3518             if test "$ac_find_libraries" != "" ; then
3519                 AC_MSG_RESULT([yes])
3520                 AC_CHECK_HEADER([X11/extensions/xf86vmode.h],
3521                                  [
3522                                   GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXxf86vm"
3523                                  ],
3524                                  [],
3525                                  [
3526                                       #if HAVE_X11_XLIB_H
3527                                         #include <X11/Xlib.h>
3528                                       #endif
3529                                  ])
3530             else
3531                 AC_MSG_RESULT([no])
3532             fi
3533
3534         else
3535             AC_MSG_RESULT([no])
3536             AC_MSG_WARN([Xinerama not found; disabling wxDisplay])
3537             wxUSE_DISPLAY="no"
3538         fi
3539     elif test "$wxUSE_MSW" = 1; then
3540 dnl ---------------------------------------------------------------------------
3541 dnl DirectDraw for MSW - optionally used by WxDisplay.
3542 dnl ---------------------------------------------------------------------------
3543         AC_CHECK_HEADER([ddraw.h], [], [], [#include <windows.h>])
3544     fi
3545 fi
3546
3547 dnl ---------------------------------------------------------------------------
3548 dnl X11 session management
3549 dnl ---------------------------------------------------------------------------
3550 if test "$wxUSE_DETECT_SM" = "yes"; then
3551     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1; then
3552         AC_MSG_CHECKING([for -lSM - X11 session management])
3553         WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],SM)
3554         if test "$ac_find_libraries" != "" ; then
3555             WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3556             if test "$ac_path_to_link" != " -L/usr/lib" ; then
3557                 LDFLAGS="$LDFLAGS $ac_path_to_link"
3558             fi
3559             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lSM"
3560             AC_MSG_RESULT([yes])
3561         else
3562             AC_MSG_RESULT([no])
3563             AC_MSG_WARN([libSM not found; disabling session management detection])
3564             wxUSE_DETECT_SM="no"
3565         fi
3566     else
3567         wxUSE_DETECT_SM="no"
3568     fi
3569 fi
3570
3571
3572 dnl ---------------------------------------------------------------------------
3573 dnl OpenGL libraries
3574 dnl ---------------------------------------------------------------------------
3575
3576 USE_OPENGL=0
3577 if test "$wxUSE_OPENGL" = "yes"; then
3578     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = "1"; then
3579         AC_MSG_WARN([wxGLCanvas not implemented for this port, library will be compiled without it.])
3580         wxUSE_OPENGL="no"
3581     elif test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = "1"; then
3582         OPENGL_LIBS="-framework OpenGL -framework AGL"
3583     elif test "$wxUSE_MSW" = 1; then
3584         OPENGL_LIBS="-lopengl32 -lglu32"
3585     else
3586         dnl adjust CPPFLAGS to include GL/gl.h location if necessary
3587         dnl (/opt/graphics/OpenGL is for HP-UX systems, bug 925307)
3588         AC_MSG_CHECKING([for OpenGL headers])
3589         WX_PATH_FIND_INCLUDES([$SEARCH_INCLUDE /opt/graphics/OpenGL/include], GL/gl.h)
3590         if test "$ac_find_includes" != "" ; then
3591             AC_MSG_RESULT(found in $ac_find_includes)
3592             WX_INCLUDE_PATH_EXIST($ac_find_includes, $CPPFLAGS)
3593             CPPFLAGS="$ac_path_to_include $CPPFLAGS"
3594         else
3595             AC_MSG_RESULT([not found])
3596         fi
3597
3598         AC_CHECK_HEADER(GL/gl.h, [
3599             AC_CHECK_HEADER(GL/glu.h, [
3600                 found_gl=0
3601
3602                 AC_MSG_CHECKING([for -lGL])
3603                 WX_PATH_FIND_LIBRARIES([$SEARCH_LIB /opt/graphics/OpenGL/lib],GL)
3604                 if test "$ac_find_libraries" != "" ; then
3605                     AC_MSG_RESULT([found in $ac_find_libraries])
3606
3607                     WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3608                     if test "$ac_path_to_link" != " -L/usr/lib" ; then
3609                         LDFLAGS_GL="$ac_path_to_link"
3610                     fi
3611
3612                     dnl don't suppose that libGL and libGLU are always in the
3613                     dnl same directory -- this is not true for some common
3614                     dnl distributions
3615                     AC_MSG_CHECKING([for -lGLU])
3616                     WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],GLU)
3617                     if test "$ac_find_libraries" != "" ; then
3618                         WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3619                         if test "$ac_path_to_link" != " -L/usr/lib" -a \
3620                                     "$ac_path_to_link" != "$LDFLAGS_GL"; then
3621                             LDFLAGS_GL="$LDFLAGS_GL$ac_path_to_link"
3622                         fi
3623
3624                         found_gl=1
3625                         OPENGL_LIBS="-lGL -lGLU"
3626                         AC_MSG_RESULT([yes])
3627                     else
3628                         AC_MSG_RESULT([no])
3629                     fi
3630                 else
3631                     AC_MSG_RESULT([no])
3632                 fi
3633
3634                 if test "$found_gl" != 1; then
3635                     AC_MSG_CHECKING([for -lMesaGL])
3636                     WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],MesaGL)
3637                     if test "$ac_find_libraries" != "" ; then
3638                         WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3639                         LDFLAGS_GL="$LDFLAGS$ac_path_to_link"
3640                         OPENGL_LIBS="-lMesaGL -lMesaGLU"
3641                         AC_MSG_RESULT([yes])
3642                     else
3643                         AC_MSG_RESULT([no])
3644                     fi
3645                 fi
3646             ])
3647         ],
3648         [],
3649         [ ])
3650
3651         if test "x$OPENGL_LIBS" = "x"; then
3652             dnl it should be an error and not a warning because OpenGL is not on
3653             dnl by default and so if it had been explicitly requested, we
3654             dnl shouldn't just fall back to compiling the library without it
3655             AC_MSG_ERROR(OpenGL libraries not available)
3656         fi
3657     fi
3658
3659     if test "$wxUSE_OPENGL" = "yes"; then
3660         USE_OPENGL=1
3661         AC_DEFINE(wxUSE_OPENGL)
3662         AC_DEFINE(wxUSE_GLCANVAS)
3663         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS opengl opengl/cube opengl/penguin opengl/isosurf"
3664     fi
3665 fi
3666
3667
3668 dnl the symbol which allows conditional compilation for the given toolkit
3669 if test -n "$TOOLKIT" ; then
3670     TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WX${TOOLKIT}__"
3671 fi
3672
3673
3674 dnl --- the marker for quick search, leave it here: SHARED_LIB_SETUP ---
3675
3676 if test "$wxUSE_SHARED" = "yes"; then
3677     case "${host}" in
3678       *-pc-msdosdjgpp )
3679         dnl only static for now
3680         wxUSE_SHARED=no
3681         AC_MSG_WARN([Host system doesn't support shared libraries, disabling])
3682       ;;
3683     esac
3684 fi
3685
3686 if test "$wxUSE_SHARED" = "yes"; then
3687
3688     dnl use versioned symbols if available on the platform
3689     WX_VERSIONED_SYMBOLS([\$(wx_top_builddir)/version-script])
3690
3691     dnl test for GCC's visibility support (sets CFLAGS_VISIBILITY, which is
3692     dnl assigned to CFLAGS and CXXFLAGS below)
3693     WX_VISIBILITY
3694
3695     dnl test for Sun CC which can be used under both Solaris and Linux
3696     if test "x$SUNCXX" = xyes; then
3697         SAMPLES_RPATH_FLAG="-R\$(wx_top_builddir)/lib"
3698         WXCONFIG_RPATH="-R\$libdir"
3699     else
3700     case "${host}" in
3701       *-*-linux* | *-*-gnu* )
3702         SAMPLES_RPATH_FLAG="-Wl,-rpath,\$(wx_top_builddir)/lib"
3703         WXCONFIG_RPATH="-Wl,-rpath,\$libdir"
3704         ;;
3705
3706       *-*-solaris2* )
3707         dnl here we know that Sun CC is not used as we tested for it above,
3708         dnl hence we must be using gcc
3709
3710         dnl newer versions of gcc need -isystem to compile X headers on
3711         dnl Solaris (which use old style C syntax)
3712         CPPFLAGS="-isystem /usr/openwin/include $CPPFLAGS"
3713
3714         dnl gcc may use Sun's ld, in which case -rpath gives a confusing
3715         dnl error message. We have to try both -Wl,-rpath and -Wl,-R:
3716         saveLdflags="$LDFLAGS"
3717         LDFLAGS="$saveLdflags -Wl,-rpath,/"
3718         AC_MSG_CHECKING([if the linker accepts -rpath])
3719         AC_TRY_LINK(
3720             [],[],
3721             [
3722                 AC_MSG_RESULT([yes])
3723                 SAMPLES_RPATH_FLAG="-Wl,-rpath,\$(wx_top_builddir)/lib"
3724                 WXCONFIG_RPATH="-Wl,-rpath,\$libdir"
3725             ],[
3726                 AC_MSG_RESULT([no])
3727                 AC_MSG_CHECKING([if the linker accepts -R])
3728                 LDFLAGS="$saveLdflags -Wl,-R,/"
3729                 AC_TRY_LINK(
3730                     [],[],
3731                     [
3732                         AC_MSG_RESULT([yes])
3733                         SAMPLES_RPATH_FLAG="-Wl,-R,\$(wx_top_builddir)/lib"
3734                         WXCONFIG_RPATH="-Wl,-R,\$libdir"
3735                     ],[
3736                         AC_MSG_RESULT([no])
3737                     ])
3738             ])
3739         LDFLAGS="$saveLdflags"
3740       ;;
3741
3742       *-*-darwin* )
3743         install_name_tool=`which install_name_tool`
3744         if test "$install_name_tool" -a -x "$install_name_tool"; then
3745             SAMPLES_RPATH_POSTLINK="\$(wx_top_builddir)/change-install-names \$(LIBDIRNAME) \$(prefix) \$@"
3746             cat <<EOF >change-install-names
3747 #!/bin/sh
3748 libnames=\`cd \${1} ; ls -1 | grep '\.[[0-9]][[0-9]]*\.dylib\$'\`
3749 inst_cmd="install_name_tool "
3750 for i in \${libnames} ; do
3751     inst_cmd="\${inst_cmd} -change \${2}/lib/\${i} \${1}/\${i}"
3752 done
3753 \${inst_cmd} \${3}
3754 EOF
3755             chmod +x change-install-names
3756         fi
3757       ;;
3758
3759       *-*-cygwin* | *-*-mingw32* )
3760         dnl this one shouldn't be used for the library build so put it in a
3761         dnl separate variable from WXCONFIG_CPPFLAGS
3762         WXCONFIG_ONLY_CPPFLAGS="$WXCONFIG_ONLY_CPPFLAGS -DWXUSINGDLL"
3763         ;;
3764
3765       *-*-hpux* )
3766         SAMPLES_RPATH_FLAG="-Wl,+b,\$(wx_top_builddir)/lib"
3767         WXCONFIG_RPATH="-Wl,+b,\$libdir"
3768         ;;
3769
3770     esac
3771     fi
3772
3773     if test $wxUSE_RPATH = "no"; then
3774         SAMPLES_RPATH_FLAG=''
3775         SAMPLES_RPATH_POSTLINK=''
3776         WXCONFIG_RPATH=''
3777     fi
3778
3779     SHARED=1
3780
3781 else
3782
3783     config_linkage_component="-static"
3784     SHARED=0
3785
3786 fi
3787
3788
3789 UNICODE=0
3790 lib_unicode_suffix=
3791 WX_CHARTYPE="ansi"
3792 if test "$wxUSE_UNICODE" = "yes"; then
3793     lib_unicode_suffix=u
3794     WX_CHARTYPE="unicode"
3795     UNICODE=1
3796 fi
3797
3798 lib_debug_suffix=
3799 WX_DEBUGTYPE="release"
3800 DEBUG_FLAG=0
3801 if test "$wxUSE_DEBUG_FLAG" = "yes"; then
3802     lib_debug_suffix=d
3803     WX_DEBUGTYPE="debug"
3804     DEBUG_FLAG=1
3805 fi
3806
3807 WX_FLAVOUR=${WX_FLAVOUR:+-$WX_FLAVOUR}
3808 WX_LIB_FLAVOUR=`echo $WX_FLAVOUR | tr '-' '_'`
3809
3810 DEBUG_INFO=0
3811 if test "$wxUSE_DEBUG_INFO" = "yes"; then
3812     DEBUG_INFO=1
3813 fi
3814
3815 WX_VERSION_TAG=`echo WX${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}_${WX_RELEASE} | tr "[[a-z]]" "[[A-Z]]"`
3816
3817 TOOLCHAIN_NAME="${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}"
3818
3819 TOOLCHAIN_FULLNAME="${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}-${WX_CHARTYPE}-${WX_DEBUGTYPE}${config_linkage_component}-${WX_RELEASE}${WX_FLAVOUR}"
3820
3821 if test "$cross_compiling" = "yes"; then
3822     HOST_SUFFIX="-$host_alias"
3823     TOOLCHAIN_NAME="$TOOLCHAIN_NAME$HOST_SUFFIX"
3824     TOOLCHAIN_FULLNAME="${host_alias}-$TOOLCHAIN_FULLNAME"
3825 fi
3826
3827 dnl library link name
3828 dnl These just save us from exporting lib_{unicode,debug,flavour}_suffix.
3829 dnl If we ever need to do that, we won't need to keep these.
3830 WX_LIBRARY_BASENAME_NOGUI="wx_base${WXBASEPORT}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}"
3831 if test "${TOOLKIT_DIR}" = "os2"; then
3832     WX_LIBRARY_BASENAME_GUI="wx_pm${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}"
3833 else
3834     WX_LIBRARY_BASENAME_GUI="wx_${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}"
3835 fi
3836
3837
3838
3839 if test "$wxUSE_COCOA" = 1; then
3840     AC_LANG_SAVE
3841     AC_WX_LANG_OBJECTIVEC
3842 dnl Recent AppKit/NSEvent.h include parts of IOKit which eventually
3843 dnl gets IOKit/graphics/IOGraphicsTypes.h included which typedefs
3844 dnl Point but only if MacTypes.h was not included first.  Of course,
3845 dnl if MacTypes.h is included later then you're screwed when it
3846 dnl tries to typedef Point.  Defining __Point__ will cause IOGraphicsTypes.h
3847 dnl to not typedef Point and thus fix the problem.
3848     AC_MSG_CHECKING([if AppKit/NSEvent.h conflicts with CoreFoundation])
3849     AC_TRY_COMPILE([#include <AppKit/NSEvent.h>
3850 #include <CoreFoundation/CoreFoundation.h>
3851         ],[],
3852         [AC_MSG_RESULT([no])],
3853         [AC_MSG_RESULT([yes])
3854         AC_MSG_CHECKING([if defining __Point__ will fix it])
3855         AC_TRY_COMPILE([#define __Point__ 1
3856 #include <AppKit/NSEvent.h>
3857 #include <CoreFoundation/CoreFoundation.h>
3858             ],[],
3859             [AC_MSG_RESULT([yes])
3860             AC_DEFINE(__Point__)
3861             ],
3862             [AC_MSG_FAILURE([no])]
3863         )]
3864     )
3865     AC_LANG_RESTORE
3866 fi
3867
3868 if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1; then
3869     dnl base name of the resource file for wxMac must be the same
3870     dnl as library installation base name (-install_name)
3871     WX_RESOURCES_MACOSX_ASCII="libwx_${TOOLCHAIN_NAME}.${wx_release_number}.r"
3872     WX_RESOURCES_MACOSX_DATA="libwx_${TOOLCHAIN_NAME}.${wx_release_number}.rsrc"
3873
3874     dnl add the resources target for wxMac
3875     LIBWXMACRES="\$(wx_top_builddir)/lib/${WX_RESOURCES_MACOSX_ASCII}"
3876
3877     AC_CHECK_PROG(REZ, Rez, Rez, /Developer/Tools/Rez)
3878     AC_CHECK_PROG(DEREZ, DeRez, DeRez, /Developer/Tools/DeRez)
3879     AC_CHECK_PROG(SETFILE, SetFile, SetFile, /Developer/Tools/SetFile)
3880
3881     MACSETFILE="\$(SETFILE)"
3882
3883     dnl resources are bundled both with shared library and applications
3884     dnl since the carb resource *must* be included in the application
3885     if test "$wxUSE_MAC" = 1; then
3886         POSTLINK_COMMAND="\$(REZ) -d __DARWIN__ -t APPL Carbon.r -o"
3887         RESCOMP="$REZ"
3888         WXCONFIG_RESFLAGS="-d __DARWIN__ -t APPL Carbon.r -o"
3889     else
3890         POSTLINK_COMMAND="echo -n | \$(REZ) -d __DARWIN__ -t APPL ${LIBWXMACRES}"
3891         RESCOMP="echo -n \| $REZ"
3892         WXCONFIG_RESFLAGS="-d __DARWIN__ -t APPL \$libdir/$WX_RESOURCES_MACOSX_ASCII"
3893     fi
3894
3895 else
3896     dnl default value is to (silently) do nothing in the makefile
3897     MACSETFILE="@true"
3898
3899     if test "$wxUSE_PM" = 1; then
3900         RESCOMP="emxbind"
3901         WXCONFIG_RESFLAGS="-ep"
3902
3903         dnl Is this one really used anywhere for pm?
3904         POSTLINK_COMMAND="$RESCOMP $WXCONFIG_RESFLAGS"
3905     else
3906         POSTLINK_COMMAND="@true"
3907     fi
3908
3909 fi
3910
3911
3912 dnl ---------------------------------------------------------------------------
3913 dnl Checks for typedefs
3914 dnl ---------------------------------------------------------------------------
3915
3916 dnl   defines mode_t if not already defined
3917 AC_TYPE_MODE_T
3918 dnl   defines off_t if not already defined
3919 AC_TYPE_OFF_T
3920 dnl   defines pid_t if not already defined
3921 AC_TYPE_PID_T
3922 dnl   defines size_t if not already defined
3923 AC_TYPE_SIZE_T
3924 dnl   defines uid_t and gid_t if not already defined
3925 AC_TYPE_UID_T
3926
3927 dnl sets HAVE_SSIZE_T if ssize_t is defined
3928 AC_CHECK_TYPES(ssize_t)
3929
3930 dnl check what exactly size_t is on this machine - this is necessary to avoid
3931 dnl ambiguous overloads in several places, notably wx/string.h and wx/array.h
3932 AC_LANG_PUSH(C++) dnl tests below use overloaded functions and so need C++
3933 AC_CACHE_CHECK([if size_t is unsigned int],
3934     wx_cv_size_t_is_uint,
3935     [
3936     dnl an obvious check like AC_TRY_COMPILE[struct Foo { ... };] doesn't work
3937     dnl with egcs (at least) up to 1.1.1 as it allows you to compile duplicate
3938     dnl methods in a local class (i.e. class inside a function) declaration
3939     dnl without any objections!!
3940     dnl
3941     dnl hence the hack below: we must have Foo at global scope!
3942     AC_TRY_COMPILE([#include <stddef.h>],
3943         [
3944             return 0; }
3945
3946             struct Foo { void foo(size_t); void foo(unsigned int); };
3947
3948             int bar() {
3949         ],
3950         wx_cv_size_t_is_uint=no,
3951         wx_cv_size_t_is_uint=yes
3952     )
3953     ]
3954 )
3955
3956 if test "$wx_cv_size_t_is_uint" = "yes"; then
3957     AC_DEFINE(wxSIZE_T_IS_UINT)
3958 else
3959     AC_CACHE_CHECK([if size_t is unsigned long],
3960         wx_cv_size_t_is_ulong,
3961         AC_TRY_COMPILE([#include <stddef.h>],
3962             [
3963                 return 0; }
3964
3965                 struct Foo { void foo(size_t); void foo(unsigned long); };
3966
3967                 int bar() {
3968             ],
3969             wx_cv_size_t_is_ulong=no,
3970             wx_cv_size_t_is_ulong=yes
3971         )
3972     )
3973
3974     if test "$wx_cv_size_t_is_ulong" = "yes"; then
3975         AC_DEFINE(wxSIZE_T_IS_ULONG)
3976     fi
3977 fi
3978
3979 AC_CACHE_CHECK([if wchar_t is separate type],
3980     wx_cv_wchar_t_is_separate_type,
3981     AC_TRY_COMPILE([#include <wchar.h>],
3982         [
3983             return 0; }
3984
3985             struct Foo { void foo(wchar_t);
3986                          void foo(unsigned short);
3987                          void foo(unsigned int);
3988                          void foo(unsigned long); };
3989
3990             int bar() {
3991         ],
3992         wx_cv_wchar_t_is_separate_type=yes,
3993         wx_cv_wchar_t_is_separate_type=no
3994     )
3995 )
3996
3997 if test "$wx_cv_wchar_t_is_separate_type" = "yes"; then
3998     AC_DEFINE(wxWCHAR_T_IS_REAL_TYPE, 1)
3999 else
4000     AC_DEFINE(wxWCHAR_T_IS_REAL_TYPE, 0)
4001 fi
4002
4003 AC_LANG_POP() dnl C++
4004
4005 dnl ---------------------------------------------------------------------------
4006 dnl Checks for structures
4007 dnl ---------------------------------------------------------------------------
4008
4009 dnl does passwd struct has the pw_gecos field?
4010 AC_CACHE_CHECK([for pw_gecos in struct passwd], wx_cv_struct_pw_gecos,
4011     [
4012         AC_TRY_COMPILE([#include <pwd.h>],
4013              [
4014                 char *p;
4015                 struct passwd *pw;
4016                 p = pw->pw_gecos;
4017              ],
4018              [
4019                 wx_cv_struct_pw_gecos=yes
4020              ],
4021              [
4022                 wx_cv_struct_pw_gecos=no
4023              ]
4024         )
4025     ]
4026 )
4027
4028 if test "$wx_cv_struct_pw_gecos" = "yes"; then
4029     AC_DEFINE(HAVE_PW_GECOS)
4030 fi
4031
4032 dnl ---------------------------------------------------------------------------
4033 dnl Check for functions
4034 dnl ---------------------------------------------------------------------------
4035
4036 dnl don't check for wchar_t functions if we haven't got wchar_t itself
4037 if test "$wxUSE_WCHAR_T" = "yes"; then
4038     AC_DEFINE(wxUSE_WCHAR_T)
4039
4040     dnl check for wcslen in all possible places
4041     WCSLEN_FOUND=0
4042     WCHAR_LINK=
4043     AC_CHECK_FUNCS(wcslen, WCSLEN_FOUND=1)
4044
4045     if test "$WCSLEN_FOUND" = 0; then
4046         if test "$TOOLKIT" = "MSW"; then
4047             AC_CHECK_LIB(msvcrt, wcslen, WCHAR_OK=1)
4048         else
4049             AC_CHECK_LIB(w, wcslen, [
4050                             WCHAR_LINK=" -lw"
4051                             WCSLEN_FOUND=1
4052                         ])
4053         fi
4054     fi
4055
4056     if test "$WCSLEN_FOUND" = 1; then
4057         AC_DEFINE(HAVE_WCSLEN)
4058     fi
4059
4060     AC_CHECK_FUNCS([wcsdup])
4061
4062     dnl On HP-UX aCC need this define to find mbstrtowcs() &c
4063     dnl Can't be used for g++ since the mbstate_t in wchar.h can conflict
4064     dnl with g++'s in <cwchar> (unless -D_INCLUDE__STDC_A1_SOURCE is in the
4065     dnl flags when g++ is configured, it will declare it's own).
4066     if test "$USE_HPUX" = 1 -a "$GCC" != "yes"; then
4067         CPPFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CPPFLAGS"
4068     fi
4069
4070     dnl Try to use wcsrtombs instead of wcstombs which is buggy in old GNU
4071     dnl libc versions if possible. AC_CHECK_FUNCS only checks it's in the
4072     dnl library, not the header, so do a header check for mbstate_t first.
4073     AC_CHECK_TYPES([mbstate_t],
4074                    [AC_CHECK_FUNCS(wcsrtombs)],
4075                    [],
4076                    [#include <wchar.h>])
4077 else
4078     AC_MSG_WARN([Wide character support is unavailable])
4079 fi
4080
4081 dnl check for vsnprintf() -- a safe version of vsprintf())
4082 dnl
4083 dnl the trouble here is that on some systems (e.g HP-UX 10) this function is
4084 dnl present in libc but not in the system headers and so AC_CHECK_FUNCS (which,
4085 dnl stupidly, provides a dummy function declaration inside its extension)
4086 dnl succeeds, even with C++ compiler, but the compilation of wxWidgets fails
4087 dnl
4088 dnl so we first check if the function is in the library
4089 dnl
4090 dnl FIXME: replace this mess with WX_CHECK_FUNCS()
4091 AC_CHECK_FUNCS(snprintf vsnprintf)
4092
4093 if test "$ac_cv_func_vsnprintf" = "yes"; then
4094     dnl yes it is -- now check if it is in the headers
4095     AC_CACHE_CHECK([for vsnprintf declaration], wx_cv_func_vsnprintf_decl,
4096         [
4097             dnl our troubles are not over: HP-UX 11 prototypes vsnprintf() as
4098             dnl taking "char *" and not "const char *" while Metrowerks does
4099             dnl provide a correct vsnprintf declaration but in C++ mode it's
4100             dnl always in std namespace and so we have to bring it in scope
4101             AC_TRY_COMPILE(
4102                 [
4103                     #include <stdio.h>
4104                     #include <stdarg.h>
4105                     #ifdef __MSL__
4106                     #if __MSL__ >= 0x6000
4107                     namespace std {}
4108                     using namespace std;
4109                     #endif
4110                     #endif
4111                 ],
4112                 [
4113                     char *buf;
4114                     va_list ap;
4115                     vsnprintf(buf, 10u, "%s", ap);
4116                 ],
4117                 wx_cv_func_vsnprintf_decl=yes,
4118                 wx_cv_func_vsnprintf_decl=no
4119             )
4120         ]
4121     )
4122
4123     if test "$wx_cv_func_vsnprintf_decl" = "yes"; then
4124         AC_DEFINE(HAVE_VSNPRINTF_DECL)
4125
4126         dnl we know there is a vsnprintf declaration, but some old headers
4127         dnl may have one taking a "char *" format instead of "const char *"
4128         AC_CACHE_CHECK([if vsnprintf declaration is broken], wx_cv_func_broken_vsnprintf_decl,
4129             [
4130                 AC_TRY_COMPILE(
4131                     [
4132                         #include <stdio.h>
4133                         #include <stdarg.h>
4134                         #ifdef __MSL__
4135                         #if __MSL__ >= 0x6000
4136                         namespace std {}
4137                         using namespace std;
4138                         #endif
4139                         #endif
4140                     ],
4141                     [
4142                         char *buf;
4143                         va_list ap;
4144                         const char *fmt = "%s";
4145                         vsnprintf(buf, 10u, fmt, ap);
4146                     ],
4147                     wx_cv_func_broken_vsnprintf_decl=no,
4148                     wx_cv_func_broken_vsnprintf_decl=yes
4149                 )
4150             ]
4151         )
4152
4153         if test "$wx_cv_func_broken_vsnprintf_decl" = "yes"; then
4154             AC_DEFINE(HAVE_BROKEN_VSNPRINTF_DECL)
4155         fi
4156     fi
4157 fi
4158
4159 dnl the same as above but for snprintf() now: it's not present in at least AIX
4160 dnl 4.2 headers
4161 if test "$ac_cv_func_snprintf" = "yes"; then
4162     AC_CACHE_CHECK([for snprintf declaration], wx_cv_func_snprintf_decl,
4163         [
4164             AC_TRY_COMPILE(
4165                 [
4166                     #include <stdio.h>
4167                     #include <stdarg.h>
4168                     #ifdef __MSL__
4169                     #if __MSL__ >= 0x6000
4170                     namespace std {}
4171                     using namespace std;
4172                     #endif
4173                     #endif
4174                 ],
4175                 [
4176                     char *buf;
4177                     snprintf(buf, 10u, "%s", "wx");
4178                 ],
4179                 wx_cv_func_snprintf_decl=yes,
4180                 wx_cv_func_snprintf_decl=no
4181             )
4182         ]
4183     )
4184
4185     if test "$wx_cv_func_snprintf_decl" = "yes"; then
4186         AC_DEFINE(HAVE_SNPRINTF_DECL)
4187
4188         dnl we know there is an snprintf declaration, but some old headers
4189         dnl may have one taking a "char *" format instead of "const char *"
4190         AC_CACHE_CHECK([if snprintf declaration is broken], wx_cv_func_broken_snprintf_decl,
4191             [
4192                 AC_TRY_COMPILE(
4193                     [
4194                         #include <stdio.h>
4195                         #include <stdarg.h>
4196                         #ifdef __MSL__
4197                         #if __MSL__ >= 0x6000
4198                         namespace std {}
4199                         using namespace std;
4200                         #endif
4201                         #endif
4202                     ],
4203                     [
4204                         char *buf;
4205                         const char *fmt = "%s";
4206                         snprintf(buf, 10u, fmt, "wx");
4207                     ],
4208                     wx_cv_func_broken_snprintf_decl=no,
4209                     wx_cv_func_broken_snprintf_decl=yes
4210                 )
4211             ]
4212         )
4213
4214         if test "$wx_cv_func_broken_snprintf_decl" = "yes"; then
4215             AC_DEFINE(HAVE_BROKEN_SNPRINTF_DECL)
4216         fi
4217     fi
4218
4219     if test "$wxUSE_PRINTF_POS_PARAMS" = "yes"; then
4220
4221         dnl check if snprintf() has support for positional arguments
4222         dnl NB: if snprintf() has positional support we can safely suppose that also
4223         dnl     other *printf() functions support them as they all belong to the same
4224         dnl     family and they all fallback to the same implementation
4225         AC_CACHE_CHECK([if snprintf supports positional arguments], wx_cv_func_snprintf_pos_params,
4226             [
4227                 AC_TRY_RUN(
4228                     [
4229                         #include <stdio.h>
4230
4231                         int main (void)
4232                         {
4233                             char buffer[128];
4234                             snprintf (buffer, 128, "%2$d %3$d %1$d", 1, 2, 3);
4235                             if (strcmp ("2 3 1", buffer) == 0)
4236                                 exit (0);
4237                             exit (1);
4238                         }
4239                     ],
4240                     wx_cv_func_snprintf_pos_params=no,
4241                     wx_cv_func_snprintf_pos_params=yes,
4242                     dnl be pessimistic when cross-compiling
4243                     [
4244                         AC_MSG_WARN([Assuming Unix98 printf() is not available,
4245 define HAVE_UNIX98_PRINTF as 1 in setup.h if it is available.])
4246                         wx_cv_func_snprintf_pos_params=no
4247                     ]
4248                 )
4249             ]
4250         )
4251
4252         if test "$wx_cv_func_snprintf_pos_params" = "yes"; then
4253             AC_DEFINE(HAVE_UNIX98_PRINTF)
4254         fi
4255     fi
4256 fi
4257
4258 if test "$wxUSE_UNICODE" = yes; then
4259
4260     dnl our wxVsnprintf() implementation needs to use the system swprintf() in Unicode
4261     dnl builds so let's check if swprintf() is declared as C99 imposes:
4262     dnl     int swprintf(wchar_t *s, size_t n, const wchar_t *format, ...);
4263     dnl or rather as:
4264     dnl     int swprintf(wchar_t *s, const wchar_t *format, ...);
4265     AC_CHECK_FUNCS(swprintf)
4266
4267     if test "$ac_cv_func_swprintf" = "yes"; then
4268         AC_CACHE_CHECK([if swprintf declaration is broken], wx_cv_func_broken_swprintf_decl,
4269             [
4270                 AC_TRY_COMPILE(
4271                     [
4272                         #include <stdio.h>
4273                         #include <stdarg.h>
4274                         #include <wchar.h>
4275                     ],
4276                     [
4277                         wchar_t *buf;
4278                         const wchar_t *fmt = L"test";
4279                         swprintf(buf, 10u, fmt);
4280                     ],
4281                     wx_cv_func_broken_swprintf_decl=no,
4282                     wx_cv_func_broken_swprintf_decl=yes
4283                 )
4284             ]
4285         )
4286
4287         if test "$wx_cv_func_broken_swprintf_decl" = "yes"; then
4288             AC_DEFINE(HAVE_BROKEN_SWPRINTF_DECL)
4289         fi
4290     fi
4291
4292     dnl also look if we have wide char IO functions, notice that [f]putws are
4293     dnl declared in special widec.h under Solaris
4294     wchar_headers="#include <stdio.h>
4295 #include <wchar.h>"
4296     case "${host}" in
4297         *-*-solaris2* )
4298             AC_CHECK_HEADER(widec.h,,, [AC_INCLUDES_DEFAULT()])
4299             if test "$ac_cv_header_widec_h" = "yes"; then
4300                 wchar_headers="$wchar_headers
4301 #include <widec.h>"
4302             fi
4303     esac
4304
4305     WX_CHECK_FUNCS(wputc wputchar putws fputws wprintf vswprintf,,,
4306                    [$wchar_headers])
4307
4308     dnl MinGW has a vswprintf with a different prototype, and
4309     dnl a _vsnwprintf with the correct prototype, but AC_CHECK_FUNCS
4310     dnl finds it even if it is not declared in some versions...
4311     AC_MSG_CHECKING([for _vsnwprintf])
4312     AC_TRY_COMPILE([#include <wchar.h>],
4313                    [&_vsnwprintf;],
4314                    [AC_MSG_RESULT([yes])
4315                     AC_DEFINE(HAVE__VSNWPRINTF)],
4316                    [AC_MSG_RESULT([no])]);
4317 fi
4318
4319 if test "x$ac_cv_header_fnmatch_h" = "xyes"; then
4320     WX_CHECK_FUNCS(fnmatch,,,[#include <fnmatch.h>])
4321 fi
4322
4323 if test "$wxUSE_FILE" = "yes"; then
4324     WX_CHECK_FUNCS(fsync)
4325 fi
4326
4327 dnl at least under IRIX with mipsPro the C99 round() function is available when
4328 dnl building using the C compiler but not when using C++ one
4329 AC_LANG_PUSH(C++)
4330 WX_CHECK_FUNCS(round,,,[#include <math.h>])
4331 AC_LANG_POP()
4332
4333 dnl the following tests are for Unix(like) systems only
4334 if test "$TOOLKIT" != "MSW"; then
4335
4336 dnl check for available version of iconv()
4337
4338 AM_ICONV
4339 LIBS="$LIBICONV $LIBS"
4340
4341 dnl check for POSIX signals if we need them
4342 if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes" -a "$wxUSE_UNIX" = "yes"; then
4343     AC_CHECK_FUNCS(sigaction)
4344
4345     if test "$ac_cv_func_sigaction" = "no"; then
4346         AC_MSG_WARN([No POSIX signal functions on this system, wxApp::OnFatalException will not be called])
4347         wxUSE_ON_FATAL_EXCEPTION=no
4348     fi
4349
4350     if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
4351       AC_CACHE_CHECK([for sa_handler type], wx_cv_type_sa_handler,
4352       [
4353         dnl C compiler happily compiles the code even if there is type mismatch
4354         AC_LANG_PUSH(C++)
4355         AC_TRY_COMPILE([#include <signal.h>],
4356                      [
4357                         extern void testSigHandler(int);
4358
4359                         struct sigaction sa;
4360                         sa.sa_handler = testSigHandler;
4361                      ], [
4362                         wx_cv_type_sa_handler=int
4363                      ], [
4364                         wx_cv_type_sa_handler=void
4365                      ])
4366         AC_LANG_POP()
4367       ])
4368
4369       AC_DEFINE_UNQUOTED(wxTYPE_SA_HANDLER, $wx_cv_type_sa_handler)
4370     fi
4371 fi
4372
4373 dnl backtrace() and backtrace_symbols() for wxStackWalker
4374 if test "$wxUSE_STACKWALKER" = "yes" -a "$wxUSE_UNIX" = "yes"; then
4375     AC_CACHE_CHECK([for backtrace() in <execinfo.h>], wx_cv_func_backtrace,
4376         [
4377             AC_LANG_PUSH(C++)
4378             AC_TRY_COMPILE([#include <execinfo.h>],
4379                 [
4380                     void *trace[1];
4381                     char **messages;
4382
4383                     backtrace(trace, 1);
4384                     messages = backtrace_symbols(trace, 1);
4385                 ],
4386                 wx_cv_func_backtrace=yes,
4387                 wx_cv_func_backtrace=no
4388             )
4389             AC_LANG_POP()
4390         ]
4391     )
4392
4393
4394     if test "$wx_cv_func_backtrace" = "no"; then
4395         AC_MSG_WARN([backtrace() is not available, wxStackWalker will not be available])
4396         wxUSE_STACKWALKER=no
4397     else
4398         AC_CACHE_CHECK([for __cxa_demangle() in <cxxabi.h>], wx_cv_func_cxa_demangle,
4399             [
4400                 AC_LANG_PUSH(C++)
4401                 AC_TRY_LINK([#include <cxxabi.h>],
4402                     [
4403                         int rc;
4404                         __cxxabiv1::__cxa_demangle("foo", 0, 0, &rc);
4405                     ],
4406                     wx_cv_func_cxa_demangle=yes,
4407                     wx_cv_func_cxa_demangle=no
4408                 )
4409                 AC_LANG_POP()
4410             ]
4411         )
4412
4413         if test "$wx_cv_func_cxa_demangle" = "yes"; then
4414             AC_DEFINE(HAVE_CXA_DEMANGLE)
4415         fi
4416     fi
4417 fi
4418
4419 if test "$wxUSE_STACKWALKER" = "yes" -a "$USE_WIN32" != "1" -a "$USE_UNIX" != "1"; then
4420     AC_MSG_WARN([wxStackWalker is only available on Win32 and UNIX... disabled])
4421     wxUSE_STACKWALKER=no
4422 fi
4423
4424
4425 dnl check for the function for temp files creation
4426 AC_CHECK_FUNCS(mkstemp mktemp, break)
4427
4428 dnl get the library function to use for wxGetDiskSpace(): it is statfs() under
4429 dnl Linux and *BSD and statvfs() under Solaris
4430 AC_CACHE_CHECK(for statfs, wx_cv_func_statfs,
4431     AC_TRY_COMPILE(
4432         [
4433              #if defined(__BSD__)
4434              #include <sys/param.h>
4435              #include <sys/mount.h>
4436              #else
4437              #include <sys/vfs.h>
4438              #endif
4439         ],
4440         [
4441              long l;
4442              struct statfs fs;
4443              statfs("/", &fs);
4444              l = fs.f_bsize;
4445              l += fs.f_blocks;
4446              l += fs.f_bavail;
4447         ],
4448          wx_cv_func_statfs=yes,
4449          wx_cv_func_statfs=no
4450     )
4451 )
4452
4453 if test "$wx_cv_func_statfs" = "yes"; then
4454     dnl check whether we have its dcelaration too: some systems (AIX 4) lack it
4455     AC_CACHE_CHECK(for statfs declaration, wx_cv_func_statfs_decl,
4456         AC_LANG_PUSH(C++)
4457         AC_TRY_COMPILE(
4458             [
4459                  #if defined(__BSD__)
4460                  #include <sys/param.h>
4461                  #include <sys/mount.h>
4462                  #else
4463                  #include <sys/vfs.h>
4464                  #endif
4465             ],
4466             [
4467                 struct statfs fs;
4468                 statfs("", &fs);
4469             ],
4470             wx_cv_func_statfs_decl=yes,
4471             wx_cv_func_statfs_decl=no
4472         )
4473         AC_LANG_POP()
4474     )
4475
4476     if test "$wx_cv_func_statfs_decl" = "yes"; then
4477         AC_DEFINE(HAVE_STATFS_DECL)
4478     fi
4479
4480     wx_cv_type_statvfs_t="struct statfs"
4481     AC_DEFINE(HAVE_STATFS)
4482 else
4483     AC_CACHE_CHECK(for statvfs, wx_cv_func_statvfs,
4484         AC_TRY_COMPILE(
4485             [
4486                 #include <stddef.h>
4487                 #include <sys/statvfs.h>
4488             ],
4489             [
4490                 statvfs("/", NULL);
4491             ],
4492             wx_cv_func_statvfs=yes,
4493             wx_cv_func_statvfs=no
4494         )
4495     )
4496
4497     if test "$wx_cv_func_statvfs" = "yes"; then
4498         dnl we also have to check whether we should use statvfs_t (works under
4499         dnl Solaris 8, doesn't work under Solaris 7) or "struct statvfs" (vice
4500         dnl versa) as the argument for statvfs in 64 bit off_t mode (in 32 bit
4501         dnl mode both work fine)
4502         dnl
4503         dnl for this check C++ compiler has to be used as passing incompatible
4504         dnl pointers is just a warning and not an error in C
4505         AC_CACHE_CHECK(for statvfs argument type, wx_cv_type_statvfs_t,
4506             AC_LANG_PUSH(C++)
4507             AC_TRY_COMPILE(
4508                 [
4509                     #include <sys/statvfs.h>
4510                 ],
4511                 [
4512                     long l;
4513                     statvfs_t fs;
4514                     statvfs("/", &fs);
4515                     l = fs.f_bsize;
4516                     l += fs.f_blocks;
4517                     l += fs.f_bavail;
4518                 ],
4519                 wx_cv_type_statvfs_t=statvfs_t,
4520                 [
4521                     AC_TRY_COMPILE(
4522                         [
4523                             #include <sys/statvfs.h>
4524                         ],
4525                         [
4526                             long l;
4527                             struct statvfs fs;
4528                             statvfs("/", &fs);
4529                             l = fs.f_bsize;
4530                             l += fs.f_blocks;
4531                             l += fs.f_bavail;
4532                         ],
4533                         wx_cv_type_statvfs_t="struct statvfs",
4534                         wx_cv_type_statvfs_t="unknown"
4535                     )
4536                 ]
4537             )
4538             AC_LANG_POP()
4539         )
4540
4541         if test "$wx_cv_type_statvfs_t" != "unknown"; then
4542             AC_DEFINE(HAVE_STATVFS)
4543         fi
4544     else
4545         dnl set it for the test below
4546         wx_cv_type_statvfs_t="unknown"
4547     fi
4548 fi
4549
4550 if test "$wx_cv_type_statvfs_t" != "unknown"; then
4551     AC_DEFINE_UNQUOTED(WX_STATFS_T, $wx_cv_type_statvfs_t)
4552 else
4553     AC_MSG_WARN([wxGetDiskSpace() function won't work without statfs()])
4554 fi
4555
4556 dnl check for fcntl() or at least flock() needed by Unix implementation of
4557 dnl wxSingleInstanceChecker
4558 if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
4559     AC_CHECK_FUNCS(fcntl flock, break)
4560
4561     if test "$ac_cv_func_fcntl" != "yes" -a "$ac_cv_func_flock" != "yes"; then
4562         AC_MSG_WARN(wxSingleInstanceChecker not available)
4563         wxUSE_SNGLINST_CHECKER=no
4564     fi
4565 fi
4566
4567 dnl check for timegm() used by datetime.cpp
4568 AC_CHECK_FUNCS(timegm)
4569
4570 dnl look for a function to modify the environment
4571 AC_CHECK_FUNCS(putenv setenv, break)
4572
4573 HAVE_SOME_SLEEP_FUNC=0
4574 if test "$USE_BEOS" = 1; then
4575     dnl BeOS has its own (wonder where did they get it from) sleep() function
4576     dnl in unistd.h
4577     AC_DEFINE(HAVE_SLEEP)
4578     HAVE_SOME_SLEEP_FUNC=1
4579 fi
4580
4581 if test "$USE_DARWIN" = 1; then
4582     dnl Mac OS X/Darwin has both nanosleep and usleep
4583     dnl but only usleep is defined in unistd.h
4584     AC_DEFINE(HAVE_USLEEP)
4585     HAVE_SOME_SLEEP_FUNC=1
4586 fi
4587
4588 if test "$HAVE_SOME_SLEEP_FUNC" != 1; then
4589     dnl try nanosleep() in libc and libposix4, if this fails - usleep()
4590     POSIX4_LINK=
4591     AC_CHECK_FUNCS(nanosleep,
4592         AC_DEFINE(HAVE_NANOSLEEP),
4593         [
4594             AC_CHECK_LIB(posix4, nanosleep,
4595                 [
4596                     AC_DEFINE(HAVE_NANOSLEEP)
4597                     POSIX4_LINK=" -lposix4"
4598                 ],
4599                 [
4600                     WX_CHECK_FUNCS(usleep,,
4601                                     AC_MSG_WARN([wxSleep() function will not work])
4602                     )
4603                 ]
4604             )
4605         ]
4606     )
4607 fi
4608
4609 dnl check for uname (POSIX) and gethostname (BSD)
4610 WX_CHECK_FUNCS(uname,,,[#include <sys/utsname.h>])
4611 if test "$wx_cv_func_uname" != yes; then
4612     WX_CHECK_FUNCS(gethostname)
4613 fi
4614
4615 WX_CHECK_FUNCS(strtok_r, [], [], [#define _REENTRANT])
4616
4617 dnl check for inet_addr and inet_aton (these may live either in libc, or in
4618 dnl libnsl or libresolv or libsocket)
4619 INET_LINK=
4620 AC_CHECK_FUNCS(inet_addr,
4621     AC_DEFINE(HAVE_INET_ADDR),
4622     [
4623         AC_CHECK_LIB(nsl, inet_addr,
4624             INET_LINK="nsl",
4625             [
4626                 AC_CHECK_LIB(resolv, inet_addr,
4627                     INET_LINK="resolv",
4628                     [
4629                         AC_CHECK_LIB(socket, inet_addr,
4630                             INET_LINK="socket"
4631                         )
4632                     ]
4633                 )
4634             ]
4635         )
4636     ]
4637 )
4638
4639 AC_CHECK_FUNCS(inet_aton,
4640         AC_DEFINE(HAVE_INET_ATON),
4641         [
4642             dnl only check it in the same lib
4643             AC_CHECK_LIB($INET_LINK, inet_aton, AC_DEFINE(HAVE_INET_ATON))
4644         ])
4645
4646 if test "x$INET_LINK" != "x"; then
4647     AC_DEFINE(HAVE_INET_ADDR)
4648     INET_LINK=" -l$INET_LINK"
4649 fi
4650
4651 WX_CHECK_FUNCS(fdopen)
4652
4653 fi
4654
4655
4656 dnl ===========================================================================
4657 dnl Now we have all the info we need - use it!
4658 dnl ===========================================================================
4659
4660 dnl flush the cache
4661 AC_CACHE_SAVE
4662
4663 dnl ---------------------------------------------------------------------------
4664 dnl thread support for Unix (for Win32 and OS/2 see past
4665 dnl                          the next matching "else")
4666 dnl ---------------------------------------------------------------------------
4667
4668 dnl under MSW (except mingw32) we always have thread support
4669 if test "$TOOLKIT" != "MSW" -a "$USE_OS2" != 1; then
4670
4671     dnl the code below:
4672     dnl
4673     dnl   defines THREADS_LINK and THREADS_CFLAGS which are the options
4674     dnl   necessary to build the MT programs for the linker and compiler
4675     dnl   respectively
4676     dnl
4677     dnl   sets wxUSE_THREADS=1 if thread support is activated
4678
4679     THREADS_LINK=
4680     THREADS_CFLAGS=
4681
4682     if test "$wxUSE_THREADS" = "yes" ; then
4683         if test "$USE_BEOS" = 1; then
4684             AC_MSG_WARN([BeOS threads are not yet supported... disabled])
4685             wxUSE_THREADS="no"
4686         fi
4687     fi
4688
4689     if test "$wxUSE_THREADS" = "yes" ; then
4690         dnl find if POSIX threads are available
4691         dnl
4692         dnl the tests here are based on ACX_PTHREAD macro from autoconf macro
4693         dnl archive from http://ac-archive.sourceforge.net/
4694         dnl
4695         dnl thanks to Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro
4696         dnl Forero Cuervo <bachue@bachue.com> for the original code
4697
4698         dnl TODO: cache the result
4699
4700         dnl define the list of the thread options to try in the loop below
4701         dnl with the convention that anything starting with '-' is a cpp flag
4702         dnl while anything else is a library (i.e. there is an implicit "-l")
4703         THREAD_OPTS="-pthread"
4704         if test "x$SUNCXX" = xyes; then
4705             THREAD_OPTS="-mt lthread $THREAD_OPTS"
4706         fi
4707
4708         case "${host}" in
4709           *-*-solaris2* | *-*-sunos4* )
4710                 if test "x$GCC" = "xyes"; then
4711                     dnl Solaris/gcc combination use this one for some reason
4712                     THREAD_OPTS="-pthreads $THREAD_OPTS"
4713                 fi
4714                 ;;
4715           *-*-freebsd*)
4716                 dnl look, in order, for the kernel threads, then Linux threads
4717                 dnl and finally the userland threads
4718                 THREAD_OPTS="-kthread lthread $THREAD_OPTS c_r"
4719                 ;;
4720           *-*-darwin* | *-*-cygwin* )
4721                 dnl Darwin / Mac OS X just uses -lpthread tested below
4722                 dnl and so does Cygwin
4723                 THREAD_OPTS=""
4724                 ;;
4725           *-*-aix*)
4726                 dnl AIX calls the library libpthreads - thanks IBM!
4727                 THREAD_OPTS="pthreads"
4728                 ;;
4729           *-hp-hpux* )
4730                 if test "x$GCC" = "xyes"; then
4731                     dnl g++ versions before 3.3.2 don't support -pthread.
4732                     $CXX -dumpspecs | grep 'pthread:' >/dev/null ||
4733                         THREAD_OPTS=""
4734                 else
4735                     dnl HP-UX aCC (tested with version B3910B A.06.05 [Jul 25
4736                     dnl 2005]) supports -mt
4737                     THREAD_OPTS="-mt"
4738                 fi
4739                 ;;
4740
4741           *-*-irix* )
4742                 dnl gcc under IRIX doesn't seem to like -pthread, but it
4743                 dnl doesn't give an error for it neither, just a warning
4744                 dnl message -- but this is still very annoying
4745                 if test "x$GCC" = "xyes"; then
4746                     THREAD_OPTS=""
4747                 fi
4748                 ;;
4749
4750           *-*-*UnixWare*)
4751                 dnl flying by man pages here: Caldera online docs use this
4752                 if test "x$GCC" != "xyes"; then
4753                     THREAD_OPTS="-Ethread"
4754                 fi
4755                 ;;
4756         esac
4757
4758         dnl simply linking with libpthread should make the test below work but
4759         dnl it's far from certain that the threaded programs compiled without
4760         dnl any special switches actually work, so try it after all the others
4761         THREAD_OPTS="$THREAD_OPTS pthread none"
4762
4763         dnl now test for all possibilities
4764         THREADS_OK=no
4765         for flag in $THREAD_OPTS; do
4766             case $flag in
4767                 none)
4768                     AC_MSG_CHECKING([whether pthreads work without any flags])
4769                     ;;
4770
4771                 -*)
4772                     AC_MSG_CHECKING([whether pthreads work with $flag])
4773                     THREADS_CFLAGS="$flag"
4774                     ;;
4775
4776                 *)
4777                     AC_MSG_CHECKING([for the pthreads library -l$flag])
4778                     THREADS_LINK="-l$flag"
4779                     ;;
4780               esac
4781
4782               save_LIBS="$LIBS"
4783               save_CFLAGS="$CFLAGS"
4784               LIBS="$THREADS_LINK $LIBS"
4785               CFLAGS="$THREADS_CFLAGS $CFLAGS"
4786
4787               AC_TRY_LINK([#include <pthread.h>],
4788                           [pthread_create(0,0,0,0);],
4789                           THREADS_OK=yes)
4790
4791               LIBS="$save_LIBS"
4792               CFLAGS="$save_CFLAGS"
4793
4794               AC_MSG_RESULT($THREADS_OK)
4795               if test "x$THREADS_OK" = "xyes"; then
4796                       break;
4797               fi
4798
4799               THREADS_LINK=""
4800               THREADS_CFLAGS=""
4801       done
4802
4803       if test "x$THREADS_OK" != "xyes"; then
4804           wxUSE_THREADS=no
4805           AC_MSG_WARN([No thread support on this system... disabled])
4806       else
4807           dnl yes, these special compiler flags should be used with the
4808           dnl linker as well
4809           LDFLAGS="$THREADS_CFLAGS $LDFLAGS"
4810           LIBS="$THREADS_LINK $LIBS"
4811
4812           AC_MSG_CHECKING([if more special flags are required for pthreads])
4813           flag=no
4814           case "${host}" in
4815             *-aix*)
4816                 dnl again quoting from
4817                 dnl http://www-1.ibm.com/servers/esdd/articles/gnu.html:
4818                 dnl
4819                 dnl     When compiling and linking with -pthread, the library
4820                 dnl     search path should include -L/usr/lib/threads at the
4821                 dnl     beginning of the path.
4822                 LDFLAGS="-L/usr/lib/threads $LDFLAGS"
4823                 flag="-D_THREAD_SAFE"
4824                 ;;
4825             *-freebsd*)
4826                 flag="-D_THREAD_SAFE"
4827                 ;;
4828             *-hp-hpux* )
4829                 flag="-D_REENTRANT"
4830                 if test "x$GCC" != "xyes"; then
4831                     dnl see http://docs.hp.com/hpux/onlinedocs/2213/threads.htm
4832                     flag="$flag -D_RWSTD_MULTI_THREAD"
4833                 fi
4834                 ;;
4835             *solaris* | alpha*-osf*)
4836                 flag="-D_REENTRANT"
4837                 ;;
4838           esac
4839           AC_MSG_RESULT(${flag})
4840           if test "x$flag" != xno; then
4841               THREADS_CFLAGS="$THREADS_CFLAGS $flag"
4842           fi
4843
4844           dnl don't add these options to CPPFLAGS as cpp might not know them
4845           WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS $THREADS_CFLAGS"
4846       fi
4847     fi
4848
4849     dnl do other tests only if we are using threads
4850     if test "$wxUSE_THREADS" = "yes" ; then
4851       AC_CHECK_FUNCS(thr_setconcurrency)
4852
4853       dnl can't use AC_CHECK_FUNCS for this one as it's usually a macro and so
4854       dnl wouldn't be found by it
4855       AC_CACHE_CHECK([for pthread_cleanup_push/pop], wx_cv_func_pthread_cleanup,
4856       [
4857         dnl C compiler may treat pthread_cleanup_push() as an undeclared
4858         dnl function and not give a warning even if it's unavailable, so use
4859         dnl the C++ one for this test
4860         AC_LANG_PUSH(C++)
4861         AC_TRY_COMPILE([#include <pthread.h>
4862                void ThreadCleanupFunc(void *p);
4863             ],
4864             [
4865                 void *p;
4866                 pthread_cleanup_push(ThreadCleanupFunc, p);
4867                 pthread_cleanup_pop(0);
4868             ], [
4869                wx_cv_func_pthread_cleanup=yes
4870             ], [
4871                wx_cv_func_pthread_cleanup=no
4872             ]
4873         )
4874         AC_LANG_POP()
4875       ])
4876       if test "x$wx_cv_func_pthread_cleanup" = "xyes"; then
4877         AC_DEFINE(wxHAVE_PTHREAD_CLEANUP)
4878       fi
4879
4880       AC_CHECK_HEADER(sched.h,,, [AC_INCLUDES_DEFAULT()])
4881       if test "$ac_cv_header_sched_h" = "yes"; then
4882           AC_CHECK_FUNC(sched_yield,
4883             AC_DEFINE(HAVE_SCHED_YIELD),
4884             [
4885                 AC_CHECK_LIB(posix4,
4886                     sched_yield,
4887                     [AC_DEFINE(HAVE_SCHED_YIELD) POSIX4_LINK=" -lposix4"],
4888                     AC_MSG_WARN(wxThread::Yield will not work properly)
4889                 )
4890             ]
4891           )
4892       fi
4893
4894       dnl to be able to set the thread priority, we need to have all of the
4895       dnl following functions:
4896       dnl   1. pthread_attr_getschedpolicy
4897       dnl   2. sched_get_priority_min and sched_get_priority_max
4898       dnl      (this one can be in either libpthread or libposix4 (under Solaris))
4899       dnl   3. pthread_attr_getschedparam and pthread_attr_setschedparam
4900       HAVE_PRIOR_FUNCS=0
4901       AC_CHECK_FUNC(pthread_attr_getschedpolicy,
4902                      [AC_CHECK_FUNC(pthread_attr_setschedparam,
4903                        [AC_CHECK_FUNC(sched_get_priority_max,
4904                            HAVE_PRIOR_FUNCS=1,
4905                            [AC_CHECK_LIB([posix4], sched_get_priority_max,
4906                              [
4907                                 HAVE_PRIOR_FUNCS=1
4908                                 POSIX4_LINK=" -lposix4"
4909                              ],
4910                            )]
4911                        )]
4912                      )]
4913                    )
4914
4915       if test "$HAVE_PRIOR_FUNCS" = 1; then
4916         AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS)
4917       else
4918         AC_MSG_WARN(Setting thread priority will not work)
4919       fi
4920
4921       AC_CHECK_FUNC(pthread_cancel,
4922                     AC_DEFINE(HAVE_PTHREAD_CANCEL),
4923                     AC_MSG_WARN([wxThread::Kill() will not work properly]))
4924
4925       AC_CHECK_FUNC(pthread_mutex_timedlock,
4926                     AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK),
4927                     AC_MSG_WARN([wxMutex::LockTimeout() will not work]))
4928
4929       AC_CHECK_FUNC(pthread_attr_setstacksize,
4930                     AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE))
4931
4932       dnl mutexattr_t initialization is done in quite different ways on different
4933       dnl platforms, so check for a few things:
4934       dnl
4935       dnl HAVE_MUTEX_RECURSIVE means that we can create recursive mutexes
4936       dnl HAVE_MUTEXATTR_SETTYPE means that we do it using
4937       dnl pthread_mutexattr_settype(PTHREAD_MUTEX_RECURSIVE) and if it is not
4938       dnl defined, we do it by directly assigned
4939       dnl PTHREAD_MUTEX_RECURSIVE_MUTEX_INITIALIZER_NP to attr
4940
4941       AC_CACHE_CHECK([for pthread_mutexattr_t], wx_cv_type_pthread_mutexattr_t,
4942       [
4943         AC_TRY_COMPILE([#include <pthread.h>],
4944             [
4945                pthread_mutexattr_t attr;
4946                pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
4947             ],
4948             wx_cv_type_pthread_mutexattr_t=yes,
4949             wx_cv_type_pthread_mutexattr_t=no
4950         )
4951       ])
4952
4953       if test "$wx_cv_type_pthread_mutexattr_t" = "yes"; then
4954         AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_T)
4955
4956         dnl check if we already have the declaration we need, it is not
4957         dnl present in some systems' headers
4958         AC_CACHE_CHECK([for pthread_mutexattr_settype declaration],
4959                        wx_cv_func_pthread_mutexattr_settype_decl, [
4960                        AC_TRY_COMPILE([#include <pthread.h>],
4961                            [
4962                                pthread_mutexattr_t attr;
4963                                pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
4964                            ],
4965                            wx_cv_func_pthread_mutexattr_settype_decl=yes,
4966                            wx_cv_func_pthread_mutexattr_settype_decl=no
4967                        )
4968         ])
4969         if test "$wx_cv_func_pthread_mutexattr_settype_decl" = "yes"; then
4970             AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_SETTYPE_DECL)
4971         fi
4972       else
4973         dnl don't despair, there may be another way to do it
4974         AC_CACHE_CHECK([for PTHREAD_RECURSIVE_MUTEX_INITIALIZER],
4975                        wx_cv_type_pthread_rec_mutex_init,
4976         [
4977             AC_TRY_COMPILE([#include <pthread.h>],
4978                 [
4979                     pthread_mutex_t attr = PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP;
4980                 ], [
4981                     wx_cv_type_pthread_rec_mutex_init=yes
4982                 ], [
4983                     wx_cv_type_pthread_rec_mutex_init=no
4984                 ]
4985             )
4986         ])
4987         if test "$wx_cv_type_pthread_rec_mutex_init" = "yes"; then
4988           AC_DEFINE(HAVE_PTHREAD_RECURSIVE_MUTEX_INITIALIZER)
4989         else
4990           dnl this may break code working elsewhere, so at least warn about it
4991           AC_MSG_WARN([wxMutex won't be recursive on this platform])
4992         fi
4993       fi
4994     fi
4995
4996 dnl from if !MSW
4997 else
4998     if test "$wxUSE_THREADS" = "yes" ; then
4999       case "${host}" in
5000         *-*-mingw32* )
5001             dnl check if the compiler accepts -mthreads
5002             AC_CACHE_CHECK([if compiler supports -mthreads],
5003                 wx_cv_cflags_mthread,
5004                 [
5005                     CFLAGS_OLD="$CFLAGS"
5006                     CFLAGS="-mthreads $CFLAGS"
5007                     AC_TRY_COMPILE([], [],
5008                         wx_cv_cflags_mthread=yes,
5009                         wx_cv_cflags_mthread=no
5010                     )
5011                 ]
5012             )
5013
5014             if test "$wx_cv_cflags_mthread" = "yes"; then
5015                 dnl it does, use it
5016                 WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -mthreads"
5017                 LDFLAGS="$LDFLAGS -mthreads"
5018             else
5019                 dnl it doesn't
5020                 CFLAGS="$CFLAGS_OLD"
5021             fi
5022         ;;
5023         *-pc-os2*emx )
5024             WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -Zmt -D__ST_MT_ERRNO__"
5025             LDFLAGS="$LDFLAGS -Zmt"
5026         ;;
5027       esac
5028     fi
5029 fi
5030
5031 AC_CHECK_FUNC(localtime_r, [ AC_DEFINE(HAVE_LOCALTIME_R) ])
5032 AC_CHECK_FUNC(gmtime_r, [ AC_DEFINE(HAVE_GMTIME_R) ])
5033 AC_CHECK_FUNC(readdir_r, [ AC_DEFINE(HAVE_READDIR_R) ])
5034 dnl By preference, we probably should use getaddrinfo which avoids thread
5035 dnl safety issues and supports IPv6, however there currently is no code
5036 dnl for it, so testing for it is temporarily disabled and we are restricted
5037 dnl to gethostbyname_r/gethostbyaddr_r  and getservbyname_r
5038
5039 dnl AC_CHECK_FUNC(getaddrinfo, AC_DEFINE(HAVE_GETADDRINFO), [
5040     dnl no getaddrinfo, so check for gethostbyname_r and
5041     dnl related functions (taken from python's configure.in)
5042     dnl sigh -- gethostbyname_r is a mess; it can have 3, 5 or 6 arguments
5043       AX_FUNC_WHICH_GETHOSTBYNAME_R
5044       if test "x$ac_cv_func_which_gethostbyname_r" = "xno" -o \
5045               "x$ac_cv_func_which_gethostbyname_r" = "xunknown" ; then
5046           AC_CHECK_FUNC(gethostbyname, [ AC_DEFINE(HAVE_GETHOSTBYNAME) ])
5047       fi
5048       dnl A similar test for getservbyname_r
5049       dnl I'm tempted to just not do this test which is taking much time and
5050       dnl do something similar as for gethostbyaddr_r, but OTOH the macro
5051       dnl doing the test already exists, so using it is easy enough.     - SN
5052       AC_raf_FUNC_WHICH_GETSERVBYNAME_R
5053       if test "x$ac_cv_func_which_getservbyname_r" = "xno" -o \
5054               "x$ac_cv_func_which_getservbyname_r" = "xunknown" ; then
5055           AC_CHECK_FUNCS(getservbyname,[ AC_DEFINE(HAVE_GETSERVBYNAME) ])
5056       fi
5057       dnl For gethostbyaddr_r, we currently do no separate test, instead, we
5058       dnl silently assume it's available exactly if gethostbyname_r is
5059       dnl available and always requires two more arguments than
5060       dnl gethostbyname_r.
5061       dnl (also, I'm lazy and there no m4 file that's ready for use for this
5062       dnl  function, although it should be easy to rewrite the gethostbyname_r
5063       dnl  check to fit this case, if it's really needed.                - SN )
5064 dnl    ]
5065 dnl )
5066
5067 if test "$wxUSE_THREADS" = "yes"; then
5068   AC_DEFINE(wxUSE_THREADS)
5069
5070   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS thread"
5071 else
5072   dnl on some systems, _REENTRANT should be defined if we want to use any _r()
5073   dnl functions - add tests for other functions here as well
5074   if test "$wx_cv_func_strtok_r" = "yes"; then
5075     AC_MSG_CHECKING(if -D_REENTRANT is needed)
5076     if test "$NEEDS_D_REENTRANT_FOR_R_FUNCS" = 1; then
5077         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_REENTRANT"
5078         AC_MSG_RESULT(yes)
5079     else
5080         AC_MSG_RESULT(no)
5081     fi
5082   fi
5083 fi
5084
5085 if test "$WXGTK20" = 1 ; then
5086   AC_DEFINE_UNQUOTED(__WXGTK20__,$WXGTK20)
5087   WXGTK12=1
5088 fi
5089
5090 if test "$WXGTK12" = 1 ; then
5091   AC_DEFINE_UNQUOTED(__WXGTK12__,$WXGTK12)
5092 fi
5093
5094 if test "$WXGTK127" = 1 ; then
5095   AC_DEFINE_UNQUOTED(__WXGTK127__,$WXGTK127)
5096 fi
5097
5098 if test "$WXGPE" = 1 ; then
5099   AC_DEFINE_UNQUOTED(__WXGPE__,$WXGPE)
5100 fi
5101
5102 dnl DEBUG_CFLAGS contains debugging options (supposed to be the same for C and C++
5103 dnl compilers: we'd need a separate DEBUG_CXXFLAGS if this is ever not the case)
5104 DEBUG_CFLAGS=
5105 if test "$wxUSE_DEBUG_INFO" = "yes" ; then
5106     DEBUG_CFLAGS="-g"
5107     wxUSE_OPTIMISE=no
5108 fi
5109
5110 if test "$wxUSE_DEBUG_GDB" = "yes" ; then
5111     wxUSE_DEBUG_INFO=yes
5112     if test "$GCC" = yes; then
5113         DEBUG_CFLAGS="-ggdb"
5114     fi
5115 fi
5116
5117 if test "$wxUSE_DEBUG_FLAG" = "yes" ; then
5118     AC_DEFINE(WXDEBUG)
5119     WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D__WXDEBUG__"
5120 else
5121     if test "$wxUSE_GTK" = 1 ; then
5122         if test "x$wxGTK_VERSION" = "x1" ; then
5123             CPPFLAGS="-DGTK_NO_CHECK_CASTS $CPPFLAGS"
5124         fi
5125     fi
5126 fi
5127
5128 if test "$wxUSE_MEM_TRACING" = "yes" ; then
5129     AC_DEFINE(wxUSE_MEMORY_TRACING)
5130     AC_DEFINE(wxUSE_GLOBAL_MEMORY_OPERATORS)
5131     AC_DEFINE(wxUSE_DEBUG_NEW_ALWAYS)
5132     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS memcheck"
5133 fi
5134
5135 if test "$wxUSE_DMALLOC" = "yes" ; then
5136     DMALLOC_LIBS="-ldmallocthcxx"
5137 fi
5138
5139 dnl cc/cxx/ld option for profiling
5140 PROFILE_FLAGS=
5141 if test "$wxUSE_PROFILE" = "yes" ; then
5142     PROFILE_FLAGS=" -pg"
5143 fi
5144
5145 if test "$GCC" = "yes" ; then
5146     if test "$wxUSE_NO_RTTI" = "yes" ; then
5147         WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fno-rtti"
5148     fi
5149     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
5150         WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fno-exceptions"
5151     fi
5152     if test "$wxUSE_PERMISSIVE" = "yes" ; then
5153         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -fpermissive"
5154     fi
5155
5156     dnl Ian Brown <ian.brown@printsoft.de> reports that versions of gcc before
5157     dnl 3.0 overflow the table of contents on rs6000 as they create an entry
5158     dnl for each subroutine by default -- using the switch below only creates
5159     dnl one entry per file instead at the price of minor performance penalty
5160     dnl
5161     dnl As of wx2.4 a bug in the hppa gcc compiler causes a similar problem
5162     dnl without -ffunction-sections.  No idea how long we'll need to maintain
5163     dnl this, or even the extent of gcc/wx version combinations affected, but
5164     dnl also as above, this 'fix' does not come without side effects.
5165     dnl
5166     dnl TODO: test for the gcc version here (how?)
5167     case "${host}" in
5168       powerpc*-*-aix* )
5169         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -mminimal-toc"
5170         ;;
5171       *-hppa* )
5172         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -ffunction-sections"
5173         ;;
5174     esac
5175 fi
5176
5177 dnl C/C++ compiler option for optimization (supposed to be the same for both)
5178 OPTIMISE_CFLAGS=
5179 if test "$wxUSE_OPTIMISE" = "no" ; then
5180     if test "$GCC" = yes ; then
5181         dnl use -O0 because compiling with it is faster than compiling with no
5182         dnl optimization options at all (at least with g++ 3.2)
5183         OPTIMISE_CFLAGS="-O0"
5184     fi
5185 else
5186     if test "$GCC" = yes ; then
5187         case "${host}" in
5188             *-pc-os2_emx | *-pc-os2-emx )
5189                 dnl Not all of the supported gcc versions understand
5190                 dnl -fstrict-aliasing and none actually needs it (yet).
5191                 OPTIMISE_CFLAGS="-O2"
5192             ;;
5193             *)
5194                 dnl Switch on optimisation but keep strict-aliasing off for
5195                 dnl now (see -fstrict-aliasing in the gcc manual). When it is
5196                 dnl switched back on consider using -Wstrict-aliasing=2.
5197                 OPTIMISE_CFLAGS="-O2 -fno-strict-aliasing"
5198             ;;
5199         esac
5200     else
5201         OPTIMISE_CFLAGS="-O"
5202     fi
5203 fi
5204
5205 dnl ---------------------------------------------------------------------------
5206 dnl compatibility level
5207 dnl ---------------------------------------------------------------------------
5208
5209 if test "x$WXWIN_COMPATIBILITY_2_6" = "xyes"; then
5210     AC_DEFINE(WXWIN_COMPATIBILITY_2_6)
5211
5212     WXWIN_COMPATIBILITY_2_8="yes"
5213 fi
5214
5215 if test "x$WXWIN_COMPATIBILITY_2_8" != "xno"; then
5216     AC_DEFINE(WXWIN_COMPATIBILITY_2_8)
5217 fi
5218
5219 dnl ---------------------------------------------------------------------------
5220 dnl the library may be built without GUI classes at all
5221 dnl ---------------------------------------------------------------------------
5222
5223 if test "$wxUSE_GUI" = "yes"; then
5224     AC_DEFINE(wxUSE_GUI)
5225
5226     dnl the things we always pull in the GUI version of the library:
5227     dnl 1. basic things like wxApp, wxWindow, wxControl, wxFrame, wxDialog (the
5228     dnl    library really can't be built without those)
5229     dnl 2. basic controls: wxButton, wxStaticText, wxTextCtrl (these are used in
5230     dnl    almost any program and the first 2 are needed to show a message box
5231     dnl    which want to be always able to do)
5232     dnl 3. GDI stuff: icon, cursors and all that. Although it would be very nice
5233     dnl    to compile without them (if the app doesn't do any drawing, it doesn't
5234     dnl    need the dcs, pens, brushes, ...), this just can't be done now
5235     dnl 4. menu stuff: wxMenu, wxMenuBar, wxMenuItem
5236     dnl 5. misc stuff: timers, settings, message box
5237 fi
5238
5239 dnl ---------------------------------------------------------------------------
5240 dnl Unix/Windows
5241 dnl ---------------------------------------------------------------------------
5242
5243 if test "$wxUSE_UNIX" = "yes"; then
5244   AC_DEFINE(wxUSE_UNIX)
5245 fi
5246
5247 dnl ------------------------------------------------------------------------
5248 dnl DLL support
5249 dnl ------------------------------------------------------------------------
5250
5251 dnl under MSW we always have LoadLibrary/GetProcAddress
5252 if test "$TOOLKIT" != "MSW" -a "$USE_OS2" != 1; then
5253
5254     HAVE_DL_FUNCS=0
5255     HAVE_SHL_FUNCS=0
5256     if test "$wxUSE_DYNAMIC_LOADER" = "yes" -o "$wxUSE_DYNLIB_CLASS" = "yes" ; then
5257         if test "$USE_DARWIN" = 1; then
5258             dnl dlopen/dlerror is implemented in dynlib.cpp for Darwin/Mac OS X
5259             HAVE_DL_FUNCS=1
5260         elif test "$USE_DOS" = 1; then
5261             HAVE_DL_FUNCS=0
5262         else
5263             dnl the test is a bit complicated because we check for dlopen() both with
5264             dnl and without -ldl and we also try to find shl_load() if there is no
5265             dnl dlopen() on this system
5266             AC_CHECK_FUNCS(dlopen,
5267             [
5268                 AC_DEFINE(HAVE_DLOPEN)
5269                 HAVE_DL_FUNCS=1
5270             ],
5271             [
5272                 AC_CHECK_LIB(dl, dlopen,
5273                             [
5274                                 AC_DEFINE(HAVE_DLOPEN)
5275                                 HAVE_DL_FUNCS=1
5276                                 DL_LINK=" -ldl$DL_LINK"
5277                             ],
5278                             [
5279                                 AC_CHECK_FUNCS(shl_load,
5280                                               [
5281                                                 AC_DEFINE(HAVE_SHL_LOAD)
5282                                                 HAVE_SHL_FUNCS=1
5283                                               ],
5284                                               [
5285                                                 AC_CHECK_LIB(shl_load, dld,
5286                                                              [
5287                                                                 HAVE_SHL_FUNCS=1
5288                                                                 DL_LINK=" -ldld$DL_LINK"
5289                                                              ])
5290                                               ])
5291                             ])
5292             ])
5293
5294         dnl check also for dlerror()
5295         if test "$HAVE_DL_FUNCS" = 1; then
5296             AC_CHECK_FUNCS(dlerror,
5297                 AC_DEFINE(HAVE_DLERROR),
5298                 [
5299                     AC_CHECK_LIB(dl, dlerror, AC_DEFINE(HAVE_DLERROR))
5300                 ]
5301             )
5302         fi
5303         fi
5304
5305         if test "$HAVE_DL_FUNCS" = 0; then
5306             if test "$HAVE_SHL_FUNCS" = 0; then
5307               if test "$USE_UNIX" = 1 -o "$USE_DOS" = 1; then
5308                   AC_MSG_WARN([Missing dynamic loading support, several features will be disabled])
5309                   wxUSE_DYNAMIC_LOADER=no
5310                   wxUSE_DYNLIB_CLASS=no
5311               else
5312                   AC_MSG_WARN([Assuming wxLibrary class works on this platform])
5313               fi
5314             fi
5315         fi
5316     fi
5317 fi
5318
5319 if test "$wxUSE_DYNAMIC_LOADER" = "yes" ; then
5320     AC_DEFINE(wxUSE_DYNAMIC_LOADER)
5321 fi
5322 if test "$wxUSE_DYNLIB_CLASS" = "yes" ; then
5323     AC_DEFINE(wxUSE_DYNLIB_CLASS)
5324 fi
5325
5326
5327 dnl ---------------------------------------------------------------------------
5328 dnl Verify consistency of plugins/monolithic/shared settings:
5329 dnl ---------------------------------------------------------------------------
5330
5331 if test "$wxUSE_PLUGINS" = "yes" ; then
5332     if test "$wxUSE_SHARED" = "no" ; then
5333         AC_MSG_WARN([plugins supported only in shared build, disabling])
5334         wxUSE_PLUGINS=no
5335     fi
5336     if test "$wxUSE_MONOLITHIC" = "yes" ; then
5337         AC_MSG_WARN([plugins not supported monolithic build, disabling])
5338         wxUSE_PLUGINS=no
5339     fi
5340     if test "$wxUSE_DYNLIB_CLASS" = "no" ; then
5341         AC_MSG_WARN([plugins require wxDynamicLibrary, disabling])
5342         wxUSE_PLUGINS=no
5343     fi
5344     if test "$wxUSE_PLUGINS" = "yes" ; then
5345         AC_DEFINE(wxUSE_PLUGINS)
5346     fi
5347 fi
5348
5349 dnl ---------------------------------------------------------------------------
5350 dnl Register non-GUI class options for makefiles and setup.h
5351 dnl ---------------------------------------------------------------------------
5352
5353 if test "$wxUSE_STL" = "yes"; then
5354   AC_DEFINE(wxUSE_STL)
5355 fi
5356
5357 if test "$wxUSE_EXTENDED_RTTI" = "yes"; then
5358   AC_DEFINE(wxUSE_EXTENDED_RTTI)
5359 fi
5360
5361 if test "$wxUSE_APPLE_IEEE" = "yes"; then
5362   AC_DEFINE(wxUSE_APPLE_IEEE)
5363 fi
5364
5365 if test "$wxUSE_TIMER" = "yes"; then
5366   AC_DEFINE(wxUSE_TIMER)
5367 fi
5368
5369 dnl Unix implementation needs additional checks because audio support
5370 dnl comes in many favours:
5371 if test "$USE_UNIX" = "1" ; then
5372     dnl mmedia doesn't compile with wxMGL, remove this if this is ever fixed
5373     if test "$wxUSE_MGL" != 1; then
5374         dnl it's not enough to check for just the header because OSS under NetBSD
5375         dnl redefines ioctl as oss_ioctrl inside it and so we also need to test
5376         dnl whether we need -lossaudio at link-time
5377         AC_CACHE_CHECK([for SNDCTL_DSP_SPEED in sys/soundcard.h], ac_cv_header_sys_soundcard, [
5378             AC_TRY_LINK([
5379                     #include <sys/ioctl.h>
5380                     #include <sys/soundcard.h>
5381                 ],
5382                 [
5383                     ioctl(0, SNDCTL_DSP_SPEED, 0);
5384                 ],
5385                 ac_cv_header_sys_soundcard=yes,
5386                 [
5387                     saveLibs="$LIBS"
5388                     LIBS="$saveLibs -lossaudio"
5389                     AC_TRY_LINK([
5390                             #include <sys/ioctl.h>
5391                             #include <sys/soundcard.h>
5392                         ],
5393                         [
5394                             ioctl(0, SNDCTL_DSP_SPEED, 0);
5395                         ],
5396                         ac_cv_header_sys_soundcard=yes,
5397                         [
5398                             LIBS="$saveLibs"
5399                             ac_cv_header_sys_soundcard=no
5400                         ]
5401                     )
5402                 ]
5403             )
5404         ])
5405     fi
5406
5407     if test "$ac_cv_header_sys_soundcard" = "yes"; then
5408         AC_DEFINE(HAVE_SYS_SOUNDCARD_H)
5409     fi
5410 fi
5411
5412 WITH_PLUGIN_SDL=0
5413 if test "$wxUSE_SOUND" = "yes"; then
5414   if test "$USE_UNIX" = "1" ; then
5415     if test "$wxUSE_LIBSDL" != "no"; then
5416       AM_PATH_SDL([1.2.0],
5417                   [
5418                     EXTRALIBS_SDL="$SDL_LIBS"
5419                     CFLAGS="$SDL_CFLAGS $CFLAGS"
5420                     CXXFLAGS="$SDL_CFLAGS $CXXFLAGS"
5421                     AC_DEFINE(wxUSE_LIBSDL)
5422                   ],
5423                   [wxUSE_LIBSDL="no"])
5424       if test "$wxUSE_LIBSDL" = "yes" -a "$wxUSE_PLUGINS" = "yes" ; then
5425         WITH_PLUGIN_SDL=1
5426       fi
5427     fi
5428   else
5429     dnl wxMGL doesn't support sound under DOS, only under Unix
5430     if test "$wxUSE_MGL" = 1; then
5431         AC_MSG_WARN([wxSound not supported in MGL under DOS... disabled])
5432         wxUSE_SOUND="no"
5433     fi
5434   fi
5435 fi
5436
5437 if test "$wxUSE_SOUND" = "yes"; then
5438   AC_DEFINE(wxUSE_SOUND)
5439   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sound"
5440 fi
5441
5442 if test "$WXGTK20" = 1; then
5443     PKG_PROG_PKG_CONFIG()
5444
5445     if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
5446         if test "$wxUSE_LIBGNOMEPRINT" = "yes" ; then
5447
5448                 PKG_CHECK_MODULES(LIBGNOMEPRINTUI,
5449                                   [libgnomeprintui-2.2 >= 2.8],
5450                     [
5451                         CFLAGS="$LIBGNOMEPRINTUI_CFLAGS $CFLAGS"
5452                         CXXFLAGS="$LIBGNOMEPRINTUI_CFLAGS $CXXFLAGS"
5453                         AC_DEFINE(wxUSE_LIBGNOMEPRINT)
5454                     ],
5455                     [
5456                         AC_MSG_WARN([libgnomeprintui not found, library will use standard PostScript printing])
5457                         wxUSE_LIBGNOMEPRINT="no"
5458                     ]
5459                 )
5460         fi
5461     fi
5462
5463     if test "$wxUSE_MIMETYPE" = "yes" ; then
5464         if test "$wxUSE_LIBGNOMEVFS" = "yes" ; then
5465
5466                 PKG_CHECK_MODULES(GNOMEVFS,
5467                                   [gnome-vfs-2.0 >= 2.0],
5468                     [
5469                         CFLAGS="$GNOMEVFS_CFLAGS $CFLAGS"
5470                         CXXFLAGS="$GNOMEVFS_CFLAGS $CXXFLAGS"
5471                         AC_DEFINE(wxUSE_LIBGNOMEVFS)
5472                     ],
5473                     [
5474                         AC_MSG_WARN([libgnomevfs not found, library won't be able to associate MIME type])
5475                         wxUSE_LIBGNOMEVFS="no"
5476                     ]
5477                 )
5478         fi
5479     fi
5480
5481     if test "$wxUSE_LIBHILDON" = "yes" ; then
5482         PKG_CHECK_MODULES(HILDON,
5483                           [hildon-lgpl >= 0.9],
5484             [
5485                 EXTRALIBS_HILDON="$HILDON_LIBS"
5486                 CFLAGS="$CFLAGS $HILDON_CFLAGS"
5487                 CXXFLAGS="$CXXFLAGS $HILDON_CFLAGS"
5488                 AC_DEFINE(wxUSE_LIBHILDON)
5489             ],
5490             [
5491                 AC_MSG_WARN([libhildon_lgpl not found])
5492                         wxUSE_LIBHILDON="no"
5493             ]
5494         )
5495     fi
5496 fi
5497
5498 if test "$wxUSE_CMDLINE_PARSER" = "yes"; then
5499   AC_DEFINE(wxUSE_CMDLINE_PARSER)
5500 fi
5501
5502 if test "$wxUSE_STOPWATCH" = "yes"; then
5503   AC_DEFINE(wxUSE_STOPWATCH)
5504 fi
5505
5506 if test "$wxUSE_DATETIME" = "yes"; then
5507   AC_DEFINE(wxUSE_DATETIME)
5508 fi
5509
5510 if test "$wxUSE_FILE" = "yes"; then
5511   AC_DEFINE(wxUSE_FILE)
5512 fi
5513
5514 if test "$wxUSE_FFILE" = "yes"; then
5515   AC_DEFINE(wxUSE_FFILE)
5516 fi
5517
5518 if test "$wxUSE_ARCHIVE_STREAMS" = "yes"; then
5519   if test "$wxUSE_STREAMS" != yes; then
5520     AC_MSG_WARN(wxArchive requires wxStreams... disabled)
5521     wxUSE_ARCHIVE_STREAMS=no
5522   else
5523     AC_DEFINE(wxUSE_ARCHIVE_STREAMS)
5524   fi
5525 fi
5526
5527 if test "$wxUSE_ZIPSTREAM" = "yes"; then
5528   if test "$wxUSE_ARCHIVE_STREAMS" != "yes"; then
5529     AC_MSG_WARN(wxZip requires wxArchive... disabled)
5530   elif test "$wxUSE_ZLIB" = "no"; then
5531     AC_MSG_WARN(wxZip requires wxZlib... disabled)
5532   else
5533     AC_DEFINE(wxUSE_ZIPSTREAM)
5534   fi
5535 fi
5536
5537 if test "$wxUSE_TARSTREAM" = "yes"; then
5538   if test "$wxUSE_ARCHIVE_STREAMS" != "yes"; then
5539     AC_MSG_WARN(wxTar requires wxArchive... disabled)
5540   else
5541     AC_DEFINE(wxUSE_TARSTREAM)
5542   fi
5543 fi
5544
5545 if test "$wxUSE_FILESYSTEM" = "yes"; then
5546   if test "$wxUSE_STREAMS" != yes -o \( "$wxUSE_FILE" != yes -a "$wxUSE_FFILE" != yes \); then
5547     AC_MSG_WARN(wxFileSystem requires wxStreams and wxFile or wxFFile... disabled)
5548     wxUSE_FILESYSTEM=no
5549   else
5550     AC_DEFINE(wxUSE_FILESYSTEM)
5551   fi
5552 fi
5553
5554 if test "$wxUSE_FS_ARCHIVE" = "yes"; then
5555   if test "$wxUSE_FILESYSTEM" != yes -o "$wxUSE_ARCHIVE_STREAMS" != yes; then
5556     AC_MSG_WARN(wxArchiveFSHandler requires wxArchive and wxFileSystem... disabled)
5557   else
5558     AC_DEFINE(wxUSE_FS_ARCHIVE)
5559   fi
5560 fi
5561
5562 if test "$wxUSE_FS_ZIP" = "yes"; then
5563   if test "$wxUSE_FS_ARCHIVE" != yes; then
5564     AC_MSG_WARN(wxZipFSHandler requires wxArchiveFSHandler... disabled)
5565   else
5566     AC_DEFINE(wxUSE_FS_ZIP)
5567   fi
5568 fi
5569
5570 if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
5571   if test "$USE_UNIX" != 1; then
5572     AC_MSG_WARN([Catching fatal exceptions not currently supported on this system, wxApp::OnFatalException will not be called])
5573     wxUSE_ON_FATAL_EXCEPTION=no
5574   else
5575     AC_DEFINE(wxUSE_ON_FATAL_EXCEPTION)
5576   fi
5577 fi
5578
5579 if test "$wxUSE_STACKWALKER" = "yes"; then
5580     AC_DEFINE(wxUSE_STACKWALKER)
5581 fi
5582
5583 if test "$wxUSE_DEBUGREPORT" = "yes"; then
5584     if test "$USE_UNIX" != "1" -a "$USE_WIN32" != "1"; then
5585         AC_MSG_WARN([Creating debug reports not currently supported on this system, disabled])
5586         wxUSE_DEBUGREPORT=no
5587     else
5588         AC_DEFINE(wxUSE_DEBUGREPORT)
5589         if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
5590             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS debugrpt"
5591         fi
5592     fi
5593 fi
5594
5595 if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
5596   AC_DEFINE(wxUSE_SNGLINST_CHECKER)
5597 fi
5598
5599 if test "$wxUSE_BUSYINFO" = "yes"; then
5600   AC_DEFINE(wxUSE_BUSYINFO)
5601 fi
5602
5603 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
5604   AC_DEFINE(wxUSE_STD_IOSTREAM)
5605 fi
5606
5607 if test "$wxUSE_STD_STRING" = "yes"; then
5608   AC_DEFINE(wxUSE_STD_STRING)
5609 fi
5610
5611 if test "$wxUSE_STDPATHS" = "yes"; then
5612   AC_DEFINE(wxUSE_STDPATHS)
5613 fi
5614
5615 if test "$wxUSE_TEXTBUFFER" = "yes"; then
5616     AC_DEFINE(wxUSE_TEXTBUFFER)
5617 fi
5618
5619 if test "$wxUSE_TEXTFILE" = "yes"; then
5620   if test "$wxUSE_FILE" != "yes" -o "$wxUSE_TEXTBUFFER" != "yes" ; then
5621     AC_MSG_WARN(wxTextFile requires wxFile and wxTextBuffer... disabled)
5622   else
5623     AC_DEFINE(wxUSE_TEXTFILE)
5624   fi
5625 fi
5626
5627 if test "$wxUSE_CONFIG" = "yes" ; then
5628   if test "$wxUSE_TEXTFILE" != "yes"; then
5629     AC_MSG_WARN(wxConfig requires wxTextFile... disabled)
5630   else
5631     AC_DEFINE(wxUSE_CONFIG)
5632     AC_DEFINE(wxUSE_CONFIG_NATIVE)
5633     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS config"
5634   fi
5635 fi
5636
5637 if test "$wxUSE_INTL" = "yes" ; then
5638   if test "$wxUSE_FILE" != "yes"; then
5639     AC_MSG_WARN(I18n code requires wxFile... disabled)
5640   else
5641     AC_DEFINE(wxUSE_INTL)
5642     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS internat"
5643     GUIDIST="$GUIDIST INTL_DIST"
5644   fi
5645 fi
5646
5647 if test "$wxUSE_LOG" = "yes"; then
5648   AC_DEFINE(wxUSE_LOG)
5649
5650     if test "$wxUSE_LOGGUI" = "yes"; then
5651       AC_DEFINE(wxUSE_LOGGUI)
5652     fi
5653
5654     if test "$wxUSE_LOGWINDOW" = "yes"; then
5655       AC_DEFINE(wxUSE_LOGWINDOW)
5656     fi
5657
5658     if test "$wxUSE_LOGDIALOG" = "yes"; then
5659       AC_DEFINE(wxUSE_LOG_DIALOG)
5660     fi
5661
5662     dnl the keyboard sample requires wxUSE_LOG
5663     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS keyboard"
5664 fi
5665
5666 if test "$wxUSE_LONGLONG" = "yes"; then
5667   AC_DEFINE(wxUSE_LONGLONG)
5668 fi
5669
5670 if test "$wxUSE_GEOMETRY" = "yes"; then
5671   AC_DEFINE(wxUSE_GEOMETRY)
5672 fi
5673
5674 if test "$wxUSE_BASE64" = "yes"; then
5675   AC_DEFINE(wxUSE_BASE64)
5676 fi
5677
5678 if test "$wxUSE_STREAMS" = "yes" ; then
5679   AC_DEFINE(wxUSE_STREAMS)
5680 fi
5681
5682 if test "$wxUSE_PRINTF_POS_PARAMS" = "yes"; then
5683   AC_DEFINE(wxUSE_PRINTF_POS_PARAMS)
5684 fi
5685
5686 if test "$wxUSE_OBJC_UNIQUIFYING" = "yes"; then
5687   AC_DEFINE(wxUSE_OBJC_UNIQUIFYING)
5688 fi
5689
5690 dnl ---------------------------------------------------------------------------
5691 dnl time/date functions
5692 dnl ---------------------------------------------------------------------------
5693
5694 if test "$wxUSE_DATETIME" = "yes"; then
5695     dnl check for strptime and for its declaration as some systems lack it
5696     AC_CHECK_FUNC(strptime)
5697     if test "$ac_cv_func_strptime" = "yes"; then
5698         AC_CACHE_CHECK([for strptime declaration], wx_cv_func_strptime_decl,
5699             [
5700                 AC_LANG_PUSH(C++)
5701                 AC_TRY_COMPILE(
5702                     [
5703                         #include <time.h>
5704                     ],
5705                     [
5706                         struct tm t;
5707                         strptime("foo", "bar", &t);
5708                     ],
5709                     wx_cv_func_strptime_decl=yes,
5710                     wx_cv_func_strptime_decl=no
5711                 )
5712                 AC_LANG_POP()
5713             ]
5714         )
5715     fi
5716     if test "$wx_cv_func_strptime_decl" = "yes"; then
5717         AC_DEFINE(HAVE_STRPTIME_DECL)
5718     else
5719         wx_strptime_decl="extern char *strptime(const char *, const char *, struct tm *);"
5720     fi
5721     if test "$ac_cv_func_strptime" = "yes"; then
5722         dnl strptime() behaviour doesn't conform to POSIX under Mac OS X <
5723         dnl 10.5 and possibly other BSD variants, check that strptime() we
5724         dnl have fails to parse format when the string doesn't match it instea
5725         dnl of just stopping immediately and returning non-NULL
5726         AC_CACHE_CHECK([whether strptime() fails on invalid strings],
5727             wx_cv_func_strptime_ok,
5728             [AC_RUN_IFELSE(
5729                 [
5730                     #include <stdlib.h>
5731                     #include <time.h>
5732                     #include "confdefs.h"
5733
5734                     $wx_strptime_decl
5735
5736                     int main()
5737                     {
5738                         struct tm t;
5739                         return !!strptime("", "%x", &t);
5740                     }
5741                 ],
5742                 wx_cv_func_strptime_ok=yes,
5743                 wx_cv_func_strptime_ok=no,
5744                 dnl be pessimistic when cross-compiling
5745                 wx_cv_func_strptime_ok=no
5746             )]
5747         )
5748
5749         if test "$wx_cv_func_strptime_ok" = "yes"; then
5750             AC_DEFINE(HAVE_STRPTIME)
5751         fi
5752     fi
5753
5754     dnl check for timezone variable
5755     dnl   doesn't exist under Darwin / Mac OS X which uses tm_gmtoff instead
5756     AC_CACHE_CHECK(for timezone variable in <time.h>,
5757                    wx_cv_var_timezone,
5758                    [
5759                         AC_LANG_PUSH(C++)
5760                         AC_TRY_COMPILE(
5761                             [
5762                                 #include <time.h>
5763                             ],
5764                             [
5765                                 int tz;
5766                                 tz = timezone;
5767                             ],
5768                             [
5769                                 wx_cv_var_timezone=timezone
5770                             ],
5771                             [
5772                                 AC_TRY_COMPILE(
5773                                     [
5774                                         #include <time.h>
5775                                     ],
5776                                     [
5777                                         int tz;
5778                                         tz = _timezone;
5779                                     ],
5780                                     [
5781                                         wx_cv_var_timezone=_timezone
5782                                     ],
5783                                     [
5784                                         AC_TRY_COMPILE(
5785                                             [
5786                                                 #include <time.h>
5787                                             ],
5788                                             [
5789                                                 int tz;
5790                                                 tz = __timezone;
5791                                             ],
5792                                             [
5793                                                 wx_cv_var_timezone=__timezone
5794                                             ],
5795                                             [
5796                                                 if test "$USE_DOS" = 0 ; then
5797                                                     AC_MSG_WARN(no timezone variable, will use tm_gmtoff instead)
5798                                                 fi
5799                                             ]
5800                                         )
5801                                     ]
5802                                 )
5803                             ]
5804                         )
5805                         AC_LANG_POP()
5806                    ]
5807     )
5808
5809     dnl as we want $wx_cv_var_timezone to be expanded, use AC_DEFINE_UNQUOTED
5810     if test "x$wx_cv_var_timezone" != x ; then
5811         AC_DEFINE_UNQUOTED(WX_TIMEZONE, $wx_cv_var_timezone)
5812     fi
5813
5814     dnl check for localtime (it's POSIX, but the check can do no harm...)
5815     AC_CHECK_FUNCS(localtime)
5816
5817     if test "$ac_cv_func_localtime" = "yes"; then
5818         AC_CACHE_CHECK(for tm_gmtoff in struct tm,
5819                        wx_cv_struct_tm_has_gmtoff,
5820         [
5821             AC_TRY_COMPILE(
5822                 [
5823                     #include <time.h>
5824                 ],
5825                 [
5826                     struct tm tm;
5827                     tm.tm_gmtoff++;
5828                 ],
5829                 [
5830                     wx_cv_struct_tm_has_gmtoff=yes
5831                 ],
5832                 wx_cv_struct_tm_has_gmtoff=no
5833             )
5834         ])
5835     fi
5836
5837     if test "$wx_cv_struct_tm_has_gmtoff" = "yes"; then
5838         AC_DEFINE(WX_GMTOFF_IN_TM)
5839     fi
5840
5841     dnl check for gettimeofday (SVr4, BSD 4.3) and ftime (V7, BSD 4.3) for the
5842     dnl function to be used for high resolution timers
5843     AC_CHECK_FUNCS(gettimeofday ftime, break)
5844
5845     if test "$ac_cv_func_gettimeofday" = "yes"; then
5846         AC_CACHE_CHECK([whether gettimeofday takes two arguments],
5847                        wx_cv_func_gettimeofday_has_2_args,
5848         [
5849             dnl on some _really_ old systems it takes only 1 argument
5850             AC_TRY_COMPILE(
5851                 [
5852                     #include <sys/time.h>
5853                     #include <unistd.h>
5854                 ],
5855                 [
5856                     struct timeval tv;
5857                     gettimeofday(&tv, NULL);
5858                 ],
5859                 wx_cv_func_gettimeofday_has_2_args=yes,
5860                 AC_TRY_COMPILE(
5861                     [
5862                         #include <sys/time.h>
5863                         #include <unistd.h>
5864                     ],
5865                     [
5866                         struct timeval tv;
5867                         gettimeofday(&tv);
5868                     ],
5869                     wx_cv_func_gettimeofday_has_2_args=no,
5870                     [
5871                         AC_MSG_WARN([failed to determine number of gettimeofday() arguments])
5872                         wx_cv_func_gettimeofday_has_2_args=unknown
5873                     ]
5874                 )
5875             )
5876         ])
5877
5878         if test "$wx_cv_func_gettimeofday_has_2_args" != "yes"; then
5879             AC_DEFINE(WX_GETTIMEOFDAY_NO_TZ)
5880         fi
5881     fi
5882
5883     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS typetest"
5884 fi
5885
5886 dnl ------------------------------------------------------------------------
5887 dnl wxSocket
5888 dnl ------------------------------------------------------------------------
5889
5890 dnl VZ: the GUI hooks wxSocket needs are not implemented yet in some toolkits
5891 if test "$wxUSE_SOCKETS" = "yes"; then
5892     if test "$wxUSE_MGL" = "1"; then
5893         AC_MSG_WARN([wxSocket not yet supported under MGL... disabled])
5894         wxUSE_SOCKETS="no"
5895     fi
5896 fi
5897
5898 if test "$wxUSE_SOCKETS" = "yes"; then
5899     dnl under MSW we always have sockets
5900     if test "$TOOLKIT" != "MSW"; then
5901         dnl under Solaris and OS/2, socket functions live in -lsocket
5902         AC_CHECK_FUNC(socket,,
5903             [
5904                 AC_CHECK_LIB(socket, socket,
5905                     if test "$INET_LINK" != " -lsocket"; then
5906                         INET_LINK="$INET_LINK -lsocket"
5907                     fi,
5908                     [
5909                         AC_MSG_WARN([socket library not found - sockets will be disabled])
5910                         wxUSE_SOCKETS=no
5911                     ]
5912                 )
5913             ]
5914         )
5915     fi
5916 fi
5917
5918 if test "$wxUSE_SOCKETS" = "yes" ; then
5919     dnl this test may be appropriate if building under cygwin
5920     dnl right now I'm assuming it also uses the winsock stuff
5921     dnl like mingw does..  -- RL
5922     if test "$TOOLKIT" != "MSW"; then
5923         dnl determine the type of third argument for getsockname
5924         dnl This test needs to be done in C++ mode since gsocket.cpp now
5925         dnl is C++ code and pointer cast that are possible even without
5926         dnl warning in C still fail in C++.
5927         AC_CACHE_CHECK([what is the type of the third argument of getsockname],
5928                        wx_cv_type_getsockname3,
5929             [
5930                 AC_LANG_PUSH(C++)
5931                 AC_TRY_COMPILE(
5932                     [
5933                         #include <sys/types.h>
5934                         #include <sys/socket.h>
5935                     ],
5936                     [
5937                         socklen_t len;
5938                         getsockname(0, 0, &len);
5939                     ],
5940                     wx_cv_type_getsockname3=socklen_t,
5941                     [
5942                         dnl the compiler will compile the version with size_t
5943                         dnl even if the real type of the last parameter is int
5944                         dnl but it should give at least a warning about
5945                         dnl converting between incompatible pointer types, so
5946                         dnl try to use it to get the correct behaviour at
5947                         dnl least with gcc (otherwise we'd always use size_t)
5948                         CFLAGS_OLD="$CFLAGS"
5949                         if test "$GCC" = yes ; then
5950                             CFLAGS="-Werror $CFLAGS"
5951                         fi
5952
5953                         AC_TRY_COMPILE(
5954                             [
5955                                 #include <sys/types.h>
5956                                 #include <sys/socket.h>
5957                             ],
5958                             [
5959                                 size_t len;
5960                                 getsockname(0, 0, &len);
5961                             ],
5962                             wx_cv_type_getsockname3=size_t,
5963                             AC_TRY_COMPILE(
5964                                 [
5965                                     #include <sys/types.h>
5966                                     #include <sys/socket.h>
5967                                 ],
5968                                 [
5969                                     int len;
5970                                     getsockname(0, 0, &len);
5971                                 ],
5972                                 wx_cv_type_getsockname3=int,
5973                                 wx_cv_type_getsockname3=unknown
5974                             )
5975                         )
5976
5977                         CFLAGS="$CFLAGS_OLD"
5978                     ]
5979                 )
5980                 AC_LANG_POP()
5981             ])
5982
5983         if test "$wx_cv_type_getsockname3" = "unknown"; then
5984             wxUSE_SOCKETS=no
5985             AC_MSG_WARN([Couldn't find socklen_t synonym for this system])
5986         else
5987             AC_DEFINE_UNQUOTED(WX_SOCKLEN_T, $wx_cv_type_getsockname3)
5988         fi
5989         dnl Do this again for getsockopt as it may be different
5990         AC_CACHE_CHECK([what is the type of the fifth argument of getsockopt],
5991                        wx_cv_type_getsockopt5,
5992             [
5993                 dnl Note that the rules for compatibility of pointers
5994                 dnl are somewhat different between C and C++, so code
5995                 dnl that fails in C++ may not even give a warning about
5996                 dnl converting between incompatible pointer types in C.
5997                 dnl So this test needs to be done in C++ mode.
5998                 AC_LANG_PUSH(C++)
5999                 AC_TRY_COMPILE(
6000                     [
6001                         #include <sys/types.h>
6002                         #include <sys/socket.h>
6003                     ],
6004                     [
6005                         socklen_t len;
6006                         getsockopt(0, 0, 0, 0, &len);
6007                     ],
6008                     wx_cv_type_getsockopt5=socklen_t,
6009                     [
6010                         AC_TRY_COMPILE(
6011                             [
6012                                 #include <sys/types.h>
6013                                 #include <sys/socket.h>
6014                             ],
6015                             [
6016                                 size_t len;
6017                                 getsockopt(0, 0, 0, 0, &len);
6018                             ],
6019                             wx_cv_type_getsockopt5=size_t,
6020                             AC_TRY_COMPILE(
6021                                 [
6022                                     #include <sys/types.h>
6023                                     #include <sys/socket.h>
6024                                 ],
6025                                 [
6026                                     int len;
6027                                     getsockopt(0, 0, 0, 0, &len);
6028                                 ],
6029                                 wx_cv_type_getsockopt5=int,
6030                                 wx_cv_type_getsockopt5=unknown
6031                             )
6032                         )
6033                     ]
6034                 )
6035                 AC_LANG_POP()
6036             ])
6037
6038         if test "$wx_cv_type_getsockopt5" = "unknown"; then
6039             wxUSE_SOCKETS=no
6040             AC_MSG_WARN([Couldn't find socklen_t synonym for this system])
6041         else
6042             AC_DEFINE_UNQUOTED(SOCKOPTLEN_T, $wx_cv_type_getsockopt5)
6043         fi
6044     fi
6045 fi
6046
6047 if test "$wxUSE_SOCKETS" = "yes" ; then
6048     AC_DEFINE(wxUSE_SOCKETS)
6049     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sockets"
6050 fi
6051
6052 if test "$wxUSE_PROTOCOL" = "yes"; then
6053     if test "$wxUSE_SOCKETS" != "yes"; then
6054         AC_MSG_WARN(Protocol classes require sockets... disabled)
6055         wxUSE_PROTOCOL=no
6056     fi
6057 fi
6058
6059 if test "$wxUSE_PROTOCOL" = "yes"; then
6060     AC_DEFINE(wxUSE_PROTOCOL)
6061
6062     if test "$wxUSE_PROTOCOL_HTTP" = "yes"; then
6063         AC_DEFINE(wxUSE_PROTOCOL_HTTP)
6064     fi
6065     if test "$wxUSE_PROTOCOL_FTP" = "yes"; then
6066         AC_DEFINE(wxUSE_PROTOCOL_FTP)
6067     fi
6068     if test "$wxUSE_PROTOCOL_FILE" = "yes"; then
6069         AC_DEFINE(wxUSE_PROTOCOL_FILE)
6070     fi
6071 else
6072     if test "$wxUSE_FS_INET" = "yes"; then
6073         AC_MSG_WARN([HTTP filesystem require protocol classes... disabled])
6074         wxUSE_FS_INET="no"
6075     fi
6076 fi
6077
6078 if test "$wxUSE_URL" = "yes"; then
6079     if test "$wxUSE_PROTOCOL" != "yes"; then
6080         AC_MSG_WARN(wxURL class requires wxProtocol... disabled)
6081         wxUSE_URL=no
6082     fi
6083     if test "$wxUSE_URL" = "yes"; then
6084         AC_DEFINE(wxUSE_URL)
6085     fi
6086 fi
6087
6088 if test "$wxUSE_VARIANT" = "yes"; then
6089     AC_DEFINE(wxUSE_VARIANT)
6090 fi
6091
6092 if test "$wxUSE_FS_INET" = "yes"; then
6093   AC_DEFINE(wxUSE_FS_INET)
6094 fi
6095
6096 dnl ---------------------------------------------------------------------------
6097 dnl Joystick support
6098 dnl ---------------------------------------------------------------------------
6099
6100 if test "$wxUSE_GUI" = "yes" -a "$wxUSE_JOYSTICK" = "yes"; then
6101     wxUSE_JOYSTICK=no
6102
6103     dnl under MSW we always have joystick support
6104     if test "$TOOLKIT" = "MSW"; then
6105         wxUSE_JOYSTICK=yes
6106
6107     dnl mac only available on darwin
6108     elif test "$TOOLKIT" = "MAC" -o "$TOOLKIT" = "COCOA"; then
6109         if test "$USE_DARWIN" = 1; then
6110             dnl check for a bug in the headers, some have bad setEventCallout
6111             AC_MSG_CHECKING([headers have declarations needed for joystick support])
6112             AC_LANG_PUSH(C++)
6113             AC_TRY_COMPILE( [ #include <IOKit/hid/IOHIDLib.h> ],
6114                             [ IOHIDQueueInterface *qi = NULL;
6115                               IOHIDCallbackFunction cb = NULL;
6116                               qi->setEventCallout(NULL, cb, NULL, NULL); ],
6117                             [ wxUSE_JOYSTICK=yes ]
6118                           )
6119             AC_LANG_POP()
6120             AC_MSG_RESULT($wxUSE_JOYSTICK)
6121         fi
6122
6123     dnl joystick support is only for Linux 2.1.x or greater
6124     else
6125         dnl wxJoystick not supported by wxMGL at all
6126         if test "$wxUSE_MGL" != "1"; then
6127             dnl notice the dummy includes argument: without it, AC_CHECK_HEADER
6128             dnl checks only whether the header can be preprocessed, not that it
6129             dnl can be compiled and in Linux 2.6.16 joystick.h is present but
6130             dnl can't be compiled because of an error and with the default
6131             dnl AC_CHECK_HEADER semantics we'd still detect it in this case and
6132             dnl build would fail later
6133             AC_CHECK_HEADER(linux/joystick.h, [wxUSE_JOYSTICK=yes],, [AC_INCLUDES_DEFAULT()])
6134         fi
6135     fi
6136
6137     if test "$wxUSE_JOYSTICK" = "yes"; then
6138         AC_DEFINE(wxUSE_JOYSTICK)
6139         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS joytest"
6140     else
6141         AC_MSG_WARN(Joystick not supported by this system... disabled)
6142     fi
6143 fi
6144
6145
6146 dnl ---------------------------------------------------------------------------
6147 dnl String stuff
6148 dnl ---------------------------------------------------------------------------
6149
6150 if test "$wxUSE_FONTMAP" = "yes" ; then
6151   AC_DEFINE(wxUSE_FONTMAP)
6152 fi
6153
6154 if test "$wxUSE_UNICODE" = "yes" ; then
6155   AC_DEFINE(wxUSE_UNICODE)
6156
6157   if test "$USE_WIN32" != 1; then
6158       wxUSE_UNICODE_MSLU=no
6159   fi
6160
6161   if test "$USE_WIN32" = 1 -a "$wxUSE_UNICODE_MSLU" = "yes"; then
6162         AC_CHECK_LIB(unicows,main,
6163             [
6164                 AC_DEFINE(wxUSE_UNICODE_MSLU)
6165             ],
6166             [
6167                 AC_MSG_WARN([Compiler doesn't support MSLU (libunicows.a), disabled.
6168                              Applications will only run on Windows NT/2000/XP!])
6169                 wxUSE_UNICODE_MSLU=no
6170             ])
6171     fi
6172 fi
6173
6174 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_UTF8" = "yes"; then
6175     AC_DEFINE(wxUSE_UNICODE_UTF8)
6176
6177     if test "$wxUSE_UNICODE_UTF8_LOCALE" = "yes"; then
6178         AC_DEFINE(wxUSE_UTF8_LOCALE_ONLY)
6179     fi
6180 fi
6181
6182 if test "$wxUSE_wxUSE_EXPERIMENTAL_PRINTF" = "yes"; then
6183   AC_DEFINE(wxUSE_EXPERIMENTAL_PRINTF)
6184 fi
6185
6186 dnl ---------------------------------------------------------------------------
6187 dnl big GUI components: MDI, doc/view, printing, help, ...
6188 dnl ---------------------------------------------------------------------------
6189
6190 if test "$wxUSE_CONSTRAINTS" = "yes"; then
6191     AC_DEFINE(wxUSE_CONSTRAINTS)
6192     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS layout"
6193 fi
6194
6195 if test "$wxUSE_MDI" = "yes"; then
6196     AC_DEFINE(wxUSE_MDI)
6197
6198     if test "$wxUSE_MDI_ARCHITECTURE" = "yes"; then
6199         AC_DEFINE(wxUSE_MDI_ARCHITECTURE)
6200         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mdi"
6201     fi
6202 fi
6203
6204 if test "$wxUSE_DOC_VIEW_ARCHITECTURE" = "yes" ; then
6205     AC_DEFINE(wxUSE_DOC_VIEW_ARCHITECTURE)
6206     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS docview"
6207     if test "$wxUSE_MDI_ARCHITECTURE" = "yes"; then
6208         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS docvwmdi"
6209     fi
6210 fi
6211
6212 if test "$wxUSE_HELP" = "yes"; then
6213     AC_DEFINE(wxUSE_HELP)
6214     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS help"
6215
6216     if test "$wxUSE_MSW" = 1; then
6217       if test "$wxUSE_MS_HTML_HELP" = "yes"; then
6218         AC_DEFINE(wxUSE_MS_HTML_HELP)
6219       fi
6220     fi
6221
6222     if test "$wxUSE_WXHTML_HELP" = "yes"; then
6223       if test "$wxUSE_HTML" = "yes"; then
6224         AC_DEFINE(wxUSE_WXHTML_HELP)
6225       else
6226         AC_MSG_WARN(Cannot use wxHTML-based help without wxHTML so it won't be compiled)
6227         wxUSE_WXHTML_HELP=no
6228       fi
6229     fi
6230 fi
6231
6232 if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
6233     if test "$wxUSE_CONSTRAINTS" != "yes"; then
6234         AC_MSG_WARN(Printing support cannot be used without constraints so it won't be compiled without it)
6235     else
6236         AC_DEFINE(wxUSE_PRINTING_ARCHITECTURE)
6237     fi
6238     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS printing"
6239 fi
6240
6241 if test "$wxUSE_POSTSCRIPT" = "yes" ; then
6242   AC_DEFINE(wxUSE_POSTSCRIPT)
6243 fi
6244
6245 AC_DEFINE(wxUSE_AFM_FOR_POSTSCRIPT)
6246
6247 AC_DEFINE(wxUSE_NORMALIZED_PS_FONTS)
6248
6249 if test "$wxUSE_SVG" = "yes"; then
6250     AC_DEFINE(wxUSE_SVG)
6251 fi
6252
6253 dnl ---------------------------------------------------------------------------
6254 dnl wxMetafile availability
6255 dnl ---------------------------------------------------------------------------
6256
6257 if test "$wxUSE_METAFILE" = "yes"; then
6258     if test "$wxUSE_MSW" != 1 -a "$wxUSE_MAC" != 1 -a "$wxUSE_PM" != 1; then
6259         AC_MSG_WARN([wxMetafile is not available on this system... disabled])
6260         wxUSE_METAFILE=no
6261     fi
6262 fi
6263
6264 dnl ---------------------------------------------------------------------------
6265 dnl IPC: IPC, Drag'n'Drop, Clipboard, ...
6266 dnl ---------------------------------------------------------------------------
6267
6268 dnl check for ole headers and disable a few features requiring it if not
6269 dnl present (earlier versions of mingw32 don't have ole2.h)
6270 if test "$USE_WIN32" = 1 -a \( "$wxUSE_DATAOBJ"       = "yes" \
6271                           -o "$wxUSE_CLIPBOARD"     = "yes" \
6272                           -o "$wxUSE_OLE"     = "yes" \
6273                           -o "$wxUSE_DRAG_AND_DROP" = "yes" \) ; then
6274     AC_CHECK_HEADER(ole2.h,,, [ ])
6275
6276     if test "$ac_cv_header_ole2_h" = "yes" ; then
6277         if test "$GCC" = yes ; then
6278             AC_MSG_CHECKING([if g++ requires -fvtable-thunks])
6279             AC_TRY_COMPILE([#include <windows.h>
6280                             #include <ole2.h>],
6281                            [],
6282                            [AC_MSG_RESULT(no)],
6283                            [AC_MSG_RESULT(yes)
6284                             WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fvtable-thunks"])
6285             LIBS=" -lrpcrt4 -loleaut32 -lole32 -luuid$LIBS"
6286             if test "$wxUSE_OLE" = "yes" ; then
6287                 AC_DEFINE(wxUSE_OLE)
6288                 AC_DEFINE(wxUSE_OLE_AUTOMATION)
6289                 AC_DEFINE(wxUSE_ACTIVEX)
6290                 SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS oleauto"
6291             fi
6292         fi
6293
6294         dnl for OLE clipboard and dnd
6295         if test "$wxUSE_DATAOBJ" = "yes" ; then
6296             AC_DEFINE(wxUSE_DATAOBJ)
6297         fi
6298     else
6299         AC_MSG_WARN([Some features disabled because OLE headers not found])
6300
6301         wxUSE_CLIPBOARD=no
6302         wxUSE_DRAG_AND_DROP=no
6303         wxUSE_DATAOBJ=no
6304         wxUSE_OLE=no
6305     fi
6306
6307     if test "$wxUSE_METAFILE" = "yes"; then
6308         AC_DEFINE(wxUSE_METAFILE)
6309
6310         dnl this one should probably be made separately configurable
6311         AC_DEFINE(wxUSE_ENH_METAFILE)
6312     fi
6313 fi
6314
6315 if test "$wxUSE_IPC" = "yes"; then
6316     if test "$wxUSE_SOCKETS" != "yes" -a "$USE_WIN32" != 1; then
6317         AC_MSG_WARN(wxWidgets IPC classes require sockets... disabled)
6318         wxUSE_IPC=no
6319     fi
6320
6321     if test "$wxUSE_IPC" = "yes"; then
6322         AC_DEFINE(wxUSE_IPC)
6323         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ipc"
6324     fi
6325 fi
6326
6327 if test "$wxUSE_DATAOBJ" = "yes"; then
6328     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
6329         AC_MSG_WARN([wxDataObject not yet supported under $TOOLKIT... disabled])
6330         wxUSE_DATAOBJ=no
6331     else
6332         AC_DEFINE(wxUSE_DATAOBJ)
6333     fi
6334 else
6335     AC_MSG_WARN([Clipboard and drag-and-drop require wxDataObject -- disabled])
6336     wxUSE_CLIPBOARD=no
6337     wxUSE_DRAG_AND_DROP=no
6338 fi
6339
6340 if test "$wxUSE_CLIPBOARD" = "yes"; then
6341     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
6342         AC_MSG_WARN([Clipboard not yet supported under $TOOLKIT... disabled])
6343         wxUSE_CLIPBOARD=no
6344     fi
6345
6346     if test "$wxUSE_CLIPBOARD" = "yes"; then
6347         AC_DEFINE(wxUSE_CLIPBOARD)
6348     fi
6349 fi
6350
6351 if test "$wxUSE_DRAG_AND_DROP" = "yes" ; then
6352     if test "$wxUSE_GTK" = 1; then
6353         if test "$WXGTK12" != 1; then
6354             AC_MSG_WARN([Drag and drop is only supported under GTK+ 1.2... disabled])
6355             wxUSE_DRAG_AND_DROP=no
6356         fi
6357     fi
6358
6359     if test "$wxUSE_MOTIF" = 1 -o "$wxUSE_X11" = 1 -o "$wxUSE_MGL" = 1 -o \
6360             "$wxUSE_DFB" = 1; then
6361         AC_MSG_WARN([Drag and drop not yet supported under $TOOLKIT... disabled])
6362         wxUSE_DRAG_AND_DROP=no
6363     fi
6364
6365     if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
6366         AC_DEFINE(wxUSE_DRAG_AND_DROP)
6367     fi
6368
6369 fi
6370
6371 if test "$wxUSE_DRAG_AND_DROP" = "yes" -o "$wxUSE_CLIPBOARD" = "yes"; then
6372     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dnd"
6373 fi
6374
6375 if test "$wxUSE_SPLINES" = "yes" ; then
6376   AC_DEFINE(wxUSE_SPLINES)
6377 fi
6378
6379 if test "$wxUSE_MOUSEWHEEL" = "yes" ; then
6380   AC_DEFINE(wxUSE_MOUSEWHEEL)
6381 fi
6382
6383 dnl ---------------------------------------------------------------------------
6384 dnl GUI controls
6385 dnl ---------------------------------------------------------------------------
6386
6387 USES_CONTROLS=0
6388 if test "$wxUSE_CONTROLS" = "yes"; then
6389   USES_CONTROLS=1
6390 fi
6391
6392 if test "$wxUSE_ACCEL" = "yes"; then
6393   AC_DEFINE(wxUSE_ACCEL)
6394   USES_CONTROLS=1
6395 fi
6396
6397 if test "$wxUSE_ANIMATIONCTRL" = "yes"; then
6398   AC_DEFINE(wxUSE_ANIMATIONCTRL)
6399   USES_CONTROLS=1
6400   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS animate"
6401 fi
6402
6403 if test "$wxUSE_BUTTON" = "yes"; then
6404   AC_DEFINE(wxUSE_BUTTON)
6405   USES_CONTROLS=1
6406 fi
6407
6408 if test "$wxUSE_BMPBUTTON" = "yes"; then
6409   AC_DEFINE(wxUSE_BMPBUTTON)
6410   USES_CONTROLS=1
6411 fi
6412
6413 if test "$wxUSE_CALCTRL" = "yes"; then
6414   AC_DEFINE(wxUSE_CALENDARCTRL)
6415   USES_CONTROLS=1
6416   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS calendar"
6417 fi
6418
6419 if test "$wxUSE_CARET" = "yes"; then
6420   AC_DEFINE(wxUSE_CARET)
6421   USES_CONTROLS=1
6422   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS caret"
6423 fi
6424
6425 if test "$wxUSE_COLLPANE" = "yes"; then
6426     AC_DEFINE(wxUSE_COLLPANE)
6427     USES_CONTROLS=1
6428     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS collpane"
6429 fi
6430
6431 if test "$wxUSE_COMBOBOX" = "yes"; then
6432   AC_DEFINE(wxUSE_COMBOBOX)
6433   USES_CONTROLS=1
6434 fi
6435
6436 if test "$wxUSE_COMBOCTRL" = "yes"; then
6437   AC_DEFINE(wxUSE_COMBOCTRL)
6438   USES_CONTROLS=1
6439 fi
6440
6441 if test "$wxUSE_CHOICE" = "yes"; then
6442   AC_DEFINE(wxUSE_CHOICE)
6443   USES_CONTROLS=1
6444 fi
6445
6446 if test "$wxUSE_CHOICEBOOK" = "yes"; then
6447     AC_DEFINE(wxUSE_CHOICEBOOK)
6448     USES_CONTROLS=1
6449 fi
6450
6451 if test "$wxUSE_CHECKBOX" = "yes"; then
6452   AC_DEFINE(wxUSE_CHECKBOX)
6453   USES_CONTROLS=1
6454 fi
6455
6456 if test "$wxUSE_CHECKLST" = "yes"; then
6457   AC_DEFINE(wxUSE_CHECKLISTBOX)
6458   USES_CONTROLS=1
6459   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS checklst"
6460 fi
6461
6462 if test "$wxUSE_COLOURPICKERCTRL" = "yes"; then
6463   AC_DEFINE(wxUSE_COLOURPICKERCTRL)
6464   USES_CONTROLS=1
6465 fi
6466
6467 if test "$wxUSE_DATEPICKCTRL" = "yes"; then
6468   AC_DEFINE(wxUSE_DATEPICKCTRL)
6469   USES_CONTROLS=1
6470 fi
6471
6472 if test "$wxUSE_DIRPICKERCTRL" = "yes"; then
6473   AC_DEFINE(wxUSE_DIRPICKERCTRL)
6474   USES_CONTROLS=1
6475 fi
6476
6477 if test "$wxUSE_FILEPICKERCTRL" = "yes"; then
6478   AC_DEFINE(wxUSE_FILEPICKERCTRL)
6479   USES_CONTROLS=1
6480 fi
6481
6482 if test "$wxUSE_FONTPICKERCTRL" = "yes"; then
6483   AC_DEFINE(wxUSE_FONTPICKERCTRL)
6484   USES_CONTROLS=1
6485 fi
6486
6487 if test "$wxUSE_DISPLAY" = "yes"; then
6488     if test "$wxUSE_DFB" = 1 -o "$wxUSE_MGL" = 1; then
6489         AC_MSG_WARN([wxDisplay not yet supported under $TOOLKIT... disabled])
6490         wxUSE_DISPLAY=no
6491     else
6492         AC_DEFINE(wxUSE_DISPLAY)
6493         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS display multimon"
6494     fi
6495 fi
6496
6497 if test "$wxUSE_DETECT_SM" = "yes"; then
6498     AC_DEFINE(wxUSE_DETECT_SM)
6499 fi
6500
6501 if test "$wxUSE_GAUGE" = "yes"; then
6502   AC_DEFINE(wxUSE_GAUGE)
6503   USES_CONTROLS=1
6504 fi
6505
6506 if test "$wxUSE_GRID" = "yes"; then
6507   AC_DEFINE(wxUSE_GRID)
6508   USES_CONTROLS=1
6509   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS grid"
6510 fi
6511
6512 if test "$wxUSE_HYPERLINKCTRL" = "yes"; then
6513   AC_DEFINE(wxUSE_HYPERLINKCTRL)
6514   USES_CONTROLS=1
6515 fi
6516
6517 if test "$wxUSE_BITMAPCOMBOBOX" = "yes"; then
6518   AC_DEFINE(wxUSE_BITMAPCOMBOBOX)
6519   USES_CONTROLS=1
6520 fi
6521
6522 if test "$wxUSE_DATAVIEWCTRL" = "yes"; then
6523   AC_DEFINE(wxUSE_DATAVIEWCTRL)
6524   USES_CONTROLS=1
6525   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dataview"
6526 fi
6527
6528 if test "$wxUSE_IMAGLIST" = "yes"; then
6529     AC_DEFINE(wxUSE_IMAGLIST)
6530 fi
6531
6532 if test "$wxUSE_LISTBOOK" = "yes"; then
6533     AC_DEFINE(wxUSE_LISTBOOK)
6534     USES_CONTROLS=1
6535 fi
6536
6537 if test "$wxUSE_LISTBOX" = "yes"; then
6538     AC_DEFINE(wxUSE_LISTBOX)
6539     USES_CONTROLS=1
6540     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS listbox"
6541 fi
6542
6543 if test "$wxUSE_LISTCTRL" = "yes"; then
6544     if test "$wxUSE_IMAGLIST" = "yes"; then
6545         AC_DEFINE(wxUSE_LISTCTRL)
6546         USES_CONTROLS=1
6547         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS listctrl"
6548     else
6549         AC_MSG_WARN([wxListCtrl requires wxImageList and won't be compiled without it])
6550     fi
6551 fi
6552
6553 if test "$wxUSE_EDITABLELISTBOX" = "yes"; then
6554     AC_DEFINE(wxUSE_EDITABLELISTBOX)
6555     USES_CONTROLS=1
6556     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS editlbox"
6557 fi
6558
6559 if test "$wxUSE_NOTEBOOK" = "yes"; then
6560     AC_DEFINE(wxUSE_NOTEBOOK)
6561     USES_CONTROLS=1
6562     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS notebook"
6563 fi
6564
6565 if test "$wxUSE_ODCOMBOBOX" = "yes"; then
6566   AC_DEFINE(wxUSE_ODCOMBOBOX)
6567   USES_CONTROLS=1
6568   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS combo"
6569 fi
6570
6571 dnl if test "$wxUSE_PROPSHEET" = "yes"; then
6572 dnl     AC_DEFINE(wxUSE_PROPSHEET)
6573 dnl     USES_CONTROLS=1
6574 dnl     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS proplist"
6575 dnl fi
6576
6577 if test "$wxUSE_RADIOBOX" = "yes"; then
6578     AC_DEFINE(wxUSE_RADIOBOX)
6579     USES_CONTROLS=1
6580 fi
6581
6582 if test "$wxUSE_RADIOBTN" = "yes"; then
6583     AC_DEFINE(wxUSE_RADIOBTN)
6584     USES_CONTROLS=1
6585 fi
6586
6587 if test "$wxUSE_SASH" = "yes"; then
6588     AC_DEFINE(wxUSE_SASH)
6589     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sashtest"
6590 fi
6591
6592 if test "$wxUSE_SCROLLBAR" = "yes"; then
6593     AC_DEFINE(wxUSE_SCROLLBAR)
6594     USES_CONTROLS=1
6595     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS scroll scrollsub"
6596 fi
6597
6598 if test "$wxUSE_SEARCHCTRL" = "yes"; then
6599     AC_DEFINE(wxUSE_SEARCHCTRL)
6600     USES_CONTROLS=1
6601 fi
6602
6603 if test "$wxUSE_SLIDER" = "yes"; then
6604     AC_DEFINE(wxUSE_SLIDER)
6605     USES_CONTROLS=1
6606 fi
6607
6608 if test "$wxUSE_SPINBTN" = "yes"; then
6609     AC_DEFINE(wxUSE_SPINBTN)
6610     USES_CONTROLS=1
6611 fi
6612
6613 if test "$wxUSE_SPINCTRL" = "yes"; then
6614     AC_DEFINE(wxUSE_SPINCTRL)
6615     USES_CONTROLS=1
6616 fi
6617
6618 if test "$wxUSE_SPLITTER" = "yes"; then
6619     AC_DEFINE(wxUSE_SPLITTER)
6620     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splitter"
6621 fi
6622
6623 if test "$wxUSE_STATBMP" = "yes"; then
6624     AC_DEFINE(wxUSE_STATBMP)
6625     USES_CONTROLS=1
6626 fi
6627
6628 if test "$wxUSE_STATBOX" = "yes"; then
6629     AC_DEFINE(wxUSE_STATBOX)
6630     USES_CONTROLS=1
6631 fi
6632
6633 if test "$wxUSE_STATTEXT" = "yes"; then
6634     AC_DEFINE(wxUSE_STATTEXT)
6635     USES_CONTROLS=1
6636 fi
6637
6638 if test "$wxUSE_STATLINE" = "yes"; then
6639     AC_DEFINE(wxUSE_STATLINE)
6640     USES_CONTROLS=1
6641 fi
6642
6643 if test "$wxUSE_STATUSBAR" = "yes"; then
6644     dnl this will get undefined in wx/chkconf.h if it's not supported
6645     AC_DEFINE(wxUSE_NATIVE_STATUSBAR)
6646     AC_DEFINE(wxUSE_STATUSBAR)
6647     USES_CONTROLS=1
6648
6649     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS statbar"
6650 fi
6651
6652 if test "$wxUSE_TAB_DIALOG" = "yes"; then
6653     AC_DEFINE(wxUSE_TAB_DIALOG)
6654 fi
6655
6656 if test "$wxUSE_TEXTCTRL" = "yes"; then
6657     AC_DEFINE(wxUSE_TEXTCTRL)
6658     USES_CONTROLS=1
6659     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS text"
6660 fi
6661
6662 if test "$wxUSE_TOGGLEBTN" = "yes"; then
6663     if test "$wxUSE_COCOA" = 1 ; then
6664         AC_MSG_WARN([Toggle button not yet supported under Mac OS X... disabled])
6665         wxUSE_TOGGLEBTN=no
6666     fi
6667
6668     if test "$wxUSE_TOGGLEBTN" = "yes"; then
6669         AC_DEFINE(wxUSE_TOGGLEBTN)
6670         USES_CONTROLS=1
6671     fi
6672 fi
6673
6674 if test "$wxUSE_TOOLBAR" = "yes"; then
6675     AC_DEFINE(wxUSE_TOOLBAR)
6676     USES_CONTROLS=1
6677
6678     if test "$wxUSE_UNIVERSAL" = "yes"; then
6679         wxUSE_TOOLBAR_NATIVE="no"
6680     else
6681         wxUSE_TOOLBAR_NATIVE="yes"
6682         AC_DEFINE(wxUSE_TOOLBAR_NATIVE)
6683     fi
6684
6685     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS toolbar"
6686 fi
6687
6688 if test "$wxUSE_TOOLTIPS" = "yes"; then
6689     if test "$wxUSE_MOTIF" = 1; then
6690         AC_MSG_WARN([wxTooltip not supported yet under Motif... disabled])
6691     else
6692         if test "$wxUSE_UNIVERSAL" = "yes"; then
6693             AC_MSG_WARN([wxTooltip not supported yet in wxUniversal... disabled])
6694         else
6695             AC_DEFINE(wxUSE_TOOLTIPS)
6696         fi
6697     fi
6698 fi
6699
6700 if test "$wxUSE_TREEBOOK" = "yes"; then
6701     AC_DEFINE(wxUSE_TREEBOOK)
6702     USES_CONTROLS=1
6703 fi
6704
6705 if test "$wxUSE_TOOLBOOK" = "yes"; then
6706     AC_DEFINE(wxUSE_TOOLBOOK)
6707     USES_CONTROLS=1
6708 fi
6709
6710 if test "$wxUSE_TREECTRL" = "yes"; then
6711     if test "$wxUSE_IMAGLIST" = "yes"; then
6712         AC_DEFINE(wxUSE_TREECTRL)
6713         USES_CONTROLS=1
6714         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS treectrl"
6715     else
6716         AC_MSG_WARN([wxTreeCtrl requires wxImageList and won't be compiled without it])
6717     fi
6718 fi
6719
6720 if test "$wxUSE_POPUPWIN" = "yes"; then
6721     if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1 ; then
6722         AC_MSG_WARN([Popup window not yet supported under Mac OS X... disabled])
6723     else
6724         if test "$wxUSE_PM" = 1; then
6725             AC_MSG_WARN([wxPopupWindow not yet supported under PM... disabled])
6726         else
6727             AC_DEFINE(wxUSE_POPUPWIN)
6728             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS popup"
6729
6730             USES_CONTROLS=1
6731         fi
6732     fi
6733 fi
6734
6735 if test "$wxUSE_DIALUP_MANAGER" = "yes"; then
6736     if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1 -o "$wxUSE_MGL" = 1; then
6737         AC_MSG_WARN([Dialup manager not supported on this platform... disabled])
6738     else
6739         AC_DEFINE(wxUSE_DIALUP_MANAGER)
6740         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dialup"
6741     fi
6742 fi
6743
6744 if test "$wxUSE_TIPWINDOW" = "yes"; then
6745     if test "$wxUSE_PM" = 1; then
6746         AC_MSG_WARN([wxTipWindow not yet supported under PM... disabled])
6747     else
6748         AC_DEFINE(wxUSE_TIPWINDOW)
6749     fi
6750 fi
6751
6752 if test "$USES_CONTROLS" = 1; then
6753     AC_DEFINE(wxUSE_CONTROLS)
6754 fi
6755
6756 dnl ---------------------------------------------------------------------------
6757 dnl misc options
6758 dnl ---------------------------------------------------------------------------
6759
6760 dnl please keep the settings below in alphabetical order
6761 if test "$wxUSE_ACCESSIBILITY" = "yes"; then
6762     AC_DEFINE(wxUSE_ACCESSIBILITY)
6763     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS access"
6764 fi
6765
6766 if test "$wxUSE_DC_CACHEING" = "yes"; then
6767     AC_DEFINE(wxUSE_DC_CACHEING)
6768 fi
6769
6770 if test "$wxUSE_DRAGIMAGE" = "yes"; then
6771     AC_DEFINE(wxUSE_DRAGIMAGE)
6772     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dragimag"
6773 fi
6774
6775 if test "$wxUSE_EXCEPTIONS" = "yes"; then
6776     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
6777         AC_MSG_WARN([--enable-exceptions can't be used with --enable-no_exceptions])
6778     else
6779         AC_DEFINE(wxUSE_EXCEPTIONS)
6780         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS except"
6781     fi
6782 fi
6783
6784 USE_HTML=0
6785 if test "$wxUSE_HTML" = "yes"; then
6786     AC_DEFINE(wxUSE_HTML)
6787     USE_HTML=1
6788     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html html/about html/help html/helpview html/printing html/test html/virtual html/widget html/zip htlbox"
6789     if test "$wxUSE_MAC" = 1; then
6790         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html/htmlctrl"
6791     fi
6792 fi
6793 if test "$wxUSE_WEBKIT" = "yes"; then
6794     if test "$wxUSE_MAC" = 1 -a "$USE_DARWIN" = 1; then
6795         old_CPPFLAGS="$CPPFLAGS"
6796         CPPFLAGS="-x objective-c++ $CPPFLAGS"
6797         AC_CHECK_HEADER([WebKit/HIWebView.h],
6798                         [
6799                            AC_DEFINE(wxUSE_WEBKIT)
6800                            WEBKIT_LINK="-framework WebKit"
6801                         ],
6802                         [
6803                            AC_MSG_WARN([WebKit headers not found; disabling wxWebKit])
6804                            wxUSE_WEBKIT=no
6805                         ],
6806                         [
6807                            #include <Carbon/Carbon.h>
6808                            #include <WebKit/WebKit.h>
6809                         ])
6810         CPPFLAGS="$old_CPPFLAGS"
6811     elif test "$wxUSE_COCOA" = 1; then
6812         AC_DEFINE(wxUSE_WEBKIT)
6813     else
6814         wxUSE_WEBKIT=no
6815     fi
6816 fi
6817
6818 USE_XRC=0
6819 if test "$wxUSE_XRC" = "yes"; then
6820     if test "$wxUSE_XML" != "yes"; then
6821         AC_MSG_WARN([XML library not built, XRC resources disabled])
6822         wxUSE_XRC=no
6823     else
6824         AC_DEFINE(wxUSE_XRC)
6825         USE_XRC=1
6826         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS xrc"
6827     fi
6828 fi
6829
6830 USE_AUI=0
6831 if test "$wxUSE_AUI" = "yes"; then
6832    AC_DEFINE(wxUSE_AUI)
6833    USE_AUI=1
6834    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS aui"
6835 fi
6836
6837 USE_STC=0
6838 if test "$wxUSE_STC" = "yes"; then
6839    AC_DEFINE(wxUSE_STC)
6840    USE_STC=1
6841    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS stc"
6842 fi
6843
6844 if test "$wxUSE_MENUS" = "yes"; then
6845     AC_DEFINE(wxUSE_MENUS)
6846     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS menu"
6847 fi
6848
6849 if test "$wxUSE_METAFILE" = "yes"; then
6850     AC_DEFINE(wxUSE_METAFILE)
6851 fi
6852
6853 if test "$wxUSE_MIMETYPE" = "yes"; then
6854     AC_DEFINE(wxUSE_MIMETYPE)
6855 fi
6856
6857 if test "$wxUSE_MINIFRAME" = "yes"; then
6858     AC_DEFINE(wxUSE_MINIFRAME)
6859     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS minifram"
6860 fi
6861
6862 if test "$wxUSE_SYSTEM_OPTIONS" = "yes"; then
6863     AC_DEFINE(wxUSE_SYSTEM_OPTIONS)
6864     if test "$TOOLKIT" = "MSW" -o "$TOOLKIT" = "GTK" -o "$TOOLKIT" = "X11" -o \
6865         "$TOOLKIT" = "MOTIF" -o "$TOOLKIT" = "COCOA"; then
6866         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS taskbar"
6867     fi
6868 fi
6869
6870
6871 if test "$wxUSE_VALIDATORS" = "yes"; then
6872     AC_DEFINE(wxUSE_VALIDATORS)
6873     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS validate"
6874 fi
6875
6876 if test "$wxUSE_PALETTE" = "yes" ; then
6877     if test "$wxUSE_DFB" = 1; then
6878         AC_MSG_WARN([wxPalette not yet supported under DFB... disabled])
6879         wxUSE_PALETTE=no
6880     else
6881         AC_DEFINE(wxUSE_PALETTE)
6882     fi
6883 fi
6884
6885 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_MSLU" = "yes" ; then
6886   dnl Must be done this late because -lunicows must be before all the other libs
6887   LIBS=" -lunicows $LIBS"
6888 fi
6889
6890 USE_RICHTEXT=0
6891 if test "$wxUSE_RICHTEXT" = "yes"; then
6892     AC_DEFINE(wxUSE_RICHTEXT)
6893     USE_RICHTEXT=1
6894     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS richtext"
6895 fi
6896
6897 dnl ---------------------------------------------------------------------------
6898 dnl wxImage options
6899 dnl ---------------------------------------------------------------------------
6900
6901 if test "$wxUSE_IMAGE" = "yes" ; then
6902     AC_DEFINE(wxUSE_IMAGE)
6903
6904     if test "$wxUSE_GIF" = "yes" ; then
6905       AC_DEFINE(wxUSE_GIF)
6906     fi
6907
6908     if test "$wxUSE_PCX" = "yes" ; then
6909       AC_DEFINE(wxUSE_PCX)
6910     fi
6911
6912     if test "$wxUSE_TGA" = "yes" ; then
6913       AC_DEFINE(wxUSE_TGA)
6914     fi
6915
6916     if test "$wxUSE_IFF" = "yes" ; then
6917       AC_DEFINE(wxUSE_IFF)
6918     fi
6919
6920     if test "$wxUSE_PNM" = "yes" ; then
6921       AC_DEFINE(wxUSE_PNM)
6922     fi
6923
6924     if test "$wxUSE_XPM" = "yes" ; then
6925       AC_DEFINE(wxUSE_XPM)
6926     fi
6927
6928     if test "$wxUSE_ICO_CUR" = "yes" ; then
6929       AC_DEFINE(wxUSE_ICO_CUR)
6930     fi
6931 fi
6932
6933 dnl ---------------------------------------------------------------------------
6934 dnl common dialogs
6935 dnl ---------------------------------------------------------------------------
6936
6937 if test "$wxUSE_ABOUTDLG" = "yes"; then
6938     AC_DEFINE(wxUSE_ABOUTDLG)
6939 fi
6940
6941 if test "$wxUSE_CHOICEDLG" = "yes"; then
6942     AC_DEFINE(wxUSE_CHOICEDLG)
6943 fi
6944
6945 if test "$wxUSE_COLOURDLG" = "yes"; then
6946     AC_DEFINE(wxUSE_COLOURDLG)
6947 fi
6948
6949 if test "$wxUSE_FILEDLG" = "yes"; then
6950     AC_DEFINE(wxUSE_FILEDLG)
6951 fi
6952
6953 if test "$wxUSE_FINDREPLDLG" = "yes"; then
6954     AC_DEFINE(wxUSE_FINDREPLDLG)
6955 fi
6956
6957 if test "$wxUSE_FONTDLG" = "yes"; then
6958     AC_DEFINE(wxUSE_FONTDLG)
6959 fi
6960
6961 if test "$wxUSE_DIRDLG" = "yes"; then
6962     if test "$wxUSE_TREECTRL" != "yes"; then
6963         AC_MSG_WARN(wxDirDialog requires wxTreeCtrl so it won't be compiled without it)
6964     else
6965         AC_DEFINE(wxUSE_DIRDLG)
6966     fi
6967 fi
6968
6969 if test "$wxUSE_MSGDLG" = "yes"; then
6970     AC_DEFINE(wxUSE_MSGDLG)
6971 fi
6972
6973 if test "$wxUSE_NUMBERDLG" = "yes"; then
6974     AC_DEFINE(wxUSE_NUMBERDLG)
6975 fi
6976
6977 if test "$wxUSE_PROGRESSDLG" = "yes"; then
6978     if test "$wxUSE_CONSTRAINTS" != "yes"; then
6979        AC_MSG_WARN(wxProgressDialog requires constraints so it won't be compiled without them)
6980     else
6981         AC_DEFINE(wxUSE_PROGRESSDLG)
6982     fi
6983 fi
6984
6985 if test "$wxUSE_SPLASH" = "yes"; then
6986     AC_DEFINE(wxUSE_SPLASH)
6987     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splash"
6988 fi
6989
6990 if test "$wxUSE_STARTUP_TIPS" = "yes"; then
6991     if test "$wxUSE_CONSTRAINTS" != "yes"; then
6992        AC_MSG_WARN(Startup tips requires constraints and won't be compiled without them)
6993     else
6994         AC_DEFINE(wxUSE_STARTUP_TIPS)
6995     fi
6996 fi
6997
6998 if test "$wxUSE_TEXTDLG" = "yes"; then
6999     AC_DEFINE(wxUSE_TEXTDLG)
7000 fi
7001
7002 if test "$wxUSE_WIZARDDLG" = "yes"; then
7003     AC_DEFINE(wxUSE_WIZARDDLG)
7004     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS wizard"
7005 fi
7006
7007 dnl ---------------------------------------------------------------------------
7008 dnl wxGraphicsContext
7009 dnl ---------------------------------------------------------------------------
7010
7011 if test "$wxUSE_GRAPHICS_CONTEXT" = "yes"; then
7012    if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = "1"; then
7013       AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)
7014    elif test "$wxUSE_GTK" != 1; then
7015       dnl for other builds we'll just wing it for now...
7016       AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)
7017    else
7018       dnl ...but let's check for cairo availability for wxGTK builds
7019       PKG_CHECK_MODULES(CAIRO, cairo,
7020           [AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)],
7021           [AC_MSG_WARN([Cairo library not found, unable to set wxUSE_GRAPHICS_CONTEXT])]
7022       )
7023    fi
7024 fi
7025
7026 dnl ---------------------------------------------------------------------------
7027 dnl wxMediaCtrl
7028 dnl ---------------------------------------------------------------------------
7029
7030 USE_MEDIA=0
7031
7032 if test "$wxUSE_MEDIACTRL" = "yes"; then
7033     USE_MEDIA=1
7034
7035     dnl -----------------------------------------------------------------------
7036     dnl GStreamer
7037     dnl -----------------------------------------------------------------------
7038     if test "$wxUSE_GTK" = 1; then
7039         wxUSE_GSTREAMER="no"
7040
7041         dnl -------------------------------------------------------------------
7042         dnl Test for at least 0.8 gstreamer module from pkg-config
7043         dnl Even totem doesn't accept 0.9 evidently.
7044         dnl
7045         dnl So, we first check to see if 0.10 if available - if not we
7046         dnl try the older 0.8 version
7047         dnl -------------------------------------------------------------------
7048         GST_VERSION_MAJOR=0
7049         GST_VERSION_MINOR=10
7050         GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
7051
7052         if test "$wxUSE_GSTREAMER8" = "no"; then
7053             PKG_CHECK_MODULES(GST,
7054                 [gstreamer-$GST_VERSION gstreamer-plugins-base-$GST_VERSION gconf-2.0],
7055                 [
7056                     wxUSE_GSTREAMER="yes"
7057                     GST_LIBS="$GST_LIBS -lgstinterfaces-$GST_VERSION"
7058                 ],
7059                 [
7060                     AC_MSG_WARN([GStreamer 0.10 not available, falling back to 0.8])
7061                     GST_VERSION_MINOR=8
7062                 ]
7063             )
7064         else
7065             dnl check only for 0.8
7066             GST_VERSION_MINOR=8
7067         fi
7068
7069         if test $GST_VERSION_MINOR = "8"; then
7070             GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
7071             PKG_CHECK_MODULES(GST,
7072                 [gstreamer-$GST_VERSION gstreamer-interfaces-$GST_VERSION gstreamer-gconf-$GST_VERSION],
7073                 wxUSE_GSTREAMER="yes",
7074                 [
7075                     AC_MSG_WARN([GStreamer 0.8/0.10 not available.])
7076                 ])
7077         fi
7078
7079
7080         if test "$wxUSE_GSTREAMER" = "yes"; then
7081             CPPFLAGS="$GST_CFLAGS $CPPFLAGS"
7082             LIBS="$GST_LIBS $LIBS"
7083
7084             AC_DEFINE(wxUSE_GSTREAMER)
7085         else
7086             USE_MEDIA=0
7087         fi
7088     fi
7089
7090     if test $USE_MEDIA = 1; then
7091         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mediaplayer"
7092         AC_DEFINE(wxUSE_MEDIACTRL)
7093     fi
7094 fi
7095
7096 dnl ---------------------------------------------------------------------------
7097 dnl get the string with OS info - used by wxGetOsDescription() on MacOS X
7098 dnl ---------------------------------------------------------------------------
7099
7100 if test "$cross_compiling" = "yes"; then
7101     dnl Use best guess from host as we can't use uname when cross compiling
7102     OSINFO="\"$host\""
7103 else
7104     dnl attualy work out OS version
7105     OSINFO=`uname -s -r -m`
7106     OSINFO="\"$OSINFO\""
7107 fi
7108
7109 AC_DEFINE_UNQUOTED(WXWIN_OS_DESCRIPTION, $OSINFO)
7110
7111 dnl ---------------------------------------------------------------------------
7112 dnl define the variable containing the installation prefix (used in dcpsg.cpp)
7113 dnl ---------------------------------------------------------------------------
7114
7115 if test "x$prefix" != "xNONE"; then
7116     wxPREFIX=$prefix
7117 else
7118     wxPREFIX=$ac_default_prefix
7119 fi
7120
7121 AC_DEFINE_UNQUOTED(wxINSTALL_PREFIX, "$wxPREFIX")
7122
7123
7124 dnl ---------------------------------------------------------------------------
7125 dnl define variables with all built libraries for wx-config
7126 dnl ---------------------------------------------------------------------------
7127
7128 STD_BASE_LIBS="base"
7129 STD_GUI_LIBS=""
7130 BUILT_WX_LIBS="base"
7131 ALL_WX_LIBS="xrc stc gl media dbgrid qa html adv core odbc xml net base"
7132
7133 if test "$wxUSE_SOCKETS" = "yes" ; then
7134     STD_BASE_LIBS="net $STD_BASE_LIBS"
7135     BUILT_WX_LIBS="net $BUILT_WX_LIBS"
7136 fi
7137 if test "$wxUSE_ODBC" != "no" ; then
7138     BUILT_WX_LIBS="odbc $BUILT_WX_LIBS"
7139 fi
7140 if test "$wxUSE_XML" = "yes" ; then
7141     STD_BASE_LIBS="xml $STD_BASE_LIBS"
7142     BUILT_WX_LIBS="xml $BUILT_WX_LIBS"
7143 fi
7144
7145 if test "$wxUSE_GUI" = "yes"; then
7146     STD_GUI_LIBS="adv core"
7147     BUILT_WX_LIBS="$STD_GUI_LIBS $BUILT_WX_LIBS"
7148
7149     if test "$wxUSE_DEBUGREPORT" = "yes" ; then
7150         STD_GUI_LIBS="qa $STD_GUI_LIBS"
7151         BUILT_WX_LIBS="qa $BUILT_WX_LIBS"
7152     fi
7153     if test "$wxUSE_ODBC" != "no" ; then
7154         BUILT_WX_LIBS="dbgrid $BUILT_WX_LIBS"
7155     fi
7156     if test "$wxUSE_HTML" = "yes" ; then
7157         STD_GUI_LIBS="html $STD_GUI_LIBS"
7158         BUILT_WX_LIBS="html $BUILT_WX_LIBS"
7159     fi
7160     if test "$wxUSE_MEDIACTRL" = "yes" ; then
7161         BUILT_WX_LIBS="media $BUILT_WX_LIBS"
7162     fi
7163     if test "$wxUSE_OPENGL" = "yes" ; then
7164         BUILT_WX_LIBS="gl $BUILT_WX_LIBS"
7165     fi
7166     if test "$wxUSE_AUI" = "yes" ; then
7167         BUILT_WX_LIBS="aui $BUILT_WX_LIBS"
7168     fi
7169     if test "$wxUSE_STC" = "yes" ; then
7170         BUILT_WX_LIBS="stc $BUILT_WX_LIBS"
7171     fi
7172     if test "$wxUSE_XRC" = "yes" ; then
7173         STD_GUI_LIBS="xrc $STD_GUI_LIBS"
7174         BUILT_WX_LIBS="xrc $BUILT_WX_LIBS"
7175     fi
7176 fi
7177
7178 AC_SUBST(ALL_WX_LIBS)
7179 AC_SUBST(BUILT_WX_LIBS)
7180 AC_SUBST(STD_BASE_LIBS)
7181 AC_SUBST(STD_GUI_LIBS)
7182
7183 dnl ---------------------------------------------------------------------------
7184 dnl Output the makefiles and such from the results found above
7185 dnl ---------------------------------------------------------------------------
7186
7187 dnl all additional libraries (except wxWidgets itself) we link with
7188
7189 if test "$wxUSE_MAC" = 1 ; then
7190     if test "$wxUSE_SOUND" = "yes" || test "$wxUSE_MEDIACTRL" = "yes"; then
7191         if test "$USE_DARWIN" = 1; then
7192             LDFLAGS="$LDFLAGS -framework QuickTime"
7193         else
7194             LDFLAGS="$LDFLAGS -lQuickTimeLib"
7195         fi
7196     fi
7197     if test "$USE_DARWIN" = 1; then
7198         LDFLAGS="$LDFLAGS -framework IOKit -framework Carbon -framework Cocoa -framework System"
7199     else
7200         LDFLAGS="$LDFLAGS -lCarbonLib"
7201     fi
7202 fi
7203 if test "$wxUSE_COCOA" = 1 ; then
7204     LDFLAGS="$LDFLAGS -framework IOKit -framework Cocoa"
7205     if test "$wxUSE_MEDIACTRL" = "yes"; then
7206         LDFLAGS="$LDFLAGS -framework QuickTime"
7207     fi
7208 fi
7209 if test "$USE_DARWIN" = 1 -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1 ; then
7210     LDFLAGS="$LDFLAGS -framework IOKit -framework CoreServices -framework System -framework ApplicationServices"
7211 fi
7212
7213 LIBS="$ZLIB_LINK $POSIX4_LINK $INET_LINK $WCHAR_LINK $DL_LINK $LIBS"
7214
7215 if test "$wxUSE_GUI" = "yes"; then
7216
7217     dnl TODO add checks that these samples will really compile (i.e. all the
7218     dnl      library features they need are present)
7219
7220     dnl TODO some samples are never built so far: mfc (requires VC++)
7221     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS artprov controls dialogs drawing \
7222                      dynamic erase event exec font image minimal mobile \
7223                      mobile/wxedit mobile/styles propsize render \
7224                      rotate shaped svg taborder vscroll widgets"
7225
7226     if test "$wxUSE_MONOLITHIC" != "yes"; then
7227         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS console"
7228     fi
7229     if test "$TOOLKIT" = "MSW"; then
7230         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS regtest"
7231         if test "$wxUSE_UNIVERSAL" != "yes"; then
7232             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ownerdrw nativdlg"
7233         fi
7234     fi
7235     if test "$TOOLKIT" = "PM" -a "$wxUSE_UNIVERSAL" != "yes"; then
7236         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ownerdrw"
7237     fi
7238 else
7239     SAMPLES_SUBDIRS="console"
7240 fi
7241
7242
7243 dnl C/C++ compiler options used to compile wxWidgets
7244 dnl
7245 dnl check for icc before gcc as icc is also recognized as gcc
7246 if test "x$INTELCC" = "xyes" ; then
7247     dnl Warnings which can't be easily suppressed in C code are disabled:
7248     dnl
7249     dnl     remark #810: conversion from "x" to "y" may lose significant bits
7250     dnl     remark #869: parameter "foo" was never referenced
7251     dnl     remark #1572: floating-point equality and inequality comparisons
7252     dnl                   are unreliable
7253     dnl     remark #1684: conversion from pointer to same-sized integral type
7254     dnl
7255     dnl (for others see below)
7256     CWARNINGS="-Wall -wd810,869,981,1418,1572,1684"
7257 elif test "$GCC" = yes ; then
7258     CWARNINGS="-Wall -Wundef"
7259 fi
7260
7261 if test "x$INTELCXX" = "xyes" ; then
7262     dnl Intel compiler gives some warnings which simply can't be worked
7263     dnl around or of which we have too many (810, 869) so it's impractical to
7264     dnl keep them enabled even if in theory it would be nice and some others
7265     dnl (279) are generated for standard macros and so there is nothing we can
7266     dnl do about them
7267     dnl
7268     dnl     remark #279: controlling expression is constant
7269     dnl     remark #383: value copied to temporary, reference to temporary used
7270     dnl     remark #444: destructor for base class "xxx" is not virtual
7271     dnl     remark #810: conversion from "x" to "y" may lose significant bits
7272     dnl     remark #869: parameter "foo" was never referenced
7273     dnl     remark #981: operands are evaluated in unspecified order
7274     dnl     remark #1418: external definition with no prior declaration
7275     dnl     remark #1419: external declaration in primary source file
7276     CXXWARNINGS="-Wall -wd279,383,444,810,869,981,1418,1419"
7277 elif test "$GXX" = yes ; then
7278     dnl CXXWARNINGS="-Wall -W -Wcast-qual -Werror"
7279     CXXWARNINGS="-Wall -Wundef -Wno-ctor-dtor-privacy"
7280 fi
7281
7282
7283 dnl combine everything together and remove the extra white space while doing it
7284 WXCONFIG_CFLAGS=`echo $WXCONFIG_CFLAGS`
7285 WXCONFIG_CXXFLAGS=`echo $WXCONFIG_CFLAGS $WXCONFIG_CXXFLAGS`
7286
7287
7288 dnl add -I options we use during library compilation
7289 dnl
7290 dnl note that the order is somewhat important: wxWidgets headers should
7291 dnl come first and the one with setup.h should be before $(top_srcdir)/include
7292 dnl in case the latter contains setup.h used by non-autoconf makefiles (e.g.
7293 dnl CodeWarrior):
7294 CPPFLAGS=`echo $WXCONFIG_CPPFLAGS \
7295  -I\\${wx_top_builddir}/lib/wx/include/${TOOLCHAIN_FULLNAME} \
7296  -I\\${top_srcdir}/include $TOOLKIT_INCLUDE \
7297  $CPPFLAGS `
7298
7299 C_AND_CXX_FLAGS="$DEBUG_CFLAGS $PROFILE_FLAGS $OPTIMISE_CFLAGS"
7300 CFLAGS=`echo $WXCONFIG_CFLAGS $CWARNINGS $C_AND_CXX_FLAGS $CFLAGS `
7301 CXXFLAGS=`echo $WXCONFIG_CXXFLAGS $C_AND_CXX_FLAGS $CXXFLAGS `
7302
7303 dnl now that we added WXCONFIG_CPPFLAGS to CPPFLAGS we can add the wx-config
7304 dnl only stuff to it
7305 WXCONFIG_CPPFLAGS=`echo $WXCONFIG_CPPFLAGS $WXCONFIG_ONLY_CPPFLAGS`
7306
7307
7308 if test "x$MWCC" = "xyes"; then
7309     dnl Correct MW 8.3 to be more similar to GCC.  In particular we
7310     dnl must use <regex.h> from system not our local copy on OS X,
7311     dnl but must use local not system on OS 9.
7312     dnl The following should make all -I paths usable for <> includes
7313     dnl while first checking in real system paths.  With 8.3 using
7314     dnl -gccincludes it will actually check local paths before system
7315     dnl even for <> which is totally wrong.
7316
7317     dnl Note that because this absolutely needs to be before any -I
7318     dnl that we have to tack it on to the end of the compiler commandline.
7319     CC="$CC -cwd source -I-"
7320     CXX="$CXX -cwd source -I-"
7321 fi
7322
7323
7324 LIBS=`echo $LIBS`
7325 EXTRALIBS="$LDFLAGS $LDFLAGS_VERSIONING $LIBS $DMALLOC_LIBS"
7326 EXTRALIBS_XML="$EXPAT_LINK"
7327 EXTRALIBS_HTML="$MSPACK_LINK"
7328 EXTRALIBS_ODBC="$ODBC_LINK"
7329 EXTRALIBS_STC="-lwxscintilla${lib_debug_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX}"
7330 if test "$wxUSE_GUI" = "yes"; then
7331     EXTRALIBS_GUI=`echo $GUI_TK_LIBRARY $PNG_LINK $JPEG_LINK $TIFF_LINK $WEBKIT_LINK $EXTRALIBS_HILDON $EXTRALIBS_GNOMEVFS $EXTRALIBS_GNOMEPRINT`
7332 fi
7333 if test "$wxUSE_OPENGL" = "yes"; then
7334     EXTRALIBS_OPENGL="$LDFLAGS_GL $OPENGL_LIBS"
7335 fi
7336
7337 LDFLAGS="$LDFLAGS $PROFILE_FLAGS"
7338
7339 WXCONFIG_LIBS="$LIBS"
7340
7341 dnl wx-config must output builtin 3rd party libs in --libs in static build:
7342 if test "$wxUSE_REGEX" = "builtin" ; then
7343     wxconfig_3rdparty="regex${lib_unicode_suffix} $wxconfig_3rdparty"
7344 fi
7345 if test "$wxUSE_EXPAT" = "builtin" ; then
7346     wxconfig_3rdparty="expat $wxconfig_3rdparty"
7347 fi
7348 if test "$wxUSE_ODBC" = "builtin" ; then
7349     wxconfig_3rdparty="odbc $wxconfig_3rdparty"
7350 fi
7351 if test "$wxUSE_LIBTIFF" = "builtin" ; then
7352     wxconfig_3rdparty="tiff $wxconfig_3rdparty"
7353 fi
7354 if test "$wxUSE_LIBJPEG" = "builtin" ; then
7355     wxconfig_3rdparty="jpeg $wxconfig_3rdparty"
7356 fi
7357 if test "$wxUSE_LIBPNG" = "builtin" ; then
7358     wxconfig_3rdparty="png $wxconfig_3rdparty"
7359 fi
7360 if test "$wxUSE_ZLIB" = "builtin" ; then
7361     wxconfig_3rdparty="zlib $wxconfig_3rdparty"
7362 fi
7363
7364 for i in $wxconfig_3rdparty ; do
7365     WXCONFIG_LIBS="-lwx${i}${lib_debug_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX} $WXCONFIG_LIBS"
7366 done
7367
7368
7369 if test "x$wxUSE_UNIVERSAL" = "xyes" ; then
7370     WXUNIV=1
7371
7372     case "$wxUNIV_THEMES" in
7373         ''|all)
7374             AC_DEFINE(wxUSE_ALL_THEMES)
7375             ;;
7376
7377         *)
7378             for t in `echo $wxUNIV_THEMES | tr , ' ' | tr a-z A-Z`; do
7379                 AC_DEFINE_UNQUOTED(wxUSE_THEME_$t)
7380             done
7381     esac
7382 else
7383     WXUNIV=0
7384 fi
7385
7386 AC_SUBST(wxUSE_ZLIB)
7387 AC_SUBST(wxUSE_REGEX)
7388 AC_SUBST(wxUSE_EXPAT)
7389 AC_SUBST(wxUSE_ODBC)
7390 AC_SUBST(wxUSE_LIBJPEG)
7391 AC_SUBST(wxUSE_LIBPNG)
7392 AC_SUBST(wxUSE_LIBTIFF)
7393
7394 if test $wxUSE_MONOLITHIC = "yes" ; then
7395     MONOLITHIC=1
7396 else
7397     MONOLITHIC=0
7398 fi
7399
7400 if test $wxUSE_PLUGINS = "yes" ; then
7401     USE_PLUGINS=1
7402 else
7403     USE_PLUGINS=0
7404 fi
7405
7406 if test $wxUSE_ODBC != "no" ; then
7407     USE_ODBC=1
7408 else
7409     USE_ODBC=0
7410 fi
7411
7412 if test "$wxUSE_DEBUGREPORT" = "yes" ; then
7413     USE_QA=1
7414 else
7415     USE_QA=0
7416 fi
7417
7418 if test $wxUSE_OFFICIAL_BUILD = "yes" ; then
7419     OFFICIAL_BUILD=1
7420 else
7421     OFFICIAL_BUILD=0
7422 fi
7423
7424 AC_SUBST(VENDOR)
7425 AC_SUBST(OFFICIAL_BUILD)
7426 AC_SUBST(WX_FLAVOUR)
7427 AC_SUBST(WX_LIB_FLAVOUR)
7428
7429 AC_SUBST(WXUNIV)
7430 AC_SUBST(MONOLITHIC)
7431 AC_SUBST(USE_PLUGINS)
7432 AC_SUBST(LIBS)
7433 AC_SUBST(CXXWARNINGS)
7434 AC_SUBST(EXTRALIBS)
7435 AC_SUBST(EXTRALIBS_XML)
7436 AC_SUBST(EXTRALIBS_HTML)
7437 AC_SUBST(EXTRALIBS_ODBC)
7438 AC_SUBST(EXTRALIBS_GUI)
7439 AC_SUBST(EXTRALIBS_OPENGL)
7440 AC_SUBST(EXTRALIBS_SDL)
7441 AC_SUBST(WITH_PLUGIN_SDL)
7442 AC_SUBST(EXTRALIBS_GNOMEPRINT)
7443 AC_SUBST(EXTRALIBS_GNOMEVFS)
7444 AC_SUBST(EXTRALIBS_HILDON)
7445 AC_SUBST(UNICODE)
7446 AC_SUBST(BUILD)
7447 AC_SUBST(DEBUG_INFO)
7448 AC_SUBST(DEBUG_FLAG)
7449 TOOLKIT_LOWERCASE=`echo $TOOLKIT | tr "[[A-Z]]" "[[a-z]]"`
7450 AC_SUBST(TOOLKIT_LOWERCASE)
7451 AC_SUBST(TOOLKIT_VERSION)
7452 AC_SUBST(SAMPLES_RPATH_FLAG)
7453 AC_SUBST(SAMPLES_RPATH_POSTLINK)
7454 AC_SUBST(HOST_SUFFIX)
7455 AC_SUBST(CPPUNIT_CFLAGS)
7456 AC_SUBST(CPPUNIT_LIBS)
7457
7458 case "$TOOLKIT" in
7459     GTK)
7460         TOOLKIT_DESC="GTK+"
7461         if test "$WXGTK20" = 1; then
7462             TOOLKIT_DESC="$TOOLKIT_DESC 2"
7463             if test "$wxUSE_LIBGNOMEPRINT" = "yes" ; then
7464                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA gnomeprint";
7465             fi
7466             if test "$wxUSE_LIBGNOMEVFS" = "yes" ; then
7467                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA gnomevfs"
7468             fi
7469             if test "$wxUSE_LIBHILDON" = "yes"; then
7470                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA hildon"
7471             fi
7472
7473             if test "$TOOLKIT_EXTRA" != ""; then
7474                 TOOLKIT_DESC="$TOOLKIT_DESC with support for `echo $TOOLKIT_EXTRA | tr -s ' '`"
7475             fi
7476         fi
7477         ;;
7478
7479     ?*)
7480         TOOLKIT_DESC=$TOOLKIT_LOWERCASE
7481         ;;
7482
7483     *)
7484         TOOLKIT_DESC="base only"
7485         ;;
7486 esac
7487
7488 if test "$wxUSE_WINE" = "yes"; then
7489     BAKEFILE_FORCE_PLATFORM=win32
7490 fi
7491
7492 dnl ---------------------------------------------------------------------------
7493 dnl Add Universal binary support
7494 dnl Note we don't do this earlier because adding these cpp/ld flags could
7495 dnl cause configure tests to fail.
7496 dnl ---------------------------------------------------------------------------
7497 if test "$wxUSE_MAC" = 1 ; then
7498     if test "x$wxUSE_UNIVERSAL_BINARY" != xno ; then
7499         dnl --enable-universal_binary uses a default SDK (currently 10.4u)
7500         dnl --enable-universal_binary=SDK names a path to an SDK
7501         if test "x$wxUSE_UNIVERSAL_BINARY" == xyes; then
7502             OSX_UNIV_OPTS="-isysroot /Developer/SDKs/MacOSX10.4u.sdk"
7503         else
7504             dnl '' would mean universal with no SDK, which may be the case if
7505             dnl the compiler uses a sysroot by default
7506             OSX_UNIV_OPTS=${wxUSE_UNIVERSAL_BINARY:+"-isysroot '$wxUSE_UNIVERSAL_BINARY'"}
7507         fi
7508         OSX_UNIV_OPTS="$OSX_UNIV_OPTS -arch ppc -arch i386"
7509         CXXFLAGS="$OSX_UNIV_OPTS $CXXFLAGS"
7510         CFLAGS="$OSX_UNIV_OPTS $CFLAGS"
7511         LDFLAGS="$OSX_UNIV_OPTS $LDFLAGS"
7512         bk_use_pch=no
7513     fi
7514     # TODO: where do we add "-syslibroot,/Developer/SDKs/MacOSX10.4u.sdk" for libtool (static builds only)?
7515     #       The makefile currently uses AR and RANLIB, which libtool apparently supercedes.
7516 fi
7517
7518 dnl gcc 3.4 has a pch bug which truncates wide character constants in headers.
7519 dnl Hopefully for a non-unicode build there aren't any wide constants in
7520 dnl headers, but for a unicode build it's best to disable pch.
7521 if test "$wxUSE_UNICODE" = yes -a "$GCC" = yes -a "$bk_use_pch" != no
7522 then
7523     AC_CACHE_CHECK(
7524         [for gcc precompiled header bug],
7525         [wx_cv_gcc_pch_bug],
7526         [[
7527             echo '#include <stdio.h>
7528                   const wchar_t test_var[] = L"awidetest";' > conftest.h
7529
7530             echo '#include "conftest.h"
7531                   int main()
7532                   {
7533                      printf("%ls", test_var);
7534                      return 0;
7535                   }' > conftest.cpp
7536
7537             wx_cv_gcc_pch_bug="pch not supported"
7538
7539             if $CXX conftest.h >/dev/null 2>&1
7540             then
7541                 wx_cv_gcc_pch_bug=
7542
7543                 if $CXX -o conftest$PROGRAM_EXT conftest.cpp >/dev/null 2>&1
7544                 then
7545                     if tr -dc '[a-z]' < conftest$PROGRAM_EXT |
7546                         grep awidetest >/dev/null
7547                     then
7548                         wx_cv_gcc_pch_bug=no
7549                     else
7550                         wx_cv_gcc_pch_bug=yes
7551                     fi
7552                 fi
7553             fi
7554
7555             rm -f conftest.h conftest.gch conftest.cpp conftest$PROGRAM_EXT
7556         ]])
7557
7558     if test "$wx_cv_gcc_pch_bug" = yes; then
7559         dnl make the default for pch 'no'
7560         dnl further below check whether the user overrode and warn them
7561         bk_use_pch=no
7562     fi
7563 fi
7564
7565 AC_BAKEFILE([m4_include(autoconf_inc.m4)])
7566
7567 dnl find out if the compiler supports PCH
7568 dnl
7569 dnl TODO: this should be in bakefile
7570 if test $GCC_PCH = 1
7571 then
7572     if test "$wx_cv_gcc_pch_bug" = yes; then
7573         AC_MSG_WARN([*** Precompiled header support is broken on this compiler])
7574         AC_MSG_WARN([*** --enable-precomp-headers is not recommended])
7575         AC_MSG_WARN([*** see http://gcc.gnu.org/bugzilla/show_bug.cgi?id=13361])
7576     fi
7577
7578     CPPFLAGS="-DWX_PRECOMP $CPPFLAGS"
7579 fi
7580
7581 dnl HACK ALERT!!
7582 dnl For now, we need to alter bk-deps not to generate deps
7583 dnl when we've configured a Universal binary build.
7584 dnl The next version of Bakefile will have the correct fix for this
7585 dnl at which time, this hack can be removed.
7586
7587 if test "$wxUSE_MAC" = 1 ; then
7588     if test "x$wxUSE_UNIVERSAL_BINARY" != "xno" ; then
7589         sed "s/DEPSMODE=gcc/DEPSMODE=none/" < bk-deps > temp
7590         mv temp bk-deps
7591         chmod +x bk-deps
7592     fi
7593 fi
7594
7595 if test "$wxUSE_SHARED" = "yes"; then
7596
7597     dnl We get the shared build linker from bakefile, since it
7598     dnl moved all the logic for this out of this file and into
7599     dnl its own macro.  But it can't decide on whether to return
7600     dnl us $(VAR), ${VAR}, or the present expansion of VAR.
7601     dnl So normalise and expand everything here now, because its
7602     dnl not going to change inside wx-config anyway.
7603     sanitised_bakefile_mess=`echo "$SHARED_LD_CXX" | tr -d '()'`
7604     EXE_LINKER=`eval echo "$sanitised_bakefile_mess"`
7605
7606     dnl Need addtional flag on OS/2, so override bakefiles value
7607     dnl (there currently is no suitable variable to which the
7608     dnl  missing flags could be added, AFAICS. SN, 18.12.2004. )
7609     case "${host}" in
7610       *-pc-os2_emx | *-pc-os2-emx )
7611         SHARED_LD_CC="`pwd`/dllar.sh -name-mangler-script ./dllnames.sh -libf INITINSTANCE -libf TERMINSTANCE -o"
7612         SHARED_LD_CXX="`pwd`/dllar.sh -name-mangler-script ./dllnames.sh -libf INITINSTANCE -libf TERMINSTANCE -o"
7613         cp -p ${srcdir}/src/os2/dllnames.sh .
7614         cp -p ${srcdir}/src/os2/dllar.sh .
7615       ;;
7616     esac
7617 else
7618
7619     dnl No bakefile support for static builds, but this should be ok for most.
7620     EXE_LINKER="$CXX -o"
7621
7622 fi
7623 if test "$wxUSE_OMF" = "yes"; then
7624     case "${host}" in
7625       *-pc-os2_emx | *-pc-os2-emx )
7626         LDFLAGS="$LDFLAGS -Zlinker /EXEPACK"
7627         LDFLAGS_GUI="-Zlinker /PMTYPE:PM"
7628         WXCONFIG_LDFLAGS_GUI="-Zlinker /PMTYPE:PM"
7629       ;;
7630     esac
7631 fi
7632
7633 dnl TOOLCHAIN_DEFS should be used for both wx and client code
7634 WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS $TOOLCHAIN_DEFS"
7635
7636
7637 dnl Sun cc is compatible with gcc and so either of them can use the C
7638 dnl libraries built with the other, i.e. gcc can be used to build wxGTK under
7639 dnl Solaris where GTK+ is compiled using cc and cc can be used under Linux
7640 dnl where GTK+ is built with gcc
7641 dnl
7642 dnl However the compiler options are not compatible at all and in particular
7643 dnl gcc doesn't like cc -mt option and cc doesn't like -pthread. We simply
7644 dnl filter them out as we already have the correct options for multithreaded
7645 dnl programs if we're using threads (and if we don't, it shouldn't matter)
7646 case "${host}" in
7647     *-*-solaris2* )
7648         dnl system packages are compiled with Sun CC and so pkg-config outputs
7649         dnl CC-specific "-mt" flag, remove it when using gcc
7650         if "$GCC" = yes; then
7651             CPPFLAGS=`echo $CPPFLAGS | sed 's/-mt//'`
7652             LIBS=`echo $LIBS | sed 's/-mt//'`
7653             EXTRALIBS_GUI=`echo $EXTRALIBS_GUI | sed 's/-mt//'`
7654         fi
7655         ;;
7656
7657     *-*-linux* )
7658         dnl OTOH when using Sun CC under Linux, the flags contain gcc-specific
7659         dnl -pthreads which Sun CC doesn't know about
7660         if test "x$SUNCXX" = xyes; then
7661             CPPFLAGS=`echo $CPPFLAGS | sed 's/-pthread//'`
7662             LIBS=`echo $LIBS | sed 's/-pthread//'`
7663             EXTRALIBS_GUI=`echo $EXTRALIBS_GUI | sed 's/-pthread//'`
7664         fi
7665         ;;
7666 esac
7667
7668 dnl Add visibility support flags to CFLAGS/CXXFLAGS - do it this late so that
7669 dnl it doesn't affect compilation checks above
7670 CFLAGS="$CFLAGS $CFLAGS_VISIBILITY"
7671 CXXFLAGS="$CXXFLAGS $CXXFLAGS_VISIBILITY"
7672
7673 dnl for convenience, sort the samples in alphabetical order
7674 dnl
7675 dnl FIXME For some mysterious reasons, sometimes the directories are duplicated
7676 dnl       in this list - hence uniq. But normally, this shouldn't be needed!
7677 dnl
7678 dnl       Unfortunately, there is a bug in OS/2's tr, such that
7679 dnl       tr ' ' '\n' introduces DOS-like line breaks, whereas tr '\n' ' '
7680 dnl       only removes the Unix-like part of the introduced line break.
7681 SAMPLES_SUBDIRS="`echo $SAMPLES_SUBDIRS | tr -s ' ' | tr ' ' '\n' | sort | uniq | tr '\n' ' '| tr -d '\r'`"
7682
7683 dnl subtle bakefile goop.
7684 dnl Used in wx-config now too, as its STATIC_FLAG with different makeup.
7685 dnl I wish we would have called it something less likely to clash with
7686 dnl things though.
7687 AC_SUBST(SHARED)
7688
7689 dnl global options
7690 AC_SUBST(WX_LIBRARY_BASENAME_NOGUI)
7691 AC_SUBST(WX_LIBRARY_BASENAME_GUI)
7692
7693 dnl toolkit options
7694 AC_SUBST(USE_GUI)
7695 AC_SUBST(AFMINSTALL)
7696 AC_SUBST(WIN32INSTALL)
7697 AC_SUBST(TOOLKIT)
7698 AC_SUBST(TOOLKIT_DIR)
7699 AC_SUBST(TOOLCHAIN_NAME)
7700 AC_SUBST(TOOLCHAIN_FULLNAME)
7701
7702 dnl wx-config options
7703 AC_SUBST(host_alias)
7704 AC_SUBST(cross_compiling)
7705 AC_SUBST(WIDGET_SET)
7706 AC_SUBST(WX_RELEASE)
7707 AC_SUBST(WX_VERSION)
7708 AC_SUBST(WX_SUBVERSION)
7709 AC_SUBST(WX_CHARTYPE)
7710 AC_SUBST(WX_DEBUGTYPE)
7711
7712 dnl note that in addition to the usual CPP/C/CXXFLAGS which are used for
7713 dnl building the library itself, we also have WXCONFIG_-prefixed variants which
7714 dnl are used when building the libraries using the library
7715 dnl
7716 dnl so put anything which should be used only during the library build in, e.g.
7717 dnl CXXFLAGS, but put everything else (by default) into WXCONFIG_CXXFLAGS
7718 dnl
7719 dnl and, finally, for some things which should be only used by wx-config but
7720 dnl not during the library compilation, use WXCONFIG_ONLY_CPPFLAGS which is
7721 dnl added to WXCONFIG_CPPFLAGS after adding the latter to CPPFLAGS
7722 AC_SUBST(WXCONFIG_CPPFLAGS)
7723 AC_SUBST(WXCONFIG_CFLAGS)
7724 AC_SUBST(WXCONFIG_CXXFLAGS)
7725
7726 AC_SUBST(WXCONFIG_LIBS)
7727 AC_SUBST(WXCONFIG_RPATH)
7728 AC_SUBST(WXCONFIG_LDFLAGS_GUI)
7729 AC_SUBST(WXCONFIG_RESFLAGS)
7730 AC_SUBST(EXE_LINKER)
7731
7732 dnl distribution vars
7733 AC_SUBST(GUIDIST)
7734 AC_SUBST(DISTDIR)
7735
7736 dnl additional subdirectories where we will build
7737 AC_SUBST(SAMPLES_SUBDIRS)
7738
7739 dnl additional libraries and linker settings
7740 AC_SUBST(LDFLAGS)
7741 AC_SUBST(LDFLAGS_GL)
7742 AC_SUBST(OPENGL_LIBS)
7743 AC_SUBST(DMALLOC_LIBS)
7744 AC_SUBST(WX_VERSION_TAG)
7745
7746 dnl additional resurces settings
7747 AC_SUBST(RESCOMP)
7748 AC_SUBST(WINDRES)
7749 AC_SUBST(REZ)
7750 AC_SUBST(RESFLAGS)
7751 AC_SUBST(RESPROGRAMOBJ)
7752 AC_SUBST(WX_RESOURCES_MACOSX_ASCII)
7753 AC_SUBST(WX_RESOURCES_MACOSX_DATA)
7754
7755 dnl additional for Mac OS X
7756 AC_SUBST(DEREZ)
7757 AC_SUBST(LIBWXMACRES)
7758 AC_SUBST(POSTLINK_COMMAND)
7759 AC_SUBST(MACSETFILE)
7760
7761 dnl other tools
7762 AC_SUBST(GCC)
7763 AC_SUBST(DLLTOOL)
7764
7765
7766 dnl MAKE_SET will be replaced with "MAKE=..." or nothing if make sets MAKE
7767 dnl itself (this macro is required if SUBDIRS variable is used in Makefile.am
7768 dnl - and we do use it)
7769 AC_PROG_MAKE_SET
7770
7771
7772 AC_CONFIG_HEADERS([lib/wx/include/${TOOLCHAIN_FULLNAME}/wx/setup.h:setup.h.in])
7773
7774 if test "$USE_WIN32" = 1; then
7775     AC_CONFIG_COMMANDS(
7776         [
7777             rcdefs.h
7778         ],
7779         [
7780             mkdir -p $outdir &&
7781             $CPP $infile | sed 's/^# *[1-9].*//;s/^ *//;/./,/^$/!d' > $outdir/rcdefs.h
7782         ],
7783         [
7784             CPP="$CPP"
7785             infile="$srcdir/include/wx/msw/genrcdefs.h"
7786             outdir="lib/wx/include/$TOOLCHAIN_FULLNAME/wx/msw"
7787         ]
7788     )
7789 fi
7790
7791 AC_CONFIG_FILES([ lib/wx/config/${TOOLCHAIN_FULLNAME}:wx-config.in ],
7792                 [ chmod +x lib/wx/config/${TOOLCHAIN_FULLNAME} ],
7793                 [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}" ])
7794
7795 AC_CONFIG_FILES([ lib/wx/config/inplace-${TOOLCHAIN_FULLNAME}:wx-config-inplace.in ],
7796                 [ chmod +x lib/wx/config/inplace-${TOOLCHAIN_FULLNAME} ],
7797                 [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}" ])
7798
7799 if test "$wx_cv_version_script" = "yes"; then
7800     AC_CONFIG_FILES(version-script)
7801 fi
7802 AC_CONFIG_FILES(Makefile)
7803
7804 AC_CONFIG_COMMANDS([wx-config],
7805                    [ rm -f wx-config
7806                      ${LN_S} lib/wx/config/inplace-${TOOLCHAIN_FULLNAME} wx-config
7807                    ],
7808                    [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}"
7809                      LN_S="${LN_S}"
7810                    ])
7811
7812 dnl This would give us us build dir that in every significant way
7813 dnl resembles an installed wx in prefix=$builddir.  It is troublesome
7814 dnl though in this form because AC_CONFIG_LINKS will fail for directories
7815 dnl on platforms that do not have symlinks.
7816 dnl AC_CONFIG_LINKS([ include/wx-$WX_RELEASE$WX_FLAVOUR:include ])
7817
7818 if test "$wxWITH_SUBDIRS" != "no"; then
7819 dnl Configure samples, demos etc. directories, but only if they are present:
7820 if test "$wxUSE_GUI" = "yes"; then
7821     SUBDIRS="samples demos utils"
7822 else dnl we build wxBase only
7823     dnl there are no wxBase programs in demos
7824     SUBDIRS="samples utils"
7825 fi
7826 dnl Add tests to the list of subdirs if cppunit 1.8.0+ is detected
7827 AM_PATH_CPPUNIT(1.8.0, [SUBDIRS="$SUBDIRS tests"])
7828
7829 for subdir in `echo $SUBDIRS`; do
7830     if test -d ${srcdir}/${subdir} ; then
7831         if test "$wxUSE_GUI" = "yes"; then
7832             if test ${subdir} = "samples"; then
7833                 dnl only take those samples which compile in the current
7834                 dnl configuration and which exist
7835                 makefiles="samples/Makefile.in $makefiles"
7836                 for sample in `echo $SAMPLES_SUBDIRS`; do
7837                     if test -d $srcdir/samples/$sample; then
7838                         makefiles="samples/$sample/Makefile.in $makefiles"
7839                     fi
7840                 done
7841             else
7842                 dnl assume that everything compiles for utils &c
7843                 dnl any that shouldn't be built can be added to
7844                 dnl DISABLED_UTILS, DISABLED_DEMOS
7845                 disabled_var=DISABLED_`echo $subdir | tr [[a-z]] [[A-Z]]`;
7846                 eval "disabled=\$$disabled_var"
7847                 disabled=/`echo X $disabled | sed 's@ @/|/@g'`/
7848                 makefiles=`(cd $srcdir ; find $subdir -name Makefile.in) | $EGREP -v "$disabled"`
7849             fi
7850         else dnl we build wxBase only
7851             dnl don't take all samples/utils, just those which build with
7852             dnl wxBase
7853             if test ${subdir} = "samples"; then
7854                 makefiles="samples/Makefile.in samples/console/Makefile.in"
7855             elif test ${subdir} = "utils"; then
7856                 makefiles=""
7857                 for util in HelpGen tex2rtf ; do
7858                     if test -d $srcdir/utils/$util ; then
7859                         makefiles="utils/$util/Makefile.in \
7860                                    utils/$util/src/Makefile.in \
7861                                    $makefiles"
7862                     fi
7863                 done
7864             else dnl assume that everything compiles for tests
7865                 makefiles=`(cd $srcdir ; find $subdir -name Makefile.in)`
7866             fi
7867         fi
7868
7869         for mkin in $makefiles ; do
7870             mk=`echo $mkin | sed 's/Makefile\.in/Makefile/g'`
7871             AC_CONFIG_FILES([$mk])
7872         done
7873     fi
7874 done
7875 fi dnl wxWITH_SUBDIRS
7876
7877 AC_OUTPUT
7878
7879 dnl report how we have been configured
7880 echo
7881 echo "Configured wxWidgets ${WX_VERSION} for \`${host}'"
7882 echo ""
7883 echo "  Which GUI toolkit should wxWidgets use?                 ${TOOLKIT_DESC}"
7884 echo "  Should wxWidgets be compiled into single library?       ${wxUSE_MONOLITHIC:-yes}"
7885
7886 echo "  Should wxWidgets be compiled in debug mode?             ${wxUSE_DEBUG:-no}"
7887 echo "  Should wxWidgets be linked as a shared library?         ${wxUSE_SHARED:-no}"
7888 echo -n "  Should wxWidgets support Unicode?                       ${wxUSE_UNICODE:-no}"
7889 if test "$wxUSE_UNICODE" = "yes"; then
7890     if test "$wxUSE_UNICODE_UTF8" = "yes"; then
7891         echo " (using UTF-8)"
7892     else
7893         echo " (using wchar_t)"
7894     fi
7895 else
7896     echo
7897 fi
7898
7899 echo "  What level of wxWidgets compatibility should be enabled?"
7900 echo "                                       wxWidgets 2.6      ${WXWIN_COMPATIBILITY_2_6:-no}"
7901 echo "                                       wxWidgets 2.8      ${WXWIN_COMPATIBILITY_2_8:-yes}"
7902
7903 echo "  Which libraries should wxWidgets use?"
7904 echo "                                       jpeg               ${wxUSE_LIBJPEG-none}"
7905 echo "                                       png                ${wxUSE_LIBPNG-none}"
7906 echo "                                       regex              ${wxUSE_REGEX}"
7907 echo "                                       tiff               ${wxUSE_LIBTIFF-none}"
7908 if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
7909 echo "                                       xpm                ${wxUSE_LIBXPM-none}"
7910 fi
7911 echo "                                       zlib               ${wxUSE_ZLIB}"
7912 echo "                                       odbc               ${wxUSE_ODBC}"
7913 echo "                                       expat              ${wxUSE_EXPAT}"
7914 echo "                                       libmspack          ${wxUSE_LIBMSPACK}"
7915 echo "                                       sdl                ${wxUSE_LIBSDL}"
7916
7917 echo ""
7918
7919 dnl vi: set et sts=4 sw=4 com=\:dnl: