src/cocoa/radiobut.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        cocoa/radiobut.mm
   3 // Purpose:     wxRadioButton
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2003/03/16
   7 // RCS-ID:      $Id:
   8 // Copyright:   (c) 2003 David Elliott
   9 // Licence:     wxWidgets licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_RADIOBTN
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/log.h"
  18     #include "wx/app.h"
  19     #include "wx/radiobut.h"
  20 #endif //WX_PRECOMP
  21
  22 #import <AppKit/NSButton.h>
  23 #include "wx/cocoa/string.h"
  24 #include "wx/cocoa/autorelease.h"
  25
  26 #include "wx/listimpl.cpp"
  27
  28 WX_DEFINE_LIST(wxRadioButtonList);
  29
  30 IMPLEMENT_DYNAMIC_CLASS(wxRadioButton, wxControl)
  31 // wxRadioButtonBase == wxControl
  32 BEGIN_EVENT_TABLE(wxRadioButton, wxControl)
  33 END_EVENT_TABLE()
  34 WX_IMPLEMENT_COCOA_OWNER(wxRadioButton,NSButton,NSControl,NSView)
  35
  36 bool wxRadioButton::Create(wxWindow *parent, wxWindowID winid,
  37            const wxString& label,
  38            const wxPoint& pos,
  39            const wxSize& size,
  40            long style,
  41            const wxValidator& validator,
  42            const wxString& name)
  43 {
  44     wxAutoNSAutoreleasePool pool;
  45     m_radioMaster = NULL;
  46     if(!CreateControl(parent,winid,pos,size,style,validator,name))
  47         return false;
  48     if(style&wxRB_GROUP)
  49     {
  50         m_radioMaster = this;
  51         m_radioSlaves.Append(this);
  52     }
  53     else if(style&wxRB_SINGLE)
  54         m_radioMaster = NULL;
  55     else
  56     {
  57         for(wxWindowList::compatibility_iterator siblingNode= GetParent()->GetChildren().GetLast();
  58             siblingNode;
  59             siblingNode = siblingNode->GetPrevious())
  60         {
  61             wxRadioButton *radioButton  = wxDynamicCast(siblingNode->GetData(),wxRadioButton);
  62             if(radioButton && radioButton!=this)
  63             {
  64                 m_radioMaster = radioButton->m_radioMaster;
  65                 wxASSERT_MSG(m_radioMaster,
  66                     wxT("Previous radio button should be part of a group"));
  67                 // Don't crash, assume user meant wxRB_SINGLE
  68                 if(m_radioMaster)
  69                     m_radioMaster->m_radioSlaves.Append(this);
  70                 break;
  71             }
  72         }
  73     }
  74
  75     m_cocoaNSView = NULL;
  76     SetNSButton([[NSButton alloc] initWithFrame: MakeDefaultNSRect(size)]);
  77     [m_cocoaNSView release];
  78     [GetNSButton() setButtonType: NSRadioButton];
  79     [GetNSButton() setTitle:wxNSStringWithWxString(label)];
  80     // If it's the first in a group, it should be selected
  81     if(style&wxRB_GROUP)
  82         [GetNSButton() setState: NSOnState];
  83     [GetNSControl() sizeToFit];
  84
  85     if(m_parent)
  86         m_parent->CocoaAddChild(this);
  87     SetInitialFrameRect(pos,size);
  88
  89     return true;
  90 }
  91
  92 wxRadioButton::~wxRadioButton()
  93 {
  94     if(m_radioMaster==this)
  95     {
  96         // First get rid of ourselves (we should ALWAYS be at the head)
  97         wxRadioButtonList::compatibility_iterator slaveNode =
  98             m_radioSlaves.GetFirst();
  99         wxASSERT(slaveNode);
 100         wxASSERT(slaveNode->GetData() == this);
 101         m_radioSlaves.Erase(slaveNode);
 102
 103         // Now find the new master
 104         wxRadioButton *newMaster = NULL;
 105         slaveNode = m_radioSlaves.GetFirst();
 106         if(slaveNode)
 107             newMaster = slaveNode->GetData();
 108
 109         // For each node (including the new master) set the master, remove
 110         // it from this list, and add it to the new master's list
 111         for(; slaveNode; slaveNode = m_radioSlaves.GetFirst())
 112         {
 113             wxRadioButton *radioButton = slaveNode->GetData();
 114             wxASSERT(radioButton->m_radioMaster == this);
 115             radioButton->m_radioMaster = newMaster;
 116             newMaster->m_radioSlaves.Append(radioButton);
 117             m_radioSlaves.Erase(slaveNode);
 118         }
 119     }
 120     else if(m_radioMaster)
 121     {
 122         m_radioMaster->m_radioSlaves.DeleteObject(this);
 123         m_radioMaster = NULL;
 124     }
 125     // normal stuff
 126     DisassociateNSButton(GetNSButton());
 127 }
 128
 129 void wxRadioButton::SetValue(bool value)
 130 {
 131     if(value)
 132         [GetNSButton() setState: NSOnState];
 133     else
 134         [GetNSButton() setState: NSOffState];
 135 }
 136
 137 bool wxRadioButton::GetValue() const
 138 {
 139     int state = [GetNSButton() state];
 140     wxASSERT(state!=NSMixedState);
 141     return state==NSOnState;
 142 }
 143
 144 void wxRadioButton::Cocoa_wxNSButtonAction(void)
 145 {
 146     wxLogTrace(wxTRACE_COCOA,wxT("wxRadioButton"));
 147     if(m_radioMaster && ([GetNSButton() state] == NSOnState))
 148     {
 149         for(wxRadioButtonList::compatibility_iterator slaveNode =
 150                 m_radioMaster->m_radioSlaves.GetFirst();
 151             slaveNode; slaveNode = slaveNode->GetNext())
 152         {
 153             wxRadioButton *radioButton = slaveNode->GetData();
 154             if(radioButton!=this)
 155                 radioButton->SetValue(false);
 156         }
 157     }
 158     wxCommandEvent event(wxEVT_COMMAND_RADIOBUTTON_SELECTED, GetId());
 159     InitCommandEvent(event); //    event.SetEventObject(this);
 160     event.SetInt(GetValue());
 161     Command(event);
 162 }
 163
 164 #endif