src/osx/carbon/colordlgosx.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/carbon/colordlgosx.mm
   3 // Purpose:     wxColourDialog class. NOTE: you can use the generic class
   4 //              if you wish, instead of implementing this.
   5 // Author:      Ryan Norton
   6 // Modified by:
   7 // Created:     2004-11-16
   8 // RCS-ID:      $Id$
   9 // Copyright:   (c) Ryan Norton
  10 // Licence:       wxWindows licence
  11 /////////////////////////////////////////////////////////////////////////////
  12
  13 // ===========================================================================
  14 // declarations
  15 // ===========================================================================
  16
  17 // ---------------------------------------------------------------------------
  18 // headers
  19 // ---------------------------------------------------------------------------
  20
  21 #include "wx/wxprec.h"
  22
  23 #include "wx/colordlg.h"
  24 #include "wx/fontdlg.h"
  25 #include "wx/testing.h"
  26
  27 // ============================================================================
  28 // implementation
  29 // ============================================================================
  30
  31 //Mac OSX 10.2+ only
  32 #if USE_NATIVE_FONT_DIALOG_FOR_MACOSX
  33
  34 IMPLEMENT_DYNAMIC_CLASS(wxColourDialog, wxDialog)
  35
  36 #include "wx/osx/private.h"
  37
  38 #import <Foundation/Foundation.h>
  39 #import <AppKit/AppKit.h>
  40
  41 // ---------------------------------------------------------------------------
  42 // wxCPWCDelegate - Window Closed delegate
  43 // ---------------------------------------------------------------------------
  44
  45 @interface wxCPWCDelegate : NSObject wxOSX_10_6_AND_LATER(<NSWindowDelegate>)
  46 {
  47     bool m_bIsClosed;
  48 }
  49
  50 // Delegate methods
  51 - (id)init;
  52 - (BOOL)windowShouldClose:(id)sender;
  53 - (BOOL)isClosed;
  54 @end // interface wxNSFontPanelDelegate : NSObject
  55
  56 @implementation wxCPWCDelegate : NSObject
  57
  58 - (id)init
  59 {
  60     self = [super init];
  61     m_bIsClosed = false;
  62
  63     return self;
  64 }
  65
  66 - (BOOL)windowShouldClose:(id)sender
  67 {
  68     wxUnusedVar(sender);
  69
  70     m_bIsClosed = true;
  71
  72     [NSApp abortModal];
  73     [NSApp stopModal];
  74     return YES;
  75 }
  76
  77 - (BOOL)isClosed
  78 {
  79     return m_bIsClosed;
  80 }
  81
  82 @end // wxNSFontPanelDelegate
  83
  84 /*
  85  * wxColourDialog
  86  */
  87
  88 wxColourDialog::wxColourDialog()
  89 {
  90     m_dialogParent = NULL;
  91 }
  92
  93 wxColourDialog::wxColourDialog(wxWindow *parent, wxColourData *data)
  94 {
  95     Create(parent, data);
  96 }
  97
  98 bool wxColourDialog::Create(wxWindow *parent, wxColourData *data)
  99 {
 100     m_dialogParent = parent;
 101
 102     if (data)
 103         m_colourData = *data;
 104
 105     //autorelease pool - req'd for carbon
 106     NSAutoreleasePool *thePool;
 107     thePool = [[NSAutoreleasePool alloc] init];
 108
 109     if(m_colourData.GetColour().IsOk())
 110         [[NSColorPanel sharedColorPanel] setColor:
 111             [NSColor colorWithCalibratedRed:(CGFloat) (m_colourData.GetColour().Red() / 255.0)
 112                                         green:(CGFloat) (m_colourData.GetColour().Green() / 255.0)
 113                                         blue:(CGFloat) (m_colourData.GetColour().Blue() / 255.0)
 114                                         alpha:(CGFloat) 1.0]
 115         ];
 116     else
 117         [[NSColorPanel sharedColorPanel] setColor:[NSColor blackColor]];
 118
 119     //We're done - free up the pool
 120     [thePool release];
 121
 122     return true;
 123 }
 124 int wxColourDialog::ShowModal()
 125 {
 126     WX_TESTING_SHOW_MODAL_HOOK();
 127
 128     //Start the pool.  Required for carbon interaction
 129     //(For those curious, the only thing that happens
 130     //if you don't do this is a bunch of error
 131     //messages about leaks on the console,
 132     //with no windows shown or anything).
 133     NSAutoreleasePool *thePool;
 134     thePool = [[NSAutoreleasePool alloc] init];
 135
 136     //Get the shared color and font panel
 137     NSColorPanel* theColorPanel = [NSColorPanel sharedColorPanel];
 138
 139     //Create and assign the delegates (cocoa event handlers) so
 140     //we can tell if a window has closed/open or not
 141     wxCPWCDelegate* theCPDelegate = [[wxCPWCDelegate alloc] init];
 142     [theColorPanel setDelegate:theCPDelegate];
 143
 144             //
 145             //  Start the color panel modal loop
 146             //
 147             wxDialog::OSXBeginModalDialog();
 148             NSModalSession session = [NSApp beginModalSessionForWindow:theColorPanel];
 149             for (;;)
 150             {
 151                 [NSApp runModalSession:session];
 152
 153                 //If the color panel is closed, return the font panel modal loop
 154                 if ([theCPDelegate isClosed])
 155                     break;
 156             }
 157             [NSApp endModalSession:session];
 158             wxDialog::OSXEndModalDialog();
 159
 160     //free up the memory for the delegates - we don't need them anymore
 161     [theColorPanel setDelegate:nil];
 162     [theCPDelegate release];
 163
 164     //Get the shared color panel along with the chosen color and set the chosen color
 165     NSColor* theColor = [[theColorPanel color] colorUsingColorSpaceName:NSCalibratedRGBColorSpace];
 166
 167     m_colourData.GetColour().Set(
 168                                 (unsigned char) ([theColor redComponent] * 255.0),
 169                                 (unsigned char) ([theColor greenComponent] * 255.0),
 170                                 (unsigned char) ([theColor blueComponent] * 255.0)
 171                                    );
 172
 173     //Release the pool, we're done :)
 174     [thePool release];
 175
 176     //Return ID_OK - there are no "apply" buttons or the like
 177     //on either the font or color panel
 178     return wxID_OK;
 179 }
 180
 181 #endif //use native font dialog
 182