Settings.mm

   1 /* WinterBoard - Theme Manager for the iPhone
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /*
   6  *        Redistribution and use in source and binary
   7  * forms, with or without modification, are permitted
   8  * provided that the following conditions are met:
   9  *
  10  * 1. Redistributions of source code must retain the
  11  *    above copyright notice, this list of conditions
  12  *    and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the
  14  *    above copyright notice, this list of conditions
  15  *    and the following disclaimer in the documentation
  16  *    and/or other materials provided with the
  17  *    distribution.
  18  * 3. The name of the author may not be used to endorse
  19  *    or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  23  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  24  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  25  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  27  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  29  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  30  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  31  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  32  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  33  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  34  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  35  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  36 */
  37
  38 #import <Foundation/Foundation.h>
  39 #import <UIKit/UIKit.h>
  40 #import <Preferences/PSRootController.h>
  41 #import <Preferences/PSViewController.h>
  42 #import <Preferences/PSListController.h>
  43 #import <Preferences/PSSpecifier.h>
  44 #import <Preferences/PSTableCell.h>
  45 #import <UIKit/UINavigationButton.h>
  46
  47 #include <dlfcn.h>
  48 #include <objc/runtime.h>
  49
  50 static BOOL (*IsIconHiddenDisplayId)(NSString *);
  51 static BOOL (*HideIconViaDisplayId)(NSString *);
  52 static BOOL (*UnHideIconViaDisplayId)(NSString *);
  53
  54 static const NSString *WinterBoardDisplayID = @"com.saurik.WinterBoard";
  55
  56 extern NSString *PSTableCellKey;
  57 extern "C" UIImage *_UIImageWithName(NSString *);
  58
  59 static UIImage *checkImage;
  60 static UIImage *uncheckedImage;
  61
  62 static BOOL settingsChanged;
  63 static NSMutableDictionary *_settings;
  64 static NSString *_plist;
  65
  66 /* [NSObject yieldToSelector:(withObject:)] {{{*/
  67 @interface NSObject (wb$yieldToSelector)
  68 - (id) wb$yieldToSelector:(SEL)selector withObject:(id)object;
  69 - (id) wb$yieldToSelector:(SEL)selector;
  70 @end
  71
  72 @implementation NSObject (Cydia)
  73
  74 - (void) wb$doNothing {
  75 }
  76
  77 - (void) wb$_yieldToContext:(NSMutableArray *)context {
  78     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
  79
  80     SEL selector(reinterpret_cast<SEL>([[context objectAtIndex:0] pointerValue]));
  81     id object([[context objectAtIndex:1] nonretainedObjectValue]);
  82     volatile bool &stopped(*reinterpret_cast<bool *>([[context objectAtIndex:2] pointerValue]));
  83
  84     /* XXX: deal with exceptions */
  85     id value([self performSelector:selector withObject:object]);
  86
  87     NSMethodSignature *signature([self methodSignatureForSelector:selector]);
  88     [context removeAllObjects];
  89     if ([signature methodReturnLength] != 0 && value != nil)
  90         [context addObject:value];
  91
  92     stopped = true;
  93
  94     [self
  95         performSelectorOnMainThread:@selector(wb$doNothing)
  96         withObject:nil
  97         waitUntilDone:NO
  98     ];
  99
 100     [pool release];
 101 }
 102
 103 - (id) wb$yieldToSelector:(SEL)selector withObject:(id)object {
 104     /*return [self performSelector:selector withObject:object];*/
 105
 106     volatile bool stopped(false);
 107
 108     NSMutableArray *context([NSMutableArray arrayWithObjects:
 109         [NSValue valueWithPointer:selector],
 110         [NSValue valueWithNonretainedObject:object],
 111         [NSValue valueWithPointer:const_cast<bool *>(&stopped)],
 112     nil]);
 113
 114     NSThread *thread([[[NSThread alloc]
 115         initWithTarget:self
 116         selector:@selector(wb$_yieldToContext:)
 117         object:context
 118     ] autorelease]);
 119
 120     [thread start];
 121
 122     NSRunLoop *loop([NSRunLoop currentRunLoop]);
 123     NSDate *future([NSDate distantFuture]);
 124
 125     while (!stopped && [loop runMode:NSDefaultRunLoopMode beforeDate:future]);
 126
 127     return [context count] == 0 ? nil : [context objectAtIndex:0];
 128 }
 129
 130 - (id) wb$yieldToSelector:(SEL)selector {
 131     return [self wb$yieldToSelector:selector withObject:nil];
 132 }
 133
 134 @end
 135 /* }}} */
 136
 137 /* Theme Settings Controller {{{ */
 138 @interface WBSThemesController: PSViewController <UITableViewDelegate, UITableViewDataSource> {
 139     UITableView *_tableView;
 140     NSMutableArray *_themes;
 141 }
 142
 143 @property (nonatomic, retain) NSMutableArray *themes;
 144
 145 + (void) load;
 146
 147 - (id) initForContentSize:(CGSize)size;
 148 - (id) view;
 149 - (id) navigationTitle;
 150 - (void) themesChanged;
 151
 152 - (int) numberOfSectionsInTableView:(UITableView *)tableView;
 153 - (id) tableView:(UITableView *)tableView titleForHeaderInSection:(int)section;
 154 - (int) tableView:(UITableView *)tableView numberOfRowsInSection:(int)section;
 155 - (id) tableView:(UITableView *)tableView cellForRowAtIndexPath:(NSIndexPath *)indexPath;
 156 - (void) tableView:(UITableView *)tableView didSelectRowAtIndexPath:(NSIndexPath *)indexPath;
 157 - (void) tableView:(UITableView *)tableView moveRowAtIndexPath:(NSIndexPath *)fromIndexPath toIndexPath:(NSIndexPath *)toIndexPath;
 158 - (UITableViewCellEditingStyle) tableView:(UITableView *)tableView editingStyleForRowAtIndexPath:(NSIndexPath *)indexPath;
 159 - (BOOL) tableView:(UITableView *)tableView shouldIndentWhileEditingRowAtIndexPath:(NSIndexPath *)indexPath;
 160 - (BOOL) tableView:(UITableView *)tableView canMoveRowAtIndexPath:(NSIndexPath *)indexPath;
 161
 162 @end
 163
 164 @implementation WBSThemesController
 165
 166 @synthesize themes = _themes;
 167
 168 + (void) load {
 169     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
 170     checkImage = [_UIImageWithName(@"UIPreferencesBlueCheck.png") retain];
 171     uncheckedImage = [[UIImage imageWithContentsOfFile:@"/System/Library/PreferenceBundles/WinterBoardSettings.bundle/SearchResultsCheckmarkClear.png"] retain];
 172     [pool release];
 173 }
 174
 175 - (id) initForContentSize:(CGSize)size {
 176     if ((self = [super initForContentSize:size]) != nil) {
 177         self.themes = [_settings objectForKey:@"Themes"];
 178         if (!_themes) {
 179             if (NSString *theme = [_settings objectForKey:@"Theme"]) {
 180                 self.themes = [NSMutableArray arrayWithObject:
 181                          [NSMutableDictionary dictionaryWithObjectsAndKeys:
 182                                             theme, @"Name",
 183                                 [NSNumber numberWithBool:YES], @"Active", nil]];
 184                 [_settings removeObjectForKey:@"Theme"];
 185             }
 186             if (!_themes)
 187                 self.themes = [NSMutableArray array];
 188             [_settings setObject:_themes forKey:@"Themes"];
 189         }
 190
 191         NSMutableArray *themesOnDisk([NSMutableArray array]);
 192
 193         [themesOnDisk
 194             addObjectsFromArray:[[NSFileManager defaultManager]
 195             contentsOfDirectoryAtPath:@"/Library/Themes" error:NULL]
 196         ];
 197
 198         [themesOnDisk addObjectsFromArray:[[NSFileManager defaultManager]
 199             contentsOfDirectoryAtPath:[NSString stringWithFormat:@"%@/Library/SummerBoard/Themes", NSHomeDirectory()]
 200             error:NULL
 201         ]];
 202
 203         for (int i = 0, count = [themesOnDisk count]; i < count; i++) {
 204             NSString *theme = [themesOnDisk objectAtIndex:i];
 205             if ([theme hasSuffix:@".theme"])
 206                 [themesOnDisk replaceObjectAtIndex:i withObject:[theme stringByDeletingPathExtension]];
 207         }
 208
 209         NSMutableSet *themesSet([NSMutableSet set]);
 210
 211         for (int i = 0, count = [_themes count]; i < count; i++) {
 212             NSDictionary *theme([_themes objectAtIndex:i]);
 213             NSString *name([theme objectForKey:@"Name"]);
 214
 215             if (!name || ![themesOnDisk containsObject:name]) {
 216                 [_themes removeObjectAtIndex:i];
 217                 i--;
 218                 count--;
 219             } else {
 220                 [themesSet addObject:name];
 221             }
 222         }
 223
 224         for (NSString *theme in themesOnDisk) {
 225             if ([themesSet containsObject:theme])
 226                 continue;
 227             [themesSet addObject:theme];
 228
 229             [_themes insertObject:[NSMutableDictionary dictionaryWithObjectsAndKeys:
 230                     theme, @"Name",
 231                     [NSNumber numberWithBool:NO], @"Active",
 232             nil] atIndex:0];
 233         }
 234
 235         _tableView = [[UITableView alloc] initWithFrame:CGRectMake(0, 0, 320, 480-64) style:UITableViewStyleGrouped];
 236         [_tableView setDataSource:self];
 237         [_tableView setDelegate:self];
 238         [_tableView setEditing:YES];
 239         [_tableView setAllowsSelectionDuringEditing:YES];
 240         if ([self respondsToSelector:@selector(setView:)])
 241             [self setView:_tableView];
 242     }
 243     return self;
 244 }
 245
 246 - (void) dealloc {
 247     [_tableView release];
 248     [_themes release];
 249     [super dealloc];
 250 }
 251
 252 - (id) navigationTitle {
 253     return @"Themes";
 254 }
 255
 256 - (id) view {
 257     return _tableView;
 258 }
 259
 260 - (void) themesChanged {
 261     settingsChanged = YES;
 262 }
 263
 264 /* UITableViewDelegate / UITableViewDataSource Methods {{{ */
 265 - (int) numberOfSectionsInTableView:(UITableView *)tableView {
 266     return 1;
 267 }
 268
 269 - (id) tableView:(UITableView *)tableView titleForHeaderInSection:(int)section {
 270     return nil;
 271 }
 272
 273 - (int) tableView:(UITableView *)tableView numberOfRowsInSection:(int)section {
 274     return _themes.count;
 275 }
 276
 277 - (id) tableView:(UITableView *)tableView cellForRowAtIndexPath:(NSIndexPath *)indexPath {
 278     UITableViewCell *cell = [tableView dequeueReusableCellWithIdentifier:@"ThemeCell"];
 279     if (!cell) {
 280         cell = [[[UITableViewCell alloc] initWithFrame:CGRectMake(0, 0, 100, 100) reuseIdentifier:@"ThemeCell"] autorelease];
 281         //[cell setTableViewStyle:UITableViewCellStyleDefault];
 282     }
 283
 284     NSDictionary *theme([_themes objectAtIndex:indexPath.row]);
 285     cell.text = [theme objectForKey:@"Name"];
 286     cell.hidesAccessoryWhenEditing = NO;
 287     NSNumber *active([theme objectForKey:@"Active"]);
 288     BOOL inactive(active == nil || ![active boolValue]);
 289     [cell setImage:(inactive ? uncheckedImage : checkImage)];
 290     return cell;
 291 }
 292
 293 - (void) tableView:(UITableView *)tableView didSelectRowAtIndexPath:(NSIndexPath *)indexPath {
 294     UITableViewCell *cell = [tableView cellForRowAtIndexPath:indexPath];
 295     NSMutableDictionary *theme = [_themes objectAtIndex:indexPath.row];
 296     NSNumber *active = [theme objectForKey:@"Active"];
 297     BOOL inactive = active == nil || ![active boolValue];
 298     [theme setObject:[NSNumber numberWithBool:inactive] forKey:@"Active"];
 299     [cell setImage:(!inactive ? uncheckedImage : checkImage)];
 300     [tableView deselectRowAtIndexPath:(NSIndexPath *)indexPath animated:YES];
 301     [self themesChanged];
 302 }
 303
 304 - (void) tableView:(UITableView *)tableView moveRowAtIndexPath:(NSIndexPath *)fromIndexPath toIndexPath:(NSIndexPath *)toIndexPath {
 305     NSUInteger fromIndex = [fromIndexPath row];
 306     NSUInteger toIndex = [toIndexPath row];
 307     if (fromIndex == toIndex)
 308         return;
 309     NSMutableDictionary *theme = [[[_themes objectAtIndex:fromIndex] retain] autorelease];
 310     [_themes removeObjectAtIndex:fromIndex];
 311     [_themes insertObject:theme atIndex:toIndex];
 312     [self themesChanged];
 313 }
 314
 315 - (UITableViewCellEditingStyle) tableView:(UITableView *)tableView editingStyleForRowAtIndexPath:(NSIndexPath *)indexPath {
 316     return UITableViewCellEditingStyleNone;
 317 }
 318
 319 - (BOOL) tableView:(UITableView *)tableView shouldIndentWhileEditingRowAtIndexPath:(NSIndexPath *)indexPath {
 320     return NO;
 321 }
 322
 323 - (BOOL) tableView:(UITableView *)tableView canMoveRowAtIndexPath:(NSIndexPath *)indexPath {
 324     return YES;
 325 }
 326 /* }}} */
 327 @end
 328 /* }}} */
 329
 330 @interface WBAdvancedController: PSListController {
 331 }
 332
 333 - (id) specifiers;
 334 - (void) settingsChanged;
 335
 336 @end
 337
 338 @implementation WBAdvancedController
 339
 340 - (id) specifiers {
 341     if (!_specifiers)
 342         _specifiers = [[self loadSpecifiersFromPlistName:@"Advanced" target:self] retain];
 343     return _specifiers;
 344 }
 345
 346 - (void) settingsChanged {
 347     settingsChanged = YES;
 348 }
 349
 350 - (void) setPreferenceValue:(id)value specifier:(PSSpecifier *)spec {
 351     NSString *key([spec propertyForKey:@"key"]);
 352     if ([[spec propertyForKey:@"negate"] boolValue])
 353         value = [NSNumber numberWithBool:(![value boolValue])];
 354     [_settings setValue:value forKey:key];
 355     [self settingsChanged];
 356 }
 357
 358 - (id) readPreferenceValue:(PSSpecifier *)spec {
 359     NSString *key([spec propertyForKey:@"key"]);
 360     id defaultValue([spec propertyForKey:@"default"]);
 361     id plistValue([_settings objectForKey:key]);
 362     if (!plistValue)
 363         return defaultValue;
 364     if ([[spec propertyForKey:@"negate"] boolValue])
 365         plistValue = [NSNumber numberWithBool:(![plistValue boolValue])];
 366     return plistValue;
 367 }
 368
 369 - (void) __optimizeThemes {
 370     system("/usr/libexec/winterboard/Optimize");
 371 }
 372
 373 - (void) optimizeThemes {
 374     UIActionSheet *sheet([[[UIActionSheet alloc]
 375         initWithTitle:@"Optimize Themes"
 376         buttons:[NSArray arrayWithObjects:@"Optimize", @"Cancel", nil]
 377         defaultButtonIndex:1
 378         delegate:self
 379         context:@"optimize"
 380     ] autorelease]);
 381
 382     [sheet setBodyText:@"Please note that this setting /replaces/ the PNG files that came with the theme. PNG files that have been iPhone-optimized cannot be viewed on a normal computer unless they are first deoptimized. You can use Cydia to reinstall themes that have been optimized in order to revert to the original PNG files."];
 383     [sheet setNumberOfRows:1];
 384     [sheet setDestructiveButtonIndex:0];
 385     [sheet popupAlertAnimated:YES];
 386 }
 387
 388 - (void) _optimizeThemes {
 389     UIView *view([self view]);
 390     UIWindow *window([view window]);
 391
 392     UIProgressHUD *hud([[[UIProgressHUD alloc] initWithWindow:window] autorelease]);
 393     [hud setText:@"Reticulating Splines\nPlease Wait (Minutes)"];
 394
 395     [window setUserInteractionEnabled:NO];
 396
 397     [window addSubview:hud];
 398     [hud show:YES];
 399     [self wb$yieldToSelector:@selector(__optimizeThemes)];
 400     [hud removeFromSuperview];
 401
 402     [window setUserInteractionEnabled:YES];
 403
 404     [self settingsChanged];
 405 }
 406
 407 - (void) alertSheet:(UIActionSheet *)sheet buttonClicked:(int)button {
 408     NSString *context([sheet context]);
 409
 410     if ([context isEqualToString:@"optimize"]) {
 411         switch (button) {
 412             case 1:
 413                 [self performSelector:@selector(_optimizeThemes) withObject:nil afterDelay:0];
 414             break;
 415         }
 416
 417         [sheet dismiss];
 418     } else
 419         [super alertSheet:sheet buttonClicked:button];
 420
 421 }
 422
 423 @end
 424
 425 @interface WBSettingsController: PSListController {
 426 }
 427
 428 - (id) initForContentSize:(CGSize)size;
 429 - (void) dealloc;
 430 - (void) suspend;
 431 - (void) navigationBarButtonClicked:(int)buttonIndex;
 432 - (void) viewWillRedisplay;
 433 - (void) pushController:(id)controller;
 434 - (id) specifiers;
 435 - (void) settingsChanged;
 436 - (NSString *) title;
 437 - (void) setPreferenceValue:(id)value specifier:(PSSpecifier *)spec;
 438 - (id) readPreferenceValue:(PSSpecifier *)spec;
 439
 440 @end
 441
 442 @implementation WBSettingsController
 443
 444 + (void) load {
 445     void *libhide(dlopen("/usr/lib/hide.dylib", RTLD_LAZY));
 446     IsIconHiddenDisplayId = reinterpret_cast<BOOL (*)(NSString *)>(dlsym(libhide, "IsIconHiddenDisplayId"));
 447     HideIconViaDisplayId = reinterpret_cast<BOOL (*)(NSString *)>(dlsym(libhide, "HideIconViaDisplayId"));
 448     UnHideIconViaDisplayId = reinterpret_cast<BOOL (*)(NSString *)>(dlsym(libhide, "UnHideIconViaDisplayId"));
 449 }
 450
 451 - (id) initForContentSize:(CGSize)size {
 452     if ((self = [super initForContentSize:size]) != nil) {
 453         _plist = [[NSString stringWithFormat:@"%@/Library/Preferences/com.saurik.WinterBoard.plist", NSHomeDirectory()] retain];
 454         _settings = [([NSMutableDictionary dictionaryWithContentsOfFile:_plist] ?: [NSMutableDictionary dictionary]) retain];
 455
 456         [_settings setObject:[NSNumber numberWithBool:IsIconHiddenDisplayId(WinterBoardDisplayID)] forKey:@"IconHidden"];
 457     } return self;
 458 }
 459
 460 - (void) dealloc {
 461     [_settings release];
 462     [_plist release];
 463     [super dealloc];
 464 }
 465
 466 - (void) suspend {
 467     if (!settingsChanged)
 468         return;
 469
 470     NSData *data([NSPropertyListSerialization dataFromPropertyList:_settings format:NSPropertyListBinaryFormat_v1_0 errorDescription:NULL]);
 471     if (!data)
 472         return;
 473     if (![data writeToFile:_plist options:NSAtomicWrite error:NULL])
 474         return;
 475
 476     ([[_settings objectForKey:@"IconHidden"] boolValue] ? HideIconViaDisplayId : UnHideIconViaDisplayId)(WinterBoardDisplayID);
 477
 478     unlink("/User/Library/Caches/com.apple.springboard-imagecache-icons");
 479     unlink("/User/Library/Caches/com.apple.springboard-imagecache-icons.plist");
 480     unlink("/User/Library/Caches/com.apple.springboard-imagecache-smallicons");
 481     unlink("/User/Library/Caches/com.apple.springboard-imagecache-smallicons.plist");
 482
 483     unlink("/User/Library/Caches/com.apple.SpringBoard.folderSwitcherLinen");
 484     unlink("/User/Library/Caches/com.apple.SpringBoard.notificationCenterLinen");
 485
 486     unlink("/User/Library/Caches/com.apple.SpringBoard.folderSwitcherLinen.0");
 487     unlink("/User/Library/Caches/com.apple.SpringBoard.folderSwitcherLinen.1");
 488     unlink("/User/Library/Caches/com.apple.SpringBoard.folderSwitcherLinen.2");
 489     unlink("/User/Library/Caches/com.apple.SpringBoard.folderSwitcherLinen.3");
 490
 491     system("rm -rf /User/Library/Caches/SpringBoardIconCache");
 492     system("rm -rf /User/Library/Caches/SpringBoardIconCache-small");
 493     system("rm -rf /User/Library/Caches/com.apple.IconsCache");
 494     system("rm -rf /User/Library/Caches/com.apple.newsstand");
 495     system("rm -rf /User/Library/Caches/com.apple.springboard.sharedimagecache");
 496
 497     system("killall lsd SpringBoard");
 498 }
 499
 500 - (void) cancelChanges {
 501     [_settings release];
 502     [_plist release];
 503     _plist = [[NSString stringWithFormat:@"%@/Library/Preferences/com.saurik.WinterBoard.plist", NSHomeDirectory()] retain];
 504     _settings = [([NSMutableDictionary dictionaryWithContentsOfFile:_plist] ?: [NSMutableDictionary dictionary]) retain];
 505
 506     [_settings setObject:[NSNumber numberWithBool:IsIconHiddenDisplayId(WinterBoardDisplayID)] forKey:@"IconHidden"];
 507     [self reloadSpecifiers];
 508     if (![[PSViewController class] instancesRespondToSelector:@selector(showLeftButton:withStyle:rightButton:withStyle:)]) {
 509         [[self navigationItem] setLeftBarButtonItem:nil];
 510         [[self navigationItem] setRightBarButtonItem:nil];
 511     } else {
 512         [self showLeftButton:nil withStyle:0 rightButton:nil withStyle:0];
 513     }
 514     settingsChanged = NO;
 515 }
 516
 517 - (void) navigationBarButtonClicked:(int)buttonIndex {
 518     if (!settingsChanged) {
 519         [super navigationBarButtonClicked:buttonIndex];
 520         return;
 521     }
 522
 523     if (buttonIndex == 0) {
 524         [self cancelChanges];
 525         return;
 526     }
 527
 528     [self suspend];
 529     [self.rootController popController];
 530 }
 531
 532 - (void) settingsConfirmButtonClicked:(UIBarButtonItem *)button {
 533     [self navigationBarButtonClicked:button.tag];
 534 }
 535
 536 - (void) viewWillRedisplay {
 537     if (settingsChanged)
 538         [self settingsChanged];
 539     [super viewWillRedisplay];
 540 }
 541
 542 - (void) viewWillAppear:(BOOL)animated {
 543     if (settingsChanged)
 544         [self settingsChanged];
 545     if ([super respondsToSelector:@selector(viewWillAppear:)])
 546         [super viewWillAppear:animated];
 547 }
 548
 549 - (void) pushController:(id)controller {
 550     [self hideNavigationBarButtons];
 551     [super pushController:controller];
 552 }
 553
 554 - (id) specifiers {
 555     if (!_specifiers)
 556         _specifiers = [[self loadSpecifiersFromPlistName:@"WinterBoard" target:self] retain];
 557     return _specifiers;
 558 }
 559
 560 - (void) settingsChanged {
 561     if (![[PSViewController class] instancesRespondToSelector:@selector(showLeftButton:withStyle:rightButton:withStyle:)]) {
 562         UIBarButtonItem *respringButton([[UIBarButtonItem alloc] initWithTitle:@"Respring" style:UIBarButtonItemStyleDone target:self action:@selector(settingsConfirmButtonClicked:)]);
 563         UIBarButtonItem *cancelButton([[UIBarButtonItem alloc] initWithTitle:@"Cancel" style:UIBarButtonItemStylePlain target:self action:@selector(settingsConfirmButtonClicked:)]);
 564         cancelButton.tag = 0;
 565         respringButton.tag = 1;
 566         [[self navigationItem] setLeftBarButtonItem:respringButton];
 567         [[self navigationItem] setRightBarButtonItem:cancelButton];
 568         [respringButton release];
 569         [cancelButton release];
 570     } else {
 571         [self showLeftButton:@"Respring" withStyle:2 rightButton:@"Cancel" withStyle:0];
 572     }
 573     settingsChanged = YES;
 574 }
 575
 576 - (NSString *) title {
 577     return @"WinterBoard";
 578 }
 579
 580 - (void) setPreferenceValue:(id)value specifier:(PSSpecifier *)spec {
 581     NSString *key([spec propertyForKey:@"key"]);
 582     if ([[spec propertyForKey:@"negate"] boolValue])
 583         value = [NSNumber numberWithBool:(![value boolValue])];
 584     [_settings setValue:value forKey:key];
 585     [self settingsChanged];
 586 }
 587
 588 - (id) readPreferenceValue:(PSSpecifier *)spec {
 589     NSString *key([spec propertyForKey:@"key"]);
 590     id defaultValue([spec propertyForKey:@"default"]);
 591     id plistValue([_settings objectForKey:key]);
 592     if (!plistValue)
 593         return defaultValue;
 594     if ([[spec propertyForKey:@"negate"] boolValue])
 595         plistValue = [NSNumber numberWithBool:(![plistValue boolValue])];
 596     return plistValue;
 597 }
 598
 599 @end
 600
 601 #define WBSAddMethod(_class, _sel, _imp, _type) \
 602     if (![[_class class] instancesRespondToSelector:@selector(_sel)]) \
 603         class_addMethod([_class class], @selector(_sel), (IMP)_imp, _type)
 604 void $PSRootController$popController(PSRootController *self, SEL _cmd) {
 605     [self popViewControllerAnimated:YES];
 606 }
 607
 608 void $PSViewController$hideNavigationBarButtons(PSRootController *self, SEL _cmd) {
 609 }
 610
 611 id $PSViewController$initForContentSize$(PSRootController *self, SEL _cmd, CGRect contentSize) {
 612     return [self init];
 613 }
 614
 615 static __attribute__((constructor)) void __wbsInit() {
 616     WBSAddMethod(PSRootController, popController, $PSRootController$popController, "v@:");
 617     WBSAddMethod(PSViewController, hideNavigationBarButtons, $PSViewController$hideNavigationBarButtons, "v@:");
 618     WBSAddMethod(PSViewController, initForContentSize:, $PSViewController$initForContentSize$, "@@:{ff}");
 619 }