src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16     #include "wx/app.h"
  17     #include "wx/dialog.h"
  18     #include "wx/menuitem.h"
  19     #include "wx/menu.h"
  20 #endif
  21
  22 #include "wx/osx/private.h"
  23
  24 NSScreen* wxOSXGetMenuScreen()
  25 {
  26     if ( [NSScreen screens] == nil )
  27         return [NSScreen mainScreen];
  28     else
  29     {
  30         return [[NSScreen screens] objectAtIndex:0];
  31     }
  32 }
  33
  34 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  35 {
  36     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  37     int y = r.y;
  38     int x = r.x ;
  39     if ( parent == NULL || ![ parent isFlipped ] )
  40         y = (int)(frame.size.height - ( r.y + r.height ));
  41     return NSMakeRect(x, y, r.width , r.height);
  42 }
  43
  44 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  45 {
  46     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  47     int y = (int)rect.origin.y;
  48     int x = (int)rect.origin.x;
  49     if ( parent == NULL || ![ parent isFlipped ] )
  50         y = (int)(frame.size.height - (rect.origin.y + rect.size.height));
  51     return wxRect( x, y, (int)rect.size.width, (int)rect.size.height );
  52 }
  53
  54 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  55 {
  56     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  57     int x = p.x ;
  58     int y = p.y;
  59     if ( parent == NULL || ![ parent isFlipped ] )
  60         y = (int)(frame.size.height - ( p.y ));
  61     return NSMakePoint(x, y);
  62 }
  63
  64 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  65 {
  66     NSRect frame = parent ? [parent bounds] : [wxOSXGetMenuScreen() frame];
  67     int x = (int)p.x;
  68     int y = (int)p.y;
  69     if ( parent == NULL || ![ parent isFlipped ] )
  70         y = (int)(frame.size.height - ( p.y ));
  71     return wxPoint( x, y);
  72 }
  73
  74 bool shouldHandleSelector(SEL selector)
  75 {
  76     if (selector == @selector(noop:)
  77             || selector == @selector(complete:)
  78             || selector == @selector(deleteBackward:)
  79             || selector == @selector(deleteForward:)
  80             || selector == @selector(insertNewline:)
  81             || selector == @selector(insertTab:)
  82             || selector == @selector(insertBacktab:)
  83             || selector == @selector(keyDown:)
  84             || selector == @selector(keyUp:)
  85             || selector == @selector(scrollPageUp:)
  86             || selector == @selector(scrollPageDown:)
  87             || selector == @selector(scrollToBeginningOfDocument:)
  88             || selector == @selector(scrollToEndOfDocument:))
  89         return false;
  90
  91     return true;
  92
  93 }
  94
  95 //
  96 // wx category for NSWindow (our own and wrapped instances)
  97 //
  98
  99 @interface NSWindow (wxNSWindowSupport)
 100
 101 - (wxNonOwnedWindowCocoaImpl*) WX_implementation;
 102
 103 - (bool) WX_filterSendEvent:(NSEvent *) event;
 104
 105 @end
 106
 107 @implementation NSWindow (wxNSWindowSupport)
 108
 109 - (wxNonOwnedWindowCocoaImpl*) WX_implementation
 110 {
 111     return (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 112 }
 113
 114 // TODO in cocoa everything during a drag is sent to the NSWindow the mouse down occured,
 115 // this does not conform to the wx behaviour if the window is not captured, so try to resend
 116 // or capture all wx mouse event handling at the tlw as we did for carbon
 117
 118 - (bool) WX_filterSendEvent:(NSEvent *) event
 119 {
 120     bool handled = false;
 121     if ( ([event type] >= NSLeftMouseDown) && ([event type] <= NSMouseExited) )
 122     {
 123         wxWindow* cw = wxWindow::GetCapture();
 124         if ( cw != NULL )
 125         {
 126             ((wxWidgetCocoaImpl*)cw->GetPeer())->DoHandleMouseEvent( event);
 127             handled = true;
 128         }
 129     }
 130     return handled;
 131 }
 132 @end
 133
 134 //
 135 // wx native implementation
 136 //
 137
 138 @interface wxNSWindow : NSWindow
 139 {
 140 }
 141
 142 - (void) sendEvent:(NSEvent *)event;
 143 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 144 - (void)noResponderFor: (SEL) selector;
 145 @end
 146
 147 @implementation wxNSWindow
 148
 149 - (void)sendEvent:(NSEvent *) event
 150 {
 151     if ( ![self WX_filterSendEvent: event] )
 152     {
 153         WXEVENTREF formerEvent = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEvent();
 154         WXEVENTHANDLERCALLREF formerHandler = wxTheApp == NULL ? NULL : wxTheApp->MacGetCurrentEventHandlerCallRef();
 155
 156         if (wxTheApp)
 157             wxTheApp->MacSetCurrentEvent(event, NULL);
 158
 159         [super sendEvent: event];
 160
 161         if (wxTheApp)
 162             wxTheApp->MacSetCurrentEvent(formerEvent , formerHandler);
 163     }
 164 }
 165
 166 // The default implementation always moves the window back onto the screen,
 167 // even when the programmer explicitly wants to hide it.
 168 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 169 {
 170     wxUnusedVar(screen);
 171     return frameRect;
 172 }
 173
 174 - (void)doCommandBySelector:(SEL)selector
 175 {
 176     if (shouldHandleSelector(selector) &&
 177         !(selector == @selector(cancel:) || selector == @selector(cancelOperation:)) )
 178         [super doCommandBySelector:selector];
 179 }
 180
 181
 182 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 183 - (void)noResponderFor: (SEL) selector
 184 {
 185     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 186     {
 187         [super noResponderFor:selector];
 188     }
 189 }
 190
 191 // We need this for borderless windows, i.e. shaped windows or windows without
 192 // a title bar. For more info, see:
 193 // http://lists.apple.com/archives/cocoa-dev/2008/May/msg02091.html
 194 - (BOOL)canBecomeKeyWindow
 195 {
 196     return YES;
 197 }
 198
 199 @end
 200
 201 @interface wxNSPanel : NSPanel
 202 {
 203 }
 204
 205 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
 206 - (void)noResponderFor: (SEL) selector;
 207 - (void)sendEvent:(NSEvent *)event;
 208 @end
 209
 210 @implementation wxNSPanel
 211
 212 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 213 {
 214     wxNonOwnedWindowCocoaImpl* impl = (wxNonOwnedWindowCocoaImpl*) wxNonOwnedWindowImpl::FindFromWXWindow( self );
 215     if (impl && impl->IsFullScreen())
 216         return frameRect;
 217     else
 218         return [super constrainFrameRect:frameRect toScreen:screen];
 219 }
 220
 221 - (BOOL)canBecomeKeyWindow
 222 {
 223     return YES;
 224 }
 225
 226 - (void)doCommandBySelector:(SEL)selector
 227 {
 228     if (shouldHandleSelector(selector))
 229         [super doCommandBySelector:selector];
 230 }
 231
 232 // NB: if we don't do this, it seems that all events that end here lead to a NSBeep
 233 - (void)noResponderFor: (SEL) selector
 234 {
 235     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 236     {
 237         [super noResponderFor:selector];
 238     }
 239 }
 240
 241 - (void)sendEvent:(NSEvent *) event
 242 {
 243     if ( ![self WX_filterSendEvent: event] )
 244         [super sendEvent: event];
 245 }
 246
 247 @end
 248
 249
 250 //
 251 // controller
 252 //
 253
 254 @interface wxNonOwnedWindowController : NSObject wxOSX_10_6_AND_LATER(<NSWindowDelegate>)
 255 {
 256 }
 257
 258 - (void)windowDidResize:(NSNotification *)notification;
 259 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 260 - (void)windowDidResignKey:(NSNotification *)notification;
 261 - (void)windowDidBecomeKey:(NSNotification *)notification;
 262 - (void)windowDidMove:(NSNotification *)notification;
 263 - (BOOL)windowShouldClose:(id)window;
 264 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame;
 265
 266 @end
 267
 268 extern int wxOSXGetIdFromSelector(SEL action );
 269
 270 @implementation wxNonOwnedWindowController
 271
 272 - (id) init
 273 {
 274     self = [super init];
 275     return self;
 276 }
 277
 278 - (BOOL) triggerMenu:(SEL) action
 279 {
 280     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 281     if ( mbar )
 282     {
 283         wxMenu* menu = NULL;
 284         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 285         if ( menu != NULL && menuitem != NULL)
 286             return menu->HandleCommandProcess(menuitem);
 287     }
 288     return NO;
 289 }
 290
 291 - (BOOL)validateMenuItem:(NSMenuItem *)menuItem
 292 {
 293     SEL action = [menuItem action];
 294
 295     wxMenuBar* mbar = wxMenuBar::MacGetInstalledMenuBar();
 296     if ( mbar )
 297     {
 298         wxMenu* menu = NULL;
 299         wxMenuItem* menuitem = mbar->FindItem(wxOSXGetIdFromSelector(action), &menu);
 300         if ( menu != NULL && menuitem != NULL)
 301         {
 302             menu->HandleCommandUpdateStatus(menuitem);
 303             return menuitem->IsEnabled();
 304         }
 305     }
 306     return YES;
 307 }
 308
 309 - (void)undo:(id)sender
 310 {
 311     wxUnusedVar(sender);
 312     [self triggerMenu:_cmd];
 313 }
 314
 315 - (void)redo:(id)sender
 316 {
 317     wxUnusedVar(sender);
 318     [self triggerMenu:_cmd];
 319 }
 320
 321 - (void)cut:(id)sender
 322 {
 323     wxUnusedVar(sender);
 324     [self triggerMenu:_cmd];
 325 }
 326
 327 - (void)copy:(id)sender
 328 {
 329     wxUnusedVar(sender);
 330     [self triggerMenu:_cmd];
 331 }
 332
 333 - (void)paste:(id)sender
 334 {
 335     wxUnusedVar(sender);
 336     [self triggerMenu:_cmd];
 337 }
 338
 339 - (void)delete:(id)sender
 340 {
 341     wxUnusedVar(sender);
 342     [self triggerMenu:_cmd];
 343 }
 344
 345 - (void)selectAll:(id)sender
 346 {
 347     wxUnusedVar(sender);
 348     [self triggerMenu:_cmd];
 349 }
 350
 351 - (BOOL)windowShouldClose:(id)nwindow
 352 {
 353     wxNonOwnedWindowCocoaImpl* windowimpl = [(NSWindow*) nwindow WX_implementation];
 354     if ( windowimpl )
 355     {
 356         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 357         if ( wxpeer )
 358             wxpeer->Close();
 359     }
 360     return NO;
 361 }
 362
 363 - (NSSize)windowWillResize:(NSWindow *)window
 364                     toSize:(NSSize)proposedFrameSize
 365 {
 366     NSRect frame = [window frame];
 367     wxRect wxframe = wxFromNSRect( NULL, frame );
 368     wxframe.SetWidth( (int)proposedFrameSize.width );
 369     wxframe.SetHeight( (int)proposedFrameSize.height );
 370
 371     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 372     if ( windowimpl )
 373     {
 374         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 375         if ( wxpeer )
 376         {
 377             wxpeer->HandleResizing( 0, &wxframe );
 378             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 379             return newSize;
 380         }
 381     }
 382
 383     return proposedFrameSize;
 384 }
 385
 386 - (void)windowDidResize:(NSNotification *)notification
 387 {
 388     NSWindow* window = (NSWindow*) [notification object];
 389     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 390     if ( windowimpl )
 391     {
 392         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 393         if ( wxpeer )
 394             wxpeer->HandleResized(0);
 395     }
 396 }
 397
 398 - (void)windowDidMove:(NSNotification *)notification
 399 {
 400     wxNSWindow* window = (wxNSWindow*) [notification object];
 401     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 402     if ( windowimpl )
 403     {
 404         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 405         if ( wxpeer )
 406             wxpeer->HandleMoved(0);
 407     }
 408 }
 409
 410 - (void)windowDidBecomeKey:(NSNotification *)notification
 411 {
 412     NSWindow* window = (NSWindow*) [notification object];
 413     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 414     if ( windowimpl )
 415     {
 416         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 417         if ( wxpeer )
 418             wxpeer->HandleActivated(0, true);
 419     }
 420 }
 421
 422 - (void)windowDidResignKey:(NSNotification *)notification
 423 {
 424     NSWindow* window = (NSWindow*) [notification object];
 425     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 426     if ( windowimpl )
 427     {
 428         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 429         if ( wxpeer )
 430         {
 431             wxpeer->HandleActivated(0, false);
 432             // Needed for popup window since the firstResponder
 433             // (focus in wx) doesn't change when this
 434             // TLW becomes inactive.
 435             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 436             event.SetEventObject(wxpeer);
 437             wxpeer->HandleWindowEvent(event);
 438         }
 439     }
 440 }
 441
 442 - (id)windowWillReturnFieldEditor:(NSWindow *)sender toObject:(id)anObject
 443 {
 444     wxUnusedVar(sender);
 445
 446     if ([anObject isKindOfClass:[wxNSTextField class]])
 447     {
 448         wxNSTextField* tf = (wxNSTextField*) anObject;
 449         wxNSTextFieldEditor* editor = [tf fieldEditor];
 450         if ( editor == nil )
 451         {
 452             editor = [[wxNSTextFieldEditor alloc] init];
 453             [editor setFieldEditor:YES];
 454             [tf setFieldEditor:editor];
 455             [editor release];
 456         }
 457         return editor;
 458     }
 459
 460     return nil;
 461 }
 462
 463 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame
 464 {
 465     wxUnusedVar(newFrame);
 466     wxNonOwnedWindowCocoaImpl* windowimpl = [window WX_implementation];
 467     if ( windowimpl )
 468     {
 469         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 470         wxMaximizeEvent event(wxpeer->GetId());
 471         event.SetEventObject(wxpeer);
 472         return !wxpeer->HandleWindowEvent(event);
 473     }
 474     return true;
 475 }
 476
 477 @end
 478
 479 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 480
 481 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 482     wxNonOwnedWindowImpl(nonownedwnd)
 483 {
 484     m_macWindow = NULL;
 485     m_macFullScreenData = NULL;
 486 }
 487
 488 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 489 {
 490     m_macWindow = NULL;
 491     m_macFullScreenData = NULL;
 492 }
 493
 494 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 495 {
 496     if ( !m_wxPeer->IsNativeWindowWrapper() )
 497     {
 498         [m_macWindow setDelegate:nil];
 499         [m_macWindow release];
 500     }
 501 }
 502
 503 void wxNonOwnedWindowCocoaImpl::WillBeDestroyed()
 504 {
 505     if ( !m_wxPeer->IsNativeWindowWrapper() )
 506     {
 507         [m_macWindow setDelegate:nil];
 508     }
 509 }
 510
 511 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* parent, const wxPoint& pos, const wxSize& size,
 512 long style, long extraStyle, const wxString& WXUNUSED(name) )
 513 {
 514     static wxNonOwnedWindowController* controller = NULL;
 515
 516     if ( !controller )
 517         controller =[[wxNonOwnedWindowController alloc] init];
 518
 519
 520     int windowstyle = NSBorderlessWindowMask;
 521
 522     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 523             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 524     {
 525         m_macWindow = [wxNSPanel alloc];
 526     }
 527     else
 528         m_macWindow = [wxNSWindow alloc];
 529
 530     CGWindowLevel level = kCGNormalWindowLevel;
 531
 532     if ( style & wxFRAME_TOOL_WINDOW )
 533     {
 534         windowstyle |= NSUtilityWindowMask;
 535         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 536             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 537         {
 538             windowstyle |= NSTitledWindowMask ;
 539         }
 540     }
 541     else if ( ( style & wxPOPUP_WINDOW ) )
 542     {
 543         level = kCGPopUpMenuWindowLevel;
 544         /*
 545         if ( ( style & wxBORDER_NONE ) )
 546         {
 547             wclass = kHelpWindowClass ;   // has no border
 548             attr |= kWindowNoShadowAttribute;
 549         }
 550         else
 551         {
 552             wclass = kPlainWindowClass ;  // has a single line border, it will have to do for now
 553         }
 554         */
 555     }
 556     else if ( ( style & wxCAPTION ) )
 557     {
 558         windowstyle |= NSTitledWindowMask ;
 559     }
 560     else if ( ( style & wxFRAME_DRAWER ) )
 561     {
 562         /*
 563         wclass = kDrawerWindowClass;
 564         */
 565     }
 566     else
 567     {
 568         // set these even if we have no title, otherwise the controls won't be visible
 569         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 570             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 571         {
 572             windowstyle |= NSTitledWindowMask ;
 573         }
 574         /*
 575         else if ( ( style & wxNO_BORDER ) )
 576         {
 577             wclass = kSimpleWindowClass ;
 578         }
 579         else
 580         {
 581             wclass = kPlainWindowClass ;
 582         }
 583         */
 584     }
 585
 586     if ( windowstyle & NSTitledWindowMask )
 587     {
 588         if ( ( style & wxMINIMIZE_BOX ) )
 589             windowstyle |= NSMiniaturizableWindowMask ;
 590
 591         if ( ( style & wxMAXIMIZE_BOX ) )
 592             windowstyle |= NSResizableWindowMask ; // TODO showing ZOOM ?
 593
 594         if ( ( style & wxRESIZE_BORDER ) )
 595             windowstyle |= NSResizableWindowMask ;
 596
 597         if ( ( style & wxCLOSE_BOX) )
 598             windowstyle |= NSClosableWindowMask ;
 599     }
 600     if ( extraStyle & wxFRAME_EX_METAL)
 601         windowstyle |= NSTexturedBackgroundWindowMask;
 602
 603     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 604         level = kCGFloatingWindowLevel;
 605
 606     if ( ( style & wxSTAY_ON_TOP ) )
 607         level = kCGUtilityWindowLevel;
 608
 609     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 610
 611     r = [NSWindow contentRectForFrameRect:r styleMask:windowstyle];
 612
 613     [m_macWindow initWithContentRect:r
 614         styleMask:windowstyle
 615         backing:NSBackingStoreBuffered
 616         defer:NO
 617         ];
 618
 619     // If the parent is modal, windows with wxFRAME_FLOAT_ON_PARENT style need
 620     // to be in kCGUtilityWindowLevel and not kCGFloatingWindowLevel to stay
 621     // above the parent.
 622     wxDialog * const parentDialog = wxDynamicCast(parent, wxDialog);
 623     if (parentDialog && parentDialog->IsModal())
 624     {
 625         if (level == kCGFloatingWindowLevel)
 626         {
 627             level = kCGUtilityWindowLevel;
 628         }
 629
 630         // Cocoa's modal loop does not process other windows by default, but
 631         // don't call this on normal window levels so nested modal dialogs will
 632         // still behave modally.
 633         if (level != kCGNormalWindowLevel)
 634         {
 635             if ([m_macWindow isKindOfClass:[NSPanel class]])
 636             {
 637                 [(NSPanel*)m_macWindow setWorksWhenModal:YES];
 638             }
 639         }
 640     }
 641
 642     [m_macWindow setLevel:level];
 643     m_macWindowLevel = level;
 644
 645     [m_macWindow setDelegate:controller];
 646
 647     [m_macWindow setAcceptsMouseMovedEvents: YES];
 648
 649     if ( ( style & wxFRAME_SHAPED) )
 650     {
 651         [m_macWindow setOpaque:NO];
 652         [m_macWindow setAlphaValue:1.0];
 653     }
 654
 655     if ( !(style & wxFRAME_TOOL_WINDOW) )
 656         [m_macWindow setHidesOnDeactivate:NO];
 657 }
 658
 659 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), WXWindow nativeWindow )
 660 {
 661     m_macWindow = nativeWindow;
 662 }
 663
 664 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 665 {
 666     return m_macWindow;
 667 }
 668
 669 void wxNonOwnedWindowCocoaImpl::Raise()
 670 {
 671     [m_macWindow makeKeyAndOrderFront:nil];
 672 }
 673
 674 void wxNonOwnedWindowCocoaImpl::Lower()
 675 {
 676     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 677 }
 678
 679 void wxNonOwnedWindowCocoaImpl::ShowWithoutActivating()
 680 {
 681     [m_macWindow orderFront:nil];
 682     [[m_macWindow contentView] setNeedsDisplay: YES];
 683 }
 684
 685 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 686 {
 687     if ( show )
 688     {
 689         wxNonOwnedWindow* wxpeer = GetWXPeer();
 690         if (wxpeer && !(wxpeer->GetWindowStyle() & wxFRAME_TOOL_WINDOW))
 691             [m_macWindow makeKeyAndOrderFront:nil];
 692         else
 693             [m_macWindow orderFront:nil];
 694         [[m_macWindow contentView] setNeedsDisplay: YES];
 695     }
 696     else
 697         [m_macWindow orderOut:nil];
 698     return true;
 699 }
 700
 701 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show,
 702                                                wxShowEffect effect,
 703                                                unsigned timeout)
 704 {
 705     return wxWidgetCocoaImpl::
 706             ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
 707 }
 708
 709 void wxNonOwnedWindowCocoaImpl::Update()
 710 {
 711     [m_macWindow displayIfNeeded];
 712 }
 713
 714 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 715 {
 716     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 717     return true;
 718 }
 719
 720 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& col )
 721 {
 722     [m_macWindow setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
 723                                                              green:(CGFloat) (col.Green() / 255.0)
 724                                                               blue:(CGFloat) (col.Blue() / 255.0)
 725                                                              alpha:(CGFloat) (col.Alpha() / 255.0)]];
 726     return true;
 727 }
 728
 729 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 730 {
 731     if ( m_macWindow )
 732     {
 733         bool metal = exStyle & wxFRAME_EX_METAL ;
 734         int windowStyle = [ m_macWindow styleMask];
 735         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 736         {
 737             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 738         }
 739         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 740         {
 741             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 742         }
 743     }
 744 }
 745
 746 void wxNonOwnedWindowCocoaImpl::SetWindowStyleFlag( long style )
 747 {
 748     if (m_macWindow)
 749     {
 750         CGWindowLevel level = kCGNormalWindowLevel;
 751
 752         if (style & wxSTAY_ON_TOP)
 753             level = kCGUtilityWindowLevel;
 754         else if (( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ))
 755             level = kCGFloatingWindowLevel;
 756
 757         [m_macWindow setLevel: level];
 758         m_macWindowLevel = level;
 759     }
 760 }
 761
 762 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle style)
 763 {
 764     if ( style == wxBG_STYLE_TRANSPARENT )
 765     {
 766         [m_macWindow setOpaque:NO];
 767         [m_macWindow setBackgroundColor:[NSColor clearColor]];
 768     }
 769
 770     return true;
 771 }
 772
 773 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 774 {
 775     return true;
 776 }
 777
 778 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 779 {
 780     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 781     // do not trigger refreshes upon invisible and possible partly created objects
 782     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 783 }
 784
 785 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 786 {
 787     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 788     x = r.GetLeft();
 789     y = r.GetTop();
 790 }
 791
 792 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 793 {
 794     NSRect rect = [m_macWindow frame];
 795     width = (int)rect.size.width;
 796     height = (int)rect.size.height;
 797 }
 798
 799 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 800 {
 801     NSRect rect = [[m_macWindow contentView] frame];
 802     left = (int)rect.origin.x;
 803     top = (int)rect.origin.y;
 804     width = (int)rect.size.width;
 805     height = (int)rect.size.height;
 806 }
 807
 808 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& WXUNUSED(region))
 809 {
 810     [m_macWindow setOpaque:NO];
 811     [m_macWindow setBackgroundColor:[NSColor clearColor]];
 812
 813     return true;
 814 }
 815
 816 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 817 {
 818     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 819 }
 820
 821 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 822 {
 823     if (([m_macWindow styleMask] & NSResizableWindowMask) != 0)
 824     {
 825         return [m_macWindow isZoomed];
 826     }
 827     else
 828     {
 829         NSRect rectScreen = [[NSScreen mainScreen] visibleFrame];
 830         NSRect rectWindow = [m_macWindow frame];
 831         return (rectScreen.origin.x == rectWindow.origin.x &&
 832                 rectScreen.origin.y == rectWindow.origin.y &&
 833                 rectScreen.size.width == rectWindow.size.width &&
 834                 rectScreen.size.height == rectWindow.size.height);
 835     }
 836 }
 837
 838 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 839 {
 840     return [m_macWindow isMiniaturized];
 841 }
 842
 843 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 844 {
 845     if ( iconize )
 846         [m_macWindow miniaturize:nil];
 847     else
 848         [m_macWindow deminiaturize:nil];
 849 }
 850
 851 void wxNonOwnedWindowCocoaImpl::Maximize(bool WXUNUSED(maximize))
 852 {
 853     [m_macWindow zoom:nil];
 854 }
 855
 856
 857 // http://cocoadevcentral.com/articles/000028.php
 858
 859 typedef struct
 860 {
 861     NSUInteger m_formerStyleMask;
 862     int m_formerLevel;
 863     NSRect m_formerFrame;
 864 } FullScreenData ;
 865
 866 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 867 {
 868     return m_macFullScreenData != NULL ;
 869 }
 870
 871 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long WXUNUSED(style))
 872 {
 873     if ( show )
 874     {
 875         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 876         delete data ;
 877         data = new FullScreenData();
 878
 879         m_macFullScreenData = data ;
 880         data->m_formerLevel = [m_macWindow level];
 881         data->m_formerFrame = [m_macWindow frame];
 882         data->m_formerStyleMask = [m_macWindow styleMask];
 883 #if 0
 884         // CGDisplayCapture( kCGDirectMainDisplay );
 885         //[m_macWindow setLevel:NSMainMenuWindowLevel+1/*CGShieldingWindowLevel()*/];
 886 #endif
 887         NSRect screenframe = [[NSScreen mainScreen] frame];
 888         NSRect frame = NSMakeRect (0, 0, 100, 100);
 889         NSRect contentRect;
 890
 891 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
 892         if ( [ m_macWindow respondsToSelector:@selector(setStyleMask:) ] )
 893             [m_macWindow setStyleMask:data->m_formerStyleMask & ~ NSResizableWindowMask];
 894 #endif
 895
 896         contentRect = [NSWindow contentRectForFrameRect: frame
 897                                 styleMask: [m_macWindow styleMask]];
 898         screenframe.origin.y += (frame.origin.y - contentRect.origin.y);
 899         screenframe.size.height += (frame.size.height - contentRect.size.height);
 900         [m_macWindow setFrame:screenframe display:YES];
 901
 902         SetSystemUIMode(kUIModeAllHidden,
 903                                 kUIOptionDisableAppleMenu
 904                         /*
 905                                 | kUIOptionDisableProcessSwitch
 906                                 | kUIOptionDisableForceQuit
 907                          */);
 908     }
 909     else if ( m_macFullScreenData != NULL )
 910     {
 911         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 912 #if 0
 913         // CGDisplayRelease( kCGDirectMainDisplay );
 914         // [m_macWindow setLevel:data->m_formerLevel];
 915 #endif
 916
 917         [m_macWindow setFrame:data->m_formerFrame display:YES];
 918 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_6
 919         if ( [ m_macWindow respondsToSelector:@selector(setStyleMask:) ] )
 920             [m_macWindow setStyleMask:data->m_formerStyleMask];
 921 #endif
 922         delete data ;
 923         m_macFullScreenData = NULL ;
 924
 925         SetSystemUIMode(kUIModeNormal, 0);
 926     }
 927
 928     return true;
 929 }
 930
 931 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int flagsWX)
 932 {
 933     NSRequestUserAttentionType flagsOSX;
 934     switch ( flagsWX )
 935     {
 936         case wxUSER_ATTENTION_INFO:
 937             flagsOSX = NSInformationalRequest;
 938             break;
 939
 940         case wxUSER_ATTENTION_ERROR:
 941             flagsOSX = NSCriticalRequest;
 942             break;
 943
 944         default:
 945             wxFAIL_MSG( "invalid RequestUserAttention() flags" );
 946             return;
 947     }
 948
 949     [NSApp requestUserAttention:flagsOSX];
 950 }
 951
 952 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 953 {
 954     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 955     NSPoint nspt = wxToNSPoint( NULL, p );
 956     nspt = [m_macWindow convertScreenToBase:nspt];
 957     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 958     p = wxFromNSPoint([m_macWindow contentView], nspt);
 959     if ( x )
 960         *x = p.x;
 961     if ( y )
 962         *y = p.y;
 963 }
 964
 965 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 966 {
 967     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 968     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 969     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 970     nspt = [m_macWindow convertBaseToScreen:nspt];
 971     p = wxFromNSPoint( NULL, nspt);
 972     if ( x )
 973         *x = p.x;
 974     if ( y )
 975         *y = p.y;
 976 }
 977
 978 bool wxNonOwnedWindowCocoaImpl::IsActive()
 979 {
 980     return [m_macWindow isKeyWindow];
 981 }
 982
 983 void wxNonOwnedWindowCocoaImpl::SetModified(bool modified)
 984 {
 985     [m_macWindow setDocumentEdited:modified];
 986 }
 987
 988 bool wxNonOwnedWindowCocoaImpl::IsModified() const
 989 {
 990     return [m_macWindow isDocumentEdited];
 991 }
 992
 993 void wxNonOwnedWindowCocoaImpl::SetRepresentedFilename(const wxString& filename)
 994 {
 995     [m_macWindow setRepresentedFilename:wxCFStringRef(filename).AsNSString()];
 996 }
 997
 998 void wxNonOwnedWindowCocoaImpl::RestoreWindowLevel()
 999 {
1000     if ( [m_macWindow level] != m_macWindowLevel )
1001         [m_macWindow setLevel:m_macWindowLevel];
1002 }
1003
1004 //
1005 //
1006 //
1007
1008 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, WXWindow nativeWindow)
1009 {
1010     wxNonOwnedWindowCocoaImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1011     now->Create( parent, nativeWindow );
1012     return now;
1013 }
1014
1015 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
1016     long style, long extraStyle, const wxString& name )
1017 {
1018     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
1019     now->Create( parent, pos, size, style , extraStyle, name );
1020     return now;
1021 }
1022