Tweak.mm

   1 /* Veency - VNC Remote Access Server for iPhoneOS
   2  * Copyright (C) 2008-2012  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 #define _trace() \
  23     fprintf(stderr, "_trace()@%s:%u[%s]\n", __FILE__, __LINE__, __FUNCTION__)
  24 #define _likely(expr) \
  25     __builtin_expect(expr, 1)
  26 #define _unlikely(expr) \
  27     __builtin_expect(expr, 0)
  28
  29 #include <substrate.h>
  30
  31 #include <rfb/rfb.h>
  32 #include <rfb/keysym.h>
  33
  34 #include <mach/mach.h>
  35 #include <mach/mach_time.h>
  36
  37 #include <sys/mman.h>
  38 #include <sys/sysctl.h>
  39
  40 #undef assert
  41
  42 #include <CoreFoundation/CFUserNotification.h>
  43 #import <CoreGraphics/CGGeometry.h>
  44 #import <GraphicsServices/GraphicsServices.h>
  45 #import <Foundation/Foundation.h>
  46 #import <UIKit/UIKit.h>
  47
  48 #include <IOKit/hid/IOHIDEventTypes.h>
  49 #include <IOKit/hidsystem/IOHIDUsageTables.h>
  50
  51 extern "C" {
  52 #include "SpringBoardAccess.h"
  53 }
  54
  55 typedef CFTypeRef IOHIDEventRef;
  56 typedef CFTypeRef IOHIDEventSystemClientRef;
  57 typedef CFTypeRef IOHIDEventSystemConnectionRef;
  58
  59 MSClassHook(BKAccessibility)
  60 MSClassHook(UIApplication)
  61
  62 @interface UIApplication (Apple)
  63 - (void) addStatusBarImageNamed:(NSString *)name;
  64 - (void) removeStatusBarImageNamed:(NSString *)name;
  65 @end
  66
  67 @interface CAWindowServerDisplay : NSObject
  68 - (mach_port_t) clientPortAtPosition:(CGPoint)position;
  69 @end
  70
  71 @interface CAWindowServer : NSObject
  72 + (CAWindowServer *) serverIfRunning;
  73 - (NSArray *) displays;
  74 @end
  75
  76 @interface UIModalView : UIView
  77 - (id) addButtonWithTitle:(NSString *)title;
  78 - (void) setBodyText:(NSString *)text;
  79 - (void) setDelegate:(id)delegate;
  80 - (void) setTitle:(NSString *)title;
  81 @end
  82
  83 @interface SBAlertItem : NSObject
  84 - (void) dismiss;
  85 - (UIModalView *) alertSheet;
  86 @end
  87
  88 @interface SBAlertItemsController : NSObject
  89 + (SBAlertItemsController *) sharedInstance;
  90 - (void) activateAlertItem:(SBAlertItem *)item;
  91 @end
  92
  93 @interface SBStatusBarController : NSObject
  94 + (SBStatusBarController *) sharedStatusBarController;
  95 - (void) addStatusBarItem:(NSString *)item;
  96 - (void) removeStatusBarItem:(NSString *)item;
  97 @end
  98
  99 #if defined(_ARM_ARCH_6) && !defined(_ARM_ARCH_7)
 100
 101 #define kIOSurfaceAllocSize kCoreSurfaceBufferAllocSize
 102 #define kIOSurfaceBytesPerRow kCoreSurfaceBufferPitch
 103 #define kIOSurfaceHeight kCoreSurfaceBufferHeight
 104 #define kIOSurfaceIsGlobal kCoreSurfaceBufferGlobal
 105 #define kIOSurfaceMemoryRegion kCoreSurfaceBufferMemoryRegion
 106 #define kIOSurfacePixelFormat kCoreSurfaceBufferPixelFormat
 107 #define kIOSurfaceWidth kCoreSurfaceBufferWidth
 108
 109 #define IOSurfaceRef CoreSurfaceBufferRef
 110 #define IOSurfaceAcceleratorRef CoreSurfaceAcceleratorRef
 111
 112 #define IOSurfaceCreate CoreSurfaceBufferCreate
 113 #define IOSurfaceFlushProcessorCaches CoreSurfaceBufferFlushProcessorCaches
 114 #define IOSurfaceGetBaseAddress CoreSurfaceBufferGetBaseAddress
 115 #define IOSurfaceLock CoreSurfaceBufferLock
 116 #define IOSurfaceUnlock CoreSurfaceBufferUnlock
 117
 118 #define IOSurfaceAcceleratorCreate CoreSurfaceAcceleratorCreate
 119 #define IOSurfaceAcceleratorTransferSurface CoreSurfaceAcceleratorTransferSurface
 120
 121 #endif
 122
 123 typedef void *IOSurfaceRef;
 124
 125 extern CFStringRef kIOSurfaceIsGlobal;
 126 extern CFStringRef kIOSurfaceMemoryRegion;
 127 extern CFStringRef kIOSurfaceBytesPerRow;
 128 extern CFStringRef kIOSurfaceWidth;
 129 extern CFStringRef kIOSurfaceHeight;
 130 extern CFStringRef kIOSurfacePixelFormat;
 131 extern CFStringRef kIOSurfaceAllocSize;
 132
 133 extern "C" IOSurfaceRef IOSurfaceCreate(CFDictionaryRef dict);
 134 extern "C" int IOSurfaceLock(IOSurfaceRef surface, unsigned int lockType);
 135 extern "C" int IOSurfaceUnlock(IOSurfaceRef surface);
 136 extern "C" void *IOSurfaceGetBaseAddress(IOSurfaceRef surface);
 137
 138 extern "C" void IOSurfaceFlushProcessorCaches(IOSurfaceRef buffer);
 139
 140 typedef void *IOSurfaceAcceleratorRef;
 141
 142 extern "C" int IOSurfaceAcceleratorCreate(CFAllocatorRef allocator, void *type, IOSurfaceAcceleratorRef *accel);
 143 extern "C" unsigned int IOSurfaceAcceleratorTransferSurface(IOSurfaceAcceleratorRef accelerator, IOSurfaceRef dest, IOSurfaceRef src, void *, void *, void *, void *);
 144
 145 typedef void *IOMobileFramebufferRef;
 146
 147 extern "C" kern_return_t IOMobileFramebufferSwapSetLayer(
 148     IOMobileFramebufferRef fb,
 149     int layer,
 150     IOSurfaceRef buffer,
 151     CGRect bounds,
 152     CGRect frame,
 153     int flags
 154 );
 155
 156 extern "C" void IOMobileFramebufferGetDisplaySize(IOMobileFramebufferRef connect, CGSize *size);
 157 extern "C" void IOMobileFramebufferIsMainDisplay(IOMobileFramebufferRef connect, int *main);
 158
 159 extern "C" {
 160     IOHIDEventRef IOHIDEventCreateKeyboardEvent(CFAllocatorRef allocator, uint64_t time, uint16_t page, uint16_t usage, Boolean down, IOHIDEventOptionBits flags);
 161
 162     IOHIDEventRef IOHIDEventCreateDigitizerEvent(CFAllocatorRef allocator, uint64_t timeStamp, IOHIDDigitizerTransducerType type, uint32_t index, uint32_t identity, uint32_t eventMask, uint32_t buttonMask, IOHIDFloat x, IOHIDFloat y, IOHIDFloat z, IOHIDFloat tipPressure, IOHIDFloat barrelPressure, Boolean range, Boolean touch, IOOptionBits options);
 163     IOHIDEventRef IOHIDEventCreateDigitizerFingerEvent(CFAllocatorRef allocator, uint64_t timeStamp, uint32_t index, uint32_t identity, uint32_t eventMask, IOHIDFloat x, IOHIDFloat y, IOHIDFloat z, IOHIDFloat tipPressure, IOHIDFloat twist, Boolean range, Boolean touch, IOOptionBits options);
 164
 165     IOHIDEventSystemClientRef IOHIDEventSystemClientCreate(CFAllocatorRef allocator);
 166
 167     void IOHIDEventAppendEvent(IOHIDEventRef parent, IOHIDEventRef child);
 168     void IOHIDEventSetIntegerValue(IOHIDEventRef event, IOHIDEventField field, int value);
 169     void IOHIDEventSetSenderID(IOHIDEventRef event, uint64_t sender);
 170
 171     void IOHIDEventSystemClientDispatchEvent(IOHIDEventSystemClientRef client, IOHIDEventRef event);
 172     void IOHIDEventSystemConnectionDispatchEvent(IOHIDEventSystemConnectionRef connection, IOHIDEventRef event);
 173 }
 174
 175 static size_t width_;
 176 static size_t height_;
 177 static NSUInteger ratio_ = 0;
 178
 179 static const size_t BytesPerPixel = 4;
 180 static const size_t BitsPerSample = 8;
 181
 182 static IOSurfaceAcceleratorRef accelerator_;
 183 static IOSurfaceRef buffer_;
 184
 185 static NSMutableSet *handlers_;
 186 static rfbScreenInfoPtr screen_;
 187 static bool running_;
 188 static int buttons_;
 189 static int x_, y_;
 190
 191 static unsigned clients_;
 192
 193 static CFMessagePortRef ashikase_;
 194 static bool cursor_;
 195
 196 static rfbPixel *black_;
 197
 198 static void VNCBlack() {
 199     if (_unlikely(black_ == NULL))
 200         black_ = reinterpret_cast<rfbPixel *>(mmap(NULL, sizeof(rfbPixel) * width_ * height_, PROT_READ, MAP_ANON | MAP_PRIVATE | MAP_NOCACHE, VM_FLAGS_PURGABLE, 0));
 201     screen_->frameBuffer = reinterpret_cast<char *>(black_);
 202 }
 203
 204 static bool Ashikase(bool always) {
 205     if (!always && !cursor_)
 206         return false;
 207
 208     if (ashikase_ == NULL)
 209         ashikase_ = CFMessagePortCreateRemote(kCFAllocatorDefault, CFSTR("jp.ashikase.mousesupport"));
 210     if (ashikase_ != NULL)
 211         return true;
 212
 213     cursor_ = false;
 214     return false;
 215 }
 216
 217 static CFDataRef cfTrue_;
 218 static CFDataRef cfFalse_;
 219
 220 typedef struct {
 221     float x, y;
 222     int buttons;
 223     BOOL absolute;
 224 } MouseEvent;
 225
 226 static MouseEvent event_;
 227 static CFDataRef cfEvent_;
 228
 229 typedef enum {
 230     MouseMessageTypeEvent,
 231     MouseMessageTypeSetEnabled
 232 } MouseMessageType;
 233
 234 static void AshikaseSendEvent(float x, float y, int buttons = 0) {
 235     event_.x = x;
 236     event_.y = y;
 237     event_.buttons = buttons;
 238     event_.absolute = true;
 239
 240     CFMessagePortSendRequest(ashikase_, MouseMessageTypeEvent, cfEvent_, 0, 0, NULL, NULL);
 241 }
 242
 243 static void AshikaseSetEnabled(bool enabled, bool always) {
 244     if (!Ashikase(always))
 245         return;
 246
 247     CFMessagePortSendRequest(ashikase_, MouseMessageTypeSetEnabled, enabled ? cfTrue_ : cfFalse_, 0, 0, NULL, NULL);
 248
 249     if (enabled)
 250         AshikaseSendEvent(x_, y_);
 251 }
 252
 253 MSClassHook(SBAlertItem)
 254 MSClassHook(SBAlertItemsController)
 255 MSClassHook(SBStatusBarController)
 256
 257 @interface VNCAlertItem : SBAlertItem
 258 @end
 259
 260 static Class $VNCAlertItem;
 261
 262 static NSString *DialogTitle(@"Remote Access Request");
 263 static NSString *DialogFormat(@"Accept connection from\n%s?\n\nVeency VNC Server\nby Jay Freeman (saurik)\nsaurik@saurik.com\nhttp://www.saurik.com/\n\nSet a VNC password in Settings!");
 264 static NSString *DialogAccept(@"Accept");
 265 static NSString *DialogReject(@"Reject");
 266
 267 static volatile rfbNewClientAction action_ = RFB_CLIENT_ON_HOLD;
 268 static NSCondition *condition_;
 269 static NSLock *lock_;
 270
 271 static rfbClientPtr client_;
 272
 273 static void VNCSetup();
 274 static void VNCEnabled();
 275
 276 float (*$GSMainScreenScaleFactor)();
 277
 278 static void VNCAction(rfbNewClientAction action) {
 279     [condition_ lock];
 280     action_ = action;
 281     [condition_ signal];
 282     [condition_ unlock];
 283 }
 284
 285 static void OnUserNotification(CFUserNotificationRef notification, CFOptionFlags flags) {
 286     if ((flags & 0x3) == 1)
 287         VNCAction(RFB_CLIENT_ACCEPT);
 288     else
 289         VNCAction(RFB_CLIENT_REFUSE);
 290
 291     CFRelease(notification);
 292 }
 293
 294 @interface VNCBridge : NSObject {
 295 }
 296
 297 + (void) askForConnection;
 298 + (void) removeStatusBarItem;
 299 + (void) registerClient;
 300
 301 @end
 302
 303 @implementation VNCBridge
 304
 305 + (void) askForConnection {
 306     if ($VNCAlertItem != nil) {
 307         [[$SBAlertItemsController sharedInstance] activateAlertItem:[[[$VNCAlertItem alloc] init] autorelease]];
 308         return;
 309     }
 310
 311     SInt32 error;
 312     CFUserNotificationRef notification(CFUserNotificationCreate(kCFAllocatorDefault, 0, kCFUserNotificationPlainAlertLevel, &error, (CFDictionaryRef) [NSDictionary dictionaryWithObjectsAndKeys:
 313         DialogTitle, kCFUserNotificationAlertHeaderKey,
 314         [NSString stringWithFormat:DialogFormat, client_->host], kCFUserNotificationAlertMessageKey,
 315         DialogAccept, kCFUserNotificationAlternateButtonTitleKey,
 316         DialogReject, kCFUserNotificationDefaultButtonTitleKey,
 317     nil]));
 318
 319     if (error != 0) {
 320         CFRelease(notification);
 321         notification = NULL;
 322     }
 323
 324     if (notification == NULL) {
 325         VNCAction(RFB_CLIENT_REFUSE);
 326         return;
 327     }
 328
 329     CFRunLoopSourceRef source(CFUserNotificationCreateRunLoopSource(kCFAllocatorDefault, notification, &OnUserNotification, 0));
 330     CFRunLoopAddSource(CFRunLoopGetCurrent(), source, kCFRunLoopDefaultMode);
 331 }
 332
 333 + (void) removeStatusBarItem {
 334     AshikaseSetEnabled(false, false);
 335
 336     if (SBA_available())
 337         SBA_removeStatusBarImage(const_cast<char *>("Veency"));
 338     else if ($SBStatusBarController != nil)
 339         [[$SBStatusBarController sharedStatusBarController] removeStatusBarItem:@"Veency"];
 340     else if (UIApplication *app = [$UIApplication sharedApplication])
 341         [app removeStatusBarImageNamed:@"Veency"];
 342 }
 343
 344 + (void) registerClient {
 345     // XXX: this could find a better home
 346     if (ratio_ == 0) {
 347         if ($GSMainScreenScaleFactor == NULL)
 348             ratio_ = 1.0f;
 349         else
 350             ratio_ = $GSMainScreenScaleFactor();
 351     }
 352
 353     ++clients_;
 354     AshikaseSetEnabled(true, false);
 355
 356     if (SBA_available())
 357         SBA_addStatusBarImage(const_cast<char *>("Veency"));
 358     else if ($SBStatusBarController != nil)
 359         [[$SBStatusBarController sharedStatusBarController] addStatusBarItem:@"Veency"];
 360     else if (UIApplication *app = [$UIApplication sharedApplication])
 361         [app addStatusBarImageNamed:@"Veency"];
 362 }
 363
 364 + (void) performSetup:(NSThread *)thread {
 365     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
 366     [thread autorelease];
 367     VNCSetup();
 368     VNCEnabled();
 369     [pool release];
 370 }
 371
 372 @end
 373
 374 MSInstanceMessage2(void, VNCAlertItem, alertSheet,buttonClicked, id, sheet, int, button) {
 375     switch (button) {
 376         case 1:
 377             VNCAction(RFB_CLIENT_ACCEPT);
 378         break;
 379
 380         case 2:
 381             VNCAction(RFB_CLIENT_REFUSE);
 382         break;
 383     }
 384
 385     [self dismiss];
 386 }
 387
 388 MSInstanceMessage2(void, VNCAlertItem, configure,requirePasscodeForActions, BOOL, configure, BOOL, require) {
 389     UIModalView *sheet([self alertSheet]);
 390     [sheet setDelegate:self];
 391     [sheet setTitle:DialogTitle];
 392     [sheet setBodyText:[NSString stringWithFormat:DialogFormat, client_->host]];
 393     [sheet addButtonWithTitle:DialogAccept];
 394     [sheet addButtonWithTitle:DialogReject];
 395 }
 396
 397 MSInstanceMessage0(void, VNCAlertItem, performUnlockAction) {
 398     [[$SBAlertItemsController sharedInstance] activateAlertItem:self];
 399 }
 400
 401 static mach_port_t (*GSTakePurpleSystemEventPort)(void);
 402 static bool PurpleAllocated;
 403 static int Level_;
 404
 405 static void FixRecord(GSEventRecord *record) {
 406     if (Level_ < 1)
 407         memmove(&record->windowContextId, &record->windowContextId + 1, sizeof(*record) - (reinterpret_cast<uint8_t *>(&record->windowContextId + 1) - reinterpret_cast<uint8_t *>(record)) + record->size);
 408 }
 409
 410 static void VNCSettings() {
 411     @synchronized (lock_) {
 412         for (NSValue *handler in handlers_)
 413             rfbUnregisterSecurityHandler(reinterpret_cast<rfbSecurityHandler *>([handler pointerValue]));
 414         [handlers_ removeAllObjects];
 415     }
 416
 417     @synchronized (condition_) {
 418         if (screen_ == NULL)
 419             return;
 420
 421         [(NSString *) screen_->authPasswdData release];
 422         screen_->authPasswdData = NULL;
 423
 424         if (CFStringRef password = (CFStringRef) CFPreferencesCopyAppValue(CFSTR("Password"), CFSTR("com.saurik.Veency")))
 425             if (CFStringGetLength(password) == 0)
 426                 CFRelease(password);
 427             else
 428                 screen_->authPasswdData = (void *) password;
 429
 430         Boolean valid;
 431         cursor_ = CFPreferencesGetAppBooleanValue(CFSTR("ShowCursor"), CFSTR("com.saurik.Veency"), &valid);
 432         if (!valid)
 433             cursor_ = true;
 434
 435         if (clients_ != 0)
 436             AshikaseSetEnabled(cursor_, true);
 437     }
 438 }
 439
 440 static void VNCNotifySettings(
 441     CFNotificationCenterRef center,
 442     void *observer,
 443     CFStringRef name,
 444     const void *object,
 445     CFDictionaryRef info
 446 ) {
 447     CFPreferencesAppSynchronize(CFSTR("com.saurik.Veency"));
 448     VNCSettings();
 449 }
 450
 451 static rfbBool VNCCheck(rfbClientPtr client, const char *data, int size) {
 452     @synchronized (condition_) {
 453         if (NSString *password = reinterpret_cast<NSString *>(screen_->authPasswdData)) {
 454             NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
 455             rfbEncryptBytes(client->authChallenge, const_cast<char *>([password UTF8String]));
 456             bool good(memcmp(client->authChallenge, data, size) == 0);
 457             [pool release];
 458             return good;
 459         } return TRUE;
 460     }
 461 }
 462
 463 static bool iPad1_;
 464
 465 struct VeencyEvent {
 466     struct GSEventRecord record;
 467     struct {
 468         struct GSEventRecordInfo info;
 469         struct GSPathInfo path;
 470     } data;
 471 };
 472
 473 static void VNCPointerOld(int buttons, int x, int y, CGPoint location, int diff, bool twas, bool tis);
 474 static void VNCPointerNew(int buttons, int x, int y, CGPoint location, int diff, bool twas, bool tis);
 475
 476 static void VNCPointer(int buttons, int x, int y, rfbClientPtr client) {
 477     if (ratio_ == 0)
 478         return;
 479
 480     CGPoint location = {x, y};
 481
 482     if (width_ > height_) {
 483         int t(x);
 484         x = height_ - 1 - y;
 485         y = t;
 486
 487         if (!iPad1_) {
 488             x = height_ - 1 - x;
 489             y = width_ - 1 - y;
 490         }
 491     }
 492
 493     x /= ratio_;
 494     y /= ratio_;
 495
 496     x_ = x; y_ = y;
 497     int diff = buttons_ ^ buttons;
 498     bool twas((buttons_ & 0x1) != 0);
 499     bool tis((buttons & 0x1) != 0);
 500     buttons_ = buttons;
 501
 502     rfbDefaultPtrAddEvent(buttons, x, y, client);
 503
 504     if (Ashikase(false)) {
 505         AshikaseSendEvent(x, y, buttons);
 506         return;
 507     }
 508
 509     if (kCFCoreFoundationVersionNumber >= 800)
 510         return VNCPointerNew(buttons, x, y, location, diff, twas, tis);
 511     else
 512         return VNCPointerOld(buttons, x, y, location, diff, twas, tis);
 513 }
 514
 515 static void VNCPointerOld(int buttons, int x, int y, CGPoint location, int diff, bool twas, bool tis) {
 516     mach_port_t purple(0);
 517
 518     if ((diff & 0x10) != 0) {
 519         struct GSEventRecord record;
 520
 521         memset(&record, 0, sizeof(record));
 522
 523         record.type = (buttons & 0x10) != 0 ?
 524             GSEventTypeHeadsetButtonDown :
 525             GSEventTypeHeadsetButtonUp;
 526
 527         record.timestamp = GSCurrentEventTimestamp();
 528
 529         FixRecord(&record);
 530         GSSendSystemEvent(&record);
 531     }
 532
 533     if ((diff & 0x04) != 0) {
 534         struct GSEventRecord record;
 535
 536         memset(&record, 0, sizeof(record));
 537
 538         record.type = (buttons & 0x04) != 0 ?
 539             GSEventTypeMenuButtonDown :
 540             GSEventTypeMenuButtonUp;
 541
 542         record.timestamp = GSCurrentEventTimestamp();
 543
 544         FixRecord(&record);
 545         GSSendSystemEvent(&record);
 546     }
 547
 548     if ((diff & 0x02) != 0) {
 549         struct GSEventRecord record;
 550
 551         memset(&record, 0, sizeof(record));
 552
 553         record.type = (buttons & 0x02) != 0 ?
 554             GSEventTypeLockButtonDown :
 555             GSEventTypeLockButtonUp;
 556
 557         record.timestamp = GSCurrentEventTimestamp();
 558
 559         FixRecord(&record);
 560         GSSendSystemEvent(&record);
 561     }
 562
 563     if (twas != tis || tis) {
 564         struct VeencyEvent event;
 565
 566         memset(&event, 0, sizeof(event));
 567
 568         event.record.type = GSEventTypeMouse;
 569         event.record.locationInWindow.x = x;
 570         event.record.locationInWindow.y = y;
 571         event.record.timestamp = GSCurrentEventTimestamp();
 572         event.record.size = sizeof(event.data);
 573
 574         event.data.info.handInfo.type = twas == tis ?
 575             GSMouseEventTypeDragged :
 576         tis ?
 577             GSMouseEventTypeDown :
 578             GSMouseEventTypeUp;
 579
 580         event.data.info.handInfo.x34 = 0x1;
 581         event.data.info.handInfo.x38 = tis ? 0x1 : 0x0;
 582
 583         if (Level_ < 3)
 584             event.data.info.pathPositions = 1;
 585         else
 586             event.data.info.x52 = 1;
 587
 588         event.data.path.x00 = 0x01;
 589         event.data.path.x01 = 0x02;
 590         event.data.path.x02 = tis ? 0x03 : 0x00;
 591         event.data.path.position = event.record.locationInWindow;
 592
 593         mach_port_t port(0);
 594
 595         if (CAWindowServer *server = [CAWindowServer serverIfRunning]) {
 596             NSArray *displays([server displays]);
 597             if (displays != nil && [displays count] != 0)
 598                 if (CAWindowServerDisplay *display = [displays objectAtIndex:0])
 599                     port = [display clientPortAtPosition:location];
 600         }
 601
 602         if (port == 0) {
 603             if (purple == 0)
 604                 purple = (*GSTakePurpleSystemEventPort)();
 605             port = purple;
 606         }
 607
 608         FixRecord(&event.record);
 609         GSSendEvent(&event.record, port);
 610     }
 611
 612     if (purple != 0 && PurpleAllocated)
 613         mach_port_deallocate(mach_task_self(), purple);
 614 }
 615
 616 static void VNCSendHIDEvent(IOHIDEventRef event) {
 617     static IOHIDEventSystemClientRef client_(NULL);
 618     if (client_ == NULL)
 619         client_ = IOHIDEventSystemClientCreate(kCFAllocatorDefault);
 620
 621     IOHIDEventSetSenderID(event, 0xDEFACEDBEEFFECE5);
 622     IOHIDEventSystemClientDispatchEvent(client_, event);
 623     CFRelease(event);
 624 }
 625
 626 static void VNCPointerNew(int buttons, int x, int y, CGPoint location, int diff, bool twas, bool tis) {
 627     if ((diff & 0x10) != 0)
 628         VNCSendHIDEvent(IOHIDEventCreateKeyboardEvent(kCFAllocatorDefault, mach_absolute_time(), kHIDPage_Telephony, kHIDUsage_Tfon_Flash, (buttons & 0x10) != 0, 0));
 629     if ((diff & 0x04) != 0)
 630         VNCSendHIDEvent(IOHIDEventCreateKeyboardEvent(kCFAllocatorDefault, mach_absolute_time(), kHIDPage_Consumer, kHIDUsage_Csmr_Menu, (buttons & 0x04) != 0, 0));
 631     if ((diff & 0x02) != 0)
 632         VNCSendHIDEvent(IOHIDEventCreateKeyboardEvent(kCFAllocatorDefault, mach_absolute_time(), kHIDPage_Consumer, kHIDUsage_Csmr_Power, (buttons & 0x02) != 0, 0));
 633
 634     uint32_t handm;
 635     uint32_t fingerm;
 636
 637     if (twas == 0 && tis == 1) {
 638         handm = kIOHIDDigitizerEventRange | kIOHIDDigitizerEventTouch | kIOHIDDigitizerEventIdentity;
 639         fingerm = kIOHIDDigitizerEventRange | kIOHIDDigitizerEventTouch;
 640     } else if (twas == 1 && tis == 1) {
 641         handm = kIOHIDDigitizerEventPosition;
 642         fingerm = kIOHIDDigitizerEventPosition;
 643     } else if (twas == 1 && tis == 0) {
 644         handm = kIOHIDDigitizerEventRange | kIOHIDDigitizerEventTouch | kIOHIDDigitizerEventIdentity | kIOHIDDigitizerEventPosition;
 645         fingerm = kIOHIDDigitizerEventRange | kIOHIDDigitizerEventTouch;
 646     } else return;
 647
 648     // XXX: avoid division in VNCPointer()
 649     x *= ratio_;
 650     y *= ratio_;
 651
 652     IOHIDFloat xf(x);
 653     IOHIDFloat yf(y);
 654
 655     xf /= width_;
 656     yf /= height_;
 657
 658     IOHIDEventRef hand(IOHIDEventCreateDigitizerEvent(kCFAllocatorDefault, mach_absolute_time(), kIOHIDDigitizerTransducerTypeHand, 1<<22, 1, handm, 0, xf, yf, 0, 0, 0, 0, 0, 0));
 659     IOHIDEventSetIntegerValue(hand, kIOHIDEventFieldIsBuiltIn, true);
 660     IOHIDEventSetIntegerValue(hand, kIOHIDEventFieldDigitizerIsDisplayIntegrated, true);
 661
 662     IOHIDEventRef finger(IOHIDEventCreateDigitizerFingerEvent(kCFAllocatorDefault, mach_absolute_time(), 3, 2, fingerm, xf, yf, 0, 0, 0, tis, tis, 0));
 663     IOHIDEventAppendEvent(hand, finger);
 664     CFRelease(finger);
 665
 666     VNCSendHIDEvent(hand);
 667 }
 668
 669 GSEventRef (*$GSEventCreateKeyEvent)(int, CGPoint, CFStringRef, CFStringRef, id, UniChar, short, short);
 670 GSEventRef (*$GSCreateSyntheticKeyEvent)(UniChar, BOOL, BOOL);
 671
 672 static void VNCKeyboardNew(rfbBool down, rfbKeySym key, rfbClientPtr client) {
 673     //NSLog(@"VNC d:%u k:%04x", down, key);
 674
 675     uint16_t usage;
 676
 677     switch (key) {
 678         case XK_exclam: case XK_1: usage = kHIDUsage_Keyboard1; break;
 679         case XK_at: case XK_2: usage = kHIDUsage_Keyboard2; break;
 680         case XK_numbersign: case XK_3: usage = kHIDUsage_Keyboard3; break;
 681         case XK_dollar: case XK_4: usage = kHIDUsage_Keyboard4; break;
 682         case XK_percent: case XK_5: usage = kHIDUsage_Keyboard5; break;
 683         case XK_asciicircum: case XK_6: usage = kHIDUsage_Keyboard6; break;
 684         case XK_ampersand: case XK_7: usage = kHIDUsage_Keyboard7; break;
 685         case XK_asterisk: case XK_8: usage = kHIDUsage_Keyboard8; break;
 686         case XK_parenleft: case XK_9: usage = kHIDUsage_Keyboard9; break;
 687         case XK_parenright: case XK_0: usage = kHIDUsage_Keyboard0; break;
 688
 689         case XK_A: case XK_a: usage = kHIDUsage_KeyboardA; break;
 690         case XK_B: case XK_b: usage = kHIDUsage_KeyboardB; break;
 691         case XK_C: case XK_c: usage = kHIDUsage_KeyboardC; break;
 692         case XK_D: case XK_d: usage = kHIDUsage_KeyboardD; break;
 693         case XK_E: case XK_e: usage = kHIDUsage_KeyboardE; break;
 694         case XK_F: case XK_f: usage = kHIDUsage_KeyboardF; break;
 695         case XK_G: case XK_g: usage = kHIDUsage_KeyboardG; break;
 696         case XK_H: case XK_h: usage = kHIDUsage_KeyboardH; break;
 697         case XK_I: case XK_i: usage = kHIDUsage_KeyboardI; break;
 698         case XK_J: case XK_j: usage = kHIDUsage_KeyboardJ; break;
 699         case XK_K: case XK_k: usage = kHIDUsage_KeyboardK; break;
 700         case XK_L: case XK_l: usage = kHIDUsage_KeyboardL; break;
 701         case XK_M: case XK_m: usage = kHIDUsage_KeyboardM; break;
 702         case XK_N: case XK_n: usage = kHIDUsage_KeyboardN; break;
 703         case XK_O: case XK_o: usage = kHIDUsage_KeyboardO; break;
 704         case XK_P: case XK_p: usage = kHIDUsage_KeyboardP; break;
 705         case XK_Q: case XK_q: usage = kHIDUsage_KeyboardQ; break;
 706         case XK_R: case XK_r: usage = kHIDUsage_KeyboardR; break;
 707         case XK_S: case XK_s: usage = kHIDUsage_KeyboardS; break;
 708         case XK_T: case XK_t: usage = kHIDUsage_KeyboardT; break;
 709         case XK_U: case XK_u: usage = kHIDUsage_KeyboardU; break;
 710         case XK_V: case XK_v: usage = kHIDUsage_KeyboardV; break;
 711         case XK_W: case XK_w: usage = kHIDUsage_KeyboardW; break;
 712         case XK_X: case XK_x: usage = kHIDUsage_KeyboardX; break;
 713         case XK_Y: case XK_y: usage = kHIDUsage_KeyboardY; break;
 714         case XK_Z: case XK_z: usage = kHIDUsage_KeyboardZ; break;
 715
 716         case XK_underscore: case XK_minus: usage = kHIDUsage_KeyboardHyphen; break;
 717         case XK_plus: case XK_equal: usage = kHIDUsage_KeyboardEqualSign; break;
 718         case XK_braceleft: case XK_bracketleft: usage = kHIDUsage_KeyboardOpenBracket; break;
 719         case XK_braceright: case XK_bracketright: usage = kHIDUsage_KeyboardCloseBracket; break;
 720         case XK_bar: case XK_backslash: usage = kHIDUsage_KeyboardBackslash; break;
 721         case XK_colon: case XK_semicolon: usage = kHIDUsage_KeyboardSemicolon; break;
 722         case XK_quotedbl: case XK_apostrophe: usage = kHIDUsage_KeyboardQuote; break;
 723         case XK_asciitilde: case XK_grave: usage = kHIDUsage_KeyboardGraveAccentAndTilde; break;
 724         case XK_less: case XK_comma: usage = kHIDUsage_KeyboardComma; break;
 725         case XK_greater: case XK_period: usage = kHIDUsage_KeyboardPeriod; break;
 726         case XK_question: case XK_slash: usage = kHIDUsage_KeyboardSlash; break;
 727
 728         case XK_Return: usage = kHIDUsage_KeyboardReturnOrEnter; break;
 729         case XK_BackSpace: usage = kHIDUsage_KeyboardDeleteOrBackspace; break;
 730         case XK_Tab: usage = kHIDUsage_KeyboardTab; break;
 731         case XK_space: usage = kHIDUsage_KeyboardSpacebar; break;
 732
 733         case XK_Shift_L: usage = kHIDUsage_KeyboardLeftShift; break;
 734         case XK_Shift_R: usage = kHIDUsage_KeyboardRightShift; break;
 735         case XK_Control_L: usage = kHIDUsage_KeyboardLeftControl; break;
 736         case XK_Control_R: usage = kHIDUsage_KeyboardRightControl; break;
 737         case XK_Meta_L: usage = kHIDUsage_KeyboardLeftAlt; break;
 738         case XK_Meta_R: usage = kHIDUsage_KeyboardRightAlt; break;
 739         case XK_Alt_L: usage = kHIDUsage_KeyboardLeftGUI; break;
 740         case XK_Alt_R: usage = kHIDUsage_KeyboardRightGUI; break;
 741
 742         case XK_Up: usage = kHIDUsage_KeyboardUpArrow; break;
 743         case XK_Down: usage = kHIDUsage_KeyboardDownArrow; break;
 744         case XK_Left: usage = kHIDUsage_KeyboardLeftArrow; break;
 745         case XK_Right: usage = kHIDUsage_KeyboardRightArrow; break;
 746
 747         case XK_Home: case XK_Begin: usage = kHIDUsage_KeyboardHome; break;
 748         case XK_End: usage = kHIDUsage_KeyboardEnd; break;
 749         case XK_Page_Up: usage = kHIDUsage_KeyboardPageUp; break;
 750         case XK_Page_Down: usage = kHIDUsage_KeyboardPageDown; break;
 751
 752         default: return;
 753     }
 754
 755     VNCSendHIDEvent(IOHIDEventCreateKeyboardEvent(kCFAllocatorDefault, mach_absolute_time(), kHIDPage_KeyboardOrKeypad, usage, down, 0));
 756 }
 757
 758 static void VNCKeyboard(rfbBool down, rfbKeySym key, rfbClientPtr client) {
 759     if (kCFCoreFoundationVersionNumber >= 800)
 760         return VNCKeyboardNew(down, key, client);
 761
 762     if (!down)
 763         return;
 764
 765     switch (key) {
 766         case XK_Return: key = '\r'; break;
 767         case XK_BackSpace: key = 0x7f; break;
 768     }
 769
 770     if (key > 0xfff)
 771         return;
 772
 773     CGPoint point(CGPointMake(x_, y_));
 774
 775     UniChar unicode(key);
 776     CFStringRef string(NULL);
 777
 778     GSEventRef event0, event1(NULL);
 779     if ($GSEventCreateKeyEvent != NULL) {
 780         string = CFStringCreateWithCharacters(kCFAllocatorDefault, &unicode, 1);
 781         event0 = (*$GSEventCreateKeyEvent)(10, point, string, string, nil, 0, 0, 1);
 782         event1 = (*$GSEventCreateKeyEvent)(11, point, string, string, nil, 0, 0, 1);
 783     } else if ($GSCreateSyntheticKeyEvent != NULL) {
 784         event0 = (*$GSCreateSyntheticKeyEvent)(unicode, YES, YES);
 785         GSEventRecord *record(_GSEventGetGSEventRecord(event0));
 786         record->type = GSEventTypeKeyDown;
 787     } else return;
 788
 789     mach_port_t port(0);
 790
 791     if (CAWindowServer *server = [CAWindowServer serverIfRunning]) {
 792         NSArray *displays([server displays]);
 793         if (displays != nil && [displays count] != 0)
 794             if (CAWindowServerDisplay *display = [displays objectAtIndex:0])
 795                 port = [display clientPortAtPosition:point];
 796     }
 797
 798     mach_port_t purple(0);
 799
 800     if (port == 0) {
 801         if (purple == 0)
 802             purple = (*GSTakePurpleSystemEventPort)();
 803         port = purple;
 804     }
 805
 806     if (port != 0) {
 807         GSSendEvent(_GSEventGetGSEventRecord(event0), port);
 808         if (event1 != NULL)
 809             GSSendEvent(_GSEventGetGSEventRecord(event1), port);
 810     }
 811
 812     if (purple != 0 && PurpleAllocated)
 813         mach_port_deallocate(mach_task_self(), purple);
 814
 815     CFRelease(event0);
 816     if (event1 != NULL)
 817         CFRelease(event1);
 818     if (string != NULL)
 819         CFRelease(string);
 820 }
 821
 822 static void VNCDisconnect(rfbClientPtr client) {
 823     @synchronized (condition_) {
 824         if (--clients_ == 0)
 825             [VNCBridge performSelectorOnMainThread:@selector(removeStatusBarItem) withObject:nil waitUntilDone:YES];
 826     }
 827 }
 828
 829 static rfbNewClientAction VNCClient(rfbClientPtr client) {
 830     [condition_ lock];
 831
 832     rfbNewClientAction action;
 833     if (screen_->authPasswdData != NULL)
 834         action = RFB_CLIENT_ACCEPT;
 835     else {
 836         client_ = client;
 837         [VNCBridge performSelectorOnMainThread:@selector(askForConnection) withObject:nil waitUntilDone:NO];
 838         while (action_ == RFB_CLIENT_ON_HOLD)
 839             [condition_ wait];
 840         action = action_;
 841         action_ = RFB_CLIENT_ON_HOLD;
 842     }
 843
 844     if (action == RFB_CLIENT_ACCEPT) {
 845         [VNCBridge performSelectorOnMainThread:@selector(registerClient) withObject:nil waitUntilDone:YES];
 846         client->clientGoneHook = &VNCDisconnect;
 847     }
 848
 849     [condition_ unlock];
 850     return action;
 851 }
 852
 853 extern "C" bool GSSystemHasCapability(NSString *);
 854
 855 static CFTypeRef (*$GSSystemCopyCapability)(CFStringRef);
 856 static CFTypeRef (*$GSSystemGetCapability)(CFStringRef);
 857 static BOOL (*$MGGetBoolAnswer)(CFStringRef);
 858
 859 static void VNCSetup() {
 860     rfbLogEnable(false);
 861
 862     @synchronized (condition_) {
 863         int argc(1);
 864         char *arg0(strdup("VNCServer"));
 865         char *argv[] = {arg0, NULL};
 866         screen_ = rfbGetScreen(&argc, argv, width_, height_, BitsPerSample, 3, BytesPerPixel);
 867         free(arg0);
 868
 869         VNCSettings();
 870     }
 871
 872     screen_->desktopName = strdup([[[NSProcessInfo processInfo] hostName] UTF8String]);
 873
 874     screen_->alwaysShared = TRUE;
 875     screen_->handleEventsEagerly = TRUE;
 876     screen_->deferUpdateTime = 1000 / 25;
 877
 878     screen_->serverFormat.redShift = BitsPerSample * 2;
 879     screen_->serverFormat.greenShift = BitsPerSample * 1;
 880     screen_->serverFormat.blueShift = BitsPerSample * 0;
 881
 882     $GSSystemCopyCapability = reinterpret_cast<CFTypeRef (*)(CFStringRef)>(dlsym(RTLD_DEFAULT, "GSSystemCopyCapability"));
 883     $GSSystemGetCapability = reinterpret_cast<CFTypeRef (*)(CFStringRef)>(dlsym(RTLD_DEFAULT, "GSSystemGetCapability"));
 884     $MGGetBoolAnswer = reinterpret_cast<BOOL (*)(CFStringRef)>(dlsym(RTLD_DEFAULT, "MGGetBoolAnswer"));
 885
 886     CFTypeRef opengles2;
 887
 888     if ($GSSystemCopyCapability != NULL) {
 889         opengles2 = (*$GSSystemCopyCapability)(CFSTR("opengles-2"));
 890     } else if ($GSSystemGetCapability != NULL) {
 891         opengles2 = (*$GSSystemGetCapability)(CFSTR("opengles-2"));
 892         if (opengles2 != NULL)
 893             CFRetain(opengles2);
 894     } else if ($MGGetBoolAnswer != NULL) {
 895         opengles2 = $MGGetBoolAnswer(CFSTR("opengles-2")) ? kCFBooleanTrue : kCFBooleanFalse;
 896         CFRetain(opengles2);
 897     } else
 898         opengles2 = NULL;
 899
 900     bool accelerated(opengles2 != NULL && [(NSNumber *)opengles2 boolValue]);
 901
 902     if (accelerated)
 903         IOSurfaceAcceleratorCreate(NULL, NULL, &accelerator_);
 904
 905     if (opengles2 != NULL)
 906         CFRelease(opengles2);
 907
 908     if (accelerator_ == NULL)
 909         VNCBlack();
 910     else {
 911         buffer_ = IOSurfaceCreate((CFDictionaryRef) [NSDictionary dictionaryWithObjectsAndKeys:
 912             @"PurpleEDRAM", kIOSurfaceMemoryRegion,
 913             [NSNumber numberWithBool:YES], kIOSurfaceIsGlobal,
 914             [NSNumber numberWithInt:(width_ * BytesPerPixel)], kIOSurfaceBytesPerRow,
 915             [NSNumber numberWithInt:width_], kIOSurfaceWidth,
 916             [NSNumber numberWithInt:height_], kIOSurfaceHeight,
 917             [NSNumber numberWithInt:'BGRA'], kIOSurfacePixelFormat,
 918             [NSNumber numberWithInt:(width_ * height_ * BytesPerPixel)], kIOSurfaceAllocSize,
 919         nil]);
 920
 921         IOSurfaceLock(buffer_, 3);
 922         screen_->frameBuffer = reinterpret_cast<char *>(IOSurfaceGetBaseAddress(buffer_));
 923         IOSurfaceUnlock(buffer_);
 924     }
 925
 926     screen_->kbdAddEvent = &VNCKeyboard;
 927     screen_->ptrAddEvent = &VNCPointer;
 928
 929     screen_->newClientHook = &VNCClient;
 930     screen_->passwordCheck = &VNCCheck;
 931
 932     screen_->cursor = NULL;
 933 }
 934
 935 static void VNCEnabled() {
 936     if (screen_ == NULL)
 937         return;
 938
 939     @synchronized (lock_) {
 940
 941     Boolean valid;
 942     bool enabled(CFPreferencesGetAppBooleanValue(CFSTR("Enabled"), CFSTR("com.saurik.Veency"), &valid));
 943     if (!valid)
 944         enabled = true;
 945
 946     if (enabled != running_)
 947         if (enabled) {
 948             running_ = true;
 949             screen_->socketState = RFB_SOCKET_INIT;
 950             rfbInitServer(screen_);
 951             rfbRunEventLoop(screen_, -1, true);
 952         } else {
 953             rfbShutdownServer(screen_, true);
 954             running_ = false;
 955         }
 956
 957     }
 958 }
 959
 960 static void VNCNotifyEnabled(
 961     CFNotificationCenterRef center,
 962     void *observer,
 963     CFStringRef name,
 964     const void *object,
 965     CFDictionaryRef info
 966 ) {
 967     CFPreferencesAppSynchronize(CFSTR("com.saurik.Veency"));
 968     VNCEnabled();
 969 }
 970
 971 void (*$IOMobileFramebufferIsMainDisplay)(IOMobileFramebufferRef, int *);
 972
 973 static IOMobileFramebufferRef main_;
 974 static IOSurfaceRef layer_;
 975
 976 static void OnLayer(IOMobileFramebufferRef fb, IOSurfaceRef layer) {
 977     if (_unlikely(width_ == 0 || height_ == 0)) {
 978         CGSize size;
 979         IOMobileFramebufferGetDisplaySize(fb, &size);
 980
 981         width_ = size.width;
 982         height_ = size.height;
 983
 984         if (width_ == 0 || height_ == 0)
 985             return;
 986
 987         NSThread *thread([NSThread alloc]);
 988
 989         [thread
 990             initWithTarget:[VNCBridge class]
 991             selector:@selector(performSetup:)
 992             object:thread
 993         ];
 994
 995         [thread start];
 996     } else if (_unlikely(clients_ != 0)) {
 997         if (layer == NULL) {
 998             if (accelerator_ != NULL)
 999                 memset(screen_->frameBuffer, 0, sizeof(rfbPixel) * width_ * height_);
1000             else
1001                 VNCBlack();
1002         } else {
1003             if (accelerator_ != NULL)
1004                 IOSurfaceAcceleratorTransferSurface(accelerator_, layer, buffer_, NULL, NULL, NULL, NULL);
1005             else {
1006                 IOSurfaceLock(layer, 2);
1007                 rfbPixel *data(reinterpret_cast<rfbPixel *>(IOSurfaceGetBaseAddress(layer)));
1008
1009                 IOSurfaceFlushProcessorCaches(layer);
1010
1011                 /*rfbPixel corner(data[0]);
1012                 data[0] = 0;
1013                 data[0] = corner;*/
1014
1015                 screen_->frameBuffer = const_cast<char *>(reinterpret_cast<volatile char *>(data));
1016                 IOSurfaceUnlock(layer);
1017             }
1018         }
1019
1020         rfbMarkRectAsModified(screen_, 0, 0, width_, height_);
1021     }
1022 }
1023
1024 static bool wait_ = false;
1025
1026 MSHook(kern_return_t, IOMobileFramebufferSwapSetLayer,
1027     IOMobileFramebufferRef fb,
1028     int layer,
1029     IOSurfaceRef buffer,
1030     CGRect bounds,
1031     CGRect frame,
1032     int flags
1033 ) {
1034     int main(false);
1035
1036     if (_unlikely(buffer == NULL))
1037         main = fb == main_;
1038     else if (_unlikely(fb == NULL))
1039         main = false;
1040     else if ($IOMobileFramebufferIsMainDisplay == NULL)
1041         main = true;
1042     else
1043         (*$IOMobileFramebufferIsMainDisplay)(fb, &main);
1044
1045     if (_likely(main)) {
1046         main_ = fb;
1047         if (wait_)
1048             layer_ = buffer;
1049         else
1050             OnLayer(fb, buffer);
1051     }
1052
1053     return _IOMobileFramebufferSwapSetLayer(fb, layer, buffer, bounds, frame, flags);
1054 }
1055
1056 // XXX: beg rpetrich for the type of this function
1057 extern "C" void *IOMobileFramebufferSwapWait(IOMobileFramebufferRef, void *, unsigned);
1058
1059 MSHook(void *, IOMobileFramebufferSwapWait, IOMobileFramebufferRef fb, void *arg1, unsigned flags) {
1060     void *value(_IOMobileFramebufferSwapWait(fb, arg1, flags));
1061     if (fb == main_)
1062         OnLayer(fb, layer_);
1063     return value;
1064 }
1065
1066 MSHook(void, rfbRegisterSecurityHandler, rfbSecurityHandler *handler) {
1067     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
1068
1069     @synchronized (lock_) {
1070         [handlers_ addObject:[NSValue valueWithPointer:handler]];
1071         _rfbRegisterSecurityHandler(handler);
1072     }
1073
1074     [pool release];
1075 }
1076
1077 template <typename Type_>
1078 static void dlset(Type_ &function, const char *name) {
1079     function = reinterpret_cast<Type_>(dlsym(RTLD_DEFAULT, name));
1080 }
1081
1082 MSInitialize {
1083     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
1084
1085     MSHookSymbol(GSTakePurpleSystemEventPort, "_GSGetPurpleSystemEventPort");
1086     if (GSTakePurpleSystemEventPort == NULL) {
1087         MSHookSymbol(GSTakePurpleSystemEventPort, "_GSCopyPurpleSystemEventPort");
1088         PurpleAllocated = true;
1089     }
1090
1091     if (dlsym(RTLD_DEFAULT, "GSLibraryCopyGenerationInfoValueForKey") != NULL)
1092         Level_ = 3;
1093     else if (dlsym(RTLD_DEFAULT, "GSKeyboardCreate") != NULL)
1094         Level_ = 2;
1095     else if (dlsym(RTLD_DEFAULT, "GSEventGetWindowContextId") != NULL)
1096         Level_ = 1;
1097     else
1098         Level_ = 0;
1099
1100     size_t size;
1101     sysctlbyname("hw.machine", NULL, &size, NULL, 0);
1102     char machine[size];
1103     sysctlbyname("hw.machine", machine, &size, NULL, 0);
1104     iPad1_ = strcmp(machine, "iPad1,1") == 0;
1105
1106     dlset($GSMainScreenScaleFactor, "GSMainScreenScaleFactor");
1107     dlset($GSEventCreateKeyEvent, "GSEventCreateKeyEvent");
1108     dlset($GSCreateSyntheticKeyEvent, "_GSCreateSyntheticKeyEvent");
1109     dlset($IOMobileFramebufferIsMainDisplay, "IOMobileFramebufferIsMainDisplay");
1110
1111     MSHookFunction(&IOMobileFramebufferSwapSetLayer, MSHake(IOMobileFramebufferSwapSetLayer));
1112     MSHookFunction(&rfbRegisterSecurityHandler, MSHake(rfbRegisterSecurityHandler));
1113
1114     if (wait_)
1115         MSHookFunction(&IOMobileFramebufferSwapWait, MSHake(IOMobileFramebufferSwapWait));
1116
1117     if ($SBAlertItem != nil) {
1118         $VNCAlertItem = objc_allocateClassPair($SBAlertItem, "VNCAlertItem", 0);
1119         MSAddMessage2(VNCAlertItem, "v@:@i", alertSheet,buttonClicked);
1120         MSAddMessage2(VNCAlertItem, "v@:cc", configure,requirePasscodeForActions);
1121         MSAddMessage0(VNCAlertItem, "v@:", performUnlockAction);
1122         objc_registerClassPair($VNCAlertItem);
1123     }
1124
1125     CFNotificationCenterAddObserver(
1126         CFNotificationCenterGetDarwinNotifyCenter(),
1127         NULL, &VNCNotifyEnabled, CFSTR("com.saurik.Veency-Enabled"), NULL, 0
1128     );
1129
1130     CFNotificationCenterAddObserver(
1131         CFNotificationCenterGetDarwinNotifyCenter(),
1132         NULL, &VNCNotifySettings, CFSTR("com.saurik.Veency-Settings"), NULL, 0
1133     );
1134
1135     condition_ = [[NSCondition alloc] init];
1136     lock_ = [[NSLock alloc] init];
1137     handlers_ = [[NSMutableSet alloc] init];
1138
1139     bool value;
1140
1141     value = true;
1142     cfTrue_ = CFDataCreate(kCFAllocatorDefault, reinterpret_cast<UInt8 *>(&value), sizeof(value));
1143
1144     value = false;
1145     cfFalse_ = CFDataCreate(kCFAllocatorDefault, reinterpret_cast<UInt8 *>(&value), sizeof(value));
1146
1147     cfEvent_ = CFDataCreateWithBytesNoCopy(kCFAllocatorDefault, reinterpret_cast<UInt8 *>(&event_), sizeof(event_), kCFAllocatorNull);
1148
1149     [pool release];
1150 }