src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: window.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     NSTrackingRectTag rectTag;
  91 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  92     NSTrackingArea* _trackingArea;
  93 #endif
  94 }
  95
  96 // the tracking tag is needed to track mouse enter / exit events
  97 - (void) setTrackingTag: (NSTrackingRectTag)tag;
  98 - (NSTrackingRectTag) trackingTag;
  99 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 100 // under 10.5 we can also track mouse moved events on non-focused windows if
 101 // we use the new NSTrackingArea APIs.
 102 - (void) updateTrackingArea;
 103 - (NSTrackingArea*) trackingArea;
 104 #endif
 105 @end // wxNSView
 106
 107 @interface NSView(PossibleMethods)
 108 - (void)setTitle:(NSString *)aString;
 109 - (void)setStringValue:(NSString *)aString;
 110 - (void)setIntValue:(int)anInt;
 111 - (void)setFloatValue:(float)aFloat;
 112 - (void)setDoubleValue:(double)aDouble;
 113
 114 - (double)minValue;
 115 - (double)maxValue;
 116 - (void)setMinValue:(double)aDouble;
 117 - (void)setMaxValue:(double)aDouble;
 118
 119 - (void)sizeToFit;
 120
 121 - (BOOL)isEnabled;
 122 - (void)setEnabled:(BOOL)flag;
 123
 124 - (void)setImage:(NSImage *)image;
 125 - (void)setControlSize:(NSControlSize)size;
 126
 127 - (void)setFont:(NSFont *)fontObject;
 128
 129 - (id)contentView;
 130
 131 - (void)setTarget:(id)anObject;
 132 - (void)setAction:(SEL)aSelector;
 133 - (void)setDoubleAction:(SEL)aSelector;
 134 - (void)setBackgroundColor:(NSColor*)aColor;
 135 - (void)setOpaque:(BOOL)opaque;
 136 - (void)setTextColor:(NSColor *)color;
 137 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 138 @end
 139
 140 long wxOSXTranslateCocoaKey( NSEvent* event )
 141 {
 142     long retval = 0;
 143
 144     if ([event type] != NSFlagsChanged)
 145     {
 146         NSString* s = [event charactersIgnoringModifiers];
 147         // backspace char reports as delete w/modifiers for some reason
 148         if ([s length] == 1)
 149         {
 150             switch ( [s characterAtIndex:0] )
 151             {
 152                 // backspace key
 153                 case 0x7F :
 154                 case 8 :
 155                     retval = WXK_BACK;
 156                     break;
 157                 case NSUpArrowFunctionKey :
 158                     retval = WXK_UP;
 159                     break;
 160                 case NSDownArrowFunctionKey :
 161                     retval = WXK_DOWN;
 162                     break;
 163                 case NSLeftArrowFunctionKey :
 164                     retval = WXK_LEFT;
 165                     break;
 166                 case NSRightArrowFunctionKey :
 167                     retval = WXK_RIGHT;
 168                     break;
 169                 case NSInsertFunctionKey  :
 170                     retval = WXK_INSERT;
 171                     break;
 172                 case NSDeleteFunctionKey  :
 173                     retval = WXK_DELETE;
 174                     break;
 175                 case NSHomeFunctionKey  :
 176                     retval = WXK_HOME;
 177                     break;
 178         //        case NSBeginFunctionKey  :
 179         //            retval = WXK_BEGIN;
 180         //            break;
 181                 case NSEndFunctionKey  :
 182                     retval = WXK_END;
 183                     break;
 184                 case NSPageUpFunctionKey  :
 185                     retval = WXK_PAGEUP;
 186                     break;
 187                case NSPageDownFunctionKey  :
 188                     retval = WXK_PAGEDOWN;
 189                     break;
 190                case NSHelpFunctionKey  :
 191                     retval = WXK_HELP;
 192                     break;
 193                 default:
 194                     int intchar = [s characterAtIndex: 0];
 195                     if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 196                         retval = WXK_F1 + (intchar - NSF1FunctionKey );
 197                     break;
 198             }
 199         }
 200     }
 201
 202     // Some keys don't seem to have constants. The code mimics the approach
 203     // taken by WebKit. See:
 204     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 205     switch( [event keyCode] )
 206     {
 207         // command key
 208         case 54:
 209         case 55:
 210             retval = WXK_COMMAND;
 211             break;
 212         // caps locks key
 213         case 57: // Capslock
 214             retval = WXK_CAPITAL;
 215             break;
 216         // shift key
 217         case 56: // Left Shift
 218         case 60: // Right Shift
 219             retval = WXK_SHIFT;
 220             break;
 221         // alt key
 222         case 58: // Left Alt
 223         case 61: // Right Alt
 224             retval = WXK_ALT;
 225             break;
 226         // ctrl key
 227         case 59: // Left Ctrl
 228         case 62: // Right Ctrl
 229             retval = WXK_CONTROL;
 230             break;
 231         // clear key
 232         case 71:
 233             retval = WXK_CLEAR;
 234             break;
 235         // tab key
 236         case 48:
 237             retval = WXK_TAB;
 238             break;
 239
 240         case 75: // /
 241             retval = WXK_NUMPAD_DIVIDE;
 242             break;
 243         case 67: // *
 244             retval = WXK_NUMPAD_MULTIPLY;
 245             break;
 246         case 78: // -
 247             retval = WXK_NUMPAD_SUBTRACT;
 248             break;
 249         case 69: // +
 250             retval = WXK_NUMPAD_ADD;
 251             break;
 252         case 76: // Enter
 253             retval = WXK_NUMPAD_ENTER;
 254             break;
 255         case 65: // .
 256             retval = WXK_NUMPAD_DECIMAL;
 257             break;
 258         case 82: // 0
 259             retval = WXK_NUMPAD0;
 260             break;
 261         case 83: // 1
 262             retval = WXK_NUMPAD1;
 263             break;
 264         case 84: // 2
 265             retval = WXK_NUMPAD2;
 266             break;
 267         case 85: // 3
 268             retval = WXK_NUMPAD3;
 269             break;
 270         case 86: // 4
 271             retval = WXK_NUMPAD4;
 272             break;
 273         case 87: // 5
 274             retval = WXK_NUMPAD5;
 275             break;
 276         case 88: // 6
 277             retval = WXK_NUMPAD6;
 278             break;
 279         case 89: // 7
 280             retval = WXK_NUMPAD7;
 281             break;
 282         case 91: // 8
 283             retval = WXK_NUMPAD8;
 284             break;
 285         case 92: // 9
 286             retval = WXK_NUMPAD9;
 287             break;
 288         default:
 289             //retval = [event keyCode];
 290             break;
 291     }
 292     return retval;
 293 }
 294
 295 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 296 {
 297     UInt32 modifiers = [nsEvent modifierFlags] ;
 298     int eventType = [nsEvent type];
 299
 300     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 301     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 302     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 303     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 304
 305     wxevent.m_rawCode = [nsEvent keyCode];
 306     wxevent.m_rawFlags = modifiers;
 307
 308     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 309
 310     wxString chars;
 311     if ( eventType != NSFlagsChanged )
 312     {
 313         NSString* nschars = [nsEvent charactersIgnoringModifiers];
 314         if ( charString )
 315         {
 316             // if charString is set, it did not come from key up / key down
 317             wxevent.SetEventType( wxEVT_CHAR );
 318             chars = wxCFStringRef::AsString(charString);
 319         }
 320         else if ( nschars )
 321         {
 322             chars = wxCFStringRef::AsString(nschars);
 323         }
 324     }
 325
 326     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 327     long keyval = 0;
 328
 329     if (wxevent.GetEventType() != wxEVT_CHAR)
 330     {
 331         keyval = wxOSXTranslateCocoaKey(nsEvent) ;
 332         switch (eventType)
 333         {
 334             case NSKeyDown :
 335                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 336                 break;
 337             case NSKeyUp :
 338                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 339                 break;
 340             case NSFlagsChanged :
 341                 switch (keyval)
 342                 {
 343                     case WXK_CONTROL:
 344                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 345                         break;
 346                     case WXK_SHIFT:
 347                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 348                         break;
 349                     case WXK_ALT:
 350                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 351                         break;
 352                     case WXK_COMMAND:
 353                         wxevent.SetEventType( wxevent.m_metaDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 354                         break;
 355                 }
 356                 break;
 357             default :
 358                 break ;
 359         }
 360     }
 361
 362     if ( !keyval )
 363     {
 364         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 365             keyval = wxToupper( aunichar ) ;
 366         else
 367             keyval = aunichar;
 368     }
 369
 370 #if wxUSE_UNICODE
 371     wxevent.m_uniChar = aunichar;
 372 #endif
 373     wxevent.m_keyCode = keyval;
 374
 375     wxWindowMac* peer = GetWXPeer();
 376     if ( peer )
 377     {
 378         wxevent.SetEventObject(peer);
 379         wxevent.SetId(peer->GetId()) ;
 380     }
 381 }
 382
 383 UInt32 g_lastButton = 0 ;
 384 bool g_lastButtonWasFakeRight = false ;
 385
 386 // better scroll wheel support
 387 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 388
 389 @interface NSEvent (DeviceDelta)
 390 - (CGFloat)deviceDeltaX;
 391 - (CGFloat)deviceDeltaY;
 392 @end
 393
 394 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 395 {
 396     int eventType = [nsEvent type];
 397     UInt32 modifiers = [nsEvent modifierFlags] ;
 398
 399     NSPoint locationInWindow = [nsEvent locationInWindow];
 400
 401     // adjust coordinates for the window of the target view
 402     if ( [nsEvent window] != [m_osxView window] )
 403     {
 404         if ( [nsEvent window] != nil )
 405             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 406
 407         if ( [m_osxView window] != nil )
 408             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 409     }
 410
 411     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 412     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 413
 414     // these parameters are not given for all events
 415     UInt32 button = [nsEvent buttonNumber];
 416     UInt32 clickCount = 0;
 417
 418     wxevent.m_x = locationInViewWX.x;
 419     wxevent.m_y = locationInViewWX.y;
 420     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 421     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 422     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 423     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 424     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 425
 426     UInt32 mouseChord = 0;
 427
 428     switch (eventType)
 429     {
 430         case NSLeftMouseDown :
 431         case NSLeftMouseDragged :
 432             mouseChord = 1U;
 433             break;
 434         case NSRightMouseDown :
 435         case NSRightMouseDragged :
 436             mouseChord = 2U;
 437             break;
 438         case NSOtherMouseDown :
 439         case NSOtherMouseDragged :
 440             mouseChord = 4U;
 441             break;
 442     }
 443
 444     // a control click is interpreted as a right click
 445     bool thisButtonIsFakeRight = false ;
 446     if ( button == 0 && (modifiers & NSControlKeyMask) )
 447     {
 448         button = 1 ;
 449         thisButtonIsFakeRight = true ;
 450     }
 451
 452     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 453     if ( clickCount > 1 && button != g_lastButton )
 454         clickCount = 1 ;
 455
 456     // we must make sure that our synthetic 'right' button corresponds in
 457     // mouse down, moved and mouse up, and does not deliver a right down and left up
 458     switch (eventType)
 459     {
 460         case NSLeftMouseDown :
 461         case NSRightMouseDown :
 462         case NSOtherMouseDown :
 463             g_lastButton = button ;
 464             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 465             break;
 466      }
 467
 468     if ( button == 0 )
 469     {
 470         g_lastButton = 0 ;
 471         g_lastButtonWasFakeRight = false ;
 472     }
 473     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 474         button = g_lastButton ;
 475
 476     // Adjust the chord mask to remove the primary button and add the
 477     // secondary button.  It is possible that the secondary button is
 478     // already pressed, e.g. on a mouse connected to a laptop, but this
 479     // possibility is ignored here:
 480     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 481         mouseChord = ((mouseChord & ~1U) | 2U);
 482
 483     if(mouseChord & 1U)
 484                 wxevent.m_leftDown = true ;
 485     if(mouseChord & 2U)
 486                 wxevent.m_rightDown = true ;
 487     if(mouseChord & 4U)
 488                 wxevent.m_middleDown = true ;
 489
 490     // translate into wx types
 491     switch (eventType)
 492     {
 493         case NSLeftMouseDown :
 494         case NSRightMouseDown :
 495         case NSOtherMouseDown :
 496             clickCount = [nsEvent clickCount];
 497             switch ( button )
 498             {
 499                 case 0 :
 500                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 501                     break ;
 502
 503                 case 1 :
 504                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 505                     break ;
 506
 507                 case 2 :
 508                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 509                     break ;
 510
 511                 default:
 512                     break ;
 513             }
 514             break ;
 515
 516         case NSLeftMouseUp :
 517         case NSRightMouseUp :
 518         case NSOtherMouseUp :
 519             clickCount = [nsEvent clickCount];
 520             switch ( button )
 521             {
 522                 case 0 :
 523                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 524                     break ;
 525
 526                 case 1 :
 527                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 528                     break ;
 529
 530                 case 2 :
 531                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 532                     break ;
 533
 534                 default:
 535                     break ;
 536             }
 537             break ;
 538
 539      case NSScrollWheel :
 540         {
 541             float deltaX = 0.0;
 542             float deltaY = 0.0;
 543
 544             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 545
 546             // see http://developer.apple.com/qa/qa2005/qa1453.html
 547             // for more details on why we have to look for the exact type
 548
 549             const EventRef cEvent = (EventRef) [nsEvent eventRef];
 550             bool isMouseScrollEvent = false;
 551             if ( cEvent )
 552                 isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 553
 554             if ( isMouseScrollEvent )
 555             {
 556                 deltaX = [nsEvent deviceDeltaX];
 557                 deltaY = [nsEvent deviceDeltaY];
 558             }
 559             else
 560             {
 561                 deltaX = ([nsEvent deltaX] * 10);
 562                 deltaY = ([nsEvent deltaY] * 10);
 563             }
 564
 565             wxevent.m_wheelDelta = 10;
 566             wxevent.m_linesPerAction = 1;
 567
 568             if ( fabs(deltaX) > fabs(deltaY) )
 569             {
 570                 wxevent.m_wheelAxis = 1;
 571                 wxevent.m_wheelRotation = (int)deltaX;
 572             }
 573             else
 574             {
 575                 wxevent.m_wheelRotation = (int)deltaY;
 576             }
 577
 578         }
 579         break ;
 580
 581         case NSMouseEntered :
 582             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 583             break;
 584         case NSMouseExited :
 585             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 586             break;
 587         case NSLeftMouseDragged :
 588         case NSRightMouseDragged :
 589         case NSOtherMouseDragged :
 590         case NSMouseMoved :
 591             wxevent.SetEventType( wxEVT_MOTION ) ;
 592             break;
 593         default :
 594             break ;
 595     }
 596
 597     wxevent.m_clickCount = clickCount;
 598     wxWindowMac* peer = GetWXPeer();
 599     if ( peer )
 600     {
 601         wxevent.SetEventObject(peer);
 602         wxevent.SetId(peer->GetId()) ;
 603     }
 604 }
 605
 606 @implementation wxNSView
 607
 608 + (void)initialize
 609 {
 610     static BOOL initialized = NO;
 611     if (!initialized)
 612     {
 613         initialized = YES;
 614         wxOSXCocoaClassAddWXMethods( self );
 615     }
 616 }
 617
 618 - (void) setTrackingTag: (NSTrackingRectTag)tag
 619 {
 620     rectTag = tag;
 621 }
 622
 623 - (NSTrackingRectTag) trackingTag
 624 {
 625     return rectTag;
 626 }
 627
 628 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 629 - (void) updateTrackingArea
 630 {
 631     if (_trackingArea)
 632     {
 633         [self removeTrackingArea: _trackingArea];
 634         [_trackingArea release];
 635     }
 636
 637     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingMouseMoved|NSTrackingActiveAlways;
 638
 639     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: [self bounds] options: options owner: self userInfo: nil];
 640     [self addTrackingArea: area];
 641
 642     _trackingArea = area;
 643 }
 644
 645 - (NSTrackingArea*) trackingArea
 646 {
 647     return _trackingArea;
 648 }
 649 #endif
 650 @end // wxNSView
 651
 652 //
 653 // event handlers
 654 //
 655
 656 #if wxUSE_DRAG_AND_DROP
 657
 658 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 659 // for details on the NSPasteboard -> PasteboardRef conversion
 660
 661 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 662 {
 663     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 664     if (impl == NULL)
 665         return NSDragOperationNone;
 666
 667     return impl->draggingEntered(sender, self, _cmd);
 668 }
 669
 670 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 671 {
 672     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 673     if (impl == NULL)
 674         return ;
 675
 676     return impl->draggingExited(sender, self, _cmd);
 677 }
 678
 679 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 680 {
 681     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 682     if (impl == NULL)
 683         return NSDragOperationNone;
 684
 685     return impl->draggingUpdated(sender, self, _cmd);
 686 }
 687
 688 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 689 {
 690     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 691     if (impl == NULL)
 692         return NSDragOperationNone;
 693
 694     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 695 }
 696
 697 #endif
 698
 699 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 700 {
 701     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 702     if (impl == NULL)
 703         return;
 704
 705     impl->mouseEvent(event, self, _cmd);
 706 }
 707
 708 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 709 {
 710     // This is needed to support click through, otherwise the first click on a window
 711     // will not do anything unless it is the active window already.
 712     return YES;
 713 }
 714
 715 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 716 {
 717     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 718     if (impl == NULL)
 719         return;
 720
 721     impl->keyEvent(event, self, _cmd);
 722 }
 723
 724 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 725 {
 726     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 727     if (impl == NULL)
 728         return;
 729
 730     impl->insertText(text, self, _cmd);
 731 }
 732
 733 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 734 {
 735     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 736     if (impl == NULL)
 737         return NO;
 738
 739     return impl->performKeyEquivalent(event, self, _cmd);
 740 }
 741
 742 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 743 {
 744     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 745     if (impl == NULL)
 746         return NO;
 747
 748     return impl->acceptsFirstResponder(self, _cmd);
 749 }
 750
 751 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 752 {
 753     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 754     if (impl == NULL)
 755         return NO;
 756
 757     return impl->becomeFirstResponder(self, _cmd);
 758 }
 759
 760 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 761 {
 762     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 763     if (impl == NULL)
 764         return NO;
 765
 766     return impl->resignFirstResponder(self, _cmd);
 767 }
 768
 769 void wxOSX_resetCursorRects(NSView* self, SEL _cmd)
 770 {
 771     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 772     if (impl == NULL)
 773         return;
 774
 775     impl->resetCursorRects(self, _cmd);
 776 }
 777
 778 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 779 {
 780     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 781     if (impl == NULL)
 782         return NO;
 783
 784     return impl->isFlipped(self, _cmd) ? YES:NO;
 785 }
 786
 787 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 788
 789 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 790 {
 791     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 792     if (impl == NULL)
 793         return;
 794
 795 #ifdef wxUSE_THREADS
 796     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 797     // dialog. This causes a drawRect of the active dialog from outside the
 798     // main UI thread. This causes an occasional crash since the wx drawing
 799     // objects (like wxPen) are not thread safe.
 800     //
 801     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 802     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 803     if ( !wxThread::IsMain() )
 804     {
 805       // just call the superclass handler, we don't need any custom wx drawing
 806       // here and it seems to work fine:
 807       wxOSX_DrawRectHandlerPtr
 808           superimpl = (wxOSX_DrawRectHandlerPtr)
 809                         [[self superclass] instanceMethodForSelector:_cmd];
 810       superimpl(self, _cmd, rect);
 811       return;
 812     }
 813 #endif // wxUSE_THREADS
 814
 815     return impl->drawRect(&rect, self, _cmd);
 816 }
 817
 818 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 819 {
 820     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 821     if (impl == NULL)
 822         return;
 823
 824     impl->controlAction(self, _cmd, sender);
 825 }
 826
 827 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 828 {
 829     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 830     if (impl == NULL)
 831         return;
 832
 833     impl->controlDoubleAction(self, _cmd, sender);
 834 }
 835
 836 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 837 {
 838     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 839     NSPasteboard *pboard = [sender draggingPasteboard];
 840     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 841
 842     wxWindow* wxpeer = GetWXPeer();
 843     if ( wxpeer == NULL )
 844         return NSDragOperationNone;
 845
 846     wxDropTarget* target = wxpeer->GetDropTarget();
 847     if ( target == NULL )
 848         return NSDragOperationNone;
 849
 850     wxDragResult result = wxDragNone;
 851     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 852     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 853
 854     if ( sourceDragMask & NSDragOperationLink )
 855         result = wxDragLink;
 856     else if ( sourceDragMask & NSDragOperationCopy )
 857         result = wxDragCopy;
 858     else if ( sourceDragMask & NSDragOperationMove )
 859         result = wxDragMove;
 860
 861     PasteboardRef pboardRef;
 862     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 863     target->SetCurrentDragPasteboard(pboardRef);
 864     result = target->OnEnter(pt.x, pt.y, result);
 865     CFRelease(pboardRef);
 866
 867     NSDragOperation nsresult = NSDragOperationNone;
 868     switch (result )
 869     {
 870         case wxDragLink:
 871             nsresult = NSDragOperationLink;
 872         case wxDragMove:
 873             nsresult = NSDragOperationMove;
 874         case wxDragCopy:
 875             nsresult = NSDragOperationCopy;
 876         default :
 877             break;
 878     }
 879     return nsresult;
 880 }
 881
 882 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 883 {
 884     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 885     NSPasteboard *pboard = [sender draggingPasteboard];
 886
 887     wxWindow* wxpeer = GetWXPeer();
 888     if ( wxpeer == NULL )
 889         return;
 890
 891     wxDropTarget* target = wxpeer->GetDropTarget();
 892     if ( target == NULL )
 893         return;
 894
 895     PasteboardRef pboardRef;
 896     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 897     target->SetCurrentDragPasteboard(pboardRef);
 898     target->OnLeave();
 899     CFRelease(pboardRef);
 900  }
 901
 902 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 903 {
 904     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 905     NSPasteboard *pboard = [sender draggingPasteboard];
 906     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 907
 908     wxWindow* wxpeer = GetWXPeer();
 909     if ( wxpeer == NULL )
 910         return NSDragOperationNone;
 911
 912     wxDropTarget* target = wxpeer->GetDropTarget();
 913     if ( target == NULL )
 914         return NSDragOperationNone;
 915
 916     wxDragResult result = wxDragNone;
 917     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 918     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 919
 920     if ( sourceDragMask & NSDragOperationLink )
 921         result = wxDragLink;
 922     else if ( sourceDragMask & NSDragOperationCopy )
 923         result = wxDragCopy;
 924     else if ( sourceDragMask & NSDragOperationMove )
 925         result = wxDragMove;
 926
 927     PasteboardRef pboardRef;
 928     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 929     target->SetCurrentDragPasteboard(pboardRef);
 930     result = target->OnDragOver(pt.x, pt.y, result);
 931     CFRelease(pboardRef);
 932
 933     NSDragOperation nsresult = NSDragOperationNone;
 934     switch (result )
 935     {
 936         case wxDragLink:
 937             nsresult = NSDragOperationLink;
 938         case wxDragMove:
 939             nsresult = NSDragOperationMove;
 940         case wxDragCopy:
 941             nsresult = NSDragOperationCopy;
 942         default :
 943             break;
 944     }
 945     return nsresult;
 946 }
 947
 948 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 949 {
 950     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 951
 952     NSPasteboard *pboard = [sender draggingPasteboard];
 953     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 954
 955     wxWindow* wxpeer = GetWXPeer();
 956     wxDropTarget* target = wxpeer->GetDropTarget();
 957     wxDragResult result = wxDragNone;
 958     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 959     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 960
 961     if ( sourceDragMask & NSDragOperationLink )
 962         result = wxDragLink;
 963     else if ( sourceDragMask & NSDragOperationCopy )
 964         result = wxDragCopy;
 965     else if ( sourceDragMask & NSDragOperationMove )
 966         result = wxDragMove;
 967
 968     PasteboardRef pboardRef;
 969     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 970     target->SetCurrentDragPasteboard(pboardRef);
 971
 972     if (target->OnDrop(pt.x, pt.y))
 973         result = target->OnData(pt.x, pt.y, result);
 974
 975     CFRelease(pboardRef);
 976
 977     return result != wxDragNone;
 978 }
 979
 980 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
 981 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 982 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 983 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
 984 typedef BOOL (*wxOSX_ResetCursorRectsHandlerPtr)(NSView* self, SEL _cmd);
 985
 986 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 987 {
 988     if ( !DoHandleMouseEvent(event) )
 989     {
 990         // for plain NSView mouse events would propagate to parents otherwise
 991         if (!m_wxPeer->MacIsUserPane())
 992         {
 993             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 994             superimpl(slf, (SEL)_cmd, event);
 995         }
 996     }
 997 }
 998
 999 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1000 {
1001     if ( [event type] == NSKeyDown )
1002         m_lastKeyDownEvent = event;
1003     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1004     {
1005         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1006         superimpl(slf, (SEL)_cmd, event);
1007     }
1008     m_lastKeyDownEvent = NULL;
1009 }
1010
1011 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1012 {
1013     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1014     {
1015         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1016         superimpl(slf, (SEL)_cmd, text);
1017     }
1018 }
1019
1020
1021 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1022 {
1023     wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1024     return superimpl(slf, (SEL)_cmd, event);
1025 }
1026
1027 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1028 {
1029     if ( m_wxPeer->MacIsUserPane() )
1030         return m_wxPeer->AcceptsFocus();
1031     else
1032     {
1033         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1034         return superimpl(slf, (SEL)_cmd);
1035     }
1036 }
1037
1038 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1039 {
1040     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1041     // get the current focus before running becomeFirstResponder
1042     NSView* otherView = FindFocus();
1043
1044     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1045     BOOL r = superimpl(slf, (SEL)_cmd);
1046     if ( r )
1047     {
1048         DoNotifyFocusEvent( true, otherWindow );
1049     }
1050
1051     return r;
1052 }
1053
1054 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1055 {
1056     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1057     BOOL r = superimpl(slf, (SEL)_cmd);
1058     // get the current focus after running resignFirstResponder
1059     // note that this value isn't reliable, it might return the same view that
1060     // is resigning
1061     NSView* otherView = FindFocus();
1062     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1063
1064     // It doesn't make sense to notify about the loss of focus if we're not
1065     // really losing it and the window which has just gained focus is the same
1066     // one as this window itself. Of course, this should never happen in the
1067     // first place but somehow it does in wxGrid code and without this check we
1068     // enter into an infinite recursion, see #12267.
1069     if ( otherWindow == this )
1070         return r;
1071
1072     // NSTextViews have an editor as true responder, therefore the might get the
1073     // resign notification if their editor takes over, don't trigger any event then
1074     if ( r && !m_hasEditor)
1075     {
1076         DoNotifyFocusEvent( false, otherWindow );
1077     }
1078     return r;
1079 }
1080
1081 void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
1082 {
1083     wxWindow* wxpeer = GetWXPeer();
1084     if ( wxpeer )
1085     {
1086         NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
1087         if (cursor == NULL)
1088         {
1089             wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1090             superimpl(slf, (SEL)_cmd);
1091         }
1092         else
1093         {
1094             [slf addCursorRect: [slf bounds]
1095                 cursor: cursor];
1096         }
1097     }
1098 }
1099
1100 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1101 {
1102     return m_isFlipped;
1103 }
1104
1105
1106 #define OSX_DEBUG_DRAWING 0
1107
1108 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1109 {
1110     // preparing the update region
1111
1112     wxRegion updateRgn;
1113     const NSRect *rects;
1114     NSInteger count;
1115
1116     [slf getRectsBeingDrawn:&rects count:&count];
1117     for ( int i = 0 ; i < count ; ++i )
1118     {
1119         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1120     }
1121
1122     wxWindow* wxpeer = GetWXPeer();
1123
1124     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1125     {
1126         // as this update region is in native window locals we must adapt it to wx window local
1127         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1128     }
1129
1130     if ( wxpeer->MacGetTopLevelWindow()->GetWindowStyle() & wxFRAME_SHAPED )
1131     {
1132         int xoffset = 0, yoffset = 0;
1133         wxRegion rgn = wxpeer->MacGetTopLevelWindow()->GetShape();
1134         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1135         rgn.Offset( xoffset, yoffset );
1136         updateRgn.Intersect(rgn);
1137     }
1138
1139     wxpeer->GetUpdateRegion() = updateRgn;
1140
1141     // setting up the drawing context
1142
1143     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1144     CGContextSaveGState( context );
1145
1146 #if OSX_DEBUG_DRAWING
1147     CGContextBeginPath( context );
1148     CGContextMoveToPoint(context, 0, 0);
1149     NSRect bounds = [slf bounds];
1150     CGContextAddLineToPoint(context, 10, 0);
1151     CGContextMoveToPoint(context, 0, 0);
1152     CGContextAddLineToPoint(context, 0, 10);
1153     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1154     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1155     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1156     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1157     CGContextClosePath( context );
1158     CGContextStrokePath(context);
1159 #endif
1160
1161     if ( !m_isFlipped )
1162     {
1163         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1164         CGContextScaleCTM( context, 1, -1 );
1165     }
1166
1167     wxpeer->MacSetCGContextRef( context );
1168
1169     bool handled = wxpeer->MacDoRedraw( 0 );
1170     CGContextRestoreGState( context );
1171
1172     CGContextSaveGState( context );
1173     if ( !handled )
1174     {
1175         // call super
1176         SEL _cmd = @selector(drawRect:);
1177         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1178         superimpl(slf, _cmd, *(NSRect*)rect);
1179         CGContextRestoreGState( context );
1180         CGContextSaveGState( context );
1181     }
1182     wxpeer->MacPaintChildrenBorders();
1183     wxpeer->MacSetCGContextRef( NULL );
1184     CGContextRestoreGState( context );
1185 }
1186
1187 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1188 {
1189     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1190     if ( wxpeer )
1191         wxpeer->OSXHandleClicked(0);
1192 }
1193
1194 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1195 {
1196 }
1197
1198 void wxWidgetCocoaImpl::controlTextDidChange()
1199 {
1200     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1201     if ( wxpeer )
1202     {
1203         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1204         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1205         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1206         if ( tc )
1207             tc->SendTextUpdatedEventIfAllowed();
1208         else if ( cb )
1209             cb->SendTextUpdatedEventIfAllowed();
1210         else
1211         {
1212             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1213         }
1214     }
1215 }
1216
1217 //
1218
1219 #if OBJC_API_VERSION >= 2
1220
1221 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1222     class_addMethod(c, s, i, t );
1223
1224 #else
1225
1226 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1227     { s, t, i },
1228
1229 #endif
1230
1231 void wxOSXCocoaClassAddWXMethods(Class c)
1232 {
1233
1234 #if OBJC_API_VERSION < 2
1235     static objc_method wxmethods[] =
1236     {
1237 #endif
1238
1239     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1240     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1241     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1242
1243     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1244     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1245     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1246
1247     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1248
1249     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1250     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1251     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1252
1253     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1254
1255     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1256     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1257     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1258
1259     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1260     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1261     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1262
1263     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1264
1265     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1266
1267     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1268     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1269     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1270     wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
1271
1272     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1273     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1274
1275     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1276     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1277
1278 #if wxUSE_DRAG_AND_DROP
1279     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1280     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1281     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1282     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1283 #endif
1284
1285 #if OBJC_API_VERSION < 2
1286     } ;
1287     static int method_count = WXSIZEOF( wxmethods );
1288     static objc_method_list *wxmethodlist = NULL;
1289     if ( wxmethodlist == NULL )
1290     {
1291         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1292         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1293         wxmethodlist->method_count = method_count;
1294         wxmethodlist->obsolete = 0;
1295     }
1296     class_addMethods( c, wxmethodlist );
1297 #endif
1298 }
1299
1300 //
1301 // C++ implementation class
1302 //
1303
1304 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1305
1306 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl ) :
1307     wxWidgetImpl( peer, isRootControl )
1308 {
1309     Init();
1310     m_osxView = w;
1311
1312     // check if the user wants to create the control initially hidden
1313     if ( !peer->IsShown() )
1314         SetVisibility(false);
1315
1316     // gc aware handling
1317     if ( m_osxView )
1318         CFRetain(m_osxView);
1319     [m_osxView release];
1320 }
1321
1322 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1323 {
1324     Init();
1325 }
1326
1327 void wxWidgetCocoaImpl::Init()
1328 {
1329     m_osxView = NULL;
1330     m_isFlipped = true;
1331     m_lastKeyDownEvent = NULL;
1332     m_hasEditor = false;
1333 }
1334
1335 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1336 {
1337     RemoveAssociations( this );
1338
1339     if ( !IsRootControl() )
1340     {
1341         NSView *sv = [m_osxView superview];
1342         if ( sv != nil )
1343             [m_osxView removeFromSuperview];
1344     }
1345     // gc aware handling
1346     if ( m_osxView )
1347         CFRelease(m_osxView);
1348 }
1349
1350 bool wxWidgetCocoaImpl::IsVisible() const
1351 {
1352     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1353 }
1354
1355 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1356 {
1357     [m_osxView setHidden:(visible ? NO:YES)];
1358 }
1359
1360 // ----------------------------------------------------------------------------
1361 // window animation stuff
1362 // ----------------------------------------------------------------------------
1363
1364 // define a delegate used to refresh the window during animation
1365 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1366 {
1367     wxWindow *m_win;
1368     bool m_isDone;
1369 }
1370
1371 - (id)init:(wxWindow *)win;
1372
1373 - (bool)isDone;
1374
1375 // NSAnimationDelegate methods
1376 - (void)animationDidEnd:(NSAnimation*)animation;
1377 - (void)animation:(NSAnimation*)animation
1378         didReachProgressMark:(NSAnimationProgress)progress;
1379 @end
1380
1381 @implementation wxNSAnimationDelegate
1382
1383 - (id)init:(wxWindow *)win
1384 {
1385     [super init];
1386
1387     m_win = win;
1388     m_isDone = false;
1389
1390     return self;
1391 }
1392
1393 - (bool)isDone
1394 {
1395     return m_isDone;
1396 }
1397
1398 - (void)animation:(NSAnimation*)animation
1399         didReachProgressMark:(NSAnimationProgress)progress
1400 {
1401     wxUnusedVar(animation);
1402     wxUnusedVar(progress);
1403
1404     m_win->SendSizeEvent();
1405 }
1406
1407 - (void)animationDidEnd:(NSAnimation*)animation
1408 {
1409     wxUnusedVar(animation);
1410     m_isDone = true;
1411 }
1412
1413 @end
1414
1415 /* static */
1416 bool
1417 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1418                                               bool show,
1419                                               wxShowEffect effect,
1420                                               unsigned timeout)
1421 {
1422     // create the dictionary describing the animation to perform on this view
1423     NSObject * const
1424         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1425     NSMutableDictionary * const
1426         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1427     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1428
1429     // determine the start and end rectangles assuming we're hiding the window
1430     const wxRect rectOrig = win->GetRect();
1431     wxRect rectStart,
1432            rectEnd;
1433     rectStart =
1434     rectEnd = rectOrig;
1435
1436     if ( show )
1437     {
1438         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1439                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1440             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1441         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1442                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1443             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1444         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1445                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1446             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1447         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1448                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1449             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1450     }
1451
1452     switch ( effect )
1453     {
1454         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1455         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1456             rectEnd.width = 0;
1457             break;
1458
1459         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1460         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1461             rectEnd.x = rectStart.GetRight();
1462             rectEnd.width = 0;
1463             break;
1464
1465         case wxSHOW_EFFECT_ROLL_TO_TOP:
1466         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1467             rectEnd.height = 0;
1468             break;
1469
1470         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1471         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1472             rectEnd.y = rectStart.GetBottom();
1473             rectEnd.height = 0;
1474             break;
1475
1476         case wxSHOW_EFFECT_EXPAND:
1477             rectEnd.x = rectStart.x + rectStart.width / 2;
1478             rectEnd.y = rectStart.y + rectStart.height / 2;
1479             rectEnd.width =
1480             rectEnd.height = 0;
1481             break;
1482
1483         case wxSHOW_EFFECT_BLEND:
1484             [dict setObject:(show ? NSViewAnimationFadeInEffect
1485                                   : NSViewAnimationFadeOutEffect)
1486                   forKey:NSViewAnimationEffectKey];
1487             break;
1488
1489         case wxSHOW_EFFECT_NONE:
1490         case wxSHOW_EFFECT_MAX:
1491             wxFAIL_MSG( "unexpected animation effect" );
1492             return false;
1493
1494         default:
1495             wxFAIL_MSG( "unknown animation effect" );
1496             return false;
1497     };
1498
1499     if ( show )
1500     {
1501         // we need to restore it to the original rectangle instead of making it
1502         // disappear
1503         wxSwap(rectStart, rectEnd);
1504
1505         // and as the window is currently hidden, we need to show it for the
1506         // animation to be visible at all (but don't restore it at its full
1507         // rectangle as it shouldn't appear immediately)
1508         win->SetSize(rectStart);
1509         win->Show();
1510     }
1511
1512     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1513                                     ? [(NSView *)viewOrWin superview]
1514                                     : nil;
1515     const NSRect rStart = wxToNSRect(parentView, rectStart);
1516     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1517
1518     [dict setObject:[NSValue valueWithRect:rStart]
1519           forKey:NSViewAnimationStartFrameKey];
1520     [dict setObject:[NSValue valueWithRect:rEnd]
1521           forKey:NSViewAnimationEndFrameKey];
1522
1523     // create an animation using the values in the above dictionary
1524     NSViewAnimation * const
1525         anim = [[NSViewAnimation alloc]
1526                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1527
1528     if ( !timeout )
1529     {
1530         // what is a good default duration? Windows uses 200ms, Web frameworks
1531         // use anything from 250ms to 1s... choose something in the middle
1532         timeout = 500;
1533     }
1534
1535     [anim setDuration:timeout/1000.];   // duration is in seconds here
1536
1537     // if the window being animated changes its layout depending on its size
1538     // (which is almost always the case) we need to redo it during animation
1539     //
1540     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1541     // controls in wxInfoBar visibly jump around)
1542     const int NUM_LAYOUTS = 20;
1543     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1544         [anim addProgressMark:f];
1545
1546     wxNSAnimationDelegate * const
1547         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1548     [anim setDelegate:animDelegate];
1549     [anim startAnimation];
1550
1551     // Cocoa is capable of doing animation asynchronously or even from separate
1552     // thread but wx API doesn't provide any way to be notified about the
1553     // animation end and without this we really must ensure that the window has
1554     // the expected (i.e. the same as if a simple Show() had been used) size
1555     // when we return, so block here until the animation finishes
1556     //
1557     // notice that because the default animation mode is NSAnimationBlocking,
1558     // no user input events ought to be processed from here
1559     {
1560         wxEventLoopGuarantor ensureEventLoopExistence;
1561         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1562         while ( ![animDelegate isDone] )
1563             loop->Dispatch();
1564     }
1565
1566     if ( !show )
1567     {
1568         // NSViewAnimation is smart enough to hide the NSView being animated at
1569         // the end but we also must ensure that it's hidden for wx too
1570         win->Hide();
1571
1572         // and we must also restore its size because it isn't expected to
1573         // change just because the window was hidden
1574         win->SetSize(rectOrig);
1575     }
1576     else
1577     {
1578         // refresh it once again after the end to ensure that everything is in
1579         // place
1580         win->SendSizeEvent();
1581     }
1582
1583     [anim setDelegate:nil];
1584     [animDelegate release];
1585     [anim release];
1586
1587     return true;
1588 }
1589
1590 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1591                                        wxShowEffect effect,
1592                                        unsigned timeout)
1593 {
1594     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1595 }
1596
1597 void wxWidgetCocoaImpl::Raise()
1598 {
1599     // Not implemented
1600 }
1601
1602 void wxWidgetCocoaImpl::Lower()
1603 {
1604     // Not implemented
1605 }
1606
1607 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1608 {
1609 #if 1
1610     SetNeedsDisplay() ;
1611 #else
1612     // We should do something like this, but it wasn't working in 10.4.
1613     if (GetNeedsDisplay() )
1614     {
1615         SetNeedsDisplay() ;
1616     }
1617     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1618     NSSize offset = NSMakeSize((float)dx, (float)dy);
1619     [m_osxView scrollRect:r by:offset];
1620 #endif
1621 }
1622
1623 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1624 {
1625     wxWindowMac* parent = GetWXPeer()->GetParent();
1626     // under Cocoa we might have a contentView in the wxParent to which we have to
1627     // adjust the coordinates
1628     if (parent && [m_osxView superview] != parent->GetHandle() )
1629     {
1630         int cx = 0,cy = 0,cw = 0,ch = 0;
1631         if ( parent->GetPeer() )
1632         {
1633             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1634             x -= cx;
1635             y -= cy;
1636         }
1637     }
1638     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
1639     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
1640     [m_osxView setFrame:r];
1641     [[m_osxView superview] setNeedsDisplayInRect:r];
1642
1643     wxNSView* wxview = (wxNSView*)m_osxView;
1644 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
1645     if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
1646         [wxview updateTrackingArea];
1647 #else
1648     if ([m_osxView respondsToSelector:@selector(trackingTag)] )
1649     {
1650         if ( [wxview trackingTag] )
1651             [wxview removeTrackingRect: [wxview trackingTag]];
1652
1653         [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
1654     }
1655 #endif
1656 }
1657
1658 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
1659 {
1660     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
1661     x = r.GetLeft();
1662     y = r.GetTop();
1663 }
1664
1665 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
1666 {
1667     NSRect rect = [m_osxView frame];
1668     width = (int)rect.size.width;
1669     height = (int)rect.size.height;
1670 }
1671
1672 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
1673 {
1674     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
1675     {
1676         NSView* cv = [m_osxView contentView];
1677
1678         NSRect bounds = [m_osxView bounds];
1679         NSRect rect = [cv frame];
1680
1681         int y = (int)rect.origin.y;
1682         int x = (int)rect.origin.x;
1683         if ( ![ m_osxView isFlipped ] )
1684             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
1685         left = x;
1686         top = y;
1687         width = (int)rect.size.width;
1688         height = (int)rect.size.height;
1689     }
1690     else
1691     {
1692         left = top = 0;
1693         GetSize( width, height );
1694     }
1695 }
1696
1697 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
1698 {
1699     if ( where )
1700         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
1701     else
1702         [m_osxView setNeedsDisplay:YES];
1703 }
1704
1705 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
1706 {
1707     return [m_osxView needsDisplay];
1708 }
1709
1710 bool wxWidgetCocoaImpl::CanFocus() const
1711 {
1712     return [m_osxView canBecomeKeyView] == YES;
1713 }
1714
1715 bool wxWidgetCocoaImpl::HasFocus() const
1716 {
1717     return ( FindFocus() == m_osxView );
1718 }
1719
1720 bool wxWidgetCocoaImpl::SetFocus()
1721 {
1722     if ( !CanFocus() )
1723         return false;
1724
1725     [[m_osxView window] makeKeyAndOrderFront:nil] ;
1726     [[m_osxView window] makeFirstResponder: m_osxView] ;
1727     return true;
1728 }
1729
1730
1731 void wxWidgetCocoaImpl::RemoveFromParent()
1732 {
1733     [m_osxView removeFromSuperview];
1734 }
1735
1736 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
1737 {
1738     NSView* container = parent->GetWXWidget() ;
1739     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
1740     [container addSubview:m_osxView];
1741 }
1742
1743 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
1744 {
1745     NSView* targetView = m_osxView;
1746     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1747         targetView = [(NSScrollView*) m_osxView documentView];
1748
1749     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
1750     {
1751         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1752                                                                 green:(CGFloat) (col.Green() / 255.0)
1753                                                                  blue:(CGFloat) (col.Blue() / 255.0)
1754                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
1755     }
1756 }
1757
1758 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
1759 {
1760     BOOL opaque = ( style == wxBG_STYLE_PAINT );
1761
1762     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
1763     {
1764         [m_osxView setOpaque: opaque];
1765     }
1766
1767     return true ;
1768 }
1769
1770 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
1771 {
1772     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
1773     {
1774         wxCFStringRef cf( title , encoding );
1775         [m_osxView setTitle:cf.AsNSString()];
1776     }
1777     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
1778     {
1779         wxCFStringRef cf( title , encoding );
1780         [m_osxView setStringValue:cf.AsNSString()];
1781     }
1782 }
1783
1784
1785 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
1786 {
1787     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
1788     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
1789     *pt = wxFromNSPoint( to->GetWXWidget(), p );
1790 }
1791
1792 wxInt32 wxWidgetCocoaImpl::GetValue() const
1793 {
1794     return [(NSControl*)m_osxView intValue];
1795 }
1796
1797 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
1798 {
1799     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
1800     {
1801         [m_osxView setIntValue:v];
1802     }
1803     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
1804     {
1805         [m_osxView setFloatValue:(double)v];
1806     }
1807     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
1808     {
1809         [m_osxView setDoubleValue:(double)v];
1810     }
1811 }
1812
1813 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
1814 {
1815     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
1816     {
1817         [m_osxView setMinValue:(double)v];
1818     }
1819 }
1820
1821 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
1822 {
1823     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
1824     {
1825         [m_osxView setMaxValue:(double)v];
1826     }
1827 }
1828
1829 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
1830 {
1831     if (  [m_osxView respondsToSelector:@selector(minValue)] )
1832     {
1833         return (int)[m_osxView minValue];
1834     }
1835     return 0;
1836 }
1837
1838 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
1839 {
1840     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
1841     {
1842         return (int)[m_osxView maxValue];
1843     }
1844     return 0;
1845 }
1846
1847 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
1848 {
1849     wxBitmap bmp;
1850
1851     // TODO: how to create a wxBitmap from NSImage?
1852 #if 0
1853     if ( [m_osxView respondsToSelector:@selector(image:)] )
1854         bmp = [m_osxView image];
1855 #endif
1856
1857     return bmp;
1858 }
1859
1860 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
1861 {
1862     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
1863     {
1864         [m_osxView setImage:bitmap.GetNSImage()];
1865         [m_osxView setNeedsDisplay:YES];
1866     }
1867 }
1868
1869 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
1870 {
1871     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
1872     {
1873         NSCellImagePosition pos;
1874         switch ( dir )
1875         {
1876             case wxLEFT:
1877                 pos = NSImageLeft;
1878                 break;
1879
1880             case wxRIGHT:
1881                 pos = NSImageRight;
1882                 break;
1883
1884             case wxTOP:
1885                 pos = NSImageAbove;
1886                 break;
1887
1888             case wxBOTTOM:
1889                 pos = NSImageBelow;
1890                 break;
1891
1892             default:
1893                 wxFAIL_MSG( "invalid image position" );
1894                 pos = NSNoImage;
1895         }
1896
1897         [m_osxView setImagePosition:pos];
1898     }
1899 }
1900
1901 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
1902 {
1903     // implementation in subclass
1904 }
1905
1906 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
1907 {
1908     r->x = r->y = r->width = r->height = 0;
1909
1910     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
1911     {
1912         NSRect former = [m_osxView frame];
1913         [m_osxView sizeToFit];
1914         NSRect best = [m_osxView frame];
1915         [m_osxView setFrame:former];
1916         r->width = (int)best.size.width;
1917         r->height = (int)best.size.height;
1918     }
1919 }
1920
1921 bool wxWidgetCocoaImpl::IsEnabled() const
1922 {
1923     NSView* targetView = m_osxView;
1924     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1925         targetView = [(NSScrollView*) m_osxView documentView];
1926
1927     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
1928         return [targetView isEnabled];
1929     return true;
1930 }
1931
1932 void wxWidgetCocoaImpl::Enable( bool enable )
1933 {
1934     NSView* targetView = m_osxView;
1935     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1936         targetView = [(NSScrollView*) m_osxView documentView];
1937
1938     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
1939         [targetView setEnabled:enable];
1940 }
1941
1942 void wxWidgetCocoaImpl::PulseGauge()
1943 {
1944 }
1945
1946 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
1947 {
1948 }
1949
1950 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
1951 {
1952     NSControlSize size = NSRegularControlSize;
1953
1954     switch ( variant )
1955     {
1956         case wxWINDOW_VARIANT_NORMAL :
1957             size = NSRegularControlSize;
1958             break ;
1959
1960         case wxWINDOW_VARIANT_SMALL :
1961             size = NSSmallControlSize;
1962             break ;
1963
1964         case wxWINDOW_VARIANT_MINI :
1965             size = NSMiniControlSize;
1966             break ;
1967
1968         case wxWINDOW_VARIANT_LARGE :
1969             size = NSRegularControlSize;
1970             break ;
1971
1972         default:
1973             wxFAIL_MSG(wxT("unexpected window variant"));
1974             break ;
1975     }
1976     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
1977         [m_osxView setControlSize:size];
1978     else if ([m_osxView respondsToSelector:@selector(cell)])
1979     {
1980         id cell = [(id)m_osxView cell];
1981         if ([cell respondsToSelector:@selector(setControlSize:)])
1982             [cell setControlSize:size];
1983     }
1984 }
1985
1986 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
1987 {
1988     if ([m_osxView respondsToSelector:@selector(setFont:)])
1989         [m_osxView setFont: font.OSXGetNSFont()];
1990     if ([m_osxView respondsToSelector:@selector(setTextColor:)])
1991         [m_osxView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1992                                                                  green:(CGFloat) (col.Green() / 255.0)
1993                                                                   blue:(CGFloat) (col.Blue() / 255.0)
1994                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
1995 }
1996
1997 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
1998 {
1999     if (tooltip)
2000     {
2001         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2002         [m_osxView setToolTip: cf.AsNSString()];
2003     }
2004     else
2005         [m_osxView setToolTip: nil];
2006
2007 }
2008
2009 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2010 {
2011     WXWidget c =  control ? control : (WXWidget) m_osxView;
2012     wxWidgetImpl::Associate( c, this ) ;
2013     if ([c respondsToSelector:@selector(setAction:)])
2014     {
2015         [c setTarget: c];
2016         [c setAction: @selector(controlAction:)];
2017         if ([c respondsToSelector:@selector(setDoubleAction:)])
2018         {
2019             [c setDoubleAction: @selector(controlDoubleAction:)];
2020         }
2021
2022     }
2023 }
2024
2025 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2026 {
2027     wxKeyEvent wxevent(wxEVT_CHAR);
2028     SetupKeyEvent( wxevent, event, text );
2029
2030     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2031 }
2032
2033 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2034 {
2035     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2036     SetupKeyEvent( wxevent, event );
2037     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2038
2039     // this will fire higher level events, like insertText, to help
2040     // us handle EVT_CHAR, etc.
2041
2042     if ( m_wxPeer->MacIsUserPane() && [event type] == NSKeyDown)
2043     {
2044         if ( !result )
2045         {
2046             if ( wxevent.GetKeyCode() < WXK_SPACE || wxevent.GetKeyCode() == WXK_DELETE || wxevent.GetKeyCode() >= WXK_START )
2047             {
2048                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2049                 wxKeyEvent wxevent2(wxevent) ;
2050                 wxevent2.SetEventType(wxEVT_CHAR);
2051                 GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2052             }
2053             else
2054             {
2055                 if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2056                     [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2057                 else
2058                     [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2059             }
2060             result = true;
2061         }
2062     }
2063
2064     return result;
2065 }
2066
2067 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2068 {
2069     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2070     SetupMouseEvent(wxevent , event) ;
2071
2072     return GetWXPeer()->HandleWindowEvent(wxevent);
2073 }
2074
2075 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2076 {
2077     wxWindow* thisWindow = GetWXPeer();
2078     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2079     {
2080         thisWindow->MacInvalidateBorders();
2081     }
2082
2083     if ( receivedFocus )
2084     {
2085         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2086         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2087         thisWindow->HandleWindowEvent(eventFocus);
2088
2089 #if wxUSE_CARET
2090         if ( thisWindow->GetCaret() )
2091             thisWindow->GetCaret()->OnSetFocus();
2092 #endif
2093
2094         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2095         event.SetEventObject(thisWindow);
2096         if (otherWindow)
2097             event.SetWindow(otherWindow->GetWXPeer());
2098         thisWindow->HandleWindowEvent(event) ;
2099     }
2100     else // !receivedFocuss
2101     {
2102 #if wxUSE_CARET
2103         if ( thisWindow->GetCaret() )
2104             thisWindow->GetCaret()->OnKillFocus();
2105 #endif
2106
2107         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2108
2109         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2110         event.SetEventObject(thisWindow);
2111         if (otherWindow)
2112             event.SetWindow(otherWindow->GetWXPeer());
2113         thisWindow->HandleWindowEvent(event) ;
2114     }
2115 }
2116
2117 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2118 {
2119     NSPoint location = [NSEvent mouseLocation];
2120     location = [[m_osxView window] convertScreenToBase:location];
2121     NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2122
2123     if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2124     {
2125         [(NSCursor*)cursor.GetHCURSOR() set];
2126     }
2127     [[m_osxView window] invalidateCursorRectsForView:m_osxView];
2128 }
2129
2130 void wxWidgetCocoaImpl::CaptureMouse()
2131 {
2132     [[m_osxView window] disableCursorRects];
2133 }
2134
2135 void wxWidgetCocoaImpl::ReleaseMouse()
2136 {
2137     [[m_osxView window] enableCursorRects];
2138 }
2139
2140 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2141 {
2142     m_isFlipped = flipped;
2143 }
2144
2145 //
2146 // Factory methods
2147 //
2148
2149 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2150     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2151     long WXUNUSED(style), long WXUNUSED(extraStyle))
2152 {
2153     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2154     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2155
2156     // temporary hook for dnd
2157     [v registerForDraggedTypes:[NSArray arrayWithObjects:
2158         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
2159
2160     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v );
2161     return c;
2162 }
2163
2164 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2165 {
2166     NSWindow* tlw = now->GetWXWindow();
2167
2168     wxWidgetCocoaImpl* c = NULL;
2169     if ( now->IsNativeWindowWrapper() )
2170     {
2171         NSView* cv = [tlw contentView];
2172         c = new wxWidgetCocoaImpl( now, cv, true );
2173         // increase ref count, because the impl destructor will decrement it again
2174         CFRetain(cv);
2175         if ( !now->IsShown() )
2176             [cv setHidden:NO];
2177
2178     }
2179     else
2180     {
2181         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2182         c = new wxWidgetCocoaImpl( now, v, true );
2183         c->InstallEventHandler();
2184         [tlw setContentView:v];
2185     }
2186     return c;
2187 }