src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     BOOL _hasToolTip;
  91     NSTrackingRectTag   _lastToolTipTrackTag;
  92     id              _lastToolTipOwner;
  93     void*           _lastUserData;
  94
  95 }
  96
  97 @end // wxNSView
  98
  99 @interface NSView(PossibleMethods)
 100 - (void)setTitle:(NSString *)aString;
 101 - (void)setStringValue:(NSString *)aString;
 102 - (void)setIntValue:(int)anInt;
 103 - (void)setFloatValue:(float)aFloat;
 104 - (void)setDoubleValue:(double)aDouble;
 105
 106 - (double)minValue;
 107 - (double)maxValue;
 108 - (void)setMinValue:(double)aDouble;
 109 - (void)setMaxValue:(double)aDouble;
 110
 111 - (void)sizeToFit;
 112
 113 - (BOOL)isEnabled;
 114 - (void)setEnabled:(BOOL)flag;
 115
 116 - (void)setImage:(NSImage *)image;
 117 - (void)setControlSize:(NSControlSize)size;
 118
 119 - (void)setFont:(NSFont *)fontObject;
 120
 121 - (id)contentView;
 122
 123 - (void)setTarget:(id)anObject;
 124 - (void)setAction:(SEL)aSelector;
 125 - (void)setDoubleAction:(SEL)aSelector;
 126 - (void)setBackgroundColor:(NSColor*)aColor;
 127 - (void)setOpaque:(BOOL)opaque;
 128 - (void)setTextColor:(NSColor *)color;
 129 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 130 @end
 131
 132 // The following code is a combination of the code listed here:
 133 // http://lists.apple.com/archives/cocoa-dev/2008/Apr/msg01582.html
 134 // (which can't be used because KLGetCurrentKeyboardLayout etc aren't 64-bit)
 135 // and the code here:
 136 // http://inquisitivecocoa.com/category/objective-c/
 137 @interface NSEvent (OsGuiUtilsAdditions)
 138 - (NSString*) charactersIgnoringModifiersIncludingShift;
 139 @end
 140
 141 @implementation NSEvent (OsGuiUtilsAdditions)
 142 - (NSString*) charactersIgnoringModifiersIncludingShift {
 143     // First try -charactersIgnoringModifiers and look for keys which UCKeyTranslate translates
 144     // differently than AppKit.
 145     NSString* c = [self charactersIgnoringModifiers];
 146     if ([c length] == 1) {
 147         unichar codepoint = [c characterAtIndex:0];
 148         if ((codepoint >= 0xF700 && codepoint <= 0xF8FF) || codepoint == 0x7F) {
 149             return c;
 150         }
 151     }
 152     // This is not a "special" key, so ask UCKeyTranslate to give us the character with no
 153     // modifiers attached.  Actually, that's not quite accurate; we attach the Command modifier
 154     // which hints the OS to use Latin characters where possible, which is generally what we want.
 155     NSString* result = @"";
 156     TISInputSourceRef currentKeyboard = TISCopyCurrentKeyboardInputSource();
 157     CFDataRef uchr = (CFDataRef)TISGetInputSourceProperty(currentKeyboard, kTISPropertyUnicodeKeyLayoutData);
 158     CFRelease(currentKeyboard);
 159     if (uchr == NULL) {
 160         // this can happen for some non-U.S. input methods (eg. Romaji or Hiragana)
 161         return c;
 162     }
 163     const UCKeyboardLayout *keyboardLayout = (const UCKeyboardLayout*)CFDataGetBytePtr(uchr);
 164     if (keyboardLayout) {
 165         UInt32 deadKeyState = 0;
 166         UniCharCount maxStringLength = 255;
 167         UniCharCount actualStringLength = 0;
 168         UniChar unicodeString[maxStringLength];
 169
 170         OSStatus status = UCKeyTranslate(keyboardLayout,
 171                                          [self keyCode],
 172                                          kUCKeyActionDown,
 173                                          cmdKey >> 8,         // force the Command key to "on"
 174                                          LMGetKbdType(),
 175                                          kUCKeyTranslateNoDeadKeysMask,
 176                                          &deadKeyState,
 177                                          maxStringLength,
 178                                          &actualStringLength,
 179                                          unicodeString);
 180
 181         if(status == noErr)
 182             result = [NSString stringWithCharacters:unicodeString length:(NSInteger)actualStringLength];
 183     }
 184     return result;
 185 }
 186 @end
 187
 188 long wxOSXTranslateCocoaKey( NSEvent* event, int eventType )
 189 {
 190     long retval = 0;
 191
 192     if ([event type] != NSFlagsChanged)
 193     {
 194         NSString* s = [event charactersIgnoringModifiersIncludingShift];
 195         // backspace char reports as delete w/modifiers for some reason
 196         if ([s length] == 1)
 197         {
 198             if ( eventType == wxEVT_CHAR && ([event modifierFlags] & NSControlKeyMask) && ( [s characterAtIndex:0] >= 'a' && [s characterAtIndex:0] <= 'z' ) )
 199             {
 200                 retval = WXK_CONTROL_A + ([s characterAtIndex:0] - 'a');
 201             }
 202             else
 203             {
 204                 switch ( [s characterAtIndex:0] )
 205                 {
 206                     // backspace key
 207                     case 0x7F :
 208                     case 8 :
 209                         retval = WXK_BACK;
 210                         break;
 211                     case NSUpArrowFunctionKey :
 212                         retval = WXK_UP;
 213                         break;
 214                     case NSDownArrowFunctionKey :
 215                         retval = WXK_DOWN;
 216                         break;
 217                     case NSLeftArrowFunctionKey :
 218                         retval = WXK_LEFT;
 219                         break;
 220                     case NSRightArrowFunctionKey :
 221                         retval = WXK_RIGHT;
 222                         break;
 223                     case NSInsertFunctionKey  :
 224                         retval = WXK_INSERT;
 225                         break;
 226                     case NSDeleteFunctionKey  :
 227                         retval = WXK_DELETE;
 228                         break;
 229                     case NSHomeFunctionKey  :
 230                         retval = WXK_HOME;
 231                         break;
 232             //        case NSBeginFunctionKey  :
 233             //            retval = WXK_BEGIN;
 234             //            break;
 235                     case NSEndFunctionKey  :
 236                         retval = WXK_END;
 237                         break;
 238                     case NSPageUpFunctionKey  :
 239                         retval = WXK_PAGEUP;
 240                         break;
 241                    case NSPageDownFunctionKey  :
 242                         retval = WXK_PAGEDOWN;
 243                         break;
 244                    case NSHelpFunctionKey  :
 245                         retval = WXK_HELP;
 246                         break;
 247                     default:
 248                         int intchar = [s characterAtIndex: 0];
 249                         if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 250                             retval = WXK_F1 + (intchar - NSF1FunctionKey );
 251                         else if ( intchar > 0 && intchar < 32 )
 252                             retval = intchar;
 253                         break;
 254                 }
 255             }
 256         }
 257     }
 258
 259     // Some keys don't seem to have constants. The code mimics the approach
 260     // taken by WebKit. See:
 261     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 262     switch( [event keyCode] )
 263     {
 264         // command key
 265         case 54:
 266         case 55:
 267             retval = WXK_CONTROL;
 268             break;
 269         // caps locks key
 270         case 57: // Capslock
 271             retval = WXK_CAPITAL;
 272             break;
 273         // shift key
 274         case 56: // Left Shift
 275         case 60: // Right Shift
 276             retval = WXK_SHIFT;
 277             break;
 278         // alt key
 279         case 58: // Left Alt
 280         case 61: // Right Alt
 281             retval = WXK_ALT;
 282             break;
 283         // ctrl key
 284         case 59: // Left Ctrl
 285         case 62: // Right Ctrl
 286             retval = WXK_RAW_CONTROL;
 287             break;
 288         // clear key
 289         case 71:
 290             retval = WXK_CLEAR;
 291             break;
 292         // tab key
 293         case 48:
 294             retval = WXK_TAB;
 295             break;
 296         default:
 297             break;
 298     }
 299
 300     // Check for NUMPAD keys.  For KEY_UP/DOWN events we need to use the
 301     // WXK_NUMPAD constants, but for the CHAR event we want to use the
 302     // standard ascii values
 303     if ( eventType != wxEVT_CHAR )
 304     {
 305         switch( [event keyCode] )
 306         {
 307             case 75: // /
 308                 retval = WXK_NUMPAD_DIVIDE;
 309                 break;
 310             case 67: // *
 311                 retval = WXK_NUMPAD_MULTIPLY;
 312                 break;
 313             case 78: // -
 314                 retval = WXK_NUMPAD_SUBTRACT;
 315                 break;
 316             case 69: // +
 317                 retval = WXK_NUMPAD_ADD;
 318                 break;
 319             case 76: // Enter
 320                 retval = WXK_NUMPAD_ENTER;
 321                 break;
 322             case 65: // .
 323                 retval = WXK_NUMPAD_DECIMAL;
 324                 break;
 325             case 82: // 0
 326                 retval = WXK_NUMPAD0;
 327                 break;
 328             case 83: // 1
 329                 retval = WXK_NUMPAD1;
 330                 break;
 331             case 84: // 2
 332                 retval = WXK_NUMPAD2;
 333                 break;
 334             case 85: // 3
 335                 retval = WXK_NUMPAD3;
 336                 break;
 337             case 86: // 4
 338                 retval = WXK_NUMPAD4;
 339                 break;
 340             case 87: // 5
 341                 retval = WXK_NUMPAD5;
 342                 break;
 343             case 88: // 6
 344                 retval = WXK_NUMPAD6;
 345                 break;
 346             case 89: // 7
 347                 retval = WXK_NUMPAD7;
 348                 break;
 349             case 91: // 8
 350                 retval = WXK_NUMPAD8;
 351                 break;
 352             case 92: // 9
 353                 retval = WXK_NUMPAD9;
 354                 break;
 355             default:
 356                 //retval = [event keyCode];
 357                 break;
 358         }
 359     }
 360     return retval;
 361 }
 362
 363 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 364 {
 365     UInt32 modifiers = [nsEvent modifierFlags] ;
 366     int eventType = [nsEvent type];
 367
 368     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 369     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 370     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 371     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 372
 373     wxevent.m_rawCode = [nsEvent keyCode];
 374     wxevent.m_rawFlags = modifiers;
 375
 376     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 377
 378     wxString chars;
 379     if ( eventType != NSFlagsChanged )
 380     {
 381         NSString* nschars = [[nsEvent charactersIgnoringModifiersIncludingShift] uppercaseString];
 382         if ( charString )
 383         {
 384             // if charString is set, it did not come from key up / key down
 385             wxevent.SetEventType( wxEVT_CHAR );
 386             chars = wxCFStringRef::AsString(charString);
 387         }
 388         else if ( nschars )
 389         {
 390             chars = wxCFStringRef::AsString(nschars);
 391         }
 392     }
 393
 394     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 395     long keyval = 0;
 396
 397     if (wxevent.GetEventType() != wxEVT_CHAR)
 398     {
 399         keyval = wxOSXTranslateCocoaKey(nsEvent, wxevent.GetEventType()) ;
 400         switch (eventType)
 401         {
 402             case NSKeyDown :
 403                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 404                 break;
 405             case NSKeyUp :
 406                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 407                 break;
 408             case NSFlagsChanged :
 409                 switch (keyval)
 410                 {
 411                     case WXK_CONTROL:
 412                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 413                         break;
 414                     case WXK_SHIFT:
 415                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 416                         break;
 417                     case WXK_ALT:
 418                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 419                         break;
 420                     case WXK_RAW_CONTROL:
 421                         wxevent.SetEventType( wxevent.m_rawControlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 422                         break;
 423                 }
 424                 break;
 425             default :
 426                 break ;
 427         }
 428     }
 429
 430     if ( !keyval )
 431     {
 432         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 433             keyval = wxToupper( aunichar ) ;
 434         else
 435             keyval = aunichar;
 436     }
 437
 438 #if wxUSE_UNICODE
 439     // OS X generates events with key codes in Unicode private use area for
 440     // unprintable symbols such as cursor arrows (WXK_UP is mapped to U+F700)
 441     // and function keys (WXK_F2 is U+F705). We don't want to use them as the
 442     // result of wxKeyEvent::GetUnicodeKey() however as it's supposed to return
 443     // WXK_NONE for "non characters" so explicitly exclude them.
 444     //
 445     // We only exclude the private use area inside the Basic Multilingual Plane
 446     // as key codes beyond it don't seem to be currently used.
 447     if ( !(aunichar >= 0xe000 && aunichar < 0xf900) )
 448         wxevent.m_uniChar = aunichar;
 449 #endif
 450     wxevent.m_keyCode = keyval;
 451
 452     wxWindowMac* peer = GetWXPeer();
 453     if ( peer )
 454     {
 455         wxevent.SetEventObject(peer);
 456         wxevent.SetId(peer->GetId()) ;
 457     }
 458 }
 459
 460 UInt32 g_lastButton = 0 ;
 461 bool g_lastButtonWasFakeRight = false ;
 462
 463 // better scroll wheel support
 464 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 465
 466 @interface NSEvent (DeviceDelta)
 467 - (CGFloat)deviceDeltaX;
 468 - (CGFloat)deviceDeltaY;
 469
 470 // 10.7+
 471 - (BOOL)hasPreciseScrollingDeltas;
 472 - (CGFloat)scrollingDeltaX;
 473 - (CGFloat)scrollingDeltaY;
 474 @end
 475
 476 void wxWidgetCocoaImpl::SetupCoordinates(wxCoord &x, wxCoord &y, NSEvent* nsEvent)
 477 {
 478     NSPoint locationInWindow = [nsEvent locationInWindow];
 479
 480     // adjust coordinates for the window of the target view
 481     if ( [nsEvent window] != [m_osxView window] )
 482     {
 483         if ( [nsEvent window] != nil )
 484             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 485
 486         if ( [m_osxView window] != nil )
 487             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 488     }
 489
 490     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 491     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 492
 493     x = locationInViewWX.x;
 494     y = locationInViewWX.y;
 495
 496 }
 497
 498 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 499 {
 500     int eventType = [nsEvent type];
 501     UInt32 modifiers = [nsEvent modifierFlags] ;
 502
 503     SetupCoordinates(wxevent.m_x, wxevent.m_y, nsEvent);
 504
 505     // these parameters are not given for all events
 506     UInt32 button = [nsEvent buttonNumber];
 507     UInt32 clickCount = 0;
 508
 509     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 510     wxevent.m_rawControlDown = modifiers & NSControlKeyMask;
 511     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 512     wxevent.m_controlDown = modifiers & NSCommandKeyMask;
 513     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 514
 515     UInt32 mouseChord = 0;
 516
 517     switch (eventType)
 518     {
 519         case NSLeftMouseDown :
 520         case NSLeftMouseDragged :
 521             mouseChord = 1U;
 522             break;
 523         case NSRightMouseDown :
 524         case NSRightMouseDragged :
 525             mouseChord = 2U;
 526             break;
 527         case NSOtherMouseDown :
 528         case NSOtherMouseDragged :
 529             mouseChord = 4U;
 530             break;
 531     }
 532
 533     // a control click is interpreted as a right click
 534     bool thisButtonIsFakeRight = false ;
 535     if ( button == 0 && (modifiers & NSControlKeyMask) )
 536     {
 537         button = 1 ;
 538         thisButtonIsFakeRight = true ;
 539     }
 540
 541     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 542     if ( clickCount > 1 && button != g_lastButton )
 543         clickCount = 1 ;
 544
 545     // we must make sure that our synthetic 'right' button corresponds in
 546     // mouse down, moved and mouse up, and does not deliver a right down and left up
 547     switch (eventType)
 548     {
 549         case NSLeftMouseDown :
 550         case NSRightMouseDown :
 551         case NSOtherMouseDown :
 552             g_lastButton = button ;
 553             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 554             break;
 555      }
 556
 557     if ( button == 0 )
 558     {
 559         g_lastButton = 0 ;
 560         g_lastButtonWasFakeRight = false ;
 561     }
 562     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 563         button = g_lastButton ;
 564
 565     // Adjust the chord mask to remove the primary button and add the
 566     // secondary button.  It is possible that the secondary button is
 567     // already pressed, e.g. on a mouse connected to a laptop, but this
 568     // possibility is ignored here:
 569     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 570         mouseChord = ((mouseChord & ~1U) | 2U);
 571
 572     if(mouseChord & 1U)
 573                 wxevent.m_leftDown = true ;
 574     if(mouseChord & 2U)
 575                 wxevent.m_rightDown = true ;
 576     if(mouseChord & 4U)
 577                 wxevent.m_middleDown = true ;
 578
 579     // translate into wx types
 580     switch (eventType)
 581     {
 582         case NSLeftMouseDown :
 583         case NSRightMouseDown :
 584         case NSOtherMouseDown :
 585             clickCount = [nsEvent clickCount];
 586             switch ( button )
 587             {
 588                 case 0 :
 589                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 590                     break ;
 591
 592                 case 1 :
 593                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 594                     break ;
 595
 596                 case 2 :
 597                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 598                     break ;
 599
 600                 default:
 601                     break ;
 602             }
 603             break ;
 604
 605         case NSLeftMouseUp :
 606         case NSRightMouseUp :
 607         case NSOtherMouseUp :
 608             clickCount = [nsEvent clickCount];
 609             switch ( button )
 610             {
 611                 case 0 :
 612                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 613                     break ;
 614
 615                 case 1 :
 616                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 617                     break ;
 618
 619                 case 2 :
 620                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 621                     break ;
 622
 623                 default:
 624                     break ;
 625             }
 626             break ;
 627
 628      case NSScrollWheel :
 629         {
 630             float deltaX = 0.0;
 631             float deltaY = 0.0;
 632
 633             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 634
 635             if ( UMAGetSystemVersion() >= 0x1070 )
 636             {
 637                 if ( [nsEvent hasPreciseScrollingDeltas] )
 638                 {
 639                     deltaX = [nsEvent scrollingDeltaX];
 640                     deltaY = [nsEvent scrollingDeltaY];
 641                 }
 642                 else
 643                 {
 644                     deltaX = [nsEvent scrollingDeltaX] * 10;
 645                     deltaY = [nsEvent scrollingDeltaY] * 10;
 646                 }
 647             }
 648             else
 649             {
 650                 const EventRef cEvent = (EventRef) [nsEvent eventRef];
 651                 // see http://developer.apple.com/qa/qa2005/qa1453.html
 652                 // for more details on why we have to look for the exact type
 653
 654                 bool isMouseScrollEvent = false;
 655                 if ( cEvent )
 656                     isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 657
 658                 if ( isMouseScrollEvent )
 659                 {
 660                     deltaX = [nsEvent deviceDeltaX];
 661                     deltaY = [nsEvent deviceDeltaY];
 662                 }
 663                 else
 664                 {
 665                     deltaX = ([nsEvent deltaX] * 10);
 666                     deltaY = ([nsEvent deltaY] * 10);
 667                 }
 668             }
 669
 670             wxevent.m_wheelDelta = 10;
 671             wxevent.m_linesPerAction = 1;
 672
 673             if ( fabs(deltaX) > fabs(deltaY) )
 674             {
 675                 wxevent.m_wheelAxis = wxMOUSE_WHEEL_HORIZONTAL;
 676                 wxevent.m_wheelRotation = (int)deltaX;
 677             }
 678             else
 679             {
 680                 wxevent.m_wheelRotation = (int)deltaY;
 681             }
 682
 683         }
 684         break ;
 685
 686         case NSMouseEntered :
 687             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 688             break;
 689         case NSMouseExited :
 690             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 691             break;
 692         case NSLeftMouseDragged :
 693         case NSRightMouseDragged :
 694         case NSOtherMouseDragged :
 695         case NSMouseMoved :
 696             wxevent.SetEventType( wxEVT_MOTION ) ;
 697             break;
 698         default :
 699             break ;
 700     }
 701
 702     wxevent.m_clickCount = clickCount;
 703     wxWindowMac* peer = GetWXPeer();
 704     if ( peer )
 705     {
 706         wxevent.SetEventObject(peer);
 707         wxevent.SetId(peer->GetId()) ;
 708     }
 709 }
 710
 711 @implementation wxNSView
 712
 713 + (void)initialize
 714 {
 715     static BOOL initialized = NO;
 716     if (!initialized)
 717     {
 718         initialized = YES;
 719         wxOSXCocoaClassAddWXMethods( self );
 720     }
 721 }
 722
 723 /* idea taken from webkit sources: overwrite the methods that (private) NSToolTipManager will use to attach its tracking rectangle
 724  * then when changing the tooltip send fake view-exit and view-enter methods which will lead to a tooltip refresh
 725  */
 726
 727
 728 - (void)_sendToolTipMouseExited
 729 {
 730     // Nothing matters except window, trackingNumber, and userData.
 731     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseExited
 732                                                 location:NSMakePoint(0, 0)
 733                                            modifierFlags:0
 734                                                timestamp:0
 735                                             windowNumber:[[self window] windowNumber]
 736                                                  context:NULL
 737                                              eventNumber:0
 738                                           trackingNumber:_lastToolTipTrackTag
 739                                                 userData:_lastUserData];
 740     [_lastToolTipOwner mouseExited:fakeEvent];
 741 }
 742
 743 - (void)_sendToolTipMouseEntered
 744 {
 745     // Nothing matters except window, trackingNumber, and userData.
 746     NSEvent *fakeEvent = [NSEvent enterExitEventWithType:NSMouseEntered
 747                                                 location:NSMakePoint(0, 0)
 748                                            modifierFlags:0
 749                                                timestamp:0
 750                                             windowNumber:[[self window] windowNumber]
 751                                                  context:NULL
 752                                              eventNumber:0
 753                                           trackingNumber:_lastToolTipTrackTag
 754                                                 userData:_lastUserData];
 755     [_lastToolTipOwner mouseEntered:fakeEvent];
 756 }
 757
 758 - (void)setToolTip:(NSString *)string;
 759 {
 760     if (string)
 761     {
 762         if ( _hasToolTip )
 763         {
 764             [self _sendToolTipMouseExited];
 765         }
 766
 767         [super setToolTip:string];
 768         _hasToolTip = YES;
 769         [self _sendToolTipMouseEntered];
 770     }
 771     else
 772     {
 773         if ( _hasToolTip )
 774         {
 775             [self _sendToolTipMouseExited];
 776             [super setToolTip:nil];
 777             _hasToolTip = NO;
 778         }
 779     }
 780 }
 781
 782 - (NSTrackingRectTag)addTrackingRect:(NSRect)rect owner:(id)owner userData:(void *)data assumeInside:(BOOL)assumeInside
 783 {
 784     NSTrackingRectTag tag = [super addTrackingRect:rect owner:owner userData:data assumeInside:assumeInside];
 785     if ( owner != self )
 786     {
 787         _lastUserData = data;
 788         _lastToolTipOwner = owner;
 789         _lastToolTipTrackTag = tag;
 790     }
 791     return tag;
 792 }
 793
 794 - (void)removeTrackingRect:(NSTrackingRectTag)tag
 795 {
 796     if (tag == _lastToolTipTrackTag)
 797     {
 798         _lastUserData = NULL;
 799         _lastToolTipOwner = nil;
 800         _lastToolTipTrackTag = 0;
 801     }
 802     [super removeTrackingRect:tag];
 803 }
 804
 805 #if wxOSX_USE_NATIVE_FLIPPED
 806 - (BOOL)isFlipped
 807 {
 808     return YES;
 809 }
 810 #endif
 811
 812 - (BOOL) canBecomeKeyView
 813 {
 814     wxWidgetCocoaImpl* viewimpl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 815     if ( viewimpl && viewimpl->IsUserPane() && viewimpl->GetWXPeer() )
 816         return viewimpl->GetWXPeer()->AcceptsFocus();
 817     return NO;
 818 }
 819
 820 @end // wxNSView
 821
 822 //
 823 // event handlers
 824 //
 825
 826 #if wxUSE_DRAG_AND_DROP
 827
 828 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 829 // for details on the NSPasteboard -> PasteboardRef conversion
 830
 831 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 832 {
 833     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 834     if (impl == NULL)
 835         return NSDragOperationNone;
 836
 837     return impl->draggingEntered(sender, self, _cmd);
 838 }
 839
 840 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 841 {
 842     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 843     if (impl == NULL)
 844         return ;
 845
 846     return impl->draggingExited(sender, self, _cmd);
 847 }
 848
 849 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 850 {
 851     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 852     if (impl == NULL)
 853         return NSDragOperationNone;
 854
 855     return impl->draggingUpdated(sender, self, _cmd);
 856 }
 857
 858 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 859 {
 860     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 861     if (impl == NULL)
 862         return NSDragOperationNone;
 863
 864     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 865 }
 866
 867 #endif
 868
 869 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 870 {
 871     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 872     if (impl == NULL)
 873         return;
 874
 875     impl->mouseEvent(event, self, _cmd);
 876 }
 877
 878 void wxOSX_cursorUpdate(NSView* self, SEL _cmd, NSEvent *event)
 879 {
 880     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 881     if (impl == NULL)
 882         return;
 883
 884     impl->cursorUpdate(event, self, _cmd);
 885 }
 886
 887 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 888 {
 889     // This is needed to support click through, otherwise the first click on a window
 890     // will not do anything unless it is the active window already.
 891     return YES;
 892 }
 893
 894 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 895 {
 896     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 897     if (impl == NULL)
 898         return;
 899
 900     impl->keyEvent(event, self, _cmd);
 901 }
 902
 903 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 904 {
 905     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 906     if (impl == NULL)
 907         return;
 908
 909     impl->insertText(text, self, _cmd);
 910 }
 911
 912 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 913 {
 914     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 915     if (impl == NULL)
 916         return NO;
 917
 918     return impl->performKeyEquivalent(event, self, _cmd);
 919 }
 920
 921 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 922 {
 923     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 924     if (impl == NULL)
 925         return NO;
 926
 927     return impl->acceptsFirstResponder(self, _cmd);
 928 }
 929
 930 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 931 {
 932     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 933     if (impl == NULL)
 934         return NO;
 935
 936     return impl->becomeFirstResponder(self, _cmd);
 937 }
 938
 939 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 940 {
 941     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 942     if (impl == NULL)
 943         return NO;
 944
 945     return impl->resignFirstResponder(self, _cmd);
 946 }
 947
 948 #if !wxOSX_USE_NATIVE_FLIPPED
 949
 950 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 951 {
 952     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 953     if (impl == NULL)
 954         return NO;
 955
 956     return impl->isFlipped(self, _cmd) ? YES:NO;
 957 }
 958
 959 #endif
 960
 961 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 962
 963 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 964 {
 965     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 966     if (impl == NULL)
 967         return;
 968
 969 #if wxUSE_THREADS
 970     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 971     // dialog. This causes a drawRect of the active dialog from outside the
 972     // main UI thread. This causes an occasional crash since the wx drawing
 973     // objects (like wxPen) are not thread safe.
 974     //
 975     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 976     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 977     if ( !wxThread::IsMain() )
 978     {
 979         if ( impl->IsUserPane() )
 980         {
 981             wxWindow* win = impl->GetWXPeer();
 982             if ( win->UseBgCol() )
 983             {
 984
 985                 CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 986                 CGContextSaveGState( context );
 987
 988                 CGContextSetFillColorWithColor( context, win->GetBackgroundColour().GetCGColor());
 989                 CGRect r = CGRectMake(rect.origin.x, rect.origin.y, rect.size.width, rect.size.height);
 990                 CGContextFillRect( context, r );
 991
 992                 CGContextRestoreGState( context );
 993             }
 994         }
 995         else
 996         {
 997             // just call the superclass handler, we don't need any custom wx drawing
 998             // here and it seems to work fine:
 999             wxOSX_DrawRectHandlerPtr
1000             superimpl = (wxOSX_DrawRectHandlerPtr)
1001             [[self superclass] instanceMethodForSelector:_cmd];
1002             superimpl(self, _cmd, rect);
1003         }
1004
1005       return;
1006     }
1007 #endif // wxUSE_THREADS
1008
1009     return impl->drawRect(&rect, self, _cmd);
1010 }
1011
1012 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
1013 {
1014     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
1015     if (impl == NULL)
1016         return;
1017
1018     impl->controlAction(self, _cmd, sender);
1019 }
1020
1021 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
1022 {
1023     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
1024     if (impl == NULL)
1025         return;
1026
1027     impl->controlDoubleAction(self, _cmd, sender);
1028 }
1029
1030 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1031 {
1032     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1033     NSPasteboard *pboard = [sender draggingPasteboard];
1034     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1035
1036     wxWindow* wxpeer = GetWXPeer();
1037     if ( wxpeer == NULL )
1038         return NSDragOperationNone;
1039
1040     wxDropTarget* target = wxpeer->GetDropTarget();
1041     if ( target == NULL )
1042         return NSDragOperationNone;
1043
1044     wxDragResult result = wxDragNone;
1045     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1046     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1047
1048     if ( sourceDragMask & NSDragOperationLink )
1049         result = wxDragLink;
1050     else if ( sourceDragMask & NSDragOperationCopy )
1051         result = wxDragCopy;
1052     else if ( sourceDragMask & NSDragOperationMove )
1053         result = wxDragMove;
1054
1055     PasteboardRef pboardRef;
1056     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1057     target->SetCurrentDragPasteboard(pboardRef);
1058     result = target->OnEnter(pt.x, pt.y, result);
1059     CFRelease(pboardRef);
1060
1061     NSDragOperation nsresult = NSDragOperationNone;
1062     switch (result )
1063     {
1064         case wxDragLink:
1065             nsresult = NSDragOperationLink;
1066         case wxDragMove:
1067             nsresult = NSDragOperationMove;
1068         case wxDragCopy:
1069             nsresult = NSDragOperationCopy;
1070         default :
1071             break;
1072     }
1073     return nsresult;
1074 }
1075
1076 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1077 {
1078     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1079     NSPasteboard *pboard = [sender draggingPasteboard];
1080
1081     wxWindow* wxpeer = GetWXPeer();
1082     if ( wxpeer == NULL )
1083         return;
1084
1085     wxDropTarget* target = wxpeer->GetDropTarget();
1086     if ( target == NULL )
1087         return;
1088
1089     PasteboardRef pboardRef;
1090     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1091     target->SetCurrentDragPasteboard(pboardRef);
1092     target->OnLeave();
1093     CFRelease(pboardRef);
1094  }
1095
1096 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1097 {
1098     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1099     NSPasteboard *pboard = [sender draggingPasteboard];
1100     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1101
1102     wxWindow* wxpeer = GetWXPeer();
1103     if ( wxpeer == NULL )
1104         return NSDragOperationNone;
1105
1106     wxDropTarget* target = wxpeer->GetDropTarget();
1107     if ( target == NULL )
1108         return NSDragOperationNone;
1109
1110     wxDragResult result = wxDragNone;
1111     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1112     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1113
1114     if ( sourceDragMask & NSDragOperationLink )
1115         result = wxDragLink;
1116     else if ( sourceDragMask & NSDragOperationCopy )
1117         result = wxDragCopy;
1118     else if ( sourceDragMask & NSDragOperationMove )
1119         result = wxDragMove;
1120
1121     PasteboardRef pboardRef;
1122     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1123     target->SetCurrentDragPasteboard(pboardRef);
1124     result = target->OnDragOver(pt.x, pt.y, result);
1125     CFRelease(pboardRef);
1126
1127     NSDragOperation nsresult = NSDragOperationNone;
1128     switch (result )
1129     {
1130         case wxDragLink:
1131             nsresult = NSDragOperationLink;
1132         case wxDragMove:
1133             nsresult = NSDragOperationMove;
1134         case wxDragCopy:
1135             nsresult = NSDragOperationCopy;
1136         default :
1137             break;
1138     }
1139     return nsresult;
1140 }
1141
1142 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1143 {
1144     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
1145
1146     NSPasteboard *pboard = [sender draggingPasteboard];
1147     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
1148
1149     wxWindow* wxpeer = GetWXPeer();
1150     wxDropTarget* target = wxpeer->GetDropTarget();
1151     wxDragResult result = wxDragNone;
1152     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
1153     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
1154
1155     if ( sourceDragMask & NSDragOperationLink )
1156         result = wxDragLink;
1157     else if ( sourceDragMask & NSDragOperationCopy )
1158         result = wxDragCopy;
1159     else if ( sourceDragMask & NSDragOperationMove )
1160         result = wxDragMove;
1161
1162     PasteboardRef pboardRef;
1163     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
1164     target->SetCurrentDragPasteboard(pboardRef);
1165
1166     if (target->OnDrop(pt.x, pt.y))
1167         result = target->OnData(pt.x, pt.y, result);
1168
1169     CFRelease(pboardRef);
1170
1171     return result != wxDragNone;
1172 }
1173
1174 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
1175 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1176 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1177 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
1178
1179 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1180 {
1181     // we are getting moved events for all windows in the hierarchy, not something wx expects
1182     // therefore we only handle it for the deepest child in the hierarchy
1183     if ( 1 /* [event type] == NSMouseMoved */ )
1184     {
1185         NSView* hitview = [[[slf window] contentView] hitTest:[event locationInWindow]];
1186         if ( hitview == NULL || hitview != slf)
1187             return;
1188     }
1189
1190     if ( !DoHandleMouseEvent(event) )
1191     {
1192         // for plain NSView mouse events would propagate to parents otherwise
1193         if (!IsUserPane())
1194         {
1195             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1196             superimpl(slf, (SEL)_cmd, event);
1197
1198             // super of built-ins keeps the mouse up, as wx expects this event, we have to synthesize it
1199             // only trigger if at this moment the mouse is already up
1200             if ( [ event type]  == NSLeftMouseDown && !wxGetMouseState().LeftIsDown() )
1201             {
1202                 wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
1203                 SetupMouseEvent(wxevent , event) ;
1204                 wxevent.SetEventType(wxEVT_LEFT_UP);
1205
1206                 GetWXPeer()->HandleWindowEvent(wxevent);
1207             }
1208         }
1209     }
1210 }
1211
1212 void wxWidgetCocoaImpl::cursorUpdate(WX_NSEvent event, WXWidget slf, void *_cmd)
1213 {
1214     if ( !SetupCursor(event) )
1215     {
1216         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1217             superimpl(slf, (SEL)_cmd, event);
1218     }
1219  }
1220
1221 bool wxWidgetCocoaImpl::SetupCursor(WX_NSEvent event)
1222 {
1223     extern wxCursor gGlobalCursor;
1224
1225     if ( gGlobalCursor.IsOk() )
1226     {
1227         gGlobalCursor.MacInstall();
1228         return true;
1229     }
1230     else
1231     {
1232         wxWindow* cursorTarget = GetWXPeer();
1233         wxCoord x,y;
1234         SetupCoordinates(x, y, event);
1235         wxPoint cursorPoint( x , y ) ;
1236
1237         while ( cursorTarget && !cursorTarget->MacSetupCursor( cursorPoint ) )
1238         {
1239             // at least in GTK cursor events are not propagated either ...
1240 #if 1
1241             cursorTarget = NULL;
1242 #else
1243             cursorTarget = cursorTarget->GetParent() ;
1244             if ( cursorTarget )
1245                 cursorPoint += cursorTarget->GetPosition();
1246 #endif
1247         }
1248
1249         return cursorTarget != NULL;
1250     }
1251 }
1252
1253 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1254 {
1255     if ( [event type] == NSKeyDown )
1256     {
1257         // there are key equivalents that are not command-combos and therefore not handled by cocoa automatically,
1258         // therefore we call the menubar directly here, exit if the menu is handling the shortcut
1259         if ( [[[NSApplication sharedApplication] mainMenu] performKeyEquivalent:event] )
1260             return;
1261
1262         m_lastKeyDownEvent = event;
1263     }
1264
1265     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1266     {
1267         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1268         superimpl(slf, (SEL)_cmd, event);
1269     }
1270     m_lastKeyDownEvent = NULL;
1271 }
1272
1273 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1274 {
1275     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1276     {
1277         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1278         superimpl(slf, (SEL)_cmd, text);
1279     }
1280 }
1281
1282
1283 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1284 {
1285     bool handled = false;
1286
1287     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1288     SetupKeyEvent( wxevent, event );
1289
1290     // because performKeyEquivalent is going up the entire view hierarchy, we don't have to
1291     // walk up the ancestors ourselves but let cocoa do it
1292
1293     int command = m_wxPeer->GetAcceleratorTable()->GetCommand( wxevent );
1294     if (command != -1)
1295     {
1296         wxEvtHandler * const handler = m_wxPeer->GetEventHandler();
1297
1298         wxCommandEvent command_event( wxEVT_COMMAND_MENU_SELECTED, command );
1299         command_event.SetEventObject( wxevent.GetEventObject() );
1300         handled = handler->ProcessEvent( command_event );
1301
1302         if ( !handled )
1303         {
1304             // accelerators can also be used with buttons, try them too
1305             command_event.SetEventType(wxEVT_COMMAND_BUTTON_CLICKED);
1306             handled = handler->ProcessEvent( command_event );
1307         }
1308     }
1309
1310     if ( !handled )
1311     {
1312         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1313         return superimpl(slf, (SEL)_cmd, event);
1314     }
1315     return YES;
1316 }
1317
1318 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1319 {
1320     if ( IsUserPane() )
1321         return m_wxPeer->AcceptsFocus();
1322     else
1323     {
1324         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1325         return superimpl(slf, (SEL)_cmd);
1326     }
1327 }
1328
1329 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1330 {
1331     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1332     // get the current focus before running becomeFirstResponder
1333     NSView* otherView = FindFocus();
1334
1335     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1336     BOOL r = superimpl(slf, (SEL)_cmd);
1337     if ( r )
1338     {
1339         DoNotifyFocusEvent( true, otherWindow );
1340     }
1341
1342     return r;
1343 }
1344
1345 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1346 {
1347     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1348     BOOL r = superimpl(slf, (SEL)_cmd);
1349     // get the current focus after running resignFirstResponder
1350     // note that this value isn't reliable, it might return the same view that
1351     // is resigning
1352     NSView* otherView = FindFocus();
1353     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1354
1355     // It doesn't make sense to notify about the loss of focus if we're not
1356     // really losing it and the window which has just gained focus is the same
1357     // one as this window itself. Of course, this should never happen in the
1358     // first place but somehow it does in wxGrid code and without this check we
1359     // enter into an infinite recursion, see #12267.
1360     if ( otherWindow == this )
1361         return r;
1362
1363     // NSTextViews have an editor as true responder, therefore the might get the
1364     // resign notification if their editor takes over, don't trigger any event then
1365     if ( r && !m_hasEditor)
1366     {
1367         DoNotifyFocusEvent( false, otherWindow );
1368     }
1369     return r;
1370 }
1371
1372 #if !wxOSX_USE_NATIVE_FLIPPED
1373
1374 bool wxWidgetCocoaImpl::isFlipped(WXWidget slf, void *WXUNUSED(_cmd))
1375 {
1376     return m_isFlipped;
1377 }
1378
1379 #endif
1380
1381 #define OSX_DEBUG_DRAWING 0
1382
1383 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1384 {
1385     // preparing the update region
1386
1387     wxRegion updateRgn;
1388
1389     // since adding many rects to a region is a costly process, by default use the bounding rect
1390 #if 0
1391     const NSRect *rects;
1392     NSInteger count;
1393     [slf getRectsBeingDrawn:&rects count:&count];
1394     for ( int i = 0 ; i < count ; ++i )
1395     {
1396         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1397     }
1398 #else
1399     updateRgn.Union(wxFromNSRect(slf,*(NSRect*)rect));
1400 #endif
1401
1402     wxWindow* wxpeer = GetWXPeer();
1403
1404     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1405     {
1406         // as this update region is in native window locals we must adapt it to wx window local
1407         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1408     }
1409
1410     // Restrict the update region to the shape of the window, if any, and also
1411     // remember the region that we need to clear later.
1412     wxNonOwnedWindow* const tlwParent = wxpeer->MacGetTopLevelWindow();
1413     const bool isTopLevel = tlwParent == wxpeer;
1414     wxRegion clearRgn;
1415     if ( tlwParent->GetWindowStyle() & wxFRAME_SHAPED )
1416     {
1417         if ( isTopLevel )
1418             clearRgn = updateRgn;
1419
1420         int xoffset = 0, yoffset = 0;
1421         wxRegion rgn = tlwParent->GetShape();
1422         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1423         rgn.Offset( xoffset, yoffset );
1424         updateRgn.Intersect(rgn);
1425
1426         if ( isTopLevel )
1427         {
1428             // Exclude the window shape from the region to be cleared below.
1429             rgn.Xor(wxpeer->GetSize());
1430             clearRgn.Intersect(rgn);
1431         }
1432     }
1433
1434     wxpeer->GetUpdateRegion() = updateRgn;
1435
1436     // setting up the drawing context
1437
1438     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1439     CGContextSaveGState( context );
1440
1441 #if OSX_DEBUG_DRAWING
1442     CGContextBeginPath( context );
1443     CGContextMoveToPoint(context, 0, 0);
1444     NSRect bounds = [slf bounds];
1445     CGContextAddLineToPoint(context, 10, 0);
1446     CGContextMoveToPoint(context, 0, 0);
1447     CGContextAddLineToPoint(context, 0, 10);
1448     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1449     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1450     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1451     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1452     CGContextClosePath( context );
1453     CGContextStrokePath(context);
1454 #endif
1455
1456     if ( ![slf isFlipped] )
1457     {
1458         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1459         CGContextScaleCTM( context, 1, -1 );
1460     }
1461
1462     wxpeer->MacSetCGContextRef( context );
1463
1464     bool handled = wxpeer->MacDoRedraw( 0 );
1465     CGContextRestoreGState( context );
1466
1467     CGContextSaveGState( context );
1468     if ( !handled )
1469     {
1470         // call super
1471         SEL _cmd = @selector(drawRect:);
1472         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1473         superimpl(slf, _cmd, *(NSRect*)rect);
1474         CGContextRestoreGState( context );
1475         CGContextSaveGState( context );
1476     }
1477     // as we called restore above, we have to flip again if necessary
1478     if ( ![slf isFlipped] )
1479     {
1480         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1481         CGContextScaleCTM( context, 1, -1 );
1482     }
1483
1484     if ( isTopLevel )
1485     {
1486         // We also need to explicitly draw the part of the top level window
1487         // outside of its region with transparent colour to ensure that it is
1488         // really transparent.
1489         if ( clearRgn.IsOk() )
1490         {
1491             wxMacCGContextStateSaver saveState(context);
1492             wxWindowDC dc(wxpeer);
1493             dc.SetBackground(wxBrush(wxTransparentColour));
1494             dc.SetDeviceClippingRegion(clearRgn);
1495             dc.Clear();
1496         }
1497
1498 #if wxUSE_GRAPHICS_CONTEXT
1499         // If the window shape is defined by a path, stroke the path to show
1500         // the window border.
1501         const wxGraphicsPath& path = tlwParent->GetShapePath();
1502         if ( !path.IsNull() )
1503         {
1504             CGContextSetLineWidth(context, 1);
1505             CGContextSetStrokeColorWithColor(context, wxLIGHT_GREY->GetCGColor());
1506             CGContextAddPath(context, (CGPathRef) path.GetNativePath());
1507             CGContextStrokePath(context);
1508         }
1509 #endif // wxUSE_GRAPHICS_CONTEXT
1510     }
1511
1512     wxpeer->MacPaintChildrenBorders();
1513     wxpeer->MacSetCGContextRef( NULL );
1514     CGContextRestoreGState( context );
1515 }
1516
1517 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1518 {
1519     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1520     if ( wxpeer )
1521     {
1522         wxpeer->OSXSimulateFocusEvents();
1523         wxpeer->OSXHandleClicked(0);
1524     }
1525 }
1526
1527 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1528 {
1529 }
1530
1531 void wxWidgetCocoaImpl::controlTextDidChange()
1532 {
1533     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1534     if ( wxpeer )
1535     {
1536         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1537         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1538         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1539         if ( tc )
1540             tc->SendTextUpdatedEventIfAllowed();
1541         else if ( cb )
1542             cb->SendTextUpdatedEventIfAllowed();
1543         else
1544         {
1545             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1546         }
1547     }
1548 }
1549
1550 //
1551
1552 #if OBJC_API_VERSION >= 2
1553
1554 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1555     class_addMethod(c, s, i, t );
1556
1557 #else
1558
1559 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1560     { s, (char*) t, i },
1561
1562 #endif
1563
1564 void wxOSXCocoaClassAddWXMethods(Class c)
1565 {
1566
1567 #if OBJC_API_VERSION < 2
1568     static objc_method wxmethods[] =
1569     {
1570 #endif
1571
1572     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1573     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1574     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1575
1576     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1577     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1578     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1579
1580     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1581
1582     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1583     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1584     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1585
1586     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1587
1588     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1589     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1590     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1591
1592     wxOSX_CLASS_ADD_METHOD(c, @selector(cursorUpdate:), (IMP) wxOSX_cursorUpdate, "v@:@" )
1593
1594     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1595     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1596     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1597
1598     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1599
1600     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1601
1602     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1603     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1604     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1605
1606 #if !wxOSX_USE_NATIVE_FLIPPED
1607     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1608 #endif
1609     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1610
1611     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1612     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1613
1614 #if wxUSE_DRAG_AND_DROP
1615     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1616     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1617     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1618     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1619 #endif
1620
1621 #if OBJC_API_VERSION < 2
1622     } ;
1623     static int method_count = WXSIZEOF( wxmethods );
1624     static objc_method_list *wxmethodlist = NULL;
1625     if ( wxmethodlist == NULL )
1626     {
1627         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1628         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1629         wxmethodlist->method_count = method_count;
1630         wxmethodlist->obsolete = 0;
1631     }
1632     class_addMethods( c, wxmethodlist );
1633 #endif
1634 }
1635
1636 //
1637 // C++ implementation class
1638 //
1639
1640 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1641
1642 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl, bool isUserPane ) :
1643     wxWidgetImpl( peer, isRootControl, isUserPane )
1644 {
1645     Init();
1646     m_osxView = w;
1647
1648     // check if the user wants to create the control initially hidden
1649     if ( !peer->IsShown() )
1650         SetVisibility(false);
1651
1652     // gc aware handling
1653     if ( m_osxView )
1654         CFRetain(m_osxView);
1655     [m_osxView release];
1656 }
1657
1658 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1659 {
1660     Init();
1661 }
1662
1663 void wxWidgetCocoaImpl::Init()
1664 {
1665     m_osxView = NULL;
1666 #if !wxOSX_USE_NATIVE_FLIPPED
1667     m_isFlipped = true;
1668 #endif
1669     m_lastKeyDownEvent = NULL;
1670     m_hasEditor = false;
1671 }
1672
1673 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1674 {
1675     RemoveAssociations( this );
1676
1677     if ( !IsRootControl() )
1678     {
1679         NSView *sv = [m_osxView superview];
1680         if ( sv != nil )
1681             [m_osxView removeFromSuperview];
1682     }
1683     // gc aware handling
1684     if ( m_osxView )
1685         CFRelease(m_osxView);
1686 }
1687
1688 bool wxWidgetCocoaImpl::IsVisible() const
1689 {
1690     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1691 }
1692
1693 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1694 {
1695     [m_osxView setHidden:(visible ? NO:YES)];
1696 }
1697
1698 // ----------------------------------------------------------------------------
1699 // window animation stuff
1700 // ----------------------------------------------------------------------------
1701
1702 // define a delegate used to refresh the window during animation
1703 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1704 {
1705     wxWindow *m_win;
1706     bool m_isDone;
1707 }
1708
1709 - (id)init:(wxWindow *)win;
1710
1711 - (bool)isDone;
1712
1713 // NSAnimationDelegate methods
1714 - (void)animationDidEnd:(NSAnimation*)animation;
1715 - (void)animation:(NSAnimation*)animation
1716         didReachProgressMark:(NSAnimationProgress)progress;
1717 @end
1718
1719 @implementation wxNSAnimationDelegate
1720
1721 - (id)init:(wxWindow *)win
1722 {
1723     self = [super init];
1724
1725     m_win = win;
1726     m_isDone = false;
1727
1728     return self;
1729 }
1730
1731 - (bool)isDone
1732 {
1733     return m_isDone;
1734 }
1735
1736 - (void)animation:(NSAnimation*)animation
1737         didReachProgressMark:(NSAnimationProgress)progress
1738 {
1739     wxUnusedVar(animation);
1740     wxUnusedVar(progress);
1741
1742     m_win->SendSizeEvent();
1743     m_win->MacOnInternalSize();
1744 }
1745
1746 - (void)animationDidEnd:(NSAnimation*)animation
1747 {
1748     wxUnusedVar(animation);
1749     m_isDone = true;
1750 }
1751
1752 @end
1753
1754 /* static */
1755 bool
1756 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1757                                               bool show,
1758                                               wxShowEffect effect,
1759                                               unsigned timeout)
1760 {
1761     // create the dictionary describing the animation to perform on this view
1762     NSObject * const
1763         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1764     NSMutableDictionary * const
1765         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1766     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1767
1768     // determine the start and end rectangles assuming we're hiding the window
1769     const wxRect rectOrig = win->GetRect();
1770     wxRect rectStart,
1771            rectEnd;
1772     rectStart =
1773     rectEnd = rectOrig;
1774
1775     if ( show )
1776     {
1777         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1778                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1779             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1780         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1781                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1782             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1783         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1784                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1785             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1786         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1787                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1788             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1789     }
1790
1791     switch ( effect )
1792     {
1793         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1794         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1795             rectEnd.width = 0;
1796             break;
1797
1798         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1799         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1800             rectEnd.x = rectStart.GetRight();
1801             rectEnd.width = 0;
1802             break;
1803
1804         case wxSHOW_EFFECT_ROLL_TO_TOP:
1805         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1806             rectEnd.height = 0;
1807             break;
1808
1809         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1810         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1811             rectEnd.y = rectStart.GetBottom();
1812             rectEnd.height = 0;
1813             break;
1814
1815         case wxSHOW_EFFECT_EXPAND:
1816             rectEnd.x = rectStart.x + rectStart.width / 2;
1817             rectEnd.y = rectStart.y + rectStart.height / 2;
1818             rectEnd.width =
1819             rectEnd.height = 0;
1820             break;
1821
1822         case wxSHOW_EFFECT_BLEND:
1823             [dict setObject:(show ? NSViewAnimationFadeInEffect
1824                                   : NSViewAnimationFadeOutEffect)
1825                   forKey:NSViewAnimationEffectKey];
1826             break;
1827
1828         case wxSHOW_EFFECT_NONE:
1829         case wxSHOW_EFFECT_MAX:
1830             wxFAIL_MSG( "unexpected animation effect" );
1831             return false;
1832
1833         default:
1834             wxFAIL_MSG( "unknown animation effect" );
1835             return false;
1836     };
1837
1838     if ( show )
1839     {
1840         // we need to restore it to the original rectangle instead of making it
1841         // disappear
1842         wxSwap(rectStart, rectEnd);
1843
1844         // and as the window is currently hidden, we need to show it for the
1845         // animation to be visible at all (but don't restore it at its full
1846         // rectangle as it shouldn't appear immediately)
1847         win->SetSize(rectStart);
1848         win->Show();
1849     }
1850
1851     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1852                                     ? [(NSView *)viewOrWin superview]
1853                                     : nil;
1854     const NSRect rStart = wxToNSRect(parentView, rectStart);
1855     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1856
1857     [dict setObject:[NSValue valueWithRect:rStart]
1858           forKey:NSViewAnimationStartFrameKey];
1859     [dict setObject:[NSValue valueWithRect:rEnd]
1860           forKey:NSViewAnimationEndFrameKey];
1861
1862     // create an animation using the values in the above dictionary
1863     NSViewAnimation * const
1864         anim = [[NSViewAnimation alloc]
1865                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1866
1867     if ( !timeout )
1868     {
1869         // what is a good default duration? Windows uses 200ms, Web frameworks
1870         // use anything from 250ms to 1s... choose something in the middle
1871         timeout = 500;
1872     }
1873
1874     [anim setDuration:timeout/1000.];   // duration is in seconds here
1875
1876     // if the window being animated changes its layout depending on its size
1877     // (which is almost always the case) we need to redo it during animation
1878     //
1879     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1880     // controls in wxInfoBar visibly jump around)
1881     const int NUM_LAYOUTS = 20;
1882     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1883         [anim addProgressMark:f];
1884
1885     wxNSAnimationDelegate * const
1886         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1887     [anim setDelegate:animDelegate];
1888     [anim startAnimation];
1889
1890     // Cocoa is capable of doing animation asynchronously or even from separate
1891     // thread but wx API doesn't provide any way to be notified about the
1892     // animation end and without this we really must ensure that the window has
1893     // the expected (i.e. the same as if a simple Show() had been used) size
1894     // when we return, so block here until the animation finishes
1895     //
1896     // notice that because the default animation mode is NSAnimationBlocking,
1897     // no user input events ought to be processed from here
1898     {
1899         wxEventLoopGuarantor ensureEventLoopExistence;
1900         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1901         while ( ![animDelegate isDone] )
1902             loop->Dispatch();
1903     }
1904
1905     if ( !show )
1906     {
1907         // NSViewAnimation is smart enough to hide the NSView being animated at
1908         // the end but we also must ensure that it's hidden for wx too
1909         win->Hide();
1910
1911         // and we must also restore its size because it isn't expected to
1912         // change just because the window was hidden
1913         win->SetSize(rectOrig);
1914     }
1915     else
1916     {
1917         // refresh it once again after the end to ensure that everything is in
1918         // place
1919         win->SendSizeEvent();
1920         win->MacOnInternalSize();
1921     }
1922
1923     [anim setDelegate:nil];
1924     [animDelegate release];
1925     [anim release];
1926
1927     return true;
1928 }
1929
1930 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1931                                        wxShowEffect effect,
1932                                        unsigned timeout)
1933 {
1934     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1935 }
1936
1937 /* note that the drawing order between siblings is not defined under 10.4 */
1938 /* only starting from 10.5 the subview order is respected */
1939
1940 /* NSComparisonResult is typedef'd as an enum pre-Leopard but typedef'd as
1941  * NSInteger post-Leopard.  Pre-Leopard the Cocoa toolkit expects a function
1942  * returning int and not NSComparisonResult.  Post-Leopard the Cocoa toolkit
1943  * expects a function returning the new non-enum NSComparsionResult.
1944  * Hence we create a typedef named CocoaWindowCompareFunctionResult.
1945  */
1946 #if defined(NSINTEGER_DEFINED)
1947 typedef NSComparisonResult CocoaWindowCompareFunctionResult;
1948 #else
1949 typedef int CocoaWindowCompareFunctionResult;
1950 #endif
1951
1952 class CocoaWindowCompareContext
1953 {
1954     wxDECLARE_NO_COPY_CLASS(CocoaWindowCompareContext);
1955 public:
1956     CocoaWindowCompareContext(); // Not implemented
1957     CocoaWindowCompareContext(NSView *target, NSArray *subviews)
1958     {
1959         m_target = target;
1960         // Cocoa sorts subviews in-place.. make a copy
1961         m_subviews = [subviews copy];
1962     }
1963
1964     ~CocoaWindowCompareContext()
1965     {   // release the copy
1966         [m_subviews release];
1967     }
1968     NSView* target()
1969     {   return m_target; }
1970
1971     NSArray* subviews()
1972     {   return m_subviews; }
1973
1974     /* Helper function that returns the comparison based off of the original ordering */
1975     CocoaWindowCompareFunctionResult CompareUsingOriginalOrdering(id first, id second)
1976     {
1977         NSUInteger firstI = [m_subviews indexOfObjectIdenticalTo:first];
1978         NSUInteger secondI = [m_subviews indexOfObjectIdenticalTo:second];
1979         // NOTE: If either firstI or secondI is NSNotFound then it will be NSIntegerMax and thus will
1980         // likely compare higher than the other view which is reasonable considering the only way that
1981         // can happen is if the subview was added after our call to subviews but before the call to
1982         // sortSubviewsUsingFunction:context:.  Thus we don't bother checking.  Particularly because
1983         // that case should never occur anyway because that would imply a multi-threaded GUI call
1984         // which is a big no-no with Cocoa.
1985
1986         // Subviews are ordered from back to front meaning one that is already lower will have an lower index.
1987         NSComparisonResult result = (firstI < secondI)
1988                 ?   NSOrderedAscending /* -1 */
1989                 :   (firstI > secondI)
1990                 ?   NSOrderedDescending /* 1 */
1991                 :   NSOrderedSame /* 0 */;
1992
1993         return result;
1994     }
1995 private:
1996     /* The subview we are trying to Raise or Lower */
1997     NSView *m_target;
1998     /* A copy of the original array of subviews */
1999     NSArray *m_subviews;
2000 };
2001
2002 /* Causes Cocoa to raise the target view to the top of the Z-Order by telling the sort function that
2003  * the target view is always higher than every other view.  When comparing two views neither of
2004  * which is the target, it returns the correct response based on the original ordering
2005  */
2006 static CocoaWindowCompareFunctionResult CocoaRaiseWindowCompareFunction(id first, id second, void *ctx)
2007 {
2008     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
2009     // first should be ordered higher
2010     if(first==compareContext->target())
2011         return NSOrderedDescending;
2012     // second should be ordered higher
2013     if(second==compareContext->target())
2014         return NSOrderedAscending;
2015     return compareContext->CompareUsingOriginalOrdering(first,second);
2016 }
2017
2018 void wxWidgetCocoaImpl::Raise()
2019 {
2020         NSView* nsview = m_osxView;
2021
2022     NSView *superview = [nsview superview];
2023     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
2024
2025     [superview sortSubviewsUsingFunction:
2026          CocoaRaiseWindowCompareFunction
2027                                                                  context: &compareContext];
2028
2029 }
2030
2031 /* Causes Cocoa to lower the target view to the bottom of the Z-Order by telling the sort function that
2032  * the target view is always lower than every other view.  When comparing two views neither of
2033  * which is the target, it returns the correct response based on the original ordering
2034  */
2035 static CocoaWindowCompareFunctionResult CocoaLowerWindowCompareFunction(id first, id second, void *ctx)
2036 {
2037     CocoaWindowCompareContext *compareContext = (CocoaWindowCompareContext*)ctx;
2038     // first should be ordered lower
2039     if(first==compareContext->target())
2040         return NSOrderedAscending;
2041     // second should be ordered lower
2042     if(second==compareContext->target())
2043         return NSOrderedDescending;
2044     return compareContext->CompareUsingOriginalOrdering(first,second);
2045 }
2046
2047 void wxWidgetCocoaImpl::Lower()
2048 {
2049         NSView* nsview = m_osxView;
2050
2051     NSView *superview = [nsview superview];
2052     CocoaWindowCompareContext compareContext(nsview, [superview subviews]);
2053
2054     [superview sortSubviewsUsingFunction:
2055          CocoaLowerWindowCompareFunction
2056                                                                  context: &compareContext];
2057 }
2058
2059 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
2060 {
2061 #if 1
2062     SetNeedsDisplay() ;
2063 #else
2064     // We should do something like this, but it wasn't working in 10.4.
2065     if (GetNeedsDisplay() )
2066     {
2067         SetNeedsDisplay() ;
2068     }
2069     NSRect r = wxToNSRect( [m_osxView superview], *rect );
2070     NSSize offset = NSMakeSize((float)dx, (float)dy);
2071     [m_osxView scrollRect:r by:offset];
2072 #endif
2073 }
2074
2075 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
2076 {
2077     wxWindowMac* parent = GetWXPeer()->GetParent();
2078     // under Cocoa we might have a contentView in the wxParent to which we have to
2079     // adjust the coordinates
2080     if (parent && [m_osxView superview] != parent->GetHandle() )
2081     {
2082         int cx = 0,cy = 0,cw = 0,ch = 0;
2083         if ( parent->GetPeer() )
2084         {
2085             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2086             x -= cx;
2087             y -= cy;
2088         }
2089     }
2090     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
2091     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
2092     [m_osxView setFrame:r];
2093     [[m_osxView superview] setNeedsDisplayInRect:r];
2094 }
2095
2096 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
2097 {
2098     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
2099     x = r.GetLeft();
2100     y = r.GetTop();
2101
2102     // under Cocoa we might have a contentView in the wxParent to which we have to
2103     // adjust the coordinates
2104     wxWindowMac* parent = GetWXPeer()->GetParent();
2105     if (parent && [m_osxView superview] != parent->GetHandle() )
2106     {
2107         int cx = 0,cy = 0,cw = 0,ch = 0;
2108         if ( parent->GetPeer() )
2109         {
2110             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
2111             x += cx;
2112             y += cy;
2113         }
2114     }
2115 }
2116
2117 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
2118 {
2119     NSRect rect = [m_osxView frame];
2120     width = (int)rect.size.width;
2121     height = (int)rect.size.height;
2122 }
2123
2124 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
2125 {
2126     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
2127     {
2128         NSView* cv = [m_osxView contentView];
2129
2130         NSRect bounds = [m_osxView bounds];
2131         NSRect rect = [cv frame];
2132
2133         int y = (int)rect.origin.y;
2134         int x = (int)rect.origin.x;
2135         if ( ![ m_osxView isFlipped ] )
2136             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
2137         left = x;
2138         top = y;
2139         width = (int)rect.size.width;
2140         height = (int)rect.size.height;
2141     }
2142     else
2143     {
2144         left = top = 0;
2145         GetSize( width, height );
2146     }
2147 }
2148
2149 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
2150 {
2151     if ( where )
2152         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
2153     else
2154         [m_osxView setNeedsDisplay:YES];
2155 }
2156
2157 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
2158 {
2159     return [m_osxView needsDisplay];
2160 }
2161
2162 bool wxWidgetCocoaImpl::CanFocus() const
2163 {
2164     return [m_osxView canBecomeKeyView] == YES;
2165 }
2166
2167 bool wxWidgetCocoaImpl::HasFocus() const
2168 {
2169     return ( FindFocus() == m_osxView );
2170 }
2171
2172 bool wxWidgetCocoaImpl::SetFocus()
2173 {
2174     if ( !CanFocus() )
2175         return false;
2176
2177     // TODO remove if no issues arise: should not raise the window, only assign focus
2178     //[[m_osxView window] makeKeyAndOrderFront:nil] ;
2179     [[m_osxView window] makeFirstResponder: m_osxView] ;
2180     return true;
2181 }
2182
2183 void wxWidgetCocoaImpl::SetDropTarget(wxDropTarget* target)
2184 {
2185     [m_osxView unregisterDraggedTypes];
2186
2187     if ( target == NULL )
2188         return;
2189
2190     wxDataObject* dobj = target->GetDataObject();
2191
2192     if( dobj )
2193     {
2194         CFMutableArrayRef typesarray = CFArrayCreateMutable(kCFAllocatorDefault,0,&kCFTypeArrayCallBacks);
2195         dobj->AddSupportedTypes(typesarray);
2196         NSView* targetView = m_osxView;
2197         if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2198             targetView = [(NSScrollView*) m_osxView documentView];
2199
2200         [targetView registerForDraggedTypes:(NSArray*)typesarray];
2201         CFRelease(typesarray);
2202     }
2203 }
2204
2205 void wxWidgetCocoaImpl::RemoveFromParent()
2206 {
2207     [m_osxView removeFromSuperview];
2208 }
2209
2210 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
2211 {
2212     NSView* container = parent->GetWXWidget() ;
2213     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
2214     [container addSubview:m_osxView];
2215
2216     if( m_wxPeer->IsFrozen() )
2217         [[m_osxView window] disableFlushWindow];
2218 }
2219
2220 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
2221 {
2222     NSView* targetView = m_osxView;
2223     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2224         targetView = [(NSScrollView*) m_osxView documentView];
2225
2226     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
2227     {
2228         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2229                                                                 green:(CGFloat) (col.Green() / 255.0)
2230                                                                  blue:(CGFloat) (col.Blue() / 255.0)
2231                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
2232     }
2233 }
2234
2235 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
2236 {
2237     BOOL opaque = ( style == wxBG_STYLE_PAINT );
2238
2239     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
2240     {
2241         [m_osxView setOpaque: opaque];
2242     }
2243
2244     return true ;
2245 }
2246
2247 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
2248 {
2249     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
2250     {
2251         wxCFStringRef cf( title , encoding );
2252         [m_osxView setTitle:cf.AsNSString()];
2253     }
2254     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
2255     {
2256         wxCFStringRef cf( title , encoding );
2257         [m_osxView setStringValue:cf.AsNSString()];
2258     }
2259 }
2260
2261
2262 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
2263 {
2264     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
2265     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
2266     *pt = wxFromNSPoint( to->GetWXWidget(), p );
2267 }
2268
2269 wxInt32 wxWidgetCocoaImpl::GetValue() const
2270 {
2271     return [(NSControl*)m_osxView intValue];
2272 }
2273
2274 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
2275 {
2276     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
2277     {
2278         [m_osxView setIntValue:v];
2279     }
2280     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
2281     {
2282         [m_osxView setFloatValue:(double)v];
2283     }
2284     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
2285     {
2286         [m_osxView setDoubleValue:(double)v];
2287     }
2288 }
2289
2290 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
2291 {
2292     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
2293     {
2294         [m_osxView setMinValue:(double)v];
2295     }
2296 }
2297
2298 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
2299 {
2300     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
2301     {
2302         [m_osxView setMaxValue:(double)v];
2303     }
2304 }
2305
2306 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
2307 {
2308     if (  [m_osxView respondsToSelector:@selector(minValue)] )
2309     {
2310         return (int)[m_osxView minValue];
2311     }
2312     return 0;
2313 }
2314
2315 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
2316 {
2317     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
2318     {
2319         return (int)[m_osxView maxValue];
2320     }
2321     return 0;
2322 }
2323
2324 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
2325 {
2326     wxBitmap bmp;
2327
2328     // TODO: how to create a wxBitmap from NSImage?
2329 #if 0
2330     if ( [m_osxView respondsToSelector:@selector(image:)] )
2331         bmp = [m_osxView image];
2332 #endif
2333
2334     return bmp;
2335 }
2336
2337 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
2338 {
2339     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
2340     {
2341         if (bitmap.IsOk())
2342             [m_osxView setImage:bitmap.GetNSImage()];
2343         else
2344             [m_osxView setImage:nil];
2345
2346         [m_osxView setNeedsDisplay:YES];
2347     }
2348 }
2349
2350 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
2351 {
2352     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
2353     {
2354         NSCellImagePosition pos;
2355         switch ( dir )
2356         {
2357             case wxLEFT:
2358                 pos = NSImageLeft;
2359                 break;
2360
2361             case wxRIGHT:
2362                 pos = NSImageRight;
2363                 break;
2364
2365             case wxTOP:
2366                 pos = NSImageAbove;
2367                 break;
2368
2369             case wxBOTTOM:
2370                 pos = NSImageBelow;
2371                 break;
2372
2373             default:
2374                 wxFAIL_MSG( "invalid image position" );
2375                 pos = NSNoImage;
2376         }
2377
2378         [m_osxView setImagePosition:pos];
2379     }
2380 }
2381
2382 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
2383 {
2384     // implementation in subclass
2385 }
2386
2387 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
2388 {
2389     r->x = r->y = r->width = r->height = 0;
2390
2391     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
2392     {
2393         NSRect former = [m_osxView frame];
2394         [m_osxView sizeToFit];
2395         NSRect best = [m_osxView frame];
2396         [m_osxView setFrame:former];
2397         r->width = (int)best.size.width;
2398         r->height = (int)best.size.height;
2399     }
2400 }
2401
2402 bool wxWidgetCocoaImpl::IsEnabled() const
2403 {
2404     NSView* targetView = m_osxView;
2405     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2406         targetView = [(NSScrollView*) m_osxView documentView];
2407
2408     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
2409         return [targetView isEnabled];
2410     return true;
2411 }
2412
2413 void wxWidgetCocoaImpl::Enable( bool enable )
2414 {
2415     NSView* targetView = m_osxView;
2416     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2417         targetView = [(NSScrollView*) m_osxView documentView];
2418
2419     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
2420         [targetView setEnabled:enable];
2421 }
2422
2423 void wxWidgetCocoaImpl::PulseGauge()
2424 {
2425 }
2426
2427 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
2428 {
2429 }
2430
2431 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
2432 {
2433     NSControlSize size = NSRegularControlSize;
2434
2435     switch ( variant )
2436     {
2437         case wxWINDOW_VARIANT_NORMAL :
2438             size = NSRegularControlSize;
2439             break ;
2440
2441         case wxWINDOW_VARIANT_SMALL :
2442             size = NSSmallControlSize;
2443             break ;
2444
2445         case wxWINDOW_VARIANT_MINI :
2446             size = NSMiniControlSize;
2447             break ;
2448
2449         case wxWINDOW_VARIANT_LARGE :
2450             size = NSRegularControlSize;
2451             break ;
2452
2453         default:
2454             wxFAIL_MSG(wxT("unexpected window variant"));
2455             break ;
2456     }
2457     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2458         [m_osxView setControlSize:size];
2459     else if ([m_osxView respondsToSelector:@selector(cell)])
2460     {
2461         id cell = [(id)m_osxView cell];
2462         if ([cell respondsToSelector:@selector(setControlSize:)])
2463             [cell setControlSize:size];
2464     }
2465
2466     // we need to propagate this to inner views as well
2467     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2468     {
2469         NSView* targetView = [(NSScrollView*) m_osxView documentView];
2470
2471         if ( [targetView respondsToSelector:@selector(setControlSize:)] )
2472             [targetView setControlSize:size];
2473         else if ([targetView respondsToSelector:@selector(cell)])
2474         {
2475             id cell = [(id)targetView cell];
2476             if ([cell respondsToSelector:@selector(setControlSize:)])
2477                 [cell setControlSize:size];
2478         }
2479     }
2480 }
2481
2482 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2483 {
2484     NSView* targetView = m_osxView;
2485     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2486         targetView = [(NSScrollView*) m_osxView documentView];
2487
2488     if ([targetView respondsToSelector:@selector(setFont:)])
2489         [targetView setFont: font.OSXGetNSFont()];
2490     if ([targetView respondsToSelector:@selector(setTextColor:)])
2491         [targetView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2492                                                                  green:(CGFloat) (col.Green() / 255.0)
2493                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2494                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2495 }
2496
2497 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2498 {
2499     if ( tooltip )
2500     {
2501         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2502         [m_osxView setToolTip: cf.AsNSString()];
2503     }
2504     else
2505     {
2506         [m_osxView setToolTip:nil];
2507     }
2508 }
2509
2510 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2511 {
2512     WXWidget c =  control ? control : (WXWidget) m_osxView;
2513     wxWidgetImpl::Associate( c, this ) ;
2514     if ([c respondsToSelector:@selector(setAction:)])
2515     {
2516         [c setTarget: c];
2517         [c setAction: @selector(controlAction:)];
2518         if ([c respondsToSelector:@selector(setDoubleAction:)])
2519         {
2520             [c setDoubleAction: @selector(controlDoubleAction:)];
2521         }
2522
2523     }
2524     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingCursorUpdate|NSTrackingMouseMoved|NSTrackingActiveAlways|NSTrackingInVisibleRect;
2525         NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: NSZeroRect options: options owner: m_osxView userInfo: nil];
2526     [m_osxView addTrackingArea: area];
2527     [area release];
2528  }
2529
2530 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2531 {
2532     wxKeyEvent wxevent(wxEVT_CHAR);
2533     SetupKeyEvent( wxevent, event, text );
2534
2535     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2536 }
2537
2538 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2539 {
2540     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2541     SetupKeyEvent( wxevent, event );
2542
2543     // Generate wxEVT_CHAR_HOOK before sending any other events but only when
2544     // the key is pressed, not when it's released (the type of wxevent is
2545     // changed by SetupKeyEvent() so it can be wxEVT_KEY_UP too by now).
2546     if ( wxevent.GetEventType() == wxEVT_KEY_DOWN )
2547     {
2548         wxKeyEvent eventHook(wxEVT_CHAR_HOOK, wxevent);
2549         if ( GetWXPeer()->OSXHandleKeyEvent(eventHook)
2550                 && !eventHook.IsNextEventAllowed() )
2551             return true;
2552     }
2553
2554     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2555
2556     // this will fire higher level events, like insertText, to help
2557     // us handle EVT_CHAR, etc.
2558
2559     if ( !result )
2560     {
2561         if ( [event type] == NSKeyDown)
2562         {
2563             long keycode = wxOSXTranslateCocoaKey( event, wxEVT_CHAR );
2564
2565             if ( (keycode > 0 && keycode < WXK_SPACE) || keycode == WXK_DELETE || keycode >= WXK_START )
2566             {
2567                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2568                 wxKeyEvent wxevent2(wxevent) ;
2569                 wxevent2.SetEventType(wxEVT_CHAR);
2570                 SetupKeyEvent( wxevent2, event );
2571                 wxevent2.m_keyCode = keycode;
2572                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2573             }
2574             else if (wxevent.CmdDown())
2575             {
2576                 wxKeyEvent wxevent2(wxevent) ;
2577                 wxevent2.SetEventType(wxEVT_CHAR);
2578                 SetupKeyEvent( wxevent2, event );
2579                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2580             }
2581             else
2582             {
2583                 if ( IsUserPane() && !wxevent.CmdDown() )
2584                 {
2585                     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2586                         [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2587                     else
2588                         [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2589                     result = true;
2590                 }
2591             }
2592         }
2593     }
2594
2595     return result;
2596 }
2597
2598 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2599 {
2600     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2601     SetupMouseEvent(wxevent , event) ;
2602     bool result = GetWXPeer()->HandleWindowEvent(wxevent);
2603
2604     (void)SetupCursor(event);
2605
2606     return result;
2607 }
2608
2609 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2610 {
2611     wxWindow* thisWindow = GetWXPeer();
2612     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2613     {
2614         thisWindow->MacInvalidateBorders();
2615     }
2616
2617     if ( receivedFocus )
2618     {
2619         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2620         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2621         thisWindow->HandleWindowEvent(eventFocus);
2622
2623 #if wxUSE_CARET
2624         if ( thisWindow->GetCaret() )
2625             thisWindow->GetCaret()->OnSetFocus();
2626 #endif
2627
2628         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2629         event.SetEventObject(thisWindow);
2630         if (otherWindow)
2631             event.SetWindow(otherWindow->GetWXPeer());
2632         thisWindow->HandleWindowEvent(event) ;
2633     }
2634     else // !receivedFocus
2635     {
2636 #if wxUSE_CARET
2637         if ( thisWindow->GetCaret() )
2638             thisWindow->GetCaret()->OnKillFocus();
2639 #endif
2640
2641         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2642
2643         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2644         event.SetEventObject(thisWindow);
2645         if (otherWindow)
2646             event.SetWindow(otherWindow->GetWXPeer());
2647         thisWindow->HandleWindowEvent(event) ;
2648     }
2649 }
2650
2651 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2652 {
2653     if ( !wxIsBusy() )
2654     {
2655         NSPoint location = [NSEvent mouseLocation];
2656         location = [[m_osxView window] convertScreenToBase:location];
2657         NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2658
2659         if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2660         {
2661             [(NSCursor*)cursor.GetHCURSOR() set];
2662         }
2663     }
2664 }
2665
2666 void wxWidgetCocoaImpl::CaptureMouse()
2667 {
2668     // TODO remove if we don't get into problems with cursor settings
2669     //    [[m_osxView window] disableCursorRects];
2670 }
2671
2672 void wxWidgetCocoaImpl::ReleaseMouse()
2673 {
2674     // TODO remove if we don't get into problems with cursor settings
2675     //    [[m_osxView window] enableCursorRects];
2676 }
2677
2678 #if !wxOSX_USE_NATIVE_FLIPPED
2679
2680 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2681 {
2682     m_isFlipped = flipped;
2683 }
2684
2685 #endif
2686
2687 void wxWidgetCocoaImpl::SetDrawingEnabled(bool enabled)
2688 {
2689     if ( enabled )
2690     {
2691         [[m_osxView window] enableFlushWindow];
2692         [m_osxView setNeedsDisplay:YES];
2693     }
2694     else
2695     {
2696         [[m_osxView window] disableFlushWindow];
2697     }
2698 }
2699 //
2700 // Factory methods
2701 //
2702
2703 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2704     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2705     long WXUNUSED(style), long WXUNUSED(extraStyle))
2706 {
2707     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2708     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2709
2710     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v, false, true );
2711     return c;
2712 }
2713
2714 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2715 {
2716     NSWindow* tlw = now->GetWXWindow();
2717
2718     wxWidgetCocoaImpl* c = NULL;
2719     if ( now->IsNativeWindowWrapper() )
2720     {
2721         NSView* cv = [tlw contentView];
2722         c = new wxWidgetCocoaImpl( now, cv, true );
2723         if ( cv != nil )
2724         {
2725             // increase ref count, because the impl destructor will decrement it again
2726             CFRetain(cv);
2727             if ( !now->IsShown() )
2728                 [cv setHidden:NO];
2729         }
2730     }
2731     else
2732     {
2733         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2734         c = new wxWidgetCocoaImpl( now, v, true );
2735         c->InstallEventHandler();
2736         [tlw setContentView:v];
2737     }
2738     return c;
2739 }