src/osx/cocoa/combobox.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/combobox.mm
   3 // Purpose:     wxChoice
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: combobox.mm 54129 2008-06-11 19:30:52Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_COMBOBOX
  15
  16 #include "wx/combobox.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/menu.h"
  20     #include "wx/dcclient.h"
  21 #endif
  22
  23 #include "wx/osx/cocoa/private/textimpl.h"
  24
  25 // work in progress
  26
  27 @interface wxNSComboBox : NSComboBox
  28 {
  29 }
  30
  31 @end
  32
  33 @implementation wxNSComboBox
  34
  35 + (void)initialize
  36 {
  37     static BOOL initialized = NO;
  38     if (!initialized)
  39     {
  40         initialized = YES;
  41         wxOSXCocoaClassAddWXMethods( self );
  42     }
  43 }
  44
  45 - (void)controlTextDidChange:(NSNotification *)aNotification
  46 {
  47     wxUnusedVar(aNotification);
  48     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  49     if ( impl && impl->ShouldSendEvents() )
  50     {
  51         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
  52         if ( wxpeer ) {
  53             wxCommandEvent event(wxEVT_COMMAND_TEXT_UPDATED, wxpeer->GetId());
  54             event.SetEventObject( wxpeer );
  55             event.SetString( static_cast<wxComboBox*>(wxpeer)->GetValue() );
  56             wxpeer->HandleWindowEvent( event );
  57         }
  58     }
  59 }
  60
  61 - (void)comboBoxSelectionDidChange:(NSNotification *)notification
  62 {
  63     wxUnusedVar(notification);
  64     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  65     if ( impl && impl->ShouldSendEvents())
  66     {
  67         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
  68         if ( wxpeer ) {
  69             wxCommandEvent event(wxEVT_COMMAND_COMBOBOX_SELECTED, wxpeer->GetId());
  70             event.SetEventObject( wxpeer );
  71             event.SetInt( static_cast<wxComboBox*>(wxpeer)->GetSelection() );
  72             // For some reason, wxComboBox::GetValue will not return the newly selected item
  73             // while we're inside this callback, so use AddPendingEvent to make sure
  74             // GetValue() returns the right value.
  75             wxpeer->GetEventHandler()->AddPendingEvent( event );
  76         }
  77     }
  78 }
  79 @end
  80
  81 wxNSComboBoxControl::wxNSComboBoxControl( wxComboBox *wxPeer, WXWidget w )
  82     : wxNSTextFieldControl(wxPeer, wxPeer, w)
  83 {
  84     m_comboBox = (NSComboBox*)w;
  85 }
  86
  87 wxNSComboBoxControl::~wxNSComboBoxControl()
  88 {
  89 }
  90
  91 int wxNSComboBoxControl::GetSelectedItem() const
  92 {
  93     return [m_comboBox indexOfSelectedItem];
  94 }
  95
  96 void wxNSComboBoxControl::SetSelectedItem(int item)
  97 {
  98     SendEvents(false);
  99
 100     if ( item != wxNOT_FOUND )
 101     {
 102         wxASSERT_MSG( item >= 0 && item < [m_comboBox numberOfItems],
 103                       "Inavlid item index." );
 104         [m_comboBox selectItemAtIndex: item];
 105     }
 106     else // remove current selection (if we have any)
 107     {
 108         const int sel = GetSelectedItem();
 109         if ( sel != wxNOT_FOUND )
 110             [m_comboBox deselectItemAtIndex:sel];
 111     }
 112
 113     SendEvents(true);
 114 }
 115
 116 int wxNSComboBoxControl::GetNumberOfItems() const
 117 {
 118     return [m_comboBox numberOfItems];
 119 }
 120
 121 void wxNSComboBoxControl::InsertItem(int pos, const wxString& item)
 122 {
 123     [m_comboBox insertItemWithObjectValue:wxCFStringRef( item , m_wxPeer->GetFont().GetEncoding() ).AsNSString() atIndex:pos];
 124 }
 125
 126 void wxNSComboBoxControl::RemoveItem(int pos)
 127 {
 128     SendEvents(false);
 129     [m_comboBox removeItemAtIndex:pos];
 130     SendEvents(true);
 131 }
 132
 133 void wxNSComboBoxControl::Clear()
 134 {
 135     SendEvents(false);
 136     [m_comboBox removeAllItems];
 137     SendEvents(true);
 138 }
 139
 140 wxString wxNSComboBoxControl::GetStringAtIndex(int pos) const
 141 {
 142     return wxCFStringRef::AsString([m_comboBox itemObjectValueAtIndex:pos], m_wxPeer->GetFont().GetEncoding());
 143 }
 144
 145 int wxNSComboBoxControl::FindString(const wxString& text) const
 146 {
 147     int result = [m_comboBox indexOfItemWithObjectValue:wxCFStringRef( text , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 148     if (result == NSNotFound)
 149         result = wxNOT_FOUND;
 150     return result;
 151 }
 152
 153 wxWidgetImplType* wxWidgetImpl::CreateComboBox( wxComboBox* wxpeer,
 154                                     wxWindowMac* WXUNUSED(parent),
 155                                     wxWindowID WXUNUSED(id),
 156                                     wxMenu* menu,
 157                                     const wxPoint& pos,
 158                                     const wxSize& size,
 159                                     long style,
 160                                     long WXUNUSED(extraStyle))
 161 {
 162     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 163     wxNSComboBox* v = [[wxNSComboBox alloc] initWithFrame:r];
 164     if (style & wxCB_READONLY)
 165         [v setEditable:NO];
 166     wxNSComboBoxControl* c = new wxNSComboBoxControl( wxpeer, v );
 167     return c;
 168 }
 169
 170 wxSize wxComboBox::DoGetBestSize() const
 171 {
 172     int lbWidth = GetCount() > 0 ? 20 : 100;  // some defaults
 173     wxSize baseSize = wxWindow::DoGetBestSize();
 174     int lbHeight = baseSize.y;
 175     int wLine;
 176
 177     {
 178         wxClientDC dc(const_cast<wxComboBox*>(this));
 179
 180         // Find the widest line
 181         for(unsigned int i = 0; i < GetCount(); i++)
 182         {
 183             wxString str(GetString(i));
 184
 185             wxCoord width, height ;
 186             dc.GetTextExtent( str , &width, &height);
 187             wLine = width ;
 188
 189             lbWidth = wxMax( lbWidth, wLine ) ;
 190         }
 191
 192         // Add room for the popup arrow
 193         lbWidth += 2 * lbHeight ;
 194     }
 195
 196     return wxSize( lbWidth, lbHeight );
 197 }
 198
 199 #endif // wxUSE_COMBOBOX