src/cocoa/button.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/button.mm
   3 // Purpose:     wxButton
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2002/12/30
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) 2002 David Elliott
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #include "wx/button.h"
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/log.h"
  18 #endif
  19
  20 #include "wx/stockitem.h"
  21 #include "wx/cocoa/autorelease.h"
  22 #include "wx/cocoa/string.h"
  23
  24 #import <AppKit/NSButton.h>
  25 #import <math.h>
  26
  27 IMPLEMENT_DYNAMIC_CLASS(wxButton, wxControl)
  28 BEGIN_EVENT_TABLE(wxButton, wxButtonBase)
  29 END_EVENT_TABLE()
  30 WX_IMPLEMENT_COCOA_OWNER(wxButton,NSButton,NSControl,NSView)
  31
  32 bool wxButton::Create(wxWindow *parent, wxWindowID winid,
  33             const wxString& lbl, const wxPoint& pos,
  34             const wxSize& size, long style,
  35             const wxValidator& validator, const wxString& name)
  36 {
  37     wxString label((lbl.empty() && wxIsStockID(winid))?wxGetStockLabel(winid):lbl);
  38
  39     wxAutoNSAutoreleasePool pool;
  40     wxLogTrace(wxTRACE_COCOA,wxT("Creating control with id=%d"),winid);
  41     if(!CreateControl(parent,winid,pos,size,style,validator,name))
  42         return false;
  43     wxLogTrace(wxTRACE_COCOA,wxT("Created control with id=%d"),GetId());
  44     m_cocoaNSView = NULL;
  45     SetNSButton([[NSButton alloc] initWithFrame: MakeDefaultNSRect(size)]);
  46     // NOTE: YES we want to release this (to match the alloc).
  47     // DoAddChild(this) will retain us again since addSubView doesn't.
  48     [m_cocoaNSView release];
  49
  50     [GetNSButton() setBezelStyle:NSRoundedBezelStyle];
  51     CocoaSetLabelForObject(label, GetNSButton());
  52
  53     do
  54     {
  55         NSTextAlignment mode;
  56         if ((style & wxBU_LEFT) && !(style & wxBU_RIGHT))
  57             mode = NSLeftTextAlignment;
  58         else if ((style & wxBU_RIGHT) && !(style & wxBU_LEFT))
  59             mode = NSRightTextAlignment;
  60         else
  61             break;
  62         [GetNSControl() setAlignment:mode];
  63     } while(0);
  64
  65     [GetNSControl() sizeToFit];
  66
  67     if(m_parent)
  68         m_parent->CocoaAddChild(this);
  69     SetInitialFrameRect(pos,size);
  70
  71     return true;
  72 }
  73
  74 wxButton::~wxButton()
  75 {
  76     DisassociateNSButton(GetNSButton());
  77 }
  78
  79 void wxButton::Cocoa_wxNSButtonAction(void)
  80 {
  81     wxLogTrace(wxTRACE_COCOA,wxT("YAY!"));
  82     wxCommandEvent event(wxEVT_COMMAND_BUTTON_CLICKED, GetId());
  83     InitCommandEvent(event); //    event.SetEventObject(this);
  84     Command(event);
  85 }
  86
  87 wxString wxButton::GetLabel() const
  88 {
  89     return wxStringWithNSString([GetNSButton() title]);
  90 }
  91
  92 void wxButton::SetLabel(const wxString& label)
  93 {
  94     CocoaSetLabelForObject(label, GetNSButton());
  95 }
  96
  97 wxSize wxButton::DoGetBestSize() const
  98 {
  99     wxSize size = wxButtonBase::DoGetBestSize();
 100     if(!HasFlag(wxBU_EXACTFIT))
 101     {
 102         if(size.x<68)
 103             size.x = 68;
 104     }
 105     return size;
 106 }
 107
 108 static NSRect MakeNSButtonDefaultRect()
 109 {
 110     // create at (10.0,10.0) with size 20.0x20.0 (just bogus values)
 111     wxObjcAutoRefFromAlloc<NSButton*> defaultButton = [[NSButton alloc]
 112             initWithFrame:NSMakeRect(10.0,10.0,20.0,20.0)];
 113     [static_cast<NSButton*>(defaultButton) setBezelStyle:NSRoundedBezelStyle];
 114     [static_cast<NSButton*>(defaultButton) setTitle:@""];
 115     [static_cast<NSButton*>(defaultButton) sizeToFit];
 116     return [static_cast<NSButton*>(defaultButton) frame];
 117 }
 118
 119 wxSize wxButtonBase::GetDefaultSize()
 120 {
 121     static NSRect cocoaRect = MakeNSButtonDefaultRect();
 122     // Apple HIG says OK/Cancel buttons have default width of 68.
 123     return wxSize(68,(int)ceil(cocoaRect.size.height));
 124 }