src/osx/cocoa/filedlg.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/filedlg.mm
   3 // Purpose:     wxFileDialog for wxCocoa
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2004-10-02
   7 // RCS-ID:      $Id: filedlg.mm 40007 2006-07-05 13:10:46Z SC $
   8 // Copyright:   (c) Ryan Norton
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ============================================================================
  13 // declarations
  14 // ============================================================================
  15
  16 // ----------------------------------------------------------------------------
  17 // headers
  18 // ----------------------------------------------------------------------------
  19
  20 // For compilers that support precompilation, includes "wx.h".
  21 #include "wx/wxprec.h"
  22
  23 #if wxUSE_FILEDLG
  24
  25 #include "wx/filedlg.h"
  26
  27 #ifndef WX_PRECOMP
  28     #include "wx/msgdlg.h"
  29     #include "wx/app.h"
  30 #endif
  31
  32 #include "wx/filename.h"
  33 #include "wx/tokenzr.h"
  34
  35 #include "wx/osx/private.h"
  36
  37 // ============================================================================
  38 // implementation
  39 // ============================================================================
  40
  41 // Open Items:
  42 // - support for old style MacOS creator / type combos
  43 // - parameter support for descending into packages as directories (setTreatsFilePackagesAsDirectories)
  44
  45 IMPLEMENT_CLASS(wxFileDialog, wxFileDialogBase)
  46
  47 wxFileDialog::wxFileDialog(
  48     wxWindow *parent, const wxString& message,
  49     const wxString& defaultDir, const wxString& defaultFileName, const wxString& wildCard,
  50     long style, const wxPoint& pos, const wxSize& sz, const wxString& name)
  51     : wxFileDialogBase(parent, message, defaultDir, defaultFileName, wildCard, style, pos, sz, name)
  52 {
  53 }
  54
  55 NSArray* GetTypesFromFilter( const wxString filter )
  56 {
  57     NSMutableArray* types = nil;
  58     if ( !filter.empty() )
  59     {
  60         wxArrayString names ;
  61         wxArrayString extensions;
  62
  63         wxString filter2(filter) ;
  64         int filterIndex = 0;
  65         bool isName = true ;
  66         wxString current ;
  67
  68         for ( unsigned int i = 0; i < filter2.length() ; i++ )
  69         {
  70             if ( filter2.GetChar(i) == wxT('|') )
  71             {
  72                 if ( isName )
  73                 {
  74                     names.Add( current ) ;
  75                 }
  76                 else
  77                 {
  78                     extensions.Add( current ) ;
  79                     ++filterIndex ;
  80                 }
  81
  82                 isName = !isName ;
  83                 current = wxEmptyString ;
  84             }
  85             else
  86             {
  87                 current += filter2.GetChar(i) ;
  88             }
  89         }
  90         // we allow for compatibility reason to have a single filter expression (like *.*) without
  91         // an explanatory text, in that case the first part is name and extension at the same time
  92
  93         wxASSERT_MSG( filterIndex == 0 || !isName , wxT("incorrect format of format string") ) ;
  94         if ( current.empty() )
  95             extensions.Add( names[filterIndex] ) ;
  96         else
  97             extensions.Add( current ) ;
  98         if ( filterIndex == 0 || isName )
  99             names.Add( current ) ;
 100
 101         ++filterIndex ;
 102
 103         const size_t extCount = extensions.GetCount();
 104         for ( size_t i = 0 ; i < extCount; i++ )
 105         {
 106             wxString extensiongroup = extensions[i];
 107             wxStringTokenizer tokenizer( extensiongroup , wxT(";") ) ;
 108             while ( tokenizer.HasMoreTokens() )
 109             {
 110                 wxString extension = tokenizer.GetNextToken() ;
 111                 // Remove leading '*'
 112                 if (extension.length() && (extension.GetChar(0) == '*'))
 113                     extension = extension.Mid( 1 );
 114
 115                 // Remove leading '.'
 116                 if (extension.length() && (extension.GetChar(0) == '.'))
 117                     extension = extension.Mid( 1 );
 118
 119                 if ( extension.IsEmpty() )
 120                 {
 121                     if ( types != nil )
 122                         [types release];
 123                     return nil;
 124                 }
 125
 126                 if ( types == nil )
 127                     types = [[NSMutableArray alloc] init];
 128
 129                 wxCFStringRef cfext(extension);
 130                 [types addObject: (NSString*)cfext.AsNSString()  ];
 131 #if 0
 132                 // add support for classic fileType / creator here
 133                 wxUint32 fileType, creator;
 134                 // extension -> mactypes
 135 #endif
 136             }
 137
 138         }
 139     }
 140     return types;
 141 }
 142
 143 int wxFileDialog::ShowModal()
 144 {
 145     int result = wxID_CANCEL;
 146
 147     NSSavePanel *panel = nil;
 148
 149     wxCFStringRef cf( m_message );
 150
 151     wxCFStringRef dir( m_dir );
 152     wxCFStringRef file( m_fileName );
 153
 154     m_path = wxEmptyString;
 155     m_fileNames.Clear();
 156
 157     wxNonOwnedWindow* parentWindow = NULL;
 158     int returnCode = -1;
 159
 160     if (GetParent())
 161     {
 162         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 163     }
 164
 165     if (HasFlag(wxFD_SAVE))
 166     {
 167         NSSavePanel* sPanel = [NSSavePanel savePanel];
 168         // makes things more convenient:
 169         [sPanel setCanCreateDirectories:YES];
 170         [sPanel setMessage:cf.AsNSString()];
 171         // if we should be able to descend into pacakges we must somehow
 172         // be able to pass this in
 173         [sPanel setTreatsFilePackagesAsDirectories:NO];
 174         [sPanel setCanSelectHiddenExtension:YES];
 175
 176         if ( HasFlag(wxFD_OVERWRITE_PROMPT) )
 177         {
 178         }
 179
 180 /*
 181         if (parentWindow)
 182         {
 183             NSWindow* nativeParent = parentWindow->GetWXWindow();
 184             ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 185             [sPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 186                 modalForWindow: nativeParent modalDelegate: sheetDelegate
 187                 didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 188                 contextInfo: nil];
 189             [sheetDelegate waitForSheetToFinish];
 190             returnCode = [sheetDelegate code];
 191             [sheetDelegate release];
 192         }
 193         else
 194 */
 195         {
 196             returnCode = [sPanel runModalForDirectory:dir.AsNSString() file:file.AsNSString() ];
 197         }
 198
 199         if (returnCode == NSOKButton )
 200         {
 201             panel = sPanel;
 202             result = wxID_OK;
 203
 204             wxCFStringRef filename( [[sPanel filename] retain] );
 205
 206             m_path = filename.AsString();
 207             m_fileName = wxFileNameFromPath(m_path);
 208             m_dir = wxPathOnly( m_path );
 209         }
 210     }
 211     else
 212     {
 213         NSArray* types = GetTypesFromFilter( m_wildCard ) ;
 214         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 215         [oPanel setTreatsFilePackagesAsDirectories:NO];
 216         [oPanel setCanChooseDirectories:NO];
 217         [oPanel setResolvesAliases:YES];
 218         [oPanel setCanChooseFiles:YES];
 219         [oPanel setMessage:cf.AsNSString()];
 220
 221 /*
 222         if (parentWindow)
 223         {
 224             NSWindow* nativeParent = parentWindow->GetWXWindow();
 225             ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 226             [oPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 227                 types: types modalForWindow: nativeParent
 228                 modalDelegate: sheetDelegate
 229                 didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 230                 contextInfo: nil];
 231             [sheetDelegate waitForSheetToFinish];
 232             returnCode = [sheetDelegate code];
 233             [sheetDelegate release];
 234         }
 235         else
 236 */
 237         {
 238             returnCode = [oPanel runModalForDirectory:dir.AsNSString()
 239                         file:file.AsNSString() types:types];
 240         }
 241         if (returnCode == NSOKButton )
 242         {
 243             panel = oPanel;
 244             result = wxID_OK;
 245             NSArray* filenames = [oPanel filenames];
 246             for ( size_t i = 0 ; i < [filenames count] ; ++ i )
 247             {
 248                 wxCFStringRef filename( [(NSString*) [filenames objectAtIndex:i] retain] );
 249                 wxString fnstr = filename.AsString();
 250                 m_paths.Add( fnstr );
 251                 m_fileNames.Add( wxFileNameFromPath(fnstr) );
 252                 if ( i == 0 )
 253                 {
 254                     m_path = fnstr;
 255                     m_fileName = wxFileNameFromPath(fnstr);
 256                     m_dir = wxPathOnly( fnstr );
 257                 }
 258             }
 259         }
 260         if ( types != nil )
 261             [types release];
 262     }
 263
 264     return result;
 265 }
 266
 267 #endif // wxUSE_FILEDLG