configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Id$)dnl
   3
   4 AC_PREREQ(2.58)
   5
   6 dnl ---------------------------------------------------------------------------
   7 dnl
   8 dnl Top-level configure.in for wxWidgets by Robert Roebling, Phil Blecker,
   9 dnl Vadim Zeitlin and Ron Lee
  10 dnl
  11 dnl This script is under the wxWidgets licence.
  12 dnl
  13 dnl Version: $Id$
  14 dnl ---------------------------------------------------------------------------
  15
  16 dnl ---------------------------------------------------------------------------
  17 dnl initialization
  18 dnl ---------------------------------------------------------------------------
  19
  20 AC_INIT([wxWidgets], [2.9.0], [wx-dev@lists.wxwidgets.org])
  21
  22 dnl the file passed to AC_CONFIG_SRCDIR should be specific to our package
  23 AC_CONFIG_SRCDIR([wx-config.in])
  24
  25 dnl sets build, host, target variables and the same with _alias
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28 AC_CANONICAL_TARGET
  29
  30
  31 dnl When making releases do:
  32 dnl
  33 dnl wx_release_number += 1
  34
  35 wx_major_version_number=2
  36 wx_minor_version_number=9
  37 wx_release_number=0
  38 wx_subrelease_number=0
  39
  40 WX_RELEASE=$wx_major_version_number.$wx_minor_version_number
  41 WX_VERSION=$WX_RELEASE.$wx_release_number
  42 WX_SUBVERSION=$WX_VERSION.$wx_subrelease_number
  43
  44 WX_MSW_VERSION=$wx_major_version_number$wx_minor_version_number$wx_release_number
  45
  46
  47 dnl Autoconf-2.60 changed the meaning of top_builddir variable, so we have
  48 dnl to use our own replacement that will work with both 2.5x and 2.60+:
  49 wx_top_builddir="`pwd`"
  50 AC_SUBST(wx_top_builddir)
  51
  52
  53 dnl ------------------------------------------------------------------------
  54 dnl Check platform (host system)
  55 dnl ------------------------------------------------------------------------
  56
  57 dnl OS (assume Unix)
  58 USE_UNIX=1
  59 USE_OS2=0
  60 USE_WIN32=0
  61 USE_DOS=0
  62 USE_BEOS=0
  63 USE_MAC=0
  64
  65 dnl Unix kind
  66 USE_AIX=
  67 USE_BSD=                            dnl any BSD
  68 USE_DARWIN=                         dnl a.k.a. Mac OS X
  69 USE_FREEBSD=
  70 USE_GNU=                            dnl GNU/Hurd
  71 USE_HPUX=
  72 USE_LINUX=
  73 USE_NETBSD=
  74 USE_OPENBSD=
  75 USE_OSF=                            dnl OSF/1 (obsolete?)
  76 USE_SGI=
  77 USE_SOLARIS=                        dnl Solaris ("SunOS" >= 5)
  78 USE_SUN=                            dnl SunOS or Solaris
  79 USE_SUNOS=                          dnl old/real SunOS (obsolete)
  80 USE_SVR4=                           dnl SysV R4
  81 USE_SYSV=                           dnl any System V
  82 USE_VMS=
  83 USE_ULTRIX=
  84 USE_UNIXWARE=
  85
  86 dnl hardware platform
  87 USE_ALPHA=
  88
  89 dnl on some platforms xxx_r() functions are declared inside "#ifdef
  90 dnl _REENTRANT" and it's easier to just define this symbol for these platforms
  91 dnl than checking it during run-time
  92 NEEDS_D_REENTRANT_FOR_R_FUNCS=0
  93
  94 dnl the list of all available toolkits
  95 dnl
  96 dnl update NUM_TOOLKITS calculation below when adding a new toolkit here!
  97 ALL_TOOLKITS="COCOA GTK OSX_CARBON OSX_COCOA MGL MICROWIN MOTIF MSW PM X11 DFB"
  98
  99 dnl NB: these wxUSE_XXX constants have value of 0 or 1 unlike all the other ones
 100 dnl     which are either yes or no
 101 DEFAULT_wxUSE_COCOA=0
 102 DEFAULT_wxUSE_GTK=0
 103 DEFAULT_wxUSE_OSX_CARBON=0
 104 DEFAULT_wxUSE_OSX_COCOA=0
 105 DEFAULT_wxUSE_MGL=0
 106 DEFAULT_wxUSE_MICROWIN=0
 107 DEFAULT_wxUSE_MOTIF=0
 108 DEFAULT_wxUSE_MSW=0
 109 DEFAULT_wxUSE_PM=0
 110 DEFAULT_wxUSE_X11=0
 111 DEFAULT_wxUSE_DFB=0
 112
 113 dnl these are the values which are really default for the given platform:
 114 dnl they're used if no --with-<toolkit> options were given to detect the
 115 dnl toolkit to use by default for the target platform
 116 DEFAULT_DEFAULT_wxUSE_COCOA=0
 117 DEFAULT_DEFAULT_wxUSE_GTK=0
 118 DEFAULT_DEFAULT_wxUSE_OSX_CARBON=0
 119 DEFAULT_DEFAULT_wxUSE_OSX_COCOA=0
 120 DEFAULT_DEFAULT_wxUSE_MGL=0
 121 DEFAULT_DEFAULT_wxUSE_MICROWIN=0
 122 DEFAULT_DEFAULT_wxUSE_MOTIF=0
 123 DEFAULT_DEFAULT_wxUSE_MSW=0
 124 DEFAULT_DEFAULT_wxUSE_PM=0
 125 DEFAULT_DEFAULT_wxUSE_X11=0
 126 DEFAULT_DEFAULT_wxUSE_DFB=0
 127
 128 PROGRAM_EXT=
 129 SO_SUFFIX=so
 130 SAMPLES_RPATH_FLAG=
 131 SAMPLES_RPATH_POSTLINK=
 132
 133 DEFAULT_STD_FLAG=yes
 134
 135 dnl to support a new system, you need to add its canonical name (as determined
 136 dnl by config.sub or specified by the configure command line) to this "case"
 137 dnl and also define the shared library flags below - search for
 138 dnl SHARED_LIB_SETUP to find the exact place
 139 case "${host}" in
 140   *-hp-hpux* )
 141     USE_HPUX=1
 142     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 143     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 144     SO_SUFFIX=sl
 145     AC_DEFINE(__HPUX__)
 146
 147     dnl many standard declarations in HP-UX headers are only included if either
 148     dnl _HPUX_SOURCE is defined, see stdsyms(5)
 149     CPPFLAGS="-D_HPUX_SOURCE $CPPFLAGS"
 150   ;;
 151   *-*-linux* )
 152     USE_LINUX=1
 153     AC_DEFINE(__LINUX__)
 154     TMP=`uname -m`
 155     if test "x$TMP" = "xalpha"; then
 156       USE_ALPHA=1
 157       AC_DEFINE(__ALPHA__)
 158     fi
 159     DEFAULT_DEFAULT_wxUSE_GTK=1
 160   ;;
 161   *-*-gnu* | *-*-k*bsd*-gnu )
 162     USE_GNU=1
 163     TMP=`uname -m`
 164     if test "x$TMP" = "xalpha"; then
 165       USE_ALPHA=1
 166       AC_DEFINE(__ALPHA__)
 167     fi
 168     DEFAULT_DEFAULT_wxUSE_GTK=1
 169   ;;
 170   *-*-irix5* | *-*-irix6* )
 171     USE_SGI=1
 172     USE_SVR4=1
 173     AC_DEFINE(__SGI__)
 174     AC_DEFINE(__SVR4__)
 175     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 176   ;;
 177   *-*-solaris2* )
 178     USE_SUN=1
 179     USE_SOLARIS=1
 180     USE_SVR4=1
 181     AC_DEFINE(__SUN__)
 182     AC_DEFINE(__SOLARIS__)
 183     AC_DEFINE(__SVR4__)
 184     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 185     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 186   ;;
 187   *-*-sunos4* )
 188     USE_SUN=1
 189     USE_SUNOS=1
 190     USE_BSD=1
 191     AC_DEFINE(__SUN__)
 192     AC_DEFINE(__SUNOS__)
 193     AC_DEFINE(__BSD__)
 194     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 195   ;;
 196   *-*-freebsd*)
 197     USE_BSD=1
 198     USE_FREEBSD=1
 199     AC_DEFINE(__FREEBSD__)
 200     AC_DEFINE(__BSD__)
 201     DEFAULT_DEFAULT_wxUSE_GTK=1
 202   ;;
 203   *-*-openbsd*|*-*-mirbsd*)
 204     USE_BSD=1
 205     USE_OPENBSD=1
 206     AC_DEFINE(__OPENBSD__)
 207     AC_DEFINE(__BSD__)
 208     DEFAULT_DEFAULT_wxUSE_GTK=1
 209   ;;
 210   *-*-netbsd*)
 211     USE_BSD=1
 212     USE_NETBSD=1
 213     AC_DEFINE(__NETBSD__)
 214     AC_DEFINE(__BSD__)
 215     DEFAULT_DEFAULT_wxUSE_GTK=1
 216     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 217
 218     dnl some standard declarations in NetBSD headers are only included if
 219     dnl _NETBSD_SOURCE and _LIBC are defined, e.g. getservbyname_r in netdb.h
 220     CPPFLAGS="-D_NETBSD_SOURCE -D_LIBC $CPPFLAGS"
 221   ;;
 222   *-*-osf* )
 223     USE_ALPHA=1
 224     USE_OSF=1
 225     AC_DEFINE(__ALPHA__)
 226     AC_DEFINE(__OSF__)
 227     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 228     NEEDS_D_REENTRANT_FOR_R_FUNCS=1
 229   ;;
 230   *-*-dgux5* )
 231     USE_ALPHA=1
 232     USE_SVR4=1
 233     AC_DEFINE(__ALPHA__)
 234     AC_DEFINE(__SVR4__)
 235     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 236   ;;
 237   *-*-sysv5* )
 238     USE_SYSV=1
 239     USE_SVR4=1
 240     AC_DEFINE(__SYSV__)
 241     AC_DEFINE(__SVR4__)
 242     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 243   ;;
 244   *-*-aix* )
 245     USE_AIX=1
 246     USE_SYSV=1
 247     USE_SVR4=1
 248     dnl quoting from http://www-1.ibm.com/servers/esdd/articles/gnu.html:
 249     dnl
 250     dnl     Both archive libraries and shared libraries on AIX have an .a
 251     dnl     extension. This will explain why you can't link with an .so and
 252     dnl     why it works with the name changed to .a.
 253     SO_SUFFIX=a
 254     AC_DEFINE(__AIX__)
 255     AC_DEFINE(__SYSV__)
 256     AC_DEFINE(__SVR4__)
 257     DEFAULT_DEFAULT_wxUSE_MOTIF=1
 258   ;;
 259
 260   *-*-*UnixWare*)
 261     USE_SYSV=1
 262     USE_SVR4=1
 263     USE_UNIXWARE=1
 264     AC_DEFINE(__UNIXWARE__)
 265   ;;
 266
 267   *-*-cygwin* | *-*-mingw32* )
 268     dnl MBN: some of the defines have been moved after toolkit detection
 269     dnl      because for wxMotif/wxGTK/wxX11 to build on Cygwin
 270     dnl      USE_UNIX  must be set and not USE_WIN32
 271     SO_SUFFIX=dll
 272     PROGRAM_EXT=".exe"
 273     DEFAULT_DEFAULT_wxUSE_MSW=1
 274   ;;
 275
 276   *-pc-msdosdjgpp )
 277     USE_UNIX=0
 278     USE_DOS=1
 279     AC_DEFINE(__DOS__)
 280     PROGRAM_EXT=".exe"
 281     DEFAULT_DEFAULT_wxUSE_MGL=1
 282   ;;
 283
 284   *-pc-os2_emx | *-pc-os2-emx )
 285     AC_DEFINE(__EMX__)
 286     USE_OS2=1
 287     AC_DEFINE(__OS2__)
 288     PROGRAM_EXT=".exe"
 289     DEFAULT_DEFAULT_wxUSE_PM=1
 290     dnl "c++" wrapper is not always available, so always use plain gcc.
 291     CXX=gcc
 292     LDFLAGS="$LDFLAGS -Zcrtdll"
 293     dnl
 294     dnl Some special code that's automatically added by autoconf-2.57 for OS/2
 295     dnl and hopefully also by autoconf-2.58 and newer on all other platforms.
 296     dnl For now however, we still need it to make sure the configure script
 297     dnl works on OS/2 no matter what platform it is generated on.
 298     ac_executable_extensions=".exe"
 299     export ac_executable_extensions
 300     dnl This strange code is necessary to deal with handling of
 301     dnl backslashes by ksh and pdksh's sh variant.
 302     ac_save_IFS="$IFS"
 303     IFS='\\'
 304     ac_TEMP_PATH=
 305     for ac_dir in $PATH; do
 306       IFS=$ac_save_IFS
 307       if test -z "$ac_TEMP_PATH"; then
 308         ac_TEMP_PATH="$ac_dir"
 309       else
 310         ac_TEMP_PATH="$ac_TEMP_PATH/$ac_dir"
 311       fi
 312     done
 313     export PATH="$ac_TEMP_PATH"
 314     unset ac_TEMP_PATH
 315     DEFAULT_STD_FLAG=no
 316   ;;
 317
 318   *-*-darwin* )
 319     dnl Darwin based distributions (including Mac OS X)
 320     USE_BSD=1
 321     USE_DARWIN=1
 322     SO_SUFFIX=dylib
 323     AC_DEFINE(__BSD__)
 324     AC_DEFINE(__DARWIN__)
 325     AC_DEFINE(TARGET_CARBON)
 326     DEFAULT_DEFAULT_wxUSE_OSX_CARBON=1
 327     DEFAULT_STD_FLAG=no
 328   ;;
 329   powerpc-apple-macos* )
 330     dnl Classic Mac OS (< X)
 331     USE_UNIX=0
 332     dnl For some reason the test that should be cross-compiler capable fails
 333     dnl However, there is no doubt that MacOS PowerPC is big endian.
 334     ac_cv_c_bigendian=yes
 335     SO_SUFFIX=shlib
 336     dnl AC_DEFINE(TARGET_CARBON)
 337     dnl platform.h needs TARGET_CARBON before setup.h, we'll add it to CPPFLAGS
 338     DEFAULT_DEFAULT_wxUSE_OSX_CARBON=1
 339     DEFAULT_STD_FLAG=no
 340   ;;
 341
 342   *-*-beos* )
 343     dnl leave USE_UNIX on - BeOS is sufficiently Unix-like for this
 344     USE_BEOS=1
 345     AC_DEFINE(__BEOS__)
 346   ;;
 347
 348   *)
 349     AC_MSG_WARN([*** System type ${host} is unknown, assuming generic Unix and continuing nevertheless.])
 350     AC_MSG_WARN([*** Please report the build results to wx-dev@lists.wxwidgets.org.])
 351
 352     DEFAULT_DEFAULT_wxUSE_X11=1
 353     DEFAULT_wxUSE_SHARED=no
 354 esac
 355
 356 dnl ---------------------------------------------------------------------------
 357 dnl command line options for configure
 358 dnl ---------------------------------------------------------------------------
 359
 360 dnl the default values for all options - we collect them all here to simplify
 361 dnl modification of the default values (for example, if the defaults for some
 362 dnl platform should be changed, it can be done here too)
 363 dnl
 364 dnl NB: see also DEFAULT_wxUSE<toolkit> variables defined above
 365
 366 dnl it's only necessary to list the options which should be disabled by
 367 dnl default, all the rest have default value of "yes" (or, rather, of
 368 dnl wxUSE_ALL_FEATURES which is the only which has to be set to "yes" by
 369 dnl default)
 370 DEFAULT_wxUSE_ALL_FEATURES=yes
 371
 372 DEFAULT_wxUSE_STD_IOSTREAM=$DEFAULT_STD_FLAG
 373 DEFAULT_wxUSE_STD_STRING=$DEFAULT_STD_FLAG
 374
 375 dnl libraries disabled by default
 376 DEFAULT_wxUSE_DMALLOC=no
 377 DEFAULT_wxUSE_LIBGNOMEVFS=no
 378 DEFAULT_wxUSE_LIBHILDON=no
 379 DEFAULT_wxUSE_LIBMSPACK=no
 380 DEFAULT_wxUSE_LIBSDL=no
 381 DEFAULT_wxUSE_OPENGL=no
 382
 383 dnl features disabled by default
 384 DEFAULT_wxUSE_ACCESSIBILITY=no
 385 DEFAULT_wxUSE_GRAPHICS_CONTEXT=no
 386 DEFAULT_wxUSE_IPV6=no
 387 DEFAULT_wxUSE_MEDIACTRL=no
 388 DEFAULT_wxUSE_TAB_DIALOG=no
 389 DEFAULT_wxUSE_GSTREAMER8=no
 390
 391 DEFAULT_wxUSE_UNICODE_UTF8=auto
 392 DEFAULT_wxUSE_UNICODE_UTF8_LOCALE=no
 393
 394 dnl Mac/Cocoa users need to enable building universal binaries explicitly
 395 DEFAULT_wxUSE_UNIVERSAL_BINARY=no
 396
 397 DEFAULT_wxUSE_OFFICIAL_BUILD=no
 398
 399 dnl Applicable only when --with-gtk was used:
 400 DEFAULT_wxUSE_GTK2=yes
 401
 402 dnl Always default to no. Only special cases require this.
 403 DEFAULT_wxUSE_OBJC_UNIQUIFYING=no
 404
 405 dnl ===========================
 406 dnl deal with configure options
 407 dnl ===========================
 408
 409 dnl we use several macros here:
 410 dnl     - AC_ARG_WITH/AC_ARG_ENABLE are the standard autoconf macros, see
 411 dnl       autoconf manual for details about them
 412 dnl     - WX_ARG_WITH/WX_ARG_ENABLE are their wx counterparts which perform
 413 dnl       the caching of the command line options and also use DEFAULT_foo
 414 dnl       variable as the default value for "foo" if neither --enable-foo nor
 415 dnl       --disable-foo is specified
 416 dnl     - WX_ARG_SYS_WITH is a special version of WX_ARG_WITH which allows
 417 dnl       to choose not only whether an external library is used but also if we
 418 dnl       use the copy of it included with wxWidgets or an already installed
 419 dnl       system version
 420 dnl     - WX_ARG_WITHOUT/WX_ARG_DISABLE mirror WX_ARG_WITH/WX_ARG_ENABLE but
 421 dnl       should be used for the options which are enabled by default
 422 dnl     - WX_ARG_FEATURE is a version of WX_ARG_ENABLE which should be used for
 423 dnl       optional features, i.e. options which should be disabled if
 424 dnl       --disable-all-features is specified (WX_ARG_WITH/WX_ARG_SYS_WITH are
 425 dnl       also affected by this)
 426
 427 dnl ---------------------------------------------------------------------------
 428 dnl global build options
 429 dnl ---------------------------------------------------------------------------
 430
 431 WX_ARG_DISABLE(gui,        [  --disable-gui           don't build GUI parts of the library], wxUSE_GUI)
 432 WX_ARG_ENABLE(monolithic,  [  --enable-monolithic     build wxWidgets as single library], wxUSE_MONOLITHIC)
 433 WX_ARG_ENABLE(plugins,     [  --enable-plugins        build parts of wxWidgets as loadable components], wxUSE_PLUGINS)
 434 WX_ARG_WITHOUT(subdirs,    [  --without-subdirs       don't generate makefiles for samples/demos/...], wxWITH_SUBDIRS)
 435 AC_ARG_WITH(flavour,       [  --with-flavour=NAME     specify a name to identify this build], [WX_FLAVOUR="$withval"])
 436 WX_ARG_ENABLE(official_build,  [  --enable-official_build official build of wxWidgets (win32 DLL only)], wxUSE_OFFICIAL_BUILD)
 437 AC_ARG_ENABLE(vendor,  [  --enable-vendor=VENDOR  vendor name (win32 DLL only)], [VENDOR="$enableval"])
 438 if test "x$VENDOR" = "x"; then
 439     VENDOR="custom"
 440 fi
 441
 442 WX_ARG_DISABLE(all-features,[  --disable-all-features  disable all optional features to build minimal library], wxUSE_ALL_FEATURES)
 443
 444 dnl ---------------------------------------------------------------------------
 445 dnl port selection
 446 dnl ---------------------------------------------------------------------------
 447
 448 if test "$wxUSE_GUI" = "yes"; then
 449
 450 WX_ARG_ENABLE(universal,   [  --enable-universal      use wxWidgets GUI controls instead of native ones], wxUSE_UNIVERSAL)
 451 if test "$wxUSE_UNIVERSAL" = "yes"; then
 452     AC_ARG_WITH(themes,    [  --with-themes=all|list  use only the specified comma-separated list of wxUniversal themes], [wxUNIV_THEMES="$withval"])
 453 fi
 454
 455 dnl we use AC_ARG_WITH and not WX_ARG_WITH for the toolkit options as they
 456 dnl shouldn't default to wxUSE_ALL_FEATURES
 457 AC_ARG_WITH(gtk,          [[  --with-gtk[=VERSION]    use GTK+, VERSION can be 2 (default), 1 or "any"]], [wxUSE_GTK="$withval" CACHE_GTK=1 TOOLKIT_GIVEN=1])
 458 AC_ARG_WITH(motif,         [  --with-motif            use Motif/Lesstif], [wxUSE_MOTIF="$withval" CACHE_MOTIF=1 TOOLKIT_GIVEN=1])
 459 AC_ARG_WITH(osx_carbon,    [  --with-osx_carbon       use Mac OS X (Carbon) ], [wxUSE_OSX_CARBON="$withval" CACHE_OSX_CARBON=1 TOOLKIT_GIVEN=1])
 460 AC_ARG_WITH(osx_cocoa,     [  --with-osx_cocoa        use Mac OS X (Cocoa) ], [wxUSE_OSX_COCOA="$withval" CACHE_OSX_COCOA=1 TOOLKIT_GIVEN=1])
 461 AC_ARG_WITH(mac,           [  --with-mac              use Mac OS X (Default) ], [wxUSE_OSX_CARBON="$withval" CACHE_OSX_CARBON=1 TOOLKIT_GIVEN=1])
 462 AC_ARG_WITH(cocoa,         [  --with-cocoa            use Cocoa], [wxUSE_COCOA="$withval" CACHE_COCOA=1 TOOLKIT_GIVEN=1])
 463 AC_ARG_WITH(wine,          [  --with-wine             use Wine], [wxUSE_WINE="$withval" CACHE_WINE=1])
 464 AC_ARG_WITH(msw,           [  --with-msw              use MS-Windows], [wxUSE_MSW="$withval" CACHE_MSW=1 TOOLKIT_GIVEN=1])
 465 AC_ARG_WITH(pm,            [  --with-pm               use OS/2 Presentation Manager], [wxUSE_PM="$withval" CACHE_PM=1 TOOLKIT_GIVEN=1])
 466 AC_ARG_WITH(mgl,           [  --with-mgl              use SciTech MGL], [wxUSE_MGL="$withval" wxUSE_UNIVERSAL="yes" CACHE_MGL=1 TOOLKIT_GIVEN=1])
 467 AC_ARG_WITH(directfb,      [  --with-directfb         use DirectFB], [wxUSE_DFB="$withval" wxUSE_UNIVERSAL="yes" CACHE_DFB=1 TOOLKIT_GIVEN=1])
 468 AC_ARG_WITH(microwin,      [  --with-microwin         use MicroWindows], [wxUSE_MICROWIN="$withval" CACHE_MICROWIN=1 TOOLKIT_GIVEN=1])
 469 AC_ARG_WITH(x11,           [  --with-x11              use X11], [wxUSE_X11="$withval" wxUSE_UNIVERSAL="yes" CACHE_X11=1 TOOLKIT_GIVEN=1])
 470 WX_ARG_ENABLE(nanox,       [  --enable-nanox          use NanoX], wxUSE_NANOX)
 471
 472 AC_ARG_ENABLE(gtk2,        [  --disable-gtk2          use GTK+ 1.2 instead of 2.0], [wxUSE_GTK2="$enableval"])
 473 WX_ARG_ENABLE(gpe,         [  --enable-gpe            use GNOME PDA Environment features if possible], wxUSE_GPE)
 474
 475 dnl check that no more than one toolkit is given and that if none are given that
 476 dnl we have a default one
 477
 478 AC_MSG_CHECKING(for toolkit)
 479
 480
 481
 482 # In Wine, we need to default to MSW, not GTK or MOTIF
 483 if test "$wxUSE_WINE" = "yes"; then
 484     DEFAULT_DEFAULT_wxUSE_GTK=0
 485     DEFAULT_DEFAULT_wxUSE_MOTIF=0
 486     DEFAULT_DEFAULT_wxUSE_MSW=1
 487     wxUSE_SHARED=no
 488     CC=${CC:-winegcc}
 489     CXX=${CXX:-wineg++}
 490 fi
 491
 492
 493 if test "$wxUSE_GUI" = "yes"; then
 494
 495     if test "$USE_BEOS" = 1; then
 496         AC_MSG_ERROR([BeOS GUI is not supported yet, use --disable-gui])
 497     fi
 498
 499     if test "$TOOLKIT_GIVEN" = 1; then
 500       dnl convert "yes", "any" or a number to 1 and "no" to 0
 501       for toolkit in $ALL_TOOLKITS; do
 502         var=wxUSE_$toolkit
 503         eval "value=\$${var}"
 504         if test "x$value" = "xno"; then
 505           eval "$var=0"
 506         elif test "x$value" != "x"; then
 507           eval "$var=1"
 508         fi
 509
 510         if test "x$value" != "x" -a "x$value" != "xyes" -a "x$value" != "xno"; then
 511           eval "wx${toolkit}_VERSION=$value"
 512         fi
 513       done
 514     else
 515       dnl try to guess the most apropriate toolkit for this platform
 516       for toolkit in $ALL_TOOLKITS; do
 517         var=DEFAULT_DEFAULT_wxUSE_$toolkit
 518         eval "wxUSE_$toolkit=\$${var}"
 519       done
 520     fi
 521
 522     dnl we suppose that expr is available (maybe there is a better way to do
 523     dnl this? what about using ALL_TOOLKITS? TODO)
 524     NUM_TOOLKITS=`expr ${wxUSE_COCOA:-0} + ${wxUSE_GTK:-0} + ${wxUSE_OSX_CARBON:-0} \
 525                   + ${wxUSE_OSX_COCOA:-0} + ${wxUSE_MGL:-0} + ${wxUSE_DFB:-0} \
 526                   + ${wxUSE_MICROWIN:-0} + ${wxUSE_MOTIF:-0} + ${wxUSE_MSW:-0} + ${wxUSE_X11:-0}`
 527
 528     dnl Allow wxUSE_PM only for OS/2 with EMX.
 529     case "${host}" in
 530       *-pc-os2_emx | *-pc-os2-emx )
 531         NUM_TOOLKITS=`expr ${NUM_TOOLKITS} + ${wxUSE_PM:-0}`
 532     esac
 533
 534     case "$NUM_TOOLKITS" in
 535       1)
 536       ;;
 537       0)
 538         AC_MSG_ERROR(Please specify a toolkit -- cannot determine the default for ${host})
 539       ;;
 540       *)
 541         AC_MSG_ERROR(Please specify at most one toolkit)
 542     esac
 543
 544     # to be removed when --disable-gtk2 isn't needed
 545     if test "x$wxUSE_GTK2" = "xyes"; then
 546         wxGTK_VERSION=2
 547     elif test "x$wxUSE_GTK2" = "xno"; then
 548         wxGTK_VERSION=1
 549     fi
 550
 551     for toolkit in $ALL_TOOLKITS; do
 552         var=wxUSE_$toolkit
 553         eval "value=\$${var}"
 554         if test "$value" = 1; then
 555           toolkit_echo=`echo $toolkit | tr '[[A-Z]]' '[[a-z]]'`
 556           AC_MSG_RESULT($toolkit_echo)
 557         fi
 558     done
 559 else
 560     if test "x$host_alias" != "x"; then
 561         AC_MSG_RESULT(base ($host_alias hosted) only)
 562     else
 563         AC_MSG_RESULT(base only)
 564     fi
 565 fi
 566
 567 wxUSE_MAC=0
 568 if test "$wxUSE_OSX_CARBON" = 1 -o "$wxUSE_OSX_COCOA" = 1; then
 569     wxUSE_MAC=1
 570 fi
 571
 572 dnl ---------------------------------------------------------------------------
 573 dnl external libraries
 574 dnl ---------------------------------------------------------------------------
 575
 576 WX_ARG_SYS_WITH(libpng,    [  --with-libpng           use libpng (PNG image format)], wxUSE_LIBPNG)
 577 WX_ARG_SYS_WITH(libjpeg,   [  --with-libjpeg          use libjpeg (JPEG file format)], wxUSE_LIBJPEG)
 578 WX_ARG_SYS_WITH(libtiff,   [  --with-libtiff          use libtiff (TIFF file format)], wxUSE_LIBTIFF)
 579 WX_ARG_SYS_WITH(libxpm,    [  --with-libxpm           use libxpm (XPM file format)], wxUSE_LIBXPM)
 580 WX_ARG_WITH(libiconv,      [  --with-libiconv         use libiconv (character conversion)], wxUSE_LIBICONV)
 581 WX_ARG_WITH(libmspack,     [  --with-libmspack        use libmspack (CHM help files loading)], wxUSE_LIBMSPACK)
 582 WX_ARG_WITHOUT(gtkprint,   [  --without-gtkprint      don't use GTK printing support], wxUSE_GTKPRINT)
 583 WX_ARG_WITHOUT(gnomeprint, [  --without-gnomeprint    don't use GNOME printing libraries], wxUSE_LIBGNOMEPRINT)
 584 WX_ARG_WITH(gnomevfs,      [  --with-gnomevfs         use GNOME VFS for associating MIME types], wxUSE_LIBGNOMEVFS)
 585 WX_ARG_WITH(hildon,        [  --with-hildon           use Hildon framework for Nokia 770], wxUSE_LIBHILDON)
 586 WX_ARG_WITH(opengl,        [  --with-opengl           use OpenGL (or Mesa)], wxUSE_OPENGL)
 587
 588 fi
 589 dnl for GUI only
 590
 591 WX_ARG_WITH(dmalloc,       [  --with-dmalloc          use dmalloc library (http://dmalloc.com/)], wxUSE_DMALLOC)
 592 WX_ARG_WITH(sdl,           [  --with-sdl              use SDL for audio on Unix], wxUSE_LIBSDL)
 593 WX_ARG_SYS_WITH(regex,     [  --with-regex            enable support for wxRegEx class], wxUSE_REGEX)
 594 WX_ARG_SYS_WITH(zlib,      [  --with-zlib             use zlib for LZW compression], wxUSE_ZLIB)
 595 WX_ARG_SYS_WITH(expat,     [  --with-expat            enable XML support using expat parser], wxUSE_EXPAT)
 596
 597 AC_MSG_CHECKING([for --with-macosx-sdk])
 598 AC_ARG_WITH(macosx-sdk,    [  --with-macosx-sdk=PATH  use an OS X SDK at PATH], [
 599         wxUSE_MACOSX_SDK=$withval
 600         wx_cv_use_macosx_sdk="wxUSE_MACOSX_SDK=$withval"
 601     ])
 602 AC_MSG_RESULT([$wxUSE_MACOSX_SDK])
 603
 604 AC_MSG_CHECKING([for --with-macosx-version-min])
 605 AC_ARG_WITH(macosx-version-min,    [  --with-macosx-version-min=VER   build binaries which require at least this OS X version], [
 606         wxUSE_MACOSX_VERSION_MIN=$withval
 607         wx_cv_use_macosx_version_min="wxUSE_MACOSX_VERSION_MIN=$withval"
 608     ])
 609 AC_MSG_RESULT([$wxUSE_MACOSX_VERSION_MIN])
 610
 611 dnl ---------------------------------------------------------------------------
 612 dnl global compile options
 613 dnl ---------------------------------------------------------------------------
 614
 615 WX_ARG_DISABLE(shared,     [  --disable-shared        create static library instead of shared], wxUSE_SHARED)
 616 WX_ARG_ENABLE(debug,       [  --enable-debug          same as debug_flag and debug_info], wxUSE_DEBUG)
 617 WX_ARG_ENABLE(stl,         [  --enable-stl            use STL for containers], wxUSE_STL)
 618 WX_ARG_ENABLE(std_iostreams, [  --enable-std_iostreams  use standard C++ stream classes], wxUSE_STD_IOSTREAM)
 619 WX_ARG_ENABLE(std_string,    [  --enable-std_string     use standard C++ string classes], wxUSE_STD_STRING)
 620 WX_ARG_DISABLE(unicode,      [  --disable-unicode       compile without Unicode support], wxUSE_UNICODE)
 621 WX_ARG_ENABLE(mslu,          [  --enable-mslu           use MS Layer for Unicode on Windows 9x (Win32 only)], wxUSE_UNICODE_MSLU)
 622 WX_ARG_ENABLE_PARAM(utf8,    [  --enable-utf8           use UTF-8 representation for strings (Unix only)], wxUSE_UNICODE_UTF8)
 623 WX_ARG_ENABLE(utf8only,      [  --enable-utf8only       only support UTF-8 locales in UTF-8 build (Unix only)], wxUSE_UNICODE_UTF8_LOCALE)
 624 WX_ARG_ENABLE(extended_rtti, [  --enable-extended_rtti  use extended RTTI (XTI)], wxUSE_EXTENDED_RTTI)
 625 if test "$USE_OS2" = 1; then
 626     DEFAULT_wxUSE_OMF=no
 627     WX_ARG_ENABLE(omf,     [  --enable-omf            use OMF object format], wxUSE_OMF)
 628 fi
 629
 630 dnl --enablle-debug is equivalent to both --enable-debug_flag and
 631 dnl --enable-debug_info
 632 if test "$wxUSE_DEBUG" = "yes"; then
 633     DEFAULT_wxUSE_DEBUG_FLAG=yes
 634     DEFAULT_wxUSE_DEBUG_INFO=yes
 635     BUILD=debug
 636 elif test "$wxUSE_DEBUG" = "no"; then
 637     DEFAULT_wxUSE_DEBUG_FLAG=no
 638     DEFAULT_wxUSE_DEBUG_INFO=no
 639     BUILD=release
 640 fi
 641
 642 WX_ARG_ENABLE(debug_flag,    [  --enable-debug_flag     set __WXDEBUG__ flag (recommended for developers!)], wxUSE_DEBUG_FLAG)
 643 WX_ARG_ENABLE(debug_info,    [  --enable-debug_info     create code with debugging information], wxUSE_DEBUG_INFO)
 644
 645 dnl it's important to also do it in the other direction to get the correct
 646 dnl output in the configure summary (which uses wxUSE_DEBUG)
 647 if test "$wxUSE_DEBUG_FLAG" = "yes" -a "$wxUSE_DEBUG_INFO" = "yes"; then
 648     wxUSE_DEBUG=yes
 649     BUILD=debug
 650 fi
 651
 652 dnl disable optimizations by default if --enable-debug was used but leave them
 653 dnl enabled if just --enable-debug_{flag,info} was
 654 dnl
 655 dnl in any case, only set the default value and allow overriding it with an
 656 dnl explicit --enable-optimise
 657 if test "$wxUSE_DEBUG" = "yes"; then
 658     DEFAULT_wxUSE_OPTIMISE=no
 659 fi
 660
 661 WX_ARG_DISABLE(optimise,   [  --disable-optimise      compile without optimisations], wxUSE_OPTIMISE)
 662
 663 WX_ARG_ENABLE(debug_gdb,     [  --enable-debug_gdb      create code with extra GDB debugging information], wxUSE_DEBUG_GDB)
 664 WX_ARG_ENABLE(debug_cntxt,   [  --enable-debug_cntxt    use wxDebugContext], wxUSE_DEBUG_CONTEXT)
 665 WX_ARG_ENABLE(mem_tracing,   [  --enable-mem_tracing    create code with memory tracing], wxUSE_MEM_TRACING)
 666 WX_ARG_ENABLE(profile,       [  --enable-profile        create code with profiling information], wxUSE_PROFILE)
 667 WX_ARG_ENABLE(no_rtti,       [  --enable-no_rtti        create code without RTTI information], wxUSE_NO_RTTI)
 668 WX_ARG_ENABLE(no_exceptions, [  --enable-no_exceptions  create code without C++ exceptions handling], wxUSE_NO_EXCEPTIONS)
 669 WX_ARG_ENABLE(permissive,    [  --enable-permissive     compile code disregarding strict ANSI], wxUSE_PERMISSIVE)
 670 WX_ARG_ENABLE(no_deps,       [  --enable-no_deps        create code without dependency information], wxUSE_NO_DEPS)
 671 WX_ARG_DISABLE(vararg_macros,[  --disable-vararg_macros don't use vararg macros, even if they are supported], wxUSE_VARARG_MACROS)
 672 WX_ARG_ENABLE_PARAM(universal_binary, [[  --enable-universal_binary  create Mac PowerPC and Intel Universal binary]], wxUSE_UNIVERSAL_BINARY)
 673
 674 WX_ARG_ENABLE(compat26,      [  --enable-compat26       enable wxWidgets 2.6 compatibility], WXWIN_COMPATIBILITY_2_6)
 675 WX_ARG_DISABLE(compat28,     [  --disable-compat28      disable wxWidgets 2.8 compatibility], WXWIN_COMPATIBILITY_2_8)
 676
 677 WX_ARG_DISABLE(rpath,        [  --disable-rpath         disable use of rpath for uninstalled builds], wxUSE_RPATH)
 678
 679 WX_ARG_ENABLE(objc_uniquifying,[  --enable-objc_uniquifying enable Objective-C class name uniquifying], wxUSE_OBJC_UNIQUIFYING)
 680
 681 WX_ARG_DISABLE(visibility,   [  --disable-visibility    disable use of ELF symbols visibility even if supported], wxUSE_VISIBILITY)
 682
 683 dnl ---------------------------------------------------------------------------
 684 dnl optional non GUI features
 685 dnl ---------------------------------------------------------------------------
 686
 687 WX_ARG_FEATURE(intl,          [  --enable-intl           use internationalization system], wxUSE_INTL)
 688 WX_ARG_FEATURE(xlocale,       [  --enable-xlocale        use x-locale support (requires wxLocale)], wxUSE_XLOCALE)
 689 WX_ARG_FEATURE(config,        [  --enable-config         use wxConfig (and derived) classes], wxUSE_CONFIG)
 690
 691 WX_ARG_FEATURE(protocols,     [  --enable-protocols      use wxProtocol and derived classes], wxUSE_PROTOCOL)
 692 WX_ARG_FEATURE(ftp,           [  --enable-ftp            use wxFTP (requires wxProtocol], wxUSE_PROTOCOL_FTP)
 693 WX_ARG_FEATURE(http,          [  --enable-http           use wxHTTP (requires wxProtocol], wxUSE_PROTOCOL_HTTP)
 694 WX_ARG_FEATURE(fileproto,     [  --enable-fileproto      use wxFileProto class (requires wxProtocol], wxUSE_PROTOCOL_FILE)
 695 WX_ARG_FEATURE(sockets,       [  --enable-sockets        use socket/network classes], wxUSE_SOCKETS)
 696 WX_ARG_FEATURE(ipv6,          [  --enable-ipv6           enable IPv6 support in wxSocket], wxUSE_IPV6)
 697 WX_ARG_FEATURE(ole,           [  --enable-ole            use OLE classes (Win32 only)], wxUSE_OLE)
 698 WX_ARG_FEATURE(dataobj,       [  --enable-dataobj        use data object classes], wxUSE_DATAOBJ)
 699
 700 WX_ARG_FEATURE(ipc,           [  --enable-ipc            use interprocess communication (wxSocket etc.)], wxUSE_IPC)
 701
 702 WX_ARG_FEATURE(baseevtloop,   [  --enable-baseevtloop    use event loop in console programs too], wxUSE_CONSOLE_EVENTLOOP)
 703 WX_ARG_FEATURE(epollloop,     [  --enable-epollloop      use wxEpollDispatcher class (Linux only)], wxUSE_EPOLL_DISPATCHER)
 704 WX_ARG_FEATURE(selectloop,    [  --enable-selectloop     use wxSelectDispatcher class], wxUSE_SELECT_DISPATCHER)
 705
 706 dnl please keep the settings below in alphabetical order
 707 WX_ARG_FEATURE(apple_ieee,    [  --enable-apple_ieee     use the Apple IEEE codec], wxUSE_APPLE_IEEE)
 708 WX_ARG_FEATURE(arcstream,     [  --enable-arcstream      use wxArchive streams], wxUSE_ARCHIVE_STREAMS)
 709 WX_ARG_FEATURE(base64,        [  --enable-base64         use base64 encoding/decoding functions], wxUSE_BASE64)
 710 WX_ARG_FEATURE(backtrace,     [  --enable-backtrace      use wxStackWalker class for getting backtraces], wxUSE_STACKWALKER)
 711 WX_ARG_FEATURE(catch_segvs,   [  --enable-catch_segvs    catch signals in wxApp::OnFatalException (Unix only)], wxUSE_ON_FATAL_EXCEPTION)
 712 WX_ARG_FEATURE(cmdline,       [  --enable-cmdline        use wxCmdLineParser class], wxUSE_CMDLINE_PARSER)
 713 WX_ARG_FEATURE(datetime,      [  --enable-datetime       use wxDateTime class], wxUSE_DATETIME)
 714 WX_ARG_FEATURE(debugreport,   [  --enable-debugreport    use wxDebugReport class], wxUSE_DEBUGREPORT)
 715 WX_ARG_FEATURE(dialupman,     [  --enable-dialupman      use dialup network classes], wxUSE_DIALUP_MANAGER)
 716 WX_ARG_FEATURE(dynlib,        [  --enable-dynlib         use wxLibrary class for DLL loading], wxUSE_DYNLIB_CLASS)
 717 WX_ARG_FEATURE(dynamicloader, [  --enable-dynamicloader  use (new) wxDynamicLibrary class], wxUSE_DYNAMIC_LOADER)
 718 WX_ARG_FEATURE(exceptions,    [  --enable-exceptions     build exception-safe library], wxUSE_EXCEPTIONS)
 719 WX_ARG_FEATURE(ffile,         [  --enable-ffile          use wxFFile class], wxUSE_FFILE)
 720 WX_ARG_FEATURE(file,          [  --enable-file           use wxFile class], wxUSE_FILE)
 721 WX_ARG_FEATURE(filesystem,    [  --enable-filesystem     use virtual file systems classes], wxUSE_FILESYSTEM)
 722 WX_ARG_FEATURE(fontenum,      [  --enable-fontenum       use wxFontEnumerator class], wxUSE_FONTENUM)
 723 WX_ARG_FEATURE(fontmap,       [  --enable-fontmap        use font encodings conversion classes], wxUSE_FONTMAP)
 724 WX_ARG_FEATURE(fs_archive,    [  --enable-fs_archive     use virtual archive filesystems], wxUSE_FS_ARCHIVE)
 725 WX_ARG_FEATURE(fs_inet,       [  --enable-fs_inet        use virtual HTTP/FTP filesystems], wxUSE_FS_INET)
 726 WX_ARG_FEATURE(fs_zip,        [  --enable-fs_zip         now replaced by fs_archive], wxUSE_FS_ZIP)
 727 WX_ARG_FEATURE(geometry,      [  --enable-geometry       use geometry class], wxUSE_GEOMETRY)
 728 WX_ARG_FEATURE(log,           [  --enable-log            use logging system], wxUSE_LOG)
 729 WX_ARG_FEATURE(longlong,      [  --enable-longlong       use wxLongLong class], wxUSE_LONGLONG)
 730 WX_ARG_FEATURE(mimetype,      [  --enable-mimetype       use wxMimeTypesManager], wxUSE_MIMETYPE)
 731 WX_ARG_FEATURE(printfposparam,[  --enable-printfposparam use wxVsnprintf() which supports positional parameters], wxUSE_PRINTF_POS_PARAMS)
 732 WX_ARG_FEATURE(snglinst,      [  --enable-snglinst       use wxSingleInstanceChecker class], wxUSE_SNGLINST_CHECKER)
 733 WX_ARG_FEATURE(sound,         [  --enable-sound          use wxSound class], wxUSE_SOUND)
 734 WX_ARG_FEATURE(stdpaths,      [  --enable-stdpaths       use wxStandardPaths class], wxUSE_STDPATHS)
 735 WX_ARG_FEATURE(stopwatch,     [  --enable-stopwatch      use wxStopWatch class], wxUSE_STOPWATCH)
 736 WX_ARG_FEATURE(streams,       [  --enable-streams        use wxStream etc classes], wxUSE_STREAMS)
 737 WX_ARG_FEATURE(system_options,[  --enable-sysoptions     use wxSystemOptions], wxUSE_SYSTEM_OPTIONS)
 738 WX_ARG_FEATURE(tarstream,     [  --enable-tarstream      use wxTar streams], wxUSE_TARSTREAM)
 739 WX_ARG_FEATURE(textbuf,       [  --enable-textbuf        use wxTextBuffer class], wxUSE_TEXTBUFFER)
 740 WX_ARG_FEATURE(textfile,      [  --enable-textfile       use wxTextFile class], wxUSE_TEXTFILE)
 741 WX_ARG_FEATURE(timer,         [  --enable-timer          use wxTimer class], wxUSE_TIMER)
 742 WX_ARG_FEATURE(variant,       [  --enable-variant        use wxVariant class], wxUSE_VARIANT)
 743 WX_ARG_FEATURE(zipstream,     [  --enable-zipstream      use wxZip streams], wxUSE_ZIPSTREAM)
 744
 745 dnl URL-related classes
 746 WX_ARG_FEATURE(url,           [  --enable-url            use wxURL class], wxUSE_URL)
 747 WX_ARG_FEATURE(protocol,      [  --enable-protocol       use wxProtocol class], wxUSE_PROTOCOL)
 748 WX_ARG_FEATURE(protocol_http, [  --enable-protocol-http  HTTP support in wxProtocol], wxUSE_PROTOCOL_HTTP)
 749 WX_ARG_FEATURE(protocol_ftp,  [  --enable-protocol-ftp   FTP support in wxProtocol], wxUSE_PROTOCOL_FTP)
 750 WX_ARG_FEATURE(protocol_file, [  --enable-protocol-file  FILE support in wxProtocol], wxUSE_PROTOCOL_FILE)
 751
 752 WX_ARG_FEATURE(threads,     [  --enable-threads        use threads], wxUSE_THREADS)
 753
 754 WX_ARG_ENABLE(iniconf,      [  --enable-iniconf        use wxIniConfig (Win32 only)], wxUSE_INICONF)
 755 WX_ARG_FEATURE(regkey,      [  --enable-regkey         use wxRegKey class (Win32 only)], wxUSE_REGKEY)
 756
 757 if test "$wxUSE_GUI" = "yes"; then
 758
 759 dnl ---------------------------------------------------------------------------
 760 dnl optional "big" GUI features
 761 dnl ---------------------------------------------------------------------------
 762
 763 WX_ARG_FEATURE(docview,     [  --enable-docview        use document view architecture], wxUSE_DOC_VIEW_ARCHITECTURE)
 764 WX_ARG_FEATURE(help,        [  --enable-help           use help subsystem], wxUSE_HELP)
 765 WX_ARG_FEATURE(mshtmlhelp,  [  --enable-mshtmlhelp     use MS HTML Help (win32)], wxUSE_MS_HTML_HELP)
 766 WX_ARG_FEATURE(html,        [  --enable-html           use wxHTML sub-library], wxUSE_HTML)
 767 WX_ARG_FEATURE(htmlhelp,    [  --enable-htmlhelp       use wxHTML-based help], wxUSE_WXHTML_HELP)
 768 WX_ARG_FEATURE(xrc,         [  --enable-xrc            use XRC resources sub-library], wxUSE_XRC)
 769 WX_ARG_FEATURE(aui,         [  --enable-aui            use AUI docking library], wxUSE_AUI)
 770 WX_ARG_FEATURE(propgrid,    [  --enable-propgrid       use wxPropertyGrid library], wxUSE_PROPGRID)
 771 WX_ARG_FEATURE(stc,         [  --enable-stc            use wxStyledTextCtrl library], wxUSE_STC)
 772 WX_ARG_FEATURE(constraints, [  --enable-constraints    use layout-constraints system], wxUSE_CONSTRAINTS)
 773 WX_ARG_FEATURE(loggui,      [  --enable-loggui         use standard GUI logger], wxUSE_LOGGUI)
 774 WX_ARG_FEATURE(logwin,      [  --enable-logwin         use wxLogWindow], wxUSE_LOGWINDOW)
 775 WX_ARG_FEATURE(logdialog,   [  --enable-logdialog      use wxLogDialog], wxUSE_LOGDIALOG)
 776 WX_ARG_FEATURE(mdi,         [  --enable-mdi            use multiple document interface architecture], wxUSE_MDI)
 777 WX_ARG_FEATURE(mdidoc,      [  --enable-mdidoc         use docview architecture with MDI], wxUSE_MDI_ARCHITECTURE)
 778 WX_ARG_FEATURE(mediactrl,   [  --enable-mediactrl      use wxMediaCtrl class], wxUSE_MEDIACTRL)
 779 WX_ARG_FEATURE(gstreamer8,  [  --enable-gstreamer8     force GStreamer 0.8 instead of 0.10 with the wxMediaCtrl class on unix], wxUSE_GSTREAMER8)
 780 WX_ARG_FEATURE(webkit,      [  --enable-webkit         use wxWebKitCtrl (Mac)], wxUSE_WEBKIT)
 781 WX_ARG_FEATURE(richtext,    [  --enable-richtext       use wxRichTextCtrl], wxUSE_RICHTEXT)
 782 WX_ARG_FEATURE(graphics_ctx,[  --enable-graphics_ctx   use graphics context 2D drawing API], wxUSE_GRAPHICS_CONTEXT)
 783 WX_ARG_FEATURE(postscript,  [  --enable-postscript     use wxPostscriptDC device context (default for gtk+)], wxUSE_POSTSCRIPT)
 784 WX_ARG_FEATURE(printarch,   [  --enable-printarch      use printing architecture], wxUSE_PRINTING_ARCHITECTURE)
 785 WX_ARG_FEATURE(svg,         [  --enable-svg            use wxSVGFileDC device context], wxUSE_SVG)
 786
 787 dnl ---------------------------------------------------------------------------
 788 dnl IPC &c
 789 dnl ---------------------------------------------------------------------------
 790
 791 WX_ARG_FEATURE(clipboard,   [  --enable-clipboard      use wxClipboard class], wxUSE_CLIPBOARD)
 792 WX_ARG_FEATURE(dnd,         [  --enable-dnd            use Drag'n'Drop classes], wxUSE_DRAG_AND_DROP)
 793 WX_ARG_FEATURE(metafile,    [  --enable-metafile       use win32 metafiles], wxUSE_METAFILE)
 794
 795 dnl ---------------------------------------------------------------------------
 796 dnl optional GUI controls (in alphabetical order except the first one)
 797 dnl ---------------------------------------------------------------------------
 798
 799 dnl don't set DEFAULT_wxUSE_XXX below if the option is not specified
 800 DEFAULT_wxUSE_CONTROLS=none
 801 WX_ARG_DISABLE(controls,    [  --disable-controls      disable compilation of all standard controls], wxUSE_CONTROLS)
 802
 803 dnl even with --enable-controls, some may be disabled by giving
 804 dnl --disable-<control> later on the command line - but by default all will be
 805 dnl used (and vice versa)
 806 if test "$wxUSE_CONTROLS" = "yes"; then
 807   DEFAULT_wxUSE_ACCEL=yes
 808   DEFAULT_wxUSE_ANIMATIONCTRL=yes
 809   DEFAULT_wxUSE_BMPBUTTON=yes
 810   DEFAULT_wxUSE_BUTTON=yes
 811   DEFAULT_wxUSE_CALCTRL=yes
 812   DEFAULT_wxUSE_CARET=yes
 813   DEFAULT_wxUSE_COMBOBOX=yes
 814   DEFAULT_wxUSE_CHECKBOX=yes
 815   DEFAULT_wxUSE_CHECKLISTBOX=yes
 816   DEFAULT_wxUSE_CHOICE=yes
 817   DEFAULT_wxUSE_CHOICEBOOK=yes
 818   DEFAULT_wxUSE_COLLPANE=yes
 819   DEFAULT_wxUSE_COLOURPICKERCTRL=yes
 820   DEFAULT_wxUSE_COMBOBOX=yes
 821   DEFAULT_wxUSE_DATEPICKCTRL=yes
 822   DEFAULT_wxUSE_DISPLAY=yes
 823   DEFAULT_wxUSE_DETECT_SM=yes
 824   DEFAULT_wxUSE_DIRPICKERCTRL=yes
 825   DEFAULT_wxUSE_FILECTRL=yes
 826   DEFAULT_wxUSE_FILEPICKERCTRL=yes
 827   DEFAULT_wxUSE_FONTPICKERCTRL=yes
 828   DEFAULT_wxUSE_GAUGE=yes
 829   DEFAULT_wxUSE_GRID=yes
 830   DEFAULT_wxUSE_HYPERLINKCTRL=yes
 831   DEFAULT_wxUSE_DATAVIEWCTRL=yes
 832   DEFAULT_wxUSE_IMAGLIST=yes
 833   DEFAULT_wxUSE_LISTBOOK=yes
 834   DEFAULT_wxUSE_LISTBOX=yes
 835   DEFAULT_wxUSE_LISTCTRL=yes
 836   DEFAULT_wxUSE_NOTEBOOK=yes
 837   DEFAULT_wxUSE_RADIOBOX=yes
 838   DEFAULT_wxUSE_RADIOBTN=yes
 839   DEFAULT_wxUSE_SASH=yes
 840   DEFAULT_wxUSE_SCROLLBAR=yes
 841   DEFAULT_wxUSE_SEARCHCTRL=yes
 842   DEFAULT_wxUSE_SLIDER=yes
 843   DEFAULT_wxUSE_SPINBTN=yes
 844   DEFAULT_wxUSE_SPINCTRL=yes
 845   DEFAULT_wxUSE_SPLITTER=yes
 846   DEFAULT_wxUSE_STATBMP=yes
 847   DEFAULT_wxUSE_STATBOX=yes
 848   DEFAULT_wxUSE_STATLINE=yes
 849   DEFAULT_wxUSE_STATUSBAR=yes
 850   DEFAULT_wxUSE_TAB_DIALOG=yes
 851   DEFAULT_wxUSE_TOGGLEBTN=yes
 852   DEFAULT_wxUSE_TOOLBAR=yes
 853   DEFAULT_wxUSE_TOOLBAR_NATIVE=yes
 854   DEFAULT_wxUSE_TOOLTIPS=yes
 855   DEFAULT_wxUSE_TREEBOOK=yes
 856   DEFAULT_wxUSE_TOOLBOOK=yes
 857   DEFAULT_wxUSE_TREECTRL=yes
 858   DEFAULT_wxUSE_POPUPWIN=yes
 859   DEFAULT_wxUSE_TIPWINDOW=yes
 860 elif test "$wxUSE_CONTROLS" = "no"; then
 861   DEFAULT_wxUSE_ACCEL=no
 862   DEFAULT_wxUSE_ANIMATIONCTRL=no
 863   DEFAULT_wxUSE_BMPBUTTON=no
 864   DEFAULT_wxUSE_BUTTON=no
 865   DEFAULT_wxUSE_CALCTRL=no
 866   DEFAULT_wxUSE_CARET=no
 867   DEFAULT_wxUSE_COLLPANE=no
 868   DEFAULT_wxUSE_COMBOBOX=no
 869   DEFAULT_wxUSE_CHECKBOX=no
 870   DEFAULT_wxUSE_CHECKLISTBOX=no
 871   DEFAULT_wxUSE_CHOICE=no
 872   DEFAULT_wxUSE_CHOICEBOOK=no
 873   DEFAULT_wxUSE_COLOURPICKERCTRL=no
 874   DEFAULT_wxUSE_COMBOBOX=no
 875   DEFAULT_wxUSE_DATEPICKCTRL=no
 876   DEFAULT_wxUSE_DISPLAY=no
 877   DEFAULT_wxUSE_DETECT_SM=no
 878   DEFAULT_wxUSE_DIRPICKERCTRL=no
 879   DEFAULT_wxUSE_FILECTRL=no
 880   DEFAULT_wxUSE_FILEPICKERCTRL=no
 881   DEFAULT_wxUSE_FONTPICKERCTRL=no
 882   DEFAULT_wxUSE_GAUGE=no
 883   DEFAULT_wxUSE_GRID=no
 884   DEFAULT_wxUSE_HYPERLINKCTRL=no
 885   DEFAULT_wxUSE_DATAVIEWCTRL=no
 886   DEFAULT_wxUSE_IMAGLIST=no
 887   DEFAULT_wxUSE_LISTBOOK=no
 888   DEFAULT_wxUSE_LISTBOX=no
 889   DEFAULT_wxUSE_LISTCTRL=no
 890   DEFAULT_wxUSE_NOTEBOOK=no
 891   DEFAULT_wxUSE_RADIOBOX=no
 892   DEFAULT_wxUSE_RADIOBTN=no
 893   DEFAULT_wxUSE_SASH=no
 894   DEFAULT_wxUSE_SCROLLBAR=no
 895   DEFAULT_wxUSE_SEARCHCTRL=no
 896   DEFAULT_wxUSE_SLIDER=no
 897   DEFAULT_wxUSE_SPINBTN=no
 898   DEFAULT_wxUSE_SPINCTRL=no
 899   DEFAULT_wxUSE_SPLITTER=no
 900   DEFAULT_wxUSE_STATBMP=no
 901   DEFAULT_wxUSE_STATBOX=no
 902   DEFAULT_wxUSE_STATLINE=no
 903   DEFAULT_wxUSE_STATUSBAR=no
 904   DEFAULT_wxUSE_TAB_DIALOG=no
 905   DEFAULT_wxUSE_TOGGLEBTN=no
 906   DEFAULT_wxUSE_TOOLBAR=no
 907   DEFAULT_wxUSE_TOOLBAR_NATIVE=no
 908   DEFAULT_wxUSE_TOOLTIPS=no
 909   DEFAULT_wxUSE_TREEBOOK=no
 910   DEFAULT_wxUSE_TOOLBOOK=no
 911   DEFAULT_wxUSE_TREECTRL=no
 912   DEFAULT_wxUSE_POPUPWIN=no
 913   DEFAULT_wxUSE_TIPWINDOW=no
 914 fi
 915
 916 WX_ARG_FEATURE(accel,       [  --enable-accel          use accelerators], wxUSE_ACCEL)
 917 WX_ARG_FEATURE(animatectrl, [  --enable-animatectrl    use wxAnimationCtrl class], wxUSE_ANIMATIONCTRL)
 918 WX_ARG_FEATURE(button,      [  --enable-button         use wxButton class], wxUSE_BUTTON)
 919 WX_ARG_FEATURE(bmpbutton,   [  --enable-bmpbutton      use wxBitmapButton class], wxUSE_BMPBUTTON)
 920 WX_ARG_FEATURE(bmpcombobox, [  --enable-bmpcombobox    use wxBitmapComboBox class], wxUSE_BITMAPCOMBOBOX)
 921 WX_ARG_FEATURE(calendar,    [  --enable-calendar       use wxCalendarCtrl class], wxUSE_CALCTRL)
 922 WX_ARG_FEATURE(caret,       [  --enable-caret          use wxCaret class], wxUSE_CARET)
 923 WX_ARG_FEATURE(checkbox,    [  --enable-checkbox       use wxCheckBox class], wxUSE_CHECKBOX)
 924 WX_ARG_FEATURE(checklst,    [  --enable-checklst       use wxCheckListBox (listbox with checkboxes) class], wxUSE_CHECKLST)
 925 WX_ARG_FEATURE(choice,      [  --enable-choice         use wxChoice class], wxUSE_CHOICE)
 926 WX_ARG_FEATURE(choicebook,  [  --enable-choicebook     use wxChoicebook class], wxUSE_CHOICEBOOK)
 927 WX_ARG_FEATURE(collpane,    [  --enable-collpane       use wxCollapsiblePane class], wxUSE_COLLPANE)
 928 WX_ARG_FEATURE(colourpicker,[  --enable-colourpicker   use wxColourPickerCtrl class], wxUSE_COLOURPICKERCTRL)
 929 WX_ARG_FEATURE(combobox,    [  --enable-combobox       use wxComboBox class], wxUSE_COMBOBOX)
 930 WX_ARG_FEATURE(comboctrl,   [  --enable-comboctrl      use wxComboCtrl class], wxUSE_COMBOCTRL)
 931 WX_ARG_FEATURE(datepick,    [  --enable-datepick       use wxDatePickerCtrl class], wxUSE_DATEPICKCTRL)
 932 WX_ARG_FEATURE(dirpicker,   [  --enable-dirpicker      use wxDirPickerCtrl class], wxUSE_DIRPICKERCTRL)
 933 WX_ARG_FEATURE(display,     [  --enable-display        use wxDisplay class], wxUSE_DISPLAY)
 934 WX_ARG_FEATURE(detect_sm,   [  --enable-detect_sm      use code to detect X11 session manager], wxUSE_DETECT_SM)
 935 WX_ARG_FEATURE(editablebox, [  --enable-editablebox    use wxEditableListBox class], wxUSE_EDITABLELISTBOX)
 936 WX_ARG_FEATURE(filepicker,  [  --enable-filepicker     use wxFilePickerCtrl class], wxUSE_FILEPICKERCTRL)
 937 WX_ARG_FEATURE(filectrl,    [  --enable-filectrl       use wxFileCtrl class], wxUSE_FILECTRL)
 938 WX_ARG_FEATURE(fontpicker,  [  --enable-fontpicker     use wxFontPickerCtrl class], wxUSE_FONTPICKERCTRL)
 939 WX_ARG_FEATURE(gauge,       [  --enable-gauge          use wxGauge class], wxUSE_GAUGE)
 940 WX_ARG_FEATURE(grid,        [  --enable-grid           use wxGrid class], wxUSE_GRID)
 941 WX_ARG_FEATURE(dataviewctrl,[  --enable-dataviewctrl   use wxDataViewCtrl class], wxUSE_DATAVIEWCTRL)
 942 WX_ARG_FEATURE(hyperlink,   [  --enable-hyperlink      use wxHyperlinkCtrl class], wxUSE_HYPERLINKCTRL)
 943 WX_ARG_FEATURE(imaglist,    [  --enable-imaglist       use wxImageList class], wxUSE_IMAGLIST)
 944 WX_ARG_FEATURE(listbook,    [  --enable-listbook       use wxListbook class], wxUSE_LISTBOOK)
 945 WX_ARG_FEATURE(listbox,     [  --enable-listbox        use wxListBox class], wxUSE_LISTBOX)
 946 WX_ARG_FEATURE(listctrl,    [  --enable-listctrl       use wxListCtrl class], wxUSE_LISTCTRL)
 947 WX_ARG_FEATURE(notebook,    [  --enable-notebook       use wxNotebook class], wxUSE_NOTEBOOK)
 948 WX_ARG_FEATURE(notifmsg,    [  --enable-notifmsg       use wxNotificationMessage class], wxUSE_NOTIFICATION_MESSAGE)
 949 WX_ARG_FEATURE(odcombobox,  [  --enable-odcombobox     use wxOwnerDrawnComboBox class], wxUSE_ODCOMBOBOX)
 950 WX_ARG_FEATURE(radiobox,    [  --enable-radiobox       use wxRadioBox class], wxUSE_RADIOBOX)
 951 WX_ARG_FEATURE(radiobtn,    [  --enable-radiobtn       use wxRadioButton class], wxUSE_RADIOBTN)
 952 WX_ARG_FEATURE(sash,        [  --enable-sash           use wxSashWindow class], wxUSE_SASH)
 953 WX_ARG_FEATURE(scrollbar,   [  --enable-scrollbar      use wxScrollBar class and scrollable windows], wxUSE_SCROLLBAR)
 954 WX_ARG_FEATURE(searchctrl,  [  --enable-searchctrl     use wxSearchCtrl class], wxUSE_SEARCHCTRL)
 955 WX_ARG_FEATURE(slider,      [  --enable-slider         use wxSlider class], wxUSE_SLIDER)
 956 WX_ARG_FEATURE(spinbtn,     [  --enable-spinbtn        use wxSpinButton class], wxUSE_SPINBTN)
 957 WX_ARG_FEATURE(spinctrl,    [  --enable-spinctrl       use wxSpinCtrl class], wxUSE_SPINCTRL)
 958 WX_ARG_FEATURE(splitter,    [  --enable-splitter       use wxSplitterWindow class], wxUSE_SPLITTER)
 959 WX_ARG_FEATURE(statbmp,     [  --enable-statbmp        use wxStaticBitmap class], wxUSE_STATBMP)
 960 WX_ARG_FEATURE(statbox,     [  --enable-statbox        use wxStaticBox class], wxUSE_STATBOX)
 961 WX_ARG_FEATURE(statline,    [  --enable-statline       use wxStaticLine class], wxUSE_STATLINE)
 962 WX_ARG_FEATURE(stattext,    [  --enable-stattext       use wxStaticText class], wxUSE_STATTEXT)
 963 WX_ARG_FEATURE(statusbar,   [  --enable-statusbar      use wxStatusBar class], wxUSE_STATUSBAR)
 964 WX_ARG_FEATURE(tabdialog,   [  --enable-tabdialog      use wxTabControl class], wxUSE_TAB_DIALOG)
 965 WX_ARG_FEATURE(taskbaricon, [  --enable-taskbaricon    use wxTaskBarIcon class], wxUSE_TASKBARICON)
 966 WX_ARG_FEATURE(textctrl,    [  --enable-textctrl       use wxTextCtrl class], wxUSE_TEXTCTRL)
 967 WX_ARG_FEATURE(togglebtn,   [  --enable-togglebtn      use wxToggleButton class], wxUSE_TOGGLEBTN)
 968 WX_ARG_FEATURE(toolbar,     [  --enable-toolbar        use wxToolBar class], wxUSE_TOOLBAR)
 969 WX_ARG_FEATURE(tbarnative,  [  --enable-tbarnative     use native wxToolBar class], wxUSE_TOOLBAR_NATIVE)
 970 WX_ARG_FEATURE(treebook,    [  --enable-treebook       use wxTreebook class], wxUSE_TREEBOOK)
 971 WX_ARG_FEATURE(toolbook,    [  --enable-toolbook       use wxToolbook class], wxUSE_TOOLBOOK)
 972 WX_ARG_FEATURE(treectrl,    [  --enable-treectrl       use wxTreeCtrl class], wxUSE_TREECTRL)
 973 WX_ARG_FEATURE(tipwindow,   [  --enable-tipwindow      use wxTipWindow class], wxUSE_TIPWINDOW)
 974 WX_ARG_FEATURE(popupwin,    [  --enable-popupwin       use wxPopUpWindow class], wxUSE_POPUPWIN)
 975
 976 dnl ---------------------------------------------------------------------------
 977 dnl common dialogs
 978 dnl ---------------------------------------------------------------------------
 979
 980 WX_ARG_FEATURE(commondlg,   [  --enable-commondlg      use all common dialogs], wxUSE_COMMONDLGS)
 981 WX_ARG_FEATURE(aboutdlg,    [  --enable-aboutdlg       use wxAboutBox], wxUSE_ABOUTDLG)
 982 WX_ARG_FEATURE(choicedlg,   [  --enable-choicedlg      use wxChoiceDialog], wxUSE_CHOICEDLG)
 983 WX_ARG_FEATURE(coldlg,      [  --enable-coldlg         use wxColourDialog], wxUSE_COLOURDLG)
 984 WX_ARG_FEATURE(filedlg,     [  --enable-filedlg        use wxFileDialog], wxUSE_FILEDLG)
 985 WX_ARG_FEATURE(finddlg,     [  --enable-finddlg        use wxFindReplaceDialog], wxUSE_FINDREPLDLG)
 986 WX_ARG_FEATURE(fontdlg,     [  --enable-fontdlg        use wxFontDialog], wxUSE_FONTDLG)
 987 WX_ARG_FEATURE(dirdlg,      [  --enable-dirdlg         use wxDirDialog], wxUSE_DIRDLG)
 988 WX_ARG_FEATURE(msgdlg,      [  --enable-msgdlg         use wxMessageDialog], wxUSE_MSGDLG)
 989 WX_ARG_FEATURE(numberdlg,   [  --enable-numberdlg      use wxNumberEntryDialog], wxUSE_NUMBERDLG)
 990 WX_ARG_FEATURE(splash,      [  --enable-splash         use wxSplashScreen], wxUSE_SPLASH)
 991 WX_ARG_FEATURE(textdlg,     [  --enable-textdlg        use wxTextDialog], wxUSE_TEXTDLG)
 992 WX_ARG_FEATURE(tipdlg,      [  --enable-tipdlg         use startup tips], wxUSE_STARTUP_TIPS)
 993 WX_ARG_FEATURE(progressdlg, [  --enable-progressdlg    use wxProgressDialog], wxUSE_PROGRESSDLG)
 994 WX_ARG_FEATURE(wizarddlg,   [  --enable-wizarddlg      use wxWizard], wxUSE_WIZARDDLG)
 995
 996 dnl ---------------------------------------------------------------------------
 997 dnl misc GUI options
 998 dnl ---------------------------------------------------------------------------
 999
1000 WX_ARG_FEATURE(menus,       [  --enable-menus          use wxMenu/wxMenuBar/wxMenuItem classes], wxUSE_MENUS)
1001 WX_ARG_FEATURE(miniframe,   [  --enable-miniframe      use wxMiniFrame class], wxUSE_MINIFRAME)
1002 WX_ARG_FEATURE(tooltips,    [  --enable-tooltips       use wxToolTip class], wxUSE_TOOLTIPS)
1003 WX_ARG_FEATURE(splines,     [  --enable-splines        use spline drawing code], wxUSE_SPLINES)
1004 WX_ARG_FEATURE(mousewheel,  [  --enable-mousewheel     use mousewheel], wxUSE_MOUSEWHEEL)
1005 WX_ARG_FEATURE(validators,  [  --enable-validators     use wxValidator and derived classes], wxUSE_VALIDATORS)
1006 WX_ARG_FEATURE(busyinfo,    [  --enable-busyinfo       use wxBusyInfo], wxUSE_BUSYINFO)
1007 WX_ARG_FEATURE(joystick,    [  --enable-joystick       use wxJoystick], wxUSE_JOYSTICK)
1008 WX_ARG_FEATURE(metafile,    [  --enable-metafiles      use wxMetaFile (Win32 only)], wxUSE_METAFILE)
1009 WX_ARG_FEATURE(dragimage,   [  --enable-dragimage      use wxDragImage], wxUSE_DRAGIMAGE)
1010 WX_ARG_FEATURE(accessibility,[  --enable-accessibility  enable accessibility support], wxUSE_ACCESSIBILITY)
1011
1012 dnl ---------------------------------------------------------------------------
1013 dnl support for image formats that do not rely on external library
1014 dnl ---------------------------------------------------------------------------
1015
1016 WX_ARG_FEATURE(palette,     [  --enable-palette        use wxPalette class], wxUSE_PALETTE)
1017 WX_ARG_FEATURE(image,       [  --enable-image          use wxImage class], wxUSE_IMAGE)
1018 WX_ARG_FEATURE(gif,         [  --enable-gif            use gif images (GIF file format)], wxUSE_GIF)
1019 WX_ARG_FEATURE(pcx,         [  --enable-pcx            use pcx images (PCX file format)], wxUSE_PCX)
1020 WX_ARG_FEATURE(tga,         [  --enable-tga            use tga images (TGA file format)], wxUSE_TGA)
1021 WX_ARG_FEATURE(iff,         [  --enable-iff            use iff images (IFF file format)], wxUSE_IFF)
1022 WX_ARG_FEATURE(pnm,         [  --enable-pnm            use pnm images (PNM file format)], wxUSE_PNM)
1023 WX_ARG_FEATURE(xpm,         [  --enable-xpm            use xpm images (XPM file format)], wxUSE_XPM)
1024 WX_ARG_FEATURE(ico_cur,     [  --enable-ico_cur        use Windows ICO and CUR formats], wxUSE_ICO_CUR)
1025
1026 dnl ---------------------------------------------------------------------------
1027 dnl wxMSW-only options
1028 dnl ---------------------------------------------------------------------------
1029
1030 WX_ARG_FEATURE(dccache,     [  --enable-dccache        cache temporary wxDC objects (Win32 only)], wxUSE_DC_CACHEING)
1031 WX_ARG_FEATURE(ps-in-msw,   [  --enable-ps-in-msw      use PS printing in wxMSW (Win32 only)], wxUSE_POSTSCRIPT_ARCHITECTURE_IN_MSW)
1032 WX_ARG_FEATURE(ownerdrawn,  [  --enable-ownerdrawn     use owner drawn controls (Win32 and OS/2 only)], wxUSE_OWNER_DRAWN)
1033 WX_ARG_FEATURE(uxtheme,     [  --enable-uxtheme        enable support for Windows XP themed look (Win32 only)], wxUSE_UXTHEME)
1034 WX_ARG_FEATURE(wxdib,       [  --enable-wxdib          use wxDIB class (Win32 only)], wxUSE_DIB)
1035
1036 dnl this one is not really MSW-specific but it exists mainly to be turned off
1037 dnl under MSW, it should be off by default on the other platforms
1038 if test "$wxUSE_MSW" != 1; then
1039     DEFAULT_wxUSE_AUTOID_MANAGEMENT=no
1040 fi
1041
1042 WX_ARG_FEATURE(autoidman,   [  --enable-autoidman      use automatic ids management], wxUSE_AUTOID_MANAGEMENT)
1043
1044 fi
1045 dnl for GUI only
1046
1047 dnl ---------------------------------------------------------------------------
1048 dnl Checks for programs
1049 dnl ---------------------------------------------------------------------------
1050
1051 dnl flush the cache because checking for programs might abort
1052 AC_CACHE_SAVE
1053
1054 dnl C-compiler checks
1055 dnl   defines CC with the compiler to use
1056 dnl   defines GCC with yes if using gcc
1057 dnl   defines GCC empty if not using gcc
1058 dnl   defines CFLAGS
1059 dnl
1060 dnl this magic incantation is needed to prevent AC_PROG_CC from setting the
1061 dnl default CFLAGS (something like "-g -O2") -- we don't need this as we add
1062 dnl -g and -O flags ourselves below
1063 CFLAGS=${CFLAGS:=}
1064 AC_BAKEFILE_PROG_CC
1065
1066 dnl is -traditional needed for correct compilations
1067 dnl   adds -traditional for gcc if needed
1068 AC_PROG_GCC_TRADITIONAL
1069
1070 dnl C++-compiler checks
1071 dnl   defines CXX with the compiler to use
1072 dnl   defines GXX with yes if using gxx
1073 dnl   defines GXX empty if not using gxx
1074 dnl   defines CXXFLAGS
1075 dnl
1076 dnl see CFLAGS line above
1077 CXXFLAGS=${CXXFLAGS:=}
1078 AC_BAKEFILE_PROG_CXX
1079
1080 dnl configure always sets CXX to something as it falls back to g++ even if no
1081 dnl C++ compiler was found, but we prefer to abort now with a clear error
1082 dnl message rather than give errors about all tests failures below
1083 if test "$CXX" = "g++" -a "$GXX" != "yes"; then
1084     AC_MSG_ERROR([C++ compiler is needed to build wxWidgets])
1085 fi
1086
1087 dnl ar command
1088 dnl   defines AR with the appropriate command
1089 dnl
1090 dnl For Sun CC AC_BAKEFILE below sets AR to the compiler itself.
1091 if test "x$SUNCXX" != xyes; then
1092     AC_CHECK_TOOL(AR, ar)
1093     if test "x$AR" = "x" ; then
1094         AC_MSG_ERROR([ar is needed to build wxWidgets])
1095     fi
1096 fi
1097
1098 retest_macosx_linking=no
1099
1100 dnl Support the old --enable-universal_binary in case anyone was using it.
1101 #if test "$wxUSE_MAC" = 1; then
1102     if test "x$wxUSE_UNIVERSAL_BINARY" != xno ; then
1103         dnl --enable-universal_binary uses a default SDK (currently 10.4u)
1104         dnl --enable-universal_binary=SDK names a path to an SDK
1105         if test "x$wxUSE_UNIVERSAL_BINARY" == xyes; then
1106             # Implicitly turn on the new --with-macosx-sdk using the default
1107             # SDK which provides the behavior this option has always had.
1108             if test "x$wxUSE_MACOSX_SDK" = "x"; then
1109                 AC_MSG_WARN([Enabling default SDK due to --enable-universal_binary.])
1110                 AC_MSG_WARN([If you don't want this, specify --without-macosx-sdk])
1111                 wxUSE_MACOSX_SDK=yes
1112             fi
1113         else
1114             # Complain to user if he specified an argument to --enable-universal_binary
1115             # and also 1) specified --with-macosx-sdk using the default (yes) or
1116             # 2) specified --with-macosx-sdk using a path or 3) specified
1117             # --without-macosx-sdk (no).
1118             if test "x$wxUSE_MACOSX_SDK" != "x" ; then
1119                 AC_MSG_FAILURE([Please specify the new --with-macosx-sdk=PATH and do not specify an arg to --enable-universal_binary])
1120             else
1121                 # Put the SDK path into the wxUSE_MACOSX_SDK.  We don't have to
1122                 # special-case the empty string because the below test simply
1123                 # converts "no" to the empty string anyway.
1124                 wxUSE_MACOSX_SDK="$wxUSE_UNIVERSAL_BINARY"
1125                 dnl Warn about deprecated usage.
1126                 AC_MSG_WARN([Please use --with-macosx-sdk=PATH and --enable-universal_binary without an argument])
1127             fi
1128         fi
1129         dnl FIXME: I think it would be better to put this into CC, CXX, and LD rather than the flags.
1130         OSX_UNIV_OPTS="-arch ppc -arch i386"
1131         CXXFLAGS="$OSX_UNIV_OPTS $CXXFLAGS"
1132         CFLAGS="$OSX_UNIV_OPTS $CFLAGS"
1133         OBJCXXFLAGS="$OSX_UNIV_OPTS $OBJCXXFLAGS"
1134         OBJCFLAGS="$OSX_UNIV_OPTS $OBJCFLAGS"
1135         LDFLAGS="$OSX_UNIV_OPTS $LDFLAGS"
1136         dnl NOTE: Only the compiler driver needs arch flags.  The link editor
1137         dnl is incapable of using them but the compiler driver (which we use
1138         dnl as LD when building dynamic libraries) uses them to invoke the
1139         dnl real ld multiple times.  If we moved to libtool -dynamic we would
1140         dnl need no arch flags because libtool automatically invokes ld for
1141         dnl every architecture found in the fat input files.
1142         dnl
1143         dnl For static library builds, AR/RANLIB automatically create proper
1144         dnl fat archives although AR is unable to update them once RANLIB has
1145         dnl made them into proper fat archives.  Fortunately, our link process
1146         dnl simply removes the .a file before using ar to create a new one.
1147         dnl If we did move to libtool -static we still wouldn't need arch flags
1148         dnl because libtool automatically figures it out based on input.
1149         retest_macosx_linking=yes
1150
1151         dnl HACK: PCH could be made to work by precompiling for each architecture into separate directories
1152         dnl and including all architecture directories with each compiler invocation.
1153         dnl That would require a major rework of Bakefile and at the same time it would be nice to have
1154         dnl Objective-C++ precompiled headers.
1155         AC_MSG_WARN([Disabling precompiled headers due to universal binary build.])
1156         bk_use_pch=no
1157     fi
1158 #fi
1159
1160 dnl Set up the Mac OS X SDK.  We do this early so configure tests will occur
1161 dnl with the SDK in place.
1162 dnl NOTE: We clobber wxUSE_MACOSX_SDK with the SDK path
1163 if test "x$wxUSE_MACOSX_SDK" = "xno"; then
1164     wxUSE_MACOSX_SDK=
1165 elif test "x$wxUSE_MACOSX_SDK" = "xyes"; then
1166     # TODO: Search for most recent SDK and use it.
1167     wxUSE_MACOSX_SDK="/Developer/SDKs/MacOSX10.4u.sdk"
1168 fi
1169
1170
1171 if test "x$wxUSE_MACOSX_SDK" != "x"; then
1172     AC_MSG_CHECKING([for SDK directory $wxUSE_MACOSX_SDK])
1173     if ! test -d "$wxUSE_MACOSX_SDK"; then
1174         AC_MSG_FAILURE([not found])
1175     else
1176         AC_MSG_RESULT([exists])
1177     fi
1178     MACOSX_SDK_OPTS="-isysroot $wxUSE_MACOSX_SDK"
1179     eval "CC=\"$CC $MACOSX_SDK_OPTS\""
1180     eval "CXX=\"$CXX $MACOSX_SDK_OPTS\""
1181     eval "LD=\"$LD $MACOSX_SDK_OPTS\""
1182     retest_macosx_linking=yes
1183     dnl NOTE: When libtool is used in lieu of AR/RANLIB (i.e. in static mode)
1184     dnl the syslibroot makes no difference.  We aren't using libtool now but
1185     dnl if we ever did, be aware that you don't need to worry about it.
1186 fi
1187
1188 dnl Set up the deployment target
1189 dnl No   : Don't specify a min version even if using an SDK
1190 dnl Yes  : Use the version from the SDK if used, otherwise same as no
1191 dnl Param: Use the specified version
1192 if test "x$wxUSE_MACOSX_VERSION_MIN" = "xno"; then
1193     wxUSE_MACOSX_VERSION_MIN=
1194 elif test "x$wxUSE_MACOSX_VERSION_MIN" = "xyes"; then
1195     if test "x$wxUSE_MACOSX_SDK" != "x"; then
1196         AC_MSG_CHECKING([SDK deployment version])
1197 dnl We need to quote the next line where we don't need macros and do need [] in the regex
1198 [
1199         MACOSX_SDK_PLIST_VERSION_MIN=`defaults read "$wxUSE_MACOSX_SDK/SDKSettings" buildSettings | grep '^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}[^"]*"\{0,1\}; *$' | sed 's/^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}\([^"]*\)"\{0,1\} *; *$/\1/'`
1200 ]
1201         # If that failed, try again with the new key
1202         if test "x$MACOSX_SDK_PLIST_VERSION_MIN" == "x"; then
1203 [
1204             MACOSX_SDK_PLIST_VERSION_MIN=`defaults read "$wxUSE_MACOSX_SDK/SDKSettings" DefaultProperties | grep '^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}[^"]*"\{0,1\}; *$' | sed 's/^ *"\{0,1\}MACOSX_DEPLOYMENT_TARGET"\{0,1\} *= *"\{0,1\}\([^"]*\)"\{0,1\} *; *$/\1/'`
1205 ]
1206         fi
1207
1208         if test "x$MACOSX_SDK_PLIST_VERSION_MIN" != "x"; then
1209             wxUSE_MACOSX_VERSION_MIN=$MACOSX_SDK_PLIST_VERSION_MIN
1210             AC_MSG_RESULT([$wxUSE_MACOSX_VERSION_MIN])
1211         else
1212             AC_MSG_WARN([Could not determine deployment target from SDKSettings.plist])
1213             wxUSE_MACOSX_VERSION_MIN=
1214         fi
1215     else
1216         wxUSE_MACOSX_VERSION_MIN=
1217     fi
1218 elif test "x$wxUSE_MACOSX_VERSION_MIN" = "x"; then
1219     if test "$wxUSE_MAC" = 1; then
1220         # otherwise configure stops on leopard for universal_binary
1221         wxUSE_MACOSX_VERSION_MIN=10.4
1222     fi
1223 fi
1224
1225 if test "x$wxUSE_MACOSX_VERSION_MIN" != "x"; then
1226     MACOSX_VERSION_MIN_OPTS="-mmacosx-version-min=$wxUSE_MACOSX_VERSION_MIN"
1227     eval "CC=\"$CC $MACOSX_VERSION_MIN_OPTS\""
1228     eval "CXX=\"$CXX $MACOSX_VERSION_MIN_OPTS\""
1229     eval "LD=\"$LD $MACOSX_VERSION_MIN_OPTS\""
1230     retest_macosx_linking=yes
1231 fi
1232
1233 dnl If either an SDK or a version option was added, make sure that we can
1234 dnl still compile and link both C and C++.  If we didn't do this, then most
1235 dnl of the remaining tests would fail.
1236 if test "x$retest_macosx_linking" = "xyes"; then
1237     AC_LANG_PUSH(C)
1238     AC_MSG_CHECKING([if C compiler works with SDK/version options])
1239     AC_TRY_LINK([],[],[AC_MSG_RESULT([yes])],[AC_MSG_FAILURE([no.  Try a different SDK]); exit 1])
1240     AC_LANG_POP()
1241
1242     AC_LANG_PUSH(C++)
1243     AC_MSG_CHECKING([if C++ compiler works with SDK/version options])
1244     AC_TRY_LINK([],[],[AC_MSG_RESULT([yes])],[AC_MSG_FAILURE([no.  Try a different SDK]); exit 1])
1245     AC_LANG_POP()
1246 fi
1247
1248
1249 case "${host}" in
1250
1251     dnl The other BSD's should probably go in here too, since this is
1252     dnl to workaround a strange static lib BSDism.
1253     dnl Mac OS X install seems to ignore -p option...
1254     *-*-darwin* )
1255         INSTALL_PROGRAM="cp -fp"
1256         INSTALL_DATA="cp -fp"
1257         ;;
1258     *)
1259         ;;
1260 esac
1261
1262 dnl ------------------------------------------------------------------------
1263 dnl Platform specific tests
1264 dnl ------------------------------------------------------------------------
1265
1266 dnl xlC needs -qunique under AIX so that one source file can be
1267 dnl compiled to multiple object files and safely linked together.
1268 if test "x$XLCXX" = "xyes" -a "x$USE_AIX" = "x1"; then
1269     CXXFLAGS="-qunique $CXXFLAGS"
1270 fi
1271
1272 dnl This case is for PowerPC OS X vs. everything else
1273 case "${host}" in
1274   powerpc-*-darwin* )
1275     AC_MSG_CHECKING([if __POWERPC__ is already defined])
1276     AC_TRY_COMPILE([],[#ifndef __POWERPC__
1277         choke me for lack of PowerPC
1278 #endif
1279 ],
1280         [AC_MSG_RESULT([yes])],
1281         [AC_MSG_RESULT([no])
1282         AC_DEFINE(__POWERPC__)
1283     ])
1284   ;;
1285 esac
1286
1287 dnl This case is for OS X vs. everything else
1288 case "${host}" in
1289   *-*-darwin* )
1290     AC_MSG_CHECKING([if CoreFoundation/CFBase.h is usable])
1291     AC_TRY_COMPILE([#include <CoreFoundation/CFBase.h>
1292 ],[],
1293         [AC_MSG_RESULT([yes])],
1294         [AC_MSG_RESULT([no])
1295         AC_MSG_CHECKING([if __CF_USE_FRAMEWORK_INCLUDES__ is required])
1296         AC_TRY_COMPILE([#define __CF_USE_FRAMEWORK_INCLUDES__
1297 #include <CoreFoundation/CFBase.h>
1298         ],[],
1299         [AC_MSG_RESULT([yes])
1300         dnl We must use -D so source files that don't include wx/setup.h
1301         dnl but do include CFBase will work.
1302         CPPFLAGS="-D__CF_USE_FRAMEWORK_INCLUDES__ $CPPFLAGS"],
1303         [AC_MSG_FAILURE([no.  CoreFoundation not available.])]
1304         )
1305         ]
1306     )
1307   ;;
1308 esac
1309
1310 dnl Determine whether we want to use Cygwin as Windows or POSIX platform: the
1311 dnl latter makes more sense for wxGTK/Motif/X11 ports
1312 wants_win32=0
1313 doesnt_want_win32=0
1314 case "${host}" in
1315   *-*-cygwin*)
1316       if test "$wxUSE_MSW" = 1 ; then
1317         wants_win32=1
1318       else
1319         dnl when we use cygwin compiler with -mno-cygwin option it uses mingw32
1320         dnl headers and libraries, so it's Windows-like in this case
1321         AC_CACHE_CHECK([if -mno-cygwin is in effect], wx_cv_nocygwin,
1322             [
1323                 AC_TRY_COMPILE(
1324                     [],
1325                     [
1326                         #ifdef __MINGW32__
1327                             choke me
1328                         #endif
1329                     ],
1330                     wx_cv_nocygwin=no,
1331                     wx_cv_nocygwin=yes
1332                 )
1333             ]
1334         )
1335
1336         if test "$wx_cv_nocygwin" = "yes"; then
1337             wants_win32=1
1338         else
1339             doesnt_want_win32=1
1340         fi
1341       fi
1342       if test "$wants_win32" = 1 ; then
1343         BAKEFILE_FORCE_PLATFORM=win32
1344       fi
1345   ;;
1346   *-*-mingw*)
1347       wants_win32=1
1348   ;;
1349 esac
1350
1351 if test "$wxUSE_WINE" = "yes"; then
1352     wants_win32=1
1353     LDFLAGS_GUI="-mwindows"
1354 fi
1355
1356 dnl NB: The two tests bellow are *NOT* mutually exclusive! They should only
1357 dnl     take effect on Cygwin/Mingw and not other platforms.
1358 if test "$wants_win32" = 1 ; then
1359     USE_UNIX=0
1360     USE_WIN32=1
1361     AC_DEFINE(__WIN32__)
1362     AC_DEFINE(__WIN95__)
1363     AC_DEFINE(__WINDOWS__)
1364     AC_DEFINE(__GNUWIN32__)
1365     AC_DEFINE(STRICT)
1366 fi
1367 if test "$doesnt_want_win32" = 1 ; then
1368     USE_UNIX=1
1369     USE_WIN32=0
1370 fi
1371 dnl (end of Windows-only piece)
1372
1373 if test "$USE_UNIX" = 1 ; then
1374     wxUSE_UNIX=yes
1375     AC_DEFINE(__UNIX__)
1376 fi
1377
1378 dnl This case is for OS/2 vs. everything else
1379 case "${host}" in
1380   *-pc-os2_emx | *-pc-os2-emx )
1381       dnl ---------------------------------------------------------------------
1382       dnl When we are using gcc on OS/2, we want to be either using resources
1383       dnl (PM) or a more complete POSIX emulation for Motif/GTK+/X11.
1384       dnl Moreover we need to link explicitly against either stdcpp.a or
1385       dnl stdcxx.a (depending on compiler version), since we are using "gcc",
1386       dnl not "g++/c++".
1387       dnl ---------------------------------------------------------------------
1388       dnl (OS/2-only piece)
1389       if test "$wxUSE_MOTIF" = 1 -o "$wxUSE_GTK" = 1 -o "$wxUSE_X11" = 1; then
1390           dnl More complete Unix emulation for unix-like ports
1391           dnl by linking in POSIX/2's cExt (if available).
1392           AC_CHECK_LIB(cExt, drand48, LIBS="$LIBS -lcExt")
1393       else
1394           dnl Include resources for the "native" port (wxPM).
1395           RESPROGRAMOBJ="\${top_srcdir}/include/wx/os2/wx.res"
1396       fi
1397       dnl Check for the gcc version (and thereby for the C runtime library).
1398       dnl wx_cv_gccversion = EMX2 -> Standard EMX environment
1399       dnl wx_cv_gccversion = EMX3 -> EMX with gcc-3.0.3 or gcc-3.2.1
1400       dnl wx_cv_gccversion = Innotek5 -> gcc-3.2.2 with Innotek libc5
1401       dnl wx_cv_gccversion = Innotek6 -> gcc-3.3.5 with Innotek libc6.
1402       AC_CACHE_CHECK([for gcc/libc version], wx_cv_gccversion,[
1403           AC_TRY_RUN(
1404               dnl Check the gcc version macro.
1405               [
1406                   #include <stdio.h>
1407
1408                   int main()
1409                   {
1410                       FILE *f=fopen("conftestval", "w");
1411                       if (!f) exit(1);
1412                       fprintf(f,
1413                   #if (__GNUC__ < 3)
1414                               "EMX2"
1415                   #elif (__GNUC__==3) && ((__GNUC_MINOR__ < 2) || ((__GNUC_MINOR__==2) && (__GNUC_PATCHLEVEL__<2)))
1416                               "EMX3"
1417                   #elif (__GNUC__==3) && (__GNUC_MINOR__==2) && (__GNUC_PATCHLEVEL__==2)
1418                               "Innotek5"
1419                   #else
1420                               "Innotek6"
1421                   #endif
1422                       );
1423                       exit(0);
1424                   }
1425               ],
1426               wx_cv_gccversion=`cat conftestval`,
1427               wx_cv_gccversion="EMX2",
1428               dnl Compilation error: Assuming standard EMX environment
1429               wx_cv_gccversion="EMX2"
1430           )
1431       ])
1432       if test "$wx_cv_gccversion" = "EMX2"; then
1433           LIBS="$LIBS -lstdcpp"
1434           LDFLAGS="$LDFLAGS -Zsysv-signals"
1435       else
1436           if test "$wx_cv_gccversion" = "EMX3"; then
1437               LIBS="$LIBS -lstdcxx -lgcc"
1438               LDFLAGS="$LDFLAGS -Zsysv-signals"
1439           else
1440               LIBS="$LIBS -lstdc++"
1441           fi
1442       fi
1443       if test "$wxUSE_SHARED" = "yes" -a "$wxUSE_OMF" = "no"; then
1444         AC_MSG_WARN([Building DLLs requires OMF mode, enabled])
1445         wxUSE_OMF=yes
1446         enable_omf=yes
1447       fi
1448       dnl (end of OS/2-only piece)
1449   ;;
1450   *)
1451       dnl ---------------------------------------------------------------------
1452       dnl look for strcasecmp() in string.h and then strings.h if it's not
1453       dnl there. Don't do this on OS/2, where "stricmp" is the function to be
1454       dnl used.
1455       dnl ---------------------------------------------------------------------
1456       dnl (non-OS/2-only piece)
1457
1458       AC_CACHE_CHECK([for strcasecmp() in string.h], ac_cv_string_strcasecmp, [
1459           AC_TRY_LINK([
1460               #include <string.h>
1461               ],
1462               [
1463                   strcasecmp("foo", "bar");
1464               ],
1465               ac_cv_string_strcasecmp=yes,
1466               ac_cv_string_strcasecmp=no
1467           )
1468       ])
1469
1470       if test x"$ac_cv_string_strcasecmp" = "xyes"; then
1471           AC_DEFINE(HAVE_STRCASECMP_IN_STRING_H)
1472       else
1473           AC_CACHE_CHECK([for strcasecmp() in strings.h], ac_cv_strings_strcasecmp, [
1474               AC_TRY_LINK([
1475                   #include <strings.h>
1476                   ],
1477                   [
1478                       strcasecmp("foo", "bar");
1479                   ],
1480                   ac_cv_strings_strcasecmp=yes,
1481                   ac_cv_strings_strcasecmp=no
1482               )
1483           ])
1484
1485           if test x"$ac_cv_strings_strcasecmp" = "xyes"; then
1486               AC_DEFINE(HAVE_STRCASECMP_IN_STRINGS_H)
1487           else
1488               AC_MSG_ERROR([No case-insensitive string comparison function found.])
1489           fi
1490       fi
1491
1492       dnl (end of non-OS/2-only piece)
1493   ;;
1494 esac
1495
1496 dnl ------------------------------------------------------------------------
1497 dnl Check for headers
1498 dnl ------------------------------------------------------------------------
1499
1500 dnl Note: non-empty last parameter makes check compile-only,
1501 dnl   skipping worthless preprocessing check
1502 AC_CHECK_HEADERS(langinfo.h wchar.h,,, [AC_INCLUDES_DEFAULT])
1503
1504 dnl maybe wchar_t is in wcstr.h if we don't have wchar.h?
1505 if test "$ac_cv_header_wchar_h" != "yes"; then
1506     AC_CHECK_HEADERS([wcstr.h],,, [AC_INCLUDES_DEFAULT()])
1507 fi
1508
1509 case "${host}" in
1510   *-pc-os2_emx | *-pc-os2-emx )
1511       dnl Explicitly link -lintl if langinfo.h is available
1512       dnl and intl not yet included in libc
1513       if test $ac_cv_header_langinfo_h = "yes" \
1514                 -a \(   "$wx_cv_gccversion" = "EMX2" \
1515                      -o "$wx_cv_gccversion" = "EMX3" \
1516                      -o "$wx_cv_gccversion" = "Innotek5" \); then
1517           LIBS="$LIBS -lintl"
1518       fi
1519   ;;
1520 esac
1521
1522 dnl POSIX needs this for select(), but old systems don't have it
1523 if test "$USE_UNIX" = 1 ; then
1524     AC_CHECK_HEADERS([sys/select.h],,, [AC_INCLUDES_DEFAULT()])
1525 fi
1526
1527 dnl ---------------------------------------------------------------------------
1528 dnl Checks for compiler characteristics
1529 dnl ---------------------------------------------------------------------------
1530
1531 dnl defines const to be empty if c-compiler does not support const fully
1532 AC_C_CONST
1533 dnl defines inline to a sensible value for the c-compiler
1534 AC_C_INLINE
1535
1536 dnl check the sizes of integral types (give some reasonable default values for
1537 dnl cross-compiling)
1538 dnl   defines the size of certain types of variables in SIZEOF_<TYPE>
1539 AC_CHECK_SIZEOF(short, 2)
1540 AC_CHECK_SIZEOF(void *, 4)
1541 AC_CHECK_SIZEOF(int, 4)
1542 AC_CHECK_SIZEOF(long, 4)
1543 AC_CHECK_SIZEOF(size_t, 4)
1544
1545 case "${host}" in
1546     arm-*-linux* )
1547         AC_CHECK_SIZEOF(long long, 8)
1548     ;;
1549     *-hp-hpux* )
1550         AC_CHECK_SIZEOF(long long, 0)
1551         if test "$ac_cv_sizeof_long_long" != 0; then
1552             dnl HPUX 10.20 headers need this define in order to use long long definitions
1553             CPPFLAGS="-D_INCLUDE_LONGLONG $CPPFLAGS"
1554         fi
1555     ;;
1556     * )
1557         AC_CHECK_SIZEOF(long long, 0)
1558 esac
1559
1560 dnl SGI/Irix's stdio.h does not include wchar_t. Mac OS X does not provide
1561 dnl wchar.h and wchar_t is defined by stdlib.h (GD)
1562 AC_CHECK_SIZEOF(wchar_t, 0,
1563     [
1564         /* DJGPP's wchar_t is now a keyword in C++ (still not C though) */
1565         #if defined(__DJGPP__) && !( (__GNUC_MINOR__ >= 8 && __GNUC__ == 2 ) || __GNUC__ >= 3 )
1566         #  error "fake wchar_t"
1567         #endif
1568         #ifdef HAVE_WCHAR_H
1569         #  ifdef __CYGWIN__
1570         #    include <stddef.h>
1571         #  endif
1572         #  include <wchar.h>
1573         #endif
1574         #ifdef HAVE_STDLIB_H
1575         #  include <stdlib.h>
1576         #endif
1577         #include <stdio.h>
1578     ]
1579 )
1580 if test "$ac_cv_sizeof_wchar_t" != 0; then
1581     wxUSE_WCHAR_T=yes
1582 else
1583     wxUSE_WCHAR_T=no
1584 fi
1585
1586 dnl checks needed to define wxVaCopy
1587 AC_CACHE_CHECK([for va_copy],
1588     wx_cv_func_va_copy,
1589     [
1590         AC_LANG_PUSH(C++)
1591         AC_LINK_IFELSE([
1592             #include <stdarg.h>
1593             void foo(char *f, ...)
1594             {
1595                 va_list ap1, ap2;
1596                 va_start(ap1, f);
1597                 va_copy(ap2, ap1);
1598                 va_end(ap2);
1599                 va_end(ap1);
1600             }
1601             int main()
1602             {
1603                 foo("hi", 17);
1604                 return 0;
1605             }],
1606             wx_cv_func_va_copy=yes,
1607             wx_cv_func_va_copy=no
1608         )
1609         AC_LANG_POP()
1610     ]
1611 )
1612
1613 if test $wx_cv_func_va_copy = "yes"; then
1614     AC_DEFINE(HAVE_VA_COPY)
1615 else
1616     dnl try to understand how can we copy va_lists
1617     AC_CACHE_CHECK([if va_list can be copied by value],
1618         wx_cv_type_va_list_lvalue,
1619         [
1620             AC_RUN_IFELSE([
1621                 #include <stdarg.h>
1622                 int foo(char *f, ...)
1623                 {
1624                     va_list ap1, ap2;
1625                     va_start(ap1, f);
1626                     ap2 = ap1;
1627                     if ( va_arg(ap1, int) != 17 || va_arg(ap2, int) != 17 )
1628                         return 1;
1629                     va_end(ap2);
1630                     va_end(ap1);
1631                     return 0;
1632                 }
1633                 int main()
1634                 {
1635                     return foo("hi", 17);
1636                 }],
1637                 wx_cv_type_va_list_lvalue=yes,
1638                 wx_cv_type_va_list_lvalue=no,
1639                 dnl assume most common case for cross-compiling...
1640                 wx_cv_type_va_list_lvalue=yes
1641             )
1642         ]
1643     )
1644
1645     if test $wx_cv_type_va_list_lvalue != "yes"; then
1646         dnl we suppose that the only thing which can't be copied like this
1647         dnl are arrays... only experience will show whether this is really true
1648         AC_DEFINE(VA_LIST_IS_ARRAY)
1649     fi
1650 fi
1651
1652 dnl don't check for vararg macros if they're explicitly disabled: this is
1653 dnl useful if the user code using the library wants to limit itself to standard
1654 dnl C++ only (e.g. is compiled with g++ -std=c++98)
1655 if test "$wxUSE_VARARG_MACROS" = "yes"; then
1656
1657 dnl Check if variadic macros (C99 feature) are supported:
1658 AC_CACHE_CHECK(
1659     [whether the compiler supports variadic macros],
1660     [wx_cv_have_variadic_macros],
1661     [
1662         dnl C compiler might support variadic macros when C++ one doesn't
1663         dnl (happens with gcc/g++ 2.95.4), so must use C++ one explicitly
1664         AC_LANG_PUSH(C++)
1665         AC_COMPILE_IFELSE(
1666             AC_LANG_PROGRAM(
1667                 [
1668                     #include <stdio.h>
1669                     #define test(fmt, ...) printf(fmt, __VA_ARGS__)
1670                 ],
1671                 [
1672                     test("%s %d %p", "test", 1, 0);
1673                 ]
1674             ),
1675             [wx_cv_have_variadic_macros=yes],
1676             [wx_cv_have_variadic_macros=no]
1677             )
1678         AC_LANG_POP()
1679     ]
1680 )
1681
1682 if test $wx_cv_have_variadic_macros = "yes"; then
1683     AC_DEFINE(HAVE_VARIADIC_MACROS)
1684 fi
1685
1686 fi dnl wxUSE_VARARG_MACROS == yes
1687
1688 dnl check for large file support
1689 AC_SYS_LARGEFILE
1690
1691 dnl we need to define _FILE_OFFSET_BITS or _LARGE_FILES on the compiler command
1692 dnl line because otherwise the system headers risk being included before
1693 dnl wx/defs.h which defines these constants leading to inconsistent
1694 dnl sizeof(off_t) in different source files of the same program and linking
1695 dnl problems
1696 if test "x$wx_largefile" = "xyes"; then
1697     if test "x$ac_cv_sys_file_offset_bits" = "x64"; then
1698         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_FILE_OFFSET_BITS=64 -D_LARGE_FILES"
1699
1700         dnl We get "Large Files (ILP32) not supported in strict ANSI mode."
1701         dnl #error from HP standard headers unless __STDC_EXT__ is defined.
1702         dnl The compiler should define it automatically, but some old g++
1703         dnl versions don't define it, so test and add it if necessary. AFAIK
1704         dnl the problem only affects the C++ compiler so it is added to
1705         dnl CXXFLAGS only.
1706         if test "$USE_HPUX" = 1 -a "$GXX" = "yes"; then
1707             AC_CACHE_CHECK(
1708                 [if -D__STDC_EXT__ is required],
1709                 wx_cv_STDC_EXT_required,
1710                 [
1711                     AC_LANG_PUSH(C++)
1712                     AC_TRY_COMPILE(
1713                         [],
1714                         [
1715                             #ifndef __STDC_EXT__
1716                                 choke me
1717                             #endif
1718                         ],
1719                         wx_cv_STDC_EXT_required=no,
1720                         wx_cv_STDC_EXT_required=yes
1721                     )
1722                     AC_LANG_POP()
1723                 ]
1724             )
1725             if test "x$wx_cv_STDC_EXT_required" = "xyes"; then
1726                 WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -D__STDC_EXT__"
1727             fi
1728         fi
1729     else
1730         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_LARGE_FILES"
1731     fi
1732     dnl AC_FUNC_FSEEKO sets HAVE_FSEEKO and $ac_cv_sys_largefile_source
1733     AC_FUNC_FSEEKO
1734     if test "$ac_cv_sys_largefile_source" != no; then
1735         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_LARGEFILE_SOURCE=$ac_cv_sys_largefile_source"
1736     fi
1737 fi
1738
1739 dnl check for bytesex stuff (don't use AC_C_BIGENDIAN to allow cross-compiling)
1740 WX_C_BIGENDIAN
1741
1742 dnl check for iostream (as opposed to iostream.h) standard header
1743 WX_CPP_NEW_HEADERS(, AC_DEFINE(wxUSE_IOSTREAMH))
1744
1745 dnl check whether C++ compiler supports bool built-in type
1746 WX_CPP_BOOL
1747
1748 dnl check whether C++ compiler supports explicit keyword
1749 WX_CPP_EXPLICIT
1750
1751 dnl check whether C++ compiler supports C++ casts
1752 AC_CXX_CONST_CAST
1753 AC_CXX_REINTERPRET_CAST
1754 AC_CXX_STATIC_CAST
1755 dnl we don't use HAVE_DYNAMIC_CAST anywhere right now...
1756 dnl AC_CXX_DYNAMIC_CAST
1757
1758 dnl With Sun CC, temporaries have block scope by default. This flag is needed
1759 dnl to get the expression scope behaviour that conforms to the standard.
1760 if test "x$SUNCXX" = xyes; then
1761     CXXFLAGS="-features=tmplife $CXXFLAGS"
1762 fi
1763
1764 dnl Sun X11 headers are (still, in 2005!) non-ANSI and the best they could do
1765 dnl was to hack their C++ compiler to accept them silently -- but C compiler
1766 dnl still spits out dozens of warnings for each X include file, so suppress
1767 dnl them
1768 if test "x$SUNCC" = xyes; then
1769     CFLAGS="-erroff=E_NO_EXPLICIT_TYPE_GIVEN $CFLAGS"
1770 fi
1771
1772 dnl SGI mipsPro compiler gives this warning for "conversion from pointer to
1773 dnl same-sized integral type" even when there is an explicit cast and as there
1774 dnl is no way to turn it off and there are hundreds of these warnings in wx
1775 dnl sources, just turn it off for now
1776 dnl
1777 dnl a better long term solution would be to use #pragma set/reset woff in
1778 dnl wxPtrToUInt() and use it instead of casts elsewhere
1779 if test "x$SGICC" = "xyes"; then
1780     CFLAGS="-woff 3970 $CFLAGS"
1781 fi
1782 if test "x$SGICXX" = "xyes"; then
1783     CXXFLAGS="-woff 3970 $CXXFLAGS"
1784 fi
1785
1786 dnl HP-UX c89/aCC compiler warnings
1787 if test "x$HPCC" = "xyes"; then
1788     dnl 2011: "unrecognized preprocessor directive": nice warning but it's given
1789     dnl       even for directives inside #if which is not true (i.e. which are
1790     dnl       used for other compilers/OS) and so we have no way to get rid of it
1791     dnl 2450: "long long is non standard" -- yes, we know
1792     CFLAGS="+W 2011,2450 $CFLAGS"
1793 fi
1794 if test "x$HPCXX" = "xyes"; then
1795     dnl 2340: "value copied to temporary, reference to temporary used": very
1796     dnl       painful as triggered by any occurrence of user-defined conversion
1797     CXXFLAGS="+W 2340 $CXXFLAGS"
1798 fi
1799
1800 dnl DEC/Compaq/HP cxx warnings
1801 if test "x$COMPAQCXX" = "xyes"; then
1802     dnl -w0 enables all warnings, then we disable some of them:
1803     dnl basclsnondto: base class dtor non virtual (sometimes we do want this)
1804     dnl unrimpret:  "end of routine block may be unreachable" is given for
1805     dnl             every "if ( ) return ...; else return ...;"
1806     dnl intconlosbit: "conversion to integral type of smaller size could lose
1807     dnl               data" this is a useful warning but there are too many of
1808     dnl               them for now
1809     CXXFLAGS="-w0 -msg_disable basclsnondto,unrimpret,intconlosbit"
1810 fi
1811
1812 dnl the next few tests are all for C++ features and so need to be done using
1813 dnl C++ compiler
1814 AC_LANG_PUSH(C++)
1815
1816 dnl check for std::string or std::wstring
1817 if test "$wxUSE_STD_STRING" = "yes" -o "$wxUSE_STL" = "yes"; then
1818     if test "$wxUSE_UNICODE" = "yes"; then
1819         std_string="std::wstring"
1820         char_type="wchar_t"
1821     else
1822         std_string="std::string"
1823         char_type="char"
1824     fi
1825
1826     dnl check if <string> declares std::[w]string
1827     AC_CACHE_CHECK([for $std_string in <string>],
1828         wx_cv_class_stdstring,
1829         [
1830             AC_TRY_COMPILE([#include <string>],
1831                 [$std_string foo;],
1832                 wx_cv_class_stdstring=yes,
1833                 wx_cv_class_stdstring=no
1834             )
1835         ]
1836     )
1837
1838     if test "$wx_cv_class_stdstring" = yes; then
1839         if test "$wxUSE_UNICODE" = "yes"; then
1840             AC_DEFINE(HAVE_STD_WSTRING)
1841         fi
1842         dnl we don't need HAVE_STD_STRING, we just suppose it's available if
1843         dnl wxUSE_STD_STRING==yes
1844     else
1845         AC_CACHE_CHECK([if std::basic_string<$char_type> works],
1846             wx_cv_class_stdbasicstring,
1847             [
1848                 AC_TRY_COMPILE([
1849                     #ifdef HAVE_WCHAR_H
1850                     #  ifdef __CYGWIN__
1851                     #    include <stddef.h>
1852                     #  endif
1853                     #  include <wchar.h>
1854                     #endif
1855                     #ifdef HAVE_STDLIB_H
1856                     #  include <stdlib.h>
1857                     #endif
1858                     #include <stdio.h>
1859                     #include <string>
1860                     ],
1861                     [std::basic_string<$char_type> foo;
1862                      const $char_type* dummy = foo.c_str();],
1863                     wx_cv_class_stdbasicstring=yes,
1864                     wx_cv_class_stdbasicstring=no
1865                 )
1866             ]
1867         )
1868
1869         if test "$wx_cv_class_stdbasicstring" != yes; then
1870             if test "$wxUSE_STL" = "yes"; then
1871                 AC_MSG_ERROR([Can't use --enable-stl without $std_string or std::basic_string<$char_type>])
1872             elif test "$wxUSE_STD_STRING" = "yes"; then
1873                 AC_MSG_ERROR([Can't use --enable-std_string without $std_string or std::basic_string<$char_type>])
1874             else
1875                 AC_MSG_WARN([No $std_string or std::basic_string<$char_type>, switching to --disable-std_string])
1876                 wxUSE_STD_STRING=no
1877             fi
1878         fi
1879     fi
1880 fi
1881
1882 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
1883     AC_CHECK_TYPES([std::istream, std::ostream],,
1884                    [wxUSE_STD_IOSTREAM=no],
1885                    [#include <iostream>])
1886
1887     if test "$wxUSE_STD_IOSTREAM" != "yes"; then
1888         if test "$wxUSE_STD_IOSTREAM" = "yes"; then
1889             AC_MSG_ERROR([Can't use --enable-std_iostreams without std::istream and std::ostream])
1890         else
1891             AC_MSG_WARN([No std::iostreams, switching to --disable-std_iostreams])
1892         fi
1893     fi
1894 fi
1895
1896 if test "$wxUSE_STL" = "yes"; then
1897     dnl check for basic STL functionality
1898     AC_CACHE_CHECK([for basic STL functionality],
1899         wx_cv_lib_stl,
1900         [AC_TRY_COMPILE([#include <string>
1901             #include <functional>
1902             #include <algorithm>
1903             #include <vector>
1904             #include <list>],
1905             [std::vector<int> moo;
1906              std::list<int> foo;
1907              std::vector<int>::iterator it =
1908                  std::find_if(moo.begin(), moo.end(),
1909                               std::bind2nd(std::less<int>(), 3));],
1910             wx_cv_lib_stl=yes,
1911             wx_cv_lib_stl=no
1912         )]
1913     )
1914
1915     if test "$wx_cv_lib_stl" != yes; then
1916          AC_MSG_ERROR([Can't use --enable-stl as basic STL functionality is missing])
1917     fi
1918
1919     dnl check for compliant std::string::compare
1920     AC_CACHE_CHECK([for compliant std::string::compare],
1921         wx_cv_func_stdstring_compare,
1922         [AC_TRY_COMPILE([#include <string>],
1923             [std::string foo, bar;
1924             foo.compare(bar);
1925             foo.compare(1, 1, bar);
1926             foo.compare(1, 1, bar, 1, 1);
1927             foo.compare("");
1928             foo.compare(1, 1, "");
1929             foo.compare(1, 1, "", 2);],
1930             wx_cv_func_stdstring_compare=yes,
1931             wx_cv_func_stdstring_compare=no
1932         )]
1933     )
1934
1935     if test "$wx_cv_func_stdstring_compare" = yes; then
1936         AC_DEFINE(HAVE_STD_STRING_COMPARE)
1937     fi
1938
1939     if test "$wx_cv_class_gnuhashmapset" = yes; then
1940          AC_DEFINE(HAVE_EXT_HASH_MAP)
1941          AC_DEFINE(HAVE_GNU_CXX_HASH_MAP)
1942     fi
1943
1944     AC_CHECK_HEADER([unordered_map],
1945         [AC_CACHE_CHECK([for unordered_map and unordered_set in std],
1946             wx_cv_class_stdunorderedmapset,
1947             [AC_TRY_COMPILE([#include <unordered_map>
1948                 #include <unordered_set>],
1949                 [std::unordered_map<double*, char*> test1;
1950                  std::unordered_set<char*> test2;],
1951                 wx_cv_class_stdunorderedmapset=yes,
1952                 wx_cv_class_stdunorderedmapset=no)
1953             ]
1954         )],
1955         [],
1956         [ ]
1957     )
1958
1959     if test "$wx_cv_class_stdunorderedmapset" = yes; then
1960          AC_DEFINE(HAVE_STD_UNORDERED_MAP)
1961          AC_DEFINE(HAVE_STD_UNORDERED_SET)
1962     else
1963         AC_CHECK_HEADER([tr1/unordered_map],
1964             [AC_CACHE_CHECK([for unordered_map and unordered_set in std::tr1],
1965                 wx_cv_class_tr1unorderedmapset,
1966                 [AC_TRY_COMPILE([#include <tr1/unordered_map>
1967                     #include <tr1/unordered_set>],
1968                     [std::tr1::unordered_map<double*, char*> test1;
1969                      std::tr1::unordered_set<char*> test2;
1970             #if defined(__GNUC__) && (__GNUC__==4) && (__GNUC_MINOR__<2)
1971             #error can't use unordered_{map,set} with gcc-4.[01]: http://gcc.gnu.org/PR24389
1972             #endif],
1973                     wx_cv_class_tr1unorderedmapset=yes,
1974                     wx_cv_class_tr1unorderedmapset=no)
1975                 ]
1976             )],
1977             [],
1978             [ ]
1979         )
1980
1981         if test "$wx_cv_class_tr1unorderedmapset" = yes; then
1982             AC_DEFINE(HAVE_TR1_UNORDERED_MAP)
1983             AC_DEFINE(HAVE_TR1_UNORDERED_SET)
1984         else
1985             dnl check for hash_map and hash_set headers
1986             AC_CHECK_HEADER([hash_map],
1987                 [AC_CACHE_CHECK([for std::hash_map and hash_set],
1988                     wx_cv_class_stdhashmapset,
1989                     [AC_TRY_COMPILE([#include <hash_map>
1990                         #include <hash_set>],
1991                         [std::hash_map<double*, char*, std::hash<double*>, std::equal_to<double*> > test1;
1992                          std::hash_set<char*, std::hash<char*>, std::equal_to<char*> > test2;],
1993                         wx_cv_class_stdhashmapset=yes,
1994                         wx_cv_class_stdhashmapset=no)
1995                     ]
1996                 )],
1997                 [],
1998                 [ ]
1999             )
2000
2001             if test "$wx_cv_class_stdhashmapset" = yes; then
2002                 AC_DEFINE(HAVE_HASH_MAP)
2003                 AC_DEFINE(HAVE_STD_HASH_MAP)
2004             fi
2005
2006             AC_CHECK_HEADER([ext/hash_map],
2007                 [AC_CACHE_CHECK([for GNU hash_map and hash_set],
2008                     wx_cv_class_gnuhashmapset,
2009                     [AC_TRY_COMPILE([#include <ext/hash_map>
2010                         #include <ext/hash_set>],
2011                         [__gnu_cxx::hash_map<double*, char*, __gnu_cxx::hash<double*>, std::equal_to<double*> > test1;
2012                          __gnu_cxx::hash_set<char*, __gnu_cxx::hash<char*>, std::equal_to<char*> > test2;],
2013                         wx_cv_class_gnuhashmapset=yes,
2014                         wx_cv_class_gnuhashmapset=no)
2015                     ]
2016                 )],
2017                 [],
2018                 [ ]
2019             )
2020
2021         fi
2022     fi
2023 fi
2024
2025 dnl check for atomic operations builtins for wx/atomic.h:
2026 WX_ATOMIC_BUILTINS
2027
2028 dnl pop C++
2029 AC_LANG_POP()
2030
2031 dnl ---------------------------------------------------------------------------
2032 dnl Define search path for includes and libraries: all headers and libs will be
2033 dnl looked for in all directories of this path
2034 dnl ---------------------------------------------------------------------------
2035
2036 dnl Notice that /usr/include should *not* be in this list, otherwise it breaks
2037 dnl compilation on Solaris/AIX/... with gcc because standard (non ANSI C)
2038 dnl headers are included instead of the "fixed" (ANSI-fied) gcc ones.
2039 dnl
2040 dnl Also try to put all directories which may contain X11R6 before those which
2041 dnl may contain X11R5/4 - we want to use R6 on machines which have both!
2042 dnl
2043 dnl In the same vein. Motif 2.1 should be tried before Motif 1.2 for the
2044 dnl systems which have both (AIX 4.x does)
2045 SEARCH_INCLUDE="\
2046     /usr/local/include        \
2047     /usr/local/X11/include    \
2048     /usr/local/include/X11    \
2049     /usr/local/X11R6/include  \
2050     /usr/local/include/X11R6  \
2051                               \
2052     /usr/Motif-2.1/include    \
2053     /usr/Motif-1.2/include    \
2054     /usr/include/Motif1.2     \
2055                               \
2056     /usr/dt/include           \
2057     /usr/openwin/include      \
2058                               \
2059     /usr/include/Xm           \
2060                               \
2061     /usr/X11R6/include        \
2062     /usr/X11R6.4/include      \
2063                               \
2064     /usr/include/X11R6        \
2065                               \
2066     /usr/X11/include          \
2067     /usr/include/X11          \
2068                               \
2069     /usr/XFree86/include/X11  \
2070     /usr/pkg/include          \
2071                               \
2072     /usr/local/X1R5/include  \
2073     /usr/local/include/X11R5  \
2074     /usr/X11R5/include        \
2075     /usr/include/X11R5        \
2076                               \
2077     /usr/local/X11R4/include  \
2078     /usr/local/include/X11R4  \
2079     /usr/X11R4/include        \
2080     /usr/include/X11R4        \
2081                               \
2082     /usr/openwin/share/include"
2083
2084 dnl try to find out the standard lib locations for the systems with multiple
2085 dnl ABIs
2086 AC_MSG_CHECKING([for libraries directory])
2087
2088 case "${host}" in
2089     *-*-irix6* )
2090         AC_CACHE_VAL(
2091             wx_cv_std_libpath,
2092             [
2093                 for d in WX_STD_LIBPATH(); do
2094                     for e in a so sl dylib dll.a; do
2095                         libc="$d/libc.$e"
2096                         if test -f $libc; then
2097                             save_LIBS="$LIBS"
2098                             LIBS="$libc"
2099                             AC_LINK_IFELSE([int main() { return 0; }],
2100                                 wx_cv_std_libpath=`echo $d | sed s@/usr/@@`)
2101                             LIBS="$save_LIBS"
2102                             if test "x$wx_cv_std_libpath" != "x"; then
2103                                 break 2
2104                             fi
2105                         fi
2106                     done
2107                 done
2108                 if test "x$wx_cv_std_libpath" = "x"; then
2109                     wx_cv_std_libpath="lib"
2110                 fi
2111             ]
2112         )
2113         ;;
2114
2115     *-*-solaris2* )
2116         dnl use ../lib or ../lib/64 depending on the size of void*
2117         if test "$ac_cv_sizeof_void_p" = 8 -a -d "/usr/lib/64"; then
2118             wx_cv_std_libpath="lib/64"
2119         else
2120             wx_cv_std_libpath="lib"
2121         fi
2122         ;;
2123
2124     *-*-linux* )
2125         dnl use ../lib or ../lib64 depending on the size of void*
2126         if test "$ac_cv_sizeof_void_p" = 8 -a \
2127                 -d "/usr/lib64" -a ! -h "/usr/lib64"; then
2128             wx_cv_std_libpath="lib64"
2129         else
2130             wx_cv_std_libpath="lib"
2131         fi
2132         ;;
2133
2134     *)
2135         wx_cv_std_libpath="lib";
2136         ;;
2137 esac
2138
2139 AC_MSG_RESULT($wx_cv_std_libpath)
2140
2141 SEARCH_LIB="`echo "$SEARCH_INCLUDE" | sed s@include@$wx_cv_std_libpath@g` /usr/$wx_cv_std_libpath"
2142
2143 dnl Cross compiling with gcc?
2144 if test "$build" != "$host" -a "$GCC" = yes; then
2145     dnl for gcc cross-compilers "$CC -print-prog-name=ld" prints the path to
2146     dnl the linker. Stripping off the trailing '/bin/ld' gives us a candiate
2147     dnl for a 'root' below which libraries and headers for the target system
2148     dnl might be installed.
2149     if cross_root=`$CC -print-prog-name=ld 2>/dev/null`; then
2150         cross_root=`dirname $cross_root`
2151         cross_root=`dirname $cross_root`
2152
2153         dnl substitute this candiate root for '^/usr' in the search lists,
2154         dnl strip out any that don't start '^/usr'.
2155         SEARCH_LIB=`for x in $SEARCH_LIB; do echo $x; done | sed -ne "s|^/usr|$cross_root|p"`
2156         SEARCH_INCLUDE=`for x in $SEARCH_INCLUDE; do echo $x; done | sed -ne "s|^/usr|$cross_root|p"`
2157         SEARCH_INCLUDE="$SEARCH_INCLUDE $cross_root/include"
2158
2159         dnl also have pkg-config search for *.pc files under this 'root'
2160         if test -z "$PKG_CONFIG_PATH"; then
2161             PKG_CONFIG_PATH="$cross_root/local/lib/pkgconfig:$cross_root/lib/pkgconfig"
2162             export PKG_CONFIG_PATH
2163         fi
2164
2165         dnl AC_PATH_XTRA doesn't work currently unless -x-includes and
2166         dnl -x-libraries are given on the command line. So if they are not
2167         dnl set then set them here to plausible defaults.
2168         if test -z "$x_includes" -o "$x_includes" = NONE; then
2169             WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, X11/Intrinsic.h)
2170             x_includes=$ac_find_includes
2171         fi
2172         if test -z "$x_libraries" -o "$x_libraries" = NONE; then
2173             WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xt)
2174             x_libraries=$ac_find_libraries
2175         fi
2176     fi
2177 fi
2178
2179 dnl ------------------------------------------------------------------------
2180 dnl Check for libraries
2181 dnl ------------------------------------------------------------------------
2182
2183 dnl flush the cache because checking for libraries below might abort
2184 AC_CACHE_SAVE
2185
2186 dnl check for glibc version
2187 dnl
2188 dnl VZ: I have no idea why had this check been there originally, but now
2189 dnl     we could probably do without it by just always adding _GNU_SOURCE
2190 if test "$USE_LINUX" = 1 -o "$USE_GNU" = 1; then
2191     AC_CACHE_CHECK([for glibc 2.1 or later], wx_cv_lib_glibc21,[
2192         AC_TRY_COMPILE([#include <features.h>],
2193             [
2194                 #if (__GLIBC__ < 2) || (__GLIBC_MINOR__ < 1)
2195                 not glibc 2.1
2196                 #endif
2197             ],
2198             [
2199                 wx_cv_lib_glibc21=yes
2200             ],
2201             [
2202                 wx_cv_lib_glibc21=no
2203             ]
2204         )
2205     ])
2206     if test "$wx_cv_lib_glibc21" = "yes"; then
2207         AC_DEFINE(wxHAVE_GLIBC2)
2208     fi
2209 fi
2210
2211 dnl we may need _GNU_SOURCE for 2 things:
2212 dnl
2213 dnl  1. to get PTHREAD_MUTEX_RECURSIVE with glibc 2.1+ (strictly speaking we
2214 dnl  only need _XOPEN_SOURCE=500 but just defining this disables _BSD_SOURCE
2215 dnl  which breaks libtiff compilation, so it is simpler to just define
2216 dnl  _GNU_SOURCE to get everything)
2217 dnl
2218 dnl  2. for Unicode functions
2219 if test "x$wx_cv_lib_glibc21" = "xyes"; then
2220     if test "$wxUSE_UNICODE" = "yes" -o "$wxUSE_THREADS" = "yes"; then
2221         AC_DEFINE(_GNU_SOURCE)
2222     fi
2223 fi
2224
2225 dnl Only add the -lm library if floating point functions cannot be used
2226 dnl without it.  This check is important on cygwin because of the bizarre
2227 dnl way that they have organized functions into libraries.  On cygwin, both
2228 dnl libc.a and libm.a are symbolic links to a single lib libcygwin.a.  This
2229 dnl means that
2230 dnl   1) linking with -lm is not necessary, and
2231 dnl   2) linking with -lm is dangerous if the order of libraries is wrong
2232 dnl In particular, if you compile any program with -mno-cygwin and link with
2233 dnl -lm, it will crash instantly when it is run.  This happens because the
2234 dnl linker incorrectly links the Cygwin libm.a (==libcygwin.a), which replaces
2235 dnl the ___main function instead of allowing it to be defined by
2236 dnl /usr/lib/mingw/libmingw32.a as it should be.
2237 dnl
2238 dnl On MacOS X, this test will find that -lm is unnecessary and leave it out.
2239 dnl
2240 dnl Just check a few floating point functions. If they are all found without
2241 dnl -lm, then we must not need -lm.
2242 have_cos=0
2243 have_floor=0
2244 AC_CHECK_FUNCS(cos, have_cos=1)
2245 AC_CHECK_FUNCS(floor, have_floor=1)
2246 AC_MSG_CHECKING(if floating point functions link without -lm)
2247 if test "$have_cos" = 1 -a "$have_floor" = 1; then
2248     AC_MSG_RESULT(yes)
2249 else
2250     AC_MSG_RESULT(no)
2251     LIBS="$LIBS -lm"
2252     # use different functions to avoid configure caching
2253     have_sin=0
2254     have_ceil=0
2255     AC_CHECK_FUNCS(sin, have_sin=1)
2256     AC_CHECK_FUNCS(ceil, have_ceil=1)
2257     AC_MSG_CHECKING(if floating point functions link with -lm)
2258     if test "$have_sin" = 1 -a "$have_ceil" = 1; then
2259         AC_MSG_RESULT(yes)
2260     else
2261         AC_MSG_RESULT(no)
2262         # not sure we should warn the user, crash, etc.
2263     fi
2264 fi
2265
2266 dnl check for C99 string to long long conversion functions, assume that if we
2267 dnl have the unsigned variants, then we have the signed ones as well
2268 dnl
2269 dnl at least under SGI these functions are only available in C99 code and not
2270 dnl in C++ so do these tests using C++ compiler
2271 AC_LANG_PUSH(C++)
2272 if test "wxUSE_UNICODE" = "yes"; then
2273     WX_CHECK_FUNCS(wcstoull)
2274 else
2275     WX_CHECK_FUNCS(strtoull)
2276 fi
2277 AC_LANG_POP()
2278
2279 dnl ---------------------------------------------------------------------------
2280 dnl Optional libraries
2281 dnl
2282 dnl   --with-<lib>=sys
2283 dnl       looks for system library and fails if not found
2284 dnl
2285 dnl   --with-<lib>
2286 dnl   --with-<lib>=yes
2287 dnl       looks for system library and, if not found, prints a warning,
2288 dnl       falls back to the builtin wx version, and continues configuration
2289 dnl
2290 dnl   --with-<lib>=builtin
2291 dnl       uses builtin wx version without searching for system library
2292 dnl
2293 dnl   --with-<lib>=no
2294 dnl   --without-<lib>
2295 dnl       do not use library (neither system nor builtin wx version)
2296 dnl
2297 dnl ---------------------------------------------------------------------------
2298
2299 dnl ------------------------------------------------------------------------
2300 dnl Check for regex libraries
2301 dnl ------------------------------------------------------------------------
2302
2303 if test "$wxUSE_REGEX" != "no"; then
2304     AC_DEFINE(wxUSE_REGEX)
2305
2306     if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_REGEX" = "yes"; then
2307         AC_MSG_WARN([Defaulting to the builtin regex library for Unicode build.])
2308         wxUSE_REGEX=builtin
2309     fi
2310
2311     if test "$wxUSE_REGEX" = "sys" -o "$wxUSE_REGEX" = "yes" ; then
2312         dnl according to Unix 98 specs, regcomp() is in libc but I believe that
2313         dnl on some old systems it may be in libregex - check for it too?
2314         AC_CHECK_HEADER(regex.h, [AC_CHECK_FUNCS(regcomp re_search)],, [ ])
2315
2316         if test "x$ac_cv_func_regcomp" != "xyes"; then
2317             if test "$wxUSE_REGEX" = "sys" ; then
2318                 AC_MSG_ERROR([system regex library not found! Use --with-regex to use built-in version])
2319             else
2320                 AC_MSG_WARN([system regex library not found, will use built-in instead])
2321                 wxUSE_REGEX=builtin
2322             fi
2323         else
2324             dnl we are using the system library
2325             wxUSE_REGEX=sys
2326             dnl only the built-in supports advanced REs
2327             AC_DEFINE(WX_NO_REGEX_ADVANCED)
2328         fi
2329     fi
2330 fi
2331
2332 dnl ------------------------------------------------------------------------
2333 dnl Check for zlib compression library
2334 dnl ------------------------------------------------------------------------
2335
2336 ZLIB_LINK=
2337 if test "$wxUSE_ZLIB" != "no" ; then
2338     AC_DEFINE(wxUSE_ZLIB)
2339
2340     if test "$wxUSE_ZLIB" = "sys" -o "$wxUSE_ZLIB" = "yes" ; then
2341         dnl don't test for zlib under Mac -- its verson there is 1.1.3 but we
2342         dnl should still use it because hopefully (can someone confirm this?)
2343         dnl Apple did fix the security problem in it and not using the system
2344         dnl library results in a whole bunch of warnings when linking with
2345         dnl Carbon framework
2346         if test "$USE_DARWIN" = 1; then
2347             system_zlib_h_ok="yes"
2348         else
2349             dnl we have troubles with ancient zlib versions (e.g. 1.0.4 is
2350             dnl known to not work) and although I don't know which is
2351             dnl the minimal required version it's safer to test for 1.1.4 as
2352             dnl it fixes a security problem in 1.1.3 -- and hopefully nobody
2353             dnl has anything more ancient (1.1.3 was released in July 1998)
2354             dnl anyhow
2355             AC_CACHE_CHECK([for zlib.h >= 1.1.4], ac_cv_header_zlib_h,
2356                 [AC_TRY_RUN(
2357                     dnl zlib.h defines ZLIB_VERSION="x.y.z"
2358                     [
2359                         #include <zlib.h>
2360                         #include <stdio.h>
2361
2362                         int main()
2363                         {
2364                             FILE *f=fopen("conftestval", "w");
2365                             if (!f) exit(1);
2366                             fprintf(f, "%s",
2367                                     ZLIB_VERSION[0] == '1' &&
2368                                     (ZLIB_VERSION[2] > '1' ||
2369                                     (ZLIB_VERSION[2] == '1' &&
2370                                      ZLIB_VERSION[4] >= '4')) ? "yes" : "no");
2371                             exit(0);
2372                         }
2373                     ],
2374                     ac_cv_header_zlib_h=`cat conftestval`,
2375                     ac_cv_header_zlib_h=no,
2376                     dnl cross-compiling: don't have an answer, try later
2377                     unset ac_cv_header_zlib_h
2378                 )]
2379             )
2380             dnl If the test above did not come up with a value (e.g. cross
2381             dnl compiling) then this should give a definitive answer
2382             AC_CHECK_HEADER(zlib.h,,, [ ])
2383
2384             system_zlib_h_ok=$ac_cv_header_zlib_h
2385         fi
2386
2387         if test "$system_zlib_h_ok" = "yes"; then
2388             AC_CHECK_LIB(z, deflate, ZLIB_LINK=" -lz")
2389         fi
2390
2391         if test "x$ZLIB_LINK" = "x" ; then
2392             if test "$wxUSE_ZLIB" = "sys" ; then
2393                 AC_MSG_ERROR([zlib library not found or too old! Use --with-zlib=builtin to use built-in version])
2394             else
2395                 AC_MSG_WARN([zlib library not found or too old, will use built-in instead])
2396                 wxUSE_ZLIB=builtin
2397             fi
2398         else
2399             dnl we are using the system library
2400             wxUSE_ZLIB=sys
2401         fi
2402     fi
2403 fi
2404
2405 dnl ------------------------------------------------------------------------
2406 dnl Check for png library
2407 dnl ------------------------------------------------------------------------
2408
2409 PNG_LINK=
2410 if test "$wxUSE_LIBPNG" != "no" ; then
2411     AC_DEFINE(wxUSE_LIBPNG)
2412
2413     if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBPNG" = "builtin" ; then
2414         AC_MSG_WARN([wxMGL doesn't work with builtin png library, will use MGL one instead])
2415         wxUSE_LIBPNG=sys
2416     fi
2417
2418     dnl for the check below to have a chance to succeed, we must already have
2419     dnl libz somewhere (don't do this when bulding wxMGL since its libpng
2420     dnl doesn't depend on zlib)
2421     if test "$wxUSE_MGL" != 1 -a "$wxUSE_LIBPNG" = "sys" -a "$wxUSE_ZLIB" != "sys" ; then
2422         AC_MSG_WARN([system png library doesn't work without system zlib, will use built-in instead])
2423         wxUSE_LIBPNG=builtin
2424     fi
2425
2426     if test "$wxUSE_MGL" != 1 ; then
2427         dnl Don't check for libpng when building wxMGL, libmgl contains it
2428         if test "$wxUSE_LIBPNG" = "sys" -o "$wxUSE_LIBPNG" = "yes" ; then
2429             dnl libpng version 0.9 is known to not work, if an even newer
2430             dnl version is required, just bump it up in the test below
2431             AC_CACHE_CHECK([for png.h > 0.90], ac_cv_header_png_h,
2432                 [AC_TRY_RUN(
2433                     dnl png.h defines PNG_LIBPNG_VER=number
2434                     [
2435                         #include <png.h>
2436                         #include <stdio.h>
2437
2438                         int main()
2439                         {
2440                             FILE *f=fopen("conftestval", "w");
2441                             if (!f) exit(1);
2442                             fprintf(f, "%s",
2443                                      PNG_LIBPNG_VER > 90 ? "yes" : "no");
2444                             exit(0);
2445                         }
2446                     ],
2447                     ac_cv_header_png_h=`cat conftestval`,
2448                     ac_cv_header_png_h=no,
2449                     dnl cross-compiling: test (later) if we have any png.h
2450                     unset ac_cv_header_png_h
2451                 )]
2452             )
2453             AC_CHECK_HEADER(png.h,,, [ ])
2454
2455             if test "$ac_cv_header_png_h" = "yes"; then
2456                 AC_CHECK_LIB(png, png_check_sig, PNG_LINK=" -lpng -lz", , [-lz -lm])
2457             fi
2458
2459             if test "x$PNG_LINK" = "x" ; then
2460                 if test "$wxUSE_LIBPNG" = "sys" ; then
2461                     AC_MSG_ERROR([system png library not found or too old! Use --with-libpng=builtin to use built-in version])
2462                 else
2463                     AC_MSG_WARN([system png library not found or too old, will use built-in instead])
2464                     wxUSE_LIBPNG=builtin
2465                 fi
2466             else
2467                 dnl we are using the system library
2468                 wxUSE_LIBPNG=sys
2469             fi
2470         fi
2471     fi
2472 fi
2473
2474 dnl ------------------------------------------------------------------------
2475 dnl Check for jpeg library
2476 dnl ------------------------------------------------------------------------
2477
2478 dnl this check must be done before the check for libtiff as libtiff uses
2479 dnl libjpeg itself
2480 JPEG_LINK=
2481 if test "$wxUSE_LIBJPEG" != "no" ; then
2482     AC_DEFINE(wxUSE_LIBJPEG)
2483
2484     if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBJPEG" = "builtin" ; then
2485         AC_MSG_WARN([wxMGL doesn't work with builtin jpeg library, will use MGL one instead])
2486         wxUSE_LIBJPEG=sys
2487     fi
2488
2489     if test "$wxUSE_MGL" != 1 ; then
2490         dnl Don't check for libjpeg when building wxMGL, libmgl contains it
2491         if test "$wxUSE_LIBJPEG" = "sys" -o "$wxUSE_LIBJPEG" = "yes" ; then
2492             dnl can't use AC_CHECK_HEADER as jconfig.h defines things like
2493             dnl HAVE_STDLIB_H which are already defined and this provokes
2494             dnl a compiler warning which configure considers as an error...
2495             AC_MSG_CHECKING(for jpeglib.h)
2496             AC_CACHE_VAL(ac_cv_header_jpeglib_h,
2497                 AC_TRY_COMPILE(
2498                     [
2499                         #undef HAVE_STDLIB_H
2500                         #include <stdio.h>
2501                         #include <jpeglib.h>
2502                     ],
2503                     [
2504                     ],
2505                     ac_cv_header_jpeglib_h=yes,
2506                     ac_cv_header_jpeglib_h=no
2507                 )
2508             )
2509             AC_MSG_RESULT($ac_cv_header_jpeglib_h)
2510
2511             if test "$ac_cv_header_jpeglib_h" = "yes"; then
2512                 AC_CHECK_LIB(jpeg, jpeg_read_header, JPEG_LINK=" -ljpeg")
2513             fi
2514
2515             if test "x$JPEG_LINK" = "x" ; then
2516                 if test "$wxUSE_LIBJPEG" = "sys" ; then
2517                     AC_MSG_ERROR([system jpeg library not found! Use --with-libjpeg=builtin to use built-in version])
2518                 else
2519                     AC_MSG_WARN([system jpeg library not found, will use built-in instead])
2520                     wxUSE_LIBJPEG=builtin
2521                 fi
2522             else
2523                 dnl we are using the system library
2524                 wxUSE_LIBJPEG=sys
2525
2526                 if test "$wxUSE_MSW" = 1; then
2527                     dnl boolean is defined by the jpeg headers and also by the
2528                     dnl Windows headers of some compilers. This type has been
2529                     dnl renamed in the builtin, so it is only an issue when
2530                     dnl using an external jpeg lib on Windows.
2531                     AC_CHECK_TYPES(
2532                         [boolean],
2533                         [
2534                             AC_CHECK_SIZEOF(
2535                                 [boolean],
2536                                 [],
2537                                 [
2538                                     #undef HAVE_BOOLEAN
2539                                     #include <stdio.h>
2540                                     #include <jpeglib.h>
2541                                 ])
2542                             AC_DEFINE_UNQUOTED(
2543                                 [wxHACK_BOOLEAN],
2544                                 [wxInt`expr 8 \* $ac_cv_sizeof_boolean`])
2545                         ],
2546                         [],
2547                         [#include <windows.h>])
2548                 fi
2549             fi
2550         fi
2551     fi
2552 fi
2553
2554 dnl ------------------------------------------------------------------------
2555 dnl Check for tiff library
2556 dnl ------------------------------------------------------------------------
2557
2558 TIFF_LINK=
2559 TIFF_PREREQ_LINKS=-lm
2560 if test "$wxUSE_LIBTIFF" != "no" ; then
2561     AC_DEFINE(wxUSE_LIBTIFF)
2562
2563     if test "$wxUSE_LIBTIFF" = "sys" -o "$wxUSE_LIBTIFF" = "yes" ; then
2564         dnl libtiff may depend on libjpeg and libz so use them in the test
2565         dnl below or it would fail
2566         if test "$wxUSE_LIBJPEG" = "sys"; then
2567             TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $JPEG_LINK"
2568         fi
2569         if test "$wxUSE_ZLIB" = "sys"; then
2570             TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $ZLIB_LINK"
2571         fi
2572         AC_CHECK_HEADER(tiffio.h,
2573                         [
2574                             AC_CHECK_LIB(tiff, TIFFError,
2575                                          TIFF_LINK=" -ltiff",
2576                                          ,
2577                                          $TIFF_PREREQ_LINKS)
2578                         ],
2579                         [],
2580                         [ ]
2581                        )
2582
2583         if test "x$TIFF_LINK" = "x" ; then
2584             if test "$wxUSE_LIBTIFF" = "sys" ; then
2585                 AC_MSG_ERROR([system tiff library not found! Use --with-libtiff=builtin to use built-in version])
2586             else
2587                 AC_MSG_WARN([system tiff library not found, will use built-in instead])
2588                 wxUSE_LIBTIFF=builtin
2589             fi
2590         else
2591             dnl we are using the system library
2592             wxUSE_LIBTIFF=sys
2593         fi
2594     fi
2595     if test "$wxUSE_LIBTIFF" = "builtin" ; then
2596         if test "$wxUSE_LIBJPEG" = "no"; then
2597             dnl we have to prevent the builtin libtiff configure from building the
2598             dnl library with JPEG support as this was explicitly disabled by user,
2599             dnl but unfortunately it needs --disable-jpeg and not --without-libjpeg
2600             dnl (which will be passed to it anyhow as configure passes arguments to
2601             dnl the top-level script to all the other ones called recursively), so
2602             dnl we need to hack around this
2603             ac_configure_args="$ac_configure_args --disable-jpeg"
2604         fi
2605         AC_CONFIG_SUBDIRS([src/tiff])
2606     fi
2607 fi
2608
2609 dnl ------------------------------------------------------------------------
2610 dnl Check for expat libraries
2611 dnl ------------------------------------------------------------------------
2612
2613 if test "$wxUSE_WCHAR_T" != "yes"; then
2614     if test "$wxUSE_EXPAT" != "no"; then
2615         AC_MSG_WARN([wxWidgets requires wchar_t to use expat, disabling])
2616         wxUSE_EXPAT=no
2617     fi
2618     if test "$wxUSE_XML" != "no"; then
2619         AC_MSG_WARN([wxWidgets requires wchar_t to use xml, disabling])
2620         wxUSE_XML=no
2621     fi
2622 fi
2623
2624 if test "$wxUSE_EXPAT" != "no"; then
2625     wxUSE_XML=yes
2626     AC_DEFINE(wxUSE_EXPAT)
2627     AC_DEFINE(wxUSE_XML)
2628
2629     if test "$wxUSE_EXPAT" = "sys" -o "$wxUSE_EXPAT" = "yes" ; then
2630         AC_CHECK_HEADER([expat.h], [found_expat_h=1],, [ ])
2631         if test "x$found_expat_h" = "x1"; then
2632             dnl Expat 1.95.6 comes with broken expat.h:
2633             AC_CACHE_CHECK([if expat.h is valid C++ header],
2634                 wx_cv_expat_is_not_broken,
2635                 [
2636                 AC_LANG_PUSH(C++)
2637                 AC_TRY_COMPILE([#include <expat.h>],[],
2638                     wx_cv_expat_is_not_broken=yes,
2639                     wx_cv_expat_is_not_broken=no
2640                 )
2641                 AC_LANG_POP()
2642                 ]
2643             )
2644             if test "$wx_cv_expat_is_not_broken" = "yes" ; then
2645                 AC_CHECK_LIB(expat, XML_ParserCreate, EXPAT_LINK=" -lexpat")
2646             fi
2647         fi
2648         if test "x$EXPAT_LINK" = "x" ; then
2649             if test "$wxUSE_EXPAT" = "sys" ; then
2650                 AC_MSG_ERROR([system expat library not found! Use --with-expat=builtin to use built-in version])
2651             else
2652                 AC_MSG_WARN([system expat library not found, will use built-in instead])
2653                 wxUSE_EXPAT=builtin
2654             fi
2655         else
2656             dnl we are using the system library
2657             wxUSE_EXPAT=sys
2658         fi
2659     fi
2660     if test "$wxUSE_EXPAT" = "builtin" ; then
2661         dnl Expat needs this:
2662         AC_CONFIG_SUBDIRS([src/expat])
2663     fi
2664 fi
2665
2666
2667 dnl ------------------------------------------------------------------------
2668 dnl Check for libmspack
2669 dnl ------------------------------------------------------------------------
2670
2671 if test "$wxUSE_LIBMSPACK" != "no"; then
2672     AC_CHECK_HEADER([mspack.h], [found_mspack_h=1],, [ ])
2673     if test "x$found_mspack_h" = "x1"; then
2674         AC_CHECK_LIB(mspack, mspack_create_chm_decompressor,
2675                      MSPACK_LINK=" -lmspack")
2676     fi
2677     if test "x$MSPACK_LINK" = "x" ; then
2678         wxUSE_LIBMSPACK=no
2679     fi
2680 fi
2681
2682 if test "$wxUSE_LIBMSPACK" != "no"; then
2683     AC_DEFINE(wxUSE_LIBMSPACK)
2684 fi
2685
2686
2687 dnl ----------------------------------------------------------------
2688 dnl search for toolkit (widget sets)
2689 dnl ----------------------------------------------------------------
2690
2691 AFMINSTALL=
2692 WIN32INSTALL=
2693
2694 TOOLKIT=
2695 TOOLKIT_INCLUDE=
2696 WIDGET_SET=
2697
2698 dnl are we building for a win32 target environment?
2699 dnl If so, setup common stuff needed for both GUI and Base libs.
2700 if test "$USE_WIN32" = 1 ; then
2701     AC_CHECK_HEADERS(w32api.h,,, [ ])
2702     AC_CHECK_HEADER(windows.h,,
2703     [
2704         AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
2705     ],
2706     [ ])
2707
2708     dnl --- FIXME: This is still a somewhat random list of libs,
2709     dnl ---        some of them should probably be included conditionally.
2710     case "${host}" in
2711         x86_64-*-mingw32* )
2712             dnl --- For mingw-w64 lctl3d32's name has changed
2713             LIBS="$LIBS -lwinspool -lwinmm -lshell32 -lcomctl32 -lcomdlg32 -lwctl3d32 -ladvapi32 -lwsock32 -lgdi32"
2714         ;;
2715         * )
2716             LIBS="$LIBS -lwinspool -lwinmm -lshell32 -lcomctl32 -lcomdlg32 -lctl3d32 -ladvapi32 -lwsock32 -lgdi32"
2717         ;;
2718     esac
2719     if test "$wxUSE_ACCESSIBILITY" = "yes" ; then
2720         LIBS="$LIBS -loleacc"
2721     fi
2722
2723     case "${host}" in
2724         *-*-cygwin* )
2725             dnl Cygwin doesn't include these by default
2726             LIBS="$LIBS -lkernel32 -luser32"
2727     esac
2728
2729     dnl This one is still used by some sample makefiles.
2730     RESFLAGS="--include-dir \$(top_srcdir)/include --include-dir \$(top_srcdir)/\$(program_dir) --define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
2731     RESPROGRAMOBJ="\$(PROGRAM)_resources.o"
2732
2733     dnl This lot we export to wx-config.  It must add the relevant
2734     dnl include directories at the point when they can be known.
2735     dnl (but are these (still) required anyway?)
2736     WXCONFIG_RESFLAGS="--define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
2737
2738     dnl install Win32-specific files in "make install"
2739     WIN32INSTALL=win32install
2740
2741     dnl pbt.h is missing on Wine at least
2742     AC_CHECK_HEADER([pbt.h],, [AC_DEFINE(NEED_PBT_H)], [ ])
2743 fi
2744
2745 if test "$wxUSE_GUI" = "yes"; then
2746     USE_GUI=1
2747
2748     GUI_TK_LIBRARY=
2749
2750     WXGTK12=
2751     WXGTK127=
2752     WXGTK2=
2753     WXGPE=
2754
2755     if test "$wxUSE_COCOA" = 1 ; then
2756         if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes"; then
2757             AC_MSG_WARN([Printing not supported under wxCocoa yet, disabled])
2758             wxUSE_PRINTING_ARCHITECTURE=no
2759         fi
2760         if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
2761             AC_MSG_WARN([Drag and Drop not supported under wxCocoa yet, disabled])
2762             wxUSE_DRAG_AND_DROP=no
2763         fi
2764         if test "$wxUSE_DRAGIMAGE" = "yes"; then
2765             AC_MSG_WARN([wxDragImage not supported under wxCocoa yet, disabled])
2766             wxUSE_DRAGIMAGE=no
2767         fi
2768     fi
2769
2770     if test "$wxUSE_MSW" = 1 ; then
2771         TOOLKIT=MSW
2772         GUIDIST=MSW_DIST
2773
2774         dnl -mwindows causes a heap of other default gui libs to be linked in.
2775         case "${host}" in
2776             *-*-mingw32* )
2777                 WXCONFIG_LDFLAGS_GUI="$LDFLAGS -Wl,--subsystem,windows -mwindows"
2778         esac
2779     fi
2780
2781     if test "$wxUSE_GTK" = 1; then
2782         dnl GTK+ test program must be compiled with C compiler
2783         AC_MSG_CHECKING([for GTK+ version])
2784
2785         gtk_version_cached=1
2786         AC_CACHE_VAL(wx_cv_lib_gtk,
2787             [
2788                 dnl stupid GTK+ AM macros produce their own messages, so we
2789                 dnl have to pass to the next line
2790                 gtk_version_cached=0
2791                 AC_MSG_RESULT()
2792
2793                 dnl we must link against lgthread unless the user
2794                 dnl used --disable-threads
2795                 GTK_MODULES=
2796                 if test "$wxUSE_THREADS" = "yes"; then
2797                     GTK_MODULES=gthread
2798                 fi
2799
2800                 dnl detect GTK2
2801                 wx_cv_lib_gtk=
2802                 if test "x$wxGTK_VERSION" != "x1"
2803                 then
2804                     dnl The gthread.pc that ships with Solaris returns '-mt',
2805                     dnl it's correct for Sun CC, but gcc requires '-pthreads'.
2806                     dnl So disable the compile check and remove the -mt below.
2807                     case "${host}" in
2808                         *-*-solaris2* )
2809                             if test "$wxUSE_THREADS" = "yes" -a "$GCC" = yes; then
2810                                 enable_gtktest=no
2811                             fi
2812                     esac
2813
2814                     AM_PATH_GTK_2_0(2.4.0, wx_cv_lib_gtk=2.0, , $GTK_MODULES)
2815
2816                     dnl Solaris also requires -lX11 for static lib
2817                     case "${host}" in
2818                         *-*-solaris2* )
2819                             if test "$wxUSE_SHARED" != "yes"; then
2820                                 GTK_LIBS="$GTK_LIBS -lX11"
2821                             fi
2822                     esac
2823                 fi
2824
2825                 dnl detect GTK1.x
2826                 if test -z "$wx_cv_lib_gtk"; then
2827                     if test "x$wxGTK_VERSION" = "x1" -o "x$wxGTK_VERSION" = "xany" ; then
2828                         AM_PATH_GTK(1.2.7, wx_cv_lib_gtk=1.2.7, , $GTK_MODULES)
2829
2830                         if test -z "$wx_cv_lib_gtk"; then
2831                             AM_PATH_GTK(1.2.3, wx_cv_lib_gtk=1.2.3, , $GTK_MODULES)
2832                         fi
2833                     fi
2834                 fi
2835
2836                 if test -z "$wx_cv_lib_gtk"; then
2837                     dnl looks better in AC_MSG_RESULT
2838                     wx_cv_lib_gtk=none
2839                 else
2840                     dnl we need to cache GTK_CFLAGS and GTK_LIBS for the
2841                     dnl subsequent runs
2842                     wx_cv_cflags_gtk=$GTK_CFLAGS
2843                     wx_cv_libs_gtk=`echo $GTK_LIBS | sed -e 's/ -l[[^ ]]*cairo[[^ ]]*//g'`
2844                 fi
2845             ]
2846         )
2847
2848         dnl if it wasn't cached, the messages from AM_PATH_GTK() above are
2849         dnl enough
2850         if test "$gtk_version_cached" = 1; then
2851             AC_MSG_RESULT($wx_cv_lib_gtk)
2852         fi
2853
2854         case "$wx_cv_lib_gtk" in
2855             2.0)    WXGTK2=1
2856                     TOOLKIT_VERSION=2
2857                     ;;
2858             1.2.7)  WXGTK127=1
2859                     WXGTK12=1
2860                     ;;
2861             1.2.3)  WXGTK12=1
2862                     ;;
2863             *)      AC_MSG_ERROR([
2864 The development files for GTK+ were not found. For GTK+ 2, please
2865 ensure that pkg-config is in the path and that gtk+-2.0.pc is
2866 installed. For GTK+ 1.2 please check that gtk-config is in the path,
2867 and that the version is 1.2.3 or above. Also check that the
2868 libraries returned by 'pkg-config gtk+-2.0 --libs' or 'gtk-config
2869 --libs' are in the LD_LIBRARY_PATH or equivalent.
2870                             ])
2871                     ;;
2872         esac
2873
2874         if test "$WXGTK2" = 1; then
2875             save_CFLAGS="$CFLAGS"
2876             save_LIBS="$LIBS"
2877             CFLAGS="$wx_cv_cflags_gtk $CFLAGS"
2878             LIBS="$LIBS $wx_cv_libs_gtk"
2879
2880             dnl test if we have at least GTK+ 2.10:
2881             AC_MSG_CHECKING([if GTK+ is version >= 2.10])
2882             AC_TRY_COMPILE([
2883                             #include <gtk/gtk.h>
2884                            ],
2885                            [
2886                             #if !GTK_CHECK_VERSION(2,10,0)
2887                             Not GTK+ 2.10
2888                             #endif
2889                            ],
2890                            [
2891                             AC_DEFINE(__WXGTK210__)
2892                             AC_DEFINE(__WXGTK26__)
2893                             AC_MSG_RESULT([yes])
2894                             ac_wxgtk210=1
2895                            ],
2896                            [
2897                             AC_MSG_RESULT([no])
2898                             ac_wxgtk210=0
2899                            ])
2900
2901             if test "$ac_wxgtk210" = 0; then
2902                 dnl test if we have at least GTK+ 2.6:
2903                 AC_MSG_CHECKING([if GTK+ is version >= 2.6])
2904                 AC_TRY_COMPILE([
2905                                 #include <gtk/gtk.h>
2906                             ],
2907                             [
2908                                 #if !GTK_CHECK_VERSION(2,6,0)
2909                                 Not GTK+ 2.6
2910                                 #endif
2911                             ],
2912                             [
2913                                 AC_DEFINE(__WXGTK26__)
2914                                 AC_MSG_RESULT([yes])
2915                                 ac_wxgtk26=1
2916                             ],
2917                             [
2918                                 AC_MSG_RESULT([no])
2919                                 ac_wxgtk26=0
2920                             ])
2921             fi
2922
2923             CFLAGS="$save_CFLAGS"
2924             LIBS="$save_LIBS"
2925         else
2926             if test "$wxUSE_UNICODE" = "yes"; then
2927                 AC_MSG_WARN([Unicode configuration not supported with GTK+ 1.x])
2928                 wxUSE_UNICODE=no
2929             fi
2930
2931             dnl test for XIM support in libgdk
2932             AC_CHECK_LIB(gdk, gdk_im_open, AC_DEFINE(HAVE_XIM))
2933
2934             dnl we need poll() in src/gtk1/app.cpp (we know that Darwin doesn't
2935             dnl have it but we do the check for the others)
2936             if test "$USE_DARWIN" != 1; then
2937                 AC_CHECK_FUNCS(poll)
2938             fi
2939         fi
2940
2941         TOOLKIT_INCLUDE="$wx_cv_cflags_gtk"
2942         GUI_TK_LIBRARY="$wx_cv_libs_gtk $GUI_TK_LIBRARY"
2943
2944         AFMINSTALL=afminstall
2945         TOOLKIT=GTK
2946         GUIDIST=GTK_DIST
2947
2948         dnl test for external libxpm if we're configured to use it
2949         if test "$wxUSE_GPE" = "yes"; then
2950             AC_MSG_CHECKING(for gpewidget library)
2951             WX_PATH_FIND_LIBRARIES($SEARCH_LIB,gpewidget)
2952             if test "$ac_find_libraries" != "" ; then
2953                 WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
2954                 dnl -lgpewidget must be before all GTK libs and
2955                 dnl we guess its path from the prefix
2956                 GUI_TK_LIBRARY="-L${prefix}/lib -lgpewidget $GUI_TK_LIBRARY"
2957                 WXGPE=1
2958                 AC_MSG_RESULT([found in $ac_find_libraries])
2959             else
2960                 AC_MSG_RESULT(not found)
2961             fi
2962
2963             dnl AC_MSG_CHECKING(for gpe library)
2964             dnl WX_PATH_FIND_LIBRARIES($SEARCH_LIB,gpe)
2965             dnl if test "$ac_find_libraries" != "" ; then
2966             dnl     WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
2967             dnl     GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lgpe"
2968             dnl     AC_MSG_RESULT(found in $ac_find_libraries)
2969             dnl else
2970             dnl     AC_MSG_RESULT(not found)
2971             dnl fi
2972         fi
2973     fi
2974
2975     if test "$wxUSE_MGL" = 1; then
2976        AC_MSG_CHECKING(for SciTech MGL library)
2977         if test "x$MGL_ROOT" = x ; then
2978             AC_MSG_RESULT(not found)
2979             AC_MSG_ERROR([Cannot find MGL library. Make sure MGL_ROOT is set.])
2980         else
2981             AC_MSG_RESULT($MGL_ROOT)
2982         fi
2983
2984         AC_MSG_CHECKING(for libmgl location)
2985         dnl Find MGL library that we want
2986         dnl FIXME_MGL - test for MGL variants for freebsd etc.;
2987         dnl             and for non-x86 versions
2988         case "${host}" in
2989             *-*-linux* )
2990               dnl glibc.so, glibc are for older versions of MGL,
2991               dnl x86/a, x86/so are used by >= 5.0 R11
2992               if test "x$wxUSE_SHARED" = xyes ; then
2993                   mgl_os_candidates="linux/gcc/x86/so linux/gcc/x86/a linux/gcc/glibc.so linux/gcc/glibc"
2994               else
2995                   mgl_os_candidates="linux/gcc/x86/a linux/gcc/x86/so linux/gcc/glibc linux/gcc/glibc.so"
2996               fi
2997               ;;
2998             *-pc-msdosdjgpp )
2999               mgl_os_candidates="dos32/dj2"
3000               ;;
3001             *)
3002               AC_MSG_ERROR(This system type ${host} is not yet supported by wxMGL.)
3003         esac
3004
3005         mgl_lib_type=""
3006         mgl_os=""
3007
3008         for mgl_os_i in $mgl_os_candidates ; do
3009             if test "x$mgl_os" = x ; then
3010                 if test "$wxUSE_DEBUG_FLAG" = yes ; then
3011                     if test -f $MGL_ROOT/lib/debug/$mgl_os_i/libmgl.a -o \
3012                             -f $MGL_ROOT/lib/debug/$mgl_os_i/libmgl.so; then
3013                         mgl_lib_type=debug
3014                         mgl_os=$mgl_os_i
3015                     fi
3016                 fi
3017                 if test "x$mgl_lib_type" = x ; then
3018                     if test -f $MGL_ROOT/lib/release/$mgl_os_i/libmgl.a -o \
3019                             -f $MGL_ROOT/lib/release/$mgl_os_i/libmgl.so; then
3020                         mgl_lib_type=release
3021                         mgl_os=$mgl_os_i
3022                     fi
3023                 fi
3024             fi
3025         done
3026
3027         if test "x$mgl_os" = x ; then
3028             AC_MSG_RESULT(not found)
3029             AC_MSG_ERROR([Cannot find MGL libraries, make sure they are compiled.])
3030         fi
3031         AC_MSG_RESULT("$MGL_ROOT/lib/$mgl_lib_type/$mgl_os")
3032
3033         wxUSE_UNIVERSAL="yes"
3034
3035         TOOLKIT_INCLUDE="-I$MGL_ROOT/include"
3036         GUI_TK_LIBRARY="-L$MGL_ROOT/lib/$mgl_lib_type/$mgl_os -lmgl -lmglcpp -lpm"
3037
3038         AFMINSTALL=afminstall
3039         TOOLKIT=MGL
3040         GUIDIST=MGL_DIST
3041     fi
3042
3043     if test "$wxUSE_DFB" = 1; then
3044        PKG_PROG_PKG_CONFIG()
3045
3046        PKG_CHECK_MODULES(DIRECTFB,
3047                          [directfb >= 0.9.23],
3048                          [
3049                            wxUSE_UNIVERSAL="yes"
3050                            TOOLKIT_INCLUDE="$DIRECTFB_CFLAGS"
3051                            GUI_TK_LIBRARY="$DIRECTFB_LIBS"
3052                            TOOLKIT=DFB
3053                            GUIDIST=DFB_DIST
3054                          ],
3055                          [
3056                            AC_MSG_ERROR([DirectFB not found.])
3057                          ]
3058                          )
3059     fi
3060
3061     if test "$wxUSE_MICROWIN" = 1; then
3062         AC_MSG_CHECKING(for MicroWindows)
3063         if test "x$MICROWINDOWS" = x ; then
3064             AC_MSG_RESULT(not found)
3065             AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWINDOWS is set.])
3066         else
3067             AC_MSG_RESULT($MICROWINDOWS)
3068         fi
3069
3070         if test -f $MICROWINDOWS/lib/libmwin.a; then
3071             AC_MSG_RESULT(MicroWindows' libraries found.)
3072         else
3073             AC_MSG_ERROR([Cannot find MicroWindows libraries, make sure they are compiled.])
3074         fi
3075
3076         TOOLKIT_INCLUDE="-I$MICROWINDOWS/include"
3077         GUI_TK_LIBRARY="-L$MICROWINDOWS/lib -lmwin -lmwengine -mwfonts -mwdrivers -mwinlib"
3078
3079         wxUSE_UNIVERSAL="yes"
3080
3081         AFMINSTALL=afminstall
3082         TOOLKIT=MICROWIN
3083         GUIDIST=MICROWIN_DIST
3084
3085         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXMSW__ -D__WIN95__ -D__WIN32__ -DMWIN -DMICROWIN_NOCONTROLS -DMICROWIN_TODO=1"
3086     fi
3087
3088     dnl common part of X11 and Motif port checks
3089     if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
3090         dnl use standard macros to check for X headers/libs, this brings
3091         dnl support for the standard configure options --x-includes,
3092         dnl --x-libraries and --no-x
3093         AC_PATH_XTRA
3094
3095         if test "$no_x" = "yes"; then
3096           AC_MSG_ERROR([X11 not found, please use --x-includes and/or --x-libraries options (see config.log for details)])
3097         fi
3098
3099         dnl for some reason AC_PATH_XTRA seems to add -INONE and -LNONE (and
3100         dnl also sometimes -RNONE) to X_CFLAGS and X_LIBS respectively, filter
3101         dnl this junk out
3102         GUI_TK_LIBRARY=`echo $X_LIBS | sed 's/ -LNONE//' | sed 's/ -RNONE//'`
3103         TOOLKIT_INCLUDE=`echo $X_CFLAGS | sed 's/ -INONE//'`
3104         AFMINSTALL=afminstall
3105         COMPILED_X_PROGRAM=0
3106
3107     fi
3108
3109     if test "$wxUSE_X11" = 1; then
3110         if test "$wxUSE_NANOX" = "yes"; then
3111             AC_MSG_CHECKING(for MicroWindows/NanoX distribution)
3112             if test "x$MICROWIN" = x ; then
3113                 AC_MSG_RESULT(not found)
3114                 AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWIN is set.])
3115             else
3116                 AC_MSG_RESULT($MICROWIN)
3117                 AC_DEFINE(wxUSE_NANOX)
3118             fi
3119         fi
3120
3121         if test "$wxUSE_UNICODE" = "yes"; then
3122             PKG_PROG_PKG_CONFIG()
3123
3124             PKG_CHECK_MODULES(PANGOX, pangox,
3125                 [
3126                     CFLAGS="$PANGOX_CFLAGS $CFLAGS"
3127                     CXXFLAGS="$PANGOX_CFLAGS $CXXFLAGS"
3128                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOX_LIBS"
3129                 ],
3130                 [
3131                     AC_MSG_ERROR([pangox library not found, library cannot be compiled in Unicode mode])
3132                 ]
3133             )
3134             PKG_CHECK_MODULES(PANGOFT2, pangoft2,
3135                 [
3136                     CFLAGS="$PANGOFT2_CFLAGS $CFLAGS"
3137                     CXXFLAGS="$PANGOFT2_CFLAGS $CXXFLAGS"
3138                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOFT2_LIBS"
3139                 ],
3140                 [
3141                     AC_MSG_WARN([pangoft2 library not found, library will be compiled without printing support])
3142                     wxUSE_PRINTING_ARCHITECTURE="no"
3143                 ]
3144             )
3145             PKG_CHECK_MODULES(PANGOXFT, pangoxft,
3146                 [
3147                     AC_DEFINE(HAVE_PANGO_XFT)
3148                     CFLAGS="$PANGOXFT_CFLAGS $CFLAGS"
3149                     CXXFLAGS="$PANGOXFT_CFLAGS $CXXFLAGS"
3150                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY $PANGOXFT_LIBS"
3151                 ],
3152                 [
3153                     AC_MSG_WARN([pangoxft library not found, library will be compiled without anti-aliasing support])
3154                 ]
3155             )
3156             save_LIBS="$LIBS"
3157             LIBS="$LIBS $PANGOX_LIBS"
3158             AC_CHECK_FUNCS([pango_font_family_is_monospace])
3159             LIBS="$save_LIBS"
3160         fi
3161
3162         wxUSE_UNIVERSAL="yes"
3163
3164         if test "$wxUSE_NANOX" = "yes"; then
3165             TOOLKIT_INCLUDE="-I\$(top_srcdir)/include/wx/x11/nanox -I\$(MICROWIN)/src/include $TOOLKIT_INCLUDE"
3166             TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__NANOX__ -DMWPIXEL_FORMAT=MWPF_TRUECOLOR0888 -DHAVE_FILEIO -DHAVE_BMP_SUPPORT=1 -DHAVE_GIF_SUPPORT=1 -DHAVE_PNM_SUPPORT=1 -DHAVE_XPM_SUPPORT=1 -DUNIX=1 -DUSE_EXPOSURE -DSCREEN_HEIGHT=480 -DSCREEN_WIDTH=640 -DSCREEN_DEPTH=4 -DX11=1"
3167             GUI_TK_LIBRARY="$GUI_TK_LIBRARY \$(MICROWIN)/src/lib/libnano-X.a"
3168         else
3169             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lX11"
3170         fi
3171
3172         TOOLKIT=X11
3173         GUIDIST=X11_DIST
3174     fi
3175
3176     if test "$wxUSE_MOTIF" = 1; then
3177         AC_MSG_CHECKING(for Motif/Lesstif headers)
3178         WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, Xm/Xm.h)
3179         if test "$ac_find_includes" != "" ; then
3180             AC_MSG_RESULT(found in $ac_find_includes)
3181             WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
3182             TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE$ac_path_to_include"
3183         else
3184             save_CFLAGS=$CFLAGS
3185             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3186
3187             AC_TRY_COMPILE(
3188                 [
3189                     #include <Xm/Xm.h>
3190                 ],
3191                 [
3192                     int version;
3193                     version = xmUseVersion;
3194                 ],
3195                 [
3196                     AC_MSG_RESULT(found in default search path)
3197                     COMPILED_X_PROGRAM=1
3198                 ],
3199                 [
3200                     AC_MSG_RESULT(no)
3201                     AC_MSG_ERROR(please set CPPFLAGS to contain the location of Xm/Xm.h)
3202                 ]
3203             )
3204
3205             CFLAGS=$save_CFLAGS
3206         fi
3207
3208
3209         AC_MSG_CHECKING(for Motif/Lesstif library)
3210         WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xm)
3211
3212         if test "x$ac_find_libraries" != "x" ; then
3213             AC_MSG_RESULT(found in $ac_find_libraries)
3214
3215             WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
3216             GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
3217         else
3218             dnl it might happen that we found headers in one of the standard
3219             dnl paths but the libs are elsewhere but still in default (linker)
3220             dnl path -- try to compile a test program to check for this
3221             save_CFLAGS=$CFLAGS
3222             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3223             save_LIBS="$LIBS"
3224             LIBS="$GUI_TK_LIBRARY -lXm -lXmu -lXext -lX11"
3225
3226             AC_TRY_LINK(
3227                 [
3228                     #include <Xm/Xm.h>
3229                 ],
3230                 [
3231                     int version;
3232                     version = xmUseVersion;
3233                 ],
3234                 [
3235                     AC_MSG_RESULT(found in default search path)
3236                     COMPILED_X_PROGRAM=1
3237                 ],
3238                 [
3239                     AC_MSG_RESULT(no)
3240                     AC_MSG_ERROR(please set LDFLAGS to contain the location of libXm)
3241                 ]
3242             )
3243
3244             CFLAGS=$save_CFLAGS
3245             LIBS="$save_LIBS"
3246         fi
3247
3248         AC_MSG_CHECKING([if we need -lXp and/or -lSM -lICE])
3249         libp_link=""
3250         libsm_ice_link=""
3251         libs_found=0
3252         for libp in "" " -lXp"; do
3253             if test "$libs_found" = 0; then
3254                 for libsm_ice in "" " -lSM -lICE"; do
3255                     if test "$libs_found" = 0; then
3256                         save_LIBS="$LIBS"
3257                         LIBS="$GUI_TK_LIBRARY -lXm ${libp} -lXmu -lXext -lXt${libsm_ice} -lX11"
3258                         save_CFLAGS=$CFLAGS
3259                         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3260
3261                         AC_TRY_LINK(
3262                             [
3263                                 #include <Xm/Xm.h>
3264                                 #include <Xm/List.h>
3265                             ],
3266                             [
3267                                 XmString string = NULL;
3268                                 Widget w = NULL;
3269                                 int position = 0;
3270                                 XmListAddItem(w, string, position);
3271                             ],
3272                             [
3273                                 libp_link="$libp"
3274                                 libsm_ice_link="$libsm_ice"
3275                                 AC_MSG_RESULT(
3276                                     [need${libp_link}${libsm_ice_link}])
3277                                 libs_found=1
3278                             ], []
3279                         )
3280
3281                         LIBS="$save_LIBS"
3282                         CFLAGS=$save_CFLAGS
3283                     fi
3284                 done
3285             fi
3286         done
3287
3288         if test "$libs_found" = 0; then
3289             AC_MSG_RESULT([can't find the right libraries])
3290             AC_MSG_ERROR([can't link a simple motif program])
3291         fi
3292
3293         dnl this seems to be needed under IRIX and shouldn't do any harm
3294         dnl elsewhere
3295         AC_CHECK_LIB(Sgm, [SgCreateList], [libsgm_link=" -lSgm"])
3296
3297         save_CFLAGS=$CFLAGS
3298         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3299
3300         AC_CACHE_CHECK([for Motif 2],
3301             wx_cv_lib_motif2,
3302             AC_TRY_COMPILE([
3303                             #include <Xm/Xm.h>
3304                            ],
3305                            [
3306                             #if XmVersion < 2000
3307                             Not Motif 2
3308                             #endif
3309                            ],
3310                            wx_cv_lib_motif2="yes",
3311                            wx_cv_lib_motif2="no"))
3312         if test "$wx_cv_lib_motif2" = "yes"; then
3313             AC_DEFINE(__WXMOTIF20__,1)
3314         else
3315             AC_DEFINE(__WXMOTIF20__,0)
3316         fi
3317
3318         AC_CACHE_CHECK([whether Motif is Lesstif],
3319             wx_cv_lib_lesstif,
3320             AC_TRY_COMPILE([
3321                             #include <Xm/Xm.h>
3322                            ],
3323                            [
3324                             #if !defined(LesstifVersion) || LesstifVersion <= 0
3325                             Not Lesstif
3326                             #endif
3327                            ],
3328                            wx_cv_lib_lesstif="yes",
3329                            wx_cv_lib_lesstif="no")
3330         )
3331         if test "$wx_cv_lib_lesstif" = "yes"; then
3332             AC_DEFINE(__WXLESSTIF__,1)
3333         else
3334             AC_DEFINE(__WXLESSTIF__,0)
3335         fi
3336
3337         CFLAGS=$save_CFLAGS
3338
3339         GUI_TK_LIBRARY="$GUI_TK_LIBRARY${libsgm_link} -lXm${libp_link} -lXmu -lXext -lXt${libsm_ice_link} -lX11"
3340         TOOLKIT=MOTIF
3341         GUIDIST=MOTIF_DIST
3342     fi
3343
3344     dnl more tests common to X11 and Motif:
3345     if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
3346         dnl test for external libxpm if we're configured to use it
3347         if test "$wxUSE_LIBXPM" = "sys"; then
3348             AC_MSG_CHECKING(for Xpm library)
3349             WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
3350             if test "$ac_find_libraries" != "" ; then
3351                 WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
3352                 GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
3353                 AC_MSG_RESULT(found in $ac_find_libraries)
3354
3355                 AC_CACHE_CHECK([for X11/xpm.h],
3356                     wx_cv_x11_xpm_h,
3357                     [
3358                         save_CFLAGS=$CFLAGS
3359                         CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3360
3361                         AC_TRY_COMPILE(
3362                             [
3363                                 #include <X11/xpm.h>
3364                             ],
3365                             [
3366                                 int version;
3367                                 version = XpmLibraryVersion();
3368                             ],
3369                             wx_cv_x11_xpm_h=yes,
3370                             wx_cv_x11_xpm_h=no
3371                         )
3372
3373                         CFLAGS=$save_CFLAGS
3374                     ]
3375                 )
3376
3377                 if test $wx_cv_x11_xpm_h = "yes"; then
3378                     GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXpm"
3379                     AC_DEFINE(wxHAVE_LIB_XPM)
3380                 else
3381                     AC_MSG_WARN([built-in less efficient XPM decoder will be used])
3382                 fi
3383             fi
3384
3385         fi
3386
3387         dnl XShapeQueryExtension checks: first the library, then prototype
3388         AC_CHECK_LIB([Xext], [XShapeQueryExtension],
3389                      [
3390                       GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXext"
3391                       wxHAVE_XEXT_LIB=1
3392                      ],
3393                      [], [$GUI_TK_LIBRARY -lX11])
3394
3395         if test "$wxHAVE_XEXT_LIB" = 1; then
3396             save_CFLAGS="$CFLAGS"
3397             CFLAGS="$TOOLKIT_INCLUDE $CFLAGS"
3398
3399             AC_MSG_CHECKING([for X11/extensions/shape.h])
3400             AC_TRY_COMPILE([
3401                             #include <X11/Xlib.h>
3402                             #include <X11/extensions/shape.h>
3403                            ],
3404                            [
3405                             int dummy1, dummy2;
3406                             XShapeQueryExtension((Display*)NULL,
3407                                                  (int*)NULL, (int*)NULL);
3408                            ],
3409                            [
3410                             AC_DEFINE(HAVE_XSHAPE)
3411                             AC_MSG_RESULT([found])
3412                            ],
3413                            [
3414                             AC_MSG_RESULT([not found])
3415                            ])
3416             CFLAGS="$save_CFLAGS"
3417
3418         fi
3419     fi
3420
3421     if test "$wxUSE_OSX_CARBON" = 1; then
3422         AC_MSG_CHECKING([for compiler syntax to enable Pascal strings])
3423         if test "$GCC" = yes; then
3424             AC_MSG_RESULT([gcc])
3425             CPPFLAGS_PASCAL="-fpascal-strings"
3426         elif test "`echo $CXX | sed -e 's@.*/@@'`" = "xlC"; then
3427             AC_MSG_RESULT([xlc])
3428             CPPFLAGS_PASCAL="-qmacpstr"
3429         else
3430             AC_MSG_RESULT([none])
3431         fi
3432
3433         if test "x$wxUSE_UNIX" = "xyes"; then
3434             CPPFLAGS="$CPPFLAGS_PASCAL -I\${top_srcdir}/src/mac/carbon/morefilex -I/Developer/Headers/FlatCarbon $CPPFLAGS"
3435         else
3436             dnl platform.h needs TARGET_CARBON before setup.h
3437             CPPFLAGS="$CPPFLAGS_PASCAL -I\${top_srcdir}/src/mac/carbon/morefilex -DTARGET_CARBON $CPPFLAGS"
3438         fi
3439
3440         TOOLKIT=OSX_CARBON
3441         dnl we can't call this MAC_DIST or autoconf thinks its a macro
3442         GUIDIST=OSX_CARBON_DIST
3443         dnl wxMac version of wxBase and wxCocoa or wxBase-only built on Darwin
3444         dnl are different, so they need different names:
3445         WXBASEPORT="_carbon"
3446     fi
3447
3448     if test "$wxUSE_OSX_COCOA" = 1; then
3449         TOOLKIT=OSX_COCOA
3450         GUIDIST=OSX_COCOA_DIST
3451     fi
3452
3453     if test "$wxUSE_COCOA" = 1; then
3454         TOOLKIT=COCOA
3455         GUIDIST=COCOA_DIST
3456     fi
3457
3458     if test "$wxUSE_PM" = 1; then
3459         TOOLKIT=PM
3460         GUIDIST=PM_DIST
3461         AC_CACHE_CHECK([for type SPBCDATA],
3462             wx_cv_spbcdata,
3463             [
3464                 AC_TRY_COMPILE(
3465                     [
3466                         #define INCL_PM
3467                         #include <os2.h>
3468                     ],
3469                     [
3470                         SPBCDATA test;
3471                     ],
3472                     wx_cv_spbcdata=yes,
3473                     wx_cv_spbcdata=no
3474                 )
3475             ]
3476         )
3477
3478         if test $wx_cv_spbcdata = "yes"; then
3479             AC_DEFINE(HAVE_SPBCDATA)
3480         fi
3481     fi
3482
3483     dnl the name of the directory where the files for this toolkit live
3484     if test "$TOOLKIT" = "PM" ; then
3485         TOOLKIT_DIR="os2"
3486     else
3487         TOOLKIT_DIR=`echo ${TOOLKIT} | tr '[[A-Z]]' '[[a-z]]'`
3488     fi
3489
3490     if test "$wxUSE_UNIVERSAL" = "yes"; then
3491         TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXUNIVERSAL__"
3492         WIDGET_SET=univ
3493     fi
3494
3495     dnl distribute samples/demos/utils with GUI versions
3496     GUIDIST="${GUIDIST} SAMPLES_DIST DEMOS_DIST UTILS_DIST MISC_DIST"
3497     DISTDIR="wx\$(TOOLKIT)"
3498 else
3499     USE_GUI=0
3500
3501     dnl this doesn't quite work right for wxBase, but the places
3502     dnl where it is wrong aren't fatal (yet) though.
3503     TOOLKIT_DIR="base"
3504
3505     dnl the sources, their dependenices and the headers
3506     if test "$USE_WIN32" = 1 ; then
3507         dnl yes, the toolkit for wxBase on win32 is actually MSW
3508         dnl wxBase on unix does not need a 'TOOLKIT' defined.
3509         TOOLKIT="MSW"
3510     fi
3511
3512     dnl distribute only wxBase sources/headers
3513     GUIDIST="BASE_DIST"
3514     DISTDIR="wxBase"
3515 fi
3516
3517
3518 dnl ---------------------------------------------------------------------------
3519 dnl UTF-8 support
3520 dnl ---------------------------------------------------------------------------
3521
3522 dnl If UTF-8 support wasn't explicitly enabled or disabled, enable it only
3523 dnl for ports where it makes sense by default (GTK+, DirectFB):
3524 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_UTF8" = "auto" ; then
3525     if test "$USE_UNIX" = 1 -a "$wxUSE_DARWIN" != 1 ; then
3526         wxUSE_UNICODE_UTF8=yes
3527     elif test "$USE_OS2" = 1 ; then
3528         dnl wide char support is quite incomplete in libc;
3529         dnl UTF-8 might actually work when evaluating/setting
3530         dnl code pages correctly, even for ports other than GTK20.
3531         wxUSE_UNICODE_UTF8=yes
3532     else
3533         wxUSE_UNICODE_UTF8=no
3534     fi
3535 fi
3536
3537 dnl ---------------------------------------------------------------------------
3538 dnl Optional libraries included when system library is not used
3539 dnl ---------------------------------------------------------------------------
3540
3541 dnl do this after test for X11 above so that we have a chance of finding Xlib.h
3542 if test "$wxUSE_GUI" = "yes"; then
3543     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_PM" != 1; then
3544         dnl defines HAVE_X11_XKBLIB_H
3545         AC_CHECK_HEADERS([X11/Xlib.h],,, [ ])
3546         AC_CHECK_HEADERS([X11/XKBlib.h],,,
3547                          [
3548                           #if HAVE_X11_XLIB_H
3549                             #include <X11/Xlib.h>
3550                           #endif
3551                          ])
3552     fi
3553 fi
3554
3555
3556 dnl ---------------------------------------------------------------------------
3557 dnl wxDisplay Sanity checks
3558 dnl ---------------------------------------------------------------------------
3559
3560 if test "$wxUSE_DISPLAY" = "yes"; then
3561 dnl ---------------------------------------------------------------------------
3562 dnl Xinerama (for unix ) - Brian Victor
3563 dnl ---------------------------------------------------------------------------
3564     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1; then
3565         AC_MSG_CHECKING([for Xinerama])
3566         WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],Xinerama)
3567         if test "$ac_find_libraries" != "" ; then
3568             WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3569             if test "$ac_path_to_link" != " -L/usr/lib" ; then
3570                 LDFLAGS="$LDFLAGS $ac_path_to_link"
3571             fi
3572             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXinerama"
3573             AC_MSG_RESULT([yes])
3574
3575             AC_MSG_CHECKING([for Xxf86vm extension])
3576             WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],Xxf86vm)
3577             if test "$ac_find_libraries" != "" ; then
3578                 AC_MSG_RESULT([yes])
3579                 AC_CHECK_HEADERS([X11/extensions/xf86vmode.h],
3580                                  [
3581                                   GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXxf86vm"
3582                                  ],
3583                                  [],
3584                                  [
3585                                       #if HAVE_X11_XLIB_H
3586                                         #include <X11/Xlib.h>
3587                                       #endif
3588                                  ])
3589             else
3590                 AC_MSG_RESULT([no])
3591             fi
3592
3593         else
3594             AC_MSG_RESULT([no])
3595             AC_MSG_WARN([Xinerama not found; disabling wxDisplay])
3596             wxUSE_DISPLAY="no"
3597         fi
3598     elif test "$wxUSE_MSW" = 1; then
3599 dnl ---------------------------------------------------------------------------
3600 dnl DirectDraw for MSW - optionally used by WxDisplay.
3601 dnl ---------------------------------------------------------------------------
3602         AC_CHECK_HEADER([ddraw.h], [], [], [#include <windows.h>])
3603     fi
3604 fi
3605
3606 dnl ---------------------------------------------------------------------------
3607 dnl X11 session management
3608 dnl ---------------------------------------------------------------------------
3609 if test "$wxUSE_DETECT_SM" = "yes"; then
3610     if test "$wxUSE_UNIX" = "yes" -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1; then
3611         AC_MSG_CHECKING([for -lSM - X11 session management])
3612         WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],SM)
3613         if test "$ac_find_libraries" != "" ; then
3614             WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3615             if test "$ac_path_to_link" != " -L/usr/lib" ; then
3616                 LDFLAGS="$LDFLAGS $ac_path_to_link"
3617             fi
3618             GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lSM"
3619             AC_MSG_RESULT([yes])
3620         else
3621             AC_MSG_RESULT([no])
3622             AC_MSG_WARN([libSM not found; disabling session management detection])
3623             wxUSE_DETECT_SM="no"
3624         fi
3625     else
3626         wxUSE_DETECT_SM="no"
3627     fi
3628 fi
3629
3630
3631 dnl ---------------------------------------------------------------------------
3632 dnl OpenGL libraries
3633 dnl ---------------------------------------------------------------------------
3634
3635 USE_OPENGL=0
3636 if test "$wxUSE_OPENGL" = "yes"; then
3637     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
3638         AC_MSG_WARN([wxGLCanvas not implemented for this port, library will be compiled without it.])
3639         wxUSE_OPENGL="no"
3640     elif test "$wxUSE_OSX_CARBON" = 1 -o "$wxUSE_OSX_COCOA" = 1 -o "$wxUSE_COCOA" = 1; then
3641         OPENGL_LIBS="-framework OpenGL -framework AGL"
3642     elif test "$wxUSE_MSW" = 1; then
3643         OPENGL_LIBS="-lopengl32 -lglu32"
3644     else
3645         dnl adjust CPPFLAGS to include GL/gl.h location if necessary
3646         dnl (/opt/graphics/OpenGL is for HP-UX systems, bug 925307)
3647         AC_MSG_CHECKING([for OpenGL headers])
3648         WX_PATH_FIND_INCLUDES([$SEARCH_INCLUDE /opt/graphics/OpenGL/include], GL/gl.h)
3649         if test "$ac_find_includes" != "" ; then
3650             AC_MSG_RESULT(found in $ac_find_includes)
3651             WX_INCLUDE_PATH_EXIST($ac_find_includes, $CPPFLAGS)
3652             CPPFLAGS="$ac_path_to_include $CPPFLAGS"
3653         else
3654             AC_MSG_RESULT([not found])
3655         fi
3656
3657         AC_CHECK_HEADER(GL/gl.h, [
3658             AC_CHECK_HEADER(GL/glu.h, [
3659                 found_gl=0
3660
3661                 AC_MSG_CHECKING([for -lGL])
3662                 WX_PATH_FIND_LIBRARIES([$SEARCH_LIB /opt/graphics/OpenGL/lib],GL)
3663                 if test "$ac_find_libraries" != "" ; then
3664                     AC_MSG_RESULT([found in $ac_find_libraries])
3665
3666                     WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3667                     if test "$ac_path_to_link" != " -L/usr/lib" ; then
3668                         LDFLAGS_GL="$ac_path_to_link"
3669                     fi
3670
3671                     dnl don't suppose that libGL and libGLU are always in the
3672                     dnl same directory -- this is not true for some common
3673                     dnl distributions
3674                     AC_MSG_CHECKING([for -lGLU])
3675                     WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],GLU)
3676                     if test "$ac_find_libraries" != "" ; then
3677                         WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3678                         if test "$ac_path_to_link" != " -L/usr/lib" -a \
3679                                     "$ac_path_to_link" != "$LDFLAGS_GL"; then
3680                             LDFLAGS_GL="$LDFLAGS_GL$ac_path_to_link"
3681                         fi
3682
3683                         found_gl=1
3684                         OPENGL_LIBS="-lGL -lGLU"
3685                         AC_MSG_RESULT([yes])
3686                     else
3687                         AC_MSG_RESULT([no])
3688                     fi
3689                 else
3690                     AC_MSG_RESULT([no])
3691                 fi
3692
3693                 if test "$found_gl" != 1; then
3694                     AC_MSG_CHECKING([for -lMesaGL])
3695                     WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],MesaGL)
3696                     if test "$ac_find_libraries" != "" ; then
3697                         WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
3698                         LDFLAGS_GL="$LDFLAGS$ac_path_to_link"
3699                         OPENGL_LIBS="-lMesaGL -lMesaGLU"
3700                         AC_MSG_RESULT([yes])
3701                     else
3702                         AC_MSG_RESULT([no])
3703                     fi
3704                 fi
3705             ],, [ ])
3706         ],
3707         [],
3708         [ ])
3709
3710         if test "x$OPENGL_LIBS" = "x"; then
3711             dnl it should be an error and not a warning because OpenGL is not on
3712             dnl by default and so if it had been explicitly requested, we
3713             dnl shouldn't just fall back to compiling the library without it
3714             AC_MSG_ERROR(OpenGL libraries not available)
3715         fi
3716     fi
3717
3718     if test "$wxUSE_OPENGL" = "yes"; then
3719         USE_OPENGL=1
3720         AC_DEFINE(wxUSE_OPENGL)
3721         AC_DEFINE(wxUSE_GLCANVAS)
3722         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS opengl opengl/cube opengl/penguin opengl/isosurf"
3723     fi
3724 fi
3725
3726
3727 dnl the symbol which allows conditional compilation for the given toolkit
3728 if test -n "$TOOLKIT" ; then
3729     TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WX${TOOLKIT}__"
3730 fi
3731
3732
3733 dnl --- the marker for quick search, leave it here: SHARED_LIB_SETUP ---
3734
3735 if test "$wxUSE_SHARED" = "yes"; then
3736     case "${host}" in
3737       *-pc-msdosdjgpp )
3738         dnl only static for now
3739         wxUSE_SHARED=no
3740         AC_MSG_WARN([Host system doesn't support shared libraries, disabling])
3741       ;;
3742     esac
3743 fi
3744
3745 if test "$wxUSE_SHARED" = "yes"; then
3746
3747     dnl use versioned symbols if available on the platform
3748     WX_VERSIONED_SYMBOLS([\$(wx_top_builddir)/version-script])
3749
3750     dnl test for GCC's visibility support (sets CFLAGS_VISIBILITY, which is
3751     dnl assigned to CFLAGS and CXXFLAGS below)
3752     if test "$wxUSE_VISIBILITY" != "no"; then
3753         WX_VISIBILITY
3754     fi
3755
3756     dnl test for Sun CC which can be used under both Solaris and Linux
3757     if test "x$SUNCXX" = xyes; then
3758         SAMPLES_RPATH_FLAG="-R\$(wx_top_builddir)/lib"
3759         WXCONFIG_RPATH="-R\$libdir"
3760     else
3761     case "${host}" in
3762       *-*-linux* | *-*-gnu* )
3763         SAMPLES_RPATH_FLAG="-Wl,-rpath,\$(wx_top_builddir)/lib"
3764         WXCONFIG_RPATH="-Wl,-rpath,\$libdir"
3765         ;;
3766
3767       *-*-solaris2* )
3768         dnl here we know that Sun CC is not used as we tested for it above,
3769         dnl hence we must be using gcc
3770
3771         dnl newer versions of gcc need -isystem to compile X headers on
3772         dnl Solaris (which use old style C syntax)
3773         CPPFLAGS="-isystem /usr/openwin/include $CPPFLAGS"
3774
3775         dnl gcc may use Sun's ld, in which case -rpath gives a confusing
3776         dnl error message. We have to try both -Wl,-rpath and -Wl,-R:
3777         saveLdflags="$LDFLAGS"
3778         LDFLAGS="$saveLdflags -Wl,-rpath,/"
3779         AC_MSG_CHECKING([if the linker accepts -rpath])
3780         AC_TRY_LINK(
3781             [],[],
3782             [
3783                 AC_MSG_RESULT([yes])
3784                 SAMPLES_RPATH_FLAG="-Wl,-rpath,\$(wx_top_builddir)/lib"
3785                 WXCONFIG_RPATH="-Wl,-rpath,\$libdir"
3786             ],[
3787                 AC_MSG_RESULT([no])
3788                 AC_MSG_CHECKING([if the linker accepts -R])
3789                 LDFLAGS="$saveLdflags -Wl,-R,/"
3790                 AC_TRY_LINK(
3791                     [],[],
3792                     [
3793                         AC_MSG_RESULT([yes])
3794                         SAMPLES_RPATH_FLAG="-Wl,-R,\$(wx_top_builddir)/lib"
3795                         WXCONFIG_RPATH="-Wl,-R,\$libdir"
3796                     ],[
3797                         AC_MSG_RESULT([no])
3798                     ])
3799             ])
3800         LDFLAGS="$saveLdflags"
3801       ;;
3802
3803       *-*-darwin* )
3804         install_name_tool=`which install_name_tool`
3805         if test "$install_name_tool" -a -x "$install_name_tool"; then
3806             SAMPLES_RPATH_POSTLINK="\$(wx_top_builddir)/change-install-names \$(LIBDIRNAME) \$(prefix) \$@"
3807             cat <<EOF >change-install-names
3808 #!/bin/sh
3809 libnames=\`cd \${1} ; ls -1 | grep '\.[[0-9]][[0-9]]*\.dylib\$'\`
3810 inst_cmd="install_name_tool "
3811 for i in \${libnames} ; do
3812     inst_cmd="\${inst_cmd} -change \${2}/lib/\${i} \${1}/\${i}"
3813 done
3814 \${inst_cmd} \${3}
3815 EOF
3816             chmod +x change-install-names
3817         fi
3818       ;;
3819
3820       *-*-cygwin* | *-*-mingw32* )
3821         ;;
3822
3823       *-*-hpux* )
3824         SAMPLES_RPATH_FLAG="-Wl,+b,\$(wx_top_builddir)/lib"
3825         WXCONFIG_RPATH="-Wl,+b,\$libdir"
3826         ;;
3827
3828     esac
3829     fi
3830
3831     dnl this one shouldn't be used for the library build so put it in a
3832     dnl separate variable from WXCONFIG_CPPFLAGS
3833     WXCONFIG_ONLY_CPPFLAGS="$WXCONFIG_ONLY_CPPFLAGS -DWXUSINGDLL"
3834
3835     if test $wxUSE_RPATH = "no"; then
3836         SAMPLES_RPATH_FLAG=''
3837         SAMPLES_RPATH_POSTLINK=''
3838         WXCONFIG_RPATH=''
3839     fi
3840
3841     SHARED=1
3842
3843 else
3844
3845     config_linkage_component="-static"
3846     SHARED=0
3847
3848 fi
3849
3850
3851 UNICODE=0
3852 lib_unicode_suffix=
3853 WX_CHARTYPE="ansi"
3854 if test "$wxUSE_UNICODE" = "yes"; then
3855     lib_unicode_suffix=u
3856     WX_CHARTYPE="unicode"
3857     UNICODE=1
3858 fi
3859
3860 lib_debug_suffix=
3861 WX_DEBUGTYPE="release"
3862 DEBUG_FLAG=0
3863 if test "$wxUSE_DEBUG_FLAG" = "yes"; then
3864     lib_debug_suffix=d
3865     WX_DEBUGTYPE="debug"
3866     DEBUG_FLAG=1
3867 fi
3868
3869 WX_FLAVOUR=${WX_FLAVOUR:+-$WX_FLAVOUR}
3870 WX_LIB_FLAVOUR=`echo $WX_FLAVOUR | tr '-' '_'`
3871
3872 DEBUG_INFO=0
3873 if test "$wxUSE_DEBUG_INFO" = "yes"; then
3874     DEBUG_INFO=1
3875 fi
3876
3877 WX_VERSION_TAG=`echo WX${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}_${WX_RELEASE} | tr '[[a-z]]' '[[A-Z]]'`
3878
3879 TOOLCHAIN_NAME="${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}"
3880
3881 TOOLCHAIN_FULLNAME="${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}-${WX_CHARTYPE}-${WX_DEBUGTYPE}${config_linkage_component}-${WX_RELEASE}${WX_FLAVOUR}"
3882
3883 if test "$cross_compiling" = "yes"; then
3884     HOST_SUFFIX="-$host_alias"
3885     TOOLCHAIN_NAME="$TOOLCHAIN_NAME$HOST_SUFFIX"
3886     TOOLCHAIN_FULLNAME="${host_alias}-$TOOLCHAIN_FULLNAME"
3887 fi
3888
3889 dnl library link name
3890 dnl These just save us from exporting lib_{unicode,debug,flavour}_suffix.
3891 dnl If we ever need to do that, we won't need to keep these.
3892 WX_LIBRARY_BASENAME_NOGUI="wx_base${WXBASEPORT}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}"
3893 if test "${TOOLKIT_DIR}" = "os2"; then
3894     WX_LIBRARY_BASENAME_GUI="wx_pm${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}"
3895 else
3896     WX_LIBRARY_BASENAME_GUI="wx_${TOOLKIT_DIR}${TOOLKIT_VERSION}${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}${WX_LIB_FLAVOUR}"
3897 fi
3898
3899
3900
3901 if test "$wxUSE_COCOA" = 1; then
3902     AC_LANG_SAVE
3903     AC_WX_LANG_OBJECTIVEC
3904 dnl Recent AppKit/NSEvent.h include parts of IOKit which eventually
3905 dnl gets IOKit/graphics/IOGraphicsTypes.h included which typedefs
3906 dnl Point but only if MacTypes.h was not included first.  Of course,
3907 dnl if MacTypes.h is included later then you're screwed when it
3908 dnl tries to typedef Point.  Defining __Point__ will cause IOGraphicsTypes.h
3909 dnl to not typedef Point and thus fix the problem.
3910     AC_MSG_CHECKING([if AppKit/NSEvent.h conflicts with CoreFoundation])
3911     AC_TRY_COMPILE([#include <AppKit/NSEvent.h>
3912 #include <CoreFoundation/CoreFoundation.h>
3913         ],[],
3914         [AC_MSG_RESULT([no])],
3915         [AC_MSG_RESULT([yes])
3916         AC_MSG_CHECKING([if defining __Point__ will fix it])
3917         AC_TRY_COMPILE([#define __Point__ 1
3918 #include <AppKit/NSEvent.h>
3919 #include <CoreFoundation/CoreFoundation.h>
3920             ],[],
3921             [AC_MSG_RESULT([yes])
3922             AC_DEFINE(__Point__)
3923             ],
3924             [AC_MSG_FAILURE([no])]
3925         )]
3926     )
3927     AC_LANG_RESTORE
3928 fi
3929
3930 dnl ---------------------------------------------------------------------------
3931 dnl Checks for typedefs
3932 dnl ---------------------------------------------------------------------------
3933
3934 dnl   defines mode_t if not already defined
3935 AC_TYPE_MODE_T
3936 dnl   defines off_t if not already defined
3937 AC_TYPE_OFF_T
3938 dnl   defines pid_t if not already defined
3939 AC_TYPE_PID_T
3940 dnl   defines size_t if not already defined
3941 AC_TYPE_SIZE_T
3942
3943 dnl sets HAVE_SSIZE_T if ssize_t is defined
3944 AC_CHECK_TYPES(ssize_t)
3945
3946 dnl check what exactly size_t is on this machine - this is necessary to avoid
3947 dnl ambiguous overloads in several places, notably wx/string.h and wx/array.h
3948 AC_LANG_PUSH(C++) dnl tests below use overloaded functions and so need C++
3949 AC_CACHE_CHECK([if size_t is unsigned int],
3950     wx_cv_size_t_is_uint,
3951     [
3952     dnl an obvious check like AC_TRY_COMPILE[struct Foo { ... };] doesn't work
3953     dnl with egcs (at least) up to 1.1.1 as it allows you to compile duplicate
3954     dnl methods in a local class (i.e. class inside a function) declaration
3955     dnl without any objections!!
3956     dnl
3957     dnl hence the hack below: we must have Foo at global scope!
3958     AC_TRY_COMPILE([#include <stddef.h>],
3959         [
3960             return 0; }
3961
3962             struct Foo { void foo(size_t); void foo(unsigned int); };
3963
3964             int bar() {
3965         ],
3966         wx_cv_size_t_is_uint=no,
3967         wx_cv_size_t_is_uint=yes
3968     )
3969     ]
3970 )
3971
3972 if test "$wx_cv_size_t_is_uint" = "yes"; then
3973     AC_DEFINE(wxSIZE_T_IS_UINT)
3974 else
3975     AC_CACHE_CHECK([if size_t is unsigned long],
3976         wx_cv_size_t_is_ulong,
3977         AC_TRY_COMPILE([#include <stddef.h>],
3978             [
3979                 return 0; }
3980
3981                 struct Foo { void foo(size_t); void foo(unsigned long); };
3982
3983                 int bar() {
3984             ],
3985             wx_cv_size_t_is_ulong=no,
3986             wx_cv_size_t_is_ulong=yes
3987         )
3988     )
3989
3990     if test "$wx_cv_size_t_is_ulong" = "yes"; then
3991         AC_DEFINE(wxSIZE_T_IS_ULONG)
3992     fi
3993 fi
3994
3995 AC_CACHE_CHECK([if wchar_t is separate type],
3996     wx_cv_wchar_t_is_separate_type,
3997     AC_TRY_COMPILE([#include <wchar.h>],
3998         [
3999             return 0; }
4000
4001             struct Foo { void foo(wchar_t);
4002                          void foo(unsigned short);
4003                          void foo(unsigned int);
4004                          void foo(unsigned long); };
4005
4006             int bar() {
4007         ],
4008         wx_cv_wchar_t_is_separate_type=yes,
4009         wx_cv_wchar_t_is_separate_type=no
4010     )
4011 )
4012
4013 if test "$wx_cv_wchar_t_is_separate_type" = "yes"; then
4014     AC_DEFINE(wxWCHAR_T_IS_REAL_TYPE, 1)
4015 else
4016     AC_DEFINE(wxWCHAR_T_IS_REAL_TYPE, 0)
4017 fi
4018
4019 AC_LANG_POP() dnl C++
4020
4021 dnl ---------------------------------------------------------------------------
4022 dnl Checks for structures
4023 dnl ---------------------------------------------------------------------------
4024
4025 dnl does passwd struct has the pw_gecos field?
4026 AC_CACHE_CHECK([for pw_gecos in struct passwd], wx_cv_struct_pw_gecos,
4027     [
4028         AC_TRY_COMPILE([#include <pwd.h>],
4029              [
4030                 char *p;
4031                 struct passwd *pw;
4032                 p = pw->pw_gecos;
4033              ],
4034              [
4035                 wx_cv_struct_pw_gecos=yes
4036              ],
4037              [
4038                 wx_cv_struct_pw_gecos=no
4039              ]
4040         )
4041     ]
4042 )
4043
4044 if test "$wx_cv_struct_pw_gecos" = "yes"; then
4045     AC_DEFINE(HAVE_PW_GECOS)
4046 fi
4047
4048 dnl ---------------------------------------------------------------------------
4049 dnl Check for functions
4050 dnl ---------------------------------------------------------------------------
4051
4052 dnl don't check for wchar_t functions if we haven't got wchar_t itself
4053 if test "$wxUSE_WCHAR_T" = "yes"; then
4054     AC_DEFINE(wxUSE_WCHAR_T)
4055
4056     dnl check for wcslen in all possible places
4057     WCSLEN_FOUND=0
4058     WCHAR_LINK=
4059     AC_CHECK_FUNCS(wcslen, WCSLEN_FOUND=1)
4060
4061     if test "$WCSLEN_FOUND" = 0; then
4062         if test "$TOOLKIT" = "MSW"; then
4063             AC_CHECK_LIB(msvcrt, wcslen, WCHAR_OK=1)
4064         else
4065             AC_CHECK_LIB(w, wcslen, [
4066                             WCHAR_LINK=" -lw"
4067                             WCSLEN_FOUND=1
4068                         ])
4069         fi
4070     fi
4071
4072     if test "$WCSLEN_FOUND" = 1; then
4073         AC_DEFINE(HAVE_WCSLEN)
4074     fi
4075
4076     AC_CHECK_FUNCS([wcsdup])
4077
4078     dnl On HP-UX aCC need this define to find mbstrtowcs() &c
4079     dnl Can't be used for g++ since the mbstate_t in wchar.h can conflict
4080     dnl with g++'s in <cwchar> (unless -D_INCLUDE__STDC_A1_SOURCE is in the
4081     dnl flags when g++ is configured, it will declare it's own).
4082     if test "$USE_HPUX" = 1 -a "$GCC" != "yes"; then
4083         CPPFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CPPFLAGS"
4084     fi
4085
4086     dnl Try to use wcsrtombs instead of wcstombs which is buggy in old GNU
4087     dnl libc versions if possible. AC_CHECK_FUNCS only checks it's in the
4088     dnl library, not the header, so do a header check for mbstate_t first.
4089     AC_CHECK_TYPES([mbstate_t],
4090                    [AC_CHECK_FUNCS(wcsrtombs)],
4091                    [],
4092                    [#include <wchar.h>])
4093 else
4094     AC_MSG_WARN([Wide character support is unavailable])
4095 fi
4096
4097 dnl check for vsnprintf() -- a safe version of vsprintf())
4098 dnl
4099 dnl the trouble here is that on some systems (e.g HP-UX 10) this function is
4100 dnl present in libc but not in the system headers and so AC_CHECK_FUNCS (which,
4101 dnl stupidly, provides a dummy function declaration inside its extension)
4102 dnl succeeds, even with C++ compiler, but the compilation of wxWidgets fails
4103 dnl
4104 dnl so we first check if the function is in the library
4105 dnl
4106 dnl FIXME: replace this mess with WX_CHECK_FUNCS()
4107 AC_CHECK_FUNCS(snprintf vsnprintf vsscanf)
4108
4109 AC_LANG_PUSH(C++)
4110 if test "$ac_cv_func_vsnprintf" = "yes"; then
4111     dnl yes it is -- now check if it is in the headers
4112     AC_CACHE_CHECK([for vsnprintf declaration], wx_cv_func_vsnprintf_decl,
4113         [
4114             dnl our troubles are not over: HP-UX 11 prototypes vsnprintf() as
4115             dnl taking "char *" and not "const char *" while Metrowerks does
4116             dnl provide a correct vsnprintf declaration but in C++ mode it's
4117             dnl always in std namespace and so we have to bring it in scope
4118             AC_TRY_COMPILE(
4119                 [
4120                     #include <stdio.h>
4121                     #include <stdarg.h>
4122                     #ifdef __MSL__
4123                     #if __MSL__ >= 0x6000
4124                     namespace std {}
4125                     using namespace std;
4126                     #endif
4127                     #endif
4128                 ],
4129                 [
4130                     char *buf;
4131                     va_list ap;
4132                     vsnprintf(buf, 10u, "%s", ap);
4133                 ],
4134                 wx_cv_func_vsnprintf_decl=yes,
4135                 wx_cv_func_vsnprintf_decl=no
4136             )
4137         ]
4138     )
4139
4140     if test "$wx_cv_func_vsnprintf_decl" = "yes"; then
4141         AC_DEFINE(HAVE_VSNPRINTF_DECL)
4142
4143         dnl we know there is a vsnprintf declaration, but some old headers
4144         dnl may have one taking a "char *" format instead of "const char *"
4145         AC_CACHE_CHECK([if vsnprintf declaration is broken], wx_cv_func_broken_vsnprintf_decl,
4146             [
4147                 AC_TRY_COMPILE(
4148                     [
4149                         #include <stdio.h>
4150                         #include <stdarg.h>
4151                         #ifdef __MSL__
4152                         #if __MSL__ >= 0x6000
4153                         namespace std {}
4154                         using namespace std;
4155                         #endif
4156                         #endif
4157                     ],
4158                     [
4159                         char *buf;
4160                         va_list ap;
4161                         const char *fmt = "%s";
4162                         vsnprintf(buf, 10u, fmt, ap);
4163                     ],
4164                     wx_cv_func_broken_vsnprintf_decl=no,
4165                     wx_cv_func_broken_vsnprintf_decl=yes
4166                 )
4167             ]
4168         )
4169
4170         if test "$wx_cv_func_broken_vsnprintf_decl" = "yes"; then
4171             AC_DEFINE(HAVE_BROKEN_VSNPRINTF_DECL)
4172         fi
4173     fi
4174 fi
4175
4176 dnl the same as above but for snprintf() now: it's not present in at least AIX
4177 dnl 4.2 headers
4178 if test "$ac_cv_func_snprintf" = "yes"; then
4179     AC_CACHE_CHECK([for snprintf declaration], wx_cv_func_snprintf_decl,
4180         [
4181             AC_TRY_COMPILE(
4182                 [
4183                     #include <stdio.h>
4184                     #include <stdarg.h>
4185                     #ifdef __MSL__
4186                     #if __MSL__ >= 0x6000
4187                     namespace std {}
4188                     using namespace std;
4189                     #endif
4190                     #endif
4191                 ],
4192                 [
4193                     char *buf;
4194                     snprintf(buf, 10u, "%s", "wx");
4195                 ],
4196                 wx_cv_func_snprintf_decl=yes,
4197                 wx_cv_func_snprintf_decl=no
4198             )
4199         ]
4200     )
4201
4202     if test "$wx_cv_func_snprintf_decl" = "yes"; then
4203         AC_DEFINE(HAVE_SNPRINTF_DECL)
4204     fi
4205
4206     if test "$wxUSE_PRINTF_POS_PARAMS" = "yes"; then
4207
4208         dnl check if snprintf() has support for positional arguments
4209         dnl NB: if snprintf() has positional support we can safely suppose that also
4210         dnl     other *printf() functions support them as they all belong to the same
4211         dnl     family and they all fallback to the same implementation
4212         AC_CACHE_CHECK([if snprintf supports positional arguments], wx_cv_func_snprintf_pos_params,
4213             [
4214                 AC_TRY_RUN(
4215                     [
4216                         #include <stdio.h>
4217
4218                         int main (void)
4219                         {
4220                             char buffer[128];
4221                             snprintf (buffer, 128, "%2$d %3$d %1$d", 1, 2, 3);
4222                             if (strcmp ("2 3 1", buffer) == 0)
4223                                 exit (0);
4224                             exit (1);
4225                         }
4226                     ],
4227                     wx_cv_func_snprintf_pos_params=no,
4228                     wx_cv_func_snprintf_pos_params=yes,
4229                     dnl be pessimistic when cross-compiling
4230                     [
4231                         AC_MSG_WARN([Assuming Unix98 printf() is not available,
4232 define HAVE_UNIX98_PRINTF as 1 in setup.h if it is available.])
4233                         wx_cv_func_snprintf_pos_params=no
4234                     ]
4235                 )
4236             ]
4237         )
4238
4239         if test "$wx_cv_func_snprintf_pos_params" = "yes"; then
4240             AC_DEFINE(HAVE_UNIX98_PRINTF)
4241         fi
4242     fi
4243 fi
4244
4245 dnl the same as above but for vsscanf() now: it's not present in at least
4246 dnl Solaris 9 headers for gcc-3.4 (due to fixinclude's processing of stdio.h)
4247 if test "$ac_cv_func_vsscanf" = "yes"; then
4248     AC_CACHE_CHECK([for vsscanf declaration], wx_cv_func_vsscanf_decl,
4249         [
4250             AC_TRY_COMPILE(
4251                 [
4252                     #include <stdio.h>
4253                     #include <stdarg.h>
4254                     #ifdef __MSL__
4255                     #if __MSL__ >= 0x6000
4256                     namespace std {}
4257                     using namespace std;
4258                     #endif
4259                     #endif
4260                 ],
4261                 [
4262                     char *buf;
4263                     va_list args;
4264                     vsscanf(buf, "%s", args);
4265                 ],
4266                 wx_cv_func_vsscanf_decl=yes,
4267                 wx_cv_func_vsscanf_decl=no
4268             )
4269         ]
4270     )
4271
4272     if test "$wx_cv_func_vsscanf_decl" = "yes"; then
4273         AC_DEFINE(HAVE_VSSCANF_DECL)
4274     fi
4275 fi
4276 AC_LANG_POP()
4277
4278 if test "$wxUSE_UNICODE" = yes; then
4279
4280     dnl also look if we have wide char IO functions, notice that [f]putws are
4281     dnl declared in special widec.h under Solaris
4282     wchar_headers="#include <stdio.h>
4283 #include <wchar.h>"
4284     case "${host}" in
4285         *-*-solaris2* )
4286             AC_CHECK_HEADERS(widec.h,,, [AC_INCLUDES_DEFAULT()])
4287             if test "$ac_cv_header_widec_h" = "yes"; then
4288                 wchar_headers="$wchar_headers
4289 #include <widec.h>"
4290             fi
4291     esac
4292
4293     WX_CHECK_FUNCS(putws fputws wprintf vswprintf vswscanf,,,
4294                    [$wchar_headers])
4295
4296     dnl MinGW has a vswprintf with a different prototype, and
4297     dnl a _vsnwprintf with the correct prototype, but AC_CHECK_FUNCS
4298     dnl finds it even if it is not declared in some versions...
4299     AC_MSG_CHECKING([for _vsnwprintf])
4300     AC_TRY_COMPILE([#include <wchar.h>],
4301                    [&_vsnwprintf;],
4302                    [AC_MSG_RESULT([yes])
4303                     AC_DEFINE(HAVE__VSNWPRINTF)],
4304                    [AC_MSG_RESULT([no])]);
4305 fi
4306
4307 if test "$wxUSE_FILE" = "yes"; then
4308     WX_CHECK_FUNCS(fsync)
4309 fi
4310
4311 dnl at least under IRIX with mipsPro the C99 round() function is available when
4312 dnl building using the C compiler but not when using C++ one
4313 AC_LANG_PUSH(C++)
4314 WX_CHECK_FUNCS(round,,,[#include <math.h>])
4315 AC_LANG_POP()
4316
4317 dnl the following tests are for Unix(like) systems only
4318 if test "$TOOLKIT" != "MSW"; then
4319
4320 dnl check for available version of iconv()
4321 if test "$wxUSE_LIBICONV" != "no" ; then
4322     AM_ICONV
4323     LIBS="$LIBICONV $LIBS"
4324 fi
4325
4326 dnl check for POSIX signals if we need them
4327 if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes" -a "$wxUSE_UNIX" = "yes"; then
4328     AC_CHECK_FUNCS(sigaction)
4329
4330     if test "$ac_cv_func_sigaction" = "no"; then
4331         AC_MSG_WARN([No POSIX signal functions on this system, wxApp::OnFatalException will not be called])
4332         wxUSE_ON_FATAL_EXCEPTION=no
4333     fi
4334
4335     if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
4336       AC_CACHE_CHECK([for sa_handler type], wx_cv_type_sa_handler,
4337       [
4338         dnl C compiler happily compiles the code even if there is type mismatch
4339         AC_LANG_PUSH(C++)
4340         AC_TRY_COMPILE([#include <signal.h>],
4341                      [
4342                         extern void testSigHandler(int);
4343
4344                         struct sigaction sa;
4345                         sa.sa_handler = testSigHandler;
4346                      ], [
4347                         wx_cv_type_sa_handler=int
4348                      ], [
4349                         wx_cv_type_sa_handler=void
4350                      ])
4351         AC_LANG_POP()
4352       ])
4353
4354       AC_DEFINE_UNQUOTED(wxTYPE_SA_HANDLER, $wx_cv_type_sa_handler)
4355     fi
4356 fi
4357
4358 dnl backtrace() and backtrace_symbols() for wxStackWalker
4359 if test "$wxUSE_STACKWALKER" = "yes" -a "$wxUSE_UNIX" = "yes"; then
4360     AC_CACHE_CHECK([for backtrace() in <execinfo.h>], wx_cv_func_backtrace,
4361         [
4362             AC_LANG_PUSH(C++)
4363             AC_TRY_COMPILE([#include <execinfo.h>],
4364                 [
4365                     void *trace[1];
4366                     char **messages;
4367
4368                     backtrace(trace, 1);
4369                     messages = backtrace_symbols(trace, 1);
4370                 ],
4371                 wx_cv_func_backtrace=yes,
4372                 wx_cv_func_backtrace=no
4373             )
4374             AC_LANG_POP()
4375         ]
4376     )
4377
4378
4379     if test "$wx_cv_func_backtrace" = "no"; then
4380         AC_MSG_WARN([backtrace() is not available, wxStackWalker will not be available])
4381         wxUSE_STACKWALKER=no
4382     else
4383         AC_CACHE_CHECK([for __cxa_demangle() in <cxxabi.h>], wx_cv_func_cxa_demangle,
4384             [
4385                 AC_LANG_PUSH(C++)
4386                 AC_TRY_LINK([#include <cxxabi.h>],
4387                     [
4388                         int rc;
4389                         __cxxabiv1::__cxa_demangle("foo", 0, 0, &rc);
4390                     ],
4391                     wx_cv_func_cxa_demangle=yes,
4392                     wx_cv_func_cxa_demangle=no
4393                 )
4394                 AC_LANG_POP()
4395             ]
4396         )
4397
4398         if test "$wx_cv_func_cxa_demangle" = "yes"; then
4399             AC_DEFINE(HAVE_CXA_DEMANGLE)
4400         fi
4401     fi
4402 fi
4403
4404 if test "$wxUSE_STACKWALKER" = "yes" -a "$USE_WIN32" != 1 -a "$USE_UNIX" != 1; then
4405     AC_MSG_WARN([wxStackWalker is only available on Win32 and UNIX... disabled])
4406     wxUSE_STACKWALKER=no
4407 fi
4408
4409
4410 dnl check for the function for temp files creation
4411 AC_CHECK_FUNCS(mkstemp mktemp, break)
4412
4413 dnl get the library function to use for wxGetDiskSpace(): it is statfs() under
4414 dnl Linux and *BSD and statvfs() under Solaris
4415 AC_CACHE_CHECK(for statfs, wx_cv_func_statfs,
4416     AC_TRY_COMPILE(
4417         [
4418              #if defined(__BSD__)
4419              #include <sys/param.h>
4420              #include <sys/mount.h>
4421              #else
4422              #include <sys/vfs.h>
4423              #endif
4424         ],
4425         [
4426              long l;
4427              struct statfs fs;
4428              statfs("/", &fs);
4429              l = fs.f_bsize;
4430              l += fs.f_blocks;
4431              l += fs.f_bavail;
4432         ],
4433          wx_cv_func_statfs=yes,
4434          wx_cv_func_statfs=no
4435     )
4436 )
4437
4438 if test "$wx_cv_func_statfs" = "yes"; then
4439     dnl check whether we have its dcelaration too: some systems (AIX 4) lack it
4440     AC_CACHE_CHECK(for statfs declaration, wx_cv_func_statfs_decl,
4441         AC_LANG_PUSH(C++)
4442         AC_TRY_COMPILE(
4443             [
4444                  #if defined(__BSD__)
4445                  #include <sys/param.h>
4446                  #include <sys/mount.h>
4447                  #else
4448                  #include <sys/vfs.h>
4449                  #endif
4450             ],
4451             [
4452                 struct statfs fs;
4453                 statfs("", &fs);
4454             ],
4455             wx_cv_func_statfs_decl=yes,
4456             wx_cv_func_statfs_decl=no
4457         )
4458         AC_LANG_POP()
4459     )
4460
4461     if test "$wx_cv_func_statfs_decl" = "yes"; then
4462         AC_DEFINE(HAVE_STATFS_DECL)
4463     fi
4464
4465     wx_cv_type_statvfs_t="struct statfs"
4466     AC_DEFINE(HAVE_STATFS)
4467 else
4468     AC_CACHE_CHECK(for statvfs, wx_cv_func_statvfs,
4469         AC_TRY_COMPILE(
4470             [
4471                 #include <stddef.h>
4472                 #include <sys/statvfs.h>
4473             ],
4474             [
4475                 statvfs("/", NULL);
4476             ],
4477             wx_cv_func_statvfs=yes,
4478             wx_cv_func_statvfs=no
4479         )
4480     )
4481
4482     if test "$wx_cv_func_statvfs" = "yes"; then
4483         dnl we also have to check whether we should use statvfs_t (works under
4484         dnl Solaris 8, doesn't work under Solaris 7) or "struct statvfs" (vice
4485         dnl versa) as the argument for statvfs in 64 bit off_t mode (in 32 bit
4486         dnl mode both work fine)
4487         dnl
4488         dnl for this check C++ compiler has to be used as passing incompatible
4489         dnl pointers is just a warning and not an error in C
4490         AC_CACHE_CHECK(for statvfs argument type, wx_cv_type_statvfs_t,
4491             AC_LANG_PUSH(C++)
4492             AC_TRY_COMPILE(
4493                 [
4494                     #include <sys/statvfs.h>
4495                 ],
4496                 [
4497                     long l;
4498                     statvfs_t fs;
4499                     statvfs("/", &fs);
4500                     l = fs.f_bsize;
4501                     l += fs.f_blocks;
4502                     l += fs.f_bavail;
4503                 ],
4504                 wx_cv_type_statvfs_t=statvfs_t,
4505                 [
4506                     AC_TRY_COMPILE(
4507                         [
4508                             #include <sys/statvfs.h>
4509                         ],
4510                         [
4511                             long l;
4512                             struct statvfs fs;
4513                             statvfs("/", &fs);
4514                             l = fs.f_bsize;
4515                             l += fs.f_blocks;
4516                             l += fs.f_bavail;
4517                         ],
4518                         wx_cv_type_statvfs_t="struct statvfs",
4519                         wx_cv_type_statvfs_t="unknown"
4520                     )
4521                 ]
4522             )
4523             AC_LANG_POP()
4524         )
4525
4526         if test "$wx_cv_type_statvfs_t" != "unknown"; then
4527             AC_DEFINE(HAVE_STATVFS)
4528         fi
4529     else
4530         dnl set it for the test below
4531         wx_cv_type_statvfs_t="unknown"
4532     fi
4533 fi
4534
4535 if test "$wx_cv_type_statvfs_t" != "unknown"; then
4536     AC_DEFINE_UNQUOTED(WX_STATFS_T, $wx_cv_type_statvfs_t)
4537 else
4538     AC_MSG_WARN([wxGetDiskSpace() function won't work without statfs()])
4539 fi
4540
4541 dnl check for fcntl() or at least flock() needed by Unix implementation of
4542 dnl wxSingleInstanceChecker
4543 if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
4544     AC_CHECK_FUNCS(fcntl flock, break)
4545
4546     if test "$ac_cv_func_fcntl" != "yes" -a "$ac_cv_func_flock" != "yes"; then
4547         AC_MSG_WARN(wxSingleInstanceChecker not available)
4548         wxUSE_SNGLINST_CHECKER=no
4549     fi
4550 fi
4551
4552 dnl look for a function to modify the environment
4553 AC_CHECK_FUNCS(setenv putenv, break)
4554 if test "$ac_cv_func_setenv" = "yes"; then
4555     AC_CHECK_FUNCS(unsetenv)
4556 fi
4557
4558 HAVE_SOME_SLEEP_FUNC=0
4559 if test "$USE_BEOS" = 1; then
4560     dnl BeOS has its own (wonder where did they get it from) sleep() function
4561     dnl in unistd.h
4562     AC_DEFINE(HAVE_SLEEP)
4563     HAVE_SOME_SLEEP_FUNC=1
4564 fi
4565
4566 if test "$USE_DARWIN" = 1; then
4567     dnl Mac OS X/Darwin has both nanosleep and usleep
4568     dnl but only usleep is defined in unistd.h
4569     AC_DEFINE(HAVE_USLEEP)
4570     HAVE_SOME_SLEEP_FUNC=1
4571 fi
4572
4573 if test "$HAVE_SOME_SLEEP_FUNC" != 1; then
4574     dnl try nanosleep() in libc and libposix4, if this fails - usleep()
4575     POSIX4_LINK=
4576     AC_CHECK_FUNCS(nanosleep,
4577         AC_DEFINE(HAVE_NANOSLEEP),
4578         [
4579             AC_CHECK_LIB(posix4, nanosleep,
4580                 [
4581                     AC_DEFINE(HAVE_NANOSLEEP)
4582                     POSIX4_LINK=" -lposix4"
4583                 ],
4584                 [
4585                     WX_CHECK_FUNCS(usleep,,
4586                                     AC_MSG_WARN([wxSleep() function will not work])
4587                     )
4588                 ]
4589             )
4590         ]
4591     )
4592 fi
4593
4594 dnl check for uname (POSIX) and gethostname (BSD)
4595 WX_CHECK_FUNCS(uname,,,[#include <sys/utsname.h>])
4596 if test "$wx_cv_func_uname" != yes; then
4597     WX_CHECK_FUNCS(gethostname)
4598 fi
4599
4600 WX_CHECK_FUNCS(strtok_r, [], [], [#define _REENTRANT])
4601
4602 dnl check for inet_addr and inet_aton (these may live either in libc, or in
4603 dnl libnsl or libresolv or libsocket)
4604 INET_LINK=
4605 AC_CHECK_FUNCS(inet_addr,
4606     AC_DEFINE(HAVE_INET_ADDR),
4607     [
4608         AC_CHECK_LIB(nsl, inet_addr,
4609             INET_LINK="nsl",
4610             [
4611                 AC_CHECK_LIB(resolv, inet_addr,
4612                     INET_LINK="resolv",
4613                     [
4614                         AC_CHECK_LIB(socket, inet_addr,
4615                             INET_LINK="socket"
4616                         )
4617                     ]
4618                 )
4619             ]
4620         )
4621     ]
4622 )
4623
4624 AC_CHECK_FUNCS(inet_aton,
4625         AC_DEFINE(HAVE_INET_ATON),
4626         [
4627             dnl only check it in the same lib
4628             AC_CHECK_LIB($INET_LINK, inet_aton, AC_DEFINE(HAVE_INET_ATON))
4629         ])
4630
4631 if test "x$INET_LINK" != "x"; then
4632     AC_DEFINE(HAVE_INET_ADDR)
4633     INET_LINK=" -l$INET_LINK"
4634 fi
4635
4636 WX_CHECK_FUNCS(fdopen)
4637
4638 if test "$wxUSE_TARSTREAM" = "yes"; then
4639     WX_CHECK_FUNCS(sysconf)
4640
4641     WX_CHECK_FUNCS(getpwuid_r, [], [],
4642                    [
4643                     #define _REENTRANT
4644                     #include <pwd.h>
4645                    ],
4646                    [[
4647                     struct passwd pw, *ppw;
4648                     char buf[1024];
4649                     getpwuid_r(0, &pw, buf, sizeof(buf), &ppw)
4650                    ]])
4651
4652     WX_CHECK_FUNCS(getgrgid_r, [], [],
4653                    [
4654                     #define _REENTRANT
4655                     #include <grp.h>
4656                    ],
4657                    [[
4658                     struct group grp, *pgrp;
4659                     char buf[1024];
4660                     getgrgid_r(0, &grp, buf, sizeof(buf), &pgrp)
4661                    ]])
4662 fi
4663
4664 fi
4665
4666
4667 dnl ===========================================================================
4668 dnl Now we have all the info we need - use it!
4669 dnl ===========================================================================
4670
4671 dnl flush the cache
4672 AC_CACHE_SAVE
4673
4674 dnl ---------------------------------------------------------------------------
4675 dnl thread support for Unix (for Win32 and OS/2 see past
4676 dnl                          the next matching "else")
4677 dnl ---------------------------------------------------------------------------
4678
4679 dnl under MSW (except mingw32) we always have thread support
4680 if test "$TOOLKIT" != "MSW" -a "$USE_OS2" != 1; then
4681
4682     dnl the code below:
4683     dnl
4684     dnl   defines THREADS_LINK and THREADS_CFLAGS which are the options
4685     dnl   necessary to build the MT programs for the linker and compiler
4686     dnl   respectively
4687     dnl
4688     dnl   sets wxUSE_THREADS=1 if thread support is activated
4689
4690     THREADS_LINK=
4691     THREADS_CFLAGS=
4692
4693     if test "$wxUSE_THREADS" = "yes" ; then
4694         if test "$USE_BEOS" = 1; then
4695             AC_MSG_WARN([BeOS threads are not yet supported... disabled])
4696             wxUSE_THREADS="no"
4697         fi
4698     fi
4699
4700     if test "$wxUSE_THREADS" = "yes" ; then
4701         dnl find if POSIX threads are available
4702         dnl
4703         dnl the tests here are based on ACX_PTHREAD macro from autoconf macro
4704         dnl archive from http://ac-archive.sourceforge.net/
4705         dnl
4706         dnl thanks to Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro
4707         dnl Forero Cuervo <bachue@bachue.com> for the original code
4708
4709         dnl TODO: cache the result
4710
4711         dnl define the list of the thread options to try in the loop below
4712         dnl with the convention that anything starting with '-' is a cpp flag
4713         dnl while anything else is a library (i.e. there is an implicit "-l")
4714         THREAD_OPTS="-pthread"
4715         if test "x$SUNCXX" = xyes; then
4716             THREAD_OPTS="-mt lthread $THREAD_OPTS"
4717         fi
4718
4719         case "${host}" in
4720           *-*-solaris2* | *-*-sunos4* )
4721                 if test "x$GCC" = "xyes"; then
4722                     dnl Solaris/gcc combination use this one for some reason
4723                     THREAD_OPTS="-pthreads $THREAD_OPTS"
4724                 fi
4725                 ;;
4726           *-*-freebsd*)
4727                 dnl look, in order, for the kernel threads, then Linux threads
4728                 dnl and finally the userland threads
4729                 THREAD_OPTS="-kthread lthread $THREAD_OPTS c_r"
4730                 ;;
4731           *-*-darwin* | *-*-cygwin* )
4732                 dnl Darwin / Mac OS X just uses -lpthread tested below
4733                 dnl and so does Cygwin
4734                 THREAD_OPTS=""
4735                 ;;
4736           *-*-aix*)
4737                 dnl AIX calls the library libpthreads - thanks IBM!
4738                 THREAD_OPTS="pthreads"
4739                 ;;
4740           *-hp-hpux* )
4741                 if test "x$GCC" = "xyes"; then
4742                     dnl g++ versions before 3.3.2 don't support -pthread.
4743                     $CXX -dumpspecs | grep 'pthread:' >/dev/null ||
4744                         THREAD_OPTS=""
4745                 else
4746                     dnl HP-UX aCC (tested with version B3910B A.06.05 [Jul 25
4747                     dnl 2005]) supports -mt
4748                     THREAD_OPTS="-mt"
4749                 fi
4750                 ;;
4751
4752           *-*-irix* )
4753                 dnl gcc under IRIX doesn't seem to like -pthread, but it
4754                 dnl doesn't give an error for it neither, just a warning
4755                 dnl message -- but this is still very annoying
4756                 if test "x$GCC" = "xyes"; then
4757                     THREAD_OPTS=""
4758                 fi
4759                 ;;
4760
4761           *-*-*UnixWare*)
4762                 dnl flying by man pages here: Caldera online docs use this
4763                 if test "x$GCC" != "xyes"; then
4764                     THREAD_OPTS="-Ethread"
4765                 fi
4766                 ;;
4767         esac
4768
4769         dnl simply linking with libpthread should make the test below work but
4770         dnl it's far from certain that the threaded programs compiled without
4771         dnl any special switches actually work, so try it after all the others
4772         THREAD_OPTS="$THREAD_OPTS pthread none"
4773
4774         dnl now test for all possibilities
4775         THREADS_OK=no
4776         for flag in $THREAD_OPTS; do
4777             case $flag in
4778                 none)
4779                     AC_MSG_CHECKING([whether pthreads work without any flags])
4780                     ;;
4781
4782                 -*)
4783                     AC_MSG_CHECKING([whether pthreads work with $flag])
4784                     THREADS_CFLAGS="$flag"
4785                     ;;
4786
4787                 *)
4788                     AC_MSG_CHECKING([for the pthreads library -l$flag])
4789                     THREADS_LINK="-l$flag"
4790                     ;;
4791               esac
4792
4793               save_LIBS="$LIBS"
4794               save_CFLAGS="$CFLAGS"
4795               LIBS="$THREADS_LINK $LIBS"
4796               CFLAGS="$THREADS_CFLAGS $CFLAGS"
4797
4798               AC_TRY_LINK([#include <pthread.h>],
4799                           [pthread_create(0,0,0,0);],
4800                           THREADS_OK=yes)
4801
4802               LIBS="$save_LIBS"
4803               CFLAGS="$save_CFLAGS"
4804
4805               AC_MSG_RESULT($THREADS_OK)
4806               if test "x$THREADS_OK" = "xyes"; then
4807                       break;
4808               fi
4809
4810               THREADS_LINK=""
4811               THREADS_CFLAGS=""
4812       done
4813
4814       if test "x$THREADS_OK" != "xyes"; then
4815           wxUSE_THREADS=no
4816           AC_MSG_WARN([No thread support on this system... disabled])
4817       else
4818           dnl yes, these special compiler flags should be used with the
4819           dnl linker as well
4820           LDFLAGS="$THREADS_CFLAGS $LDFLAGS"
4821           LIBS="$THREADS_LINK $LIBS"
4822
4823           AC_MSG_CHECKING([if more special flags are required for pthreads])
4824           flag=no
4825           case "${host}" in
4826             *-aix*)
4827                 dnl again quoting from
4828                 dnl http://www-1.ibm.com/servers/esdd/articles/gnu.html:
4829                 dnl
4830                 dnl     When compiling and linking with -pthread, the library
4831                 dnl     search path should include -L/usr/lib/threads at the
4832                 dnl     beginning of the path.
4833                 LDFLAGS="-L/usr/lib/threads $LDFLAGS"
4834                 flag="-D_THREAD_SAFE"
4835                 ;;
4836             *-freebsd*)
4837                 flag="-D_THREAD_SAFE"
4838                 ;;
4839             *-hp-hpux* )
4840                 flag="-D_REENTRANT"
4841                 if test "x$GCC" != "xyes"; then
4842                     dnl see http://docs.hp.com/hpux/onlinedocs/2213/threads.htm
4843                     flag="$flag -D_RWSTD_MULTI_THREAD"
4844                 fi
4845                 ;;
4846             *solaris* | alpha*-osf*)
4847                 flag="-D_REENTRANT"
4848                 ;;
4849           esac
4850           AC_MSG_RESULT(${flag})
4851           if test "x$flag" != xno; then
4852               THREADS_CFLAGS="$THREADS_CFLAGS $flag"
4853           fi
4854
4855           dnl don't add these options to CPPFLAGS as cpp might not know them
4856           WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS $THREADS_CFLAGS"
4857       fi
4858     fi
4859
4860     dnl do other tests only if we are using threads
4861     if test "$wxUSE_THREADS" = "yes" ; then
4862       AC_CHECK_FUNCS(thr_setconcurrency)
4863
4864       dnl can't use AC_CHECK_FUNCS for this one as it's usually a macro and so
4865       dnl wouldn't be found by it
4866       AC_CACHE_CHECK([for pthread_cleanup_push/pop], wx_cv_func_pthread_cleanup,
4867       [
4868         dnl C compiler may treat pthread_cleanup_push() as an undeclared
4869         dnl function and not give a warning even if it's unavailable, so use
4870         dnl the C++ one for this test
4871         AC_LANG_PUSH(C++)
4872         AC_TRY_COMPILE([#include <pthread.h>
4873                void ThreadCleanupFunc(void *p);
4874             ],
4875             [
4876                 void *p;
4877                 pthread_cleanup_push(ThreadCleanupFunc, p);
4878                 pthread_cleanup_pop(0);
4879             ], [
4880                wx_cv_func_pthread_cleanup=yes
4881             ], [
4882                wx_cv_func_pthread_cleanup=no
4883             ]
4884         )
4885         AC_LANG_POP()
4886       ])
4887       if test "x$wx_cv_func_pthread_cleanup" = "xyes"; then
4888         AC_DEFINE(wxHAVE_PTHREAD_CLEANUP)
4889       fi
4890
4891       AC_CHECK_HEADERS(sched.h,,, [AC_INCLUDES_DEFAULT()])
4892       if test "$ac_cv_header_sched_h" = "yes"; then
4893           AC_CHECK_FUNC(sched_yield,
4894             AC_DEFINE(HAVE_SCHED_YIELD),
4895             [
4896                 AC_CHECK_LIB(posix4,
4897                     sched_yield,
4898                     [AC_DEFINE(HAVE_SCHED_YIELD) POSIX4_LINK=" -lposix4"],
4899                     AC_MSG_WARN(wxThread::Yield will not work properly)
4900                 )
4901             ]
4902           )
4903       fi
4904
4905       dnl to be able to set the thread priority, we need to have all of the
4906       dnl following functions:
4907       dnl   1. pthread_attr_getschedpolicy
4908       dnl   2. sched_get_priority_min and sched_get_priority_max
4909       dnl      (this one can be in either libpthread or libposix4 (under Solaris))
4910       dnl   3. pthread_attr_getschedparam and pthread_attr_setschedparam
4911       HAVE_PRIOR_FUNCS=0
4912       AC_CHECK_FUNC(pthread_attr_getschedpolicy,
4913                      [AC_CHECK_FUNC(pthread_attr_setschedparam,
4914                        [AC_CHECK_FUNC(sched_get_priority_max,
4915                            HAVE_PRIOR_FUNCS=1,
4916                            [AC_CHECK_LIB([posix4], sched_get_priority_max,
4917                              [
4918                                 HAVE_PRIOR_FUNCS=1
4919                                 POSIX4_LINK=" -lposix4"
4920                              ],
4921                            )]
4922                        )]
4923                      )]
4924                    )
4925
4926       if test "$HAVE_PRIOR_FUNCS" = 1; then
4927         AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS)
4928       else
4929         AC_MSG_WARN(Setting thread priority will not work)
4930       fi
4931
4932       AC_CHECK_FUNC(pthread_cancel,
4933                     AC_DEFINE(HAVE_PTHREAD_CANCEL),
4934                     AC_MSG_WARN([wxThread::Kill() will not work properly]))
4935
4936       AC_CHECK_FUNC(pthread_mutex_timedlock,
4937                     AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK),
4938                     AC_MSG_WARN([wxMutex::LockTimeout() will not work]))
4939
4940       AC_CHECK_FUNC(pthread_attr_setstacksize,
4941                     AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE))
4942
4943       dnl mutexattr_t initialization is done in quite different ways on different
4944       dnl platforms, so check for a few things:
4945       dnl
4946       dnl HAVE_MUTEX_RECURSIVE means that we can create recursive mutexes
4947       dnl HAVE_MUTEXATTR_SETTYPE means that we do it using
4948       dnl pthread_mutexattr_settype(PTHREAD_MUTEX_RECURSIVE) and if it is not
4949       dnl defined, we do it by directly assigned
4950       dnl PTHREAD_MUTEX_RECURSIVE_MUTEX_INITIALIZER_NP to attr
4951
4952       AC_CACHE_CHECK([for pthread_mutexattr_t], wx_cv_type_pthread_mutexattr_t,
4953       [
4954         AC_TRY_COMPILE([#include <pthread.h>],
4955             [
4956                pthread_mutexattr_t attr;
4957                pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
4958             ],
4959             wx_cv_type_pthread_mutexattr_t=yes,
4960             wx_cv_type_pthread_mutexattr_t=no
4961         )
4962       ])
4963
4964       if test "$wx_cv_type_pthread_mutexattr_t" = "yes"; then
4965         AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_T)
4966
4967         dnl check if we already have the declaration we need, it is not
4968         dnl present in some systems' headers
4969         AC_CACHE_CHECK([for pthread_mutexattr_settype declaration],
4970                        wx_cv_func_pthread_mutexattr_settype_decl, [
4971                        AC_TRY_COMPILE([#include <pthread.h>],
4972                            [
4973                                pthread_mutexattr_t attr;
4974                                pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
4975                            ],
4976                            wx_cv_func_pthread_mutexattr_settype_decl=yes,
4977                            wx_cv_func_pthread_mutexattr_settype_decl=no
4978                        )
4979         ])
4980         if test "$wx_cv_func_pthread_mutexattr_settype_decl" = "yes"; then
4981             AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_SETTYPE_DECL)
4982         fi
4983       else
4984         dnl don't despair, there may be another way to do it
4985         AC_CACHE_CHECK([for PTHREAD_RECURSIVE_MUTEX_INITIALIZER],
4986                        wx_cv_type_pthread_rec_mutex_init,
4987         [
4988             AC_TRY_COMPILE([#include <pthread.h>],
4989                 [
4990                     pthread_mutex_t attr = PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP;
4991                 ], [
4992                     wx_cv_type_pthread_rec_mutex_init=yes
4993                 ], [
4994                     wx_cv_type_pthread_rec_mutex_init=no
4995                 ]
4996             )
4997         ])
4998         if test "$wx_cv_type_pthread_rec_mutex_init" = "yes"; then
4999           AC_DEFINE(HAVE_PTHREAD_RECURSIVE_MUTEX_INITIALIZER)
5000         else
5001           dnl this may break code working elsewhere, so at least warn about it
5002           AC_MSG_WARN([wxMutex won't be recursive on this platform])
5003         fi
5004       fi
5005
5006       dnl test for compiler thread-specific variables support
5007       AC_CACHE_CHECK([for __thread keyword],
5008                      wx_cv_cc___thread,
5009       [
5010           AC_TRY_COMPILE([#include <pthread.h>],
5011               [
5012                   static __thread int n = 0;
5013                   static __thread int *p = 0;
5014               ],
5015               wx_cv_cc___thread=yes,
5016               wx_cv_cc___thread=no
5017           )
5018       ])
5019
5020       if test "$wx_cv_cc___thread" = "yes"; then
5021         AC_DEFINE(HAVE___THREAD_KEYWORD)
5022       fi
5023     fi
5024
5025 dnl from if !MSW
5026 else
5027     if test "$wxUSE_THREADS" = "yes" ; then
5028       case "${host}" in
5029         x86_64-*-mingw32* )
5030         ;;
5031         *-*-mingw32* )
5032             dnl check if the compiler accepts -mthreads
5033             AC_CACHE_CHECK([if compiler supports -mthreads],
5034                 wx_cv_cflags_mthread,
5035                 [
5036                     CFLAGS_OLD="$CFLAGS"
5037                     CFLAGS="-mthreads $CFLAGS"
5038                     AC_TRY_COMPILE([], [],
5039                         wx_cv_cflags_mthread=yes,
5040                         wx_cv_cflags_mthread=no
5041                     )
5042                 ]
5043             )
5044
5045             if test "$wx_cv_cflags_mthread" = "yes"; then
5046                 dnl it does, use it
5047                 WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -mthreads"
5048                 LDFLAGS="$LDFLAGS -mthreads"
5049             else
5050                 dnl it doesn't
5051                 CFLAGS="$CFLAGS_OLD"
5052             fi
5053         ;;
5054         *-pc-os2*emx )
5055             WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -Zmt -D__ST_MT_ERRNO__"
5056             LDFLAGS="$LDFLAGS -Zmt"
5057         ;;
5058       esac
5059     fi
5060 fi
5061
5062 AC_CHECK_FUNC(localtime_r, [ AC_DEFINE(HAVE_LOCALTIME_R) ])
5063 AC_CHECK_FUNC(gmtime_r, [ AC_DEFINE(HAVE_GMTIME_R) ])
5064 dnl By preference, we probably should use getaddrinfo which avoids thread
5065 dnl safety issues and supports IPv6, however there currently is no code
5066 dnl for it, so testing for it is temporarily disabled and we are restricted
5067 dnl to gethostbyname_r/gethostbyaddr_r  and getservbyname_r
5068
5069 dnl AC_CHECK_FUNC(getaddrinfo, AC_DEFINE(HAVE_GETADDRINFO), [
5070     dnl no getaddrinfo, so check for gethostbyname_r and
5071     dnl related functions (taken from python's configure.in)
5072     dnl sigh -- gethostbyname_r is a mess; it can have 3, 5 or 6 arguments
5073       AX_FUNC_WHICH_GETHOSTBYNAME_R
5074       if test "x$ac_cv_func_which_gethostbyname_r" = "xno" -o \
5075               "x$ac_cv_func_which_gethostbyname_r" = "xunknown" ; then
5076           AC_CHECK_FUNC(gethostbyname, [ AC_DEFINE(HAVE_GETHOSTBYNAME) ])
5077       fi
5078       dnl A similar test for getservbyname_r
5079       dnl I'm tempted to just not do this test which is taking much time and
5080       dnl do something similar as for gethostbyaddr_r, but OTOH the macro
5081       dnl doing the test already exists, so using it is easy enough.     - SN
5082       AC_raf_FUNC_WHICH_GETSERVBYNAME_R
5083       if test "x$ac_cv_func_which_getservbyname_r" = "xno" -o \
5084               "x$ac_cv_func_which_getservbyname_r" = "xunknown" ; then
5085           AC_CHECK_FUNCS(getservbyname,[ AC_DEFINE(HAVE_GETSERVBYNAME) ])
5086       fi
5087       dnl For gethostbyaddr_r, we currently do no separate test, instead, we
5088       dnl silently assume it's available exactly if gethostbyname_r is
5089       dnl available and always requires two more arguments than
5090       dnl gethostbyname_r.
5091       dnl (also, I'm lazy and there no m4 file that's ready for use for this
5092       dnl  function, although it should be easy to rewrite the gethostbyname_r
5093       dnl  check to fit this case, if it's really needed.                - SN )
5094 dnl    ]
5095 dnl )
5096
5097 if test "$wxUSE_THREADS" = "yes"; then
5098   AC_DEFINE(wxUSE_THREADS)
5099
5100   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS thread"
5101 else
5102   dnl on some systems, _REENTRANT should be defined if we want to use any _r()
5103   dnl functions - add tests for other functions here as well
5104   if test "$wx_cv_func_strtok_r" = "yes"; then
5105     AC_MSG_CHECKING(if -D_REENTRANT is needed)
5106     if test "$NEEDS_D_REENTRANT_FOR_R_FUNCS" = 1; then
5107         WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D_REENTRANT"
5108         AC_MSG_RESULT(yes)
5109     else
5110         AC_MSG_RESULT(no)
5111     fi
5112   fi
5113 fi
5114
5115 if test "$WXGTK2" = 1 ; then
5116   AC_DEFINE_UNQUOTED(__WXGTK20__,$WXGTK2)
5117   WXGTK12=1
5118 fi
5119
5120 if test "$WXGTK12" = 1 ; then
5121   AC_DEFINE_UNQUOTED(__WXGTK12__,$WXGTK12)
5122 fi
5123
5124 if test "$WXGTK127" = 1 ; then
5125   AC_DEFINE_UNQUOTED(__WXGTK127__,$WXGTK127)
5126 fi
5127
5128 if test "$WXGPE" = 1 ; then
5129   AC_DEFINE_UNQUOTED(__WXGPE__,$WXGPE)
5130 fi
5131
5132 dnl DEBUG_CFLAGS contains debugging options (supposed to be the same for C and C++
5133 dnl compilers: we'd need a separate DEBUG_CXXFLAGS if this is ever not the case)
5134 DEBUG_CFLAGS=
5135 if test "$wxUSE_DEBUG_INFO" = "yes" ; then
5136     DEBUG_CFLAGS="-g"
5137 fi
5138
5139 if test "$wxUSE_DEBUG_GDB" = "yes" ; then
5140     wxUSE_DEBUG_INFO=yes
5141     if test "$GCC" = yes; then
5142         DEBUG_CFLAGS="-ggdb"
5143     fi
5144 fi
5145
5146 if test "$wxUSE_DEBUG_FLAG" = "yes" ; then
5147     AC_DEFINE(WXDEBUG)
5148     WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS -D__WXDEBUG__"
5149 else
5150     if test "$wxUSE_GTK" = 1 ; then
5151         if test "x$wxGTK_VERSION" = "x1" ; then
5152             CPPFLAGS="-DGTK_NO_CHECK_CASTS $CPPFLAGS"
5153         fi
5154     fi
5155 fi
5156
5157 if test "$wxUSE_MEM_TRACING" = "yes" ; then
5158     AC_DEFINE(wxUSE_MEMORY_TRACING)
5159     AC_DEFINE(wxUSE_GLOBAL_MEMORY_OPERATORS)
5160     AC_DEFINE(wxUSE_DEBUG_NEW_ALWAYS)
5161     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS memcheck"
5162 fi
5163
5164 if test "$wxUSE_DMALLOC" = "yes" ; then
5165     DMALLOC_LIBS="-ldmallocthcxx"
5166 fi
5167
5168 dnl cc/cxx/ld option for profiling
5169 PROFILE_FLAGS=
5170 if test "$wxUSE_PROFILE" = "yes" ; then
5171     PROFILE_FLAGS=" -pg"
5172 fi
5173
5174 if test "$GCC" = "yes" ; then
5175     if test "$wxUSE_NO_RTTI" = "yes" ; then
5176         WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fno-rtti"
5177     fi
5178     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
5179         WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fno-exceptions"
5180     fi
5181     if test "$wxUSE_PERMISSIVE" = "yes" ; then
5182         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -fpermissive"
5183     fi
5184
5185     dnl Ian Brown <ian.brown@printsoft.de> reports that versions of gcc before
5186     dnl 3.0 overflow the table of contents on rs6000 as they create an entry
5187     dnl for each subroutine by default -- using the switch below only creates
5188     dnl one entry per file instead at the price of minor performance penalty
5189     dnl
5190     dnl As of wx2.4 a bug in the hppa gcc compiler causes a similar problem
5191     dnl without -ffunction-sections.  No idea how long we'll need to maintain
5192     dnl this, or even the extent of gcc/wx version combinations affected, but
5193     dnl also as above, this 'fix' does not come without side effects.
5194     dnl
5195     dnl TODO: test for the gcc version here (how?)
5196     case "${host}" in
5197       powerpc*-*-aix* )
5198         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -mminimal-toc"
5199         ;;
5200       *-hppa* )
5201         WXCONFIG_CFLAGS="$WXCONFIG_CFLAGS -ffunction-sections"
5202         ;;
5203     esac
5204 fi
5205
5206 dnl C/C++ compiler option for optimization (supposed to be the same for both)
5207 OPTIMISE_CFLAGS=
5208 if test "$wxUSE_OPTIMISE" = "no" ; then
5209     if test "$GCC" = yes ; then
5210         dnl use -O0 because compiling with it is faster than compiling with no
5211         dnl optimization options at all (at least with g++ 3.2)
5212         OPTIMISE_CFLAGS="-O0"
5213     fi
5214 else
5215     if test "$GCC" = yes ; then
5216         case "${host}" in
5217             *-pc-os2_emx | *-pc-os2-emx )
5218                 dnl Not all of the supported gcc versions understand
5219                 dnl -fstrict-aliasing and none actually needs it (yet).
5220                 OPTIMISE_CFLAGS="-O2"
5221             ;;
5222             *)
5223                 dnl Switch on optimisation but keep strict-aliasing off for
5224                 dnl now (see -fstrict-aliasing in the gcc manual). When it is
5225                 dnl switched back on consider using -Wstrict-aliasing=2.
5226                 OPTIMISE_CFLAGS="-O2 -fno-strict-aliasing"
5227             ;;
5228         esac
5229     else
5230         OPTIMISE_CFLAGS="-O"
5231     fi
5232 fi
5233
5234 dnl ---------------------------------------------------------------------------
5235 dnl compatibility level
5236 dnl ---------------------------------------------------------------------------
5237
5238 if test "x$WXWIN_COMPATIBILITY_2_6" = "xyes"; then
5239     AC_DEFINE(WXWIN_COMPATIBILITY_2_6)
5240
5241     WXWIN_COMPATIBILITY_2_8="yes"
5242 fi
5243
5244 if test "x$WXWIN_COMPATIBILITY_2_8" != "xno"; then
5245     AC_DEFINE(WXWIN_COMPATIBILITY_2_8)
5246 fi
5247
5248 dnl ---------------------------------------------------------------------------
5249 dnl the library may be built without GUI classes at all
5250 dnl ---------------------------------------------------------------------------
5251
5252 if test "$wxUSE_GUI" = "yes"; then
5253     AC_DEFINE(wxUSE_GUI)
5254
5255     dnl the things we always pull in the GUI version of the library:
5256     dnl 1. basic things like wxApp, wxWindow, wxControl, wxFrame, wxDialog (the
5257     dnl    library really can't be built without those)
5258     dnl 2. basic controls: wxButton, wxStaticText, wxTextCtrl (these are used in
5259     dnl    almost any program and the first 2 are needed to show a message box
5260     dnl    which want to be always able to do)
5261     dnl 3. GDI stuff: icon, cursors and all that. Although it would be very nice
5262     dnl    to compile without them (if the app doesn't do any drawing, it doesn't
5263     dnl    need the dcs, pens, brushes, ...), this just can't be done now
5264     dnl 4. menu stuff: wxMenu, wxMenuBar, wxMenuItem
5265     dnl 5. misc stuff: timers, settings, message box
5266 fi
5267
5268 dnl ---------------------------------------------------------------------------
5269 dnl Unix/Windows
5270 dnl ---------------------------------------------------------------------------
5271
5272 if test "$wxUSE_UNIX" = "yes"; then
5273   AC_DEFINE(wxUSE_UNIX)
5274 fi
5275
5276 dnl ------------------------------------------------------------------------
5277 dnl DLL support
5278 dnl ------------------------------------------------------------------------
5279
5280 dnl under MSW we always have LoadLibrary/GetProcAddress
5281 if test "$TOOLKIT" != "MSW" -a "$USE_OS2" != 1; then
5282
5283     HAVE_DL_FUNCS=0
5284     HAVE_SHL_FUNCS=0
5285     if test "$wxUSE_DYNAMIC_LOADER" = "yes" -o "$wxUSE_DYNLIB_CLASS" = "yes" ; then
5286         if test "$USE_DOS" = 1; then
5287             HAVE_DL_FUNCS=0
5288         else
5289             dnl the test is a bit complicated because we check for dlopen() both with
5290             dnl and without -ldl and we also try to find shl_load() if there is no
5291             dnl dlopen() on this system
5292             AC_CHECK_FUNCS(dlopen,
5293             [
5294                 AC_DEFINE(HAVE_DLOPEN)
5295                 HAVE_DL_FUNCS=1
5296             ],
5297             [
5298                 AC_CHECK_LIB(dl, dlopen,
5299                             [
5300                                 AC_DEFINE(HAVE_DLOPEN)
5301                                 HAVE_DL_FUNCS=1
5302                                 DL_LINK=" -ldl$DL_LINK"
5303                             ],
5304                             [
5305                                 AC_CHECK_FUNCS(shl_load,
5306                                               [
5307                                                 AC_DEFINE(HAVE_SHL_LOAD)
5308                                                 HAVE_SHL_FUNCS=1
5309                                               ],
5310                                               [
5311                                                 AC_CHECK_LIB(shl_load, dld,
5312                                                              [
5313                                                                 HAVE_SHL_FUNCS=1
5314                                                                 DL_LINK=" -ldld$DL_LINK"
5315                                                              ])
5316                                               ])
5317                             ])
5318             ])
5319
5320             dnl check also for dlerror()
5321             if test "$HAVE_DL_FUNCS" = 1; then
5322                 AC_CHECK_FUNCS(dlerror,
5323                     AC_DEFINE(HAVE_DLERROR),
5324                     [
5325                         AC_CHECK_LIB(dl, dlerror, AC_DEFINE(HAVE_DLERROR))
5326                     ]
5327                 )
5328             fi
5329         fi
5330
5331         dnl Force HAVE_DL_FUNCS on for Darwin, even if the tests failed (e.g. pre-10.3)
5332         if test "$USE_DARWIN" = 1; then
5333             dnl dlopen/dlerror is implemented in dynlib.cpp for Darwin/Mac OS X
5334             HAVE_DL_FUNCS=1
5335         fi
5336
5337         if test "$HAVE_DL_FUNCS" = 0; then
5338             if test "$HAVE_SHL_FUNCS" = 0; then
5339               if test "$USE_UNIX" = 1 -o "$USE_DOS" = 1; then
5340                   AC_MSG_WARN([Missing dynamic loading support, several features will be disabled])
5341                   wxUSE_DYNAMIC_LOADER=no
5342                   wxUSE_DYNLIB_CLASS=no
5343               else
5344                   AC_MSG_WARN([Assuming wxLibrary class works on this platform])
5345               fi
5346             fi
5347         fi
5348     fi
5349 fi
5350
5351 if test "$wxUSE_DYNAMIC_LOADER" = "yes" ; then
5352     AC_DEFINE(wxUSE_DYNAMIC_LOADER)
5353 fi
5354 if test "$wxUSE_DYNLIB_CLASS" = "yes" ; then
5355     AC_DEFINE(wxUSE_DYNLIB_CLASS)
5356 fi
5357
5358
5359 dnl ---------------------------------------------------------------------------
5360 dnl Verify consistency of plugins/monolithic/shared settings:
5361 dnl ---------------------------------------------------------------------------
5362
5363 if test "$wxUSE_PLUGINS" = "yes" ; then
5364     if test "$wxUSE_SHARED" = "no" ; then
5365         AC_MSG_WARN([plugins supported only in shared build, disabling])
5366         wxUSE_PLUGINS=no
5367     fi
5368     if test "$wxUSE_MONOLITHIC" = "yes" ; then
5369         AC_MSG_WARN([plugins not supported monolithic build, disabling])
5370         wxUSE_PLUGINS=no
5371     fi
5372     if test "$wxUSE_DYNLIB_CLASS" = "no" ; then
5373         AC_MSG_WARN([plugins require wxDynamicLibrary, disabling])
5374         wxUSE_PLUGINS=no
5375     fi
5376     if test "$wxUSE_PLUGINS" = "yes" ; then
5377         AC_DEFINE(wxUSE_PLUGINS)
5378     fi
5379 fi
5380
5381 dnl ---------------------------------------------------------------------------
5382 dnl Register non-GUI class options for makefiles and setup.h
5383 dnl ---------------------------------------------------------------------------
5384
5385 if test "$wxUSE_STL" = "yes"; then
5386   AC_DEFINE(wxUSE_STL)
5387 fi
5388
5389 if test "$wxUSE_EXTENDED_RTTI" = "yes"; then
5390   AC_DEFINE(wxUSE_EXTENDED_RTTI)
5391 fi
5392
5393 if test "$wxUSE_APPLE_IEEE" = "yes"; then
5394   AC_DEFINE(wxUSE_APPLE_IEEE)
5395 fi
5396
5397 if test "$wxUSE_TIMER" = "yes"; then
5398   AC_DEFINE(wxUSE_TIMER)
5399 fi
5400
5401 dnl Unix implementation needs additional checks because audio support
5402 dnl comes in many favours:
5403 if test "$USE_UNIX" = 1 ; then
5404     dnl mmedia doesn't compile with wxMGL, remove this if this is ever fixed
5405     if test "$wxUSE_MGL" != 1; then
5406         dnl it's not enough to check for just the header because OSS under NetBSD
5407         dnl redefines ioctl as oss_ioctrl inside it and so we also need to test
5408         dnl whether we need -lossaudio at link-time
5409         AC_CACHE_CHECK([for SNDCTL_DSP_SPEED in sys/soundcard.h], ac_cv_header_sys_soundcard, [
5410             AC_TRY_LINK([
5411                     #include <sys/ioctl.h>
5412                     #include <sys/soundcard.h>
5413                 ],
5414                 [
5415                     ioctl(0, SNDCTL_DSP_SPEED, 0);
5416                 ],
5417                 ac_cv_header_sys_soundcard=yes,
5418                 [
5419                     saveLibs="$LIBS"
5420                     LIBS="$saveLibs -lossaudio"
5421                     AC_TRY_LINK([
5422                             #include <sys/ioctl.h>
5423                             #include <sys/soundcard.h>
5424                         ],
5425                         [
5426                             ioctl(0, SNDCTL_DSP_SPEED, 0);
5427                         ],
5428                         ac_cv_header_sys_soundcard=yes,
5429                         [
5430                             LIBS="$saveLibs"
5431                             ac_cv_header_sys_soundcard=no
5432                         ]
5433                     )
5434                 ]
5435             )
5436         ])
5437     fi
5438
5439     if test "$ac_cv_header_sys_soundcard" = "yes"; then
5440         AC_DEFINE(HAVE_SYS_SOUNDCARD_H)
5441     fi
5442 fi
5443
5444 WITH_PLUGIN_SDL=0
5445 if test "$wxUSE_SOUND" = "yes"; then
5446   if test "$USE_UNIX" = 1 ; then
5447     if test "$wxUSE_LIBSDL" != "no"; then
5448       AM_PATH_SDL([1.2.0],
5449                   [
5450                     EXTRALIBS_SDL="$SDL_LIBS"
5451                     CFLAGS="$SDL_CFLAGS $CFLAGS"
5452                     CXXFLAGS="$SDL_CFLAGS $CXXFLAGS"
5453                     AC_DEFINE(wxUSE_LIBSDL)
5454                   ],
5455                   [wxUSE_LIBSDL="no"])
5456       if test "$wxUSE_LIBSDL" = "yes" -a "$wxUSE_PLUGINS" = "yes" ; then
5457         WITH_PLUGIN_SDL=1
5458       fi
5459     fi
5460   else
5461     dnl wxMGL doesn't support sound under DOS, only under Unix
5462     if test "$wxUSE_MGL" = 1; then
5463         AC_MSG_WARN([wxSound not supported in MGL under DOS... disabled])
5464         wxUSE_SOUND="no"
5465     fi
5466   fi
5467 fi
5468
5469 if test "$wxUSE_SOUND" = "yes"; then
5470   AC_DEFINE(wxUSE_SOUND)
5471   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sound"
5472 fi
5473
5474 if test "$WXGTK2" = 1; then
5475     PKG_PROG_PKG_CONFIG()
5476
5477     if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
5478
5479         if test "$wxUSE_GTKPRINT" = "yes" ; then
5480
5481                 PKG_CHECK_MODULES(GTKPRINT,
5482                                   [gtk+-unix-print-2.0 >= 2.10],
5483                     [
5484                         CFLAGS="$GTKPRINT_CFLAGS $CFLAGS"
5485                         CXXFLAGS="$GTKPRINT_CFLAGS $CXXFLAGS"
5486                         AC_DEFINE(wxUSE_GTKPRINT)
5487                     ],
5488                     [
5489                         AC_MSG_WARN([GTK printing support not found (GTK+ >= 2.10), library will use GNOME printing support or standard PostScript printing])
5490                         wxUSE_GTKPRINT="no"
5491                     ]
5492                 )
5493         fi
5494
5495         if test "$wxUSE_LIBGNOMEPRINT" = "yes" ; then
5496
5497                 PKG_CHECK_MODULES(LIBGNOMEPRINTUI,
5498                                   [libgnomeprintui-2.2 >= 2.8],
5499                     [
5500                         CFLAGS="$LIBGNOMEPRINTUI_CFLAGS $CFLAGS"
5501                         CXXFLAGS="$LIBGNOMEPRINTUI_CFLAGS $CXXFLAGS"
5502                         AC_DEFINE(wxUSE_LIBGNOMEPRINT)
5503                     ],
5504                     [
5505                         AC_MSG_WARN([libgnomeprintui not found, library will use standard PostScript printing])
5506                         wxUSE_LIBGNOMEPRINT="no"
5507                     ]
5508                 )
5509         fi
5510     fi
5511
5512     if test "$wxUSE_MIMETYPE" = "yes" ; then
5513         if test "$wxUSE_LIBGNOMEVFS" = "yes" ; then
5514
5515                 PKG_CHECK_MODULES(GNOMEVFS,
5516                                   [gnome-vfs-2.0 >= 2.0],
5517                     [
5518                         CFLAGS="$GNOMEVFS_CFLAGS $CFLAGS"
5519                         CXXFLAGS="$GNOMEVFS_CFLAGS $CXXFLAGS"
5520                         AC_DEFINE(wxUSE_LIBGNOMEVFS)
5521                     ],
5522                     [
5523                         AC_MSG_WARN([libgnomevfs not found, library won't be able to associate MIME type])
5524                         wxUSE_LIBGNOMEVFS="no"
5525                     ]
5526                 )
5527         fi
5528     fi
5529
5530     if test "$wxUSE_LIBHILDON" = "yes" ; then
5531         PKG_CHECK_MODULES(HILDON,
5532                           [hildon-lgpl >= 0.9],
5533             [
5534                 EXTRALIBS_HILDON="$HILDON_LIBS"
5535                 CFLAGS="$CFLAGS $HILDON_CFLAGS"
5536                 CXXFLAGS="$CXXFLAGS $HILDON_CFLAGS"
5537                 AC_DEFINE(wxUSE_LIBHILDON)
5538             ],
5539             [
5540                 AC_MSG_WARN([libhildon_lgpl not found])
5541                         wxUSE_LIBHILDON="no"
5542             ]
5543         )
5544     fi
5545 fi
5546
5547 if test "$wxUSE_CMDLINE_PARSER" = "yes"; then
5548   AC_DEFINE(wxUSE_CMDLINE_PARSER)
5549 fi
5550
5551 if test "$wxUSE_STOPWATCH" = "yes"; then
5552   AC_DEFINE(wxUSE_STOPWATCH)
5553 fi
5554
5555 if test "$wxUSE_DATETIME" = "yes"; then
5556   AC_DEFINE(wxUSE_DATETIME)
5557 fi
5558
5559 if test "$wxUSE_FILE" = "yes"; then
5560   AC_DEFINE(wxUSE_FILE)
5561 fi
5562
5563 if test "$wxUSE_FFILE" = "yes"; then
5564   AC_DEFINE(wxUSE_FFILE)
5565 fi
5566
5567 if test "$wxUSE_ARCHIVE_STREAMS" = "yes"; then
5568   if test "$wxUSE_STREAMS" != yes; then
5569     AC_MSG_WARN(wxArchive requires wxStreams... disabled)
5570     wxUSE_ARCHIVE_STREAMS=no
5571   else
5572     AC_DEFINE(wxUSE_ARCHIVE_STREAMS)
5573   fi
5574 fi
5575
5576 if test "$wxUSE_ZIPSTREAM" = "yes"; then
5577   if test "$wxUSE_ARCHIVE_STREAMS" != "yes"; then
5578     AC_MSG_WARN(wxZip requires wxArchive... disabled)
5579   elif test "$wxUSE_ZLIB" = "no"; then
5580     AC_MSG_WARN(wxZip requires wxZlib... disabled)
5581   else
5582     AC_DEFINE(wxUSE_ZIPSTREAM)
5583   fi
5584 fi
5585
5586 if test "$wxUSE_TARSTREAM" = "yes"; then
5587   if test "$wxUSE_ARCHIVE_STREAMS" != "yes"; then
5588     AC_MSG_WARN(wxTar requires wxArchive... disabled)
5589   else
5590     AC_DEFINE(wxUSE_TARSTREAM)
5591   fi
5592 fi
5593
5594 if test "$wxUSE_FILESYSTEM" = "yes"; then
5595   if test "$wxUSE_STREAMS" != yes -o \( "$wxUSE_FILE" != yes -a "$wxUSE_FFILE" != yes \); then
5596     AC_MSG_WARN(wxFileSystem requires wxStreams and wxFile or wxFFile... disabled)
5597     wxUSE_FILESYSTEM=no
5598   else
5599     AC_DEFINE(wxUSE_FILESYSTEM)
5600   fi
5601 fi
5602
5603 if test "$wxUSE_FS_ARCHIVE" = "yes"; then
5604   if test "$wxUSE_FILESYSTEM" != yes -o "$wxUSE_ARCHIVE_STREAMS" != yes; then
5605     AC_MSG_WARN(wxArchiveFSHandler requires wxArchive and wxFileSystem... disabled)
5606   else
5607     AC_DEFINE(wxUSE_FS_ARCHIVE)
5608   fi
5609 fi
5610
5611 if test "$wxUSE_FS_ZIP" = "yes"; then
5612   if test "$wxUSE_FS_ARCHIVE" != yes; then
5613     AC_MSG_WARN(wxZipFSHandler requires wxArchiveFSHandler... disabled)
5614   else
5615     AC_DEFINE(wxUSE_FS_ZIP)
5616   fi
5617 fi
5618
5619 if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
5620   if test "$USE_UNIX" != 1; then
5621     AC_MSG_WARN([Catching fatal exceptions not currently supported on this system, wxApp::OnFatalException will not be called])
5622     wxUSE_ON_FATAL_EXCEPTION=no
5623   else
5624     AC_DEFINE(wxUSE_ON_FATAL_EXCEPTION)
5625   fi
5626 fi
5627
5628 if test "$wxUSE_STACKWALKER" = "yes"; then
5629     AC_DEFINE(wxUSE_STACKWALKER)
5630 fi
5631
5632 if test "$wxUSE_DEBUGREPORT" = "yes"; then
5633     if test "$USE_UNIX" != 1 -a "$USE_WIN32" != 1; then
5634         AC_MSG_WARN([Creating debug reports not currently supported on this system, disabled])
5635         wxUSE_DEBUGREPORT=no
5636     else
5637         AC_DEFINE(wxUSE_DEBUGREPORT)
5638         if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
5639             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS debugrpt"
5640         fi
5641     fi
5642 fi
5643
5644 if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
5645   AC_DEFINE(wxUSE_SNGLINST_CHECKER)
5646 fi
5647
5648 if test "$wxUSE_BUSYINFO" = "yes"; then
5649   AC_DEFINE(wxUSE_BUSYINFO)
5650 fi
5651
5652 if test "$wxUSE_STD_IOSTREAM" = "yes"; then
5653   AC_DEFINE(wxUSE_STD_IOSTREAM)
5654 fi
5655
5656 if test "$wxUSE_STD_STRING" = "yes"; then
5657   AC_DEFINE(wxUSE_STD_STRING)
5658 fi
5659
5660 if test "$wxUSE_STDPATHS" = "yes"; then
5661   AC_DEFINE(wxUSE_STDPATHS)
5662 fi
5663
5664 if test "$wxUSE_TEXTBUFFER" = "yes"; then
5665     AC_DEFINE(wxUSE_TEXTBUFFER)
5666 fi
5667
5668 if test "$wxUSE_TEXTFILE" = "yes"; then
5669   if test "$wxUSE_FILE" != "yes" -o "$wxUSE_TEXTBUFFER" != "yes" ; then
5670     AC_MSG_WARN(wxTextFile requires wxFile and wxTextBuffer... disabled)
5671   else
5672     AC_DEFINE(wxUSE_TEXTFILE)
5673   fi
5674 fi
5675
5676 if test "$wxUSE_CONFIG" = "yes" ; then
5677   if test "$wxUSE_TEXTFILE" != "yes"; then
5678     AC_MSG_WARN(wxConfig requires wxTextFile... disabled)
5679   else
5680     AC_DEFINE(wxUSE_CONFIG)
5681     AC_DEFINE(wxUSE_CONFIG_NATIVE)
5682     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS config"
5683   fi
5684 fi
5685
5686 if test "$wxUSE_INTL" = "yes" ; then
5687   if test "$wxUSE_FILE" != "yes"; then
5688     AC_MSG_WARN(I18n code requires wxFile... disabled)
5689   else
5690     AC_DEFINE(wxUSE_INTL)
5691     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS internat"
5692     GUIDIST="$GUIDIST INTL_DIST"
5693   fi
5694 fi
5695
5696 if test "$wxUSE_XLOCALE" == "yes" ; then
5697     AC_DEFINE(wxUSE_XLOCALE)
5698     AC_CHECK_TYPES(locale_t,,,
5699                    [#include <xlocale.h>
5700                     #include <locale.h>])
5701 fi
5702
5703 if test "$wxUSE_LOG" = "yes"; then
5704   AC_DEFINE(wxUSE_LOG)
5705
5706     if test "$wxUSE_LOGGUI" = "yes"; then
5707       AC_DEFINE(wxUSE_LOGGUI)
5708     fi
5709
5710     if test "$wxUSE_LOGWINDOW" = "yes"; then
5711       AC_DEFINE(wxUSE_LOGWINDOW)
5712     fi
5713
5714     if test "$wxUSE_LOGDIALOG" = "yes"; then
5715       AC_DEFINE(wxUSE_LOG_DIALOG)
5716     fi
5717
5718     dnl the keyboard sample requires wxUSE_LOG
5719     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS keyboard"
5720 fi
5721
5722 if test "$wxUSE_LONGLONG" = "yes"; then
5723   AC_DEFINE(wxUSE_LONGLONG)
5724 fi
5725
5726 if test "$wxUSE_GEOMETRY" = "yes"; then
5727   AC_DEFINE(wxUSE_GEOMETRY)
5728 fi
5729
5730 if test "$wxUSE_BASE64" = "yes"; then
5731   AC_DEFINE(wxUSE_BASE64)
5732 fi
5733
5734 if test "$wxUSE_STREAMS" = "yes" ; then
5735   AC_DEFINE(wxUSE_STREAMS)
5736 fi
5737
5738 if test "$wxUSE_PRINTF_POS_PARAMS" = "yes"; then
5739   AC_DEFINE(wxUSE_PRINTF_POS_PARAMS)
5740 fi
5741
5742 if test "$wxUSE_OBJC_UNIQUIFYING" = "yes"; then
5743   AC_DEFINE(wxUSE_OBJC_UNIQUIFYING)
5744 fi
5745
5746 dnl ---------------------------------------------------------------------------
5747 dnl console event loop stuff
5748 dnl ---------------------------------------------------------------------------
5749
5750 if test "$wxUSE_CONSOLE_EVENTLOOP" = "yes"; then
5751     AC_DEFINE(wxUSE_CONSOLE_EVENTLOOP)
5752
5753     if test "$wxUSE_UNIX" = "yes"; then
5754         if test "$wxUSE_SELECT_DISPATCHER" = "yes"; then
5755             AC_DEFINE(wxUSE_SELECT_DISPATCHER)
5756         fi
5757
5758         if test "$wxUSE_EPOLL_DISPATCHER" = "yes"; then
5759             AC_CHECK_HEADERS(sys/epoll.h,,, [AC_INCLUDES_DEFAULT()])
5760             if test "$ac_cv_header_sys_epoll_h" = "yes"; then
5761                 AC_DEFINE(wxUSE_EPOLL_DISPATCHER)
5762             else
5763                 AC_MSG_WARN([sys/epoll.h not available, wxEpollDispatcher disabled])
5764             fi
5765         fi
5766     fi
5767 fi
5768
5769 dnl ---------------------------------------------------------------------------
5770 dnl time/date functions
5771 dnl ---------------------------------------------------------------------------
5772
5773 dnl check for gettimeofday (SVr4, BSD 4.3) and ftime (V7, BSD 4.3) for the
5774 dnl function to be used for high resolution timers
5775 AC_CHECK_FUNCS(gettimeofday ftime, break)
5776
5777 if test "$ac_cv_func_gettimeofday" = "yes"; then
5778     AC_CACHE_CHECK([whether gettimeofday takes two arguments],
5779                    wx_cv_func_gettimeofday_has_2_args,
5780     [
5781         dnl on some _really_ old systems it takes only 1 argument
5782         AC_TRY_COMPILE(
5783             [
5784                 #include <sys/time.h>
5785                 #include <unistd.h>
5786             ],
5787             [
5788                 struct timeval tv;
5789                 gettimeofday(&tv, NULL);
5790             ],
5791             wx_cv_func_gettimeofday_has_2_args=yes,
5792             AC_TRY_COMPILE(
5793                 [
5794                     #include <sys/time.h>
5795                     #include <unistd.h>
5796                 ],
5797                 [
5798                     struct timeval tv;
5799                     gettimeofday(&tv);
5800                 ],
5801                 wx_cv_func_gettimeofday_has_2_args=no,
5802                 [
5803                     AC_MSG_WARN([failed to determine number of gettimeofday() arguments])
5804                     wx_cv_func_gettimeofday_has_2_args=unknown
5805                 ]
5806             )
5807         )
5808     ])
5809
5810     if test "$wx_cv_func_gettimeofday_has_2_args" != "yes"; then
5811         AC_DEFINE(WX_GETTIMEOFDAY_NO_TZ)
5812     fi
5813 fi
5814
5815 if test "$wxUSE_DATETIME" = "yes"; then
5816     dnl check for strptime and for its declaration as some systems lack it
5817     AC_CHECK_FUNC(strptime)
5818     if test "$ac_cv_func_strptime" = "yes"; then
5819         AC_CACHE_CHECK([for strptime declaration], wx_cv_func_strptime_decl,
5820             [
5821                 AC_LANG_PUSH(C++)
5822                 AC_TRY_COMPILE(
5823                     [
5824                         #include <time.h>
5825                     ],
5826                     [
5827                         struct tm t;
5828                         strptime("foo", "bar", &t);
5829                     ],
5830                     wx_cv_func_strptime_decl=yes,
5831                     wx_cv_func_strptime_decl=no
5832                 )
5833                 AC_LANG_POP()
5834             ]
5835         )
5836     fi
5837     if test "$wx_cv_func_strptime_decl" = "yes"; then
5838         AC_DEFINE(HAVE_STRPTIME_DECL)
5839     else
5840         wx_strptime_decl="extern char *strptime(const char *, const char *, struct tm *);"
5841     fi
5842     if test "$ac_cv_func_strptime" = "yes"; then
5843         dnl strptime() behaviour doesn't conform to POSIX under Mac OS X <
5844         dnl 10.5 and possibly other BSD variants, check that strptime() we
5845         dnl have fails to parse format when the string doesn't match it instea
5846         dnl of just stopping immediately and returning non-NULL
5847         AC_CACHE_CHECK([whether strptime() fails on invalid strings],
5848             wx_cv_func_strptime_ok,
5849             [AC_RUN_IFELSE(
5850                 [
5851                     #include <stdlib.h>
5852                     #include <time.h>
5853                     #include "confdefs.h"
5854
5855                     $wx_strptime_decl
5856
5857                     int main()
5858                     {
5859                         struct tm t;
5860                         return !!strptime("", "%x", &t);
5861                     }
5862                 ],
5863                 wx_cv_func_strptime_ok=yes,
5864                 wx_cv_func_strptime_ok=no,
5865                 dnl be pessimistic when cross-compiling
5866                 wx_cv_func_strptime_ok=no
5867             )]
5868         )
5869
5870         if test "$wx_cv_func_strptime_ok" = "yes"; then
5871             AC_DEFINE(HAVE_STRPTIME)
5872         fi
5873     fi
5874
5875     dnl check for timezone variable
5876     dnl   doesn't exist under Darwin / Mac OS X which uses tm_gmtoff instead
5877     AC_CACHE_CHECK(for timezone variable in <time.h>,
5878                    wx_cv_var_timezone,
5879                    [
5880                         AC_LANG_PUSH(C++)
5881                         AC_TRY_COMPILE(
5882                             [
5883                                 #include <time.h>
5884                             ],
5885                             [
5886                                 int tz;
5887                                 tz = timezone;
5888                             ],
5889                             [
5890                                 wx_cv_var_timezone=timezone
5891                             ],
5892                             [
5893                                 AC_TRY_COMPILE(
5894                                     [
5895                                         #include <time.h>
5896                                     ],
5897                                     [
5898                                         int tz;
5899                                         tz = _timezone;
5900                                     ],
5901                                     [
5902                                         wx_cv_var_timezone=_timezone
5903                                     ],
5904                                     [
5905                                         AC_TRY_COMPILE(
5906                                             [
5907                                                 #include <time.h>
5908                                             ],
5909                                             [
5910                                                 int tz;
5911                                                 tz = __timezone;
5912                                             ],
5913                                             [
5914                                                 wx_cv_var_timezone=__timezone
5915                                             ],
5916                                             [
5917                                                 if test "$USE_DOS" = 0 ; then
5918                                                     AC_MSG_WARN(no timezone variable, will use tm_gmtoff instead)
5919                                                 fi
5920                                             ]
5921                                         )
5922                                     ]
5923                                 )
5924                             ]
5925                         )
5926                         AC_LANG_POP()
5927                    ]
5928     )
5929
5930     dnl as we want $wx_cv_var_timezone to be expanded, use AC_DEFINE_UNQUOTED
5931     if test "x$wx_cv_var_timezone" != x ; then
5932         AC_DEFINE_UNQUOTED(WX_TIMEZONE, $wx_cv_var_timezone)
5933     fi
5934
5935     dnl check for localtime (it's POSIX, but the check can do no harm...)
5936     AC_CHECK_FUNCS(localtime)
5937
5938     if test "$ac_cv_func_localtime" = "yes"; then
5939         AC_CACHE_CHECK(for tm_gmtoff in struct tm,
5940                        wx_cv_struct_tm_has_gmtoff,
5941         [
5942             AC_TRY_COMPILE(
5943                 [
5944                     #include <time.h>
5945                 ],
5946                 [
5947                     struct tm tm;
5948                     tm.tm_gmtoff++;
5949                 ],
5950                 [
5951                     wx_cv_struct_tm_has_gmtoff=yes
5952                 ],
5953                 wx_cv_struct_tm_has_gmtoff=no
5954             )
5955         ])
5956     fi
5957
5958     if test "$wx_cv_struct_tm_has_gmtoff" = "yes"; then
5959         AC_DEFINE(WX_GMTOFF_IN_TM)
5960     fi
5961
5962     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS typetest"
5963 fi
5964
5965 dnl ------------------------------------------------------------------------
5966 dnl wxSocket
5967 dnl ------------------------------------------------------------------------
5968
5969 dnl VZ: the GUI hooks wxSocket needs are not implemented yet in some toolkits
5970 if test "$wxUSE_SOCKETS" = "yes"; then
5971     if test "$wxUSE_MGL" = 1; then
5972         AC_MSG_WARN([wxSocket not yet supported under MGL... disabled])
5973         wxUSE_SOCKETS="no"
5974     fi
5975 fi
5976
5977 if test "$wxUSE_SOCKETS" = "yes"; then
5978     dnl under MSW we always have sockets
5979     if test "$TOOLKIT" != "MSW"; then
5980         dnl under Solaris and OS/2, socket functions live in -lsocket
5981         AC_CHECK_FUNC(socket,,
5982             [
5983                 AC_CHECK_LIB(socket, socket,
5984                     if test "$INET_LINK" != " -lsocket"; then
5985                         INET_LINK="$INET_LINK -lsocket"
5986                     fi,
5987                     [
5988                         AC_MSG_WARN([socket library not found - sockets will be disabled])
5989                         wxUSE_SOCKETS=no
5990                     ]
5991                 )
5992             ]
5993         )
5994     fi
5995 fi
5996
5997 if test "$wxUSE_SOCKETS" = "yes" ; then
5998     dnl this test may be appropriate if building under cygwin
5999     dnl right now I'm assuming it also uses the winsock stuff
6000     dnl like mingw does..  -- RL
6001     if test "$TOOLKIT" != "MSW"; then
6002         dnl determine the type of third argument for getsockname
6003         dnl This test needs to be done in C++ mode since gsocket.cpp now
6004         dnl is C++ code and pointer cast that are possible even without
6005         dnl warning in C still fail in C++.
6006         AC_CACHE_CHECK([what is the type of the third argument of getsockname],
6007                        wx_cv_type_getsockname3,
6008             [
6009                 AC_LANG_PUSH(C++)
6010                 AC_TRY_COMPILE(
6011                     [
6012                         #include <sys/types.h>
6013                         #include <sys/socket.h>
6014                     ],
6015                     [
6016                         socklen_t len;
6017                         getsockname(0, 0, &len);
6018                     ],
6019                     wx_cv_type_getsockname3=socklen_t,
6020                     [
6021                         dnl the compiler will compile the version with size_t
6022                         dnl even if the real type of the last parameter is int
6023                         dnl but it should give at least a warning about
6024                         dnl converting between incompatible pointer types, so
6025                         dnl try to use it to get the correct behaviour at
6026                         dnl least with gcc (otherwise we'd always use size_t)
6027                         CFLAGS_OLD="$CFLAGS"
6028                         if test "$GCC" = yes ; then
6029                             CFLAGS="-Werror $CFLAGS"
6030                         fi
6031
6032                         AC_TRY_COMPILE(
6033                             [
6034                                 #include <sys/types.h>
6035                                 #include <sys/socket.h>
6036                             ],
6037                             [
6038                                 size_t len;
6039                                 getsockname(0, 0, &len);
6040                             ],
6041                             wx_cv_type_getsockname3=size_t,
6042                             AC_TRY_COMPILE(
6043                                 [
6044                                     #include <sys/types.h>
6045                                     #include <sys/socket.h>
6046                                 ],
6047                                 [
6048                                     int len;
6049                                     getsockname(0, 0, &len);
6050                                 ],
6051                                 wx_cv_type_getsockname3=int,
6052                                 wx_cv_type_getsockname3=unknown
6053                             )
6054                         )
6055
6056                         CFLAGS="$CFLAGS_OLD"
6057                     ]
6058                 )
6059                 AC_LANG_POP()
6060             ])
6061
6062         if test "$wx_cv_type_getsockname3" = "unknown"; then
6063             wxUSE_SOCKETS=no
6064             AC_MSG_WARN([Couldn't find socklen_t synonym for this system])
6065         else
6066             AC_DEFINE_UNQUOTED(WX_SOCKLEN_T, $wx_cv_type_getsockname3)
6067         fi
6068         dnl Do this again for getsockopt as it may be different
6069         AC_CACHE_CHECK([what is the type of the fifth argument of getsockopt],
6070                        wx_cv_type_getsockopt5,
6071             [
6072                 dnl Note that the rules for compatibility of pointers
6073                 dnl are somewhat different between C and C++, so code
6074                 dnl that fails in C++ may not even give a warning about
6075                 dnl converting between incompatible pointer types in C.
6076                 dnl So this test needs to be done in C++ mode.
6077                 AC_LANG_PUSH(C++)
6078                 AC_TRY_COMPILE(
6079                     [
6080                         #include <sys/types.h>
6081                         #include <sys/socket.h>
6082                     ],
6083                     [
6084                         socklen_t len;
6085                         getsockopt(0, 0, 0, 0, &len);
6086                     ],
6087                     wx_cv_type_getsockopt5=socklen_t,
6088                     [
6089                         AC_TRY_COMPILE(
6090                             [
6091                                 #include <sys/types.h>
6092                                 #include <sys/socket.h>
6093                             ],
6094                             [
6095                                 size_t len;
6096                                 getsockopt(0, 0, 0, 0, &len);
6097                             ],
6098                             wx_cv_type_getsockopt5=size_t,
6099                             AC_TRY_COMPILE(
6100                                 [
6101                                     #include <sys/types.h>
6102                                     #include <sys/socket.h>
6103                                 ],
6104                                 [
6105                                     int len;
6106                                     getsockopt(0, 0, 0, 0, &len);
6107                                 ],
6108                                 wx_cv_type_getsockopt5=int,
6109                                 wx_cv_type_getsockopt5=unknown
6110                             )
6111                         )
6112                     ]
6113                 )
6114                 AC_LANG_POP()
6115             ])
6116
6117         if test "$wx_cv_type_getsockopt5" = "unknown"; then
6118             wxUSE_SOCKETS=no
6119             AC_MSG_WARN([Couldn't find socklen_t synonym for this system])
6120         else
6121             AC_DEFINE_UNQUOTED(SOCKOPTLEN_T, $wx_cv_type_getsockopt5)
6122         fi
6123     fi
6124 fi
6125
6126 if test "$wxUSE_SOCKETS" = "yes" ; then
6127     if test "$wxUSE_IPV6" = "yes"; then
6128         AC_CACHE_CHECK(
6129             [whether we have sockaddr_in6],
6130             [wx_cv_type_sockaddr_in6],
6131             [
6132                 AC_TRY_COMPILE(
6133                     [
6134                         #include <sys/types.h>
6135                         #include <sys/socket.h>
6136                         #include <netinet/in.h>
6137                     ],
6138                     [
6139                         struct sockaddr_in6 sa6;
6140                     ],
6141                     wx_cv_type_sockaddr_in6=yes,
6142                     wx_cv_type_sockaddr_in6=no
6143                 )
6144             ]
6145         )
6146
6147         if test "$wx_cv_type_sockaddr_in6"="yes"; then
6148             AC_DEFINE(wxUSE_IPV6)
6149         else
6150             AC_MSG_WARN([IPv6 support not available... disabled])
6151         fi
6152     fi
6153
6154     AC_DEFINE(wxUSE_SOCKETS)
6155     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sockets"
6156 fi
6157
6158 if test "$wxUSE_PROTOCOL" = "yes"; then
6159     if test "$wxUSE_SOCKETS" != "yes"; then
6160         AC_MSG_WARN(Protocol classes require sockets... disabled)
6161         wxUSE_PROTOCOL=no
6162     fi
6163 fi
6164
6165 if test "$wxUSE_PROTOCOL" = "yes"; then
6166     AC_DEFINE(wxUSE_PROTOCOL)
6167
6168     if test "$wxUSE_PROTOCOL_HTTP" = "yes"; then
6169         AC_DEFINE(wxUSE_PROTOCOL_HTTP)
6170     fi
6171     if test "$wxUSE_PROTOCOL_FTP" = "yes"; then
6172         AC_DEFINE(wxUSE_PROTOCOL_FTP)
6173     fi
6174     if test "$wxUSE_PROTOCOL_FILE" = "yes"; then
6175         AC_DEFINE(wxUSE_PROTOCOL_FILE)
6176     fi
6177 else
6178     if test "$wxUSE_FS_INET" = "yes"; then
6179         AC_MSG_WARN([HTTP filesystem require protocol classes... disabled])
6180         wxUSE_FS_INET="no"
6181     fi
6182 fi
6183
6184 if test "$wxUSE_URL" = "yes"; then
6185     if test "$wxUSE_PROTOCOL" != "yes"; then
6186         AC_MSG_WARN(wxURL class requires wxProtocol... disabled)
6187         wxUSE_URL=no
6188     fi
6189     if test "$wxUSE_URL" = "yes"; then
6190         AC_DEFINE(wxUSE_URL)
6191     fi
6192 fi
6193
6194 if test "$wxUSE_VARIANT" = "yes"; then
6195     AC_DEFINE(wxUSE_VARIANT)
6196 fi
6197
6198 if test "$wxUSE_FS_INET" = "yes"; then
6199   AC_DEFINE(wxUSE_FS_INET)
6200 fi
6201
6202 dnl ---------------------------------------------------------------------------
6203 dnl Joystick support
6204 dnl ---------------------------------------------------------------------------
6205
6206 if test "$wxUSE_GUI" = "yes" -a "$wxUSE_JOYSTICK" = "yes"; then
6207     wxUSE_JOYSTICK=no
6208
6209     dnl under MSW we always have joystick support
6210     if test "$TOOLKIT" = "MSW"; then
6211         wxUSE_JOYSTICK=yes
6212
6213     dnl mac only available on darwin
6214     elif test "$TOOLKIT" = "OSX" -o "$TOOLKIT" = "COCOA"; then
6215         if test "$USE_DARWIN" = 1; then
6216             dnl check for a bug in the headers, some have bad setEventCallout
6217             AC_MSG_CHECKING([headers have declarations needed for joystick support])
6218             AC_LANG_PUSH(C++)
6219             AC_TRY_COMPILE( [ #include <IOKit/hid/IOHIDLib.h> ],
6220                             [ IOHIDQueueInterface *qi = NULL;
6221                               IOHIDCallbackFunction cb = NULL;
6222                               qi->setEventCallout(NULL, cb, NULL, NULL); ],
6223                             [ wxUSE_JOYSTICK=yes ]
6224                           )
6225             AC_LANG_POP()
6226             AC_MSG_RESULT($wxUSE_JOYSTICK)
6227         fi
6228
6229     dnl joystick support is only for Linux 2.1.x or greater
6230     else
6231         dnl wxJoystick not supported by wxMGL at all
6232         if test "$wxUSE_MGL" != 1; then
6233             dnl notice the dummy includes argument: without it, AC_CHECK_HEADER
6234             dnl checks only whether the header can be preprocessed, not that it
6235             dnl can be compiled and in Linux 2.6.16 joystick.h is present but
6236             dnl can't be compiled because of an error and with the default
6237             dnl AC_CHECK_HEADER semantics we'd still detect it in this case and
6238             dnl build would fail later
6239             AC_CHECK_HEADERS([linux/joystick.h], [wxUSE_JOYSTICK=yes],, [AC_INCLUDES_DEFAULT()])
6240         fi
6241     fi
6242
6243     if test "$wxUSE_JOYSTICK" = "yes"; then
6244         AC_DEFINE(wxUSE_JOYSTICK)
6245         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS joytest"
6246     else
6247         AC_MSG_WARN(Joystick not supported by this system... disabled)
6248     fi
6249 fi
6250
6251
6252 dnl ---------------------------------------------------------------------------
6253 dnl String stuff
6254 dnl ---------------------------------------------------------------------------
6255
6256 if test "$wxUSE_FONTENUM" = "yes" ; then
6257   AC_DEFINE(wxUSE_FONTENUM)
6258 fi
6259
6260 if test "$wxUSE_FONTMAP" = "yes" ; then
6261   AC_DEFINE(wxUSE_FONTMAP)
6262 fi
6263
6264 if test "$wxUSE_UNICODE" = "yes" ; then
6265   AC_DEFINE(wxUSE_UNICODE)
6266
6267   if test "$USE_WIN32" != 1; then
6268       wxUSE_UNICODE_MSLU=no
6269   fi
6270
6271   if test "$USE_WIN32" = 1 -a "$wxUSE_UNICODE_MSLU" = "yes"; then
6272         AC_CHECK_LIB(unicows,main,
6273             [
6274                 AC_DEFINE(wxUSE_UNICODE_MSLU)
6275             ],
6276             [
6277                 AC_MSG_WARN([Compiler doesn't support MSLU (libunicows.a), disabled.
6278                              Applications will only run on Windows NT/2000/XP!])
6279                 wxUSE_UNICODE_MSLU=no
6280             ])
6281     fi
6282 fi
6283
6284 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_UTF8" = "yes"; then
6285     AC_DEFINE(wxUSE_UNICODE_UTF8)
6286
6287     if test "$wxUSE_UNICODE_UTF8_LOCALE" = "yes"; then
6288         AC_DEFINE(wxUSE_UTF8_LOCALE_ONLY)
6289     fi
6290 fi
6291
6292 dnl ---------------------------------------------------------------------------
6293 dnl big GUI components: MDI, doc/view, printing, help, ...
6294 dnl ---------------------------------------------------------------------------
6295
6296 if test "$wxUSE_CONSTRAINTS" = "yes"; then
6297     AC_DEFINE(wxUSE_CONSTRAINTS)
6298     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS layout"
6299 fi
6300
6301 if test "$wxUSE_MDI" = "yes"; then
6302     AC_DEFINE(wxUSE_MDI)
6303
6304     if test "$wxUSE_MDI_ARCHITECTURE" = "yes"; then
6305         AC_DEFINE(wxUSE_MDI_ARCHITECTURE)
6306         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mdi"
6307     fi
6308 fi
6309
6310 if test "$wxUSE_DOC_VIEW_ARCHITECTURE" = "yes" ; then
6311     AC_DEFINE(wxUSE_DOC_VIEW_ARCHITECTURE)
6312     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS docview"
6313 fi
6314
6315 if test "$wxUSE_HELP" = "yes"; then
6316     AC_DEFINE(wxUSE_HELP)
6317     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS help"
6318
6319     if test "$wxUSE_MSW" = 1; then
6320       if test "$wxUSE_MS_HTML_HELP" = "yes"; then
6321         AC_DEFINE(wxUSE_MS_HTML_HELP)
6322       fi
6323     fi
6324
6325     if test "$wxUSE_WXHTML_HELP" = "yes"; then
6326       if test "$wxUSE_HTML" = "yes"; then
6327         AC_DEFINE(wxUSE_WXHTML_HELP)
6328       else
6329         AC_MSG_WARN(Cannot use wxHTML-based help without wxHTML so it won't be compiled)
6330         wxUSE_WXHTML_HELP=no
6331       fi
6332     fi
6333 fi
6334
6335 if test "$wxUSE_PRINTING_ARCHITECTURE" = "yes" ; then
6336     if test "$wxUSE_CONSTRAINTS" != "yes"; then
6337         AC_MSG_WARN(Printing support cannot be used without constraints so it won't be compiled without it)
6338     else
6339         AC_DEFINE(wxUSE_PRINTING_ARCHITECTURE)
6340     fi
6341     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS printing"
6342 fi
6343
6344 if test "$wxUSE_POSTSCRIPT" = "yes" ; then
6345   AC_DEFINE(wxUSE_POSTSCRIPT)
6346 fi
6347
6348 AC_DEFINE(wxUSE_AFM_FOR_POSTSCRIPT)
6349
6350 if test "$wxUSE_SVG" = "yes"; then
6351     AC_DEFINE(wxUSE_SVG)
6352 fi
6353
6354 dnl ---------------------------------------------------------------------------
6355 dnl wxMetafile availability
6356 dnl ---------------------------------------------------------------------------
6357
6358 if test "$wxUSE_METAFILE" = "yes"; then
6359     if test "$wxUSE_MSW" != 1 -a "$wxUSE_MAC" != 1 -a "$wxUSE_PM" != 1; then
6360         AC_MSG_WARN([wxMetafile is not available on this system... disabled])
6361         wxUSE_METAFILE=no
6362     fi
6363 fi
6364
6365 dnl ---------------------------------------------------------------------------
6366 dnl IPC: IPC, Drag'n'Drop, Clipboard, ...
6367 dnl ---------------------------------------------------------------------------
6368
6369 dnl check for ole headers and disable a few features requiring it if not
6370 dnl present (earlier versions of mingw32 don't have ole2.h)
6371 if test "$USE_WIN32" = 1 -a \( "$wxUSE_DATAOBJ"       = "yes" \
6372                           -o "$wxUSE_CLIPBOARD"     = "yes" \
6373                           -o "$wxUSE_OLE"     = "yes" \
6374                           -o "$wxUSE_DRAG_AND_DROP" = "yes" \) ; then
6375     AC_CHECK_HEADER(ole2.h,,, [ ])
6376
6377     if test "$ac_cv_header_ole2_h" = "yes" ; then
6378         if test "$GCC" = yes ; then
6379             AC_MSG_CHECKING([if g++ requires -fvtable-thunks])
6380             AC_TRY_COMPILE([#include <windows.h>
6381                             #include <ole2.h>],
6382                            [],
6383                            [AC_MSG_RESULT(no)],
6384                            [AC_MSG_RESULT(yes)
6385                             WXCONFIG_CXXFLAGS="$WXCONFIG_CXXFLAGS -fvtable-thunks"])
6386             LIBS=" -lrpcrt4 -loleaut32 -lole32 -luuid$LIBS"
6387             if test "$wxUSE_OLE" = "yes" ; then
6388                 AC_DEFINE(wxUSE_OLE)
6389                 AC_DEFINE(wxUSE_OLE_AUTOMATION)
6390                 AC_DEFINE(wxUSE_ACTIVEX)
6391                 SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS oleauto"
6392             fi
6393         fi
6394
6395         dnl for OLE clipboard and dnd
6396         if test "$wxUSE_DATAOBJ" = "yes" ; then
6397             AC_DEFINE(wxUSE_DATAOBJ)
6398         fi
6399     else
6400         AC_MSG_WARN([Some features disabled because OLE headers not found])
6401
6402         wxUSE_CLIPBOARD=no
6403         wxUSE_DRAG_AND_DROP=no
6404         wxUSE_DATAOBJ=no
6405         wxUSE_OLE=no
6406     fi
6407
6408     if test "$wxUSE_METAFILE" = "yes"; then
6409         AC_DEFINE(wxUSE_METAFILE)
6410
6411         dnl this one should probably be made separately configurable
6412         AC_DEFINE(wxUSE_ENH_METAFILE)
6413     fi
6414 fi
6415
6416 if test "$wxUSE_IPC" = "yes"; then
6417     if test "$wxUSE_SOCKETS" != "yes" -a "$USE_WIN32" != 1; then
6418         AC_MSG_WARN(wxWidgets IPC classes require sockets... disabled)
6419         wxUSE_IPC=no
6420     fi
6421
6422     if test "$wxUSE_IPC" = "yes"; then
6423         AC_DEFINE(wxUSE_IPC)
6424         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ipc"
6425     fi
6426 fi
6427
6428 if test "$wxUSE_DATAOBJ" = "yes"; then
6429     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
6430         AC_MSG_WARN([wxDataObject not yet supported under $TOOLKIT... disabled])
6431         wxUSE_DATAOBJ=no
6432     else
6433         AC_DEFINE(wxUSE_DATAOBJ)
6434     fi
6435 else
6436     AC_MSG_WARN([Clipboard and drag-and-drop require wxDataObject -- disabled])
6437     wxUSE_CLIPBOARD=no
6438     wxUSE_DRAG_AND_DROP=no
6439 fi
6440
6441 if test "$wxUSE_CLIPBOARD" = "yes"; then
6442     if test "$wxUSE_MGL" = 1 -o "$wxUSE_DFB" = 1; then
6443         AC_MSG_WARN([Clipboard not yet supported under $TOOLKIT... disabled])
6444         wxUSE_CLIPBOARD=no
6445     fi
6446
6447     if test "$wxUSE_CLIPBOARD" = "yes"; then
6448         AC_DEFINE(wxUSE_CLIPBOARD)
6449     fi
6450 fi
6451
6452 if test "$wxUSE_DRAG_AND_DROP" = "yes" ; then
6453     if test "$wxUSE_GTK" = 1; then
6454         if test "$WXGTK12" != 1; then
6455             AC_MSG_WARN([Drag and drop is only supported under GTK+ 1.2... disabled])
6456             wxUSE_DRAG_AND_DROP=no
6457         fi
6458     fi
6459
6460     if test "$wxUSE_MOTIF" = 1 -o "$wxUSE_X11" = 1 -o "$wxUSE_MGL" = 1 -o \
6461             "$wxUSE_DFB" = 1; then
6462         AC_MSG_WARN([Drag and drop not yet supported under $TOOLKIT... disabled])
6463         wxUSE_DRAG_AND_DROP=no
6464     fi
6465
6466     if test "$wxUSE_DRAG_AND_DROP" = "yes"; then
6467         AC_DEFINE(wxUSE_DRAG_AND_DROP)
6468     fi
6469
6470 fi
6471
6472 if test "$wxUSE_DRAG_AND_DROP" = "yes" -o "$wxUSE_CLIPBOARD" = "yes"; then
6473     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dnd"
6474 fi
6475
6476 if test "$wxUSE_SPLINES" = "yes" ; then
6477   AC_DEFINE(wxUSE_SPLINES)
6478 fi
6479
6480 if test "$wxUSE_MOUSEWHEEL" = "yes" ; then
6481   AC_DEFINE(wxUSE_MOUSEWHEEL)
6482 fi
6483
6484 dnl ---------------------------------------------------------------------------
6485 dnl GUI controls
6486 dnl ---------------------------------------------------------------------------
6487
6488 USES_CONTROLS=0
6489 if test "$wxUSE_CONTROLS" = "yes"; then
6490   USES_CONTROLS=1
6491 fi
6492
6493 if test "$wxUSE_ACCEL" = "yes"; then
6494   AC_DEFINE(wxUSE_ACCEL)
6495   USES_CONTROLS=1
6496 fi
6497
6498 if test "$wxUSE_ANIMATIONCTRL" = "yes"; then
6499   AC_DEFINE(wxUSE_ANIMATIONCTRL)
6500   USES_CONTROLS=1
6501   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS animate"
6502 fi
6503
6504 if test "$wxUSE_BUTTON" = "yes"; then
6505   AC_DEFINE(wxUSE_BUTTON)
6506   USES_CONTROLS=1
6507 fi
6508
6509 if test "$wxUSE_BMPBUTTON" = "yes"; then
6510   AC_DEFINE(wxUSE_BMPBUTTON)
6511   USES_CONTROLS=1
6512 fi
6513
6514 if test "$wxUSE_CALCTRL" = "yes"; then
6515   AC_DEFINE(wxUSE_CALENDARCTRL)
6516   USES_CONTROLS=1
6517   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS calendar"
6518 fi
6519
6520 if test "$wxUSE_CARET" = "yes"; then
6521   AC_DEFINE(wxUSE_CARET)
6522   USES_CONTROLS=1
6523   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS caret"
6524 fi
6525
6526 if test "$wxUSE_COLLPANE" = "yes"; then
6527     AC_DEFINE(wxUSE_COLLPANE)
6528     USES_CONTROLS=1
6529     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS collpane"
6530 fi
6531
6532 if test "$wxUSE_COMBOBOX" = "yes"; then
6533   AC_DEFINE(wxUSE_COMBOBOX)
6534   USES_CONTROLS=1
6535 fi
6536
6537 if test "$wxUSE_COMBOCTRL" = "yes"; then
6538   AC_DEFINE(wxUSE_COMBOCTRL)
6539   USES_CONTROLS=1
6540 fi
6541
6542 if test "$wxUSE_CHOICE" = "yes"; then
6543   AC_DEFINE(wxUSE_CHOICE)
6544   USES_CONTROLS=1
6545 fi
6546
6547 if test "$wxUSE_CHOICEBOOK" = "yes"; then
6548     AC_DEFINE(wxUSE_CHOICEBOOK)
6549     USES_CONTROLS=1
6550 fi
6551
6552 if test "$wxUSE_CHECKBOX" = "yes"; then
6553   AC_DEFINE(wxUSE_CHECKBOX)
6554   USES_CONTROLS=1
6555 fi
6556
6557 if test "$wxUSE_CHECKLST" = "yes"; then
6558   AC_DEFINE(wxUSE_CHECKLISTBOX)
6559   USES_CONTROLS=1
6560 fi
6561
6562 if test "$wxUSE_COLOURPICKERCTRL" = "yes"; then
6563   AC_DEFINE(wxUSE_COLOURPICKERCTRL)
6564   USES_CONTROLS=1
6565 fi
6566
6567 if test "$wxUSE_DATEPICKCTRL" = "yes"; then
6568   AC_DEFINE(wxUSE_DATEPICKCTRL)
6569   USES_CONTROLS=1
6570 fi
6571
6572 if test "$wxUSE_DIRPICKERCTRL" = "yes"; then
6573   AC_DEFINE(wxUSE_DIRPICKERCTRL)
6574   USES_CONTROLS=1
6575 fi
6576
6577 if test "$wxUSE_FILECTRL" = "yes"; then
6578   AC_DEFINE(wxUSE_FILECTRL)
6579   USES_CONTROLS=1
6580 fi
6581
6582 if test "$wxUSE_FILEPICKERCTRL" = "yes"; then
6583   AC_DEFINE(wxUSE_FILEPICKERCTRL)
6584   USES_CONTROLS=1
6585 fi
6586
6587 if test "$wxUSE_FONTPICKERCTRL" = "yes"; then
6588   AC_DEFINE(wxUSE_FONTPICKERCTRL)
6589   USES_CONTROLS=1
6590 fi
6591
6592 if test "$wxUSE_DISPLAY" = "yes"; then
6593     if test "$wxUSE_DFB" = 1 -o "$wxUSE_MGL" = 1; then
6594         AC_MSG_WARN([wxDisplay not yet supported under $TOOLKIT... disabled])
6595         wxUSE_DISPLAY=no
6596     else
6597         AC_DEFINE(wxUSE_DISPLAY)
6598         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS display"
6599     fi
6600 fi
6601
6602 if test "$wxUSE_DETECT_SM" = "yes"; then
6603     AC_DEFINE(wxUSE_DETECT_SM)
6604 fi
6605
6606 if test "$wxUSE_GAUGE" = "yes"; then
6607   AC_DEFINE(wxUSE_GAUGE)
6608   USES_CONTROLS=1
6609 fi
6610
6611 if test "$wxUSE_GRID" = "yes"; then
6612   AC_DEFINE(wxUSE_GRID)
6613   USES_CONTROLS=1
6614   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS grid"
6615 fi
6616
6617 if test "$wxUSE_HYPERLINKCTRL" = "yes"; then
6618   AC_DEFINE(wxUSE_HYPERLINKCTRL)
6619   USES_CONTROLS=1
6620 fi
6621
6622 if test "$wxUSE_BITMAPCOMBOBOX" = "yes"; then
6623   AC_DEFINE(wxUSE_BITMAPCOMBOBOX)
6624   USES_CONTROLS=1
6625 fi
6626
6627 if test "$wxUSE_DATAVIEWCTRL" = "yes"; then
6628   AC_DEFINE(wxUSE_DATAVIEWCTRL)
6629   USES_CONTROLS=1
6630   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dataview"
6631 fi
6632
6633 if test "$wxUSE_IMAGLIST" = "yes"; then
6634     AC_DEFINE(wxUSE_IMAGLIST)
6635 fi
6636
6637 if test "$wxUSE_LISTBOOK" = "yes"; then
6638     AC_DEFINE(wxUSE_LISTBOOK)
6639     USES_CONTROLS=1
6640 fi
6641
6642 if test "$wxUSE_LISTBOX" = "yes"; then
6643     AC_DEFINE(wxUSE_LISTBOX)
6644     USES_CONTROLS=1
6645 fi
6646
6647 if test "$wxUSE_LISTCTRL" = "yes"; then
6648     if test "$wxUSE_IMAGLIST" = "yes"; then
6649         AC_DEFINE(wxUSE_LISTCTRL)
6650         USES_CONTROLS=1
6651         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS listctrl"
6652     else
6653         AC_MSG_WARN([wxListCtrl requires wxImageList and won't be compiled without it])
6654     fi
6655 fi
6656
6657 if test "$wxUSE_EDITABLELISTBOX" = "yes"; then
6658     AC_DEFINE(wxUSE_EDITABLELISTBOX)
6659     USES_CONTROLS=1
6660     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS editlbox"
6661 fi
6662
6663 if test "$wxUSE_NOTEBOOK" = "yes"; then
6664     AC_DEFINE(wxUSE_NOTEBOOK)
6665     USES_CONTROLS=1
6666     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS notebook"
6667 fi
6668
6669 if test "$wxUSE_NOTIFICATION_MESSAGE" = "yes"; then
6670     AC_DEFINE(wxUSE_NOTIFICATION_MESSAGE)
6671 fi
6672
6673 if test "$wxUSE_ODCOMBOBOX" = "yes"; then
6674   AC_DEFINE(wxUSE_ODCOMBOBOX)
6675   USES_CONTROLS=1
6676   SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS combo"
6677 fi
6678
6679 if test "$wxUSE_RADIOBOX" = "yes"; then
6680     AC_DEFINE(wxUSE_RADIOBOX)
6681     USES_CONTROLS=1
6682 fi
6683
6684 if test "$wxUSE_RADIOBTN" = "yes"; then
6685     AC_DEFINE(wxUSE_RADIOBTN)
6686     USES_CONTROLS=1
6687 fi
6688
6689 if test "$wxUSE_SASH" = "yes"; then
6690     AC_DEFINE(wxUSE_SASH)
6691     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sashtest"
6692 fi
6693
6694 if test "$wxUSE_SCROLLBAR" = "yes"; then
6695     AC_DEFINE(wxUSE_SCROLLBAR)
6696     USES_CONTROLS=1
6697     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS scroll scrollsub"
6698 fi
6699
6700 if test "$wxUSE_SEARCHCTRL" = "yes"; then
6701     AC_DEFINE(wxUSE_SEARCHCTRL)
6702     USES_CONTROLS=1
6703 fi
6704
6705 if test "$wxUSE_SLIDER" = "yes"; then
6706     AC_DEFINE(wxUSE_SLIDER)
6707     USES_CONTROLS=1
6708 fi
6709
6710 if test "$wxUSE_SPINBTN" = "yes"; then
6711     AC_DEFINE(wxUSE_SPINBTN)
6712     USES_CONTROLS=1
6713 fi
6714
6715 if test "$wxUSE_SPINCTRL" = "yes"; then
6716     AC_DEFINE(wxUSE_SPINCTRL)
6717     USES_CONTROLS=1
6718 fi
6719
6720 if test "$wxUSE_SPLITTER" = "yes"; then
6721     AC_DEFINE(wxUSE_SPLITTER)
6722     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splitter"
6723 fi
6724
6725 if test "$wxUSE_STATBMP" = "yes"; then
6726     AC_DEFINE(wxUSE_STATBMP)
6727     USES_CONTROLS=1
6728 fi
6729
6730 if test "$wxUSE_STATBOX" = "yes"; then
6731     AC_DEFINE(wxUSE_STATBOX)
6732     USES_CONTROLS=1
6733 fi
6734
6735 if test "$wxUSE_STATTEXT" = "yes"; then
6736     AC_DEFINE(wxUSE_STATTEXT)
6737     USES_CONTROLS=1
6738 fi
6739
6740 if test "$wxUSE_STATLINE" = "yes"; then
6741     AC_DEFINE(wxUSE_STATLINE)
6742     USES_CONTROLS=1
6743 fi
6744
6745 if test "$wxUSE_STATUSBAR" = "yes"; then
6746     dnl this will get undefined in wx/chkconf.h if it's not supported
6747     AC_DEFINE(wxUSE_NATIVE_STATUSBAR)
6748     AC_DEFINE(wxUSE_STATUSBAR)
6749     USES_CONTROLS=1
6750
6751     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS statbar"
6752 fi
6753
6754 if test "$wxUSE_TAB_DIALOG" = "yes"; then
6755     AC_DEFINE(wxUSE_TAB_DIALOG)
6756 fi
6757
6758 if test "$wxUSE_TEXTCTRL" = "yes"; then
6759     AC_DEFINE(wxUSE_TEXTCTRL)
6760     USES_CONTROLS=1
6761     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS text"
6762
6763     dnl we don't have special switches to disable wxUSE_RICHEDIT[2], it doesn't
6764     dnl seem useful to allow disabling them
6765     AC_DEFINE(wxUSE_RICHEDIT)
6766     AC_DEFINE(wxUSE_RICHEDIT2)
6767 fi
6768
6769 if test "$wxUSE_TOGGLEBTN" = "yes"; then
6770     if test "$wxUSE_COCOA" = 1 ; then
6771         AC_MSG_WARN([Toggle button not yet supported under Mac OS X... disabled])
6772         wxUSE_TOGGLEBTN=no
6773     fi
6774
6775     if test "$wxUSE_TOGGLEBTN" = "yes"; then
6776         AC_DEFINE(wxUSE_TOGGLEBTN)
6777         USES_CONTROLS=1
6778     fi
6779 fi
6780
6781 if test "$wxUSE_TOOLBAR" = "yes"; then
6782     AC_DEFINE(wxUSE_TOOLBAR)
6783     USES_CONTROLS=1
6784
6785     if test "$wxUSE_UNIVERSAL" = "yes"; then
6786         wxUSE_TOOLBAR_NATIVE="no"
6787     else
6788         wxUSE_TOOLBAR_NATIVE="yes"
6789         AC_DEFINE(wxUSE_TOOLBAR_NATIVE)
6790     fi
6791
6792     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS toolbar"
6793 fi
6794
6795 if test "$wxUSE_TOOLTIPS" = "yes"; then
6796     if test "$wxUSE_MOTIF" = 1; then
6797         AC_MSG_WARN([wxTooltip not supported yet under Motif... disabled])
6798     else
6799         if test "$wxUSE_UNIVERSAL" = "yes"; then
6800             AC_MSG_WARN([wxTooltip not supported yet in wxUniversal... disabled])
6801         else
6802             AC_DEFINE(wxUSE_TOOLTIPS)
6803         fi
6804     fi
6805 fi
6806
6807 if test "$wxUSE_TREEBOOK" = "yes"; then
6808     AC_DEFINE(wxUSE_TREEBOOK)
6809     USES_CONTROLS=1
6810 fi
6811
6812 if test "$wxUSE_TOOLBOOK" = "yes"; then
6813     AC_DEFINE(wxUSE_TOOLBOOK)
6814     USES_CONTROLS=1
6815 fi
6816
6817 if test "$wxUSE_TREECTRL" = "yes"; then
6818     if test "$wxUSE_IMAGLIST" = "yes"; then
6819         AC_DEFINE(wxUSE_TREECTRL)
6820         USES_CONTROLS=1
6821         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS treectrl"
6822     else
6823         AC_MSG_WARN([wxTreeCtrl requires wxImageList and won't be compiled without it])
6824     fi
6825 fi
6826
6827 if test "$wxUSE_POPUPWIN" = "yes"; then
6828     if test "$wxUSE_COCOA" = 1 ; then
6829         AC_MSG_WARN([Popup window not yet supported under Mac OS X... disabled])
6830     else
6831         if test "$wxUSE_PM" = 1; then
6832             AC_MSG_WARN([wxPopupWindow not yet supported under PM... disabled])
6833         else
6834             AC_DEFINE(wxUSE_POPUPWIN)
6835             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS popup"
6836
6837             USES_CONTROLS=1
6838         fi
6839     fi
6840 fi
6841
6842 if test "$wxUSE_DIALUP_MANAGER" = "yes"; then
6843     if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1 -o "$wxUSE_MGL" = 1; then
6844         AC_MSG_WARN([Dialup manager not supported on this platform... disabled])
6845     else
6846         AC_DEFINE(wxUSE_DIALUP_MANAGER)
6847         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dialup"
6848     fi
6849 fi
6850
6851 if test "$wxUSE_TIPWINDOW" = "yes"; then
6852     if test "$wxUSE_PM" = 1; then
6853         AC_MSG_WARN([wxTipWindow not yet supported under PM... disabled])
6854     else
6855         AC_DEFINE(wxUSE_TIPWINDOW)
6856     fi
6857 fi
6858
6859 if test "$USES_CONTROLS" = 1; then
6860     AC_DEFINE(wxUSE_CONTROLS)
6861 fi
6862
6863 dnl ---------------------------------------------------------------------------
6864 dnl misc options
6865 dnl ---------------------------------------------------------------------------
6866
6867 dnl please keep the settings below in alphabetical order
6868 if test "$wxUSE_ACCESSIBILITY" = "yes"; then
6869     AC_DEFINE(wxUSE_ACCESSIBILITY)
6870     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS access"
6871 fi
6872
6873 if test "$wxUSE_DRAGIMAGE" = "yes"; then
6874     AC_DEFINE(wxUSE_DRAGIMAGE)
6875     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS dragimag"
6876 fi
6877
6878 if test "$wxUSE_EXCEPTIONS" = "yes"; then
6879     if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
6880         AC_MSG_WARN([--enable-exceptions can't be used with --enable-no_exceptions])
6881     else
6882         AC_DEFINE(wxUSE_EXCEPTIONS)
6883         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS except"
6884     fi
6885 fi
6886
6887 USE_HTML=0
6888 if test "$wxUSE_HTML" = "yes"; then
6889     AC_DEFINE(wxUSE_HTML)
6890     USE_HTML=1
6891     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html html/about html/help html/helpview html/printing html/test html/virtual html/widget html/zip htlbox"
6892 fi
6893 if test "$wxUSE_WEBKIT" = "yes"; then
6894     if test "$wxUSE_MAC" = 1 -a "$USE_DARWIN" = 1; then
6895         old_CPPFLAGS="$CPPFLAGS"
6896         CPPFLAGS="-x objective-c++ $CPPFLAGS"
6897         AC_CHECK_HEADER([WebKit/HIWebView.h],
6898                         [
6899                            AC_DEFINE(wxUSE_WEBKIT)
6900                            WEBKIT_LINK="-framework WebKit"
6901                         ],
6902                         [
6903                            AC_MSG_WARN([WebKit headers not found; disabling wxWebKit])
6904                            wxUSE_WEBKIT=no
6905                         ],
6906                         [
6907                            #include <Carbon/Carbon.h>
6908                            #include <WebKit/WebKit.h>
6909                         ])
6910         CPPFLAGS="$old_CPPFLAGS"
6911     elif test "$wxUSE_COCOA" = 1; then
6912         AC_DEFINE(wxUSE_WEBKIT)
6913     else
6914         wxUSE_WEBKIT=no
6915     fi
6916     if test "$wxUSE_WEBKIT" = "yes"; then
6917         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS html/htmlctrl"
6918     fi
6919 fi
6920
6921 USE_XRC=0
6922 if test "$wxUSE_XRC" = "yes"; then
6923     if test "$wxUSE_XML" != "yes"; then
6924         AC_MSG_WARN([XML library not built, XRC resources disabled])
6925         wxUSE_XRC=no
6926     else
6927         AC_DEFINE(wxUSE_XRC)
6928         USE_XRC=1
6929         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS xrc"
6930     fi
6931 fi
6932
6933 USE_AUI=0
6934 if test "$wxUSE_AUI" = "yes"; then
6935    AC_DEFINE(wxUSE_AUI)
6936    USE_AUI=1
6937    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS aui"
6938 fi
6939
6940 USE_PROPGRID=0
6941 if test "$wxUSE_PROPGRID" = "yes"; then
6942    AC_DEFINE(wxUSE_PROPGRID)
6943    USE_PROPGRID=1
6944    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS propgrid"
6945 fi
6946
6947 USE_STC=0
6948 if test "$wxUSE_STC" = "yes"; then
6949    AC_DEFINE(wxUSE_STC)
6950    USE_STC=1
6951    SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS stc"
6952 fi
6953
6954 if test "$wxUSE_MENUS" = "yes"; then
6955     AC_DEFINE(wxUSE_MENUS)
6956     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS menu"
6957 fi
6958
6959 if test "$wxUSE_METAFILE" = "yes"; then
6960     AC_DEFINE(wxUSE_METAFILE)
6961 fi
6962
6963 if test "$wxUSE_MIMETYPE" = "yes"; then
6964     AC_DEFINE(wxUSE_MIMETYPE)
6965 fi
6966
6967 if test "$wxUSE_MINIFRAME" = "yes"; then
6968     AC_DEFINE(wxUSE_MINIFRAME)
6969 fi
6970
6971 if test "$wxUSE_SYSTEM_OPTIONS" = "yes"; then
6972     AC_DEFINE(wxUSE_SYSTEM_OPTIONS)
6973 fi
6974
6975 if test "$wxUSE_TASKBARICON" = "yes"; then
6976     AC_DEFINE(wxUSE_TASKBARICON)
6977     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS taskbar"
6978 fi
6979
6980
6981 if test "$wxUSE_VALIDATORS" = "yes"; then
6982     AC_DEFINE(wxUSE_VALIDATORS)
6983     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS validate"
6984 fi
6985
6986 if test "$wxUSE_PALETTE" = "yes" ; then
6987     if test "$wxUSE_DFB" = 1; then
6988         AC_MSG_WARN([wxPalette not yet supported under DFB... disabled])
6989         wxUSE_PALETTE=no
6990     else
6991         AC_DEFINE(wxUSE_PALETTE)
6992     fi
6993 fi
6994
6995 if test "$wxUSE_UNICODE" = "yes" -a "$wxUSE_UNICODE_MSLU" = "yes" ; then
6996   dnl Must be done this late because -lunicows must be before all the other libs
6997   LIBS=" -lunicows $LIBS"
6998 fi
6999
7000 USE_RICHTEXT=0
7001 if test "$wxUSE_RICHTEXT" = "yes"; then
7002     AC_DEFINE(wxUSE_RICHTEXT)
7003     USE_RICHTEXT=1
7004     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS richtext"
7005 fi
7006
7007 dnl ---------------------------------------------------------------------------
7008 dnl wxImage options
7009 dnl ---------------------------------------------------------------------------
7010
7011 if test "$wxUSE_IMAGE" = "yes" ; then
7012     AC_DEFINE(wxUSE_IMAGE)
7013
7014     if test "$wxUSE_GIF" = "yes" ; then
7015       AC_DEFINE(wxUSE_GIF)
7016     fi
7017
7018     if test "$wxUSE_PCX" = "yes" ; then
7019       AC_DEFINE(wxUSE_PCX)
7020     fi
7021
7022     if test "$wxUSE_TGA" = "yes" ; then
7023       AC_DEFINE(wxUSE_TGA)
7024     fi
7025
7026     if test "$wxUSE_IFF" = "yes" ; then
7027       AC_DEFINE(wxUSE_IFF)
7028     fi
7029
7030     if test "$wxUSE_PNM" = "yes" ; then
7031       AC_DEFINE(wxUSE_PNM)
7032     fi
7033
7034     if test "$wxUSE_XPM" = "yes" ; then
7035       AC_DEFINE(wxUSE_XPM)
7036     fi
7037
7038     if test "$wxUSE_ICO_CUR" = "yes" ; then
7039       AC_DEFINE(wxUSE_ICO_CUR)
7040     fi
7041 fi
7042
7043 dnl ---------------------------------------------------------------------------
7044 dnl common dialogs
7045 dnl ---------------------------------------------------------------------------
7046
7047 if test "$wxUSE_ABOUTDLG" = "yes"; then
7048     AC_DEFINE(wxUSE_ABOUTDLG)
7049 fi
7050
7051 if test "$wxUSE_CHOICEDLG" = "yes"; then
7052     AC_DEFINE(wxUSE_CHOICEDLG)
7053 fi
7054
7055 if test "$wxUSE_COLOURDLG" = "yes"; then
7056     AC_DEFINE(wxUSE_COLOURDLG)
7057 fi
7058
7059 if test "$wxUSE_FILEDLG" = "yes"; then
7060     AC_DEFINE(wxUSE_FILEDLG)
7061 fi
7062
7063 if test "$wxUSE_FINDREPLDLG" = "yes"; then
7064     AC_DEFINE(wxUSE_FINDREPLDLG)
7065 fi
7066
7067 if test "$wxUSE_FONTDLG" = "yes"; then
7068     AC_DEFINE(wxUSE_FONTDLG)
7069 fi
7070
7071 if test "$wxUSE_DIRDLG" = "yes"; then
7072     if test "$wxUSE_TREECTRL" != "yes"; then
7073         AC_MSG_WARN(wxDirDialog requires wxTreeCtrl so it won't be compiled without it)
7074     else
7075         AC_DEFINE(wxUSE_DIRDLG)
7076     fi
7077 fi
7078
7079 if test "$wxUSE_MSGDLG" = "yes"; then
7080     AC_DEFINE(wxUSE_MSGDLG)
7081 fi
7082
7083 if test "$wxUSE_NUMBERDLG" = "yes"; then
7084     AC_DEFINE(wxUSE_NUMBERDLG)
7085 fi
7086
7087 if test "$wxUSE_PROGRESSDLG" = "yes"; then
7088     if test "$wxUSE_CONSTRAINTS" != "yes"; then
7089        AC_MSG_WARN(wxProgressDialog requires constraints so it won't be compiled without them)
7090     else
7091         AC_DEFINE(wxUSE_PROGRESSDLG)
7092     fi
7093 fi
7094
7095 if test "$wxUSE_SPLASH" = "yes"; then
7096     AC_DEFINE(wxUSE_SPLASH)
7097     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS splash"
7098 fi
7099
7100 if test "$wxUSE_STARTUP_TIPS" = "yes"; then
7101     if test "$wxUSE_CONSTRAINTS" != "yes"; then
7102        AC_MSG_WARN(Startup tips requires constraints and won't be compiled without them)
7103     else
7104         AC_DEFINE(wxUSE_STARTUP_TIPS)
7105     fi
7106 fi
7107
7108 if test "$wxUSE_TEXTDLG" = "yes"; then
7109     AC_DEFINE(wxUSE_TEXTDLG)
7110 fi
7111
7112 if test "$wxUSE_WIZARDDLG" = "yes"; then
7113     AC_DEFINE(wxUSE_WIZARDDLG)
7114     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS wizard"
7115 fi
7116
7117 dnl ---------------------------------------------------------------------------
7118 dnl options used under wxMSW and wxPM
7119 dnl ---------------------------------------------------------------------------
7120
7121 if test "$wxUSE_MSW" = 1 -o "$wxUSE_PM" = 1; then
7122     if test "$wxUSE_OWNER_DRAWN" = "yes"; then
7123         AC_DEFINE(wxUSE_OWNER_DRAWN)
7124     fi
7125 fi
7126
7127 dnl ---------------------------------------------------------------------------
7128 dnl wxMSW-only options
7129 dnl ---------------------------------------------------------------------------
7130
7131 if test "$wxUSE_MSW" = 1 ; then
7132
7133     if test "$wxUSE_DC_CACHEING" = "yes"; then
7134         AC_DEFINE(wxUSE_DC_CACHEING)
7135     fi
7136
7137     if test "$wxUSE_DIB" = "yes"; then
7138         AC_DEFINE(wxUSE_WXDIB)
7139     fi
7140
7141     if test "$wxUSE_POSTSCRIPT_ARCHITECTURE_IN_MSW" = "yes"; then
7142         AC_DEFINE(wxUSE_POSTSCRIPT_ARCHITECTURE_IN_MSW)
7143     fi
7144
7145     if test "$wxUSE_UXTHEME" = "yes"; then
7146         AC_DEFINE(wxUSE_UXTHEME)
7147     fi
7148
7149 fi
7150 dnl wxUSE_MSW = 1
7151
7152 dnl not quite MSW-only although mostly useful to disable this under MSW
7153 if test "$wxUSE_AUTOID_MANAGEMENT" = "yes"; then
7154     AC_DEFINE(wxUSE_AUTOID_MANAGEMENT)
7155 fi
7156
7157 if test "$USE_WIN32" = 1 ; then
7158     if test "$wxUSE_INICONF" = "yes"; then
7159         AC_DEFINE(wxUSE_INICONF)
7160     fi
7161
7162     if test "$wxUSE_REGKEY" = "yes"; then
7163         AC_DEFINE(wxUSE_REGKEY)
7164     fi
7165 fi
7166 dnl USE_WIN32 = 1
7167
7168 dnl ---------------------------------------------------------------------------
7169 dnl wxGraphicsContext
7170 dnl ---------------------------------------------------------------------------
7171
7172 if test "$wxUSE_MAC" = 1; then
7173         wxUSE_GRAPHICS_CONTEXT="yes"
7174 fi
7175
7176 if test "$wxUSE_GRAPHICS_CONTEXT" = "yes"; then
7177    if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1; then
7178       AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)
7179    elif test "$wxUSE_GTK" != 1; then
7180       dnl for other builds we'll just wing it for now...
7181       AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)
7182    else
7183       dnl ...but let's check for cairo availability for wxGTK builds
7184       PKG_CHECK_MODULES(CAIRO, cairo,
7185           [AC_DEFINE(wxUSE_GRAPHICS_CONTEXT)],
7186           [AC_MSG_WARN([Cairo library not found, unable to set wxUSE_GRAPHICS_CONTEXT])]
7187       )
7188    fi
7189 fi
7190
7191 dnl ---------------------------------------------------------------------------
7192 dnl wxMediaCtrl
7193 dnl ---------------------------------------------------------------------------
7194
7195 USE_MEDIA=0
7196
7197 if test "$wxUSE_MEDIACTRL" = "yes"; then
7198     USE_MEDIA=1
7199
7200     dnl -----------------------------------------------------------------------
7201     dnl GStreamer
7202     dnl -----------------------------------------------------------------------
7203     if test "$wxUSE_GTK" = 1; then
7204         wxUSE_GSTREAMER="no"
7205
7206         dnl -------------------------------------------------------------------
7207         dnl Test for at least 0.8 gstreamer module from pkg-config
7208         dnl Even totem doesn't accept 0.9 evidently.
7209         dnl
7210         dnl So, we first check to see if 0.10 if available - if not we
7211         dnl try the older 0.8 version
7212         dnl -------------------------------------------------------------------
7213         GST_VERSION_MAJOR=0
7214         GST_VERSION_MINOR=10
7215         GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
7216
7217         if test "$wxUSE_GSTREAMER8" = "no"; then
7218             PKG_CHECK_MODULES(GST,
7219                 [gstreamer-$GST_VERSION gstreamer-plugins-base-$GST_VERSION gconf-2.0],
7220                 [
7221                     wxUSE_GSTREAMER="yes"
7222                     GST_LIBS="$GST_LIBS -lgstinterfaces-$GST_VERSION"
7223                 ],
7224                 [
7225                     AC_MSG_WARN([GStreamer 0.10 not available, falling back to 0.8])
7226                     GST_VERSION_MINOR=8
7227                 ]
7228             )
7229         else
7230             dnl check only for 0.8
7231             GST_VERSION_MINOR=8
7232         fi
7233
7234         if test $GST_VERSION_MINOR = "8"; then
7235             GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
7236             PKG_CHECK_MODULES(GST,
7237                 [gstreamer-$GST_VERSION gstreamer-interfaces-$GST_VERSION gstreamer-gconf-$GST_VERSION],
7238                 wxUSE_GSTREAMER="yes",
7239                 [
7240                     AC_MSG_WARN([GStreamer 0.8/0.10 not available.])
7241                 ])
7242         fi
7243
7244
7245         if test "$wxUSE_GSTREAMER" = "yes"; then
7246             CPPFLAGS="$GST_CFLAGS $CPPFLAGS"
7247             EXTRALIBS_MEDIA="$GST_LIBS"
7248
7249             AC_DEFINE(wxUSE_GSTREAMER)
7250         else
7251             USE_MEDIA=0
7252         fi
7253     fi
7254
7255     if test $USE_MEDIA = 1; then
7256         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS mediaplayer"
7257         AC_DEFINE(wxUSE_MEDIACTRL)
7258     fi
7259 fi
7260
7261 dnl ---------------------------------------------------------------------------
7262 dnl get the string with OS info - used by wxGetOsDescription() on MacOS X
7263 dnl ---------------------------------------------------------------------------
7264
7265 if test "$cross_compiling" = "yes"; then
7266     dnl Use best guess from host as we can't use uname when cross compiling
7267     OSINFO="\"$host\""
7268 else
7269     dnl attualy work out OS version
7270     OSINFO=`uname -s -r -m`
7271     OSINFO="\"$OSINFO\""
7272 fi
7273
7274 AC_DEFINE_UNQUOTED(WXWIN_OS_DESCRIPTION, $OSINFO)
7275
7276 dnl ---------------------------------------------------------------------------
7277 dnl define the variable containing the installation prefix (used in dcpsg.cpp)
7278 dnl ---------------------------------------------------------------------------
7279
7280 if test "x$prefix" != "xNONE"; then
7281     wxPREFIX=$prefix
7282 else
7283     wxPREFIX=$ac_default_prefix
7284 fi
7285
7286 AC_DEFINE_UNQUOTED(wxINSTALL_PREFIX, "$wxPREFIX")
7287
7288
7289 dnl ---------------------------------------------------------------------------
7290 dnl define variables with all built libraries for wx-config
7291 dnl ---------------------------------------------------------------------------
7292
7293 STD_BASE_LIBS="base"
7294 STD_GUI_LIBS=""
7295 BUILT_WX_LIBS="base"
7296 ALL_WX_LIBS="xrc stc gl media qa html adv core xml net base"
7297
7298 if test "$wxUSE_SOCKETS" = "yes" ; then
7299     STD_BASE_LIBS="net $STD_BASE_LIBS"
7300     BUILT_WX_LIBS="net $BUILT_WX_LIBS"
7301 fi
7302 if test "$wxUSE_XML" = "yes" ; then
7303     STD_BASE_LIBS="xml $STD_BASE_LIBS"
7304     BUILT_WX_LIBS="xml $BUILT_WX_LIBS"
7305 fi
7306
7307 if test "$wxUSE_GUI" = "yes"; then
7308     STD_GUI_LIBS="adv core"
7309     BUILT_WX_LIBS="$STD_GUI_LIBS $BUILT_WX_LIBS"
7310
7311     if test "$wxUSE_DEBUGREPORT" = "yes" ; then
7312         STD_GUI_LIBS="qa $STD_GUI_LIBS"
7313         BUILT_WX_LIBS="qa $BUILT_WX_LIBS"
7314     fi
7315     if test "$wxUSE_HTML" = "yes" ; then
7316         STD_GUI_LIBS="html $STD_GUI_LIBS"
7317         BUILT_WX_LIBS="html $BUILT_WX_LIBS"
7318     fi
7319     if test "$wxUSE_MEDIACTRL" = "yes" ; then
7320         BUILT_WX_LIBS="media $BUILT_WX_LIBS"
7321     fi
7322     if test "$wxUSE_OPENGL" = "yes" ; then
7323         BUILT_WX_LIBS="gl $BUILT_WX_LIBS"
7324     fi
7325     if test "$wxUSE_AUI" = "yes" ; then
7326         BUILT_WX_LIBS="aui $BUILT_WX_LIBS"
7327     fi
7328     if test "$wxUSE_PROPGRID" = "yes" ; then
7329         BUILT_WX_LIBS="propgrid $BUILT_WX_LIBS"
7330     fi
7331     if test "$wxUSE_STC" = "yes" ; then
7332         BUILT_WX_LIBS="stc $BUILT_WX_LIBS"
7333     fi
7334     if test "$wxUSE_XRC" = "yes" ; then
7335         STD_GUI_LIBS="xrc $STD_GUI_LIBS"
7336         BUILT_WX_LIBS="xrc $BUILT_WX_LIBS"
7337     fi
7338 fi
7339
7340 AC_SUBST(ALL_WX_LIBS)
7341 AC_SUBST(BUILT_WX_LIBS)
7342 AC_SUBST(STD_BASE_LIBS)
7343 AC_SUBST(STD_GUI_LIBS)
7344
7345 dnl ---------------------------------------------------------------------------
7346 dnl Output the makefiles and such from the results found above
7347 dnl ---------------------------------------------------------------------------
7348
7349 dnl all additional libraries (except wxWidgets itself) we link with
7350
7351 if test "$wxUSE_MAC" = 1 ; then
7352     if test "$wxUSE_SOUND" = "yes" || test "$wxUSE_MEDIACTRL" = "yes"; then
7353         if test "$USE_DARWIN" = 1; then
7354             LDFLAGS="$LDFLAGS -framework QuickTime"
7355         fi
7356     fi
7357     if test "$USE_DARWIN" = 1; then
7358         LDFLAGS="$LDFLAGS -framework IOKit -framework Carbon -framework Cocoa -framework AudioToolbox -framework System -framework OpenGL"
7359     fi
7360 fi
7361 if test "$wxUSE_COCOA" = 1 ; then
7362     LDFLAGS="$LDFLAGS -framework IOKit -framework Cocoa"
7363     if test "$wxUSE_MEDIACTRL" = "yes"; then
7364         LDFLAGS="$LDFLAGS -framework QuickTime"
7365     fi
7366 fi
7367 if test "$USE_DARWIN" = 1 -a "$wxUSE_MAC" != 1 -a "$wxUSE_COCOA" != 1 ; then
7368     LDFLAGS="$LDFLAGS -framework IOKit -framework CoreServices -framework System -framework ApplicationServices"
7369 fi
7370
7371 LIBS="$ZLIB_LINK $POSIX4_LINK $INET_LINK $WCHAR_LINK $DL_LINK $LIBS"
7372
7373 if test "$wxUSE_GUI" = "yes"; then
7374
7375     dnl TODO add checks that these samples will really compile (i.e. all the
7376     dnl      library features they need are present)
7377
7378     dnl TODO some samples are never built so far: mfc (requires VC++)
7379     SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS artprov controls dialogs drawing \
7380                      erase event exec font image minimal mobile \
7381                      mobile/wxedit mobile/styles render \
7382                      shaped svg taborder vscroll widgets"
7383
7384     if test "$wxUSE_MONOLITHIC" != "yes"; then
7385         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS console"
7386     fi
7387     if test "$TOOLKIT" = "MSW"; then
7388         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS regtest"
7389         if test "$wxUSE_UNIVERSAL" != "yes"; then
7390             SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ownerdrw nativdlg"
7391         fi
7392     fi
7393     if test "$TOOLKIT" = "PM" -a "$wxUSE_UNIVERSAL" != "yes"; then
7394         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ownerdrw"
7395     fi
7396 else
7397     SAMPLES_SUBDIRS="console"
7398     if test "$wxUSE_SOCKETS" = "yes" ; then
7399         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS sockets"
7400     fi
7401     if test "$wxUSE_IPC" = "yes" ; then
7402         SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS ipc"
7403     fi
7404 fi
7405
7406
7407 dnl C/C++ compiler options used to compile wxWidgets
7408 dnl
7409 dnl check for icc before gcc as icc is also recognized as gcc
7410 if test "x$INTELCC" = "xyes" ; then
7411     dnl Warnings which can't be easily suppressed in C code are disabled:
7412     dnl
7413     dnl     remark #810: conversion from "x" to "y" may lose significant bits
7414     dnl     remark #869: parameter "foo" was never referenced
7415     dnl     remark #1572: floating-point equality and inequality comparisons
7416     dnl                   are unreliable
7417     dnl     remark #1684: conversion from pointer to same-sized integral type
7418     dnl
7419     dnl (for others see below)
7420     CWARNINGS="-Wall -wd810,869,981,1418,1572,1684"
7421 elif test "$GCC" = yes ; then
7422     CWARNINGS="-Wall -Wundef"
7423 fi
7424
7425 if test "x$INTELCXX" = "xyes" ; then
7426     dnl Intel compiler gives some warnings which simply can't be worked
7427     dnl around or of which we have too many (810, 869) so it's impractical to
7428     dnl keep them enabled even if in theory it would be nice and some others
7429     dnl (279) are generated for standard macros and so there is nothing we can
7430     dnl do about them
7431     dnl
7432     dnl     remark #279: controlling expression is constant
7433     dnl     remark #383: value copied to temporary, reference to temporary used
7434     dnl     remark #444: destructor for base class "xxx" is not virtual
7435     dnl     remark #810: conversion from "x" to "y" may lose significant bits
7436     dnl     remark #869: parameter "foo" was never referenced
7437     dnl     remark #981: operands are evaluated in unspecified order
7438     dnl     remark #1418: external definition with no prior declaration
7439     dnl     remark #1419: external declaration in primary source file
7440     CXXWARNINGS="-Wall -wd279,383,444,810,869,981,1418,1419"
7441 elif test "$GXX" = yes ; then
7442     dnl CXXWARNINGS="-Wall -W -Wcast-qual -Werror"
7443     CXXWARNINGS="-Wall -Wundef -Wunused-parameter -Wno-ctor-dtor-privacy"
7444 fi
7445
7446
7447 dnl combine everything together and remove the extra white space while doing it
7448 WXCONFIG_CFLAGS=`echo $WXCONFIG_CFLAGS`
7449 WXCONFIG_CXXFLAGS=`echo $WXCONFIG_CFLAGS $WXCONFIG_CXXFLAGS`
7450
7451
7452 dnl add -I options we use during library compilation
7453 dnl
7454 dnl note that the order is somewhat important: wxWidgets headers should
7455 dnl come first and the one with setup.h should be before $(top_srcdir)/include
7456 dnl in case the latter contains setup.h used by non-autoconf makefiles (e.g.
7457 dnl CodeWarrior):
7458 CPPFLAGS=`echo $WXCONFIG_CPPFLAGS \
7459  -I\\${wx_top_builddir}/lib/wx/include/${TOOLCHAIN_FULLNAME} \
7460  -I\\${top_srcdir}/include $TOOLKIT_INCLUDE \
7461  $CPPFLAGS `
7462
7463 C_AND_CXX_FLAGS="$DEBUG_CFLAGS $PROFILE_FLAGS $OPTIMISE_CFLAGS"
7464 CFLAGS=`echo $WXCONFIG_CFLAGS $CWARNINGS $C_AND_CXX_FLAGS $CFLAGS `
7465 CXXFLAGS=`echo $WXCONFIG_CXXFLAGS $C_AND_CXX_FLAGS $CXXFLAGS `
7466 OBJCFLAGS=`echo $WXCONFIG_CFLAGS $CWARNINGS $C_AND_CXX_FLAGS $OBJCFLAGS `
7467 OBJCXXFLAGS=`echo $WXCONFIG_CXXFLAGS $C_AND_CXX_FLAGS $OBJCXXFLAGS `
7468
7469 dnl now that we added WXCONFIG_CPPFLAGS to CPPFLAGS we can add the wx-config
7470 dnl only stuff to it
7471 WXCONFIG_CPPFLAGS=`echo $WXCONFIG_CPPFLAGS $WXCONFIG_ONLY_CPPFLAGS`
7472
7473
7474 if test "x$MWCC" = "xyes"; then
7475     dnl Correct MW 8.3 to be more similar to GCC.  In particular we
7476     dnl must use <regex.h> from system not our local copy on OS X,
7477     dnl but must use local not system on OS 9.
7478     dnl The following should make all -I paths usable for <> includes
7479     dnl while first checking in real system paths.  With 8.3 using
7480     dnl -gccincludes it will actually check local paths before system
7481     dnl even for <> which is totally wrong.
7482
7483     dnl Note that because this absolutely needs to be before any -I
7484     dnl that we have to tack it on to the end of the compiler commandline.
7485     CC="$CC -cwd source -I-"
7486     CXX="$CXX -cwd source -I-"
7487 fi
7488
7489
7490 LIBS=`echo $LIBS`
7491 EXTRALIBS="$LDFLAGS $LDFLAGS_VERSIONING $LIBS $DMALLOC_LIBS"
7492 EXTRALIBS_XML="$EXPAT_LINK"
7493 EXTRALIBS_HTML="$MSPACK_LINK"
7494 EXTRALIBS_MEDIA="$GST_LIBS"
7495 EXTRALIBS_STC="-lwxscintilla${lib_debug_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX}"
7496 if test "$wxUSE_GUI" = "yes"; then
7497     EXTRALIBS_GUI=`echo $GUI_TK_LIBRARY $PNG_LINK $JPEG_LINK $TIFF_LINK $WEBKIT_LINK $EXTRALIBS_HILDON $EXTRALIBS_GNOMEVFS $EXTRALIBS_GNOMEPRINT`
7498 fi
7499 if test "$wxUSE_OPENGL" = "yes"; then
7500     EXTRALIBS_OPENGL="$LDFLAGS_GL $OPENGL_LIBS"
7501 fi
7502
7503 LDFLAGS="$LDFLAGS $PROFILE_FLAGS"
7504
7505 WXCONFIG_LIBS="$LIBS"
7506
7507 dnl wx-config must output builtin 3rd party libs in --libs in static build:
7508 if test "$wxUSE_REGEX" = "builtin" ; then
7509     wxconfig_3rdparty="regex${lib_unicode_suffix} $wxconfig_3rdparty"
7510 fi
7511 if test "$wxUSE_EXPAT" = "builtin" ; then
7512     wxconfig_3rdparty="expat $wxconfig_3rdparty"
7513 fi
7514 if test "$wxUSE_LIBTIFF" = "builtin" ; then
7515     wxconfig_3rdparty="tiff $wxconfig_3rdparty"
7516 fi
7517 if test "$wxUSE_LIBJPEG" = "builtin" ; then
7518     wxconfig_3rdparty="jpeg $wxconfig_3rdparty"
7519 fi
7520 if test "$wxUSE_LIBPNG" = "builtin" ; then
7521     wxconfig_3rdparty="png $wxconfig_3rdparty"
7522 fi
7523 if test "$wxUSE_ZLIB" = "builtin" ; then
7524     wxconfig_3rdparty="zlib $wxconfig_3rdparty"
7525 fi
7526
7527 for i in $wxconfig_3rdparty ; do
7528     WXCONFIG_LIBS="-lwx${i}${lib_debug_suffix}${WX_LIB_FLAVOUR}-${WX_RELEASE}${HOST_SUFFIX} $WXCONFIG_LIBS"
7529 done
7530
7531
7532 if test "x$wxUSE_UNIVERSAL" = "xyes" ; then
7533     WXUNIV=1
7534
7535     case "$wxUNIV_THEMES" in
7536         ''|all)
7537             AC_DEFINE(wxUSE_ALL_THEMES)
7538             ;;
7539
7540         *)
7541             for t in `echo $wxUNIV_THEMES | tr , ' ' | tr '[[a-z]]' '[[A-Z]]'`; do
7542                 AC_DEFINE_UNQUOTED(wxUSE_THEME_$t)
7543             done
7544     esac
7545 else
7546     WXUNIV=0
7547 fi
7548
7549 AC_SUBST(wxUSE_ZLIB)
7550 AC_SUBST(wxUSE_REGEX)
7551 AC_SUBST(wxUSE_EXPAT)
7552 AC_SUBST(wxUSE_LIBJPEG)
7553 AC_SUBST(wxUSE_LIBPNG)
7554 AC_SUBST(wxUSE_LIBTIFF)
7555
7556 if test $wxUSE_MONOLITHIC = "yes" ; then
7557     MONOLITHIC=1
7558 else
7559     MONOLITHIC=0
7560 fi
7561
7562 if test $wxUSE_PLUGINS = "yes" ; then
7563     USE_PLUGINS=1
7564 else
7565     USE_PLUGINS=0
7566 fi
7567
7568 if test "$wxUSE_DEBUGREPORT" = "yes" ; then
7569     USE_QA=1
7570 else
7571     USE_QA=0
7572 fi
7573
7574 if test $wxUSE_OFFICIAL_BUILD = "yes" ; then
7575     OFFICIAL_BUILD=1
7576 else
7577     OFFICIAL_BUILD=0
7578 fi
7579
7580 AC_SUBST(VENDOR)
7581 AC_SUBST(OFFICIAL_BUILD)
7582 AC_SUBST(WX_FLAVOUR)
7583 AC_SUBST(WX_LIB_FLAVOUR)
7584
7585 AC_SUBST(WXUNIV)
7586 AC_SUBST(MONOLITHIC)
7587 AC_SUBST(USE_PLUGINS)
7588 AC_SUBST(LIBS)
7589 AC_SUBST(CXXWARNINGS)
7590 AC_SUBST(EXTRALIBS)
7591 AC_SUBST(EXTRALIBS_XML)
7592 AC_SUBST(EXTRALIBS_HTML)
7593 AC_SUBST(EXTRALIBS_MEDIA)
7594 AC_SUBST(EXTRALIBS_GUI)
7595 AC_SUBST(EXTRALIBS_OPENGL)
7596 AC_SUBST(EXTRALIBS_SDL)
7597 AC_SUBST(EXTRALIBS_STC)
7598 AC_SUBST(WITH_PLUGIN_SDL)
7599 AC_SUBST(EXTRALIBS_GTKPRINT)
7600 AC_SUBST(EXTRALIBS_GNOMEPRINT)
7601 AC_SUBST(EXTRALIBS_GNOMEVFS)
7602 AC_SUBST(EXTRALIBS_HILDON)
7603 AC_SUBST(UNICODE)
7604 AC_SUBST(BUILD)
7605 AC_SUBST(DEBUG_INFO)
7606 AC_SUBST(DEBUG_FLAG)
7607 if test "$TOOLKIT" = "MAC"; then
7608     TOOLKIT_LOWERCASE=osx
7609 else
7610     TOOLKIT_LOWERCASE=`echo $TOOLKIT | tr '[[A-Z]]' '[[a-z]]'`
7611 fi
7612 AC_SUBST(TOOLKIT_LOWERCASE)
7613 AC_SUBST(TOOLKIT_VERSION)
7614 AC_SUBST(SAMPLES_RPATH_FLAG)
7615 AC_SUBST(SAMPLES_RPATH_POSTLINK)
7616 AC_SUBST(HOST_SUFFIX)
7617 AC_SUBST(CPPUNIT_CFLAGS)
7618 AC_SUBST(CPPUNIT_LIBS)
7619
7620 case "$TOOLKIT" in
7621     GTK)
7622         TOOLKIT_DESC="GTK+"
7623         if test "$WXGTK2" = 1; then
7624             TOOLKIT_DESC="$TOOLKIT_DESC 2"
7625             if test "$wxUSE_GTKPRINT" = "yes" ; then
7626                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA GTK+ printing";
7627             fi
7628             if test "$wxUSE_LIBGNOMEPRINT" = "yes" ; then
7629                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA gnomeprint";
7630             fi
7631             if test "$wxUSE_LIBGNOMEVFS" = "yes" ; then
7632                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA gnomevfs"
7633             fi
7634             if test "$wxUSE_LIBHILDON" = "yes"; then
7635                 TOOLKIT_EXTRA="$TOOLKIT_EXTRA hildon"
7636             fi
7637
7638             if test "$TOOLKIT_EXTRA" != ""; then
7639                 TOOLKIT_DESC="$TOOLKIT_DESC with support for `echo $TOOLKIT_EXTRA | tr -s ' '`"
7640             fi
7641         fi
7642         ;;
7643
7644     ?*)
7645         TOOLKIT_DESC=$TOOLKIT_LOWERCASE
7646         ;;
7647
7648     *)
7649         TOOLKIT_DESC="base only"
7650         ;;
7651 esac
7652
7653 if test "$wxUSE_WINE" = "yes"; then
7654     BAKEFILE_FORCE_PLATFORM=win32
7655 fi
7656
7657 dnl gcc 3.4 has a pch bug which truncates wide character constants in headers.
7658 dnl Hopefully for a non-unicode build there aren't any wide constants in
7659 dnl headers, but for a unicode build it's best to disable pch.
7660 if test "$wxUSE_UNICODE" = yes -a "$GCC" = yes -a "$bk_use_pch" != no
7661 then
7662     AC_CACHE_CHECK(
7663         [for gcc precompiled header bug],
7664         [wx_cv_gcc_pch_bug],
7665         [[
7666             echo '#include <stdio.h>
7667                   const wchar_t test_var[] = L"awidetest";' > conftest.h
7668
7669             echo '#include "conftest.h"
7670                   int main()
7671                   {
7672                      printf("%ls", test_var);
7673                      return 0;
7674                   }' > conftest.cpp
7675
7676             wx_cv_gcc_pch_bug="pch not supported"
7677
7678             if $CXX conftest.h >/dev/null 2>&1
7679             then
7680                 wx_cv_gcc_pch_bug=
7681
7682                 if $CXX -o conftest$PROGRAM_EXT conftest.cpp >/dev/null 2>&1
7683                 then
7684                     if tr -dc '[a-z]' < conftest$PROGRAM_EXT |
7685                         grep awidetest >/dev/null
7686                     then
7687                         wx_cv_gcc_pch_bug=no
7688                     else
7689                         wx_cv_gcc_pch_bug=yes
7690                     fi
7691                 fi
7692             fi
7693
7694             rm -f conftest.h conftest.gch conftest.cpp conftest$PROGRAM_EXT
7695         ]])
7696
7697     if test "$wx_cv_gcc_pch_bug" = yes; then
7698         dnl make the default for pch 'no'
7699         dnl further below check whether the user overrode and warn them
7700         bk_use_pch=no
7701     fi
7702 fi
7703
7704 AC_BAKEFILE([m4_include(autoconf_inc.m4)])
7705
7706 dnl make install path absolute (if not already);
7707 dnl will fail with (some) MSDOS paths
7708 case ${INSTALL} in
7709   /* ) # Absolute
7710      ;;
7711   ?:* ) # Drive letter, considered as absolute.
7712      ;;
7713   *)
7714      INSTALL=`pwd`/${INSTALL} ;;
7715 esac
7716
7717 if test "$wxUSE_GUI" = "yes"; then
7718
7719 if test "$wxUSE_MSW" = 1 ; then
7720     if test "x$WINDRES" = "x"; then
7721         AC_MSG_ERROR([Required windres program not found])
7722     fi
7723
7724     RESCOMP="$WINDRES"
7725 fi
7726
7727 if test "$wxUSE_MAC" = 1 -o "$wxUSE_COCOA" = 1; then
7728     dnl base name of the resource file for wxMac must be the same
7729     dnl as library installation base name (-install_name)
7730     WX_RESOURCES_MACOSX_ASCII="libwx_${TOOLCHAIN_NAME}.${wx_release_number}.r"
7731     WX_RESOURCES_MACOSX_DATA="libwx_${TOOLCHAIN_NAME}.${wx_release_number}.rsrc"
7732
7733     dnl add the resources target for wxMac
7734     LIBWXMACRES="\$(wx_top_builddir)/lib/${WX_RESOURCES_MACOSX_ASCII}"
7735
7736     AC_CHECK_PROG(DEREZ, DeRez, DeRez, /Developer/Tools/DeRez)
7737
7738     MACSETFILE="\$(SETFILE)"
7739
7740     dnl resources are bundled both with shared library and applications
7741     dnl since the carb resource *must* be included in the application
7742     if test "$wxUSE_OSX_CARBON" = 1; then
7743         POSTLINK_COMMAND="\$(REZ) -d __DARWIN__ -t APPL Carbon.r -o"
7744         RESCOMP="$REZ"
7745         WXCONFIG_RESFLAGS="-d __DARWIN__ -t APPL Carbon.r -o"
7746     else
7747         POSTLINK_COMMAND="cat /dev/null | \$(REZ) -d __DARWIN__ -t APPL ${LIBWXMACRES}"
7748         RESCOMP="cat /dev/null \| $REZ"
7749         WXCONFIG_RESFLAGS="-d __DARWIN__ -t APPL \$libdir/$WX_RESOURCES_MACOSX_ASCII"
7750     fi
7751
7752 else
7753     dnl default value is to (silently) do nothing in the makefile
7754     MACSETFILE="@true"
7755
7756     if test "$wxUSE_PM" = 1; then
7757         RESCOMP="emxbind"
7758         WXCONFIG_RESFLAGS="-ep"
7759
7760         dnl Is this one really used anywhere for pm?
7761         POSTLINK_COMMAND="$RESCOMP $WXCONFIG_RESFLAGS"
7762     else
7763         POSTLINK_COMMAND="@true"
7764     fi
7765 fi
7766
7767 fi
7768 dnl wxUSE_GUI = 1
7769
7770
7771 dnl find out if the compiler supports PCH
7772 dnl
7773 dnl TODO: this should be in bakefile
7774 if test $GCC_PCH = 1
7775 then
7776     if test "$wx_cv_gcc_pch_bug" = yes; then
7777         AC_MSG_WARN([*** Precompiled header support is broken on this compiler])
7778         AC_MSG_WARN([*** --enable-precomp-headers is not recommended])
7779         AC_MSG_WARN([*** see http://gcc.gnu.org/bugzilla/show_bug.cgi?id=13361])
7780     fi
7781
7782     # Our WX_PRECOMP flag does not make sense for any language except C++ because
7783     # the headers that benefit from precompilation are mostly C++ headers.
7784     CXXFLAGS="-DWX_PRECOMP $CXXFLAGS"
7785     # When Bakefile can do multi-language PCH (e.g. C++ and Objective-C++) enable this:
7786     #OBJCXXFLAGS="-DWX_PRECOMP $CXXFLAGS"
7787 fi
7788
7789 dnl HACK ALERT!!
7790 dnl For now, we need to alter bk-deps not to generate deps
7791 dnl when we've configured a Universal binary build.
7792 dnl The next version of Bakefile will have the correct fix for this
7793 dnl at which time, this hack can be removed.
7794
7795 if test "$wxUSE_MAC" = 1 ; then
7796     if test "x$wxUSE_UNIVERSAL_BINARY" != "xno" ; then
7797         sed "s/DEPSMODE=gcc/DEPSMODE=none/" < bk-deps > temp
7798         mv temp bk-deps
7799         chmod +x bk-deps
7800     fi
7801 fi
7802
7803 if test "$wxUSE_SHARED" = "yes"; then
7804     dnl Need addtional flag on OS/2, so override bakefiles value
7805     dnl (there currently is no suitable variable to which the
7806     dnl  missing flags could be added, AFAICS. SN, 18.12.2004. )
7807     case "${host}" in
7808       *-pc-os2_emx | *-pc-os2-emx )
7809         SHARED_LD_CC="`pwd`/dllar.sh -name-mangler-script ./dllnames.sh -libf INITINSTANCE -libf TERMINSTANCE -o"
7810         SHARED_LD_CXX="`pwd`/dllar.sh -name-mangler-script ./dllnames.sh -libf INITINSTANCE -libf TERMINSTANCE -o"
7811         cp -p ${srcdir}/src/os2/dllnames.sh .
7812         cp -p ${srcdir}/src/os2/dllar.sh .
7813       ;;
7814     esac
7815 fi
7816 if test "$wxUSE_OMF" = "yes"; then
7817     case "${host}" in
7818       *-pc-os2_emx | *-pc-os2-emx )
7819         LDFLAGS="$LDFLAGS -Zlinker /EXEPACK"
7820         LDFLAGS_GUI="-Zlinker /PMTYPE:PM"
7821         WXCONFIG_LDFLAGS_GUI="-Zlinker /PMTYPE:PM"
7822       ;;
7823     esac
7824 fi
7825
7826 dnl TOOLCHAIN_DEFS should be used for both wx and client code
7827 WXCONFIG_CPPFLAGS="$WXCONFIG_CPPFLAGS $TOOLCHAIN_DEFS"
7828
7829
7830 dnl Sun cc is compatible with gcc and so either of them can use the C
7831 dnl libraries built with the other, i.e. gcc can be used to build wxGTK under
7832 dnl Solaris where GTK+ is compiled using cc and cc can be used under Linux
7833 dnl where GTK+ is built with gcc
7834 dnl
7835 dnl However the compiler options are not compatible at all and in particular
7836 dnl gcc doesn't like cc -mt option and cc doesn't like -pthread. We simply
7837 dnl filter them out as we already have the correct options for multithreaded
7838 dnl programs if we're using threads (and if we don't, it shouldn't matter)
7839 case "${host}" in
7840     *-*-solaris2* )
7841         dnl system packages are compiled with Sun CC and so pkg-config outputs
7842         dnl CC-specific "-mt" flag, remove it when using gcc
7843         if test "$GCC" = yes; then
7844             CPPFLAGS=`echo $CPPFLAGS | sed 's/-mt//'`
7845             LIBS=`echo $LIBS | sed 's/-mt//'`
7846             EXTRALIBS_GUI=`echo $EXTRALIBS_GUI | sed 's/-mt//'`
7847         fi
7848         ;;
7849
7850     *-*-linux* )
7851         dnl OTOH when using Sun CC under Linux, the flags contain gcc-specific
7852         dnl -pthreads which Sun CC doesn't know about
7853         if test "x$SUNCXX" = xyes; then
7854             CPPFLAGS=`echo $CPPFLAGS | sed 's/-pthread//'`
7855             LIBS=`echo $LIBS | sed 's/-pthread//'`
7856             EXTRALIBS_GUI=`echo $EXTRALIBS_GUI | sed 's/-pthread//'`
7857         fi
7858         ;;
7859 esac
7860
7861 dnl Add visibility support flags to CFLAGS/CXXFLAGS - do it this late so that
7862 dnl it doesn't affect compilation checks above
7863 CFLAGS="$CFLAGS $CFLAGS_VISIBILITY"
7864 CXXFLAGS="$CXXFLAGS $CXXFLAGS_VISIBILITY"
7865 OBJCFLAGS="$OBJCFLAGS $CFLAGS_VISIBILITY"
7866 OBJCXXFLAGS="$OBJCXXFLAGS $CXXFLAGS_VISIBILITY"
7867
7868 dnl for convenience, sort the samples in alphabetical order
7869 dnl
7870 dnl FIXME For some mysterious reasons, sometimes the directories are duplicated
7871 dnl       in this list - hence uniq. But normally, this shouldn't be needed!
7872 dnl
7873 dnl       Unfortunately, there is a bug in OS/2's tr, such that
7874 dnl       tr ' ' '\n' introduces DOS-like line breaks, whereas tr '\n' ' '
7875 dnl       only removes the Unix-like part of the introduced line break.
7876 SAMPLES_SUBDIRS="`echo $SAMPLES_SUBDIRS | tr -s ' ' | tr ' ' '\n' | sort | uniq | tr '\n' ' '| tr -d '\r'`"
7877
7878 dnl subtle bakefile goop.
7879 dnl Used in wx-config now too, as its STATIC_FLAG with different makeup.
7880 dnl I wish we would have called it something less likely to clash with
7881 dnl things though.
7882 AC_SUBST(SHARED)
7883
7884 dnl global options
7885 AC_SUBST(WX_LIBRARY_BASENAME_NOGUI)
7886 AC_SUBST(WX_LIBRARY_BASENAME_GUI)
7887
7888 dnl toolkit options
7889 AC_SUBST(USE_GUI)
7890 AC_SUBST(AFMINSTALL)
7891 AC_SUBST(WIN32INSTALL)
7892 AC_SUBST(TOOLKIT)
7893 AC_SUBST(TOOLKIT_DIR)
7894 AC_SUBST(TOOLCHAIN_NAME)
7895 AC_SUBST(TOOLCHAIN_FULLNAME)
7896
7897 dnl wx-config options
7898 AC_SUBST(host_alias)
7899 AC_SUBST(cross_compiling)
7900 AC_SUBST(WIDGET_SET)
7901 AC_SUBST(WX_RELEASE)
7902 AC_SUBST(WX_VERSION)
7903 AC_SUBST(WX_SUBVERSION)
7904 AC_SUBST(WX_CHARTYPE)
7905 AC_SUBST(WX_DEBUGTYPE)
7906
7907 dnl note that in addition to the usual CPP/C/CXXFLAGS which are used for
7908 dnl building the library itself, we also have WXCONFIG_-prefixed variants which
7909 dnl are used when building the libraries using the library
7910 dnl
7911 dnl so put anything which should be used only during the library build in, e.g.
7912 dnl CXXFLAGS, but put everything else (by default) into WXCONFIG_CXXFLAGS
7913 dnl
7914 dnl and, finally, for some things which should be only used by wx-config but
7915 dnl not during the library compilation, use WXCONFIG_ONLY_CPPFLAGS which is
7916 dnl added to WXCONFIG_CPPFLAGS after adding the latter to CPPFLAGS
7917 AC_SUBST(WXCONFIG_CPPFLAGS)
7918 AC_SUBST(WXCONFIG_CFLAGS)
7919 AC_SUBST(WXCONFIG_CXXFLAGS)
7920
7921 AC_SUBST(WXCONFIG_LIBS)
7922 AC_SUBST(WXCONFIG_RPATH)
7923 AC_SUBST(WXCONFIG_LDFLAGS_GUI)
7924 AC_SUBST(WXCONFIG_RESFLAGS)
7925
7926 dnl distribution vars
7927 AC_SUBST(GUIDIST)
7928 AC_SUBST(DISTDIR)
7929
7930 dnl additional subdirectories where we will build
7931 AC_SUBST(SAMPLES_SUBDIRS)
7932
7933 dnl additional libraries and linker settings
7934 AC_SUBST(LDFLAGS)
7935 AC_SUBST(LDFLAGS_GL)
7936 AC_SUBST(OPENGL_LIBS)
7937 AC_SUBST(DMALLOC_LIBS)
7938 AC_SUBST(WX_VERSION_TAG)
7939
7940 dnl additional resurces settings
7941 AC_SUBST(RESCOMP)
7942 AC_SUBST(WINDRES)
7943 AC_SUBST(REZ)
7944 AC_SUBST(RESFLAGS)
7945 AC_SUBST(RESPROGRAMOBJ)
7946 AC_SUBST(WX_RESOURCES_MACOSX_ASCII)
7947 AC_SUBST(WX_RESOURCES_MACOSX_DATA)
7948
7949 dnl additional for Mac OS X
7950 AC_SUBST(DEREZ)
7951 AC_SUBST(LIBWXMACRES)
7952 AC_SUBST(POSTLINK_COMMAND)
7953 AC_SUBST(MACSETFILE)
7954
7955 dnl other tools
7956 AC_SUBST(GCC)
7957 AC_SUBST(DLLTOOL)
7958
7959
7960 dnl MAKE_SET will be replaced with "MAKE=..." or nothing if make sets MAKE
7961 dnl itself (this macro is required if SUBDIRS variable is used in Makefile.am
7962 dnl - and we do use it)
7963 AC_PROG_MAKE_SET
7964
7965
7966 AC_CONFIG_HEADERS([lib/wx/include/${TOOLCHAIN_FULLNAME}/wx/setup.h:setup.h.in])
7967
7968 if test "$USE_WIN32" = 1; then
7969     AC_CONFIG_COMMANDS(
7970         [
7971             rcdefs.h
7972         ],
7973         [
7974             mkdir -p $outdir &&
7975             $CPP $infile | sed 's/^# *[1-9].*//;s/^ *//;/./,/^$/!d' > $outdir/rcdefs.h
7976         ],
7977         [
7978             CPP="$CPP"
7979             infile="$srcdir/include/wx/msw/genrcdefs.h"
7980             outdir="lib/wx/include/$TOOLCHAIN_FULLNAME/wx/msw"
7981         ]
7982     )
7983 fi
7984
7985 AC_CONFIG_FILES([ lib/wx/config/${TOOLCHAIN_FULLNAME}:wx-config.in ],
7986                 [ chmod +x lib/wx/config/${TOOLCHAIN_FULLNAME} ],
7987                 [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}" ])
7988
7989 AC_CONFIG_FILES([ lib/wx/config/inplace-${TOOLCHAIN_FULLNAME}:wx-config-inplace.in ],
7990                 [ chmod +x lib/wx/config/inplace-${TOOLCHAIN_FULLNAME} ],
7991                 [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}" ])
7992
7993 dnl this is used to run ifacecheck with the same flags used by the compiler
7994 dnl for the real compilation:
7995 AC_CONFIG_FILES([ utils/ifacecheck/rungccxml.sh ],
7996                 [ chmod +x utils/ifacecheck/rungccxml.sh ])
7997
7998 if test "$wx_cv_version_script" = "yes"; then
7999     AC_CONFIG_FILES(version-script)
8000 fi
8001 AC_CONFIG_FILES(Makefile)
8002
8003 AC_CONFIG_COMMANDS([wx-config],
8004                    [ rm -f wx-config
8005                      ${LN_S} lib/wx/config/inplace-${TOOLCHAIN_FULLNAME} wx-config
8006                    ],
8007                    [ TOOLCHAIN_FULLNAME="${TOOLCHAIN_FULLNAME}"
8008                      LN_S="${LN_S}"
8009                    ])
8010
8011 dnl This would give us us build dir that in every significant way
8012 dnl resembles an installed wx in prefix=$builddir.  It is troublesome
8013 dnl though in this form because AC_CONFIG_LINKS will fail for directories
8014 dnl on platforms that do not have symlinks.
8015 dnl AC_CONFIG_LINKS([ include/wx-$WX_RELEASE$WX_FLAVOUR:include ])
8016
8017 if test "$wxWITH_SUBDIRS" != "no"; then
8018 dnl Configure samples, demos etc. directories, but only if they are present:
8019 if test "$wxUSE_GUI" = "yes"; then
8020     SUBDIRS="samples demos utils"
8021 else
8022     dnl we build wxBase only
8023     dnl there are no wxBase programs in demos
8024     SUBDIRS="samples utils"
8025 fi
8026 dnl Add tests to the list of subdirs if cppunit 1.8.0+ is detected
8027 AM_PATH_CPPUNIT(1.8.0, [SUBDIRS="$SUBDIRS tests"])
8028
8029 for subdir in $SUBDIRS; do
8030     if test -d ${srcdir}/${subdir} ; then
8031         if test "$wxUSE_GUI" = "yes"; then
8032             if test ${subdir} = "samples"; then
8033                 dnl only take those samples which compile in the current
8034                 dnl configuration and which exist
8035                 makefiles="samples/Makefile.in $makefiles"
8036                 for sample in $SAMPLES_SUBDIRS; do
8037                     if test -d $srcdir/samples/$sample; then
8038                         makefiles="samples/$sample/Makefile.in $makefiles"
8039                     fi
8040                 done
8041             else
8042                 dnl assume that everything compiles for utils &c
8043                 dnl any that shouldn't be built can be added to
8044                 dnl DISABLED_UTILS, DISABLED_DEMOS
8045                 disabled_var=DISABLED_`echo $subdir | tr '[[a-z]]' '[[A-Z]]'`
8046                 eval "disabled=\$$disabled_var"
8047                 disabled=/`echo X $disabled | sed 's@ @/|/@g'`/
8048                 makefiles=`(cd $srcdir ; find $subdir -name Makefile.in) | $EGREP -v "$disabled"`
8049             fi
8050         else
8051             dnl we build wxBase only
8052             dnl don't take all samples/utils, just those which build with wxBase
8053             if test ${subdir} = "samples"; then
8054                 dnl only take those samples which compile in the current
8055                 dnl configuration and which exist
8056                 makefiles="samples/Makefile.in $makefiles"
8057                 for sample in `echo $SAMPLES_SUBDIRS`; do
8058                     if test -d $srcdir/samples/$sample; then
8059                         makefiles="samples/$sample/Makefile.in $makefiles"
8060                     fi
8061                 done
8062             elif test ${subdir} = "utils"; then
8063                 makefiles=""
8064                 for util in ifacecheck ; do
8065                     if test -d $srcdir/utils/$util ; then
8066                         makefiles="utils/$util/src/Makefile.in \
8067                                    $makefiles"
8068                     fi
8069                 done
8070             else
8071                 dnl assume that everything compiles for tests
8072                 makefiles=`(cd $srcdir ; find $subdir -name Makefile.in)`
8073             fi
8074         fi
8075
8076         for mkin in $makefiles ; do
8077             mk=`echo $mkin | sed 's/Makefile\.in/Makefile/g'`
8078             AC_CONFIG_FILES([$mk])
8079         done
8080     fi
8081 done
8082 fi dnl wxWITH_SUBDIRS
8083
8084 AC_OUTPUT
8085
8086 dnl report how we have been configured
8087 echo
8088 echo "Configured wxWidgets ${WX_VERSION} for \`${host}'"
8089 echo ""
8090 echo "  Which GUI toolkit should wxWidgets use?                 ${TOOLKIT_DESC}"
8091 echo "  Should wxWidgets be compiled into single library?       ${wxUSE_MONOLITHIC:-yes}"
8092
8093 echo "  Should wxWidgets be compiled in debug mode?             ${wxUSE_DEBUG:-no}"
8094 echo "  Should wxWidgets be linked as a shared library?         ${wxUSE_SHARED:-no}"
8095 echo $ECHO_N "  Should wxWidgets support Unicode?                       ${wxUSE_UNICODE:-no}$ECHO_C"
8096 if test "$wxUSE_UNICODE" = "yes"; then
8097     if test "$wxUSE_UNICODE_UTF8" = "yes"; then
8098         echo " (using UTF-8)"
8099     else
8100         echo " (using wchar_t)"
8101     fi
8102 else
8103     echo
8104 fi
8105
8106 echo "  What level of wxWidgets compatibility should be enabled?"
8107 echo "                                       wxWidgets 2.6      ${WXWIN_COMPATIBILITY_2_6:-no}"
8108 echo "                                       wxWidgets 2.8      ${WXWIN_COMPATIBILITY_2_8:-yes}"
8109
8110 echo "  Which libraries should wxWidgets use?"
8111 echo "                                       STL                ${wxUSE_STL}"
8112 echo "                                       jpeg               ${wxUSE_LIBJPEG-none}"
8113 echo "                                       png                ${wxUSE_LIBPNG-none}"
8114 echo "                                       regex              ${wxUSE_REGEX}"
8115 echo "                                       tiff               ${wxUSE_LIBTIFF-none}"
8116 if test "$wxUSE_X11" = 1 -o "$wxUSE_MOTIF" = 1; then
8117 echo "                                       xpm                ${wxUSE_LIBXPM-none}"
8118 fi
8119 echo "                                       zlib               ${wxUSE_ZLIB}"
8120 echo "                                       expat              ${wxUSE_EXPAT}"
8121 echo "                                       libmspack          ${wxUSE_LIBMSPACK}"
8122 echo "                                       sdl                ${wxUSE_LIBSDL}"
8123
8124 echo ""
8125
8126 dnl vi: set et sts=4 sw=4 com=\:dnl: