src/osx/webview_webkit.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/webview_webkit.mm
   3 // Purpose:     wxWebViewWebKit - embeddable web kit control,
   4 //                             OS X implementation of web view component
   5 // Author:      Jethro Grassie / Kevin Ollivier / Marianne Gagnon
   6 // Modified by:
   7 // Created:     2004-4-16
   8 // RCS-ID:      $Id$
   9 // Copyright:   (c) Jethro Grassie / Kevin Ollivier / Marianne Gagnon
  10 // Licence:     wxWindows licence
  11 /////////////////////////////////////////////////////////////////////////////
  12
  13 // http://developer.apple.com/mac/library/documentation/Cocoa/Reference/WebKit/Classes/WebView_Class/Reference/Reference.html
  14
  15 #include "wx/osx/webview_webkit.h"
  16
  17 #if wxUSE_WEBVIEW_WEBKIT && (defined(__WXOSX_COCOA__) \
  18                          ||  defined(__WXOSX_CARBON__))
  19
  20 // For compilers that support precompilation, includes "wx.h".
  21 #include "wx/wxprec.h"
  22
  23 #ifndef WX_PRECOMP
  24     #include "wx/wx.h"
  25 #endif
  26
  27 #ifdef __WXCOCOA__
  28 #include "wx/cocoa/autorelease.h"
  29 #else
  30 #include "wx/osx/private.h"
  31
  32 #include <WebKit/WebKit.h>
  33 #include <WebKit/HIWebView.h>
  34 #include <WebKit/CarbonUtils.h>
  35 #endif
  36
  37 #include <Foundation/NSURLError.h>
  38
  39 // FIXME: find cleaner way to find the wxWidgets ID of a webview than this hack
  40 #include <map>
  41 std::map<WebView*, wxWebViewWebKit*> wx_webviewctrls;
  42
  43 #define DEBUG_WEBKIT_SIZING 0
  44
  45 // ----------------------------------------------------------------------------
  46 // macros
  47 // ----------------------------------------------------------------------------
  48
  49 wxIMPLEMENT_DYNAMIC_CLASS(wxWebViewWebKit, wxWebView);
  50
  51 BEGIN_EVENT_TABLE(wxWebViewWebKit, wxControl)
  52 #if defined(__WXMAC__) && wxOSX_USE_CARBON
  53     EVT_SIZE(wxWebViewWebKit::OnSize)
  54 #endif
  55 END_EVENT_TABLE()
  56
  57 #if defined(__WXOSX__) && wxOSX_USE_CARBON
  58
  59 // ----------------------------------------------------------------------------
  60 // Carbon Events handlers
  61 // ----------------------------------------------------------------------------
  62
  63 // prototype for function in src/osx/carbon/nonownedwnd.cpp
  64 void SetupMouseEvent( wxMouseEvent &wxevent , wxMacCarbonEvent &cEvent );
  65
  66 static const EventTypeSpec eventList[] =
  67 {
  68     //{ kEventClassControl, kEventControlTrack } ,
  69     { kEventClassMouse, kEventMouseUp },
  70     { kEventClassMouse, kEventMouseDown },
  71     { kEventClassMouse, kEventMouseMoved },
  72     { kEventClassMouse, kEventMouseDragged },
  73
  74     { kEventClassKeyboard, kEventRawKeyDown } ,
  75     { kEventClassKeyboard, kEventRawKeyRepeat } ,
  76     { kEventClassKeyboard, kEventRawKeyUp } ,
  77     { kEventClassKeyboard, kEventRawKeyModifiersChanged } ,
  78
  79     { kEventClassTextInput, kEventTextInputUnicodeForKeyEvent } ,
  80     { kEventClassTextInput, kEventTextInputUpdateActiveInputArea } ,
  81
  82 #if DEBUG_WEBKIT_SIZING == 1
  83     { kEventClassControl, kEventControlBoundsChanged } ,
  84 #endif
  85 };
  86
  87 // mix this in from window.cpp
  88 pascal OSStatus wxMacUnicodeTextEventHandler(EventHandlerCallRef handler,
  89                                              EventRef event, void *data) ;
  90
  91 // NOTE: This is mostly taken from KeyboardEventHandler in toplevel.cpp, but
  92 // that expects the data pointer is a top-level window, so I needed to change
  93 // that in this case. However, once 2.8 is out, we should factor out the common
  94 // logic among the two functions and merge them.
  95 static pascal OSStatus wxWebKitKeyEventHandler(EventHandlerCallRef handler,
  96                                                EventRef event, void *data)
  97 {
  98     OSStatus result = eventNotHandledErr ;
  99     wxMacCarbonEvent cEvent( event ) ;
 100
 101     wxWebViewWebKit* thisWindow = (wxWebViewWebKit*) data ;
 102     wxWindow* focus = thisWindow ;
 103
 104     unsigned char charCode ;
 105     wxChar uniChar[2] ;
 106     uniChar[0] = 0;
 107     uniChar[1] = 0;
 108
 109     UInt32 keyCode ;
 110     UInt32 modifiers ;
 111     Point point ;
 112     UInt32 when = EventTimeToTicks( GetEventTime( event ) ) ;
 113
 114 #if wxUSE_UNICODE
 115     ByteCount dataSize = 0 ;
 116     if ( GetEventParameter(event, kEventParamKeyUnicodes, typeUnicodeText,
 117                            NULL, 0 , &dataSize, NULL ) == noErr)
 118     {
 119         UniChar buf[2] ;
 120         int numChars = dataSize / sizeof( UniChar) + 1;
 121
 122         UniChar* charBuf = buf ;
 123
 124         if ( numChars * 2 > 4 )
 125             charBuf = new UniChar[ numChars ] ;
 126         GetEventParameter(event, kEventParamKeyUnicodes, typeUnicodeText, NULL,
 127                           dataSize , NULL , charBuf) ;
 128         charBuf[ numChars - 1 ] = 0;
 129
 130 #if SIZEOF_WCHAR_T == 2
 131         uniChar = charBuf[0] ;
 132 #else
 133         wxMBConvUTF16 converter ;
 134         converter.MB2WC( uniChar , (const char*)charBuf , 2 ) ;
 135 #endif
 136
 137         if ( numChars * 2 > 4 )
 138             delete[] charBuf ;
 139     }
 140 #endif
 141
 142     GetEventParameter(event, kEventParamKeyMacCharCodes, typeChar, NULL,
 143                       sizeof(char), NULL, &charCode );
 144     GetEventParameter(event, kEventParamKeyCode, typeUInt32, NULL,
 145                       sizeof(UInt32), NULL, &keyCode );
 146     GetEventParameter(event, kEventParamKeyModifiers, typeUInt32, NULL,
 147                       sizeof(UInt32), NULL, &modifiers );
 148     GetEventParameter(event, kEventParamMouseLocation, typeQDPoint, NULL,
 149                       sizeof(Point), NULL, &point );
 150
 151     UInt32 message = (keyCode << 8) + charCode;
 152     switch ( GetEventKind( event ) )
 153     {
 154         case kEventRawKeyRepeat :
 155         case kEventRawKeyDown :
 156         {
 157             WXEVENTREF formerEvent = wxTheApp->MacGetCurrentEvent() ;
 158             WXEVENTHANDLERCALLREF formerHandler =
 159                 wxTheApp->MacGetCurrentEventHandlerCallRef() ;
 160
 161             wxTheApp->MacSetCurrentEvent( event , handler ) ;
 162             if ( /* focus && */ wxTheApp->MacSendKeyDownEvent(
 163                 focus, message, modifiers, when, point.h, point.v, uniChar[0]))
 164             {
 165                 result = noErr ;
 166             }
 167             wxTheApp->MacSetCurrentEvent( formerEvent , formerHandler ) ;
 168         }
 169         break ;
 170
 171         case kEventRawKeyUp :
 172             if ( /* focus && */ wxTheApp->MacSendKeyUpEvent(
 173                 focus , message , modifiers , when , point.h , point.v , uniChar[0] ) )
 174             {
 175                 result = noErr ;
 176             }
 177             break ;
 178
 179         case kEventRawKeyModifiersChanged :
 180             {
 181                 wxKeyEvent event(wxEVT_KEY_DOWN);
 182
 183                 event.m_shiftDown = modifiers & shiftKey;
 184                 event.m_controlDown = modifiers & controlKey;
 185                 event.m_altDown = modifiers & optionKey;
 186                 event.m_metaDown = modifiers & cmdKey;
 187                 event.m_x = point.h;
 188                 event.m_y = point.v;
 189
 190 #if wxUSE_UNICODE
 191                 event.m_uniChar = uniChar[0] ;
 192 #endif
 193
 194                 event.SetTimestamp(when);
 195                 event.SetEventObject(focus);
 196
 197                 if ( /* focus && */ (modifiers ^ wxApp::s_lastModifiers ) & controlKey )
 198                 {
 199                     event.m_keyCode = WXK_CONTROL ;
 200                     event.SetEventType( ( modifiers & controlKey ) ? wxEVT_KEY_DOWN : wxEVT_KEY_UP ) ;
 201                     focus->GetEventHandler()->ProcessEvent( event ) ;
 202                 }
 203                 if ( /* focus && */ (modifiers ^ wxApp::s_lastModifiers ) & shiftKey )
 204                 {
 205                     event.m_keyCode = WXK_SHIFT ;
 206                     event.SetEventType( ( modifiers & shiftKey ) ? wxEVT_KEY_DOWN : wxEVT_KEY_UP ) ;
 207                     focus->GetEventHandler()->ProcessEvent( event ) ;
 208                 }
 209                 if ( /* focus && */ (modifiers ^ wxApp::s_lastModifiers ) & optionKey )
 210                 {
 211                     event.m_keyCode = WXK_ALT ;
 212                     event.SetEventType( ( modifiers & optionKey ) ? wxEVT_KEY_DOWN : wxEVT_KEY_UP ) ;
 213                     focus->GetEventHandler()->ProcessEvent( event ) ;
 214                 }
 215                 if ( /* focus && */ (modifiers ^ wxApp::s_lastModifiers ) & cmdKey )
 216                 {
 217                     event.m_keyCode = WXK_COMMAND ;
 218                     event.SetEventType( ( modifiers & cmdKey ) ? wxEVT_KEY_DOWN : wxEVT_KEY_UP ) ;
 219                     focus->GetEventHandler()->ProcessEvent( event ) ;
 220                 }
 221
 222                 wxApp::s_lastModifiers = modifiers ;
 223             }
 224             break ;
 225
 226         default:
 227             break;
 228     }
 229
 230     return result ;
 231 }
 232
 233 static pascal OSStatus wxWebViewWebKitEventHandler( EventHandlerCallRef handler , EventRef event , void *data )
 234 {
 235     OSStatus result = eventNotHandledErr ;
 236
 237     wxMacCarbonEvent cEvent( event ) ;
 238
 239     ControlRef controlRef ;
 240     wxWebViewWebKit* thisWindow = (wxWebViewWebKit*) data ;
 241     wxNonOwnedWindow* tlw = NULL;
 242     if (thisWindow)
 243         tlw = thisWindow->MacGetTopLevelWindow();
 244
 245     cEvent.GetParameter( kEventParamDirectObject , &controlRef ) ;
 246
 247     wxWindow* currentMouseWindow = thisWindow ;
 248
 249     if ( wxApp::s_captureWindow )
 250         currentMouseWindow = wxApp::s_captureWindow;
 251
 252     switch ( GetEventClass( event ) )
 253     {
 254         case kEventClassKeyboard:
 255         {
 256             result = wxWebKitKeyEventHandler(handler, event, data);
 257             break;
 258         }
 259
 260         case kEventClassTextInput:
 261         {
 262             result = wxMacUnicodeTextEventHandler(handler, event, data);
 263             break;
 264         }
 265
 266         case kEventClassMouse:
 267         {
 268             switch ( GetEventKind( event ) )
 269             {
 270                 case kEventMouseDragged :
 271                 case kEventMouseMoved :
 272                 case kEventMouseDown :
 273                 case kEventMouseUp :
 274                 {
 275                     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
 276                     SetupMouseEvent( wxevent , cEvent ) ;
 277
 278                     currentMouseWindow->ScreenToClient( &wxevent.m_x , &wxevent.m_y ) ;
 279                     wxevent.SetEventObject( currentMouseWindow ) ;
 280                     wxevent.SetId( currentMouseWindow->GetId() ) ;
 281
 282                     if ( currentMouseWindow->GetEventHandler()->ProcessEvent(wxevent) )
 283                     {
 284                         result = noErr;
 285                     }
 286
 287                     break; // this should enable WebKit to fire mouse dragged and mouse up events...
 288                 }
 289                 default :
 290                     break ;
 291             }
 292         }
 293         default:
 294             break;
 295     }
 296
 297     result = CallNextEventHandler(handler, event);
 298     return result ;
 299 }
 300
 301 DEFINE_ONE_SHOT_HANDLER_GETTER( wxWebViewWebKitEventHandler )
 302
 303 #endif
 304
 305 //---------------------------------------------------------
 306 // helper functions for NSString<->wxString conversion
 307 //---------------------------------------------------------
 308
 309 inline wxString wxStringWithNSString(NSString *nsstring)
 310 {
 311 #if wxUSE_UNICODE
 312     return wxString([nsstring UTF8String], wxConvUTF8);
 313 #else
 314     return wxString([nsstring lossyCString]);
 315 #endif // wxUSE_UNICODE
 316 }
 317
 318 inline NSString* wxNSStringWithWxString(const wxString &wxstring)
 319 {
 320 #if wxUSE_UNICODE
 321     return [NSString stringWithUTF8String: wxstring.mb_str(wxConvUTF8)];
 322 #else
 323     return [NSString stringWithCString: wxstring.c_str() length:wxstring.Len()];
 324 #endif // wxUSE_UNICODE
 325 }
 326
 327 @interface MyFrameLoadMonitor : NSObject
 328 {
 329     wxWebViewWebKit* webKitWindow;
 330 }
 331
 332 - initWithWxWindow: (wxWebViewWebKit*)inWindow;
 333
 334 @end
 335
 336 @interface MyPolicyDelegate : NSObject
 337 {
 338     wxWebViewWebKit* webKitWindow;
 339 }
 340
 341 - initWithWxWindow: (wxWebViewWebKit*)inWindow;
 342
 343 @end
 344
 345 // ----------------------------------------------------------------------------
 346 // creation/destruction
 347 // ----------------------------------------------------------------------------
 348
 349 bool wxWebViewWebKit::Create(wxWindow *parent,
 350                                  wxWindowID winID,
 351                                  const wxString& strURL,
 352                                  const wxPoint& pos,
 353                                  const wxSize& size, long style,
 354                                  const wxString& name)
 355 {
 356     m_busy = false;
 357     //m_pageTitle = _("Untitled Page");
 358
 359  //still needed for wxCocoa??
 360 /*
 361     int width, height;
 362     wxSize sizeInstance;
 363     if (size.x == wxDefaultCoord || size.y == wxDefaultCoord)
 364     {
 365         m_parent->GetClientSize(&width, &height);
 366         sizeInstance.x = width;
 367         sizeInstance.y = height;
 368     }
 369     else
 370     {
 371         sizeInstance.x = size.x;
 372         sizeInstance.y = size.y;
 373     }
 374 */
 375     // now create and attach WebKit view...
 376 #ifdef __WXCOCOA__
 377     wxControl::Create(parent, m_windowID, pos, sizeInstance, style, name);
 378     SetSize(pos.x, pos.y, sizeInstance.x, sizeInstance.y);
 379
 380     wxTopLevelWindowCocoa *topWin = wxDynamicCast(this, wxTopLevelWindowCocoa);
 381     NSWindow* nsWin = topWin->GetNSWindow();
 382     NSRect rect;
 383     rect.origin.x = pos.x;
 384     rect.origin.y = pos.y;
 385     rect.size.width = sizeInstance.x;
 386     rect.size.height = sizeInstance.y;
 387     m_webView = (WebView*)[[WebView alloc] initWithFrame:rect
 388                                                frameName:@"webkitFrame"
 389                                                groupName:@"webkitGroup"];
 390     SetNSView(m_webView);
 391     [m_cocoaNSView release];
 392
 393     if(m_parent) m_parent->CocoaAddChild(this);
 394     SetInitialFrameRect(pos,sizeInstance);
 395 #else
 396     wxControl::Create(parent, winID, pos, size, style, wxDefaultValidator, name);
 397
 398 #if wxOSX_USE_CARBON
 399     m_peer = new wxMacControl(this);
 400     WebInitForCarbon();
 401     HIWebViewCreate( m_peer->GetControlRefAddr() );
 402
 403     m_webView = (WebView*) HIWebViewGetWebView( m_peer->GetControlRef() );
 404
 405 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_3
 406     if ( UMAGetSystemVersion() >= 0x1030 )
 407         HIViewChangeFeatures( m_peer->GetControlRef() , kHIViewIsOpaque , 0 ) ;
 408 #endif
 409     InstallControlEventHandler(m_peer->GetControlRef(),
 410                                GetwxWebViewWebKitEventHandlerUPP(),
 411                                GetEventTypeCount(eventList), eventList, this,
 412                               (EventHandlerRef *)&m_webKitCtrlEventHandler);
 413 #else
 414     NSRect r = wxOSXGetFrameForControl( this, pos , size ) ;
 415     m_webView = [[WebView alloc] initWithFrame:r
 416                                      frameName:@"webkitFrame"
 417                                      groupName:@"webkitGroup"];
 418     m_peer = new wxWidgetCocoaImpl( this, m_webView );
 419 #endif
 420
 421     wx_webviewctrls[m_webView] = this;
 422
 423     MacPostControlCreate(pos, size);
 424
 425 #if wxOSX_USE_CARBON
 426     HIViewSetVisible( m_peer->GetControlRef(), true );
 427 #endif
 428     [m_webView setHidden:false];
 429
 430 #endif
 431
 432     // Register event listener interfaces
 433     MyFrameLoadMonitor* myFrameLoadMonitor =
 434             [[MyFrameLoadMonitor alloc] initWithWxWindow: this];
 435
 436     [m_webView setFrameLoadDelegate:myFrameLoadMonitor];
 437
 438     // this is used to veto page loads, etc.
 439     MyPolicyDelegate* myPolicyDelegate =
 440             [[MyPolicyDelegate alloc] initWithWxWindow: this];
 441
 442     [m_webView setPolicyDelegate:myPolicyDelegate];
 443
 444     InternalLoadURL(strURL);
 445     return true;
 446 }
 447
 448 wxWebViewWebKit::~wxWebViewWebKit()
 449 {
 450     MyFrameLoadMonitor* myFrameLoadMonitor = [m_webView frameLoadDelegate];
 451     MyPolicyDelegate* myPolicyDelegate = [m_webView policyDelegate];
 452     [m_webView setFrameLoadDelegate: nil];
 453     [m_webView setPolicyDelegate: nil];
 454
 455     if (myFrameLoadMonitor)
 456         [myFrameLoadMonitor release];
 457
 458     if (myPolicyDelegate)
 459         [myPolicyDelegate release];
 460 }
 461
 462 // ----------------------------------------------------------------------------
 463 // public methods
 464 // ----------------------------------------------------------------------------
 465
 466 void wxWebViewWebKit::InternalLoadURL(const wxString &url)
 467 {
 468     if( !m_webView )
 469         return;
 470
 471     [[m_webView mainFrame] loadRequest:[NSURLRequest requestWithURL:
 472             [NSURL URLWithString:wxNSStringWithWxString(url)]]];
 473 }
 474
 475 bool wxWebViewWebKit::CanGoBack()
 476 {
 477     if ( !m_webView )
 478         return false;
 479
 480     return [m_webView canGoBack];
 481 }
 482
 483 bool wxWebViewWebKit::CanGoForward()
 484 {
 485     if ( !m_webView )
 486         return false;
 487
 488     return [m_webView canGoForward];
 489 }
 490
 491 void wxWebViewWebKit::GoBack()
 492 {
 493     if ( !m_webView )
 494         return;
 495
 496     bool result = [(WebView*)m_webView goBack];
 497
 498     // TODO: return result (if it also exists in other backends...)
 499     //return result;
 500 }
 501
 502 void wxWebViewWebKit::GoForward()
 503 {
 504     if ( !m_webView )
 505         return;
 506
 507     bool result = [(WebView*)m_webView goForward];
 508
 509     // TODO: return result (if it also exists in other backends...)
 510     //return result;
 511 }
 512
 513 void wxWebViewWebKit::Reload(wxWebViewReloadFlags flags)
 514 {
 515     if ( !m_webView )
 516         return;
 517
 518     if (flags & wxWEB_VIEW_RELOAD_NO_CACHE)
 519     {
 520         // TODO: test this indeed bypasses the cache
 521         [[m_webView preferences] setUsesPageCache:NO];
 522         [[m_webView mainFrame] reload];
 523         [[m_webView preferences] setUsesPageCache:YES];
 524     }
 525     else
 526     {
 527         [[m_webView mainFrame] reload];
 528     }
 529 }
 530
 531 void wxWebViewWebKit::Stop()
 532 {
 533     if ( !m_webView )
 534         return;
 535
 536     [[m_webView mainFrame] stopLoading];
 537 }
 538
 539 bool wxWebViewWebKit::CanGetPageSource()
 540 {
 541     if ( !m_webView )
 542         return false;
 543
 544     WebDataSource* dataSource = [[m_webView mainFrame] dataSource];
 545     return ( [[dataSource representation] canProvideDocumentSource] );
 546 }
 547
 548 wxString wxWebViewWebKit::GetPageSource()
 549 {
 550
 551     if (CanGetPageSource())
 552         {
 553         WebDataSource* dataSource = [[m_webView mainFrame] dataSource];
 554                 wxASSERT (dataSource != nil);
 555
 556                 id<WebDocumentRepresentation> representation = [dataSource representation];
 557                 wxASSERT (representation != nil);
 558
 559                 NSString* source = [representation documentSource];
 560                 if (source == nil)
 561                 {
 562                         return wxEmptyString;
 563                 }
 564
 565         return wxStringWithNSString( source );
 566     }
 567
 568     return wxEmptyString;
 569 }
 570
 571 wxString wxWebViewWebKit::GetSelection()
 572 {
 573     if ( !m_webView )
 574         return wxEmptyString;
 575
 576     NSString* selectedText = [[m_webView selectedDOMRange] toString];
 577     return wxStringWithNSString( selectedText );
 578 }
 579
 580 bool wxWebViewWebKit::CanIncreaseTextSize()
 581 {
 582     if ( !m_webView )
 583         return false;
 584
 585     if ([m_webView canMakeTextLarger])
 586         return true;
 587     else
 588         return false;
 589 }
 590
 591 void wxWebViewWebKit::IncreaseTextSize()
 592 {
 593     if ( !m_webView )
 594         return;
 595
 596     if (CanIncreaseTextSize())
 597         [m_webView makeTextLarger:(WebView*)m_webView];
 598 }
 599
 600 bool wxWebViewWebKit::CanDecreaseTextSize()
 601 {
 602     if ( !m_webView )
 603         return false;
 604
 605     if ([m_webView canMakeTextSmaller])
 606         return true;
 607     else
 608         return false;
 609 }
 610
 611 void wxWebViewWebKit::DecreaseTextSize()
 612 {
 613     if ( !m_webView )
 614         return;
 615
 616     if (CanDecreaseTextSize())
 617         [m_webView makeTextSmaller:(WebView*)m_webView];
 618 }
 619
 620 void wxWebViewWebKit::Print()
 621 {
 622
 623     // TODO: allow specifying the "show prompt" parameter in Print() ?
 624     bool showPrompt = true;
 625
 626     if ( !m_webView )
 627         return;
 628
 629     id view = [[[m_webView mainFrame] frameView] documentView];
 630     NSPrintOperation *op = [NSPrintOperation printOperationWithView:view
 631                                  printInfo: [NSPrintInfo sharedPrintInfo]];
 632     if (showPrompt)
 633     {
 634         [op setShowsPrintPanel: showPrompt];
 635         // in my tests, the progress bar always freezes and it stops the whole
 636         // print operation. do not turn this to true unless there is a
 637         // workaround for the bug.
 638         [op setShowsProgressPanel: false];
 639     }
 640     // Print it.
 641     [op runOperation];
 642 }
 643
 644 void wxWebViewWebKit::SetEditable(bool enable)
 645 {
 646     if ( !m_webView )
 647         return;
 648
 649     [m_webView setEditable:enable ];
 650 }
 651
 652 bool wxWebViewWebKit::IsEditable()
 653 {
 654     if ( !m_webView )
 655         return false;
 656
 657     return [m_webView isEditable];
 658 }
 659
 660 void wxWebViewWebKit::SetZoomType(wxWebViewZoomType zoomType)
 661 {
 662     // there is only one supported zoom type at the moment so this setter
 663     // does nothing beyond checking sanity
 664     wxASSERT(zoomType == wxWEB_VIEW_ZOOM_TYPE_TEXT);
 665 }
 666
 667 wxWebViewZoomType wxWebViewWebKit::GetZoomType() const
 668 {
 669     // for now that's the only one that is supported
 670     // FIXME: does the default zoom type change depending on webkit versions? :S
 671     //        Then this will be wrong
 672     return wxWEB_VIEW_ZOOM_TYPE_TEXT;
 673 }
 674
 675 bool wxWebViewWebKit::CanSetZoomType(wxWebViewZoomType type) const
 676 {
 677     switch (type)
 678     {
 679         // for now that's the only one that is supported
 680         // TODO: I know recent versions of webkit support layout zoom too,
 681         //       check if we can support it
 682         case wxWEB_VIEW_ZOOM_TYPE_TEXT:
 683             return true;
 684
 685         default:
 686             return false;
 687     }
 688 }
 689
 690 int wxWebViewWebKit::GetScrollPos()
 691 {
 692     id result = [[m_webView windowScriptObject]
 693                     evaluateWebScript:@"document.body.scrollTop"];
 694     return [result intValue];
 695 }
 696
 697 void wxWebViewWebKit::SetScrollPos(int pos)
 698 {
 699     if ( !m_webView )
 700         return;
 701
 702     wxString javascript;
 703     javascript.Printf(wxT("document.body.scrollTop = %d;"), pos);
 704     [[m_webView windowScriptObject] evaluateWebScript:
 705             (NSString*)wxNSStringWithWxString( javascript )];
 706 }
 707
 708 wxString wxWebViewWebKit::GetSelectedText()
 709 {
 710     NSString* selection = [[m_webView selectedDOMRange] markupString];
 711     if (!selection) return wxEmptyString;
 712
 713     return wxStringWithNSString(selection);
 714 }
 715
 716 void wxWebViewWebKit::RunScript(const wxString& javascript)
 717 {
 718     if ( !m_webView )
 719         return;
 720
 721     [[m_webView windowScriptObject] evaluateWebScript:
 722                     (NSString*)wxNSStringWithWxString( javascript )];
 723 }
 724
 725 void wxWebViewWebKit::OnSize(wxSizeEvent &event)
 726 {
 727 #if defined(__WXMAC_) && wxOSX_USE_CARBON
 728     // This is a nasty hack because WebKit seems to lose its position when it is
 729     // embedded in a control that is not itself the content view for a TLW.
 730     // I put it in OnSize because these calcs are not perfect, and in fact are
 731     // basically guesses based on reverse engineering, so it's best to give
 732     // people the option of overriding OnSize with their own calcs if need be.
 733     // I also left some test debugging print statements as a convenience if
 734     // a(nother) problem crops up.
 735
 736     wxWindow* tlw = MacGetTopLevelWindow();
 737
 738     NSRect frame = [(WebView*)m_webView frame];
 739     NSRect bounds = [(WebView*)m_webView bounds];
 740
 741 #if DEBUG_WEBKIT_SIZING
 742     fprintf(stderr,"Carbon window x=%d, y=%d, width=%d, height=%d\n",
 743             GetPosition().x, GetPosition().y, GetSize().x, GetSize().y);
 744     fprintf(stderr, "Cocoa window frame x=%G, y=%G, width=%G, height=%G\n",
 745             frame.origin.x, frame.origin.y,
 746             frame.size.width, frame.size.height);
 747     fprintf(stderr, "Cocoa window bounds x=%G, y=%G, width=%G, height=%G\n",
 748             bounds.origin.x, bounds.origin.y,
 749             bounds.size.width, bounds.size.height);
 750 #endif
 751
 752     // This must be the case that Apple tested with, because well, in this one case
 753     // we don't need to do anything! It just works. ;)
 754     if (GetParent() == tlw) return;
 755
 756     // since we no longer use parent coordinates, we always want 0,0.
 757     int x = 0;
 758     int y = 0;
 759
 760     HIRect rect;
 761     rect.origin.x = x;
 762     rect.origin.y = y;
 763
 764 #if DEBUG_WEBKIT_SIZING
 765     printf("Before conversion, origin is: x = %d, y = %d\n", x, y);
 766 #endif
 767
 768     // NB: In most cases, when calling HIViewConvertRect, what people want is to
 769     // use GetRootControl(), and this tripped me up at first. But in fact, what
 770     // we want is the root view, because we need to make the y origin relative
 771     // to the very top of the window, not its contents, since we later flip
 772     // the y coordinate for Cocoa.
 773     HIViewConvertRect (&rect, m_peer->GetControlRef(),
 774                                 HIViewGetRoot(
 775                                     (WindowRef) MacGetTopLevelWindowRef()
 776                                  ));
 777
 778     x = (int)rect.origin.x;
 779     y = (int)rect.origin.y;
 780
 781 #if DEBUG_WEBKIT_SIZING
 782     printf("Moving Cocoa frame origin to: x = %d, y = %d\n", x, y);
 783 #endif
 784
 785     if (tlw){
 786         //flip the y coordinate to convert to Cocoa coordinates
 787         y = tlw->GetSize().y - ((GetSize().y) + y);
 788     }
 789
 790 #if DEBUG_WEBKIT_SIZING
 791     printf("y = %d after flipping value\n", y);
 792 #endif
 793
 794     frame.origin.x = x;
 795     frame.origin.y = y;
 796     [(WebView*)m_webView setFrame:frame];
 797
 798     if (IsShown())
 799         [(WebView*)m_webView display];
 800     event.Skip();
 801 #endif
 802 }
 803
 804 void wxWebViewWebKit::MacVisibilityChanged(){
 805 #if defined(__WXMAC__) && wxOSX_USE_CARBON
 806     bool isHidden = !IsControlVisible( m_peer->GetControlRef());
 807     if (!isHidden)
 808         [(WebView*)m_webView display];
 809
 810     [m_webView setHidden:isHidden];
 811 #endif
 812 }
 813
 814 void wxWebViewWebKit::LoadUrl(const wxString& url)
 815 {
 816     InternalLoadURL(url);
 817 }
 818
 819 wxString wxWebViewWebKit::GetCurrentURL()
 820 {
 821     return wxStringWithNSString([m_webView mainFrameURL]);
 822 }
 823
 824 wxString wxWebViewWebKit::GetCurrentTitle()
 825 {
 826     return GetPageTitle();
 827 }
 828
 829 float wxWebViewWebKit::GetWebkitZoom()
 830 {
 831     return [m_webView textSizeMultiplier];
 832 }
 833
 834 void wxWebViewWebKit::SetWebkitZoom(float zoom)
 835 {
 836     [m_webView setTextSizeMultiplier:zoom];
 837 }
 838
 839 wxWebViewZoom wxWebViewWebKit::GetZoom()
 840 {
 841     float zoom = GetWebkitZoom();
 842
 843     // arbitrary way to map float zoom to our common zoom enum
 844     if (zoom <= 0.55)
 845     {
 846         return wxWEB_VIEW_ZOOM_TINY;
 847     }
 848     else if (zoom > 0.55 && zoom <= 0.85)
 849     {
 850         return wxWEB_VIEW_ZOOM_SMALL;
 851     }
 852     else if (zoom > 0.85 && zoom <= 1.15)
 853     {
 854         return wxWEB_VIEW_ZOOM_MEDIUM;
 855     }
 856     else if (zoom > 1.15 && zoom <= 1.45)
 857     {
 858         return wxWEB_VIEW_ZOOM_LARGE;
 859     }
 860     else if (zoom > 1.45)
 861     {
 862         return wxWEB_VIEW_ZOOM_LARGEST;
 863     }
 864
 865     // to shut up compilers, this can never be reached logically
 866     wxASSERT(false);
 867     return wxWEB_VIEW_ZOOM_MEDIUM;
 868 }
 869
 870 void wxWebViewWebKit::SetZoom(wxWebViewZoom zoom)
 871 {
 872     // arbitrary way to map our common zoom enum to float zoom
 873     switch (zoom)
 874     {
 875         case wxWEB_VIEW_ZOOM_TINY:
 876             SetWebkitZoom(0.4f);
 877             break;
 878
 879         case wxWEB_VIEW_ZOOM_SMALL:
 880             SetWebkitZoom(0.7f);
 881             break;
 882
 883         case wxWEB_VIEW_ZOOM_MEDIUM:
 884             SetWebkitZoom(1.0f);
 885             break;
 886
 887         case wxWEB_VIEW_ZOOM_LARGE:
 888             SetWebkitZoom(1.3);
 889             break;
 890
 891         case wxWEB_VIEW_ZOOM_LARGEST:
 892             SetWebkitZoom(1.6);
 893             break;
 894
 895         default:
 896             wxASSERT(false);
 897     }
 898
 899 }
 900
 901 void wxWebViewWebKit::SetPage(const wxString& src, const wxString& baseUrl)
 902 {
 903    if ( !m_webView )
 904         return;
 905
 906     [[m_webView mainFrame] loadHTMLString:(NSString*)wxNSStringWithWxString(src)
 907                                   baseURL:[NSURL URLWithString:
 908                                     wxNSStringWithWxString( baseUrl )]];
 909 }
 910
 911 void wxWebViewWebKit::Cut()
 912 {
 913     if ( !m_webView )
 914         return;
 915
 916     [(WebView*)m_webView cut:m_webView];
 917 }
 918
 919 void wxWebViewWebKit::Copy()
 920 {
 921     if ( !m_webView )
 922         return;
 923
 924     [(WebView*)m_webView copy:m_webView];
 925 }
 926
 927 void wxWebViewWebKit::Paste()
 928 {
 929     if ( !m_webView )
 930         return;
 931
 932     [(WebView*)m_webView paste:m_webView];
 933 }
 934
 935 void wxWebViewWebKit::DeleteSelection()
 936 {
 937     if ( !m_webView )
 938         return;
 939
 940     [(WebView*)m_webView deleteSelection];
 941 }
 942
 943 void wxWebViewWebKit::EnableHistory(bool enable)
 944 {
 945     if ( !m_webView )
 946         return;
 947
 948     [m_webView setMaintainsBackForwardList:enable];
 949 }
 950
 951 //------------------------------------------------------------
 952 // Listener interfaces
 953 //------------------------------------------------------------
 954
 955 // NB: I'm still tracking this down, but it appears the Cocoa window
 956 // still has these events fired on it while the Carbon control is being
 957 // destroyed. Therefore, we must be careful to check both the existence
 958 // of the Carbon control and the event handler before firing events.
 959
 960 @implementation MyFrameLoadMonitor
 961
 962 - initWithWxWindow: (wxWebViewWebKit*)inWindow
 963 {
 964     [super init];
 965     webKitWindow = inWindow;    // non retained
 966     return self;
 967 }
 968
 969 - (void)webView:(WebView *)sender
 970     didStartProvisionalLoadForFrame:(WebFrame *)frame
 971 {
 972         wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
 973     wx_webviewctrls[sender]->m_busy = true;
 974 }
 975
 976 - (void)webView:(WebView *)sender didCommitLoadForFrame:(WebFrame *)frame
 977 {
 978         wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
 979     wx_webviewctrls[sender]->m_busy = true;
 980
 981     if (webKitWindow && frame == [sender mainFrame]){
 982         NSString *url = [[[[frame dataSource] request] URL] absoluteString];
 983         wxString target = wxStringWithNSString([frame name]);
 984         wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_NAVIGATED,
 985                                        wx_webviewctrls[sender]->GetId(),
 986                                        wxStringWithNSString( url ),
 987                                        target, false);
 988
 989         if (webKitWindow && webKitWindow->GetEventHandler())
 990             webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
 991     }
 992 }
 993
 994 - (void)webView:(WebView *)sender didFinishLoadForFrame:(WebFrame *)frame
 995 {
 996         wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
 997     wx_webviewctrls[sender]->m_busy = false;
 998
 999     if (webKitWindow && frame == [sender mainFrame]){
1000         NSString *url = [[[[frame dataSource] request] URL] absoluteString];
1001
1002         wxString target = wxStringWithNSString([frame name]);
1003         wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_LOADED,
1004                                        wx_webviewctrls[sender]->GetId(),
1005                                        wxStringWithNSString( url ),
1006                                        target, false);
1007
1008         if (webKitWindow && webKitWindow->GetEventHandler())
1009             webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
1010     }
1011 }
1012
1013 wxString nsErrorToWxHtmlError(NSError* error, wxWebNavigationError* out)
1014 {
1015     *out = wxWEB_NAV_ERR_OTHER;
1016
1017     if ([[error domain] isEqualToString:NSURLErrorDomain])
1018     {
1019         switch ([error code])
1020         {
1021             case NSURLErrorCannotFindHost:
1022             case NSURLErrorFileDoesNotExist:
1023             case NSURLErrorRedirectToNonExistentLocation:
1024                 *out = wxWEB_NAV_ERR_NOT_FOUND;
1025                 break;
1026
1027             case NSURLErrorResourceUnavailable:
1028             case NSURLErrorHTTPTooManyRedirects:
1029             case NSURLErrorDataLengthExceedsMaximum:
1030             case NSURLErrorBadURL:
1031             case NSURLErrorFileIsDirectory:
1032                 *out = wxWEB_NAV_ERR_REQUEST;
1033                 break;
1034
1035             case NSURLErrorTimedOut:
1036             case NSURLErrorDNSLookupFailed:
1037             case NSURLErrorNetworkConnectionLost:
1038             case NSURLErrorCannotConnectToHost:
1039             case NSURLErrorNotConnectedToInternet:
1040             //case NSURLErrorInternationalRoamingOff:
1041             //case NSURLErrorCallIsActive:
1042             //case NSURLErrorDataNotAllowed:
1043                 *out = wxWEB_NAV_ERR_CONNECTION;
1044                 break;
1045
1046             case NSURLErrorCancelled:
1047             case NSURLErrorUserCancelledAuthentication:
1048                 *out = wxWEB_NAV_ERR_USER_CANCELLED;
1049                 break;
1050
1051             case NSURLErrorCannotDecodeRawData:
1052             case NSURLErrorCannotDecodeContentData:
1053             case NSURLErrorBadServerResponse:
1054             case NSURLErrorCannotParseResponse:
1055                 *out = wxWEB_NAV_ERR_REQUEST;
1056                 break;
1057
1058             case NSURLErrorUserAuthenticationRequired:
1059             case NSURLErrorSecureConnectionFailed:
1060             case NSURLErrorClientCertificateRequired:
1061                 *out = wxWEB_NAV_ERR_AUTH;
1062                 break;
1063
1064             case NSURLErrorNoPermissionsToReadFile:
1065                                 *out = wxWEB_NAV_ERR_SECURITY;
1066                 break;
1067
1068             case NSURLErrorServerCertificateHasBadDate:
1069             case NSURLErrorServerCertificateUntrusted:
1070             case NSURLErrorServerCertificateHasUnknownRoot:
1071             case NSURLErrorServerCertificateNotYetValid:
1072             case NSURLErrorClientCertificateRejected:
1073                 *out = wxWEB_NAV_ERR_CERTIFICATE;
1074                 break;
1075         }
1076     }
1077
1078     wxString message = wxStringWithNSString([error localizedDescription]);
1079     NSString* detail = [error localizedFailureReason];
1080     if (detail != NULL)
1081     {
1082         message = message + " (" + wxStringWithNSString(detail) + ")";
1083     }
1084     return message;
1085 }
1086
1087 - (void)webView:(WebView *)sender didFailLoadWithError:(NSError*) error
1088         forFrame:(WebFrame *)frame
1089 {
1090         wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
1091     wx_webviewctrls[sender]->m_busy = false;
1092
1093     if (webKitWindow && frame == [sender mainFrame]){
1094         NSString *url = [[[[frame dataSource] request] URL] absoluteString];
1095
1096         wxWebNavigationError type;
1097         wxString description = nsErrorToWxHtmlError(error, &type);
1098                 wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_ERROR,
1099                                                wx_webviewctrls[sender]->GetId(),
1100                                        wxStringWithNSString( url ),
1101                                        wxEmptyString, false);
1102                 thisEvent.SetString(description);
1103                 thisEvent.SetInt(type);
1104
1105                 if (webKitWindow && webKitWindow->GetEventHandler())
1106                 {
1107                         webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
1108                 }
1109     }
1110 }
1111
1112 - (void)webView:(WebView *)sender
1113         didFailProvisionalLoadWithError:(NSError*)error
1114                                forFrame:(WebFrame *)frame
1115 {
1116         wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
1117     wx_webviewctrls[sender]->m_busy = false;
1118
1119     if (webKitWindow && frame == [sender mainFrame]){
1120         NSString *url = [[[[frame provisionalDataSource] request] URL]
1121                             absoluteString];
1122
1123                 wxWebNavigationError type;
1124         wxString description = nsErrorToWxHtmlError(error, &type);
1125                 wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_ERROR,
1126                                                wx_webviewctrls[sender]->GetId(),
1127                                        wxStringWithNSString( url ),
1128                                        wxEmptyString, false);
1129                 thisEvent.SetString(description);
1130                 thisEvent.SetInt(type);
1131
1132                 if (webKitWindow && webKitWindow->GetEventHandler())
1133                         webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
1134     }
1135 }
1136
1137 - (void)webView:(WebView *)sender didReceiveTitle:(NSString *)title
1138                                          forFrame:(WebFrame *)frame
1139 {
1140     if (webKitWindow && frame == [sender mainFrame])
1141     {
1142         webKitWindow->SetPageTitle(wxStringWithNSString( title ));
1143     }
1144     wxString target = wxStringWithNSString([frame name]);
1145     wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_TITLE_CHANGED,
1146                                    wx_webviewctrls[sender]->GetId(),
1147                                    wx_webviewctrls[sender]->GetCurrentURL(),
1148                                    target, true);
1149
1150     thisEvent.SetString(wxStringWithNSString(title));
1151
1152     if (webKitWindow && webKitWindow->GetEventHandler())
1153         webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
1154 }
1155 @end
1156
1157 @implementation MyPolicyDelegate
1158
1159 - initWithWxWindow: (wxWebViewWebKit*)inWindow
1160 {
1161     [super init];
1162     webKitWindow = inWindow;    // non retained
1163     return self;
1164 }
1165
1166 - (void)webView:(WebView *)sender
1167         decidePolicyForNavigationAction:(NSDictionary *)actionInformation
1168                                 request:(NSURLRequest *)request
1169                                   frame:(WebFrame *)frame
1170                        decisionListener:(id<WebPolicyDecisionListener>)listener
1171 {
1172     wxUnusedVar(frame);
1173
1174     wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
1175     wx_webviewctrls[sender]->m_busy = true;
1176     NSString *url = [[request URL] absoluteString];
1177     wxString target = wxStringWithNSString([frame name]);
1178     wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_NAVIGATING,
1179                                    wx_webviewctrls[sender]->GetId(),
1180                                    wxStringWithNSString( url ), target, true);
1181
1182     if (webKitWindow && webKitWindow->GetEventHandler())
1183         webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
1184
1185     if (thisEvent.IsVetoed())
1186     {
1187         wx_webviewctrls[sender]->m_busy = false;
1188         [listener ignore];
1189     }
1190     else
1191     {
1192         [listener use];
1193     }
1194 }
1195
1196 - (void)webView:(WebView *)sender
1197       decidePolicyForNewWindowAction:(NSDictionary *)actionInformation
1198                              request:(NSURLRequest *)request
1199                         newFrameName:(NSString *)frameName
1200                     decisionListener:(id < WebPolicyDecisionListener >)listener
1201 {
1202     wxUnusedVar(actionInformation);
1203
1204     wxASSERT(wx_webviewctrls.find(sender) != wx_webviewctrls.end());
1205     NSString *url = [[request URL] absoluteString];
1206     wxWebNavigationEvent thisEvent(wxEVT_COMMAND_WEB_VIEW_NEWWINDOW,
1207                                    wx_webviewctrls[sender]->GetId(),
1208                                    wxStringWithNSString( url ), "", true);
1209
1210     if (webKitWindow && webKitWindow->GetEventHandler())
1211         webKitWindow->GetEventHandler()->ProcessEvent(thisEvent);
1212
1213     [listener ignore];
1214 }
1215 @end
1216
1217 #endif //wxUSE_WEBVIEW_WEBKIT