acinclude.m4

   1 dnl ---------------------------------------------------------------------------
   2 dnl
   3 dnl Macros for configure.in for wxWindows by Robert Roebling, Phil Blecker,
   4 dnl Vadim Zeitlin and Ron Lee
   5 dnl
   6 dnl This script is under the wxWindows licence.
   7 dnl
   8 dnl Version: $Id$
   9 dnl ---------------------------------------------------------------------------
  10
  11
  12 dnl ===========================================================================
  13 dnl Objective-C(++) related macros
  14 dnl ===========================================================================
  15 m4_define([AC_WX_LANG_OBJECTIVEC],
  16 [AC_LANG(C)
  17 ac_ext=m
  18 ])
  19
  20 m4_define([AC_WX_LANG_OBJECTIVECPLUSPLUS],
  21 [AC_LANG(C++)
  22 ac_ext=mm
  23 ])
  24
  25 dnl ===========================================================================
  26 dnl macros to find the a file in the list of include/lib paths
  27 dnl ===========================================================================
  28
  29 dnl ---------------------------------------------------------------------------
  30 dnl call WX_PATH_FIND_INCLUDES(search path, header name), sets ac_find_includes
  31 dnl to the full name of the file that was found or leaves it empty if not found
  32 dnl ---------------------------------------------------------------------------
  33 AC_DEFUN([WX_PATH_FIND_INCLUDES],
  34 [
  35 ac_find_includes=
  36 for ac_dir in $1 /usr/include;
  37   do
  38     if test -f "$ac_dir/$2"; then
  39       ac_find_includes=$ac_dir
  40       break
  41     fi
  42   done
  43 ])
  44
  45 dnl ---------------------------------------------------------------------------
  46 dnl call WX_PATH_FIND_LIBRARIES(search path, lib name), sets ac_find_libraries
  47 dnl to the full name of the file that was found or leaves it empty if not found
  48 dnl ---------------------------------------------------------------------------
  49 AC_DEFUN([WX_PATH_FIND_LIBRARIES],
  50 [
  51   ac_find_libraries=
  52   for ac_dir in $1;
  53   do
  54     for ac_extension in a so sl dylib dll.a; do
  55       if test -f "$ac_dir/lib$2.$ac_extension"; then
  56         ac_find_libraries=$ac_dir
  57         break 2
  58       fi
  59     done
  60   done
  61 ])
  62
  63 dnl ---------------------------------------------------------------------------
  64 dnl return list of standard library paths
  65 dnl ---------------------------------------------------------------------------
  66 dnl return all default locations:
  67 dnl   - /usr/lib: standard
  68 dnl   - /usr/lib32: n32 ABI on IRIX
  69 dnl   - /usr/lib64: n64 ABI on IRIX
  70 dnl   - /usr/lib/64: 64 bit ABI on Solaris and Linux x86-64
  71 dnl
  72 dnl NB: if any of directories in the list is not a subdir of /usr, code setting
  73 dnl     wx_cv_std_libpath needs to be updated
  74 AC_DEFUN([WX_STD_LIBPATH], [/usr/lib /usr/lib32 /usr/lib/64 /usr/lib64])
  75
  76 dnl ---------------------------------------------------------------------------
  77 dnl Path to include, already defined
  78 dnl ---------------------------------------------------------------------------
  79 AC_DEFUN([WX_INCLUDE_PATH_EXIST],
  80 [
  81   dnl never add -I/usr/include to the CPPFLAGS
  82   if test "x$1" = "x/usr/include"; then
  83     ac_path_to_include=""
  84   else
  85     echo "$2" | grep "\-I$1" > /dev/null
  86     result=$?
  87     if test $result = 0; then
  88       ac_path_to_include=""
  89     else
  90       ac_path_to_include=" -I$1"
  91     fi
  92   fi
  93 ])
  94
  95 dnl ---------------------------------------------------------------------------
  96 dnl Usage: WX_LINK_PATH_EXIST(path, libpath)
  97 dnl
  98 dnl Set ac_path_to_link to nothing if path is already in libpath of to -Lpath
  99 dnl if it is not, so that libpath can be set to "$libpath$ac_path_to_link"
 100 dnl after calling this function
 101 dnl ---------------------------------------------------------------------------
 102 AC_DEFUN([WX_LINK_PATH_EXIST],
 103 [
 104   dnl never add -L/usr/libXXX explicitely to libpath
 105   if test "$1" = "default location"; then
 106     ac_path_to_link=""
 107   else
 108     echo "$2" | grep "\-L$1" > /dev/null
 109     result=$?
 110     if test $result = 0; then
 111       ac_path_to_link=""
 112     else
 113       ac_path_to_link=" -L$1"
 114     fi
 115   fi
 116 ])
 117
 118 dnl ===========================================================================
 119 dnl C++ features test
 120 dnl ===========================================================================
 121
 122 dnl ---------------------------------------------------------------------------
 123 dnl WX_CPP_NEW_HEADERS checks whether the compiler has "new" <iostream> header
 124 dnl or only the old <iostream.h> one - it may be generally assumed that if
 125 dnl <iostream> exists, the other "new" headers (without .h) exist too.
 126 dnl
 127 dnl call WX_CPP_NEW_HEADERS(actiof-if-true, action-if-false)
 128 dnl ---------------------------------------------------------------------------
 129
 130 AC_DEFUN([WX_CPP_NEW_HEADERS],
 131 [
 132     AC_LANG_SAVE
 133     AC_LANG_CPLUSPLUS
 134
 135     AC_CHECK_HEADERS([iostream],,, [ ])
 136
 137     if test "$ac_cv_header_iostream" = "yes" ; then
 138       ifelse([$1], , :, [$1])
 139     else
 140       ifelse([$2], , :, [$2])
 141     fi
 142
 143     AC_LANG_RESTORE
 144 ])
 145
 146 dnl ---------------------------------------------------------------------------
 147 dnl WX_CPP_BOOL checks whether the C++ compiler has a built in bool type
 148 dnl
 149 dnl call WX_CPP_BOOL - will define HAVE_BOOL if the compiler supports bool
 150 dnl ---------------------------------------------------------------------------
 151
 152 AC_DEFUN([WX_CPP_BOOL],
 153 [
 154   AC_CACHE_CHECK([if C++ compiler supports bool], wx_cv_cpp_bool,
 155   [
 156     AC_LANG_SAVE
 157     AC_LANG_CPLUSPLUS
 158
 159     AC_TRY_COMPILE(
 160       [
 161       ],
 162       [
 163         bool b = true;
 164
 165         return 0;
 166       ],
 167       [
 168         wx_cv_cpp_bool=yes
 169       ],
 170       [
 171         wx_cv_cpp_bool=no
 172       ]
 173     )
 174
 175     AC_LANG_RESTORE
 176   ])
 177
 178   if test "$wx_cv_cpp_bool" = "yes"; then
 179     AC_DEFINE(HAVE_BOOL)
 180   fi
 181 ])
 182
 183 dnl ---------------------------------------------------------------------------
 184 dnl WX_CPP_EXPLICIT checks whether the C++ compiler support the explicit
 185 dnl keyword and defines HAVE_EXPLICIT if this is the case
 186 dnl ---------------------------------------------------------------------------
 187
 188 AC_DEFUN([WX_CPP_EXPLICIT],
 189 [
 190   AC_CACHE_CHECK([if C++ compiler supports the explicit keyword],
 191                  wx_cv_explicit,
 192   [
 193     AC_LANG_SAVE
 194     AC_LANG_CPLUSPLUS
 195
 196     dnl do the test in 2 steps: first check that the compiler knows about the
 197     dnl explicit keyword at all and then verify that it really honours it
 198     AC_TRY_COMPILE(
 199       [
 200         class Foo { public: explicit Foo(int) {} };
 201       ],
 202       [
 203         return 0;
 204       ],
 205       [
 206         AC_TRY_COMPILE(
 207             [
 208                 class Foo { public: explicit Foo(int) {} };
 209                 static void TakeFoo(const Foo& foo) { }
 210             ],
 211             [
 212                 TakeFoo(17);
 213                 return 0;
 214             ],
 215             wx_cv_explicit=no,
 216             wx_cv_explicit=yes
 217         )
 218       ],
 219       wx_cv_explicit=no
 220     )
 221
 222     AC_LANG_RESTORE
 223   ])
 224
 225   if test "$wx_cv_explicit" = "yes"; then
 226     AC_DEFINE(HAVE_EXPLICIT)
 227   fi
 228 ])
 229
 230 dnl ---------------------------------------------------------------------------
 231 dnl WX_CHECK_FUNCS(FUNCTIONS...,
 232 dnl                [ACTION-IF-FOUND],
 233 dnl                [ACTION-IF-NOT-FOUND],
 234 dnl                [EXTRA-DEFINES-AND-INCLUDES],
 235 dnl                [EXTRA-TEST-CODE])
 236 dnl
 237 dnl Checks that the functions listed in FUNCTIONS exist in the headers and the
 238 dnl libs. For each function, if it is found then defines 'HAVE_FUNCTION' and
 239 dnl executes ACTION-IF-FOUND, otherwise executes ACTION-IF-NOT-FOUND.
 240 dnl
 241 dnl The code from EXTRA-DEFINES-AND-INCLUDES is inserted into the test before
 242 dnl the default headers are included, and EXTRA-TEST-CODE is inserted into
 243 dnl the main() function after the default test for existence.
 244 dnl
 245 dnl Examples:
 246 dnl   # the simple case
 247 dnl   WX_CHECK_FUNCS(stat)
 248 dnl   # use break to finish the loop early
 249 dnl   WX_CHECK_FUNCS(mkstemp mktemp, break)
 250 dnl   # extra defines
 251 dnl   WX_CHECK_FUNCS(strtok_r, [], [], [#define _RREENTRANT])
 252 dnl   # extra includes
 253 dnl   WX_CHECK_FUNCS(swprintf, [], [], [#include <wchar.h>])
 254 dnl   # checking the signature with extra test code
 255 dnl   WX_CHECK_FUNCS(gettimeofday, [], [], [#include <sys/time.h>]
 256 dnl     [struct timeval tv; struct timezone tz; gettimeofday(&tv, &tz)])
 257 dnl ---------------------------------------------------------------------------
 258
 259 AC_DEFUN([WX_CHECK_FUNCS],
 260 [
 261   for wx_func in $1
 262   do
 263     AC_CACHE_CHECK(
 264       [for $wx_func],
 265       [wx_cv_func_$wx_func],
 266       [
 267         AC_LINK_IFELSE(
 268           [
 269             AC_LANG_PROGRAM(
 270               [
 271                 $4
 272                 AC_INCLUDES_DEFAULT
 273               ],
 274               [
 275                 #ifndef $wx_func
 276                   &$wx_func;
 277                 #endif
 278                 $5
 279               ])
 280           ],
 281           [eval wx_cv_func_$wx_func=yes],
 282           [eval wx_cv_func_$wx_func=no])
 283       ])
 284
 285     if eval test \$wx_cv_func_$wx_func = yes
 286     then
 287       AC_DEFINE_UNQUOTED([HAVE_`echo $wx_func | tr 'a-z' 'A-Z'`])
 288       $2
 289     else
 290       :
 291       $3
 292     fi
 293   done
 294 ])
 295
 296 dnl ---------------------------------------------------------------------------
 297 dnl a slightly better AC_C_BIGENDIAN macro which allows cross-compiling
 298 dnl ---------------------------------------------------------------------------
 299
 300 AC_DEFUN([WX_C_BIGENDIAN],
 301 [AC_CACHE_CHECK([whether byte ordering is bigendian], ac_cv_c_bigendian,
 302 [ac_cv_c_bigendian=unknown
 303 # See if sys/param.h defines the BYTE_ORDER macro.
 304 AC_TRY_COMPILE([#include <sys/types.h>
 305 #include <sys/param.h>], [
 306 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
 307  bogus endian macros
 308 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
 309 AC_TRY_COMPILE([#include <sys/types.h>
 310 #include <sys/param.h>], [
 311 #if BYTE_ORDER != BIG_ENDIAN
 312  not big endian
 313 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
 314 if test $ac_cv_c_bigendian = unknown; then
 315 AC_TRY_RUN([main () {
 316   /* Are we little or big endian?  From Harbison&Steele.  */
 317   union
 318   {
 319     long l;
 320     char c[sizeof (long)];
 321   } u;
 322   u.l = 1;
 323   exit (u.c[sizeof (long) - 1] == 1);
 324 }], [ac_cv_c_bigendian=no], [ac_cv_c_bigendian=yes], [ac_cv_c_bigendian=unknown])
 325 fi])
 326 if test $ac_cv_c_bigendian = unknown; then
 327   AC_MSG_WARN([Assuming little-endian target machine - this may be overriden by adding the line "ac_cv_c_bigendian=${ac_cv_c_bigendian='yes'}" to config.cache file])
 328 fi
 329 if test $ac_cv_c_bigendian = yes; then
 330   AC_DEFINE(WORDS_BIGENDIAN)
 331 fi
 332 ])
 333
 334 dnl ---------------------------------------------------------------------------
 335 dnl override AC_ARG_ENABLE/WITH to cache the results in .cache file
 336 dnl ---------------------------------------------------------------------------
 337
 338 AC_DEFUN([WX_ARG_CACHE_INIT],
 339         [
 340           wx_arg_cache_file="configarg.cache"
 341           echo "loading argument cache $wx_arg_cache_file"
 342           rm -f ${wx_arg_cache_file}.tmp
 343           touch ${wx_arg_cache_file}.tmp
 344           touch ${wx_arg_cache_file}
 345         ])
 346
 347 AC_DEFUN([WX_ARG_CACHE_FLUSH],
 348         [
 349           echo "saving argument cache $wx_arg_cache_file"
 350           mv ${wx_arg_cache_file}.tmp ${wx_arg_cache_file}
 351         ])
 352
 353 dnl return the name of the variable to store the value of the given
 354 dnl WX_ARG_WITH/ENABLE option
 355 AC_DEFUN([WX_ARG_CACHE_NAME],)
 356
 357 dnl this macro checks for a three-valued command line --with argument:
 358 dnl   possible arguments are 'yes', 'no', 'sys', or 'builtin'
 359 dnl usage: WX_ARG_SYS_WITH(option, helpmessage, variable-name)
 360 dnl
 361 dnl the default value (used if the option is not specified at all) is the value
 362 dnl of wxUSE_ALL_FEATURES (which is "yes" by default but can be changed by
 363 dnl giving configure --disable-all-features option)
 364 AC_DEFUN([WX_ARG_SYS_WITH],
 365         [
 366           AC_MSG_CHECKING([for --with-$1])
 367           AC_ARG_WITH($1, [$2],
 368                       [
 369                         if test "$withval" = yes; then
 370                           AS_TR_SH(wx_cv_use_$1)='$3=yes'
 371                         elif test "$withval" = no; then
 372                           AS_TR_SH(wx_cv_use_$1)='$3=no'
 373                         elif test "$withval" = sys; then
 374                           AS_TR_SH(wx_cv_use_$1)='$3=sys'
 375                         elif test "$withval" = builtin; then
 376                           AS_TR_SH(wx_cv_use_$1)='$3=builtin'
 377                         else
 378                           AC_MSG_ERROR([Invalid value for --with-$1: should be yes, no, sys, or builtin])
 379                         fi
 380                         cache=yes
 381                       ],
 382                       [
 383                         cache=no
 384                         LINE=`grep "^$3=" ${wx_arg_cache_file}`
 385                         if test "x$LINE" != x ; then
 386                           eval "DEFAULT_$LINE"
 387                         fi
 388
 389                         AS_TR_SH(wx_cv_use_$1)='$3=${'DEFAULT_$3":-$wxUSE_ALL_FEATURES}"
 390                       ])
 391
 392           eval "$AS_TR_SH(wx_cv_use_$1)"
 393           if test "x$cache" = xyes; then
 394             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 395           fi
 396
 397           if test "$$3" = yes; then
 398             AC_MSG_RESULT(yes)
 399           elif test "$$3" = no; then
 400             AC_MSG_RESULT(no)
 401           elif test "$$3" = sys; then
 402             AC_MSG_RESULT([system version])
 403           elif test "$$3" = builtin; then
 404             AC_MSG_RESULT([builtin version])
 405           else
 406             AC_MSG_ERROR([Invalid value for --with-$1: should be yes, no, sys, or builtin])
 407           fi
 408         ])
 409
 410 dnl this macro checks for a command line argument and caches the result
 411 dnl usage: WX_ARG_WITH(option, helpmessage, variable-name, [withstring])
 412 AC_DEFUN([WX_ARG_WITH],
 413         [
 414           withstring=$4
 415           defaultval=$wxUSE_ALL_FEATURES
 416           if test -z "$defaultval"; then
 417               if test x"$withstring" = xwithout; then
 418                   defaultval=yes
 419               else
 420                   defaultval=no
 421               fi
 422           fi
 423           AC_MSG_CHECKING([for --${withstring:-with}-$1])
 424           AC_ARG_WITH($1, [$2],
 425                       [
 426                         if test "$withval" = yes; then
 427                           AS_TR_SH(wx_cv_use_$1)='$3=yes'
 428                         else
 429                           AS_TR_SH(wx_cv_use_$1)='$3=no'
 430                         fi
 431                         cache=yes
 432                       ],
 433                       [
 434                         cache=no
 435                         LINE=`grep "^$3=" ${wx_arg_cache_file}`
 436                         if test "x$LINE" != x ; then
 437                           eval "DEFAULT_$LINE"
 438                         fi
 439
 440                         AS_TR_SH(wx_cv_use_$1)='$3=${'DEFAULT_$3":-$defaultval}"
 441                       ])
 442
 443           eval "$AS_TR_SH(wx_cv_use_$1)"
 444           if test "x$cache" = xyes; then
 445             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 446           fi
 447
 448           if test x"$withstring" = xwithout; then
 449             if test $$3 = yes; then
 450               result=no
 451             else
 452               result=yes
 453             fi
 454           else
 455             result=$$3
 456           fi
 457
 458           AC_MSG_RESULT($result)
 459         ])
 460
 461 dnl same as WX_ARG_WITH but makes it clear that the option is enabled by default
 462 AC_DEFUN([WX_ARG_WITHOUT], [WX_ARG_WITH($1, [$2], $3, without)])
 463
 464 dnl like WX_ARG_WITH but uses AC_ARG_ENABLE instead of AC_ARG_WITH
 465 dnl usage: WX_ARG_ENABLE(option, helpmessage, var, [enablestring], [default])
 466 dnl
 467 dnl enablestring can be omitted or a literal string "disable" and allows to
 468 dnl show "checking for --disable-foo" message when running configure instead of
 469 dnl the default "checking for --enable-foo" one whih is useful for the options
 470 dnl enabled by default
 471 dnl
 472 dnl the "default" argument can be omitted or contain the default value to use
 473 dnl for the option if it's unspecified
 474 AC_DEFUN([WX_ARG_ENABLE],
 475         [
 476           enablestring=$4
 477           defaultval=$5
 478           if test -z "$defaultval"; then
 479               if test x"$enablestring" = xdisable; then
 480                   defaultval=yes
 481               else
 482                   defaultval=no
 483               fi
 484           fi
 485
 486           AC_MSG_CHECKING([for --${enablestring:-enable}-$1])
 487           AC_ARG_ENABLE($1, [$2],
 488                         [
 489                           if test "$enableval" = yes; then
 490                             AS_TR_SH(wx_cv_use_$1)='$3=yes'
 491                           else
 492                             AS_TR_SH(wx_cv_use_$1)='$3=no'
 493                           fi
 494                           cache=yes
 495                         ],
 496                         [
 497                           cache=no
 498                           LINE=`grep "^$3=" ${wx_arg_cache_file}`
 499                           if test "x$LINE" != x ; then
 500                             eval "DEFAULT_$LINE"
 501                           fi
 502
 503                           AS_TR_SH(wx_cv_use_$1)='$3=${'DEFAULT_$3":-$defaultval}"
 504                         ])
 505
 506           eval "$AS_TR_SH(wx_cv_use_$1)"
 507           if test "x$cache" = xyes; then
 508             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 509           fi
 510
 511           if test x"$enablestring" = xdisable; then
 512             if test $$3 = yes; then
 513               result=no
 514             else
 515               result=yes
 516             fi
 517           else
 518             result=$$3
 519           fi
 520
 521           AC_MSG_RESULT($result)
 522         ])
 523
 524 dnl the same as WX_ARG_ENABLE but makes it more clear that the option is
 525 dnl enabled by default
 526 AC_DEFUN([WX_ARG_DISABLE], [WX_ARG_ENABLE($1, [$2], $3, disable)])
 527
 528 dnl same as WX_ARG_ENABLE but defaults to wxUSE_ALL_FEATURES instead of "yes"
 529 AC_DEFUN([WX_ARG_FEATURE], [WX_ARG_ENABLE($1, [$2], $3,, $wxUSE_ALL_FEATURES)])
 530
 531 dnl Like WX_ARG_ENABLE but accepts a parameter.
 532 dnl
 533 dnl Usage:
 534 dnl   WX_ARG_ENABLE_PARAM(option, helpmessage, variable-name, enablestring)
 535 dnl
 536 dnl Example:
 537 dnl   WX_ARG_ENABLE_PARAM(foo, [[  --enable-foo[=bar] use foo]], wxUSE_FOO)
 538 dnl
 539 dnl  --enable-foo       wxUSE_FOO=yes
 540 dnl  --disable-foo      wxUSE_FOO=no
 541 dnl  --enable-foo=bar   wxUSE_FOO=bar
 542 dnl  <not given>        value from configarg.cache or
 543 dnl                     wxUSE_FOO=$DEFAULT_wxUSE_FOO
 544 dnl
 545 AC_DEFUN([WX_ARG_ENABLE_PARAM],
 546         [
 547           enablestring=$4
 548           AC_MSG_CHECKING([for --${enablestring:-enable}-$1])
 549           AC_ARG_ENABLE($1, [$2],
 550                         [
 551                           wx_cv_use_$1="$3='$enableval'"
 552                           cache=yes
 553                         ],
 554                         [
 555                           cache=no
 556                           LINE=`grep "^$3=" ${wx_arg_cache_file}`
 557                           if test "x$LINE" != x ; then
 558                             eval "DEFAULT_$LINE"
 559                           fi
 560
 561                           wx_cv_use_$1='$3='$DEFAULT_$3
 562                         ])
 563
 564           eval "$wx_cv_use_$1"
 565           if test "x$cache" = xyes; then
 566             echo "$3=$$3" >> ${wx_arg_cache_file}.tmp
 567           fi
 568
 569           AC_MSG_RESULT([$$3])
 570         ])
 571
 572 dnl ===========================================================================
 573 dnl Linker features test
 574 dnl ===========================================================================
 575
 576 dnl ---------------------------------------------------------------------------
 577 dnl WX_VERSIONED_SYMBOLS checks whether the linker can create versioned
 578 dnl symbols. If it can, sets LDFLAGS_VERSIONING to $CXX flags needed to use
 579 dnl version script file named versionfile
 580 dnl
 581 dnl call WX_VERSIONED_SYMBOLS(versionfile)
 582 dnl ---------------------------------------------------------------------------
 583 AC_DEFUN([WX_VERSIONED_SYMBOLS],
 584 [
 585     case "${host}" in
 586         *-*-cygwin* | *-*-mingw* )
 587             dnl although ld does support version script option on these
 588             dnl platforms, it doesn't make much sense to use it under Win32
 589             dnl and, moreover, this breaks linking because of a bug in handling
 590             dnl paths in -Wl,--version-script,path option (if we ever do need
 591             dnl to use it for cygwin/mingw32, keep in mind that replacing last
 592             dnl comma with the equal sign works) so
 593             dnl simply disable it
 594             wx_cv_version_script=no
 595             ;;
 596
 597         *)
 598             AC_CACHE_CHECK([if the linker accepts --version-script], wx_cv_version_script,
 599             [
 600                 echo "VER_1 { *; };" >conftest.sym
 601                 echo "int main() { return 0; }" >conftest.cpp
 602
 603                 if AC_TRY_COMMAND([
 604                         $CXX -o conftest.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 605                         -Wl,--version-script,conftest.sym >/dev/null 2>conftest.stderr]) ; then
 606                   if test -s conftest.stderr ; then
 607                       wx_cv_version_script=no
 608                   else
 609                       wx_cv_version_script=yes
 610                   fi
 611                 else
 612                   wx_cv_version_script=no
 613                 fi
 614
 615                 dnl There's a problem in some old linkers with --version-script that
 616                 dnl can cause linking to fail when you have objects with vtables in
 617                 dnl libs 3 deep.  This is known to happen in netbsd and openbsd with
 618                 dnl ld 2.11.2.
 619                 dnl
 620                 dnl To test for this we need to make some shared libs and
 621                 dnl unfortunately we can't be sure of the right way to do that. If the
 622                 dnl first two compiles don't succeed then it looks like the test isn't
 623                 dnl working and the result is ignored, but if OTOH the first two
 624                 dnl succeed but the third does not then the bug has been detected and
 625                 dnl the --version-script flag is dropped.
 626                 if test $wx_cv_version_script = yes
 627                 then
 628                   echo "struct B { virtual ~B() { } }; \
 629                         struct D : public B { }; \
 630                         void F() { D d; }" > conftest.cpp
 631
 632                   if AC_TRY_COMMAND([
 633                         $CXX -shared -fPIC -o conftest1.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 634                         -Wl,--version-script,conftest.sym >/dev/null 2>/dev/null]) &&
 635                      AC_TRY_COMMAND([
 636                         $CXX -shared -fPIC -o conftest2.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 637                         -Wl,--version-script,conftest.sym conftest1.output >/dev/null 2>/dev/null])
 638                   then
 639                     if AC_TRY_COMMAND([
 640                           $CXX -shared -fPIC -o conftest3.output $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.cpp
 641                           -Wl,--version-script,conftest.sym conftest2.output conftest1.output >/dev/null 2>/dev/null])
 642                     then
 643                       wx_cv_version_script=yes
 644                     else
 645                       wx_cv_version_script=no
 646                     fi
 647                   fi
 648                 fi
 649
 650                 rm -f conftest.output conftest.stderr conftest.sym conftest.cpp
 651                 rm -f conftest1.output conftest2.output conftest3.output
 652             ])
 653
 654             if test $wx_cv_version_script = yes ; then
 655                 LDFLAGS_VERSIONING="-Wl,--version-script,$1"
 656             fi
 657             ;;
 658     esac
 659 ])
 660
 661
 662 dnl ===========================================================================
 663 dnl "3rd party" macros included here because they are not widely available
 664 dnl ===========================================================================
 665
 666 dnl ---------------------------------------------------------------------------
 667 dnl test for availability of iconv()
 668 dnl ---------------------------------------------------------------------------
 669
 670 dnl From Bruno Haible.
 671
 672 AC_DEFUN([AM_ICONV],
 673 [
 674   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 675   dnl those with the standalone portable GNU libiconv installed).
 676
 677   AC_ARG_WITH([libiconv-prefix],
 678 [  --with-libiconv-prefix=DIR  search for libiconv in DIR/include and DIR/lib], [
 679     for dir in `echo "$withval" | tr : ' '`; do
 680       if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi
 681       if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi
 682     done
 683    ])
 684
 685   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 686     am_cv_func_iconv="no, consider installing GNU libiconv"
 687     am_cv_lib_iconv=no
 688     AC_TRY_LINK([#include <stdlib.h>
 689 #include <iconv.h>],
 690       [iconv_t cd = iconv_open("","");
 691        iconv(cd,NULL,NULL,NULL,NULL);
 692        iconv_close(cd);],
 693       am_cv_func_iconv=yes)
 694     if test "$am_cv_func_iconv" != yes; then
 695       am_save_LIBS="$LIBS"
 696       LIBS="$LIBS -liconv"
 697       AC_TRY_LINK([#include <stdlib.h>
 698 #include <iconv.h>],
 699         [iconv_t cd = iconv_open("","");
 700          iconv(cd,NULL,NULL,NULL,NULL);
 701          iconv_close(cd);],
 702         am_cv_lib_iconv=yes
 703         am_cv_func_iconv=yes)
 704       LIBS="$am_save_LIBS"
 705     fi
 706   ])
 707   if test "$am_cv_func_iconv" = yes; then
 708     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 709     AC_CACHE_CHECK([if iconv needs const], wx_cv_func_iconv_const,
 710       AC_TRY_COMPILE([
 711 #include <stdlib.h>
 712 #include <iconv.h>
 713 extern
 714 #ifdef __cplusplus
 715 "C"
 716 #endif
 717 #if defined(__STDC__) || defined(__cplusplus)
 718 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 719 #else
 720 size_t iconv();
 721 #endif
 722         ],
 723         [],
 724         wx_cv_func_iconv_const="no",
 725         wx_cv_func_iconv_const="yes"
 726       )
 727     )
 728
 729     iconv_const=
 730     if test "x$wx_cv_func_iconv_const" = "xyes"; then
 731         iconv_const="const"
 732     fi
 733
 734     AC_DEFINE_UNQUOTED(ICONV_CONST, $iconv_const,
 735       [Define as const if the declaration of iconv() needs const.])
 736   fi
 737   LIBICONV=
 738   if test "$am_cv_lib_iconv" = yes; then
 739     LIBICONV="-liconv"
 740   fi
 741   AC_SUBST(LIBICONV)
 742 ])
 743
 744 dnl ---------------------------------------------------------------------------
 745 dnl AC_SYS_LARGEFILE (partly based on the code from autoconf 2.5x)
 746 dnl ---------------------------------------------------------------------------
 747
 748 dnl WX_SYS_LARGEFILE_TEST
 749 dnl
 750 dnl NB: original autoconf test was checking if compiler supported 6 bit off_t
 751 dnl     arithmetic properly but this failed miserably with gcc under Linux
 752 dnl     whereas the system still supports 64 bit files, so now simply check
 753 dnl     that off_t is big enough
 754 define(WX_SYS_LARGEFILE_TEST,
 755 [typedef struct {
 756     unsigned int field: sizeof(off_t) == 8;
 757 } wxlf;
 758 ])
 759
 760
 761 dnl WX_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR)
 762 define(WX_SYS_LARGEFILE_MACRO_VALUE,
 763 [
 764     AC_CACHE_CHECK([for $1 value needed for large files], [$3],
 765         [
 766           AC_TRY_COMPILE([#define $1 $2
 767                           #include <sys/types.h>],
 768                          WX_SYS_LARGEFILE_TEST,
 769                          [$3=$2],
 770                          [$3=no])
 771         ]
 772     )
 773
 774     if test "$$3" != no; then
 775         wx_largefile=yes
 776         AC_DEFINE_UNQUOTED([$1], [$$3])
 777     fi
 778 ])
 779
 780
 781 dnl AC_SYS_LARGEFILE
 782 dnl ----------------
 783 dnl By default, many hosts won't let programs access large files;
 784 dnl one must use special compiler options to get large-file access to work.
 785 dnl For more details about this brain damage please see:
 786 dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
 787 AC_DEFUN([AC_SYS_LARGEFILE],
 788 [AC_ARG_ENABLE(largefile,
 789                [  --disable-largefile     omit support for large files])
 790 if test "$enable_largefile" != no; then
 791     dnl _FILE_OFFSET_BITS==64 is needed for Linux, Solaris, ...
 792     dnl _LARGE_FILES -- for AIX
 793     wx_largefile=no
 794     WX_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64, ac_cv_sys_file_offset_bits)
 795     if test "x$wx_largefile" != "xyes"; then
 796         WX_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1, ac_cv_sys_large_files)
 797     fi
 798
 799     AC_MSG_CHECKING(if large file support is available)
 800     if test "x$wx_largefile" = "xyes"; then
 801         AC_DEFINE(HAVE_LARGEFILE_SUPPORT)
 802     fi
 803     AC_MSG_RESULT($wx_largefile)
 804 fi
 805 ])
 806
 807
 808 dnl Available from the GNU Autoconf Macro Archive at:
 809 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_const_cast.html
 810 dnl
 811 AC_DEFUN([AC_CXX_CONST_CAST],
 812 [AC_CACHE_CHECK(whether the compiler supports const_cast<>,
 813 ac_cv_cxx_const_cast,
 814 [AC_LANG_SAVE
 815  AC_LANG_CPLUSPLUS
 816  AC_TRY_COMPILE(,[int x = 0;const int& y = x;int& z = const_cast<int&>(y);return z;],
 817  ac_cv_cxx_const_cast=yes, ac_cv_cxx_const_cast=no)
 818  AC_LANG_RESTORE
 819 ])
 820 if test "$ac_cv_cxx_const_cast" = yes; then
 821   AC_DEFINE(HAVE_CONST_CAST,,[define if the compiler supports const_cast<>])
 822 fi
 823 ])
 824
 825 dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_reinterpret_cast.html
 826 AC_DEFUN([AC_CXX_REINTERPRET_CAST],
 827 [AC_CACHE_CHECK(whether the compiler supports reinterpret_cast<>,
 828 ac_cv_cxx_reinterpret_cast,
 829 [AC_LANG_SAVE
 830  AC_LANG_CPLUSPLUS
 831  AC_TRY_COMPILE([#include <typeinfo>
 832 class Base { public : Base () {} virtual void f () = 0;};
 833 class Derived : public Base { public : Derived () {} virtual void f () {} };
 834 class Unrelated { public : Unrelated () {} };
 835 int g (Unrelated&) { return 0; }],[
 836 Derived d;Base& b=d;Unrelated& e=reinterpret_cast<Unrelated&>(b);return g(e);],
 837  ac_cv_cxx_reinterpret_cast=yes, ac_cv_cxx_reinterpret_cast=no)
 838  AC_LANG_RESTORE
 839 ])
 840 if test "$ac_cv_cxx_reinterpret_cast" = yes; then
 841   AC_DEFINE(HAVE_REINTERPRET_CAST,,
 842             [define if the compiler supports reinterpret_cast<>])
 843 fi
 844 ])
 845
 846 dnl and http://www.gnu.org/software/ac-archive/htmldoc/ac_cxx_static_cast.html
 847 AC_DEFUN([AC_CXX_STATIC_CAST],
 848 [AC_CACHE_CHECK(whether the compiler supports static_cast<>,
 849 ac_cv_cxx_static_cast,
 850 [AC_LANG_SAVE
 851  AC_LANG_CPLUSPLUS
 852  AC_TRY_COMPILE([#include <typeinfo>
 853 class Base { public : Base () {} virtual void f () = 0; };
 854 class Derived : public Base { public : Derived () {} virtual void f () {} };
 855 int g (Derived&) { return 0; }],[
 856 Derived d; Base& b = d; Derived& s = static_cast<Derived&> (b); return g (s);],
 857  ac_cv_cxx_static_cast=yes, ac_cv_cxx_static_cast=no)
 858  AC_LANG_RESTORE
 859 ])
 860 if test "$ac_cv_cxx_static_cast" = yes; then
 861   AC_DEFINE(HAVE_STATIC_CAST,, [define if the compiler supports static_cast<>])
 862 fi
 863 ])
 864
 865 dnl http://autoconf-archive.cryp.to/ac_cxx_dynamic_cast.html
 866 AC_DEFUN([AC_CXX_DYNAMIC_CAST],
 867 [AC_CACHE_CHECK(whether the compiler supports dynamic_cast<>,
 868 ac_cv_cxx_dynamic_cast,
 869 [AC_LANG_SAVE
 870  AC_LANG_CPLUSPLUS
 871  AC_TRY_COMPILE([#include <typeinfo>
 872 class Base { public : Base () {} virtual void f () = 0;};
 873 class Derived : public Base { public : Derived () {} virtual void f () {} };],[
 874 Derived d; Base& b=d; return dynamic_cast<Derived*>(&b) ? 0 : 1;],
 875  ac_cv_cxx_dynamic_cast=yes, ac_cv_cxx_dynamic_cast=no)
 876  AC_LANG_RESTORE
 877 ])
 878 if test "$ac_cv_cxx_dynamic_cast" = yes; then
 879   AC_DEFINE(HAVE_DYNAMIC_CAST,,[define if the compiler supports dynamic_cast<>])
 880 fi
 881 ])
 882