src/osx/cocoa/menu.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/menu.mm
   3 // Purpose:     wxMenu, wxMenuBar, wxMenuItem
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: menu.cpp 54129 2008-06-11 19:30:52Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ============================================================================
  13 // headers & declarations
  14 // ============================================================================
  15
  16 // wxWidgets headers
  17 // -----------------
  18
  19 #include "wx/wxprec.h"
  20
  21 #include "wx/menu.h"
  22
  23 #ifndef WX_PRECOMP
  24     #include "wx/log.h"
  25     #include "wx/app.h"
  26     #include "wx/utils.h"
  27     #include "wx/frame.h"
  28     #include "wx/menuitem.h"
  29 #endif
  30
  31 #include "wx/osx/private.h"
  32
  33 // other standard headers
  34 // ----------------------
  35 #include <string.h>
  36
  37 @implementation wxNSMenu
  38
  39 - (id) init
  40 {
  41     [super init];
  42     impl = NULL;
  43     return self;
  44 }
  45
  46 - (void)setImplementation: (wxMenuImpl *) theImplementation
  47 {
  48     impl = theImplementation;
  49 }
  50
  51 - (wxMenuImpl*) implementation
  52 {
  53     return impl;
  54 }
  55
  56 @end
  57
  58 @interface wxNSMenuController : NSObject
  59 {
  60 }
  61
  62 - (void)menuWillOpen:(NSMenu *)menu;
  63 - (void)menuDidClose:(NSMenu *)menu;
  64 - (void)menu:(NSMenu *)menu willHighlightItem:(NSMenuItem *)item;
  65
  66 @end
  67
  68 @implementation wxNSMenuController
  69
  70 - (id) init
  71 {
  72     [super init];
  73     return self;
  74 }
  75
  76 - (void)menuWillOpen:(NSMenu *)smenu
  77 {
  78     wxNSMenu* menu = (wxNSMenu*) smenu;
  79     wxMenuImpl* menuimpl = [menu implementation];
  80     if ( menuimpl )
  81     {
  82         wxMenu* wxpeer = (wxMenu*) menuimpl->GetWXPeer();
  83         if ( wxpeer )
  84             wxpeer->HandleMenuOpened();
  85     }
  86 }
  87
  88 - (void)menuDidClose:(NSMenu *)smenu
  89 {
  90     wxNSMenu* menu = (wxNSMenu*) smenu;
  91     wxMenuImpl* menuimpl = [menu implementation];
  92     if ( menuimpl )
  93     {
  94         wxMenu* wxpeer = (wxMenu*) menuimpl->GetWXPeer();
  95         if ( wxpeer )
  96             wxpeer->HandleMenuClosed();
  97     }
  98 }
  99
 100 - (void)menu:(NSMenu *)smenu willHighlightItem:(NSMenuItem *)item
 101 {
 102     wxNSMenu* menu = (wxNSMenu*) smenu;
 103     wxMenuImpl* menuimpl = [menu implementation];
 104     if ( menuimpl )
 105     {
 106         wxMenu* wxpeer = (wxMenu*) menuimpl->GetWXPeer();
 107         if ( [ item isKindOfClass:[wxNSMenuItem class] ] )
 108         {
 109             wxMenuItemImpl* menuitemimpl = (wxMenuItemImpl*) [ (wxNSMenuItem*) item implementation ];
 110             if ( wxpeer && menuitemimpl )
 111             {
 112                 wxpeer->HandleMenuItemHighlighted( menuitemimpl->GetWXPeer() );
 113             }
 114         }
 115     }
 116 }
 117
 118 @end
 119
 120 @interface NSApplication(MissingAppleMenuCall)
 121 - (void)setAppleMenu:(NSMenu *)menu;
 122 @end
 123
 124 class wxMenuCocoaImpl : public wxMenuImpl
 125 {
 126 public :
 127     wxMenuCocoaImpl( wxMenu* peer , wxNSMenu* menu) : wxMenuImpl(peer), m_osxMenu(menu)
 128     {
 129         static wxNSMenuController* controller = NULL;
 130         if ( controller == NULL )
 131         {
 132             controller = [[wxNSMenuController alloc] init];
 133         }
 134         [menu setDelegate:controller];
 135         [m_osxMenu setImplementation:this];
 136     }
 137
 138     virtual ~wxMenuCocoaImpl();
 139
 140     virtual void InsertOrAppend(wxMenuItem *pItem, size_t pos)
 141     {
 142         if ( pos == (size_t) -1 )
 143             [m_osxMenu addItem:(NSMenuItem*) pItem->GetPeer()->GetHMenuItem() ];
 144         else
 145             [m_osxMenu insertItem:(NSMenuItem*) pItem->GetPeer()->GetHMenuItem() atIndex:pos];
 146     }
 147
 148     virtual void Remove( wxMenuItem *pItem )
 149     {
 150         [m_osxMenu removeItem:(NSMenuItem*) pItem->GetPeer()->GetHMenuItem()];
 151     }
 152
 153     virtual void MakeRoot()
 154     {
 155         [NSApp setMainMenu:m_osxMenu];
 156         [NSApp setAppleMenu:[[m_osxMenu itemAtIndex:0] submenu]];
 157     }
 158
 159     virtual void Enable( bool enable )
 160     {
 161     }
 162
 163     virtual void SetTitle( const wxString& text )
 164     {
 165         wxCFStringRef cfText(text);
 166         [m_osxMenu setTitle:cfText.AsNSString()];
 167     }
 168
 169     virtual void PopUp( wxWindow *win, int x, int y )
 170     {
 171         win->ScreenToClient( &x , &y ) ;
 172         NSView *view = win->GetPeer()->GetWXWidget();
 173         NSRect frame = [view frame];
 174         frame.origin.x = x;
 175         frame.origin.y = y;
 176         frame.size.width = 1;
 177         frame.size.height = 1;
 178         NSPopUpButtonCell *popUpButtonCell = [[NSPopUpButtonCell alloc] initTextCell:@"" pullsDown:NO];
 179         [popUpButtonCell setAutoenablesItems:NO];
 180         [popUpButtonCell setAltersStateOfSelectedItem:NO];
 181         [popUpButtonCell setMenu:m_osxMenu];
 182         [popUpButtonCell selectItem:nil];
 183         [popUpButtonCell performClickWithFrame:frame inView:view];
 184         [popUpButtonCell release];
 185     }
 186
 187     WXHMENU GetHMenu() { return m_osxMenu; }
 188
 189     static wxMenuImpl* Create( wxMenu* peer, const wxString& title );
 190     static wxMenuImpl* CreateRootMenu( wxMenu* peer );
 191 protected :
 192     wxNSMenu* m_osxMenu;
 193 } ;
 194
 195 wxMenuCocoaImpl::~wxMenuCocoaImpl()
 196 {
 197     [m_osxMenu setDelegate:nil];
 198     [m_osxMenu setImplementation:nil];
 199     [m_osxMenu release];
 200 }
 201
 202 wxMenuImpl* wxMenuImpl::Create( wxMenu* peer, const wxString& title )
 203 {
 204     wxCFStringRef cfText( title );
 205     wxNSMenu* menu = [[wxNSMenu alloc] initWithTitle:cfText.AsNSString()];
 206     wxMenuImpl* c = new wxMenuCocoaImpl( peer, menu );
 207     return c;
 208 }