src/osx/carbon/utilscocoa.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/carbon/utils.mm
   3 // Purpose:     various cocoa mixin utility functions
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: utilscocoa.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxOSX_USE_COCOA_OR_CARBON
  15 #include <Cocoa/Cocoa.h>
  16 #else
  17 #import <UIKit/UIKit.h>
  18 #endif
  19
  20 #ifdef __WXMAC__
  21 #include "wx/osx/private.h"
  22 #endif
  23
  24 #include "wx/fontutil.h"
  25
  26 #if wxOSX_USE_COCOA
  27 #include "wx/cocoa/string.h"
  28 #endif
  29
  30 #ifdef __WXMAC__
  31
  32 #if wxOSX_USE_CARBON
  33 bool wxMacInitCocoa()
  34 {
  35     bool cocoaLoaded = NSApplicationLoad();
  36     wxASSERT_MSG(cocoaLoaded,wxT("Couldn't load Cocoa in Carbon Environment")) ;
  37     return cocoaLoaded;
  38 }
  39 #endif
  40
  41 wxMacAutoreleasePool::wxMacAutoreleasePool()
  42 {
  43     m_pool = [[NSAutoreleasePool alloc] init];
  44 }
  45
  46 wxMacAutoreleasePool::~wxMacAutoreleasePool()
  47 {
  48     [(NSAutoreleasePool*)m_pool release];
  49 }
  50
  51 #endif
  52
  53 #if wxOSX_USE_COCOA
  54
  55 CGContextRef wxOSXGetContextFromCurrentContext()
  56 {
  57     CGContextRef context = (CGContextRef)[[NSGraphicsContext currentContext]
  58                                           graphicsPort];
  59     return context;
  60 }
  61
  62 bool wxOSXLockFocus( WXWidget view)
  63 {
  64     return [view lockFocusIfCanDraw];
  65 }
  66
  67 void wxOSXUnlockFocus( WXWidget view)
  68 {
  69     [view unlockFocus];
  70 }
  71
  72 #endif
  73
  74 #if wxOSX_USE_IPHONE
  75
  76 CGContextRef wxOSXGetContextFromCurrentContext()
  77 {
  78     CGContextRef context = UIGraphicsGetCurrentContext();
  79     return context;
  80 }
  81
  82 #endif
  83
  84 // ----------------------------------------------------------------------------
  85 // NSObject Utils
  86 // ----------------------------------------------------------------------------
  87
  88 void wxMacCocoaRelease( void* obj )
  89 {
  90     [(NSObject*)obj release];
  91 }
  92
  93 void wxMacCocoaAutorelease( void* obj )
  94 {
  95     [(NSObject*)obj autorelease];
  96 }
  97
  98 void* wxMacCocoaRetain( void* obj )
  99 {
 100     [(NSObject*)obj retain];
 101     return obj;
 102 }
 103
 104 // ----------------------------------------------------------------------------
 105 // NSFont Utils
 106 // ----------------------------------------------------------------------------
 107
 108 #if wxOSX_USE_COCOA
 109 wxFont::wxFont(WX_NSFont nsfont)
 110 {
 111     [nsfont retain];
 112     wxNativeFontInfo info;
 113     SetNativeInfoFromNSFont(nsfont, &info);
 114     Create(info);
 115 }
 116
 117 void wxFont::SetNativeInfoFromNSFont(WX_NSFont theFont, wxNativeFontInfo* info)
 118 {
 119     if ( info->m_faceName.empty())
 120     {
 121         //Get more information about the user's chosen font
 122         NSFontTraitMask theTraits = [[NSFontManager sharedFontManager] traitsOfFont:theFont];
 123         int theFontWeight = [[NSFontManager sharedFontManager] weightOfFont:theFont];
 124
 125         wxFontFamily fontFamily = wxFONTFAMILY_DEFAULT;
 126         //Set the wx font to the appropriate data
 127         if(theTraits & NSFixedPitchFontMask)
 128             fontFamily = wxFONTFAMILY_TELETYPE;
 129
 130         wxFontStyle fontstyle = wxFONTSTYLE_NORMAL;
 131         wxFontWeight fontweight = wxFONTWEIGHT_NORMAL;
 132         bool underlined = false;
 133
 134         int size = (int) ([theFont pointSize]+0.5);
 135
 136         if ( theFontWeight >= 9 )
 137             fontweight = wxFONTWEIGHT_BOLD ;
 138         else if ( theFontWeight < 5 )
 139             fontweight = wxFONTWEIGHT_LIGHT;
 140         else
 141             fontweight = wxFONTWEIGHT_NORMAL ;
 142
 143         if ( theTraits & NSItalicFontMask )
 144             fontstyle = wxFONTSTYLE_ITALIC ;
 145
 146         info->Init(size,fontFamily,fontstyle,fontweight,underlined,
 147             wxStringWithNSString([theFont familyName]), wxFONTENCODING_DEFAULT);
 148
 149     }
 150 }
 151
 152 WX_NSFont wxFont::OSXCreateNSFont(wxOSXSystemFont font, wxNativeFontInfo* info)
 153 {
 154     NSFont* nsfont = nil;
 155     switch( font )
 156     {
 157         case wxOSX_SYSTEM_FONT_NORMAL:
 158             nsfont = [NSFont systemFontOfSize:[NSFont systemFontSize]];
 159             break;
 160         case wxOSX_SYSTEM_FONT_BOLD:
 161             nsfont = [NSFont boldSystemFontOfSize:[NSFont systemFontSize]];
 162             break;
 163         case wxOSX_SYSTEM_FONT_SMALL:
 164             nsfont = [NSFont systemFontOfSize:[NSFont smallSystemFontSize]];
 165             break;
 166         case wxOSX_SYSTEM_FONT_SMALL_BOLD:
 167             nsfont = [NSFont boldSystemFontOfSize:[NSFont smallSystemFontSize]];
 168             break;
 169         case wxOSX_SYSTEM_FONT_MINI:
 170             nsfont = [NSFont systemFontOfSize:
 171                 [NSFont systemFontSizeForControlSize:NSMiniControlSize]];
 172             break;
 173        case wxOSX_SYSTEM_FONT_MINI_BOLD:
 174             nsfont = [NSFont boldSystemFontOfSize:
 175                 [NSFont systemFontSizeForControlSize:NSMiniControlSize]];
 176             break;
 177         case wxOSX_SYSTEM_FONT_LABELS:
 178             nsfont = [NSFont labelFontOfSize:[NSFont labelFontSize]];
 179             break;
 180        case wxOSX_SYSTEM_FONT_VIEWS:
 181             nsfont = [NSFont controlContentFontOfSize:0];
 182             break;
 183         default:
 184             break;
 185     }
 186     [nsfont retain];
 187     SetNativeInfoFromNSFont(nsfont, info);
 188     return nsfont;
 189 }
 190
 191 static inline double DegToRad(double deg) { return (deg * M_PI) / 180.0; }
 192 static const NSAffineTransformStruct kSlantNSTransformStruct = { 1, 0, tan(DegToRad(11)), 1, 0, 0  };
 193
 194 WX_NSFont wxFont::OSXCreateNSFont(const wxNativeFontInfo* info)
 195 {
 196     NSFont* nsFont;
 197     int weight = 5;
 198     NSFontTraitMask traits = 0;
 199     if (info->m_weight == wxFONTWEIGHT_BOLD)
 200     {
 201         traits |= NSBoldFontMask;
 202         weight = 9;
 203     }
 204     else if (info->m_weight == wxFONTWEIGHT_LIGHT)
 205         weight = 3;
 206
 207     if (info->m_style == wxFONTSTYLE_ITALIC || info->m_style == wxFONTSTYLE_SLANT)
 208         traits |= NSItalicFontMask;
 209
 210     nsFont = [[NSFontManager sharedFontManager] fontWithFamily:wxCFStringRef(info->m_faceName).AsNSString()
 211         traits:traits weight:weight size:info->m_pointSize];
 212
 213     if ( nsFont == nil )
 214     {
 215         NSFontTraitMask remainingTraits = traits;
 216         nsFont = [[NSFontManager sharedFontManager] fontWithFamily:wxCFStringRef(info->m_faceName).AsNSString()
 217                                                             traits:0 weight:5 size:info->m_pointSize];
 218         if ( nsFont == nil )
 219         {
 220             if ( info->m_weight == wxFONTWEIGHT_BOLD )
 221             {
 222                 nsFont = [NSFont boldSystemFontOfSize:info->m_pointSize];
 223                 remainingTraits &= ~NSBoldFontMask;
 224             }
 225             else
 226                 nsFont = [NSFont systemFontOfSize:info->m_pointSize];
 227         }
 228
 229         // fallback - if in doubt, let go of the bold attribute
 230         if ( nsFont && (remainingTraits & NSItalicFontMask) )
 231         {
 232             NSFont* nsFontWithTraits = nil;
 233             if ( remainingTraits & NSBoldFontMask)
 234             {
 235                 nsFontWithTraits = [[NSFontManager sharedFontManager] convertFont:nsFont toHaveTrait:NSBoldFontMask];
 236                 if ( nsFontWithTraits == nil )
 237                 {
 238                     nsFontWithTraits = [[NSFontManager sharedFontManager] convertFont:nsFont toHaveTrait:NSItalicFontMask];
 239                     if ( nsFontWithTraits != nil )
 240                         remainingTraits &= ~NSItalicFontMask;
 241                 }
 242                 else
 243                 {
 244                     remainingTraits &= ~NSBoldFontMask;
 245                 }
 246             }
 247             // the code below causes crashes, because fontDescriptorWithMatrix is not returning a valid font descriptor
 248             // it adds a NSCTFontMatrixAttribute as well which cannot be disposed of correctly by the autorelease pool
 249             // so at the moment we have to disable this and cannot synthesize italic fonts if they are not available on the system
 250 #if 0
 251             if ( remainingTraits & NSItalicFontMask )
 252             {
 253                 if ( nsFontWithTraits == nil )
 254                     nsFontWithTraits = nsFont;
 255
 256                 NSAffineTransform* transform = [NSAffineTransform transform];
 257                 [transform setTransformStruct:kSlantNSTransformStruct];
 258                 [transform scaleBy:info->m_pointSize];
 259                 NSFontDescriptor* italicDesc = [[nsFontWithTraits fontDescriptor] fontDescriptorWithMatrix:transform];
 260                 if ( italicDesc != nil )
 261                 {
 262                     NSFont* f = [NSFont fontWithDescriptor:italicDesc size:(CGFloat)(info->m_pointSize)];
 263                     if ( f != nil )
 264                         nsFontWithTraits = f;
 265                 }
 266             }
 267 #endif
 268             if ( nsFontWithTraits != nil )
 269                 nsFont = nsFontWithTraits;
 270         }
 271     }
 272
 273     wxASSERT_MSG(nsFont != nil,wxT("Couldn't create nsFont")) ;
 274     wxMacCocoaRetain(nsFont);
 275     return nsFont;
 276 }
 277
 278 #endif
 279
 280 #if wxOSX_USE_IPHONE
 281
 282 WX_UIFont wxFont::OSXCreateUIFont(wxOSXSystemFont font, wxNativeFontInfo* info)
 283 {
 284     UIFont* uifont;
 285     switch( font )
 286     {
 287         case wxOSX_SYSTEM_FONT_NORMAL:
 288             uifont = [UIFont systemFontOfSize:[UIFont systemFontSize]];
 289             break;
 290         case wxOSX_SYSTEM_FONT_BOLD:
 291             uifont = [UIFont boldSystemFontOfSize:[UIFont systemFontSize]];
 292             break;
 293         case wxOSX_SYSTEM_FONT_MINI:
 294         case wxOSX_SYSTEM_FONT_SMALL:
 295             uifont = [UIFont systemFontOfSize:[UIFont smallSystemFontSize]];
 296             break;
 297         case wxOSX_SYSTEM_FONT_MINI_BOLD:
 298         case wxOSX_SYSTEM_FONT_SMALL_BOLD:
 299             uifont = [UIFont boldSystemFontOfSize:[UIFont smallSystemFontSize]];
 300             break;
 301         case wxOSX_SYSTEM_FONT_VIEWS:
 302         case wxOSX_SYSTEM_FONT_LABELS:
 303             uifont = [UIFont systemFontOfSize:[UIFont labelFontSize]];
 304             break;
 305         default:
 306             break;
 307     }
 308     [uifont retain];
 309     if ( info->m_faceName.empty())
 310     {
 311         wxFontStyle fontstyle = wxFONTSTYLE_NORMAL;
 312         wxFontWeight fontweight = wxFONTWEIGHT_NORMAL;
 313         bool underlined = false;
 314
 315         int size = (int) ([uifont pointSize]+0.5);
 316         /*
 317         NSFontSymbolicTraits traits = [desc symbolicTraits];
 318
 319         if ( traits & NSFontBoldTrait )
 320             fontweight = wxFONTWEIGHT_BOLD ;
 321         else
 322             fontweight = wxFONTWEIGHT_NORMAL ;
 323         if ( traits & NSFontItalicTrait )
 324             fontstyle = wxFONTSTYLE_ITALIC ;
 325         */
 326         wxCFStringRef fontname( wxCFRetain([uifont familyName]) );
 327         info->Init(size,wxFONTFAMILY_DEFAULT,fontstyle,fontweight,underlined,
 328             fontname.AsString(), wxFONTENCODING_DEFAULT);
 329
 330     }
 331     return uifont;
 332 }
 333
 334 WX_UIFont wxFont::OSXCreateUIFont(const wxNativeFontInfo* info)
 335 {
 336     UIFont* uiFont;
 337     uiFont = [UIFont fontWithName:wxCFStringRef(info->m_faceName).AsNSString() size:info->m_pointSize];
 338     wxMacCocoaRetain(uiFont);
 339     return uiFont;
 340 }
 341
 342 #endif
 343 // ----------------------------------------------------------------------------
 344 // NSImage Utils
 345 // ----------------------------------------------------------------------------
 346
 347 #if wxOSX_USE_IPHONE
 348
 349 WX_UIImage  wxOSXGetUIImageFromCGImage( CGImageRef image )
 350 {
 351     UIImage  *newImage = [UIImage imageWithCGImage:image];
 352     [newImage autorelease];
 353     return( newImage );
 354 }
 355
 356 #endif
 357
 358 #if wxOSX_USE_COCOA
 359
 360 //  From "Cocoa Drawing Guide:Working with Images"
 361 WX_NSImage  wxOSXGetNSImageFromCGImage( CGImageRef image )
 362 {
 363     NSRect      imageRect    = NSMakeRect(0.0, 0.0, 0.0, 0.0);
 364
 365     // Get the image dimensions.
 366     imageRect.size.height = CGImageGetHeight(image);
 367     imageRect.size.width = CGImageGetWidth(image);
 368
 369     // Create a new image to receive the Quartz image data.
 370     NSImage  *newImage = [[NSImage alloc] initWithSize:imageRect.size];
 371     [newImage lockFocus];
 372
 373     // Get the Quartz context and draw.
 374     CGContextRef  imageContext = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 375     CGContextDrawImage( imageContext, *(CGRect*)&imageRect, image );
 376     [newImage unlockFocus];
 377
 378     /*
 379         // Create a bitmap rep from the image...
 380         NSBitmapImageRep *bitmapRep = [[NSBitmapImageRep alloc] initWithCGImage:cgImage];
 381         // Create an NSImage and add the bitmap rep to it...
 382         NSImage *image = [[NSImage alloc] init];
 383         [image addRepresentation:bitmapRep];
 384         [bitmapRep release];
 385     */
 386     [newImage autorelease];
 387     return( newImage );
 388 }
 389
 390 CGImageRef wxOSXCreateCGImageFromNSImage( WX_NSImage nsimage )
 391 {
 392     // based on http://www.mail-archive.com/cocoa-dev@lists.apple.com/msg18065.html
 393
 394     NSSize imageSize = [nsimage size];
 395     CGColorSpaceRef genericRGB = CGColorSpaceCreateWithName(kCGColorSpaceGenericRGB);
 396     CGContextRef context = CGBitmapContextCreate(NULL, imageSize.width, imageSize.height, 8, 0, genericRGB, kCGImageAlphaPremultipliedFirst);
 397     NSGraphicsContext *nsGraphicsContext = [NSGraphicsContext graphicsContextWithGraphicsPort:context flipped:NO];
 398     [NSGraphicsContext saveGraphicsState];
 399     [NSGraphicsContext setCurrentContext:nsGraphicsContext];
 400     [[NSColor whiteColor] setFill];
 401     NSRectFill(NSMakeRect(0.0, 0.0, imageSize.width, imageSize.height));
 402     [nsimage drawAtPoint:NSZeroPoint fromRect:NSZeroRect operation:NSCompositeCopy fraction:1.0];
 403     [NSGraphicsContext setCurrentContext:nsGraphicsContext];
 404     CGImageRef image = CGBitmapContextCreateImage(context);
 405     CFRelease(context);
 406     return image;
 407  }
 408
 409 // ----------------------------------------------------------------------------
 410 // NSCursor Utils
 411 // ----------------------------------------------------------------------------
 412
 413 // copied from cursor.mm
 414
 415 static NSCursor* wxGetStockCursor( short sIndex )
 416 {
 417     ClassicCursor* pCursor = &gMacCursors[sIndex];
 418
 419     //Classic mac cursors are 1bps 16x16 black and white with a
 420     //identical mask that is 1 for on and 0 for off
 421     NSImage *theImage = [[NSImage alloc] initWithSize:NSMakeSize(16.0,16.0)];
 422
 423     //NSCursor takes an NSImage takes a number of Representations - here
 424     //we need only one for the raw data
 425     NSBitmapImageRep *theRep = [[NSBitmapImageRep alloc]
 426         initWithBitmapDataPlanes: NULL  // Tell Cocoa to allocate the planes for us.
 427         pixelsWide: 16      // All classic cursors are 16x16
 428         pixelsHigh: 16
 429         bitsPerSample: 1    // All classic cursors are bitmaps with bitmasks
 430         samplesPerPixel: 2  // Sample 0:image 1:mask
 431         hasAlpha: YES       // Identify last sample as a mask
 432         isPlanar: YES       // Use a separate array for each sample
 433         colorSpaceName: NSCalibratedWhiteColorSpace // 0.0=black 1.0=white
 434         bytesPerRow: 2      // Rows in each plane are on 2-byte boundaries (no pad)
 435         bitsPerPixel: 1];   // same as bitsPerSample since data is planar
 436
 437     // Ensure that Cocoa allocated 2 and only 2 of the 5 possible planes
 438     unsigned char *planes[5];
 439     [theRep getBitmapDataPlanes:planes];
 440     wxASSERT(planes[0] != NULL);
 441     wxASSERT(planes[1] != NULL);
 442     wxASSERT(planes[2] == NULL);
 443     wxASSERT(planes[3] == NULL);
 444     wxASSERT(planes[4] == NULL);
 445
 446     // NOTE1: The Cursor's bits field is white=0 black=1.. thus the bitwise-not
 447     // Why not use NSCalibratedBlackColorSpace?  Because that reverses the
 448     // sense of the alpha (mask) plane.
 449     // NOTE2: The mask data is 0=off 1=on
 450     // NOTE3: Cocoa asks for "premultiplied" color planes.  Since we have a
 451     // 1-bit color plane and a 1-bit alpha plane we can just do a bitwise-and
 452     // on the two.  The original cursor bitmaps have 0 (white actually) for
 453     // any masked-off pixels.  Therefore every masked-off pixel would be wrong
 454     // since we bit-flip all of the picture bits.  In practice, Cocoa doesn't
 455     // seem to care, but we are following the documentation.
 456
 457     // Fill in the color (black/white) plane
 458     for(int i=0; i<16; ++i)
 459     {
 460         planes[0][2*i  ] = (~pCursor->bits[i] & pCursor->mask[i]) >> 8 & 0xff;
 461         planes[0][2*i+1] = (~pCursor->bits[i] & pCursor->mask[i]) & 0xff;
 462     }
 463     // Fill in the alpha (i.e. mask) plane
 464     for(int i=0; i<16; ++i)
 465     {
 466         planes[1][2*i  ] = pCursor->mask[i] >> 8 & 0xff;
 467         planes[1][2*i+1] = pCursor->mask[i] & 0xff;
 468     }
 469
 470     //add the representation (data) to the image
 471     [theImage addRepresentation:theRep];
 472
 473     //create the new cursor
 474     NSCursor* theCursor =  [[NSCursor alloc]  initWithImage:theImage
 475                                     hotSpot:NSMakePoint(pCursor->hotspot[1], pCursor->hotspot[0])
 476                             ];
 477
 478     //do the usual cleanups
 479     [theRep release];
 480     [theImage release];
 481
 482     //return the new cursor
 483     return theCursor;
 484 }
 485
 486 WX_NSCursor wxMacCocoaCreateStockCursor( int cursor_type )
 487 {
 488     WX_NSCursor cursor = nil;
 489     switch (cursor_type)
 490     {
 491     case wxCURSOR_COPY_ARROW:
 492         cursor = [[NSCursor arrowCursor] retain];
 493         break;
 494
 495     case wxCURSOR_WATCH:
 496     case wxCURSOR_WAIT:
 497         // should be displayed by the system when things are running
 498         cursor = [[NSCursor arrowCursor] retain];
 499         break;
 500
 501     case wxCURSOR_IBEAM:
 502         cursor = [[NSCursor IBeamCursor] retain];
 503         break;
 504
 505     case wxCURSOR_CROSS:
 506         cursor = [[NSCursor crosshairCursor] retain];
 507         break;
 508
 509     case wxCURSOR_SIZENWSE:
 510         cursor = wxGetStockCursor(kwxCursorSizeNWSE);
 511         break;
 512
 513     case wxCURSOR_SIZENESW:
 514         cursor = wxGetStockCursor(kwxCursorSizeNESW);
 515         break;
 516
 517     case wxCURSOR_SIZEWE:
 518         cursor = [[NSCursor resizeLeftRightCursor] retain];
 519         break;
 520
 521     case wxCURSOR_SIZENS:
 522         cursor = [[NSCursor resizeUpDownCursor] retain];
 523         break;
 524
 525     case wxCURSOR_SIZING:
 526         cursor = wxGetStockCursor(kwxCursorSize);
 527         break;
 528
 529     case wxCURSOR_HAND:
 530         cursor = [[NSCursor pointingHandCursor] retain];
 531         break;
 532
 533     case wxCURSOR_BULLSEYE:
 534         cursor = wxGetStockCursor(kwxCursorBullseye);
 535         break;
 536
 537     case wxCURSOR_PENCIL:
 538         cursor = wxGetStockCursor(kwxCursorPencil);
 539         break;
 540
 541     case wxCURSOR_MAGNIFIER:
 542         cursor = wxGetStockCursor(kwxCursorMagnifier);
 543         break;
 544
 545     case wxCURSOR_NO_ENTRY:
 546         cursor = wxGetStockCursor(kwxCursorNoEntry);
 547         break;
 548
 549     case wxCURSOR_PAINT_BRUSH:
 550         cursor = wxGetStockCursor(kwxCursorPaintBrush);
 551         break;
 552
 553     case wxCURSOR_POINT_LEFT:
 554         cursor = wxGetStockCursor(kwxCursorPointLeft);
 555         break;
 556
 557     case wxCURSOR_POINT_RIGHT:
 558         cursor = wxGetStockCursor(kwxCursorPointRight);
 559         break;
 560
 561     case wxCURSOR_QUESTION_ARROW:
 562         cursor = wxGetStockCursor(kwxCursorQuestionArrow);
 563         break;
 564
 565     case wxCURSOR_BLANK:
 566         cursor = wxGetStockCursor(kwxCursorBlank);
 567         break;
 568
 569     case wxCURSOR_RIGHT_ARROW:
 570         cursor = wxGetStockCursor(kwxCursorRightArrow);
 571         break;
 572
 573     case wxCURSOR_SPRAYCAN:
 574         cursor = wxGetStockCursor(kwxCursorRoller);
 575         break;
 576
 577     case wxCURSOR_OPEN_HAND:
 578         cursor = [[NSCursor openHandCursor] retain];
 579         break;
 580
 581     case wxCURSOR_CLOSED_HAND:
 582         cursor = [[NSCursor closedHandCursor] retain];
 583         break;
 584
 585     case wxCURSOR_CHAR:
 586     case wxCURSOR_ARROW:
 587     case wxCURSOR_LEFT_BUTTON:
 588     case wxCURSOR_RIGHT_BUTTON:
 589     case wxCURSOR_MIDDLE_BUTTON:
 590     default:
 591         cursor = [[NSCursor arrowCursor] retain];
 592         break;
 593     }
 594     return cursor;
 595 }
 596
 597 //  C-based style wrapper routines around NSCursor
 598 WX_NSCursor  wxMacCocoaCreateCursorFromCGImage( CGImageRef cgImageRef, float hotSpotX, float hotSpotY )
 599 {
 600     static BOOL    firstTime  = YES;
 601
 602     if ( firstTime )
 603     {
 604         //  Must first call [[[NSWindow alloc] init] release] to get the NSWindow machinery set up so that NSCursor can use a window to cache the cursor image
 605         [[[NSWindow alloc] init] release];
 606         firstTime = NO;
 607     }
 608
 609     NSImage    *nsImage  = wxOSXGetNSImageFromCGImage( cgImageRef );
 610     NSCursor  *cursor    = [[NSCursor alloc] initWithImage:nsImage hotSpot:NSMakePoint( hotSpotX, hotSpotY )];
 611
 612     return cursor;
 613 }
 614
 615 void  wxMacCocoaSetCursor( WX_NSCursor cursor )
 616 {
 617     [cursor set];
 618 }
 619
 620 void  wxMacCocoaHideCursor()
 621 {
 622     [NSCursor hide];
 623 }
 624
 625 void  wxMacCocoaShowCursor()
 626 {
 627     [NSCursor unhide];
 628 }
 629
 630 #endif
 631