src/osx/cocoa/filedlg.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/filedlg.mm
   3 // Purpose:     wxFileDialog for wxCocoa
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2004-10-02
   7 // RCS-ID:      $Id: filedlg.mm 40007 2006-07-05 13:10:46Z SC $
   8 // Copyright:   (c) Ryan Norton
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ============================================================================
  13 // declarations
  14 // ============================================================================
  15
  16 // ----------------------------------------------------------------------------
  17 // headers
  18 // ----------------------------------------------------------------------------
  19
  20 // For compilers that support precompilation, includes "wx.h".
  21 #include "wx/wxprec.h"
  22
  23 #if wxUSE_FILEDLG
  24
  25 #include "wx/filedlg.h"
  26
  27 #ifndef WX_PRECOMP
  28     #include "wx/msgdlg.h"
  29     #include "wx/app.h"
  30 #endif
  31
  32 #include "wx/filename.h"
  33 #include "wx/tokenzr.h"
  34
  35 #include "wx/osx/private.h"
  36
  37 // ============================================================================
  38 // implementation
  39 // ============================================================================
  40
  41 // Open Items:
  42 // - support for old style MacOS creator / type combos
  43 // - parameter support for descending into packages as directories (setTreatsFilePackagesAsDirectories)
  44
  45 IMPLEMENT_CLASS(wxFileDialog, wxFileDialogBase)
  46
  47 wxFileDialog::wxFileDialog(
  48     wxWindow *parent, const wxString& message,
  49     const wxString& defaultDir, const wxString& defaultFileName, const wxString& wildCard,
  50     long style, const wxPoint& pos, const wxSize& sz, const wxString& name)
  51     : wxFileDialogBase(parent, message, defaultDir, defaultFileName, wildCard, style, pos, sz, name)
  52 {
  53 }
  54
  55 NSArray* GetTypesFromFilter( const wxString filter )
  56 {
  57     NSMutableArray* types = nil;
  58     if ( !filter.empty() )
  59     {
  60         wxArrayString names ;
  61         wxArrayString extensions;
  62
  63         wxString filter2(filter) ;
  64         int filterIndex = 0;
  65         bool isName = true ;
  66         wxString current ;
  67
  68         for ( unsigned int i = 0; i < filter2.length() ; i++ )
  69         {
  70             if ( filter2.GetChar(i) == wxT('|') )
  71             {
  72                 if ( isName )
  73                 {
  74                     names.Add( current ) ;
  75                 }
  76                 else
  77                 {
  78                     extensions.Add( current ) ;
  79                     ++filterIndex ;
  80                 }
  81
  82                 isName = !isName ;
  83                 current = wxEmptyString ;
  84             }
  85             else
  86             {
  87                 current += filter2.GetChar(i) ;
  88             }
  89         }
  90         // we allow for compatibility reason to have a single filter expression (like *.*) without
  91         // an explanatory text, in that case the first part is name and extension at the same time
  92
  93         wxASSERT_MSG( filterIndex == 0 || !isName , wxT("incorrect format of format string") ) ;
  94         if ( current.empty() )
  95             extensions.Add( names[filterIndex] ) ;
  96         else
  97             extensions.Add( current ) ;
  98         if ( filterIndex == 0 || isName )
  99             names.Add( current ) ;
 100
 101         ++filterIndex ;
 102
 103         const size_t extCount = extensions.GetCount();
 104         for ( size_t i = 0 ; i < extCount; i++ )
 105         {
 106             wxString extensiongroup = extensions[i];
 107             wxStringTokenizer tokenizer( extensiongroup , wxT(";") ) ;
 108             while ( tokenizer.HasMoreTokens() )
 109             {
 110                 wxString extension = tokenizer.GetNextToken() ;
 111                 // Remove leading '*'
 112                 if (extension.length() && (extension.GetChar(0) == '*'))
 113                     extension = extension.Mid( 1 );
 114
 115                 // Remove leading '.'
 116                 if (extension.length() && (extension.GetChar(0) == '.'))
 117                     extension = extension.Mid( 1 );
 118
 119                 if ( extension.IsEmpty() )
 120                 {
 121                     if ( types != nil )
 122                         [types release];
 123                     return nil;
 124                 }
 125
 126                 if ( types == nil )
 127                     types = [[NSMutableArray alloc] init];
 128
 129                 wxCFStringRef cfext(extension);
 130                 [types addObject: (NSString*)cfext.AsNSString()  ];
 131 #if 0
 132                 // add support for classic fileType / creator here
 133                 wxUint32 fileType, creator;
 134                 // extension -> mactypes
 135 #endif
 136             }
 137
 138         }
 139     }
 140     return types;
 141 }
 142
 143 int wxFileDialog::ShowModal()
 144 {
 145     int result = wxID_CANCEL;
 146
 147     NSSavePanel *panel = nil;
 148
 149     wxCFStringRef cf( m_message );
 150
 151     wxCFStringRef dir( m_dir );
 152     wxCFStringRef file( m_fileName );
 153
 154     m_path = wxEmptyString;
 155     m_fileNames.Clear();
 156     m_paths.Clear();
 157
 158     wxNonOwnedWindow* parentWindow = NULL;
 159     int returnCode = -1;
 160
 161     if (GetParent())
 162     {
 163         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 164     }
 165
 166     if (HasFlag(wxFD_SAVE))
 167     {
 168         NSSavePanel* sPanel = [NSSavePanel savePanel];
 169         // makes things more convenient:
 170         [sPanel setCanCreateDirectories:YES];
 171         [sPanel setMessage:cf.AsNSString()];
 172         // if we should be able to descend into pacakges we must somehow
 173         // be able to pass this in
 174         [sPanel setTreatsFilePackagesAsDirectories:NO];
 175         [sPanel setCanSelectHiddenExtension:YES];
 176
 177         if ( HasFlag(wxFD_OVERWRITE_PROMPT) )
 178         {
 179         }
 180
 181 /*
 182         if (parentWindow)
 183         {
 184             NSWindow* nativeParent = parentWindow->GetWXWindow();
 185             ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 186             [sPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 187                 modalForWindow: nativeParent modalDelegate: sheetDelegate
 188                 didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 189                 contextInfo: nil];
 190             [sheetDelegate waitForSheetToFinish];
 191             returnCode = [sheetDelegate code];
 192             [sheetDelegate release];
 193         }
 194         else
 195 */
 196         {
 197             returnCode = [sPanel runModalForDirectory:dir.AsNSString() file:file.AsNSString() ];
 198         }
 199
 200         if (returnCode == NSOKButton )
 201         {
 202             panel = sPanel;
 203             result = wxID_OK;
 204
 205             m_path = wxCFStringRef::AsString([sPanel filename]);
 206             m_fileName = wxFileNameFromPath(m_path);
 207             m_dir = wxPathOnly( m_path );
 208         }
 209     }
 210     else
 211     {
 212         NSArray* types = GetTypesFromFilter( m_wildCard ) ;
 213         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 214         [oPanel setTreatsFilePackagesAsDirectories:NO];
 215         [oPanel setCanChooseDirectories:NO];
 216         [oPanel setResolvesAliases:YES];
 217         [oPanel setCanChooseFiles:YES];
 218         [oPanel setMessage:cf.AsNSString()];
 219
 220 /*
 221         if (parentWindow)
 222         {
 223             NSWindow* nativeParent = parentWindow->GetWXWindow();
 224             ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 225             [oPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 226                 types: types modalForWindow: nativeParent
 227                 modalDelegate: sheetDelegate
 228                 didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 229                 contextInfo: nil];
 230             [sheetDelegate waitForSheetToFinish];
 231             returnCode = [sheetDelegate code];
 232             [sheetDelegate release];
 233         }
 234         else
 235 */
 236         {
 237             returnCode = [oPanel runModalForDirectory:dir.AsNSString()
 238                         file:file.AsNSString() types:types];
 239         }
 240         if (returnCode == NSOKButton )
 241         {
 242             panel = oPanel;
 243             result = wxID_OK;
 244             NSArray* filenames = [oPanel filenames];
 245             for ( size_t i = 0 ; i < [filenames count] ; ++ i )
 246             {
 247                 wxString fnstr = wxCFStringRef::AsString([filenames objectAtIndex:i]);
 248                 m_paths.Add( fnstr );
 249                 m_fileNames.Add( wxFileNameFromPath(fnstr) );
 250                 if ( i == 0 )
 251                 {
 252                     m_path = fnstr;
 253                     m_fileName = wxFileNameFromPath(fnstr);
 254                     m_dir = wxPathOnly( fnstr );
 255                 }
 256             }
 257         }
 258         if ( types != nil )
 259             [types release];
 260     }
 261
 262     return result;
 263 }
 264
 265 #endif // wxUSE_FILEDLG