src/osx/cocoa/filedlg.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/filedlg.mm
   3 // Purpose:     wxFileDialog for wxCocoa
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2004-10-02
   7 // RCS-ID:      $Id: filedlg.mm 40007 2006-07-05 13:10:46Z SC $
   8 // Copyright:   (c) Ryan Norton
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ============================================================================
  13 // declarations
  14 // ============================================================================
  15
  16 // ----------------------------------------------------------------------------
  17 // headers
  18 // ----------------------------------------------------------------------------
  19
  20 // For compilers that support precompilation, includes "wx.h".
  21 #include "wx/wxprec.h"
  22
  23 #if wxUSE_FILEDLG
  24
  25 #include "wx/filedlg.h"
  26
  27 #ifndef WX_PRECOMP
  28     #include "wx/msgdlg.h"
  29     #include "wx/app.h"
  30 #endif
  31
  32 #include "wx/filename.h"
  33 #include "wx/tokenzr.h"
  34
  35 #include "wx/osx/private.h"
  36
  37 // ============================================================================
  38 // implementation
  39 // ============================================================================
  40
  41 // Open Items:
  42 // - support for old style MacOS creator / type combos
  43 // - parameter support for descending into packages as directories (setTreatsFilePackagesAsDirectories)
  44
  45 IMPLEMENT_CLASS(wxFileDialog, wxFileDialogBase)
  46
  47 wxFileDialog::wxFileDialog(
  48     wxWindow *parent, const wxString& message,
  49     const wxString& defaultDir, const wxString& defaultFileName, const wxString& wildCard,
  50     long style, const wxPoint& pos, const wxSize& sz, const wxString& name)
  51     : wxFileDialogBase(parent, message, defaultDir, defaultFileName, wildCard, style, pos, sz, name)
  52 {
  53 }
  54
  55 NSArray* GetTypesFromFilter( const wxString filter )
  56 {
  57     NSMutableArray* types = nil;
  58     if ( !filter.empty() )
  59     {
  60         wxArrayString names ;
  61         wxArrayString extensions;
  62
  63         wxString filter2(filter) ;
  64         int filterIndex = 0;
  65         bool isName = true ;
  66         wxString current ;
  67
  68         for ( unsigned int i = 0; i < filter2.length() ; i++ )
  69         {
  70             if ( filter2.GetChar(i) == wxT('|') )
  71             {
  72                 if ( isName )
  73                 {
  74                     names.Add( current ) ;
  75                 }
  76                 else
  77                 {
  78                     extensions.Add( current ) ;
  79                     ++filterIndex ;
  80                 }
  81
  82                 isName = !isName ;
  83                 current = wxEmptyString ;
  84             }
  85             else
  86             {
  87                 current += filter2.GetChar(i) ;
  88             }
  89         }
  90         // we allow for compatibility reason to have a single filter expression (like *.*) without
  91         // an explanatory text, in that case the first part is name and extension at the same time
  92
  93         wxASSERT_MSG( filterIndex == 0 || !isName , wxT("incorrect format of format string") ) ;
  94         if ( current.empty() )
  95             extensions.Add( names[filterIndex] ) ;
  96         else
  97             extensions.Add( current ) ;
  98         if ( filterIndex == 0 || isName )
  99             names.Add( current ) ;
 100
 101         ++filterIndex ;
 102
 103         const size_t extCount = extensions.GetCount();
 104         for ( size_t i = 0 ; i < extCount; i++ )
 105         {
 106             wxString extensiongroup = extensions[i];
 107             wxStringTokenizer tokenizer( extensiongroup , wxT(";") ) ;
 108             while ( tokenizer.HasMoreTokens() )
 109             {
 110                 wxString extension = tokenizer.GetNextToken() ;
 111                 // Remove leading '*'
 112                 if (extension.length() && (extension.GetChar(0) == '*'))
 113                     extension = extension.Mid( 1 );
 114
 115                 // Remove leading '.'
 116                 if (extension.length() && (extension.GetChar(0) == '.'))
 117                     extension = extension.Mid( 1 );
 118
 119                 if ( extension.IsEmpty() )
 120                 {
 121                     if ( types != nil )
 122                         [types release];
 123                     return nil;
 124                 }
 125
 126                 if ( types == nil )
 127                     types = [[NSMutableArray alloc] init];
 128
 129                 wxCFStringRef cfext(extension);
 130                 [types addObject: (NSString*)cfext.AsNSString()  ];
 131 #if 0
 132                 // add support for classic fileType / creator here
 133                 wxUint32 fileType, creator;
 134                 // extension -> mactypes
 135 #endif
 136             }
 137
 138         }
 139     }
 140     return types;
 141 }
 142
 143 int wxFileDialog::ShowModal()
 144 {
 145     int result = wxID_CANCEL;
 146
 147     NSSavePanel *panel = nil;
 148
 149     wxCFStringRef cf( m_message );
 150
 151     wxCFStringRef dir( m_dir );
 152     wxCFStringRef file( m_fileName );
 153
 154     m_path = wxEmptyString;
 155     m_fileNames.Clear();
 156     m_paths.Clear();
 157     // since we don't support retrieving the matching filter
 158     m_filterIndex = -1;
 159
 160     wxNonOwnedWindow* parentWindow = NULL;
 161     int returnCode = -1;
 162
 163     if (GetParent())
 164     {
 165         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 166     }
 167
 168     if (HasFlag(wxFD_SAVE))
 169     {
 170         NSSavePanel* sPanel = [NSSavePanel savePanel];
 171         // makes things more convenient:
 172         [sPanel setCanCreateDirectories:YES];
 173         [sPanel setMessage:cf.AsNSString()];
 174         // if we should be able to descend into pacakges we must somehow
 175         // be able to pass this in
 176         [sPanel setTreatsFilePackagesAsDirectories:NO];
 177         [sPanel setCanSelectHiddenExtension:YES];
 178
 179         if ( HasFlag(wxFD_OVERWRITE_PROMPT) )
 180         {
 181         }
 182
 183 /*
 184         if (parentWindow)
 185         {
 186             NSWindow* nativeParent = parentWindow->GetWXWindow();
 187             ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 188             [sPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 189                 modalForWindow: nativeParent modalDelegate: sheetDelegate
 190                 didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 191                 contextInfo: nil];
 192             [sheetDelegate waitForSheetToFinish];
 193             returnCode = [sheetDelegate code];
 194             [sheetDelegate release];
 195         }
 196         else
 197 */
 198         {
 199             returnCode = [sPanel runModalForDirectory:dir.AsNSString() file:file.AsNSString() ];
 200         }
 201
 202         if (returnCode == NSOKButton )
 203         {
 204             panel = sPanel;
 205             result = wxID_OK;
 206
 207             m_path = wxCFStringRef::AsString([sPanel filename]);
 208             m_fileName = wxFileNameFromPath(m_path);
 209             m_dir = wxPathOnly( m_path );
 210         }
 211     }
 212     else
 213     {
 214         NSArray* types = GetTypesFromFilter( m_wildCard ) ;
 215         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 216         [oPanel setTreatsFilePackagesAsDirectories:NO];
 217         [oPanel setCanChooseDirectories:NO];
 218         [oPanel setResolvesAliases:YES];
 219         [oPanel setCanChooseFiles:YES];
 220         [oPanel setMessage:cf.AsNSString()];
 221
 222 /*
 223         if (parentWindow)
 224         {
 225             NSWindow* nativeParent = parentWindow->GetWXWindow();
 226             ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 227             [oPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 228                 types: types modalForWindow: nativeParent
 229                 modalDelegate: sheetDelegate
 230                 didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 231                 contextInfo: nil];
 232             [sheetDelegate waitForSheetToFinish];
 233             returnCode = [sheetDelegate code];
 234             [sheetDelegate release];
 235         }
 236         else
 237 */
 238         {
 239             returnCode = [oPanel runModalForDirectory:dir.AsNSString()
 240                         file:file.AsNSString() types:types];
 241         }
 242         if (returnCode == NSOKButton )
 243         {
 244             panel = oPanel;
 245             result = wxID_OK;
 246             NSArray* filenames = [oPanel filenames];
 247             for ( size_t i = 0 ; i < [filenames count] ; ++ i )
 248             {
 249                 wxString fnstr = wxCFStringRef::AsString([filenames objectAtIndex:i]);
 250                 m_paths.Add( fnstr );
 251                 m_fileNames.Add( wxFileNameFromPath(fnstr) );
 252                 if ( i == 0 )
 253                 {
 254                     m_path = fnstr;
 255                     m_fileName = wxFileNameFromPath(fnstr);
 256                     m_dir = wxPathOnly( fnstr );
 257                 }
 258             }
 259         }
 260         if ( types != nil )
 261             [types release];
 262     }
 263
 264     return result;
 265 }
 266
 267 #endif // wxUSE_FILEDLG