configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Id$)dnl
   3
   4 dnl ---------------------------------------------------------------------------
   5 dnl
   6 dnl Top-level configure.in for wxWindows by Robert Roebling, Phil Blecker and
   7 dnl Vadim Zeitlin
   8 dnl
   9 dnl This script is under the wxWindows licence.
  10 dnl
  11 dnl Version: $Id$
  12 dnl ---------------------------------------------------------------------------
  13
  14 dnl ---------------------------------------------------------------------------
  15 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
  16 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS. Uses variables
  17 dnl gtk_config_prefix and/or gtk_config_exec_prefix if defined.
  18 dnl ---------------------------------------------------------------------------
  19 dnl
  20 AC_DEFUN(AM_PATH_GTK,
  21 [
  22   if test x$gtk_config_exec_prefix != x ; then
  23      gtk_config_args="$gtk_config_args --exec-prefix=$gtk_config_exec_prefix"
  24      if test x${GTK_CONFIG+set} != xset ; then
  25         GTK_CONFIG=$gtk_config_exec_prefix/bin/gtk-config
  26      fi
  27   fi
  28   if test x$gtk_config_prefix != x ; then
  29      gtk_config_args="$gtk_config_args --prefix=$gtk_config_prefix"
  30      if test x${GTK_CONFIG+set} != xset ; then
  31         GTK_CONFIG=$gtk_config_prefix/bin/gtk-config
  32      fi
  33   fi
  34
  35   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
  36   min_gtk_version=ifelse([$1], ,0.99.7,$1)
  37   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
  38   no_gtk=""
  39   if test "$GTK_CONFIG" != "no" ; then
  40     GTK_CFLAGS=`$GTK_CONFIG --cflags`
  41     GTK_LIBS=`$GTK_CONFIG --libs`
  42     ac_save_CFLAGS="$CFLAGS"
  43     ac_save_LIBS="$LIBS"
  44     CFLAGS="$CFLAGS $GTK_CFLAGS"
  45     LIBS="$LIBS $GTK_LIBS"
  46 dnl
  47 dnl Now check if the installed GTK is sufficiently new. (Also sanity
  48 dnl checks the results of gtk-config to some extent)
  49 dnl
  50     AC_TRY_RUN([
  51 #include <gtk/gtk.h>
  52 #include <stdio.h>
  53
  54 int
  55 main ()
  56 {
  57   int major, minor, micro;
  58
  59   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
  60      printf("%s, bad version string\n", "$min_gtk_version");
  61      exit(1);
  62    }
  63
  64    if (gtk_minor_version == 1) return FALSE;
  65
  66    return !((gtk_major_version > major) ||
  67             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
  68             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
  69 }
  70 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
  71      CFLAGS="$ac_save_CFLAGS"
  72      LIBS="$ac_save_LIBS"
  73   else
  74      no_gtk=yes
  75   fi
  76   if test "x$no_gtk" = x ; then
  77      AC_MSG_RESULT(yes)
  78      ifelse([$2], , :, [$2])
  79   else
  80      AC_MSG_RESULT(no)
  81      GTK_CFLAGS=""
  82      GTK_LIBS=""
  83      ifelse([$3], , :, [$3])
  84   fi
  85   AC_SUBST(GTK_CFLAGS)
  86   AC_SUBST(GTK_LIBS)
  87 ])
  88
  89 dnl ===========================================================================
  90 dnl macros to find the a file in the list of include/lib paths
  91 dnl ===========================================================================
  92
  93 dnl ---------------------------------------------------------------------------
  94 dnl call WX_PATH_FIND_INCLUDES(search path, header name), sets ac_find_includes
  95 dnl to the full name of the file that was found or leaves it empty if not found
  96 dnl ---------------------------------------------------------------------------
  97 AC_DEFUN(WX_PATH_FIND_INCLUDES,
  98 [
  99 ac_find_includes=
 100 for ac_dir in $1;
 101   do
 102     if test -f "$ac_dir/$2"; then
 103       ac_find_includes=$ac_dir
 104       break
 105     fi
 106   done
 107 ])
 108
 109 dnl ---------------------------------------------------------------------------
 110 dnl call WX_PATH_FIND_LIBRARIES(search path, header name), sets ac_find_includes
 111 dnl to the full name of the file that was found or leaves it empty if not found
 112 dnl ---------------------------------------------------------------------------
 113 AC_DEFUN(WX_PATH_FIND_LIBRARIES,
 114 [
 115 ac_find_libraries=
 116 for ac_dir in $1;
 117   do
 118     for ac_extension in a so sl; do
 119       if test -f "$ac_dir/lib$2.$ac_extension"; then
 120         ac_find_libraries=$ac_dir
 121         break 2
 122       fi
 123     done
 124   done
 125 ])
 126
 127 dnl ---------------------------------------------------------------------------
 128 dnl Path to include, already defined
 129 dnl ---------------------------------------------------------------------------
 130 AC_DEFUN(WX_INCLUDE_PATH_EXIST,
 131 [
 132   ac_path_to_include=$1
 133   echo "$2" | grep "\-I$1" > /dev/null
 134   result=$?
 135   if test $result = 0; then
 136     ac_path_to_include=""
 137   else
 138     ac_path_to_include="-I$1"
 139   fi
 140 ])
 141
 142 dnl ---------------------------------------------------------------------------
 143 dnl Path to link, already defined
 144 dnl ---------------------------------------------------------------------------
 145 AC_DEFUN(WX_LINK_PATH_EXIST,
 146 [
 147   echo "$2" | grep "\-L$1" > /dev/null
 148   result=$?
 149   if test $result = 0; then
 150     ac_path_to_link=""
 151   else
 152     ac_path_to_link="-L$1"
 153   fi
 154 ])
 155
 156 dnl ===========================================================================
 157 dnl C++ features test
 158 dnl ===========================================================================
 159
 160 dnl ---------------------------------------------------------------------------
 161 dnl WX_CPP_NEW_HEADERS checks whether the compiler has "new" <iostream> header
 162 dnl or only the old <iostream.h> one - it may be generally assumed that if
 163 dnl <iostream> exists, the other "new" headers (without .h) exist too.
 164 dnl
 165 dnl call WX_CPP_NEW_HEADERS(actiof-if-true, action-if-false-or-cross-compiling)
 166 dnl ---------------------------------------------------------------------------
 167
 168 AC_DEFUN(WX_CPP_NEW_HEADERS,
 169 [
 170   if test "$cross_compiling" = "yes"; then
 171     ifelse([$2], , :, [$2])
 172   else
 173     AC_LANG_SAVE
 174     AC_LANG_CPLUSPLUS
 175
 176     AC_CHECK_HEADERS(iostream)
 177
 178     if test "x$HAVE_IOSTREAM" = x ; then
 179       ifelse([$2], , :, [$2])
 180     else
 181       ifelse([$1], , :, [$1])
 182     fi
 183
 184     AC_LANG_RESTORE
 185   fi
 186 ])
 187
 188 dnl ---------------------------------------------------------------------------
 189 dnl WX_CPP_BOOL checks whether the C++ compiler has a built in bool type
 190 dnl
 191 dnl call WX_CPP_BOOL - will define HAVE_BOOL if the compiler supports bool
 192 dnl ---------------------------------------------------------------------------
 193
 194 AC_DEFUN(WX_CPP_BOOL,
 195 [
 196   AC_CACHE_CHECK([if C++ compiler supports bool], wx_cv_cpp_bool,
 197   [
 198     AC_LANG_SAVE
 199     AC_LANG_CPLUSPLUS
 200
 201     AC_TRY_RUN([
 202         int main()
 203         {
 204             bool b = true;
 205
 206             return 0;
 207         }
 208       ],
 209       [
 210         AC_DEFINE(HAVE_BOOL)
 211         wx_cv_cpp_bool=yes
 212       ],
 213       wx_cv_cpp_bool=no,
 214       wx_cv_cpp_bool=no
 215     )
 216
 217     AC_LANG_RESTORE
 218   ])
 219
 220   if test "$wx_cv_cpp_bool" = "yes"; then
 221     AC_DEFINE(HAVE_BOOL)
 222   fi
 223 ])
 224
 225 dnl ---------------------------------------------------------------------------
 226 dnl WX_CPP_SIZE_T_IS_NOT_INT checks whether size_t and int are different types,
 227 dnl i.e. whether we may overload operator[] on its argument type
 228 dnl ---------------------------------------------------------------------------
 229
 230 AC_DEFUN(WX_CPP_SIZE_T_IS_NOT_INT,
 231 [
 232   AC_CACHE_CHECK([if size_t and int are different types], wx_cv_cpp_sizet_not_int,
 233   [
 234     AC_LANG_SAVE
 235     AC_LANG_CPLUSPLUS
 236
 237     AC_TRY_RUN([
 238         #include <stdlib.h>
 239
 240         class S
 241         {
 242         public:
 243           S(char *s) { m_s = s; }
 244
 245           char operator[](size_t n) const { return m_s[n]; }
 246           char operator[](int n) const { return m_s[n]; }
 247
 248         private:
 249           char *m_s;
 250         };
 251
 252         int main()
 253         {
 254             S s("dummy");
 255             size_t n1 = 2;
 256             int n2 = 3;
 257
 258             return s[n1] == s[n2];
 259         }
 260       ],
 261       AC_DEFINE(wxUSE_SIZE_T_STRING_OPERATOR) wx_cv_cpp_sizet_not_int=yes,
 262       wx_cv_cpp_sizet_not_int=no,
 263       wx_cv_cpp_sizet_not_int=no
 264     )
 265
 266     AC_LANG_RESTORE
 267   ])
 268 ])
 269
 270 dnl ---------------------------------------------------------------------------
 271 dnl a slightly better AC_C_BIGENDIAN macro which allows cross-compiling
 272 dnl ---------------------------------------------------------------------------
 273
 274 AC_DEFUN(WX_C_BIGENDIAN,
 275 [AC_CACHE_CHECK(whether byte ordering is bigendian, ac_cv_c_bigendian,
 276 [ac_cv_c_bigendian=unknown
 277 # See if sys/param.h defines the BYTE_ORDER macro.
 278 AC_TRY_COMPILE([#include <sys/types.h>
 279 #include <sys/param.h>], [
 280 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
 281  bogus endian macros
 282 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
 283 AC_TRY_COMPILE([#include <sys/types.h>
 284 #include <sys/param.h>], [
 285 #if BYTE_ORDER != BIG_ENDIAN
 286  not big endian
 287 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
 288 if test $ac_cv_c_bigendian = unknown; then
 289 AC_TRY_RUN([main () {
 290   /* Are we little or big endian?  From Harbison&Steele.  */
 291   union
 292   {
 293     long l;
 294     char c[sizeof (long)];
 295   } u;
 296   u.l = 1;
 297   exit (u.c[sizeof (long) - 1] == 1);
 298 }], ac_cv_c_bigendian=no, ac_cv_c_bigendian=yes, ac_cv_c_bigendian=unknown)
 299 fi])
 300 if test $ac_cv_c_bigendian = unknown; then
 301   AC_MSG_WARN([Assuming little-endian target machine - this may be overriden by adding the line "ac_cv_c_bigendian=${ac_cv_c_bigendian='yes'}" to config.cache file])
 302 fi
 303 if test $ac_cv_c_bigendian = yes; then
 304   AC_DEFINE(WORDS_BIGENDIAN)
 305 fi
 306 ])
 307
 308 dnl ---------------------------------------------------------------------------
 309 dnl override AC_ARG_ENABLE/WITH to cache the results in .cache file
 310 dnl ---------------------------------------------------------------------------
 311
 312 AC_DEFUN(WX_ARG_CACHE_INIT,
 313         [
 314           wx_arg_cache_file="configarg.cache"
 315           echo "loading argument cache $wx_arg_cache_file"
 316           rm -f ${wx_arg_cache_file}.tmp
 317           touch ${wx_arg_cache_file}.tmp
 318           touch ${wx_arg_cache_file}
 319         ])
 320
 321 AC_DEFUN(WX_ARG_CACHE_FLUSH,
 322         [
 323           echo "saving argument cache $wx_arg_cache_file"
 324           mv ${wx_arg_cache_file}.tmp ${wx_arg_cache_file}
 325         ])
 326
 327 dnl this macro checks for a command line argument and caches the result
 328 dnl usage: WX_ARG_WITH(option, helpmessage, variable-name)
 329 AC_DEFUN(WX_ARG_WITH,
 330         [
 331           AC_MSG_CHECKING("for --with-$1")
 332           no_cache=0
 333           AC_ARG_WITH($1, $2,
 334                       [
 335                         if test "$withval" = yes; then
 336                           ac_cv_use_$1='$3=yes'
 337                         else
 338                           ac_cv_use_$1='$3=no'
 339                         fi
 340                       ],
 341                       [
 342                         LINE=`grep "$3" ${wx_arg_cache_file}`
 343                         if test "x$LINE" != x ; then
 344                           eval "DEFAULT_$LINE"
 345                         else
 346                           no_cache=1
 347                         fi
 348
 349                         ac_cv_use_$1='$3='$DEFAULT_$3
 350                       ])
 351
 352           eval "$ac_cv_use_$1"
 353           if test "$no_cache" != 1; then
 354             echo $ac_cv_use_$1 >> ${wx_arg_cache_file}.tmp
 355           fi
 356
 357           if test "$$3" = yes; then
 358             AC_MSG_RESULT(yes)
 359           else
 360             AC_MSG_RESULT(no)
 361           fi
 362         ])
 363
 364 dnl like WX_ARG_WITH but uses AC_ARG_ENABLE instead of AC_ARG_WITH
 365 dnl usage: WX_ARG_ENABLE(option, helpmessage, variable-name)
 366 AC_DEFUN(WX_ARG_ENABLE,
 367         [
 368           AC_MSG_CHECKING("for --enable-$1")
 369           no_cache=0
 370           AC_ARG_ENABLE($1, $2,
 371                         [
 372                           if test "$enableval" = yes; then
 373                             ac_cv_use_$1='$3=yes'
 374                           else
 375                             ac_cv_use_$1='$3=no'
 376                           fi
 377                         ],
 378                         [
 379                           LINE=`grep "$3" ${wx_arg_cache_file}`
 380                           if test "x$LINE" != x ; then
 381                             eval "DEFAULT_$LINE"
 382                           else
 383                             no_cache=1
 384                           fi
 385
 386                           ac_cv_use_$1='$3='$DEFAULT_$3
 387                         ])
 388
 389           eval "$ac_cv_use_$1"
 390           if test "$no_cache" != 1; then
 391             echo $ac_cv_use_$1 >> ${wx_arg_cache_file}.tmp
 392           fi
 393
 394           if test "$$3" = yes; then
 395             AC_MSG_RESULT(yes)
 396           else
 397             AC_MSG_RESULT(no)
 398           fi
 399         ])
 400
 401 dnl -
 402 dnl - GNU libc extension (added by GL)
 403 dnl -
 404
 405 AC_DEFUN(WX_GNU_EXTENSIONS,
 406 [
 407 AC_MSG_CHECKING([if you need GNU extensions])
 408 AC_CACHE_VAL(wx_cv_gnu_extensions,[
 409    AC_TRY_COMPILE([#include <features.h>],[
 410
 411 #ifndef __GNU_LIBRARY__
 412  Compile error wanted
 413 #endif
 414
 415 ],
 416   [wx_cv_gnu_extensions=yes],
 417   [wx_cv_gnu_extensions=no])
 418 ])
 419
 420 AC_MSG_RESULT($wx_cv_gnu_extensions)
 421 if test "$wx_cv_gnu_extensions" = "yes"; then
 422   AC_DEFINE_UNQUOTED(_GNU_SOURCE)
 423 fi
 424 ])
 425
 426
 427 dnl ---------------------------------------------------------------------------
 428 dnl initialization
 429 dnl ---------------------------------------------------------------------------
 430
 431 dnl the file passed to AC_INIT should be specific to our package
 432 AC_INIT(wx-config.in)
 433
 434 AC_CANONICAL_SYSTEM
 435
 436 dnl When making releases do:
 437 dnl
 438 dnl WX_RELEASE_NUMBER += 1
 439 dnl WX_INTERFACE_AGE += 1
 440 dnl WX_BINARY_AGE += 1
 441 dnl
 442 dnl if any functions have been added, do:
 443 dnl
 444 dnl WX_INTERFACE_AGE = 0
 445
 446 WX_MAJOR_VERSION_NUMBER=2
 447 WX_MINOR_VERSION_NUMBER=1
 448 WX_RELEASE_NUMBER=0
 449
 450 WX_INTERFACE_AGE=0
 451 WX_BINARY_AGE=0
 452
 453 WX_VERSION=$WX_MAJOR_VERSION_NUMBER.$WX_MINOR_VERSION_NUMBER.$WX_RELEASE_NUMBER
 454
 455 dnl wxWindows shared library versioning
 456 WX_RELEASE=$WX_MAJOR_VERSION_NUMBER.$WX_MINOR_VERSION_NUMBER
 457 WX_CURRENT=`expr $WX_RELEASE_NUMBER - $WX_INTERFACE_AGE`
 458 WX_REVISION=$WX_INTERFACE_AGE
 459 WX_AGE=`expr $WX_BINARY_AGE - $WX_INTERFACE_AGE`
 460
 461 dnl ------------------------------------------------------------------------
 462 dnl Check platform (host system)
 463 dnl ------------------------------------------------------------------------
 464
 465 dnl assume Unix
 466 USE_UNIX=1
 467 USE_LINUX=
 468 USE_SGI=
 469 USE_HPUX=
 470 USE_SYSV=
 471 USE_SVR4=
 472 USE_AIX=
 473 USE_SUN=
 474 USE_SOLARIS=
 475 USE_SUNOS=
 476 USE_ALPHA=
 477 USE_OSF=
 478 USE_BSD=
 479 USE_FREEBSD=
 480 USE_VMS=
 481 USE_ULTRIX=
 482 USE_CYGWIN=
 483 USE_MINGW=
 484 USE_DATA_GENERAL=
 485
 486 dnl the list of all available toolkits
 487 ALL_TOOLKITS="CYGWIN GTK MINGW MOTIF WINE"
 488
 489 dnl NB: these wxUSE_XXX constants have value of 0 or 1 unlike all the other ones
 490 dnl     which are either yes or no
 491 DEFAULT_wxUSE_GTK=0
 492 DEFAULT_wxUSE_MOTIF=0
 493 DEFAULT_wxUSE_MSW=0
 494 DEFAULT_wxUSE_WINE=0
 495
 496 dnl these are the values which are really default for the given platform -
 497 dnl they're not cached and are only used if no --with-toolkit was given *and*
 498 dnl nothing was found in the cache
 499 DEFAULT_DEFAULT_wxUSE_GTK=0
 500 DEFAULT_DEFAULT_wxUSE_MOTIF=0
 501 DEFAULT_DEFAULT_wxUSE_MSW=0
 502 DEFAULT_DEFAULT_wxUSE_WINE=0
 503
 504 case "${host}" in
 505   *-hp-hpux* )
 506     USE_HPUX=1
 507     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 508     AC_DEFINE(__HPUX__)
 509   ;;
 510   *-*-linux* )
 511     USE_LINUX=1
 512     AC_DEFINE(__LINUX__)
 513     TMP=`uname -m`
 514     if test "x$TMP" = "xalpha"; then
 515       USE_ALPHA=1
 516       AC_DEFINE(__ALPHA__)
 517     fi
 518     DEFAULT_DEFAULT_wxUSE_GTK=1
 519   ;;
 520   *-*-irix5* | *-*-irix6* )
 521     USE_SGI=1
 522     USE_SVR4=1
 523     AC_DEFINE(__SGI__)
 524     AC_DEFINE(__SVR4__)
 525     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 526   ;;
 527   *-*-solaris2* )
 528     USE_SUN=1
 529     USE_SOLARIS=1
 530     USE_SVR4=1
 531     AC_DEFINE(__SUN__)
 532     AC_DEFINE(__SOLARIS__)
 533     AC_DEFINE(__SVR4__)
 534     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 535   ;;
 536   *-*-sunos4* )
 537     USE_SUN=1
 538     USE_SUNOS=1
 539     USE_BSD=1
 540     AC_DEFINE(__SUN__)
 541     AC_DEFINE(__SUNOS__)
 542     AC_DEFINE(__BSD__)
 543     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 544   ;;
 545   *-*-freebsd* | *-*-netbsd*)
 546     USE_BSD=1
 547     USE_FREEBSD=1
 548     AC_DEFINE(__FREEBSD__)
 549     AC_DEFINE(__BSD__)
 550     DEFAULT_DEFAULT_wxUSE_GTK=1
 551   ;;
 552   *-*-osf* )
 553     USE_ALPHA=1
 554     USE_OSF=1
 555     AC_DEFINE(__ALPHA__)
 556     AC_DEFINE(__OSF__)
 557     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 558   ;;
 559   *-*-dgux5* )
 560     USE_ALPHA=1
 561     USE_SVR4=1
 562     AC_DEFINE(__ALPHA__)
 563     AC_DEFINE(__SVR4__)
 564     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 565   ;;
 566   *-*-sysv5* )
 567     USE_SYSV=1
 568     USE_SVR4=1
 569     AC_DEFINE(__SYSV__)
 570     AC_DEFINE(__SVR4__)
 571     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 572   ;;
 573   *-*-aix* )
 574     USE_AIX=1
 575     USE_SYSV=1
 576     USE_SVR4=1
 577     AC_DEFINE(__AIX__)
 578     AC_DEFINE(__SYSV__)
 579     AC_DEFINE(__SVR4__)
 580     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 581   ;;
 582
 583   *-*-cygwin32* )
 584     USE_UNIX=0
 585     AC_DEFINE(__WIN32__)
 586     AC_DEFINE(__WIN95__)
 587     AC_DEFINE(__WINDOWS__)
 588     AC_DEFINE(__GNUWIN32__)
 589     AC_DEFINE(WINVER, 0x0400)
 590     DEFAULT_DEFAULT_wxUSE_MSW=1
 591   ;;
 592   *-*-mingw32* )
 593     USE_UNIX=0
 594     AC_DEFINE(__WIN32__)
 595     AC_DEFINE(__WIN95__)
 596     AC_DEFINE(__WINDOWS__)
 597     AC_DEFINE(__GNUWIN32__)
 598     AC_DEFINE(WINVER, 0x0400)
 599     DEFAULT_DEFAULT_wxUSE_MSW=1
 600   ;;
 601
 602   *-pc-os2_emx )
 603     AC_DEFINE(__EMX__)
 604   ;;
 605
 606   *)
 607     AC_MSG_ERROR(unknown system type ${host}.)
 608 esac
 609
 610 if test "$USE_UNIX" = 1 ; then
 611   wxUSE_UNIX=yes
 612   AC_DEFINE(__UNIX__)
 613   SRC_SUBDIRS="$SRC_SUBDIRS unix"
 614   INCLUDE_SUBDIRS="$INCLUDE_SUBDIRS unix"
 615 fi
 616
 617 dnl Linux: test for libc5/glibc2: glibc2 has gettext() included
 618 if test "$USE_LINUX" = 1; then
 619   AC_CHECK_LIB(c,gettext,AC_DEFINE(wxHAVE_GLIBC2))
 620 fi
 621
 622 dnl ---------------------------------------------------------------------------
 623 dnl command line options for configure
 624 dnl ---------------------------------------------------------------------------
 625
 626 dnl the default values for all options - we collect them all here to simplify
 627 dnl modification of the default values (for example, if the defaults for some
 628 dnl platform should be changed, it can be done here too)
 629 dnl
 630 dnl NB: see also DEFAULT_wxUSE<toolkit> variables defined above
 631
 632 WX_ARG_CACHE_INIT
 633
 634 dnl useful to test the compilation with minimum options, define as 0 for normal
 635 dnl usage
 636 DEBUG_CONFIGURE=0
 637 if test $DEBUG_CONFIGURE = 1; then
 638   DEFAULT_wxUSE_THREADS=yes
 639
 640   DEFAULT_wxUSE_SHARED=yes
 641   DEFAULT_wxUSE_OPTIMISE=yes
 642   DEFAULT_wxUSE_PROFILE=no
 643   DEFAULT_wxUSE_NO_RTTI=no
 644   DEFAULT_wxUSE_NO_EXCEPTIONS=no
 645   DEFAULT_wxUSE_DEBUG_FLAG=yes
 646   DEFAULT_wxUSE_DEBUG_INFO=yes
 647   DEFAULT_wxUSE_DEBUG_GDB=yes
 648   DEFAULT_wxUSE_MEM_TRACING=no
 649   DEFAULT_wxUSE_DEBUG_CONTEXT=no
 650   DEFAULT_wxUSE_DMALLOC=no
 651   DEFAULT_wxUSE_APPLE_IEEE=no
 652
 653   DEFAULT_wxUSE_LOG=yes
 654
 655   DEFAULT_wxUSE_GUI=yes
 656
 657   DEFAULT_wxUSE_ZLIB=no
 658   DEFAULT_wxUSE_LIBPNG=no
 659   DEFAULT_wxUSE_LIBGIF=no
 660   DEFAULT_wxUSE_LIBJPEG=no
 661   DEFAULT_wxUSE_ODBC=no
 662
 663   DEFAULT_wxUSE_STD_IOSTREAM=no
 664   DEFAULT_wxUSE_FILE=no
 665   DEFAULT_wxUSE_TEXTFILE=no
 666   DEFAULT_wxUSE_TIMEDATE=no
 667   DEFAULT_wxUSE_WAVE=no
 668   DEFAULT_wxUSE_INTL=no
 669   DEFAULT_wxUSE_CONFIG=no
 670   DEFAULT_wxUSE_STREAMS=no
 671   DEFAULT_wxUSE_SOCKETS=no
 672   DEFAULT_wxUSE_SERIAL=no
 673   DEFAULT_wxUSE_JOYSTICK=no
 674   DEFAULT_wxUSE_DYNLIB_CLASS=no
 675   DEFAULT_wxUSE_LONGLONG=no
 676
 677   DEFAULT_wxUSE_AFM_FOR_POSTSCRIPT=no
 678   DEFAULT_wxUSE_NORMALIZED_PS_FONTS=no
 679   DEFAULT_wxUSE_POSTSCRIPT=no
 680
 681   DEFAULT_wxUSE_X_RESOURCES=no
 682   DEFAULT_wxUSE_CLIPBOARD=no
 683   DEFAULT_wxUSE_TOOLTIPS=no
 684   DEFAULT_wxUSE_DRAG_AND_DROP=no
 685   DEFAULT_wxUSE_SPLINES=no
 686
 687   DEFAULT_wxUSE_MDI_ARCHITECTURE=no
 688   DEFAULT_wxUSE_DOC_VIEW_ARCHITECTURE=no
 689   DEFAULT_wxUSE_PRINTING_ARCHITECTURE=no
 690
 691   DEFAULT_wxUSE_PROLOGIO=no
 692   DEFAULT_wxUSE_RESOURCES=no
 693   DEFAULT_wxUSE_CONSTRAINTS=no
 694   DEFAULT_wxUSE_IPC=no
 695   DEFAULT_wxUSE_HELP=no
 696   DEFAULT_wxUSE_WXTREE=no
 697   DEFAULT_wxUSE_METAFILE=no
 698
 699   DEFAULT_wxUSE_COMMONDLGS=no
 700   DEFAULT_wxUSE_DIRDLG=no
 701   DEFAULT_wxUSE_TEXTDLG=no
 702   DEFAULT_wxUSE_STARTUP_TIPS=no
 703   DEFAULT_wxUSE_PROGRESSDLG=no
 704   DEFAULT_wxUSE_MINIFRAME=no
 705   DEFAULT_wxUSE_HTML=no
 706   DEFAULT_wxUSE_FS_INET=no
 707   DEFAULT_wxUSE_FS_ZIP=no
 708   DEFAULT_wxUSE_BUSYINFO=no
 709   DEFAULT_wxUSE_ZIPSTREAM=no
 710   DEFAULT_wxUSE_VALIDATORS=yes
 711
 712   DEFAULT_wxUSE_ACCEL=no
 713   DEFAULT_wxUSE_CARET=no
 714   DEFAULT_wxUSE_BMPBUTTON=no
 715   DEFAULT_wxUSE_CHECKBOX=no
 716   DEFAULT_wxUSE_CHECKLST=no
 717   DEFAULT_wxUSE_CHOICE=yes
 718   DEFAULT_wxUSE_COMBOBOX=no
 719   DEFAULT_wxUSE_GAUGE=no
 720   DEFAULT_wxUSE_GRID=no
 721   DEFAULT_wxUSE_IMAGLIST=no
 722   DEFAULT_wxUSE_LISTBOX=no
 723   DEFAULT_wxUSE_LISTCTRL=no
 724   DEFAULT_wxUSE_NOTEBOOK=no
 725   DEFAULT_wxUSE_RADIOBOX=no
 726   DEFAULT_wxUSE_RADIOBTN=no
 727   DEFAULT_wxUSE_SASH=no
 728   DEFAULT_wxUSE_SCROLLBAR=no
 729   DEFAULT_wxUSE_SLIDER=no
 730   DEFAULT_wxUSE_SPINBTN=no
 731   DEFAULT_wxUSE_SPLITTER=no
 732   DEFAULT_wxUSE_STATBMP=no
 733   DEFAULT_wxUSE_STATBOX=no
 734   DEFAULT_wxUSE_STATLINE=no
 735   DEFAULT_wxUSE_STATUSBAR=yes
 736   DEFAULT_wxUSE_TABDIALOG=no
 737   DEFAULT_wxUSE_TOOLBAR=no
 738   DEFAULT_wxUSE_TREECTRL=no
 739
 740   DEFAULT_wxUSE_UNICODE=no
 741   DEFAULT_wxUSE_WCSRTOMBS=no
 742 else
 743   DEFAULT_wxUSE_THREADS=yes
 744
 745   DEFAULT_wxUSE_SHARED=yes
 746   DEFAULT_wxUSE_OPTIMISE=yes
 747   DEFAULT_wxUSE_PROFILE=no
 748   DEFAULT_wxUSE_NO_RTTI=no
 749   DEFAULT_wxUSE_NO_EXCEPTIONS=no
 750   DEFAULT_wxUSE_DEBUG_FLAG=no
 751   DEFAULT_wxUSE_DEBUG_INFO=no
 752   DEFAULT_wxUSE_DEBUG_GDB=no
 753   DEFAULT_wxUSE_MEM_TRACING=no
 754   DEFAULT_wxUSE_DEBUG_CONTEXT=no
 755   DEFAULT_wxUSE_DMALLOC=no
 756   DEFAULT_wxUSE_APPLE_IEEE=yes
 757
 758   DEFAULT_wxUSE_LOG=yes
 759
 760   DEFAULT_wxUSE_GUI=yes
 761
 762   DEFAULT_wxUSE_ZLIB=yes
 763   DEFAULT_wxUSE_LIBPNG=yes
 764   DEFAULT_wxUSE_LIBGIF=yes
 765   DEFAULT_wxUSE_LIBJPEG=yes
 766   DEFAULT_wxUSE_ODBC=no
 767
 768   DEFAULT_wxUSE_STD_IOSTREAM=no
 769   DEFAULT_wxUSE_FILE=yes
 770   DEFAULT_wxUSE_TEXTFILE=yes
 771   DEFAULT_wxUSE_TIMEDATE=yes
 772   DEFAULT_wxUSE_WAVE=no
 773   DEFAULT_wxUSE_INTL=yes
 774   DEFAULT_wxUSE_CONFIG=yes
 775   DEFAULT_wxUSE_STREAMS=yes
 776   DEFAULT_wxUSE_SOCKETS=yes
 777   DEFAULT_wxUSE_SERIAL=yes
 778   DEFAULT_wxUSE_JOYSTICK=yes
 779   DEFAULT_wxUSE_DYNLIB_CLASS=yes
 780   DEFAULT_wxUSE_LONGLONG=no
 781
 782   DEFAULT_wxUSE_AFM_FOR_POSTSCRIPT=yes
 783   DEFAULT_wxUSE_NORMALIZED_PS_FONTS=yes
 784   DEFAULT_wxUSE_POSTSCRIPT=yes
 785
 786   DEFAULT_wxUSE_X_RESOURCES=no
 787   DEFAULT_wxUSE_CLIPBOARD=yes
 788   DEFAULT_wxUSE_TOOLTIPS=yes
 789   DEFAULT_wxUSE_DRAG_AND_DROP=yes
 790   DEFAULT_wxUSE_SPLINES=yes
 791
 792   DEFAULT_wxUSE_MDI_ARCHITECTURE=yes
 793   DEFAULT_wxUSE_DOC_VIEW_ARCHITECTURE=yes
 794   DEFAULT_wxUSE_PRINTING_ARCHITECTURE=yes
 795
 796   DEFAULT_wxUSE_PROLOGIO=yes
 797   DEFAULT_wxUSE_RESOURCES=yes
 798   DEFAULT_wxUSE_CONSTRAINTS=yes
 799   DEFAULT_wxUSE_IPC=yes
 800   DEFAULT_wxUSE_HELP=yes
 801   DEFAULT_wxUSE_WXTREE=yes
 802   DEFAULT_wxUSE_METAFILE=yes
 803
 804   DEFAULT_wxUSE_COMMONDLGS=yes
 805   DEFAULT_wxUSE_DIRDLG=yes
 806   DEFAULT_wxUSE_TEXTDLG=yes
 807   DEFAULT_wxUSE_STARTUP_TIPS=yes
 808   DEFAULT_wxUSE_PROGRESSDLG=yes
 809   DEFAULT_wxUSE_MINIFRAME=yes
 810   DEFAULT_wxUSE_HTML=yes
 811   DEFAULT_wxUSE_FS_INET=yes
 812   DEFAULT_wxUSE_FS_ZIP=yes
 813   DEFAULT_wxUSE_BUSYINFO=yes
 814   DEFAULT_wxUSE_ZIPSTREAM=yes
 815   DEFAULT_wxUSE_VALIDATORS=yes
 816
 817   DEFAULT_wxUSE_ACCEL=yes
 818   DEFAULT_wxUSE_CARET=yes
 819   DEFAULT_wxUSE_BMPBUTTON=yes
 820   DEFAULT_wxUSE_CHECKBOX=yes
 821   DEFAULT_wxUSE_CHECKLST=yes
 822   DEFAULT_wxUSE_CHOICE=yes
 823   DEFAULT_wxUSE_COMBOBOX=yes
 824   DEFAULT_wxUSE_GAUGE=yes
 825   DEFAULT_wxUSE_GRID=yes
 826   DEFAULT_wxUSE_IMAGLIST=yes
 827   DEFAULT_wxUSE_LISTBOX=yes
 828   DEFAULT_wxUSE_LISTCTRL=yes
 829   DEFAULT_wxUSE_NOTEBOOK=yes
 830   DEFAULT_wxUSE_RADIOBOX=yes
 831   DEFAULT_wxUSE_RADIOBTN=yes
 832   DEFAULT_wxUSE_SASH=yes
 833   DEFAULT_wxUSE_SCROLLBAR=yes
 834   DEFAULT_wxUSE_SLIDER=yes
 835   DEFAULT_wxUSE_SPINBTN=yes
 836   DEFAULT_wxUSE_SPLITTER=yes
 837   DEFAULT_wxUSE_STATBMP=yes
 838   DEFAULT_wxUSE_STATBOX=yes
 839   DEFAULT_wxUSE_STATLINE=yes
 840   DEFAULT_wxUSE_STATUSBAR=yes
 841   DEFAULT_wxUSE_TABDIALOG=no
 842   DEFAULT_wxUSE_TOOLBAR=yes
 843   DEFAULT_wxUSE_TREECTRL=yes
 844
 845   DEFAULT_wxUSE_UNICODE=no
 846   DEFAULT_wxUSE_WCSRTOMBS=no
 847 fi
 848
 849 dnl WX_ARG_WITH should be used to select whether an external package will be
 850 dnl used or not, to configure compile-time features of this package itself,
 851 dnl use WX_ARG_ENABLE instead
 852
 853 dnl ============================
 854 dnl external package dependecies
 855 dnl ============================
 856
 857 dnl these options use AC_ARG_WITH and not WX_ARG_WITH on purpose - we cache
 858 dnl these values manually
 859 for toolkit in `echo $ALL_TOOLKITS`; do
 860   LINE=`grep "wxUSE_$toolkit" ${wx_arg_cache_file}`
 861   if test "x$LINE" != x ; then
 862     has_toolkit_in_cache=1
 863     eval "DEFAULT_$LINE"
 864     eval "CACHE_$toolkit=1"
 865   fi
 866 done
 867
 868 AC_ARG_WITH(gtk,           [  --with-gtk              use GTK+], [wxUSE_GTK="$withval" CACHE_GTK=1 TOOLKIT_GIVEN=1])
 869 AC_ARG_WITH(motif,         [  --with-motif            use Motif/Lesstif], [wxUSE_MOTIF="$withval" CACHE_MOTIF=1 TOOLKIT_GIVEN=1])
 870 AC_ARG_WITH(wine,          [  --with-wine             use WINE], [wxUSE_WINE="$withval" CACHE_WINE=1 TOOLKIT_GIVEN=1])
 871 AC_ARG_WITH(cygwin,        [  --with-cygwin           use Cygwin for MS-Windows], [wxUSE_CYGWIN="$withval" CACHE_CYGWIN=1 TOOLKIT_GIVEN=1])
 872 AC_ARG_WITH(mingw,         [  --with-mingw            use GCC Minimal MS-Windows], [wxUSE_MINGW="$withval" CACHE_MINGW=1 TOOLKIT_GIVEN=1])
 873
 874 AC_ARG_WITH(gtk-prefix,    [  --with-gtk-prefix=PFX   Prefix where GTK is installed],
 875             gtk_config_prefix="$withval", gtk_config_prefix="")
 876 AC_ARG_WITH(gtk-exec-prefix, [  --with-gtk-exec-prefix=PFX  Exec prefix where GTK is installed],
 877             gtk_config_exec_prefix="$withval", gtk_config_exec_prefix="")
 878
 879 WX_ARG_WITH(dmalloc,       [  --with-dmalloc          use dmalloc library (www.letters.com/dmalloc)], wxUSE_DMALLOC)
 880 WX_ARG_WITH(zlib,          [  --with-zlib             use zlib for LZW compression], wxUSE_ZLIB)
 881 WX_ARG_WITH(libpng,        [  --with-libpng           use libpng (PNG image format)], wxUSE_LIBPNG)
 882 WX_ARG_WITH(libgif,        [  --with-libgif           use libgif (GIF file format)], wxUSE_LIBGIF)
 883 WX_ARG_WITH(libjpeg,       [  --with-libjpeg          use libjpeg (JPEG file format)], wxUSE_LIBJPEG)
 884 WX_ARG_WITH(opengl,        [  --with-opengl           use OpenGL (or Mesa)], wxUSE_OPENGL)
 885 WX_ARG_WITH(odbc,          [  --with-odbc             use the IODBC and wxODBC classes], wxUSE_ODBC)
 886
 887 dnl ====================
 888 dnl compile-time options
 889 dnl ====================
 890
 891 dnl ---------------------------------------------------------------------------
 892 dnl compile options
 893 dnl ---------------------------------------------------------------------------
 894
 895 WX_ARG_ENABLE(shared,      [  --enable-shared         create shared library code], wxUSE_SHARED)
 896 WX_ARG_ENABLE(optimise,    [  --enable-optimise       create optimised code], wxUSE_OPTIMISE)
 897 WX_ARG_ENABLE(debug,       [  --enable-debug          same as debug_flag and debug_info], wxUSE_DEBUG)
 898
 899 if test "$wxUSE_DEBUG" = "yes"; then
 900   DEFAULT_wxUSE_DEBUG_FLAG=yes
 901   DEFAULT_wxUSE_DEBUG_INFO=yes
 902 elif test "$wxUSE_DEBUG" = "no"; then
 903   DEFAULT_wxUSE_DEBUG_FLAG=no
 904   DEFAULT_wxUSE_DEBUG_INFO=no
 905 fi
 906
 907 WX_ARG_ENABLE(debug_flag,    [  --enable-debug_flag     set __WXDEBUG__ flag (recommended for developers!)], wxUSE_DEBUG_FLAG)
 908 WX_ARG_ENABLE(debug_info,    [  --enable-debug_info     create code with debugging information], wxUSE_DEBUG_INFO)
 909 WX_ARG_ENABLE(debug_gdb,     [  --enable-debug_gdb      create code with extra GDB debugging information], wxUSE_DEBUG_GDB)
 910 WX_ARG_ENABLE(debug_cntxt,   [  --enable-debug_cntxt    use wxDebugContext], wxUSE_DEBUG_CONTEXT)
 911 WX_ARG_ENABLE(mem_tracing,   [  --enable-mem_tracing    create code with memory tracing], wxUSE_MEM_TRACING)
 912 WX_ARG_ENABLE(profile,       [  --enable-profile        create code with profiling information], wxUSE_PROFILE)
 913 WX_ARG_ENABLE(no_rtti,       [  --enable-no_rtti        create code without RTTI information], wxUSE_NO_RTTI)
 914 WX_ARG_ENABLE(no_exceptions, [  --enable-no_exceptions  create code without exceptions information], wxUSE_NO_EXCEPTIONS)
 915
 916 dnl ---------------------------------------------------------------------------
 917 dnl --disable-gui will build only non-GUI part of wxWindows
 918 dnl
 919 dnl NB: this is still in testing stage, don't use if you don't know what you're
 920 dnl     doing
 921 dnl ---------------------------------------------------------------------------
 922
 923 WX_ARG_ENABLE(gui,         [  --enable-gui            use GUI classes], wxUSE_GUI)
 924
 925 dnl ---------------------------------------------------------------------------
 926 dnl (small) optional non GUI classes
 927 dnl ---------------------------------------------------------------------------
 928
 929 WX_ARG_ENABLE(intl,          [  --enable-intl           use internationalization system], wxUSE_INTL)
 930 WX_ARG_ENABLE(config,        [  --enable-config         use wxConfig (and derived) classes], wxUSE_CONFIG)
 931 WX_ARG_ENABLE(sockets,       [  --enable-sockets        use socket/network classes], wxUSE_SOCKETS)
 932 WX_ARG_ENABLE(ipc,           [  --enable-ipc            use interprocess communication (wxSocket etc.)], wxUSE_IPC)
 933 WX_ARG_ENABLE(apple_ieee,    [  --enable-apple_ieee     use the Apple IEEE codec], wxUSE_APPLE_IEEE)
 934 WX_ARG_ENABLE(timedate,      [  --enable-timedate       use date/time classes], wxUSE_TIMEDATE)
 935 WX_ARG_ENABLE(wave,          [  --enable-wave           use wxWave class], wxUSE_WAVE)
 936 WX_ARG_ENABLE(fraction,      [  --enable-fraction       use wxFraction class], wxUSE_FRACTION)
 937 WX_ARG_ENABLE(dynlib,        [  --enable-dynlib         use wxLibrary class for DLL loading], wxUSE_DYNLIB_CLASS)
 938 WX_ARG_ENABLE(longlong,      [  --enable-longlong       use wxLongLong class], wxUSE_LONGLONG)
 939 WX_ARG_ENABLE(log,           [  --enable-log            use logging system], wxUSE_LOG)
 940 WX_ARG_ENABLE(streams,       [  --enable-streams        use wxStream etc classes], wxUSE_STREAMS)
 941 WX_ARG_ENABLE(file,          [  --enable-file           use wxFile classes], wxUSE_FILE)
 942 WX_ARG_ENABLE(textfile,      [  --enable-textfile       use wxTextFile classes], wxUSE_TEXTFILE)
 943 WX_ARG_ENABLE(unicode,       [  --enable-unicode        compile wxString with Unicode support], wxUSE_UNICODE)
 944 WX_ARG_ENABLE(wcsrtombs,     [  --enable-wcsrtombs      use wcsrtombs instead of buggy (GNU libc1/Linux libc5) wcstombs], wxUSE_WCSRTOMBS)
 945 WX_ARG_ENABLE(wxprintfv,     [  --enable-wxprintfv      use wxWindows implementation of vprintf()], wxUSE_EXPERIMENTAL_PRINTF)
 946 WX_ARG_ENABLE(joystick,      [  --enable-joystick       compile in joystick support (Linux only)], wxUSE_JOYSTICK)
 947 WX_ARG_ENABLE(std_iostreams, [  --enable-std_iostreams  use standard C++ stream classes], wxUSE_STD_IOSTREAM)
 948 WX_ARG_ENABLE(fs_inet,       [  --enable-fs_inet        use virtual HTTP/FTP filesystems], wxUSE_FS_INET)
 949 WX_ARG_ENABLE(fs_zip,        [  --enable-fs_zip         use virtual ZIP filesystems], wxUSE_FS_ZIP)
 950 WX_ARG_ENABLE(zipstream,     [  --enable-zipstream      use wxZipInputStream], wxUSE_ZIPSTREAM)
 951
 952 dnl ---------------------------------------------------------------------------
 953 dnl "big" options (i.e. those which change a lot of things throughout the library)
 954 dnl ---------------------------------------------------------------------------
 955
 956 WX_ARG_ENABLE(threads,     [  --enable-threads        use threads], wxUSE_THREADS)
 957 WX_ARG_ENABLE(serial,      [  --enable-serial         use class serialization], wxUSE_SERIAL)
 958
 959 dnl ---------------------------------------------------------------------------
 960 dnl "big" GUI options
 961 dnl ---------------------------------------------------------------------------
 962
 963 WX_ARG_ENABLE(docview,     [  --enable-docview        use document view architecture], wxUSE_DOC_VIEW_ARCHITECTURE)
 964 WX_ARG_ENABLE(help,        [  --enable-help           use help (using external browser at present)], wxUSE_HELP)
 965 WX_ARG_ENABLE(constraints, [  --enable-constraints    use layout-constraints system], wxUSE_CONSTRAINTS)
 966 WX_ARG_ENABLE(printarch,   [  --enable-printarch      use printing architecture], wxUSE_PRINTING_ARCHITECTURE)
 967 WX_ARG_ENABLE(mdi,         [  --enable-mdi            use multiple document interface architecture], wxUSE_MDI_ARCHITECTURE)
 968
 969 dnl ---------------------------------------------------------------------------
 970 dnl PostScript options
 971 dnl ---------------------------------------------------------------------------
 972 WX_ARG_ENABLE(postscript,  [  --enable-postscript     use wxPostscriptDC device context (default for gtk+)], wxUSE_POSTSCRIPT)
 973
 974 dnl VZ: these options seem to be always on, if someone wants to change it please do
 975 dnl WX_ARG_ENABLE(PS-normalized,    [  --enable-PS-normalized  use normalized PS fonts], dnl             wxUSE_NORMALIZED_PS_FONTS)
 976 dnl WX_ARG_ENABLE(afmfonts,        [  --enable-afmfonts       use Adobe Font Metric Font table], dnl             wxUSE_AFM_FOR_POSTSCRIPT)
 977
 978 dnl ---------------------------------------------------------------------------
 979 dnl resources
 980 dnl ---------------------------------------------------------------------------
 981 WX_ARG_ENABLE(prologio,    [  --enable-prologio       use Prolog IO library], wxUSE_PROLOGIO)
 982 WX_ARG_ENABLE(resources,   [  --enable-resources      use wxWindows resources], wxUSE_RESOURCES)
 983
 984 WX_ARG_ENABLE(xresources,  [  --enable-xresources     use X resources for save (default for gtk+)], wxUSE_X_RESOURCES)
 985
 986 dnl ---------------------------------------------------------------------------
 987 dnl IPC &c
 988 dnl ---------------------------------------------------------------------------
 989
 990 WX_ARG_ENABLE(clipboard,   [  --enable-clipboard      use wxClipboard classes], wxUSE_CLIPBOARD)
 991 WX_ARG_ENABLE(dnd,         [  --enable-dnd            use Drag'n'Drop classes], wxUSE_DRAG_AND_DROP)
 992
 993 dnl TODO: doesn't work yet
 994 WX_ARG_ENABLE(wxtree,      [  --enable-wxtree         make wxTree library], wxUSE_WXTREE)
 995
 996 dnl ---------------------------------------------------------------------------
 997 dnl optional GUI controls (in alphabetical order except the first one)
 998 dnl ---------------------------------------------------------------------------
 999
1000 WX_ARG_ENABLE(controls,    [  --enable-controls       use all usual controls], wxUSE_CONTROLS)
1001
1002 dnl even with --enable-controls, some may be disabled by giving
1003 dnl --disable-<control> later on the command line - but by default all will be
1004 dnl used (and vice versa)
1005 if test "$wxUSE_CONTROLS" = "yes"; then
1006   DEFAULT_wxUSE_ACCEL=yes
1007   DEFAULT_wxUSE_CARET=yes
1008   DEFAULT_wxUSE_COMBOBOX=yes
1009   DEFAULT_wxUSE_BMPBUTTON=yes
1010   DEFAULT_wxUSE_CHECKBOX=yes
1011   DEFAULT_wxUSE_CHECKLISTBOX=yes
1012   DEFAULT_wxUSE_CHOICE=yes
1013   DEFAULT_wxUSE_GAUGE=yes
1014   DEFAULT_wxUSE_GRID=yes
1015   DEFAULT_wxUSE_IMAGLIST=yes
1016   DEFAULT_wxUSE_LISTBOX=yes
1017   DEFAULT_wxUSE_LISTCTRL=yes
1018   DEFAULT_wxUSE_NOTEBOOK=yes
1019   DEFAULT_wxUSE_RADIOBOX=yes
1020   DEFAULT_wxUSE_RADIOBTN=yes
1021   DEFAULT_wxUSE_SASH=yes
1022   DEFAULT_wxUSE_SCROLLBAR=yes
1023   DEFAULT_wxUSE_SLIDER=yes
1024   DEFAULT_wxUSE_SPINBTN=yes
1025   DEFAULT_wxUSE_SPLITTER=yes
1026   DEFAULT_wxUSE_STATBMP=yes
1027   DEFAULT_wxUSE_STATBOX=yes
1028   DEFAULT_wxUSE_STATLINE=yes
1029   DEFAULT_wxUSE_STATUSBAR=yes
1030   DEFAULT_wxUSE_TAB_DIALOG=yes
1031   DEFAULT_wxUSE_TOOLBAR=yes
1032   DEFAULT_wxUSE_TOOLTIPS=yes
1033   DEFAULT_wxUSE_TREECTRL=yes
1034 elif test "$wxUSE_CONTROLS" = "no"; then
1035   DEFAULT_wxUSE_ACCEL=no
1036   DEFAULT_wxUSE_CARET=no
1037   DEFAULT_wxUSE_COMBOBOX=no
1038   DEFAULT_wxUSE_BMPBUTTON=no
1039   DEFAULT_wxUSE_CHECKBOX=no
1040   DEFAULT_wxUSE_CHECKLISTBOX=no
1041   DEFAULT_wxUSE_CHOICE=no
1042   DEFAULT_wxUSE_GAUGE=no
1043   DEFAULT_wxUSE_GRID=no
1044   DEFAULT_wxUSE_IMAGLIST=no
1045   DEFAULT_wxUSE_LISTBOX=no
1046   DEFAULT_wxUSE_LISTCTRL=no
1047   DEFAULT_wxUSE_NOTEBOOK=no
1048   DEFAULT_wxUSE_RADIOBOX=no
1049   DEFAULT_wxUSE_RADIOBTN=no
1050   DEFAULT_wxUSE_SASH=no
1051   DEFAULT_wxUSE_SCROLLBAR=no
1052   DEFAULT_wxUSE_SLIDER=no
1053   DEFAULT_wxUSE_SPINBTN=no
1054   DEFAULT_wxUSE_SPLITTER=no
1055   DEFAULT_wxUSE_STATBMP=no
1056   DEFAULT_wxUSE_STATBOX=no
1057   DEFAULT_wxUSE_STATLINE=no
1058   DEFAULT_wxUSE_STATUSBAR=no
1059   DEFAULT_wxUSE_TAB_DIALOG=no
1060   DEFAULT_wxUSE_TOOLBAR=no
1061   DEFAULT_wxUSE_TOOLTIPS=no
1062   DEFAULT_wxUSE_TREECTRL=no
1063 fi
1064
1065 WX_ARG_ENABLE(accel,       [  --enable-accel          use accelerators], wxUSE_ACCEL)
1066 WX_ARG_ENABLE(caret,       [  --enable-caret          use wxCaret class], wxUSE_CARET)
1067 WX_ARG_ENABLE(bmpbutton,   [  --enable-bmpbutton      use wxBitmapButton class], wxUSE_BMPBUTTON)
1068 WX_ARG_ENABLE(checkbox,    [  --enable-checkbox       use wxCheckBox class], wxUSE_CHECKBOX)
1069 WX_ARG_ENABLE(checklst,    [  --enable-checklst       use wxCheckListBox (listbox with checkboxes) class], wxUSE_CHECKLST)
1070 WX_ARG_ENABLE(choice,      [  --enable-choice         use wxChoice class], wxUSE_CHOICE)
1071 WX_ARG_ENABLE(combobox,    [  --enable-combobox       use wxComboBox classes], wxUSE_COMBOBOX)
1072 WX_ARG_ENABLE(gauge,       [  --enable-gauge          use wxGauge class], wxUSE_GAUGE)
1073 WX_ARG_ENABLE(grid,        [  --enable-grid           use wxGrid class], wxUSE_GRID)
1074 WX_ARG_ENABLE(imaglist,    [  --enable-imaglist       use wxImageList class], wxUSE_IMAGLIST)
1075 WX_ARG_ENABLE(listbox,     [  --enable-listbox        use wxListBox class], wxUSE_LISTBOX)
1076 WX_ARG_ENABLE(listctrl,    [  --enable-listctrl       use wxListCtrl class], wxUSE_LISTCTRL)
1077 WX_ARG_ENABLE(notebook,    [  --enable-notebook       use wxNotebook class], wxUSE_NOTEBOOK)
1078 WX_ARG_ENABLE(radiobox,    [  --enable-radiobox       use wxRadioBox class], wxUSE_RADIOBOX)
1079 WX_ARG_ENABLE(radiobtn,    [  --enable-radiobtn       use wxRadioButton class], wxUSE_RADIOBTN)
1080 WX_ARG_ENABLE(sash,        [  --enable-sash           use wxSashWindow class], wxUSE_SASH)
1081 WX_ARG_ENABLE(scrollbar,   [  --enable-scrollbar      use wxScrollBar class and scrollable windows], wxUSE_SCROLLBAR)
1082 WX_ARG_ENABLE(slider,      [  --enable-slider         use wxSlider class], wxUSE_SLIDER)
1083 WX_ARG_ENABLE(spinbtn,     [  --enable-spinbtn        use wxSpinButton class], wxUSE_SPINBTN)
1084 WX_ARG_ENABLE(splitter,    [  --enable-splitter       use wxSplitterWindow class], wxUSE_SPLITTER)
1085 WX_ARG_ENABLE(statbmp,     [  --enable-statbmp        use wxStaticBitmap class], wxUSE_STATBMP)
1086 WX_ARG_ENABLE(statbox,     [  --enable-statbox        use wxStaticBox class], wxUSE_STATBOX)
1087 WX_ARG_ENABLE(statline,    [  --enable-statline       use wxStaticLine class], wxUSE_STATLINE)
1088 WX_ARG_ENABLE(statusbar,   [  --enable-statusbar      use wxStatusBar class], wxUSE_STATUSBAR)
1089 WX_ARG_ENABLE(tabdialog,   [  --enable-tabdialog      use wxTabControl class], wxUSE_TABDIALOG)
1090 WX_ARG_ENABLE(toolbar,     [  --enable-toolbar        use wxToolBar class], wxUSE_TOOLBAR)
1091 WX_ARG_ENABLE(treectrl,    [  --enable-treectrl       use wxTreeCtrl class], wxUSE_TREECTRL)
1092
1093 dnl ---------------------------------------------------------------------------
1094 dnl misc GUI options
1095 dnl ---------------------------------------------------------------------------
1096
1097 WX_ARG_ENABLE(commondlg,   [  --enable-commondlg      use common dialogs (wxDirDialog, wxProgressDialog, wxTextDialog, ...)], wxUSE_COMMONDLGS)
1098 WX_ARG_ENABLE(dirdlg,      [  --enable-dirdlg         use wxDirDialog], wxUSE_DIRDLG)
1099 WX_ARG_ENABLE(textdlg,     [  --enable-textdlg        use wxTextDialog], wxUSE_TEXTDLG)
1100 WX_ARG_ENABLE(tipdlg,      [  --enable-tipdlg         use startup tips], wxUSE_STARTUP_TIPS)
1101 WX_ARG_ENABLE(progressdlg, [  --enable-progressdlg    use wxProgressDialog], wxUSE_PROGRESSDLG)
1102 WX_ARG_ENABLE(miniframe,   [  --enable-miniframe      use wxMiniFrame class], wxUSE_MINIFRAME)
1103 WX_ARG_ENABLE(html,        [  --enable-html           use wxHTML sub-library], wxUSE_HTML)
1104 WX_ARG_ENABLE(tooltips,    [  --enable-tooltips       use wxToolTip class], wxUSE_TOOLTIPS)
1105 WX_ARG_ENABLE(splines,     [  --enable-splines        use spline drawing code], wxUSE_SPLINES)
1106 WX_ARG_ENABLE(validators,  [  --enable-validators     use wxValidator and derived classes], wxUSE_VALIDATORS)
1107 WX_ARG_ENABLE(busyinfo,    [  --enable-busyinfo       use wxBusyInfo], wxUSE_BUSYINFO)
1108
1109 dnl cache the options values before (may be) aborting below
1110 WX_ARG_CACHE_FLUSH
1111
1112 dnl check that no more than one toolkit is given and that if none are given that
1113 dnl we have a default one
1114
1115 AC_MSG_CHECKING(for toolkit)
1116
1117 if test "$TOOLKIT_GIVEN" = 1; then
1118   dnl convert "yes" to 1 and "no" to 0
1119   for toolkit in `echo $ALL_TOOLKITS`; do
1120     var=wxUSE_$toolkit
1121     eval "value=\$${var}"
1122     eval "$var=`echo \$value | sed -e "s/yes/1/" -e "s/no/0/"`"
1123   done
1124 else
1125   dnl try to guess the most apropriate toolkit for this platform
1126   for toolkit in `echo $ALL_TOOLKITS`; do
1127     if test "$has_toolkit_in_cache" != 1; then
1128       var=DEFAULT_DEFAULT_wxUSE_$toolkit
1129     else
1130       var=DEFAULT_wxUSE_$toolkit
1131     fi
1132     eval "wxUSE_$toolkit=\$${var}"
1133   done
1134 fi
1135
1136 dnl we suppose that expr exists...
1137 NUM_TOOLKITS=`expr ${wxUSE_GTK:-0} + ${wxUSE_MOTIF:-0} + ${wxUSE_WINE:-0} + ${wxUSE_MINGW:-0} + ${wxUSE_CYGWIN:-0}`
1138
1139 case "$NUM_TOOLKITS" in
1140   1)
1141   ;;
1142   0)
1143     AC_MSG_ERROR(Please specify a toolkit - cannot determine the default for ${host})
1144   ;;
1145   *)
1146     AC_MSG_ERROR(Please specify at most one toolkit (may be some are cached?))
1147 esac
1148
1149 dnl cache the wxUSE_<TOOLKIT> values too
1150 for toolkit in `echo $ALL_TOOLKITS`; do
1151   var=wxUSE_$toolkit
1152   eval "value=\$${var}"
1153   if test "x$value" != x; then
1154     cache_var=CACHE_$toolkit
1155     eval "cache=\$${cache_var}"
1156     if test "$cache" = 1; then
1157       echo "$var=$value" >> ${wx_arg_cache_file}
1158     fi
1159     if test "$value" = 1; then
1160       AC_MSG_RESULT(`echo $toolkit | tr [[A-Z]] [[a-z]]`)
1161     fi
1162   fi
1163 done
1164
1165 dnl ---------------------------------------------------------------------------
1166 dnl Checks for programs
1167 dnl ---------------------------------------------------------------------------
1168
1169 dnl flush the cache because checking for programs might abort
1170 AC_CACHE_SAVE
1171
1172 dnl cross-compiling support: we're cross compiling if the build system is
1173 dnl different from the target one (assume host and target be always the same)
1174 if eval "test $host != $build"; then
1175   if eval "test $host_alias != NONE"; then
1176     CC=$host_alias-gcc
1177     CXX=$host_alias-c++
1178     AR=$host_alias-ar
1179     RANLIB=$host_alias-ranlib
1180     DLLTOOL=$host_alias-dlltool
1181     LD=$host_alias-ld
1182     NM=$host_alias-nm
1183     STRIP=$host_alias-strip
1184   fi
1185 fi
1186
1187 dnl C-compiler checks
1188 dnl   defines CC with the compiler to use
1189 dnl   defines GCC with yes if using gcc
1190 dnl   defines GCC empty if not using gcc
1191 dnl   defines CFLAGS
1192 AC_PROG_CC
1193
1194 CFLAGS=`echo "$CFLAGS" | sed 's/-g//g'`
1195
1196 dnl what is the c-preprocessor
1197 dnl   defines CPP with the c-preprocessor
1198 AC_PROG_CPP
1199
1200 dnl is -traditional needed for correct compilations
1201 dnl   adds -traditional for gcc if needed
1202 AC_PROG_GCC_TRADITIONAL
1203
1204 AC_LANG_SAVE
1205 AC_LANG_CPLUSPLUS
1206
1207 dnl C++-compiler checks
1208 dnl   defines CXX with the compiler to use
1209 dnl   defines GXX with yes if using gxx
1210 dnl   defines GXX empty if not using gxx
1211 dnl   defines CXXFLAGS
1212 AC_PROG_CXX
1213
1214 dnl what is the C++-preprocessor
1215 dnl   defines CXXCPP with the C++-preprocessor
1216 AC_PROG_CXXCPP
1217
1218 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g//g'`
1219
1220 AC_LANG_RESTORE
1221
1222 dnl ranlib command
1223 dnl   defines RANLIB with the appropriate command
1224 AC_PROG_RANLIB
1225
1226 dnl ar command
1227 dnl   defines AR with the appropriate command
1228 AC_CHECK_PROG(AR, ar, ar, ar)
1229
1230 dnl install checks
1231 dnl   defines INSTALL with the appropriate command
1232 AC_PROG_INSTALL
1233
1234 dnl strip command
1235 dnl   defines STRIP as strip or nothing if not found
1236 AC_CHECK_PROG(STRIP, strip, strip, true)
1237
1238 dnl check if VPATH works
1239 AC_MSG_CHECKING("make for VPATH support")
1240 dnl create Makefile
1241 cat - << EOF > confMake
1242 check : file
1243         cp \$? \$@
1244         cp \$? final_file
1245 EOF
1246
1247 if test ! -d sub ; then
1248   mkdir sub
1249 fi
1250 echo dummy > sub/file
1251 ${MAKE-make} -f confMake VPATH=sub 2> config.log > /dev/null
1252 RESULT=$?
1253 rm -f sub/file check final_file confMake
1254 rmdir sub
1255 if test "$RESULT" = 0; then
1256   AC_MSG_RESULT(yes)
1257 else
1258   AC_MSG_RESULT(no)
1259   AC_MSG_ERROR(
1260 You need a make-utility that is able to use the variable
1261 VPATH correctly.
1262 If your version of make does not support VPATH correctly,
1263 please install GNU-make (possibly as gmake), and start
1264 configure with the following command:
1265 export MAKE=gmake; ./configure  for sh-type shells
1266 setenv MAKE gmake; ./configure  for csh-type shells
1267 Also please do remember to use gmake in this case every time
1268 you are trying to compile.
1269 )
1270 fi
1271
1272 dnl YACC checks
1273 dnl   defines YACC with the appropriate command
1274 AC_PROG_YACC
1275
1276 dnl LEX checks
1277 dnl   defines LEX with the appropriate command
1278 dnl   defines LEXLIB with the appropriate library
1279 AC_PROG_LEX
1280
1281 dnl needed for making link to setup.h
1282 AC_PROG_LN_S
1283
1284 dnl ---------------------------------------------------------------------------
1285 dnl Define search path for includes and libraries: all headers and libs will be
1286 dnl looked for in all directories of this path
1287 dnl ---------------------------------------------------------------------------
1288
1289 SEARCH_INCLUDE="\
1290     /usr/Motif-1.2/include    \
1291     /usr/Motif-2.1/include    \
1292                               \
1293     /usr/include/Motif1.2     \
1294     /opt/xpm/include/X11      \
1295                               \
1296     /usr/Motif1.2/include     \
1297     /usr/dt/include           \
1298     /usr/include/Xm           \
1299                               \
1300     /usr/X11R6/include        \
1301     /usr/X11R5/include        \
1302     /usr/X11R4/include        \
1303                               \
1304     /usr/X11R6/lib            \
1305     /usr/X11R5/lib            \
1306     /usr/X11R4/lib            \
1307                               \
1308     /usr/include/X11R6        \
1309     /usr/include/X11R5        \
1310     /usr/include/X11R4        \
1311                               \
1312     /usr/local/X11R6/include  \
1313     /usr/local/X11R5/include  \
1314     /usr/local/X11R4/include  \
1315                               \
1316     /usr/local/include/X11R6  \
1317     /usr/local/include/X11R5  \
1318     /usr/local/include/X11R4  \
1319                               \
1320     /usr/X11/include          \
1321     /usr/include/X11          \
1322     /usr/local/X11/include    \
1323     /usr/local/include/X11    \
1324                               \
1325     /usr/X386/include         \
1326     /usr/x386/include         \
1327     /usr/XFree86/include/X11  \
1328                               \
1329     /usr/include              \
1330     /usr/local/include        \
1331                               \
1332     /usr/include/gtk          \
1333     /usr/local/include/gtk    \
1334     /usr/include/glib         \
1335     /usr/local/include/glib   \
1336                               \
1337     /usr/include/qt           \
1338     /usr/local/include/qt     \
1339                               \
1340     /usr/include/windows      \
1341     /usr/include/wine         \
1342     /usr/local/include/wine   \
1343                               \
1344     /usr/unsupported/include  \
1345     /usr/athena/include       \
1346     /usr/local/x11r5/include  \
1347     /usr/lpp/Xamples/include  \
1348                               \
1349     /usr/openwin/include      \
1350     /usr/openwin/share/include \
1351     "
1352
1353 SEARCH_LIB="`echo "$SEARCH_INCLUDE" | sed s/include/lib/g` "
1354
1355 dnl ------------------------------------------------------------------------
1356 dnl Check for libraries
1357 dnl ------------------------------------------------------------------------
1358
1359 dnl flush the cache because checking for libraries below might abort
1360 AC_CACHE_SAVE
1361
1362 dnl ----------------------------------------------------------------
1363 dnl search for toolkit (widget sets)
1364 dnl ----------------------------------------------------------------
1365
1366 TOOLKIT=
1367 TOOLKIT_INCLUDE=
1368
1369 GUIOBJS=
1370 COMMONOBJS=
1371 GENERICOBJS=
1372
1373 GUI_TK_LIBRARY=
1374 GUI_TK_LINK=
1375
1376 WXGTK12=
1377
1378 WXWINE=
1379
1380 if test "$wxUSE_CYGWIN" = 1 || test "$wxUSE_MINGW" = 1 ; then
1381   AC_MSG_CHECKING(for Windows headers)
1382   WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, windows.h)
1383   INCLUDE_SUBDIRS="$INCLUDE_SUBDIRS msw"
1384
1385   dnl --- Quick & Dirty ; link against most/all libraries
1386   dnl --- This will bloat the executable, but it'll work for now...
1387   LIBS="$LIBS  -lkernel32 -luser32 -lgdi32 -lcomdlg32 -lwinspool -lwinmm -lshell32 -loldnames -lcomctl32 -lctl3d32 -lcrtdll -ladvapi32 -lwsock32"
1388
1389   if test "$ac_find_includes" != "" ; then
1390     AC_MSG_RESULT(found $ac_find_includes)
1391     TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE -I$ac_find_includes"
1392   else
1393     AC_MSG_RESULT(no)
1394     if test "$cross_compiling" != "yes" ; then
1395       AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
1396     fi
1397   fi
1398
1399   TOOLKIT=MSW
1400 fi
1401
1402 if test "$wxUSE_GTK" = 1; then
1403     dnl avoid calling AM_PATH_GTK twice, so check first for the newer version and
1404     dnl only then, if it wasn't found, for an older one
1405     AM_PATH_GTK(1.2.0, WXGTK12=1)
1406     if test "$WXGTK12" != 1; then
1407        AM_PATH_GTK(1.0.0, , AC_MSG_ERROR(Is gtk-config in path and GTK+ is version 1.2.X or 1.0.X?))
1408     fi
1409
1410     TOOLKIT_INCLUDE="$GTK_CFLAGS"
1411     GUI_TK_LIBRARY="$GTK_LIBS"
1412     TOOLKIT=GTK
1413
1414     GUIOBJS=GTK_GUIOBJS
1415     GUIHEADERS=GTK_HEADERS
1416     COMMONOBJS=GTK_COMMONOBJS
1417     GENERICOBJS=GTK_GENERICOBJS
1418 fi
1419
1420 if test "$wxUSE_WINE" = 1; then
1421     AC_MSG_CHECKING(for WINE includes)
1422     WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, windows.h)
1423     if test "$ac_find_includes" != "" ; then
1424         AC_MSG_RESULT(found $ac_find_includes)
1425         TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE -I$ac_find_includes"
1426     else
1427         AC_MSG_RESULT(no)
1428         AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
1429     fi
1430
1431     XPM_LINK=""
1432     AC_MSG_CHECKING(for Xpm library)
1433     WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
1434     if test "$ac_find_libraries" != "" ; then
1435         GUI_TK_LIBRARY="-L$ac_find_libraries"
1436         XPM_LINK="-lXpm"
1437         AC_DEFINE(wxHAVE_LIB_XPM)
1438         AC_MSG_RESULT(found at $ac_find_libraries)
1439     else
1440         AC_MSG_RESULT(no)
1441         AC_MSG_WARN(library will be compiled without support for images in XPM format)
1442     fi
1443
1444     MESA_LINK=""
1445     AC_MSG_CHECKING(for Mesa library)
1446     WX_PATH_FIND_LIBRARIES($SEARCH_LIB,MesaGL)
1447     if test "$ac_find_libraries" != "" ; then
1448         GUI_TK_LIBRARY="$GUI_TK_LIBRARY -L$ac_find_libraries"
1449         MESA_LINK="-lMesaGL"
1450         AC_MSG_RESULT(found at $ac_find_libraries)
1451     else
1452         AC_MSG_ERROR(no)
1453     fi
1454
1455     GUI_TK_LINK="-lwine $MESA_LINK $XPM_LINK -lXxf86dga -lXxf86vm -lSM -lICE -lXext -lXmu -lX11 -lncurses -ldl -lm"
1456     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $GUI_TK_LINK"
1457     WXWINE=1
1458     TOOLKIT=MSW
1459 fi
1460
1461 if test "$wxUSE_MOTIF" = 1; then
1462     dnl find the X11 include and library files
1463     dnl   defines x_includes and x_libraries
1464     AC_PATH_XTRA
1465
1466     if test "$no_x" = "yes"; then
1467       AC_MSG_ERROR(X11 libraries not found, aborting)
1468     fi
1469
1470     TOOLKIT_INCLUDE="$X_CFLAGS"
1471     GUI_TK_LIBRARY="$X_LIBS"
1472
1473     AC_MSG_CHECKING(for Motif/Lesstif includes)
1474     WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, Xm/Xm.h)
1475     if test "$ac_find_includes" != "" ; then
1476         AC_MSG_RESULT(found $ac_find_includes)
1477     else
1478         AC_MSG_RESULT(no)
1479         AC_MSG_ERROR(please set CFLAGS to contain the location of Xm/Xm.h)
1480     fi
1481
1482     AC_MSG_CHECKING(for Motif/Lesstif library)
1483     WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xm)
1484     if test "$ac_find_libraries" != "" ; then
1485         WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
1486         WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
1487
1488         CHECK_LINK="$GUI_TK_LIBRARY $ac_path_to_link"
1489         TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE $ac_path_to_include"
1490         AC_MSG_RESULT(found at $ac_find_libraries)
1491     else
1492         AC_MSG_RESULT(no)
1493         AC_MSG_ERROR(please set LDFLAGS to contain the location of libXm)
1494     fi
1495
1496     AC_MSG_CHECKING(for Xt library)
1497     WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xt)
1498     if test "$ac_find_libraries" != "" ; then
1499         WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
1500         CHECK_LINK="$GUI_TK_LIBRARY $ac_path_to_link"
1501         AC_MSG_RESULT(found at $ac_find_libraries)
1502     else
1503         AC_MSG_RESULT(no)
1504         AC_MSG_ERROR(please set LDFLAGS to contain the location of libXt)
1505     fi
1506
1507     XPM_LINK=""
1508     AC_MSG_CHECKING(for Xpm library)
1509     WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
1510     if test "$ac_find_libraries" != "" ; then
1511         WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
1512         CHECK_LINK="$GUI_TK_LIBRARY $ac_path_to_link"
1513         XPM_LINK="-lXpm "
1514         AC_DEFINE(wxHAVE_LIB_XPM)
1515         AC_MSG_RESULT(found at $ac_find_libraries)
1516     else
1517         AC_MSG_RESULT(no)
1518         AC_MSG_WARN(library will be compiled without support for images in XPM format)
1519     fi
1520
1521     GUI_TK_LINK="-lXm $XPM_LINK -lXmu -lXt -lX11 -ldl -lm"
1522     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $GUI_TK_LINK"
1523     TOOLKIT=MOTIF
1524
1525     GUIOBJS=MOTIF_GUIOBJS
1526     GUIHEADERS=MOTIF_HEADERS
1527     COMMONOBJS=MOTIF_COMMONOBJS
1528     GENERICOBJS=MOTIF_GENERICOBJS
1529 fi
1530
1531 dnl the name of the directory where the files for this toolkit live
1532 TOOLKIT_DIR=`echo ${TOOLKIT} | tr "A-Z" "a-z"`
1533
1534 dnl the symbol which allows conditional compilation for the given toolkit
1535 TOOLKIT_DEF="-D__WX${TOOLKIT}__"
1536
1537 dnl the name of the (libtool) library
1538 WX_LIBRARY="wx_${TOOLKIT_DIR}"
1539
1540 dnl the name of the (libtool) library
1541 WX_LIBRARY_NAME="libwx_${TOOLKIT_DIR}.la"
1542
1543 dnl the name of the static library
1544 WX_LIBRARY_NAME_STATIC="libwx_${TOOLKIT_DIR}.a"
1545
1546 dnl the name of the shared library
1547 WX_LIBRARY_NAME_SHARED="libwx_${TOOLKIT_DIR}-${WX_RELEASE}.so.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
1548
1549 dnl the name of the links to the shared library
1550 WX_LIBRARY_LINK1="libwx_${TOOLKIT_DIR}-${WX_RELEASE}.so.${WX_CURRENT}"
1551 WX_LIBRARY_LINK2="libwx_${TOOLKIT_DIR}-${WX_RELEASE}.so"
1552 WX_LIBRARY_LINK3="libwx_${TOOLKIT_DIR}.so"
1553
1554 dnl shared library settings
1555 SHARED_LD=
1556 PIC_FLAG=
1557 WX_CREATE_LINKS=
1558
1559 if test "$wxUSE_SHARED" = "yes"; then
1560     dnl set target to shared
1561     WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_SHARED}"
1562
1563 case "${host}" in
1564   *-hp-hpux* )
1565     WX_LIBRARY_NAME_SHARED="libwx_${TOOLKIT_DIR}.sl"
1566     SHARED_LD="${CXX} -b -o"
1567     PIC_FLAG="+Z"
1568   ;;
1569   *-*-linux* )
1570     SHARED_LD="${CC} -shared -o"
1571     PIC_FLAG="-fPIC"
1572     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1573     WX_CREATE_LINKS="CREATE_LINKS"
1574   ;;
1575   *-*-irix5* | *-*-irix6* )
1576     SHARED_LD="${CXX} -shared -o"
1577     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1578     WX_CREATE_LINKS="CREATE_LINKS"
1579   ;;
1580   *-*-solaris2* )
1581     SHARED_LD="${CXX} -G -o"
1582     PIC_FLAG="PIC"
1583     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1584     WX_CREATE_LINKS="CREATE_LINKS"
1585   ;;
1586   *-*-sunos4* )
1587     SHARED_LD="${CXX} -shared -o"
1588     PIC_FLAG="-fPIC"
1589     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1590     WX_CREATE_LINKS="CREATE_LINKS"
1591   ;;
1592   *-*-freebsd* | *-*-netbsd*)
1593     SHARED_LD="${CXX} -shared -o"
1594     PIC_FLAG="-fPIC"
1595     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1596     WX_CREATE_LINKS="CREATE_LINKS"
1597   ;;
1598   *-*-osf* )
1599     SHARED_LD="${CXX} -shared -o"
1600     PIC_FLAG="-fPIC"
1601     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1602     WX_CREATE_LINKS="CREATE_LINKS"
1603   ;;
1604   *-*-dgux5* )
1605     SHARED_LD="${CXX} -shared -o"
1606     PIC_FLAG="-fPIC"
1607     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1608     WX_CREATE_LINKS="CREATE_LINKS"
1609   ;;
1610   *-*-sysv5* )
1611     SHARED_LD="${CXX} -shared -o"
1612     PIC_FLAG="-fPIC"
1613     WX_CREATE_INSTALLED_LINKS="CREATE_INSTALLED_LINKS"
1614     WX_CREATE_LINKS="CREATE_LINKS"
1615   ;;
1616   *-*-aix* )
1617     SHARED_LD="/usr/lpp/xlC/bin/makeC++SharedLib -p 0 -o"
1618   ;;
1619   *-*-cygwin32* )
1620   ;;
1621   *-*-mingw32* )
1622   ;;
1623   *-pc-os2_emx )
1624   ;;
1625   *)
1626     AC_MSG_ERROR(unknown system type ${host}.)
1627 esac
1628
1629 else
1630     dnl set target to static
1631     WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_STATIC}"
1632 fi
1633
1634 dnl ------------------------------------------------------------------------
1635 dnl Check for headers
1636 dnl ------------------------------------------------------------------------
1637
1638 dnl defines HAVE_STRINGS_H (where some string functions live on AIX for example)
1639 AC_CHECK_HEADERS(strings.h)
1640 dnl defines HAVE_UNISTD_H
1641 AC_CHECK_HEADERS(unistd.h)
1642 dnl defines HAVE_WCHAR_H
1643 AC_CHECK_HEADERS(wchar.h)
1644 dnl defines HAVE_WCSTR_H
1645 AC_CHECK_HEADERS(wcstr.h)
1646 dnl defines HAVE_FNMATCH_H
1647 AC_CHECK_HEADERS(fnmatch.h)
1648 dnl defines HAVE_X11_XKBLIB_H
1649 AC_CHECK_HEADERS(X11/XKBlib.h)
1650
1651 dnl ---------------------------------------------------------------------------
1652 dnl Checks for typedefs
1653 dnl ---------------------------------------------------------------------------
1654
1655 dnl   defines mode_t if not already defined
1656 AC_TYPE_MODE_T
1657 dnl   defines off_t if not already defined
1658 AC_TYPE_OFF_T
1659 dnl   defines pid_t if not already defined
1660 AC_TYPE_PID_T
1661 dnl   defines size_t if not already defined
1662 AC_TYPE_SIZE_T
1663 dnl   defines uid_t and gid_t if not already defined
1664 AC_TYPE_UID_T
1665
1666 dnl ---------------------------------------------------------------------------
1667 dnl Checks for structures
1668 dnl ---------------------------------------------------------------------------
1669
1670 dnl ---------------------------------------------------------------------------
1671 dnl Checks for compiler characteristics
1672 dnl ---------------------------------------------------------------------------
1673
1674 dnl defines const to be empty if c-compiler does not support const fully
1675 AC_C_CONST
1676 dnl defines inline to a sensible value for the c-compiler
1677 AC_C_INLINE
1678
1679 dnl check the sizes of integral types (give some reasonable default values for
1680 dnl cross-compiling)
1681 dnl   defines the size of certain types of variables in SIZEOF_<TYPE>
1682 AC_CHECK_SIZEOF(char, 1)
1683 AC_CHECK_SIZEOF(short, 2)
1684 AC_CHECK_SIZEOF(int *, 4)
1685 AC_CHECK_SIZEOF(int, 4)
1686 AC_CHECK_SIZEOF(long, 4)
1687 AC_CHECK_SIZEOF(long long, 0)
1688
1689 dnl for bytesex stuff (don't use AC_C_BIGENDIAN to allow cross-compiling)
1690 WX_C_BIGENDIAN
1691
1692 dnl check for iostream (as opposed to iostream.h) standard header
1693 WX_CPP_NEW_HEADERS(, AC_DEFINE(wxUSE_IOSTREAMH))
1694
1695 dnl check whether C++ compiler supports bool built-in type
1696 WX_CPP_BOOL
1697
1698 dnl check whether overloading on size_t/int parameter works
1699 WX_CPP_SIZE_T_IS_NOT_INT
1700
1701 dnl check whether we should define _GNU_SOURCE
1702 WX_GNU_EXTENSIONS
1703
1704 dnl ---------------------------------------------------------------------------
1705 dnl Check for functions
1706 dnl ---------------------------------------------------------------------------
1707
1708 dnl check for wcslen
1709 AC_CHECK_LIB(c, wcslen, [
1710             AC_DEFINE(HAVE_WCSLEN)
1711             WCHAR_LINK=""
1712         ], [
1713             AC_CHECK_LIB(w, wcslen, [
1714                 AC_DEFINE(HAVE_WCSLEN)
1715                 WCHAR_LINK="-lw"
1716             ])
1717         ])
1718
1719 dnl check for vprintf/vsprintf() which are GNU extensions
1720 AC_FUNC_VPRINTF
1721
1722 dnl check for vsnprintf() - a safe version of vsprintf()
1723 AC_CHECK_FUNCS(vsnprintf,
1724                AC_DEFINE(HAVE_VSNPRINTF),
1725                AC_MSG_WARN(unsafe function sprintf will be used instead of snprintf)
1726               )
1727
1728 dnl check for vsscanf() - on some platforms (Linux, glibc 2.1.1) it's
1729 dnl available in the library but the prototype is missing, so we can't use
1730 dnl AC_CHECK_FUNCS here, do it manually
1731 AC_LANG_SAVE
1732 AC_LANG_CPLUSPLUS
1733
1734 AC_CACHE_CHECK([for vsscanf], wx_cv_func_vsscanf,
1735 [
1736   AC_TRY_COMPILE(
1737              [
1738                 #include <stdio.h>
1739                 #include <stdarg.h>
1740              ],
1741              [
1742                 va_list ap;
1743                 vsscanf("", "", ap);
1744              ], [
1745                 wx_cv_func_vsscanf=yes
1746                 AC_DEFINE(HAVE_VSSCANF)
1747              ], [
1748                 wx_cv_func_vsscanf=no
1749              ])
1750 ])
1751
1752 AC_LANG_RESTORE
1753
1754 dnl check for vfork() (even if it's the same as fork() in modern Unices)
1755 AC_CHECK_FUNCS(vfork)
1756
1757 POSIX4_LINK=
1758 AC_CHECK_FUNCS(nanosleep, AC_DEFINE(HAVE_NANOSLEEP), [
1759     AC_CHECK_LIB(posix4, nanosleep, [
1760       AC_DEFINE(HAVE_NANOSLEEP)
1761       POSIX4_LINK="-lposix4"
1762     ], [
1763     AC_CHECK_FUNCS(usleep,
1764         AC_DEFINE(HAVE_USLEEP),
1765         AC_MSG_WARN([wxSleep() function will not work]))
1766     ])
1767 ])
1768
1769 dnl check for uname (POSIX) and gethostname (BSD)
1770 AC_CHECK_FUNCS(uname gethostname, break)
1771
1772 dnl check for inet_addr, inet_aton, ...
1773 AC_CHECK_FUNCS(inet_addr)
1774 AC_CHECK_FUNCS(inet_aton)
1775
1776 dnl ===========================================================================
1777 dnl Now we have all the info we need - use it!
1778 dnl ===========================================================================
1779
1780 dnl flush the cache
1781 AC_CACHE_SAVE
1782
1783 dnl ---------------------------------------------------------------------------
1784 dnl thread support for Unix (always available under Win32)
1785 dnl ---------------------------------------------------------------------------
1786
1787 if test "$USE_UNIX" = 1; then
1788
1789 dnl the code below:
1790 dnl   defines THREADS_OBJ which contains the object files to build
1791 dnl   defines THREADS_LINK which contains the thread library to link with
1792 dnl   defines wxUSE_THREADS=1 if thread support is activated
1793
1794 THREADS_LINK=""
1795 THREADS_OBJ=""
1796
1797 if test "$wxUSE_THREADS" = "yes" ; then
1798     if test "$wxUSE_WINE" = 1 ; then
1799         AC_MSG_WARN([Threads are not supported under WINE])
1800         wxUSE_THREADS="no"
1801     fi
1802 fi
1803
1804 if test "$wxUSE_THREADS" = "yes" ; then
1805     dnl find if POSIX threads are available
1806
1807     dnl standard lib name is pthread
1808     dnl We no longer test for pthread-0.7 as it breaks compilation on some
1809     dnl glibc2 systems, especially for static linkage.
1810     AC_CHECK_LIB(pthread, pthread_create, [
1811             THREADS_OBJ="threadpsx.lo"
1812             THREADS_LINK="pthread"
1813         ], [
1814             dnl thread functions are in libc_r under FreeBSD
1815             AC_CHECK_LIB(c_r, pthread_create, [
1816                 THREADS_OBJ="threadpsx.lo"
1817                 THREADS_LINK="c_r"
1818             ], [
1819                 dnl VZ: SGI threads are not supported currently
1820                 AC_CHECK_HEADER(sys/prctl.h, [
1821                     THREADS_OBJ="threadsgi.lo"
1822                 ])
1823             ])
1824         ])
1825
1826     if test -z "$THREADS_OBJ" ; then
1827         wxUSE_THREADS=no
1828         AC_MSG_WARN(No thread support on this system)
1829     fi
1830 fi
1831
1832 dnl do other tests only if we are using threads
1833 if test "$wxUSE_THREADS" = "yes" ; then
1834   dnl define autoconf macro to check for given function in both pthread and
1835   dnl posix4 libraries
1836   dnl usage: AC_FUNC_THREAD(FUNCTION_NAME)
1837   dnl VZ: TODO
1838   dnl AC_DEFUN(AC_FUNC_THREAD,
1839   dnl [
1840   dnl     AC_CHECK_LIB($THREADS_LINK, $1,
1841   dnl            AC_DEFINE(HAVE_`'translit($1, `A-Z', 'a-z'),
1842   dnl            [AC_CHECK_LIB("posix4", $1,
1843   dnl                [AC_DEFINE(HAVE_`'translit($1, `A-Z', 'a-z'))
1844   dnl                 POSIX4_LINK="-lposix4"
1845   dnl             ])
1846   dnl            ])
1847   dnl ])
1848
1849   AC_CHECK_HEADERS(sched.h)
1850
1851   AC_CHECK_LIB($THREADS_LINK, sched_yield,
1852                AC_DEFINE(HAVE_SCHED_YIELD),
1853                [AC_CHECK_LIB("posix4", sched_yield,
1854                    [AC_DEFINE(HAVE_SCHED_YIELD) POSIX4_LINK="-lposix4"],
1855                    AC_MSG_WARN(wxThread::Yield will not work properly)
1856                 )]
1857                )
1858
1859   dnl VZ: we should be checking for all of the following functions instead:
1860   dnl   1. pthread_attr_getschedpolicy
1861   dnl   2. sched_get_priority_min and sched_get_priority_max
1862   dnl   3. pthread_attr_getschedparam and pthread_attr_setschedparam
1863   dnl but it seems that if the first one is there, the other ones are too (of
1864   dnl course the proper solution would be to implement AC_FUNC_THREAD above
1865   dnl and do test for them all - anyone?)
1866   AC_CHECK_LIB($THREADS_LINK, pthread_attr_getschedpolicy,
1867                AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS),
1868                [AC_CHECK_LIB("posix4", pthread_attr_getschedpolicy,
1869                    [AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS) POSIX4_LINK="-lposix4"],
1870                    AC_MSG_WARN(Setting thread priority will not work)
1871                 )]
1872                )
1873
1874   AC_CHECK_LIB($THREADS_LINK, pthread_cancel,
1875                AC_DEFINE(HAVE_PTHREAD_CANCEL),
1876                AC_MSG_WARN([wxThread::Kill() will not work properly]))
1877
1878   AC_CACHE_CHECK([for pthread_cleanup_push/pop], wx_cv_func_pthread_cleanup_push,
1879   [
1880     AC_TRY_COMPILE([#include <pthread.h>],
1881                  [
1882                     pthread_cleanup_push(NULL, NULL);
1883                     pthread_cleanup_pop(0);
1884                  ], [
1885                     wx_cv_func_pthread_cleanup_push=yes
1886                     AC_DEFINE(HAVE_THREAD_CLEANUP_FUNCTIONS)
1887                  ], [
1888                     wx_cv_func_pthread_cleanup_push=no
1889                  ])
1890   ])
1891
1892   THREADS_LINK="-l$THREADS_LINK"
1893 fi
1894
1895 dnl from if USE_UNIX
1896 fi
1897
1898 if test "$wxUSE_THREADS" = "yes"; then
1899   AC_DEFINE(wxUSE_THREADS)
1900
1901   dnl must define _REENTRANT for multithreaded code
1902   CFLAGS="${CFLAGS} -D_REENTRANT"
1903   CXXFLAGS="${CXXFLAGS} -D_REENTRANT"
1904
1905   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS thread"
1906 fi
1907
1908 if test "$WXGTK12" = 1 ; then
1909   AC_DEFINE_UNQUOTED(__WXGTK12__,$WXGTK12)
1910 fi
1911
1912 if test "$WXWINE" = 1 ; then
1913   TOOLKIT_DEF="${TOOLKIT_DEF} -D__WXWINE__"
1914 fi
1915
1916 if test "$wxUSE_CYGWIN" = 1 ; then
1917   TOOLKIT_DEF="${TOOLKIT_DEF} -D__WIN95__"
1918 fi
1919
1920 WXDEBUG=
1921 if test "$wxUSE_DEBUG_GDB" = "yes" ; then
1922     wxUSE_DEBUG_INFO=yes
1923     WXDEBUG="-ggdb"
1924 fi
1925
1926 if test "$wxUSE_DEBUG_INFO" = "yes" ; then
1927     WXDEBUG="-g"
1928     wxUSE_OPTIMISE=no
1929 fi
1930
1931 if test "$wxUSE_DEBUG_FLAG" = "yes" ; then
1932     AC_DEFINE(WXDEBUG)
1933     WXDEBUG_DEFINE="-D__WXDEBUG__"
1934 else
1935     if test "$wxUSE_GTK" = 1 ; then
1936         WXDEBUG_DEFINE="-DGTK_NO_CHECK_CASTS"
1937     fi
1938 fi
1939
1940 if test "$wxUSE_MEM_TRACING" = "yes" ; then
1941     AC_DEFINE(wxUSE_MEMORY_TRACING)
1942     AC_DEFINE(wxUSE_GLOBAL_MEMORY_OPERATORS)
1943     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS memcheck"
1944 fi
1945
1946 if test "$wxUSE_DMALLOC" = "yes" ; then
1947     DMALLOC_LINK="-ldmalloc"
1948 fi
1949
1950 PROFILE=
1951 if test "$wxUSE_PROFILE" = "yes" ; then
1952     PROFILE="-pg"
1953 fi
1954
1955 if test "$GCC" = yes ; then
1956     if test "$wxUSE_NO_RTTI" = "yes" ; then
1957         WXDEBUG_DEFINE="$WXDEBUG_DEFINE -fno-rtti"
1958     fi
1959     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
1960         WXDEBUG_DEFINE="$WXDEBUG_DEFINE -fno-exceptions"
1961     fi
1962 fi
1963
1964
1965 CXXFLAGS=`echo "${CXXFLAGS}" | sed "s/\-O.//g" `
1966 CFLAGS=`echo "${CFLAGS}" | sed "s/\-O.//g" `
1967 if test "$wxUSE_OPTIMISE" = "no" ; then
1968     OPTIMISE=
1969 else
1970     if test "$GCC" = yes ; then
1971         OPTIMISE="-O2"
1972         case "${host}" in
1973             i586-*-*|i686-*-* )
1974             OPTIMISE="${OPTIMISE} "
1975         ;;
1976         esac
1977     else
1978         OPTIMISE="-O"
1979     fi
1980 fi
1981
1982 dnl ---------------------------------------------------------------------------
1983 dnl Optional libraries
1984 dnl ---------------------------------------------------------------------------
1985
1986 ZLIB_INCLUDE=
1987 if test "$wxUSE_ZLIB" = "yes" ; then
1988   AC_DEFINE(wxUSE_ZLIB)
1989   ZLIB_INCLUDE="-I\${top_srcdir}/src/zlib"
1990 fi
1991
1992 PNG_INCLUDE=
1993 if test "$wxUSE_LIBPNG" = "yes" ; then
1994   AC_DEFINE(wxUSE_LIBPNG)
1995   PNG_INCLUDE="-I\${top_srcdir}/src/png"
1996   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS png"
1997 fi
1998
1999 if test "$wxUSE_LIBGIF" = "yes" ; then
2000   AC_DEFINE(wxUSE_LIBGIF)
2001 fi
2002
2003 JPEG_INCLUDE=
2004 if test "$wxUSE_LIBJPEG" = "yes" ; then
2005   AC_DEFINE(wxUSE_LIBJPEG)
2006   JPEG_INCLUDE="-I\${top_srcdir}/src/jpeg"
2007 fi
2008
2009 if test "$wxUSE_OPENGL" = "yes"; then
2010   AC_CHECK_HEADER(GL/gl.h, [
2011     AC_CHECK_LIB(GL, glInitNames, [
2012       OPENGL_LINK="-lGL"
2013       AC_DEFINE(wxUSE_OPENGL)
2014       UTILS_SUBDIRS="$UTILS_SUBDIRS glcanvas/src"
2015     ],[
2016         AC_CHECK_LIB(MesaGL, glInitNames, [
2017         OPENGL_LINK="-lMesaGL"
2018         AC_DEFINE(wxUSE_OPENGL)
2019         UTILS_SUBDIRS="$UTILS_SUBDIRS glcanvas/src"
2020       ],wxUSE_OPENGL=0)
2021      ],wxUSE_OPENGL=0)
2022     ],wxUSE_OPENGL=0)
2023 fi
2024
2025 dnl ---------------------------------------------------------------------------
2026 dnl the library may be built without GUI classes at all
2027 dnl ---------------------------------------------------------------------------
2028
2029 if test "$wxUSE_GUI" = "yes"; then
2030   AC_DEFINE(wxUSE_GUI)
2031
2032   dnl the things we always pull in the GUI version of the library:
2033   dnl 1. basic things like wxApp, wxWindow, wxControl, wxFrame, wxDialog (the
2034   dnl    library really can't be built without those)
2035   dnl 2. basic controls: wxButton, wxStaticText, wxTextCtrl (these are used in
2036   dnl    almost any program and the first 2 are needed to show a message box
2037   dnl    which want to be always able to do)
2038   dnl 3. GDI stuff: icon, cursors and all that. Although it would be very nice
2039   dnl    to compile without them (if the app doesn't do any drawing, it doesn't
2040   dnl    need the dcs, pens, brushes, ...), this just can't be done now
2041   dnl 4. menu stuff: wxMenu, wxMenuBar, wxMenuItem
2042   dnl 5. misc stuff: timers, settings, message box
2043 else
2044   AC_DEFINE(wxUSE_NOGUI)
2045 fi
2046
2047 dnl ---------------------------------------------------------------------------
2048 dnl Unix/Windows
2049 dnl ---------------------------------------------------------------------------
2050
2051 if test "$wxUSE_UNIX" = "yes"; then
2052   AC_DEFINE(wxUSE_UNIX)
2053 fi
2054
2055 dnl ---------------------------------------------------------------------------
2056 dnl Register non-GUI class options for makefiles and setup.h
2057 dnl ---------------------------------------------------------------------------
2058
2059 if test "$wxUSE_APPLE_IEEE" = "yes"; then
2060   AC_DEFINE(wxUSE_APPLE_IEEE)
2061 fi
2062
2063 if test "$wxUSE_TIMEDATE" = "yes"; then
2064   AC_DEFINE(wxUSE_TIMEDATE)
2065   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS typetest"
2066 fi
2067
2068 if test "$wxUSE_WAVE" = "yes"; then
2069   AC_DEFINE(wxUSE_WAVE)
2070 fi
2071
2072 if test "$wxUSE_FILE" = "yes"; then
2073   AC_DEFINE(wxUSE_FILE)
2074 fi
2075
2076 if test "$wxUSE_FS_INET" = "yes"; then
2077   AC_DEFINE(wxUSE_FS_INET)
2078 fi
2079
2080 if test "$wxUSE_FS_ZIP" = "yes"; then
2081   AC_DEFINE(wxUSE_FS_ZIP)
2082 fi
2083
2084 if test "$wxUSE_ZIPSTREAM" = "yes"; then
2085   AC_DEFINE(wxUSE_ZIPSTREAM)
2086 fi
2087
2088 if test "$wxUSE_BUSYINFO" = "yes"; then
2089   AC_DEFINE(wxUSE_BUSYINFO)
2090 fi
2091
2092 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
2093   AC_DEFINE(wxUSE_STD_IOSTREAM)
2094 fi
2095
2096 if test "$wxUSE_TEXTFILE" = "yes"; then
2097   if test "$wxUSE_FILE" != "yes"; then
2098     AC_MSG_WARN(wxTextFile requires wxFile and it won't be compiled without it)
2099   else
2100     AC_DEFINE(wxUSE_TEXTFILE)
2101   fi
2102 fi
2103
2104 if test "$wxUSE_CONFIG" = "yes" ; then
2105   if test "$wxUSE_TEXTFILE" != "yes"; then
2106     AC_MSG_WARN(wxConfig requires wxTextFile and it won't be compiled without it)
2107   else
2108     AC_DEFINE(wxUSE_CONFIG)
2109     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS config"
2110   fi
2111 fi
2112
2113 if test "$wxUSE_INTL" = "yes" ; then
2114   if test "$wxUSE_FILE" != "yes"; then
2115     AC_MSG_WARN(I18n code requires wxFile and it won't be compiled without it)
2116   else
2117     AC_DEFINE(wxUSE_INTL)
2118     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS internat"
2119   fi
2120 fi
2121
2122 if test "$wxUSE_LOG" = "yes"; then
2123   AC_DEFINE(wxUSE_LOG)
2124 fi
2125
2126 if test "$wxUSE_LONGLONG" = "yes"; then
2127   AC_DEFINE(wxUSE_LONGLONG)
2128 fi
2129
2130 if test "$wxUSE_SOCKETS" = "yes" ; then
2131     if test "$wxUSE_THREADS" = "yes" ; then
2132         AC_DEFINE(wxUSE_SOCKETS)
2133         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS wxsocket"
2134         INCLUDE_SUBDIRS="$INCLUDE_SUBDIRS protocol"
2135     else
2136         AC_MSG_WARN(Socket classes require --with-threads and won't be compiled without it)
2137         wxUSE_SOCKETS=0
2138     fi
2139 fi
2140
2141 if test "$wxUSE_STREAMS" = "yes" ; then
2142   AC_DEFINE(wxUSE_STREAMS)
2143 fi
2144
2145 if test "$wxUSE_SERIAL" = "yes" ; then
2146   AC_DEFINE(wxUSE_SERIAL)
2147 fi
2148
2149 dnl ------------------------------------------------------------------------
2150 dnl wxSocket
2151 dnl ------------------------------------------------------------------------
2152
2153 if test "$wxUSE_SOCKETS" = "yes"; then
2154     AC_LANG_SAVE
2155     AC_LANG_CPLUSPLUS
2156     dnl determine the type of third argument for getsockname
2157     AC_MSG_CHECKING(the type of the third argument of getsockname)
2158     AC_TRY_COMPILE(
2159         [#include <sys/socket.h>],
2160         [socklen_t len; getsockname(0, NULL, &len);],
2161         AC_DEFINE(SOCKLEN_T, socklen_t) AC_MSG_RESULT(socklen_t),
2162            AC_TRY_COMPILE(
2163             [#include <sys/socket.h>],
2164             [size_t len; getsockname(0, NULL, &len);],
2165             AC_DEFINE(SOCKLEN_T, size_t) AC_MSG_RESULT(size_t),
2166             AC_TRY_COMPILE(
2167                 [#include <sys/socket.h>],
2168                 [int len; getsockname(0, NULL, &len);],
2169                 AC_DEFINE(SOCKLEN_T, int) AC_MSG_RESULT(int),
2170             AC_MSG_RESULT(unknown)
2171         )
2172         )
2173     )
2174     AC_LANG_RESTORE
2175 fi
2176
2177 dnl ---------------------------------------------------------------------------
2178 dnl Joystick support
2179 dnl ---------------------------------------------------------------------------
2180
2181 if test "$wxUSE_JOYSTICK" = 1; then
2182   dnl joystick support is only for Linux 2.1.x or greater
2183   AC_CHECK_HEADERS(linux/joystick.h)
2184   if test "$ac_cv_header_linux_joystick_h" = "yes"; then
2185     AC_DEFINE(wxUSE_JOYSTICK)
2186     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS joytest"
2187   fi
2188 fi
2189
2190 dnl ------------------------------------------------------------------------
2191 dnl DLL support
2192 dnl ------------------------------------------------------------------------
2193
2194 HAVE_DL_FUNCS=0
2195 HAVE_SHL_FUNCS=0
2196 if test "$wxUSE_DYNLIB_CLASS" = "yes"; then
2197     dnl the test is a bit complicated because we check for dlopen() both with
2198     dnl and without -ldl
2199     AC_CHECK_FUNCS(dlopen,
2200         [AC_DEFINE(HAVE_DLOPEN) HAVE_DL_FUNCS=1],
2201         [AC_CHECK_LIB(dl, dlopen,
2202             [AC_DEFINE(HAVE_DLOPEN) HAVE_DL_FUNCS=1])])
2203     AC_CHECK_FUNCS( shl_load,
2204                     [AC_DEFINE(HAVE_SHL_LOAD) HAVE_DL_FUNCS=1 HAVE_SHL_FUNCS=1])
2205
2206     if test "$HAVE_DL_FUNCS" = 0; then
2207         if test "$USE_UNIX" = 1; then
2208             AC_MSG_WARN("--with-dynlib and --with-odbc will be disabled due to missing shared library support")
2209             wxUSE_ODBC=no
2210             wxUSE_DYNLIB_CLASS=no
2211         else
2212             AC_MSG_WARN("Cannot check dynlib requirements on non-Unix platforms. dynlib remains enabled.")
2213         fi
2214     fi
2215 fi
2216
2217 if test "$wxUSE_DYNLIB_CLASS" = "yes" ; then
2218   AC_DEFINE(wxUSE_DYNLIB_CLASS)
2219 fi
2220
2221 dnl ---------------------------------------------------------------------------
2222 dnl String stuff
2223 dnl ---------------------------------------------------------------------------
2224
2225 if test "$wxUSE_UNICODE" = "yes" ; then
2226   AC_DEFINE(wxUSE_UNICODE)
2227 fi
2228
2229 if test "$wxUSE_WCSRTOMBS" = "yes" ; then
2230   AC_DEFINE(wxUSE_WCSRTOMBS)
2231 fi
2232
2233 if test "$wxUSE_wxUSE_EXPERIMENTAL_PRINTF" = "yes"; then
2234   AC_DEFINE(wxUSE_EXPERIMENTAL_PRINTF)
2235 fi
2236
2237 dnl ----------------------------------------------------------------
2238 dnl iODBC support
2239 dnl ----------------------------------------------------------------
2240
2241 IODBC_C_SRC=""
2242 if test "$wxUSE_ODBC" = "yes" ; then
2243   AC_DEFINE(wxUSE_ODBC)
2244   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS db"
2245 fi
2246
2247 dnl ----------------------------------------------------------------
2248 dnl Register PostScript options for makefiles and setup.h
2249 dnl ----------------------------------------------------------------
2250
2251 if test "$wxUSE_POSTSCRIPT" = "yes" ; then
2252   AC_DEFINE(wxUSE_POSTSCRIPT)
2253 fi
2254
2255 AC_DEFINE(wxUSE_AFM_FOR_POSTSCRIPT)
2256
2257 AC_DEFINE(wxUSE_NORMALIZED_PS_FONTS)
2258
2259 dnl ---------------------------------------------------------------------------
2260 dnl big GUI components: MDI, doc/view, printing, help, ...
2261 dnl ---------------------------------------------------------------------------
2262
2263 if test "$wxUSE_CONSTRAINTS" = "yes"; then
2264     AC_DEFINE(wxUSE_CONSTRAINTS)
2265     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS layout"
2266 fi
2267
2268 if test "$wxUSE_MDI_ARCHITECTURE" = "yes"; then
2269     AC_DEFINE(wxUSE_MDI_ARCHITECTURE)
2270     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mdi"
2271 fi
2272
2273 if test "$wxUSE_DOC_VIEW_ARCHITECTURE" = "yes" ; then
2274     AC_DEFINE(wxUSE_DOC_VIEW_ARCHITECTURE)
2275     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS docview"
2276     if test "$wxUSE_MDI_ARCHITECTURE" = "yes"; then
2277         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS docvwmdi"
2278     fi
2279 fi
2280
2281 if test "$wxUSE_HELP" = "yes"; then
2282     AC_DEFINE(wxUSE_HELP)
2283     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS help"
2284 fi
2285
2286 if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
2287     if test "$wxUSE_CONSTRAINTS" != "yes"; then
2288         AC_MSG_WARN(Printing support cannot be used without constraints so it won't be compiled without it)
2289     else
2290         AC_DEFINE(wxUSE_PRINTING_ARCHITECTURE)
2291     fi
2292     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS printing"
2293 fi
2294
2295 if test "$wxUSE_PROLOGIO" = "yes" ; then
2296     AC_DEFINE(wxUSE_PROLOGIO)
2297 fi
2298
2299 if test "$wxUSE_RESOURCES" = "yes" ; then
2300     if test "$wxUSE_PROLOGIO" = "yes" ; then
2301         AC_DEFINE(wxUSE_RESOURCES)
2302         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS resource"
2303     else
2304         AC_MSG_WARN([wxWindows ressource system requires PrologIO and can't be compiled without it.])
2305     fi
2306 fi
2307
2308 if test "$wxUSE_X_RESOURCES" = "yes"; then
2309     AC_DEFINE(wxUSE_X_RESOURCES)
2310 fi
2311
2312 dnl ---------------------------------------------------------------------------
2313 dnl IPC: IPC, Drag'n'Drop, Clipboard, ...
2314 dnl ---------------------------------------------------------------------------
2315
2316 if test "$wxUSE_IPC" = "yes"; then
2317     AC_DEFINE(wxUSE_IPC)
2318 fi
2319
2320 if test "$wxUSE_CLIPBOARD" = "yes"; then
2321     AC_DEFINE(wxUSE_CLIPBOARD)
2322 fi
2323
2324 if test "$wxUSE_DRAG_AND_DROP" = "yes" ; then
2325     if test "$wxUSE_GTK" = 1; then
2326         if test "$WXGTK12" != 1; then
2327             AC_MSG_WARN([Drag and drop is only supported under wxGTK 2.1])
2328             wxUSE_DRAG_AND_DROP=no
2329         fi
2330     fi
2331
2332     if test "$wxUSE_MOTIF" = 1; then
2333         AC_MSG_WARN([Drag and drop is not yet supported under Motif])
2334         wxUSE_DRAG_AND_DROP=no
2335     fi
2336
2337     if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
2338         AC_DEFINE(wxUSE_DRAG_AND_DROP)
2339         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dnd"
2340     fi
2341 fi
2342
2343 if test "$wxUSE_SPLINES" = "yes" ; then
2344   AC_DEFINE(wxUSE_SPLINES)
2345 fi
2346
2347 dnl ---------------------------------------------------------------------------
2348 dnl GUI controls
2349 dnl ---------------------------------------------------------------------------
2350
2351 if test "$wxUSE_ACCEL" = "yes"; then
2352   AC_DEFINE(wxUSE_ACCEL)
2353 fi
2354
2355 if test "$wxUSE_CARET" = "yes"; then
2356   AC_DEFINE(wxUSE_CARET)
2357   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS caret"
2358 fi
2359
2360 if test "$wxUSE_COMBOBOX" = "yes"; then
2361   AC_DEFINE(wxUSE_COMBOBOX)
2362 fi
2363
2364 if test "$wxUSE_CHOICE" = "yes"; then
2365   AC_DEFINE(wxUSE_CHOICE)
2366 fi
2367
2368 if test "$wxUSE_BMPBUTTON" = "yes"; then
2369   AC_DEFINE(wxUSE_BMPBUTTON)
2370 fi
2371
2372 if test "$wxUSE_CHECKBOX" = "yes"; then
2373   AC_DEFINE(wxUSE_CHECKBOX)
2374 fi
2375
2376 if test "$wxUSE_CHECKLST" = "yes"; then
2377   AC_DEFINE(wxUSE_CHECKLISTBOX)
2378   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS checklst"
2379 fi
2380
2381 if test "$wxUSE_GAUGE" = "yes"; then
2382   AC_DEFINE(wxUSE_GAUGE)
2383 fi
2384
2385 if test "$wxUSE_GRID" = "yes"; then
2386   AC_DEFINE(wxUSE_GRID)
2387   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS grid"
2388 fi
2389
2390 if test "$wxUSE_IMAGLIST" = "yes"; then
2391     AC_DEFINE(wxUSE_IMAGLIST)
2392 fi
2393
2394 if test "$wxUSE_LISTBOX" = "yes"; then
2395     AC_DEFINE(wxUSE_LISTBOX)
2396 fi
2397
2398 if test "$wxUSE_LISTCTRL" = "yes"; then
2399     if test "$wxUSE_IMAGLIST" = "yes"; then
2400         AC_DEFINE(wxUSE_LISTCTRL)
2401         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS listctrl"
2402     else
2403         AC_MSG_WARN([wxListCtrl requires wxImageList and won't be compiled without it])
2404     fi
2405 fi
2406
2407 if test "$wxUSE_NOTEBOOK" = "yes"; then
2408     AC_DEFINE(wxUSE_NOTEBOOK)
2409     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS notebook"
2410 fi
2411
2412 if test "$wxUSE_RADIOBOX" = "yes"; then
2413     AC_DEFINE(wxUSE_RADIOBOX)
2414 fi
2415
2416 if test "$wxUSE_RADIOBTN" = "yes"; then
2417     AC_DEFINE(wxUSE_RADIOBTN)
2418 fi
2419
2420 if test "$wxUSE_SASH" = "yes"; then
2421     AC_DEFINE(wxUSE_SASH)
2422     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sashtest"
2423 fi
2424
2425 if test "$wxUSE_SCROLLBAR" = "yes"; then
2426     AC_DEFINE(wxUSE_SCROLLBAR)
2427     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS scroll"
2428 fi
2429
2430 if test "$wxUSE_SLIDER" = "yes"; then
2431     AC_DEFINE(wxUSE_SLIDER)
2432 fi
2433
2434 if test "$wxUSE_SPINBTN" = "yes"; then
2435     AC_DEFINE(wxUSE_SPINBTN)
2436 fi
2437
2438 if test "$wxUSE_SPLITTER" = "yes"; then
2439     AC_DEFINE(wxUSE_SPLITTER)
2440     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splitter"
2441 fi
2442
2443 if test "$wxUSE_STATBMP" = "yes"; then
2444     AC_DEFINE(wxUSE_STATBMP)
2445 fi
2446
2447 if test "$wxUSE_STATBOX" = "yes"; then
2448     AC_DEFINE(wxUSE_STATBOX)
2449 fi
2450
2451 if test "$wxUSE_STATLINE" = "yes"; then
2452     if test "$wxUSE_WINE" = 1 ; then
2453         AC_MSG_WARN([wxStaticLine is not supported under WINE])
2454     else
2455         if test "$wxUSE_MOTIF" = 1 ; then
2456             AC_MSG_WARN([wxStaticLine is not supported under Motif])
2457         else
2458             AC_DEFINE(wxUSE_STATLINE)
2459         fi
2460     fi
2461 fi
2462
2463 if test "$wxUSE_STATUSBAR" = "yes"; then
2464     AC_DEFINE(wxUSE_STATUSBAR)
2465 fi
2466
2467 if test "$wxUSE_TABDIALOG" = "yes"; then
2468     AC_DEFINE(wxUSE_TAB_DIALOG)
2469     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS tab"
2470 fi
2471
2472 if test "$wxUSE_TOOLBAR" = "yes"; then
2473     AC_DEFINE(wxUSE_TOOLBAR)
2474     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS toolbar"
2475 fi
2476
2477 if test "$wxUSE_TOOLTIPS" = "yes"; then
2478     if test "$wxUSE_MOTIF" = 1; then
2479         AC_MSG_WARN(wxTooltip not supported yet under Motif)
2480     else
2481         if test "$wxUSE_WINE" = 1; then
2482             AC_MSG_WARN(wxTooltip not supported under WINE)
2483         else
2484             AC_DEFINE(wxUSE_TOOLTIPS)
2485         fi
2486     fi
2487 fi
2488
2489 if test "$wxUSE_TREECTRL" = "yes"; then
2490     if test "$wxUSE_IMAGLIST" = "yes"; then
2491         AC_DEFINE(wxUSE_TREECTRL)
2492         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS treectrl"
2493     else
2494         AC_MSG_WARN([wxTreeCtrl requires wxImageList and won't be compiled without it])
2495     fi
2496 fi
2497
2498 dnl ---------------------------------------------------------------------------
2499 dnl misc options
2500 dnl ---------------------------------------------------------------------------
2501
2502 dnl TODO this is unused for now...
2503 dnl if test "$wxUSE_WXTREE" = "yes"; then
2504 dnl   AC_DEFINE(wxUSE_WXTREE)
2505 dnl fi
2506
2507 if test "$wxUSE_METAFILE" = "yes"; then
2508     AC_DEFINE(wxUSE_METAFILE)
2509 fi
2510
2511 if test "$wxUSE_DIRDLG" = "yes"; then
2512     if test "$wxUSE_CONSTRAINTS" != "yes"; then
2513        AC_MSG_WARN(wxDirDialog requires constraints so it won't be compiled without them)
2514     else
2515         if test "$wxUSE_TREECTRL" != "yes"; then
2516             AC_MSG_WARN(wxDirDialog requires wxTreeCtrl so it won't be compiled without it)
2517         else
2518             AC_DEFINE(wxUSE_DIRDLG)
2519         fi
2520     fi
2521 fi
2522
2523 if test "$wxUSE_TEXTDLG" = "yes"; then
2524     AC_DEFINE(wxUSE_TEXTDLG)
2525 fi
2526
2527 if test "$wxUSE_STARTUP_TIPS" = "yes"; then
2528     if test "$wxUSE_CONSTRAINTS" != "yes"; then
2529        AC_MSG_WARN(Startup tips requires constraints and won't be compiled without them)
2530     else
2531         AC_DEFINE(wxUSE_STARTUP_TIPS)
2532     fi
2533 fi
2534
2535 if test "$wxUSE_PROGRESSDLG" = "yes"; then
2536     if test "$wxUSE_CONSTRAINTS" != "yes"; then
2537        AC_MSG_WARN(wxProgressDialog requires constraints so it won't be compiled without them)
2538     else
2539         AC_DEFINE(wxUSE_PROGRESSDLG)
2540     fi
2541 fi
2542
2543 if test "$wxUSE_MINIFRAME" = "yes"; then
2544     AC_DEFINE(wxUSE_MINIFRAME)
2545     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS minifram"
2546 fi
2547
2548 if test "$wxUSE_HTML" = "yes"; then
2549     AC_DEFINE(wxUSE_HTML)
2550     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html"
2551     INCLUDE_SUBDIRS="$INCLUDE_SUBDIRS html"
2552 fi
2553
2554 if test "$wxUSE_VALIDATORS" = "yes"; then
2555     AC_DEFINE(wxUSE_VALIDATORS)
2556     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS validate"
2557 fi
2558
2559 dnl ---------------------------------------------------------------------------
2560 dnl Output the makefiles and such from the results found above
2561 dnl ---------------------------------------------------------------------------
2562
2563 dnl if we add wxUSE_GUI in the future, it might be handy to separate the libs
2564 dnl into GUI and non-GUI parts
2565 GUILIBS="$GUI_TK_LIBRARY $OPENGL_LINK $LIBPNG_LINK $ZLIB_LINK $TOOLKIT_LINK"
2566
2567 dnl all additional libraries (except wxWindows itself) we link with
2568 EXTRA_LIBS="$LIBS $POSIX4_LINK $WCHAR_LINK $THREADS_LINK $DMALLOC_LINK $GUILIBS"
2569
2570 dnl all the libraries needed to link wxWindows programs (when the library is not
2571 dnl yet installed)
2572 LIBS="\${top_builddir}/src/${TOOLKIT_DIR}/${WX_LIBRARY_NAME} $EXTRA_LIBS"
2573
2574 dnl all the libraries needed to link wxWindows programs when using the
2575 dnl makefile system without libtool
2576 LD_LIBS="\${top_builddir}/lib/${WX_LIBRARY_NAME_STATIC} $EXTRA_LIBS"
2577
2578 dnl all -I options we must pass to the compiler
2579 INCLUDES="-I. -I\${top_builddir}/include -I\${top_srcdir}/include $ZLIB_INCLUDE $PNG_INCLUDE $JPEG_INCLUDE $TOOLKIT_INCLUDE"
2580
2581 dnl C/C++ compiler options used to compile wxWindows
2582 if test "$GXX" = yes ; then
2583     dnl CXXWARNINGS="-Wall -W -Wcast-qual -Werror"
2584     CXXWARNINGS="-Wall"
2585     dnl there is one weird warning in docview.h:71 which prevents me from doing
2586     dnl this...
2587     dnl CXXWARNINGS="-Wall -Werror"
2588 fi
2589 EXTRA_CFLAGS="$WXDEBUG $PROFILE $OPTIMISE $INCLUDES"
2590
2591 CPPFLAGS="-I\${top_srcdir}/include $CPPFLAGS"
2592 CFLAGS="$CFLAGS $EXTRA_CFLAGS"
2593 CXXFLAGS="$CXXFLAGS $EXTRA_CFLAGS $CXXWARNINGS"
2594
2595 if test "$wxUSE_GUI" = "yes"; then
2596     dnl TODO add checks that these samples will really compile (i.e. all the
2597     dnl      library features they need are present)
2598
2599     dnl TODO some samples are never built so far:
2600     dnl      mfc, nativdlg, oleauto, ownerdrw, proplist
2601     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS bombs controls dialogs drawing dynamic \
2602                      forty fractal image wxpoem"
2603 fi
2604
2605 dnl for convenience, sort the samples in alphabetical order
2606 dnl
2607 dnl FIXME For some mysterious reasons, sometimes the directories are duplicated
2608 dnl       in this list - hence uniq. But normally, this shouldn't be needed!
2609 SAMPLES_SUBDIRS="`echo $SAMPLES_SUBDIRS | tr -s ' ' | tr ' ' '\n' | sort | uniq | tr '\n' ' '`"
2610
2611 dnl global options
2612 AC_SUBST(WX_MAJOR_VERSION_NUMBER)
2613 AC_SUBST(WX_MINOR_VERSION_NUMBER)
2614 AC_SUBST(WX_RELEASE_NUMBER)
2615 AC_SUBST(WX_LIBRARY_NAME)
2616 AC_SUBST(WX_LIBRARY_NAME_STATIC)
2617 AC_SUBST(WX_LIBRARY_NAME_SHARED)
2618 AC_SUBST(WX_LIBRARY)
2619 AC_SUBST(WX_TARGET_LIBRARY)
2620 AC_SUBST(WX_LIBRARY_LINK1)
2621 AC_SUBST(WX_LIBRARY_LINK2)
2622 AC_SUBST(WX_LIBRARY_LINK3)
2623
2624 dnl are we supposed to create the links?
2625 AC_SUBST(WX_CREATE_LINKS)
2626 AC_SUBST(WX_CREATE_INSTALLED_LINKS)
2627
2628 AC_SUBST(SHARED_LD)
2629 AC_SUBST(PIC_FLAG)
2630
2631 dnl debugging options
2632 AC_SUBST(WXDEBUG_DEFINE)
2633
2634 dnl toolkit options
2635 AC_SUBST(TOOLKIT)
2636 AC_SUBST(TOOLKIT_DEF)
2637 AC_SUBST(TOOLKIT_DIR)
2638 AC_SUBST(TOOLKIT_INCLUDE)
2639
2640 dnl what to compile
2641 AC_SUBST(GUIOBJS)
2642 AC_SUBST(GUIHEADERS)
2643 AC_SUBST(COMMONOBJS)
2644 AC_SUBST(GENERICOBJS)
2645
2646 dnl additional subdirectories where we will build
2647 AC_SUBST(SRC_SUBDIRS)
2648 AC_SUBST(INCLUDE_SUBDIRS)
2649 AC_SUBST(UTILS_SUBDIRS)
2650 AC_SUBST(DOCS_SUBDIRS)
2651 AC_SUBST(SAMPLES_SUBDIRS)
2652 AC_SUBST(USER_SUBDIRS)
2653
2654 dnl additional libraries
2655 AC_SUBST(EXTRA_LIBS)
2656 AC_SUBST(LIBS)
2657 AC_SUBST(LD_LIBS)
2658
2659 dnl MAKE_SET will be replaced with "MAKE=..." or nothing if make sets MAKE
2660 dnl itself (this is macro is required if SUBDIRS variable is used in Makefile.am
2661 dnl - and we do use it)
2662 AC_PROG_MAKE_SET
2663
2664 AC_CONFIG_HEADER(setup.h:setup.h.in)
2665
2666
2667 dnl create each of the files in the space separated list from the file.in
2668 dnl (the original file name may be overriden by appending another name after a
2669 dnl colon)
2670 AC_OUTPUT([
2671             wx-config
2672             src/make.env
2673             src/makeprog.env
2674             src/makelib.env
2675             Makefile
2676             samples/Makefile
2677             samples/bombs/Makefile
2678             samples/caret/Makefile
2679             samples/checklst/Makefile
2680             samples/config/Makefile
2681             samples/controls/Makefile
2682           ],
2683           [
2684             chmod +x wx-config
2685             if test ! -d include; then
2686               mkdir include
2687             fi
2688             if test ! -d include/wx; then
2689               mkdir include/wx
2690             fi
2691             if test ! -d include/wx/${TOOLKIT_DIR}; then
2692               mkdir include/wx/${TOOLKIT_DIR}
2693             fi
2694             cp -f setup.h include/wx/${TOOLKIT_DIR}/setup.h
2695           ],
2696           [
2697             LN_S="${ac_cv_prog_LN_S}"
2698             TOOLKIT_DIR="${TOOLKIT_DIR}"
2699           ]
2700          )
2701