src/osx/cocoa/filedlg.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/filedlg.mm
   3 // Purpose:     wxFileDialog for wxCocoa
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2004-10-02
   7 // RCS-ID:      $Id: filedlg.mm 40007 2006-07-05 13:10:46Z SC $
   8 // Copyright:   (c) Ryan Norton
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ============================================================================
  13 // declarations
  14 // ============================================================================
  15
  16 // ----------------------------------------------------------------------------
  17 // headers
  18 // ----------------------------------------------------------------------------
  19
  20 // For compilers that support precompilation, includes "wx.h".
  21 #include "wx/wxprec.h"
  22
  23 #if wxUSE_FILEDLG
  24
  25 #include "wx/filedlg.h"
  26
  27 #ifndef WX_PRECOMP
  28     #include "wx/msgdlg.h"
  29     #include "wx/app.h"
  30 #endif
  31
  32 #include "wx/filename.h"
  33 #include "wx/tokenzr.h"
  34
  35 #include "wx/osx/private.h"
  36
  37 // ============================================================================
  38 // implementation
  39 // ============================================================================
  40
  41 // Open Items:
  42 // - support for old style MacOS creator / type combos
  43 // - parameter support for descending into packages as directories (setTreatsFilePackagesAsDirectories)
  44
  45 IMPLEMENT_CLASS(wxFileDialog, wxFileDialogBase)
  46
  47 wxFileDialog::wxFileDialog(
  48     wxWindow *parent, const wxString& message,
  49     const wxString& defaultDir, const wxString& defaultFileName, const wxString& wildCard,
  50     long style, const wxPoint& pos, const wxSize& sz, const wxString& name)
  51     : wxFileDialogBase(parent, message, defaultDir, defaultFileName, wildCard, style, pos, sz, name)
  52 {
  53 }
  54
  55 bool wxFileDialog::SupportsExtraControl() const
  56 {
  57     return true;
  58 }
  59
  60 NSArray* CopyTypesFromFilter( const wxString filter )
  61 {
  62     NSMutableArray* types = nil;
  63     if ( !filter.empty() )
  64     {
  65         wxArrayString names ;
  66         wxArrayString extensions;
  67
  68         wxString filter2(filter) ;
  69         int filterIndex = 0;
  70         bool isName = true ;
  71         wxString current ;
  72
  73         for ( unsigned int i = 0; i < filter2.length() ; i++ )
  74         {
  75             if ( filter2.GetChar(i) == wxT('|') )
  76             {
  77                 if ( isName )
  78                 {
  79                     names.Add( current ) ;
  80                 }
  81                 else
  82                 {
  83                     extensions.Add( current ) ;
  84                     ++filterIndex ;
  85                 }
  86
  87                 isName = !isName ;
  88                 current = wxEmptyString ;
  89             }
  90             else
  91             {
  92                 current += filter2.GetChar(i) ;
  93             }
  94         }
  95         // we allow for compatibility reason to have a single filter expression (like *.*) without
  96         // an explanatory text, in that case the first part is name and extension at the same time
  97
  98         wxASSERT_MSG( filterIndex == 0 || !isName , wxT("incorrect format of format string") ) ;
  99         if ( current.empty() )
 100             extensions.Add( names[filterIndex] ) ;
 101         else
 102             extensions.Add( current ) ;
 103         if ( filterIndex == 0 || isName )
 104             names.Add( current ) ;
 105
 106         ++filterIndex ;
 107
 108         const size_t extCount = extensions.GetCount();
 109         for ( size_t i = 0 ; i < extCount; i++ )
 110         {
 111             wxString extensiongroup = extensions[i];
 112             wxStringTokenizer tokenizer( extensiongroup , wxT(";") ) ;
 113             while ( tokenizer.HasMoreTokens() )
 114             {
 115                 wxString extension = tokenizer.GetNextToken() ;
 116                 // Remove leading '*'
 117                 if (extension.length() && (extension.GetChar(0) == '*'))
 118                     extension = extension.Mid( 1 );
 119
 120                 // Remove leading '.'
 121                 if (extension.length() && (extension.GetChar(0) == '.'))
 122                     extension = extension.Mid( 1 );
 123
 124                 // Remove leading '*', this is for handling *.*
 125                 if (extension.length() && (extension.GetChar(0) == '*'))
 126                     extension = extension.Mid( 1 );
 127
 128                 if ( extension.IsEmpty() )
 129                 {
 130                     [types release];
 131                     types = nil;
 132                     return nil;
 133                 }
 134
 135                 if ( types == nil )
 136                     types = [[NSMutableArray alloc] init];
 137
 138                 wxCFStringRef cfext(extension);
 139                 [types addObject: (NSString*)cfext.AsNSString()  ];
 140 #if 0
 141                 // add support for classic fileType / creator here
 142                 wxUint32 fileType, creator;
 143                 // extension -> mactypes
 144 #endif
 145             }
 146
 147         }
 148     }
 149     return types;
 150 }
 151
 152 void wxFileDialog::ShowWindowModal()
 153 {
 154     wxCFStringRef cf( m_message );
 155     wxCFStringRef dir( m_dir );
 156     wxCFStringRef file( m_fileName );
 157
 158     wxNonOwnedWindow* parentWindow = NULL;
 159
 160     m_modality = wxDIALOG_MODALITY_WINDOW_MODAL;
 161
 162     if (GetParent())
 163         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 164
 165     wxASSERT_MSG(parentWindow, "Window modal display requires parent.");
 166
 167     if (HasFlag(wxFD_SAVE))
 168     {
 169         NSSavePanel* sPanel = [NSSavePanel savePanel];
 170
 171         SetupExtraControls(sPanel);
 172
 173         // makes things more convenient:
 174         [sPanel setCanCreateDirectories:YES];
 175         [sPanel setMessage:cf.AsNSString()];
 176         // if we should be able to descend into pacakges we must somehow
 177         // be able to pass this in
 178         [sPanel setTreatsFilePackagesAsDirectories:NO];
 179         [sPanel setCanSelectHiddenExtension:YES];
 180
 181         NSWindow* nativeParent = parentWindow->GetWXWindow();
 182         ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 183         [sheetDelegate setImplementation: this];
 184         [sPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 185             modalForWindow: nativeParent modalDelegate: sheetDelegate
 186             didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 187             contextInfo: nil];
 188     }
 189     else
 190     {
 191         NSArray* types = CopyTypesFromFilter( m_wildCard ) ;
 192         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 193
 194         SetupExtraControls(oPanel);
 195
 196         [oPanel setTreatsFilePackagesAsDirectories:NO];
 197         [oPanel setCanChooseDirectories:NO];
 198         [oPanel setResolvesAliases:YES];
 199         [oPanel setCanChooseFiles:YES];
 200         [oPanel setMessage:cf.AsNSString()];
 201
 202         NSWindow* nativeParent = parentWindow->GetWXWindow();
 203         ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 204         [sheetDelegate setImplementation: this];
 205         [oPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 206             types: types modalForWindow: nativeParent
 207             modalDelegate: sheetDelegate
 208             didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 209             contextInfo: nil];
 210         [types release];
 211         types = nil;
 212     }
 213 }
 214
 215 void wxFileDialog::SetupExtraControls(WXWindow nativeWindow)
 216 {
 217     NSSavePanel* panel = (NSSavePanel*) nativeWindow;
 218
 219     wxNonOwnedWindow::Create( GetParent(), nativeWindow );
 220
 221     if (HasExtraControlCreator())
 222     {
 223         CreateExtraControl();
 224         wxWindow* control = GetExtraControl();
 225         if ( control )
 226         {
 227             NSView* accView = control->GetHandle();
 228             [accView removeFromSuperview];
 229             [panel setAccessoryView:accView];
 230         }
 231         else
 232         {
 233             [panel setAccessoryView:nil];
 234         }
 235     }
 236 }
 237
 238 int wxFileDialog::ShowModal()
 239 {
 240     wxCFStringRef cf( m_message );
 241
 242     wxCFStringRef dir( m_dir );
 243     wxCFStringRef file( m_fileName );
 244
 245     m_path = wxEmptyString;
 246     m_fileNames.Clear();
 247     m_paths.Clear();
 248     // since we don't support retrieving the matching filter
 249     m_filterIndex = -1;
 250
 251     wxNonOwnedWindow* parentWindow = NULL;
 252     int returnCode = -1;
 253
 254     if (GetParent())
 255     {
 256         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 257     }
 258
 259     if (HasFlag(wxFD_SAVE))
 260     {
 261         NSSavePanel* sPanel = [NSSavePanel savePanel];
 262
 263         SetupExtraControls(sPanel);
 264
 265         // makes things more convenient:
 266         [sPanel setCanCreateDirectories:YES];
 267         [sPanel setMessage:cf.AsNSString()];
 268         // if we should be able to descend into pacakges we must somehow
 269         // be able to pass this in
 270         [sPanel setTreatsFilePackagesAsDirectories:NO];
 271         [sPanel setCanSelectHiddenExtension:YES];
 272
 273         if ( HasFlag(wxFD_OVERWRITE_PROMPT) )
 274         {
 275         }
 276
 277         returnCode = [sPanel runModalForDirectory:dir.AsNSString() file:file.AsNSString() ];
 278         ModalFinishedCallback(sPanel, returnCode);
 279
 280         UnsubclassWin();
 281         [sPanel setAccessoryView:nil];
 282     }
 283     else
 284     {
 285         NSArray* types = CopyTypesFromFilter( m_wildCard ) ;
 286         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 287
 288         SetupExtraControls(oPanel);
 289
 290         [oPanel setTreatsFilePackagesAsDirectories:NO];
 291         [oPanel setCanChooseDirectories:NO];
 292         [oPanel setResolvesAliases:YES];
 293         [oPanel setCanChooseFiles:YES];
 294         [oPanel setMessage:cf.AsNSString()];
 295
 296         returnCode = [oPanel runModalForDirectory:dir.AsNSString()
 297                         file:file.AsNSString() types:types];
 298
 299         ModalFinishedCallback(oPanel, returnCode);
 300
 301         UnsubclassWin();
 302         [oPanel setAccessoryView:nil];
 303
 304         [types release];
 305         types = nil;
 306     }
 307
 308     return GetReturnCode();
 309 }
 310
 311 void wxFileDialog::ModalFinishedCallback(void* panel, int returnCode)
 312 {
 313     int result = wxID_CANCEL;
 314     if (HasFlag(wxFD_SAVE))
 315     {
 316         if (returnCode == NSOKButton )
 317         {
 318             NSSavePanel* sPanel = (NSSavePanel*)panel;
 319             result = wxID_OK;
 320
 321             m_path = wxCFStringRef::AsString([sPanel filename]);
 322             m_fileName = wxFileNameFromPath(m_path);
 323             m_dir = wxPathOnly( m_path );
 324         }
 325     }
 326     else
 327     {
 328         NSOpenPanel* oPanel = (NSOpenPanel*)panel;
 329         if (returnCode == NSOKButton )
 330         {
 331             panel = oPanel;
 332             result = wxID_OK;
 333             NSArray* filenames = [oPanel filenames];
 334             for ( size_t i = 0 ; i < [filenames count] ; ++ i )
 335             {
 336                 wxString fnstr = wxCFStringRef::AsString([filenames objectAtIndex:i]);
 337                 m_paths.Add( fnstr );
 338                 m_fileNames.Add( wxFileNameFromPath(fnstr) );
 339                 if ( i == 0 )
 340                 {
 341                     m_path = fnstr;
 342                     m_fileName = wxFileNameFromPath(fnstr);
 343                     m_dir = wxPathOnly( fnstr );
 344                 }
 345             }
 346         }
 347     }
 348     SetReturnCode(result);
 349
 350     if (GetModality() == wxDIALOG_MODALITY_WINDOW_MODAL)
 351         SendWindowModalDialogEvent ( wxEVT_WINDOW_MODAL_DIALOG_CLOSED  );
 352
 353     [(NSSavePanel*) panel setAccessoryView:nil];
 354 }
 355
 356 #endif // wxUSE_FILEDLG