src/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/window.mm
   3 // Purpose:     wxWindowCocoa
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2002/12/26
   7 // RCS-ID:      $Id:
   8 // Copyright:   (c) 2002 David Elliott
   9 // Licence:     wxWindows license
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/log.h"
  15     #include "wx/window.h"
  16 #endif //WX_PRECOMP
  17
  18 #include "wx/cocoa/autorelease.h"
  19
  20 #import <AppKit/NSView.h>
  21 #import <AppKit/NSEvent.h>
  22 #import <AppKit/NSScrollView.h>
  23 #import <AppKit/NSColor.h>
  24 #import <AppKit/NSClipView.h>
  25
  26 // Turn this on to paint green over the dummy views for debugging
  27 #undef WXCOCOA_FILL_DUMMY_VIEW
  28
  29 #ifdef WXCOCOA_FILL_DUMMY_VIEW
  30 #import <AppKit/NSBezierPath.h>
  31 #endif //def WXCOCOA_FILL_DUMMY_VIEW
  32
  33 // ========================================================================
  34 // wxWindowCocoaHider
  35 // ========================================================================
  36 class wxWindowCocoaHider: protected wxCocoaNSView
  37 {
  38     DECLARE_NO_COPY_CLASS(wxWindowCocoaHider)
  39 public:
  40     wxWindowCocoaHider(wxWindow *owner);
  41     virtual ~wxWindowCocoaHider();
  42     inline WX_NSView GetNSView() { return m_dummyNSView; }
  43 protected:
  44     wxWindowCocoa *m_owner;
  45     WX_NSView m_dummyNSView;
  46     virtual void Cocoa_FrameChanged(void);
  47 #ifdef WXCOCOA_FILL_DUMMY_VIEW
  48     virtual bool Cocoa_drawRect(const NSRect& rect);
  49 #endif //def WXCOCOA_FILL_DUMMY_VIEW
  50 private:
  51     wxWindowCocoaHider();
  52 };
  53
  54 // ========================================================================
  55 // wxWindowCocoaScroller
  56 // ========================================================================
  57 class wxWindowCocoaScroller: protected wxCocoaNSView
  58 {
  59     DECLARE_NO_COPY_CLASS(wxWindowCocoaScroller)
  60 public:
  61     wxWindowCocoaScroller(wxWindow *owner);
  62     virtual ~wxWindowCocoaScroller();
  63     inline WX_NSScrollView GetNSScrollView() { return m_cocoaNSScrollView; }
  64     void ClientSizeToSize(int &width, int &height);
  65     void DoGetClientSize(int *x, int *y) const;
  66     void Encapsulate();
  67     void Unencapsulate();
  68 protected:
  69     wxWindowCocoa *m_owner;
  70     WX_NSScrollView m_cocoaNSScrollView;
  71     virtual void Cocoa_FrameChanged(void);
  72 private:
  73     wxWindowCocoaScroller();
  74 };
  75
  76 // ========================================================================
  77 // wxDummyNSView
  78 // ========================================================================
  79 @interface wxDummyNSView : NSView
  80 - (NSView *)hitTest:(NSPoint)aPoint;
  81 @end
  82
  83 @implementation wxDummyNSView : NSView
  84 - (NSView *)hitTest:(NSPoint)aPoint
  85 {
  86     return nil;
  87 }
  88
  89 @end
  90
  91 // ========================================================================
  92 // wxWindowCocoaHider
  93 // ========================================================================
  94 wxWindowCocoaHider::wxWindowCocoaHider(wxWindow *owner)
  95 :   m_owner(owner)
  96 {
  97     wxASSERT(owner);
  98     wxASSERT(owner->GetNSViewForHiding());
  99     m_dummyNSView = [[wxDummyNSView alloc]
 100         initWithFrame:[owner->GetNSViewForHiding() frame]];
 101     [m_dummyNSView setAutoresizingMask: [owner->GetNSViewForHiding() autoresizingMask]];
 102     AssociateNSView(m_dummyNSView);
 103 }
 104
 105 wxWindowCocoaHider::~wxWindowCocoaHider()
 106 {
 107     DisassociateNSView(m_dummyNSView);
 108     [m_dummyNSView release];
 109 }
 110
 111 void wxWindowCocoaHider::Cocoa_FrameChanged(void)
 112 {
 113     // Keep the real window in synch with the dummy
 114     wxASSERT(m_dummyNSView);
 115     [m_owner->GetNSViewForHiding() setFrame:[m_dummyNSView frame]];
 116 }
 117
 118 #ifdef WXCOCOA_FILL_DUMMY_VIEW
 119 bool wxWindowCocoaHider::Cocoa_drawRect(const NSRect& rect)
 120 {
 121     NSBezierPath *bezpath = [NSBezierPath bezierPathWithRect:rect];
 122     [[NSColor greenColor] set];
 123     [bezpath stroke];
 124     [bezpath fill];
 125     return true;
 126 }
 127 #endif //def WXCOCOA_FILL_DUMMY_VIEW
 128
 129 // ========================================================================
 130 // wxFlippedNSClipView
 131 // ========================================================================
 132 @interface wxFlippedNSClipView : NSClipView
 133 - (BOOL)isFlipped;
 134 @end
 135
 136 @implementation wxFlippedNSClipView : NSClipView
 137 - (BOOL)isFlipped
 138 {
 139     return YES;
 140 }
 141
 142 @end
 143
 144 // ========================================================================
 145 // wxWindowCocoaScroller
 146 // ========================================================================
 147 wxWindowCocoaScroller::wxWindowCocoaScroller(wxWindow *owner)
 148 :   m_owner(owner)
 149 {
 150     wxASSERT(owner);
 151     wxASSERT(owner->GetNSView());
 152     m_cocoaNSScrollView = [[NSScrollView alloc]
 153         initWithFrame:[owner->GetNSView() frame]];
 154     AssociateNSView(m_cocoaNSScrollView);
 155
 156     /* Replace the default NSClipView with a flipped one.  This ensures
 157        scrolling is "pinned" to the top-left instead of bottom-right. */
 158     NSClipView *flippedClip = [[wxFlippedNSClipView alloc]
 159         initWithFrame: [[m_cocoaNSScrollView contentView] frame]];
 160     [m_cocoaNSScrollView setContentView:flippedClip];
 161     [flippedClip release];
 162
 163     [m_cocoaNSScrollView setBackgroundColor: [NSColor windowBackgroundColor]];
 164     [m_cocoaNSScrollView setHasHorizontalScroller: YES];
 165     [m_cocoaNSScrollView setHasVerticalScroller: YES];
 166     Encapsulate();
 167 }
 168
 169 void wxWindowCocoaScroller::Encapsulate()
 170 {
 171     // Set the scroll view autoresizingMask to match the current NSView
 172     [m_cocoaNSScrollView setAutoresizingMask: [m_owner->GetNSView() autoresizingMask]];
 173     [m_owner->GetNSView() setAutoresizingMask: NSViewNotSizable];
 174     // NOTE: replaceSubView will cause m_cocaNSView to be released
 175     // except when it hasn't been added into an NSView hierarchy in which
 176     // case it doesn't need to be and this should work out to a no-op
 177     m_owner->CocoaReplaceView(m_owner->GetNSView(), m_cocoaNSScrollView);
 178     // The NSView is still retained by owner
 179     [m_cocoaNSScrollView setDocumentView: m_owner->GetNSView()];
 180     // Now it's also retained by the NSScrollView
 181 }
 182
 183 void wxWindowCocoaScroller::Unencapsulate()
 184 {
 185     [m_cocoaNSScrollView setDocumentView: nil];
 186     m_owner->CocoaReplaceView(m_cocoaNSScrollView, m_owner->GetNSView());
 187     if(![[m_owner->GetNSView() superview] isFlipped])
 188         [m_owner->GetNSView() setAutoresizingMask: NSViewMinYMargin];
 189 }
 190
 191 wxWindowCocoaScroller::~wxWindowCocoaScroller()
 192 {
 193     DisassociateNSView(m_cocoaNSScrollView);
 194     [m_cocoaNSScrollView release];
 195 }
 196
 197 void wxWindowCocoaScroller::ClientSizeToSize(int &width, int &height)
 198 {
 199     NSSize frameSize = [NSScrollView
 200         frameSizeForContentSize: NSMakeSize(width,height)
 201         hasHorizontalScroller: [m_cocoaNSScrollView hasHorizontalScroller]
 202         hasVerticalScroller: [m_cocoaNSScrollView hasVerticalScroller]
 203         borderType: [m_cocoaNSScrollView borderType]];
 204     width = (int)frameSize.width;
 205     height = (int)frameSize.height;
 206 }
 207
 208 void wxWindowCocoaScroller::DoGetClientSize(int *x, int *y) const
 209 {
 210     NSSize nssize = [m_cocoaNSScrollView contentSize];
 211     if(x)
 212         *x = (int)nssize.width;
 213     if(y)
 214         *y = (int)nssize.height;
 215 }
 216
 217 void wxWindowCocoaScroller::Cocoa_FrameChanged(void)
 218 {
 219     wxLogTrace(wxTRACE_COCOA,wxT("Cocoa_FrameChanged"));
 220     wxSizeEvent event(m_owner->GetSize(), m_owner->GetId());
 221     event.SetEventObject(m_owner);
 222     m_owner->GetEventHandler()->ProcessEvent(event);
 223 }
 224
 225 // ========================================================================
 226 // wxWindowCocoa
 227 // ========================================================================
 228 // normally the base classes aren't included, but wxWindow is special
 229 #ifdef __WXUNIVERSAL__
 230 IMPLEMENT_ABSTRACT_CLASS(wxWindowCocoa, wxWindowBase)
 231 #else
 232 IMPLEMENT_DYNAMIC_CLASS(wxWindow, wxWindowBase)
 233 #endif
 234
 235 BEGIN_EVENT_TABLE(wxWindowCocoa, wxWindowBase)
 236 END_EVENT_TABLE()
 237
 238 wxWindow *wxWindowCocoa::sm_capturedWindow = NULL;
 239
 240 // Constructor
 241 void wxWindowCocoa::Init()
 242 {
 243     m_cocoaNSView = NULL;
 244     m_cocoaHider = NULL;
 245     m_cocoaScroller = NULL;
 246     m_isBeingDeleted = FALSE;
 247     m_isInPaint = FALSE;
 248     m_shouldBeEnabled = true;
 249 }
 250
 251 // Constructor
 252 bool wxWindow::Create(wxWindow *parent, wxWindowID winid,
 253            const wxPoint& pos,
 254            const wxSize& size,
 255            long style,
 256            const wxString& name)
 257 {
 258     if(!CreateBase(parent,winid,pos,size,style,wxDefaultValidator,name))
 259         return false;
 260
 261     // TODO: create the window
 262     m_cocoaNSView = NULL;
 263     SetNSView([[NSView alloc] initWithFrame: MakeDefaultNSRect(size)]);
 264     [m_cocoaNSView release];
 265
 266     if (m_parent)
 267     {
 268         m_parent->AddChild(this);
 269         m_parent->CocoaAddChild(this);
 270         SetInitialFrameRect(pos,size);
 271     }
 272
 273     return TRUE;
 274 }
 275
 276 // Destructor
 277 wxWindow::~wxWindow()
 278 {
 279     wxAutoNSAutoreleasePool pool;
 280     DestroyChildren();
 281
 282     // Make sure our parent (in the wxWindows sense) is our superview
 283     // before we go removing from it.
 284     if(m_parent && m_parent->GetNSView()==[GetNSViewForSuperview() superview])
 285         CocoaRemoveFromParent();
 286     delete m_cocoaHider;
 287     delete m_cocoaScroller;
 288     SetNSView(NULL);
 289 }
 290
 291 void wxWindowCocoa::CocoaAddChild(wxWindowCocoa *child)
 292 {
 293     NSView *childView = child->GetNSViewForSuperview();
 294
 295     wxASSERT(childView);
 296     [m_cocoaNSView addSubview: childView];
 297     child->m_isShown = !m_cocoaHider;
 298 }
 299
 300 void wxWindowCocoa::CocoaRemoveFromParent(void)
 301 {
 302     [GetNSViewForSuperview() removeFromSuperview];
 303 }
 304
 305 void wxWindowCocoa::SetNSView(WX_NSView cocoaNSView)
 306 {
 307     bool need_debug = cocoaNSView || m_cocoaNSView;
 308     if(need_debug) wxLogTrace(wxTRACE_COCOA_RetainRelease,wxT("wxWindowCocoa=%p::SetNSView [m_cocoaNSView=%p retainCount]=%d"),this,m_cocoaNSView,[m_cocoaNSView retainCount]);
 309     DisassociateNSView(m_cocoaNSView);
 310     [cocoaNSView retain];
 311     [m_cocoaNSView release];
 312     m_cocoaNSView = cocoaNSView;
 313     AssociateNSView(m_cocoaNSView);
 314     if(need_debug) wxLogTrace(wxTRACE_COCOA_RetainRelease,wxT("wxWindowCocoa=%p::SetNSView [cocoaNSView=%p retainCount]=%d"),this,cocoaNSView,[cocoaNSView retainCount]);
 315 }
 316
 317 WX_NSView wxWindowCocoa::GetNSViewForSuperview() const
 318 {
 319     return m_cocoaHider
 320         ?   m_cocoaHider->GetNSView()
 321         :   m_cocoaScroller
 322             ?   m_cocoaScroller->GetNSScrollView()
 323             :   m_cocoaNSView;
 324 }
 325
 326 WX_NSView wxWindowCocoa::GetNSViewForHiding() const
 327 {
 328     return m_cocoaScroller
 329         ?   m_cocoaScroller->GetNSScrollView()
 330         :   m_cocoaNSView;
 331 }
 332
 333 bool wxWindowCocoa::Cocoa_drawRect(const NSRect &rect)
 334 {
 335     wxLogTrace(wxTRACE_COCOA,wxT("Cocoa_drawRect"));
 336     // Recursion can happen if the event loop runs from within the paint
 337     // handler.  For instance, if an assertion dialog is shown.
 338     // FIXME: This seems less than ideal.
 339     if(m_isInPaint)
 340     {
 341         wxLogDebug(wxT("Paint event recursion!"));
 342         return false;
 343     }
 344     //FIXME: should probably turn that rect into the update region
 345     m_isInPaint = TRUE;
 346     wxPaintEvent event(m_windowId);
 347     event.SetEventObject(this);
 348     bool ret = GetEventHandler()->ProcessEvent(event);
 349     m_isInPaint = FALSE;
 350     return ret;
 351 }
 352
 353 void wxWindowCocoa::InitMouseEvent(wxMouseEvent& event, WX_NSEvent cocoaEvent)
 354 {
 355     wxASSERT_MSG([m_cocoaNSView window]==[cocoaEvent window],wxT("Mouse event for different NSWindow"));
 356     NSPoint cocoaPoint = [m_cocoaNSView convertPoint:[(NSEvent*)cocoaEvent locationInWindow] fromView:nil];
 357     NSRect cocoaRect = [m_cocoaNSView frame];
 358     const wxPoint &clientorigin = GetClientAreaOrigin();
 359     event.m_x = (wxCoord)cocoaPoint.x - clientorigin.x;
 360     event.m_y = (wxCoord)(cocoaRect.size.height - cocoaPoint.y) - clientorigin.y;
 361
 362     event.m_shiftDown = [cocoaEvent modifierFlags] & NSShiftKeyMask;
 363     event.m_controlDown = [cocoaEvent modifierFlags] & NSControlKeyMask;
 364     event.m_altDown = [cocoaEvent modifierFlags] & NSAlternateKeyMask;
 365     event.m_metaDown = [cocoaEvent modifierFlags] & NSCommandKeyMask;
 366
 367     // TODO: set timestamp?
 368     event.SetEventObject(this);
 369     event.SetId(GetId());
 370 }
 371
 372 bool wxWindowCocoa::Cocoa_mouseMoved(WX_NSEvent theEvent)
 373 {
 374     wxMouseEvent event(wxEVT_MOTION);
 375     InitMouseEvent(event,theEvent);
 376     wxLogTrace(wxTRACE_COCOA,wxT("Mouse Drag @%d,%d"),event.m_x,event.m_y);
 377     return GetEventHandler()->ProcessEvent(event);
 378 }
 379
 380 bool wxWindowCocoa::Cocoa_mouseEntered(WX_NSEvent theEvent)
 381 {
 382     return false;
 383 }
 384
 385 bool wxWindowCocoa::Cocoa_mouseExited(WX_NSEvent theEvent)
 386 {
 387     return false;
 388 }
 389
 390 bool wxWindowCocoa::Cocoa_mouseDown(WX_NSEvent theEvent)
 391 {
 392     wxMouseEvent event([theEvent clickCount]<2?wxEVT_LEFT_DOWN:wxEVT_LEFT_DCLICK);
 393     InitMouseEvent(event,theEvent);
 394     wxLogTrace(wxTRACE_COCOA,wxT("Mouse Down @%d,%d num clicks=%d"),event.m_x,event.m_y,[theEvent clickCount]);
 395     return GetEventHandler()->ProcessEvent(event);
 396 }
 397
 398 bool wxWindowCocoa::Cocoa_mouseDragged(WX_NSEvent theEvent)
 399 {
 400     wxMouseEvent event(wxEVT_MOTION);
 401     InitMouseEvent(event,theEvent);
 402     event.m_leftDown = true;
 403     wxLogTrace(wxTRACE_COCOA,wxT("Mouse Drag @%d,%d"),event.m_x,event.m_y);
 404     return GetEventHandler()->ProcessEvent(event);
 405 }
 406
 407 bool wxWindowCocoa::Cocoa_mouseUp(WX_NSEvent theEvent)
 408 {
 409     wxMouseEvent event(wxEVT_LEFT_UP);
 410     InitMouseEvent(event,theEvent);
 411     wxLogTrace(wxTRACE_COCOA,wxT("Mouse Up @%d,%d"),event.m_x,event.m_y);
 412     return GetEventHandler()->ProcessEvent(event);
 413 }
 414
 415 bool wxWindowCocoa::Cocoa_rightMouseDown(WX_NSEvent theEvent)
 416 {
 417     wxMouseEvent event([theEvent clickCount]<2?wxEVT_RIGHT_DOWN:wxEVT_RIGHT_DCLICK);
 418     InitMouseEvent(event,theEvent);
 419     wxLogDebug(wxT("Mouse Down @%d,%d num clicks=%d"),event.m_x,event.m_y,[theEvent clickCount]);
 420     return GetEventHandler()->ProcessEvent(event);
 421 }
 422
 423 bool wxWindowCocoa::Cocoa_rightMouseDragged(WX_NSEvent theEvent)
 424 {
 425     wxMouseEvent event(wxEVT_MOTION);
 426     InitMouseEvent(event,theEvent);
 427     event.m_rightDown = true;
 428     wxLogDebug(wxT("Mouse Drag @%d,%d"),event.m_x,event.m_y);
 429     return GetEventHandler()->ProcessEvent(event);
 430 }
 431
 432 bool wxWindowCocoa::Cocoa_rightMouseUp(WX_NSEvent theEvent)
 433 {
 434     wxMouseEvent event(wxEVT_RIGHT_UP);
 435     InitMouseEvent(event,theEvent);
 436     wxLogDebug(wxT("Mouse Up @%d,%d"),event.m_x,event.m_y);
 437     return GetEventHandler()->ProcessEvent(event);
 438 }
 439
 440 bool wxWindowCocoa::Cocoa_otherMouseDown(WX_NSEvent theEvent)
 441 {
 442     return false;
 443 }
 444
 445 bool wxWindowCocoa::Cocoa_otherMouseDragged(WX_NSEvent theEvent)
 446 {
 447     return false;
 448 }
 449
 450 bool wxWindowCocoa::Cocoa_otherMouseUp(WX_NSEvent theEvent)
 451 {
 452     return false;
 453 }
 454
 455 void wxWindowCocoa::Cocoa_FrameChanged(void)
 456 {
 457     wxLogTrace(wxTRACE_COCOA,wxT("Cocoa_FrameChanged"));
 458     wxSizeEvent event(GetSize(), m_windowId);
 459     event.SetEventObject(this);
 460     GetEventHandler()->ProcessEvent(event);
 461 }
 462
 463 bool wxWindow::Close(bool force)
 464 {
 465     // The only reason this function exists is that it is virtual and
 466     // wxTopLevelWindowCocoa will override it.
 467     return wxWindowBase::Close(force);
 468 }
 469
 470 void wxWindow::CocoaReplaceView(WX_NSView oldView, WX_NSView newView)
 471 {
 472     [[oldView superview] replaceSubview:oldView with:newView];
 473 }
 474
 475 bool wxWindow::EnableSelfAndChildren(bool enable)
 476 {
 477     // If the state isn't changing, don't do anything
 478     if(!wxWindowBase::Enable(enable && m_shouldBeEnabled))
 479         return false;
 480     // Set the state of the Cocoa window
 481     CocoaSetEnabled(m_isEnabled);
 482     // Disable all children or (if enabling) return them to their proper state
 483     for(wxWindowList::compatibility_iterator node = GetChildren().GetFirst();
 484         node; node = node->GetNext())
 485     {
 486         node->GetData()->EnableSelfAndChildren(enable);
 487     }
 488     return true;
 489 }
 490
 491 bool wxWindow::Enable(bool enable)
 492 {
 493     // Keep track of what the window SHOULD be doing
 494     m_shouldBeEnabled = enable;
 495     // If the parent is disabled for any reason, then this window will be too.
 496     if(!IsTopLevel() && GetParent())
 497     {
 498         enable = enable && GetParent()->IsEnabled();
 499     }
 500     return EnableSelfAndChildren(enable);
 501 }
 502
 503 bool wxWindow::Show(bool show)
 504 {
 505     wxAutoNSAutoreleasePool pool;
 506     // If the window is marked as visible, then it shouldn't have a dummy view
 507     // If the window is marked hidden, then it should have a dummy view
 508     // wxSpinCtrl (generic) abuses m_isShown, don't use it for any logic
 509 //    wxASSERT_MSG( (m_isShown && !m_dummyNSView) || (!m_isShown && m_dummyNSView),wxT("wxWindow: m_isShown does not agree with m_dummyNSView"));
 510     // Return false if there isn't a window to show or hide
 511     NSView *cocoaView = GetNSViewForHiding();
 512     if(!cocoaView)
 513         return false;
 514     if(show)
 515     {
 516         // If state isn't changing, return false
 517         if(!m_cocoaHider)
 518             return false;
 519         CocoaReplaceView(m_cocoaHider->GetNSView(), cocoaView);
 520         wxASSERT(![m_cocoaHider->GetNSView() superview]);
 521         delete m_cocoaHider;
 522         m_cocoaHider = NULL;
 523         wxASSERT([cocoaView superview]);
 524     }
 525     else
 526     {
 527         // If state isn't changing, return false
 528         if(m_cocoaHider)
 529             return false;
 530         m_cocoaHider = new wxWindowCocoaHider(this);
 531         // NOTE: replaceSubview:with will cause m_cocaNSView to be
 532         // (auto)released which balances out addSubview
 533         CocoaReplaceView(cocoaView, m_cocoaHider->GetNSView());
 534         // m_coocaNSView is now only retained by us
 535         wxASSERT([m_cocoaHider->GetNSView() superview]);
 536         wxASSERT(![cocoaView superview]);
 537     }
 538     m_isShown = show;
 539     return true;
 540 }
 541
 542 void wxWindowCocoa::DoSetSize(int x, int y, int width, int height, int sizeFlags)
 543 {
 544     wxLogTrace(wxTRACE_COCOA_Window_Size,"wxWindow=%p::DoSetSizeWindow(%d,%d,%d,%d,Auto: %s%s)",this,x,y,width,height,(sizeFlags&wxSIZE_AUTO_WIDTH)?"W":".",sizeFlags&wxSIZE_AUTO_HEIGHT?"H":".");
 545     int currentX, currentY;
 546     int currentW, currentH;
 547     DoGetPosition(&currentX, &currentY);
 548     DoGetSize(&currentW, &currentH);
 549     if((x==-1) && !(sizeFlags&wxSIZE_ALLOW_MINUS_ONE))
 550         x=currentX;
 551     if((y==-1) && !(sizeFlags&wxSIZE_ALLOW_MINUS_ONE))
 552         y=currentY;
 553
 554     AdjustForParentClientOrigin(x,y,sizeFlags);
 555
 556     wxSize size(-1,-1);
 557
 558     if((width==-1)&&!(sizeFlags&wxSIZE_ALLOW_MINUS_ONE))
 559     {
 560         if(sizeFlags&wxSIZE_AUTO_WIDTH)
 561         {
 562             size=DoGetBestSize();
 563             width=size.x;
 564         }
 565         else
 566             width=currentW;
 567     }
 568     if((height==-1)&&!(sizeFlags&wxSIZE_ALLOW_MINUS_ONE))
 569     {
 570         if(sizeFlags&wxSIZE_AUTO_HEIGHT)
 571         {
 572             if(size.x==-1)
 573                 size=DoGetBestSize();
 574             height=size.y;
 575         }
 576         else
 577             height=currentH;
 578     }
 579     DoMoveWindow(x,y,width,height);
 580 }
 581
 582 void wxWindowCocoa::DoMoveWindow(int x, int y, int width, int height)
 583 {
 584     wxAutoNSAutoreleasePool pool;
 585     wxLogTrace(wxTRACE_COCOA_Window_Size,"wxWindow=%p::DoMoveWindow(%d,%d,%d,%d)",this,x,y,width,height);
 586
 587     NSView *nsview = GetNSViewForSuperview();
 588     NSView *superview = [nsview superview];
 589     wxCHECK_RET(superview,wxT("NSView does not have a superview"));
 590     NSRect parentRect = [superview bounds];
 591
 592     NSRect cocoaRect = NSMakeRect(x,parentRect.size.height-(y+height),width,height);
 593     [nsview setFrame: cocoaRect];
 594     // Be sure to redraw the parent to reflect the changed position
 595     [superview setNeedsDisplay:YES];
 596 }
 597
 598 void wxWindowCocoa::SetInitialFrameRect(const wxPoint& pos, const wxSize& size)
 599 {
 600     NSView *nsview = GetNSViewForSuperview();
 601     NSView *superview = [nsview superview];
 602     wxCHECK_RET(superview,wxT("NSView does not have a superview"));
 603     NSRect parentRect = [superview bounds];
 604     NSRect frameRect = [nsview frame];
 605     if(size.x!=-1)
 606         frameRect.size.width = size.x;
 607     if(size.y!=-1)
 608         frameRect.size.height = size.y;
 609     frameRect.origin.x = pos.x;
 610     frameRect.origin.y = parentRect.size.height-(pos.y+frameRect.size.height);
 611     // Tell Cocoa to change the margin between the bottom of the superview
 612     // and the bottom of the control.  Keeps the control pinned to the top
 613     // of its superview so that its position in the wxWindows coordinate
 614     // system doesn't change.
 615     if(![superview isFlipped])
 616         [nsview setAutoresizingMask: NSViewMinYMargin];
 617     // MUST set the mask before setFrame: which can generate a size event
 618     // and cause a scroller to be added!
 619     [nsview setFrame: frameRect];
 620 }
 621
 622 // Get total size
 623 void wxWindow::DoGetSize(int *w, int *h) const
 624 {
 625     NSRect cocoaRect = [GetNSViewForSuperview() frame];
 626     if(w)
 627         *w=(int)cocoaRect.size.width;
 628     if(h)
 629         *h=(int)cocoaRect.size.height;
 630     wxLogTrace(wxTRACE_COCOA_Window_Size,"wxWindow=%p::DoGetSize = (%d,%d)",this,(int)cocoaRect.size.width,(int)cocoaRect.size.height);
 631 }
 632
 633 void wxWindow::DoGetPosition(int *x, int *y) const
 634 {
 635     NSView *nsview = GetNSViewForSuperview();
 636     NSView *superview = [nsview superview];
 637     wxCHECK_RET(superview,wxT("NSView does not have a superview"));
 638     NSRect parentRect = [superview bounds];
 639
 640     NSRect cocoaRect = [nsview frame];
 641     if(x)
 642         *x=(int)cocoaRect.origin.x;
 643     if(y)
 644         *y=(int)(parentRect.size.height-(cocoaRect.origin.y+cocoaRect.size.height));
 645     wxLogTrace(wxTRACE_COCOA_Window_Size,"wxWindow=%p::DoGetPosition = (%d,%d)",this,(int)cocoaRect.origin.x,(int)cocoaRect.origin.y);
 646 }
 647
 648 WXWidget wxWindow::GetHandle() const
 649 {
 650     return m_cocoaNSView;
 651 }
 652
 653 void wxWindow::Refresh(bool eraseBack, const wxRect *rect)
 654 {
 655     [m_cocoaNSView setNeedsDisplay:YES];
 656 }
 657
 658 void wxWindow::SetFocus()
 659 {
 660     // TODO
 661 }
 662
 663 void wxWindow::DoCaptureMouse()
 664 {
 665     // TODO
 666     sm_capturedWindow = this;
 667 }
 668
 669 void wxWindow::DoReleaseMouse()
 670 {
 671     // TODO
 672     sm_capturedWindow = NULL;
 673 }
 674
 675 void wxWindow::DoScreenToClient(int *x, int *y) const
 676 {
 677     // TODO
 678 }
 679
 680 void wxWindow::DoClientToScreen(int *x, int *y) const
 681 {
 682     // TODO
 683 }
 684
 685 // Get size *available for subwindows* i.e. excluding menu bar etc.
 686 void wxWindow::DoGetClientSize(int *x, int *y) const
 687 {
 688     wxLogTrace(wxTRACE_COCOA,wxT("DoGetClientSize:"));
 689     if(m_cocoaScroller)
 690         m_cocoaScroller->DoGetClientSize(x,y);
 691     else
 692         wxWindowCocoa::DoGetSize(x,y);
 693 }
 694
 695 void wxWindow::DoSetClientSize(int width, int height)
 696 {
 697     wxLogTrace(wxTRACE_COCOA_Window_Size,wxT("DoSetClientSize=(%d,%d)"),width,height);
 698     if(m_cocoaScroller)
 699         m_cocoaScroller->ClientSizeToSize(width,height);
 700     CocoaSetWxWindowSize(width,height);
 701 }
 702
 703 void wxWindow::CocoaSetWxWindowSize(int width, int height)
 704 {
 705     wxWindowCocoa::DoSetSize(-1,-1,width,height,wxSIZE_USE_EXISTING);
 706 }
 707
 708 int wxWindow::GetCharHeight() const
 709 {
 710     // TODO
 711     return 0;
 712 }
 713
 714 int wxWindow::GetCharWidth() const
 715 {
 716     // TODO
 717     return 0;
 718 }
 719
 720 void wxWindow::GetTextExtent(const wxString& string, int *x, int *y,
 721         int *descent, int *externalLeading, const wxFont *theFont) const
 722 {
 723     // TODO
 724 }
 725
 726 // Coordinates relative to the window
 727 void wxWindow::WarpPointer (int x_pos, int y_pos)
 728 {
 729     // TODO
 730 }
 731
 732 int wxWindow::GetScrollPos(int orient) const
 733 {
 734     // TODO
 735     return 0;
 736 }
 737
 738 // This now returns the whole range, not just the number
 739 // of positions that we can scroll.
 740 int wxWindow::GetScrollRange(int orient) const
 741 {
 742     // TODO
 743     return 0;
 744 }
 745
 746 int wxWindow::GetScrollThumb(int orient) const
 747 {
 748     // TODO
 749     return 0;
 750 }
 751
 752 void wxWindow::SetScrollPos(int orient, int pos, bool refresh)
 753 {
 754     // TODO
 755 }
 756
 757 void wxWindow::CocoaCreateNSScrollView()
 758 {
 759     if(!m_cocoaScroller)
 760     {
 761         m_cocoaScroller = new wxWindowCocoaScroller(this);
 762     }
 763 }
 764
 765 // New function that will replace some of the above.
 766 void wxWindow::SetScrollbar(int orient, int pos, int thumbVisible,
 767     int range, bool refresh)
 768 {
 769     CocoaCreateNSScrollView();
 770     // TODO
 771 }
 772
 773 // Does a physical scroll
 774 void wxWindow::ScrollWindow(int dx, int dy, const wxRect *rect)
 775 {
 776     // TODO
 777 }
 778
 779 void wxWindow::DoSetVirtualSize( int x, int y )
 780 {
 781     wxWindowBase::DoSetVirtualSize(x,y);
 782     CocoaCreateNSScrollView();
 783     [m_cocoaNSView setFrameSize:NSMakeSize(m_virtualSize.x,m_virtualSize.y)];
 784 }
 785
 786 bool wxWindow::SetFont(const wxFont& font)
 787 {
 788     // TODO
 789     return TRUE;
 790 }
 791
 792 static int CocoaRaiseWindowCompareFunction(id first, id second, void *target)
 793 {
 794     // first should be ordered higher
 795     if(first==target)
 796         return NSOrderedDescending;
 797     // second should be ordered higher
 798     if(second==target)
 799         return NSOrderedAscending;
 800     return NSOrderedSame;
 801 }
 802
 803 // Raise the window to the top of the Z order
 804 void wxWindow::Raise()
 805 {
 806 //    wxAutoNSAutoreleasePool pool;
 807     NSView *nsview = GetNSViewForSuperview();
 808     [[nsview superview] sortSubviewsUsingFunction:
 809             CocoaRaiseWindowCompareFunction
 810         context: nsview];
 811 }
 812
 813 static int CocoaLowerWindowCompareFunction(id first, id second, void *target)
 814 {
 815     // first should be ordered lower
 816     if(first==target)
 817         return NSOrderedAscending;
 818     // second should be ordered lower
 819     if(second==target)
 820         return NSOrderedDescending;
 821     return NSOrderedSame;
 822 }
 823
 824 // Lower the window to the bottom of the Z order
 825 void wxWindow::Lower()
 826 {
 827     NSView *nsview = GetNSViewForSuperview();
 828     [[nsview superview] sortSubviewsUsingFunction:
 829             CocoaLowerWindowCompareFunction
 830         context: nsview];
 831 }
 832
 833 bool wxWindow::DoPopupMenu(wxMenu *menu, int x, int y)
 834 {
 835     return FALSE;
 836 }
 837
 838 // Get the window with the focus
 839 wxWindow *wxWindowBase::FindFocus()
 840 {
 841     // TODO
 842     return NULL;
 843 }
 844
 845 /* static */ wxWindow *wxWindowBase::GetCapture()
 846 {
 847     // TODO
 848     return wxWindowCocoa::sm_capturedWindow;
 849 }
 850
 851 wxWindow *wxGetActiveWindow()
 852 {
 853     // TODO
 854     return NULL;
 855 }
 856
 857 wxPoint wxGetMousePosition()
 858 {
 859     // TODO
 860     return wxDefaultPosition;
 861 }
 862
 863 wxWindow* wxFindWindowAtPointer(wxPoint& pt)
 864 {
 865     pt = wxGetMousePosition();
 866     return NULL;
 867 }
 868