src/osx/cocoa/dataview.mm

   1 ///////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/dataview.mm
   3 // Purpose:     wxDataView
   4 // Author:
   5 // Modified by:
   6 // Created:     2009-01-31
   7 // RCS-ID:      $Id: dataview.mm$
   8 // Copyright:
   9 // Licence:     wxWindows licence
  10 ///////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/app.h"
  18     #include "wx/toplevel.h"
  19     #include "wx/font.h"
  20     #include "wx/settings.h"
  21     #include "wx/utils.h"
  22 #endif
  23
  24 #include "wx/osx/private.h"
  25 #include "wx/osx/cocoa/dataview.h"
  26 #include "wx/renderer.h"
  27 #include "wx/stopwatch.h"
  28 #include "wx/dcgraph.h"
  29
  30 // ============================================================================
  31 // Constants used locally
  32 // ============================================================================
  33
  34 #define DataViewPboardType @"OutlineViewItem"
  35
  36 // ============================================================================
  37 // Classes used locally in dataview.mm
  38 // ============================================================================
  39
  40 // ============================================================================
  41 // wxPointerObject
  42 // ============================================================================
  43
  44 @implementation wxPointerObject
  45
  46 -(id) init
  47 {
  48     self = [super init];
  49     if (self != nil)
  50         self->pointer = NULL;
  51     return self;
  52 }
  53
  54 -(id) initWithPointer:(void*) initPointer
  55 {
  56     self = [super init];
  57     if (self != nil)
  58         self->pointer = initPointer;
  59     return self;
  60 }
  61
  62 //
  63 // inherited methods from NSObject
  64 //
  65 -(BOOL) isEqual:(id)object
  66 {
  67     return (object != nil) &&
  68              ([object isKindOfClass:[wxPointerObject class]]) &&
  69                  (pointer == [((wxPointerObject*) object) pointer]);
  70 }
  71
  72 -(NSUInteger) hash
  73 {
  74     return (NSUInteger) pointer;
  75 }
  76
  77 -(void*) pointer
  78 {
  79     return pointer;
  80 }
  81
  82 -(void) setPointer:(void*) newPointer
  83 {
  84     pointer = newPointer;
  85 }
  86
  87 @end
  88
  89 namespace
  90 {
  91
  92 inline wxDataViewItem wxDataViewItemFromItem(id item)
  93 {
  94     return wxDataViewItem([static_cast<wxPointerObject *>(item) pointer]);
  95 }
  96
  97 inline wxDataViewItem wxDataViewItemFromMaybeNilItem(id item)
  98 {
  99     return item == nil ? wxDataViewItem() : wxDataViewItemFromItem(item);
 100 }
 101
 102 } // anonymous namespace
 103
 104 // ----------------------------------------------------------------------------
 105 // wxCustomRendererObject
 106 // ----------------------------------------------------------------------------
 107
 108 @interface wxCustomRendererObject : NSObject <NSCopying>
 109 {
 110 @public
 111     wxDataViewCustomRenderer* customRenderer; // not owned by the class
 112 }
 113
 114     -(id) init;
 115     -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer;
 116 @end
 117
 118 @implementation wxCustomRendererObject
 119
 120 -(id) init
 121 {
 122     self = [super init];
 123     if (self != nil)
 124     {
 125         customRenderer = NULL;
 126     }
 127     return self;
 128 }
 129
 130 -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer
 131 {
 132     self = [super init];
 133     if (self != nil)
 134     {
 135         customRenderer = renderer;
 136     }
 137     return self;
 138 }
 139
 140 -(id) copyWithZone:(NSZone*)zone
 141 {
 142     wxCustomRendererObject* copy;
 143
 144     copy = [[[self class] allocWithZone:zone] init];
 145     copy->customRenderer = customRenderer;
 146
 147     return copy;
 148 }
 149 @end
 150
 151 // ----------------------------------------------------------------------------
 152 // wxDVCNSTableColumn: exists only to override NSTableColumn:dataCellForRow:
 153 // ----------------------------------------------------------------------------
 154
 155 @interface wxDVCNSTableColumn : NSTableColumn
 156 {
 157 }
 158
 159     // Get the identifier we use for the specified column. This should be used
 160     // for finding columns from identifier only, to initialize the identifier
 161     // of a new column use initWithColumnPointer below instead.
 162     +(NSString*) identifierForColumnPointer:(const wxDataViewColumn*)column;
 163
 164     // Initialize the column with the given pointer to the associated
 165     // wxDataViewColumn. This pointer can later be retrieved using
 166     // getColumnPointer.
 167     -(id) initWithColumnPointer:(const wxDataViewColumn*)column;
 168
 169     // Retrieve the associated column.
 170     -(wxDataViewColumn*) getColumnPointer;
 171
 172     -(id) dataCellForRow:(NSInteger)row;
 173 @end
 174
 175 @implementation wxDVCNSTableColumn
 176
 177 +(NSString*) identifierForColumnPointer:(const wxDataViewColumn*)column
 178 {
 179     // Starting from OS X 10.7 the column identifier must be an NSString and
 180     // not just some arbitrary object, so we serialize the pointer into the
 181     // string. Notice the use of NSInteger which is big enough to store a
 182     // pointer in both 32 and 64 bit builds.
 183     return [NSString stringWithFormat:@"%lu", reinterpret_cast<NSUInteger>(column)];
 184 }
 185
 186 -(id) initWithColumnPointer:(const wxDataViewColumn*)column
 187 {
 188     [self initWithIdentifier: [wxDVCNSTableColumn identifierForColumnPointer:column]];
 189     return self;
 190 }
 191
 192 -(wxDataViewColumn*) getColumnPointer
 193 {
 194     // The case to NSString is needed for OS X < 10.7.
 195     return reinterpret_cast<wxDataViewColumn*>(
 196             [static_cast<NSString*>([self identifier]) integerValue]);
 197 }
 198
 199 -(id) dataCellForRow:(NSInteger)row
 200 {
 201     // what we want to do here is to simply return nil for the cells which
 202     // shouldn't show anything as otherwise we would show e.g. empty combo box
 203     // or progress cells in the columns using the corresponding types even for
 204     // the container rows which is wrong
 205
 206     const wxDataViewColumn * const dvCol = [self getColumnPointer];
 207
 208     const wxDataViewCtrl * const dvc = dvCol->GetOwner();
 209     const wxCocoaDataViewControl * const
 210         peer = static_cast<wxCocoaDataViewControl *>(dvc->GetPeer());
 211
 212
 213     // once we do have everything, simply ask NSOutlineView for the item...
 214     const id item = peer->GetItemAtRow(row);
 215     if ( item )
 216     {
 217         // ... and if it succeeded, ask the model whether it has any value
 218         wxDataViewItem dvItem(wxDataViewItemFromItem(item));
 219
 220         if ( !dvc->GetModel()->HasValue(dvItem, dvCol->GetModelColumn()) )
 221             return nil;
 222     }
 223
 224     return [super dataCellForRow:row];
 225 }
 226
 227 @end
 228
 229 // ============================================================================
 230 // local helpers
 231 // ============================================================================
 232
 233 namespace
 234 {
 235
 236 // convert from NSObject to different C++ types: all these functions check
 237 // that the conversion really makes sense and assert if it doesn't
 238 wxString ObjectToString(NSObject *object)
 239 {
 240     wxCHECK_MSG( [object isKindOfClass:[NSString class]], "",
 241                  wxString::Format
 242                  (
 243                     "string expected but got %s",
 244                     wxCFStringRef::AsString([object className])
 245                  ));
 246
 247     return wxCFStringRef([((NSString*) object) retain]).AsString();
 248 }
 249
 250 bool ObjectToBool(NSObject *object)
 251 {
 252     // actually the value must be of NSCFBoolean class but it's private so we
 253     // can't check for it directly
 254     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], false,
 255                  wxString::Format
 256                  (
 257                     "number expected but got %s",
 258                     wxCFStringRef::AsString([object className])
 259                  ));
 260
 261     return [(NSNumber *)object boolValue];
 262 }
 263
 264 long ObjectToLong(NSObject *object)
 265 {
 266     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], -1,
 267                  wxString::Format
 268                  (
 269                     "number expected but got %s",
 270                     wxCFStringRef::AsString([object className])
 271                  ));
 272
 273     return [(NSNumber *)object longValue];
 274 }
 275
 276 wxDateTime ObjectToDate(NSObject *object)
 277 {
 278     wxCHECK_MSG( [object isKindOfClass:[NSDate class]], wxInvalidDateTime,
 279                  wxString::Format
 280                  (
 281                     "date expected but got %s",
 282                     wxCFStringRef::AsString([object className])
 283                  ));
 284
 285     // get the number of seconds since 1970-01-01 UTC and this is the only
 286     // way to convert a double to a wxLongLong
 287     const wxLongLong seconds = [((NSDate*) object) timeIntervalSince1970];
 288
 289     wxDateTime dt(1, wxDateTime::Jan, 1970);
 290     dt.Add(wxTimeSpan(0,0,seconds));
 291
 292     // the user has entered a date in the local timezone but seconds
 293     // contains the number of seconds from date in the local timezone
 294     // since 1970-01-01 UTC; therefore, the timezone information has to be
 295     // transferred to wxWidgets, too:
 296     dt.MakeFromTimezone(wxDateTime::UTC);
 297
 298     return dt;
 299 }
 300
 301 NSInteger CompareItems(id item1, id item2, void* context)
 302 {
 303     NSArray* const sortDescriptors = (NSArray*) context;
 304
 305     NSUInteger const count = [sortDescriptors count];
 306
 307     NSInteger result = NSOrderedSame;
 308     for ( NSUInteger i = 0; i < count && result == NSOrderedSame; ++i )
 309     {
 310         wxSortDescriptorObject* const
 311             sortDescriptor = (wxSortDescriptorObject*)
 312                 [sortDescriptors objectAtIndex:i];
 313
 314         int rc = [sortDescriptor modelPtr]->Compare
 315                  (
 316                      wxDataViewItemFromItem(item1),
 317                      wxDataViewItemFromItem(item2),
 318                      [sortDescriptor columnPtr]->GetModelColumn(),
 319                      [sortDescriptor ascending] == YES
 320                  );
 321
 322         if ( rc < 0 )
 323             result = NSOrderedAscending;
 324         else if ( rc > 0 )
 325             result = NSOrderedDescending;
 326     }
 327
 328     return result;
 329 }
 330
 331 NSTextAlignment ConvertToNativeHorizontalTextAlignment(int alignment)
 332 {
 333     if (alignment & wxALIGN_CENTER_HORIZONTAL)
 334         return NSCenterTextAlignment;
 335     else if (alignment & wxALIGN_RIGHT)
 336         return NSRightTextAlignment;
 337     else
 338         return NSLeftTextAlignment;
 339 }
 340
 341 NSTableColumn* CreateNativeColumn(const wxDataViewColumn *column)
 342 {
 343     wxDataViewRenderer * const renderer = column->GetRenderer();
 344
 345     wxCHECK_MSG( renderer, NULL, "column should have a renderer" );
 346
 347     wxDVCNSTableColumn * const nativeColumn(
 348         [[wxDVCNSTableColumn alloc] initWithColumnPointer: column]
 349     );
 350
 351     // setting the size related parameters:
 352     int resizingMask;
 353     if (column->IsResizeable())
 354     {
 355         resizingMask = NSTableColumnUserResizingMask;
 356         [nativeColumn setMinWidth:column->GetMinWidth()];
 357         [nativeColumn setMaxWidth:column->GetMaxWidth()];
 358     }
 359     else // column is not resizable [by user]
 360     {
 361         // if the control doesn't show a header, make the columns resize
 362         // automatically, this is particularly important for the single column
 363         // controls (such as wxDataViewTreeCtrl) as their unique column should
 364         // always take up all the available splace
 365         resizingMask = column->GetOwner()->HasFlag(wxDV_NO_HEADER)
 366                             ? NSTableColumnAutoresizingMask
 367                             : NSTableColumnNoResizing;
 368     }
 369     [nativeColumn setResizingMask:resizingMask];
 370
 371 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
 372     // setting the visibility:
 373     [nativeColumn setHidden:static_cast<BOOL>(column->IsHidden())];
 374 #endif
 375
 376     wxDataViewRendererNativeData * const renderData = renderer->GetNativeData();
 377
 378     // setting the header:
 379     [[nativeColumn headerCell] setAlignment:
 380         ConvertToNativeHorizontalTextAlignment(column->GetAlignment())];
 381     [[nativeColumn headerCell] setStringValue:
 382         [[wxCFStringRef(column->GetTitle()).AsNSString() retain] autorelease]];
 383     renderData->ApplyLineBreakMode([nativeColumn headerCell]);
 384
 385     // setting data cell's properties:
 386     [[nativeColumn dataCell] setWraps:NO];
 387     // setting the default data cell:
 388     [nativeColumn setDataCell:renderData->GetColumnCell()];
 389     // setting the editablility:
 390     const bool isEditable = renderer->GetMode() == wxDATAVIEW_CELL_EDITABLE;
 391
 392     [nativeColumn setEditable:isEditable];
 393     [[nativeColumn dataCell] setEditable:isEditable];
 394
 395     return nativeColumn;
 396 }
 397
 398 } // anonymous namespace
 399
 400 // ============================================================================
 401 // Public helper functions for dataview implementation on OSX
 402 // ============================================================================
 403
 404 wxWidgetImplType* CreateDataView(wxWindowMac* wxpeer,
 405                                  wxWindowMac* WXUNUSED(parent),
 406                                  wxWindowID WXUNUSED(id),
 407                                  const wxPoint& pos,
 408                                  const wxSize& size,
 409                                  long style,
 410                                  long WXUNUSED(extraStyle))
 411 {
 412     return new wxCocoaDataViewControl(wxpeer,pos,size,style);
 413 }
 414
 415 // ============================================================================
 416 // wxSortDescriptorObject
 417 // ============================================================================
 418
 419 @implementation wxSortDescriptorObject
 420 -(id) init
 421 {
 422     self = [super init];
 423     if (self != nil)
 424     {
 425         columnPtr = NULL;
 426         modelPtr  = NULL;
 427     }
 428     return self;
 429 }
 430
 431 -(id)
 432 initWithModelPtr:(wxDataViewModel*)initModelPtr
 433     sortingColumnPtr:(wxDataViewColumn*)initColumnPtr
 434     ascending:(BOOL)sortAscending
 435 {
 436     self = [super initWithKey:@"dummy" ascending:sortAscending];
 437     if (self != nil)
 438     {
 439         columnPtr = initColumnPtr;
 440         modelPtr  = initModelPtr;
 441     }
 442     return self;
 443 }
 444
 445 -(id) copyWithZone:(NSZone*)zone
 446 {
 447     wxSortDescriptorObject* copy;
 448
 449
 450     copy = [super copyWithZone:zone];
 451     copy->columnPtr = columnPtr;
 452     copy->modelPtr  = modelPtr;
 453
 454     return copy;
 455 }
 456
 457 //
 458 // access to model column's index
 459 //
 460 -(wxDataViewColumn*) columnPtr
 461 {
 462     return columnPtr;
 463 }
 464
 465 -(wxDataViewModel*) modelPtr
 466 {
 467     return modelPtr;
 468 }
 469
 470 -(void) setColumnPtr:(wxDataViewColumn*)newColumnPtr
 471 {
 472     columnPtr = newColumnPtr;
 473 }
 474
 475 -(void) setModelPtr:(wxDataViewModel*)newModelPtr
 476 {
 477     modelPtr = newModelPtr;
 478 }
 479
 480 @end
 481
 482 // ============================================================================
 483 // wxCocoaOutlineDataSource
 484 // ============================================================================
 485 @implementation wxCocoaOutlineDataSource
 486
 487 //
 488 // constructors / destructor
 489 //
 490 -(id) init
 491 {
 492     self = [super init];
 493     if (self != nil)
 494     {
 495         implementation = NULL;
 496         model          = NULL;
 497
 498         currentParentItem = nil;
 499
 500         children = [[NSMutableArray alloc] init];
 501         items    = [[NSMutableSet   alloc] init];
 502     }
 503     return self;
 504 }
 505
 506 -(void) dealloc
 507 {
 508     [currentParentItem release];
 509
 510     [children release];
 511     [items    release];
 512
 513     [super dealloc];
 514 }
 515
 516 //
 517 // methods of informal protocol:
 518 //
 519 -(BOOL)
 520 outlineView:(NSOutlineView*)outlineView
 521     acceptDrop:(id<NSDraggingInfo>)info
 522     item:(id)item childIndex:(NSInteger)index
 523 {
 524     wxUnusedVar(outlineView);
 525     wxUnusedVar(index);
 526
 527     NSArray* supportedTypes(
 528         [NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]
 529     );
 530
 531     NSPasteboard* pasteboard([info draggingPasteboard]);
 532
 533     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 534
 535     if ( bestType == nil )
 536         return FALSE;
 537
 538     wxDataViewCtrl * const dvc(implementation->GetDataViewCtrl());
 539
 540     wxCHECK_MSG( dvc, false,
 541                      "Pointer to data view control not set correctly." );
 542     wxCHECK_MSG( dvc->GetModel(), false,
 543                     "Pointer to model not set correctly." );
 544
 545     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_DROP, dvc->GetId());
 546     event.SetEventObject(dvc);
 547     event.SetItem(wxDataViewItemFromItem(item));
 548     event.SetModel(dvc->GetModel());
 549
 550     BOOL dragSuccessful = false;
 551     if ( [bestType compare:DataViewPboardType] == NSOrderedSame )
 552     {
 553         NSArray* dataArray((NSArray*)
 554                       [pasteboard propertyListForType:DataViewPboardType]);
 555         NSUInteger indexDraggedItem, noOfDraggedItems([dataArray count]);
 556
 557         indexDraggedItem = 0;
 558         while (indexDraggedItem < noOfDraggedItems)
 559         {
 560             wxDataObjectComposite* dataObjects(
 561                 implementation->GetDnDDataObjects((NSData*)
 562                     [dataArray objectAtIndex:indexDraggedItem]));
 563
 564             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 565             {
 566                 wxMemoryBuffer buffer;
 567
 568                 // copy data into data object:
 569                 event.SetDataObject(dataObjects);
 570                 event.SetDataFormat(
 571                     implementation->GetDnDDataFormat(dataObjects));
 572                 // copy data into buffer:
 573                 dataObjects->GetDataHere(
 574                     event.GetDataFormat().GetType(),
 575                     buffer.GetWriteBuf(event.GetDataSize()));
 576                 buffer.UngetWriteBuf(event.GetDataSize());
 577                 event.SetDataBuffer(buffer.GetData());
 578                 // finally, send event:
 579                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 580                 {
 581                     dragSuccessful = true;
 582                     ++indexDraggedItem;
 583                 }
 584                 else
 585                 {
 586                     dragSuccessful   = true;
 587                     indexDraggedItem = noOfDraggedItems; // stop loop
 588                 }
 589             }
 590             else
 591             {
 592                 dragSuccessful   = false;
 593                 indexDraggedItem = noOfDraggedItems; // stop loop
 594             }
 595             // clean-up:
 596             delete dataObjects;
 597         }
 598     }
 599     else
 600     {
 601         // needed to convert internally used UTF-16 representation to a UTF-8
 602         // representation
 603         CFDataRef              osxData;
 604         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 605         wxTextDataObject*      textDataObject(new wxTextDataObject());
 606
 607         osxData = ::CFStringCreateExternalRepresentation
 608                     (
 609                      kCFAllocatorDefault,
 610                      (CFStringRef)[pasteboard stringForType:NSStringPboardType],
 611                      kCFStringEncodingUTF8,
 612                      32
 613                     );
 614         if (textDataObject->SetData(::CFDataGetLength(osxData),
 615                                     ::CFDataGetBytePtr(osxData)))
 616             dataObjects->Add(textDataObject);
 617         else
 618             delete textDataObject;
 619         // send event if data could be copied:
 620         if (dataObjects->GetFormatCount() > 0)
 621         {
 622             event.SetDataObject(dataObjects);
 623             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 624             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 625                 dragSuccessful = true;
 626             else
 627                 dragSuccessful = false;
 628         }
 629         else
 630             dragSuccessful = false;
 631         // clean up:
 632         ::CFRelease(osxData);
 633         delete dataObjects;
 634     }
 635     return dragSuccessful;
 636 }
 637
 638 -(id) outlineView:(NSOutlineView*)outlineView
 639     child:(NSInteger)index
 640     ofItem:(id)item
 641 {
 642     wxUnusedVar(outlineView);
 643
 644     if ((item == currentParentItem) &&
 645             (index < ((NSInteger) [self getChildCount])))
 646         return [self getChild:index];
 647
 648     wxDataViewItemArray dataViewChildren;
 649
 650     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 651     model->GetChildren(wxDataViewItemFromMaybeNilItem(item), dataViewChildren);
 652     [self bufferItem:item withChildren:&dataViewChildren];
 653     if ([sortDescriptors count] > 0)
 654         [children sortUsingFunction:CompareItems context:sortDescriptors];
 655     return [self getChild:index];
 656 }
 657
 658 -(BOOL) outlineView:(NSOutlineView*)outlineView isItemExpandable:(id)item
 659 {
 660     wxUnusedVar(outlineView);
 661
 662     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 663     return model->IsContainer(wxDataViewItemFromItem(item));
 664 }
 665
 666 -(NSInteger) outlineView:(NSOutlineView*)outlineView numberOfChildrenOfItem:(id)item
 667 {
 668     wxUnusedVar(outlineView);
 669
 670     NSInteger noOfChildren;
 671
 672     wxDataViewItemArray dataViewChildren;
 673
 674
 675     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 676     noOfChildren = model->GetChildren(wxDataViewItemFromMaybeNilItem(item),
 677                                       dataViewChildren);
 678     [self bufferItem:item withChildren:&dataViewChildren];
 679     if ([sortDescriptors count] > 0)
 680         [children sortUsingFunction:CompareItems context:sortDescriptors];
 681     return noOfChildren;
 682 }
 683
 684 -(id)
 685 outlineView:(NSOutlineView*)outlineView
 686     objectValueForTableColumn:(NSTableColumn*)tableColumn
 687     byItem:(id)item
 688 {
 689     wxUnusedVar(outlineView);
 690
 691     wxCHECK_MSG( model, nil, "Valid model in data source does not exist." );
 692
 693     wxDataViewColumn* const
 694         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
 695     const unsigned colIdx = col->GetModelColumn();
 696
 697     wxDataViewItem dataViewItem(wxDataViewItemFromItem(item));
 698
 699     if ( model->HasValue(dataViewItem, colIdx) )
 700     {
 701         wxVariant value;
 702         model->GetValue(value,dataViewItem, colIdx);
 703         col->GetRenderer()->SetValue(value);
 704     }
 705
 706     return nil;
 707 }
 708
 709 -(void)
 710 outlineView:(NSOutlineView*)outlineView
 711     setObjectValue:(id)object
 712     forTableColumn:(NSTableColumn*)tableColumn
 713     byItem:(id)item
 714 {
 715     wxUnusedVar(outlineView);
 716
 717     wxDataViewColumn* const
 718         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
 719
 720     col->GetRenderer()->
 721         OSXOnCellChanged(object, wxDataViewItemFromItem(item), col->GetModelColumn());
 722 }
 723
 724 -(void) outlineView:(NSOutlineView*)outlineView sortDescriptorsDidChange:(NSArray*)oldDescriptors
 725 {
 726     wxUnusedVar(oldDescriptors);
 727
 728     // Warning: the new sort descriptors are guaranteed to be only of type
 729     // NSSortDescriptor! Therefore, the sort descriptors for the data source
 730     // have to be converted.
 731     NSArray* newDescriptors;
 732
 733     NSMutableArray* wxSortDescriptors;
 734
 735     NSUInteger noOfDescriptors;
 736
 737     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 738
 739
 740     // convert NSSortDescriptors to wxSortDescriptorObjects:
 741     newDescriptors    = [outlineView sortDescriptors];
 742     noOfDescriptors   = [newDescriptors count];
 743     wxSortDescriptors = [NSMutableArray arrayWithCapacity:noOfDescriptors];
 744     for (NSUInteger i=0; i<noOfDescriptors; ++i)
 745     {
 746         NSSortDescriptor* const newDescriptor = [newDescriptors objectAtIndex:i];
 747
 748         [wxSortDescriptors addObject:[[[wxSortDescriptorObject alloc] initWithModelPtr:model
 749             sortingColumnPtr:dvc->GetColumn([[newDescriptor key] intValue])
 750             ascending:[newDescriptor ascending]] autorelease]];
 751     }
 752     [(wxCocoaOutlineDataSource*)[outlineView dataSource] setSortDescriptors:wxSortDescriptors];
 753
 754     // send first the event to wxWidgets that the sorting has changed so that
 755     // the program can do special actions before the sorting actually starts:
 756     wxDataViewEvent event(wxEVT_DATAVIEW_COLUMN_SORTED,dvc->GetId()); // variable definition
 757
 758     event.SetEventObject(dvc);
 759     if (noOfDescriptors > 0)
 760     {
 761         wxDataViewColumn* const col = [[wxSortDescriptors objectAtIndex:0] columnPtr];
 762
 763         event.SetColumn(dvc->GetColumnPosition(col));
 764         event.SetDataViewColumn(col);
 765     }
 766     dvc->GetEventHandler()->ProcessEvent(event);
 767
 768     // start re-ordering the data;
 769     // children's buffer must be cleared first because it contains the old order:
 770     [self clearChildren];
 771     // sorting is done while reloading the data:
 772     [outlineView reloadData];
 773 }
 774
 775 -(NSDragOperation) outlineView:(NSOutlineView*)outlineView validateDrop:(id<NSDraggingInfo>)info proposedItem:(id)item proposedChildIndex:(NSInteger)index
 776 {
 777     wxUnusedVar(outlineView);
 778     wxUnusedVar(index);
 779
 780     NSArray* supportedTypes([NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]);
 781
 782     NSPasteboard* pasteboard([info draggingPasteboard]);
 783
 784     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 785     if (bestType == nil)
 786         return NSDragOperationNone;
 787
 788     NSDragOperation dragOperation = NSDragOperationNone;
 789     wxDataViewCtrl* const dvc(implementation->GetDataViewCtrl());
 790
 791     wxCHECK_MSG(dvc, false, "Pointer to data view control not set correctly.");
 792     wxCHECK_MSG(dvc->GetModel(), false, "Pointer to model not set correctly.");
 793
 794     wxDataViewEvent
 795         event(wxEVT_DATAVIEW_ITEM_DROP_POSSIBLE,dvc->GetId());
 796
 797     event.SetEventObject(dvc);
 798     event.SetItem(wxDataViewItemFromItem(item));
 799     event.SetModel(dvc->GetModel());
 800     if ([bestType compare:DataViewPboardType] == NSOrderedSame)
 801     {
 802         NSArray*               dataArray((NSArray*)[pasteboard propertyListForType:DataViewPboardType]);
 803         NSUInteger             indexDraggedItem, noOfDraggedItems([dataArray count]);
 804
 805         indexDraggedItem = 0;
 806         while (indexDraggedItem < noOfDraggedItems)
 807         {
 808             wxDataObjectComposite* dataObjects(implementation->GetDnDDataObjects((NSData*)[dataArray objectAtIndex:indexDraggedItem]));
 809
 810             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 811             {
 812                 wxMemoryBuffer buffer;
 813
 814                 // copy data into data object:
 815                 event.SetDataObject(dataObjects);
 816                 event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 817                 // copy data into buffer:
 818                 dataObjects->GetDataHere(event.GetDataFormat().GetType(),buffer.GetWriteBuf(event.GetDataSize()));
 819                 buffer.UngetWriteBuf(event.GetDataSize());
 820                 event.SetDataBuffer(buffer.GetData());
 821                 // finally, send event:
 822                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 823                 {
 824                     dragOperation = NSDragOperationEvery;
 825                     ++indexDraggedItem;
 826                 }
 827                 else
 828                 {
 829                     dragOperation    = NSDragOperationNone;
 830                     indexDraggedItem = noOfDraggedItems; // stop loop
 831                 }
 832             }
 833             else
 834             {
 835                 dragOperation    = NSDragOperationNone;
 836                 indexDraggedItem = noOfDraggedItems; // stop loop
 837             }
 838             // clean-up:
 839             delete dataObjects;
 840         }
 841     }
 842     else
 843     {
 844         // needed to convert internally used UTF-16 representation to a UTF-8
 845         // representation
 846         CFDataRef              osxData;
 847         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 848         wxTextDataObject*      textDataObject(new wxTextDataObject());
 849
 850         osxData = ::CFStringCreateExternalRepresentation(kCFAllocatorDefault,(CFStringRef)[pasteboard stringForType:NSStringPboardType],kCFStringEncodingUTF8,32);
 851         if (textDataObject->SetData(::CFDataGetLength(osxData),::CFDataGetBytePtr(osxData)))
 852             dataObjects->Add(textDataObject);
 853         else
 854             delete textDataObject;
 855         // send event if data could be copied:
 856         if (dataObjects->GetFormatCount() > 0)
 857         {
 858             event.SetDataObject(dataObjects);
 859             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 860             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 861                 dragOperation = NSDragOperationEvery;
 862             else
 863                 dragOperation = NSDragOperationNone;
 864         }
 865         else
 866             dragOperation = NSDragOperationNone;
 867         // clean up:
 868         ::CFRelease(osxData);
 869         delete dataObjects;
 870     }
 871
 872     return dragOperation;
 873 }
 874
 875 -(BOOL) outlineView:(NSOutlineView*)outlineView writeItems:(NSArray*)writeItems toPasteboard:(NSPasteboard*)pasteboard
 876 {
 877     wxUnusedVar(outlineView);
 878
 879     // the pasteboard will be filled up with an array containing the data as
 880     // returned by the events (including the data type) and a concatenation of
 881     // text (string) data; the text data will only be put onto the pasteboard
 882     // if for all items a string representation exists
 883     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 884
 885     wxDataViewItemArray dataViewItems;
 886
 887
 888     wxCHECK_MSG(dvc, false,"Pointer to data view control not set correctly.");
 889     wxCHECK_MSG(dvc->GetModel(),false,"Pointer to model not set correctly.");
 890
 891     if ([writeItems count] > 0)
 892     {
 893         bool            dataStringAvailable(true); // a flag indicating if for all items a data string is available
 894         NSMutableArray* dataArray = [NSMutableArray arrayWithCapacity:[writeItems count]]; // data of all items
 895         wxString        dataString; // contains the string data of all items
 896
 897         // send a begin drag event for all selected items and proceed with
 898         // dragging unless the event is vetoed:
 899         wxDataViewEvent
 900             event(wxEVT_DATAVIEW_ITEM_BEGIN_DRAG,dvc->GetId());
 901
 902         event.SetEventObject(dvc);
 903         event.SetModel(dvc->GetModel());
 904         for (size_t itemCounter=0; itemCounter<[writeItems count]; ++itemCounter)
 905         {
 906             bool                   itemStringAvailable(false);              // a flag indicating if for the current item a string is available
 907             wxDataObjectComposite* itemObject(new wxDataObjectComposite()); // data object for current item
 908             wxString               itemString;                              // contains the TAB concatenated data of an item
 909
 910             event.SetItem(
 911                 wxDataViewItemFromItem([writeItems objectAtIndex:itemCounter]));
 912             itemString = ::ConcatenateDataViewItemValues(dvc,event.GetItem());
 913             itemObject->Add(new wxTextDataObject(itemString));
 914             event.SetDataObject(itemObject);
 915             // check if event has not been vetoed:
 916             if (dvc->HandleWindowEvent(event) && event.IsAllowed() && (event.GetDataObject()->GetFormatCount() > 0))
 917             {
 918                 size_t const noOfFormats = event.GetDataObject()->GetFormatCount();
 919                 wxDataFormat* dataFormats(new wxDataFormat[noOfFormats]);
 920
 921                 event.GetDataObject()->GetAllFormats(dataFormats,wxDataObject::Get);
 922                 for (size_t formatCounter=0; formatCounter<noOfFormats; ++formatCounter)
 923                 {
 924                     // constant definitions for abbreviational purposes:
 925                     wxDataFormatId const idDataFormat = dataFormats[formatCounter].GetType();
 926                     size_t const dataSize       = event.GetDataObject()->GetDataSize(idDataFormat);
 927                     size_t const dataBufferSize = sizeof(wxDataFormatId)+dataSize;
 928                     // variable definitions (used in all case statements):
 929                     // give additional headroom for trailing NULL
 930                     wxMemoryBuffer dataBuffer(dataBufferSize+4);
 931
 932                     dataBuffer.AppendData(&idDataFormat,sizeof(wxDataFormatId));
 933                     switch (idDataFormat)
 934                     {
 935                         case wxDF_TEXT:
 936                             // otherwise wxDF_UNICODETEXT already filled up
 937                             // the string; and the UNICODE representation has
 938                             // priority
 939                             if (!itemStringAvailable)
 940                             {
 941                                 event.GetDataObject()->GetDataHere(wxDF_TEXT,dataBuffer.GetAppendBuf(dataSize));
 942                                 dataBuffer.UngetAppendBuf(dataSize);
 943                                 [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 944                                 itemString = wxString(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),wxConvLocal);
 945                                 itemStringAvailable = true;
 946                             }
 947                             break;
 948                         case wxDF_UNICODETEXT:
 949                             {
 950                                 event.GetDataObject()->GetDataHere(wxDF_UNICODETEXT,dataBuffer.GetAppendBuf(dataSize));
 951                                 dataBuffer.UngetAppendBuf(dataSize);
 952                                 if (itemStringAvailable) // does an object already exist as an ASCII text (see wxDF_TEXT case statement)?
 953                                     [dataArray replaceObjectAtIndex:itemCounter withObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 954                                 else
 955                                     [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 956                                 itemString = wxString::FromUTF8(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),dataSize);
 957                                 itemStringAvailable = true;
 958                             } /* block */
 959                             break;
 960                         default:
 961                             wxFAIL_MSG("Data object has invalid or unsupported data format");
 962                             return NO;
 963                     }
 964                 }
 965                 delete[] dataFormats;
 966                 delete itemObject;
 967                 if (dataStringAvailable)
 968                     if (itemStringAvailable)
 969                     {
 970                         if (itemCounter > 0)
 971                             dataString << wxT('\n');
 972                         dataString << itemString;
 973                     }
 974                     else
 975                         dataStringAvailable = false;
 976             }
 977             else
 978             {
 979                 delete itemObject;
 980                 return NO; // dragging was vetoed or no data available
 981             }
 982         }
 983         if (dataStringAvailable)
 984         {
 985             wxCFStringRef osxString(dataString);
 986
 987             [pasteboard declareTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil] owner:nil];
 988             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 989             [pasteboard setString:osxString.AsNSString() forType:NSStringPboardType];
 990         }
 991         else
 992         {
 993             [pasteboard declareTypes:[NSArray arrayWithObject:DataViewPboardType] owner:nil];
 994             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 995         }
 996         return YES;
 997     }
 998     else
 999         return NO; // no items to drag (should never occur)
1000 }
1001
1002 //
1003 // buffer handling
1004 //
1005 -(void) addToBuffer:(wxPointerObject*)item
1006 {
1007     [items addObject:item];
1008 }
1009
1010 -(void) clearBuffer
1011 {
1012     [items removeAllObjects];
1013 }
1014
1015 -(wxPointerObject*) getDataViewItemFromBuffer:(const wxDataViewItem&)item
1016 {
1017     return [items member:[[[wxPointerObject alloc] initWithPointer:item.GetID()] autorelease]];
1018 }
1019
1020 -(wxPointerObject*) getItemFromBuffer:(wxPointerObject*)item
1021 {
1022     return [items member:item];
1023 }
1024
1025 -(BOOL) isInBuffer:(wxPointerObject*)item
1026 {
1027     return [items containsObject:item];
1028 }
1029
1030 -(void) removeFromBuffer:(wxPointerObject*)item
1031 {
1032     [items removeObject:item];
1033 }
1034
1035 //
1036 // children handling
1037 //
1038 -(void) appendChild:(wxPointerObject*)item
1039 {
1040     [children addObject:item];
1041 }
1042
1043 -(void) clearChildren
1044 {
1045     [children removeAllObjects];
1046 }
1047
1048 -(wxPointerObject*) getChild:(NSUInteger)index
1049 {
1050     return [children objectAtIndex:index];
1051 }
1052
1053 -(NSUInteger) getChildCount
1054 {
1055     return [children count];
1056 }
1057
1058 -(void) removeChild:(NSUInteger)index
1059 {
1060     [children removeObjectAtIndex:index];
1061 }
1062
1063 //
1064 // buffer handling
1065 //
1066 -(void) clearBuffers
1067 {
1068     [self clearBuffer];
1069     [self clearChildren];
1070     [self setCurrentParentItem:nil];
1071 }
1072
1073 //
1074 // sorting
1075 //
1076 -(NSArray*) sortDescriptors
1077 {
1078     return sortDescriptors;
1079 }
1080
1081 -(void) setSortDescriptors:(NSArray*)newSortDescriptors
1082 {
1083     [newSortDescriptors retain];
1084     [sortDescriptors release];
1085     sortDescriptors = newSortDescriptors;
1086 }
1087
1088 //
1089 // access to wxWidget's implementation
1090 //
1091 -(wxPointerObject*) currentParentItem
1092 {
1093     return currentParentItem;
1094 }
1095
1096 -(wxCocoaDataViewControl*) implementation
1097 {
1098     return implementation;
1099 }
1100
1101 -(wxDataViewModel*) model
1102 {
1103     return model;
1104 }
1105
1106 -(void) setCurrentParentItem:(wxPointerObject*)newCurrentParentItem
1107 {
1108     [newCurrentParentItem retain];
1109     [currentParentItem release];
1110     currentParentItem = newCurrentParentItem;
1111 }
1112
1113 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1114 {
1115     implementation = newImplementation;
1116 }
1117
1118 -(void) setModel:(wxDataViewModel*) newModel
1119 {
1120     model = newModel;
1121 }
1122
1123 //
1124 // other methods
1125 //
1126 -(void) bufferItem:(wxPointerObject*)parentItem withChildren:(wxDataViewItemArray*)dataViewChildrenPtr
1127 {
1128     NSInteger const noOfChildren = (*dataViewChildrenPtr).GetCount();
1129
1130     [self setCurrentParentItem:parentItem];
1131     [self clearChildren];
1132     for (NSInteger indexChild=0; indexChild<noOfChildren; ++indexChild)
1133     {
1134         wxPointerObject* bufferedPointerObject;
1135         wxPointerObject* newPointerObject([[wxPointerObject alloc] initWithPointer:(*dataViewChildrenPtr)[indexChild].GetID()]);
1136
1137         // The next statement and test looks strange but there is
1138         // unfortunately no workaround: due to the fact that two pointer
1139         // objects are identical if their pointers are identical - because the
1140         // method isEqual has been overloaded - the set operation will only
1141         // add a new pointer object if there is not already one in the set
1142         // having the same pointer. On the other side the children's array
1143         // would always add the new pointer object. This means that different
1144         // pointer objects are stored in the set and array. This will finally
1145         // lead to a crash as objects diverge. To solve this issue it is first
1146         // tested if the child already exists in the set and if it is the case
1147         // the sets object is going to be appended to the array, otheriwse the
1148         // new pointer object is added to the set and array:
1149         bufferedPointerObject = [self getItemFromBuffer:newPointerObject];
1150         if (bufferedPointerObject == nil)
1151         {
1152             [items    addObject:newPointerObject];
1153             [children addObject:newPointerObject];
1154         }
1155         else
1156             [children addObject:bufferedPointerObject];
1157         [newPointerObject release];
1158     }
1159 }
1160
1161 @end
1162
1163 // ============================================================================
1164 // wxCustomCell
1165 // ============================================================================
1166
1167 @implementation wxCustomCell
1168
1169 #if 0 // starting implementation for custom cell clicks
1170
1171 - (id)init
1172 {
1173     self = [super init];
1174     [self setAction:@selector(clickedAction)];
1175     [self setTarget:self];
1176     return self;
1177 }
1178
1179 - (void) clickedAction: (id) sender
1180 {
1181     wxUnusedVar(sender);
1182 }
1183
1184 #endif
1185
1186 -(NSSize) cellSize
1187 {
1188     wxCustomRendererObject * const
1189         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1190
1191
1192     const wxSize size = obj->customRenderer->GetSize();
1193     return NSMakeSize(size.x, size.y);
1194 }
1195
1196 //
1197 // implementations
1198 //
1199 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1200 {
1201     wxCustomRendererObject * const
1202         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1203     if ( !obj )
1204     {
1205         // this may happen for the custom cells in container rows: they don't
1206         // have any values
1207         return;
1208     }
1209
1210     wxDataViewCustomRenderer * const renderer = obj->customRenderer;
1211
1212     // if this method is called everything is already setup correctly,
1213     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1214     CGContextSaveGState( context );
1215
1216     if ( ![controlView isFlipped] )
1217     {
1218         CGContextTranslateCTM( context, 0,  [controlView bounds].size.height );
1219         CGContextScaleCTM( context, 1, -1 );
1220     }
1221
1222     wxGCDC dc;
1223     wxGraphicsContext* gc = wxGraphicsContext::CreateFromNative(context);
1224     dc.SetGraphicsContext(gc);
1225
1226     int state = 0;
1227     if ( [self isHighlighted] )
1228         state |= wxDATAVIEW_CELL_SELECTED;
1229
1230     renderer->WXCallRender(wxFromNSRect(controlView, cellFrame), &dc, state);
1231
1232     CGContextRestoreGState( context );
1233 }
1234
1235 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1236 {
1237     return cellFrame;
1238 }
1239
1240 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1241 {
1242     return cellFrame;
1243 }
1244
1245 @end
1246
1247 // ============================================================================
1248 // wxImageTextCell
1249 // ============================================================================
1250 @implementation wxImageTextCell
1251 //
1252 // initialization
1253 //
1254 -(id) init
1255 {
1256     self = [super init];
1257     if (self != nil)
1258     {
1259         // initializing the text part:
1260         [self setSelectable:YES];
1261         // initializing the image part:
1262         image       = nil;
1263         imageSize   = NSMakeSize(16,16);
1264         spaceImageText = 5.0;
1265         xImageShift    = 5.0;
1266     }
1267     return self;
1268 }
1269
1270 -(id) copyWithZone:(NSZone*)zone
1271 {
1272     wxImageTextCell* cell;
1273
1274
1275     cell = (wxImageTextCell*) [super copyWithZone:zone];
1276     cell->image          = [image retain];
1277     cell->imageSize      = imageSize;
1278     cell->spaceImageText = spaceImageText;
1279     cell->xImageShift    = xImageShift;
1280
1281     return cell;
1282 }
1283
1284 -(void) dealloc
1285 {
1286     [image release];
1287
1288     [super dealloc];
1289 }
1290
1291 //
1292 // alignment
1293 //
1294 -(NSTextAlignment) alignment
1295 {
1296     return cellAlignment;
1297 }
1298
1299 -(void) setAlignment:(NSTextAlignment)newAlignment
1300 {
1301     cellAlignment = newAlignment;
1302     switch (newAlignment)
1303     {
1304         case NSCenterTextAlignment:
1305         case NSLeftTextAlignment:
1306         case NSJustifiedTextAlignment:
1307         case NSNaturalTextAlignment:
1308             [super setAlignment:NSLeftTextAlignment];
1309             break;
1310         case NSRightTextAlignment:
1311             [super setAlignment:NSRightTextAlignment];
1312             break;
1313         default:
1314             wxFAIL_MSG("Unknown alignment type.");
1315     }
1316 }
1317
1318 //
1319 // image access
1320 //
1321 -(NSImage*) image
1322 {
1323     return image;
1324 }
1325
1326 -(void) setImage:(NSImage*)newImage
1327 {
1328     [newImage retain];
1329     [image release];
1330     image = newImage;
1331 }
1332
1333 -(NSSize) imageSize
1334 {
1335     return imageSize;
1336 }
1337
1338 -(void) setImageSize:(NSSize) newImageSize
1339 {
1340     imageSize = newImageSize;
1341 }
1342
1343 //
1344 // other methods
1345 //
1346 -(NSSize) cellImageSize
1347 {
1348     return NSMakeSize(imageSize.width+xImageShift+spaceImageText,imageSize.height);
1349 }
1350
1351 -(NSSize) cellSize
1352 {
1353     NSSize cellSize([super cellSize]);
1354
1355
1356     if (imageSize.height > cellSize.height)
1357         cellSize.height = imageSize.height;
1358     cellSize.width += imageSize.width+xImageShift+spaceImageText;
1359
1360     return cellSize;
1361 }
1362
1363 -(NSSize) cellTextSize
1364 {
1365     return [super cellSize];
1366 }
1367
1368 //
1369 // implementations
1370 //
1371 -(void) determineCellParts:(NSRect)cellFrame imagePart:(NSRect*)imageFrame textPart:(NSRect*)textFrame
1372 {
1373     switch (cellAlignment)
1374     {
1375         case NSCenterTextAlignment:
1376             {
1377                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1378
1379                 // if the cell's frame is smaller than its contents (at least
1380                 // in x-direction) make sure that the image is visible:
1381                 if (cellSpace <= 0)
1382                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1383                 else // otherwise center the image and text in the cell's frame
1384                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+0.5*cellSpace,NSMinXEdge);
1385             }
1386             break;
1387         case NSJustifiedTextAlignment:
1388         case NSLeftTextAlignment:
1389         case NSNaturalTextAlignment: // how to determine the natural writing direction? TODO
1390             NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1391             break;
1392         case NSRightTextAlignment:
1393             {
1394                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1395
1396                 // if the cell's frame is smaller than its contents (at least
1397                 // in x-direction) make sure that the image is visible:
1398                 if (cellSpace <= 0)
1399                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1400                 else // otherwise right align the image and text in the cell's frame
1401                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+cellSpace,NSMinXEdge);
1402             }
1403             break;
1404         default:
1405             *imageFrame = NSZeroRect;
1406             *textFrame  = NSZeroRect;
1407             wxFAIL_MSG("Unhandled alignment type.");
1408     }
1409 }
1410
1411 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1412 {
1413     NSRect textFrame, imageFrame;
1414
1415
1416     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1417     // draw the image part by ourselves;
1418     // check if the cell has to draw its own background (checking is done by
1419     // the parameter of the textfield's cell):
1420     if ([self drawsBackground])
1421     {
1422         [[self backgroundColor] set];
1423         NSRectFill(imageFrame);
1424     }
1425     if (image != nil)
1426     {
1427         // the image is slightly shifted (xImageShift) and has a fixed size
1428         // but the image's frame might be larger and starts currently on the
1429         // left side of the cell's frame; therefore, the origin and the
1430         // image's frame size have to be adjusted:
1431         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1432         {
1433             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1434             imageFrame.size.width = imageSize.width;
1435         }
1436         else
1437         {
1438             imageFrame.origin.x   += xImageShift;
1439             imageFrame.size.width -= xImageShift+spaceImageText;
1440         }
1441         // ...and the image has to be centered in the y-direction:
1442         if (imageFrame.size.height > imageSize.height)
1443             imageFrame.size.height = imageSize.height;
1444         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1445
1446         // according to the documentation the coordinate system should be
1447         // flipped for NSTableViews (y-coordinate goes from top to bottom); to
1448         // draw an image correctly the coordinate system has to be transformed
1449         // to a bottom-top coordinate system, otherwise the image's
1450         // content is flipped:
1451         NSAffineTransform* coordinateTransform([NSAffineTransform transform]);
1452
1453         if ([controlView isFlipped])
1454         {
1455             [coordinateTransform scaleXBy: 1.0 yBy:-1.0]; // first the coordinate system is brought back to bottom-top orientation
1456             [coordinateTransform translateXBy:0.0 yBy:(-2.0)*imageFrame.origin.y-imageFrame.size.height]; // the coordinate system has to be moved to compensate for the
1457             [coordinateTransform concat];                                                                 // other orientation and the position of the image's frame
1458         }
1459         [image drawInRect:imageFrame fromRect:NSZeroRect operation:NSCompositeSourceOver fraction:1.0]; // suggested method to draw the image
1460         // instead of compositeToPoint:operation:
1461         // take back previous transformation (if the view is not flipped the
1462         // coordinate transformation matrix contains the identity matrix and
1463         // the next two operations do not change the content's transformation
1464         // matrix):
1465         [coordinateTransform invert];
1466         [coordinateTransform concat];
1467     }
1468     // let the textfield cell draw the text part:
1469     if (textFrame.size.width > [self cellTextSize].width)
1470     {
1471         // for unknown reasons the alignment of the text cell is ignored;
1472         // therefore change the size so that alignment does not influence the
1473         // visualization anymore
1474         textFrame.size.width = [self cellTextSize].width;
1475     }
1476     [super drawWithFrame:textFrame inView:controlView];
1477 }
1478
1479 -(void) editWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject event:(NSEvent*)theEvent
1480 {
1481     NSRect textFrame, imageFrame;
1482
1483
1484     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1485     [super editWithFrame:textFrame inView:controlView editor:textObj delegate:anObject event:theEvent];
1486 }
1487
1488 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
1489 -(NSUInteger) hitTestForEvent:(NSEvent*)event inRect:(NSRect)cellFrame ofView:(NSView*)controlView
1490 {
1491     NSPoint point = [controlView convertPoint:[event locationInWindow] fromView:nil];
1492
1493     NSRect imageFrame, textFrame;
1494
1495
1496     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1497     if (image != nil)
1498     {
1499         // the image is shifted...
1500         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1501         {
1502             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1503             imageFrame.size.width = imageSize.width;
1504         }
1505         else
1506         {
1507             imageFrame.origin.x   += xImageShift;
1508             imageFrame.size.width -= xImageShift+spaceImageText;
1509         }
1510         // ...and centered:
1511         if (imageFrame.size.height > imageSize.height)
1512             imageFrame.size.height = imageSize.height;
1513         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1514         // If the point is in the image rect, then it is a content hit (see
1515         // documentation for hitTestForEvent:inRect:ofView):
1516         if (NSMouseInRect(point, imageFrame, [controlView isFlipped]))
1517             return NSCellHitContentArea;
1518     }
1519     // if the image was not hit let's try the text part:
1520     if (textFrame.size.width > [self cellTextSize].width)
1521     {
1522         // for unknown reasons the alignment of the text cell is ignored;
1523         // therefore change the size so that alignment does not influence the
1524         // visualization anymore
1525         textFrame.size.width = [self cellTextSize].width;
1526     }
1527
1528     return [super hitTestForEvent:event inRect:textFrame ofView:controlView];
1529 }
1530 #endif
1531
1532 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1533 {
1534     NSRect textFrame, imageFrame;
1535
1536
1537     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1538     if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1539     {
1540         imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1541         imageFrame.size.width = imageSize.width;
1542     }
1543     else
1544     {
1545         imageFrame.origin.x   += xImageShift;
1546         imageFrame.size.width -= xImageShift+spaceImageText;
1547     }
1548     // ...and centered:
1549     if (imageFrame.size.height > imageSize.height)
1550         imageFrame.size.height = imageSize.height;
1551     imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1552
1553     return imageFrame;
1554 }
1555
1556 -(void) selectWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject start:(NSInteger)selStart length:(NSInteger)selLength
1557 {
1558     NSRect textFrame, imageFrame;
1559
1560
1561     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1562     [super selectWithFrame:textFrame inView:controlView editor:textObj delegate:anObject start:selStart length:selLength];
1563 }
1564
1565 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1566 {
1567     NSRect textFrame, imageFrame;
1568
1569
1570     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1571     return textFrame;
1572 }
1573
1574 @end
1575
1576 // ============================================================================
1577 // wxCocoaOutlineView
1578 // ============================================================================
1579 @implementation wxCocoaOutlineView
1580
1581 //
1582 // initializers / destructor
1583 //
1584 -(id) init
1585 {
1586     self = [super init];
1587     if (self != nil)
1588     {
1589         currentlyEditedColumn =
1590             currentlyEditedRow = -1;
1591
1592         [self registerForDraggedTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]];
1593         [self setDelegate:self];
1594         [self setDoubleAction:@selector(actionDoubleClick:)];
1595         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:NO];
1596         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:YES];
1597         [self setTarget:self];
1598     }
1599     return self;
1600 }
1601
1602 //
1603 // access to wxWidget's implementation
1604 //
1605 -(wxCocoaDataViewControl*) implementation
1606 {
1607     return implementation;
1608 }
1609
1610 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1611 {
1612     implementation = newImplementation;
1613 }
1614
1615 //
1616 // actions
1617 //
1618 -(void) actionDoubleClick:(id)sender
1619 {
1620     wxUnusedVar(sender);
1621
1622     // actually the documentation (NSTableView 2007-10-31) for doubleAction:
1623     // and setDoubleAction: seems to be wrong as this action message is always
1624     // sent whether the cell is editable or not
1625     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1626
1627     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_ACTIVATED,dvc->GetId());
1628
1629
1630     event.SetEventObject(dvc);
1631     event.SetItem(wxDataViewItemFromItem([self itemAtRow:[self clickedRow]]));
1632     dvc->GetEventHandler()->ProcessEvent(event);
1633 }
1634
1635
1636 //
1637 // contextual menus
1638 //
1639 -(NSMenu*) menuForEvent:(NSEvent*)theEvent
1640 {
1641     wxUnusedVar(theEvent);
1642
1643     // this method does not do any special menu event handling but only sends
1644     // an event message; therefore, the user has full control if a context
1645     // menu should be shown or not
1646     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1647
1648     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_CONTEXT_MENU,dvc->GetId());
1649
1650     wxDataViewItemArray selectedItems;
1651
1652
1653     event.SetEventObject(dvc);
1654     event.SetModel(dvc->GetModel());
1655     // get the item information;
1656     // theoretically more than one ID can be returned but the event can only
1657     // handle one item, therefore only the first item of the array is
1658     // returned:
1659     if (dvc->GetSelections(selectedItems) > 0)
1660         event.SetItem(selectedItems[0]);
1661     dvc->GetEventHandler()->ProcessEvent(event);
1662     // nothing is done:
1663     return nil;
1664 }
1665
1666 //
1667 // delegate methods
1668 //
1669 -(void) outlineView:(NSOutlineView*)outlineView mouseDownInHeaderOfTableColumn:(NSTableColumn*)tableColumn
1670 {
1671     wxDataViewColumn* const
1672         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1673
1674     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1675
1676     wxDataViewEvent
1677         event(wxEVT_DATAVIEW_COLUMN_HEADER_CLICK,dvc->GetId());
1678
1679
1680     // first, send an event that the user clicked into a column's header:
1681     event.SetEventObject(dvc);
1682     event.SetColumn(dvc->GetColumnPosition(col));
1683     event.SetDataViewColumn(col);
1684     dvc->HandleWindowEvent(event);
1685
1686     // now, check if the click may have had an influence on sorting, too;
1687     // the sorting setup has to be done only if the clicked table column is
1688     // sortable and has not been used for sorting before the click; if the
1689     // column is already responsible for sorting the native control changes
1690     // the sorting direction automatically and informs the data source via
1691     // outlineView:sortDescriptorsDidChange:
1692     if (col->IsSortable() && ([tableColumn sortDescriptorPrototype] == nil))
1693     {
1694         // remove the sort order from the previously sorted column table (it
1695         // can also be that no sorted column table exists):
1696         UInt32 const noOfColumns = [outlineView numberOfColumns];
1697
1698         for (UInt32 i=0; i<noOfColumns; ++i)
1699             [[[outlineView tableColumns] objectAtIndex:i] setSortDescriptorPrototype:nil];
1700         // make column table sortable:
1701         NSArray*          sortDescriptors;
1702         NSSortDescriptor* sortDescriptor;
1703
1704         sortDescriptor = [[NSSortDescriptor alloc] initWithKey:[NSString stringWithFormat:@"%d",[outlineView columnWithIdentifier:[tableColumn identifier]]]
1705             ascending:YES];
1706         sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
1707         [tableColumn setSortDescriptorPrototype:sortDescriptor];
1708         [outlineView setSortDescriptors:sortDescriptors];
1709         [sortDescriptor release];
1710     }
1711 }
1712
1713 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldCollapseItem:(id)item
1714 {
1715     wxUnusedVar(outlineView);
1716
1717     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1718
1719     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_COLLAPSING,dvc->GetId());
1720
1721
1722     event.SetEventObject(dvc);
1723     event.SetItem       (wxDataViewItemFromItem(item));
1724     event.SetModel      (dvc->GetModel());
1725     // finally send the equivalent wxWidget event:
1726     dvc->GetEventHandler()->ProcessEvent(event);
1727     // opening the container is allowed if not vetoed:
1728     return event.IsAllowed();
1729 }
1730
1731 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldExpandItem:(id)item
1732 {
1733     wxUnusedVar(outlineView);
1734
1735     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1736
1737     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_EXPANDING,dvc->GetId());
1738
1739
1740     event.SetEventObject(dvc);
1741     event.SetItem       (wxDataViewItemFromItem(item));
1742     event.SetModel      (dvc->GetModel());
1743     // finally send the equivalent wxWidget event:
1744     dvc->GetEventHandler()->ProcessEvent(event);
1745     // opening the container is allowed if not vetoed:
1746     return event.IsAllowed();
1747 }
1748
1749 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldSelectTableColumn:(NSTableColumn*)tableColumn
1750 {
1751     wxUnusedVar(tableColumn);
1752     wxUnusedVar(outlineView);
1753
1754     return NO;
1755 }
1756
1757 -(void) outlineView:(wxCocoaOutlineView*)outlineView
1758     willDisplayCell:(id)cell
1759     forTableColumn:(NSTableColumn*)tableColumn
1760     item:(id)item
1761 {
1762     wxUnusedVar(outlineView);
1763
1764     wxDataViewCtrl * const dvc = implementation->GetDataViewCtrl();
1765     wxDataViewModel * const model = dvc->GetModel();
1766
1767     wxDataViewColumn* const
1768         dvCol([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1769     const unsigned colIdx = dvCol->GetModelColumn();
1770
1771     wxDataViewItem dvItem(wxDataViewItemFromItem(item));
1772
1773     if ( !model->HasValue(dvItem, colIdx) )
1774         return;
1775
1776     wxDataViewRenderer * const renderer = dvCol->GetRenderer();
1777     wxDataViewRendererNativeData * const data = renderer->GetNativeData();
1778
1779     // let the renderer know about what it's going to render next
1780     data->SetColumnPtr(tableColumn);
1781     data->SetItem(item);
1782     data->SetItemCell(cell);
1783
1784     // use the attributes: notice that we need to do this whether we have them
1785     // or not as even if this cell doesn't have any attributes, the previous
1786     // one might have had some and then we need to reset them back to default
1787     wxDataViewItemAttr attr;
1788     model->GetAttr(dvItem, colIdx, attr);
1789     renderer->OSXApplyAttr(attr);
1790
1791     // set the state (enabled/disabled) of the item
1792     renderer->OSXApplyEnabled(model->IsEnabled(dvItem, colIdx));
1793
1794     // and finally do draw it
1795     renderer->MacRender();
1796 }
1797
1798 //
1799 // notifications
1800 //
1801 -(void) outlineViewColumnDidMove:(NSNotification*)notification
1802 {
1803     int const newColumnPosition = [[[notification userInfo] objectForKey:@"NSNewColumn"] intValue];
1804
1805     NSTableColumn*
1806         tableColumn = [[self tableColumns] objectAtIndex:newColumnPosition];
1807     wxDataViewColumn* const
1808         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1809
1810     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1811
1812     wxDataViewEvent event(wxEVT_DATAVIEW_COLUMN_REORDERED,dvc->GetId());
1813
1814
1815     event.SetEventObject(dvc);
1816     event.SetColumn(dvc->GetColumnPosition(col));
1817     event.SetDataViewColumn(col);
1818     dvc->GetEventHandler()->ProcessEvent(event);
1819 }
1820
1821 -(void) outlineViewItemDidCollapse:(NSNotification*)notification
1822 {
1823     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1824
1825     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_COLLAPSED,dvc->GetId());
1826
1827
1828     event.SetEventObject(dvc);
1829     event.SetItem(wxDataViewItemFromItem(
1830                     [[notification userInfo] objectForKey:@"NSObject"]));
1831     dvc->GetEventHandler()->ProcessEvent(event);
1832 }
1833
1834 -(void) outlineViewItemDidExpand:(NSNotification*)notification
1835 {
1836     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1837
1838     wxDataViewEvent event(wxEVT_DATAVIEW_ITEM_EXPANDED,dvc->GetId());
1839
1840
1841     event.SetEventObject(dvc);
1842     event.SetItem(wxDataViewItemFromItem(
1843                     [[notification userInfo] objectForKey:@"NSObject"]));
1844     dvc->GetEventHandler()->ProcessEvent(event);
1845 }
1846
1847 -(void) outlineViewSelectionDidChange:(NSNotification*)notification
1848 {
1849     wxUnusedVar(notification);
1850
1851     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1852
1853     wxDataViewEvent event(wxEVT_DATAVIEW_SELECTION_CHANGED,dvc->GetId());
1854
1855     event.SetEventObject(dvc);
1856     event.SetModel(dvc->GetModel());
1857     event.SetItem(dvc->GetSelection());
1858     dvc->GetEventHandler()->ProcessEvent(event);
1859 }
1860
1861 -(void) textDidBeginEditing:(NSNotification*)notification
1862 {
1863     // this notification is only sent if the user started modifying the cell
1864     // (not when the user clicked into the cell and the cell's editor is
1865     // called!)
1866
1867     // call method of superclass (otherwise editing does not work correctly -
1868     // the outline data source class is not informed about a change of data):
1869     [super textDidBeginEditing:notification];
1870
1871     // remember the column being edited, it will be used in textDidEndEditing:
1872     currentlyEditedColumn = [self editedColumn];
1873     currentlyEditedRow = [self editedRow];
1874
1875     NSTableColumn*
1876         tableColumn = [[self tableColumns] objectAtIndex:currentlyEditedColumn];
1877     wxDataViewColumn* const
1878         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1879
1880     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1881
1882
1883     // stop editing of a custom item first (if necessary)
1884     dvc->FinishCustomItemEditing();
1885
1886     // now, send the event:
1887     wxDataViewEvent
1888         event(wxEVT_DATAVIEW_ITEM_EDITING_STARTED,dvc->GetId());
1889
1890     event.SetEventObject(dvc);
1891     event.SetItem(
1892             wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1893     event.SetColumn(dvc->GetColumnPosition(col));
1894     event.SetDataViewColumn(col);
1895     dvc->GetEventHandler()->ProcessEvent(event);
1896 }
1897
1898 -(void) textDidEndEditing:(NSNotification*)notification
1899 {
1900     // call method of superclass (otherwise editing does not work correctly -
1901     // the outline data source class is not informed about a change of data):
1902     [super textDidEndEditing:notification];
1903
1904     // under OSX an event indicating the end of an editing session can be sent
1905     // even if no event indicating a start of an editing session has been sent
1906     // (see Documentation for NSControl controlTextDidEndEditing:); this is
1907     // not expected by a user of the wxWidgets library and therefore an
1908     // wxEVT_DATAVIEW_ITEM_EDITING_DONE event is only sent if a
1909     // corresponding wxEVT_DATAVIEW_ITEM_EDITING_STARTED has been sent
1910     // before; to check if a wxEVT_DATAVIEW_ITEM_EDITING_STARTED has
1911     // been sent the last edited column/row are valid:
1912     if ( currentlyEditedColumn != -1 && currentlyEditedRow != -1 )
1913     {
1914         NSTableColumn*
1915             tableColumn = [[self tableColumns] objectAtIndex:currentlyEditedColumn];
1916         wxDataViewColumn* const
1917             col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1918
1919         wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1920
1921         // send event to wxWidgets:
1922         wxDataViewEvent
1923             event(wxEVT_DATAVIEW_ITEM_EDITING_DONE,dvc->GetId());
1924
1925         event.SetEventObject(dvc);
1926         event.SetItem(
1927                 wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1928         event.SetColumn(dvc->GetColumnPosition(col));
1929         event.SetDataViewColumn(col);
1930         dvc->GetEventHandler()->ProcessEvent(event);
1931
1932
1933         // we're not editing any more
1934         currentlyEditedColumn =
1935             currentlyEditedRow = -1;
1936     }
1937 }
1938
1939 @end
1940
1941 // ============================================================================
1942 // wxCocoaDataViewControl
1943 // ============================================================================
1944
1945 wxCocoaDataViewControl::wxCocoaDataViewControl(wxWindow* peer,
1946                                                const wxPoint& pos,
1947                                                const wxSize& size,
1948                                                long style)
1949     : wxWidgetCocoaImpl
1950       (
1951         peer,
1952         [[NSScrollView alloc] initWithFrame:wxOSXGetFrameForControl(peer,pos,size)]
1953       ),
1954       m_DataSource(NULL),
1955       m_OutlineView([[wxCocoaOutlineView alloc] init])
1956 {
1957     // initialize scrollview (the outline view is part of a scrollview):
1958     NSScrollView* scrollview = (NSScrollView*) GetWXWidget();
1959
1960     [scrollview setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
1961     [scrollview setBorderType:NSNoBorder];
1962     [scrollview setHasVerticalScroller:YES];
1963     [scrollview setHasHorizontalScroller:YES];
1964     [scrollview setAutohidesScrollers:YES];
1965     [scrollview setDocumentView:m_OutlineView];
1966
1967     // we cannot call InstallHandler(m_OutlineView) here, because we are handling
1968     // our action:s ourselves, only associate the view with this impl
1969     Associate(m_OutlineView,this);
1970     // initialize the native control itself too
1971     InitOutlineView(style);
1972 }
1973
1974 void wxCocoaDataViewControl::InitOutlineView(long style)
1975 {
1976     [m_OutlineView setImplementation:this];
1977     [m_OutlineView setColumnAutoresizingStyle:NSTableViewSequentialColumnAutoresizingStyle];
1978     [m_OutlineView setIndentationPerLevel:GetDataViewCtrl()->GetIndent()];
1979     NSUInteger maskGridStyle(NSTableViewGridNone);
1980     if (style & wxDV_HORIZ_RULES)
1981         maskGridStyle |= NSTableViewSolidHorizontalGridLineMask;
1982     if (style & wxDV_VERT_RULES)
1983         maskGridStyle |= NSTableViewSolidVerticalGridLineMask;
1984     [m_OutlineView setGridStyleMask:maskGridStyle];
1985     [m_OutlineView setAllowsMultipleSelection:           (style & wxDV_MULTIPLE)  != 0];
1986     [m_OutlineView setUsesAlternatingRowBackgroundColors:(style & wxDV_ROW_LINES) != 0];
1987
1988     if ( style & wxDV_NO_HEADER )
1989         [m_OutlineView setHeaderView:nil];
1990 }
1991
1992 wxCocoaDataViewControl::~wxCocoaDataViewControl()
1993 {
1994     [m_DataSource  release];
1995     [m_OutlineView release];
1996 }
1997
1998 //
1999 // column related methods (inherited from wxDataViewWidgetImpl)
2000 //
2001 bool wxCocoaDataViewControl::ClearColumns()
2002 {
2003     // as there is a bug in NSOutlineView version (OSX 10.5.6 #6555162) the
2004     // columns cannot be deleted if there is an outline column in the view;
2005     // therefore, the whole view is deleted and newly constructed:
2006     [m_OutlineView release];
2007     m_OutlineView = [[wxCocoaOutlineView alloc] init];
2008     [((NSScrollView*) GetWXWidget()) setDocumentView:m_OutlineView];
2009     [m_OutlineView setDataSource:m_DataSource];
2010
2011     InitOutlineView(GetDataViewCtrl()->GetWindowStyle());
2012
2013     return true;
2014 }
2015
2016 bool wxCocoaDataViewControl::DeleteColumn(wxDataViewColumn* columnPtr)
2017 {
2018     if ([m_OutlineView outlineTableColumn] == columnPtr->GetNativeData()->GetNativeColumnPtr())
2019         [m_OutlineView setOutlineTableColumn:nil]; // due to a bug this does not work
2020     [m_OutlineView removeTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()]; // due to a confirmed bug #6555162 the deletion does not work for
2021     // outline table columns (... and there is no workaround)
2022     return (([m_OutlineView columnWithIdentifier:[wxDVCNSTableColumn identifierForColumnPointer:columnPtr]]) == -1);
2023 }
2024
2025 void wxCocoaDataViewControl::DoSetExpanderColumn(const wxDataViewColumn *columnPtr)
2026 {
2027     [m_OutlineView setOutlineTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()];
2028 }
2029
2030 wxDataViewColumn* wxCocoaDataViewControl::GetColumn(unsigned int pos) const
2031 {
2032     NSTableColumn* tableColumn = [[m_OutlineView tableColumns] objectAtIndex:pos];
2033     return [static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer];
2034 }
2035
2036 int wxCocoaDataViewControl::GetColumnPosition(const wxDataViewColumn *columnPtr) const
2037 {
2038     return [m_OutlineView columnWithIdentifier:[wxDVCNSTableColumn identifierForColumnPointer:columnPtr]];
2039 }
2040
2041 bool wxCocoaDataViewControl::InsertColumn(unsigned int pos, wxDataViewColumn* columnPtr)
2042 {
2043     // create column and set the native data of the dataview column:
2044     NSTableColumn *nativeColumn = ::CreateNativeColumn(columnPtr);
2045     columnPtr->GetNativeData()->SetNativeColumnPtr(nativeColumn);
2046     // as the native control does not allow the insertion of a column at a
2047     // specified position the column is first appended and - if necessary -
2048     // moved to its final position:
2049     [m_OutlineView addTableColumn:nativeColumn];
2050     if (pos != static_cast<unsigned int>([m_OutlineView numberOfColumns]-1))
2051         [m_OutlineView moveColumn:[m_OutlineView numberOfColumns]-1 toColumn:pos];
2052
2053     // set columns width now that it can be computed even for autosized columns:
2054     columnPtr->SetWidth(columnPtr->GetWidthVariable());
2055
2056     // done:
2057     return true;
2058 }
2059
2060 void wxCocoaDataViewControl::FitColumnWidthToContent(unsigned int pos)
2061 {
2062 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
2063     const int count = GetCount();
2064     NSTableColumn *column = GetColumn(pos)->GetNativeData()->GetNativeColumnPtr();
2065
2066     class MaxWidthCalculator
2067     {
2068     public:
2069         MaxWidthCalculator(wxCocoaOutlineView *view,
2070                            NSTableColumn *column, unsigned columnIndex)
2071             : m_width(0),
2072               m_view(view),
2073               m_column(columnIndex),
2074               m_indent(0)
2075         {
2076             // account for indentation in the column with expander
2077             if ( column == [m_view outlineTableColumn] )
2078                 m_indent = [m_view indentationPerLevel];
2079         }
2080
2081         void UpdateWithWidth(int width)
2082         {
2083             m_width = wxMax(m_width, width);
2084         }
2085
2086         void UpdateWithRow(int row)
2087         {
2088             NSCell *cell = [m_view preparedCellAtColumn:m_column row:row];
2089             unsigned cellWidth = [cell cellSize].width + 1/*round the float up*/;
2090
2091             if ( m_indent )
2092                 cellWidth += m_indent * ([m_view levelForRow:row] + 1);
2093
2094             m_width = wxMax(m_width, cellWidth);
2095         }
2096
2097         int GetMaxWidth() const { return m_width; }
2098
2099     private:
2100         int m_width;
2101         wxCocoaOutlineView *m_view;
2102         unsigned m_column;
2103         int m_indent;
2104     };
2105
2106     MaxWidthCalculator calculator(m_OutlineView, column, pos);
2107
2108     if ( [column headerCell] )
2109     {
2110         calculator.UpdateWithWidth([[column headerCell] cellSize].width + 1/*round the float up*/);
2111     }
2112
2113     // The code below deserves some explanation. For very large controls, we
2114     // simply can't afford to calculate sizes for all items, it takes too
2115     // long. So the best we can do is to check the first and the last N/2
2116     // items in the control for some sufficiently large N and calculate best
2117     // sizes from that. That can result in the calculated best width being too
2118     // small for some outliers, but it's better to get slightly imperfect
2119     // result than to wait several seconds after every update. To avoid highly
2120     // visible miscalculations, we also include all currently visible items
2121     // no matter what.  Finally, the value of N is determined dynamically by
2122     // measuring how much time we spent on the determining item widths so far.
2123
2124 #if wxUSE_STOPWATCH
2125     int top_part_end = count;
2126     static const long CALC_TIMEOUT = 20/*ms*/;
2127     // don't call wxStopWatch::Time() too often
2128     static const unsigned CALC_CHECK_FREQ = 100;
2129     wxStopWatch timer;
2130 #else
2131     // use some hard-coded limit, that's the best we can do without timer
2132     int top_part_end = wxMin(500, count);
2133 #endif // wxUSE_STOPWATCH/!wxUSE_STOPWATCH
2134
2135     int row = 0;
2136
2137     for ( row = 0; row < top_part_end; row++ )
2138     {
2139 #if wxUSE_STOPWATCH
2140         if ( row % CALC_CHECK_FREQ == CALC_CHECK_FREQ-1 &&
2141              timer.Time() > CALC_TIMEOUT )
2142             break;
2143 #endif // wxUSE_STOPWATCH
2144         calculator.UpdateWithRow(row);
2145     }
2146
2147     // row is the first unmeasured item now; that's our value of N/2
2148
2149     if ( row < count )
2150     {
2151         top_part_end = row;
2152
2153         // add bottom N/2 items now:
2154         const int bottom_part_start = wxMax(row, count - row);
2155         for ( row = bottom_part_start; row < count; row++ )
2156             calculator.UpdateWithRow(row);
2157
2158         // finally, include currently visible items in the calculation:
2159         const NSRange visible = [m_OutlineView rowsInRect:[m_OutlineView visibleRect]];
2160         const int first_visible = wxMax(visible.location, top_part_end);
2161         const int last_visible = wxMin(first_visible + visible.length, bottom_part_start);
2162
2163         for ( row = first_visible; row < last_visible; row++ )
2164             calculator.UpdateWithRow(row);
2165
2166         wxLogTrace("dataview",
2167                    "determined best size from %d top, %d bottom plus %d more visible items out of %d total",
2168                    top_part_end,
2169                    count - bottom_part_start,
2170                    wxMax(0, last_visible - first_visible),
2171                    count);
2172     }
2173
2174     [column setWidth:calculator.GetMaxWidth()];
2175 #endif // MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
2176 }
2177
2178 //
2179 // item related methods (inherited from wxDataViewWidgetImpl)
2180 //
2181 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
2182 {
2183     if (parent.IsOk())
2184         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2185     else
2186         [m_OutlineView reloadData];
2187     return true;
2188 }
2189
2190 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(items))
2191 {
2192     if (parent.IsOk())
2193         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2194     else
2195         [m_OutlineView reloadData];
2196     return true;
2197 }
2198
2199 void wxCocoaDataViewControl::Collapse(const wxDataViewItem& item)
2200 {
2201     [m_OutlineView collapseItem:[m_DataSource getDataViewItemFromBuffer:item]];
2202 }
2203
2204 void wxCocoaDataViewControl::EnsureVisible(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
2205 {
2206     if (item.IsOk())
2207     {
2208         [m_OutlineView scrollRowToVisible:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2209         if (columnPtr)
2210             [m_OutlineView scrollColumnToVisible:GetColumnPosition(columnPtr)];
2211     }
2212 }
2213
2214 void wxCocoaDataViewControl::Expand(const wxDataViewItem& item)
2215 {
2216     [m_OutlineView expandItem:[m_DataSource getDataViewItemFromBuffer:item]];
2217 }
2218
2219 unsigned int wxCocoaDataViewControl::GetCount() const
2220 {
2221     return [m_OutlineView numberOfRows];
2222 }
2223
2224 wxRect wxCocoaDataViewControl::GetRectangle(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
2225 {
2226     return wxFromNSRect([m_osxView superview],[m_OutlineView frameOfCellAtColumn:GetColumnPosition(columnPtr)
2227             row:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]);
2228 }
2229
2230 bool wxCocoaDataViewControl::IsExpanded(const wxDataViewItem& item) const
2231 {
2232     return [m_OutlineView isItemExpanded:[m_DataSource getDataViewItemFromBuffer:item]];
2233 }
2234
2235 bool wxCocoaDataViewControl::Reload()
2236 {
2237     [m_DataSource clearBuffers];
2238     [m_OutlineView reloadData];
2239     [m_OutlineView scrollColumnToVisible:0];
2240     [m_OutlineView scrollRowToVisible:0];
2241     return true;
2242 }
2243
2244 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
2245 {
2246     if (parent.IsOk())
2247         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2248     else
2249         [m_OutlineView reloadData];
2250     return true;
2251 }
2252
2253 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(item))
2254 {
2255     if (parent.IsOk())
2256         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2257     else
2258         [m_OutlineView reloadData];
2259     return true;
2260 }
2261
2262 bool wxCocoaDataViewControl::Update(const wxDataViewColumn *columnPtr)
2263 {
2264     wxUnusedVar(columnPtr);
2265
2266     return false;
2267 }
2268
2269 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItem& item)
2270 {
2271     [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:item]];
2272     return true;
2273 }
2274
2275 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItemArray& items)
2276 {
2277     for (size_t i=0; i<items.GetCount(); ++i)
2278         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:items[i]]];
2279     return true;
2280 }
2281
2282 //
2283 // model related methods
2284 //
2285 bool wxCocoaDataViewControl::AssociateModel(wxDataViewModel* model)
2286 {
2287     [m_DataSource release];
2288     if (model)
2289     {
2290         m_DataSource = [[wxCocoaOutlineDataSource alloc] init];
2291         [m_DataSource setImplementation:this];
2292         [m_DataSource setModel:model];
2293     }
2294     else
2295         m_DataSource = NULL;
2296     [m_OutlineView setDataSource:m_DataSource]; // if there is a data source the data is immediately going to be requested
2297     return true;
2298 }
2299
2300 //
2301 // selection related methods (inherited from wxDataViewWidgetImpl)
2302 //
2303
2304 wxDataViewItem wxCocoaDataViewControl::GetCurrentItem() const
2305 {
2306     return wxDataViewItem([[m_OutlineView itemAtRow:[m_OutlineView selectedRow]] pointer]);
2307 }
2308
2309 wxDataViewColumn *wxCocoaDataViewControl::GetCurrentColumn() const
2310 {
2311     int col = [m_OutlineView selectedColumn];
2312     if ( col == -1 )
2313         return NULL;
2314     return GetColumn(col);
2315 }
2316
2317 void wxCocoaDataViewControl::SetCurrentItem(const wxDataViewItem& item)
2318 {
2319     // We can't have unselected current item in a NSTableView, as the
2320     // documentation of its deselectRow method explains, the control will
2321     // automatically change the current item to the closest still selected item
2322     // if the current item is deselected. So we have no choice but to select
2323     // the item in the same time as making it current.
2324     Select(item);
2325 }
2326
2327 int wxCocoaDataViewControl::GetSelectedItemsCount() const
2328 {
2329     return [m_OutlineView numberOfSelectedRows];
2330 }
2331
2332 int wxCocoaDataViewControl::GetSelections(wxDataViewItemArray& sel) const
2333 {
2334     NSIndexSet* selectedRowIndexes([m_OutlineView selectedRowIndexes]);
2335
2336     NSUInteger indexRow;
2337
2338
2339     sel.Empty();
2340     sel.Alloc([selectedRowIndexes count]);
2341     indexRow = [selectedRowIndexes firstIndex];
2342     while (indexRow != NSNotFound)
2343     {
2344         sel.Add(wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]));
2345         indexRow = [selectedRowIndexes indexGreaterThanIndex:indexRow];
2346     }
2347     return sel.GetCount();
2348 }
2349
2350 bool wxCocoaDataViewControl::IsSelected(const wxDataViewItem& item) const
2351 {
2352     return [m_OutlineView isRowSelected:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2353 }
2354
2355 void wxCocoaDataViewControl::Select(const wxDataViewItem& item)
2356 {
2357     if (item.IsOk())
2358         [m_OutlineView selectRowIndexes:[NSIndexSet indexSetWithIndex:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]
2359             byExtendingSelection:GetDataViewCtrl()->HasFlag(wxDV_MULTIPLE) ? YES : NO];
2360 }
2361
2362 void wxCocoaDataViewControl::SelectAll()
2363 {
2364     [m_OutlineView selectAll:m_OutlineView];
2365 }
2366
2367 void wxCocoaDataViewControl::Unselect(const wxDataViewItem& item)
2368 {
2369     if (item.IsOk())
2370         [m_OutlineView deselectRow:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2371 }
2372
2373 void wxCocoaDataViewControl::UnselectAll()
2374 {
2375     [m_OutlineView deselectAll:m_OutlineView];
2376 }
2377
2378 //
2379 // sorting related methods
2380 //
2381 wxDataViewColumn* wxCocoaDataViewControl::GetSortingColumn() const
2382 {
2383     NSArray* const columns = [m_OutlineView tableColumns];
2384
2385     UInt32 const noOfColumns = [columns count];
2386
2387
2388     for (UInt32 i=0; i<noOfColumns; ++i)
2389         if ([[columns objectAtIndex:i] sortDescriptorPrototype] != nil)
2390             return GetColumn(i);
2391     return NULL;
2392 }
2393
2394 void wxCocoaDataViewControl::Resort()
2395 {
2396     [m_DataSource clearChildren];
2397     [m_OutlineView reloadData];
2398 }
2399
2400 void wxCocoaDataViewControl::StartEditor( const wxDataViewItem & item, unsigned int column )
2401 {
2402     [m_OutlineView editColumn:column row:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]] withEvent:nil select:YES];
2403 }
2404
2405 //
2406 // other methods (inherited from wxDataViewWidgetImpl)
2407 //
2408 void wxCocoaDataViewControl::DoSetIndent(int indent)
2409 {
2410     [m_OutlineView setIndentationPerLevel:static_cast<CGFloat>(indent)];
2411 }
2412
2413 void wxCocoaDataViewControl::HitTest(const wxPoint& point, wxDataViewItem& item, wxDataViewColumn*& columnPtr) const
2414 {
2415     NSPoint const nativePoint = wxToNSPoint((NSScrollView*) GetWXWidget(),point);
2416
2417     int indexColumn;
2418     int indexRow;
2419
2420
2421     indexColumn = [m_OutlineView columnAtPoint:nativePoint];
2422     indexRow    = [m_OutlineView rowAtPoint:   nativePoint];
2423     if ((indexColumn >= 0) && (indexRow >= 0))
2424     {
2425         columnPtr = GetColumn(indexColumn);
2426         item      = wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]);
2427     }
2428     else
2429     {
2430         columnPtr = NULL;
2431         item      = wxDataViewItem();
2432     }
2433 }
2434
2435 void wxCocoaDataViewControl::SetRowHeight(const wxDataViewItem& WXUNUSED(item), unsigned int WXUNUSED(height))
2436     // Not supported by the native control
2437 {
2438 }
2439
2440 void wxCocoaDataViewControl::OnSize()
2441 {
2442     if ([m_OutlineView numberOfColumns] == 1)
2443         [m_OutlineView sizeLastColumnToFit];
2444 }
2445
2446 //
2447 // drag & drop helper methods
2448 //
2449 wxDataFormat wxCocoaDataViewControl::GetDnDDataFormat(wxDataObjectComposite* dataObjects)
2450 {
2451     wxDataFormat resultFormat;
2452     if ( !dataObjects )
2453         return resultFormat;
2454
2455     bool compatible(true);
2456
2457     size_t const noOfFormats = dataObjects->GetFormatCount();
2458     size_t       indexFormat;
2459
2460     wxDataFormat* formats;
2461
2462     // get all formats and check afterwards if the formats are compatible; if
2463     // they are compatible the preferred format is returned otherwise
2464     // wxDF_INVALID is returned;
2465     // currently compatible types (ordered by priority are):
2466     //  - wxDF_UNICODETEXT - wxDF_TEXT
2467     formats = new wxDataFormat[noOfFormats];
2468     dataObjects->GetAllFormats(formats);
2469     indexFormat = 0;
2470     while ((indexFormat < noOfFormats) && compatible)
2471     {
2472         switch (resultFormat.GetType())
2473         {
2474             case wxDF_INVALID:
2475                 resultFormat.SetType(formats[indexFormat].GetType()); // first format (should only be reached if indexFormat == 0)
2476                 break;
2477             case wxDF_TEXT:
2478                 if (formats[indexFormat].GetType() == wxDF_UNICODETEXT)
2479                     resultFormat.SetType(wxDF_UNICODETEXT);
2480                 else // incompatible
2481                 {
2482                     resultFormat.SetType(wxDF_INVALID);
2483                     compatible = false;
2484                 }
2485                 break;
2486             case wxDF_UNICODETEXT:
2487                 if (formats[indexFormat].GetType() != wxDF_TEXT)
2488                 {
2489                     resultFormat.SetType(wxDF_INVALID);
2490                     compatible = false;
2491                 }
2492                 break;
2493             default:
2494                 resultFormat.SetType(wxDF_INVALID); // not (yet) supported format
2495                 compatible = false;
2496         }
2497         ++indexFormat;
2498     }
2499
2500     delete[] formats;
2501
2502     return resultFormat;
2503 }
2504
2505 wxDataObjectComposite* wxCocoaDataViewControl::GetDnDDataObjects(NSData* dataObject) const
2506 {
2507     wxDataFormatId dataFormatID;
2508
2509
2510     [dataObject getBytes:&dataFormatID length:sizeof(wxDataFormatId)];
2511     switch (dataFormatID)
2512     {
2513         case wxDF_TEXT:
2514         case wxDF_UNICODETEXT:
2515             {
2516                 wxTextDataObject* textDataObject(new wxTextDataObject());
2517
2518                 if (textDataObject->SetData(wxDataFormat(dataFormatID),[dataObject length]-sizeof(wxDataFormatId),static_cast<char const*>([dataObject bytes])+sizeof(wxDataFormatId)))
2519                 {
2520                     wxDataObjectComposite* dataObjectComposite(new wxDataObjectComposite());
2521
2522                     dataObjectComposite->Add(textDataObject);
2523                     return dataObjectComposite;
2524                 }
2525                 else
2526                 {
2527                     delete textDataObject;
2528                     return NULL;
2529                 }
2530             }
2531             break;
2532         default:
2533             return NULL;
2534     }
2535 }
2536
2537 id wxCocoaDataViewControl::GetItemAtRow(int row) const
2538 {
2539     return [m_OutlineView itemAtRow:row];
2540 }
2541
2542 // ----------------------------------------------------------------------------
2543 // wxDataViewRendererNativeData
2544 // ----------------------------------------------------------------------------
2545
2546 void wxDataViewRendererNativeData::Init()
2547 {
2548     m_origFont = NULL;
2549     m_origTextColour = NULL;
2550     m_ellipsizeMode = wxELLIPSIZE_MIDDLE;
2551
2552     if ( m_ColumnCell )
2553         ApplyLineBreakMode(m_ColumnCell);
2554 }
2555
2556 void wxDataViewRendererNativeData::ApplyLineBreakMode(NSCell *cell)
2557 {
2558     NSLineBreakMode nsMode = NSLineBreakByWordWrapping;
2559     switch ( m_ellipsizeMode )
2560     {
2561         case wxELLIPSIZE_NONE:
2562             nsMode = NSLineBreakByClipping;
2563             break;
2564
2565         case wxELLIPSIZE_START:
2566             nsMode = NSLineBreakByTruncatingHead;
2567             break;
2568
2569         case wxELLIPSIZE_MIDDLE:
2570             nsMode = NSLineBreakByTruncatingMiddle;
2571             break;
2572
2573         case wxELLIPSIZE_END:
2574             nsMode = NSLineBreakByTruncatingTail;
2575             break;
2576     }
2577
2578     wxASSERT_MSG( nsMode != NSLineBreakByWordWrapping, "unknown wxEllipsizeMode" );
2579
2580     [cell setLineBreakMode: nsMode];
2581 }
2582
2583 // ---------------------------------------------------------
2584 // wxDataViewRenderer
2585 // ---------------------------------------------------------
2586
2587 wxDataViewRenderer::wxDataViewRenderer(const wxString& varianttype,
2588                                        wxDataViewCellMode mode,
2589                                        int align)
2590     : wxDataViewRendererBase(varianttype, mode, align),
2591       m_alignment(align),
2592       m_mode(mode),
2593       m_NativeDataPtr(NULL)
2594 {
2595 }
2596
2597 wxDataViewRenderer::~wxDataViewRenderer()
2598 {
2599     delete m_NativeDataPtr;
2600 }
2601
2602 void wxDataViewRenderer::SetAlignment(int align)
2603 {
2604     m_alignment = align;
2605     [GetNativeData()->GetColumnCell() setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2606 }
2607
2608 void wxDataViewRenderer::SetMode(wxDataViewCellMode mode)
2609 {
2610     m_mode = mode;
2611     if ( GetOwner() )
2612         [GetOwner()->GetNativeData()->GetNativeColumnPtr() setEditable:(mode == wxDATAVIEW_CELL_EDITABLE)];
2613 }
2614
2615 void wxDataViewRenderer::SetNativeData(wxDataViewRendererNativeData* newNativeDataPtr)
2616 {
2617     delete m_NativeDataPtr;
2618     m_NativeDataPtr = newNativeDataPtr;
2619 }
2620
2621 void wxDataViewRenderer::EnableEllipsize(wxEllipsizeMode mode)
2622 {
2623     // we need to store this value to apply it to the columns headerCell in
2624     // CreateNativeColumn()
2625     GetNativeData()->SetEllipsizeMode(mode);
2626
2627     // but we may already apply it to the column cell which will be used for
2628     // this column
2629     GetNativeData()->ApplyLineBreakMode(GetNativeData()->GetColumnCell());
2630 }
2631
2632 wxEllipsizeMode wxDataViewRenderer::GetEllipsizeMode() const
2633 {
2634     return GetNativeData()->GetEllipsizeMode();
2635 }
2636
2637 void
2638 wxDataViewRenderer::OSXOnCellChanged(NSObject *object,
2639                                      const wxDataViewItem& item,
2640                                      unsigned col)
2641 {
2642     // TODO: This code should really be removed and this function be made pure
2643     //       virtual. We just need to decide what to do with custom renderers
2644     //       (i.e. wxDataViewCustomRenderer), currently OS X "in place" editing
2645     //       which doesn't really create an editor control is not compatible
2646     //       with the in place editing under other platforms.
2647
2648     wxVariant value;
2649     if ( [object isKindOfClass:[NSString class]] )
2650         value = ObjectToString(object);
2651     else if ( [object isKindOfClass:[NSNumber class]] )
2652         value = ObjectToLong(object);
2653     else if ( [object isKindOfClass:[NSDate class]] )
2654         value = ObjectToDate(object);
2655     else
2656     {
2657         wxFAIL_MSG( wxString::Format
2658                     (
2659                      "unknown value type %s",
2660                      wxCFStringRef::AsString([object className])
2661                     ));
2662         return;
2663     }
2664
2665     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2666     model->ChangeValue(value, item, col);
2667 }
2668
2669 void wxDataViewRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2670 {
2671     wxDataViewRendererNativeData * const data = GetNativeData();
2672     NSCell * const cell = data->GetItemCell();
2673
2674     // set the font and text colour to use: we need to do it if we had ever
2675     // changed them before, even if this item itself doesn't have any special
2676     // attributes as otherwise it would reuse the attributes from the previous
2677     // cell rendered using the same renderer
2678     NSFont *font = NULL;
2679     NSColor *colText = NULL;
2680
2681     if ( attr.HasFont() )
2682     {
2683         font = data->GetOriginalFont();
2684         if ( !font )
2685         {
2686             // this is the first time we're setting the font, remember the
2687             // original one before changing it
2688             font = [cell font];
2689             data->SaveOriginalFont(font);
2690         }
2691
2692         if ( font )
2693         {
2694             // FIXME: using wxFont methods here doesn't work for some reason
2695             NSFontManager * const fm = [NSFontManager sharedFontManager];
2696             if ( attr.GetBold() )
2697                 font = [fm convertFont:font toHaveTrait:NSBoldFontMask];
2698             if ( attr.GetItalic() )
2699                 font = [fm convertFont:font toHaveTrait:NSItalicFontMask];
2700         }
2701         //else: can't change font if the cell doesn't have any
2702     }
2703
2704     if ( attr.HasColour() )
2705     {
2706         // we can set font for any cell but only NSTextFieldCell provides
2707         // a method for setting text colour so check that this method is
2708         // available before using it
2709         if ( [cell respondsToSelector:@selector(setTextColor:)] &&
2710                 [cell respondsToSelector:@selector(textColor)] )
2711         {
2712             if ( !data->GetOriginalTextColour() )
2713             {
2714                 // the cast to (untyped) id is safe because of the check above
2715                 data->SaveOriginalTextColour([(id)cell textColor]);
2716             }
2717
2718             const wxColour& c = attr.GetColour();
2719             colText = [NSColor colorWithCalibratedRed:c.Red() / 255.
2720                 green:c.Green() / 255.
2721                 blue:c.Blue() / 255.
2722                 alpha:c.Alpha() / 255.];
2723         }
2724     }
2725
2726     if ( !font )
2727         font = data->GetOriginalFont();
2728     if ( !colText )
2729         colText = data->GetOriginalTextColour();
2730
2731     if ( font )
2732         [cell setFont:font];
2733
2734     if ( colText )
2735         [(id)cell setTextColor:colText];
2736 }
2737
2738 void wxDataViewRenderer::OSXApplyEnabled(bool enabled)
2739 {
2740     [GetNativeData()->GetItemCell() setEnabled:enabled];
2741 }
2742
2743 IMPLEMENT_ABSTRACT_CLASS(wxDataViewRenderer,wxDataViewRendererBase)
2744
2745 // ---------------------------------------------------------
2746 // wxDataViewCustomRenderer
2747 // ---------------------------------------------------------
2748 wxDataViewCustomRenderer::wxDataViewCustomRenderer(const wxString& varianttype,
2749                                                    wxDataViewCellMode mode,
2750                                                    int align)
2751     : wxDataViewCustomRendererBase(varianttype, mode, align),
2752       m_editorCtrlPtr(NULL),
2753       m_DCPtr(NULL)
2754 {
2755     SetNativeData(new wxDataViewRendererNativeData([[wxCustomCell alloc] init]));
2756 }
2757
2758 bool wxDataViewCustomRenderer::MacRender()
2759 {
2760     [GetNativeData()->GetItemCell() setObjectValue:[[[wxCustomRendererObject alloc] initWithRenderer:this] autorelease]];
2761     return true;
2762 }
2763
2764 void wxDataViewCustomRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2765 {
2766     // simply save the attribute so that it could be reused from our Render()
2767     SetAttr(attr);
2768
2769     // it's not necessary to call the base class version which sets the cell
2770     // properties to correspond to this attribute because we currently don't
2771     // use any NSCell methods in custom renderers anyhow but if we ever start
2772     // doing this (e.g. override RenderText() here to use NSTextFieldCell
2773     // methods), then we should pass it on to wxDataViewRenderer here
2774 }
2775
2776 IMPLEMENT_ABSTRACT_CLASS(wxDataViewCustomRenderer, wxDataViewRenderer)
2777
2778 // ---------------------------------------------------------
2779 // wxDataViewTextRenderer
2780 // ---------------------------------------------------------
2781 wxDataViewTextRenderer::wxDataViewTextRenderer(const wxString& varianttype,
2782                                                wxDataViewCellMode mode,
2783                                                int align)
2784     : wxDataViewRenderer(varianttype,mode,align)
2785 {
2786     NSTextFieldCell* cell;
2787
2788
2789     cell = [[NSTextFieldCell alloc] init];
2790     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2791     SetNativeData(new wxDataViewRendererNativeData(cell));
2792     [cell release];
2793 }
2794
2795 bool wxDataViewTextRenderer::MacRender()
2796 {
2797     if (GetValue().GetType() == GetVariantType())
2798     {
2799         [GetNativeData()->GetItemCell() setObjectValue:wxCFStringRef(GetValue().GetString()).AsNSString()];
2800         return true;
2801     }
2802     else
2803     {
2804         wxFAIL_MSG(wxString("Text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2805         return false;
2806     }
2807 }
2808
2809 void
2810 wxDataViewTextRenderer::OSXOnCellChanged(NSObject *value,
2811                                          const wxDataViewItem& item,
2812                                          unsigned col)
2813 {
2814     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2815     model->ChangeValue(ObjectToString(value), item, col);
2816 }
2817
2818 IMPLEMENT_CLASS(wxDataViewTextRenderer,wxDataViewRenderer)
2819
2820 // ---------------------------------------------------------
2821 // wxDataViewBitmapRenderer
2822 // ---------------------------------------------------------
2823 wxDataViewBitmapRenderer::wxDataViewBitmapRenderer(const wxString& varianttype,
2824                                                    wxDataViewCellMode mode,
2825                                                    int align)
2826     : wxDataViewRenderer(varianttype,mode,align)
2827 {
2828     NSImageCell* cell;
2829
2830
2831     cell = [[NSImageCell alloc] init];
2832     SetNativeData(new wxDataViewRendererNativeData(cell));
2833     [cell release];
2834 }
2835
2836 // This method returns 'true' if
2837 //  - the passed bitmap is valid and it could be assigned to the native data
2838 //  browser;
2839 //  - the passed bitmap is invalid (or is not initialized); this case
2840 //  simulates a non-existing bitmap.
2841 // In all other cases the method returns 'false'.
2842 bool wxDataViewBitmapRenderer::MacRender()
2843 {
2844     wxCHECK_MSG(GetValue().GetType() == GetVariantType(),false,wxString("Bitmap renderer cannot render value; value type: ") << GetValue().GetType());
2845
2846     wxBitmap bitmap;
2847
2848     bitmap << GetValue();
2849     if (bitmap.IsOk())
2850         [GetNativeData()->GetItemCell() setObjectValue:[[bitmap.GetNSImage() retain] autorelease]];
2851     return true;
2852 }
2853
2854 IMPLEMENT_CLASS(wxDataViewBitmapRenderer,wxDataViewRenderer)
2855
2856 // -------------------------------------
2857 // wxDataViewChoiceRenderer
2858 // -------------------------------------
2859 wxDataViewChoiceRenderer::wxDataViewChoiceRenderer(const wxArrayString& choices,
2860                                                    wxDataViewCellMode mode,
2861                                                    int alignment)
2862     : wxDataViewRenderer(wxT("string"), mode, alignment),
2863       m_choices(choices)
2864 {
2865     NSPopUpButtonCell* cell;
2866
2867
2868     cell = [[NSPopUpButtonCell alloc] init];
2869     [cell setControlSize:NSMiniControlSize];
2870     [cell setFont:[NSFont fontWithName:[[cell font] fontName] size:[NSFont systemFontSizeForControlSize:NSMiniControlSize]]];
2871     for (size_t i=0; i<choices.GetCount(); ++i)
2872         [cell addItemWithTitle:wxCFStringRef(choices[i]).AsNSString()];
2873     SetNativeData(new wxDataViewRendererNativeData(cell));
2874     [cell release];
2875 }
2876
2877 void
2878 wxDataViewChoiceRenderer::OSXOnCellChanged(NSObject *value,
2879                                            const wxDataViewItem& item,
2880                                            unsigned col)
2881 {
2882     // At least under OS X 10.7 we get the index of the item selected and not
2883     // its string.
2884     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2885     model->ChangeValue(GetChoice(ObjectToLong(value)), item, col);
2886 }
2887
2888 bool wxDataViewChoiceRenderer::MacRender()
2889 {
2890     if (GetValue().GetType() == GetVariantType())
2891     {
2892         [((NSPopUpButtonCell*) GetNativeData()->GetItemCell()) selectItemWithTitle:[[wxCFStringRef(GetValue().GetString()).AsNSString() retain] autorelease]];
2893         return true;
2894     }
2895     else
2896     {
2897         wxFAIL_MSG(wxString("Choice renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2898         return false;
2899     }
2900 }
2901
2902 IMPLEMENT_CLASS(wxDataViewChoiceRenderer,wxDataViewRenderer)
2903
2904 // ---------------------------------------------------------
2905 // wxDataViewDateRenderer
2906 // ---------------------------------------------------------
2907
2908 wxDataViewDateRenderer::wxDataViewDateRenderer(const wxString& varianttype,
2909                                                wxDataViewCellMode mode,
2910                                                int align)
2911     : wxDataViewRenderer(varianttype,mode,align)
2912 {
2913     NSTextFieldCell* cell;
2914
2915     NSDateFormatter* dateFormatter;
2916
2917
2918     dateFormatter = [[NSDateFormatter alloc] init];
2919     [dateFormatter setFormatterBehavior:NSDateFormatterBehavior10_4];
2920     [dateFormatter setDateStyle:NSDateFormatterShortStyle];
2921     cell = [[NSTextFieldCell alloc] init];
2922     [cell setFormatter:dateFormatter];
2923     SetNativeData(new wxDataViewRendererNativeData(cell,[NSDate dateWithString:@"2000-12-30 20:00:00 +0000"]));
2924     [cell          release];
2925     [dateFormatter release];
2926 }
2927
2928 bool wxDataViewDateRenderer::MacRender()
2929 {
2930     if (GetValue().GetType() == GetVariantType())
2931     {
2932         if (GetValue().GetDateTime().IsValid())
2933         {
2934             // -- find best fitting style to show the date --
2935             // as the style should be identical for all cells a reference date
2936             // instead of the actual cell's date value is used for all cells;
2937             // this reference date is stored in the renderer's native data
2938             // section for speed purposes; otherwise, the reference date's
2939             // string has to be recalculated for each item that may become
2940             // timewise long if a lot of rows using dates exist; the algorithm
2941             // has the preference to display as much information as possible
2942             // in the first instance; but as this is often impossible due to
2943             // space restrictions the style is shortened per loop; finally, if
2944             // the shortest time and date format does not fit into the cell
2945             // the time part is dropped; remark: the time part itself is not
2946             // modified per iteration loop and only uses the short style,
2947             // means that only the hours and minutes are being shown
2948
2949             // GetObject() returns a date for testing the size of a date object
2950             [GetNativeData()->GetItemCell() setObjectValue:GetNativeData()->GetObject()];
2951             [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterShortStyle];
2952             for (int dateFormatterStyle=4; dateFormatterStyle>0; --dateFormatterStyle)
2953             {
2954                 [[GetNativeData()->GetItemCell() formatter] setDateStyle:(NSDateFormatterStyle)dateFormatterStyle];
2955                 if (dateFormatterStyle == 1)
2956                 {
2957                     // if the shortest style for displaying the date and time
2958                     // is too long to be fully visible remove the time part of
2959                     // the date:
2960                     if ([GetNativeData()->GetItemCell() cellSize].width > [GetNativeData()->GetColumnPtr() width])
2961                         [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterNoStyle];
2962                     {
2963                         // basically not necessary as the loop would end anyway
2964                         // but let's save the last comparison
2965                         break;
2966                     }
2967                 }
2968                 else if ([GetNativeData()->GetItemCell() cellSize].width <= [GetNativeData()->GetColumnPtr() width])
2969                     break;
2970             }
2971             // set data (the style is set by the previous loop); on OSX the
2972             // date has to be specified with respect to UTC; in wxWidgets the
2973             // date is always entered in the local timezone; so, we have to do
2974             // a conversion from the local to UTC timezone when adding the
2975             // seconds to 1970-01-01 UTC:
2976             [GetNativeData()->GetItemCell() setObjectValue:[NSDate dateWithTimeIntervalSince1970:GetValue().GetDateTime().ToUTC().Subtract(wxDateTime(1,wxDateTime::Jan,1970)).GetSeconds().ToDouble()]];
2977         }
2978         return true;
2979     }
2980     else
2981     {
2982         wxFAIL_MSG(wxString("Date renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2983         return false;
2984     }
2985 }
2986
2987 void
2988 wxDataViewDateRenderer::OSXOnCellChanged(NSObject *value,
2989                                          const wxDataViewItem& item,
2990                                          unsigned col)
2991 {
2992     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2993     model->ChangeValue(ObjectToDate(value), item, col);
2994 }
2995
2996 IMPLEMENT_ABSTRACT_CLASS(wxDataViewDateRenderer,wxDataViewRenderer)
2997
2998 // ---------------------------------------------------------
2999 // wxDataViewIconTextRenderer
3000 // ---------------------------------------------------------
3001 wxDataViewIconTextRenderer::wxDataViewIconTextRenderer(const wxString& varianttype,
3002                                                        wxDataViewCellMode mode,
3003                                                        int align)
3004      : wxDataViewRenderer(varianttype,mode)
3005 {
3006     wxImageTextCell* cell;
3007
3008
3009     cell = [[wxImageTextCell alloc] init];
3010     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
3011     SetNativeData(new wxDataViewRendererNativeData(cell));
3012     [cell release];
3013 }
3014
3015 bool wxDataViewIconTextRenderer::MacRender()
3016 {
3017     if (GetValue().GetType() == GetVariantType())
3018     {
3019         wxDataViewIconText iconText;
3020
3021         wxImageTextCell* cell;
3022
3023         cell = (wxImageTextCell*) GetNativeData()->GetItemCell();
3024         iconText << GetValue();
3025         if (iconText.GetIcon().IsOk())
3026             [cell setImage:[[wxBitmap(iconText.GetIcon()).GetNSImage() retain] autorelease]];
3027         else
3028             [cell setImage:nil];
3029         [cell setStringValue:[[wxCFStringRef(iconText.GetText()).AsNSString() retain] autorelease]];
3030         return true;
3031     }
3032     else
3033     {
3034         wxFAIL_MSG(wxString("Icon & text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
3035         return false;
3036     }
3037 }
3038
3039 void
3040 wxDataViewIconTextRenderer::OSXOnCellChanged(NSObject *value,
3041                                              const wxDataViewItem& item,
3042                                              unsigned col)
3043 {
3044     wxVariant valueIconText;
3045     valueIconText << wxDataViewIconText(ObjectToString(value));
3046
3047     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
3048     model->ChangeValue(valueIconText, item, col);
3049 }
3050
3051 IMPLEMENT_ABSTRACT_CLASS(wxDataViewIconTextRenderer,wxDataViewRenderer)
3052
3053 // ---------------------------------------------------------
3054 // wxDataViewToggleRenderer
3055 // ---------------------------------------------------------
3056 wxDataViewToggleRenderer::wxDataViewToggleRenderer(const wxString& varianttype,
3057                                                    wxDataViewCellMode mode,
3058                                                    int align)
3059     : wxDataViewRenderer(varianttype,mode)
3060 {
3061     NSButtonCell* cell;
3062
3063
3064     cell = [[NSButtonCell alloc] init];
3065     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
3066     [cell setButtonType:NSSwitchButton];
3067     [cell setImagePosition:NSImageOnly];
3068     SetNativeData(new wxDataViewRendererNativeData(cell));
3069     [cell release];
3070 }
3071
3072 bool wxDataViewToggleRenderer::MacRender()
3073 {
3074     if (GetValue().GetType() == GetVariantType())
3075     {
3076         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
3077         return true;
3078     }
3079     else
3080     {
3081         wxFAIL_MSG(wxString("Toggle renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
3082         return false;
3083     }
3084 }
3085
3086 void
3087 wxDataViewToggleRenderer::OSXOnCellChanged(NSObject *value,
3088                                            const wxDataViewItem& item,
3089                                            unsigned col)
3090 {
3091     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
3092     model->ChangeValue(ObjectToBool(value), item, col);
3093 }
3094
3095 IMPLEMENT_ABSTRACT_CLASS(wxDataViewToggleRenderer,wxDataViewRenderer)
3096
3097 // ---------------------------------------------------------
3098 // wxDataViewProgressRenderer
3099 // ---------------------------------------------------------
3100 wxDataViewProgressRenderer::wxDataViewProgressRenderer(const wxString& label,
3101                                                        const wxString& varianttype,
3102                                                        wxDataViewCellMode mode,
3103                                                        int align)
3104     : wxDataViewRenderer(varianttype,mode,align)
3105 {
3106     wxUnusedVar(label);
3107
3108     NSLevelIndicatorCell* cell;
3109
3110     cell = [[NSLevelIndicatorCell alloc] initWithLevelIndicatorStyle:NSContinuousCapacityLevelIndicatorStyle];
3111     [cell setMinValue:0];
3112     [cell setMaxValue:100];
3113     SetNativeData(new wxDataViewRendererNativeData(cell));
3114     [cell release];
3115 }
3116
3117 bool wxDataViewProgressRenderer::MacRender()
3118 {
3119     if (GetValue().GetType() == GetVariantType())
3120     {
3121         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
3122         return true;
3123     }
3124     else
3125     {
3126         wxFAIL_MSG(wxString("Progress renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
3127         return false;
3128     }
3129 }
3130
3131 void
3132 wxDataViewProgressRenderer::OSXOnCellChanged(NSObject *value,
3133                                              const wxDataViewItem& item,
3134                                              unsigned col)
3135 {
3136     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
3137     model->ChangeValue(ObjectToLong(value), item, col);
3138 }
3139
3140 IMPLEMENT_ABSTRACT_CLASS(wxDataViewProgressRenderer,wxDataViewRenderer)
3141
3142 // ---------------------------------------------------------
3143 // wxDataViewColumn
3144 // ---------------------------------------------------------
3145
3146 wxDataViewColumn::wxDataViewColumn(const wxString& title,
3147                                    wxDataViewRenderer* renderer,
3148                                    unsigned int model_column,
3149                                    int width,
3150                                    wxAlignment align,
3151                                    int flags)
3152      : wxDataViewColumnBase(renderer, model_column),
3153        m_NativeDataPtr(new wxDataViewColumnNativeData()),
3154        m_title(title)
3155 {
3156     InitCommon(width, align, flags);
3157     if (renderer && !renderer->IsCustomRenderer() &&
3158         (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
3159         renderer->SetAlignment(align);
3160 }
3161
3162 wxDataViewColumn::wxDataViewColumn(const wxBitmap& bitmap,
3163                                    wxDataViewRenderer* renderer,
3164                                    unsigned int model_column,
3165                                    int width,
3166                                    wxAlignment align,
3167                                    int flags)
3168     : wxDataViewColumnBase(bitmap, renderer, model_column),
3169       m_NativeDataPtr(new wxDataViewColumnNativeData())
3170 {
3171     InitCommon(width, align, flags);
3172     if (renderer && !renderer->IsCustomRenderer() &&
3173         (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
3174         renderer->SetAlignment(align);
3175 }
3176
3177 wxDataViewColumn::~wxDataViewColumn()
3178 {
3179     delete m_NativeDataPtr;
3180 }
3181
3182 int wxDataViewColumn::GetWidth() const
3183 {
3184     return [m_NativeDataPtr->GetNativeColumnPtr() width];
3185 }
3186
3187 bool wxDataViewColumn::IsSortKey() const
3188 {
3189     NSTableColumn *nsCol = GetNativeData()->GetNativeColumnPtr();
3190     return nsCol && ([nsCol sortDescriptorPrototype] != nil);
3191 }
3192
3193 void wxDataViewColumn::SetAlignment(wxAlignment align)
3194 {
3195     m_alignment = align;
3196     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
3197     if (m_renderer && !m_renderer->IsCustomRenderer() &&
3198         (m_renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
3199         m_renderer->SetAlignment(align);
3200 }
3201
3202 void wxDataViewColumn::SetBitmap(const wxBitmap& bitmap)
3203 {
3204     // bitmaps and titles cannot exist at the same time - if the bitmap is set
3205     // the title is removed:
3206     m_title = wxEmptyString;
3207     wxDataViewColumnBase::SetBitmap(bitmap);
3208     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setImage:[[bitmap.GetNSImage() retain] autorelease]];
3209 }
3210
3211 void wxDataViewColumn::SetMaxWidth(int maxWidth)
3212 {
3213     m_maxWidth = maxWidth;
3214     [m_NativeDataPtr->GetNativeColumnPtr() setMaxWidth:maxWidth];
3215 }
3216
3217 void wxDataViewColumn::SetMinWidth(int minWidth)
3218 {
3219     m_minWidth = minWidth;
3220     [m_NativeDataPtr->GetNativeColumnPtr() setMinWidth:minWidth];
3221 }
3222
3223 void wxDataViewColumn::SetReorderable(bool reorderable)
3224 {
3225     wxUnusedVar(reorderable);
3226 }
3227
3228 void wxDataViewColumn::SetHidden(bool hidden)
3229 {
3230     // How to set flag here?
3231
3232     [m_NativeDataPtr->GetNativeColumnPtr() setHidden:hidden];
3233 }
3234
3235 bool wxDataViewColumn::IsHidden() const
3236 {
3237     return [m_NativeDataPtr->GetNativeColumnPtr() isHidden];
3238 }
3239
3240 void wxDataViewColumn::SetResizeable(bool resizable)
3241 {
3242     wxDataViewColumnBase::SetResizeable(resizable);
3243     if (resizable)
3244         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnUserResizingMask];
3245     else
3246         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnNoResizing];
3247 }
3248
3249 void wxDataViewColumn::SetSortable(bool sortable)
3250 {
3251     // wxDataViewColumnBase::SetSortable(sortable);
3252     // Avoid endless recursion and just set the flag here
3253     if (sortable)
3254         m_flags |= wxDATAVIEW_COL_SORTABLE;
3255     else
3256         m_flags &= ~wxDATAVIEW_COL_SORTABLE;
3257 }
3258
3259 void wxDataViewColumn::SetSortOrder(bool ascending)
3260 {
3261     if (m_ascending != ascending)
3262     {
3263         m_ascending = ascending;
3264         if (IsSortKey())
3265         {
3266             // change sorting order:
3267             NSArray*          sortDescriptors;
3268             NSSortDescriptor* sortDescriptor;
3269             NSTableColumn*    tableColumn;
3270
3271             tableColumn     = m_NativeDataPtr->GetNativeColumnPtr();
3272             sortDescriptor  = [[NSSortDescriptor alloc] initWithKey:[[tableColumn sortDescriptorPrototype] key] ascending:m_ascending];
3273             sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
3274             [tableColumn setSortDescriptorPrototype:sortDescriptor];
3275             [[tableColumn tableView] setSortDescriptors:sortDescriptors];
3276             [sortDescriptor release];
3277         }
3278     }
3279 }
3280
3281 void wxDataViewColumn::SetTitle(const wxString& title)
3282 {
3283     // bitmaps and titles cannot exist at the same time - if the title is set
3284     // the bitmap is removed:
3285     wxDataViewColumnBase::SetBitmap(wxBitmap());
3286     m_title = title;
3287     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setStringValue:[[wxCFStringRef(title).AsNSString() retain] autorelease]];
3288 }
3289
3290 void wxDataViewColumn::SetWidth(int width)
3291 {
3292     m_width = width;
3293
3294     switch ( width )
3295     {
3296         case wxCOL_WIDTH_AUTOSIZE:
3297 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
3298             if ( GetOwner() )
3299             {
3300                 wxCocoaDataViewControl *peer = static_cast<wxCocoaDataViewControl*>(GetOwner()->GetPeer());
3301                 peer->FitColumnWidthToContent(GetOwner()->GetColumnPosition(this));
3302                 break;
3303             }
3304 #endif
3305             // fall through if unsupported (OSX < 10.5) or not yet settable
3306
3307         case wxCOL_WIDTH_DEFAULT:
3308             width = wxDVC_DEFAULT_WIDTH;
3309             // fall through
3310
3311         default:
3312             [m_NativeDataPtr->GetNativeColumnPtr() setWidth:width];
3313             break;
3314     }
3315 }
3316
3317 void wxDataViewColumn::SetNativeData(wxDataViewColumnNativeData* newNativeDataPtr)
3318 {
3319     delete m_NativeDataPtr;
3320     m_NativeDataPtr = newNativeDataPtr;
3321 }
3322
3323 #endif // (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)