src/mac/carbon/fontdlgosx.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        fontdlg.cpp
   3 // Purpose:     wxFontDialog class.
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2004-10-03
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Ryan Norton
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ===========================================================================
  13 // declarations
  14 // ===========================================================================
  15
  16 // ---------------------------------------------------------------------------
  17 // headers
  18 // ---------------------------------------------------------------------------
  19
  20 #include "wx/cmndata.h"
  21 #include "wx/fontdlg.h"
  22 #include "wx/fontutil.h"
  23 #include "wx/log.h"
  24
  25 // ============================================================================
  26 // implementation
  27 // ============================================================================
  28
  29 //Mac OSX 10.2+ only
  30 #if USE_NATIVE_FONT_DIALOG_FOR_MACOSX
  31
  32 #if !USE_SHARED_LIBRARY
  33 IMPLEMENT_DYNAMIC_CLASS(wxFontDialog, wxDialog)
  34 #endif
  35
  36 // Cocoa headers
  37 #include "wx/cocoa/autorelease.h"
  38 #include "wx/cocoa/string.h"
  39
  40 #import <AppKit/NSFont.h>
  41 #import <AppKit/NSFontManager.h>
  42 #import <AppKit/NSFontPanel.h>
  43 #import <AppKit/NSColor.h>
  44 #import <AppKit/NSColorPanel.h>
  45
  46 // ---------------------------------------------------------------------------
  47 // wxWCDelegate - Window Closed delegate
  48 // ---------------------------------------------------------------------------
  49
  50 @interface wxWCDelegate : NSObject
  51 {
  52     bool m_bIsClosed;
  53 }
  54
  55 // Delegate methods
  56 - (id)init;
  57 - (BOOL)windowShouldClose:(id)sender;
  58 - (BOOL)isClosed;
  59 @end // interface wxNSFontPanelDelegate : NSObject
  60
  61 @implementation wxWCDelegate : NSObject
  62
  63 - (id)init
  64 {
  65     [super init];
  66     m_bIsClosed = false;
  67
  68     return self;
  69 }
  70
  71 - (BOOL)windowShouldClose:(id)sender
  72 {
  73     m_bIsClosed = true;
  74
  75     [NSApp abortModal];
  76     [NSApp stopModal];
  77     return YES;
  78 }
  79
  80 - (BOOL)isClosed
  81 {
  82     return m_bIsClosed;
  83 }
  84
  85 @end // wxNSFontPanelDelegate
  86
  87 // ---------------------------------------------------------------------------
  88 // wxWCODelegate - Window Closed or Open delegate
  89 // ---------------------------------------------------------------------------
  90
  91 @interface wxWCODelegate : NSObject
  92 {
  93     bool m_bIsClosed;
  94     bool m_bIsOpen;
  95 }
  96
  97 // Delegate methods
  98 - (id)init;
  99 - (BOOL)windowShouldClose:(id)sender;
 100 - (void)windowDidUpdate:(NSNotification *)aNotification;
 101 - (BOOL)isClosed;
 102 - (BOOL)isOpen;
 103 @end // interface wxNSFontPanelDelegate : NSObject
 104
 105 @implementation wxWCODelegate : NSObject
 106
 107 - (id)init
 108 {
 109     [super init];
 110     m_bIsClosed = false;
 111     m_bIsOpen = false;
 112
 113     return self;
 114 }
 115
 116 - (BOOL)windowShouldClose:(id)sender
 117 {
 118     m_bIsClosed = true;
 119     m_bIsOpen = false;
 120
 121     [NSApp abortModal];
 122     [NSApp stopModal];
 123     return YES;
 124 }
 125
 126 - (void)windowDidUpdate:(NSNotification *)aNotification
 127 {
 128     if (m_bIsOpen == NO)
 129     {
 130         m_bIsClosed = false;
 131         m_bIsOpen = true;
 132
 133         [NSApp abortModal];
 134         [NSApp stopModal];
 135     }
 136 }
 137
 138 - (BOOL)isClosed
 139 {
 140     return m_bIsClosed;
 141 }
 142
 143 - (BOOL)isOpen
 144 {
 145     return m_bIsOpen;
 146 }
 147
 148 @end // wxNSFontPanelDelegate
 149
 150 // ---------------------------------------------------------------------------
 151 // wxFontDialog
 152 // ---------------------------------------------------------------------------
 153
 154 wxFontDialog::wxFontDialog()
 155 {
 156 }
 157
 158 wxFontDialog::wxFontDialog(wxWindow *parent, const wxFontData&  data)
 159 {
 160     Create(parent, data);
 161 }
 162
 163 wxFontDialog::~wxFontDialog()
 164 {
 165 }
 166
 167 bool wxFontDialog::Create(wxWindow *parent, const wxFontData& data)
 168 {
 169     m_fontData = data;
 170
 171     //
 172     //  This is the key call - this initializes
 173     //  events and window stuff for cocoa for carbon
 174     //  applications.
 175     //
 176     //  This is also the only call here that is
 177     //  10.2+ specific (the rest is OSX only),
 178     //  which, ironically, the carbon font
 179     //  panel requires.
 180     //
 181     bool bOK = NSApplicationLoad();
 182
 183     //autorelease pool - req'd for carbon
 184     NSAutoreleasePool *thePool;
 185     thePool = [[NSAutoreleasePool alloc] init];
 186
 187     //Get the initial wx font
 188     wxFont& thewxfont = m_fontData.m_initialFont;
 189
 190     //if the font is valid set the default (selected) font of the
 191     //NSFontDialog to that font
 192     if (thewxfont.Ok())
 193     {
 194         NSFontTraitMask theMask = 0;
 195
 196         if(thewxfont.GetStyle() == wxFONTSTYLE_ITALIC)
 197             theMask |= NSItalicFontMask;
 198
 199         if(thewxfont.IsFixedWidth())
 200             theMask |= NSFixedPitchFontMask;
 201
 202         NSFont* theDefaultFont =
 203             [[NSFontManager sharedFontManager] fontWithFamily:
 204                                                     wxNSStringWithWxString(thewxfont.GetFaceName())
 205                                             traits:theMask
 206                                             weight:thewxfont.GetWeight() == wxBOLD ? 9 :
 207                                                     thewxfont.GetWeight() == wxLIGHT ? 0 : 5
 208                                             size: (float)(thewxfont.GetPointSize())
 209             ];
 210
 211         wxASSERT_MSG(theDefaultFont, wxT("Invalid default font for wxCocoaFontDialog!"));
 212
 213         //set the initial font of the NSFontPanel
 214         //(the font manager calls the appropriate NSFontPanel method)
 215         [[NSFontManager sharedFontManager] setSelectedFont:theDefaultFont isMultiple:NO];
 216
 217     }
 218
 219     if(m_fontData.m_fontColour.Ok())
 220         [[NSColorPanel sharedColorPanel] setColor:
 221             [NSColor colorWithCalibratedRed:m_fontData.m_fontColour.Red() / 255.0
 222                                         green:m_fontData.m_fontColour.Green() / 255.0
 223                                         blue:m_fontData.m_fontColour.Blue() / 255.0
 224                                         alpha:1.0]
 225         ];
 226     else
 227         [[NSColorPanel sharedColorPanel] setColor:[NSColor blackColor]];
 228
 229     //We're done - free up the pool
 230     [thePool release];
 231
 232     return bOK;
 233 }
 234
 235 int wxFontDialog::ShowModal()
 236 {
 237     //Start the pool.  Required for carbon interaction
 238     //(For those curious, the only thing that happens
 239     //if you don't do this is a bunch of error
 240     //messages about leaks on the console,
 241     //with no windows shown or anything).
 242     NSAutoreleasePool *thePool;
 243     thePool = [[NSAutoreleasePool alloc] init];
 244
 245     //Get the shared color and font panel
 246     NSFontPanel* theFontPanel   = [NSFontPanel sharedFontPanel];
 247     NSColorPanel* theColorPanel = [NSColorPanel sharedColorPanel];
 248
 249     //Create and assign the delegates (cocoa event handlers) so
 250     //we can tell if a window has closed/open or not
 251     wxWCDelegate* theFPDelegate = [[wxWCDelegate alloc] init];
 252     [theFontPanel setDelegate:theFPDelegate];
 253
 254     wxWCODelegate* theCPDelegate = [[wxWCODelegate alloc] init];
 255     [theColorPanel setDelegate:theCPDelegate];
 256
 257     //
 258     //  Begin the modal loop for the font and color panels
 259     //
 260     //  The idea is that we first make the font panel modal,
 261     //  but if the color panel is opened, unless we stop the
 262     //  modal loop the color panel opens behind the font panel
 263     //  with no input acceptable to it - which makes it useless.
 264     //
 265     //  So we set up delegates for both the color and font panels,
 266     //  and the if the font panel opens the color panel, we
 267     //  stop the modal loop, and start a seperate modal loop for
 268     //  the color panel until the color panel closes, switching
 269     //  back to the font panel modal loop once it does close.
 270     //
 271     do
 272     {
 273         //
 274         //      Start the font panel modal loop
 275         //
 276         NSModalSession session = [NSApp beginModalSessionForWindow:theFontPanel];
 277         for (;;)
 278         {
 279             [NSApp runModalSession:session];
 280
 281             //If the font panel is closed or the font panel
 282             //opened the color panel, break
 283             if ([theFPDelegate isClosed] || [theCPDelegate isOpen])
 284                 break;
 285         }
 286         [NSApp endModalSession:session];
 287
 288         //is the color panel open?
 289         if ([theCPDelegate isOpen])
 290         {
 291             //
 292             //  Start the color panel modal loop
 293             //
 294             NSModalSession session = [NSApp beginModalSessionForWindow:theColorPanel];
 295             for (;;)
 296             {
 297                 [NSApp runModalSession:session];
 298
 299                 //If the color panel is closed, return the font panel modal loop
 300                 if ([theCPDelegate isClosed])
 301                     break;
 302             }
 303             [NSApp endModalSession:session];
 304         }
 305         //If the font panel is still alive (I.E. we broke
 306         //out of its modal loop because the color panel was
 307         //opened) return the font panel modal loop
 308     }while([theFPDelegate isClosed] == NO);
 309
 310     //free up the memory for the delegates - we don't need them anymore
 311     [theFPDelegate release];
 312     [theCPDelegate release];
 313
 314     //Get the font the user selected
 315     NSFont* theFont = [theFontPanel panelConvertFont:[NSFont userFontOfSize:0]];
 316
 317     //Get more information about the user's chosen font
 318     NSFontTraitMask theTraits = [[NSFontManager sharedFontManager] traitsOfFont:theFont];
 319     int theFontWeight = [[NSFontManager sharedFontManager] weightOfFont:theFont];
 320     int theFontSize = (int) [theFont pointSize];
 321
 322     //Set the wx font to the appropriate data
 323     if(theTraits & NSFixedPitchFontMask)
 324         m_fontData.m_chosenFont.SetFamily(wxTELETYPE);
 325
 326     m_fontData.m_chosenFont.SetFaceName(wxStringWithNSString([theFont familyName]));
 327     m_fontData.m_chosenFont.SetPointSize(theFontSize);
 328     m_fontData.m_chosenFont.SetStyle(theTraits & NSItalicFontMask ? wxFONTSTYLE_ITALIC : 0);
 329     m_fontData.m_chosenFont.SetWeight(theFontWeight < 5 ? wxLIGHT :
 330                                     theFontWeight >= 9 ? wxBOLD : wxNORMAL);
 331
 332     //Get the shared color panel along with the chosen color and set the chosen color
 333     NSColor* theColor = [[theColorPanel color] colorUsingColorSpaceName:NSCalibratedRGBColorSpace];
 334
 335     m_fontData.m_fontColour.Set((unsigned char) ([theColor redComponent] * 255.0),
 336                                 (unsigned char) ([theColor greenComponent] * 255.0),
 337                                 (unsigned char) ([theColor blueComponent] * 255.0));
 338
 339     //Friendly debug stuff
 340 #ifdef FONTDLGDEBUG
 341     wxPrintf(wxT("---Font Panel---\n--NS--\nSize:%f\nWeight:%i\nTraits:%i\n--WX--\nFaceName:%s\nPointSize:%i\nStyle:%i\nWeight:%i\nColor:%i,%i,%i\n---END Font Panel---\n"),
 342
 343                 (float) theFontSize,
 344                 theFontWeight,
 345                 theTraits,
 346
 347                 m_fontData.m_chosenFont.GetFaceName().c_str(),
 348                 m_fontData.m_chosenFont.GetPointSize(),
 349                 m_fontData.m_chosenFont.GetStyle(),
 350                 m_fontData.m_chosenFont.GetWeight(),
 351                     m_fontData.m_fontColour.Red(),
 352                     m_fontData.m_fontColour.Green(),
 353                     m_fontData.m_fontColour.Blue() );
 354 #endif
 355
 356     //Release the pool, we're done :)
 357     [thePool release];
 358
 359     //Return ID_OK - there are no "apply" buttons or the like
 360     //on either the font or color panel
 361     return wxID_OK;
 362 }
 363
 364 //old api stuff (REMOVE ME)
 365 bool wxFontDialog::IsShown() const
 366 {
 367     return false;
 368 }
 369
 370 #endif // 10.2+