src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16     #include "wx/app.h"
  17     #include "wx/dialog.h"
  18     #include "wx/menuitem.h"
  19     #include "wx/menu.h"
  20 #endif
  21
  22 #include "wx/osx/private.h"
  23
  24 NSScreen* wxOSXGetMenuScreen()
  25 {
  26     if ( [NSScreen screens] == nil )
  27         return [NSScreen mainScreen];
  28     else
  29     {
  30         return [[NSScreen screens] objectAtIndex:0];
  31     }
  32 }
  33
  34 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  35 {
  36     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  37     int y = r.y;
  38     int x = r.x ;
  39     if ( parent == NULL || ![ parent isFlipped ] )
  40         y = (int)(frame.size.height - ( r.y + r.height ));
  41     return NSMakeRect(x, y, r.width , r.height);
  42 }
  43
  44 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  45 {
  46     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  47     int y = (int)rect.origin.y;
  48     int x = (int)rect.origin.x;
  49     if ( parent == NULL || ![ parent isFlipped ] )
  50         y = (int)(frame.size.height - (rect.origin.y + rect.size.height));
  51     return wxRect( x, y, (int)rect.size.width, (int)rect.size.height );
  52 }
  53
  54 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  55 {
  56     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  57     int x = p.x ;
  58     int y = p.y;
  59     if ( parent == NULL || ![ parent isFlipped ] )
  60         y = (int)(frame.size.height - ( p.y ));
  61     return NSMakePoint(x, y);
  62 }
  63
  64 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  65 {
  66     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  67     int x = (int)p.x;
  68     int y = (int)p.y;
  69     if ( parent == NULL || ![ parent isFlipped ] )
  70         y = (int)(frame.size.height - ( p.y ));
  71     return wxPoint( x, y);
  72 }
  73
  74 bool shouldHandleSelector(SEL selector)
  75 {
  76     if (selector == @selector(noop:)
  77             || selector == @selector(complete:)
  78             || selector == @selector(deleteBackward:)
  79             || selector == @selector(deleteForward:)
  80             || selector == @selector(insertNewline:)
  81             || selector == @selector(insertTab:)
  82             || selector == @selector(insertBacktab:)
  83             || selector == @selector(keyDown:)
  84             || selector == @selector(keyUp:)
  85             || selector == @selector(scrollPageUp:)
  86             || selector == @selector(scrollPageDown:)
  87             || selector == @selector(scrollToBeginningOfDocument:)
  88             || selector == @selector(scrollToEndOfDocument:))
  89         return false;
  90
  91     return true;
  92
  93 }
  94
  95 //
  96 // wx category for NSWindow (our own and wrapped instances)
  97 //
  98
  99 @interface NSWindow (wxNSWindowSupport)
 100
 101 - (wxNonOwnedWindowCocoaImpl*) WX_implementation;
 102
 103 - (bool) WX_filterSendEvent:(NSEvent *) event;
 104
 105 @end
 106
 107 @implementation NSWindow (wxNSWindowSupport)
 108
 109 - (wxNonOwnedWindowCocoaImpl*) WX_implementation
 110 {
 111     return (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 112 }
 113
 114 // TODO in cocoa everything during a drag is sent to the NSWindow the mouse down occured,
 115 // this does not conform to the wx behaviour if the window is not captured, so try to resend
 116 // or capture all wx mouse event handling at the tlw as we did for carbon
 117
 118 - (bool) WX_filterSendEvent:(NSEvent *) event
 119 {
 120     bool handled = false;
 121     if ( ([event type] >= NSLeftMouseDown) && ([event type] <= NSMouseExited) )
 122     {
 123         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 124         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 125
 126         wxWindow* cw = wxWindow::GetCapture();
 127         if ( cw != NULL )
 128         {
 129             if (wxTheApp)
 130                 wxTheApp->MacSetCurrentEvent(event, NULL);
 131             ((wxWidgetCocoaImpl*)cw->GetPeer())->DoHandleMouseEvent( event);
 132             handled = true;
 133         }
 134         if ( handled )
 135         {
 136             if (wxTheApp)
 137                 wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 138         }
 139     }
 140     return handled;
 141 }
 142 @end
 143
 144 //
 145 // wx native implementation
 146 //
 147
 148 @interface wxNSWindow : NSWindow
 149 {
 150 }
 151
 152 - (void) sendEvent:(NSEvent *)event;
 153 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 154 - (void)noResponderFor: (SEL) selector;
 155 @end
 156
 157 @implementation wxNSWindow
 158
 159 - (void)sendEvent:(NSEvent *) event
 160 {
 161     if ( ![self WX_filterSendEvent: event] )
 162     {
 163         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 164         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 165
 166         if (wxTheApp)
 167             wxTheApp->MacSetCurrentEvent(event, NULL);
 168
 169         [super sendEvent: event];
 170
 171         if (wxTheApp)
 172             wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 173     }
 174 }
 175
 176 // The default implementation always moves the window back onto the screen,
 177 // even when the programmer explicitly wants to hide it.
 178 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 179 {
 180     wxUnusedVar(screen);
 181     return frameRect;
 182 }
 183
 184 - (void)doCommandBySelector:(SEL)selector
 185 {
 186     if (shouldHandleSelector(selector) &&
 187         !(selector == @selector(cancel:) || selector == @selector(cancelOperation:)) )
 188         [super doCommandBySelector:selector];
 189 }
 190
 191
 192 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 193 - (void)noResponderFor: (SEL) selector
 194 {
 195     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 196     {
 197         [super noResponderFor:selector];
 198     }
 199 }
 200
 201 // We need this for borderless windows, i.e. shaped windows or windows without
 202 // a title bar. For more info, see:
 203 // http://lists.apple.com/archives/cocoa-dev/2008/May/msg02091.html
 204 - (BOOL)canBecomeKeyWindow
 205 {
 206     return YES;
 207 }
 208
 209 @end
 210
 211 @interface wxNSPanel : NSPanel
 212 {
 213 }
 214
 215 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 216 - (void)noResponderFor: (SEL) selector;
 217 - (void)sendEvent:(NSEvent *)event;
 218 @end
 219
 220 @implementation wxNSPanel
 221
 222 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 223 {
 224     wxNonOwnedWindowCocoaImpl* impl = (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 225     if (impl && impl->IsFullScreen())
 226         return frameRect;
 227     else
 228         return [super constrainFrameRect:frameRect toScreen:screen];
 229 }
 230
 231 - (BOOL)canBecomeKeyWindow
 232 {
 233     return YES;
 234 }
 235
 236 - (void)doCommandBySelector:(SEL)selector
 237 {
 238     if (shouldHandleSelector(selector))
 239         [super doCommandBySelector:selector];
 240 }
 241
 242 // NB: if we don't do this, it seems that all events that end here lead to a NSBeep
 243 - (void)noResponderFor: (SEL) selector
 244 {
 245     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 246     {
 247         [super noResponderFor:selector];
 248     }
 249 }
 250
 251 - (void)sendEvent:(NSEvent *) event
 252 {
 253     if ( ![self WX_filterSendEvent: event] )
 254     {
 255         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 256         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 257
 258         if (wxTheApp)
 259             wxTheApp->MacSetCurrentEvent(event, NULL);
 260
 261         [super sendEvent: event];
 262
 263         if (wxTheApp)
 264             wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 265     }
 266 }
 267
 268 @end
 269
 270
 271 //
 272 // controller
 273 //
 274
 275 @interface wxNonOwnedWindowController : NSObject wxOSX_10_6_AND_LATER(<NSWindowDelegate>)
 276 {
 277 }
 278
 279 - (void)windowDidResize:(NSNotification *)notification;
 280 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 281 - (void)windowDidResignKey:(NSNotification *)notification;
 282 - (void)windowDidBecomeKey:(NSNotification *)notification;
 283 - (void)windowDidMove:(NSNotification *)notification;
 284 - (BOOL)windowShouldClose:(id)window;
 285 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame;
 286
 287 @end
 288
 289 extern int wxOSXGetIdFromSelector(SEL action );
 290
 291 @implementation wxNonOwnedWindowController
 292
 293 - (id) init
 294 {
 295     self = [super init];
 296     return self;
 297 }
 298
 299 - (BOOL) triggerMenu:(SEL) action
 300 {
 301     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 302     if ( mbar )
 303     {
 304         wxMenu* menu = NULL;
 305         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 306         if ( menu != NULL && menuitem != NULL)
 307             return menu->HandleCommandProcess(menuitem);
 308     }
 309     return NO;
 310 }
 311
 312 - (BOOL)validateMenuItem:(NSMenuItem *)menuItem
 313 {
 314     SEL action = [menuItem action];
 315
 316     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 317     if ( mbar )
 318     {
 319         wxMenu* menu = NULL;
 320         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 321         if ( menu != NULL && menuitem != NULL)
 322         {
 323             menu->HandleCommandUpdateStatus(menuitem);
 324             return menuitem->IsEnabled();
 325         }
 326     }
 327     return YES;
 328 }
 329
 330 - (void)undo:(id)sender
 331 {
 332     wxUnusedVar(sender);
 333     [self triggerMenu:_cmd];
 334 }
 335
 336 - (void)redo:(id)sender
 337 {
 338     wxUnusedVar(sender);
 339     [self triggerMenu:_cmd];
 340 }
 341
 342 - (void)cut:(id)sender
 343 {
 344     wxUnusedVar(sender);
 345     [self triggerMenu:_cmd];
 346 }
 347
 348 - (void)copy:(id)sender
 349 {
 350     wxUnusedVar(sender);
 351     [self triggerMenu:_cmd];
 352 }
 353
 354 - (void)paste:(id)sender
 355 {
 356     wxUnusedVar(sender);
 357     [self triggerMenu:_cmd];
 358 }
 359
 360 - (void)delete:(id)sender
 361 {
 362     wxUnusedVar(sender);
 363     [self triggerMenu:_cmd];
 364 }
 365
 366 - (void)selectAll:(id)sender
 367 {
 368     wxUnusedVar(sender);
 369     [self triggerMenu:_cmd];
 370 }
 371
 372 - (BOOL)windowShouldClose:(id)nwindow
 373 {
 374     wxNonOwnedWindowCocoaImpl* windowimpl = [(NSWindow*) nwindow WX_implementation];
 375     if ( windowimpl )
 376     {
 377         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 378         if ( wxpeer )
 379             wxpeer->Close();
 380     }
 381     return NO;
 382 }
 383
 384 - (NSSize)windowWillResize:(NSWindow *)window
 385                     toSize:(NSSize)proposedFrameSize
 386 {
 387     NSRect frame = [window frame];
 388     wxRect wxframe = wxFromNSRect( NULL, frame );
 389     wxframe.SetWidth( (int)proposedFrameSize.width );
 390     wxframe.SetHeight( (int)proposedFrameSize.height );
 391
 392     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 393     if ( windowimpl )
 394     {
 395         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 396         if ( wxpeer )
 397         {
 398             wxpeer->HandleResizing( 0, &wxframe );
 399             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 400             return newSize;
 401         }
 402     }
 403
 404     return proposedFrameSize;
 405 }
 406
 407 - (void)windowDidResize:(NSNotification *)notification
 408 {
 409     NSWindow* window = (NSWindow*) [notification object];
 410     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 411     if ( windowimpl )
 412     {
 413         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 414         if ( wxpeer )
 415             wxpeer->HandleResized(0);
 416     }
 417 }
 418
 419 - (void)windowDidMove:(NSNotification *)notification
 420 {
 421     wxNSWindow* window = (wxNSWindow*) [notification object];
 422     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 423     if ( windowimpl )
 424     {
 425         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 426         if ( wxpeer )
 427             wxpeer->HandleMoved(0);
 428     }
 429 }
 430
 431 - (void)windowDidBecomeKey:(NSNotification *)notification
 432 {
 433     NSWindow* window = (NSWindow*) [notification object];
 434     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 435     if ( windowimpl )
 436     {
 437         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 438         if ( wxpeer )
 439             wxpeer->HandleActivated(0, true);
 440     }
 441 }
 442
 443 - (void)windowDidResignKey:(NSNotification *)notification
 444 {
 445     NSWindow* window = (NSWindow*) [notification object];
 446     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 447     if ( windowimpl )
 448     {
 449         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 450         if ( wxpeer )
 451         {
 452             wxpeer->HandleActivated(0, false);
 453             // Needed for popup window since the firstResponder
 454             // (focus in wx) doesn't change when this
 455             // TLW becomes inactive.
 456             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 457             event.SetEventObject(wxpeer);
 458             wxpeer->HandleWindowEvent(event);
 459         }
 460     }
 461 }
 462
 463 - (id)windowWillReturnFieldEditor:(NSWindow *)sender toObject:(id)anObject
 464 {
 465     wxUnusedVar(sender);
 466
 467     if ([anObject isKindOfClass:[wxNSTextField class]])
 468     {
 469         wxNSTextField* tf = (wxNSTextField*) anObject;
 470         wxNSTextFieldEditor* editor = [tf fieldEditor];
 471         if ( editor == nil )
 472         {
 473             editor = [[wxNSTextFieldEditor alloc] init];
 474             [editor setFieldEditor:YES];
 475             [tf setFieldEditor:editor];
 476             [editor release];
 477         }
 478         return editor;
 479     }
 480
 481     return nil;
 482 }
 483
 484 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame
 485 {
 486     wxUnusedVar(newFrame);
 487     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 488     if ( windowimpl )
 489     {
 490         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 491         wxMaximizeEvent event(wxpeer->GetId());
 492         event.SetEventObject(wxpeer);
 493         return !wxpeer->HandleWindowEvent(event);
 494     }
 495     return true;
 496 }
 497
 498 @end
 499
 500 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 501
 502 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 503     wxNonOwnedWindowImpl(nonownedwnd)
 504 {
 505     m_macWindow = NULL;
 506     m_macFullScreenData = NULL;
 507 }
 508
 509 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 510 {
 511     m_macWindow = NULL;
 512     m_macFullScreenData = NULL;
 513 }
 514
 515 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 516 {
 517     if ( !m_wxPeer->IsNativeWindowWrapper() )
 518     {
 519         [m_macWindow setDelegate:nil];
 520         [m_macWindow release];
 521     }
 522 }
 523
 524 void wxNonOwnedWindowCocoaImpl::WillBeDestroyed()
 525 {
 526     if ( !m_wxPeer->IsNativeWindowWrapper() )
 527     {
 528         [m_macWindow setDelegate:nil];
 529     }
 530 }
 531
 532 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* parent, const wxPoint& pos, const wxSize& size,
 533 long style, long extraStyle, const wxString& WXUNUSED(name) )
 534 {
 535     static wxNonOwnedWindowController* controller = NULL;
 536
 537     if ( !controller )
 538         controller =[[wxNonOwnedWindowController alloc] init];
 539
 540
 541     int windowstyle = NSBorderlessWindowMask;
 542
 543     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 544             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 545     {
 546         m_macWindow = [wxNSPanel alloc];
 547     }
 548     else
 549         m_macWindow = [wxNSWindow alloc];
 550
 551     CGWindowLevel level = kCGNormalWindowLevel;
 552
 553     if ( style & wxFRAME_TOOL_WINDOW )
 554     {
 555         windowstyle |= NSUtilityWindowMask;
 556     }
 557     else if ( ( style & wxPOPUP_WINDOW ) )
 558     {
 559         level = kCGPopUpMenuWindowLevel;
 560     }
 561     else if ( ( style & wxFRAME_DRAWER ) )
 562     {
 563         /*
 564         wclass = kDrawerWindowClass;
 565         */
 566     }
 567
 568     if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 569         ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) || ( style & wxCAPTION ) )
 570     {
 571         windowstyle |= NSTitledWindowMask ;
 572         if ( ( style & wxMINIMIZE_BOX ) )
 573             windowstyle |= NSMiniaturizableWindowMask ;
 574
 575         if ( ( style & wxMAXIMIZE_BOX ) )
 576             windowstyle |= NSResizableWindowMask ;
 577
 578         if ( ( style & wxCLOSE_BOX) )
 579             windowstyle |= NSClosableWindowMask ;
 580     }
 581
 582     if ( ( style & wxRESIZE_BORDER ) )
 583         windowstyle |= NSResizableWindowMask ;
 584
 585     if ( extraStyle & wxFRAME_EX_METAL)
 586         windowstyle |= NSTexturedBackgroundWindowMask;
 587
 588     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 589         level = kCGFloatingWindowLevel;
 590
 591     if ( ( style & wxSTAY_ON_TOP ) )
 592         level = kCGUtilityWindowLevel;
 593
 594     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 595
 596     r = [NSWindow contentRectForFrameRect:r styleMask:windowstyle];
 597
 598     [m_macWindow initWithContentRect:r
 599         styleMask:windowstyle
 600         backing:NSBackingStoreBuffered
 601         defer:NO
 602         ];
 603
 604     // if we just have a title bar with no buttons needed, hide them
 605     if ( (windowstyle & NSTitledWindowMask) &&
 606         !(style & wxCLOSE_BOX) && !(style & wxMAXIMIZE_BOX) && !(style & wxMINIMIZE_BOX) )
 607     {
 608         [[m_macWindow standardWindowButton:NSWindowZoomButton] setHidden:YES];
 609         [[m_macWindow standardWindowButton:NSWindowCloseButton] setHidden:YES];
 610         [[m_macWindow standardWindowButton:NSWindowMiniaturizeButton] setHidden:YES];
 611     }
 612
 613     // If the parent is modal, windows with wxFRAME_FLOAT_ON_PARENT style need
 614     // to be in kCGUtilityWindowLevel and not kCGFloatingWindowLevel to stay
 615     // above the parent.
 616     wxDialog * const parentDialog = wxDynamicCast(parent, wxDialog);
 617     if (parentDialog && parentDialog->IsModal())
 618     {
 619         if (level == kCGFloatingWindowLevel)
 620         {
 621             level = kCGUtilityWindowLevel;
 622         }
 623
 624         // Cocoa's modal loop does not process other windows by default, but
 625         // don't call this on normal window levels so nested modal dialogs will
 626         // still behave modally.
 627         if (level != kCGNormalWindowLevel)
 628         {
 629             if ([m_macWindow isKindOfClass:[NSPanel class]])
 630             {
 631                 [(NSPanel*)m_macWindow setWorksWhenModal:YES];
 632             }
 633         }
 634     }
 635
 636     [m_macWindow setLevel:level];
 637     m_macWindowLevel = level;
 638
 639     [m_macWindow setDelegate:controller];
 640
 641     if ( ( style & wxFRAME_SHAPED) )
 642     {
 643         [m_macWindow setOpaque:NO];
 644         [m_macWindow setAlphaValue:1.0];
 645     }
 646
 647     if ( !(style & wxFRAME_TOOL_WINDOW) )
 648         [m_macWindow setHidesOnDeactivate:NO];
 649 }
 650
 651 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), WXWindow nativeWindow )
 652 {
 653     m_macWindow = nativeWindow;
 654 }
 655
 656 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 657 {
 658     return m_macWindow;
 659 }
 660
 661 void wxNonOwnedWindowCocoaImpl::Raise()
 662 {
 663     [m_macWindow makeKeyAndOrderFront:nil];
 664 }
 665
 666 void wxNonOwnedWindowCocoaImpl::Lower()
 667 {
 668     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 669 }
 670
 671 void wxNonOwnedWindowCocoaImpl::ShowWithoutActivating()
 672 {
 673     [m_macWindow orderFront:nil];
 674     [[m_macWindow contentView] setNeedsDisplay: YES];
 675 }
 676
 677 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 678 {
 679     if ( show )
 680     {
 681         wxNonOwnedWindow* wxpeer = GetWXPeer();
 682         if (wxpeer && !(wxpeer->GetWindowStyle() & wxFRAME_TOOL_WINDOW))
 683             [m_macWindow makeKeyAndOrderFront:nil];
 684         else
 685             [m_macWindow orderFront:nil];
 686         [[m_macWindow contentView] setNeedsDisplay: YES];
 687     }
 688     else
 689         [m_macWindow orderOut:nil];
 690     return true;
 691 }
 692
 693 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show,
 694                                                wxShowEffect effect,
 695                                                unsigned timeout)
 696 {
 697     return wxWidgetCocoaImpl::
 698             ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
 699 }
 700
 701 void wxNonOwnedWindowCocoaImpl::Update()
 702 {
 703     [m_macWindow displayIfNeeded];
 704 }
 705
 706 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 707 {
 708     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 709     return true;
 710 }
 711
 712 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& col )
 713 {
 714     [m_macWindow setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
 715                                                              green:(CGFloat) (col.Green() / 255.0)
 716                                                               blue:(CGFloat) (col.Blue() / 255.0)
 717                                                              alpha:(CGFloat) (col.Alpha() / 255.0)]];
 718     return true;
 719 }
 720
 721 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 722 {
 723     if ( m_macWindow )
 724     {
 725         bool metal = exStyle & wxFRAME_EX_METAL ;
 726         int windowStyle = [ m_macWindow styleMask];
 727         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 728         {
 729             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 730         }
 731         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 732         {
 733             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 734         }
 735     }
 736 }
 737
 738 void wxNonOwnedWindowCocoaImpl::SetWindowStyleFlag( long style )
 739 {
 740     if (m_macWindow)
 741     {
 742         CGWindowLevel level = kCGNormalWindowLevel;
 743
 744         if (style & wxSTAY_ON_TOP)
 745             level = kCGUtilityWindowLevel;
 746         else if (( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ))
 747             level = kCGFloatingWindowLevel;
 748
 749         [m_macWindow setLevel: level];
 750         m_macWindowLevel = level;
 751     }
 752 }
 753
 754 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle style)
 755 {
 756     if ( style == wxBG_STYLE_TRANSPARENT )
 757     {
 758         [m_macWindow setOpaque:NO];
 759         [m_macWindow setBackgroundColor:[NSColor clearColor]];
 760     }
 761
 762     return true;
 763 }
 764
 765 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 766 {
 767     return true;
 768 }
 769
 770 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 771 {
 772     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 773     // do not trigger refreshes upon invisible and possible partly created objects
 774     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 775 }
 776
 777 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 778 {
 779     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 780     x = r.GetLeft();
 781     y = r.GetTop();
 782 }
 783
 784 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 785 {
 786     NSRect rect = [m_macWindow frame];
 787     width = (int)rect.size.width;
 788     height = (int)rect.size.height;
 789 }
 790
 791 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 792 {
 793     NSRect rect = [[m_macWindow contentView] frame];
 794     left = (int)rect.origin.x;
 795     top = (int)rect.origin.y;
 796     width = (int)rect.size.width;
 797     height = (int)rect.size.height;
 798 }
 799
 800 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& WXUNUSED(region))
 801 {
 802     [m_macWindow setOpaque:NO];
 803     [m_macWindow setBackgroundColor:[NSColor clearColor]];
 804
 805     return true;
 806 }
 807
 808 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 809 {
 810     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 811 }
 812
 813 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 814 {
 815     if (([m_macWindow styleMask] & NSResizableWindowMask) != 0)
 816     {
 817         return [m_macWindow isZoomed];
 818     }
 819     else
 820     {
 821         NSRect rectScreen = [[NSScreen mainScreen] visibleFrame];
 822         NSRect rectWindow = [m_macWindow frame];
 823         return (rectScreen.origin.x == rectWindow.origin.x &&
 824                 rectScreen.origin.y == rectWindow.origin.y &&
 825                 rectScreen.size.width == rectWindow.size.width &&
 826                 rectScreen.size.height == rectWindow.size.height);
 827     }
 828 }
 829
 830 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 831 {
 832     return [m_macWindow isMiniaturized];
 833 }
 834
 835 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 836 {
 837     if ( iconize )
 838         [m_macWindow miniaturize:nil];
 839     else
 840         [m_macWindow deminiaturize:nil];
 841 }
 842
 843 void wxNonOwnedWindowCocoaImpl::Maximize(bool WXUNUSED(maximize))
 844 {
 845     [m_macWindow zoom:nil];
 846 }
 847
 848
 849 // http://cocoadevcentral.com/articles/000028.php
 850
 851 typedef struct
 852 {
 853     NSUInteger m_formerStyleMask;
 854     int m_formerLevel;
 855     NSRect m_formerFrame;
 856 } FullScreenData ;
 857
 858 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 859 {
 860     return m_macFullScreenData != NULL ;
 861 }
 862
 863 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long WXUNUSED(style))
 864 {
 865     if ( show )
 866     {
 867         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 868         delete data ;
 869         data = new FullScreenData();
 870
 871         m_macFullScreenData = data ;
 872         data->m_formerLevel = [m_macWindow level];
 873         data->m_formerFrame = [m_macWindow frame];
 874         data->m_formerStyleMask = [m_macWindow styleMask];
 875 #if 0
 876         // CGDisplayCapture( kCGDirectMainDisplay );
 877         //[m_macWindow setLevel:NSMainMenuWindowLevel+1/*CGShieldingWindowLevel()*/];
 878 #endif
 879         NSRect screenframe = [[NSScreen mainScreen] frame];
 880         NSRect frame = NSMakeRect (0, 0, 100, 100);
 881         NSRect contentRect;
 882
 883 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
 884         if ( [ m_macWindow respondsToSelector:@selector(setStyleMask:) ] )
 885             [m_macWindow setStyleMask:data->m_formerStyleMask & ~ NSResizableWindowMask];
 886 #endif
 887
 888         contentRect = [NSWindow contentRectForFrameRect: frame
 889                                 styleMask: [m_macWindow styleMask]];
 890         screenframe.origin.y += (frame.origin.y - contentRect.origin.y);
 891         screenframe.size.height += (frame.size.height - contentRect.size.height);
 892         [m_macWindow setFrame:screenframe display:YES];
 893
 894         SetSystemUIMode(kUIModeAllHidden,
 895                                 kUIOptionDisableAppleMenu
 896                         /*
 897                                 | kUIOptionDisableProcessSwitch
 898                                 | kUIOptionDisableForceQuit
 899                          */);
 900     }
 901     else if ( m_macFullScreenData != NULL )
 902     {
 903         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 904 #if 0
 905         // CGDisplayRelease( kCGDirectMainDisplay );
 906         // [m_macWindow setLevel:data->m_formerLevel];
 907 #endif
 908
 909         [m_macWindow setFrame:data->m_formerFrame display:YES];
 910 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
 911         if ( [ m_macWindow respondsToSelector:@selector(setStyleMask:) ] )
 912             [m_macWindow setStyleMask:data->m_formerStyleMask];
 913 #endif
 914         delete data ;
 915         m_macFullScreenData = NULL ;
 916
 917         SetSystemUIMode(kUIModeNormal, 0);
 918     }
 919
 920     return true;
 921 }
 922
 923 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int flagsWX)
 924 {
 925     NSRequestUserAttentionType flagsOSX;
 926     switch ( flagsWX )
 927     {
 928         case wxUSER_ATTENTION_INFO:
 929             flagsOSX = NSInformationalRequest;
 930             break;
 931
 932         case wxUSER_ATTENTION_ERROR:
 933             flagsOSX = NSCriticalRequest;
 934             break;
 935
 936         default:
 937             wxFAIL_MSG( "invalid RequestUserAttention() flags" );
 938             return;
 939     }
 940
 941     [NSApp requestUserAttention:flagsOSX];
 942 }
 943
 944 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 945 {
 946     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 947     NSPoint nspt = wxToNSPoint( NULL, p );
 948     nspt = [m_macWindow convertScreenToBase:nspt];
 949     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 950     p = wxFromNSPoint([m_macWindow contentView], nspt);
 951     if ( x )
 952         *x = p.x;
 953     if ( y )
 954         *y = p.y;
 955 }
 956
 957 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 958 {
 959     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 960     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 961     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 962     nspt = [m_macWindow convertBaseToScreen:nspt];
 963     p = wxFromNSPoint( NULL, nspt);
 964     if ( x )
 965         *x = p.x;
 966     if ( y )
 967         *y = p.y;
 968 }
 969
 970 bool wxNonOwnedWindowCocoaImpl::IsActive()
 971 {
 972     return [m_macWindow isKeyWindow];
 973 }
 974
 975 void wxNonOwnedWindowCocoaImpl::SetModified(bool modified)
 976 {
 977     [m_macWindow setDocumentEdited:modified];
 978 }
 979
 980 bool wxNonOwnedWindowCocoaImpl::IsModified() const
 981 {
 982     return [m_macWindow isDocumentEdited];
 983 }
 984
 985 void wxNonOwnedWindowCocoaImpl::SetRepresentedFilename(const wxString& filename)
 986 {
 987     [m_macWindow setRepresentedFilename:wxCFStringRef(filename).AsNSString()];
 988 }
 989
 990 void wxNonOwnedWindowCocoaImpl::RestoreWindowLevel()
 991 {
 992     if ( [m_macWindow level] != m_macWindowLevel )
 993         [m_macWindow setLevel:m_macWindowLevel];
 994 }
 995
 996 //
 997 //
 998 //
 999
1000 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, WXWindow nativeWindow)
1001 {
1002     wxNonOwnedWindowCocoaImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1003     now->Create( parent, nativeWindow );
1004     return now;
1005 }
1006
1007 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
1008     long style, long extraStyle, const wxString& name )
1009 {
1010     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1011     now->Create( parent, pos, size, style , extraStyle, name );
1012     return now;
1013 }
1014