install/gtk/configure.in

   1 dnl ////////////////////////////////////////////////////////////////////////
   2 dnl
   3 dnl Top-level configure.in for wxGTK by Robert Roebling, Wolfram Gloger
   4 dnl and Martin Sperl.
   5 dnl
   6 dnl This script is under the wxWindows licence.
   7 dnl
   8 dnl ////////////////////////////////////////////////////////////////////////
   9
  10 dnl AM_PATH_GTK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
  11 dnl Test for GTK, and define GTK_CFLAGS and GTK_LIBS
  12 dnl
  13 AC_DEFUN(AM_PATH_GTK,
  14 [dnl
  15 dnl Get the cflags and libraries from the gtk-config script
  16 dnl
  17 AC_ARG_WITH(gtk-prefix,[  --with-gtk-prefix=PFX   Prefix where GTK is installed (optional)],
  18             gtk_config_prefix="$withval", gtk_config_prefix="")
  19 AC_ARG_WITH(gtk-exec-prefix,[  --with-gtk-exec-prefix=PFX Exec prefix where GTK is installed (optional)],
  20             gtk_config_exec_prefix="$withval", gtk_config_exec_prefix="")
  21
  22   if test x$gtk_config_exec_prefix != x ; then
  23      gtk_config_args="$gtk_config_args --exec-prefix=$gtk_config_exec_prefix"
  24      if test x${GTK_CONFIG+set} != xset ; then
  25         GTK_CONFIG=$gtk_config_exec_prefix/bin/gtk-config
  26      fi
  27   fi
  28   if test x$gtk_config_prefix != x ; then
  29      gtk_config_args="$gtk_config_args --prefix=$gtk_config_prefix"
  30      if test x${GTK_CONFIG+set} != xset ; then
  31         GTK_CONFIG=$gtk_config_prefix/bin/gtk-config
  32      fi
  33   fi
  34
  35   AC_PATH_PROG(GTK_CONFIG, gtk-config, no)
  36   min_gtk_version=ifelse([$1], ,0.99.7,$1)
  37   AC_MSG_CHECKING(for GTK - version >= $min_gtk_version)
  38   no_gtk=""
  39   if test "$GTK_CONFIG" != "no" ; then
  40     GTK_CFLAGS=`$GTK_CONFIG --cflags`
  41     GTK_LIBS=`$GTK_CONFIG --libs`
  42     ac_save_CFLAGS="$CFLAGS"
  43     ac_save_LIBS="$LIBS"
  44     CFLAGS="$CFLAGS $GTK_CFLAGS"
  45     LIBS="$LIBS $GTK_LIBS"
  46 dnl
  47 dnl Now check if the installed GTK is sufficiently new. (Also sanity
  48 dnl checks the results of gtk-config to some extent
  49 dnl
  50     AC_TRY_RUN([
  51 #include <gtk/gtk.h>
  52 #include <stdio.h>
  53
  54 int
  55 main ()
  56 {
  57   int major, minor, micro;
  58
  59   if (sscanf("$min_gtk_version", "%d.%d.%d", &major, &minor, &micro) != 3) {
  60      printf("%s, bad version string\n", "$min_gtk_version");
  61      exit(1);
  62    }
  63
  64    return !((gtk_major_version > major) ||
  65             ((gtk_major_version == major) && (gtk_minor_version > minor)) ||
  66             ((gtk_major_version == major) && (gtk_minor_version == minor) && (gtk_micro_version >= micro)));
  67 }
  68 ],, no_gtk=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
  69      CFLAGS="$ac_save_CFLAGS"
  70      LIBS="$ac_save_LIBS"
  71   else
  72      no_gtk=yes
  73   fi
  74   if test "x$no_gtk" = x ; then
  75      AC_MSG_RESULT(yes)
  76      ifelse([$2], , :, [$2])
  77   else
  78      AC_MSG_RESULT(no)
  79      GTK_CFLAGS=""
  80      GTK_LIBS=""
  81      ifelse([$3], , :, [$3])
  82   fi
  83   AC_SUBST(GTK_CFLAGS)
  84   AC_SUBST(GTK_LIBS)
  85 ])
  86
  87 dnl ------------------------------------------------------------------------
  88 dnl custom macros
  89 dnl ------------------------------------------------------------------------
  90
  91 AC_DEFUN(AC_OVERRIDES_PREPARE,
  92 [
  93 rm -f ${OSTYPE}.system.cache.tmp
  94 touch ${OSTYPE}.system.cache.tmp
  95 touch ${OSTYPE}.system.cache
  96 ])
  97
  98 AC_DEFUN(AC_OVERRIDES_DONE,
  99 [
 100 mv ${OSTYPE}.system.cache.tmp ${OSTYPE}.system.cache
 101 ])
 102
 103 dnl package,message,helpmessage,variable
 104 AC_DEFUN(AC_OVERRIDES,
 105 [
 106 AC_MSG_CHECKING("for $2")
 107 AC_ARG_WITH($1,$3,
 108 [if test "x$with_$1" = xyes; then
 109   ac_cv_use_$1='$4="1"'
 110 else
 111   ac_cv_use_$1='$4="0"'
 112 fi],
 113 [
 114   LINE=`grep "$4" ${OSTYPE}.system.cache`
 115   if test "x$LINE" != x ; then
 116     eval "DEFAULT_$LINE"
 117   fi
 118   ac_cv_use_$1='$4='$DEFAULT_$4
 119 ])
 120 eval "$ac_cv_use_$1"
 121 echo $ac_cv_use_$1 >> ${OSTYPE}.system.cache.tmp
 122 if test "$$4" = 1; then
 123   AC_MSG_RESULT(yes)
 124 else
 125   AC_MSG_RESULT(no)
 126 fi
 127 ])
 128
 129 dnl package,message,helpmessage,variable
 130 AC_DEFUN(AC_OVERRIDES_OLD,
 131 [
 132 AC_MSG_CHECKING("for $2")
 133 AC_CACHE_VAL(ac_cv_use_$1,
 134 [
 135 AC_ARG_WITH($1,$3,
 136 [if test "x$with_$1" = xyes; then
 137   ac_cv_use_$1='$4="1"'
 138 else
 139   ac_cv_use_$1='$4="0"'
 140 fi],[ac_cv_use_$1='$4=$DEFAULT_$4'])
 141 ])
 142 eval "$ac_cv_use_$1"
 143
 144 if test "$$4" = 1; then
 145   AC_MSG_RESULT(yes)
 146 else
 147   AC_MSG_RESULT(no)
 148 fi
 149 ])
 150
 151 AC_DEFUN(AC_PATH_FIND_INCLUDES,
 152 [
 153 ac_find_includes=
 154 for ac_dir in $1;
 155   do
 156     if test -f "$ac_dir/$2"; then
 157       ac_find_includes=$ac_dir
 158       break
 159     fi
 160   done
 161 ])
 162
 163 AC_DEFUN(AC_PATH_FIND_LIBRARIES,
 164 [
 165 ac_find_libraries=
 166 for ac_dir in $1;
 167   do
 168     for ac_extension in a so sl; do
 169       if test -f "$ac_dir/lib$2.$ac_extension"; then
 170         ac_find_libraries=$ac_dir
 171         break 2
 172       fi
 173     done
 174   done
 175 ])
 176
 177 dnl Path to include, allready defined
 178 AC_DEFUN(AC_INCLUDE_PATH_EXIST,
 179 [
 180   ac_path_to_include=$1
 181   echo "$2" | grep "\-I$1" > /dev/null
 182   result=$?
 183   if test $result = 0; then
 184     ac_path_to_include=""
 185   else
 186     ac_path_to_include="-I$1"
 187   fi
 188 ])
 189
 190 dnl Path to link, allready defined
 191 AC_DEFUN(AC_LINK_PATH_EXIST,
 192 [
 193   echo "$2" | grep "\-L$1" > /dev/null
 194   result=$?
 195   if test $result = 0; then
 196     ac_path_to_link=""
 197   else
 198     ac_path_to_link="-L$1"
 199   fi
 200 ])
 201
 202 dnl ------------------------------------------------------------------------
 203 dnl Process this file with autoconf to produce a configure script.
 204 dnl ------------------------------------------------------------------------
 205
 206 AC_INIT(configure.in)
 207
 208 dnl ------------------------------------------------------------------------
 209 dnl Check platform
 210 dnl ------------------------------------------------------------------------
 211
 212 OS="${OSTYPE}"
 213
 214 if test "x$OS" = "x"; then
 215   UNAME=`uname`
 216   AC_MSG_ERROR("The system variable OS has not been set"
 217                "please set is everytime befor compiling on this system"
 218                "A good example for this system would be:"
 219                "setenv OSTYPE $UNAME        for csh as a SHELL"
 220                "EXPORT OSTYPE=$UNAME        for sh as SHELL"
 221                "please set this and restart again."
 222               )
 223 fi
 224
 225 dnl ------------------------------------------------------------------------
 226 dnl Set base directory
 227 dnl ------------------------------------------------------------------------
 228
 229 cd ../..
 230 WXBASEDIR=`pwd`
 231 cd install/gtk
 232 AC_SUBST(WXBASEDIR)
 233
 234 dnl ------------------------------------------------------------------------
 235 dnl search path for includes and libraries
 236 dnl ------------------------------------------------------------------------
 237
 238 SEARCH_INCLUDE="\
 239     /usr/Motif1.2/include     \
 240                               \
 241     /usr/X11R6/include        \
 242     /usr/X11R5/include        \
 243     /usr/X11R4/include        \
 244                               \
 245     /usr/include/X11R6        \
 246     /usr/include/X11R5        \
 247     /usr/include/X11R4        \
 248                               \
 249     /usr/local/X11R6/include  \
 250     /usr/local/X11R5/include  \
 251     /usr/local/X11R4/include  \
 252                               \
 253     /usr/local/include/X11R6  \
 254     /usr/local/include/X11R5  \
 255     /usr/local/include/X11R4  \
 256                               \
 257     /usr/X11/include          \
 258     /usr/include/X11          \
 259     /usr/local/X11/include    \
 260     /usr/local/include/X11    \
 261                               \
 262     /usr/X386/include         \
 263     /usr/x386/include         \
 264     /usr/XFree86/include/X11  \
 265                               \
 266     /usr/include              \
 267     /usr/local/include        \
 268     /usr/local/include/gtk    \
 269     /usr/unsupported/include  \
 270     /usr/athena/include       \
 271     /usr/local/x11r5/include  \
 272     /usr/lpp/Xamples/include  \
 273                               \
 274     /usr/openwin/include      \
 275     /usr/openwin/share/include \
 276     "
 277
 278 SEARCH_LIB="`echo "$SEARCH_INCLUDE" | sed s/include/lib/g` \
 279     "
 280
 281 dnl ------------------------------------------------------------------------
 282 dnl standard checks
 283 dnl ------------------------------------------------------------------------
 284
 285 dnl ###################
 286 dnl # checks programs #
 287 dnl ###################
 288
 289 dnl C-compiler checks
 290 dnl =================
 291 dnl use what compiler
 292 AC_PROG_CC
 293 dnl   defines CC with the compiler to use
 294 dnl   defines GCC with yes if using gcc
 295 dnl   defines GCC empty if not using gcc
 296 dnl   defines CFLAGS
 297
 298 CFLAGS=`echo "$CFLAGS" | sed 's/-g//g'`
 299
 300 dnl does compiler support -c and -o simultaniously
 301 AC_PROG_CC_C_O
 302 dnl   defines NO_MINUS_C_MINUS_O if compiler does not accept
 303 dnl                              both switches simultaniously
 304 dnl what is the c-preprocessor
 305 AC_PROG_CPP
 306 dnl   defines CPP with the c-preprocessor
 307 dnl is -traditional needed for correct compilations
 308 AC_PROG_GCC_TRADITIONAL
 309 dnl   adds -traditional for gcc if needed
 310
 311 AC_LANG_SAVE
 312
 313 dnl C++-compiler checks
 314 dnl ===================
 315 dnl use what compiler
 316 AC_PROG_CXX
 317 dnl   defines CXX with the compiler to use
 318 dnl   defines GXX with yes if using gxx
 319 dnl   defines GXX empty if not using gxx
 320 dnl   defines CXXFLAGS
 321 dnl what is the C++-preprocessor
 322 AC_PROG_CXXCPP
 323 dnl   defines CXXCPP with the C++-preprocessor
 324
 325 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g//g'`
 326
 327 AC_LANG_RESTORE
 328
 329 dnl ranlib command
 330 dnl ==============
 331 AC_PROG_RANLIB
 332 dnl   defines RANLIB with the appropriate command
 333
 334 dnl ar command
 335 dnl ==========
 336 AC_CHECK_PROG(AR, ar, ar, ar)
 337 dnl   defines AR with the appropriate command
 338
 339 dnl install checks
 340 dnl ==============
 341 AC_PROG_INSTALL
 342 dnl   defines INSTALL with the appropriate command
 343
 344 dnl does ln -s works
 345 dnl ================
 346 AC_PROG_LN_S
 347 dnl   defines LN_S with the appropriate command
 348
 349 dnl awk command
 350 dnl ===========
 351 AC_PROG_AWK
 352 dnl   defines AWK with the appropriate command
 353
 354 dnl ###############
 355 dnl # make checks #
 356 dnl ###############
 357 dnl check if VPATH works
 358 AC_MSG_CHECKING("make for VPATH support")
 359 dnl create Makefile
 360 cat - << EOF > confMake
 361 check : file
 362         cp \$? \$@
 363         cp \$? final_file
 364 EOF
 365
 366 if test ! -d sub ; then
 367   mkdir sub
 368 fi
 369 echo dummy > sub/file
 370 ${MAKE-make} -f confMake VPATH=sub 2> config.log > /dev/null
 371 RESULT=$?
 372 rm -f sub/file check final_file config.log confMake
 373 rmdir sub
 374 if test "$RESULT" = 0; then
 375   AC_MSG_RESULT(yes)
 376 else
 377   AC_MSG_RESULT(no)
 378   AC_MSG_ERROR(
 379 You need a make-utility that is able to use the variable
 380 VPATH correctly.
 381 If your version of make does not support VPATH correctly,
 382 please install GNU-make (possibly as gmake), and start
 383 configure with the following command:
 384 export MAKE=gmake; ./configure  for sh-type shells
 385 setenv MAKE gmake; ./configure  for csh-type shells
 386 Also please do remember to use gmake in this case every time
 387 you are trying to compile.
 388 )
 389 fi
 390
 391 dnl ####################
 392 dnl # checks libraries #
 393 dnl ####################
 394
 395 dnl find the X11 include and library files
 396 AC_PATH_XTRA
 397 dnl   defines x_includes and x_libraries
 398
 399 dnl #######################
 400 dnl # checks header files #
 401 dnl #######################
 402 AC_HEADER_DIRENT
 403 dnl   defines DIR
 404 dnl   defines MACRO HAVE_DIRENT_H if dirent.h exists
 405 dnl   defines MACRO HAVE_SYS_NDIR_H if sys/ndir.h exists
 406 dnl   defines MACRO HAVE_SYS_DIR_H if sys/dir.h exists
 407 dnl   defines MACRO HAVE_NDIR_H if ndir.h exists
 408 AC_HEADER_STDC
 409 dnl   defines STDC_HEADERS if ANSI-C header
 410 AC_HEADER_SYS_WAIT
 411 dnl   defines HAVE_SYS_WAIT_H if sys/wait.h exist and is POSIX.1
 412 AC_CHECK_HEADER(fcntl.h)
 413 dnl   defines HAVE_FCNTL_H
 414 AC_CHECK_HEADER(limits.h)
 415 dnl   defines HAVE_LIMITS_h
 416 AC_CHECK_HEADER(sys/file.h)
 417 dnl   defines HAVE_SYS_FILE_H
 418 AC_CHECK_HEADER(sys/time.h)
 419 dnl   defines HAVE_SYS_TIME_H
 420 AC_CHECK_HEADER(unistd.h)
 421 dnl   defines HAVE_UNISTD_H
 422 dnl As it needs Linux 2.1.x for the moment: check whether the file exists (GL).
 423 AC_CHECK_HEADER(linux/joystick.h)
 424 GTK_JOYSTICK=""
 425 if test "$ac_cv_header_linux_joystick_h" = "yes"; then
 426   GTK_JOYSTICK="gtk/joystick.cpp"
 427 fi
 428 AC_SUBST(GTK_JOYSTICK)
 429
 430 dnl ###################
 431 dnl # checks typedefs #
 432 dnl ###################
 433 AC_TYPE_GETGROUPS
 434 dnl   defines GETGROUPS_T
 435 AC_TYPE_MODE_T
 436 dnl   defines mode_t if not already defined
 437 AC_TYPE_OFF_T
 438 dnl   defines off_t if not already defined
 439 AC_TYPE_PID_T
 440 dnl   defines pid_t if not already defined
 441 AC_TYPE_SIGNAL
 442 dnl   defines RETSIGTYPE for the correct return type of signal
 443 AC_TYPE_SIZE_T
 444 dnl   defines size_t if not already defined
 445 AC_TYPE_UID_T
 446 dnl   defines uid_t and gid_t if not already defined
 447
 448 dnl #####################
 449 dnl # checks structures #
 450 dnl #####################
 451
 452 AC_HEADER_STAT
 453 dnl   defines STAT_MACROS_BROKEN if S_ISDIR and S_ISREG
 454 dnl                              do not work properly
 455 AC_HEADER_TIME
 456 dnl   defines TIME_WITH_SYS_TIME if time.h and sys/time.h can
 457 dnl                              both be included
 458 AC_STRUCT_ST_BLKSIZE
 459 dnl   defines HAVE_ST_BLKSIZE if struct stat contains st_blksize
 460 AC_STRUCT_ST_BLOCKS
 461 dnl   defines HAVE_ST_BLOCKS if struct stat contains st_blocks
 462 AC_STRUCT_ST_RDEV
 463 dnl   defines HAVE_ST_RDEV if struct stat contains st_rdev
 464 AC_STRUCT_TM
 465 dnl   defines TM_IN_SYS_TIME if struct tm is not in time.h
 466 AC_STRUCT_TIMEZONE
 467 dnl   defines HAVE_ST_BLKSIZE if struct tm contains tm_zone
 468 dnl   otherwise
 469 dnl   defines HAVE_TZNAME if external array tzname is found
 470
 471 dnl ###################################
 472 dnl # checks compiler characteristics #
 473 dnl ###################################
 474 dnl AC_C_CROSS
 475
 476 AC_C_CONST
 477 dnl   defines const to be empty if c-compiler does not support const fully
 478 AC_C_INLINE
 479 dnl   defines inline to a sensible value for the c-compiler
 480 AC_C_CHAR_UNSIGNED
 481 dnl   defines __CHAR_UNSIGNED__ if char is unsigned
 482 AC_C_LONG_DOUBLE
 483 dnl   defines HAVE_LONGDOUBLE if compiler supports long double
 484
 485 AC_C_BIGENDIAN
 486 dnl   defines WORDS_BIGENDIAN if system is big endian
 487
 488 AC_CHECK_SIZEOF(int *)
 489 AC_CHECK_SIZEOF(int)
 490 AC_CHECK_SIZEOF(long)
 491 dnl   defines the size of certain types of variables in SIZEOF_???
 492
 493 dnl ############################
 494 dnl # checks library functions #
 495 dnl ############################
 496
 497 dnl ##########################
 498 dnl # checks system services #
 499 dnl ##########################
 500
 501
 502 dnl ##### Threads #####
 503 USE_THREADS=1
 504 THREADS_LINK=""
 505 UNIX_THREAD=""
 506
 507 AC_ARG_WITH(threads,
 508 [  --without-threads       Force disabling threads ],
 509 [USE_THREADS="$withval"])
 510
 511 if test "$USE_THREADS" = "1"; then
 512   UNIX_THREAD="gtk/threadno.cpp"
 513
 514   dnl For glibc 2 users who have the old libc 5 too
 515
 516   AC_CHECK_LIB(pthread-0.7, pthread_create, [
 517      UNIX_THREAD="gtk/threadpsx.cpp"
 518      THREADS_LINK="-lpthread-0.7"
 519      AC_DEFINE(USE_THREADS)
 520   ],[
 521     AC_CHECK_LIB(pthread, pthread_create, [
 522        UNIX_THREAD="gtk/threadpsx.cpp"
 523        THREADS_LINK="-lpthread"
 524        AC_DEFINE(USE_THREADS)
 525     ])
 526   ])
 527   AC_CHECK_LIB(pthreads, pthread_create, [
 528      UNIX_THREAD="gtk/threadpsx.cpp"
 529      THREADS_LINK="-lpthreads"
 530      AC_DEFINE(USE_THREADS)
 531   ])
 532   AC_CHECK_HEADER(sys/prctl.h, [
 533      UNIX_THREAD="gtk/threadsgi.cpp"
 534      AC_DEFINE(USE_THREADS)
 535   ])
 536 fi
 537
 538 AC_SUBST(UNIX_THREAD)
 539 AC_SUBST(THREADS_LINK)
 540 dnl   defines UNIX_THREAD it contains the source file to use for threads. (GL)
 541 dnl   defines THREADS_LINK it contains the thread library to link with. (GL)
 542 dnl   defines USE_THREADS if thread support is activated. (GL)
 543
 544 AC_SYS_LONG_FILE_NAMES
 545 dnl   defines HAVE_LONG_FILENAMES if filenames longer then
 546 dnl                               14 chars are supported
 547
 548 dnl AC_SYS_RESTARTABLE_SYSCALLS
 549 dnl   defines HAVE_RESTARTABLE_SYSCALLS if the system restarts a
 550 dnl                                     system call that is interrupted
 551 dnl                                     by a signal
 552
 553 dnl #################
 554 dnl # checks PARSER #
 555 dnl #################
 556
 557 dnl YACC checks
 558 dnl ===========
 559 AC_PROG_YACC
 560 dnl   defines YACC with the appropriate command
 561
 562 dnl LEX checks
 563 dnl ==========
 564 AC_PROG_LEX
 565 dnl   defines LEX with the appropriate command
 566 dnl   defines LEXLIB with the appropriate library
 567 dnl what type is yytext
 568 AC_DECL_YYTEXT
 569 dnl   defines YYTEXT_POINTER  if yytext is char*
 570 dnl   defines LEX_OUTPUT_ROOT as to the base of the
 571 dnl                           filename output by the lexer
 572
 573 dnl ------------------------------------------------------------------------
 574 dnl main includes
 575 dnl ------------------------------------------------------------------------
 576
 577 CHECK_INCLUDE="-I/usr/include $X_CFLAGS"
 578 CHECK_LIB="-L/lib -L/usr/lib $X_LIBS"
 579
 580 dnl ------------------------------------------------------------------------
 581 dnl host system
 582 dnl ------------------------------------------------------------------------
 583
 584 AC_CANONICAL_HOST
 585 canonical=$host
 586 configuration=$host_alias
 587
 588 dnl ------------------------------------------------------------------------
 589 dnl system settings
 590 dnl ------------------------------------------------------------------------
 591
 592 USE_GTK=1
 593 USE_UNIX=1
 594
 595 TOOLKIT=GTK
 596 TOOLKIT_DEF=__WXGTK__
 597
 598 USE_LINUX=
 599 USE_SGI=
 600 USE_HPUX=
 601 USE_SYSV=
 602 USE_SVR4=
 603 USE_AIX=
 604 USE_SUN=
 605 USE_SOLARIS=
 606 USE_SUNOS=
 607 USE_ALPHA=
 608 USE_OSF=
 609 USE_BSD=
 610 USE_FREEBSD=
 611 USE_VMS=
 612 USE_ULTRIX=
 613 USE_DATA_GENERAL=
 614
 615 case "${canonical}" in
 616   *-hp-hpux* )
 617     USE_HPUX=1
 618     AC_DEFINE(__HPUX__)
 619   ;;
 620   *-*-linux* )
 621     USE_LINUX=1
 622     AC_DEFINE(__LINUX__)
 623   ;;
 624   *-*-irix5* | *-*-irix6* )
 625     USE_SGI=1
 626     USE_SVR4=1
 627     AC_DEFINE(__SGI__)
 628     AC_DEFINE(__SVR4__)
 629   ;;
 630   *-*-solaris2* )
 631     USE_SUN=1
 632     USE_SOLARIS=1
 633     USE_SVR4=1
 634     AC_DEFINE(__SUN__)
 635     AC_DEFINE(__SOLARIS__)
 636     AC_DEFINE(__SVR4__)
 637   ;;
 638   *-*-sunos4* )
 639     USE_SUN=1
 640     USE_SUNOS=1
 641     USE_BSD=1
 642     AC_DEFINE(__SUN__)
 643     AC_DEFINE(__SUNOS__)
 644     AC_DEFINE(__BSD__)
 645   ;;
 646   *-*-freebsd* | *-*-netbsd*)
 647     USE_BSD=1
 648     USE_FREEBSD=1
 649     AC_DEFINE(__FREEBSD__)
 650     AC_DEFINE(__BSD__)
 651   ;;
 652   *-*-osf* )
 653     USE_ALPHA=1
 654     USE_OSF=1
 655     AC_DEFINE(__ALPHA__)
 656     AC_DEFINE(__OSF__)
 657   ;;
 658   *-*-dgux5* )
 659     USE_ALPHA=1
 660     USE_SVR4=1
 661     AC_DEFINE(__ALPHA__)
 662     AC_DEFINE(__SVR4__)
 663   ;;
 664   *-*-sysv5* )
 665     USE_SYSV=1
 666     USE_SVR4=1
 667     AC_DEFINE(__SYSV__)
 668     AC_DEFINE(__SVR4__)
 669   ;;
 670   *-*-aix* )
 671     USE_AIX=1
 672     USE_SYSV=1
 673     USE_SVR4=1
 674     AC_DEFINE(__AIX__)
 675     AC_DEFINE(__SYSV__)
 676     AC_DEFINE(__SVR4__)
 677   ;;
 678   *)
 679     AC_MSG_ERROR(I don't know your system type.)
 680 esac
 681
 682 dnl ------------------------------------------------------------------------
 683 dnl defaults for command options
 684 dnl ------------------------------------------------------------------------
 685
 686 AC_OVERRIDES_PREPARE
 687
 688 DEFAULT_USE_SHARED=0
 689 DEFAULT_USE_OPTIMISE=1
 690 DEFAULT_USE_PROFILE=0
 691 DEFAULT_USE_DEBUG_FLAG=0
 692 DEFAULT_USE_DEBUG_INFO=0
 693 DEFAULT_USE_MEM_TRACING=0
 694
 695 DEFAULT_USE_ZLIB=1
 696 DEFAULT_USE_GDK_IMLIB=1
 697 DEFAULT_USE_LIBPNG=1
 698
 699 DEFAULT_USE_APPLE_IEEE=1
 700 DEFAULT_USE_STORABLE_CLASSES=1
 701 DEFAULT_USE_AUTOTRANS=1
 702 DEFAULT_USE_AFM_FOR_POSTSCRIPT=1
 703 DEFAULT_WX_NORMALIZED_PS_FONTS=1
 704
 705 DEFAULT_USE_IOSTREAMH=1
 706
 707 DEFAULT_USE_OPENGL=0
 708
 709 DEFAULT_USE_WXCONFIG=1
 710 DEFAULT_USE_POSTSCRIPT=1
 711 DEFAULT_USE_IPC=1
 712 DEFAULT_USE_RESOURCES=1
 713 DEFAULT_USE_TIMEDATE=1
 714 DEFAULT_USE_FRACTION=1
 715 DEFAULT_USE_CONSTRAINTS=1
 716 DEFAULT_USE_TOOLBAR=1
 717 DEFAULT_USE_GAUGE=1
 718 DEFAULT_USE_SCROLLBAR=1
 719 DEFAULT_USE_DOC_VIEW_ARCHITECTURE=1
 720 DEFAULT_USE_PRINTING_ARCHITECTURE=1
 721
 722 DEFAULT_USE_METAFILE=0
 723 DEFAULT_USE_HELP=0
 724 DEFAULT_USE_CLIPBOARD=0
 725 DEFAULT_USE_VLBOX=0
 726 DEFAULT_USE_WXGRAPH=0
 727 DEFAULT_USE_WXTREE=0
 728 DEFAULT_USE_ENHANCED_DIALOG=0
 729
 730 DEFAULT_USE_FORM=0
 731 DEFAULT_USE_PROLOGIO=1
 732 DEFAULT_USE_RPC=0
 733 DEFAULT_USE_WX_RESOURCES=1
 734
 735 dnl ----------------------------------------------------------------
 736 dnl user options
 737 dnl ----------------------------------------------------------------
 738
 739 AC_OVERRIDES(shared,shared,
 740 **--with-shared           create shared libraries,
 741 USE_SHARED)
 742
 743 AC_OVERRIDES(optimise,optimise,
 744 **--with-optimise      create optimised code,
 745 USE_OPTIMISE)
 746
 747 AC_OVERRIDES(debug_flag,debug_flag,
 748 **--with-debug_flag       create code with DEBUG define set to 1,
 749 USE_DEBUG_FLAG)
 750
 751 AC_OVERRIDES(debug_info,debug_info,
 752 **--with-debug_info       create code with debuging information included,
 753 USE_DEBUG_INFO)
 754
 755 AC_OVERRIDES(mem_tracing,mem_tracing,
 756 **--with-mem_traing       create code with memory tracing,
 757 USE_MEM_TRACING)
 758
 759 AC_OVERRIDES(profile,profile,
 760 **--with-profile          create code with profiling information included,
 761 USE_PROFILE)
 762
 763 dnl ----------------------------------------------------------------
 764 dnl user options for libraries (no choice yet)
 765 dnl ----------------------------------------------------------------
 766
 767 AC_OVERRIDES(zlib,zlib,
 768 **--with-zlib             use zlib (LZW comression),
 769 USE_ZLIB)
 770
 771 AC_OVERRIDES(gdk_imlib,gdk_imlib,
 772 **--with-gdk_imlib        use Raster's gdk_imlib (Image library),
 773 USE_GDK_IMLIB)
 774
 775 AC_OVERRIDES(libpng,libpng,
 776 **--with-libpng           use libpng (PNG image format),
 777 USE_LIBPNG)
 778
 779 AC_OVERRIDES(opengl,opengl,
 780 **--with-opengl           use opengl (OpenGL or Mesa),
 781 USE_OPENGL)
 782
 783 dnl ----------------------------------------------------------------
 784 dnl user options for code features (no choice yet)
 785 dnl ----------------------------------------------------------------
 786
 787 AC_OVERRIDES(apple_ieee, apple_ieee,
 788 **--with_apple_ieee       use the Apple IEEE codec,
 789 USE_APPLE_IEEE)
 790
 791 AC_OVERRIDES(storable,storable,
 792 **--with-storable         use storable classes,
 793 USE_STORABLE_CLASSES)
 794
 795 AC_OVERRIDES(autotrans,autotrans,
 796 **--with-autotrans        use gettext automatic translation,
 797 USE_AUTOTRANS)
 798
 799 AC_OVERRIDES(afmfonts,afmfonts,
 800 **--with-afmfonts         use Adobe Font Metric Font table,
 801 USE_AFM_FOR_POSTSCRIPT)
 802
 803 AC_OVERRIDES(normalized, normalized,
 804 **--with-PS-normalized    use normalized PS fonts,
 805 WX_NORMALIZED_PS_FONTS)
 806
 807 AC_OVERRIDES(rpc,RPC,
 808 **--with-rpc              use RPC,
 809 USE_RPC)
 810
 811 AC_OVERRIDES(wxresources,wxresources,
 812 **--with-wxresources      use wxresources,
 813 USE_WX_RESOURCES)
 814
 815 AC_OVERRIDES(prologio,prologio,
 816 **--with-prologio         use prologio,
 817 USE_PROLOGIO)
 818
 819 AC_OVERRIDES(postscript, postscript,
 820 **--with-postscript       use postscript-device-context,
 821 USE_POSTSCRIPT)
 822
 823 AC_OVERRIDES(wxconfig, wxconfig,
 824 **--with-wxconfig         use wxconfig,
 825 USE_WXCONFIG)
 826
 827 AC_OVERRIDES(metafile, metafile,
 828 **--with-metafile         use metafile,
 829 USE_METAFILE)
 830
 831 AC_OVERRIDES(form,form,
 832 **--with-form             use form,
 833 USE_FORM)
 834
 835 AC_OVERRIDES(help,help,
 836 **--with-help             use help,
 837 USE_HELP)
 838
 839 AC_OVERRIDES(ipc,IPC,
 840 **--with-ipc              use ipc,
 841 USE_IPC)
 842
 843 AC_OVERRIDES(enhanceddialog,enhanced dialog,
 844 **--with-enhanceddialog   use enhanced dialog,
 845 USE_ENHANCED_DIALOG)
 846
 847 AC_OVERRIDES(resources,resources,
 848 **--with-resources        use resources,
 849 USE_RESOURCES)
 850
 851 AC_OVERRIDES(clipboard,clipboard,
 852 **--with-clipboard        use clipboard,
 853 USE_CLIPBOARD)
 854
 855 AC_OVERRIDES(timedate, timedate,
 856 **--with-timedate         use timedate,
 857 USE_TIMEDATE)
 858
 859 AC_OVERRIDES(fraction,fraction,
 860 **--with-fraction         use fraction,
 861 USE_FRACTION)
 862
 863 AC_OVERRIDES(constraints,constrains,
 864 **--with-constraints      use constraints,
 865 USE_CONSTRAINTS)
 866
 867 AC_OVERRIDES(toolbar,toolbar,
 868 **--with-toolbar          use toolbar,
 869 USE_TOOLBAR)
 870
 871 AC_OVERRIDES(gauge,gauge,
 872 **--with-gauge            use gauge,
 873 USE_GAUGE)
 874
 875 AC_OVERRIDES(vllist,vllist,
 876 **--with-vlbox            use virtual list box,
 877 USE_VLBOX)
 878
 879 AC_OVERRIDES(scrollbar,scrollbar,
 880 **--with-scrollbar        use scrollbar,
 881 USE_SCROLLBAR)
 882
 883 AC_OVERRIDES(docview,docview,
 884 **--with-docview          use document view architecture,
 885 USE_DOC_VIEW_ARCHITECTURE)
 886
 887 AC_OVERRIDES(printarch,printarch,
 888 **--with-printarch        use printing architecture,
 889 USE_PRINTING_ARCHITECTURE)
 890
 891 AC_OVERRIDES(typetree,typetree,
 892 **--with-typetree         use typetree,
 893 USE_TYPETREE)
 894
 895 AC_OVERRIDES(wxgraph,wxgraph,
 896 **--with-wxgraph          use wxgraph,
 897 USE_WXGRAPH)
 898
 899 AC_OVERRIDES(wxtree,wxtree,
 900 **--with-wxtree           use wxtree,
 901 USE_WXTREE)
 902
 903 dnl AC_OVERRIDES(package,message,helpmessage,variable)
 904
 905 dnl ----------------------------------------------------------------
 906 dnl register changes for Makefiles (via substit) and setup.h
 907 dnl ----------------------------------------------------------------
 908
 909 ZLIB=NONE
 910 if test "$USE_ZLIB" = 1 ; then
 911   ZLIB="ZLIB"
 912 fi
 913
 914 GDK_IMLIB=NONE
 915 if test "$USE_GDK_IMLIB" = 1 ; then
 916   GDK_IMLIB="GDK_IMLIB"
 917 fi
 918
 919 LIBPNG=NONE
 920 if test "$USE_LIBPNG" = 1 ; then
 921   LIBPNG="LIBPNG"
 922 fi
 923
 924 APPLE_IEEE=NONE
 925 if test "$USE_APPLE_IEEE" = 1 ; then
 926   APPLE_IEEE="APPLE_IEEE"
 927   AC_DEFINE_UNQUOTED(USE_APPLE_IEEE,$USE_APPLE_IEEE)
 928 fi
 929
 930 STORABLE=NONE
 931 if test "$USE_STORABLE_CLASSES" = 1 ; then
 932   STORABLE="STORABLE"
 933   AC_DEFINE_UNQUOTED(USE_STORABLE_CLASSES,$USE_STORABLE_CLASSES)
 934 fi
 935
 936 AUTOTRANS=NONE
 937 if test "$USE_AUTOTRANS" = 1 ; then
 938   AUTOTRANS="AUTOTRANS"
 939   AC_DEFINE_UNQUOTED(USE_AUTOTRANS,$USE_AUTOTRANS)
 940 fi
 941
 942 WXDEBUG=
 943 if test "$USE_DEBUG_INFO" = 1 ; then
 944   WXDEBUG="-g"
 945 fi
 946 AC_SUBST(WXDEBUG)
 947
 948 if test "$USE_DEBUG_FLAG" = 1 ; then
 949   AC_DEFINE_UNQUOTED(WXDEBUG,$USE_DEBUG_FLAG)
 950 fi
 951
 952 if test "$USE_MEM_TRACING" = 1 ; then
 953   AC_DEFINE_UNQUOTED(USE_MEMORY_TRACING,$USE_MEM_TRACING)
 954   AC_DEFINE_UNQUOTED(USE_GLOBAL_MEMORY_OPERATORS,$USE_MEM_TRACING)
 955 fi
 956
 957 PROFILE=
 958 if test "$USE_PROFILE" = 1 ; then
 959   PROFILE="-pg"
 960 fi
 961 AC_SUBST(PROFILE)
 962
 963 CXXFLAGS=`echo "${CXXFLAGS}" | sed "s/\-O.//g" `
 964 CFLAGS=`echo "${CFLAGS}" | sed "s/\-O.//g" `
 965 if test "$USE_OPTIMISE" = 0 ; then
 966   OPTIMISE=
 967 else
 968   if test "$GCC" = yes ; then
 969     OPTIMISE="-O2"
 970     case "${canonical}" in
 971       i586-*-*|i686-*-* )
 972         OPTIMISE="${OPTIMISE} "
 973         ;;
 974     esac
 975   else
 976     OPTIMISE="-O"
 977   fi
 978 fi
 979 AC_SUBST(OPTIMISE)
 980
 981 USE_IOSTREAMH=$DEFAULT_USE_IOSTREAMH
 982 AC_DEFINE_UNQUOTED(USE_IOSTREAMH,$USE_IOSTREAMH)
 983
 984 RPC=NONE
 985 if test "$USE_RPC" = 1 ; then
 986   RPC="RPC"
 987   AC_DEFINE_UNQUOTED(USE_RPC,$USE_RPC)
 988 fi
 989 AC_SUBST(RPC)
 990
 991 WXRESOURCES=NONE
 992 if test "$USE_WX_RESOURCES" = 1 ; then
 993   WXRESOURCES="WXRESOURCES"
 994   AC_DEFINE_UNQUOTED(USE_WX_RESOURCES,$USE_WX_RESOURCES)
 995 fi
 996 AC_SUBST(WXRESOURCES)
 997
 998 PROLOGIO=NONE
 999 PROLOGIOSRC=NONE
1000 if test "$USE_PROLOGIO" = 1 ; then
1001   PROLOGIO="PROLOGIO"
1002   PROLOGIOSRC="PROLOGIOSRC"
1003   AC_DEFINE_UNQUOTED(USE_PROLOGIO)
1004 fi
1005 AC_SUBST(PROLOGIO)
1006 AC_SUBST(PROLOGIOSRC)
1007
1008 POSTSCRIPTDC=NONE
1009 if test "$USE_POSTSCRIPT" = 1 ; then
1010   POSTSCRIPTDC="POSTSCRIPTDC"
1011   AC_DEFINE_UNQUOTED(USE_POSTSCRIPT)
1012 fi
1013 AC_SUBST(POSTSCRIPTDC)
1014
1015 if test "$USE_WXCONFIG" = 1 ; then
1016   AC_DEFINE_UNQUOTED(USE_WXCONFIG,$USE_WXCONFIG)
1017 fi
1018
1019 METAFILE=NONE
1020 if test "$USE_METAFILE" = 1 ; then
1021   METAFILE="METAFILE"
1022   AC_DEFINE_UNQUOTED(USE_METAFILE,$USE_METAFILE)
1023 fi
1024 AC_SUBST(METAFILE)
1025
1026 FORM=NONE
1027 if test "$USE_FORM" = 1 ; then
1028   FORM="FORM"
1029   AC_DEFINE_UNQUOTED(USE_FORM,$USE_FORM)
1030 fi
1031 AC_SUBST(FORM)
1032
1033 HELP=NONE
1034 if test "$USE_HELP" = 1 ; then
1035   HELP="HELP"
1036   AC_DEFINE_UNQUOTED(USE_HELP,$USE_HELP)
1037 fi
1038 AC_SUBST(HELP)
1039
1040 IPC=NONE
1041 if test "$USE_IPC" = 1 ; then
1042   IPC="IPC"
1043   AC_DEFINE_UNQUOTED(USE_IPC)
1044 fi
1045 AC_SUBST(IPC)
1046
1047 ENHDIALOGBOX=NONE
1048 if test "$USE_ENHANCED_DIALOG" = 1 ; then
1049   ENHDIALOGBOX="ENHDIALOGBOX"
1050   AC_DEFINE_UNQUOTED(USE_ENHANCED_DIALOG,$USE_ENHANCED_DIALOG)
1051 fi
1052 AC_SUBST(ENHDIALOGBOX)
1053
1054 XRESOURCES=NONE
1055 if test "$USE_RESOURCES" = 1 ; then
1056   XRESOURCES="XRESOURCES"
1057   AC_DEFINE_UNQUOTED(USE_RESOURCES,$USE_RESOURCES)
1058 fi
1059 AC_SUBST(XRESOURCES)
1060
1061 CLIPBOARD=NONE
1062 if test "$USE_CLIPBOARD" = 1 ; then
1063   CLIPBOARD="CLIPBOARD"
1064   AC_DEFINE_UNQUOTED(USE_CLIPBOARD,$USE_CLIPBOARD)
1065 fi
1066 AC_SUBST(CLIPBOARD)
1067
1068 CONSTRAINTS=NONE
1069 if test "$USE_CONSTRAINTS" = 1 ; then
1070   CONSTRAINTS="CONSTRAINTS"
1071   AC_DEFINE_UNQUOTED(USE_CONSTRAINTS,$USE_CONSTRAINTS)
1072 fi
1073 AC_SUBST(CONSTRAINTS)
1074
1075 TIMEDATE=NONE
1076 if test "$USE_TIMEDATE" = 1 ; then
1077   TIMEDATE="TIMEDATE"
1078   AC_DEFINE_UNQUOTED(USE_TIMEDATE,$USE_TIMEDATE)
1079 fi
1080 AC_SUBST(TIMEDATE)
1081
1082 FRACTION=NONE
1083 if test "$USE_FRACTION" = 1 ; then
1084   FRACTION="FRACTION"
1085   AC_DEFINE_UNQUOTED(USE_FRACTION,$USE_FRACTION)
1086 fi
1087 AC_SUBST(FRACTION)
1088
1089 TOOLBAR=NONE
1090 if test "$USE_TOOLBAR" = 1 ; then
1091   TOOLBAR="TOOLBAR"
1092   AC_DEFINE_UNQUOTED(USE_TOOLBAR,$USE_TOOLBAR)
1093   AC_DEFINE_UNQUOTED(USE_XT_TOOLBAR,$USE_XT_TOOLBAR)
1094 fi
1095 AC_SUBST(TOOLBAR)
1096
1097 GAUGE=NONE
1098 if test "$USE_GAUGE" = 1 ; then
1099   GAUGE="GAUGE"
1100   AC_SUBST(GAUGE)
1101   AC_DEFINE_UNQUOTED(USE_GAUGE,$USE_GAUGE)
1102 fi
1103
1104 VIRLISTBOX=NONE
1105 if test "$USE_VLBOX" = 1 ; then
1106   VIRTLISTBOX="VIRLISTBOX"
1107   AC_DEFINE_UNQUOTED(USE_VIRLISTBOX,$USE_VIRLISTBOX)
1108 fi
1109 AC_SUBST(VIRLISTBOX)
1110
1111 SCROLLBAR=NONE
1112 if test "$USE_SCROLLBAR" = 1 ; then
1113   SCROLLBAR="SCROLLBAR"
1114   AC_DEFINE_UNQUOTED(USE_SCROLLBAR,$USE_SCROLLBAR)
1115 fi
1116 AC_SUBST(SCROLLBAR)
1117
1118 DOCVIEW=NONE
1119 if test "$USE_DOC_VIEW_ARCHITECTURE" = 1 ; then
1120   DOCVIEW="DOCVIEW"
1121   AC_DEFINE_UNQUOTED(USE_DOC_VIEW_ARCHITECTURE,$USE_DOC_VIEW_ARCHITECTURE)
1122 fi
1123 AC_SUBST(DOCVIEW)
1124
1125 PRINTPREVIEW=NONE
1126 if test "$USE_PRINTING_ARCHITECTURE" = 1 ; then
1127   PRINTPREVIEW="PRINTPREVIEW"
1128   AC_DEFINE_UNQUOTED(USE_PRINTING_ARCHITECTURE,$USE_PRINTING_ARCHITECTURE)
1129 fi
1130 AC_SUBST(PRINTPREVIEW)
1131
1132 TYPETREE=NONE
1133 if test "$USE_TYPETREE" = 1 ; then
1134   TYPETREE="TYPETREE"
1135   AC_DEFINE_UNQUOTED(USE_TYPETREE,$USE_TYPETREE)
1136 fi
1137 AC_SUBST(TYPETREE)
1138
1139 WXGRAPH=NONE
1140 if test "$USE_WXGRAPH" = 1 ; then
1141   WXGRAPH="WXGRAPH"
1142   AC_DEFINE_UNQUOTED(USE_WXGRAPH,$USE_WXGRAPH)
1143 fi
1144 AC_SUBST(WXGRAPH)
1145
1146 WXTREE=NONE
1147 if test "$USE_WXTREE" = 1 ; then
1148   WXTREE="WXTREE"
1149   AC_DEFINE_UNQUOTED(USE_WXTREE,$USE_WXTREE)
1150 fi
1151 AC_SUBST(WXTREE)
1152
1153 GLCANVAS=NONE
1154 if test "$USE_OPENGL" = 1 ; then
1155   GLCANVAS="GLCANVAS"
1156 fi
1157
1158 AC_DEFINE_UNQUOTED(USE_AFM_FOR_POSTSCRIPT,$USE_AFM_FOR_POSTSCRIPT)
1159
1160 AC_DEFINE_UNQUOTED(WX_NORMALIZED_PS_FONTS,$WX_NORMALIZED_PS_FONTS)
1161
1162 dnl ----------------------------------------------------------------
1163 dnl Unix, obviously
1164 dnl ----------------------------------------------------------------
1165
1166 if test "$USE_UNIX" = 1 ; then
1167   AC_DEFINE(__UNIX__)
1168 fi
1169
1170 dnl ----------------------------------------------------------------
1171 dnl search for GTK
1172 dnl ----------------------------------------------------------------
1173
1174 GUI_TK_INCLUDE=
1175 GUI_TK_LIBRARY=
1176 GUI_TK_LINK=
1177
1178 if test "$USE_GTK" = 1; then
1179   AM_PATH_GTK(0.99.7, [
1180        GUI_TK_INCLUDE="$GTK_CFLAGS"
1181        GUI_TK_LIBRARY="$GTK_LIBS"
1182   ], AC_MSG_ERROR(Are gtk-config and the GTK in path and up-to-date?))
1183   AC_DEFINE(__WXGTK__)
1184 fi
1185 AC_SUBST(GUI_TK_INCLUDE)
1186 AC_SUBST(GUI_TK_LIBRARY)
1187 AC_SUBST(GUI_TK_LINK)
1188
1189 AC_SUBST(TOOLKIT)
1190 AC_SUBST(TOOLKIT_DEF)
1191
1192 dnl ----------------------------------------------------------------
1193 dnl search for opengl
1194 dnl ----------------------------------------------------------------
1195
1196 OPENGL_INCLUDE=
1197 OPENGL_LIBRARY=
1198 OPENGL_LINK=
1199
1200 if test "$USE_OPENGL" = 1; then
1201   dnl checking OPENGL includes
1202   AC_MSG_CHECKING(for OpenGL includes)
1203   AC_PATH_FIND_INCLUDES($SEARCH_INCLUDE,GL/gl.h)
1204   if test "$ac_find_includes" != "" ; then
1205     OPENGL_INCLUDE="-I$ac_find_includes"
1206     AC_MSG_RESULT(found $ac_find_includes)
1207     dnl checking OPENGL libraries
1208     AC_MSG_CHECKING(for OpenGL library)
1209     AC_PATH_FIND_LIBRARIES($SEARCH_LIB,GL)
1210     if test "$ac_find_libraries" != "" ; then
1211       AC_INCLUDE_PATH_EXIST($ac_find_includes,$CHECK_INCLUDE)
1212       AC_LINK_PATH_EXIST($ac_find_libraries,$CHECK_LIB)
1213       CHECK_LINK="$CHECK_INCLUDE $ac_path_to_link"
1214       CHECK_INCLUDE="$CHECK_INCLUDE $ac_path_to_include"
1215       OPENGL_LIBRARY="$ac_path_to_link"
1216       OPENGL_INCLUDE="$ac_path_to_include"
1217       OPENGL_LINK="-lGL"
1218       AC_MSG_RESULT(found OpenGL at $ac_find_libraries)
1219     else
1220       AC_PATH_FIND_LIBRARIES($SEARCH_LIB,MesaGL)
1221       if test "$ac_find_libraries" != "" ; then
1222         AC_INCLUDE_PATH_EXIST($ac_find_includes,$CHECK_INCLUDE)
1223         AC_LINK_PATH_EXIST($ac_find_libraries,$CHECK_LIB)
1224         CHECK_LINK="$CHECK_INCLUDE $ac_path_to_link"
1225         CHECK_INCLUDE="$CHECK_INCLUDE $ac_path_to_include"
1226         OPENGL_LIBRARY="$ac_path_to_link"
1227         OPENGL_INCLUDE="$ac_path_to_include"
1228         OPENGL_LINK="-lMesaGL"
1229         AC_MSG_RESULT(found MESA at $ac_find_libraries)
1230       else
1231         AC_MSG_ERROR(no)
1232       fi
1233     fi
1234   else
1235     AC_MSG_ERROR(no)
1236   fi
1237 fi
1238
1239 dnl ----------------------------------------------------------------
1240 dnl search for gdk_imlib
1241 dnl ----------------------------------------------------------------
1242 dnl
1243 dnl GDK_IMLIB_INCLUDE=
1244 dnl GDK_IMLIB_LIBRARY=
1245 dnl GDK_IMLIB_LINK=
1246 dnl
1247     if test "$USE_GDK_IMLIB" = 1; then
1248 dnl   AC_MSG_CHECKING(for gdk_imlib includes)
1249 dnl   AC_PATH_FIND_INCLUDES($SEARCH_INCLUDE,gdk_imlib.h)
1250 dnl   if test "$ac_find_includes" != "" ; then
1251 dnl     dnl GDK_IMLIB_INCLUDE="-I$ac_find_includes"
1252 dnl     AC_MSG_RESULT(found $ac_find_includes)
1253 dnl     AC_MSG_CHECKING(for gdk_imlib library)
1254 dnl     AC_PATH_FIND_LIBRARIES($SEARCH_LIB,gdk_imlib)
1255 dnl     if test "$ac_find_libraries" != "" ; then
1256 dnl       AC_INCLUDE_PATH_EXIST($ac_find_includes,$CHECK_INCLUDE)
1257 dnl       AC_LINK_PATH_EXIST($ac_find_libraries,$CHECK_LIB)
1258 dnl       CHECK_LINK="$CHECK_INCLUDE $ac_path_to_link"
1259 dnl       CHECK_INCLUDE="$CHECK_INCLUDE $ac_path_to_include"
1260 dnl       GDK_IMLIB_LIBRARY="$ac_path_to_link"
1261 dnl       GDK_IMLIB_INCLUDE="$ac_path_to_include"
1262 dnl       GDK_IMLIB_LINK="-lgdk_imlib"
1263 dnl       AC_MSG_RESULT(found gdk_imlib at $ac_find_libraries)
1264 dnl     else
1265 dnl       AC_MSG_ERROR(no)
1266 dnl     fi
1267 dnl   else
1268 dnl     AC_MSG_ERROR(no)
1269 dnl   fi
1270       AC_DEFINE_UNQUOTED(USE_GDK_IMLIB,$USE_GDK_IMLIB)
1271     fi
1272 dnl AC_SUBST(GDK_IMLIB_INCLUDE)
1273 dnl AC_SUBST(GDK_IMLIB_LIBRARY)
1274 dnl AC_SUBST(GDK_IMLIB_LINK)
1275
1276 dnl ----------------------------------------------------------------
1277 dnl search for zlib
1278 dnl ----------------------------------------------------------------
1279 dnl
1280 dnl ZLIB_INCLUDE=
1281 dnl ZLIB_LINK=
1282 dnl
1283     if test "$USE_ZLIB" = 1; then
1284 dnl   AC_MSG_CHECKING(for zlib includes)
1285 dnl   AC_PATH_FIND_INCLUDES($SEARCH_INCLUDE,zlib.h)
1286 dnl   if test "$ac_find_includes" != "" ; then
1287 dnl     AC_MSG_RESULT(found $ac_find_includes)
1288 dnl     AC_MSG_CHECKING(for zlib library)
1289 dnl     AC_PATH_FIND_LIBRARIES($SEARCH_LIB,z)
1290 dnl     if test "$ac_find_libraries" != "" ; then
1291 dnl       AC_INCLUDE_PATH_EXIST($ac_find_includes,$CHECK_INCLUDE)
1292 dnl       AC_LINK_PATH_EXIST($ac_find_libraries,$CHECK_LIB)
1293 dnl       CHECK_LINK="$CHECK_INCLUDE $ac_path_to_link"
1294 dnl       CHECK_INCLUDE="$CHECK_INCLUDE $ac_path_to_include"
1295 dnl       ZLIB_INCLUDE="$ac_path_to_include"
1296 dnl       ZLIB_LINK="-lz"
1297 dnl       AC_MSG_RESULT(found zlib at $ac_find_libraries)
1298 dnl     else
1299 dnl       AC_MSG_ERROR(no)
1300 dnl     fi
1301 dnl   else
1302 dnl     AC_MSG_ERROR(no)
1303 dnl   fi
1304       AC_DEFINE_UNQUOTED(USE_ZLIB,$USE_ZLIB)
1305     fi
1306 dnl AC_SUBST(ZLIB_INCLUDE)
1307 dnl AC_SUBST(ZLIB_LIBRARY)
1308 dnl AC_SUBST(ZLIB_LINK)
1309
1310 dnl ----------------------------------------------------------------
1311 dnl search for libpng
1312 dnl ----------------------------------------------------------------
1313 dnl
1314 dnl LIBPNG_INCLUDE=
1315 dnl LIBPNG_LIBRARY=
1316 dnl LIBPNG_LINK=
1317 dnl
1318     if test "$USE_LIBPNG" = 1; then
1319 dnl   AC_MSG_CHECKING(for libpng includes)
1320 dnl   AC_PATH_FIND_INCLUDES($SEARCH_INCLUDE,png.h)
1321 dnl   if test "$ac_find_includes" != "" ; then
1322 dnl     AC_MSG_RESULT(found $ac_find_includes)
1323 dnl     AC_MSG_CHECKING(for libpng library)
1324 dnl     AC_PATH_FIND_LIBRARIES($SEARCH_LIB,png)
1325 dnl     if test "$ac_find_libraries" != "" ; then
1326 dnl       AC_INCLUDE_PATH_EXIST($ac_find_includes,$CHECK_INCLUDE)
1327 dnl       AC_LINK_PATH_EXIST($ac_find_libraries,$CHECK_LIB)
1328 dnl       CHECK_LINK="$CHECK_INCLUDE $ac_path_to_link"
1329 dnl       CHECK_INCLUDE="$CHECK_INCLUDE $ac_path_to_include"
1330 dnl       LIBPNG_LIBRARY="$ac_path_to_link"
1331 dnl       LIBPNG_INCLUDE="$ac_path_to_include"
1332 dnl       LIBPNG_LINK="-lpng"
1333 dnl       AC_MSG_RESULT(found libpng at $ac_find_libraries)
1334 dnl     else
1335 dnl       AC_MSG_RESULT(no)
1336 dnl     fi
1337 dnl   else
1338 dnl     AC_MSG_ERROR(no)
1339 dnl   fi
1340       AC_DEFINE_UNQUOTED(USE_LIBPNG,$USE_LIBPNG)
1341     fi
1342 dnl AC_SUBST(LIBPNG_INCLUDE)
1343 dnl AC_SUBST(LIBPNG_LIBRARY)
1344 dnl AC_SUBST(LIBPNG_LINK)
1345
1346 dnl ----------------------------------------------------------------
1347 dnl search for Python
1348 dnl ----------------------------------------------------------------
1349
1350 dnl ----------------------------------------------------------------
1351 dnl search for ODBC
1352 dnl ----------------------------------------------------------------
1353
1354 dnl ----------------------------------------------------------------
1355 dnl left-over
1356 dnl ----------------------------------------------------------------
1357
1358 USE_GLX=$USE_OPENGL
1359 if test "$USE_OPENGL" != 1; then
1360   OPENGL_LIBRARIES=
1361   OPENGL_INCLUDE=
1362   OPENGL_LINK=
1363   GLCANVAS=NONE
1364 fi
1365
1366 AC_DEFINE_UNQUOTED(USE_GLX,$USE_GLX)
1367 AC_SUBST(OPENGL_INCLUDE)
1368 AC_SUBST(OPENGL_LIBRARY)
1369 AC_SUBST(OPENGL_LINK)
1370 AC_SUBST(GLCANVAS)
1371
1372 dnl ------------------------------------------------------------------------
1373 dnl compiler options for shared libs
1374 dnl ------------------------------------------------------------------------
1375
1376 PICFLAGS=
1377 CREATE_SHARED=
1378 case "${canonical}" in
1379
1380   *-hp-hpux* )
1381     if test "${CC}" != "gcc" ; then
1382       CXXFLAGS="${CXXFLAGS} +a1 -z -Aa -D_HPUX_SOURCE"
1383       CFLAGS="${CFLAGS} -z -D_HPUX_SOURCE"
1384       PICFLAGS="+z"
1385     else
1386       PICFLAGS="-fPIC"
1387     fi
1388     LDFLAGS="-Wl,+s"
1389     CREATE_SHARED=sharedHpux
1390   ;;
1391
1392   *-*-linux* )
1393     PICFLAGS=-fPIC
1394     CREATE_SHARED=sharedLinux
1395   ;;
1396
1397   *-*-irix5* | *-*-irix6* )
1398     # PICFLAGS can remain empty, as pic is the default
1399     LDFLAGS="-Wl,+s"
1400     CREATE_SHARED=sharedIrix
1401     AC_DEFINE(SVR4)
1402   ;;
1403
1404   *-*-solaris2* )
1405     if test "${CC}" != "gcc" ; then
1406       PICFLAGS="-KPIC"
1407     else
1408       PICFLAGS="-fPIC"
1409     fi
1410     CREATE_SHARED=sharedSolaris2
1411     AC_DEFINE(SVR4)
1412   ;;
1413
1414   *-*-sunos4* )
1415     if test "${CC}" != "gcc" ; then
1416       PICFLAGS="-PIC"
1417     else
1418       PICFLAGS="-fPIC"
1419     fi
1420     LDFLAGS="-Wl,+s"
1421     CREATE_SHARED=sharedSunos4
1422     AC_DEFINE(BSD)
1423   ;;
1424
1425   *-*-freebsd* | *-*-netbsd*)
1426     PICFLAGS=-fPIC
1427     CREATE_SHARED=sharedBsd
1428     AC_DEFINE(BSD)
1429   ;;
1430
1431   *-*-osf* )
1432     PICFLAGS="-fPIC"
1433     CREATE_SHARED=sharedOSF
1434   ;;
1435
1436   *-*-dgux5* )
1437     if test "${CC}" != "gcc" ; then
1438       PICFLAGS="-K PIC"
1439     else
1440       PICFLAGS="-fPIC"
1441     fi
1442     CREATE_SHARED=sharedDgux
1443     AC_DEFINE(SVR4)
1444   ;;
1445
1446   *-*-sysv5* )
1447     if test "${CC}" != "gcc" ; then
1448       PICFLAGS="-K PIC"
1449     else
1450       PICFLAGS="-fPIC"
1451     fi
1452     CREATE_SHARED=sharedSysV
1453     AC_DEFINE(SVR4)
1454   ;;
1455
1456   *-*-aix* )
1457     if test "${CC}" != "gcc" ; then
1458       PICFLAGS="-bM\:SRE"
1459     else
1460       PICFLAGS="-fPIC"
1461     fi
1462     CREATE_SHARED=sharedAIX
1463     AC_DEFINE(SYSV)
1464   ;;
1465
1466   *)
1467     CREATE_SHARED=
1468     PICFLAGS=
1469 esac
1470
1471 if test "x$GCC" = xyes; then
1472   CFLAGS="${CFLAGS} -Wall"
1473 fi
1474
1475 if test "x$GXX" = xyes; then
1476   CXXFLAGS="${CXXFLAGS} -Wall"
1477 fi
1478
1479 if test "$USE_SHARED" != 1; then
1480     CREATE_SHARED=
1481     PICFLAGS=
1482 fi
1483
1484 AC_SUBST(OS)
1485 AC_SUBST(PICFLAGS)
1486 AC_SUBST(CREATE_SHARED)
1487
1488 dnl ------------------------------------------------------------------------
1489 dnl finish and clean-up
1490 dnl ------------------------------------------------------------------------
1491
1492 dnl add OS to list of configured
1493 echo $OS >> system.list
1494 echo $OS >> ../../system.list
1495
1496 AC_CONFIG_HEADER(../../include/wx/gtk/setup.h:../../src/gtk/setup/setup.hin)
1497 dnl AC_OUTPUT(../../src/gtk/setup/substit,../../src/gtk/setup/general/createall)
1498 AC_OUTPUT(../../src/gtk/setup/substit,)
1499 AC_OVERRIDES_DONE