acinclude.m4

   1 dnl ---------------------------------------------------------------------------
   2 dnl
   3 dnl Macros for configure.in for wxWindows by Robert Roebling, Phil Blecker,
   4 dnl Vadim Zeitlin and Ron Lee
   5 dnl
   6 dnl This script is under the wxWindows licence.
   7 dnl
   8 dnl Version: $Id$
   9 dnl ---------------------------------------------------------------------------
  10
  11
  12 dnl ===========================================================================
  13 dnl Objective-C(++) related macros
  14 dnl ===========================================================================
  15 m4_define([AC_WX_LANG_OBJECTIVEC],
  16 [AC_LANG(C)
  17 ac_ext=m
  18 ])
  19
  20 m4_define([AC_WX_LANG_OBJECTIVECPLUSPLUS],
  21 [AC_LANG(C++)
  22 ac_ext=mm
  23 ])
  24
  25 dnl ===========================================================================
  26 dnl macros to find the a file in the list of include/lib paths
  27 dnl ===========================================================================
  28
  29 dnl ---------------------------------------------------------------------------
  30 dnl call WX_PATH_FIND_INCLUDES(search path, header name), sets ac_find_includes
  31 dnl to the full name of the file that was found or leaves it empty if not found
  32 dnl ---------------------------------------------------------------------------
  33 AC_DEFUN([WX_PATH_FIND_INCLUDES],
  34 [
  35 ac_find_includes=
  36 for ac_dir in $1 /usr/include;
  37   do
  38     if test -f "$ac_dir/$2"; then
  39       ac_find_includes=$ac_dir
  40       break
  41     fi
  42   done
  43 ])
  44
  45 dnl ---------------------------------------------------------------------------
  46 dnl call WX_PATH_FIND_LIBRARIES(search path, lib name), sets ac_find_libraries
  47 dnl to the full name of the file that was found or leaves it empty if not found
  48 dnl ---------------------------------------------------------------------------
  49 AC_DEFUN([WX_PATH_FIND_LIBRARIES],
  50 [
  51   ac_find_libraries=
  52   for ac_dir in $1;
  53   do
  54     for ac_extension in a so sl dylib dll.a; do
  55       if test -f "$ac_dir/lib$2.$ac_extension"; then
  56         ac_find_libraries=$ac_dir
  57         break 2
  58       fi
  59     done
  60   done
  61 ])
  62
  63 dnl ---------------------------------------------------------------------------
  64 dnl return list of standard library paths
  65 dnl ---------------------------------------------------------------------------
  66 dnl return all default locations:
  67 dnl   - /usr/lib: standard
  68 dnl   - /usr/lib32: n32 ABI on IRIX
  69 dnl   - /usr/lib64: n64 ABI on IRIX
  70 dnl   - /usr/lib/64: 64 bit ABI on Solaris and Linux x86-64
  71 dnl
  72 dnl NB: if any of directories in the list is not a subdir of /usr, code setting
  73 dnl     wx_cv_std_libpath needs to be updated
  74 AC_DEFUN([WX_STD_LIBPATH], [/usr/lib /usr/lib32 /usr/lib/64 /usr/lib64])
  75
  76 dnl ---------------------------------------------------------------------------
  77 dnl Path to include, already defined
  78 dnl ---------------------------------------------------------------------------
  79 AC_DEFUN([WX_INCLUDE_PATH_EXIST],
  80 [
  81   dnl never add -I/usr/include to the CPPFLAGS
  82   if test "x$1" = "x/usr/include"; then
  83     ac_path_to_include=""
  84   else
  85     echo "$2" | grep "\-I$1" > /dev/null
  86     result=$?
  87     if test $result = 0; then
  88       ac_path_to_include=""
  89     else
  90       ac_path_to_include=" -I$1"
  91     fi
  92   fi
  93 ])
  94
  95 dnl ---------------------------------------------------------------------------
  96 dnl Usage: WX_LINK_PATH_EXIST(path, libpath)
  97 dnl
  98 dnl Set ac_path_to_link to nothing if path is already in libpath of to -Lpath
  99 dnl if it is not, so that libpath can be set to "$libpath$ac_path_to_link"
 100 dnl after calling this function
 101 dnl ---------------------------------------------------------------------------
 102 AC_DEFUN([WX_LINK_PATH_EXIST],
 103 [
 104   dnl never add -L/usr/libXXX explicitely to libpath
 105   if test "$1" = "default location"; then
 106     ac_path_to_link=""
 107   else
 108     echo "$2" | grep "\-L$1" > /dev/null
 109     result=$?
 110     if test $result = 0; then
 111       ac_path_to_link=""
 112     else
 113       ac_path_to_link=" -L$1"
 114     fi
 115   fi
 116 ])
 117
 118 dnl ===========================================================================
 119 dnl C++ features test
 120 dnl ===========================================================================
 121
 122 dnl ---------------------------------------------------------------------------
 123 dnl WX_CPP_NEW_HEADERS checks whether the compiler has "new" <iostream> header
 124 dnl or only the old <iostream.h> one - it may be generally assumed that if
 125 dnl <iostream> exists, the other "new" headers (without .h) exist too.
 126 dnl
 127 dnl call WX_CPP_NEW_HEADERS(actiof-if-true, action-if-false)
 128 dnl ---------------------------------------------------------------------------
 129
 130 AC_DEFUN([WX_CPP_NEW_HEADERS],
 131 [
 132     AC_LANG_SAVE
 133     AC_LANG_CPLUSPLUS
 134
 135     AC_CHECK_HEADERS([iostream],,, [ ])
 136
 137     if test "$ac_cv_header_iostream" = "yes" ; then
 138       ifelse([$1], , :, [$1])
 139     else
 140       ifelse([$2], , :, [$2])
 141     fi
 142
 143     AC_LANG_RESTORE
 144 ])
 145
 146 dnl ---------------------------------------------------------------------------
 147 dnl WX_CPP_BOOL checks whether the C++ compiler has a built in bool type
 148 dnl
 149 dnl call WX_CPP_BOOL - will define HAVE_BOOL if the compiler supports bool
 150 dnl ---------------------------------------------------------------------------
 151
 152 AC_DEFUN([WX_CPP_BOOL],
 153 [
 154   AC_CACHE_CHECK([if C++ compiler supports bool], wx_cv_cpp_bool,
 155   [
 156     AC_LANG_SAVE
 157     AC_LANG_CPLUSPLUS
 158
 159     AC_TRY_COMPILE(
 160       [
 161       ],
 162       [
 163         bool b = true;
 164
 165         return 0;
 166       ],
 167       [
 168         wx_cv_cpp_bool=yes
 169       ],
 170       [
 171         wx_cv_cpp_bool=no
 172       ]
 173     )
 174
 175     AC_LANG_RESTORE
 176   ])
 177
 178   if test "$wx_cv_cpp_bool" = "yes"; then
 179     AC_DEFINE(HAVE_BOOL)
 180   fi
 181 ])
 182
 183 dnl ---------------------------------------------------------------------------
 184 dnl WX_CPP_EXPLICIT checks whether the C++ compiler support the explicit
 185 dnl keyword and defines HAVE_EXPLICIT if this is the case
 186 dnl ---------------------------------------------------------------------------
 187
 188 AC_DEFUN([WX_CPP_EXPLICIT],
 189 [
 190   AC_CACHE_CHECK([if C++ compiler supports the explicit keyword],
 191                  wx_cv_explicit,
 192   [
 193     AC_LANG_SAVE
 194     AC_LANG_CPLUSPLUS
 195
 196     dnl do the test in 2 steps: first check that the compiler knows about the
 197     dnl explicit keyword at all and then verify that it really honours it
 198     AC_TRY_COMPILE(
 199       [
 200         class Foo { public: explicit Foo(int) {} };
 201       ],
 202       [
 203         return 0;
 204       ],
 205       [
 206         AC_TRY_COMPILE(
 207             [
 208                 class Foo { public: explicit Foo(int) {} };
 209                 static void TakeFoo(const Foo& foo) { }
 210             ],
 211             [
 212                 TakeFoo(17);
 213                 return 0;
 214             ],
 215             wx_cv_explicit=no,
 216             wx_cv_explicit=yes
 217         )
 218       ],
 219       wx_cv_explicit=no
 220     )
 221
 222     AC_LANG_RESTORE
 223   ])
 224
 225   if test "$wx_cv_explicit" = "yes"; then
 226     AC_DEFINE(HAVE_EXPLICIT)
 227   fi
 228 ])
 229
 230 dnl ---------------------------------------------------------------------------
 231 dnl WX_CHECK_FUNCS(FUNCTIONS...,
 232 dnl                [ACTION-IF-FOUND],
 233 dnl                [ACTION-IF-NOT-FOUND],
 234 dnl                [EXTRA-DEFINES-AND-INCLUDES],
 235 dnl                [EXTRA-TEST-CODE])
 236 dnl
 237 dnl Checks that the functions listed in FUNCTIONS exist in the headers and the
 238 dnl libs. For each function, if it is found then defines 'HAVE_FUNCTION' and
 239 dnl executes ACTION-IF-FOUND, otherwise executes ACTION-IF-NOT-FOUND.
 240 dnl
 241 dnl The code from EXTRA-DEFINES-AND-INCLUDES is inserted into the test before
 242 dnl the default headers are included, and EXTRA-TEST-CODE is inserted into
 243 dnl the main() function after the default test for existence.
 244 dnl
 245 dnl Examples:
 246 dnl   # the simple case
 247 dnl   WX_CHECK_FUNCS(stat)
 248 dnl   # use break to finish the loop early
 249 dnl   WX_CHECK_FUNCS(mkstemp mktemp, break)
 250 dnl   # extra defines
 251 dnl   WX_CHECK_FUNCS(strtok_r, [], [], [#define _RREENTRANT])
 252 dnl   # extra includes
 253 dnl   WX_CHECK_FUNCS(swprintf, [], [], [#include <wchar.h>])
 254 dnl   # checking the signature with extra test code
 255 dnl   WX_CHECK_FUNCS(gettimeofday, [], [], [#include <sys/time.h>]
 256 dnl     [struct timeval tv; struct timezone tz; gettimeofday(&tv, &tz)])
 257 dnl ---------------------------------------------------------------------------
 258
 259 AC_DEFUN([WX_CHECK_FUNCS],
 260 [
 261   for wx_func in $1
 262   do
 263     AC_CACHE_CHECK(
 264       [for $wx_func],
 265       [wx_cv_func_$wx_func],
 266       [
 267         AC_LINK_IFELSE(
 268           [
 269             AC_LANG_PROGRAM(
 270               [
 271                 $4
 272                 AC_INCLUDES_DEFAULT
 273               ],
 274               [
 275                 #ifndef $wx_func
 276                   &$wx_func;
 277                 #endif
 278                 $5
 279               ])
 280           ],
 281           [eval wx_cv_func_$wx_func=yes],
 282           [eval wx_cv_func_$wx_func=no])
 283       ])
 284
 285     if eval test \$wx_cv_func_$wx_func = yes
 286     then
 287       AC_DEFINE_UNQUOTED([HAVE_`echo $wx_func | tr 'a-z' 'A-Z'`])
 288       $2
 289     else
 290       :
 291       $3
 292     fi
 293   done
 294 ])
 295
 296 dnl ---------------------------------------------------------------------------
 297 dnl a slightly better AC_C_BIGENDIAN macro which allows cross-compiling
 298 dnl ---------------------------------------------------------------------------
 299
 300 AC_DEFUN([WX_C_BIGENDIAN],
 301 [AC_CACHE_CHECK([whether byte ordering is bigendian], ac_cv_c_bigendian,
 302 [ac_cv_c_bigendian=unknown
 303 # See if sys/param.h defines the BYTE_ORDER macro.
 304 AC_TRY_COMPILE([#include <sys/types.h>
 305 #include <sys/param.h>], [
 306 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
 307  bogus endian macros
 308 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
 309 AC_TRY_COMPILE([#include <sys/types.h>
 310 #include <sys/param.h>], [
 311 #if BYTE_ORDER != BIG_ENDIAN
 312  not big endian
 313 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
 314 if test $ac_cv_c_bigendian = unknown; then
 315 AC_TRY_RUN([main () {
 316   /* Are we little or big endian?  From Harbison&Steele.  */
 317   union
 318   {
 319     long l;
 320     char c[sizeof (long)];
 321   } u;
 322   u.l = 1;
 323   exit (u.c[sizeof (long) - 1] == 1);
 324 }], [ac_cv_c_bigendian=no], [ac_cv_c_bigendian=yes], [ac_cv_c_bigendian=unknown])
 325 fi])
 326 if test $ac_cv_c_bigendian = unknown; then
 327   AC_MSG_WARN([Assuming little-endian target machine - this may be overriden by adding the line "ac_cv_c_bigendian=${ac_cv_c_bigendian='yes'}" to config.cache file])
 328 fi
 329 if test $ac_cv_c_bigendian = yes; then
 330   AC_DEFINE(WORDS_BIGENDIAN)
 331 fi
 332 ])
 333
 334 dnl ---------------------------------------------------------------------------
 335 dnl override AC_ARG_ENABLE/WITH to cache the results in .cache file
 336 dnl ---------------------------------------------------------------------------
 337
 338 AC_DEFUN([WX_ARG_CACHE_INIT],
 339         [
 340           wx_arg_cache_file="configarg.cache"
 341           echo "loading argument cache $wx_arg_cache_file"
 342           rm -f ${wx_arg_cache_file}.tmp
 343           touch ${wx_arg_cache_file}.tmp
 344           touch ${wx_arg_cache_file}
 345         ])
 346
 347 AC_DEFUN([WX_ARG_CACHE_FLUSH],
 348         [
 349           echo "saving argument cache $wx_arg_cache_file"
 350           mv ${wx_arg_cache_file}.tmp ${wx_arg_cache_file}
 351         ])
 352
 353 dnl return the name of the variable to store the value of the given
 354 dnl WX_ARG_WITH/ENABLE option
 355 AC_DEFUN([WX_ARG_CACHE_NAME],)
 356
 357 dnl this macro checks for a three-valued command line --with argument:
 358 dnl   possible arguments are 'yes', 'no', 'sys', or 'builtin'
 359 dnl usage: WX_ARG_SYS_WITH(option, helpmessage, variable-name)
 360 dnl
 361 dnl the default value (used if the option is not specified at all) is the value
 362 dnl of wxUSE_ALL_FEATURES (which is "yes" by default but can be changed by
 363 dnl giving configure --disable-all-features option)
 364 AC_DEFUN([WX_ARG_SYS_WITH],
 365         [
 366           AC_MSG_CHECKING([for --with-$1])
 367           AC_ARG_WITH($1, [$2],
 368                       [
 369                         if test "$withval" = yes; then
 370                           AS_TR_SH(wx_cv_use_$1)='$3=yes'
 371                         elif test "$withval" = no; then
 372                           AS_TR_SH(wx_cv_use_$1)='$3=no'
 373                         elif test "$withval" = sys; then
 374                           AS_TR_SH(wx_cv_use_$1)='$3=sys'
 375                         elif test "$withval" = builtin; then
 376                           AS_TR_SH(wx_cv_use_$1)='$3=builtin'
 377                         else
 378                           AC_MSG_ERROR([Invalid value for --with-$1: should be yes, no, sys, or builtin])
 379                         fi
 380                         cache=yes
 381                       ],
 382                       [
 383                         LINE=`grep "^$3=" ${wx_arg_cache_file}`
 384                         if test "x$LINE" != x ; then
 385                           eval "DEFAULT_$LINE"
 386                         fi
 387
 388                         AS_TR_SH(wx_cv_use_$1)='$3=${'DEFAULT_$3":-$wxUSE_ALL_FEATURES}"
 389                       ])
 390
 391           eval "$AS_TR_SH(wx_cv_use_$1)"
 392           if test "x$cache" = xyes; then
 393             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 394           fi
 395
 396           if test "$$3" = yes; then
 397             AC_MSG_RESULT(yes)
 398           elif test "$$3" = no; then
 399             AC_MSG_RESULT(no)
 400           elif test "$$3" = sys; then
 401             AC_MSG_RESULT([system version])
 402           elif test "$$3" = builtin; then
 403             AC_MSG_RESULT([builtin version])
 404           else
 405             AC_MSG_ERROR([Invalid value for --with-$1: should be yes, no, sys, or builtin])
 406           fi
 407         ])
 408
 409 dnl this macro checks for a command line argument and caches the result
 410 dnl usage: WX_ARG_WITH(option, helpmessage, variable-name, [withstring])
 411 AC_DEFUN([WX_ARG_WITH],
 412         [
 413           withstring=$4
 414           defaultval=$wxUSE_ALL_FEATURES
 415           if test -z "$defaultval"; then
 416               if test x"$withstring" = xwithout; then
 417                   defaultval=yes
 418               else
 419                   defaultval=no
 420               fi
 421           fi
 422           AC_MSG_CHECKING([for --${withstring:-with}-$1])
 423           AC_ARG_WITH($1, [$2],
 424                       [
 425                         if test "$withval" = yes; then
 426                           AS_TR_SH(wx_cv_use_$1)='$3=yes'
 427                         else
 428                           AS_TR_SH(wx_cv_use_$1)='$3=no'
 429                         fi
 430                         cache=yes
 431                       ],
 432                       [
 433                         LINE=`grep "^$3=" ${wx_arg_cache_file}`
 434                         if test "x$LINE" != x ; then
 435                           eval "DEFAULT_$LINE"
 436                         fi
 437
 438                         AS_TR_SH(wx_cv_use_$1)='$3=${'DEFAULT_$3":-$defaultval}"
 439                       ])
 440
 441           eval "$AS_TR_SH(wx_cv_use_$1)"
 442           if test "x$cache" != xyes; then
 443             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 444           fi
 445
 446           if test x"$withstring" = xwithout; then
 447             if test $$3 = yes; then
 448               result=no
 449             else
 450               result=yes
 451             fi
 452           else
 453             result=$$3
 454           fi
 455
 456           AC_MSG_RESULT($result)
 457         ])
 458
 459 dnl same as WX_ARG_WITH but makes it clear that the option is enabled by default
 460 AC_DEFUN([WX_ARG_WITHOUT], [WX_ARG_WITH($1, [$2], $3, without)])
 461
 462 dnl like WX_ARG_WITH but uses AC_ARG_ENABLE instead of AC_ARG_WITH
 463 dnl usage: WX_ARG_ENABLE(option, helpmessage, var, [enablestring], [default])
 464 dnl
 465 dnl enablestring can be omitted or a literal string "disable" and allows to
 466 dnl show "checking for --disable-foo" message when running configure instead of
 467 dnl the default "checking for --enable-foo" one whih is useful for the options
 468 dnl enabled by default
 469 dnl
 470 dnl the "default" argument can be omitted or contain the default value to use
 471 dnl for the option if it's unspecified
 472 AC_DEFUN([WX_ARG_ENABLE],
 473         [
 474           enablestring=$4
 475           defaultval=$5
 476           if test -z "$defaultval"; then
 477               if test x"$enablestring" = xdisable; then
 478                   defaultval=yes
 479               else
 480                   defaultval=no
 481               fi
 482           fi
 483
 484           AC_MSG_CHECKING([for --${enablestring:-enable}-$1])
 485           AC_ARG_ENABLE($1, [$2],
 486                         [
 487                           if test "$enableval" = yes; then
 488                             AS_TR_SH(wx_cv_use_$1)='$3=yes'
 489                           else
 490                             AS_TR_SH(wx_cv_use_$1)='$3=no'
 491                           fi
 492                           cache=yes
 493                         ],
 494                         [
 495                           LINE=`grep "^$3=" ${wx_arg_cache_file}`
 496                           if test "x$LINE" != x ; then
 497                             eval "DEFAULT_$LINE"
 498                           fi
 499
 500                           AS_TR_SH(wx_cv_use_$1)='$3=${'DEFAULT_$3":-$defaultval}"
 501                         ])
 502
 503           eval "$AS_TR_SH(wx_cv_use_$1)"
 504           if test "x$cache" = xyes; then
 505             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 506           fi
 507
 508           if test x"$enablestring" = xdisable; then
 509             if test $$3 = yes; then
 510               result=no
 511             else
 512               result=yes
 513             fi
 514           else
 515             result=$$3
 516           fi
 517
 518           AC_MSG_RESULT($result)
 519         ])
 520
 521 dnl the same as WX_ARG_ENABLE but makes it more clear that the option is
 522 dnl enabled by default
 523 AC_DEFUN([WX_ARG_DISABLE], [WX_ARG_ENABLE($1, [$2], $3, disable)])
 524
 525 dnl same as WX_ARG_ENABLE but defaults to wxUSE_ALL_FEATURES instead of "yes"
 526 AC_DEFUN([WX_ARG_FEATURE], [WX_ARG_ENABLE($1, [$2], $3,, $wxUSE_ALL_FEATURES)])
 527
 528 dnl Like WX_ARG_ENABLE but accepts a parameter.
 529 dnl
 530 dnl Usage:
 531 dnl   WX_ARG_ENABLE_PARAM(option, helpmessage, variable-name, enablestring)
 532 dnl
 533 dnl Example:
 534 dnl   WX_ARG_ENABLE_PARAM(foo, [[  --enable-foo[=bar] use foo]], wxUSE_FOO)
 535 dnl
 536 dnl  --enable-foo       wxUSE_FOO=yes
 537 dnl  --disable-foo      wxUSE_FOO=no
 538 dnl  --enable-foo=bar   wxUSE_FOO=bar
 539 dnl  <not given>        value from configarg.cache or
 540 dnl                     wxUSE_FOO=$DEFAULT_wxUSE_FOO
 541 dnl
 542 AC_DEFUN([WX_ARG_ENABLE_PARAM],
 543         [
 544           enablestring=$4
 545           AC_MSG_CHECKING([for --${enablestring:-enable}-$1])
 546           AC_ARG_ENABLE($1, [$2],
 547                         [
 548                           wx_cv_use_$1="$3='$enableval'"
 549                           cache=yes
 550                         ],
 551                         [
 552                           LINE=`grep "^$3=" ${wx_arg_cache_file}`
 553                           if test "x$LINE" != x ; then
 554                             eval "DEFAULT_$LINE"
 555                           fi
 556
 557                           wx_cv_use_$1='$3='$DEFAULT_$3
 558                         ])
 559
 560           eval "$wx_cv_use_$1"
 561           if test "x$cache" = xyes; then
 562             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 563           fi
 564
 565           AC_MSG_RESULT([$$3])
 566         ])
 567
 568 dnl ===========================================================================
 569 dnl Linker features test
 570 dnl ===========================================================================
 571
 572 dnl ---------------------------------------------------------------------------
 573 dnl WX_VERSIONED_SYMBOLS checks whether the linker can create versioned
 574 dnl symbols. If it can, sets LDFLAGS_VERSIONING to $CXX flags needed to use
 575 dnl version script file named versionfile
 576 dnl
 577 dnl call WX_VERSIONED_SYMBOLS(versionfile)
 578 dnl ---------------------------------------------------------------------------
 579 AC_DEFUN([WX_VERSIONED_SYMBOLS],
 580 [
 581     case "${host}" in
 582         *-*-cygwin* | *-*-mingw* )
 583             dnl although ld does support version script option on these
 584             dnl platforms, it doesn't make much sense to use it under Win32
 585             dnl and, moreover, this breaks linking because of a bug in handling
 586             dnl paths in -Wl,--version-script,path option (if we ever do need
 587             dnl to use it for cygwin/mingw32, keep in mind that replacing last
 588             dnl comma with the equal sign works) so
 589             dnl simply disable it
 590             wx_cv_version_script=no
 591             ;;
 592
 593         *)
 594             AC_CACHE_CHECK([if the linker accepts --version-script], wx_cv_version_script,
 595             [
 596                 echo "VER_1 { *; };" >conftest.sym
 597                 echo "int main() { return 0; }" >conftest.cpp
 598
 599                 if AC_TRY_COMMAND([
 600                         $CXX -o conftest.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 601                         -Wl,--version-script,conftest.sym >/dev/null 2>conftest.stderr]) ; then
 602                   if test -s conftest.stderr ; then
 603                       wx_cv_version_script=no
 604                   else
 605                       wx_cv_version_script=yes
 606                   fi
 607                 else
 608                   wx_cv_version_script=no
 609                 fi
 610
 611                 dnl There's a problem in some old linkers with --version-script that
 612                 dnl can cause linking to fail when you have objects with vtables in
 613                 dnl libs 3 deep.  This is known to happen in netbsd and openbsd with
 614                 dnl ld 2.11.2.
 615                 dnl
 616                 dnl To test for this we need to make some shared libs and
 617                 dnl unfortunately we can't be sure of the right way to do that. If the
 618                 dnl first two compiles don't succeed then it looks like the test isn't
 619                 dnl working and the result is ignored, but if OTOH the first two
 620                 dnl succeed but the third does not then the bug has been detected and
 621                 dnl the --version-script flag is dropped.
 622                 if test $wx_cv_version_script = yes
 623                 then
 624                   echo "struct B { virtual ~B() { } }; \
 625                         struct D : public B { }; \
 626                         void F() { D d; }" > conftest.cpp
 627
 628                   if AC_TRY_COMMAND([
 629                         $CXX -shared -fPIC -o conftest1.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 630                         -Wl,--version-script,conftest.sym >/dev/null 2>/dev/null]) &&
 631                      AC_TRY_COMMAND([
 632                         $CXX -shared -fPIC -o conftest2.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 633                         -Wl,--version-script,conftest.sym conftest1.output >/dev/null 2>/dev/null])
 634                   then
 635                     if AC_TRY_COMMAND([
 636                           $CXX -shared -fPIC -o conftest3.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 637                           -Wl,--version-script,conftest.sym conftest2.output conftest1.output >/dev/null 2>/dev/null])
 638                     then
 639                       wx_cv_version_script=yes
 640                     else
 641                       wx_cv_version_script=no
 642                     fi
 643                   fi
 644                 fi
 645
 646                 rm -f conftest.output conftest.stderr conftest.sym conftest.cpp
 647                 rm -f conftest1.output conftest2.output conftest3.output
 648             ])
 649
 650             if test $wx_cv_version_script = yes ; then
 651                 LDFLAGS_VERSIONING="-Wl,--version-script,$1"
 652             fi
 653             ;;
 654     esac
 655 ])
 656
 657
 658 dnl ===========================================================================
 659 dnl "3rd party" macros included here because they are not widely available
 660 dnl ===========================================================================
 661
 662 dnl ---------------------------------------------------------------------------
 663 dnl test for availability of iconv()
 664 dnl ---------------------------------------------------------------------------
 665
 666 dnl From Bruno Haible.
 667
 668 AC_DEFUN([AM_ICONV],
 669 [
 670   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 671   dnl those with the standalone portable GNU libiconv installed).
 672
 673   AC_ARG_WITH([libiconv-prefix],
 674 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
 675     for dir in `echo "$withval" | tr : ' '`; do
 676       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
 677       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
 678     done
 679    ])
 680
 681   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 682     am_cv_func_iconv="no, consider installing GNU libiconv"
 683     am_cv_lib_iconv=no
 684     AC_TRY_LINK([#include <stdlib.h>
 685 #include <iconv.h>],
 686       [iconv_t cd = iconv_open("","");
 687        iconv(cd,NULL,NULL,NULL,NULL);
 688        iconv_close(cd);],
 689       am_cv_func_iconv=yes)
 690     if test "$am_cv_func_iconv" != yes; then
 691       am_save_LIBS="$LIBS"
 692       LIBS="$LIBS -liconv"
 693       AC_TRY_LINK([#include <stdlib.h>
 694 #include <iconv.h>],
 695         [iconv_t cd = iconv_open("","");
 696          iconv(cd,NULL,NULL,NULL,NULL);
 697          iconv_close(cd);],
 698         am_cv_lib_iconv=yes
 699         am_cv_func_iconv=yes)
 700       LIBS="$am_save_LIBS"
 701     fi
 702   ])
 703   if test "$am_cv_func_iconv" = yes; then
 704     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 705     AC_CACHE_CHECK([if iconv needs const], wx_cv_func_iconv_const,
 706       AC_TRY_COMPILE([
 707 #include <stdlib.h>
 708 #include <iconv.h>
 709 extern
 710 #ifdef __cplusplus
 711 "C"
 712 #endif
 713 #if defined(__STDC__) || defined(__cplusplus)
 714 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 715 #else
 716 size_t iconv();
 717 #endif
 718         ],
 719         [],
 720         wx_cv_func_iconv_const="no",
 721         wx_cv_func_iconv_const="yes"
 722       )
 723     )
 724
 725     iconv_const=
 726     if test "x$wx_cv_func_iconv_const" = "xyes"; then
 727         iconv_const="const"
 728     fi
 729
 730     AC_DEFINE_UNQUOTED(ICONV_CONST, $iconv_const,
 731       [Define as const if the declaration of iconv() needs const.])
 732   fi
 733   LIBICONV=
 734   if test "$am_cv_lib_iconv" = yes; then
 735     LIBICONV="-liconv"
 736   fi
 737   AC_SUBST(LIBICONV)
 738 ])
 739
 740 dnl ---------------------------------------------------------------------------
 741 dnl AC_SYS_LARGEFILE (partly based on the code from autoconf 2.5x)
 742 dnl ---------------------------------------------------------------------------
 743
 744 dnl WX_SYS_LARGEFILE_TEST
 745 dnl
 746 dnl NB: original autoconf test was checking if compiler supported 6 bit off_t
 747 dnl     arithmetic properly but this failed miserably with gcc under Linux
 748 dnl     whereas the system still supports 64 bit files, so now simply check
 749 dnl     that off_t is big enough
 750 define(WX_SYS_LARGEFILE_TEST,
 751 [typedef struct {
 752     unsigned int field: sizeof(off_t) == 8;
 753 } wxlf;
 754 ])
 755
 756
 757 dnl WX_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR)
 758 define(WX_SYS_LARGEFILE_MACRO_VALUE,
 759 [
 760     AC_CACHE_CHECK([for $1 value needed for large files], [$3],
 761         [
 762           AC_TRY_COMPILE([#define $1 $2
 763                           #include <sys/types.h>],
 764                          WX_SYS_LARGEFILE_TEST,
 765                          [$3=$2],
 766                          [$3=no])
 767         ]
 768     )
 769
 770     if test "$$3" != no; then
 771         wx_largefile=yes
 772         AC_DEFINE_UNQUOTED([$1], [$$3])
 773     fi
 774 ])
 775
 776
 777 dnl AC_SYS_LARGEFILE
 778 dnl ----------------
 779 dnl By default, many hosts won't let programs access large files;
 780 dnl one must use special compiler options to get large-file access to work.
 781 dnl For more details about this brain damage please see:
 782 dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
 783 AC_DEFUN([AC_SYS_LARGEFILE],
 784 [AC_ARG_ENABLE(largefile,
 785                [  --disable-largefile     omit support for large files])
 786 if test "$enable_largefile" != no; then
 787     dnl _FILE_OFFSET_BITS==64 is needed for Linux, Solaris, ...
 788     dnl _LARGE_FILES -- for AIX
 789     wx_largefile=no
 790     WX_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64, ac_cv_sys_file_offset_bits)
 791     if test "x$wx_largefile" != "xyes"; then
 792         WX_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1, ac_cv_sys_large_files)
 793     fi
 794
 795     AC_MSG_CHECKING(if large file support is available)
 796     if test "x$wx_largefile" = "xyes"; then
 797         AC_DEFINE(HAVE_LARGEFILE_SUPPORT)
 798     fi
 799     AC_MSG_RESULT($wx_largefile)
 800 fi
 801 ])
 802
 803
 804 dnl Available from the GNU Autoconf Macro Archive at:
 805 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_const_cast.html
 806 dnl
 807 AC_DEFUN([AC_CXX_CONST_CAST],
 808 [AC_CACHE_CHECK(whether the compiler supports const_cast<>,
 809 ac_cv_cxx_const_cast,
 810 [AC_LANG_SAVE
 811  AC_LANG_CPLUSPLUS
 812  AC_TRY_COMPILE(,[int x = 0;const int& y = x;int& z = const_cast<int&>(y);return z;],
 813  ac_cv_cxx_const_cast=yes, ac_cv_cxx_const_cast=no)
 814  AC_LANG_RESTORE
 815 ])
 816 if test "$ac_cv_cxx_const_cast" = yes; then
 817   AC_DEFINE(HAVE_CONST_CAST,,[define if the compiler supports const_cast<>])
 818 fi
 819 ])
 820
 821 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_reinterpret_cast.html
 822 AC_DEFUN([AC_CXX_REINTERPRET_CAST],
 823 [AC_CACHE_CHECK(whether the compiler supports reinterpret_cast<>,
 824 ac_cv_cxx_reinterpret_cast,
 825 [AC_LANG_SAVE
 826  AC_LANG_CPLUSPLUS
 827  AC_TRY_COMPILE([#include <typeinfo>
 828 class Base { public : Base () {} virtual void f () = 0;};
 829 class Derived : public Base { public : Derived () {} virtual void f () {} };
 830 class Unrelated { public : Unrelated () {} };
 831 int g (Unrelated&) { return 0; }],[
 832 Derived d;Base& b=d;Unrelated& e=reinterpret_cast<Unrelated&>(b);return g(e);],
 833  ac_cv_cxx_reinterpret_cast=yes, ac_cv_cxx_reinterpret_cast=no)
 834  AC_LANG_RESTORE
 835 ])
 836 if test "$ac_cv_cxx_reinterpret_cast" = yes; then
 837   AC_DEFINE(HAVE_REINTERPRET_CAST,,
 838             [define if the compiler supports reinterpret_cast<>])
 839 fi
 840 ])
 841
 842 dnl and http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_static_cast.html
 843 AC_DEFUN([AC_CXX_STATIC_CAST],
 844 [AC_CACHE_CHECK(whether the compiler supports static_cast<>,
 845 ac_cv_cxx_static_cast,
 846 [AC_LANG_SAVE
 847  AC_LANG_CPLUSPLUS
 848  AC_TRY_COMPILE([#include <typeinfo>
 849 class Base { public : Base () {} virtual void f () = 0; };
 850 class Derived : public Base { public : Derived () {} virtual void f () {} };
 851 int g (Derived&) { return 0; }],[
 852 Derived d; Base& b = d; Derived& s = static_cast<Derived&> (b); return g (s);],
 853  ac_cv_cxx_static_cast=yes, ac_cv_cxx_static_cast=no)
 854  AC_LANG_RESTORE
 855 ])
 856 if test "$ac_cv_cxx_static_cast" = yes; then
 857   AC_DEFINE(HAVE_STATIC_CAST,, [define if the compiler supports static_cast<>])
 858 fi
 859 ])
 860
 861 dnl http://autoconf-archive.cryp.to/ac_cxx_dynamic_cast.html
 862 AC_DEFUN([AC_CXX_DYNAMIC_CAST],
 863 [AC_CACHE_CHECK(whether the compiler supports dynamic_cast<>,
 864 ac_cv_cxx_dynamic_cast,
 865 [AC_LANG_SAVE
 866  AC_LANG_CPLUSPLUS
 867  AC_TRY_COMPILE([#include <typeinfo>
 868 class Base { public : Base () {} virtual void f () = 0;};
 869 class Derived : public Base { public : Derived () {} virtual void f () {} };],[
 870 Derived d; Base& b=d; return dynamic_cast<Derived*>(&b) ? 0 : 1;],
 871  ac_cv_cxx_dynamic_cast=yes, ac_cv_cxx_dynamic_cast=no)
 872  AC_LANG_RESTORE
 873 ])
 874 if test "$ac_cv_cxx_dynamic_cast" = yes; then
 875   AC_DEFINE(HAVE_DYNAMIC_CAST,,[define if the compiler supports dynamic_cast<>])
 876 fi
 877 ])
 878