src/osx/cocoa/nonownedwnd.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/nonownedwnd.mm
   3 // Purpose:     non owned window for cocoa
   4 // Author:      DavidStefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: nonownedwnd.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/nonownedwnd.h"
  15     #include "wx/frame.h"
  16 #endif
  17
  18 #include "wx/osx/private.h"
  19
  20 NSRect wxToNSRect( NSView* parent, const wxRect& r )
  21 {
  22     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  23     int y = r.y;
  24     int x = r.x ;
  25     if ( parent == NULL || ![ parent isFlipped ] )
  26         y = (int)(frame.size.height - ( r.y + r.height ));
  27     return NSMakeRect(x, y, r.width , r.height);
  28 }
  29
  30 wxRect wxFromNSRect( NSView* parent, const NSRect& rect )
  31 {
  32     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  33     int y = (int)rect.origin.y;
  34     int x = (int)rect.origin.x;
  35     if ( parent == NULL || ![ parent isFlipped ] )
  36         y = (int)(frame.size.height - (rect.origin.y + rect.size.height));
  37     return wxRect( x, y, (int)rect.size.width, (int)rect.size.height );
  38 }
  39
  40 NSPoint wxToNSPoint( NSView* parent, const wxPoint& p )
  41 {
  42     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  43     int x = p.x ;
  44     int y = p.y;
  45     if ( parent == NULL || ![ parent isFlipped ] )
  46         y = (int)(frame.size.height - ( p.y ));
  47     return NSMakePoint(x, y);
  48 }
  49
  50 wxPoint wxFromNSPoint( NSView* parent, const NSPoint& p )
  51 {
  52     NSRect frame = parent ? [parent bounds] : [[NSScreen mainScreen] frame];
  53     int x = (int)p.x;
  54     int y = (int)p.y;
  55     if ( parent == NULL || ![ parent isFlipped ] )
  56         y = (int)(frame.size.height - ( p.y ));
  57     return wxPoint( x, y);
  58 }
  59
  60 bool shouldHandleSelector(SEL selector)
  61 {
  62     if (selector == @selector(noop:)
  63             || selector == @selector(complete:)
  64             || selector == @selector(deleteBackward:)
  65             || selector == @selector(deleteForward:)
  66             || selector == @selector(insertNewline:)
  67             || selector == @selector(insertTab:)
  68             || selector == @selector(keyDown:)
  69             || selector == @selector(keyUp:)
  70             || selector == @selector(scrollPageUp:)
  71             || selector == @selector(scrollPageDown:)
  72             || selector == @selector(scrollToBeginningOfDocument:)
  73             || selector == @selector(scrollToEndOfDocument:))
  74         return false;
  75
  76     return true;
  77
  78 }
  79
  80 //
  81 // wx native implementation classes
  82 //
  83
  84 typedef void (*wxOSX_NoResponderHandlerPtr)(NSView* self, SEL _cmd, SEL selector);
  85
  86 @interface wxNSWindow : NSWindow
  87 {
  88     wxNonOwnedWindowCocoaImpl* impl;
  89 }
  90
  91 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen;
  92 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation;
  93 - (wxNonOwnedWindowCocoaImpl*) implementation;
  94 - (void)noResponderFor: (SEL) selector;
  95 @end
  96
  97 @implementation wxNSWindow
  98
  99 // The default implementation always moves the window back onto the screen,
 100 // even when the programmer explicitly wants to hide it.
 101 - (NSRect)constrainFrameRect:(NSRect)frameRect toScreen:(NSScreen *)screen
 102 {
 103     wxUnusedVar(screen);
 104     return frameRect;
 105 }
 106
 107 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation
 108 {
 109     impl = theImplementation;
 110 }
 111
 112 - (wxNonOwnedWindowCocoaImpl*) implementation
 113 {
 114     return impl;
 115 }
 116
 117 - (void)doCommandBySelector:(SEL)selector
 118 {
 119     if (shouldHandleSelector(selector) &&
 120         !(selector == @selector(cancel:) || selector == @selector(cancelOperation:)) )
 121         [super doCommandBySelector:selector];
 122 }
 123
 124
 125 // NB: if we don't do this, all key downs that get handled lead to a NSBeep
 126 - (void)noResponderFor: (SEL) selector
 127 {
 128     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 129     {
 130         [super noResponderFor:selector];
 131 //        wxOSX_NoResponderHandlerPtr superimpl = (wxOSX_NoResponderHandlerPtr) [[self superclass] instanceMethodForSelector:@selector(noResponderFor:)];
 132 //        superimpl(self, @selector(noResponderFor:), selector);
 133     }
 134 }
 135
 136 // We need this for borderless windows, i.e. shaped windows or windows without
 137 // a title bar. For more info, see:
 138 // http://lists.apple.com/archives/cocoa-dev/2008/May/msg02091.html
 139 - (BOOL)canBecomeKeyWindow
 140 {
 141     return YES;
 142 }
 143
 144 @end
 145
 146 @interface wxNSPanel : NSPanel
 147
 148 {
 149     wxNonOwnedWindowCocoaImpl* impl;
 150 }
 151
 152 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation;
 153 - (wxNonOwnedWindowCocoaImpl*) implementation;
 154 - (void)noResponderFor: (SEL) selector;
 155 @end
 156
 157 @implementation wxNSPanel
 158
 159 - (void)setImplementation: (wxNonOwnedWindowCocoaImpl *) theImplementation
 160 {
 161     impl = theImplementation;
 162 }
 163
 164 - (BOOL)canBecomeKeyWindow
 165 {
 166     return YES;
 167 }
 168
 169 - (wxNonOwnedWindowCocoaImpl*) implementation
 170 {
 171     return impl;
 172 }
 173
 174 - (void)doCommandBySelector:(SEL)selector
 175 {
 176     if (shouldHandleSelector(selector))
 177         [super doCommandBySelector:selector];
 178 }
 179
 180 // NB: if we don't do this, it seems that all events that end here lead to a NSBeep
 181 - (void)noResponderFor: (SEL) selector
 182 {
 183     if (selector != @selector(keyDown:) && selector != @selector(keyUp:))
 184     {
 185         [super noResponderFor:selector];
 186 //        wxOSX_NoResponderHandlerPtr superimpl = (wxOSX_NoResponderHandlerPtr) [[self superclass] instanceMethodForSelector:@selector(noResponderFor:)];
 187 //        superimpl(self, @selector(noResponderFor:), selector);
 188     }
 189 }
 190
 191 @end
 192
 193
 194 //
 195 // controller
 196 //
 197
 198 @interface wxNonOwnedWindowController : NSObject wxOSX_10_6_AND_LATER(<NSWindowDelegate>)
 199 {
 200 }
 201
 202 - (void)windowDidResize:(NSNotification *)notification;
 203 - (NSSize)windowWillResize:(NSWindow *)window toSize:(NSSize)proposedFrameSize;
 204 - (void)windowDidResignKey:(NSNotification *)notification;
 205 - (void)windowDidBecomeKey:(NSNotification *)notification;
 206 - (void)windowDidMove:(NSNotification *)notification;
 207 - (BOOL)windowShouldClose:(id)window;
 208 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame;
 209
 210 @end
 211
 212 @implementation wxNonOwnedWindowController
 213
 214 - (id) init
 215 {
 216     [super init];
 217     return self;
 218 }
 219
 220 - (BOOL)windowShouldClose:(id)nwindow
 221 {
 222     wxNSWindow* window = (wxNSWindow*) nwindow;
 223     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 224     if ( windowimpl )
 225     {
 226         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 227         if ( wxpeer )
 228             wxpeer->Close();
 229     }
 230     return NO;
 231 }
 232
 233 - (NSSize)windowWillResize:(NSWindow *)win
 234                     toSize:(NSSize)proposedFrameSize
 235 {
 236     NSRect frame = [win frame];
 237     wxRect wxframe = wxFromNSRect( NULL, frame );
 238     wxframe.SetWidth( (int)proposedFrameSize.width );
 239     wxframe.SetHeight( (int)proposedFrameSize.height );
 240     wxNSWindow* window = (wxNSWindow*) win;
 241     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 242     if ( windowimpl )
 243     {
 244         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 245         if ( wxpeer )
 246         {
 247             wxpeer->HandleResizing( 0, &wxframe );
 248             NSSize newSize = NSMakeSize(wxframe.GetWidth(), wxframe.GetHeight());
 249             return newSize;
 250         }
 251     }
 252
 253     return proposedFrameSize;
 254 }
 255
 256 - (void)windowDidResize:(NSNotification *)notification
 257 {
 258     wxNSWindow* window = (wxNSWindow*) [notification object];
 259     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 260     if ( windowimpl )
 261     {
 262         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 263         if ( wxpeer )
 264             wxpeer->HandleResized(0);
 265     }
 266 }
 267
 268 - (void)windowDidMove:(NSNotification *)notification
 269 {
 270     wxNSWindow* window = (wxNSWindow*) [notification object];
 271     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 272     if ( windowimpl )
 273     {
 274         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 275         if ( wxpeer )
 276             wxpeer->HandleMoved(0);
 277     }
 278 }
 279
 280 - (void)windowDidBecomeKey:(NSNotification *)notification
 281 {
 282     wxNSWindow* window = (wxNSWindow*) [notification object];
 283     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 284     if ( windowimpl )
 285     {
 286         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 287         if ( wxpeer )
 288             wxpeer->HandleActivated(0, true);
 289     }
 290 }
 291
 292 - (void)windowDidResignKey:(NSNotification *)notification
 293 {
 294     wxNSWindow* window = (wxNSWindow*) [notification object];
 295     wxNonOwnedWindowCocoaImpl* windowimpl = [window implementation];
 296     if ( windowimpl )
 297     {
 298         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 299         if ( wxpeer )
 300         {
 301             wxpeer->HandleActivated(0, false);
 302             // Needed for popup window since the firstResponder
 303             // (focus in wx) doesn't change when this
 304             // TLW becomes inactive.
 305             wxFocusEvent event( wxEVT_KILL_FOCUS, wxpeer->GetId());
 306             event.SetEventObject(wxpeer);
 307             wxpeer->HandleWindowEvent(event);
 308         }
 309     }
 310 }
 311
 312 - (id)windowWillReturnFieldEditor:(NSWindow *)sender toObject:(id)anObject
 313 {
 314     wxUnusedVar(sender);
 315
 316     if ([anObject isKindOfClass:[wxNSTextField class]])
 317     {
 318         wxNSTextField* tf = (wxNSTextField*) anObject;
 319         wxNSTextFieldEditor* editor = [tf fieldEditor];
 320         if ( editor == nil )
 321         {
 322             editor = [[wxNSTextFieldEditor alloc] init];
 323             [editor setFieldEditor:YES];
 324             [tf setFieldEditor:editor];
 325         }
 326         return editor;
 327     }
 328
 329     return nil;
 330 }
 331
 332 - (BOOL)windowShouldZoom:(NSWindow *)window toFrame:(NSRect)newFrame
 333 {
 334     wxNonOwnedWindowCocoaImpl* windowimpl = [(wxNSWindow*)window implementation];
 335     if ( windowimpl )
 336     {
 337         wxNonOwnedWindow* wxpeer = windowimpl->GetWXPeer();
 338         wxMaximizeEvent event(wxpeer->GetId());
 339         event.SetEventObject(wxpeer);
 340         return !wxpeer->HandleWindowEvent(event);
 341     }
 342     return true;
 343 }
 344
 345 @end
 346
 347 IMPLEMENT_DYNAMIC_CLASS( wxNonOwnedWindowCocoaImpl , wxNonOwnedWindowImpl )
 348
 349 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl( wxNonOwnedWindow* nonownedwnd) :
 350     wxNonOwnedWindowImpl(nonownedwnd)
 351 {
 352     m_macWindow = NULL;
 353     m_macFullScreenData = NULL;
 354 }
 355
 356 wxNonOwnedWindowCocoaImpl::wxNonOwnedWindowCocoaImpl()
 357 {
 358     m_macWindow = NULL;
 359     m_macFullScreenData = NULL;
 360 }
 361
 362 wxNonOwnedWindowCocoaImpl::~wxNonOwnedWindowCocoaImpl()
 363 {
 364     if ( !m_wxPeer->IsNativeWindowWrapper() )
 365     {
 366         [m_macWindow setImplementation:nil];
 367         [m_macWindow setDelegate:nil];
 368         [m_macWindow release];
 369     }
 370 }
 371
 372 void wxNonOwnedWindowCocoaImpl::WillBeDestroyed()
 373 {
 374     if ( !m_wxPeer->IsNativeWindowWrapper() )
 375     {
 376         [m_macWindow setDelegate:nil];
 377     }
 378 }
 379
 380 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), const wxPoint& pos, const wxSize& size,
 381 long style, long extraStyle, const wxString& WXUNUSED(name) )
 382 {
 383     static wxNonOwnedWindowController* controller = NULL;
 384
 385     if ( !controller )
 386         controller =[[wxNonOwnedWindowController alloc] init];
 387
 388
 389     int windowstyle = NSBorderlessWindowMask;
 390
 391     if ( style & wxFRAME_TOOL_WINDOW || ( style & wxPOPUP_WINDOW ) ||
 392             GetWXPeer()->GetExtraStyle() & wxTOPLEVEL_EX_DIALOG )
 393     {
 394         m_macWindow = [wxNSPanel alloc];
 395     }
 396     else
 397         m_macWindow = [wxNSWindow alloc];
 398
 399     CGWindowLevel level = kCGNormalWindowLevel;
 400
 401     if ( style & wxFRAME_TOOL_WINDOW )
 402     {
 403         windowstyle |= NSUtilityWindowMask;
 404         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 405             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 406         {
 407             windowstyle |= NSTitledWindowMask ;
 408         }
 409     }
 410     else if ( ( style & wxPOPUP_WINDOW ) )
 411     {
 412         level = kCGPopUpMenuWindowLevel;
 413         /*
 414         if ( ( style & wxBORDER_NONE ) )
 415         {
 416             wclass = kHelpWindowClass ;   // has no border
 417             attr |= kWindowNoShadowAttribute;
 418         }
 419         else
 420         {
 421             wclass = kPlainWindowClass ;  // has a single line border, it will have to do for now
 422         }
 423         */
 424     }
 425     else if ( ( style & wxCAPTION ) )
 426     {
 427         windowstyle |= NSTitledWindowMask ;
 428     }
 429     else if ( ( style & wxFRAME_DRAWER ) )
 430     {
 431         /*
 432         wclass = kDrawerWindowClass;
 433         */
 434     }
 435     else
 436     {
 437         // set these even if we have no title, otherwise the controls won't be visible
 438         if ( ( style & wxMINIMIZE_BOX ) || ( style & wxMAXIMIZE_BOX ) ||
 439             ( style & wxCLOSE_BOX ) || ( style & wxSYSTEM_MENU ) )
 440         {
 441             windowstyle |= NSTitledWindowMask ;
 442         }
 443         /*
 444         else if ( ( style & wxNO_BORDER ) )
 445         {
 446             wclass = kSimpleWindowClass ;
 447         }
 448         else
 449         {
 450             wclass = kPlainWindowClass ;
 451         }
 452         */
 453     }
 454
 455     if ( windowstyle & NSTitledWindowMask )
 456     {
 457         if ( ( style & wxMINIMIZE_BOX ) )
 458             windowstyle |= NSMiniaturizableWindowMask ;
 459
 460         if ( ( style & wxMAXIMIZE_BOX ) )
 461             windowstyle |= NSResizableWindowMask ; // TODO showing ZOOM ?
 462
 463         if ( ( style & wxRESIZE_BORDER ) )
 464             windowstyle |= NSResizableWindowMask ;
 465
 466         if ( ( style & wxCLOSE_BOX) )
 467             windowstyle |= NSClosableWindowMask ;
 468     }
 469     if ( extraStyle & wxFRAME_EX_METAL)
 470         windowstyle |= NSTexturedBackgroundWindowMask;
 471
 472     if ( ( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ) )
 473         level = kCGFloatingWindowLevel;
 474
 475     if ( ( style & wxSTAY_ON_TOP ) )
 476         level = kCGUtilityWindowLevel;
 477
 478     NSRect r = wxToNSRect( NULL, wxRect( pos, size) );
 479
 480     [m_macWindow setImplementation:this];
 481     r = [NSWindow contentRectForFrameRect:r styleMask:windowstyle];
 482
 483     [m_macWindow initWithContentRect:r
 484         styleMask:windowstyle
 485         backing:NSBackingStoreBuffered
 486         defer:NO
 487         ];
 488
 489     [m_macWindow setLevel:level];
 490
 491     [m_macWindow setDelegate:controller];
 492
 493     [m_macWindow setAcceptsMouseMovedEvents: YES];
 494
 495     if ( ( style & wxFRAME_SHAPED) )
 496     {
 497         [m_macWindow setOpaque:NO];
 498         [m_macWindow setAlphaValue:1.0];
 499     }
 500 }
 501
 502 void wxNonOwnedWindowCocoaImpl::Create( wxWindow* WXUNUSED(parent), WXWindow nativeWindow )
 503 {
 504     m_macWindow = nativeWindow;
 505 }
 506
 507 WXWindow wxNonOwnedWindowCocoaImpl::GetWXWindow() const
 508 {
 509     return m_macWindow;
 510 }
 511
 512 void wxNonOwnedWindowCocoaImpl::Raise()
 513 {
 514     [m_macWindow orderWindow:NSWindowAbove relativeTo:0];
 515 }
 516
 517 void wxNonOwnedWindowCocoaImpl::Lower()
 518 {
 519     [m_macWindow orderWindow:NSWindowBelow relativeTo:0];
 520 }
 521
 522 void wxNonOwnedWindowCocoaImpl::ShowWithoutActivating()
 523 {
 524     [m_macWindow orderFront:nil];
 525     [[m_macWindow contentView] setNeedsDisplay: YES];
 526 }
 527
 528 bool wxNonOwnedWindowCocoaImpl::Show(bool show)
 529 {
 530     if ( show )
 531     {
 532         wxNonOwnedWindow* wxpeer = GetWXPeer();
 533         if (wxpeer && !(wxpeer->GetWindowStyle() & wxFRAME_TOOL_WINDOW))
 534             [m_macWindow makeKeyAndOrderFront:nil];
 535         else
 536             [m_macWindow orderFront:nil];
 537         [[m_macWindow contentView] setNeedsDisplay: YES];
 538     }
 539     else
 540         [m_macWindow orderOut:nil];
 541     return true;
 542 }
 543
 544 bool wxNonOwnedWindowCocoaImpl::ShowWithEffect(bool show,
 545                                                wxShowEffect effect,
 546                                                unsigned timeout)
 547 {
 548     return wxWidgetCocoaImpl::
 549             ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
 550 }
 551
 552 void wxNonOwnedWindowCocoaImpl::Update()
 553 {
 554     [m_macWindow displayIfNeeded];
 555 }
 556
 557 bool wxNonOwnedWindowCocoaImpl::SetTransparent(wxByte alpha)
 558 {
 559     [m_macWindow setAlphaValue:(CGFloat) alpha/255.0];
 560     return true;
 561 }
 562
 563 bool wxNonOwnedWindowCocoaImpl::SetBackgroundColour(const wxColour& WXUNUSED(col) )
 564 {
 565     return true;
 566 }
 567
 568 void wxNonOwnedWindowCocoaImpl::SetExtraStyle( long exStyle )
 569 {
 570     if ( m_macWindow )
 571     {
 572         bool metal = exStyle & wxFRAME_EX_METAL ;
 573         int windowStyle = [ m_macWindow styleMask];
 574         if ( metal && !(windowStyle & NSTexturedBackgroundWindowMask) )
 575         {
 576             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 577         }
 578         else if ( !metal && (windowStyle & NSTexturedBackgroundWindowMask ) )
 579         {
 580             wxFAIL_MSG( wxT("Metal Style cannot be changed after creation") );
 581         }
 582     }
 583 }
 584
 585 void wxNonOwnedWindowCocoaImpl::SetWindowStyleFlag( long style )
 586 {
 587     if (m_macWindow)
 588     {
 589         CGWindowLevel level = kCGNormalWindowLevel;
 590
 591         if (style & wxSTAY_ON_TOP)
 592             level = kCGUtilityWindowLevel;
 593         else if (( style & wxFRAME_FLOAT_ON_PARENT ) || ( style & wxFRAME_TOOL_WINDOW ))
 594             level = kCGFloatingWindowLevel;
 595
 596         [m_macWindow setLevel: level];
 597     }
 598 }
 599
 600 bool wxNonOwnedWindowCocoaImpl::SetBackgroundStyle(wxBackgroundStyle style)
 601 {
 602     if ( style == wxBG_STYLE_TRANSPARENT )
 603     {
 604         [m_macWindow setOpaque:NO];
 605         [m_macWindow setBackgroundColor:[NSColor clearColor]];
 606     }
 607
 608     return true;
 609 }
 610
 611 bool wxNonOwnedWindowCocoaImpl::CanSetTransparent()
 612 {
 613     return true;
 614 }
 615
 616 void wxNonOwnedWindowCocoaImpl::MoveWindow(int x, int y, int width, int height)
 617 {
 618     NSRect r = wxToNSRect( NULL, wxRect(x,y,width, height) );
 619     // do not trigger refreshes upon invisible and possible partly created objects
 620     [m_macWindow setFrame:r display:GetWXPeer()->IsShownOnScreen()];
 621 }
 622
 623 void wxNonOwnedWindowCocoaImpl::GetPosition( int &x, int &y ) const
 624 {
 625     wxRect r = wxFromNSRect( NULL, [m_macWindow frame] );
 626     x = r.GetLeft();
 627     y = r.GetTop();
 628 }
 629
 630 void wxNonOwnedWindowCocoaImpl::GetSize( int &width, int &height ) const
 631 {
 632     NSRect rect = [m_macWindow frame];
 633     width = (int)rect.size.width;
 634     height = (int)rect.size.height;
 635 }
 636
 637 void wxNonOwnedWindowCocoaImpl::GetContentArea( int& left, int &top, int &width, int &height ) const
 638 {
 639     NSRect outer = NSMakeRect(100,100,100,100);
 640     NSRect content = [NSWindow contentRectForFrameRect:outer styleMask:[m_macWindow styleMask] ];
 641     NSRect rect = [[m_macWindow contentView] frame];
 642     left = (int)rect.origin.x;
 643     top = (int)rect.origin.y;
 644     width = (int)rect.size.width;
 645     height = (int)rect.size.height;
 646 }
 647
 648 bool wxNonOwnedWindowCocoaImpl::SetShape(const wxRegion& WXUNUSED(region))
 649 {
 650     [m_macWindow setOpaque:NO];
 651     [m_macWindow setBackgroundColor:[NSColor clearColor]];
 652
 653     return true;
 654 }
 655
 656 void wxNonOwnedWindowCocoaImpl::SetTitle( const wxString& title, wxFontEncoding encoding )
 657 {
 658     [m_macWindow setTitle:wxCFStringRef( title , encoding ).AsNSString()];
 659 }
 660
 661 bool wxNonOwnedWindowCocoaImpl::IsMaximized() const
 662 {
 663     if (([m_macWindow styleMask] & NSResizableWindowMask) != 0)
 664     {
 665         return [m_macWindow isZoomed];
 666     }
 667     else
 668     {
 669         NSRect rectScreen = [[NSScreen mainScreen] visibleFrame];
 670         NSRect rectWindow = [m_macWindow frame];
 671         return (rectScreen.origin.x == rectWindow.origin.x &&
 672                 rectScreen.origin.y == rectWindow.origin.y &&
 673                 rectScreen.size.width == rectWindow.size.width &&
 674                 rectScreen.size.height == rectWindow.size.height);
 675     }
 676 }
 677
 678 bool wxNonOwnedWindowCocoaImpl::IsIconized() const
 679 {
 680     return [m_macWindow isMiniaturized];
 681 }
 682
 683 void wxNonOwnedWindowCocoaImpl::Iconize( bool iconize )
 684 {
 685     if ( iconize )
 686         [m_macWindow miniaturize:nil];
 687     else
 688         [m_macWindow deminiaturize:nil];
 689 }
 690
 691 void wxNonOwnedWindowCocoaImpl::Maximize(bool WXUNUSED(maximize))
 692 {
 693     [m_macWindow zoom:nil];
 694 }
 695
 696
 697 // http://cocoadevcentral.com/articles/000028.php
 698
 699 typedef struct
 700 {
 701     int m_formerLevel;
 702     NSRect m_formerFrame;
 703 } FullScreenData ;
 704
 705 bool wxNonOwnedWindowCocoaImpl::IsFullScreen() const
 706 {
 707     return m_macFullScreenData != NULL ;
 708 }
 709
 710 bool wxNonOwnedWindowCocoaImpl::ShowFullScreen(bool show, long WXUNUSED(style))
 711 {
 712     if ( show )
 713     {
 714         FullScreenData *data = (FullScreenData *)m_macFullScreenData ;
 715         delete data ;
 716         data = new FullScreenData();
 717
 718         m_macFullScreenData = data ;
 719         data->m_formerLevel = [m_macWindow level];
 720         data->m_formerFrame = [m_macWindow frame];
 721         CGDisplayCapture( kCGDirectMainDisplay );
 722         [m_macWindow setLevel:CGShieldingWindowLevel()];
 723         [m_macWindow setFrame:[[NSScreen mainScreen] frame] display:YES];
 724     }
 725     else if ( m_macFullScreenData != NULL )
 726     {
 727         FullScreenData *data = (FullScreenData *) m_macFullScreenData ;
 728         CGDisplayRelease( kCGDirectMainDisplay );
 729         [m_macWindow setLevel:data->m_formerLevel];
 730         [m_macWindow setFrame:data->m_formerFrame display:YES];
 731         delete data ;
 732         m_macFullScreenData = NULL ;
 733     }
 734
 735     return true;
 736 }
 737
 738 void wxNonOwnedWindowCocoaImpl::RequestUserAttention(int flagsWX)
 739 {
 740     NSRequestUserAttentionType flagsOSX;
 741     switch ( flagsWX )
 742     {
 743         case wxUSER_ATTENTION_INFO:
 744             flagsOSX = NSInformationalRequest;
 745             break;
 746
 747         case wxUSER_ATTENTION_ERROR:
 748             flagsOSX = NSCriticalRequest;
 749             break;
 750
 751         default:
 752             wxFAIL_MSG( "invalid RequestUserAttention() flags" );
 753             return;
 754     }
 755
 756     [NSApp requestUserAttention:flagsOSX];
 757 }
 758
 759 void wxNonOwnedWindowCocoaImpl::ScreenToWindow( int *x, int *y )
 760 {
 761     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 762     NSPoint nspt = wxToNSPoint( NULL, p );
 763     nspt = [m_macWindow convertScreenToBase:nspt];
 764     nspt = [[m_macWindow contentView] convertPoint:nspt fromView:nil];
 765     p = wxFromNSPoint([m_macWindow contentView], nspt);
 766     if ( x )
 767         *x = p.x;
 768     if ( y )
 769         *y = p.y;
 770 }
 771
 772 void wxNonOwnedWindowCocoaImpl::WindowToScreen( int *x, int *y )
 773 {
 774     wxPoint p((x ? *x : 0), (y ? *y : 0) );
 775     NSPoint nspt = wxToNSPoint( [m_macWindow contentView], p );
 776     nspt = [[m_macWindow contentView] convertPoint:nspt toView:nil];
 777     nspt = [m_macWindow convertBaseToScreen:nspt];
 778     p = wxFromNSPoint( NULL, nspt);
 779     if ( x )
 780         *x = p.x;
 781     if ( y )
 782         *y = p.y;
 783 }
 784
 785 bool wxNonOwnedWindowCocoaImpl::IsActive()
 786 {
 787     return [m_macWindow isKeyWindow];
 788 }
 789
 790 void wxNonOwnedWindowCocoaImpl::SetModified(bool modified)
 791 {
 792     [m_macWindow setDocumentEdited:modified];
 793 }
 794
 795 bool wxNonOwnedWindowCocoaImpl::IsModified() const
 796 {
 797     return [m_macWindow isDocumentEdited];
 798 }
 799
 800 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, WXWindow nativeWindow)
 801 {
 802     wxNonOwnedWindowCocoaImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
 803     now->Create( parent, nativeWindow );
 804     return now;
 805 }
 806
 807 wxNonOwnedWindowImpl* wxNonOwnedWindowImpl::CreateNonOwnedWindow( wxNonOwnedWindow* wxpeer, wxWindow* parent, const wxPoint& pos, const wxSize& size,
 808     long style, long extraStyle, const wxString& name )
 809 {
 810     wxNonOwnedWindowImpl* now = new wxNonOwnedWindowCocoaImpl( wxpeer );
 811     now->Create( parent, pos, size, style , extraStyle, name );
 812     return now;
 813 }