build/tools/wxwidgets.iss

   1 ; Script generated by the Inno Setup Script Wizard.
   2 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
   3
   4 #if GetEnv("INNO") != ""
   5     #define WXW_DIR GetEnv("INNO")
   6 #else
   7     #define WXW_DIR "..\.."
   8 #endif
   9
  10 #if GetEnv("WXW_VER") == "SVN"
  11     #define INFOFILE  WXW_DIR + "\BuildSVN.txt"
  12     #define WX_VERSION "SVN"
  13 #elif GetEnv("WXW_VER") != ""
  14     #define INFOFILE WXW_DIR + "\docs\msw\install.txt"
  15     #define WX_VERSION GetEnv("WXW_VER")
  16 #else
  17     #error "WXW_VER environment variable must be defined."
  18 #endif
  19
  20 #define SETUPFILENAME  "wxMSW-" + GetEnv("WXW_VER") + "-Setup"
  21
  22
  23
  24 [Setup]
  25 AppName=wxWidgets
  26 AppVerName=wxWidgets {#WX_VERSION}
  27 AppPublisher=wxWidgets
  28 AppPublisherURL=http://www.wxwidgets.org
  29 AppSupportURL=http://www.wxwidgets.org
  30 AppUpdatesURL=http://www.wxwidgets.org
  31 DefaultDirName={sd}\wxWidgets-{#WX_VERSION}
  32 DefaultGroupName=wxWidgets {#WX_VERSION}
  33 UsePreviousAppDir=no
  34 DisableProgramGroupPage=yes
  35 LicenseFile={#WXW_DIR}\docs\licence.txt
  36 InfoBeforeFile={#WXW_DIR}\docs\readme.txt
  37 InfoAfterFile={#INFOFILE}
  38 OutputDir={#WXW_DIR}\..
  39 OutputBaseFilename={#SETUPFILENAME}
  40 PrivilegesRequired=none
  41 SetupIconFile={#WXW_DIR}\art\wxwin.ico
  42 Compression=lzma
  43 SolidCompression=yes
  44
  45 [Files]
  46 ; source files
  47 Source: "{#WXW_DIR}\*"; DestDir: "{app}"; Excludes: "cocoa,dfb,gtk,gtk1,motif,msdos,os2,osx,wxWindows.xcod*,x11,debian,distrib"; Flags: ignoreversion recursesubdirs createallsubdirs
  48
  49 [INI]
  50 Filename: "{app}\wx.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.wxwidgets.org"
  51
  52 [Icons]
  53 Name: "{group}\{cm:ProgramOnTheWeb,wxWidgets}"; Filename: "{app}\wx.url"
  54 Name: {group}\wxWidgets Manual; Filename: {app}\docs\htmlhelp\wx.chm; WorkingDir: {app}; IconIndex: 0; Flags: useapppaths
  55 Name: {group}\Changes; Filename: {app}\docs\changes.txt; WorkingDir: {app}; IconIndex: 0; Flags: useapppaths
  56 Name: {group}\Readme; Filename: {app}\docs\readme.txt; WorkingDir: {app}; IconIndex: 0; Flags: useapppaths
  57 Name: {group}\Compiling wxWidgets; Filename: {app}\docs\msw\install.txt; WorkingDir: {app}; IconIndex: 0; Flags: useapppaths
  58 Name: "{group}\Uninstall wxWidgets {#WX_VERSION}"; Filename: "{uninstallexe}"
  59
  60
  61 [UninstallDelete]
  62 Type: files; Name: "{app}\wx.url"