src/cocoa/dcclient.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/dcclient.mm
   3 // Purpose:     wxWindowDC, wxPaintDC, and wxClientDC classes
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2003/04/01
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) 2003 David Elliott
   9 // Licence:     wxWidgets licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/log.h"
  15     #include "wx/window.h"
  16     #include "wx/dcclient.h"
  17 #endif //WX_PRECOMP
  18
  19 #import <AppKit/NSView.h>
  20 #import <AppKit/NSAffineTransform.h>
  21 #import <AppKit/NSColor.h>
  22 #import <AppKit/NSGraphicsContext.h>
  23 #import <AppKit/NSBezierPath.h>
  24 #import <AppKit/NSWindow.h>
  25
  26 /*
  27  * wxWindowDC
  28  */
  29 IMPLEMENT_DYNAMIC_CLASS(wxWindowDC, wxDC)
  30
  31 wxWindowDC::wxWindowDC(void)
  32 :   m_window(NULL)
  33 ,   m_lockedNSView(NULL)
  34 {
  35 };
  36
  37 wxWindowDC::wxWindowDC( wxWindow *window )
  38 :   m_window(window)
  39 ,   m_lockedNSView(NULL)
  40 {
  41     wxLogDebug(wxT("non-client window DC's are not supported, oh well"));
  42 };
  43
  44 wxWindowDC::~wxWindowDC(void)
  45 {
  46     CocoaUnwindStackAndLoseFocus();
  47 };
  48
  49 bool wxWindowDC::CocoaLockFocusOnNSView(WX_NSView nsview)
  50 {
  51     if([nsview lockFocusIfCanDraw])
  52     {
  53         sm_cocoaDCStack.Insert(this);
  54         CocoaApplyTransformations();
  55         m_lockedNSView = nsview;
  56         return true;
  57     }
  58     wxLogDebug(wxT("focus lock failed!"));
  59     return false;
  60 }
  61
  62 bool wxWindowDC::CocoaUnlockFocusOnNSView()
  63 {
  64     [[m_lockedNSView window] flushWindow];
  65     [m_lockedNSView unlockFocus];
  66     m_lockedNSView = NULL;
  67     return true;
  68 }
  69
  70 bool wxWindowDC::CocoaLockFocus()
  71 {
  72     wxLogTrace(wxTRACE_COCOA,wxT("Locking focus on wxWindowDC=%p, NSView=%p"),this, m_window->GetNonClientNSView());
  73     m_cocoaWxToBoundsTransform = CocoaGetWxToBoundsTransform([m_window->GetNonClientNSView() isFlipped], [m_window->GetNonClientNSView() bounds].size.height);
  74     return CocoaLockFocusOnNSView(m_window->GetNonClientNSView());
  75 }
  76
  77 bool wxWindowDC::CocoaUnlockFocus()
  78 {
  79     wxLogTrace(wxTRACE_COCOA,wxT("Unlocking focus on wxWindowDC=%p, NSView=%p"),this, m_window->GetNonClientNSView());
  80     return CocoaUnlockFocusOnNSView();
  81 }
  82
  83 void wxWindowDC::Clear()
  84 {
  85     if(!CocoaTakeFocus()) return;
  86
  87     NSGraphicsContext *context = [NSGraphicsContext currentContext];
  88     [context saveGraphicsState];
  89
  90     [m_backgroundBrush.GetNSColor() set];
  91     [NSBezierPath fillRect:[m_lockedNSView bounds]];
  92
  93     [context restoreGraphicsState];
  94 }
  95
  96 /*
  97  * wxClientDC
  98  */
  99 IMPLEMENT_DYNAMIC_CLASS(wxClientDC, wxWindowDC)
 100
 101 wxClientDC::wxClientDC(void)
 102 {
 103 };
 104
 105 wxClientDC::wxClientDC( wxWindow *window )
 106 {
 107     m_window = window;
 108 };
 109
 110 wxClientDC::~wxClientDC(void)
 111 {
 112     CocoaUnwindStackAndLoseFocus();
 113 };
 114
 115 bool wxClientDC::CocoaLockFocus()
 116 {
 117     wxLogTrace(wxTRACE_COCOA,wxT("Locking focus on wxClientDC=%p, NSView=%p"),this, m_window->GetNSView());
 118     m_cocoaWxToBoundsTransform = m_window->CocoaGetWxToBoundsTransform();
 119     return CocoaLockFocusOnNSView(m_window->GetNSView());
 120 }
 121
 122 bool wxClientDC::CocoaUnlockFocus()
 123 {
 124     wxLogTrace(wxTRACE_COCOA,wxT("Unlocking focus on wxClientDC=%p, NSView=%p"),this, m_window->GetNSView());
 125     return CocoaUnlockFocusOnNSView();
 126 }
 127
 128 /*
 129  * wxPaintDC
 130  */
 131 IMPLEMENT_DYNAMIC_CLASS(wxPaintDC, wxWindowDC)
 132
 133 wxPaintDC::wxPaintDC(void)
 134 {
 135 };
 136
 137 wxPaintDC::wxPaintDC( wxWindow *window )
 138 {
 139     m_window = window;
 140     wxASSERT_MSG([NSView focusView]==window->GetNSView(), wxT("PaintDC's NSView does not have focus.  Please use wxPaintDC only as the first DC created in a paint handler"));
 141     sm_cocoaDCStack.Insert(this);
 142     m_lockedNSView = window->GetNSView();
 143     m_cocoaWxToBoundsTransform = window->CocoaGetWxToBoundsTransform();
 144     CocoaApplyTransformations();
 145 };
 146
 147 wxPaintDC::~wxPaintDC(void)
 148 {
 149     CocoaUnwindStackAndLoseFocus();
 150 };
 151
 152 bool wxPaintDC::CocoaLockFocus()
 153 {
 154     wxFAIL_MSG(wxT("wxPaintDC cannot be asked to lock focus!"));
 155     return false;
 156 }
 157
 158 bool wxPaintDC::CocoaUnlockFocus()
 159 {
 160     // wxPaintDC focus can never be unlocked.
 161     return false;
 162 }
 163