src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     BOOL _hasToolTip;
  91     NSTrackingRectTag   _lastToolTipTrackTag;
  92     id              _lastToolTipOwner;
  93     void*           _lastUserData;
  94
  95 }
  96
  97 @end // wxNSView
  98
  99 @interface NSView(PossibleMethods)
 100 - (void)setTitle:(NSString *)aString;
 101 - (void)setStringValue:(NSString *)aString;
 102 - (void)setIntValue:(int)anInt;
 103 - (void)setFloatValue:(float)aFloat;
 104 - (void)setDoubleValue:(double)aDouble;
 105
 106 - (double)minValue;
 107 - (double)maxValue;
 108 - (void)setMinValue:(double)aDouble;
 109 - (void)setMaxValue:(double)aDouble;
 110
 111 - (void)sizeToFit;
 112
 113 - (BOOL)isEnabled;
 114 - (void)setEnabled:(BOOL)flag;
 115
 116 - (void)setImage:(NSImage *)image;
 117 - (void)setControlSize:(NSControlSize)size;
 118
 119 - (void)setFont:(NSFont *)fontObject;
 120
 121 - (id)contentView;
 122
 123 - (void)setTarget:(id)anObject;
 124 - (void)setAction:(SEL)aSelector;
 125 - (void)setDoubleAction:(SEL)aSelector;
 126 - (void)setBackgroundColor:(NSColor*)aColor;
 127 - (void)setOpaque:(BOOL)opaque;
 128 - (void)setTextColor:(NSColor *)color;
 129 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 130 @end
 131
 132 // The following code is a combination of the code listed here:
 133 // http://lists.apple.com/archives/cocoa-dev/2008/Apr/msg01582.html
 134 // (which can't be used because KLGetCurrentKeyboardLayout etc aren't 64-bit)
 135 // and the code here:
 136 // http://inquisitivecocoa.com/category/objective-c/
 137 @interface NSEvent (OsGuiUtilsAdditions)
 138 - (NSString*) charactersIgnoringModifiersIncludingShift;
 139 @end
 140
 141 @implementation NSEvent (OsGuiUtilsAdditions)
 142 - (NSString*) charactersIgnoringModifiersIncludingShift {
 143     // First try -charactersIgnoringModifiers and look for keys which UCKeyTranslate translates
 144     // differently than AppKit.
 145     NSString* c = [self charactersIgnoringModifiers];
 146     if ([c length] == 1) {
 147         unichar codepoint = [c characterAtIndex:0];
 148         if ((codepoint >= 0xF700 && codepoint <= 0xF8FF) || codepoint == 0x7F) {
 149             return c;
 150         }
 151     }
 152     // This is not a "special" key, so ask UCKeyTranslate to give us the character with no
 153     // modifiers attached.  Actually, that's not quite accurate; we attach the Command modifier
 154     // which hints the OS to use Latin characters where possible, which is generally what we want.
 155     NSString* result = @"";
 156     TISInputSourceRef currentKeyboard = TISCopyCurrentKeyboardInputSource();
 157     CFDataRef uchr = (CFDataRef)TISGetInputSourceProperty(currentKeyboard, kTISPropertyUnicodeKeyLayoutData);
 158     CFRelease(currentKeyboard);
 159     if (uchr == NULL) {
 160         // this can happen for some non-U.S. input methods (eg. Romaji or Hiragana)
 161         return c;
 162     }
 163     const UCKeyboardLayout *keyboardLayout = (const UCKeyboardLayout*)CFDataGetBytePtr(uchr);
 164     if (keyboardLayout) {
 165         UInt32 deadKeyState = 0;
 166         UniCharCount maxStringLength = 255;
 167         UniCharCount actualStringLength = 0;
 168         UniChar unicodeString[maxStringLength];
 169
 170         OSStatus status = UCKeyTranslate(keyboardLayout,
 171                                          [self keyCode],
 172                                          kUCKeyActionDown,
 173                                          cmdKey >> 8,         // force the Command key to "on"
 174                                          LMGetKbdType(),
 175                                          kUCKeyTranslateNoDeadKeysMask,
 176                                          &deadKeyState,
 177                                          maxStringLength,
 178                                          &actualStringLength,
 179                                          unicodeString);
 180
 181         if(status == noErr)
 182             result = [NSString stringWithCharacters:unicodeString length:(NSInteger)actualStringLength];
 183     }
 184     return result;
 185 }
 186 @end
 187
 188 long wxOSXTranslateCocoaKey( NSEvent* event, int eventType )
 189 {
 190     long retval = 0;
 191
 192     if ([event type] != NSFlagsChanged)
 193     {
 194         NSString* s = [event charactersIgnoringModifiersIncludingShift];
 195         // backspace char reports as delete w/modifiers for some reason
 196         if ([s length] == 1)
 197         {
 198             if ( eventType == wxEVT_CHAR && ([event modifierFlags] & NSControlKeyMask) && ( [s characterAtIndex:0] >= 'a' && [s characterAtIndex:0] <= 'z' ) )
 199             {
 200                 retval = WXK_CONTROL_A + ([s characterAtIndex:0] - 'a');
 201             }
 202             else
 203             {
 204                 switch ( [s characterAtIndex:0] )
 205                 {
 206                     // backspace key
 207                     case 0x7F :
 208                     case 8 :
 209                         retval = WXK_BACK;
 210                         break;
 211                     case NSUpArrowFunctionKey :
 212                         retval = WXK_UP;
 213                         break;
 214                     case NSDownArrowFunctionKey :
 215                         retval = WXK_DOWN;
 216                         break;
 217                     case NSLeftArrowFunctionKey :
 218                         retval = WXK_LEFT;
 219                         break;
 220                     case NSRightArrowFunctionKey :
 221                         retval = WXK_RIGHT;
 222                         break;
 223                     case NSInsertFunctionKey  :
 224                         retval = WXK_INSERT;
 225                         break;
 226                     case NSDeleteFunctionKey  :
 227                         retval = WXK_DELETE;
 228                         break;
 229                     case NSHomeFunctionKey  :
 230                         retval = WXK_HOME;
 231                         break;
 232             //        case NSBeginFunctionKey  :
 233             //            retval = WXK_BEGIN;
 234             //            break;
 235                     case NSEndFunctionKey  :
 236                         retval = WXK_END;
 237                         break;
 238                     case NSPageUpFunctionKey  :
 239                         retval = WXK_PAGEUP;
 240                         break;
 241                    case NSPageDownFunctionKey  :
 242                         retval = WXK_PAGEDOWN;
 243                         break;
 244                    case NSHelpFunctionKey  :
 245                         retval = WXK_HELP;
 246                         break;
 247                     default:
 248                         int intchar = [s characterAtIndex: 0];
 249                         if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 250                             retval = WXK_F1 + (intchar - NSF1FunctionKey );
 251                         else if ( intchar > 0 && intchar < 32 )
 252                             retval = intchar;
 253                         break;
 254                 }
 255             }
 256         }
 257     }
 258
 259     // Some keys don't seem to have constants. The code mimics the approach
 260     // taken by WebKit. See:
 261     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 262     switch( [event keyCode] )
 263     {
 264         // command key
 265         case 54:
 266         case 55:
 267             retval = WXK_CONTROL;
 268             break;
 269         // caps locks key
 270         case 57: // Capslock
 271             retval = WXK_CAPITAL;
 272             break;
 273         // shift key
 274         case 56: // Left Shift
 275         case 60: // Right Shift
 276             retval = WXK_SHIFT;
 277             break;
 278         // alt key
 279         case 58: // Left Alt
 280         case 61: // Right Alt
 281             retval = WXK_ALT;
 282             break;
 283         // ctrl key
 284         case 59: // Left Ctrl
 285         case 62: // Right Ctrl
 286             retval = WXK_RAW_CONTROL;
 287             break;
 288         // clear key
 289         case 71:
 290             retval = WXK_CLEAR;
 291             break;
 292         // tab key
 293         case 48:
 294             retval = WXK_TAB;
 295             break;
 296         default:
 297             break;
 298     }
 299
 300     // Check for NUMPAD keys.  For KEY_UP/DOWN events we need to use the
 301     // WXK_NUMPAD constants, but for the CHAR event we want to use the
 302     // standard ascii values
 303     if ( eventType != wxEVT_CHAR )
 304     {
 305         switch( [event keyCode] )
 306         {
 307             case 75: // /
 308                 retval = WXK_NUMPAD_DIVIDE;
 309                 break;
 310             case 67: // *
 311                 retval = WXK_NUMPAD_MULTIPLY;
 312                 break;
 313             case 78: // -
 314                 retval = WXK_NUMPAD_SUBTRACT;
 315                 break;
 316             case 69: // +
 317                 retval = WXK_NUMPAD_ADD;
 318                 break;
 319             case 76: // Enter
 320                 retval = WXK_NUMPAD_ENTER;
 321                 break;
 322             case 65: // .
 323                 retval = WXK_NUMPAD_DECIMAL;
 324                 break;
 325             case 82: // 0
 326                 retval = WXK_NUMPAD0;
 327                 break;
 328             case 83: // 1
 329                 retval = WXK_NUMPAD1;
 330                 break;
 331             case 84: // 2
 332                 retval = WXK_NUMPAD2;
 333                 break;
 334             case 85: // 3
 335                 retval = WXK_NUMPAD3;
 336                 break;
 337             case 86: // 4
 338                 retval = WXK_NUMPAD4;
 339                 break;
 340             case 87: // 5
 341                 retval = WXK_NUMPAD5;
 342                 break;
 343             case 88: // 6
 344                 retval = WXK_NUMPAD6;
 345                 break;
 346             case 89: // 7
 347                 retval = WXK_NUMPAD7;
 348                 break;
 349             case 91: // 8
 350                 retval = WXK_NUMPAD8;
 351                 break;
 352             case 92: // 9
 353                 retval = WXK_NUMPAD9;
 354                 break;
 355             default:
 356                 //retval = [event keyCode];
 357                 break;
 358         }
 359     }
 360     return retval;
 361 }
 362
 363 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 364 {
 365     UInt32 modifiers = [nsEvent modifierFlags] ;
 366     int eventType = [nsEvent type];
 367
 368     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 369     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 370     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 371     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 372
 373     wxevent.m_rawCode = [nsEvent keyCode];
 374     wxevent.m_rawFlags = modifiers;
 375
 376     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 377
 378     wxString chars;
 379     if ( eventType != NSFlagsChanged )
 380     {
 381         NSString* nschars = [[nsEvent charactersIgnoringModifiersIncludingShift] uppercaseString];
 382         if ( charString )
 383         {
 384             // if charString is set, it did not come from key up / key down
 385             wxevent.SetEventType( wxEVT_CHAR );
 386             chars = wxCFStringRef::AsString(charString);
 387         }
 388         else if ( nschars )
 389         {
 390             chars = wxCFStringRef::AsString(nschars);
 391         }
 392     }
 393
 394     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 395     long keyval = 0;
 396
 397     if (wxevent.GetEventType() != wxEVT_CHAR)
 398     {
 399         keyval = wxOSXTranslateCocoaKey(nsEvent, wxevent.GetEventType()) ;
 400         switch (eventType)
 401         {
 402             case NSKeyDown :
 403                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 404                 break;
 405             case NSKeyUp :
 406                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 407                 break;
 408             case NSFlagsChanged :
 409                 switch (keyval)
 410                 {
 411                     case WXK_CONTROL:
 412                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 413                         break;
 414                     case WXK_SHIFT:
 415                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 416                         break;
 417                     case WXK_ALT:
 418                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 419                         break;
 420                     case WXK_RAW_CONTROL:
 421                         wxevent.SetEventType( wxevent.m_rawControlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 422                         break;
 423                 }
 424                 break;
 425             default :
 426                 break ;
 427         }
 428     }
 429
 430     if ( !keyval )
 431     {
 432         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 433             keyval = wxToupper( aunichar ) ;
 434         else
 435             keyval = aunichar;
 436     }
 437
 438 #if wxUSE_UNICODE
 439     // OS X generates events with key codes in Unicode private use area for
 440     // unprintable symbols such as cursor arrows (WXK_UP is mapped to U+F700)
 441     // and function keys (WXK_F2 is U+F705). We don't want to use them as the
 442     // result of wxKeyEvent::GetUnicodeKey() however as it's supposed to return
 443     // WXK_NONE for "non characters" so explicitly exclude them.
 444     //
 445     // We only exclude the private use area inside the Basic Multilingual Plane
 446     // as key codes beyond it don't seem to be currently used.
 447     if ( !(aunichar >= 0xe000 && aunichar < 0xf900) )
 448         wxevent.m_uniChar = aunichar;
 449 #endif
 450     wxevent.m_keyCode = keyval;
 451
 452     wxWindowMac* peer = GetWXPeer();
 453     if ( peer )
 454     {
 455         wxevent.SetEventObject(peer);
 456         wxevent.SetId(peer->GetId()) ;
 457     }
 458 }
 459
 460 UInt32 g_lastButton = 0 ;
 461 bool g_lastButtonWasFakeRight = false ;
 462
 463 // better scroll wheel support
 464 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 465
 466 @interface NSEvent (DeviceDelta)
 467 - (CGFloat)deviceDeltaX;
 468 - (CGFloat)deviceDeltaY;
 469
 470 // 10.7+
 471 - (BOOL)hasPreciseScrollingDeltas;
 472 - (CGFloat)scrollingDeltaX;
 473 - (CGFloat)scrollingDeltaY;
 474 @end
 475
 476 void wxWidgetCocoaImpl::SetupCoordinates(wxCoord &x, wxCoord &y, NSEvent* nsEvent)
 477 {
 478     NSPoint locationInWindow = [nsEvent locationInWindow];
 479
 480     // adjust coordinates for the window of the target view
 481     if ( [nsEvent window] != [m_osxView window] )
 482     {
 483         if ( [nsEvent window] != nil )
 484             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 485
 486         if ( [m_osxView window] != nil )
 487             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 488     }
 489
 490     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 491     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 492
 493     x = locationInViewWX.x;
 494     y = locationInViewWX.y;
 495
 496 }
 497
 498 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 499 {
 500     int eventType = [nsEvent type];
 501     UInt32 modifiers = [nsEvent modifierFlags] ;
 502
 503     SetupCoordinates(wxevent.m_x, wxevent.m_y, nsEvent);
 504
 505     // these parameters are not given for all events
 506     UInt32 button = [nsEvent buttonNumber];
 507     UInt32 clickCount = 0;
 508
 509     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 510     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 511     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 512     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 513     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 514
 515     UInt32 mouseChord = 0;
 516
 517     switch (eventType)
 518     {
 519         case NSLeftMouseDown :
 520         case NSLeftMouseDragged :
 521             mouseChord = 1U;
 522             break;
 523         case NSRightMouseDown :
 524         case NSRightMouseDragged :
 525             mouseChord = 2U;
 526             break;
 527         case NSOtherMouseDown :
 528         case NSOtherMouseDragged :
 529             mouseChord = 4U;
 530             break;
 531     }
 532
 533     // a control click is interpreted as a right click
 534     bool thisButtonIsFakeRight = false ;
 535     if ( button == 0 && (modifiers & NSControlKeyMask) )
 536     {
 537         button = 1 ;
 538         thisButtonIsFakeRight = true ;
 539     }
 540
 541     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 542     if ( clickCount > 1 && button != g_lastButton )
 543         clickCount = 1 ;
 544
 545     // we must make sure that our synthetic 'right' button corresponds in
 546     // mouse down, moved and mouse up, and does not deliver a right down and left up
 547     switch (eventType)
 548     {
 549         case NSLeftMouseDown :
 550         case NSRightMouseDown :
 551         case NSOtherMouseDown :
 552             g_lastButton = button ;
 553             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 554             break;
 555      }
 556
 557     if ( button == 0 )
 558     {
 559         g_lastButton = 0 ;
 560         g_lastButtonWasFakeRight = false ;
 561     }
 562     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 563         button = g_lastButton ;
 564
 565     // Adjust the chord mask to remove the primary button and add the
 566     // secondary button.  It is possible that the secondary button is
 567     // already pressed, e.g. on a mouse connected to a laptop, but this
 568     // possibility is ignored here:
 569     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 570         mouseChord = ((mouseChord & ~1U) | 2U);
 571
 572     if(mouseChord & 1U)
 573                 wxevent.m_leftDown = true ;
 574     if(mouseChord & 2U)
 575                 wxevent.m_rightDown = true ;
 576     if(mouseChord & 4U)
 577                 wxevent.m_middleDown = true ;
 578
 579     // translate into wx types
 580     switch (eventType)
 581     {
 582         case NSLeftMouseDown :
 583         case NSRightMouseDown :
 584         case NSOtherMouseDown :
 585             clickCount = [nsEvent clickCount];
 586             switch ( button )
 587             {
 588                 case 0 :
 589                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 590                     break ;
 591
 592                 case 1 :
 593                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 594                     break ;
 595
 596                 case 2 :
 597                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 598                     break ;
 599
 600                 default:
 601                     break ;
 602             }
 603             break ;
 604
 605         case NSLeftMouseUp :
 606         case NSRightMouseUp :
 607         case NSOtherMouseUp :
 608             clickCount = [nsEvent clickCount];
 609             switch ( button )
 610             {
 611                 case 0 :
 612                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 613                     break ;
 614
 615                 case 1 :
 616                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 617                     break ;
 618
 619                 case 2 :
 620                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 621                     break ;
 622
 623                 default:
 624                     break ;
 625             }
 626             break ;
 627
 628      case NSScrollWheel :
 629         {
 630             float deltaX = 0.0;
 631             float deltaY = 0.0;
 632
 633             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 634
 635             if ( UMAGetSystemVersion() >= 0x1070 )
 636             {
 637                 if ( [nsEvent hasPreciseScrollingDeltas] )
 638                 {
 639                     deltaX = [nsEvent scrollingDeltaX];
 640                     deltaY = [nsEvent scrollingDeltaY];
 641                 }
 642                 else
 643                 {
 644                     deltaX = [nsEvent scrollingDeltaX] * 10;
 645                     deltaY = [nsEvent scrollingDeltaY] * 10;
 646                 }
 647             }
 648             else
 649             {
 650                 const EventRef cEvent = (EventRef) [nsEvent eventRef];
 651                 // see http://developer.apple.com/qa/qa2005/qa1453.html
 652                 // for more details on why we have to look for the exact type
 653
 654                 bool isMouseScrollEvent = false;
 655                 if ( cEvent )
 656                     isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 657
 658                 if ( isMouseScrollEvent )
 659                 {
 660                     deltaX = [nsEvent deviceDeltaX];
 661                     deltaY = [nsEvent deviceDeltaY];
 662                 }
 663                 else
 664                 {
 665                     deltaX = ([nsEvent deltaX] * 10);
 666                     deltaY = ([nsEvent deltaY] * 10);
 667                 }
 668             }
 669
 670             wxevent.m_wheelDelta = 10;
 671             wxevent.m_linesPerAction = 1;
 672
 673             if ( fabs(deltaX) > fabs(deltaY) )
 674             {
 675                 wxevent.m_wheelAxis = wxMOUSE_WHEEL_HORIZONTAL;
 676                 wxevent.m_wheelRotation = (int)deltaX;
 677             }
 678             else
 679             {
 680                 wxevent.m_wheelRotation = (int)deltaY;
 681             }
 682
 683         }
 684         break ;
 685
 686         case NSMouseEntered :
 687             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 688             break;
 689         case NSMouseExited :
 690             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 691             break;
 692         case NSLeftMouseDragged :
 693         case NSRightMouseDragged :
 694         case NSOtherMouseDragged :
 695         case NSMouseMoved :
 696             wxevent.SetEventType( wxEVT_MOTION ) ;
 697             break;
 698         default :
 699             break ;
 700     }
 701
 702     wxevent.m_clickCount = clickCount;
 703     wxWindowMac* peer = GetWXPeer();
 704     if ( peer )
 705     {
 706         wxevent.SetEventObject(peer);
 707         wxevent.SetId(peer->GetId()) ;
 708     }
 709 }
 710
 711 @implementation wxNSView
 712
 713 + (void)initialize
 714 {
 715     static BOOL initialized = NO;
 716     if (!initialized)
 717     {
 718         initialized = YES;
 719         wxOSXCocoaClassAddWXMethods( self );
 720     }
 721 }
 722
 723 /* idea taken from webkit sources: overwrite the methods that (private) NSToolTipManager will use to attach its tracking rectangle
 724  * then when changing the tooltip send fake view-exit and view-enter methods which will lead to a tooltip refresh
 725  */
 726
 727
 728 - (void)_sendToolTipMouseExited
 729 {
 730     // Nothing matters except window, trackingNumber, and userData.
 731     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseExited
 732                                                 location:NSMakePoint(0, 0)
 733                                            modifierFlags:0
 734                                                timestamp:0
 735                                             windowNumber:[[self window] windowNumber]
 736                                                  context:NULL
 737                                              eventNumber:0
 738                                           trackingNumber:_lastToolTipTrackTag
 739                                                 userData:_lastUserData];
 740     [_lastToolTipOwner mouseExited:fakeEvent];
 741 }
 742
 743 - (void)_sendToolTipMouseEntered
 744 {
 745     // Nothing matters except window, trackingNumber, and userData.
 746     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseEntered
 747                                                 location:NSMakePoint(0, 0)
 748                                            modifierFlags:0
 749                                                timestamp:0
 750                                             windowNumber:[[self window] windowNumber]
 751                                                  context:NULL
 752                                              eventNumber:0
 753                                           trackingNumber:_lastToolTipTrackTag
 754                                                 userData:_lastUserData];
 755     [_lastToolTipOwner mouseEntered:fakeEvent];
 756 }
 757
 758 - (void)setToolTip:(NSString *)string;
 759 {
 760     if (string)
 761     {
 762         if ( _hasToolTip )
 763         {
 764             [self _sendToolTipMouseExited];
 765         }
 766
 767         [super setToolTip:string];
 768         _hasToolTip = YES;
 769         [self _sendToolTipMouseEntered];
 770     }
 771     else
 772     {
 773         if ( _hasToolTip )
 774         {
 775             [self _sendToolTipMouseExited];
 776             [super setToolTip:nil];
 777             _hasToolTip = NO;
 778         }
 779     }
 780 }
 781
 782 - (NSTrackingRectTag)addTrackingRect:(NSRect)rect owner:(id)owner userData:(void *)data assumeInside:(BOOL)assumeInside
 783 {
 784     NSTrackingRectTag tag = [super addTrackingRect:rect owner:owner userData:data assumeInside:assumeInside];
 785     if ( owner != self )
 786     {
 787         _lastUserData = data;
 788         _lastToolTipOwner = owner;
 789         _lastToolTipTrackTag = tag;
 790     }
 791     return tag;
 792 }
 793
 794 - (void)removeTrackingRect:(NSTrackingRectTag)tag
 795 {
 796     if (tag == _lastToolTipTrackTag)
 797     {
 798         _lastUserData = NULL;
 799         _lastToolTipOwner = nil;
 800         _lastToolTipTrackTag = 0;
 801     }
 802     [super removeTrackingRect:tag];
 803 }
 804
 805 #if wxOSX_USE_NATIVE_FLIPPED
 806 - (BOOL)isFlipped
 807 {
 808     return YES;
 809 }
 810 #endif
 811
 812 - (BOOL) canBecomeKeyView
 813 {
 814     wxWidgetCocoaImpl* viewimpl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 815     if ( viewimpl && viewimpl->IsUserPane() && viewimpl->GetWXPeer() )
 816         return viewimpl->GetWXPeer()->AcceptsFocus();
 817     return NO;
 818 }
 819
 820 @end // wxNSView
 821
 822 //
 823 // event handlers
 824 //
 825
 826 #if wxUSE_DRAG_AND_DROP
 827
 828 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 829 // for details on the NSPasteboard -> PasteboardRef conversion
 830
 831 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 832 {
 833     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 834     if (impl == NULL)
 835         return NSDragOperationNone;
 836
 837     return impl->draggingEntered(sender, self, _cmd);
 838 }
 839
 840 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 841 {
 842     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 843     if (impl == NULL)
 844         return ;
 845
 846     return impl->draggingExited(sender, self, _cmd);
 847 }
 848
 849 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 850 {
 851     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 852     if (impl == NULL)
 853         return NSDragOperationNone;
 854
 855     return impl->draggingUpdated(sender, self, _cmd);
 856 }
 857
 858 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 859 {
 860     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 861     if (impl == NULL)
 862         return NSDragOperationNone;
 863
 864     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 865 }
 866
 867 #endif
 868
 869 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 870 {
 871     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 872     if (impl == NULL)
 873         return;
 874
 875     impl->mouseEvent(event, self, _cmd);
 876 }
 877
 878 void wxOSX_cursorUpdate(NSView* self, SEL _cmd, NSEvent *event)
 879 {
 880     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 881     if (impl == NULL)
 882         return;
 883
 884     impl->cursorUpdate(event, self, _cmd);
 885 }
 886
 887 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 888 {
 889     // This is needed to support click through, otherwise the first click on a window
 890     // will not do anything unless it is the active window already.
 891     return YES;
 892 }
 893
 894 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 895 {
 896     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 897     if (impl == NULL)
 898         return;
 899
 900     impl->keyEvent(event, self, _cmd);
 901 }
 902
 903 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 904 {
 905     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 906     if (impl == NULL)
 907         return;
 908
 909     impl->insertText(text, self, _cmd);
 910 }
 911
 912 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 913 {
 914     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 915     if (impl == NULL)
 916         return NO;
 917
 918     return impl->performKeyEquivalent(event, self, _cmd);
 919 }
 920
 921 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 922 {
 923     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 924     if (impl == NULL)
 925         return NO;
 926
 927     return impl->acceptsFirstResponder(self, _cmd);
 928 }
 929
 930 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 931 {
 932     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 933     if (impl == NULL)
 934         return NO;
 935
 936     return impl->becomeFirstResponder(self, _cmd);
 937 }
 938
 939 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 940 {
 941     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 942     if (impl == NULL)
 943         return NO;
 944
 945     return impl->resignFirstResponder(self, _cmd);
 946 }
 947
 948 #if !wxOSX_USE_NATIVE_FLIPPED
 949
 950 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 951 {
 952     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 953     if (impl == NULL)
 954         return NO;
 955
 956     return impl->isFlipped(self, _cmd) ? YES:NO;
 957 }
 958
 959 #endif
 960
 961 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 962
 963 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 964 {
 965     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 966     if (impl == NULL)
 967         return;
 968
 969 #if wxUSE_THREADS
 970     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 971     // dialog. This causes a drawRect of the active dialog from outside the
 972     // main UI thread. This causes an occasional crash since the wx drawing
 973     // objects (like wxPen) are not thread safe.
 974     //
 975     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 976     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 977     if ( !wxThread::IsMain() )
 978     {
 979         if ( impl->IsUserPane() )
 980         {
 981             wxWindow* win = impl->GetWXPeer();
 982             if ( win->UseBgCol() )
 983             {
 984
 985                 CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 986                 CGContextSaveGState( context );
 987
 988                 CGContextSetFillColorWithColor( context, win->GetBackgroundColour().GetCGColor());
 989                 CGRect r = CGRectMake(rect.origin.x, rect.origin.y, rect.size.width, rect.size.height);
 990                 CGContextFillRect( context, r );
 991
 992                 CGContextRestoreGState( context );
 993             }
 994         }
 995         else
 996         {
 997             // just call the superclass handler, we don't need any custom wx drawing
 998             // here and it seems to work fine:
 999             wxOSX_DrawRectHandlerPtr
1000             superimpl = (wxOSX_DrawRectHandlerPtr)
1001             [[self superclass] instanceMethodForSelector:_cmd];
1002             superimpl(self, _cmd, rect);
1003         }
1004
1005       return;
1006     }
1007 #endif // wxUSE_THREADS
1008
1009     return impl->drawRect(&rect, self, _cmd);
1010 }
1011
1012 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
1013 {
1014     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
1015     if (impl == NULL)
1016         return;
1017
1018     impl->controlAction(self, _cmd, sender);
1019 }
1020
1021 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
1022 {
1023     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
1024     if (impl == NULL)
1025         return;
1026
1027     impl->controlDoubleAction(self, _cmd, sender);
1028 }
1029
1030 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1031 {
1032     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1033     NSPasteboard *pboard = [sender draggingPasteboard];
1034     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1035
1036     wxWindow* wxpeer = GetWXPeer();
1037     if ( wxpeer == NULL )
1038         return NSDragOperationNone;
1039
1040     wxDropTarget* target = wxpeer->GetDropTarget();
1041     if ( target == NULL )
1042         return NSDragOperationNone;
1043
1044     wxDragResult result = wxDragNone;
1045     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1046     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1047
1048     if ( sourceDragMask & NSDragOperationLink )
1049         result = wxDragLink;
1050     else if ( sourceDragMask & NSDragOperationCopy )
1051         result = wxDragCopy;
1052     else if ( sourceDragMask & NSDragOperationMove )
1053         result = wxDragMove;
1054
1055     PasteboardRef pboardRef;
1056     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1057     target->SetCurrentDragPasteboard(pboardRef);
1058     result = target->OnEnter(pt.x, pt.y, result);
1059     CFRelease(pboardRef);
1060
1061     NSDragOperation nsresult = NSDragOperationNone;
1062     switch (result )
1063     {
1064         case wxDragLink:
1065             nsresult = NSDragOperationLink;
1066         case wxDragMove:
1067             nsresult = NSDragOperationMove;
1068         case wxDragCopy:
1069             nsresult = NSDragOperationCopy;
1070         default :
1071             break;
1072     }
1073     return nsresult;
1074 }
1075
1076 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1077 {
1078     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1079     NSPasteboard *pboard = [sender draggingPasteboard];
1080
1081     wxWindow* wxpeer = GetWXPeer();
1082     if ( wxpeer == NULL )
1083         return;
1084
1085     wxDropTarget* target = wxpeer->GetDropTarget();
1086     if ( target == NULL )
1087         return;
1088
1089     PasteboardRef pboardRef;
1090     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1091     target->SetCurrentDragPasteboard(pboardRef);
1092     target->OnLeave();
1093     CFRelease(pboardRef);
1094  }
1095
1096 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1097 {
1098     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1099     NSPasteboard *pboard = [sender draggingPasteboard];
1100     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1101
1102     wxWindow* wxpeer = GetWXPeer();
1103     if ( wxpeer == NULL )
1104         return NSDragOperationNone;
1105
1106     wxDropTarget* target = wxpeer->GetDropTarget();
1107     if ( target == NULL )
1108         return NSDragOperationNone;
1109
1110     wxDragResult result = wxDragNone;
1111     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1112     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1113
1114     if ( sourceDragMask & NSDragOperationLink )
1115         result = wxDragLink;
1116     else if ( sourceDragMask & NSDragOperationCopy )
1117         result = wxDragCopy;
1118     else if ( sourceDragMask & NSDragOperationMove )
1119         result = wxDragMove;
1120
1121     PasteboardRef pboardRef;
1122     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1123     target->SetCurrentDragPasteboard(pboardRef);
1124     result = target->OnDragOver(pt.x, pt.y, result);
1125     CFRelease(pboardRef);
1126
1127     NSDragOperation nsresult = NSDragOperationNone;
1128     switch (result )
1129     {
1130         case wxDragLink:
1131             nsresult = NSDragOperationLink;
1132         case wxDragMove:
1133             nsresult = NSDragOperationMove;
1134         case wxDragCopy:
1135             nsresult = NSDragOperationCopy;
1136         default :
1137             break;
1138     }
1139     return nsresult;
1140 }
1141
1142 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1143 {
1144     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1145
1146     NSPasteboard *pboard = [sender draggingPasteboard];
1147     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1148
1149     wxWindow* wxpeer = GetWXPeer();
1150     wxDropTarget* target = wxpeer->GetDropTarget();
1151     wxDragResult result = wxDragNone;
1152     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1153     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1154
1155     if ( sourceDragMask & NSDragOperationLink )
1156         result = wxDragLink;
1157     else if ( sourceDragMask & NSDragOperationCopy )
1158         result = wxDragCopy;
1159     else if ( sourceDragMask & NSDragOperationMove )
1160         result = wxDragMove;
1161
1162     PasteboardRef pboardRef;
1163     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1164     target->SetCurrentDragPasteboard(pboardRef);
1165
1166     if (target->OnDrop(pt.x, pt.y))
1167         result = target->OnData(pt.x, pt.y, result);
1168
1169     CFRelease(pboardRef);
1170
1171     return result != wxDragNone;
1172 }
1173
1174 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
1175 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1176 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1177 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
1178
1179 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1180 {
1181     // we are getting moved events for all windows in the hierarchy, not something wx expects
1182     // therefore we only handle it for the deepest child in the hierarchy
1183     if ( [event type] == NSMouseMoved )
1184     {
1185         NSView* hitview = [[[slf window] contentView] hitTest:[event locationInWindow]];
1186         if ( hitview == NULL || hitview != slf)
1187             return;
1188     }
1189
1190     if ( !DoHandleMouseEvent(event) )
1191     {
1192         // for plain NSView mouse events would propagate to parents otherwise
1193         if (!IsUserPane())
1194         {
1195             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1196             superimpl(slf, (SEL)_cmd, event);
1197
1198             // super of built-ins keeps the mouse up, as wx expects this event, we have to synthesize it
1199             // only trigger if at this moment the mouse is already up
1200             if ( [ event type]  == NSLeftMouseDown && !wxGetMouseState().LeftIsDown() )
1201             {
1202                 wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
1203                 SetupMouseEvent(wxevent , event) ;
1204                 wxevent.SetEventType(wxEVT_LEFT_UP);
1205
1206                 GetWXPeer()->HandleWindowEvent(wxevent);
1207             }
1208         }
1209     }
1210 }
1211
1212 void wxWidgetCocoaImpl::cursorUpdate(WX_NSEvent event, WXWidget slf, void *_cmd)
1213 {
1214     if ( !SetupCursor(event) )
1215     {
1216         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1217             superimpl(slf, (SEL)_cmd, event);
1218     }
1219  }
1220
1221 bool wxWidgetCocoaImpl::SetupCursor(WX_NSEvent event)
1222 {
1223     extern wxCursor gGlobalCursor;
1224
1225     if ( gGlobalCursor.IsOk() )
1226     {
1227         gGlobalCursor.MacInstall();
1228         return true;
1229     }
1230     else
1231     {
1232         wxWindow* cursorTarget = GetWXPeer();
1233         wxCoord x,y;
1234         SetupCoordinates(x, y, event);
1235         wxPoint cursorPoint( x , y ) ;
1236
1237         while ( cursorTarget && !cursorTarget->MacSetupCursor( cursorPoint ) )
1238         {
1239             // at least in GTK cursor events are not propagated either ...
1240 #if 1
1241             cursorTarget = NULL;
1242 #else
1243             cursorTarget = cursorTarget->GetParent() ;
1244             if ( cursorTarget )
1245                 cursorPoint += cursorTarget->GetPosition();
1246 #endif
1247         }
1248
1249         return cursorTarget != NULL;
1250     }
1251 }
1252
1253 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1254 {
1255     if ( [event type] == NSKeyDown )
1256     {
1257         // there are key equivalents that are not command-combos and therefore not handled by cocoa automatically,
1258         // therefore we call the menubar directly here, exit if the menu is handling the shortcut
1259         if ( [[[NSApplication sharedApplication] mainMenu] performKeyEquivalent:event] )
1260             return;
1261
1262         m_lastKeyDownEvent = event;
1263     }
1264
1265     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1266     {
1267         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1268         superimpl(slf, (SEL)_cmd, event);
1269     }
1270     m_lastKeyDownEvent = NULL;
1271 }
1272
1273 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1274 {
1275     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1276     {
1277         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1278         superimpl(slf, (SEL)_cmd, text);
1279     }
1280 }
1281
1282
1283 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1284 {
1285     bool handled = false;
1286
1287     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1288     SetupKeyEvent( wxevent, event );
1289
1290     // because performKeyEquivalent is going up the entire view hierarchy, we don't have to
1291     // walk up the ancestors ourselves but let cocoa do it
1292
1293     int command = m_wxPeer->GetAcceleratorTable()->GetCommand( wxevent );
1294     if (command != -1)
1295     {
1296         wxEvtHandler * const handler = m_wxPeer->GetEventHandler();
1297
1298         wxCommandEvent command_event( wxEVT_MENU, command );
1299         command_event.SetEventObject( wxevent.GetEventObject() );
1300         handled = handler->ProcessEvent( command_event );
1301
1302         if ( !handled )
1303         {
1304             // accelerators can also be used with buttons, try them too
1305             command_event.SetEventType(wxEVT_BUTTON);
1306             handled = handler->ProcessEvent( command_event );
1307         }
1308     }
1309
1310     if ( !handled )
1311     {
1312         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1313         return superimpl(slf, (SEL)_cmd, event);
1314     }
1315     return YES;
1316 }
1317
1318 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1319 {
1320     if ( IsUserPane() )
1321         return m_wxPeer->AcceptsFocus();
1322     else
1323     {
1324         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1325         return superimpl(slf, (SEL)_cmd);
1326     }
1327 }
1328
1329 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1330 {
1331     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1332     // get the current focus before running becomeFirstResponder
1333     NSView* otherView = FindFocus();
1334
1335     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1336     BOOL r = superimpl(slf, (SEL)_cmd);
1337     if ( r )
1338     {
1339         DoNotifyFocusEvent( true, otherWindow );
1340     }
1341
1342     return r;
1343 }
1344
1345 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1346 {
1347     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1348     BOOL r = superimpl(slf, (SEL)_cmd);
1349     // get the current focus after running resignFirstResponder
1350     // note that this value isn't reliable, it might return the same view that
1351     // is resigning
1352     NSView* otherView = FindFocus();
1353     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1354
1355     // CS: the fix for #12267 leads to missed focus events like in #14938 , as #12267 doesn't seem to happen anymore even
1356     // without the fix, I'm turning it off, if it still is needed we should only use it in case of the wxGridCellTextEditor
1357 #if 0
1358     // It doesn't make sense to notify about the loss of focus if we're not
1359     // really losing it and the window which has just gained focus is the same
1360     // one as this window itself. Of course, this should never happen in the
1361     // first place but somehow it does in wxGrid code and without this check we
1362     // enter into an infinite recursion, see #12267.
1363     if ( otherWindow == this )
1364         return r;
1365 #endif
1366
1367     // NSTextViews have an editor as true responder, therefore the might get the
1368     // resign notification if their editor takes over, don't trigger any event then
1369     if ( r && !m_hasEditor)
1370     {
1371         DoNotifyFocusEvent( false, otherWindow );
1372     }
1373     return r;
1374 }
1375
1376 #if !wxOSX_USE_NATIVE_FLIPPED
1377
1378 bool wxWidgetCocoaImpl::isFlipped(WXWidget slf, void *WXUNUSED(_cmd))
1379 {
1380     return m_isFlipped;
1381 }
1382
1383 #endif
1384
1385 #define OSX_DEBUG_DRAWING 0
1386
1387 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1388 {
1389     // preparing the update region
1390
1391     wxRegion updateRgn;
1392
1393     // since adding many rects to a region is a costly process, by default use the bounding rect
1394 #if 0
1395     const NSRect *rects;
1396     NSInteger count;
1397     [slf getRectsBeingDrawn:&rects count:&count];
1398     for ( int i = 0 ; i < count ; ++i )
1399     {
1400         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1401     }
1402 #else
1403     updateRgn.Union(wxFromNSRect(slf,*(NSRect*)rect));
1404 #endif
1405
1406     wxWindow* wxpeer = GetWXPeer();
1407
1408     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1409     {
1410         // as this update region is in native window locals we must adapt it to wx window local
1411         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1412     }
1413
1414     // Restrict the update region to the shape of the window, if any, and also
1415     // remember the region that we need to clear later.
1416     wxNonOwnedWindow* const tlwParent = wxpeer->MacGetTopLevelWindow();
1417     const bool isTopLevel = tlwParent == wxpeer;
1418     wxRegion clearRgn;
1419     if ( tlwParent->GetWindowStyle() & wxFRAME_SHAPED )
1420     {
1421         if ( isTopLevel )
1422             clearRgn = updateRgn;
1423
1424         int xoffset = 0, yoffset = 0;
1425         wxRegion rgn = tlwParent->GetShape();
1426         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1427         rgn.Offset( xoffset, yoffset );
1428         updateRgn.Intersect(rgn);
1429
1430         if ( isTopLevel )
1431         {
1432             // Exclude the window shape from the region to be cleared below.
1433             rgn.Xor(wxpeer->GetSize());
1434             clearRgn.Intersect(rgn);
1435         }
1436     }
1437
1438     wxpeer->GetUpdateRegion() = updateRgn;
1439
1440     // setting up the drawing context
1441
1442     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1443     CGContextSaveGState( context );
1444
1445 #if OSX_DEBUG_DRAWING
1446     CGContextBeginPath( context );
1447     CGContextMoveToPoint(context, 0, 0);
1448     NSRect bounds = [slf bounds];
1449     CGContextAddLineToPoint(context, 10, 0);
1450     CGContextMoveToPoint(context, 0, 0);
1451     CGContextAddLineToPoint(context, 0, 10);
1452     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1453     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1454     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1455     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1456     CGContextClosePath( context );
1457     CGContextStrokePath(context);
1458 #endif
1459
1460     if ( ![slf isFlipped] )
1461     {
1462         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1463         CGContextScaleCTM( context, 1, -1 );
1464     }
1465
1466     wxpeer->MacSetCGContextRef( context );
1467
1468     bool handled = wxpeer->MacDoRedraw( 0 );
1469     CGContextRestoreGState( context );
1470
1471     CGContextSaveGState( context );
1472     if ( !handled )
1473     {
1474         // call super
1475         SEL _cmd = @selector(drawRect:);
1476         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1477         superimpl(slf, _cmd, *(NSRect*)rect);
1478         CGContextRestoreGState( context );
1479         CGContextSaveGState( context );
1480     }
1481     // as we called restore above, we have to flip again if necessary
1482     if ( ![slf isFlipped] )
1483     {
1484         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1485         CGContextScaleCTM( context, 1, -1 );
1486     }
1487
1488     if ( isTopLevel )
1489     {
1490         // We also need to explicitly draw the part of the top level window
1491         // outside of its region with transparent colour to ensure that it is
1492         // really transparent.
1493         if ( clearRgn.IsOk() )
1494         {
1495             wxMacCGContextStateSaver saveState(context);
1496             wxWindowDC dc(wxpeer);
1497             dc.SetBackground(wxBrush(wxTransparentColour));
1498             dc.SetDeviceClippingRegion(clearRgn);
1499             dc.Clear();
1500         }
1501
1502 #if wxUSE_GRAPHICS_CONTEXT
1503         // If the window shape is defined by a path, stroke the path to show
1504         // the window border.
1505         const wxGraphicsPath& path = tlwParent->GetShapePath();
1506         if ( !path.IsNull() )
1507         {
1508             CGContextSetLineWidth(context, 1);
1509             CGContextSetStrokeColorWithColor(context, wxLIGHT_GREY->GetCGColor());
1510             CGContextAddPath(context, (CGPathRef) path.GetNativePath());
1511             CGContextStrokePath(context);
1512         }
1513 #endif // wxUSE_GRAPHICS_CONTEXT
1514     }
1515
1516     wxpeer->MacPaintChildrenBorders();
1517     wxpeer->MacSetCGContextRef( NULL );
1518     CGContextRestoreGState( context );
1519 }
1520
1521 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1522 {
1523     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1524     if ( wxpeer )
1525     {
1526         wxpeer->OSXSimulateFocusEvents();
1527         wxpeer->OSXHandleClicked(0);
1528     }
1529 }
1530
1531 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1532 {
1533 }
1534
1535 void wxWidgetCocoaImpl::controlTextDidChange()
1536 {
1537     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1538     if ( wxpeer )
1539     {
1540         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1541         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1542         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1543         if ( tc )
1544             tc->SendTextUpdatedEventIfAllowed();
1545         else if ( cb )
1546             cb->SendTextUpdatedEventIfAllowed();
1547         else
1548         {
1549             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1550         }
1551     }
1552 }
1553
1554 //
1555
1556 #if OBJC_API_VERSION >= 2
1557
1558 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1559     class_addMethod(c, s, i, t );
1560
1561 #else
1562
1563 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1564     { s, (char*) t, i },
1565
1566 #endif
1567
1568 void wxOSXCocoaClassAddWXMethods(Class c)
1569 {
1570
1571 #if OBJC_API_VERSION < 2
1572     static objc_method wxmethods[] =
1573     {
1574 #endif
1575
1576     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1577     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1578     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1579
1580     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1581     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1582     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1583
1584     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1585
1586     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1587     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1588     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1589
1590     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1591
1592     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1593     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1594     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1595
1596     wxOSX_CLASS_ADD_METHOD(c, @selector(cursorUpdate:), (IMP) wxOSX_cursorUpdate, "v@:@" )
1597
1598     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1599     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1600     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1601
1602     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1603
1604     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1605
1606     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1607     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1608     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1609
1610 #if !wxOSX_USE_NATIVE_FLIPPED
1611     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1612 #endif
1613     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1614
1615     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1616     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1617
1618 #if wxUSE_DRAG_AND_DROP
1619     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1620     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1621     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1622     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1623 #endif
1624
1625 #if OBJC_API_VERSION < 2
1626     } ;
1627     static int method_count = WXSIZEOF( wxmethods );
1628     static objc_method_list *wxmethodlist = NULL;
1629     if ( wxmethodlist == NULL )
1630     {
1631         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1632         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1633         wxmethodlist->method_count = method_count;
1634         wxmethodlist->obsolete = 0;
1635     }
1636     class_addMethods( c, wxmethodlist );
1637 #endif
1638 }
1639
1640 //
1641 // C++ implementation class
1642 //
1643
1644 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1645
1646 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl, bool isUserPane ) :
1647     wxWidgetImpl( peer, isRootControl, isUserPane )
1648 {
1649     Init();
1650     m_osxView = w;
1651
1652     // check if the user wants to create the control initially hidden
1653     if ( !peer->IsShown() )
1654         SetVisibility(false);
1655
1656     // gc aware handling
1657     if ( m_osxView )
1658         CFRetain(m_osxView);
1659     [m_osxView release];
1660 }
1661
1662 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1663 {
1664     Init();
1665 }
1666
1667 void wxWidgetCocoaImpl::Init()
1668 {
1669     m_osxView = NULL;
1670 #if !wxOSX_USE_NATIVE_FLIPPED
1671     m_isFlipped = true;
1672 #endif
1673     m_lastKeyDownEvent = NULL;
1674     m_hasEditor = false;
1675 }
1676
1677 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1678 {
1679     RemoveAssociations( this );
1680
1681     if ( !IsRootControl() )
1682     {
1683         NSView *sv = [m_osxView superview];
1684         if ( sv != nil )
1685             [m_osxView removeFromSuperview];
1686     }
1687     // gc aware handling
1688     if ( m_osxView )
1689         CFRelease(m_osxView);
1690 }
1691
1692 bool wxWidgetCocoaImpl::IsVisible() const
1693 {
1694     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1695 }
1696
1697 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1698 {
1699     [m_osxView setHidden:(visible ? NO:YES)];
1700 }
1701
1702 // ----------------------------------------------------------------------------
1703 // window animation stuff
1704 // ----------------------------------------------------------------------------
1705
1706 // define a delegate used to refresh the window during animation
1707 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1708 {
1709     wxWindow *m_win;
1710     bool m_isDone;
1711 }
1712
1713 - (id)init:(wxWindow *)win;
1714
1715 - (bool)isDone;
1716
1717 // NSAnimationDelegate methods
1718 - (void)animationDidEnd:(NSAnimation*)animation;
1719 - (void)animation:(NSAnimation*)animation
1720         didReachProgressMark:(NSAnimationProgress)progress;
1721 @end
1722
1723 @implementation wxNSAnimationDelegate
1724
1725 - (id)init:(wxWindow *)win
1726 {
1727     self = [super init];
1728
1729     m_win = win;
1730     m_isDone = false;
1731
1732     return self;
1733 }
1734
1735 - (bool)isDone
1736 {
1737     return m_isDone;
1738 }
1739
1740 - (void)animation:(NSAnimation*)animation
1741         didReachProgressMark:(NSAnimationProgress)progress
1742 {
1743     wxUnusedVar(animation);
1744     wxUnusedVar(progress);
1745
1746     m_win->SendSizeEvent();
1747     m_win->MacOnInternalSize();
1748 }
1749
1750 - (void)animationDidEnd:(NSAnimation*)animation
1751 {
1752     wxUnusedVar(animation);
1753     m_isDone = true;
1754 }
1755
1756 @end
1757
1758 /* static */
1759 bool
1760 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1761                                               bool show,
1762                                               wxShowEffect effect,
1763                                               unsigned timeout)
1764 {
1765     // create the dictionary describing the animation to perform on this view
1766     NSObject * const
1767         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1768     NSMutableDictionary * const
1769         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1770     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1771
1772     // determine the start and end rectangles assuming we're hiding the window
1773     const wxRect rectOrig = win->GetRect();
1774     wxRect rectStart,
1775            rectEnd;
1776     rectStart =
1777     rectEnd = rectOrig;
1778
1779     if ( show )
1780     {
1781         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1782                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1783             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1784         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1785                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1786             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1787         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1788                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1789             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1790         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1791                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1792             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1793     }
1794
1795     switch ( effect )
1796     {
1797         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1798         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1799             rectEnd.width = 0;
1800             break;
1801
1802         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1803         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1804             rectEnd.x = rectStart.GetRight();
1805             rectEnd.width = 0;
1806             break;
1807
1808         case wxSHOW_EFFECT_ROLL_TO_TOP:
1809         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1810             rectEnd.height = 0;
1811             break;
1812
1813         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1814         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1815             rectEnd.y = rectStart.GetBottom();
1816             rectEnd.height = 0;
1817             break;
1818
1819         case wxSHOW_EFFECT_EXPAND:
1820             rectEnd.x = rectStart.x + rectStart.width / 2;
1821             rectEnd.y = rectStart.y + rectStart.height / 2;
1822             rectEnd.width =
1823             rectEnd.height = 0;
1824             break;
1825
1826         case wxSHOW_EFFECT_BLEND:
1827             [dict setObject:(show ? NSViewAnimationFadeInEffect
1828                                   : NSViewAnimationFadeOutEffect)
1829                   forKey:NSViewAnimationEffectKey];
1830             break;
1831
1832         case wxSHOW_EFFECT_NONE:
1833         case wxSHOW_EFFECT_MAX:
1834             wxFAIL_MSG( "unexpected animation effect" );
1835             return false;
1836
1837         default:
1838             wxFAIL_MSG( "unknown animation effect" );
1839             return false;
1840     };
1841
1842     if ( show )
1843     {
1844         // we need to restore it to the original rectangle instead of making it
1845         // disappear
1846         wxSwap(rectStart, rectEnd);
1847
1848         // and as the window is currently hidden, we need to show it for the
1849         // animation to be visible at all (but don't restore it at its full
1850         // rectangle as it shouldn't appear immediately)
1851         win->SetSize(rectStart);
1852         win->Show();
1853     }
1854
1855     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1856                                     ? [(NSView *)viewOrWin superview]
1857                                     : nil;
1858     const NSRect rStart = wxToNSRect(parentView, rectStart);
1859     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1860
1861     [dict setObject:[NSValue valueWithRect:rStart]
1862           forKey:NSViewAnimationStartFrameKey];
1863     [dict setObject:[NSValue valueWithRect:rEnd]
1864           forKey:NSViewAnimationEndFrameKey];
1865
1866     // create an animation using the values in the above dictionary
1867     NSViewAnimation * const
1868         anim = [[NSViewAnimation alloc]
1869                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1870
1871     if ( !timeout )
1872     {
1873         // what is a good default duration? Windows uses 200ms, Web frameworks
1874         // use anything from 250ms to 1s... choose something in the middle
1875         timeout = 500;
1876     }
1877
1878     [anim setDuration:timeout/1000.];   // duration is in seconds here
1879
1880     // if the window being animated changes its layout depending on its size
1881     // (which is almost always the case) we need to redo it during animation
1882     //
1883     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1884     // controls in wxInfoBar visibly jump around)
1885     const int NUM_LAYOUTS = 20;
1886     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1887         [anim addProgressMark:f];
1888
1889     wxNSAnimationDelegate * const
1890         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1891     [anim setDelegate:animDelegate];
1892     [anim startAnimation];
1893
1894     // Cocoa is capable of doing animation asynchronously or even from separate
1895     // thread but wx API doesn't provide any way to be notified about the
1896     // animation end and without this we really must ensure that the window has
1897     // the expected (i.e. the same as if a simple Show() had been used) size
1898     // when we return, so block here until the animation finishes
1899     //
1900     // notice that because the default animation mode is NSAnimationBlocking,
1901     // no user input events ought to be processed from here
1902     {
1903         wxEventLoopGuarantor ensureEventLoopExistence;
1904         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1905         while ( ![animDelegate isDone] )
1906             loop->Dispatch();
1907     }
1908
1909     if ( !show )
1910     {
1911         // NSViewAnimation is smart enough to hide the NSView being animated at
1912         // the end but we also must ensure that it's hidden for wx too
1913         win->Hide();
1914
1915         // and we must also restore its size because it isn't expected to
1916         // change just because the window was hidden
1917         win->SetSize(rectOrig);
1918     }
1919     else
1920     {
1921         // refresh it once again after the end to ensure that everything is in
1922         // place
1923         win->SendSizeEvent();
1924         win->MacOnInternalSize();
1925     }
1926
1927     [anim setDelegate:nil];
1928     [animDelegate release];
1929     [anim release];
1930
1931     return true;
1932 }
1933
1934 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1935                                        wxShowEffect effect,
1936                                        unsigned timeout)
1937 {
1938     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1939 }
1940
1941 /* note that the drawing order between siblings is not defined under 10.4 */
1942 /* only starting from 10.5 the subview order is respected */
1943
1944 /* NSComparisonResult is typedef'd as an enum pre-Leopard but typedef'd as
1945  * NSInteger post-Leopard.  Pre-Leopard the Cocoa toolkit expects a function
1946  * returning int and not NSComparisonResult.  Post-Leopard the Cocoa toolkit
1947  * expects a function returning the new non-enum NSComparsionResult.
1948  * Hence we create a typedef named CocoaWindowCompareFunctionResult.
1949  */
1950 #if defined(NSINTEGER_DEFINED)
1951 typedef NSComparisonResult CocoaWindowCompareFunctionResult;
1952 #else
1953 typedef int CocoaWindowCompareFunctionResult;
1954 #endif
1955
1956 class CocoaWindowCompareContext
1957 {
1958     wxDECLARE_NO_COPY_CLASS(CocoaWindowCompareContext);
1959 public:
1960     CocoaWindowCompareContext(); // Not implemented
1961     CocoaWindowCompareContext(NSView *target, NSArray *subviews)
1962     {
1963         m_target = target;
1964         // Cocoa sorts subviews in-place.. make a copy
1965         m_subviews = [subviews copy];
1966     }
1967
1968     ~CocoaWindowCompareContext()
1969     {   // release the copy
1970         [m_subviews release];
1971     }
1972     NSView* target()
1973     {   return m_target; }
1974
1975     NSArray* subviews()
1976     {   return m_subviews; }
1977
1978     /* Helper function that returns the comparison based off of the original ordering */
1979     CocoaWindowCompareFunctionResult CompareUsingOriginalOrdering(id first, id second)
1980     {
1981         NSUInteger firstI = [m_subviews indexOfObjectIdenticalTo:first];
1982         NSUInteger secondI = [m_subviews indexOfObjectIdenticalTo:second];
1983         // NOTE: If either firstI or secondI is NSNotFound then it will be NSIntegerMax and thus will
1984         // likely compare higher than the other view which is reasonable considering the only way that
1985         // can happen is if the subview was added after our call to subviews but before the call to
1986         // sortSubviewsUsingFunction:context:.  Thus we don't bother checking.  Particularly because
1987         // that case should never occur anyway because that would imply a multi-threaded GUI call
1988         // which is a big no-no with Cocoa.
1989
1990         // Subviews are ordered from back to front meaning one that is already lower will have an lower index.
1991         NSComparisonResult result = (firstI < secondI)
1992                 ?   NSOrderedAscending /* -1 */
1993                 :   (firstI > secondI)
1994                 ?   NSOrderedDescending /* 1 */
1995                 :   NSOrderedSame /* 0 */;
1996
1997         return result;
1998     }
1999 private:
2000     /* The subview we are trying to Raise or Lower */
2001     NSView *m_target;
2002     /* A copy of the original array of subviews */
2003     NSArray *m_subviews;
2004 };
2005
2006 /* Causes Cocoa to raise the target view to the top of the Z-Order by telling the sort function that
2007  * the target view is always higher than every other view.  When comparing two views neither of
2008  * which is the target, it returns the correct response based on the original ordering
2009  */
2010 static CocoaWindowCompareFunctionResult CocoaRaiseWindowCompareFunction(id first, id second, void *ctx)
2011 {
2012     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
2013     // first should be ordered higher
2014     if(first==compareContext->target())
2015         return NSOrderedDescending;
2016     // second should be ordered higher
2017     if(second==compareContext->target())
2018         return NSOrderedAscending;
2019     return compareContext->CompareUsingOriginalOrdering(first,second);
2020 }
2021
2022 void wxWidgetCocoaImpl::Raise()
2023 {
2024         NSView* nsview = m_osxView;
2025
2026     NSView *superview = [nsview superview];
2027     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
2028
2029     [superview sortSubviewsUsingFunction:
2030          CocoaRaiseWindowCompareFunction
2031                                                                  context: &compareContext];
2032
2033 }
2034
2035 /* Causes Cocoa to lower the target view to the bottom of the Z-Order by telling the sort function that
2036  * the target view is always lower than every other view.  When comparing two views neither of
2037  * which is the target, it returns the correct response based on the original ordering
2038  */
2039 static CocoaWindowCompareFunctionResult CocoaLowerWindowCompareFunction(id first, id second, void *ctx)
2040 {
2041     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
2042     // first should be ordered lower
2043     if(first==compareContext->target())
2044         return NSOrderedAscending;
2045     // second should be ordered lower
2046     if(second==compareContext->target())
2047         return NSOrderedDescending;
2048     return compareContext->CompareUsingOriginalOrdering(first,second);
2049 }
2050
2051 void wxWidgetCocoaImpl::Lower()
2052 {
2053         NSView* nsview = m_osxView;
2054
2055     NSView *superview = [nsview superview];
2056     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
2057
2058     [superview sortSubviewsUsingFunction:
2059          CocoaLowerWindowCompareFunction
2060                                                                  context: &compareContext];
2061 }
2062
2063 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
2064 {
2065 #if 1
2066     SetNeedsDisplay() ;
2067 #else
2068     // We should do something like this, but it wasn't working in 10.4.
2069     if (GetNeedsDisplay() )
2070     {
2071         SetNeedsDisplay() ;
2072     }
2073     NSRect r = wxToNSRect( [m_osxView superview], *rect );
2074     NSSize offset = NSMakeSize((float)dx, (float)dy);
2075     [m_osxView scrollRect:r by:offset];
2076 #endif
2077 }
2078
2079 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
2080 {
2081     wxWindowMac* parent = GetWXPeer()->GetParent();
2082     // under Cocoa we might have a contentView in the wxParent to which we have to
2083     // adjust the coordinates
2084     if (parent && [m_osxView superview] != parent->GetHandle() )
2085     {
2086         int cx = 0,cy = 0,cw = 0,ch = 0;
2087         if ( parent->GetPeer() )
2088         {
2089             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2090             x -= cx;
2091             y -= cy;
2092         }
2093     }
2094     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
2095     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
2096     [m_osxView setFrame:r];
2097     [[m_osxView superview] setNeedsDisplayInRect:r];
2098 }
2099
2100 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
2101 {
2102     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
2103     x = r.GetLeft();
2104     y = r.GetTop();
2105
2106     // under Cocoa we might have a contentView in the wxParent to which we have to
2107     // adjust the coordinates
2108     wxWindowMac* parent = GetWXPeer()->GetParent();
2109     if (parent && [m_osxView superview] != parent->GetHandle() )
2110     {
2111         int cx = 0,cy = 0,cw = 0,ch = 0;
2112         if ( parent->GetPeer() )
2113         {
2114             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2115             x += cx;
2116             y += cy;
2117         }
2118     }
2119 }
2120
2121 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
2122 {
2123     NSRect rect = [m_osxView frame];
2124     width = (int)rect.size.width;
2125     height = (int)rect.size.height;
2126 }
2127
2128 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
2129 {
2130     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
2131     {
2132         NSView* cv = [m_osxView contentView];
2133
2134         NSRect bounds = [m_osxView bounds];
2135         NSRect rect = [cv frame];
2136
2137         int y = (int)rect.origin.y;
2138         int x = (int)rect.origin.x;
2139         if ( ![ m_osxView isFlipped ] )
2140             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
2141         left = x;
2142         top = y;
2143         width = (int)rect.size.width;
2144         height = (int)rect.size.height;
2145     }
2146     else
2147     {
2148         left = top = 0;
2149         GetSize( width, height );
2150     }
2151 }
2152
2153 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
2154 {
2155     if ( where )
2156         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
2157     else
2158         [m_osxView setNeedsDisplay:YES];
2159 }
2160
2161 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
2162 {
2163     return [m_osxView needsDisplay];
2164 }
2165
2166 bool wxWidgetCocoaImpl::CanFocus() const
2167 {
2168     return [m_osxView canBecomeKeyView] == YES;
2169 }
2170
2171 bool wxWidgetCocoaImpl::HasFocus() const
2172 {
2173     return ( FindFocus() == m_osxView );
2174 }
2175
2176 bool wxWidgetCocoaImpl::SetFocus()
2177 {
2178     if ( !CanFocus() )
2179         return false;
2180
2181     // TODO remove if no issues arise: should not raise the window, only assign focus
2182     //[[m_osxView window] makeKeyAndOrderFront:nil] ;
2183     [[m_osxView window] makeFirstResponder: m_osxView] ;
2184     return true;
2185 }
2186
2187 void wxWidgetCocoaImpl::SetDropTarget(wxDropTarget* target)
2188 {
2189     [m_osxView unregisterDraggedTypes];
2190
2191     if ( target == NULL )
2192         return;
2193
2194     wxDataObject* dobj = target->GetDataObject();
2195
2196     if( dobj )
2197     {
2198         CFMutableArrayRef typesarray = CFArrayCreateMutable(kCFAllocatorDefault,0,&kCFTypeArrayCallBacks);
2199         dobj->AddSupportedTypes(typesarray);
2200         NSView* targetView = m_osxView;
2201         if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2202             targetView = [(NSScrollView*) m_osxView documentView];
2203
2204         [targetView registerForDraggedTypes:(NSArray*)typesarray];
2205         CFRelease(typesarray);
2206     }
2207 }
2208
2209 void wxWidgetCocoaImpl::RemoveFromParent()
2210 {
2211     [m_osxView removeFromSuperview];
2212 }
2213
2214 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
2215 {
2216     NSView* container = parent->GetWXWidget() ;
2217     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
2218     [container addSubview:m_osxView];
2219
2220     if( m_wxPeer->IsFrozen() )
2221         [[m_osxView window] disableFlushWindow];
2222 }
2223
2224 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
2225 {
2226     NSView* targetView = m_osxView;
2227     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2228         targetView = [(NSScrollView*) m_osxView documentView];
2229
2230     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
2231     {
2232         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2233                                                                 green:(CGFloat) (col.Green() / 255.0)
2234                                                                  blue:(CGFloat) (col.Blue() / 255.0)
2235                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
2236     }
2237 }
2238
2239 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
2240 {
2241     BOOL opaque = ( style == wxBG_STYLE_PAINT );
2242
2243     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
2244     {
2245         [m_osxView setOpaque: opaque];
2246     }
2247
2248     return true ;
2249 }
2250
2251 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
2252 {
2253     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
2254     {
2255         wxCFStringRef cf( title , encoding );
2256         [m_osxView setTitle:cf.AsNSString()];
2257     }
2258     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
2259     {
2260         wxCFStringRef cf( title , encoding );
2261         [m_osxView setStringValue:cf.AsNSString()];
2262     }
2263 }
2264
2265
2266 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
2267 {
2268     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
2269     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
2270     *pt = wxFromNSPoint( to->GetWXWidget(), p );
2271 }
2272
2273 wxInt32 wxWidgetCocoaImpl::GetValue() const
2274 {
2275     return [(NSControl*)m_osxView intValue];
2276 }
2277
2278 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
2279 {
2280     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
2281     {
2282         [m_osxView setIntValue:v];
2283     }
2284     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
2285     {
2286         [m_osxView setFloatValue:(double)v];
2287     }
2288     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
2289     {
2290         [m_osxView setDoubleValue:(double)v];
2291     }
2292 }
2293
2294 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
2295 {
2296     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
2297     {
2298         [m_osxView setMinValue:(double)v];
2299     }
2300 }
2301
2302 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
2303 {
2304     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
2305     {
2306         [m_osxView setMaxValue:(double)v];
2307     }
2308 }
2309
2310 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
2311 {
2312     if (  [m_osxView respondsToSelector:@selector(minValue)] )
2313     {
2314         return (int)[m_osxView minValue];
2315     }
2316     return 0;
2317 }
2318
2319 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
2320 {
2321     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
2322     {
2323         return (int)[m_osxView maxValue];
2324     }
2325     return 0;
2326 }
2327
2328 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
2329 {
2330     wxBitmap bmp;
2331
2332     // TODO: how to create a wxBitmap from NSImage?
2333 #if 0
2334     if ( [m_osxView respondsToSelector:@selector(image:)] )
2335         bmp = [m_osxView image];
2336 #endif
2337
2338     return bmp;
2339 }
2340
2341 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
2342 {
2343     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
2344     {
2345         if (bitmap.IsOk())
2346             [m_osxView setImage:bitmap.GetNSImage()];
2347         else
2348             [m_osxView setImage:nil];
2349
2350         [m_osxView setNeedsDisplay:YES];
2351     }
2352 }
2353
2354 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
2355 {
2356     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
2357     {
2358         NSCellImagePosition pos;
2359         switch ( dir )
2360         {
2361             case wxLEFT:
2362                 pos = NSImageLeft;
2363                 break;
2364
2365             case wxRIGHT:
2366                 pos = NSImageRight;
2367                 break;
2368
2369             case wxTOP:
2370                 pos = NSImageAbove;
2371                 break;
2372
2373             case wxBOTTOM:
2374                 pos = NSImageBelow;
2375                 break;
2376
2377             default:
2378                 wxFAIL_MSG( "invalid image position" );
2379                 pos = NSNoImage;
2380         }
2381
2382         [m_osxView setImagePosition:pos];
2383     }
2384 }
2385
2386 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
2387 {
2388     // implementation in subclass
2389 }
2390
2391 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
2392 {
2393     r->x = r->y = r->width = r->height = 0;
2394
2395     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
2396     {
2397         NSRect former = [m_osxView frame];
2398         [m_osxView sizeToFit];
2399         NSRect best = [m_osxView frame];
2400         [m_osxView setFrame:former];
2401         r->width = (int)best.size.width;
2402         r->height = (int)best.size.height;
2403     }
2404 }
2405
2406 bool wxWidgetCocoaImpl::IsEnabled() const
2407 {
2408     NSView* targetView = m_osxView;
2409     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2410         targetView = [(NSScrollView*) m_osxView documentView];
2411
2412     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
2413         return [targetView isEnabled];
2414     return true;
2415 }
2416
2417 void wxWidgetCocoaImpl::Enable( bool enable )
2418 {
2419     NSView* targetView = m_osxView;
2420     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2421         targetView = [(NSScrollView*) m_osxView documentView];
2422
2423     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
2424         [targetView setEnabled:enable];
2425 }
2426
2427 void wxWidgetCocoaImpl::PulseGauge()
2428 {
2429 }
2430
2431 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
2432 {
2433 }
2434
2435 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
2436 {
2437     NSControlSize size = NSRegularControlSize;
2438
2439     switch ( variant )
2440     {
2441         case wxWINDOW_VARIANT_NORMAL :
2442             size = NSRegularControlSize;
2443             break ;
2444
2445         case wxWINDOW_VARIANT_SMALL :
2446             size = NSSmallControlSize;
2447             break ;
2448
2449         case wxWINDOW_VARIANT_MINI :
2450             size = NSMiniControlSize;
2451             break ;
2452
2453         case wxWINDOW_VARIANT_LARGE :
2454             size = NSRegularControlSize;
2455             break ;
2456
2457         default:
2458             wxFAIL_MSG(wxT("unexpected window variant"));
2459             break ;
2460     }
2461     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2462         [m_osxView setControlSize:size];
2463     else if ([m_osxView respondsToSelector:@selector(cell)])
2464     {
2465         id cell = [(id)m_osxView cell];
2466         if ([cell respondsToSelector:@selector(setControlSize:)])
2467             [cell setControlSize:size];
2468     }
2469
2470     // we need to propagate this to inner views as well
2471     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2472     {
2473         NSView* targetView = [(NSScrollView*) m_osxView documentView];
2474
2475         if ( [targetView respondsToSelector:@selector(setControlSize:)] )
2476             [targetView setControlSize:size];
2477         else if ([targetView respondsToSelector:@selector(cell)])
2478         {
2479             id cell = [(id)targetView cell];
2480             if ([cell respondsToSelector:@selector(setControlSize:)])
2481                 [cell setControlSize:size];
2482         }
2483     }
2484 }
2485
2486 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2487 {
2488     NSView* targetView = m_osxView;
2489     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2490         targetView = [(NSScrollView*) m_osxView documentView];
2491
2492     if ([targetView respondsToSelector:@selector(setFont:)])
2493         [targetView setFont: font.OSXGetNSFont()];
2494     if ([targetView respondsToSelector:@selector(setTextColor:)])
2495         [targetView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2496                                                                  green:(CGFloat) (col.Green() / 255.0)
2497                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2498                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2499 }
2500
2501 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2502 {
2503     if ( tooltip )
2504     {
2505         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2506         [m_osxView setToolTip: cf.AsNSString()];
2507     }
2508     else
2509     {
2510         [m_osxView setToolTip:nil];
2511     }
2512 }
2513
2514 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2515 {
2516     WXWidget c =  control ? control : (WXWidget) m_osxView;
2517     wxWidgetImpl::Associate( c, this ) ;
2518     if ([c respondsToSelector:@selector(setAction:)])
2519     {
2520         [c setTarget: c];
2521         [c setAction: @selector(controlAction:)];
2522         if ([c respondsToSelector:@selector(setDoubleAction:)])
2523         {
2524             [c setDoubleAction: @selector(controlDoubleAction:)];
2525         }
2526
2527     }
2528     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingCursorUpdate|NSTrackingMouseMoved|NSTrackingActiveAlways|NSTrackingInVisibleRect;
2529     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: NSZeroRect options: options owner: m_osxView userInfo: nil];
2530     [m_osxView addTrackingArea: area];
2531     [area release];
2532  }
2533
2534 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2535 {
2536     wxKeyEvent wxevent(wxEVT_CHAR);
2537     SetupKeyEvent( wxevent, event, text );
2538
2539     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2540 }
2541
2542 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2543 {
2544     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2545     SetupKeyEvent( wxevent, event );
2546
2547     // Generate wxEVT_CHAR_HOOK before sending any other events but only when
2548     // the key is pressed, not when it's released (the type of wxevent is
2549     // changed by SetupKeyEvent() so it can be wxEVT_KEY_UP too by now).
2550     if ( wxevent.GetEventType() == wxEVT_KEY_DOWN )
2551     {
2552         wxKeyEvent eventHook(wxEVT_CHAR_HOOK, wxevent);
2553         if ( GetWXPeer()->OSXHandleKeyEvent(eventHook)
2554                 && !eventHook.IsNextEventAllowed() )
2555             return true;
2556     }
2557
2558     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2559
2560     // this will fire higher level events, like insertText, to help
2561     // us handle EVT_CHAR, etc.
2562
2563     if ( !result )
2564     {
2565         if ( [event type] == NSKeyDown)
2566         {
2567             long keycode = wxOSXTranslateCocoaKey( event, wxEVT_CHAR );
2568
2569             if ( (keycode > 0 && keycode < WXK_SPACE) || keycode == WXK_DELETE || keycode >= WXK_START )
2570             {
2571                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2572                 wxKeyEvent wxevent2(wxevent) ;
2573                 wxevent2.SetEventType(wxEVT_CHAR);
2574                 SetupKeyEvent( wxevent2, event );
2575                 wxevent2.m_keyCode = keycode;
2576                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2577             }
2578             else if (wxevent.CmdDown())
2579             {
2580                 wxKeyEvent wxevent2(wxevent) ;
2581                 wxevent2.SetEventType(wxEVT_CHAR);
2582                 SetupKeyEvent( wxevent2, event );
2583                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2584             }
2585             else
2586             {
2587                 if ( IsUserPane() && !wxevent.CmdDown() )
2588                 {
2589                     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2590                         [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2591                     else
2592                         [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2593                     result = true;
2594                 }
2595             }
2596         }
2597     }
2598
2599     return result;
2600 }
2601
2602 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2603 {
2604     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2605     SetupMouseEvent(wxevent , event) ;
2606     bool result = GetWXPeer()->HandleWindowEvent(wxevent);
2607
2608     (void)SetupCursor(event);
2609
2610     return result;
2611 }
2612
2613 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2614 {
2615     wxWindow* thisWindow = GetWXPeer();
2616     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2617     {
2618         thisWindow->MacInvalidateBorders();
2619     }
2620
2621     if ( receivedFocus )
2622     {
2623         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2624         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2625         thisWindow->HandleWindowEvent(eventFocus);
2626
2627 #if wxUSE_CARET
2628         if ( thisWindow->GetCaret() )
2629             thisWindow->GetCaret()->OnSetFocus();
2630 #endif
2631
2632         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2633         event.SetEventObject(thisWindow);
2634         if (otherWindow)
2635             event.SetWindow(otherWindow->GetWXPeer());
2636         thisWindow->HandleWindowEvent(event) ;
2637     }
2638     else // !receivedFocus
2639     {
2640 #if wxUSE_CARET
2641         if ( thisWindow->GetCaret() )
2642             thisWindow->GetCaret()->OnKillFocus();
2643 #endif
2644
2645         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2646
2647         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2648         event.SetEventObject(thisWindow);
2649         if (otherWindow)
2650             event.SetWindow(otherWindow->GetWXPeer());
2651         thisWindow->HandleWindowEvent(event) ;
2652     }
2653 }
2654
2655 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2656 {
2657     if ( !wxIsBusy() )
2658     {
2659         NSPoint location = [NSEvent mouseLocation];
2660         location = [[m_osxView window] convertScreenToBase:location];
2661         NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2662
2663         if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2664         {
2665             [(NSCursor*)cursor.GetHCURSOR() set];
2666         }
2667     }
2668 }
2669
2670 void wxWidgetCocoaImpl::CaptureMouse()
2671 {
2672     // TODO remove if we don't get into problems with cursor settings
2673     //    [[m_osxView window] disableCursorRects];
2674 }
2675
2676 void wxWidgetCocoaImpl::ReleaseMouse()
2677 {
2678     // TODO remove if we don't get into problems with cursor settings
2679     //    [[m_osxView window] enableCursorRects];
2680 }
2681
2682 #if !wxOSX_USE_NATIVE_FLIPPED
2683
2684 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2685 {
2686     m_isFlipped = flipped;
2687 }
2688
2689 #endif
2690
2691 void wxWidgetCocoaImpl::SetDrawingEnabled(bool enabled)
2692 {
2693     if ( enabled )
2694     {
2695         [[m_osxView window] enableFlushWindow];
2696         [m_osxView setNeedsDisplay:YES];
2697     }
2698     else
2699     {
2700         [[m_osxView window] disableFlushWindow];
2701     }
2702 }
2703 //
2704 // Factory methods
2705 //
2706
2707 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2708     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2709     long WXUNUSED(style), long WXUNUSED(extraStyle))
2710 {
2711     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2712     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2713
2714     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v, false, true );
2715     return c;
2716 }
2717
2718 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2719 {
2720     NSWindow* tlw = now->GetWXWindow();
2721
2722     wxWidgetCocoaImpl* c = NULL;
2723     if ( now->IsNativeWindowWrapper() )
2724     {
2725         NSView* cv = [tlw contentView];
2726         c = new wxWidgetCocoaImpl( now, cv, true );
2727         if ( cv != nil )
2728         {
2729             // increase ref count, because the impl destructor will decrement it again
2730             CFRetain(cv);
2731             if ( !now->IsShown() )
2732                 [cv setHidden:NO];
2733         }
2734     }
2735     else
2736     {
2737         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2738         c = new wxWidgetCocoaImpl( now, v, true );
2739         c->InstallEventHandler();
2740         [tlw setContentView:v];
2741     }
2742     return c;
2743 }