src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: window.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19 #endif
  20
  21 #ifdef __WXMAC__
  22     #include "wx/osx/private.h"
  23 #endif
  24
  25 #include "wx/evtloop.h"
  26
  27 #if wxUSE_CARET
  28     #include "wx/caret.h"
  29 #endif
  30
  31 #if wxUSE_DRAG_AND_DROP
  32     #include "wx/dnd.h"
  33 #endif
  34
  35 #if wxUSE_TOOLTIPS
  36     #include "wx/tooltip.h"
  37 #endif
  38
  39 #include <objc/objc-runtime.h>
  40
  41 // Get the window with the focus
  42
  43 NSView* GetViewFromResponder( NSResponder* responder )
  44 {
  45     NSView* view = nil;
  46     if ( [responder isKindOfClass:[NSTextView class]] )
  47     {
  48         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  49         if ( [delegate isKindOfClass:[NSTextField class] ] )
  50             view = delegate;
  51         else
  52             view =  (NSView*) responder;
  53     }
  54     else
  55     {
  56         if ( [responder isKindOfClass:[NSView class]] )
  57             view = (NSView*) responder;
  58     }
  59     return view;
  60 }
  61
  62 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  63 {
  64     NSView* focusedView = nil;
  65     if ( keyWindow != nil )
  66         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  67
  68     return focusedView;
  69 }
  70
  71 WXWidget wxWidgetImpl::FindFocus()
  72 {
  73     return GetFocusedViewInWindow( [NSApp keyWindow] );
  74 }
  75
  76 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  77 {
  78     int x, y, w, h ;
  79
  80     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  81     wxRect bounds(x,y,w,h);
  82     NSView* sv = (window->GetParent()->GetHandle() );
  83
  84     return wxToNSRect( sv, bounds );
  85 }
  86
  87 @interface wxNSView : NSView
  88 {
  89     NSTrackingRectTag rectTag;
  90 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  91     NSTrackingArea* _trackingArea;
  92 #endif
  93 }
  94
  95 // the tracking tag is needed to track mouse enter / exit events
  96 - (void) setTrackingTag: (NSTrackingRectTag)tag;
  97 - (NSTrackingRectTag) trackingTag;
  98 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  99 // under 10.5 we can also track mouse moved events on non-focused windows if
 100 // we use the new NSTrackingArea APIs.
 101 - (void) updateTrackingArea;
 102 - (NSTrackingArea*) trackingArea;
 103 #endif
 104 @end // wxNSView
 105
 106 @interface NSView(PossibleMethods)
 107 - (void)setTitle:(NSString *)aString;
 108 - (void)setStringValue:(NSString *)aString;
 109 - (void)setIntValue:(int)anInt;
 110 - (void)setFloatValue:(float)aFloat;
 111 - (void)setDoubleValue:(double)aDouble;
 112
 113 - (double)minValue;
 114 - (double)maxValue;
 115 - (void)setMinValue:(double)aDouble;
 116 - (void)setMaxValue:(double)aDouble;
 117
 118 - (void)sizeToFit;
 119
 120 - (BOOL)isEnabled;
 121 - (void)setEnabled:(BOOL)flag;
 122
 123 - (void)setImage:(NSImage *)image;
 124 - (void)setControlSize:(NSControlSize)size;
 125
 126 - (void)setFont:(NSFont *)fontObject;
 127
 128 - (id)contentView;
 129
 130 - (void)setTarget:(id)anObject;
 131 - (void)setAction:(SEL)aSelector;
 132 - (void)setDoubleAction:(SEL)aSelector;
 133 - (void)setBackgroundColor:(NSColor*)aColor;
 134 - (void)setOpaque:(BOOL)opaque;
 135 - (void)setTextColor:(NSColor *)color;
 136 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 137 @end
 138
 139 long wxOSXTranslateCocoaKey( NSEvent* event )
 140 {
 141     long retval = 0;
 142
 143     if ([event type] != NSFlagsChanged)
 144     {
 145         NSString* s = [event charactersIgnoringModifiers];
 146         // backspace char reports as delete w/modifiers for some reason
 147         if ([s length] == 1)
 148         {
 149             switch ( [s characterAtIndex:0] )
 150             {
 151                 // backspace key
 152                 case 0x7F :
 153                 case 8 :
 154                     retval = WXK_BACK;
 155                     break;
 156                 case NSUpArrowFunctionKey :
 157                     retval = WXK_UP;
 158                     break;
 159                 case NSDownArrowFunctionKey :
 160                     retval = WXK_DOWN;
 161                     break;
 162                 case NSLeftArrowFunctionKey :
 163                     retval = WXK_LEFT;
 164                     break;
 165                 case NSRightArrowFunctionKey :
 166                     retval = WXK_RIGHT;
 167                     break;
 168                 case NSInsertFunctionKey  :
 169                     retval = WXK_INSERT;
 170                     break;
 171                 case NSDeleteFunctionKey  :
 172                     retval = WXK_DELETE;
 173                     break;
 174                 case NSHomeFunctionKey  :
 175                     retval = WXK_HOME;
 176                     break;
 177         //        case NSBeginFunctionKey  :
 178         //            retval = WXK_BEGIN;
 179         //            break;
 180                 case NSEndFunctionKey  :
 181                     retval = WXK_END;
 182                     break;
 183                 case NSPageUpFunctionKey  :
 184                     retval = WXK_PAGEUP;
 185                     break;
 186                case NSPageDownFunctionKey  :
 187                     retval = WXK_PAGEDOWN;
 188                     break;
 189                case NSHelpFunctionKey  :
 190                     retval = WXK_HELP;
 191                     break;
 192                 default:
 193                     int intchar = [s characterAtIndex: 0];
 194                     if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 195                         retval = WXK_F1 + (intchar - NSF1FunctionKey );
 196                     break;
 197             }
 198         }
 199     }
 200
 201     // Some keys don't seem to have constants. The code mimics the approach
 202     // taken by WebKit. See:
 203     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 204     switch( [event keyCode] )
 205     {
 206         // command key
 207         case 54:
 208         case 55:
 209             retval = WXK_COMMAND;
 210             break;
 211         // caps locks key
 212         case 57: // Capslock
 213             retval = WXK_CAPITAL;
 214             break;
 215         // shift key
 216         case 56: // Left Shift
 217         case 60: // Right Shift
 218             retval = WXK_SHIFT;
 219             break;
 220         // alt key
 221         case 58: // Left Alt
 222         case 61: // Right Alt
 223             retval = WXK_ALT;
 224             break;
 225         // ctrl key
 226         case 59: // Left Ctrl
 227         case 62: // Right Ctrl
 228             retval = WXK_CONTROL;
 229             break;
 230         // clear key
 231         case 71:
 232             retval = WXK_CLEAR;
 233             break;
 234         // tab key
 235         case 48:
 236             retval = WXK_TAB;
 237             break;
 238
 239         case 75: // /
 240             retval = WXK_NUMPAD_DIVIDE;
 241             break;
 242         case 67: // *
 243             retval = WXK_NUMPAD_MULTIPLY;
 244             break;
 245         case 78: // -
 246             retval = WXK_NUMPAD_SUBTRACT;
 247             break;
 248         case 69: // +
 249             retval = WXK_NUMPAD_ADD;
 250             break;
 251         case 76: // Enter
 252             retval = WXK_NUMPAD_ENTER;
 253             break;
 254         case 65: // .
 255             retval = WXK_NUMPAD_DECIMAL;
 256             break;
 257         case 82: // 0
 258             retval = WXK_NUMPAD0;
 259             break;
 260         case 83: // 1
 261             retval = WXK_NUMPAD1;
 262             break;
 263         case 84: // 2
 264             retval = WXK_NUMPAD2;
 265             break;
 266         case 85: // 3
 267             retval = WXK_NUMPAD3;
 268             break;
 269         case 86: // 4
 270             retval = WXK_NUMPAD4;
 271             break;
 272         case 87: // 5
 273             retval = WXK_NUMPAD5;
 274             break;
 275         case 88: // 6
 276             retval = WXK_NUMPAD6;
 277             break;
 278         case 89: // 7
 279             retval = WXK_NUMPAD7;
 280             break;
 281         case 91: // 8
 282             retval = WXK_NUMPAD8;
 283             break;
 284         case 92: // 9
 285             retval = WXK_NUMPAD9;
 286             break;
 287         default:
 288             //retval = [event keyCode];
 289             break;
 290     }
 291     return retval;
 292 }
 293
 294 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 295 {
 296     UInt32 modifiers = [nsEvent modifierFlags] ;
 297     int eventType = [nsEvent type];
 298
 299     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 300     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 301     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 302     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 303
 304     wxevent.m_rawCode = [nsEvent keyCode];
 305     wxevent.m_rawFlags = modifiers;
 306
 307     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 308
 309     wxString chars;
 310     if ( eventType != NSFlagsChanged )
 311     {
 312         NSString* nschars = [nsEvent charactersIgnoringModifiers];
 313         if ( charString )
 314         {
 315             // if charString is set, it did not come from key up / key down
 316             wxevent.SetEventType( wxEVT_CHAR );
 317             chars = wxCFStringRef::AsString(charString);
 318         }
 319         else if ( nschars )
 320         {
 321             chars = wxCFStringRef::AsString(nschars);
 322         }
 323     }
 324
 325     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 326     long keyval = 0;
 327
 328     if (wxevent.GetEventType() != wxEVT_CHAR)
 329     {
 330         keyval = wxOSXTranslateCocoaKey(nsEvent) ;
 331         switch (eventType)
 332         {
 333             case NSKeyDown :
 334                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 335                 break;
 336             case NSKeyUp :
 337                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 338                 break;
 339             case NSFlagsChanged :
 340                 switch (keyval)
 341                 {
 342                     case WXK_CONTROL:
 343                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 344                         break;
 345                     case WXK_SHIFT:
 346                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 347                         break;
 348                     case WXK_ALT:
 349                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 350                         break;
 351                     case WXK_COMMAND:
 352                         wxevent.SetEventType( wxevent.m_metaDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 353                         break;
 354                 }
 355                 break;
 356             default :
 357                 break ;
 358         }
 359     }
 360
 361     if ( !keyval )
 362     {
 363         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 364             keyval = wxToupper( aunichar ) ;
 365         else
 366             keyval = aunichar;
 367     }
 368
 369 #if wxUSE_UNICODE
 370     wxevent.m_uniChar = aunichar;
 371 #endif
 372     wxevent.m_keyCode = keyval;
 373
 374     wxWindowMac* peer = GetWXPeer();
 375     if ( peer )
 376     {
 377         wxevent.SetEventObject(peer);
 378         wxevent.SetId(peer->GetId()) ;
 379     }
 380 }
 381
 382 UInt32 g_lastButton = 0 ;
 383 bool g_lastButtonWasFakeRight = false ;
 384
 385 // better scroll wheel support
 386 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 387
 388 @interface NSEvent (DeviceDelta)
 389 - (float)deviceDeltaX;
 390 - (float)deviceDeltaY;
 391 @end
 392
 393 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 394 {
 395     int eventType = [nsEvent type];
 396     UInt32 modifiers = [nsEvent modifierFlags] ;
 397
 398     NSPoint locationInWindow = [nsEvent locationInWindow];
 399
 400     // adjust coordinates for the window of the target view
 401     if ( [nsEvent window] != [m_osxView window] )
 402     {
 403         if ( [nsEvent window] != nil )
 404             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 405
 406         if ( [m_osxView window] != nil )
 407             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 408     }
 409
 410     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 411     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 412
 413     // these parameters are not given for all events
 414     UInt32 button = [nsEvent buttonNumber];
 415     UInt32 clickCount = 0;
 416
 417     wxevent.m_x = locationInViewWX.x;
 418     wxevent.m_y = locationInViewWX.y;
 419     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 420     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 421     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 422     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 423     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 424
 425     UInt32 mouseChord = 0;
 426
 427     switch (eventType)
 428     {
 429         case NSLeftMouseDown :
 430         case NSLeftMouseDragged :
 431             mouseChord = 1U;
 432             break;
 433         case NSRightMouseDown :
 434         case NSRightMouseDragged :
 435             mouseChord = 2U;
 436             break;
 437         case NSOtherMouseDown :
 438         case NSOtherMouseDragged :
 439             mouseChord = 4U;
 440             break;
 441     }
 442
 443     // a control click is interpreted as a right click
 444     bool thisButtonIsFakeRight = false ;
 445     if ( button == 0 && (modifiers & NSControlKeyMask) )
 446     {
 447         button = 1 ;
 448         thisButtonIsFakeRight = true ;
 449     }
 450
 451     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 452     if ( clickCount > 1 && button != g_lastButton )
 453         clickCount = 1 ;
 454
 455     // we must make sure that our synthetic 'right' button corresponds in
 456     // mouse down, moved and mouse up, and does not deliver a right down and left up
 457     switch (eventType)
 458     {
 459         case NSLeftMouseDown :
 460         case NSRightMouseDown :
 461         case NSOtherMouseDown :
 462             g_lastButton = button ;
 463             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 464             break;
 465      }
 466
 467     if ( button == 0 )
 468     {
 469         g_lastButton = 0 ;
 470         g_lastButtonWasFakeRight = false ;
 471     }
 472     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 473         button = g_lastButton ;
 474
 475     // Adjust the chord mask to remove the primary button and add the
 476     // secondary button.  It is possible that the secondary button is
 477     // already pressed, e.g. on a mouse connected to a laptop, but this
 478     // possibility is ignored here:
 479     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 480         mouseChord = ((mouseChord & ~1U) | 2U);
 481
 482     if(mouseChord & 1U)
 483                 wxevent.m_leftDown = true ;
 484     if(mouseChord & 2U)
 485                 wxevent.m_rightDown = true ;
 486     if(mouseChord & 4U)
 487                 wxevent.m_middleDown = true ;
 488
 489     // translate into wx types
 490     switch (eventType)
 491     {
 492         case NSLeftMouseDown :
 493         case NSRightMouseDown :
 494         case NSOtherMouseDown :
 495             clickCount = [nsEvent clickCount];
 496             switch ( button )
 497             {
 498                 case 0 :
 499                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 500                     break ;
 501
 502                 case 1 :
 503                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 504                     break ;
 505
 506                 case 2 :
 507                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 508                     break ;
 509
 510                 default:
 511                     break ;
 512             }
 513             break ;
 514
 515         case NSLeftMouseUp :
 516         case NSRightMouseUp :
 517         case NSOtherMouseUp :
 518             clickCount = [nsEvent clickCount];
 519             switch ( button )
 520             {
 521                 case 0 :
 522                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 523                     break ;
 524
 525                 case 1 :
 526                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 527                     break ;
 528
 529                 case 2 :
 530                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 531                     break ;
 532
 533                 default:
 534                     break ;
 535             }
 536             break ;
 537
 538      case NSScrollWheel :
 539         {
 540             float deltaX = 0.0;
 541             float deltaY = 0.0;
 542
 543             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 544
 545             // see http://developer.apple.com/qa/qa2005/qa1453.html
 546             // for more details on why we have to look for the exact type
 547
 548             const EventRef cEvent = (EventRef) [nsEvent eventRef];
 549             bool isMouseScrollEvent = false;
 550             if ( cEvent )
 551                 isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 552
 553             if ( isMouseScrollEvent )
 554             {
 555                 deltaX = [nsEvent deviceDeltaX];
 556                 deltaY = [nsEvent deviceDeltaY];
 557             }
 558             else
 559             {
 560                 deltaX = ([nsEvent deltaX] * 10);
 561                 deltaY = ([nsEvent deltaY] * 10);
 562             }
 563
 564             wxevent.m_wheelDelta = 10;
 565             wxevent.m_linesPerAction = 1;
 566
 567             if ( fabs(deltaX) > fabs(deltaY) )
 568             {
 569                 wxevent.m_wheelAxis = 1;
 570                 wxevent.m_wheelRotation = (int)deltaX;
 571             }
 572             else
 573             {
 574                 wxevent.m_wheelRotation = (int)deltaY;
 575             }
 576
 577         }
 578         break ;
 579
 580         case NSMouseEntered :
 581             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 582             break;
 583         case NSMouseExited :
 584             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 585             break;
 586         case NSLeftMouseDragged :
 587         case NSRightMouseDragged :
 588         case NSOtherMouseDragged :
 589         case NSMouseMoved :
 590             wxevent.SetEventType( wxEVT_MOTION ) ;
 591             break;
 592         default :
 593             break ;
 594     }
 595
 596     wxevent.m_clickCount = clickCount;
 597     wxWindowMac* peer = GetWXPeer();
 598     if ( peer )
 599     {
 600         wxevent.SetEventObject(peer);
 601         wxevent.SetId(peer->GetId()) ;
 602     }
 603 }
 604
 605 @implementation wxNSView
 606
 607 + (void)initialize
 608 {
 609     static BOOL initialized = NO;
 610     if (!initialized)
 611     {
 612         initialized = YES;
 613         wxOSXCocoaClassAddWXMethods( self );
 614     }
 615 }
 616
 617 - (void) setTrackingTag: (NSTrackingRectTag)tag
 618 {
 619     rectTag = tag;
 620 }
 621
 622 - (NSTrackingRectTag) trackingTag
 623 {
 624     return rectTag;
 625 }
 626
 627 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 628 - (void) updateTrackingArea
 629 {
 630     if (_trackingArea)
 631     {
 632         [self removeTrackingArea: _trackingArea];
 633         [_trackingArea release];
 634     }
 635
 636     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingMouseMoved|NSTrackingActiveAlways;
 637
 638     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: [self bounds] options: options owner: self userInfo: nil];
 639     [self addTrackingArea: area];
 640
 641     _trackingArea = area;
 642 }
 643
 644 - (NSTrackingArea*) trackingArea
 645 {
 646     return _trackingArea;
 647 }
 648 #endif
 649 @end // wxNSView
 650
 651 //
 652 // event handlers
 653 //
 654
 655 #if wxUSE_DRAG_AND_DROP
 656
 657 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 658 // for details on the NSPasteboard -> PasteboardRef conversion
 659
 660 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 661 {
 662     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 663     if (impl == NULL)
 664         return NSDragOperationNone;
 665
 666     return impl->draggingEntered(sender, self, _cmd);
 667 }
 668
 669 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 670 {
 671     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 672     if (impl == NULL)
 673         return ;
 674
 675     return impl->draggingExited(sender, self, _cmd);
 676 }
 677
 678 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 679 {
 680     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 681     if (impl == NULL)
 682         return NSDragOperationNone;
 683
 684     return impl->draggingUpdated(sender, self, _cmd);
 685 }
 686
 687 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 688 {
 689     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 690     if (impl == NULL)
 691         return NSDragOperationNone;
 692
 693     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 694 }
 695
 696 #endif
 697
 698 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 699 {
 700     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 701     if (impl == NULL)
 702         return;
 703
 704     impl->mouseEvent(event, self, _cmd);
 705 }
 706
 707 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 708 {
 709     // This is needed to support click through, otherwise the first click on a window
 710     // will not do anything unless it is the active window already.
 711     return YES;
 712 }
 713
 714 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 715 {
 716     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 717     if (impl == NULL)
 718         return;
 719
 720     impl->keyEvent(event, self, _cmd);
 721 }
 722
 723 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 724 {
 725     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 726     if (impl == NULL)
 727         return;
 728
 729     impl->insertText(text, self, _cmd);
 730 }
 731
 732 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 733 {
 734     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 735     if (impl == NULL)
 736         return NO;
 737
 738     return impl->performKeyEquivalent(event, self, _cmd);
 739 }
 740
 741 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 742 {
 743     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 744     if (impl == NULL)
 745         return NO;
 746
 747     return impl->acceptsFirstResponder(self, _cmd);
 748 }
 749
 750 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 751 {
 752     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 753     if (impl == NULL)
 754         return NO;
 755
 756     return impl->becomeFirstResponder(self, _cmd);
 757 }
 758
 759 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 760 {
 761     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 762     if (impl == NULL)
 763         return NO;
 764
 765     return impl->resignFirstResponder(self, _cmd);
 766 }
 767
 768 void wxOSX_resetCursorRects(NSView* self, SEL _cmd)
 769 {
 770     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 771     if (impl == NULL)
 772         return;
 773
 774     impl->resetCursorRects(self, _cmd);
 775 }
 776
 777 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 778 {
 779     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 780     if (impl == NULL)
 781         return NO;
 782
 783     return impl->isFlipped(self, _cmd) ? YES:NO;
 784 }
 785
 786 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 787 {
 788     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 789     if (impl == NULL)
 790         return;
 791
 792     return impl->drawRect(&rect, self, _cmd);
 793 }
 794
 795 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 796 {
 797     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 798     if (impl == NULL)
 799         return;
 800
 801     impl->controlAction(self, _cmd, sender);
 802 }
 803
 804 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 805 {
 806     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 807     if (impl == NULL)
 808         return;
 809
 810     impl->controlDoubleAction(self, _cmd, sender);
 811 }
 812
 813 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 814 {
 815     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 816     NSPasteboard *pboard = [sender draggingPasteboard];
 817     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 818
 819     wxWindow* wxpeer = GetWXPeer();
 820     if ( wxpeer == NULL )
 821         return NSDragOperationNone;
 822
 823     wxDropTarget* target = wxpeer->GetDropTarget();
 824     if ( target == NULL )
 825         return NSDragOperationNone;
 826
 827     wxDragResult result = wxDragNone;
 828     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 829     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 830
 831     if ( sourceDragMask & NSDragOperationLink )
 832         result = wxDragLink;
 833     else if ( sourceDragMask & NSDragOperationCopy )
 834         result = wxDragCopy;
 835     else if ( sourceDragMask & NSDragOperationMove )
 836         result = wxDragMove;
 837
 838     PasteboardRef pboardRef;
 839     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 840     target->SetCurrentDragPasteboard(pboardRef);
 841     result = target->OnEnter(pt.x, pt.y, result);
 842     CFRelease(pboardRef);
 843
 844     NSDragOperation nsresult = NSDragOperationNone;
 845     switch (result )
 846     {
 847         case wxDragLink:
 848             nsresult = NSDragOperationLink;
 849         case wxDragMove:
 850             nsresult = NSDragOperationMove;
 851         case wxDragCopy:
 852             nsresult = NSDragOperationCopy;
 853         default :
 854             break;
 855     }
 856     return nsresult;
 857 }
 858
 859 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 860 {
 861     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 862     NSPasteboard *pboard = [sender draggingPasteboard];
 863
 864     wxWindow* wxpeer = GetWXPeer();
 865     if ( wxpeer == NULL )
 866         return;
 867
 868     wxDropTarget* target = wxpeer->GetDropTarget();
 869     if ( target == NULL )
 870         return;
 871
 872     PasteboardRef pboardRef;
 873     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 874     target->SetCurrentDragPasteboard(pboardRef);
 875     target->OnLeave();
 876     CFRelease(pboardRef);
 877  }
 878
 879 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 880 {
 881     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 882     NSPasteboard *pboard = [sender draggingPasteboard];
 883     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 884
 885     wxWindow* wxpeer = GetWXPeer();
 886     if ( wxpeer == NULL )
 887         return NSDragOperationNone;
 888
 889     wxDropTarget* target = wxpeer->GetDropTarget();
 890     if ( target == NULL )
 891         return NSDragOperationNone;
 892
 893     wxDragResult result = wxDragNone;
 894     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 895     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 896
 897     if ( sourceDragMask & NSDragOperationLink )
 898         result = wxDragLink;
 899     else if ( sourceDragMask & NSDragOperationCopy )
 900         result = wxDragCopy;
 901     else if ( sourceDragMask & NSDragOperationMove )
 902         result = wxDragMove;
 903
 904     PasteboardRef pboardRef;
 905     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 906     target->SetCurrentDragPasteboard(pboardRef);
 907     result = target->OnDragOver(pt.x, pt.y, result);
 908     CFRelease(pboardRef);
 909
 910     NSDragOperation nsresult = NSDragOperationNone;
 911     switch (result )
 912     {
 913         case wxDragLink:
 914             nsresult = NSDragOperationLink;
 915         case wxDragMove:
 916             nsresult = NSDragOperationMove;
 917         case wxDragCopy:
 918             nsresult = NSDragOperationCopy;
 919         default :
 920             break;
 921     }
 922     return nsresult;
 923 }
 924
 925 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 926 {
 927     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 928
 929     NSPasteboard *pboard = [sender draggingPasteboard];
 930     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 931
 932     wxWindow* wxpeer = GetWXPeer();
 933     wxDropTarget* target = wxpeer->GetDropTarget();
 934     wxDragResult result = wxDragNone;
 935     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 936     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 937
 938     if ( sourceDragMask & NSDragOperationLink )
 939         result = wxDragLink;
 940     else if ( sourceDragMask & NSDragOperationCopy )
 941         result = wxDragCopy;
 942     else if ( sourceDragMask & NSDragOperationMove )
 943         result = wxDragMove;
 944
 945     PasteboardRef pboardRef;
 946     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 947     target->SetCurrentDragPasteboard(pboardRef);
 948
 949     if (target->OnDrop(pt.x, pt.y))
 950         result = target->OnData(pt.x, pt.y, result);
 951
 952     CFRelease(pboardRef);
 953
 954     return result != wxDragNone;
 955 }
 956
 957 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
 958 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 959 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 960 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
 961 typedef BOOL (*wxOSX_ResetCursorRectsHandlerPtr)(NSView* self, SEL _cmd);
 962 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 963
 964 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 965 {
 966     if ( !DoHandleMouseEvent(event) )
 967     {
 968         // for plain NSView mouse events would propagate to parents otherwise
 969         if (!m_wxPeer->MacIsUserPane())
 970         {
 971             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 972             superimpl(slf, (SEL)_cmd, event);
 973         }
 974     }
 975 }
 976
 977 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 978 {
 979     if ( [event type] == NSKeyDown )
 980         m_lastKeyDownEvent = event;
 981     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
 982     {
 983         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 984         superimpl(slf, (SEL)_cmd, event);
 985     }
 986     m_lastKeyDownEvent = NULL;
 987 }
 988
 989 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
 990 {
 991     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
 992     {
 993         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 994         superimpl(slf, (SEL)_cmd, text);
 995     }
 996 }
 997
 998
 999 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1000 {
1001     wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1002     return superimpl(slf, (SEL)_cmd, event);
1003 }
1004
1005 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1006 {
1007     if ( m_wxPeer->MacIsUserPane() )
1008         return m_wxPeer->AcceptsFocus();
1009     else
1010     {
1011         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1012         return superimpl(slf, (SEL)_cmd);
1013     }
1014 }
1015
1016 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1017 {
1018     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1019     // get the current focus before running becomeFirstResponder
1020     NSView* otherView = FindFocus();
1021
1022     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1023     BOOL r = superimpl(slf, (SEL)_cmd);
1024     if ( r )
1025     {
1026         DoNotifyFocusEvent( true, otherWindow );
1027     }
1028
1029     return r;
1030 }
1031
1032 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1033 {
1034     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1035     BOOL r = superimpl(slf, (SEL)_cmd);
1036     // get the current focus after running resignFirstResponder
1037     // note that this value isn't reliable, it might return the same view that
1038     // is resigning
1039     NSView* otherView = FindFocus();
1040     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1041     // NSTextViews have an editor as true responder, therefore the might get the
1042     // resign notification if their editor takes over, don't trigger any event then
1043     if ( r && !m_hasEditor)
1044     {
1045         DoNotifyFocusEvent( false, otherWindow );
1046     }
1047     return r;
1048 }
1049
1050 void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
1051 {
1052     wxWindow* wxpeer = GetWXPeer();
1053     if ( wxpeer )
1054     {
1055         NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
1056         if (cursor == NULL)
1057         {
1058             wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1059             superimpl(slf, (SEL)_cmd);
1060         }
1061         else
1062         {
1063             [slf addCursorRect: [slf bounds]
1064                 cursor: cursor];
1065         }
1066     }
1067 }
1068
1069 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1070 {
1071     return m_isFlipped;
1072 }
1073
1074
1075 #define OSX_DEBUG_DRAWING 0
1076
1077 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1078 {
1079     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1080     CGContextSaveGState( context );
1081
1082 #if OSX_DEBUG_DRAWING
1083     CGContextBeginPath( context );
1084     CGContextMoveToPoint(context, 0, 0);
1085     NSRect bounds = [self bounds];
1086     CGContextAddLineToPoint(context, 10, 0);
1087     CGContextMoveToPoint(context, 0, 0);
1088     CGContextAddLineToPoint(context, 0, 10);
1089     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1090     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1091     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1092     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1093     CGContextClosePath( context );
1094     CGContextStrokePath(context);
1095 #endif
1096
1097     if ( !m_isFlipped )
1098     {
1099         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1100         CGContextScaleCTM( context, 1, -1 );
1101     }
1102
1103     wxRegion updateRgn;
1104     const NSRect *rects;
1105     NSInteger count;
1106
1107     [slf getRectsBeingDrawn:&rects count:&count];
1108     for ( int i = 0 ; i < count ; ++i )
1109     {
1110         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1111     }
1112
1113     wxWindow* wxpeer = GetWXPeer();
1114     if ( wxpeer->MacGetTopLevelWindow()->GetWindowStyle() & wxFRAME_SHAPED )
1115     {
1116         int xoffset = 0, yoffset = 0;
1117         wxRegion rgn = wxpeer->MacGetTopLevelWindow()->GetShape();
1118         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1119         rgn.Offset( xoffset, yoffset );
1120         updateRgn.Intersect(rgn);
1121     }
1122
1123     wxpeer->GetUpdateRegion() = updateRgn;
1124     wxpeer->MacSetCGContextRef( context );
1125
1126     bool handled = wxpeer->MacDoRedraw( 0 );
1127     CGContextRestoreGState( context );
1128
1129     CGContextSaveGState( context );
1130     if ( !handled )
1131     {
1132         // call super
1133         SEL _cmd = @selector(drawRect:);
1134         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1135         superimpl(slf, _cmd, *(NSRect*)rect);
1136         CGContextRestoreGState( context );
1137         CGContextSaveGState( context );
1138     }
1139     wxpeer->MacPaintChildrenBorders();
1140     wxpeer->MacSetCGContextRef( NULL );
1141     CGContextRestoreGState( context );
1142 }
1143
1144 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1145 {
1146     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1147     if ( wxpeer )
1148         wxpeer->OSXHandleClicked(0);
1149 }
1150
1151 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1152 {
1153 }
1154
1155 void wxWidgetCocoaImpl::controlTextDidChange()
1156 {
1157     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1158     if ( wxpeer )
1159     {
1160         wxCommandEvent event(wxEVT_COMMAND_TEXT_UPDATED, wxpeer->GetId());
1161         event.SetEventObject( wxpeer );
1162         event.SetString( static_cast<wxTextCtrl*>(wxpeer)->GetValue() );
1163         wxpeer->HandleWindowEvent( event );
1164     }
1165 }
1166
1167 //
1168
1169 #if OBJC_API_VERSION >= 2
1170
1171 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1172     class_addMethod(c, s, i, t );
1173
1174 #else
1175
1176 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1177     { s, t, i },
1178
1179 #endif
1180
1181 void wxOSXCocoaClassAddWXMethods(Class c)
1182 {
1183
1184 #if OBJC_API_VERSION < 2
1185     static objc_method wxmethods[] =
1186     {
1187 #endif
1188
1189     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1190     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1191     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1192
1193     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1194     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1195     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1196
1197     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1198
1199     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1200     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1201     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1202
1203     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1204
1205     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1206     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1207     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1208
1209     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1210     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1211     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1212
1213     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1214
1215     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1216
1217     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1218     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1219     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1220     wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
1221
1222     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1223     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1224
1225     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1226     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1227
1228 #if wxUSE_DRAG_AND_DROP
1229     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1230     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1231     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1232     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1233 #endif
1234
1235 #if OBJC_API_VERSION < 2
1236     } ;
1237     static int method_count = WXSIZEOF( wxmethods );
1238     static objc_method_list *wxmethodlist = NULL;
1239     if ( wxmethodlist == NULL )
1240     {
1241         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1242         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1243         wxmethodlist->method_count = method_count;
1244         wxmethodlist->obsolete = 0;
1245     }
1246     class_addMethods( c, wxmethodlist );
1247 #endif
1248 }
1249
1250 //
1251 // C++ implementation class
1252 //
1253
1254 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1255
1256 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl ) :
1257     wxWidgetImpl( peer, isRootControl )
1258 {
1259     Init();
1260     m_osxView = w;
1261
1262     // check if the user wants to create the control initially hidden
1263     if ( !peer->IsShown() )
1264         SetVisibility(false);
1265
1266     // gc aware handling
1267     if ( m_osxView )
1268         CFRetain(m_osxView);
1269     [m_osxView release];
1270 }
1271
1272 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1273 {
1274     Init();
1275 }
1276
1277 void wxWidgetCocoaImpl::Init()
1278 {
1279     m_osxView = NULL;
1280     m_isFlipped = true;
1281     m_lastKeyDownEvent = NULL;
1282     m_hasEditor = false;
1283 }
1284
1285 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1286 {
1287     RemoveAssociations( this );
1288
1289     if ( !IsRootControl() )
1290     {
1291         NSView *sv = [m_osxView superview];
1292         if ( sv != nil )
1293             [m_osxView removeFromSuperview];
1294     }
1295     // gc aware handling
1296     if ( m_osxView )
1297         CFRelease(m_osxView);
1298 }
1299
1300 bool wxWidgetCocoaImpl::IsVisible() const
1301 {
1302     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1303 }
1304
1305 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1306 {
1307     [m_osxView setHidden:(visible ? NO:YES)];
1308 }
1309
1310 // ----------------------------------------------------------------------------
1311 // window animation stuff
1312 // ----------------------------------------------------------------------------
1313
1314 // define a delegate used to refresh the window during animation
1315 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1316 {
1317     wxWindow *m_win;
1318     bool m_isDone;
1319 }
1320
1321 - (id)init:(wxWindow *)win;
1322
1323 - (bool)isDone;
1324
1325 // NSAnimationDelegate methods
1326 - (void)animationDidEnd:(NSAnimation*)animation;
1327 - (void)animation:(NSAnimation*)animation
1328         didReachProgressMark:(NSAnimationProgress)progress;
1329 @end
1330
1331 @implementation wxNSAnimationDelegate
1332
1333 - (id)init:(wxWindow *)win
1334 {
1335     [super init];
1336
1337     m_win = win;
1338     m_isDone = false;
1339
1340     return self;
1341 }
1342
1343 - (bool)isDone
1344 {
1345     return m_isDone;
1346 }
1347
1348 - (void)animation:(NSAnimation*)animation
1349         didReachProgressMark:(NSAnimationProgress)progress
1350 {
1351     wxUnusedVar(animation);
1352     wxUnusedVar(progress);
1353
1354     m_win->SendSizeEvent();
1355 }
1356
1357 - (void)animationDidEnd:(NSAnimation*)animation
1358 {
1359     wxUnusedVar(animation);
1360     m_isDone = true;
1361 }
1362
1363 @end
1364
1365 /* static */
1366 bool
1367 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1368                                               bool show,
1369                                               wxShowEffect effect,
1370                                               unsigned timeout)
1371 {
1372     // create the dictionary describing the animation to perform on this view
1373     NSObject * const
1374         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1375     NSMutableDictionary * const
1376         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1377     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1378
1379     // determine the start and end rectangles assuming we're hiding the window
1380     const wxRect rectOrig = win->GetRect();
1381     wxRect rectStart,
1382            rectEnd;
1383     rectStart =
1384     rectEnd = rectOrig;
1385
1386     if ( show )
1387     {
1388         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1389                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1390             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1391         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1392                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1393             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1394         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1395                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1396             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1397         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1398                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1399             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1400     }
1401
1402     switch ( effect )
1403     {
1404         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1405         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1406             rectEnd.width = 0;
1407             break;
1408
1409         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1410         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1411             rectEnd.x = rectStart.GetRight();
1412             rectEnd.width = 0;
1413             break;
1414
1415         case wxSHOW_EFFECT_ROLL_TO_TOP:
1416         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1417             rectEnd.height = 0;
1418             break;
1419
1420         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1421         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1422             rectEnd.y = rectStart.GetBottom();
1423             rectEnd.height = 0;
1424             break;
1425
1426         case wxSHOW_EFFECT_EXPAND:
1427             rectEnd.x = rectStart.x + rectStart.width / 2;
1428             rectEnd.y = rectStart.y + rectStart.height / 2;
1429             rectEnd.width =
1430             rectEnd.height = 0;
1431             break;
1432
1433         case wxSHOW_EFFECT_BLEND:
1434             [dict setObject:(show ? NSViewAnimationFadeInEffect
1435                                   : NSViewAnimationFadeOutEffect)
1436                   forKey:NSViewAnimationEffectKey];
1437             break;
1438
1439         case wxSHOW_EFFECT_NONE:
1440         case wxSHOW_EFFECT_MAX:
1441             wxFAIL_MSG( "unexpected animation effect" );
1442             return false;
1443
1444         default:
1445             wxFAIL_MSG( "unknown animation effect" );
1446             return false;
1447     };
1448
1449     if ( show )
1450     {
1451         // we need to restore it to the original rectangle instead of making it
1452         // disappear
1453         wxSwap(rectStart, rectEnd);
1454
1455         // and as the window is currently hidden, we need to show it for the
1456         // animation to be visible at all (but don't restore it at its full
1457         // rectangle as it shouldn't appear immediately)
1458         win->SetSize(rectStart);
1459         win->Show();
1460     }
1461
1462     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1463                                     ? [(NSView *)viewOrWin superview]
1464                                     : nil;
1465     const NSRect rStart = wxToNSRect(parentView, rectStart);
1466     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1467
1468     [dict setObject:[NSValue valueWithRect:rStart]
1469           forKey:NSViewAnimationStartFrameKey];
1470     [dict setObject:[NSValue valueWithRect:rEnd]
1471           forKey:NSViewAnimationEndFrameKey];
1472
1473     // create an animation using the values in the above dictionary
1474     NSViewAnimation * const
1475         anim = [[NSViewAnimation alloc]
1476                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1477
1478     if ( !timeout )
1479     {
1480         // what is a good default duration? Windows uses 200ms, Web frameworks
1481         // use anything from 250ms to 1s... choose something in the middle
1482         timeout = 500;
1483     }
1484
1485     [anim setDuration:timeout/1000.];   // duration is in seconds here
1486
1487     // if the window being animated changes its layout depending on its size
1488     // (which is almost always the case) we need to redo it during animation
1489     //
1490     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1491     // controls in wxInfoBar visibly jump around)
1492     const int NUM_LAYOUTS = 20;
1493     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1494         [anim addProgressMark:f];
1495
1496     wxNSAnimationDelegate * const
1497         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1498     [anim setDelegate:animDelegate];
1499     [anim startAnimation];
1500
1501     // Cocoa is capable of doing animation asynchronously or even from separate
1502     // thread but wx API doesn't provide any way to be notified about the
1503     // animation end and without this we really must ensure that the window has
1504     // the expected (i.e. the same as if a simple Show() had been used) size
1505     // when we return, so block here until the animation finishes
1506     //
1507     // notice that because the default animation mode is NSAnimationBlocking,
1508     // no user input events ought to be processed from here
1509     {
1510         wxEventLoopGuarantor ensureEventLoopExistence;
1511         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1512         while ( ![animDelegate isDone] )
1513             loop->Dispatch();
1514     }
1515
1516     if ( !show )
1517     {
1518         // NSViewAnimation is smart enough to hide the NSView being animated at
1519         // the end but we also must ensure that it's hidden for wx too
1520         win->Hide();
1521
1522         // and we must also restore its size because it isn't expected to
1523         // change just because the window was hidden
1524         win->SetSize(rectOrig);
1525     }
1526     else
1527     {
1528         // refresh it once again after the end to ensure that everything is in
1529         // place
1530         win->SendSizeEvent();
1531     }
1532
1533     [anim setDelegate:nil];
1534     [animDelegate release];
1535     [anim release];
1536
1537     return true;
1538 }
1539
1540 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1541                                        wxShowEffect effect,
1542                                        unsigned timeout)
1543 {
1544     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1545 }
1546
1547 void wxWidgetCocoaImpl::Raise()
1548 {
1549     // Not implemented
1550 }
1551
1552 void wxWidgetCocoaImpl::Lower()
1553 {
1554     // Not implemented
1555 }
1556
1557 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1558 {
1559 #if 1
1560     SetNeedsDisplay() ;
1561 #else
1562     // We should do something like this, but it wasn't working in 10.4.
1563     if (GetNeedsDisplay() )
1564     {
1565         SetNeedsDisplay() ;
1566     }
1567     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1568     NSSize offset = NSMakeSize((float)dx, (float)dy);
1569     [m_osxView scrollRect:r by:offset];
1570 #endif
1571 }
1572
1573 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1574 {
1575     wxWindowMac* parent = GetWXPeer()->GetParent();
1576     // under Cocoa we might have a contentView in the wxParent to which we have to
1577     // adjust the coordinates
1578     if (parent && [m_osxView superview] != parent->GetHandle() )
1579     {
1580         int cx = 0,cy = 0,cw = 0,ch = 0;
1581         if ( parent->GetPeer() )
1582         {
1583             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1584             x -= cx;
1585             y -= cy;
1586         }
1587     }
1588     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
1589     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
1590     [m_osxView setFrame:r];
1591     [[m_osxView superview] setNeedsDisplayInRect:r];
1592
1593     wxNSView* wxview = (wxNSView*)m_osxView;
1594 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
1595     if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
1596         [wxview updateTrackingArea];
1597 #else
1598     if ([m_osxView respondsToSelector:@selector(trackingTag)] )
1599     {
1600         if ( [wxview trackingTag] )
1601             [wxview removeTrackingRect: [wxview trackingTag]];
1602
1603         [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
1604     }
1605 #endif
1606 }
1607
1608 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
1609 {
1610     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
1611     x = r.GetLeft();
1612     y = r.GetTop();
1613 }
1614
1615 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
1616 {
1617     NSRect rect = [m_osxView frame];
1618     width = (int)rect.size.width;
1619     height = (int)rect.size.height;
1620 }
1621
1622 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
1623 {
1624     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
1625     {
1626         NSView* cv = [m_osxView contentView];
1627
1628         NSRect bounds = [m_osxView bounds];
1629         NSRect rect = [cv frame];
1630
1631         int y = (int)rect.origin.y;
1632         int x = (int)rect.origin.x;
1633         if ( ![ m_osxView isFlipped ] )
1634             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
1635         left = x;
1636         top = y;
1637         width = (int)rect.size.width;
1638         height = (int)rect.size.height;
1639     }
1640     else
1641     {
1642         left = top = 0;
1643         GetSize( width, height );
1644     }
1645 }
1646
1647 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
1648 {
1649     if ( where )
1650         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
1651     else
1652         [m_osxView setNeedsDisplay:YES];
1653 }
1654
1655 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
1656 {
1657     return [m_osxView needsDisplay];
1658 }
1659
1660 bool wxWidgetCocoaImpl::CanFocus() const
1661 {
1662     return [m_osxView canBecomeKeyView] == YES;
1663 }
1664
1665 bool wxWidgetCocoaImpl::HasFocus() const
1666 {
1667     return ( FindFocus() == m_osxView );
1668 }
1669
1670 bool wxWidgetCocoaImpl::SetFocus()
1671 {
1672     if ( !CanFocus() )
1673         return false;
1674
1675     [[m_osxView window] makeKeyAndOrderFront:nil] ;
1676     [[m_osxView window] makeFirstResponder: m_osxView] ;
1677     return true;
1678 }
1679
1680
1681 void wxWidgetCocoaImpl::RemoveFromParent()
1682 {
1683     [m_osxView removeFromSuperview];
1684 }
1685
1686 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
1687 {
1688     NSView* container = parent->GetWXWidget() ;
1689     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
1690     [container addSubview:m_osxView];
1691 }
1692
1693 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
1694 {
1695     NSView* targetView = m_osxView;
1696     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1697         targetView = [(NSScrollView*) m_osxView documentView];
1698
1699     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
1700     {
1701         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1702                                                                 green:(CGFloat) (col.Green() / 255.0)
1703                                                                  blue:(CGFloat) (col.Blue() / 255.0)
1704                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
1705     }
1706 }
1707
1708 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
1709 {
1710     BOOL opaque = ( style == wxBG_STYLE_PAINT );
1711
1712     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
1713     {
1714         [m_osxView setOpaque: opaque];
1715     }
1716
1717     return true ;
1718 }
1719
1720 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
1721 {
1722     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
1723     {
1724         wxCFStringRef cf( title , encoding );
1725         [m_osxView setTitle:cf.AsNSString()];
1726     }
1727     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
1728     {
1729         wxCFStringRef cf( title , encoding );
1730         [m_osxView setStringValue:cf.AsNSString()];
1731     }
1732 }
1733
1734
1735 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
1736 {
1737     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
1738     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
1739     *pt = wxFromNSPoint( to->GetWXWidget(), p );
1740 }
1741
1742 wxInt32 wxWidgetCocoaImpl::GetValue() const
1743 {
1744     return [(NSControl*)m_osxView intValue];
1745 }
1746
1747 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
1748 {
1749     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
1750     {
1751         [m_osxView setIntValue:v];
1752     }
1753     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
1754     {
1755         [m_osxView setFloatValue:(double)v];
1756     }
1757     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
1758     {
1759         [m_osxView setDoubleValue:(double)v];
1760     }
1761 }
1762
1763 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
1764 {
1765     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
1766     {
1767         [m_osxView setMinValue:(double)v];
1768     }
1769 }
1770
1771 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
1772 {
1773     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
1774     {
1775         [m_osxView setMaxValue:(double)v];
1776     }
1777 }
1778
1779 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
1780 {
1781     if (  [m_osxView respondsToSelector:@selector(getMinValue:)] )
1782     {
1783         return (int)[m_osxView minValue];
1784     }
1785     return 0;
1786 }
1787
1788 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
1789 {
1790     if (  [m_osxView respondsToSelector:@selector(getMaxValue:)] )
1791     {
1792         return (int)[m_osxView maxValue];
1793     }
1794     return 0;
1795 }
1796
1797 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
1798 {
1799     wxBitmap bmp;
1800
1801     // TODO: how to create a wxBitmap from NSImage?
1802 #if 0
1803     if ( [m_osxView respondsToSelector:@selector(image:)] )
1804         bmp = [m_osxView image];
1805 #endif
1806
1807     return bmp;
1808 }
1809
1810 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
1811 {
1812     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
1813     {
1814         [m_osxView setImage:bitmap.GetNSImage()];
1815         [m_osxView setNeedsDisplay:YES];
1816     }
1817 }
1818
1819 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
1820 {
1821     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
1822     {
1823         NSCellImagePosition pos;
1824         switch ( dir )
1825         {
1826             case wxLEFT:
1827                 pos = NSImageLeft;
1828                 break;
1829
1830             case wxRIGHT:
1831                 pos = NSImageRight;
1832                 break;
1833
1834             case wxTOP:
1835                 pos = NSImageAbove;
1836                 break;
1837
1838             case wxBOTTOM:
1839                 pos = NSImageBelow;
1840                 break;
1841
1842             default:
1843                 wxFAIL_MSG( "invalid image position" );
1844                 pos = NSNoImage;
1845         }
1846
1847         [m_osxView setImagePosition:pos];
1848     }
1849 }
1850
1851 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
1852 {
1853     // implementation in subclass
1854 }
1855
1856 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
1857 {
1858     r->x = r->y = r->width = r->height = 0;
1859
1860     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
1861     {
1862         NSRect former = [m_osxView frame];
1863         [m_osxView sizeToFit];
1864         NSRect best = [m_osxView frame];
1865         [m_osxView setFrame:former];
1866         r->width = (int)best.size.width;
1867         r->height = (int)best.size.height;
1868     }
1869 }
1870
1871 bool wxWidgetCocoaImpl::IsEnabled() const
1872 {
1873     if ( [m_osxView respondsToSelector:@selector(isEnabled) ] )
1874         return [m_osxView isEnabled];
1875     return true;
1876 }
1877
1878 void wxWidgetCocoaImpl::Enable( bool enable )
1879 {
1880     if ( [m_osxView respondsToSelector:@selector(setEnabled:) ] )
1881         [m_osxView setEnabled:enable];
1882 }
1883
1884 void wxWidgetCocoaImpl::PulseGauge()
1885 {
1886 }
1887
1888 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
1889 {
1890 }
1891
1892 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
1893 {
1894     NSControlSize size = NSRegularControlSize;
1895
1896     switch ( variant )
1897     {
1898         case wxWINDOW_VARIANT_NORMAL :
1899             size = NSRegularControlSize;
1900             break ;
1901
1902         case wxWINDOW_VARIANT_SMALL :
1903             size = NSSmallControlSize;
1904             break ;
1905
1906         case wxWINDOW_VARIANT_MINI :
1907             size = NSMiniControlSize;
1908             break ;
1909
1910         case wxWINDOW_VARIANT_LARGE :
1911             size = NSRegularControlSize;
1912             break ;
1913
1914         default:
1915             wxFAIL_MSG(wxT("unexpected window variant"));
1916             break ;
1917     }
1918     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
1919         [m_osxView setControlSize:size];
1920     else if ([m_osxView respondsToSelector:@selector(cell)])
1921     {
1922         id cell = [(id)m_osxView cell];
1923         if ([cell respondsToSelector:@selector(setControlSize:)])
1924             [cell setControlSize:size];
1925     }
1926 }
1927
1928 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
1929 {
1930     if ([m_osxView respondsToSelector:@selector(setFont:)])
1931         [m_osxView setFont: font.OSXGetNSFont()];
1932     if ([m_osxView respondsToSelector:@selector(setTextColor:)])
1933         [m_osxView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1934                                                                  green:(CGFloat) (col.Green() / 255.0)
1935                                                                   blue:(CGFloat) (col.Blue() / 255.0)
1936                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
1937 }
1938
1939 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
1940 {
1941     if (tooltip)
1942     {
1943         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
1944         [m_osxView setToolTip: cf.AsNSString()];
1945     }
1946     else
1947         [m_osxView setToolTip: nil];
1948
1949 }
1950
1951 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
1952 {
1953     WXWidget c =  control ? control : (WXWidget) m_osxView;
1954     wxWidgetImpl::Associate( c, this ) ;
1955     if ([c respondsToSelector:@selector(setAction:)])
1956     {
1957         [c setTarget: c];
1958         [c setAction: @selector(controlAction:)];
1959         if ([c respondsToSelector:@selector(setDoubleAction:)])
1960         {
1961             [c setDoubleAction: @selector(controlDoubleAction:)];
1962         }
1963
1964     }
1965 }
1966
1967 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
1968 {
1969     wxKeyEvent wxevent(wxEVT_CHAR);
1970     SetupKeyEvent( wxevent, event, text );
1971
1972     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
1973 }
1974
1975 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
1976 {
1977     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1978     SetupKeyEvent( wxevent, event );
1979     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
1980
1981     // this will fire higher level events, like insertText, to help
1982     // us handle EVT_CHAR, etc.
1983
1984     if ( m_wxPeer->MacIsUserPane() && [event type] == NSKeyDown)
1985     {
1986         if ( !result )
1987         {
1988             if ( wxevent.GetKeyCode() < WXK_SPACE || wxevent.GetKeyCode() == WXK_DELETE || wxevent.GetKeyCode() >= WXK_START )
1989             {
1990                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
1991                 wxKeyEvent wxevent2(wxevent) ;
1992                 wxevent2.SetEventType(wxEVT_CHAR);
1993                 GetWXPeer()->OSXHandleKeyEvent(wxevent2);
1994             }
1995             else
1996             {
1997                 if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1998                     [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
1999                 else
2000                     [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2001             }
2002             result = true;
2003         }
2004     }
2005
2006     return result;
2007 }
2008
2009 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2010 {
2011     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2012     SetupMouseEvent(wxevent , event) ;
2013
2014     return GetWXPeer()->HandleWindowEvent(wxevent);
2015 }
2016
2017 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2018 {
2019     wxWindow* thisWindow = GetWXPeer();
2020     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2021     {
2022         thisWindow->MacInvalidateBorders();
2023     }
2024
2025     if ( receivedFocus )
2026     {
2027         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2028         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2029         thisWindow->HandleWindowEvent(eventFocus);
2030
2031 #if wxUSE_CARET
2032         if ( thisWindow->GetCaret() )
2033             thisWindow->GetCaret()->OnSetFocus();
2034 #endif
2035
2036         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2037         event.SetEventObject(thisWindow);
2038         if (otherWindow)
2039             event.SetWindow(otherWindow->GetWXPeer());
2040         thisWindow->HandleWindowEvent(event) ;
2041     }
2042     else // !receivedFocuss
2043     {
2044 #if wxUSE_CARET
2045         if ( thisWindow->GetCaret() )
2046             thisWindow->GetCaret()->OnKillFocus();
2047 #endif
2048
2049         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2050
2051         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2052         event.SetEventObject(thisWindow);
2053         if (otherWindow)
2054             event.SetWindow(otherWindow->GetWXPeer());
2055         thisWindow->HandleWindowEvent(event) ;
2056     }
2057 }
2058
2059 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2060 {
2061     NSPoint location = [NSEvent mouseLocation];
2062     location = [[m_osxView window] convertScreenToBase:location];
2063     NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2064
2065     if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2066     {
2067         [(NSCursor*)cursor.GetHCURSOR() set];
2068     }
2069     [[m_osxView window] invalidateCursorRectsForView:m_osxView];
2070 }
2071
2072 void wxWidgetCocoaImpl::CaptureMouse()
2073 {
2074     [[m_osxView window] disableCursorRects];
2075 }
2076
2077 void wxWidgetCocoaImpl::ReleaseMouse()
2078 {
2079     [[m_osxView window] enableCursorRects];
2080 }
2081
2082 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2083 {
2084     m_isFlipped = flipped;
2085 }
2086
2087 //
2088 // Factory methods
2089 //
2090
2091 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2092     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2093     long WXUNUSED(style), long WXUNUSED(extraStyle))
2094 {
2095     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2096     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2097
2098     // temporary hook for dnd
2099     [v registerForDraggedTypes:[NSArray arrayWithObjects:
2100         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
2101
2102     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v );
2103     return c;
2104 }
2105
2106 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2107 {
2108     NSWindow* tlw = now->GetWXWindow();
2109
2110     wxWidgetCocoaImpl* c = NULL;
2111     if ( now->IsNativeWindowWrapper() )
2112     {
2113         NSView* cv = [tlw contentView];
2114         c = new wxWidgetCocoaImpl( now, cv, true );
2115         // increase ref count, because the impl destructor will decrement it again
2116         CFRetain(cv);
2117         if ( !now->IsShown() )
2118             [cv setHidden:NO];
2119
2120     }
2121     else
2122     {
2123         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2124         c = new wxWidgetCocoaImpl( now, v, true );
2125         c->InstallEventHandler();
2126         [tlw setContentView:v];
2127     }
2128     return c;
2129 }