src/cocoa/choice.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        cocoa/choice.mm
   3 // Purpose:     wxChoice
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2003/03/16
   7 // RCS-ID:      $Id:
   8 // Copyright:   (c) 2003 David Elliott
   9 // Licence:     wxWindows license
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/log.h"
  15     #include "wx/app.h"
  16     #include "wx/choice.h"
  17     #include "wx/arrstr.h"
  18 #endif //WX_PRECOMP
  19
  20 #include "wx/cocoa/string.h"
  21
  22 #import <AppKit/NSPopUpButton.h>
  23 #import <AppKit/NSMenu.h>
  24 #import <Foundation/NSNotification.h>
  25 #import <Foundation/NSDictionary.h>
  26
  27 IMPLEMENT_DYNAMIC_CLASS(wxChoice, wxControl)
  28 BEGIN_EVENT_TABLE(wxChoice, wxChoiceBase)
  29 END_EVENT_TABLE()
  30 // WX_IMPLEMENT_COCOA_OWNER(wxChoice,NSButton,NSControl,NSView)
  31
  32 void wxChoice::Init()
  33 {
  34     m_sortedStrings = NULL;
  35 }
  36
  37 bool wxChoice::Create(wxWindow *parent, wxWindowID winid,
  38             const wxPoint& pos,
  39             const wxSize& size,
  40             const wxArrayString& choices,
  41             long style,
  42             const wxValidator& validator,
  43             const wxString& name)
  44 {
  45     wxCArrayString chs(choices);
  46
  47     return Create(parent, winid, pos, size, chs.GetCount(), chs.GetStrings(),
  48                   style, validator, name);
  49 }
  50
  51 bool wxChoice::Create(wxWindow *parent, wxWindowID winid,
  52             const wxPoint& pos,
  53             const wxSize& size,
  54             int n, const wxString choices[],
  55             long style,
  56             const wxValidator& validator,
  57             const wxString& name)
  58 {
  59     if(!CreateControl(parent,winid,pos,size,style,validator,name))
  60         return false;
  61
  62     SetNSView([[NSPopUpButton alloc] initWithFrame:MakeDefaultNSRect(size)
  63         pullsDown: NO]);
  64     [m_cocoaNSView release];
  65
  66     NSMenu *nsmenu = [(NSPopUpButton*)m_cocoaNSView menu];
  67     AssociateNSMenu(nsmenu, OBSERVE_DidSendAction);
  68
  69     if(style&wxCB_SORT)
  70     {
  71         m_sortedStrings = new wxSortedArrayString;
  72         for(int i=0; i<n; i++)
  73         {
  74             m_sortedStrings->Add(choices[i]);
  75         }
  76         for(size_t i=0; i < m_sortedStrings->GetCount(); i++)
  77         {
  78             [nsmenu addItemWithTitle:wxNSStringWithWxString(
  79                     m_sortedStrings->Item(i))
  80                 action: nil keyEquivalent:@""];
  81         }
  82     }
  83     else
  84     {
  85         for(int i=0; i<n; i++)
  86         {
  87             [nsmenu addItemWithTitle:wxNSStringWithWxString(choices[i])
  88                 action: nil keyEquivalent:@""];
  89         }
  90     }
  91     m_itemsClientData.SetCount(n);
  92
  93     [(NSPopUpButton*)m_cocoaNSView sizeToFit];
  94     if(m_parent)
  95         m_parent->CocoaAddChild(this);
  96     SetInitialFrameRect(pos,size);
  97
  98     return true;
  99 }
 100
 101 wxChoice::~wxChoice()
 102 {
 103     DisassociateNSMenu([(NSPopUpButton*)m_cocoaNSView menu]);
 104
 105     if(m_sortedStrings)
 106         m_sortedStrings->Clear();
 107     delete m_sortedStrings;
 108
 109     if(HasClientObjectData())
 110     {
 111         for(size_t i=0; i < m_itemsClientData.GetCount(); i++)
 112             delete (wxClientData*)m_itemsClientData.Item(i);
 113     }
 114     m_itemsClientData.Clear();
 115
 116     CocoaRemoveFromParent();
 117 }
 118
 119 void wxChoice::CocoaNotification_menuDidSendAction(WX_NSNotification notification)
 120 {
 121     NSDictionary *userInfo = [notification userInfo];
 122     NSMenuItem *menuitem = [userInfo objectForKey:@"MenuItem"];
 123     int index = [[(NSPopUpButton*)m_cocoaNSView menu] indexOfItem: menuitem];
 124     int selectedItem = [(NSPopUpButton*)m_cocoaNSView indexOfSelectedItem];
 125     wxLogDebug(wxT("menuDidSendAction, index=%d, selectedItem=%d"), index, selectedItem);
 126     wxCommandEvent event(wxEVT_COMMAND_CHOICE_SELECTED, m_windowId);
 127     event.SetInt(index);
 128     event.SetEventObject(this);
 129     event.SetString(GetStringSelection());
 130     GetEventHandler()->ProcessEvent(event);
 131 }
 132
 133 void wxChoice::Clear()
 134 {
 135     if(m_sortedStrings)
 136         m_sortedStrings->Clear();
 137     if(HasClientObjectData())
 138     {
 139         for(size_t i=0; i < m_itemsClientData.GetCount(); i++)
 140             delete (wxClientData*)m_itemsClientData.Item(i);
 141     }
 142     m_itemsClientData.Clear();
 143     [(NSPopUpButton*)m_cocoaNSView removeAllItems];
 144 }
 145
 146 void wxChoice::Delete(int n)
 147 {
 148     if(m_sortedStrings)
 149         m_sortedStrings->RemoveAt(n);
 150     if(HasClientObjectData())
 151         delete (wxClientData*)m_itemsClientData.Item(n);
 152     m_itemsClientData.RemoveAt(n);
 153     [(NSPopUpButton*)m_cocoaNSView removeItemAtIndex:n];
 154 }
 155
 156 int wxChoice::GetCount() const
 157 {
 158     return [(NSPopUpButton*)m_cocoaNSView numberOfItems];
 159 }
 160
 161 wxString wxChoice::GetString(int n) const
 162 {
 163     return wxStringWithNSString([(NSPopUpButton*)m_cocoaNSView itemTitleAtIndex:n]);
 164 }
 165
 166 void wxChoice::SetString(int n, const wxString& title)
 167 {
 168     NSMenuItem *item = [(NSPopUpButton*)m_cocoaNSView itemAtIndex:n];
 169     [item setTitle:wxNSStringWithWxString(title)];
 170 }
 171
 172 int wxChoice::FindString(const wxString& title) const
 173 {
 174     return [(NSPopUpButton*)m_cocoaNSView indexOfItemWithTitle:
 175         wxNSStringWithWxString(title)];
 176 }
 177
 178 int wxChoice::GetSelection() const
 179 {
 180     return [(NSPopUpButton*)m_cocoaNSView indexOfSelectedItem];
 181 }
 182
 183 int wxChoice::DoAppend(const wxString& title)
 184 {
 185     NSMenu *nsmenu = [(NSPopUpButton*)m_cocoaNSView menu];
 186     NSMenuItem *item;
 187     if(m_sortedStrings)
 188     {
 189         int sortedIndex = m_sortedStrings->Add(title);
 190         item = [nsmenu insertItemWithTitle:
 191                 wxNSStringWithWxString(title)
 192             action: nil keyEquivalent:@"" atIndex:sortedIndex];
 193         m_itemsClientData.Insert(NULL, sortedIndex);
 194     }
 195     else
 196     {
 197         item = [nsmenu addItemWithTitle:wxNSStringWithWxString(title)
 198             action: nil keyEquivalent:@""];
 199         m_itemsClientData.Add(NULL);
 200     }
 201     return [nsmenu indexOfItem:item];
 202 }
 203
 204 int wxChoice::DoInsert(const wxString& title, int pos)
 205 {
 206     if(m_sortedStrings)
 207         return DoAppend(title);
 208     NSMenu *nsmenu = [(NSPopUpButton*)m_cocoaNSView menu];
 209     NSMenuItem *item = [nsmenu insertItemWithTitle:wxNSStringWithWxString(title)
 210         action: nil keyEquivalent:@"" atIndex:pos];
 211     m_itemsClientData.Insert(NULL, pos);
 212     return [nsmenu indexOfItem:item];
 213 }
 214
 215 void wxChoice::DoSetItemClientData(int n, void *data)
 216 {
 217     m_itemsClientData.Item(n) = data;
 218 }
 219
 220 void* wxChoice::DoGetItemClientData(int n) const
 221 {
 222     return m_itemsClientData.Item(n);
 223 }
 224
 225 void wxChoice::DoSetItemClientObject(int n, wxClientData *data)
 226 {
 227     m_itemsClientData.Item(n) = data;
 228 }
 229
 230 wxClientData* wxChoice::DoGetItemClientObject(int n) const
 231 {
 232     return (wxClientData*)m_itemsClientData.Item(n);
 233 }
 234
 235 void wxChoice::SetSelection(int n)
 236 {
 237     [(NSPopUpButton*)m_cocoaNSView selectItemAtIndex:n];
 238 }
 239