src/osx/carbon/utilscocoa.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/carbon/utils.mm
   3 // Purpose:     various cocoa mixin utility functions
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: utilscocoa.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxOSX_USE_COCOA_OR_CARBON
  15 #include <Cocoa/Cocoa.h>
  16 #else
  17 #import <UIKit/UIKit.h>
  18 #endif
  19
  20 #ifdef __WXMAC__
  21 #include "wx/osx/private.h"
  22 #endif
  23
  24 #include "wx/fontutil.h"
  25
  26 #if wxOSX_USE_COCOA
  27 #include "wx/cocoa/string.h"
  28 #endif
  29
  30 #ifdef __WXMAC__
  31
  32 #if wxOSX_USE_CARBON
  33 bool wxMacInitCocoa()
  34 {
  35     bool cocoaLoaded = NSApplicationLoad();
  36     wxASSERT_MSG(cocoaLoaded,wxT("Couldn't load Cocoa in Carbon Environment")) ;
  37     return cocoaLoaded;
  38 }
  39 #endif
  40
  41 wxMacAutoreleasePool::wxMacAutoreleasePool()
  42 {
  43     m_pool = [[NSAutoreleasePool alloc] init];
  44 }
  45
  46 wxMacAutoreleasePool::~wxMacAutoreleasePool()
  47 {
  48     [(NSAutoreleasePool*)m_pool release];
  49 }
  50
  51 #endif
  52
  53 #if wxOSX_USE_COCOA
  54
  55 CGContextRef wxOSXGetContextFromCurrentContext()
  56 {
  57     CGContextRef context = (CGContextRef)[[NSGraphicsContext currentContext]
  58                                           graphicsPort];
  59     return context;
  60 }
  61
  62 bool wxOSXLockFocus( WXWidget view)
  63 {
  64     return [view lockFocusIfCanDraw];
  65 }
  66
  67 void wxOSXUnlockFocus( WXWidget view)
  68 {
  69     [view unlockFocus];
  70 }
  71
  72 #endif
  73
  74 #if wxOSX_USE_IPHONE
  75
  76 CGContextRef wxOSXGetContextFromCurrentContext()
  77 {
  78     CGContextRef context = UIGraphicsGetCurrentContext();
  79     return context;
  80 }
  81
  82 #endif
  83
  84 // ----------------------------------------------------------------------------
  85 // NSObject Utils
  86 // ----------------------------------------------------------------------------
  87
  88 void wxMacCocoaRelease( void* obj )
  89 {
  90     [(NSObject*)obj release];
  91 }
  92
  93 void wxMacCocoaAutorelease( void* obj )
  94 {
  95     [(NSObject*)obj autorelease];
  96 }
  97
  98 void* wxMacCocoaRetain( void* obj )
  99 {
 100     [(NSObject*)obj retain];
 101     return obj;
 102 }
 103
 104 // ----------------------------------------------------------------------------
 105 // NSFont Utils
 106 // ----------------------------------------------------------------------------
 107
 108 #if wxOSX_USE_COCOA
 109 wxFont::wxFont(WX_NSFont nsfont)
 110 {
 111     [nsfont retain];
 112     wxNativeFontInfo info;
 113     SetNativeInfoFromNSFont(nsfont, &info);
 114     Create(info);
 115 }
 116
 117 void wxFont::SetNativeInfoFromNSFont(WX_NSFont theFont, wxNativeFontInfo* info)
 118 {
 119     if ( info->m_faceName.empty())
 120     {
 121         //Get more information about the user's chosen font
 122         NSFontTraitMask theTraits = [[NSFontManager sharedFontManager] traitsOfFont:theFont];
 123         int theFontWeight = [[NSFontManager sharedFontManager] weightOfFont:theFont];
 124
 125         wxFontFamily fontFamily = wxFONTFAMILY_DEFAULT;
 126         //Set the wx font to the appropriate data
 127         if(theTraits & NSFixedPitchFontMask)
 128             fontFamily = wxFONTFAMILY_TELETYPE;
 129
 130         wxFontStyle fontstyle = wxFONTSTYLE_NORMAL;
 131         wxFontWeight fontweight = wxFONTWEIGHT_NORMAL;
 132         bool underlined = false;
 133
 134         int size = (int) ([theFont pointSize]+0.5);
 135
 136         if ( theFontWeight >= 9 )
 137             fontweight = wxFONTWEIGHT_BOLD ;
 138         else if ( theFontWeight < 5 )
 139             fontweight = wxFONTWEIGHT_LIGHT;
 140         else
 141             fontweight = wxFONTWEIGHT_NORMAL ;
 142
 143         if ( theTraits & NSItalicFontMask )
 144             fontstyle = wxFONTSTYLE_ITALIC ;
 145
 146         info->Init(size,fontFamily,fontstyle,fontweight,underlined,
 147             wxStringWithNSString([theFont familyName]), wxFONTENCODING_DEFAULT);
 148
 149     }
 150 }
 151
 152 WX_NSFont wxFont::OSXCreateNSFont(wxOSXSystemFont font, wxNativeFontInfo* info)
 153 {
 154     NSFont* nsfont = nil;
 155     switch( font )
 156     {
 157         case wxOSX_SYSTEM_FONT_NORMAL:
 158             nsfont = [NSFont systemFontOfSize:[NSFont systemFontSize]];
 159             break;
 160         case wxOSX_SYSTEM_FONT_BOLD:
 161             nsfont = [NSFont boldSystemFontOfSize:[NSFont systemFontSize]];
 162             break;
 163         case wxOSX_SYSTEM_FONT_SMALL:
 164             nsfont = [NSFont systemFontOfSize:[NSFont smallSystemFontSize]];
 165             break;
 166         case wxOSX_SYSTEM_FONT_SMALL_BOLD:
 167             nsfont = [NSFont boldSystemFontOfSize:[NSFont smallSystemFontSize]];
 168             break;
 169         case wxOSX_SYSTEM_FONT_MINI:
 170             nsfont = [NSFont systemFontOfSize:
 171                 [NSFont systemFontSizeForControlSize:NSMiniControlSize]];
 172             break;
 173        case wxOSX_SYSTEM_FONT_MINI_BOLD:
 174             nsfont = [NSFont boldSystemFontOfSize:
 175                 [NSFont systemFontSizeForControlSize:NSMiniControlSize]];
 176             break;
 177         case wxOSX_SYSTEM_FONT_LABELS:
 178             nsfont = [NSFont labelFontOfSize:[NSFont labelFontSize]];
 179             break;
 180        case wxOSX_SYSTEM_FONT_VIEWS:
 181             nsfont = [NSFont controlContentFontOfSize:0];
 182             break;
 183         default:
 184             break;
 185     }
 186     [nsfont retain];
 187     SetNativeInfoFromNSFont(nsfont, info);
 188     return nsfont;
 189 }
 190
 191 WX_NSFont wxFont::OSXCreateNSFont(const wxNativeFontInfo* info)
 192 {
 193     NSFont* nsFont;
 194     int weight = 5;
 195     NSFontTraitMask traits = 0;
 196     if (info->m_weight == wxFONTWEIGHT_BOLD)
 197     {
 198         traits |= NSBoldFontMask;
 199         weight = 9;
 200     }
 201     else if (info->m_weight == wxFONTWEIGHT_LIGHT)
 202         weight = 3;
 203
 204     if (info->m_style == wxFONTSTYLE_ITALIC || info->m_style == wxFONTSTYLE_SLANT)
 205         traits |= NSItalicFontMask;
 206
 207     nsFont = [[NSFontManager sharedFontManager] fontWithFamily:wxCFStringRef(info->m_faceName).AsNSString()
 208         traits:traits weight:weight size:info->m_pointSize];
 209
 210     wxASSERT_MSG(nsFont != nil,wxT("Couldn't create nsFont")) ;
 211     wxMacCocoaRetain(nsFont);
 212     return nsFont;
 213 }
 214
 215 #endif
 216
 217 #if wxOSX_USE_IPHONE
 218
 219 WX_UIFont wxFont::OSXCreateUIFont(wxOSXSystemFont font, wxNativeFontInfo* info)
 220 {
 221     UIFont* uifont;
 222     switch( font )
 223     {
 224         case wxOSX_SYSTEM_FONT_NORMAL:
 225             uifont = [UIFont systemFontOfSize:[UIFont systemFontSize]];
 226             break;
 227         case wxOSX_SYSTEM_FONT_BOLD:
 228             uifont = [UIFont boldSystemFontOfSize:[UIFont systemFontSize]];
 229             break;
 230         case wxOSX_SYSTEM_FONT_MINI:
 231         case wxOSX_SYSTEM_FONT_SMALL:
 232             uifont = [UIFont systemFontOfSize:[UIFont smallSystemFontSize]];
 233             break;
 234         case wxOSX_SYSTEM_FONT_MINI_BOLD:
 235         case wxOSX_SYSTEM_FONT_SMALL_BOLD:
 236             uifont = [UIFont boldSystemFontOfSize:[UIFont smallSystemFontSize]];
 237             break;
 238         case wxOSX_SYSTEM_FONT_VIEWS:
 239         case wxOSX_SYSTEM_FONT_LABELS:
 240             uifont = [UIFont systemFontOfSize:[UIFont labelFontSize]];
 241             break;
 242         default:
 243             break;
 244     }
 245     [uifont retain];
 246     if ( info->m_faceName.empty())
 247     {
 248         wxFontStyle fontstyle = wxFONTSTYLE_NORMAL;
 249         wxFontWeight fontweight = wxFONTWEIGHT_NORMAL;
 250         bool underlined = false;
 251
 252         int size = (int) ([uifont pointSize]+0.5);
 253         /*
 254         NSFontSymbolicTraits traits = [desc symbolicTraits];
 255
 256         if ( traits & NSFontBoldTrait )
 257             fontweight = wxFONTWEIGHT_BOLD ;
 258         else
 259             fontweight = wxFONTWEIGHT_NORMAL ;
 260         if ( traits & NSFontItalicTrait )
 261             fontstyle = wxFONTSTYLE_ITALIC ;
 262         */
 263         wxCFStringRef fontname( wxCFRetain([uifont familyName]) );
 264         info->Init(size,wxFONTFAMILY_DEFAULT,fontstyle,fontweight,underlined,
 265             fontname.AsString(), wxFONTENCODING_DEFAULT);
 266
 267     }
 268     return uifont;
 269 }
 270
 271 WX_UIFont wxFont::OSXCreateUIFont(const wxNativeFontInfo* info)
 272 {
 273     UIFont* uiFont;
 274     uiFont = [UIFont fontWithName:wxCFStringRef(info->m_faceName).AsNSString() size:info->m_pointSize];
 275     wxMacCocoaRetain(uiFont);
 276     return uiFont;
 277 }
 278
 279 #endif
 280 // ----------------------------------------------------------------------------
 281 // NSImage Utils
 282 // ----------------------------------------------------------------------------
 283
 284 #if wxOSX_USE_IPHONE
 285
 286 WX_UIImage  wxOSXGetUIImageFromCGImage( CGImageRef image )
 287 {
 288     UIImage  *newImage = [UIImage imageWithCGImage:image];
 289     [newImage autorelease];
 290     return( newImage );
 291 }
 292
 293 #endif
 294
 295 #if wxOSX_USE_COCOA
 296
 297 //  From "Cocoa Drawing Guide:Working with Images"
 298 WX_NSImage  wxOSXGetNSImageFromCGImage( CGImageRef image )
 299 {
 300     NSRect      imageRect    = NSMakeRect(0.0, 0.0, 0.0, 0.0);
 301
 302     // Get the image dimensions.
 303     imageRect.size.height = CGImageGetHeight(image);
 304     imageRect.size.width = CGImageGetWidth(image);
 305
 306     // Create a new image to receive the Quartz image data.
 307     NSImage  *newImage = [[NSImage alloc] initWithSize:imageRect.size];
 308     [newImage lockFocus];
 309
 310     // Get the Quartz context and draw.
 311     CGContextRef  imageContext = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 312     CGContextDrawImage( imageContext, *(CGRect*)&imageRect, image );
 313     [newImage unlockFocus];
 314
 315     /*
 316         // Create a bitmap rep from the image...
 317         NSBitmapImageRep *bitmapRep = [[NSBitmapImageRep alloc] initWithCGImage:cgImage];
 318         // Create an NSImage and add the bitmap rep to it...
 319         NSImage *image = [[NSImage alloc] init];
 320         [image addRepresentation:bitmapRep];
 321         [bitmapRep release];
 322     */
 323     [newImage autorelease];
 324     return( newImage );
 325 }
 326
 327 CGImageRef wxOSXCreateCGImageFromNSImage( WX_NSImage nsimage )
 328 {
 329     // based on http://www.mail-archive.com/cocoa-dev@lists.apple.com/msg18065.html
 330
 331     NSSize imageSize = [nsimage size];
 332     CGColorSpaceRef genericRGB = CGColorSpaceCreateWithName(kCGColorSpaceGenericRGB);
 333     CGContextRef context = CGBitmapContextCreate(NULL, imageSize.width, imageSize.height, 8, 0, genericRGB, kCGImageAlphaPremultipliedFirst);
 334     NSGraphicsContext *nsGraphicsContext = [NSGraphicsContext graphicsContextWithGraphicsPort:context flipped:NO];
 335     [NSGraphicsContext saveGraphicsState];
 336     [NSGraphicsContext setCurrentContext:nsGraphicsContext];
 337     [[NSColor whiteColor] setFill];
 338     NSRectFill(NSMakeRect(0.0, 0.0, imageSize.width, imageSize.height));
 339     [nsimage drawAtPoint:NSZeroPoint fromRect:NSZeroRect operation:NSCompositeCopy fraction:1.0];
 340     [NSGraphicsContext setCurrentContext:nsGraphicsContext];
 341     CGImageRef image = CGBitmapContextCreateImage(context);
 342     CFRelease(context);
 343     return image;
 344  }
 345
 346 // ----------------------------------------------------------------------------
 347 // NSCursor Utils
 348 // ----------------------------------------------------------------------------
 349
 350 // copied from cursor.mm
 351
 352 static NSCursor* wxGetStockCursor( short sIndex )
 353 {
 354     ClassicCursor* pCursor = &gMacCursors[sIndex];
 355
 356     //Classic mac cursors are 1bps 16x16 black and white with a
 357     //identical mask that is 1 for on and 0 for off
 358     NSImage *theImage = [[NSImage alloc] initWithSize:NSMakeSize(16.0,16.0)];
 359
 360     //NSCursor takes an NSImage takes a number of Representations - here
 361     //we need only one for the raw data
 362     NSBitmapImageRep *theRep = [[NSBitmapImageRep alloc]
 363         initWithBitmapDataPlanes: NULL  // Tell Cocoa to allocate the planes for us.
 364         pixelsWide: 16      // All classic cursors are 16x16
 365         pixelsHigh: 16
 366         bitsPerSample: 1    // All classic cursors are bitmaps with bitmasks
 367         samplesPerPixel: 2  // Sample 0:image 1:mask
 368         hasAlpha: YES       // Identify last sample as a mask
 369         isPlanar: YES       // Use a separate array for each sample
 370         colorSpaceName: NSCalibratedWhiteColorSpace // 0.0=black 1.0=white
 371         bytesPerRow: 2      // Rows in each plane are on 2-byte boundaries (no pad)
 372         bitsPerPixel: 1];   // same as bitsPerSample since data is planar
 373
 374     // Ensure that Cocoa allocated 2 and only 2 of the 5 possible planes
 375     unsigned char *planes[5];
 376     [theRep getBitmapDataPlanes:planes];
 377     wxASSERT(planes[0] != NULL);
 378     wxASSERT(planes[1] != NULL);
 379     wxASSERT(planes[2] == NULL);
 380     wxASSERT(planes[3] == NULL);
 381     wxASSERT(planes[4] == NULL);
 382
 383     // NOTE1: The Cursor's bits field is white=0 black=1.. thus the bitwise-not
 384     // Why not use NSCalibratedBlackColorSpace?  Because that reverses the
 385     // sense of the alpha (mask) plane.
 386     // NOTE2: The mask data is 0=off 1=on
 387     // NOTE3: Cocoa asks for "premultiplied" color planes.  Since we have a
 388     // 1-bit color plane and a 1-bit alpha plane we can just do a bitwise-and
 389     // on the two.  The original cursor bitmaps have 0 (white actually) for
 390     // any masked-off pixels.  Therefore every masked-off pixel would be wrong
 391     // since we bit-flip all of the picture bits.  In practice, Cocoa doesn't
 392     // seem to care, but we are following the documentation.
 393
 394     // Fill in the color (black/white) plane
 395     for(int i=0; i<16; ++i)
 396     {
 397         planes[0][2*i  ] = (~pCursor->bits[i] & pCursor->mask[i]) >> 8 & 0xff;
 398         planes[0][2*i+1] = (~pCursor->bits[i] & pCursor->mask[i]) & 0xff;
 399     }
 400     // Fill in the alpha (i.e. mask) plane
 401     for(int i=0; i<16; ++i)
 402     {
 403         planes[1][2*i  ] = pCursor->mask[i] >> 8 & 0xff;
 404         planes[1][2*i+1] = pCursor->mask[i] & 0xff;
 405     }
 406
 407     //add the representation (data) to the image
 408     [theImage addRepresentation:theRep];
 409
 410     //create the new cursor
 411     NSCursor* theCursor =  [[NSCursor alloc]  initWithImage:theImage
 412                                     hotSpot:NSMakePoint(pCursor->hotspot[1], pCursor->hotspot[0])
 413                             ];
 414
 415     //do the usual cleanups
 416     [theRep release];
 417     [theImage release];
 418
 419     //return the new cursor
 420     return theCursor;
 421 }
 422
 423 WX_NSCursor wxMacCocoaCreateStockCursor( int cursor_type )
 424 {
 425     WX_NSCursor cursor = nil;
 426     switch (cursor_type)
 427     {
 428     case wxCURSOR_COPY_ARROW:
 429         cursor = [[NSCursor arrowCursor] retain];
 430         break;
 431
 432     case wxCURSOR_WATCH:
 433     case wxCURSOR_WAIT:
 434         // should be displayed by the system when things are running
 435         cursor = [[NSCursor arrowCursor] retain];
 436         break;
 437
 438     case wxCURSOR_IBEAM:
 439         cursor = [[NSCursor IBeamCursor] retain];
 440         break;
 441
 442     case wxCURSOR_CROSS:
 443         cursor = [[NSCursor crosshairCursor] retain];
 444         break;
 445
 446     case wxCURSOR_SIZENWSE:
 447         cursor = wxGetStockCursor(kwxCursorSizeNWSE);
 448         break;
 449
 450     case wxCURSOR_SIZENESW:
 451         cursor = wxGetStockCursor(kwxCursorSizeNESW);
 452         break;
 453
 454     case wxCURSOR_SIZEWE:
 455         cursor = [[NSCursor resizeLeftRightCursor] retain];
 456         break;
 457
 458     case wxCURSOR_SIZENS:
 459         cursor = [[NSCursor resizeUpDownCursor] retain];
 460         break;
 461
 462     case wxCURSOR_SIZING:
 463         cursor = wxGetStockCursor(kwxCursorSize);
 464         break;
 465
 466     case wxCURSOR_HAND:
 467         cursor = [[NSCursor pointingHandCursor] retain];
 468         break;
 469
 470     case wxCURSOR_BULLSEYE:
 471         cursor = wxGetStockCursor(kwxCursorBullseye);
 472         break;
 473
 474     case wxCURSOR_PENCIL:
 475         cursor = wxGetStockCursor(kwxCursorPencil);
 476         break;
 477
 478     case wxCURSOR_MAGNIFIER:
 479         cursor = wxGetStockCursor(kwxCursorMagnifier);
 480         break;
 481
 482     case wxCURSOR_NO_ENTRY:
 483         cursor = wxGetStockCursor(kwxCursorNoEntry);
 484         break;
 485
 486     case wxCURSOR_PAINT_BRUSH:
 487         cursor = wxGetStockCursor(kwxCursorPaintBrush);
 488         break;
 489
 490     case wxCURSOR_POINT_LEFT:
 491         cursor = wxGetStockCursor(kwxCursorPointLeft);
 492         break;
 493
 494     case wxCURSOR_POINT_RIGHT:
 495         cursor = wxGetStockCursor(kwxCursorPointRight);
 496         break;
 497
 498     case wxCURSOR_QUESTION_ARROW:
 499         cursor = wxGetStockCursor(kwxCursorQuestionArrow);
 500         break;
 501
 502     case wxCURSOR_BLANK:
 503         cursor = wxGetStockCursor(kwxCursorBlank);
 504         break;
 505
 506     case wxCURSOR_RIGHT_ARROW:
 507         cursor = wxGetStockCursor(kwxCursorRightArrow);
 508         break;
 509
 510     case wxCURSOR_SPRAYCAN:
 511         cursor = wxGetStockCursor(kwxCursorRoller);
 512         break;
 513
 514     case wxCURSOR_OPEN_HAND:
 515         cursor = [[NSCursor openHandCursor] retain];
 516         break;
 517
 518     case wxCURSOR_CLOSED_HAND:
 519         cursor = [[NSCursor closedHandCursor] retain];
 520         break;
 521
 522     case wxCURSOR_CHAR:
 523     case wxCURSOR_ARROW:
 524     case wxCURSOR_LEFT_BUTTON:
 525     case wxCURSOR_RIGHT_BUTTON:
 526     case wxCURSOR_MIDDLE_BUTTON:
 527     default:
 528         cursor = [[NSCursor arrowCursor] retain];
 529         break;
 530     }
 531     return cursor;
 532 }
 533
 534 //  C-based style wrapper routines around NSCursor
 535 WX_NSCursor  wxMacCocoaCreateCursorFromCGImage( CGImageRef cgImageRef, float hotSpotX, float hotSpotY )
 536 {
 537     static BOOL    firstTime  = YES;
 538
 539     if ( firstTime )
 540     {
 541         //  Must first call [[[NSWindow alloc] init] release] to get the NSWindow machinery set up so that NSCursor can use a window to cache the cursor image
 542         [[[NSWindow alloc] init] release];
 543         firstTime = NO;
 544     }
 545
 546     NSImage    *nsImage  = wxOSXGetNSImageFromCGImage( cgImageRef );
 547     NSCursor  *cursor    = [[NSCursor alloc] initWithImage:nsImage hotSpot:NSMakePoint( hotSpotX, hotSpotY )];
 548
 549     return cursor;
 550 }
 551
 552 void  wxMacCocoaSetCursor( WX_NSCursor cursor )
 553 {
 554     [cursor set];
 555 }
 556
 557 void  wxMacCocoaHideCursor()
 558 {
 559     [NSCursor hide];
 560 }
 561
 562 void  wxMacCocoaShowCursor()
 563 {
 564     [NSCursor unhide];
 565 }
 566
 567 #endif
 568