src/osx/cocoa/textctrl.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/textctrl.mm
   3 // Purpose:     wxTextCtrl
   4 // Author:      Stefan Csomor
   5 // Modified by: Ryan Norton (MLTE GetLineLength and GetLineText)
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: textctrl.cpp 54820 2008-07-29 20:04:11Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_TEXTCTRL
  15
  16 #include "wx/textctrl.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/intl.h"
  20     #include "wx/app.h"
  21     #include "wx/utils.h"
  22     #include "wx/dc.h"
  23     #include "wx/button.h"
  24     #include "wx/menu.h"
  25     #include "wx/settings.h"
  26     #include "wx/msgdlg.h"
  27     #include "wx/toplevel.h"
  28 #endif
  29
  30 #ifdef __DARWIN__
  31     #include <sys/types.h>
  32     #include <sys/stat.h>
  33 #else
  34     #include <stat.h>
  35 #endif
  36
  37 #if wxUSE_STD_IOSTREAM
  38     #if wxUSE_IOSTREAMH
  39         #include <fstream.h>
  40     #else
  41         #include <fstream>
  42     #endif
  43 #endif
  44
  45 #include "wx/filefn.h"
  46 #include "wx/sysopt.h"
  47 #include "wx/thread.h"
  48
  49 #include "wx/osx/private.h"
  50 #include "wx/osx/cocoa/private/textimpl.h"
  51
  52 @interface NSView(EditableView)
  53 - (BOOL)isEditable;
  54 - (void)setEditable:(BOOL)flag;
  55 @end
  56
  57 class wxMacEditHelper
  58 {
  59 public :
  60     wxMacEditHelper( NSView* textView )
  61     {
  62         m_textView = textView ;
  63         if ( textView )
  64         {
  65             m_formerState = [textView isEditable];
  66             [textView setEditable:YES];
  67         }
  68     }
  69
  70     ~wxMacEditHelper()
  71     {
  72         if ( m_textView )
  73             [m_textView setEditable:m_formerState];
  74     }
  75
  76 protected :
  77     BOOL m_formerState ;
  78     NSView* m_textView;
  79 } ;
  80
  81 @implementation wxNSSecureTextField
  82
  83 + (void)initialize
  84 {
  85     static BOOL initialized = NO;
  86     if (!initialized)
  87     {
  88         initialized = YES;
  89         wxOSXCocoaClassAddWXMethods( self );
  90     }
  91 }
  92
  93 - (void)controlTextDidChange:(NSNotification *)aNotification
  94 {
  95     wxUnusedVar(aNotification);
  96     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  97     if ( impl )
  98     {
  99         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 100         if ( wxpeer ) {
 101             wxCommandEvent event(wxEVT_COMMAND_TEXT_UPDATED, wxpeer->GetId());
 102             event.SetEventObject( wxpeer );
 103             event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
 104             wxpeer->HandleWindowEvent( event );
 105         }
 106     }
 107 }
 108
 109 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 110 {
 111     wxUnusedVar(aNotification);
 112     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 113     if ( impl )
 114     {
 115         impl->DoNotifyFocusEvent( false, NULL );
 116     }
 117 }
 118
 119 @end
 120
 121 @interface wxNSTextScrollView : NSScrollView
 122 {
 123 }
 124 @end
 125
 126 @implementation wxNSTextScrollView
 127
 128 + (void)initialize
 129 {
 130     static BOOL initialized = NO;
 131     if (!initialized)
 132     {
 133         initialized = YES;
 134         wxOSXCocoaClassAddWXMethods( self );
 135     }
 136 }
 137
 138 @end
 139
 140 @implementation wxNSTextFieldEditor
 141
 142 - (void) keyDown:(NSEvent*) event
 143 {
 144     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 145     lastKeyDownEvent = event;
 146     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 147         [super keyDown:event];
 148     lastKeyDownEvent = nil;
 149 }
 150
 151 - (void) keyUp:(NSEvent*) event
 152 {
 153     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 154     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 155         [super keyUp:event];
 156 }
 157
 158 - (void) flagsChanged:(NSEvent*) event
 159 {
 160     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 161     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 162         [super flagsChanged:event];
 163 }
 164
 165 - (BOOL) performKeyEquivalent:(NSEvent*) event
 166 {
 167     BOOL retval = [super performKeyEquivalent:event];
 168     return retval;
 169 }
 170
 171 - (void) insertText:(id) str
 172 {
 173     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 174     if ( impl == NULL || lastKeyDownEvent==nil || !impl->DoHandleCharEvent(lastKeyDownEvent, str) )
 175     {
 176         [super insertText:str];
 177     }
 178 }
 179
 180 @end
 181
 182 @implementation wxNSTextView
 183
 184 + (void)initialize
 185 {
 186     static BOOL initialized = NO;
 187     if (!initialized)
 188     {
 189         initialized = YES;
 190         wxOSXCocoaClassAddWXMethods( self );
 191     }
 192 }
 193
 194 @end
 195
 196 @implementation wxNSTextField
 197
 198 + (void)initialize
 199 {
 200     static BOOL initialized = NO;
 201     if (!initialized)
 202     {
 203         initialized = YES;
 204         wxOSXCocoaClassAddWXMethods( self );
 205     }
 206 }
 207
 208 - (id) initWithFrame:(NSRect) frame
 209 {
 210     self = [super initWithFrame:frame];
 211     fieldEditor = nil;
 212     return self;
 213 }
 214
 215 - (void) dealloc
 216 {
 217     [fieldEditor release];
 218     [super dealloc];
 219 }
 220
 221 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
 222 {
 223     fieldEditor = editor;
 224 }
 225
 226 - (wxNSTextFieldEditor*) fieldEditor
 227 {
 228     return fieldEditor;
 229 }
 230
 231
 232 - (void) setEnabled:(BOOL) flag
 233 {
 234     [super setEnabled: flag];
 235
 236     if (![self drawsBackground]) {
 237         // Static text is drawn incorrectly when disabled.
 238         // For an explanation, see
 239         // http://www.cocoabuilder.com/archive/message/cocoa/2006/7/21/168028
 240         if (flag) {
 241             [self setTextColor: [NSColor controlTextColor]];
 242         } else {
 243             [self setTextColor: [NSColor secondarySelectedControlColor]];
 244         }
 245     }
 246 }
 247
 248 - (void)controlTextDidChange:(NSNotification *)aNotification
 249 {
 250     wxUnusedVar(aNotification);
 251     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 252     if ( impl )
 253     {
 254         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 255         if ( wxpeer ) {
 256             wxCommandEvent event(wxEVT_COMMAND_TEXT_UPDATED, wxpeer->GetId());
 257             event.SetEventObject( wxpeer );
 258             event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
 259             wxpeer->HandleWindowEvent( event );
 260         }
 261     }
 262 }
 263
 264 typedef BOOL (*wxOSX_insertNewlineHandlerPtr)(NSView* self, SEL _cmd, NSControl *control, NSTextView* textView, SEL commandSelector);
 265
 266 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 267 {
 268     wxUnusedVar(textView);
 269     wxUnusedVar(control);
 270     if (commandSelector == @selector(insertNewline:))
 271     {
 272         wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 273         if ( impl  )
 274         {
 275             wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 276             if ( wxpeer && wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER )
 277             {
 278                 wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 279                 event.SetEventObject( wxpeer );
 280                 event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
 281                 wxpeer->HandleWindowEvent( event );
 282             }
 283         }
 284     }
 285
 286     return NO;
 287 }
 288
 289 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 290 {
 291     wxUnusedVar(aNotification);
 292     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 293     if ( impl )
 294     {
 295         impl->DoNotifyFocusEvent( false, NULL );
 296     }
 297 }
 298 @end
 299
 300 // wxNSTextViewControl
 301
 302 wxNSTextViewControl::wxNSTextViewControl( wxTextCtrl *wxPeer, WXWidget w ) : wxWidgetCocoaImpl(wxPeer, w)
 303 {
 304     wxNSTextScrollView* sv = (wxNSTextScrollView*) w;
 305     m_scrollView = sv;
 306
 307     [m_scrollView setHasVerticalScroller:YES];
 308     [m_scrollView setHasHorizontalScroller:NO];
 309     [m_scrollView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
 310     NSSize contentSize = [m_scrollView contentSize];
 311
 312     wxNSTextView* tv = [[wxNSTextView alloc] initWithFrame: NSMakeRect(0, 0,
 313             contentSize.width, contentSize.height)];
 314     m_textView = tv;
 315     [tv setVerticallyResizable:YES];
 316     [tv setHorizontallyResizable:NO];
 317     [tv setAutoresizingMask:NSViewWidthSizable];
 318
 319     [m_scrollView setDocumentView: tv];
 320
 321     [tv setDelegate: w];
 322
 323     InstallEventHandler(tv);
 324 }
 325
 326 wxNSTextViewControl::~wxNSTextViewControl()
 327 {
 328     if (m_textView)
 329         [m_textView setDelegate: nil];
 330 }
 331
 332 wxString wxNSTextViewControl::GetStringValue() const
 333 {
 334     if (m_textView)
 335     {
 336         wxString result = wxCFStringRef::AsString([m_textView string], m_wxPeer->GetFont().GetEncoding());
 337         wxMacConvertNewlines13To10( &result ) ;
 338         return result;
 339     }
 340     return wxEmptyString;
 341 }
 342 void wxNSTextViewControl::SetStringValue( const wxString &str)
 343 {
 344     wxString st = str;
 345     wxMacConvertNewlines10To13( &st );
 346     wxMacEditHelper helper(m_textView);
 347
 348     if (m_textView)
 349         [m_textView setString: wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 350 }
 351
 352 void wxNSTextViewControl::Copy()
 353 {
 354     if (m_textView)
 355         [m_textView copy:nil];
 356
 357 }
 358
 359 void wxNSTextViewControl::Cut()
 360 {
 361     if (m_textView)
 362         [m_textView cut:nil];
 363 }
 364
 365 void wxNSTextViewControl::Paste()
 366 {
 367     if (m_textView)
 368         [m_textView paste:nil];
 369 }
 370
 371 bool wxNSTextViewControl::CanPaste() const
 372 {
 373     return true;
 374 }
 375
 376 void wxNSTextViewControl::SetEditable(bool editable)
 377 {
 378     if (m_textView)
 379         [m_textView setEditable: editable];
 380 }
 381
 382 void wxNSTextViewControl::GetSelection( long* from, long* to) const
 383 {
 384     if (m_textView)
 385     {
 386         NSRange range = [m_textView selectedRange];
 387         *from = range.location;
 388         *to = range.location + range.length;
 389     }
 390 }
 391
 392 void wxNSTextViewControl::SetSelection( long from , long to )
 393 {
 394     long textLength = [[m_textView string] length];
 395     if ((from == -1) && (to == -1))
 396     {
 397         from = 0 ;
 398         to = textLength ;
 399     }
 400     else
 401     {
 402         from = wxMin(textLength,wxMax(from,0)) ;
 403         if ( to == -1 )
 404             to = textLength;
 405         else
 406             to = wxMax(0,wxMin(textLength,to)) ;
 407     }
 408
 409     NSRange selrange = NSMakeRange(from, to-from);
 410     [m_textView setSelectedRange:selrange];
 411     [m_textView scrollRangeToVisible:selrange];
 412 }
 413
 414 void wxNSTextViewControl::WriteText(const wxString& str)
 415 {
 416     wxString st = str;
 417     wxMacConvertNewlines10To13( &st );
 418     wxMacEditHelper helper(m_textView);
 419
 420     [m_textView insertText:wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 421 }
 422
 423 void wxNSTextViewControl::SetFont( const wxFont & font , const wxColour& foreground , long windowStyle, bool ignoreBlack )
 424 {
 425     if ([m_textView respondsToSelector:@selector(setFont:)])
 426         [m_textView setFont: font.OSXGetNSFont()];
 427 }
 428
 429
 430 // wxNSTextFieldControl
 431
 432 wxNSTextFieldControl::wxNSTextFieldControl( wxTextCtrl *wxPeer, WXWidget w ) : wxWidgetCocoaImpl(wxPeer, w)
 433 {
 434     m_textField = (NSTextField*) w;
 435     [m_textField setDelegate: w];
 436     m_selStart = m_selEnd = 0;
 437     m_hasEditor = [w isKindOfClass:[NSTextField class]];
 438 }
 439
 440 wxNSTextFieldControl::~wxNSTextFieldControl()
 441 {
 442     if (m_textField)
 443         [m_textField setDelegate: nil];
 444 }
 445
 446 wxString wxNSTextFieldControl::GetStringValue() const
 447 {
 448     return wxCFStringRef::AsString([m_textField stringValue], m_wxPeer->GetFont().GetEncoding());
 449 }
 450
 451 void wxNSTextFieldControl::SetStringValue( const wxString &str)
 452 {
 453     wxMacEditHelper helper(m_textField);
 454     [m_textField setStringValue: wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 455 }
 456
 457 void wxNSTextFieldControl::Copy()
 458 {
 459     NSText* editor = [m_textField currentEditor];
 460     if ( editor )
 461     {
 462         [editor copy:nil];
 463     }
 464 }
 465
 466 void wxNSTextFieldControl::Cut()
 467 {
 468     NSText* editor = [m_textField currentEditor];
 469     if ( editor )
 470     {
 471         [editor cut:nil];
 472     }
 473 }
 474
 475 void wxNSTextFieldControl::Paste()
 476 {
 477     NSText* editor = [m_textField currentEditor];
 478     if ( editor )
 479     {
 480         [editor paste:nil];
 481     }
 482 }
 483
 484 bool wxNSTextFieldControl::CanPaste() const
 485 {
 486     return true;
 487 }
 488
 489 void wxNSTextFieldControl::SetEditable(bool editable)
 490 {
 491     [m_textField setEditable:editable];
 492 }
 493
 494 void wxNSTextFieldControl::GetSelection( long* from, long* to) const
 495 {
 496     NSText* editor = [m_textField currentEditor];
 497     if ( editor )
 498     {
 499         NSRange range = [editor selectedRange];
 500         *from = range.location;
 501         *to = range.location + range.length;
 502     }
 503     else
 504     {
 505         *from = m_selStart;
 506         *to = m_selEnd;
 507     }
 508 }
 509
 510 void wxNSTextFieldControl::SetSelection( long from , long to )
 511 {
 512     long textLength = [[m_textField stringValue] length];
 513     if ((from == -1) && (to == -1))
 514     {
 515         from = 0 ;
 516         to = textLength ;
 517     }
 518     else
 519     {
 520         from = wxMin(textLength,wxMax(from,0)) ;
 521         if ( to == -1 )
 522             to = textLength;
 523         else
 524             to = wxMax(0,wxMin(textLength,to)) ;
 525     }
 526
 527     NSText* editor = [m_textField currentEditor];
 528     if ( editor )
 529     {
 530         [editor setSelectedRange:NSMakeRange(from, to-from)];
 531     }
 532     else
 533     {
 534         m_selStart = from;
 535         m_selEnd = to;
 536     }
 537 }
 538
 539 void wxNSTextFieldControl::WriteText(const wxString& str)
 540 {
 541     NSText* editor = [m_textField currentEditor];
 542     if ( editor )
 543     {
 544         wxMacEditHelper helper(m_textField);
 545         [editor insertText:wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 546     }
 547     else
 548     {
 549         wxString val = GetStringValue() ;
 550         long start , end ;
 551         GetSelection( &start , &end ) ;
 552         val.Remove( start , end - start ) ;
 553         val.insert( start , str ) ;
 554         SetStringValue( val ) ;
 555         SetSelection( start + str.length() , start + str.length() ) ;
 556     }
 557 }
 558
 559 void wxNSTextFieldControl::controlAction(WXWidget WXUNUSED(slf),
 560     void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 561 {
 562     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
 563     if ( wxpeer && (wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER) )
 564     {
 565         wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 566         event.SetEventObject( wxpeer );
 567         event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
 568         wxpeer->HandleWindowEvent( event );
 569     }
 570 }
 571
 572 //
 573 //
 574 //
 575
 576 wxWidgetImplType* wxWidgetImpl::CreateTextControl( wxTextCtrl* wxpeer,
 577                                     wxWindowMac* WXUNUSED(parent),
 578                                     wxWindowID WXUNUSED(id),
 579                                     const wxString& str,
 580                                     const wxPoint& pos,
 581                                     const wxSize& size,
 582                                     long style,
 583                                     long WXUNUSED(extraStyle))
 584 {
 585     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 586     wxWidgetCocoaImpl* c = NULL;
 587
 588     if ( style & wxTE_MULTILINE || style & wxTE_RICH || style & wxTE_RICH2 )
 589     {
 590         wxNSTextScrollView* v = nil;
 591         v = [[wxNSTextScrollView alloc] initWithFrame:r];
 592         c = new wxNSTextViewControl( wxpeer, v );
 593         static_cast<wxNSTextViewControl*>(c)->SetStringValue(str);
 594     }
 595     else
 596     {
 597         NSTextField* v = nil;
 598         if ( style & wxTE_PASSWORD )
 599             v = [[wxNSSecureTextField alloc] initWithFrame:r];
 600         else
 601             v = [[wxNSTextField alloc] initWithFrame:r];
 602
 603         if ( style & wxNO_BORDER )
 604         {
 605             // FIXME: How can we remove the native control's border?
 606             // setBordered is separate from the text ctrl's border.
 607         }
 608
 609         [v setBezeled:NO];
 610         [v setBordered:NO];
 611
 612         c = new wxNSTextFieldControl( wxpeer, v );
 613         static_cast<wxNSTextFieldControl*>(c)->SetStringValue(str);
 614     }
 615
 616     return c;
 617 }
 618
 619
 620 #endif // wxUSE_TEXTCTRL