src/osx/cocoa/combobox.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/combobox.mm
   3 // Purpose:     wxChoice
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_COMBOBOX
  15
  16 #include "wx/combobox.h"
  17 #include "wx/evtloop.h"
  18
  19 #ifndef WX_PRECOMP
  20     #include "wx/menu.h"
  21     #include "wx/dcclient.h"
  22 #endif
  23
  24 #include "wx/osx/cocoa/private/textimpl.h"
  25
  26 // work in progress
  27
  28 @interface wxNSTableDataSource : NSObject wxOSX_10_6_AND_LATER(<NSComboBoxDataSource>)
  29 {
  30     wxNSComboBoxControl* impl;
  31 }
  32
  33 - (NSInteger)numberOfItemsInComboBox:(NSComboBox *)aComboBox;
  34 - (id)comboBox:(NSComboBox *)aComboBox objectValueForItemAtIndex:(NSInteger)index;
  35
  36 @end
  37
  38
  39 @implementation wxNSComboBox
  40
  41 + (void)initialize
  42 {
  43     static BOOL initialized = NO;
  44     if (!initialized)
  45     {
  46         initialized = YES;
  47         wxOSXCocoaClassAddWXMethods( self );
  48     }
  49 }
  50
  51 - (void) dealloc
  52 {
  53     [fieldEditor release];
  54     [super dealloc];
  55 }
  56
  57 // Over-riding NSComboBox onKeyDown method doesn't work for key events.
  58 // Ensure that we can use our own wxNSTextFieldEditor to catch key events.
  59 // See windowWillReturnFieldEditor in nonownedwnd.mm.
  60 // Key events will be caught and handled via wxNSTextFieldEditor onkey...
  61 // methods in textctrl.mm.
  62
  63 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
  64 {
  65     if ( editor != fieldEditor )
  66     {
  67         [editor retain];
  68         [fieldEditor release];
  69         fieldEditor = editor;
  70     }
  71 }
  72
  73 - (wxNSTextFieldEditor*) fieldEditor
  74 {
  75     return fieldEditor;
  76 }
  77
  78 - (void)controlTextDidChange:(NSNotification *)aNotification
  79 {
  80     wxUnusedVar(aNotification);
  81     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  82     if ( impl && impl->ShouldSendEvents() )
  83     {
  84         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
  85         if ( wxpeer ) {
  86             wxCommandEvent event(wxEVT_TEXT, wxpeer->GetId());
  87             event.SetEventObject( wxpeer );
  88             event.SetString( static_cast<wxComboBox*>(wxpeer)->GetValue() );
  89             wxpeer->HandleWindowEvent( event );
  90         }
  91     }
  92 }
  93
  94 - (void)comboBoxSelectionDidChange:(NSNotification *)notification
  95 {
  96     wxUnusedVar(notification);
  97     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
  98     if ( impl && impl->ShouldSendEvents())
  99     {
 100         wxComboBox* wxpeer = static_cast<wxComboBox*>(impl->GetWXPeer());
 101         if ( wxpeer ) {
 102             const int sel = wxpeer->GetSelection();
 103
 104             wxCommandEvent event(wxEVT_COMBOBOX, wxpeer->GetId());
 105             event.SetEventObject( wxpeer );
 106             event.SetInt( sel );
 107             event.SetString( wxpeer->GetString(sel) );
 108             // For some reason, wxComboBox::GetValue will not return the newly selected item
 109             // while we're inside this callback, so use AddPendingEvent to make sure
 110             // GetValue() returns the right value.
 111
 112             wxpeer->GetEventHandler()->AddPendingEvent( event );
 113
 114         }
 115     }
 116 }
 117 @end
 118
 119 wxNSComboBoxControl::wxNSComboBoxControl( wxComboBox *wxPeer, WXWidget w )
 120     : wxNSTextFieldControl(wxPeer, wxPeer, w)
 121 {
 122     m_comboBox = (NSComboBox*)w;
 123 }
 124
 125 wxNSComboBoxControl::~wxNSComboBoxControl()
 126 {
 127 }
 128
 129 void wxNSComboBoxControl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 130 {
 131     // NSComboBox has its own event loop, which reacts very badly to our synthetic
 132     // events used to signal when a wxEvent is posted, so during that time we switch
 133     // the wxEventLoop::WakeUp implementation to a lower-level version
 134
 135     bool reset = false;
 136     wxEventLoop* const loop = (wxEventLoop*) wxEventLoopBase::GetActive();
 137
 138     if ( loop != NULL && [event type] == NSLeftMouseDown )
 139     {
 140         reset = true;
 141         loop->OSXUseLowLevelWakeup(true);
 142     }
 143
 144     wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 145     superimpl(slf, (SEL)_cmd, event);
 146
 147     if ( reset )
 148     {
 149         loop->OSXUseLowLevelWakeup(true);
 150     }
 151 }
 152
 153 int wxNSComboBoxControl::GetSelectedItem() const
 154 {
 155     return [m_comboBox indexOfSelectedItem];
 156 }
 157
 158 void wxNSComboBoxControl::SetSelectedItem(int item)
 159 {
 160     SendEvents(false);
 161
 162     if ( item != wxNOT_FOUND )
 163     {
 164         wxASSERT_MSG( item >= 0 && item < [m_comboBox numberOfItems],
 165                       "Inavlid item index." );
 166         [m_comboBox selectItemAtIndex: item];
 167     }
 168     else // remove current selection (if we have any)
 169     {
 170         const int sel = GetSelectedItem();
 171         if ( sel != wxNOT_FOUND )
 172             [m_comboBox deselectItemAtIndex:sel];
 173     }
 174
 175     SendEvents(true);
 176 }
 177
 178 int wxNSComboBoxControl::GetNumberOfItems() const
 179 {
 180     return [m_comboBox numberOfItems];
 181 }
 182
 183 void wxNSComboBoxControl::InsertItem(int pos, const wxString& item)
 184 {
 185     [m_comboBox insertItemWithObjectValue:wxCFStringRef( item , m_wxPeer->GetFont().GetEncoding() ).AsNSString() atIndex:pos];
 186 }
 187
 188 void wxNSComboBoxControl::RemoveItem(int pos)
 189 {
 190     SendEvents(false);
 191     [m_comboBox removeItemAtIndex:pos];
 192     SendEvents(true);
 193 }
 194
 195 void wxNSComboBoxControl::Clear()
 196 {
 197     SendEvents(false);
 198     [m_comboBox removeAllItems];
 199     [m_comboBox setStringValue:@""];
 200     SendEvents(true);
 201 }
 202
 203 wxString wxNSComboBoxControl::GetStringAtIndex(int pos) const
 204 {
 205     return wxCFStringRef::AsString([m_comboBox itemObjectValueAtIndex:pos], m_wxPeer->GetFont().GetEncoding());
 206 }
 207
 208 int wxNSComboBoxControl::FindString(const wxString& text) const
 209 {
 210     NSInteger nsresult = [m_comboBox indexOfItemWithObjectValue:wxCFStringRef( text , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 211
 212     int result;
 213     if (nsresult == NSNotFound)
 214         result = wxNOT_FOUND;
 215     else
 216         result = (int) nsresult;
 217     return result;
 218 }
 219
 220 void wxNSComboBoxControl::Popup()
 221 {
 222     id ax = NSAccessibilityUnignoredDescendant(m_comboBox);
 223     [ax accessibilitySetValue: [NSNumber numberWithBool: YES] forAttribute: NSAccessibilityExpandedAttribute];
 224 }
 225
 226 void wxNSComboBoxControl::Dismiss()
 227 {
 228     id ax = NSAccessibilityUnignoredDescendant(m_comboBox);
 229     [ax accessibilitySetValue: [NSNumber numberWithBool: NO] forAttribute: NSAccessibilityExpandedAttribute];
 230 }
 231
 232 void wxNSComboBoxControl::SetEditable(bool editable)
 233 {
 234     // TODO: unfortunately this does not work, setEditable just means the same as CB_READONLY
 235     // I don't see a way to access the text field directly
 236
 237     // Behavior NONE <- SELECTECTABLE
 238     [m_comboBox setEditable:editable];
 239 }
 240
 241 wxWidgetImplType* wxWidgetImpl::CreateComboBox( wxComboBox* wxpeer,
 242                                     wxWindowMac* WXUNUSED(parent),
 243                                     wxWindowID WXUNUSED(id),
 244                                     wxMenu* WXUNUSED(menu),
 245                                     const wxPoint& pos,
 246                                     const wxSize& size,
 247                                     long style,
 248                                     long WXUNUSED(extraStyle))
 249 {
 250     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 251     wxNSComboBox* v = [[wxNSComboBox alloc] initWithFrame:r];
 252     if (style & wxCB_READONLY)
 253         [v setEditable:NO];
 254     wxNSComboBoxControl* c = new wxNSComboBoxControl( wxpeer, v );
 255     return c;
 256 }
 257
 258 wxSize wxComboBox::DoGetBestSize() const
 259 {
 260     int lbWidth = GetCount() > 0 ? 20 : 100;  // some defaults
 261     wxSize baseSize = wxWindow::DoGetBestSize();
 262     int lbHeight = baseSize.y;
 263     int wLine;
 264
 265     {
 266         wxClientDC dc(const_cast<wxComboBox*>(this));
 267
 268         // Find the widest line
 269         for(unsigned int i = 0; i < GetCount(); i++)
 270         {
 271             wxString str(GetString(i));
 272
 273             wxCoord width, height ;
 274             dc.GetTextExtent( str , &width, &height);
 275             wLine = width ;
 276
 277             lbWidth = wxMax( lbWidth, wLine ) ;
 278         }
 279
 280         // Add room for the popup arrow
 281         lbWidth += 2 * lbHeight ;
 282     }
 283
 284     return wxSize( lbWidth, lbHeight );
 285 }
 286
 287 #endif // wxUSE_COMBOBOX